qcsrc/common/monsters/monster/shambler.qc

   1 #ifdef REGISTER_MONSTER
   2 REGISTER_MONSTER(
   3 /* MON_##id   */ SHAMBLER,
   4 /* function   */ m_shambler,
   5 /* spawnflags */ MONSTER_SIZE_BROKEN | MON_FLAG_SUPERMONSTER,
   6 /* mins,maxs  */ '-41 -41 -31', '41 41 65',
   7 /* model      */ "shambler.mdl",
   8 /* netname    */ "shambler",
   9 /* fullname   */ _("Shambler")
  10 );
  11
  12 #define SHAMBLER_SETTINGS(monster) \
  13         MON_ADD_CVAR(monster, health) \
  14         MON_ADD_CVAR(monster, attack_smash_damage) \
  15         MON_ADD_CVAR(monster, attack_claw_damage) \
  16         MON_ADD_CVAR(monster, attack_lightning_damage) \
  17         MON_ADD_CVAR(monster, speed_stop) \
  18         MON_ADD_CVAR(monster, speed_run) \
  19         MON_ADD_CVAR(monster, speed_walk)
  20
  21 #ifdef SVQC
  22 SHAMBLER_SETTINGS(shambler)
  23 #endif // SVQC
  24 #else
  25 #ifdef SVQC
  26 const float shambler_anim_stand         = 0;
  27 const float shambler_anim_walk          = 1;
  28 const float shambler_anim_run           = 2;
  29 const float shambler_anim_smash         = 3;
  30 const float shambler_anim_swingr        = 4;
  31 const float shambler_anim_swingl        = 5;
  32 const float shambler_anim_magic         = 6;
  33 const float shambler_anim_pain          = 7;
  34 const float shambler_anim_death         = 8;
  35
  36 void shambler_smash()
  37 {
  38         monster_melee(self.enemy, MON_CVAR(shambler, attack_smash_damage), self.attack_range, DEATH_MONSTER_SHAMBLER_SMASH, TRUE);
  39 }
  40
  41 void shambler_delayedsmash()
  42 {
  43         monsters_setframe(shambler_anim_smash);
  44         defer(0.7, shambler_smash);
  45         self.attack_finished_single = time + 1.1;
  46 }
  47
  48 void shambler_swing()
  49 {
  50         float r = (random() < 0.5);
  51         monsters_setframe((r) ? shambler_anim_swingr : shambler_anim_swingl);
  52         monster_melee(self.enemy, MON_CVAR(shambler, attack_claw_damage), self.attack_range, DEATH_MONSTER_SHAMBLER_CLAW, TRUE);
  53         self.attack_finished_single = time + 0.8;
  54         if(r)
  55                 defer(0.5, shambler_swing);
  56 }
  57
  58 void CastLightning()
  59 {
  60         local vector org, dir;
  61         //vector v = '0 0 0';
  62
  63         self.effects |= EF_MUZZLEFLASH;
  64
  65         org = self.origin + '0 0 40';
  66
  67         dir = self.enemy.origin + '0 0 16' - org;
  68         dir = normalize (dir);
  69
  70         traceline (org, self.origin + dir * 1000, TRUE, self);
  71
  72         FireRailgunBullet (org, org + dir * 1000, MON_CVAR(shambler, attack_lightning_damage) * monster_skill, 0, 0, 0, 0, 0, DEATH_MONSTER_SHAMBLER_ZAP);
  73
  74         // teamcolor / hit beam effect
  75         //v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
  76         //WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3"), org, v);
  77
  78         te_csqc_lightningarc(org, trace_endpos);
  79 }
  80
  81 float shambler_attack(float attack_type)
  82 {
  83         switch(attack_type)
  84         {
  85                 case MONSTER_ATTACK_MELEE:
  86                 {
  87                         float chance = random();
  88
  89                         if(chance > 0.6)
  90                                 shambler_delayedsmash();
  91                         else
  92                                 shambler_swing();
  93
  94                         return TRUE;
  95                 }
  96                 case MONSTER_ATTACK_RANGED:
  97                 {
  98                         monsters_setframe(shambler_anim_magic);
  99                         self.attack_finished_single = time + 1.1;
 100                         defer(0.6, CastLightning);
 101
 102                         return TRUE;
 103                 }
 104         }
 105
 106         return FALSE;
 107 }
 108
 109 void spawnfunc_monster_shambler()
 110 {
 111         self.classname = "monster_shambler";
 112
 113         self.monster_spawnfunc = spawnfunc_monster_shambler;
 114
 115         if(Monster_CheckAppearFlags(self))
 116                 return;
 117
 118         if not(monster_initialize(MON_SHAMBLER, FALSE)) { remove(self); return; }
 119 }
 120
 121 float m_shambler(float req)
 122 {
 123         switch(req)
 124         {
 125                 case MR_THINK:
 126                 {
 127                         monster_move(MON_CVAR(shambler, speed_run), MON_CVAR(shambler, speed_walk), MON_CVAR(shambler, speed_stop), shambler_anim_run, shambler_anim_walk, shambler_anim_stand);
 128                         return TRUE;
 129                 }
 130                 case MR_DEATH:
 131                 {
 132                         monsters_setframe(shambler_anim_death);
 133                         return TRUE;
 134                 }
 135                 case MR_SETUP:
 136                 {
 137                         if not(self.health) self.health = MON_CVAR(shambler, health);
 138                         if not(self.attack_range) self.attack_range = 150;
 139
 140                         self.monster_loot = spawnfunc_item_health_mega;
 141                         self.monster_attackfunc = shambler_attack;
 142                         monsters_setframe(shambler_anim_stand);
 143                         self.weapon = WEP_NEX;
 144
 145                         return TRUE;
 146                 }
 147                 case MR_INIT:
 148                 {
 149                         // nothing
 150                         return TRUE;
 151                 }
 152                 case MR_CONFIG:
 153                 {
 154                         MON_CONFIG_SETTINGS(SHAMBLER_SETTINGS(shambler))
 155                         return TRUE;
 156                 }
 157         }
 158
 159         return TRUE;
 160 }
 161
 162 #endif // SVQC
 163 #ifdef CSQC
 164 float m_shambler(float req)
 165 {
 166         switch(req)
 167         {
 168                 case MR_DEATH:
 169                 {
 170                         // nothing
 171                         return TRUE;
 172                 }
 173                 case MR_INIT:
 174                 {
 175                         precache_model ("models/monsters/shambler.mdl");
 176                         return TRUE;
 177                 }
 178         }
 179
 180         return TRUE;
 181 }
 182
 183 #endif // CSQC
 184 #endif // REGISTER_MONSTER