qcsrc/common/notifications/all.qh

   1 #pragma once
   2
   3 #include <common/command/_mod.qh>
   4
   5 #include <common/constants.qh>
   6 #include <common/teams.qh>
   7 #include <common/util.qh>
   8 #include <common/sounds/sound.qh>
   9 #include <common/weapons/all.qh>
  10
  11 // Operator for bold notifications
  12 #define BOLD_OPERATOR "^BOLD"
  13
  14 /** main types/groups of notifications */
  15 ENUMCLASS(MSG)
  16         /** "Global" AND "personal" announcer messages */
  17         CASE(MSG, ANNCE)
  18         /** "Global" information messages */
  19         CASE(MSG, INFO)
  20         /** "Personal" centerprint messages */
  21         CASE(MSG, CENTER)
  22         /** Subcall MSG_INFO and/or MSG_CENTER notifications */
  23         CASE(MSG, MULTI)
  24         /** Choose which subcall wrapper to activate */
  25         CASE(MSG, CHOICE)
  26         /** Kill centerprint message @deprecated */
  27         CASE(MSG, CENTER_KILL)
  28 ENUMCLASS_END(MSG)
  29
  30 string Get_Notif_TypeName(MSG net_type)
  31 {
  32         switch (net_type)
  33         {
  34                 case MSG_ANNCE: return "MSG_ANNCE";
  35                 case MSG_INFO: return "MSG_INFO";
  36                 case MSG_CENTER: return "MSG_CENTER";
  37                 case MSG_MULTI: return "MSG_MULTI";
  38                 case MSG_CHOICE: return "MSG_CHOICE";
  39                 case MSG_CENTER_KILL: return "MSG_CENTER_KILL";
  40         }
  41         LOG_WARNF("Get_Notif_TypeName(%d): Improper net type!", ORDINAL(net_type));
  42         return "";
  43 }
  44
  45 ENUMCLASS(CPID)
  46         CASE(CPID, ASSAULT_ROLE)
  47         CASE(CPID, ROUND)
  48         CASE(CPID, CAMPCHECK)
  49         CASE(CPID, CTF_CAPSHIELD)
  50         CASE(CPID, CTF_LOWPRIO)
  51         CASE(CPID, CTF_PASS)
  52         CASE(CPID, STALEMATE)
  53         CASE(CPID, NADES)
  54         CASE(CPID, IDLING)
  55         CASE(CPID, ITEM)
  56         CASE(CPID, PREVENT_JOIN)
  57         CASE(CPID, KEEPAWAY)
  58         CASE(CPID, KEEPAWAY_WARN)
  59         CASE(CPID, KEYHUNT)
  60         CASE(CPID, KEYHUNT_OTHER)
  61         CASE(CPID, LMS)
  62         CASE(CPID, MISSING_TEAMS)
  63         CASE(CPID, MISSING_PLAYERS)
  64         CASE(CPID, INSTAGIB_FINDAMMO)
  65         CASE(CPID, NIX)
  66         CASE(CPID, ONSLAUGHT)
  67         CASE(CPID, ONS_CAPSHIELD)
  68         CASE(CPID, OVERTIME)
  69         CASE(CPID, POWERUP)
  70         CASE(CPID, RACE_FINISHLAP)
  71         CASE(CPID, TEAMCHANGE)
  72         CASE(CPID, TIMEOUT)
  73         CASE(CPID, TIMEIN)
  74         CASE(CPID, VEHICLES)
  75         CASE(CPID, VEHICLES_OTHER)
  76         /** always last */
  77         CASE(CPID, LAST)
  78 ENUMCLASS_END(CPID)
  79
  80 USING(Notification, entity);
  81
  82 // used for notification system multi-team identifiers
  83 #define APP_TEAM_NUM(num, prefix) ((num == NUM_TEAM_1) ? prefix##_RED : ((num == NUM_TEAM_2) ? prefix##_BLUE : ((num == NUM_TEAM_3) ? prefix##_YELLOW : prefix##_PINK)))
  84 #define APP_NUM(num, prefix) ((num) ? APP_TEAM_NUM(num, prefix) : prefix##_NEUTRAL)
  85
  86 #define EIGHT_VARS_TO_VARARGS_VARLIST \
  87         VARITEM(1, 0, s1) \
  88         VARITEM(2, 0, XPD(s1, s2)) \
  89         VARITEM(3, 0, XPD(s1, s2, s3)) \
  90         VARITEM(4, 0, XPD(s1, s2, s3, s4)) \
  91         VARITEM(0, 1, f1) \
  92         VARITEM(1, 1, XPD(s1, f1)) \
  93         VARITEM(2, 1, XPD(s1, s2, f1)) \
  94         VARITEM(3, 1, XPD(s1, s2, s3, f1)) \
  95         VARITEM(4, 1, XPD(s1, s2, s3, s4, f1)) \
  96         VARITEM(0, 2, XPD(f1, f2)) \
  97         VARITEM(1, 2, XPD(s1, f1, f2)) \
  98         VARITEM(2, 2, XPD(s1, s2, f1, f2)) \
  99         VARITEM(3, 2, XPD(s1, s2, s3, f1, f2)) \
 100         VARITEM(4, 2, XPD(s1, s2, s3, s4, f1, f2)) \
 101         VARITEM(0, 3, XPD(f1, f2, f3)) \
 102         VARITEM(1, 3, XPD(s1, f1, f2, f3)) \
 103         VARITEM(2, 3, XPD(s1, s2, f1, f2, f3)) \
 104         VARITEM(3, 3, XPD(s1, s2, s3, f1, f2, f3)) \
 105         VARITEM(4, 3, XPD(s1, s2, s3, s4, f1, f2, f3)) \
 106         VARITEM(0, 4, XPD(f1, f2, f3, f4)) \
 107         VARITEM(1, 4, XPD(s1, f1, f2, f3, f4)) \
 108         VARITEM(2, 4, XPD(s1, s2, f1, f2, f3, f4)) \
 109         VARITEM(3, 4, XPD(s1, s2, s3, f1, f2, f3, f4)) \
 110         VARITEM(4, 4, XPD(s1, s2, s3, s4, f1, f2, f3, f4))
 111
 112 void Destroy_All_Notifications();
 113 void Create_Notification_Entity(entity notif,
 114         float var_default,
 115         float var_cvar,
 116         MSG typeId,
 117         string namestring,
 118         int teamnum);
 119 void Create_Notification_Entity_Annce(entity notif,
 120                                                                                 float var_cvar,
 121                                                                                 string namestring,
 122                                                                                 /* MSG_ANNCE */
 123                                                                                 float channel,
 124                                                                                 string snd,
 125                                                                                 float vol,
 126                                                                                 float position);
 127
 128 void Create_Notification_Entity_InfoCenter(entity notif,
 129                                                                                         float var_cvar,
 130                                                                                         string namestring,
 131                                                                                         int strnum,
 132                                                                                         int flnum,
 133                                                                                         /* MSG_INFO & MSG_CENTER */
 134                                                                                         string args,
 135                                                                                         string hudargs,
 136                                                                                         string icon,
 137                                                                                         CPID cpid,
 138                                                                                         string durcnt,
 139                                                                                         string normal,
 140                                                                                         string gentle);
 141
 142 void Create_Notification_Entity_Multi(entity notif,
 143                                                                                 float var_cvar,
 144                                                                                 string namestring,
 145                                                                                 /* MSG_MULTI */
 146                                                                                 Notification anncename,
 147                                                                                 Notification infoname,
 148                                                                                 Notification centername);
 149
 150 void Create_Notification_Entity_Choice(entity notif,
 151                                                                                 float var_cvar,
 152                                                                                 string namestring,
 153                                                                                 /* MSG_CHOICE */
 154                                                                                 float challow_def,
 155                                                                                 float challow_var,
 156                                                                                 MSG chtype,
 157                                                                                 Notification optiona,
 158                                                                                 Notification optionb);
 159
 160 void Dump_Notifications(int fh, bool alsoprint);
 161
 162 #define DEFAULT_FILENAME "notifications_dump.cfg"
 163 // NOTE: dumpeffectinfo, dumpnotifs, dumpturrets and dumpweapons use similar code
 164 GENERIC_COMMAND(dumpnotifs, "Dump all notifications into " DEFAULT_FILENAME, false)
 165 {
 166         switch (request)
 167         {
 168                 case CMD_REQUEST_COMMAND:
 169                 {
 170                         #ifdef GAMEQC
 171                         string filename = argv(1);
 172                         bool alsoprint = false;
 173                         if (filename == "")
 174                         {
 175                                 filename = DEFAULT_FILENAME;
 176                                 alsoprint = false;
 177                         }
 178                         else if (filename == "-")
 179                         {
 180                                 filename = DEFAULT_FILENAME;
 181                                 alsoprint = true;
 182                         }
 183                         int fh = fopen(filename, FILE_WRITE);
 184                         if (fh >= 0)
 185                         {
 186                                 Dump_Notifications(fh, alsoprint);
 187                                 LOG_INFOF("Dumping notifications... File located in ^2data/data/%s^7.", filename);
 188                                 fclose(fh);
 189                         }
 190                         else
 191                         {
 192                                 LOG_INFOF("^1Error: ^7Could not open file '%s'!", filename);
 193                         }
 194                         #else
 195                         LOG_INFO("Notification dump command only works with cl_cmd and sv_cmd.");
 196                         #endif
 197                         return;
 198                 }
 199                 default:
 200                 case CMD_REQUEST_USAGE:
 201                 {
 202                         LOG_HELP("Usage:^3 ", GetProgramCommandPrefix(), " dumpnotifs [<filename>]");
 203                         LOG_HELPF("  Where <filename> is the file to write (default is %s),", DEFAULT_FILENAME);
 204                         LOG_HELP("  if supplied with '-' output to console as well as default,");
 205                         LOG_HELP("  if left blank, it will only write to default.");
 206                         return;
 207                 }
 208         }
 209 }
 210 #undef DEFAULT_FILENAME
 211
 212 #ifdef NOTIFICATIONS_DEBUG
 213 bool autocvar_notification_debug = false;
 214 void Debug_Notification(string input)
 215 {
 216         switch (autocvar_notification_debug)
 217         {
 218                 case 1: { LOG_TRACE(input); break; }
 219                 case 2: { LOG_INFO(input); break; }
 220         }
 221 }
 222 #endif
 223
 224 void Local_Notification(MSG net_type, Notification net_name, ...count);
 225 /** glue for networking, forwards to `Local_Notification` */
 226 void Local_Notification_WOVA(
 227         MSG net_type, Notification net_name,
 228         float stringcount, float floatcount,
 229         string s1, string s2, string s3, string s4,
 230         float f1, float f2, float f3, float f4);
 231
 232 #ifdef CSQC
 233 string prev_soundfile;
 234 float prev_soundtime;
 235 #endif
 236
 237 #ifdef SVQC
 238 IntrusiveList g_notifications;
 239 STATIC_INIT(g_notifications) { g_notifications = IL_NEW(); }
 240 #endif
 241
 242 #ifdef SVQC
 243 ENUMCLASS(NOTIF)
 244         /** send to one client and their spectators */
 245         CASE(NOTIF, ONE)
 246         /** send ONLY to one client */
 247         CASE(NOTIF, ONE_ONLY)
 248         /** send only to X team and their spectators */
 249         CASE(NOTIF, TEAM)
 250         /** send only to X team and their spectators, except for Y person and their spectators */
 251         CASE(NOTIF, TEAM_EXCEPT)
 252         /** send to everyone */
 253         CASE(NOTIF, ALL)
 254         /** send to everyone except X person and their spectators */
 255         CASE(NOTIF, ALL_EXCEPT)
 256 ENUMCLASS_END(NOTIF)
 257
 258 string Get_Notif_BroadcastName(NOTIF broadcast)
 259 {
 260         switch (broadcast)
 261         {
 262                 case NOTIF_ONE: return "NOTIF_ONE";
 263                 case NOTIF_ONE_ONLY: return "NOTIF_ONE_ONLY";
 264                 case NOTIF_ALL_EXCEPT: return "NOTIF_ALL_EXCEPT";
 265                 case NOTIF_ALL: return "NOTIF_ALL";
 266                 case NOTIF_TEAM: return "NOTIF_TEAM";
 267                 case NOTIF_TEAM_EXCEPT: return "NOTIF_TEAM_EXCEPT";
 268         }
 269         LOG_WARNF("Get_Notif_BroadcastName(%d): Improper broadcast!", broadcast);
 270         return "";
 271 }
 272
 273 void Kill_Notification(
 274         NOTIF broadcast, entity client,
 275         MSG net_type, CPID net_name);
 276 void Send_Notification(
 277         NOTIF broadcast, entity client,
 278         MSG net_type, Notification net_name,
 279         ...count);
 280 void Send_Notification_WOVA(
 281         NOTIF broadcast, entity client,
 282         MSG net_type, Notification net_name,
 283         float stringcount, float floatcount,
 284         string s1, string s2, string s3, string s4,
 285         float f1, float f2, float f3, float f4);
 286 void Send_Notification_WOCOVA(
 287         NOTIF broadcast, entity client,
 288         MSG net_type, Notification net_name,
 289         string s1, string s2, string s3, string s4,
 290         float f1, float f2, float f3, float f4);
 291 #endif
 292
 293 // ===========================
 294 //  Special CVAR Declarations
 295 // ===========================
 296
 297 // MAKE SURE THIS IS ALWAYS SYNCHRONIZED WITH THE DUMP
 298 // NOTIFICATIONS FUNCTION IN THE .QC FILE!
 299
 300 #define NOTIF_ADD_AUTOCVAR(name,defaultvalue) float autocvar_notification_##name = defaultvalue;
 301
 302 float autocvar_notification_show_location = false;
 303 string autocvar_notification_show_location_string = ""; //_(" at the %s");
 304 float autocvar_notification_show_sprees = true;
 305 float autocvar_notification_show_sprees_info = 3; // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 306 float autocvar_notification_show_sprees_info_newline = true;
 307 float autocvar_notification_show_sprees_info_specialonly = true;
 308 float autocvar_notification_errors_are_fatal = true;
 309 #ifdef SVQC
 310 float autocvar_notification_lifetime_runtime = 0.5;
 311 float autocvar_notification_lifetime_mapload = 10;
 312 #endif
 313
 314 #ifdef SVQC
 315 void Notification_GetCvars(entity this, entity store);
 316 float autocvar_notification_server_allows_location = 1; // 0 = no, 1 = yes
 317 #else
 318 float autocvar_notification_item_centerprinttime = 1.5;
 319
 320 // 0 = no, 1 = yes, 2 = forced on for all MSG_INFO notifs
 321 // DISABLED IN CODE, BUT ENABLED IN CONFIG FOR COMPATIBILITY WITH OLD CLIENTS
 322 float autocvar_notification_allow_chatboxprint = 0;
 323
 324 float autocvar_notification_show_sprees_center = true;
 325 float autocvar_notification_show_sprees_center_specialonly = true;
 326 #endif
 327
 328
 329 // ============================
 330 //  Notification Argument List
 331 // ============================
 332 /*
 333  These arguments get replaced with the Local_Notification_sprintf
 334  and other such functions found in all.qc to supply data
 335  from networked notifications to their usage in sprintf... It
 336  allows for more dynamic data to be inferred by the local
 337  notification parser, so that the server does not have to network
 338  anything too crazy on a per-client/per-situation basis.
 339
 340  Pay attention to the CSQC/SVQC relations, some of these are redefined
 341  in slightly different ways for different programs, this is because the
 342  server does a more conservative approach to the notifs than the client.
 343
 344  All arguments are swapped into strings, so be sure that your
 345  sprintf usage matches with proper %s placement.
 346
 347  Argument descriptions:
 348         s1-s4: string arguments to be literally swapped into sprintf
 349         s2loc: s2 string of locations of deaths or other events
 350         s3loc: s3 string of locations of deaths or other events
 351         f1-f4: float arguments expanded into strings to be swapped into sprintf
 352         f1p2dec: f1 float to string with 2 decimal places
 353         f2p2dec: f2 float to string with 2 decimal places
 354         f2primsec: f2 float primary or secondary selection for weapons
 355         f3primsec: f3 float primary or secondary selection for weapons
 356         f1secs: count_seconds of f1
 357         f1points: point or points depending on f1
 358         f1ord: count_ordinal of f1
 359         f1time: process_time of f1
 360         f1race_time: TIME_ENCODED_TOSTRING of f1
 361         f2race_time: TIME_ENCODED_TOSTRING of f2
 362         race_col: color of race time/position (i.e. good or bad)
 363         race_diff: show time difference between f2 and f3
 364         missing_teams: show which teams still need players
 365         pass_key: find the keybind for "passing" or "dropping" in CTF game mode
 366         nade_key: find the keybind for nade throwing
 367         frag_ping: show the ping of a player
 368         frag_stats: show health/armor/ping of a player
 369         frag_pos: show score status and position in the match of a player
 370         spree_cen: centerprint notif for kill spree/how many kills they have
 371         spree_inf: info notif for kill spree/how many kills they have
 372         spree_end: placed at the end of murder messages to show ending of sprees
 373         spree_lost: placed at the end of suicide messages to show losing of sprees
 374         item_wepname: return full name of a weapon from weaponid
 375         item_wepammo: ammo display for weapon from f1 and f2
 376         item_centime: amount of time to display weapon message in centerprint
 377         item_buffname: return full name of a buff from buffid
 378         death_team: show the full name of the team a player is switching from
 379         minigame1_name: return human readable name of a minigame from its id(s1)
 380         minigame1_d: return descriptor name of a minigame from its id(s1)
 381 */
 382
 383 const float NOTIF_MAX_ARGS = 7;
 384 const float NOTIF_MAX_HUDARGS = 2;
 385 const float NOTIF_MAX_DURCNT = 2;
 386
 387 string arg_slot[NOTIF_MAX_ARGS];
 388
 389 const float ARG_CS_SV_HA = 1; // enabled on CSQC, SVQC, and Hudargs
 390 const float ARG_CS_SV_DC = 2; // enabled on CSQC, SVQC, and durcnt centerprint
 391 const float ARG_CS_SV = 3; // enabled on CSQC and SVQC
 392 const float ARG_CS = 4; // unique result to CSQC
 393 const float ARG_SV = 5; // unique result to SVQC
 394 const float ARG_DC = 6; // unique result to durcnt/centerprint
 395
 396 // todo possible idea.... declare how many floats/strings each arg needs, and then dynamically increment the input
 397 // this way, we don't need to have duplicates like i.e. s2loc and s3loc?
 398
 399 string BUFF_NAME(int i);
 400
 401 #define NOTIF_ARGUMENT_LIST \
 402         ARG_CASE(ARG_CS_SV_HA,  "s1",            s1) \
 403         ARG_CASE(ARG_CS_SV_HA,  "s2",            s2) \
 404         ARG_CASE(ARG_CS_SV_HA,  "s3",            s3) \
 405         ARG_CASE(ARG_CS_SV_HA,  "s4",            s4) \
 406         ARG_CASE(ARG_CS_SV,     "s2loc",         ((autocvar_notification_show_location && (s2 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s2) : "")) \
 407         ARG_CASE(ARG_CS_SV,     "s3loc",         ((autocvar_notification_show_location && (s3 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s3) : "")) \
 408         ARG_CASE(ARG_CS_SV_DC,  "f1",            ftos(f1)) \
 409         ARG_CASE(ARG_CS_SV_DC,  "f2",            ftos(f2)) \
 410         ARG_CASE(ARG_CS_SV,     "f3",            ftos(f3)) \
 411         ARG_CASE(ARG_CS_SV,     "f4",            ftos(f4)) \
 412         ARG_CASE(ARG_CS_SV,     "f1dtime",       ftos_decimals(TIME_DECODE(f1), 2)) \
 413         ARG_CASE(ARG_CS_SV,     "f2dtime",       ftos_decimals(TIME_DECODE(f2), 2)) \
 414         ARG_CASE(ARG_CS,        "f2primsec",     (f2 ? _("secondary") : _("primary"))) \
 415         ARG_CASE(ARG_CS,        "f3primsec",     (f3 ? _("secondary") : _("primary"))) \
 416         ARG_CASE(ARG_CS,        "f1secs",        count_seconds(f1)) \
 417         ARG_CASE(ARG_CS,        "f1points",      (f1 == 1 ? _("point") : _("points"))) \
 418         ARG_CASE(ARG_CS_SV,     "f1ord",         count_ordinal(f1)) \
 419         ARG_CASE(ARG_CS_SV,     "f1time",        process_time(2, f1)) \
 420         ARG_CASE(ARG_CS_SV_HA,  "f1race_time",   TIME_ENCODED_TOSTRING(f1, true)) \
 421         ARG_CASE(ARG_CS_SV_HA,  "f2race_time",   TIME_ENCODED_TOSTRING(f2, true)) \
 422         ARG_CASE(ARG_CS_SV_HA,  "f3race_time",   TIME_ENCODED_TOSTRING(f3, true)) \
 423         ARG_CASE(ARG_CS_SV,     "race_col",      CCR(((f1 == 1) ? "^F1" : "^F2"))) \
 424         ARG_CASE(ARG_CS_SV,     "race_diff",     ((f2 > f3) ? sprintf(CCR("^1[+%s]"), TIME_ENCODED_TOSTRING(f2 - f3, true)) : sprintf(CCR("^2[-%s]"), TIME_ENCODED_TOSTRING(f3 - f2, true)))) \
 425         ARG_CASE(ARG_CS,        "missing_teams", notif_arg_missing_teams(f1)) \
 426         ARG_CASE(ARG_CS,        "pass_key",      getcommandkey(_("drop flag"), "+use")) \
 427         ARG_CASE(ARG_CS,        "nade_key",      getcommandkey(_("throw nade"), "dropweapon")) \
 428         ARG_CASE(ARG_CS,        "join_key",      getcommandkey(_("jump"), "+jump")) \
 429         ARG_CASE(ARG_CS,        "frag_ping",     notif_arg_frag_ping(true, f2)) \
 430         ARG_CASE(ARG_CS,        "frag_stats",    notif_arg_frag_stats(f2, f3, f4)) \
 431         /*ARG_CASE(ARG_CS,      "frag_pos",      ((Should_Print_Score_Pos(f1)) ? sprintf("\n^BG%s", Read_Score_Pos(f1)) : ""))*/ \
 432         ARG_CASE(ARG_CS,        "spree_cen",     (autocvar_notification_show_sprees ? notif_arg_spree_cen(f1) : "")) \
 433         ARG_CASE(ARG_CS_SV,     "spree_inf",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(1, input, s2, f2) : "")) \
 434         ARG_CASE(ARG_CS_SV,     "spree_end",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(-1, "", "", f1) : "")) \
 435         ARG_CASE(ARG_CS_SV,     "spree_lost",    (autocvar_notification_show_sprees ? notif_arg_spree_inf(-2, "", "", f1) : "")) \
 436         ARG_CASE(ARG_CS_SV,     "item_wepname",  REGISTRY_GET(Weapons, f1).m_name) \
 437         ARG_CASE(ARG_CS_SV,     "item_buffname", BUFF_NAME(f1)) \
 438         ARG_CASE(ARG_CS_SV,     "f3buffname",    BUFF_NAME(f3)) \
 439         ARG_CASE(ARG_CS_SV,     "item_wepammo",  (f2 > 0 ? notif_arg_item_wepammo(f1, f2) : "")) \
 440         ARG_CASE(ARG_DC,        "item_centime",  ftos(autocvar_notification_item_centerprinttime)) \
 441         ARG_CASE(ARG_SV,        "death_team",    Team_ColoredFullName(f1)) \
 442         ARG_CASE(ARG_CS,        "death_team",    Team_ColoredFullName(f1 - 1)) \
 443         ARG_CASE(ARG_CS_SV_HA,  "minigame1_name",find(NULL,netname,s1).descriptor.message) \
 444         ARG_CASE(ARG_CS_SV_HA,  "minigame1_d",   find(NULL,netname,s1).descriptor.netname)
 445
 446 #define NOTIF_HIT_MAX(count,funcname) MACRO_BEGIN \
 447         if(sel_num == count) { backtrace(sprintf("%s: Hit maximum arguments!\n", funcname)); break; } \
 448 MACRO_END
 449
 450 #define NOTIF_HIT_UNKNOWN(token,funcname) { backtrace(sprintf("%s: Hit unknown token in selected string! '%s'\n", funcname, selected)); break; }
 451
 452 #define KILL_SPREE_LIST \
 453         SPREE_ITEM(3, 03, _("TRIPLE FRAG! "), _("%s^K1 made a TRIPLE FRAG! %s^BG"), _("%s^K1 made a TRIPLE SCORE! %s^BG")) \
 454         SPREE_ITEM(5, 05, _("RAGE! "), _("%s^K1 unlocked RAGE! %s^BG"), _("%s^K1 made FIVE SCORES IN A ROW! %s^BG")) \
 455         SPREE_ITEM(10, 10, _("MASSACRE! "), _("%s^K1 started a MASSACRE! %s^BG"), _("%s^K1 made TEN SCORES IN A ROW! %s^BG")) \
 456         SPREE_ITEM(15, 15, _("MAYHEM! "), _("%s^K1 executed MAYHEM! %s^BG"), _("%s^K1 made FIFTEEN SCORES IN A ROW! %s^BG")) \
 457         SPREE_ITEM(20, 20, _("BERSERKER! "), _("%s^K1 is a BERSERKER! %s^BG"), _("%s^K1 made TWENTY SCORES IN A ROW! %s^BG")) \
 458         SPREE_ITEM(25, 25, _("CARNAGE! "), _("%s^K1 inflicts CARNAGE! %s^BG"), _("%s^K1 made TWENTY FIVE SCORES IN A ROW! %s^BG")) \
 459         SPREE_ITEM(30, 30, _("ARMAGEDDON! "), _("%s^K1 unleashes ARMAGEDDON! %s^BG"), _("%s^K1 made THIRTY SCORES IN A ROW! %s^BG"))
 460
 461 #ifdef CSQC
 462 string notif_arg_frag_ping(bool newline, float fping)
 463 {
 464         string s = newline ? "\n" : " ";
 465         if (fping < 0)
 466                 return sprintf(CCR(_("%s(^F1Bot^BG)")), s);
 467         else
 468                 return sprintf(CCR(_("%s(Ping ^F1%d^BG)")), s, fping);
 469 }
 470
 471 string notif_arg_frag_stats(float fhealth, float farmor, float fping)
 472 {
 473         string s = notif_arg_frag_ping(false, fping);
 474         if (fhealth > 1)
 475                 return sprintf(CCR(_("\n(Health ^1%d^BG / Armor ^2%d^BG)%s")), fhealth, farmor, s);
 476         else
 477                 return sprintf(CCR(_("\n(^F4Dead^BG)%s")), s);
 478 }
 479
 480 string notif_arg_missing_teams(float f1)
 481 {
 482         return strcat(
 483                 ((f1 & BIT(0)) ? strcat(Team_ColoredFullName(NUM_TEAM_1), (f1 >> 1) ? ", " : "") : ""),
 484                 ((f1 & BIT(1)) ? strcat(Team_ColoredFullName(NUM_TEAM_2), (f1 >> 2) ? ", " : "") : ""),
 485                 ((f1 & BIT(2)) ? strcat(Team_ColoredFullName(NUM_TEAM_3), (f1 >> 3) ? ", " : "") : ""),
 486                 ((f1 & BIT(3)) ?        Team_ColoredFullName(NUM_TEAM_4)                         : "")
 487         );
 488 }
 489
 490 string notif_arg_spree_cen(float spree)
 491 {
 492         // 0 = off, 1 = target (but only for first victim) and attacker
 493         if(autocvar_notification_show_sprees_center)
 494         {
 495                 if(spree > 1)
 496                 {
 497                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 498                                 case counta: { return normal_or_gentle(center, sprintf(_("%d score spree! "), spree)); }
 499
 500                         switch(spree)
 501                         {
 502                                 KILL_SPREE_LIST
 503                                 default:
 504                                 {
 505                                         if (!autocvar_notification_show_sprees_center_specialonly)
 506                                         {
 507                                                 return
 508                                                         sprintf(
 509                                                                 normal_or_gentle(
 510                                                                         _("%d frag spree! "),
 511                                                                         _("%d score spree! ")
 512                                                                 ),
 513                                                                 spree);
 514                                         }
 515                                         else { return ""; } // don't show spree information if it isn't an achievement
 516                                 }
 517                         }
 518
 519                         #undef SPREE_ITEM
 520                 }
 521                 else if(spree == -1) // first blood
 522                 {
 523                         return normal_or_gentle(_("First blood! "), _("First score! "));
 524                 }
 525                 else if(spree == -2) // first victim
 526                 {
 527                         return normal_or_gentle(_("First victim! "), _("First casualty! "));
 528                 }
 529         }
 530         return "";
 531 }
 532 #endif
 533
 534 string notif_arg_spree_inf(float type, string input, string player, float spree)
 535 {
 536         switch(type)
 537         {
 538                 case 1: // attacker kill spree
 539                 {
 540                         // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 541                         // this conditional (& 2) is true for 2 and 3
 542                         if(autocvar_notification_show_sprees_info & 2)
 543                         {
 544                                 #ifdef CSQC
 545                                 string spree_newline =
 546                                         ( autocvar_notification_show_sprees_info_newline ?
 547                                                 ((substring(input, 0, 1) == "\{3}") ? "\n\{3}" : "\n") : "" );
 548                                 #else
 549                                 string spree_newline =
 550                                         (autocvar_notification_show_sprees_info_newline ? "\n" : "");
 551                                 #endif
 552
 553                                 if(spree > 1)
 554                                 {
 555                                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 556                                                 case counta: { return sprintf(CCR(normal_or_gentle(normal, gentle)), player, spree_newline); }
 557
 558                                         switch(spree)
 559                                         {
 560                                                 KILL_SPREE_LIST
 561                                                 default:
 562                                                 {
 563                                                         if (!autocvar_notification_show_sprees_info_specialonly)
 564                                                         {
 565                                                                 return
 566                                                                         sprintf(
 567                                                                                 CCR(normal_or_gentle(
 568                                                                                         _("%s^K1 has %d frags in a row! %s^BG"),
 569                                                                                         _("%s^K1 made %d scores in a row! %s^BG")
 570                                                                                 )),
 571                                                                                 player,
 572                                                                                 spree,
 573                                                                                 spree_newline
 574                                                                         );
 575                                                         }
 576                                                         else { return ""; } // don't show spree information if it isn't an achievement
 577                                                 }
 578                                         }
 579
 580                                         #undef SPREE_ITEM
 581                                 }
 582                                 else if(spree == -1) // firstblood
 583                                 {
 584                                         return
 585                                                 sprintf(
 586                                                         CCR(normal_or_gentle(
 587                                                                 _("%s^K1 drew first blood! %s^BG"),
 588                                                                 _("%s^K1 got the first score! %s^BG")
 589                                                         )),
 590                                                         player,
 591                                                         spree_newline
 592                                                 );
 593                                 }
 594                         }
 595                         break;
 596                 }
 597
 598                 case -1: // kill spree ended
 599                 {
 600                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 601                         {
 602                                 return
 603                                         sprintf(normal_or_gentle(
 604                                                 _(", ending their %d frag spree"),
 605                                                 _(", ending their %d score spree")
 606                                                 ),
 607                                                 spree
 608                                         );
 609                         }
 610                         break;
 611                 }
 612
 613                 case -2: // kill spree lost
 614                 {
 615                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 616                         {
 617                                 return
 618                                         sprintf(normal_or_gentle(
 619                                                 _(", losing their %d frag spree"),
 620                                                 _(", losing their %d score spree")
 621                                                 ),
 622                                                 spree
 623                                         );
 624                         }
 625                         break;
 626                 }
 627         }
 628         return "";
 629 }
 630
 631 string notif_arg_item_wepammo(float f1, float f2)
 632 {
 633         string ammoitems = "";
 634         Weapon wep = REGISTRY_GET(Weapons, f1);
 635         // TODO: registry handles
 636         switch (wep.ammo_type)
 637         {
 638                 case RES_SHELLS:  ammoitems = ITEM_Shells.m_name;      break;
 639                 case RES_BULLETS: ammoitems = ITEM_Bullets.m_name;     break;
 640                 case RES_ROCKETS: ammoitems = ITEM_Rockets.m_name;     break;
 641                 case RES_CELLS:   ammoitems = ITEM_Cells.m_name;       break;
 642                 case RES_PLASMA:  ammoitems = ITEM_Plasma.m_name;      break;
 643                 case RES_FUEL:    ammoitems = ITEM_JetpackFuel.m_name; break;
 644                 default: return ""; // doesn't use ammo
 645         }
 646         return sprintf(_(" with %d %s"), f2, ammoitems);
 647 }
 648
 649
 650 // ====================================
 651 //  Initialization/Create Declarations
 652 // ====================================
 653
 654 // common notification entity values
 655 .int nent_default;
 656 .bool nent_enabled;
 657 .MSG nent_type;
 658 .string nent_name;
 659 .int nent_stringcount;
 660 .int nent_floatcount;
 661 .int nent_teamnum;
 662
 663 // MSG_ANNCE entity values
 664 .int nent_channel;
 665 .string nent_snd;
 666 .float nent_vol;
 667 .float nent_position;
 668
 669 // MSG_INFO and MSG_CENTER entity values
 670 .string nent_args; // used by both
 671 .string nent_hudargs; // used by info
 672 .string nent_icon; // used by info
 673 .CPID nent_cpid; // used by center
 674 .string nent_durcnt; // used by center
 675 .string nent_string; // used by both
 676
 677 // MSG_MULTI entity values
 678 .entity nent_msgannce;
 679 .entity nent_msginfo;
 680 .entity nent_msgcenter;
 681
 682 // MSG_CHOICE entity values
 683 .float nent_challow_def;
 684 .float nent_challow_var;
 685 .entity nent_optiona;
 686 .entity nent_optionb;
 687
 688 // networked notification entity values
 689 #ifdef SVQC
 690 .NOTIF nent_broadcast;
 691 #endif
 692 .entity nent_client;
 693 .MSG nent_net_type;
 694 .float nent_net_name;
 695 .string nent_strings[4];
 696 .float nent_floats[4];
 697
 698 #define ACVNN(name) autocvar_notification_##name
 699
 700 REGISTRY(Notifications, BITS(11))
 701 REGISTER_REGISTRY(Notifications)
 702 REGISTRY_SORT(Notifications);
 703
 704 REGISTRY_DEFINE_GET(Notifications, NULL)
 705 STATIC_INIT(Notifications) { FOREACH(Notifications, true, it.m_id = i); }
 706 REGISTRY_CHECK(Notifications)
 707
 708 const int NOTIF_CHOICE_MAX = 20;
 709 // NOTE: a team choice is actually made of 4 choices (one per team) with the same nent_choice_idx
 710 // thus they are counted as 1 in nent_choice_count
 711 int nent_choice_count = 0;
 712 .int nent_choice_idx;
 713 .int msg_choice_choices[NOTIF_CHOICE_MAX]; // set on each player containing MSG_CHOICE choices
 714 // initialization error detection
 715 bool notif_error;
 716 bool notif_global_error;
 717
 718 STATIC_INIT_LATE(Notif_Choices)
 719 {
 720         if (nent_choice_count > NOTIF_CHOICE_MAX)
 721                 LOG_FATALF("Too many MSG_CHOICE notifications (%d), hit NOTIF_CHOICE_MAX (%d) limit",
 722                         nent_choice_count, NOTIF_CHOICE_MAX);
 723 }
 724
 725 string Get_Notif_CvarName(Notification notif)
 726 {
 727         if(!notif.nent_teamnum)
 728                 return notif.nent_name;
 729         return substring(notif.nent_name, 0, -strlen(Static_Team_ColorName(notif.nent_teamnum)) - 2);
 730 }
 731
 732 Notification Get_Notif_Ent(MSG net_type, int net_name)
 733 {
 734         Notification it = REGISTRY_GET(Notifications, net_name);
 735         if (it.nent_type != net_type) {
 736                 LOG_WARNF("Get_Notif_Ent(%s (%d), %s (%d)): Improper net type '%s'!",
 737                         Get_Notif_TypeName(net_type), net_type,
 738                         it.registered_id, net_name,
 739                         Get_Notif_TypeName(it.nent_type)
 740                 );
 741                 return NULL;
 742         }
 743         return it;
 744 }
 745
 746 #define MSG_ANNCE_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, sound, channel, volume, position) \
 747         MSG_ANNCE_NOTIF_(teamnum, ANNCE_##name, ANNCE_##cvarname, defaultvalue, sound, channel, volume, position)
 748
 749 #define MSG_ANNCE_NOTIF(name, defaultvalue, sound, channel, volume, position) \
 750         NOTIF_ADD_AUTOCVAR(ANNCE_##name, defaultvalue) \
 751         MSG_ANNCE_NOTIF_(0, ANNCE_##name, ANNCE_##name, defaultvalue, sound, channel, volume, position)
 752
 753 #define MSG_ANNCE_NOTIF_(teamnum, name, cvarname, defaultvalue, sound, channel, volume, position) \
 754         REGISTER(Notifications, name, m_id, new_pure(msg_annce_notification)) { \
 755                 Create_Notification_Entity      (this, defaultvalue, ACVNN(cvarname), MSG_ANNCE, strtoupper(#name), teamnum); \
 756                 Create_Notification_Entity_Annce(this, ACVNN(cvarname), strtoupper(#name), \
 757                         channel,   /* channel  */ \
 758                         sound,     /* snd      */ \
 759                         volume,    /* vol      */ \
 760                         position); /* position */ \
 761         }
 762
 763 #define MSG_INFO_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle) \
 764         MSG_INFO_NOTIF_(teamnum, INFO_##name, INFO_##cvarname, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle)
 765
 766 #define MSG_INFO_NOTIF(name, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle) \
 767         NOTIF_ADD_AUTOCVAR(INFO_##name, defaultvalue) \
 768         MSG_INFO_NOTIF_(0, INFO_##name, INFO_##name, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle)
 769
 770 #define MSG_INFO_NOTIF_(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle) \
 771         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 772                 Create_Notification_Entity           (this, defaultvalue, ACVNN(cvarname), MSG_INFO, strtoupper(#name), teamnum); \
 773                 Create_Notification_Entity_InfoCenter(this, ACVNN(cvarname), strtoupper(#name), strnum, flnum, \
 774                         args,     /* args    */ \
 775                         hudargs,  /* hudargs */ \
 776                         icon,     /* icon    */ \
 777                         CPID_Null,/* cpid    */ \
 778                         "",       /* durcnt  */ \
 779                         normal,   /* normal  */ \
 780                         gentle);  /* gentle  */ \
 781         }
 782
 783 .string nent_iconargs;
 784 #define MULTIICON_INFO(name, defaultvalue, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 785         MULTIICON_INFO_(INFO_##name, defaultvalue, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle)
 786 #define MULTIICON_INFO_(name, defaultvalue, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 787         NOTIF_ADD_AUTOCVAR(name, defaultvalue) \
 788         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 789                 Create_Notification_Entity           (this, defaultvalue, ACVNN(name), MSG_INFO, strtoupper(#name), 0); \
 790                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
 791                         args,     /* args    */ \
 792                         hudargs,  /* hudargs */ \
 793                         icon,     /* icon    */ \
 794                         CPID_Null,/* cpid    */ \
 795                         "",       /* durcnt  */ \
 796                         normal,   /* normal  */ \
 797                         gentle);  /* gentle  */ \
 798                 this.nent_iconargs = iconargs; \
 799         }
 800
 801 #define MSG_CENTER_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 802         MSG_CENTER_NOTIF_(teamnum, CENTER_##name, CENTER_##cvarname, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle)
 803
 804 #define MSG_CENTER_NOTIF(name, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 805         NOTIF_ADD_AUTOCVAR(CENTER_##name, defaultvalue) \
 806         MSG_CENTER_NOTIF_(0, CENTER_##name, CENTER_##name, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle)
 807
 808 #define MSG_CENTER_NOTIF_(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 809         REGISTER(Notifications, name, m_id, new_pure(msg_center_notification)) { \
 810                 Create_Notification_Entity           (this, defaultvalue, ACVNN(cvarname), MSG_CENTER, strtoupper(#name), teamnum); \
 811                 Create_Notification_Entity_InfoCenter(this, ACVNN(cvarname), strtoupper(#name), strnum, flnum, \
 812                         args,    /* args    */ \
 813                         "",      /* hudargs */ \
 814                         "",      /* icon    */ \
 815                         cpid,    /* cpid    */ \
 816                         durcnt,  /* durcnt  */ \
 817                         normal,  /* normal  */ \
 818                         gentle); /* gentle  */ \
 819         }
 820
 821 #define MSG_MULTI_NOTIF(name, defaultvalue, anncename, infoname, centername) \
 822         NOTIF_ADD_AUTOCVAR(name, defaultvalue) \
 823         REGISTER(Notifications, name, m_id, new_pure(msg_multi_notification)) { \
 824                 Create_Notification_Entity      (this, defaultvalue, ACVNN(name), MSG_MULTI, strtoupper(#name), 0); \
 825                 Create_Notification_Entity_Multi(this, ACVNN(name), strtoupper(#name), \
 826                         anncename,   /* anncename  */ \
 827                         infoname,    /* infoname   */ \
 828                         centername); /* centername */ \
 829         }
 830
 831 #define MSG_CHOICE_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, challow, chtype, optiona, optionb) \
 832         MSG_CHOICE_NOTIF_(teamnum, CHOICE_##name, CHOICE_##cvarname, defaultvalue, challow, chtype, optiona, optionb)
 833
 834 #define MSG_CHOICE_NOTIF(name, defaultvalue, challow, chtype, optiona, optionb) \
 835         NOTIF_ADD_AUTOCVAR(CHOICE_##name, defaultvalue) \
 836         NOTIF_ADD_AUTOCVAR(CHOICE_##name##_ALLOWED, challow) \
 837         MSG_CHOICE_NOTIF_(0, CHOICE_##name, CHOICE_##name, defaultvalue, challow, chtype, optiona, optionb)
 838
 839 #define MSG_CHOICE_NOTIF_(teamnum, name, cvarname, defaultvalue, challow, chtype, optiona, optionb) \
 840         REGISTER(Notifications, name, m_id, new_pure(msg_choice_notification)) { \
 841                 this.nent_choice_idx = nent_choice_count; \
 842                 if (!teamnum || teamnum == NUM_TEAM_4) \
 843                         nent_choice_count++; \
 844                 Create_Notification_Entity       (this, defaultvalue, ACVNN(cvarname), MSG_CHOICE, strtoupper(#name), teamnum); \
 845                 Create_Notification_Entity_Choice(this, ACVNN(cvarname), strtoupper(#name), \
 846                         challow,                                 /* challow_def */ \
 847                         autocvar_notification_##cvarname##_ALLOWED,  /* challow_var */ \
 848                         chtype,                                  /* chtype      */ \
 849                         optiona,                                 /* optiona     */ \
 850                         optionb);                                /* optionb     */ \
 851         }
 852
 853 REGISTRY_BEGIN(Notifications)
 854 {
 855         notif_global_error = false;
 856 }
 857
 858 REGISTRY_END(Notifications)
 859 {
 860         if (!notif_global_error) return;
 861         // shit happened... stop the loading of the program now if this is unacceptable
 862         if (autocvar_notification_errors_are_fatal)
 863                 LOG_FATAL("Notification initialization failed! Read above and fix the errors!");
 864         else
 865                 LOG_SEVERE("Notification initialization failed! Read above and fix the errors!");
 866 }
 867
 868 #ifdef CSQC
 869 .int cvar_value;
 870 void ReplicateVars(bool would_destroy)
 871 {
 872         if (!would_destroy)
 873                 FOREACH(Notifications, it.nent_type == MSG_CHOICE && (!it.nent_teamnum || it.nent_teamnum == NUM_TEAM_1), {
 874                         string cvarname = strcat("notification_", Get_Notif_CvarName(it));
 875                         // NOTE: REPLICATE_SIMPLE can return;
 876                         REPLICATE_SIMPLE(it.cvar_value, cvarname);
 877                 });
 878 }
 879 #endif
 880
 881 #include "all.inc"