qcsrc/common/mutators/mutator/itemstime.qc

   1 REGISTER_MUTATOR(itemstime, true);
   2
   3 #ifdef SVQC
   4 void IT_Write(entity e, int i, float f) {
   5     if (!IS_REAL_CLIENT(e)) return;
   6     msg_entity = e;
   7     WriteByte(MSG_ONE, SVC_TEMPENTITY);
   8     WriteMutator(MSG_ONE, itemstime);
   9     WriteByte(MSG_ONE, i);
  10     WriteFloat(MSG_ONE, f);
  11 }
  12 #endif
  13
  14 #ifdef CSQC
  15 float ItemsTime_time[MAX_ITEMS];
  16 float ItemsTime_availableTime[MAX_ITEMS];
  17 MUTATOR_HOOKFUNCTION(itemstime, CSQC_Parse_TempEntity) {
  18     if (MUTATOR_RETURNVALUE) return false;
  19     if (!ReadMutatorEquals(mutator_argv_int_0, itemstime)) return false;
  20     int i = ReadByte();
  21     float f = ReadFloat();
  22     ItemsTime_time[i] = f;
  23     return true;
  24 }
  25 #endif
  26
  27 bool Item_ItemsTime_Allow(GameItem it, WepSet _weapons)
  28 {
  29         return (false
  30         || it.instanceOfPowerup
  31         || it == ITEM_ArmorMega     || it == ITEM_ArmorLarge
  32         || it == ITEM_HealthMega    || it == ITEM_HealthLarge
  33         || (_weapons & WEPSET_SUPERWEAPONS)
  34         );
  35 }
  36
  37 #ifdef SVQC
  38
  39 float it_times[MAX_ITEMS];
  40
  41 void Item_ItemsTime_Init()
  42 {
  43     FOREACH(ITEMS, true, LAMBDA(
  44         it_times[it.m_id] = -1;
  45     ));
  46 }
  47
  48 STATIC_INIT(ItemsTime_Init) {
  49     // items time
  50     Item_ItemsTime_Init();
  51 }
  52
  53 void Item_ItemsTime_ResetTimes()
  54 {
  55     FOREACH(ITEMS, true, LAMBDA(
  56         it_times[it.m_id] = (it_times[it.m_id] == -1) ? -1 : 0;
  57     ));
  58 }
  59
  60 void Item_ItemsTime_ResetTimesForPlayer(entity e)
  61 {
  62     FOREACH(ITEMS, true, LAMBDA(
  63         IT_Write(e, it.m_id, (it_times[it.m_id] == -1) ? -1 : 0);
  64     ));
  65 }
  66
  67 void Item_ItemsTime_SetTimesForPlayer(entity e)
  68 {
  69     FOREACH(ITEMS, true, LAMBDA(
  70         IT_Write(e, it.m_id, it_times[it.m_id]);
  71     ));
  72 }
  73
  74 void Item_ItemsTime_SetTime(entity e, float t)
  75 {
  76     if (!autocvar_sv_itemstime)
  77         return;
  78
  79     GameItem item = e.itemdef;
  80     it_times[item.m_id] = t;
  81 }
  82
  83 void Item_ItemsTime_SetTimesForAllPlayers()
  84 {
  85     entity e;
  86     FOR_EACH_REALCLIENT(e) if (warmup_stage || !IS_PLAYER(e))
  87         Item_ItemsTime_SetTimesForPlayer(e);
  88 }
  89
  90 float Item_ItemsTime_UpdateTime(entity e, float t)
  91 {
  92     bool isavailable = (t == 0);
  93     if (e.weapons & WEPSET_SUPERWEAPONS)
  94     {
  95         for (entity head = world; (head = nextent(head)); )
  96         {
  97             if (clienttype(head) != CLIENTTYPE_NOTACLIENT || !(head.weapons & WEPSET_SUPERWEAPONS) || head.classname == "weapon_info")
  98                 continue;
  99             if (e == head)
 100                 continue;
 101
 102             if (head.scheduledrespawntime <= time)
 103                 isavailable = true;
 104             else if (t == 0 || head.scheduledrespawntime < t)
 105                 t = head.scheduledrespawntime;
 106         }
 107     }
 108     else
 109     {
 110         for (entity head = world; (head = nextent(head)); )
 111         {
 112             if (head.itemdef != e.itemdef)
 113                 continue;
 114             if (e == head)
 115                 continue;
 116
 117             if (head.scheduledrespawntime <= time)
 118                 isavailable = true;
 119             else if (t == 0 || head.scheduledrespawntime < t)
 120                 t = head.scheduledrespawntime;
 121         }
 122     }
 123     if (isavailable)
 124         t = -t; // let know the client there's another available item
 125     return t;
 126 }
 127
 128 MUTATOR_HOOKFUNCTION(itemstime, reset_map_global) {
 129     Item_ItemsTime_ResetTimes();
 130 }
 131
 132 MUTATOR_HOOKFUNCTION(itemstime, MakePlayerObserver) {
 133     Item_ItemsTime_SetTimesForPlayer(self);
 134 }
 135
 136 MUTATOR_HOOKFUNCTION(itemstime, PlayerSpawn) {
 137     if (warmup_stage) return;
 138     Item_ItemsTime_ResetTimesForPlayer(self);
 139 }
 140
 141 #endif
 142
 143 #ifdef CSQC
 144
 145 void DrawItemsTimeItem(vector myPos, vector mySize, float ar, entity item, float item_time, bool item_available, float item_availableTime)
 146 {
 147     float t = 0;
 148     vector color = '0 0 0';
 149     float picalpha;
 150
 151     if (autocvar_hud_panel_itemstime_hidespawned == 2)
 152         picalpha = 1;
 153     else if (item_available)
 154     {
 155         float BLINK_FACTOR = 0.15;
 156         float BLINK_BASE = 0.85;
 157         float BLINK_FREQ = 5;
 158         picalpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
 159     }
 160     else
 161         picalpha = 0.5;
 162     t = floor(item_time - time + 0.999);
 163     if (t < 5)
 164         color = '0.7 0 0';
 165     else if (t < 10)
 166         color = '0.7 0.7 0';
 167     else
 168         color = '1 1 1';
 169
 170     vector picpos, numpos;
 171     if (autocvar_hud_panel_itemstime_iconalign)
 172     {
 173         numpos = myPos;
 174         picpos = myPos + eX * (ar - 1) * mySize_y;
 175     }
 176     else
 177     {
 178         numpos = myPos + eX * mySize_y;
 179         picpos = myPos;
 180     }
 181
 182     if (t > 0 && autocvar_hud_panel_itemstime_progressbar)
 183     {
 184         vector p_pos, p_size;
 185         if (autocvar_hud_panel_itemstime_progressbar_reduced)
 186         {
 187             p_pos = numpos;
 188             p_size = eX * ((ar - 1)/ar) * mySize_x + eY * mySize_y;
 189         }
 190         else
 191         {
 192             p_pos = myPos;
 193             p_size = mySize;
 194         }
 195         HUD_Panel_DrawProgressBar(p_pos, p_size, autocvar_hud_panel_itemstime_progressbar_name, t/autocvar_hud_panel_itemstime_progressbar_maxtime, 0, autocvar_hud_panel_itemstime_iconalign, color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 196     }
 197
 198     if (t > 0 && autocvar_hud_panel_itemstime_text)
 199         drawstring_aspect(numpos, ftos(t), eX * ((ar - 1)/ar) * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 200     else
 201         picpos.x = myPos.x + mySize.x / 2 - mySize.y / 2;
 202     if (item_availableTime)
 203         drawpic_aspect_skin_expanding(picpos, item.m_icon, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL, item_availableTime);
 204     drawpic_aspect_skin(picpos, item.m_icon, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL);
 205 }
 206
 207 void HUD_ItemsTime()
 208 {
 209     if (!autocvar__hud_configure)
 210     {
 211         if (!(
 212             (autocvar_hud_panel_itemstime == 1 && spectatee_status != 0)
 213         ||      (autocvar_hud_panel_itemstime == 2 && (spectatee_status != 0 || warmup_stage))
 214             )) { return; }
 215     }
 216     else
 217     {
 218         ItemsTime_time[ITEM_ArmorMega.m_id] = time + 0;
 219         ItemsTime_time[ITEM_HealthMega.m_id] = time + 8;
 220         ItemsTime_time[ITEM_Strength.m_id] = time + 0;
 221         ItemsTime_time[ITEM_Shield.m_id] = time + 4;
 222     }
 223
 224     int count = 0;
 225     if (autocvar_hud_panel_itemstime_hidespawned == 1)
 226         FOREACH(ITEMS, Item_ItemsTime_Allow(it, '0 0 0'), LAMBDA(
 227             count += (ItemsTime_time[i] > time || -ItemsTime_time[i] > time);
 228         ));
 229     else if (autocvar_hud_panel_itemstime_hidespawned == 2)
 230         FOREACH(ITEMS, Item_ItemsTime_Allow(it, '0 0 0'), LAMBDA(
 231             count += (ItemsTime_time[i] > time);
 232         ));
 233     else
 234         FOREACH(ITEMS, Item_ItemsTime_Allow(it, '0 0 0'), LAMBDA(
 235             count += (ItemsTime_time[i] != -1);
 236         ));
 237     if (count == 0)
 238         return;
 239
 240     HUD_Panel_UpdateCvars();
 241
 242     vector pos, mySize;
 243     pos = panel_pos;
 244     mySize = panel_size;
 245
 246     if (panel_bg_padding)
 247     {
 248         pos += '1 1 0' * panel_bg_padding;
 249         mySize -= '2 2 0' * panel_bg_padding;
 250     }
 251
 252     float rows, columns;
 253     float ar = max(2, autocvar_hud_panel_itemstime_ratio) + 1;
 254     rows = HUD_GetRowCount(count, mySize, ar);
 255     columns = ceil(count/rows);
 256
 257     vector itemstime_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
 258
 259     vector offset = '0 0 0';
 260     float newSize;
 261     if (autocvar_hud_panel_itemstime_dynamicsize)
 262     {
 263         if (autocvar__hud_configure)
 264         if (menu_enabled != 2)
 265             HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
 266
 267         // reduce panel to avoid spacing items
 268         if (itemstime_size.x / itemstime_size.y < ar)
 269         {
 270             newSize = rows * itemstime_size.x / ar;
 271             pos.y += (mySize.y - newSize) / 2;
 272             mySize.y = newSize;
 273             itemstime_size.y = mySize.y / rows;
 274         }
 275         else
 276         {
 277             newSize = columns * itemstime_size.y * ar;
 278             pos.x += (mySize.x - newSize) / 2;
 279             mySize.x = newSize;
 280             itemstime_size.x = mySize.x / columns;
 281         }
 282         panel_pos = pos - '1 1 0' * panel_bg_padding;
 283         panel_size = mySize + '2 2 0' * panel_bg_padding;
 284     }
 285     else
 286     {
 287         if (itemstime_size.x/itemstime_size.y > ar)
 288         {
 289             newSize = ar * itemstime_size.y;
 290             offset.x = itemstime_size.x - newSize;
 291             pos.x += offset.x/2;
 292             itemstime_size.x = newSize;
 293         }
 294         else
 295         {
 296             newSize = 1/ar * itemstime_size.x;
 297             offset.y = itemstime_size.y - newSize;
 298             pos.y += offset.y/2;
 299             itemstime_size.y = newSize;
 300         }
 301     }
 302
 303     HUD_Panel_DrawBg(1);
 304
 305     float row = 0, column = 0;
 306     bool item_available;
 307     FOREACH(ITEMS, Item_ItemsTime_Allow(it, '0 0 0') && ItemsTime_time[i] != -1, LAMBDA(
 308         float item_time = ItemsTime_time[i];
 309         if (item_time < -1)
 310         {
 311             item_available = true;
 312             item_time = -item_time;
 313         }
 314         else
 315             item_available = (item_time <= time);
 316
 317         if (ItemsTime_time[i] >= 0)
 318         {
 319             if (time <= ItemsTime_time[i])
 320                 ItemsTime_availableTime[i] = 0;
 321             else if (ItemsTime_availableTime[i] == 0)
 322                 ItemsTime_availableTime[i] = time;
 323         }
 324         else if (ItemsTime_availableTime[i] == 0)
 325             ItemsTime_availableTime[i] = time;
 326
 327         float f = (time - ItemsTime_availableTime[i]) * 2;
 328         f = (f > 1) ? 0 : bound(0, f, 1);
 329
 330         if (autocvar_hud_panel_itemstime_hidespawned == 1)
 331             if (!(ItemsTime_time[i] > time || -ItemsTime_time[i] > time))
 332                 continue;
 333
 334         if (autocvar_hud_panel_itemstime_hidespawned == 2)
 335             if (!(ItemsTime_time[i] > time))
 336                 continue;
 337
 338         DrawItemsTimeItem(pos + eX * column * (itemstime_size.x + offset.x) + eY * row * (itemstime_size.y + offset.y), itemstime_size, ar, it, item_time, item_available, f);
 339         ++row;
 340         if (row >= rows)
 341         {
 342             row = 0;
 343             column = column + 1;
 344         }
 345     ));
 346 }
 347
 348 #endif