qcsrc/common/monsters/sv_monsters.qc

   1 // =========================
   2 //      SVQC Monster Properties
   3 // =========================
   4
   5
   6 void monster_dropitem()
   7 {
   8         if(!self.candrop || !self.monster_loot)
   9                 return;
  10
  11         vector org = self.origin + ((self.mins + self.maxs) * 0.5);
  12         entity e = spawn(), oldself = self;
  13
  14         e.monster_loot = self.monster_loot;
  15
  16         other = e;
  17         MUTATOR_CALLHOOK(MonsterDropItem);
  18         e = other;
  19
  20         if(e && e.monster_loot)
  21         {
  22                 self = e;
  23                 e.noalign = TRUE;
  24                 e.monster_loot();
  25                 e.gravity = 1;
  26                 e.movetype = MOVETYPE_TOSS;
  27                 e.reset = SUB_Remove;
  28                 setorigin(e, org);
  29                 e.velocity = randomvec() * 175 + '0 0 325';
  30                 e.item_spawnshieldtime = time + 0.7;
  31                 e.classname = "droppedweapon"; // use weapon handling to remove it on touch
  32                 SUB_SetFade(e, time + autocvar_g_monsters_drop_time, 1);
  33                 self = oldself;
  34         }
  35 }
  36
  37 float Monster_SkillModifier()
  38 {
  39         float t = 0.5+self.monster_skill*((1.2-0.3)/10);
  40
  41         return t;
  42 }
  43
  44 float monster_isvalidtarget (entity targ, entity ent)
  45 {
  46         if(!targ || !ent)
  47                 return FALSE; // someone doesn't exist
  48
  49         if(targ == ent)
  50                 return FALSE; // don't attack ourselves
  51
  52         //traceline(ent.origin, targ.origin, MOVE_NORMAL, ent);
  53
  54         //if(trace_ent != targ)
  55                 //return FALSE;
  56
  57         if(targ.vehicle_flags & VHF_ISVEHICLE)
  58         if(!((get_monsterinfo(ent.monsterid)).spawnflags & MON_FLAG_RANGED))
  59                 return FALSE; // melee attacks are useless against vehicles
  60
  61         if(time < game_starttime)
  62                 return FALSE; // monsters do nothing before the match has started
  63
  64         if(targ.takedamage == DAMAGE_NO)
  65                 return FALSE; // enemy can't be damaged
  66
  67         if(targ.items & IT_INVISIBILITY)
  68                 return FALSE; // enemy is invisible
  69
  70         if(substring(targ.classname, 0, 10) == "onslaught_")
  71                 return FALSE; // don't attack onslaught targets
  72
  73         if(IS_SPEC(targ) || IS_OBSERVER(targ))
  74                 return FALSE; // enemy is a spectator
  75
  76         if(!(targ.vehicle_flags & VHF_ISVEHICLE))
  77         if(targ.deadflag != DEAD_NO || ent.deadflag != DEAD_NO || targ.health <= 0 || ent.health <= 0)
  78                 return FALSE; // enemy/self is dead
  79
  80         if(ent.monster_owner == targ)
  81                 return FALSE; // don't attack our master
  82
  83         if(targ.monster_owner == ent)
  84                 return FALSE; // don't attack our pet
  85
  86         if(!(targ.vehicle_flags & VHF_ISVEHICLE))
  87         if(targ.flags & FL_NOTARGET)
  88                 return FALSE; // enemy can't be targeted
  89
  90         if(!autocvar_g_monsters_typefrag)
  91         if(targ.BUTTON_CHAT)
  92                 return FALSE; // no typefragging!
  93
  94         if(SAME_TEAM(targ, ent))
  95                 return FALSE; // enemy is on our team
  96
  97         if (targ.freezetag_frozen)
  98                 return FALSE; // ignore frozen
  99
 100         if(autocvar_g_monsters_target_infront || (ent.spawnflags & MONSTERFLAG_INFRONT))
 101         if(ent.enemy != targ)
 102         {
 103                 float dot;
 104
 105                 makevectors (ent.angles);
 106                 dot = normalize (targ.origin - ent.origin) * v_forward;
 107
 108                 if(dot <= 0.3)
 109                         return FALSE;
 110         }
 111
 112         return TRUE;
 113 }
 114
 115 entity FindTarget (entity ent)
 116 {
 117         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return ent.enemy; } // Handled by a mutator
 118
 119         entity head, closest_target = world;
 120         head = findradius(ent.origin, ent.target_range);
 121         //head = WarpZone_FindRadius(ent.origin, ent.target_range, TRUE);
 122
 123         while(head) // find the closest acceptable target to pass to
 124         {
 125                 if(head.monster_attack)
 126                 if(monster_isvalidtarget(head, ent))
 127                 {
 128                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
 129                         vector head_center = CENTER_OR_VIEWOFS(head);
 130                         //vector head_center = WarpZone_UnTransformOrigin(head, CENTER_OR_VIEWOFS(head));
 131                         vector ent_center = CENTER_OR_VIEWOFS(ent);
 132
 133                         traceline(ent_center, head_center, MOVE_NORMAL, ent);
 134
 135                         if(trace_ent == head)
 136                         if(closest_target)
 137                         {
 138                                 vector closest_target_center = CENTER_OR_VIEWOFS(closest_target);
 139                                 //vector closest_target_center = WarpZone_UnTransformOrigin(closest_target, CENTER_OR_VIEWOFS(closest_target));
 140                                 if(vlen(ent_center - head_center) < vlen(ent_center - closest_target_center))
 141                                         { closest_target = head; }
 142                         }
 143                         else { closest_target = head; }
 144                 }
 145
 146                 head = head.chain;
 147         }
 148
 149         return closest_target;
 150 }
 151
 152 void MonsterTouch ()
 153 {
 154         if(other == world)
 155                 return;
 156
 157         if(self.enemy != other)
 158         if(!(other.flags & FL_MONSTER))
 159         if(monster_isvalidtarget(other, self))
 160                 self.enemy = other;
 161 }
 162
 163 string get_monster_model_datafilename(string m, float sk, string fil)
 164 {
 165         if(m)
 166                 m = strcat(m, "_");
 167         else
 168                 m = "models/monsters/*_";
 169         if(sk >= 0)
 170                 m = strcat(m, ftos(sk));
 171         else
 172                 m = strcat(m, "*");
 173         return strcat(m, ".", fil);
 174 }
 175
 176 void PrecacheMonsterSounds(string f)
 177 {
 178         float fh;
 179         string s;
 180         fh = fopen(f, FILE_READ);
 181         if(fh < 0)
 182                 return;
 183         while((s = fgets(fh)))
 184         {
 185                 if(tokenize_console(s) != 3)
 186                 {
 187                         dprint("Invalid sound info line: ", s, "\n");
 188                         continue;
 189                 }
 190                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
 191         }
 192         fclose(fh);
 193 }
 194
 195 void precache_monstersounds()
 196 {
 197         string m = (get_monsterinfo(self.monsterid)).model;
 198         float globhandle, n, i;
 199         string f;
 200
 201         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
 202         if (globhandle < 0)
 203                 return;
 204         n = search_getsize(globhandle);
 205         for (i = 0; i < n; ++i)
 206         {
 207                 //print(search_getfilename(globhandle, i), "\n");
 208                 f = search_getfilename(globhandle, i);
 209                 PrecacheMonsterSounds(f);
 210         }
 211         search_end(globhandle);
 212 }
 213
 214 void ClearMonsterSounds()
 215 {
 216 #define _MSOUND(m) if(self.monstersound_##m) { strunzone(self.monstersound_##m); self.monstersound_##m = string_null; }
 217         ALLMONSTERSOUNDS
 218 #undef _MSOUND
 219 }
 220
 221 .string GetMonsterSoundSampleField(string type)
 222 {
 223         GetMonsterSoundSampleField_notFound = 0;
 224         switch(type)
 225         {
 226 #define _MSOUND(m) case #m: return monstersound_##m;
 227                 ALLMONSTERSOUNDS
 228 #undef _MSOUND
 229         }
 230         GetMonsterSoundSampleField_notFound = 1;
 231         return string_null;
 232 }
 233
 234 float LoadMonsterSounds(string f, float first)
 235 {
 236         float fh;
 237         string s;
 238         var .string field;
 239         fh = fopen(f, FILE_READ);
 240         if(fh < 0)
 241         {
 242                 dprint("Monster sound file not found: ", f, "\n");
 243                 return 0;
 244         }
 245         while((s = fgets(fh)))
 246         {
 247                 if(tokenize_console(s) != 3)
 248                         continue;
 249                 field = GetMonsterSoundSampleField(argv(0));
 250                 if(GetMonsterSoundSampleField_notFound)
 251                         continue;
 252                 if(self.field)
 253                         strunzone(self.field);
 254                 self.field = strzone(strcat(argv(1), " ", argv(2)));
 255         }
 256         fclose(fh);
 257         return 1;
 258 }
 259
 260 .float skin_for_monstersound;
 261 void UpdateMonsterSounds()
 262 {
 263         entity mon = get_monsterinfo(self.monsterid);
 264
 265         if(self.skin == self.skin_for_monstersound)
 266                 return;
 267         self.skin_for_monstersound = self.skin;
 268         ClearMonsterSounds();
 269         //LoadMonsterSounds("sound/monsters/default.sounds", 1);
 270         if(!autocvar_g_debug_defaultsounds)
 271         if(!LoadMonsterSounds(get_monster_model_datafilename(mon.model, self.skin, "sounds"), 0))
 272                 LoadMonsterSounds(get_monster_model_datafilename(mon.model, 0, "sounds"), 0);
 273 }
 274
 275 void MonsterSound(.string samplefield, float sound_delay, float delaytoo, float chan)
 276 {
 277         if(!autocvar_g_monsters_sounds) { return; }
 278
 279         if(delaytoo)
 280         if(time < self.msound_delay)
 281                 return; // too early
 282         GlobalSound(self.samplefield, chan, VOICETYPE_PLAYERSOUND);
 283
 284         self.msound_delay = time + sound_delay;
 285 }
 286
 287 void monster_makevectors(entity e)
 288 {
 289         vector v;
 290
 291         v = e.origin + (e.mins + e.maxs) * 0.5;
 292         self.v_angle = vectoangles(v - (self.origin + self.view_ofs));
 293         self.v_angle_x = -self.v_angle_x;
 294
 295         makevectors(self.v_angle);
 296 }
 297
 298 float monster_melee(entity targ, float damg, float anim, float er, float anim_finished, float deathtype, float dostop)
 299 {
 300         if (self.health <= 0)
 301                 return FALSE; // attacking while dead?!
 302
 303         if(dostop)
 304         {
 305                 self.velocity_x = 0;
 306                 self.velocity_y = 0;
 307                 self.state = MONSTER_STATE_ATTACK_MELEE;
 308         }
 309
 310         self.frame = anim;
 311
 312         if(anim_finished != 0)
 313                 self.attack_finished_single = time + anim_finished;
 314
 315         monster_makevectors(targ);
 316
 317         traceline(self.origin + self.view_ofs, self.origin + v_forward * er, 0, self);
 318
 319         if(trace_ent.takedamage)
 320                 Damage(trace_ent, self, self, damg * Monster_SkillModifier(), deathtype, trace_ent.origin, normalize(trace_ent.origin - self.origin));
 321
 322         return TRUE;
 323 }
 324
 325 void Monster_CheckMinibossFlag ()
 326 {
 327         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 328                 return;
 329
 330         float chance = random() * 100;
 331
 332         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 333         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 334         {
 335                 self.health += autocvar_g_monsters_miniboss_healthboost;
 336                 self.effects |= EF_RED;
 337                 if(!self.weapon)
 338                         self.weapon = WEP_NEX;
 339         }
 340 }
 341
 342 float Monster_CanRespawn(entity ent)
 343 {
 344         other = ent;
 345         if(ent.deadflag == DEAD_DEAD) // don't call when monster isn't dead
 346         if(MUTATOR_CALLHOOK(MonsterRespawn))
 347                 return TRUE; // enabled by a mutator
 348
 349         if(ent.spawnflags & MONSTERFLAG_NORESPAWN)
 350                 return FALSE;
 351
 352         if(!autocvar_g_monsters_respawn)
 353                 return FALSE;
 354
 355         return TRUE;
 356 }
 357
 358 float monster_initialize(float mon_id);
 359 void monster_respawn()
 360 {
 361         // is this function really needed?
 362         monster_initialize(self.monsterid);
 363 }
 364
 365 void Monster_Fade ()
 366 {
 367         if(Monster_CanRespawn(self))
 368         {
 369                 self.spawnflags |= MONSTERFLAG_RESPAWNED;
 370                 self.think = monster_respawn;
 371                 self.nextthink = time + self.respawntime;
 372                 self.monster_lifetime = 0;
 373                 self.deadflag = DEAD_RESPAWNING;
 374                 if(self.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
 375                 {
 376                         self.pos1 = self.origin;
 377                         self.pos2 = self.angles;
 378                 }
 379                 self.event_damage = func_null;
 380                 self.takedamage = DAMAGE_NO;
 381                 setorigin(self, self.pos1);
 382                 self.angles = self.pos2;
 383                 self.health = self.max_health;
 384                 setmodel(self, "null");
 385         }
 386         else
 387         {
 388                 // number of monsters spawned with mobspawn command
 389                 totalspawned -= 1;
 390
 391                 if(IS_CLIENT(self.realowner))
 392                         self.realowner.monstercount -= 1;
 393
 394                 SUB_SetFade(self, time + 3, 1);
 395         }
 396 }
 397
 398 float Monster_CanJump (vector vel)
 399 {
 400         if(self.state)
 401                 return FALSE; // already attacking
 402         if(!(self.flags & FL_ONGROUND))
 403                 return FALSE; // not on the ground
 404         if(self.health <= 0)
 405                 return FALSE; // called when dead?
 406         if(time < self.attack_finished_single)
 407                 return FALSE; // still attacking
 408
 409         vector old = self.velocity;
 410
 411         self.velocity = vel;
 412         tracetoss(self, self);
 413         self.velocity = old;
 414         if (trace_ent != self.enemy)
 415                 return FALSE;
 416
 417         return TRUE;
 418 }
 419
 420 float monster_leap (float anm, void() touchfunc, vector vel, float anim_finished)
 421 {
 422         if(!Monster_CanJump(vel))
 423                 return FALSE;
 424
 425         self.frame = anm;
 426         self.state = MONSTER_STATE_ATTACK_LEAP;
 427         self.touch = touchfunc;
 428         self.origin_z += 1;
 429         self.velocity = vel;
 430         self.flags &= ~FL_ONGROUND;
 431
 432         self.attack_finished_single = time + anim_finished;
 433
 434         return TRUE;
 435 }
 436
 437 void monster_checkattack(entity e, entity targ)
 438 {
 439         if(e == world)
 440                 return;
 441         if(targ == world)
 442                 return;
 443
 444         if(!e.monster_attackfunc)
 445                 return;
 446
 447         if(time < e.attack_finished_single)
 448                 return;
 449
 450         if(vlen(targ.origin - e.origin) <= e.attack_range)
 451         if(e.monster_attackfunc(MONSTER_ATTACK_MELEE))
 452         {
 453                 MonsterSound(monstersound_melee, 0, FALSE, CH_VOICE);
 454                 return;
 455         }
 456
 457         if(vlen(targ.origin - e.origin) > e.attack_range)
 458         if(e.monster_attackfunc(MONSTER_ATTACK_RANGED))
 459         {
 460                 MonsterSound(monstersound_ranged, 0, FALSE, CH_VOICE);
 461                 return;
 462         }
 463 }
 464
 465 void monster_use ()
 466 {
 467         if(!self.enemy)
 468         if(self.health > 0)
 469         if(monster_isvalidtarget(activator, self))
 470                 self.enemy = activator;
 471 }
 472
 473 .float last_trace;
 474 .float last_enemycheck; // for checking enemy
 475 vector monster_pickmovetarget(entity targ)
 476 {
 477         // enemy is always preferred target
 478         if(self.enemy)
 479         {
 480                 vector targ_origin = ((self.enemy.absmin + self.enemy.absmax) * 0.5);
 481                 targ_origin = WarpZone_RefSys_TransformOrigin(self.enemy, self, targ_origin); // origin of target as seen by the monster (us)
 482                 WarpZone_TraceLine(self.origin, targ_origin, MOVE_NOMONSTERS, self);
 483
 484                 if((self.enemy == world)
 485                         || (self.enemy.deadflag != DEAD_NO || self.enemy.health < 1)
 486                         || (self.enemy.freezetag_frozen)
 487                         || (self.enemy.flags & FL_NOTARGET)
 488                         || (self.enemy.alpha < 0.5)
 489                         || (self.enemy.takedamage == DAMAGE_NO)
 490                         || (vlen(self.origin - targ_origin) > self.target_range)
 491                         || ((trace_fraction < 1) && (trace_ent != self.enemy)))
 492                         //|| (time > self.ctf_droptime + autocvar_g_ctf_pass_timelimit)) // TODO: chase timelimit?
 493                 {
 494                         self.enemy = world;
 495                         self.pass_distance = 0;
 496                 }
 497
 498                 if(self.enemy)
 499                 {
 500                         /*WarpZone_TrailParticles(world, particleeffectnum("red_pass"), self.origin, targ_origin);
 501                         print("Trace origin: ", vtos(targ_origin), "\n");
 502                         print("Target origin: ", vtos(self.enemy.origin), "\n");
 503                         print("My origin: ", vtos(self.origin), "\n"); */
 504
 505                         self.monster_movestate = MONSTER_MOVE_ENEMY;
 506                         self.last_trace = time + 1.2;
 507                         return targ_origin;
 508                 }
 509
 510                 /*makevectors(self.angles);
 511                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 512                 self.last_trace = time + 1.2;
 513                 return self.enemy.origin; */
 514         }
 515
 516         switch(self.monster_moveflags)
 517         {
 518                 case MONSTER_MOVE_OWNER:
 519                 {
 520                         self.monster_movestate = MONSTER_MOVE_OWNER;
 521                         self.last_trace = time + 0.3;
 522                         return (self.monster_owner) ? self.monster_owner.origin : self.origin;
 523                 }
 524                 case MONSTER_MOVE_SPAWNLOC:
 525                 {
 526                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 527                         self.last_trace = time + 2;
 528                         return self.pos1;
 529                 }
 530                 case MONSTER_MOVE_NOMOVE:
 531                 {
 532                         self.monster_movestate = MONSTER_MOVE_NOMOVE;
 533                         self.last_trace = time + 2;
 534                         return self.origin;
 535                 }
 536                 default:
 537                 case MONSTER_MOVE_WANDER:
 538                 {
 539                         vector pos;
 540                         self.monster_movestate = MONSTER_MOVE_WANDER;
 541
 542                         if(targ)
 543                         {
 544                                 self.last_trace = time + 0.5;
 545                                 pos = targ.origin;
 546                         }
 547                         else
 548                         {
 549                                 self.last_trace = time + self.wander_delay;
 550
 551                                 self.angles_y = rint(random() * 500);
 552                                 makevectors(self.angles);
 553                                 pos = self.origin + v_forward * self.wander_distance;
 554
 555                                 if(((self.flags & FL_FLY) && (self.spawnflags & MONSTERFLAG_FLY_VERTICAL)) || (self.flags & FL_SWIM))
 556                                 {
 557                                         pos_z = random() * 200;
 558                                         if(random() >= 0.5)
 559                                                 pos_z *= -1;
 560                                 }
 561                         }
 562
 563                         return pos;
 564                 }
 565         }
 566 }
 567
 568 void monster_CalculateVelocity(entity mon, vector to, vector from, float turnrate, float movespeed)
 569 {
 570         float current_distance = vlen((('1 0 0' * to_x) + ('0 1 0' * to_y)) - (('1 0 0' * from_x) + ('0 1 0' * from_y))); // for the sake of this check, exclude Z axis
 571         float initial_height = 0; //min(50, (targ_distance * tanh(20)));
 572         float current_height = (initial_height * min(1, (current_distance / self.pass_distance)));
 573         //print("current_height = ", ftos(current_height), ", initial_height = ", ftos(initial_height), ".\n");
 574
 575         vector targpos;
 576         if(current_height) // make sure we can actually do this arcing path
 577         {
 578                 targpos = (to + ('0 0 1' * current_height));
 579                 WarpZone_TraceLine(mon.origin, targpos, MOVE_NOMONSTERS, mon);
 580                 if(trace_fraction < 1)
 581                 {
 582                         //print("normal arc line failed, trying to find new pos...");
 583                         WarpZone_TraceLine(to, targpos, MOVE_NOMONSTERS, mon);
 584                         targpos = (trace_endpos + '0 0 -10');
 585                         WarpZone_TraceLine(mon.origin, targpos, MOVE_NOMONSTERS, mon);
 586                         if(trace_fraction < 1) { targpos = to; /* print(" ^1FAILURE^7, reverting to original direction.\n"); */ }
 587                         /*else { print(" ^3SUCCESS^7, using new arc line.\n"); } */
 588                 }
 589         }
 590         else { targpos = to; }
 591
 592         //mon.angles = normalize(('0 1 0' * to_y) - ('0 1 0' * from_y));
 593
 594         vector desired_direction = normalize(targpos - from);
 595         if(turnrate) { mon.velocity = (normalize(normalize(mon.velocity) + (desired_direction * 50)) * movespeed); }
 596         else { mon.velocity = (desired_direction * movespeed); }
 597
 598         //mon.steerto = steerlib_attract2(targpos, 0.5, 500, 0.95);
 599         //mon.angles = vectoangles(mon.velocity);
 600 }
 601
 602 void monster_move(float runspeed, float walkspeed, float stopspeed, float manim_run, float manim_walk, float manim_idle)
 603 {
 604         //fixedmakevectors(self.angles);
 605
 606         if(self.target2)
 607                 self.goalentity = find(world, targetname, self.target2);
 608
 609         entity targ;
 610
 611         if(self.flags & FL_SWIM)
 612         {
 613                 if(self.waterlevel < WATERLEVEL_WETFEET)
 614                 {
 615                         if(time >= self.last_trace)
 616                         {
 617                                 self.fish_wasdrowning = TRUE;
 618                                 self.last_trace = time + 0.4;
 619
 620                                 Damage (self, world, world, 2, DEATH_DROWN, self.origin, '0 0 0');
 621                                 self.angles = '90 90 0';
 622                                 if(random() < 0.5)
 623                                 {
 624                                         self.velocity_y += random() * 50;
 625                                         self.velocity_x -= random() * 50;
 626                                 }
 627                                 else
 628                                 {
 629                                         self.velocity_y -= random() * 50;
 630                                         self.velocity_x += random() * 50;
 631                                 }
 632                                 self.velocity_z += random() * 150;
 633                         }
 634
 635
 636                         self.movetype = MOVETYPE_BOUNCE;
 637                         //self.velocity_z = -200;
 638
 639                         return;
 640                 }
 641                 else if(self.fish_wasdrowning)
 642                 {
 643                         self.fish_wasdrowning = FALSE;
 644                         self.angles_x = 0;
 645                         self.movetype = MOVETYPE_WALK;
 646                 }
 647         }
 648
 649         targ = self.goalentity;
 650
 651         monster_target = targ;
 652         monster_speed_run = runspeed;
 653         monster_speed_walk = walkspeed;
 654
 655         if(MUTATOR_CALLHOOK(MonsterMove) || gameover || self.draggedby != world || (round_handler_IsActive() && !round_handler_IsRoundStarted()) || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start) || time < self.spawn_time)
 656         {
 657                 runspeed = walkspeed = 0;
 658                 if(time >= self.spawn_time)
 659                         self.frame = manim_idle;
 660                 movelib_beak_simple(stopspeed);
 661                 return;
 662         }
 663
 664         targ = monster_target;
 665         runspeed = bound(0, monster_speed_run * Monster_SkillModifier(), runspeed * 2); // limit maxspeed to prevent craziness
 666         walkspeed = bound(0, monster_speed_walk * Monster_SkillModifier(), walkspeed * 2); // limit maxspeed to prevent craziness
 667
 668         if(time < self.spider_slowness)
 669         {
 670                 runspeed *= 0.5;
 671                 walkspeed *= 0.5;
 672         }
 673
 674         if(teamplay)
 675         if(autocvar_g_monsters_teams)
 676         if(DIFF_TEAM(self.monster_owner, self))
 677                 self.monster_owner = world;
 678
 679         if(time >= self.last_enemycheck)
 680         {
 681                 if(!self.enemy)
 682                 {
 683                         self.enemy = FindTarget(self);
 684                         if(self.enemy)
 685                         {
 686                                 WarpZone_RefSys_Copy(self.enemy, self);
 687                                 WarpZone_RefSys_AddInverse(self.enemy, self); // wz1^-1 ... wzn^-1 receiver
 688                                 self.moveto = WarpZone_RefSys_TransformOrigin(self.enemy, self, (0.5 * (self.enemy.absmin + self.enemy.absmax)));
 689
 690                                 self.pass_distance = vlen((('1 0 0' * self.enemy.origin_x) + ('0 1 0' * self.enemy.origin_y)) - (('1 0 0' *  self.origin_x) + ('0 1 0' *  self.origin_y)));
 691                                 MonsterSound(monstersound_sight, 0, FALSE, CH_VOICE);
 692                         }
 693                 }
 694
 695                 self.last_enemycheck = time + 1; // check for enemies every second
 696         }
 697
 698         if(self.state == MONSTER_STATE_ATTACK_MELEE && time >= self.attack_finished_single)
 699                 self.state = 0;
 700
 701         if(self.state != MONSTER_STATE_ATTACK_MELEE) // don't move if set
 702         if(time >= self.last_trace || self.enemy) // update enemy instantly
 703                 self.moveto = monster_pickmovetarget(targ);
 704
 705         if(!self.enemy)
 706                 MonsterSound(monstersound_idle, 7, TRUE, CH_VOICE);
 707
 708         if(self.state == MONSTER_STATE_ATTACK_LEAP && (self.flags & FL_ONGROUND))
 709         {
 710                 self.state = 0;
 711                 self.touch = MonsterTouch;
 712         }
 713
 714         if(self.state == MONSTER_STATE_ATTACK_MELEE)
 715                 self.moveto = self.origin;
 716
 717         if(self.enemy && self.enemy.vehicle)
 718                 runspeed = 0;
 719
 720         if(!(((self.flags & FL_FLY) && (self.spawnflags & MONSTERFLAG_FLY_VERTICAL)) || (self.flags & FL_SWIM)))
 721                 //v_forward = normalize(self.moveto - self.origin);
 722         //else
 723                 self.moveto_z = self.origin_z;
 724
 725         if(vlen(self.origin - self.moveto) > 64)
 726         {
 727                 if((self.flags & FL_ONGROUND) || ((self.flags & FL_FLY) || (self.flags & FL_SWIM)))
 728                         monster_CalculateVelocity(self, self.moveto, self.origin, TRUE, ((self.enemy) ? runspeed : walkspeed));
 729
 730                 /*&if(self.flags & FL_FLY || self.flags & FL_SWIM)
 731                         movelib_move_simple(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 732                 else
 733                         movelib_move_simple_gravity(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6); */
 734
 735                 if(time > self.pain_finished)
 736                 if(time > self.attack_finished_single)
 737                 if(vlen(self.velocity) > 10)
 738                         self.frame = ((self.enemy) ? manim_run : manim_walk);
 739                 else
 740                         self.frame = manim_idle;
 741         }
 742         else
 743         {
 744                 entity e = find(world, targetname, self.target2);
 745                 if(e.target2)
 746                         self.target2 = e.target2;
 747                 else if(e.target)
 748                         self.target2 = e.target;
 749
 750                 movelib_beak_simple(stopspeed);
 751                 if(time > self.attack_finished_single)
 752                 if(time > self.pain_finished)
 753                 if (vlen(self.velocity) <= 30)
 754                         self.frame = manim_idle;
 755         }
 756
 757         self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 758
 759         vector real_angle = vectoangles(self.steerto) - self.angles;
 760         float turny = 25;
 761         if(self.state == MONSTER_STATE_ATTACK_MELEE)
 762                 turny = 0;
 763         if(turny)
 764         {
 765                 turny = bound(turny * -1, shortangle_f(real_angle_y, self.angles_y), turny);
 766                 self.angles_y += turny;
 767         }
 768
 769         monster_checkattack(self, self.enemy);
 770 }
 771
 772 void monster_remove(entity mon)
 773 {
 774         if(!mon)
 775                 return; // nothing to remove
 776
 777         pointparticles(particleeffectnum("item_pickup"), mon.origin, '0 0 0', 1);
 778
 779         if(mon.weaponentity)
 780                 remove(mon.weaponentity);
 781
 782         WaypointSprite_Kill(mon.sprite);
 783
 784         remove(mon);
 785 }
 786
 787 void monster_dead_think()
 788 {
 789         self.nextthink = time + self.ticrate;
 790
 791         CSQCMODEL_AUTOUPDATE();
 792
 793         if(self.monster_lifetime != 0)
 794         if(time >= self.monster_lifetime)
 795         {
 796                 Monster_Fade();
 797                 return;
 798         }
 799 }
 800
 801 void monsters_setstatus()
 802 {
 803         self.stat_monsters_total = monsters_total;
 804         self.stat_monsters_killed = monsters_killed;
 805 }
 806
 807 void Monster_Appear()
 808 {
 809         self.enemy = activator;
 810         self.spawnflags &= ~MONSTERFLAG_APPEAR; // otherwise, we get an endless loop
 811         monster_initialize(self.monsterid);
 812 }
 813
 814 float Monster_CheckAppearFlags(entity ent, float monster_id)
 815 {
 816         if(!(ent.spawnflags & MONSTERFLAG_APPEAR))
 817                 return FALSE;
 818
 819         ent.think = func_null;
 820         ent.monsterid = monster_id; // set so this monster is properly registered (otherwise, normal initialization is used)
 821         ent.nextthink = 0;
 822         ent.use = Monster_Appear;
 823         ent.flags = FL_MONSTER; // set so this monster can get butchered
 824
 825         return TRUE;
 826 }
 827
 828 void monsters_reset()
 829 {
 830         setorigin(self, self.pos1);
 831         self.angles = self.pos2;
 832
 833         self.health = self.max_health;
 834         self.velocity = '0 0 0';
 835         self.enemy = world;
 836         self.goalentity = world;
 837         self.attack_finished_single = 0;
 838         self.moveto = self.origin;
 839 }
 840
 841 void monsters_corpse_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 842 {
 843         self.health -= damage;
 844
 845         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 846
 847         if(self.health <= -100) // 100 health until gone?
 848         {
 849                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 850
 851                 // number of monsters spawned with mobspawn command
 852                 totalspawned -= 1;
 853
 854                 if(IS_CLIENT(self.realowner))
 855                         self.realowner.monstercount -= 1;
 856
 857                 self.think = SUB_Remove;
 858                 self.nextthink = time + 0.1;
 859                 self.event_damage = func_null;
 860         }
 861 }
 862
 863 void monster_die(entity attacker, float gibbed)
 864 {
 865         self.think = monster_dead_think;
 866         self.nextthink = time;
 867         self.monster_lifetime = time + 5;
 868
 869         monster_dropitem();
 870
 871         MonsterSound(monstersound_death, 0, FALSE, CH_VOICE);
 872
 873         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !(self.spawnflags & MONSTERFLAG_RESPAWNED))
 874                 monsters_killed += 1;
 875
 876         if(IS_PLAYER(attacker))
 877         if(autocvar_g_monsters_score_spawned || !((self.spawnflags & MONSTERFLAG_SPAWNED) || (self.spawnflags & MONSTERFLAG_RESPAWNED)))
 878                 PlayerScore_Add(attacker, SP_SCORE, +autocvar_g_monsters_score_kill);
 879
 880         if(gibbed)
 881         {
 882                 // number of monsters spawned with mobspawn command
 883                 totalspawned -= 1;
 884
 885                 if(IS_CLIENT(self.realowner))
 886                         self.realowner.monstercount -= 1;
 887         }
 888
 889         if(self.candrop && self.weapon)
 890                 W_ThrowNewWeapon(self, self.weapon, 0, self.origin, randomvec() * 150 + '0 0 325');
 891
 892         self.event_damage       = ((gibbed) ? func_null : monsters_corpse_damage);
 893         self.solid                      = SOLID_CORPSE;
 894         self.takedamage         = DAMAGE_AIM;
 895         self.deadflag           = DEAD_DEAD;
 896         self.enemy                      = world;
 897         self.movetype           = MOVETYPE_TOSS;
 898         self.moveto                     = self.origin;
 899         self.touch                      = MonsterTouch; // reset incase monster was pouncing
 900         self.reset                      = func_null;
 901         self.state                      = 0;
 902         self.attack_finished_single = 0;
 903
 904         if(!((self.flags & FL_FLY) || (self.flags & FL_SWIM)))
 905                 self.velocity = '0 0 0';
 906
 907         MON_ACTION(self.monsterid, MR_DEATH);
 908 }
 909
 910 void monsters_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 911 {
 912         if((self.spawnflags & MONSTERFLAG_INVINCIBLE) && deathtype != DEATH_KILL)
 913                 return;
 914
 915         if(time < self.pain_finished && deathtype != DEATH_KILL)
 916                 return;
 917
 918         if(time < self.spawnshieldtime && deathtype != DEATH_KILL)
 919                 return;
 920
 921         if(deathtype == DEATH_FALL && self.draggedby != world)
 922                 return;
 923
 924         vector v;
 925         float take, save;
 926
 927         v = healtharmor_applydamage(self.armorvalue, self.m_armor_blockpercent, deathtype, damage);
 928         take = v_x;
 929         save = v_y;
 930
 931         self.health -= take;
 932
 933         WaypointSprite_UpdateHealth(self.sprite, self.health);
 934
 935         self.dmg_time = time;
 936
 937         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN)
 938                 spamsound (self, CH_PAIN, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 939
 940         self.velocity += force * self.damageforcescale;
 941
 942         if(deathtype != DEATH_DROWN)
 943         {
 944                 Violence_GibSplash_At(hitloc, force, 2, bound(0, take, 200) / 16, self, attacker);
 945                 if (take > 50)
 946                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 947                 if (take > 100)
 948                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 949         }
 950
 951         if(self.health <= 0)
 952         {
 953                 if(deathtype == DEATH_KILL)
 954                         self.candrop = FALSE; // killed by mobkill command
 955
 956                 // TODO: fix this?
 957                 activator = attacker;
 958                 other = self.enemy;
 959                 SUB_UseTargets();
 960                 self.target2 = self.oldtarget2; // reset to original target on death, incase we respawn
 961
 962                 monster_die(attacker, (self.health <= -100 || deathtype == DEATH_KILL));
 963
 964                 WaypointSprite_Kill(self.sprite);
 965
 966                 frag_attacker = attacker;
 967                 frag_target = self;
 968                 MUTATOR_CALLHOOK(MonsterDies);
 969
 970                 if(self.health <= -100 || deathtype == DEATH_KILL) // check if we're already gibbed
 971                 {
 972                         Violence_GibSplash(self, 1, 0.5, attacker);
 973
 974                         self.think = SUB_Remove;
 975                         self.nextthink = time + 0.1;
 976                 }
 977         }
 978 }
 979
 980 void monster_setupcolors()
 981 {
 982         if(IS_PLAYER(self.monster_owner))
 983                 self.colormap = self.monster_owner.colormap;
 984         else if(teamplay && self.team)
 985                 self.colormap = 1024 + (self.team - 1) * 17;
 986         else
 987         {
 988                 if(self.monster_skill <= MONSTER_SKILL_EASY)
 989                         self.colormap = 1029;
 990                 else if(self.monster_skill <= MONSTER_SKILL_MEDIUM)
 991                         self.colormap = 1027;
 992                 else if(self.monster_skill <= MONSTER_SKILL_HARD)
 993                         self.colormap = 1038;
 994                 else if(self.monster_skill <= MONSTER_SKILL_INSANE)
 995                         self.colormap = 1028;
 996                 else if(self.monster_skill <= MONSTER_SKILL_NIGHTMARE)
 997                         self.colormap = 1032;
 998                 else
 999                         self.colormap = 1024;
1000         }
1001 }
1002
1003 void monster_think()
1004 {
1005         self.think = monster_think;
1006         self.nextthink = self.ticrate;
1007
1008         if(self.monster_lifetime)
1009         if(time >= self.monster_lifetime)
1010         {
1011                 Damage(self, self, self, self.health + self.max_health, DEATH_KILL, self.origin, self.origin);
1012                 return;
1013         }
1014
1015         MON_ACTION(self.monsterid, MR_THINK);
1016
1017         CSQCMODEL_AUTOUPDATE();
1018 }
1019
1020 float monster_spawn()
1021 {
1022         MON_ACTION(self.monsterid, MR_SETUP);
1023
1024         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
1025         {
1026                 Monster_CheckMinibossFlag();
1027                 self.health *= Monster_SkillModifier();
1028         }
1029
1030         self.max_health = self.health;
1031         self.pain_finished = self.nextthink;
1032
1033         if(IS_PLAYER(self.monster_owner))
1034                 self.effects |= EF_DIMLIGHT;
1035
1036         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
1037         if(!self.skin)
1038                 self.skin = rint(random() * 4);
1039
1040         if(!self.attack_range)
1041                 self.attack_range = autocvar_g_monsters_attack_range;
1042
1043         if(!self.wander_delay) { self.wander_delay = 2; }
1044         if(!self.wander_distance) { self.wander_distance = 600; }
1045
1046         precache_monstersounds();
1047         UpdateMonsterSounds();
1048
1049         if(teamplay)
1050                 self.monster_attack = TRUE; // we can have monster enemies in team games
1051
1052         MonsterSound(monstersound_spawn, 0, FALSE, CH_VOICE);
1053
1054         WaypointSprite_Spawn(M_NAME(self.monsterid), 0, 1024, self, '0 0 1' * (self.maxs_z + 15), world, self.team, self, sprite, TRUE, RADARICON_DANGER, ((self.team) ? Team_ColorRGB(self.team) : '1 0 0'));
1055         if(!(self.spawnflags & MONSTERFLAG_INVINCIBLE))
1056         {
1057                 WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
1058                 WaypointSprite_UpdateHealth(self.sprite, self.health);
1059         }
1060
1061         self.think = monster_think;
1062         self.nextthink = time + self.ticrate;
1063
1064         if(MUTATOR_CALLHOOK(MonsterSpawn))
1065                 return FALSE;
1066
1067         return TRUE;
1068 }
1069
1070 float monster_initialize(float mon_id)
1071 {
1072         if(!autocvar_g_monsters) { return FALSE; }
1073
1074         if(Monster_CheckAppearFlags(self, mon_id)) { return TRUE; } // return true so the monster isn't removed
1075
1076         entity mon = get_monsterinfo(mon_id);
1077
1078         if(!self.monster_skill)
1079                 self.monster_skill = cvar("g_monsters_skill");
1080
1081         // support for quake style removing monsters based on skill
1082         if(self.monster_skill == MONSTER_SKILL_EASY) if(self.spawnflags & MONSTERSKILL_NOTEASY) { return FALSE; }
1083         if(self.monster_skill == MONSTER_SKILL_MEDIUM) if(self.spawnflags & MONSTERSKILL_NOTMEDIUM) { return FALSE; }
1084         if(self.monster_skill == MONSTER_SKILL_HARD) if(self.spawnflags & MONSTERSKILL_NOTHARD) { return FALSE; }
1085
1086         if(self.team && !teamplay)
1087                 self.team = 0;
1088
1089         if(!(self.spawnflags & MONSTERFLAG_SPAWNED)) // naturally spawned monster
1090         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED)) // don't count re-spawning monsters either
1091                 monsters_total += 1;
1092
1093         setmodel(self, mon.model);
1094         //setsize(self, mon.mins, mon.maxs);
1095         self.flags                              = FL_MONSTER;
1096         self.takedamage                 = DAMAGE_AIM;
1097         self.bot_attack                 = TRUE;
1098         self.iscreature                 = TRUE;
1099         self.teleportable               = TRUE;
1100         self.damagedbycontents  = TRUE;
1101         self.monsterid                  = mon_id;
1102         self.damageforcescale   = 0;
1103         self.event_damage               = monsters_damage;
1104         self.touch                              = MonsterTouch;
1105         self.use                                = monster_use;
1106         self.solid                              = SOLID_BBOX;
1107         self.movetype                   = MOVETYPE_WALK;
1108         self.spawnshieldtime    = time + autocvar_g_monsters_spawnshieldtime;
1109         self.enemy                              = world;
1110         self.velocity                   = '0 0 0';
1111         self.moveto                             = self.origin;
1112         self.pos1                               = self.origin;
1113         self.pos2                               = self.angles;
1114         self.reset                              = monsters_reset;
1115         self.netname                    = mon.netname;
1116         self.monster_name               = M_NAME(mon_id);
1117         self.candrop                    = TRUE;
1118         self.view_ofs                   = '0 0 1' * (self.maxs_z * 0.5);
1119         self.oldtarget2                 = self.target2;
1120         self.pass_distance              = 0;
1121         self.deadflag                   = DEAD_NO;
1122         self.noalign                    = ((mon.spawnflags & MONSTER_TYPE_FLY) || (mon.spawnflags & MONSTER_TYPE_SWIM));
1123         self.spawn_time                 = time;
1124         self.spider_slowness    = 0;
1125         self.gravity                    = 1;
1126         self.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1127
1128         if(!self.scale)
1129                 self.scale = 1;
1130
1131         if(autocvar_g_monsters_edit)
1132                 self.grab = 1; // owner may carry their monster
1133
1134         if(autocvar_g_fullbrightplayers)
1135                 self.effects |= EF_FULLBRIGHT;
1136
1137         if(autocvar_g_nodepthtestplayers)
1138                 self.effects |= EF_NODEPTHTEST;
1139
1140         if(mon.spawnflags & MONSTER_TYPE_SWIM)
1141                 self.flags |= FL_SWIM;
1142
1143         if(mon.spawnflags & MONSTER_TYPE_FLY)
1144         {
1145                 self.flags |= FL_FLY;
1146                 self.movetype = MOVETYPE_FLY;
1147         }
1148
1149         if(mon.spawnflags & MONSTER_SIZE_BROKEN)
1150         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
1151                 self.scale *= 1.3;
1152
1153         setsize(self, mon.mins * self.scale, mon.maxs * self.scale);
1154
1155         if(!self.ticrate)
1156                 self.ticrate = autocvar_g_monsters_think_delay;
1157
1158         self.ticrate = bound(sys_frametime, self.ticrate, 60);
1159
1160         if(!self.m_armor_blockpercent)
1161                 self.m_armor_blockpercent = 0.5;
1162
1163         if(!self.target_range)
1164                 self.target_range = autocvar_g_monsters_target_range;
1165
1166         if(!self.respawntime)
1167                 self.respawntime = autocvar_g_monsters_respawn_delay;
1168
1169         if(!self.monster_moveflags)
1170                 self.monster_moveflags = MONSTER_MOVE_WANDER;
1171
1172         if(!self.noalign)
1173         {
1174                 setorigin(self, self.origin + '0 0 20');
1175                 tracebox(self.origin + '0 0 64', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
1176                 setorigin(self, trace_endpos);
1177         }
1178
1179         if(!monster_spawn())
1180                 return FALSE;
1181
1182         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
1183                 monster_setupcolors();
1184
1185         CSQCMODEL_AUTOINIT();
1186
1187         return TRUE;
1188 }