qcsrc/common/mutators/mutator/overkill/overkill.qc

   1 #ifdef IMPLEMENTATION
   2 bool autocvar_g_overkill_powerups_replace;
   3 float autocvar_g_overkill_superguns_respawn_time;
   4 bool autocvar_g_overkill_100h_anyway;
   5 bool autocvar_g_overkill_100a_anyway;
   6 bool autocvar_g_overkill_ammo_charge;
   7 float autocvar_g_overkill_ammo_charge_notice;
   8 float autocvar_g_overkill_ammo_charge_limit;
   9
  10 .vector ok_deathloc;
  11 .float ok_spawnsys_timer;
  12 .float ok_lastwep;
  13 .float ok_item;
  14
  15 .float ok_notice_time;
  16 .float ammo_charge[Weapons_MAX];
  17 .float ok_use_ammocharge = _STAT(OK_AMMO_CHARGE);
  18 .float ok_ammo_charge = _STAT(OK_AMMO_CHARGEPOOL);
  19
  20 .float ok_pauseregen_finished;
  21
  22 void(entity ent, float wep) ok_DecreaseCharge;
  23
  24 void ok_Initialize();
  25
  26 REGISTER_MUTATOR(ok, cvar("g_overkill") && !cvar("g_instagib") && !g_nexball && cvar_string("g_mod_balance") == "Overkill")
  27 {
  28         MUTATOR_ONADD
  29         {
  30                 ok_Initialize();
  31         }
  32
  33         MUTATOR_ONREMOVE
  34         {
  35                 WEP_RPC.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  36                 WEP_HMG.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  37         }
  38
  39         return false;
  40 }
  41
  42 MUTATOR_HOOKFUNCTION(ok, W_DecreaseAmmo)
  43 {
  44         entity actor = M_ARGV(0, entity);
  45         if (actor.ok_use_ammocharge)
  46         {
  47                 ok_DecreaseCharge(actor, PS(actor).m_weapon.m_id);
  48                 return true;
  49         }
  50 }
  51
  52 MUTATOR_HOOKFUNCTION(ok, W_Reload)
  53 {
  54         entity actor = M_ARGV(0, entity);
  55         return actor.ok_use_ammocharge;
  56 }
  57
  58 void W_Blaster_Attack(entity, float, float, float, float, float, float, float, float, float, float);
  59 spawnfunc(weapon_hmg);
  60 spawnfunc(weapon_rpc);
  61
  62 void ok_DecreaseCharge(entity ent, int wep)
  63 {
  64         if(!ent.ok_use_ammocharge) return;
  65
  66         entity wepent = Weapons_from(wep);
  67
  68         if (wepent == WEP_Null) return;  // dummy
  69
  70         ent.ammo_charge[wep] -= max(0, cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  71 }
  72
  73 void ok_IncreaseCharge(entity ent, int wep)
  74 {
  75         entity wepent = Weapons_from(wep);
  76
  77         if (wepent == WEP_Null) return;  // dummy
  78
  79         if(ent.ok_use_ammocharge)
  80         if(!PHYS_INPUT_BUTTON_ATCK(ent)) // not while attacking?
  81                 ent.ammo_charge[wep] = min(autocvar_g_overkill_ammo_charge_limit, ent.ammo_charge[wep] + cvar(sprintf("g_overkill_ammo_charge_rate_%s", wepent.netname)) * frametime / W_TICSPERFRAME);
  82 }
  83
  84 float ok_CheckWeaponCharge(entity ent, int wep)
  85 {
  86         if(!ent.ok_use_ammocharge) return true;
  87
  88         entity wepent = Weapons_from(wep);
  89
  90         if(wepent == WEP_Null) return 0;  // dummy
  91
  92         return (ent.ammo_charge[wep] >= cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  93 }
  94
  95 MUTATOR_HOOKFUNCTION(ok, PlayerDamage_Calculate, CBC_ORDER_LAST)
  96 {
  97         entity frag_attacker = M_ARGV(1, entity);
  98         entity frag_target = M_ARGV(2, entity);
  99         float frag_deathtype = M_ARGV(3, float);
 100
 101         if(IS_PLAYER(frag_attacker) && IS_PLAYER(frag_target))
 102         if(DEATH_ISWEAPON(frag_deathtype, WEP_BLASTER))
 103         {
 104                 if(frag_attacker != frag_target)
 105                 if(frag_target.health > 0)
 106                 if(STAT(FROZEN, frag_target) == 0)
 107                 if(!IS_DEAD(frag_target))
 108                 {
 109                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_SECONDARY_NODAMAGE);
 110                         M_ARGV(6, vector) = '0 0 0';
 111                 }
 112
 113                 M_ARGV(4, float) = 0;
 114         }
 115
 116         return false;
 117 }
 118
 119 MUTATOR_HOOKFUNCTION(ok, PlayerDamage_SplitHealthArmor)
 120 {
 121         entity frag_target = M_ARGV(2, entity);
 122         float damage_take = M_ARGV(4, float);
 123
 124         if(damage_take)
 125                 frag_target.ok_pauseregen_finished = max(frag_target.ok_pauseregen_finished, time + 2);
 126 }
 127
 128 void ok_DropItem(entity this, entity targ)
 129 {
 130         entity e = new(droppedweapon); // hax
 131         e.ok_item = true;
 132         e.noalign = true;
 133         e.pickup_anyway = true;
 134         e.spawnfunc_checked = true;
 135         WITHSELF(e, spawnfunc_item_armor_small(e));
 136         if (!wasfreed(e)) { // might have been blocked by a mutator
 137         e.movetype = MOVETYPE_TOSS;
 138         e.gravity = 1;
 139         e.reset = SUB_Remove;
 140         setorigin(e, this.origin + '0 0 32');
 141         e.velocity = '0 0 200' + normalize(targ.origin - this.origin) * 500;
 142         SUB_SetFade(e, time + 5, 1);
 143         }
 144 }
 145
 146 MUTATOR_HOOKFUNCTION(ok, PlayerDies)
 147 {
 148         entity frag_attacker = M_ARGV(1, entity);
 149         entity frag_target = M_ARGV(2, entity);
 150
 151         entity targ = ((frag_attacker) ? frag_attacker : frag_target);
 152
 153         ok_DropItem(frag_target, targ);
 154
 155         frag_target.ok_lastwep = PS(frag_target).m_switchweapon.m_id;
 156 }
 157
 158 MUTATOR_HOOKFUNCTION(ok, MonsterDropItem)
 159 {
 160         entity mon = M_ARGV(0, entity);
 161         entity olditem = M_ARGV(1, entity);
 162         entity frag_attacker = M_ARGV(2, entity);
 163
 164         remove(olditem);
 165
 166         M_ARGV(1, entity) = NULL;
 167
 168         ok_DropItem(mon, frag_attacker);
 169 }
 170
 171 MUTATOR_HOOKFUNCTION(ok, PlayerRegen)
 172 {SELFPARAM();
 173         // overkill's values are different, so use custom regen
 174         if(!STAT(FROZEN, self))
 175         {
 176                 self.armorvalue = CalcRotRegen(self.armorvalue, autocvar_g_balance_armor_regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, 1 * frametime * (time > self.ok_pauseregen_finished), 0, 0, 1, 1 * frametime * (time > self.pauserotarmor_finished), autocvar_g_balance_armor_limit);
 177                 self.health = CalcRotRegen(self.health, autocvar_g_balance_health_regenstable, 0, 100, 1 * frametime * (time > self.ok_pauseregen_finished), 200, 0, autocvar_g_balance_health_rotlinear, 1 * frametime * (time > self.pauserothealth_finished), autocvar_g_balance_health_limit);
 178
 179                 float minf, maxf, limitf;
 180
 181                 maxf = autocvar_g_balance_fuel_rotstable;
 182                 minf = autocvar_g_balance_fuel_regenstable;
 183                 limitf = autocvar_g_balance_fuel_limit;
 184
 185                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
 186         }
 187         return true; // return true anyway, as frozen uses no regen
 188 }
 189
 190 MUTATOR_HOOKFUNCTION(ok, ForbidThrowCurrentWeapon)
 191 {
 192         return true;
 193 }
 194
 195 MUTATOR_HOOKFUNCTION(ok, PlayerPreThink)
 196 {
 197         if(intermission_running || gameover)
 198                 return false;
 199
 200         entity player = M_ARGV(0, entity);
 201
 202         if(IS_DEAD(player) || !IS_PLAYER(player) || STAT(FROZEN, player))
 203                 return false;
 204
 205         if(player.ok_lastwep)
 206         {
 207                 Weapon newwep = Weapons_from(player.ok_lastwep);
 208                 if(player.ok_lastwep == WEP_HMG.m_id)
 209                         newwep = WEP_MACHINEGUN;
 210                 if(player.ok_lastwep == WEP_RPC.m_id)
 211                         newwep = WEP_VORTEX;
 212                 PS(player).m_switchweapon = newwep;
 213                 player.ok_lastwep = 0;
 214         }
 215
 216         ok_IncreaseCharge(player, PS(player).m_weapon.m_id);
 217
 218         if(PHYS_INPUT_BUTTON_ATCK2(player))
 219         if(!forbidWeaponUse(player) || player.weapon_blocked) // allow if weapon is blocked
 220         if(time >= player.jump_interval)
 221         {
 222                 player.jump_interval = time + WEP_CVAR_PRI(blaster, refire) * W_WeaponRateFactor(player);
 223                 makevectors(player.v_angle);
 224
 225                 Weapon oldwep = PS(player).m_weapon;
 226                 PS(player).m_weapon = WEP_BLASTER;
 227                 W_Blaster_Attack(
 228                         player,
 229                         WEP_BLASTER.m_id | HITTYPE_SECONDARY,
 230                         WEP_CVAR_SEC(vaporizer, shotangle),
 231                         WEP_CVAR_SEC(vaporizer, damage),
 232                         WEP_CVAR_SEC(vaporizer, edgedamage),
 233                         WEP_CVAR_SEC(vaporizer, radius),
 234                         WEP_CVAR_SEC(vaporizer, force),
 235                         WEP_CVAR_SEC(vaporizer, speed),
 236                         WEP_CVAR_SEC(vaporizer, spread),
 237                         WEP_CVAR_SEC(vaporizer, delay),
 238                         WEP_CVAR_SEC(vaporizer, lifetime)
 239                 );
 240                 PS(player).m_weapon = oldwep;
 241         }
 242
 243         player.weapon_blocked = false;
 244
 245         player.ok_ammo_charge = player.ammo_charge[PS(player).m_weapon.m_id];
 246
 247         if(player.ok_use_ammocharge)
 248         if(!ok_CheckWeaponCharge(player, PS(player).m_weapon.m_id))
 249         {
 250                 if(autocvar_g_overkill_ammo_charge_notice && time > player.ok_notice_time && PHYS_INPUT_BUTTON_ATCK(player) && IS_REAL_CLIENT(player) && PS(player).m_weapon == PS(player).m_switchweapon)
 251                 {
 252                         //Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_OVERKILL_CHARGE);
 253                         player.ok_notice_time = time + 2;
 254                         play2(player, SND(DRYFIRE));
 255                 }
 256                 Weapon wpn = PS(player).m_weapon;
 257                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 258                 if(player.(weaponentity).state != WS_CLEAR)
 259                         w_ready(wpn, player, weaponentity, PHYS_INPUT_BUTTON_ATCK(player) | (PHYS_INPUT_BUTTON_ATCK2(player) << 1));
 260
 261                 player.weapon_blocked = true;
 262         }
 263
 264         PHYS_INPUT_BUTTON_ATCK2(player) = false;
 265 }
 266
 267 MUTATOR_HOOKFUNCTION(ok, PlayerSpawn)
 268 {
 269         entity player = M_ARGV(0, entity);
 270
 271         if(autocvar_g_overkill_ammo_charge)
 272         {
 273                 FOREACH(Weapons, it != WEP_Null, LAMBDA(player.ammo_charge[it.m_id] = autocvar_g_overkill_ammo_charge_limit));
 274
 275                 player.ok_use_ammocharge = 1;
 276                 player.ok_notice_time = time;
 277         }
 278         else
 279                 player.ok_use_ammocharge = 0;
 280
 281         // if player changed their weapon while dead, don't switch to their death weapon
 282         if(player.impulse)
 283                 player.ok_lastwep = 0;
 284
 285         player.ok_pauseregen_finished = time + 2;
 286
 287         return false;
 288 }
 289
 290 void self_spawnfunc_weapon_hmg(entity this) { spawnfunc_weapon_hmg(this); }
 291 void self_spawnfunc_weapon_rpc(entity this) { spawnfunc_weapon_rpc(this); }
 292
 293 MUTATOR_HOOKFUNCTION(ok, OnEntityPreSpawn)
 294 {
 295         entity ent = M_ARGV(0, entity);
 296
 297         if(autocvar_g_powerups)
 298         if(autocvar_g_overkill_powerups_replace)
 299         {
 300                 if(ent.classname == "item_strength")
 301                 {
 302                         entity wep = new(weapon_hmg);
 303                         setorigin(wep, ent.origin);
 304                         setmodel(wep, MDL_OK_HMG);
 305                         wep.ok_item = true;
 306                         wep.noalign = ent.noalign;
 307                         wep.cnt = ent.cnt;
 308                         wep.team = ent.team;
 309                         wep.respawntime = autocvar_g_overkill_superguns_respawn_time;
 310                         wep.pickup_anyway = true;
 311                         wep.spawnfunc_checked = true;
 312                         setthink(wep, self_spawnfunc_weapon_hmg);
 313                         wep.nextthink = time + 0.1;
 314                         return true;
 315                 }
 316
 317                 if(ent.classname == "item_invincible")
 318                 {
 319                         entity wep = new(weapon_rpc);
 320                         setorigin(wep, ent.origin);
 321                         setmodel(wep, MDL_OK_RPC);
 322                         wep.ok_item = true;
 323                         wep.noalign = ent.noalign;
 324                         wep.cnt = ent.cnt;
 325                         wep.team = ent.team;
 326                         wep.respawntime = autocvar_g_overkill_superguns_respawn_time;
 327                         wep.pickup_anyway = true;
 328                         wep.spawnfunc_checked = true;
 329                         setthink(wep, self_spawnfunc_weapon_rpc);
 330                         wep.nextthink = time + 0.1;
 331                         return true;
 332                 }
 333         }
 334
 335         return false;
 336 }
 337
 338 MUTATOR_HOOKFUNCTION(ok, FilterItem)
 339 {
 340         entity item = M_ARGV(0, entity);
 341
 342         if(item.ok_item)
 343                 return false;
 344
 345         switch(item.items)
 346         {
 347                 case ITEM_HealthMega.m_itemid: return !(autocvar_g_overkill_100h_anyway);
 348                 case ITEM_ArmorMega.m_itemid: return !(autocvar_g_overkill_100a_anyway);
 349         }
 350
 351         return true;
 352 }
 353
 354 MUTATOR_HOOKFUNCTION(ok, SpectateCopy)
 355 {
 356         entity spectatee = M_ARGV(0, entity);
 357         entity client = M_ARGV(1, entity);
 358
 359         client.ammo_charge[PS(client).m_weapon.m_id] = spectatee.ammo_charge[PS(spectatee).m_weapon.m_id];
 360         client.ok_use_ammocharge = spectatee.ok_use_ammocharge;
 361 }
 362
 363 MUTATOR_HOOKFUNCTION(ok, SetStartItems)
 364 {
 365         WepSet ok_start_items = (WEPSET(MACHINEGUN) | WEPSET(VORTEX) | WEPSET(SHOTGUN));
 366
 367         if(WEP_RPC.weaponstart > 0) { ok_start_items |= WEPSET(RPC); }
 368         if(WEP_HMG.weaponstart > 0) { ok_start_items |= WEPSET(HMG); }
 369
 370         start_items |= IT_UNLIMITED_WEAPON_AMMO;
 371         start_weapons = warmup_start_weapons = ok_start_items;
 372
 373         return false;
 374 }
 375
 376 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsString)
 377 {
 378         M_ARGV(0, string) = strcat(M_ARGV(0, string), ":OK");
 379 }
 380
 381 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsPrettyString)
 382 {
 383         M_ARGV(0, string) = strcat(M_ARGV(0, string), ", Overkill");
 384 }
 385
 386 MUTATOR_HOOKFUNCTION(ok, SetModname)
 387 {
 388         M_ARGV(0, string) = "Overkill";
 389         return true;
 390 }
 391
 392 void ok_SetCvars()
 393 {
 394         // hack to force overkill playermodels
 395         cvar_settemp("sv_defaultcharacter", "1");
 396         cvar_settemp("sv_defaultplayermodel", "models/ok_player/okrobot1.dpm models/ok_player/okrobot2.dpm models/ok_player/okrobot3.dpm models/ok_player/okrobot4.dpm models/ok_player/okmale1.dpm models/ok_player/okmale2.dpm models/ok_player/okmale3.dpm models/ok_player/okmale4.dpm");
 397         cvar_settemp("sv_defaultplayermodel_red", "models/ok_player/okrobot1.dpm models/ok_player/okrobot2.dpm models/ok_player/okrobot3.dpm models/ok_player/okrobot4.dpm");
 398         cvar_settemp("sv_defaultplayermodel_blue", "models/ok_player/okmale1.dpm models/ok_player/okmale2.dpm models/ok_player/okmale3.dpm models/ok_player/okmale4.dpm");
 399 }
 400
 401 void ok_Initialize()
 402 {
 403         ok_SetCvars();
 404
 405         precache_all_playermodels("models/ok_player/*.dpm");
 406
 407         WEP_RPC.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 408         WEP_HMG.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 409
 410         WEP_SHOTGUN.mdl = "ok_shotgun";
 411         WEP_MACHINEGUN.mdl = "ok_mg";
 412         WEP_VORTEX.mdl = "ok_sniper";
 413 }
 414 #endif