qcsrc/common/minigames/minigame/bd.qc

   1 REGISTER_MINIGAME(bd, "Bulldozer");
   2
   3 const int BD_TURN_MOVE  = 0x0100; // player must move the bulldozer
   4 const int BD_TURN_WIN   = 0x0200; // victory
   5 const int BD_TURN_LOSS  = 0x0400; // they did it?!
   6 const int BD_TURN_EDIT  = 0x0800; // editing mode
   7 const int BD_TURN_TYPE  = 0x0f00; // turn type mask
   8
   9 const int BD_SF_PLAYERMOVES = MINIG_SF_CUSTOM;
  10
  11 // 240 tiles...
  12 const int BD_LET_CNT = 20;
  13 const int BD_NUM_CNT = 20;
  14
  15 const int BD_TILE_SIZE = 20;
  16
  17 const int BD_TEAMS = 1;
  18
  19 .vector bd_dir;
  20
  21 .int bd_moves;
  22
  23 .string bd_levelname;
  24 .string bd_nextlevel;
  25
  26 #ifdef SVQC
  27 .bool bd_canedit;
  28 #endif
  29
  30 .int bd_tiletype;
  31 const int BD_TILE_DOZER = 1;
  32 const int BD_TILE_TARGET = 2;
  33 const int BD_TILE_BOULDER = 3;
  34 const int BD_TILE_BRICK1 = 4;
  35 const int BD_TILE_BRICK2 = 5;
  36 const int BD_TILE_BRICK3 = 6;
  37 const int BD_TILE_BRICK4 = 7;
  38 const int BD_TILE_BRICK5 = 8;
  39 const int BD_TILE_BRICK6 = 9;
  40 const int BD_TILE_LAST = 9;
  41
  42 string autocvar_sv_minigames_bulldozer_startlevel = "level1";
  43
  44 // find same game piece given its tile name
  45 entity bd_find_piece(entity minig, string tile, bool check_target)
  46 {
  47         entity e = world;
  48         while ( ( e = findentity(e,owner,minig) ) )
  49                 if ( e.classname == "minigame_board_piece" && e.netname == tile && ((check_target) ? e.bd_tiletype == BD_TILE_TARGET : e.bd_tiletype != BD_TILE_TARGET) )
  50                         return e;
  51         return world;
  52 }
  53
  54 // check if the tile name is valid (15x15 grid)
  55 bool bd_valid_tile(string tile)
  56 {
  57         if ( !tile )
  58                 return false;
  59         int number = minigame_tile_number(tile);
  60         int letter = minigame_tile_letter(tile);
  61         return 0 <= number && number < BD_NUM_CNT && 0 <= letter && letter < BD_LET_CNT;
  62 }
  63
  64 entity bd_find_dozer(entity minig)
  65 {
  66         entity e = world;
  67         while ( ( e = findentity(e,owner,minig) ) )
  68                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype == BD_TILE_DOZER )
  69                         return e;
  70         return world;
  71 }
  72
  73 void bd_check_winner(entity minig)
  74 {
  75         int total = 0, valid = 0;
  76         entity e = world;
  77         while ( ( e = findentity(e,owner,minig) ) )
  78                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype == BD_TILE_TARGET )
  79                 {
  80                         ++total;
  81                         if(bd_find_piece(minig, e.netname, false).bd_tiletype == BD_TILE_BOULDER)
  82                                 ++valid;
  83                 }
  84
  85         if(valid >= total)
  86         {
  87                 minig.minigame_flags = BD_TURN_WIN;
  88                 minigame_server_sendflags(minig,MINIG_SF_UPDATE);
  89         }
  90 }
  91
  92 bool bd_canfill(int ttype)
  93 {
  94         switch(ttype)
  95         {
  96                 case BD_TILE_BRICK6:
  97                 case BD_TILE_BRICK5:
  98                 case BD_TILE_BRICK4:
  99                 case BD_TILE_BRICK3:
 100                 case BD_TILE_BRICK2:
 101                 case BD_TILE_BRICK1: return true;
 102         }
 103
 104         return false;
 105 }
 106
 107 bool bd_move_dozer(entity minigame, entity dozer)
 108 {
 109         if(!dozer.bd_dir_x && !dozer.bd_dir_y)
 110                 return false; // nope!
 111
 112         int myx = minigame_tile_letter(dozer.netname);
 113         int myy = minigame_tile_number(dozer.netname);
 114
 115         myx += dozer.bd_dir_x;
 116         myy += dozer.bd_dir_y;
 117
 118         string newpos = minigame_tile_buildname(myx, myy);
 119         entity hit = bd_find_piece(minigame, newpos, false);
 120
 121         if(!bd_valid_tile(newpos))
 122                 return false;
 123
 124         if(hit)
 125         switch(hit.bd_tiletype)
 126         {
 127                 case BD_TILE_DOZER: // wtf, but let's do this incase
 128                 case BD_TILE_BRICK6:
 129                 case BD_TILE_BRICK5:
 130                 case BD_TILE_BRICK4:
 131                 case BD_TILE_BRICK3:
 132                 case BD_TILE_BRICK2:
 133                 case BD_TILE_BRICK1: return false;
 134                 case BD_TILE_BOULDER:
 135                 {
 136                         string testpos;
 137                         int tx = minigame_tile_letter(hit.netname);
 138                         int ty = minigame_tile_number(hit.netname);
 139
 140                         tx += dozer.bd_dir_x;
 141                         ty += dozer.bd_dir_y;
 142
 143                         testpos = minigame_tile_buildname(tx, ty);
 144                         entity testhit = bd_find_piece(minigame, testpos, false);
 145
 146                         if(!bd_valid_tile(testpos) || testhit)
 147                                 return false;
 148
 149                         if(hit.netname) { strunzone(hit.netname); }
 150                         hit.netname = strzone(testpos);
 151                         minigame_server_sendflags(hit,MINIG_SF_UPDATE);
 152                         break;
 153                 }
 154         }
 155
 156         if(dozer.netname) { strunzone(dozer.netname); }
 157         dozer.netname = strzone(newpos);
 158
 159         return true;
 160 }
 161
 162 // make a move
 163 void bd_move(entity minigame, entity player, string dir)
 164 {
 165         if ( minigame.minigame_flags & BD_TURN_MOVE )
 166         if ( dir )
 167         {
 168                 //if ( bd_valid_tile(pos) )
 169                 //if ( bd_find_piece(minigame, pos, false) )
 170                 {
 171                         entity dozer = bd_find_dozer(minigame);
 172                         if(!dozer)
 173                         {
 174                                 LOG_INFO("Dozer wasn't found!\n");
 175                                 return; // should not happen... TODO: end match?
 176                         }
 177
 178                         int dxs = 0, dys = 0;
 179                         string thedir = strtolower(dir);
 180                         if(thedir == "up" || thedir == "u") { dxs = 0; dys = 1; }
 181                         if(thedir == "down" || thedir == "dn" || thedir == "d") { dxs = 0; dys = -1; }
 182                         if(thedir == "left" || thedir == "lt" || thedir == "l") { dxs = -1; dys = 0; }
 183                         if(thedir == "right" || thedir == "rt" || thedir == "r") { dxs = 1; dys = 0; }
 184
 185                         int dx = bound(-1, dxs, 1);
 186                         int dy = bound(-1, dys, 1);
 187
 188                         dozer.bd_dir_x = dx;
 189                         dozer.bd_dir_y = dy;
 190                         dozer.bd_dir_z = 0;
 191
 192                         if(bd_move_dozer(minigame, dozer))
 193                                 player.bd_moves++;
 194
 195                         bd_check_winner(minigame);
 196
 197                         minigame_server_sendflags(dozer,MINIG_SF_UPDATE); // update anyway
 198                         minigame_server_sendflags(player,BD_SF_PLAYERMOVES);
 199                         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 200                 }
 201         }
 202 }
 203
 204 // editor
 205 void bd_editor_place(entity minigame, entity player, string pos, int thetile, string thedir)
 206 {
 207         if ( minigame.minigame_flags & BD_TURN_EDIT )
 208         if ( pos && thetile )
 209         {
 210                 if ( bd_valid_tile(pos) )
 211                 {
 212                         entity found_piece = bd_find_piece(minigame, pos, false);
 213                         entity targ = bd_find_piece(minigame, pos, true);
 214
 215                         if(found_piece.bd_tiletype == BD_TILE_DOZER && thedir != "")
 216                         {
 217                                 int dxs = 0, dys = 0;
 218                                 string newdir = strtolower(thedir);
 219                                 if(newdir == "up" || newdir == "u") { dxs = 0; dys = 1; }
 220                                 if(newdir == "down" || newdir == "dn" || newdir == "d") { dxs = 0; dys = -1; }
 221                                 if(newdir == "left" || newdir == "lt" || newdir == "l") { dxs = -1; dys = 0; }
 222                                 if(newdir == "right" || newdir == "rt" || newdir == "r") { dxs = 1; dys = 0; }
 223
 224                                 int dx = bound(-1, dxs, 1);
 225                                 int dy = bound(-1, dys, 1);
 226
 227                                 found_piece.bd_dir_x = dx;
 228                                 found_piece.bd_dir_y = dy;
 229                                 found_piece.bd_dir_z = 0;
 230                                 minigame_server_sendflags(found_piece,MINIG_SF_UPDATE); // update anyway
 231                                 return;
 232                         }
 233
 234                         entity dozer = bd_find_dozer(minigame);
 235                         if(dozer && thetile == BD_TILE_DOZER && pos != dozer.netname)
 236                                 return; // nice try
 237
 238                         if(found_piece || (targ && thetile != BD_TILE_BOULDER))
 239                         {
 240                                 entity piece = bd_find_piece(minigame, pos, false);
 241                                 if(!piece) piece = bd_find_piece(minigame, pos, true);
 242                                 if(!piece)
 243                                         return; // how?!
 244
 245                                 if(piece.netname) { strunzone(piece.netname); }
 246                                 remove(piece);
 247                                 minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 248                                 return;
 249                         }
 250
 251                         entity piece = msle_spawn(minigame,"minigame_board_piece");
 252                         piece.team = 1;
 253                         piece.netname = strzone(pos);
 254                         piece.bd_tiletype = thetile;
 255                         piece.bd_dir = '0 -1 0';
 256                         minigame_server_sendflags(piece,MINIG_SF_UPDATE);
 257
 258                         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 259                 }
 260         }
 261 }
 262
 263 void bd_do_move(entity minigame, entity player, string dir, string thetile, string thedir)
 264 {
 265         if(minigame.minigame_flags & BD_TURN_MOVE)
 266                 bd_move(minigame, player, dir);
 267
 268         if(minigame.minigame_flags & BD_TURN_EDIT)
 269                 bd_editor_place(minigame, player, dir, stof(thetile), thedir);
 270 }
 271
 272 void bd_fill_recurse(entity minigame, entity player, int thetype, int letter, int number)
 273 {
 274         string pos = minigame_tile_buildname(letter,number);
 275         if(!bd_valid_tile(pos))
 276                 return;
 277         if(bd_find_piece(minigame, pos, false) || bd_find_piece(minigame, pos, true))
 278                 return;
 279
 280         bd_editor_place(minigame, player, pos, thetype, "");
 281
 282         bd_fill_recurse(minigame, player, thetype, letter - 1, number);
 283         bd_fill_recurse(minigame, player, thetype, letter + 1, number);
 284         bd_fill_recurse(minigame, player, thetype, letter, number - 1);
 285         bd_fill_recurse(minigame, player, thetype, letter, number + 1);
 286 }
 287
 288 void bd_do_fill(entity minigame, entity player, string dir, string thetile)
 289 {
 290         if(minigame.minigame_flags & BD_TURN_EDIT)
 291         {
 292                 int thetype = stof(thetile);
 293
 294                 if(!bd_canfill(thetype))
 295                         return;
 296
 297                 int letter = minigame_tile_letter(dir);
 298                 int number = minigame_tile_number(dir);
 299
 300                 bd_fill_recurse(minigame, player, thetype, letter, number);
 301         }
 302 }
 303
 304 void bd_reset_moves(entity minigame)
 305 {
 306         entity e;
 307 #ifdef SVQC
 308         for(e = minigame.minigame_players; e; e = e.list_next)
 309 #elif defined(CSQC)
 310         e = world;
 311         while( (e = findentity(e,owner,minigame)) )
 312                 if ( e.classname == "minigame_player" )
 313 #endif
 314                 {
 315                         e.bd_moves = 0;
 316                         minigame_server_sendflags(e,BD_SF_PLAYERMOVES);
 317                 }
 318 }
 319
 320 void bd_load_level(entity minigame);
 321 void bd_setup_pieces(entity minigame)
 322 {
 323         entity e = world;
 324         while( (e = findentity(e, owner, minigame)) )
 325                 if(e.classname == "minigame_board_piece")
 326                 {
 327                         if(e.netname) { strunzone(e.netname); }
 328                         remove(e);
 329                 }
 330
 331         bd_load_level(minigame);
 332 }
 333
 334 void bd_do_next_match(entity minigame, entity player)
 335 {
 336         minigame.minigame_flags = BD_TURN_MOVE;
 337         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 338
 339         if(minigame.bd_nextlevel && minigame.bd_nextlevel != "")
 340         {
 341                 if(minigame.bd_levelname) { strunzone(minigame.bd_levelname); }
 342                 minigame.bd_levelname = strzone(minigame.bd_nextlevel);
 343         }
 344
 345         bd_setup_pieces(minigame);
 346
 347         bd_reset_moves(minigame);
 348 }
 349
 350 void bd_set_next_match(entity minigame, string next)
 351 {
 352         if(minigame.bd_nextlevel) { strunzone(minigame.bd_nextlevel); }
 353         minigame.bd_nextlevel = strzone(next);
 354 }
 355
 356 void bd_next_match(entity minigame, entity player, string next)
 357 {
 358         if(minigame.minigame_flags & BD_TURN_WIN)
 359                 bd_do_next_match(minigame, player);
 360         if(minigame.minigame_flags & BD_TURN_EDIT)
 361                 bd_set_next_match(minigame, next);
 362 }
 363
 364 // request a new match
 365 void bd_restart_match(entity minigame, entity player)
 366 {
 367         minigame.minigame_flags = BD_TURN_MOVE;
 368         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 369
 370         bd_setup_pieces(minigame);
 371
 372         bd_reset_moves(minigame);
 373 }
 374
 375 void bd_activate_editor(entity minigame, entity player)
 376 {
 377 #ifdef SVQC
 378         if(!player.minigame_players.bd_canedit)
 379         {
 380                 sprint(player.minigame_players, "You're not allowed to edit levels, sorry!\n");
 381                 return;
 382         }
 383 #endif
 384
 385         minigame.minigame_flags = BD_TURN_EDIT;
 386         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 387
 388         bd_reset_moves(minigame);
 389
 390         bd_setup_pieces(minigame);
 391 }
 392
 393 string bd_save_piece(entity minigame, entity e)
 394 {
 395         string bd_string = "";
 396
 397         bd_string = strcat(bd_string, "\"", e.netname, "\" ");
 398         bd_string = strcat(bd_string, ftos(e.bd_tiletype), " ");
 399         bd_string = strcat(bd_string, sprintf("\"%.9v\"", e.bd_dir), " ");
 400         bd_string = strcat(bd_string, "; ");
 401
 402         return bd_string;
 403 }
 404
 405 void bd_set_nextlevel(entity minigame, string s)
 406 {
 407         tokenize_console(s);
 408
 409         if(minigame.bd_nextlevel) { strunzone(minigame.bd_nextlevel); }
 410         minigame.bd_nextlevel = strzone(argv(2));
 411 }
 412
 413 entity bd_load_piece(entity minigame, string s)
 414 {
 415         // separate pieces between the ; symbols
 416         tokenizebyseparator(s, "; ");
 417         string bd_string = argv(0);
 418
 419         tokenize_console(bd_string);
 420
 421         entity e = msle_spawn(minigame,"minigame_board_piece");
 422         e.team = 1;
 423         e.bd_dir = '0 -1 0';
 424
 425         int argv_num = 0;
 426         e.netname = strzone(argv(argv_num)); ++argv_num;
 427         e.bd_tiletype = stof(argv(argv_num)); ++argv_num;
 428         e.bd_dir = stov(argv(argv_num)); ++argv_num;
 429
 430         minigame_server_sendflags(e,MINIG_SF_ALL);
 431
 432         return e;
 433 }
 434
 435 bool bd_save_level(entity minigame)
 436 {
 437         if(minigame.bd_levelname && minigame.bd_levelname != "")
 438         {
 439                 int target_count = 0, boulder_count = 0;
 440                 entity piece = world;
 441                 while((piece = findentity(piece,owner,minigame)))
 442                 if(piece.classname == "minigame_board_piece")
 443                         if(piece.bd_tiletype == BD_TILE_BOULDER)
 444                                 ++boulder_count;
 445                         else if(piece.bd_tiletype == BD_TILE_TARGET)
 446                                 ++target_count;
 447
 448                 if(boulder_count != target_count)
 449                 {
 450                         LOG_INFO("Not enough targets or boulders, fix your level!\n");
 451                         return false;
 452                 }
 453
 454                 // saves all objects to the database file
 455                 string file_name;
 456                 float file_get;
 457
 458                 file_name = strcat("minigames/bulldozer/storage_", minigame.bd_levelname, ".txt");
 459                 file_get = fopen(file_name, FILE_WRITE);
 460                 fputs(file_get, strcat("// bulldozer storage \"", minigame.bd_levelname, "\" last updated ", strftime(true, "%d-%m-%Y %H:%M:%S"), "\n"));
 461
 462                 if(minigame.bd_nextlevel && minigame.bd_nextlevel != "" && fexists(strcat("minigames/bulldozer/storage_", minigame.bd_nextlevel, ".txt")))
 463                         fputs(file_get, strcat("nextlevel = \"", minigame.bd_nextlevel, "\"\n"));
 464
 465                 entity e = world;
 466                 while ( ( e = findentity(e,owner,minigame) ) )
 467                 if ( e.classname == "minigame_board_piece" )
 468                 {
 469                         // use a line of text for each object, listing all properties
 470                         fputs(file_get, strcat(bd_save_piece(minigame, e), "\n"));
 471                 }
 472                 fclose(file_get);
 473
 474                 return true;
 475         }
 476
 477         return false;
 478 }
 479
 480 void bd_load_level(entity minigame)
 481 {
 482         // loads all items from the database file
 483         string file_read, file_name;
 484         float file_get;
 485
 486         file_name = strcat("minigames/bulldozer/storage_", minigame.bd_levelname, ".txt");
 487         file_get = fopen(file_name, FILE_READ);
 488         if(file_get < 0)
 489         {
 490                 LOG_INFO("^3BULLDOZER: ^7could not find storage file ^3", file_name, "^7, no items were loaded\n");
 491         }
 492         else
 493         {
 494                 for(;;)
 495                 {
 496                         file_read = fgets(file_get);
 497                         if(file_read == "")
 498                                 break;
 499                         if(substring(file_read, 0, 2) == "//")
 500                                 continue;
 501                         if(substring(file_read, 0, 1) == "#")
 502                                 continue;
 503                         if(substring(file_read, 0, 9) == "nextlevel")
 504                         {
 505                                 bd_set_nextlevel(minigame, file_read);
 506                                 continue;
 507                         }
 508
 509                         entity e;
 510                         e = bd_load_piece(minigame, file_read);
 511                 }
 512         }
 513         fclose(file_get);
 514 }
 515
 516 void bd_close_editor(entity minigame)
 517 {
 518         entity dozer = bd_find_dozer(minigame);
 519         if(!dozer)
 520         {
 521                 LOG_INFO("You need to place a bulldozer on the level to save it!\n");
 522                 return;
 523         }
 524
 525         if(bd_save_level(minigame))
 526         {
 527                 minigame.minigame_flags = BD_TURN_MOVE;
 528                 minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 529         }
 530         else
 531         {
 532                 LOG_INFO("You need to set the level name!\n");
 533                 return;
 534         }
 535 }
 536
 537 #ifdef SVQC
 538
 539 // required function, handle server side events
 540 int bd_server_event(entity minigame, string event, ...)
 541 {
 542         switch(event)
 543         {
 544                 case "start":
 545                 {
 546                         if(minigame.bd_levelname) { strunzone(minigame.bd_levelname); }
 547                         minigame.bd_levelname = strzone(autocvar_sv_minigames_bulldozer_startlevel);
 548                         bd_setup_pieces(minigame);
 549                         minigame.minigame_flags = BD_TURN_MOVE;
 550
 551                         return true;
 552                 }
 553                 case "end":
 554                 {
 555                         entity e = world;
 556                         while( (e = findentity(e, owner, minigame)) )
 557                         if(e.classname == "minigame_board_piece")
 558                         {
 559                                 if(e.netname) { strunzone(e.netname); }
 560                                 remove(e);
 561                         }
 562
 563                         if(minigame.bd_nextlevel) { strunzone(minigame.bd_nextlevel); }
 564                         if(minigame.bd_levelname) { strunzone(minigame.bd_levelname); }
 565                         return false;
 566                 }
 567                 case "join":
 568                 {
 569                         int pl_num = minigame_count_players(minigame);
 570
 571                         if(pl_num >= BD_TEAMS) { return false; }
 572
 573                         return 1;
 574                 }
 575                 case "cmd":
 576                 {
 577                         switch(argv(0))
 578                         {
 579                                 case "move":
 580                                         bd_do_move(minigame, ...(0,entity), ((...(1,int)) >= 2 ? argv(1) : string_null), ((...(1,int)) >= 3 ? argv(2) : string_null), ((...(1,int)) >= 4 ? argv(3) : string_null));
 581                                         return true;
 582                                 case "next":
 583                                         bd_next_match(minigame,...(0,entity), ((...(1,int) >= 2 ? argv(1) : string_null)));
 584                                         return true;
 585                                 case "restart":
 586                                         bd_restart_match(minigame,...(0,entity));
 587                                         return true;
 588                                 case "edit":
 589                                         bd_activate_editor(minigame,...(0,entity));
 590                                         return true;
 591                                 case "save":
 592                                         bd_close_editor(minigame);
 593                                         return true;
 594                                 case "fill":
 595                                         bd_do_fill(minigame, ...(0,entity), ((...(1,int)) >= 2 ? argv(1) : string_null), ((...(1,int)) >= 3 ? argv(2) : string_null));
 596                                         return true;
 597                         }
 598
 599                         return false;
 600                 }
 601                 case "network_send":
 602                 {
 603                         entity sent = ...(0,entity);
 604                         int sf = ...(1,int);
 605                         if ( sent.classname == "minigame_board_piece" && (sf & MINIG_SF_UPDATE) )
 606                         {
 607                                 int letter = minigame_tile_letter(sent.netname);
 608                                 int number = minigame_tile_number(sent.netname);
 609
 610                                 WriteByte(MSG_ENTITY,letter);
 611                                 WriteByte(MSG_ENTITY,number);
 612
 613                                 WriteByte(MSG_ENTITY,sent.bd_tiletype);
 614
 615                                 int dx = sent.bd_dir_x;
 616                                 int dy = sent.bd_dir_y;
 617                                 if(dx == -1) dx = 2;
 618                                 if(dy == -1) dy = 2;
 619                                 WriteByte(MSG_ENTITY,dx);
 620                                 WriteByte(MSG_ENTITY,dy);
 621                         }
 622                         else if(sent.classname == "minigame_player" && (sf & BD_SF_PLAYERMOVES))
 623                                 WriteShort(MSG_ENTITY,sent.bd_moves);
 624                         return false;
 625                 }
 626         }
 627
 628         return false;
 629 }
 630
 631
 632 #elif defined(CSQC)
 633
 634 int bd_curr_tile;
 635 string bd_curr_pos;
 636
 637 vector bd_boardpos; // HUD board position
 638 vector bd_boardsize;// HUD board size
 639
 640 string bd_get_tile_pic(int tileid)
 641 {
 642         switch(tileid)
 643         {
 644                 case BD_TILE_BOULDER: return "bd/boulder";
 645                 case BD_TILE_BRICK1: return "bd/brick1";
 646                 case BD_TILE_BRICK2: return "bd/brick2";
 647                 case BD_TILE_BRICK3: return "bd/brick3";
 648                 case BD_TILE_BRICK4: return "bd/brick4";
 649                 case BD_TILE_BRICK5: return "bd/brick5";
 650                 case BD_TILE_BRICK6: return "bd/brick6";
 651                 case BD_TILE_TARGET: return "bd/target";
 652                 case BD_TILE_DOZER: return "bd/dozer";
 653         }
 654
 655         return string_null;
 656 }
 657
 658 // Required function, draw the game board
 659 void bd_hud_board(vector pos, vector mySize)
 660 {
 661         minigame_hud_fitsqare(pos, mySize);
 662         bd_boardpos = pos;
 663         bd_boardsize = mySize;
 664
 665         minigame_hud_simpleboard(pos,mySize,minigame_texture("bd/board"));
 666
 667         vector tile_size = minigame_hud_denormalize_size('1 1 0' / BD_TILE_SIZE,pos,mySize);
 668         vector tile_pos;
 669
 670         entity e;
 671         FOREACH_MINIGAME_ENTITY(e)
 672         {
 673                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype != BD_TILE_TARGET && e.bd_tiletype != BD_TILE_DOZER )
 674                 {
 675                         tile_pos = minigame_tile_pos(e.netname,BD_NUM_CNT,BD_LET_CNT);
 676                         tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 677
 678                         string thepiece = bd_get_tile_pic(e.bd_tiletype);
 679
 680                         minigame_drawpic_centered( tile_pos,
 681                                         minigame_texture(thepiece),
 682                                         tile_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL );
 683                 }
 684
 685                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype == BD_TILE_TARGET && e.bd_tiletype != BD_TILE_DOZER )
 686                 {
 687                         tile_pos = minigame_tile_pos(e.netname,BD_NUM_CNT,BD_LET_CNT);
 688                         tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 689
 690                         minigame_drawpic_centered( tile_pos,
 691                                         minigame_texture("bd/target"),
 692                                         tile_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL );
 693                 }
 694
 695                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype != BD_TILE_TARGET && e.bd_tiletype == BD_TILE_DOZER )
 696                 {
 697                         tile_pos = minigame_tile_pos(e.netname,BD_NUM_CNT,BD_LET_CNT);
 698                         tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 699
 700                         vector thedir = e.bd_dir;
 701                         float theang = 0;
 702
 703                         if(thedir_y == -1) { theang = M_PI; }
 704                         if(thedir_x == 1) { theang = M_PI/2; }
 705                         if(thedir_x == -1) { theang = M_PI*3/2; }
 706
 707                         drawrotpic(tile_pos, theang, minigame_texture("bd/dozer"),
 708                                                 tile_size, tile_size/2, '1 1 1',
 709                                                 panel_fg_alpha, DRAWFLAG_NORMAL );
 710                 }
 711         }
 712
 713         FOREACH_MINIGAME_ENTITY(e)
 714         {
 715                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype == BD_TILE_TARGET )
 716                 {
 717                         tile_pos = minigame_tile_pos(e.netname,BD_NUM_CNT,BD_LET_CNT);
 718                         tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 719
 720                         minigame_drawpic_centered( tile_pos,
 721                                         minigame_texture("bd/target"),
 722                                         tile_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL );
 723                 }
 724         }
 725
 726         FOREACH_MINIGAME_ENTITY(e)
 727         {
 728                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype == BD_TILE_DOZER )
 729                 {
 730                         tile_pos = minigame_tile_pos(e.netname,BD_NUM_CNT,BD_LET_CNT);
 731                         tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 732
 733                         vector thedir = e.bd_dir;
 734                         float theang = 0;
 735
 736                         if(thedir_y == -1) { theang = M_PI; }
 737                         if(thedir_x == 1) { theang = M_PI/2; }
 738                         if(thedir_x == -1) { theang = M_PI*3/2; }
 739
 740                         drawrotpic(tile_pos, theang, minigame_texture("bd/dozer"),
 741                                                 tile_size, tile_size/2, '1 1 1',
 742                                                 panel_fg_alpha, DRAWFLAG_NORMAL );
 743                 }
 744         }
 745
 746         if(active_minigame.minigame_flags & BD_TURN_EDIT)
 747         if(bd_valid_tile(bd_curr_pos))
 748         {
 749                 entity piece = bd_find_piece(active_minigame, bd_curr_pos, false);
 750                 entity targ = bd_find_piece(active_minigame, bd_curr_pos, true);
 751                 string thepiece = ((piece || (targ && bd_curr_tile != BD_TILE_BOULDER)) ? "bd/delete" : bd_get_tile_pic(bd_curr_tile));
 752
 753                 tile_pos = minigame_tile_pos(bd_curr_pos,BD_LET_CNT,BD_NUM_CNT);
 754                 tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 755                 if(bd_curr_tile == BD_TILE_DOZER)
 756                 {
 757                         drawrotpic(tile_pos, M_PI, minigame_texture("bd/dozer"),
 758                                                 tile_size, tile_size/2, '1 1 1',
 759                                                 panel_fg_alpha/2, DRAWFLAG_NORMAL );
 760                 }
 761                 else
 762                 {
 763                         minigame_drawpic_centered( tile_pos,
 764                                         minigame_texture(thepiece),
 765                                         tile_size, '1 1 1', panel_fg_alpha/2, DRAWFLAG_NORMAL );
 766                 }
 767         }
 768
 769         if ( (active_minigame.minigame_flags & BD_TURN_LOSS) || (active_minigame.minigame_flags & BD_TURN_WIN) )
 770         {
 771                 vector winfs = hud_fontsize*2;
 772                 string victory_text = "Game over!";
 773
 774                 if(active_minigame.minigame_flags & BD_TURN_WIN)
 775                         victory_text = "You win!";
 776
 777                 vector win_pos = pos+eY*(mySize_y-winfs_y)/2;
 778                 vector win_sz;
 779                 win_sz = minigame_drawcolorcodedstring_wrapped(mySize_x,win_pos,
 780                         sprintf("%s", victory_text),
 781                         winfs, 0, DRAWFLAG_NORMAL, 0.5);
 782
 783                 drawfill(win_pos-eY*hud_fontsize_y,win_sz+2*eY*hud_fontsize_y,'0.3 0.3 1',0.8,DRAWFLAG_ADDITIVE);
 784
 785                 minigame_drawcolorcodedstring_wrapped(mySize_x,win_pos,
 786                         sprintf("%s", victory_text),
 787                         winfs, panel_fg_alpha, DRAWFLAG_NORMAL, 0.5);
 788         }
 789 }
 790
 791
 792 // Required function, draw the game status panel
 793 void bd_hud_status(vector pos, vector mySize)
 794 {
 795         HUD_Panel_DrawBg(1);
 796         vector ts;
 797         ts = minigame_drawstring_wrapped(mySize_x,pos,active_minigame.descriptor.message,
 798                 hud_fontsize * 2, '0.25 0.47 0.72', panel_fg_alpha, DRAWFLAG_NORMAL,0.5);
 799
 800         pos_y += ts_y;
 801         mySize_y -= ts_y;
 802
 803         vector player_fontsize = hud_fontsize * 1.75;
 804         ts_y = ( mySize_y - 2*player_fontsize_y ) / BD_TEAMS;
 805         ts_x = mySize_x;
 806         vector mypos;
 807         vector tile_size = '48 48 0';
 808
 809         mypos = pos;
 810         drawfill(mypos,eX*mySize_x+eY*player_fontsize_y,'1 1 1',0.5,DRAWFLAG_ADDITIVE);
 811         mypos_y += player_fontsize_y;
 812         drawfill(mypos,eX*mySize_x+eY*tile_size_y,'1 1 1',0.25,DRAWFLAG_ADDITIVE);
 813
 814         entity e;
 815         FOREACH_MINIGAME_ENTITY(e)
 816         {
 817                 if ( e.classname == "minigame_player" )
 818                 {
 819                         mypos = pos;
 820                         minigame_drawcolorcodedstring_trunc(mySize_x,mypos,
 821                                 GetPlayerName(e.minigame_playerslot-1),
 822                                 player_fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
 823
 824                         mypos_y += player_fontsize_y;
 825                         string thepiece = "bd/dozer";
 826                         if(active_minigame.minigame_flags & BD_TURN_EDIT)
 827                                 thepiece = bd_get_tile_pic(bd_curr_tile);
 828                         drawpic( mypos,
 829                                         minigame_texture(thepiece),
 830                                         tile_size * 0.7, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL );
 831
 832                         mypos_x += tile_size_x;
 833
 834                         drawstring(mypos,ftos(e.bd_moves),tile_size,
 835                                            '0.7 0.84 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 836                 }
 837         }
 838 }
 839
 840 // Turn a set of flags into a help message
 841 string bd_turn_to_string(int turnflags)
 842 {
 843         if ( turnflags & BD_TURN_LOSS )
 844                 return _("Better luck next time!");
 845
 846         if ( turnflags & BD_TURN_WIN )
 847                 if(random() > 0.5)
 848                         return _("Tubular! Press ""Next Level"" to continue!");
 849                 else
 850                         return _("Wicked! Press ""Next Level"" to continue!");
 851
 852         if( turnflags & BD_TURN_EDIT )
 853                 return _("Press the space bar to change your currently selected tile");
 854
 855         if ( turnflags & BD_TURN_MOVE )
 856                 return _("Push the boulders onto the targets");
 857
 858         return "";
 859 }
 860
 861 // Make the correct move
 862 void bd_make_move(entity minigame, string dir)
 863 {
 864         if ( minigame.minigame_flags == BD_TURN_MOVE )
 865         {
 866                 minigame_cmd("move ", dir);
 867         }
 868 }
 869
 870 void bd_editor_make_move(entity minigame, string dir)
 871 {
 872         if ( minigame.minigame_flags == BD_TURN_EDIT )
 873         {
 874                 minigame_cmd("move ", bd_curr_pos, " ", ftos(bd_curr_tile), " ", dir);
 875         }
 876 }
 877
 878 void bd_editor_fill(entity minigame)
 879 {
 880         if ( minigame.minigame_flags == BD_TURN_EDIT )
 881         {
 882                 minigame_cmd("fill ", bd_curr_pos, " ", ftos(bd_curr_tile));
 883         }
 884 }
 885
 886 void bd_set_curr_pos(string s)
 887 {
 888         if ( bd_curr_pos )
 889                 strunzone(bd_curr_pos);
 890         if ( s )
 891                 s = strzone(s);
 892         bd_curr_pos = s;
 893 }
 894
 895 bool bd_normal_move(entity minigame, int themove)
 896 {
 897         switch ( themove )
 898         {
 899                 case K_RIGHTARROW:
 900                 case K_KP_RIGHTARROW:
 901                         bd_make_move(minigame, "r");
 902                         return true;
 903                 case K_LEFTARROW:
 904                 case K_KP_LEFTARROW:
 905                         bd_make_move(minigame, "l");
 906                         return true;
 907                 case K_UPARROW:
 908                 case K_KP_UPARROW:
 909                         bd_make_move(minigame, "u");
 910                         return true;
 911                 case K_DOWNARROW:
 912                 case K_KP_DOWNARROW:
 913                         bd_make_move(minigame, "d");
 914                         return true;
 915         }
 916
 917         return false;
 918 }
 919
 920 bool bd_change_dozer_angle(entity minigame)
 921 {
 922         entity dozer = bd_find_piece(minigame, bd_curr_pos, false);
 923         if(!dozer || dozer.bd_tiletype != BD_TILE_DOZER)
 924                 return false;
 925
 926         string thedir = "";
 927         vector dir = dozer.bd_dir;
 928         if(dir.x == 0 && dir.y == 0) { thedir = "r"; }
 929
 930         if(dir.x == 0 && dir.y == 1) { thedir = "r"; }
 931         if(dir.x == 0 && dir.y ==-1) { thedir = "l"; }
 932         if(dir.x ==-1 && dir.y == 0) { thedir = "u"; }
 933         if(dir.x == 1 && dir.y == 0) { thedir = "d"; }
 934
 935         bd_editor_make_move(minigame, thedir);
 936         return true;
 937 }
 938
 939 bool bd_editor_move(entity minigame, int themove)
 940 {
 941         switch ( themove )
 942         {
 943                 case K_RIGHTARROW:
 944                 case K_KP_RIGHTARROW:
 945                         if ( ! bd_curr_pos )
 946                                 bd_set_curr_pos("a3");
 947                         else
 948                                 bd_set_curr_pos(minigame_relative_tile(bd_curr_pos,1,0,BD_NUM_CNT,BD_LET_CNT));
 949                         return true;
 950                 case K_LEFTARROW:
 951                 case K_KP_LEFTARROW:
 952                         if ( ! bd_curr_pos )
 953                                 bd_set_curr_pos("c3");
 954                         else
 955                                 bd_set_curr_pos(minigame_relative_tile(bd_curr_pos,-1,0,BD_NUM_CNT,BD_LET_CNT));
 956                         return true;
 957                 case K_UPARROW:
 958                 case K_KP_UPARROW:
 959                         if ( ! bd_curr_pos )
 960                                 bd_set_curr_pos("a1");
 961                         else
 962                                 bd_set_curr_pos(minigame_relative_tile(bd_curr_pos,0,1,BD_NUM_CNT,BD_LET_CNT));
 963                         return true;
 964                 case K_DOWNARROW:
 965                 case K_KP_DOWNARROW:
 966                         if ( ! bd_curr_pos )
 967                                 bd_set_curr_pos("a3");
 968                         else
 969                                 bd_set_curr_pos(minigame_relative_tile(bd_curr_pos,0,-1,BD_NUM_CNT,BD_LET_CNT));
 970                         return true;
 971                 case K_ENTER:
 972                 case K_KP_ENTER:
 973                         bd_editor_make_move(minigame, "");
 974                         return true;
 975                 case K_SPACE:
 976                         if(bd_change_dozer_angle(minigame))
 977                                 return true;
 978                         bd_curr_tile += 1;
 979                         if(bd_curr_tile > BD_TILE_LAST)
 980                                 bd_curr_tile = 1;
 981                         return true;
 982         }
 983
 984         return false;
 985 }
 986
 987 // Required function, handle client events
 988 int bd_client_event(entity minigame, string event, ...)
 989 {
 990         switch(event)
 991         {
 992                 case "activate":
 993                 {
 994                         minigame.message = bd_turn_to_string(minigame.minigame_flags);
 995                         bd_set_curr_pos("");
 996                         bd_curr_tile = BD_TILE_BRICK1;
 997                         return false;
 998                 }
 999                 case "key_pressed":
1000                 {
1001                         if(minigame.minigame_flags & BD_TURN_MOVE)
1002                         {
1003                                 if(bd_normal_move(minigame, ...(0,int)))
1004                                         return true;
1005                         }
1006
1007                         if(minigame.minigame_flags & BD_TURN_EDIT)
1008                         {
1009                                 if(bd_editor_move(minigame, ...(0,int)))
1010                                         return true;
1011                         }
1012
1013                         return false;
1014                 }
1015                 case "mouse_pressed":
1016                 {
1017                         if(minigame.minigame_flags & BD_TURN_EDIT)
1018                         {
1019                                 if(...(0,int) == K_MOUSE1)
1020                                 {
1021                                         bd_editor_make_move(minigame, "");
1022                                         return true;
1023                                 }
1024
1025                                 if(...(0,int) == K_MOUSE2)
1026                                 {
1027                                         bd_editor_fill(minigame);
1028                                         return true;
1029                                 }
1030                         }
1031
1032                         return false;
1033                 }
1034                 case "mouse_moved":
1035                 {
1036                         if(minigame.minigame_flags & BD_TURN_EDIT)
1037                         {
1038                                 vector mouse_pos = minigame_hud_normalize(mousepos,bd_boardpos,bd_boardsize);
1039                                 bd_set_curr_pos(minigame_tile_name(mouse_pos,BD_LET_CNT,BD_NUM_CNT));
1040                                 if ( ! bd_valid_tile(bd_curr_pos) )
1041                                         bd_set_curr_pos("");
1042                         }
1043                         return true;
1044                 }
1045                 case "network_receive":
1046                 {
1047                         entity sent = ...(0,entity);
1048                         int sf = ...(1,int);
1049                         if ( sent.classname == "minigame" )
1050                         {
1051                                 if ( sf & MINIG_SF_UPDATE )
1052                                 {
1053                                         sent.message = bd_turn_to_string(sent.minigame_flags);
1054                                         //if ( sent.minigame_flags & minigame_self.team )
1055                                                 minigame_prompt();
1056                                 }
1057                         }
1058                         else if(sent.classname == "minigame_board_piece")
1059                         {
1060                                 if(sf & MINIG_SF_UPDATE)
1061                                 {
1062                                         int letter = ReadByte();
1063                                         int number = ReadByte();
1064                                         if(sent.netname) { strunzone(sent.netname); }
1065                                         sent.netname = strzone(minigame_tile_buildname(letter, number));
1066
1067                                         sent.bd_tiletype = ReadByte();
1068
1069                                         int dx = ReadByte();
1070                                         int dy = ReadByte();
1071
1072                                         if(dx == 2) dx = -1;
1073                                         if(dy == 2) dy = -1;
1074
1075                                         sent.bd_dir_x = dx;
1076                                         sent.bd_dir_y = dy;
1077                                         sent.bd_dir_z = 0;
1078                                 }
1079                         }
1080                         else if(sent.classname == "minigame_player" && (sf & BD_SF_PLAYERMOVES))
1081                                 sent.bd_moves = ReadShort(); // make this a byte when possible
1082
1083                         return false;
1084                 }
1085                 case "menu_show":
1086                 {
1087                         HUD_MinigameMenu_CustomEntry(...(0,entity),_("Next Level"),"next");
1088                         HUD_MinigameMenu_CustomEntry(...(0,entity),_("Restart"),"restart");
1089                         HUD_MinigameMenu_CustomEntry(...(0,entity),_("Editor"),"edit");
1090                         HUD_MinigameMenu_CustomEntry(...(0,entity),_("Save"),"save");
1091                         return false;
1092                 }
1093                 case "menu_click":
1094                 {
1095                         if(...(0,string) == "next")
1096                                 minigame_cmd("next");
1097                         if(...(0,string) == "restart")
1098                                 minigame_cmd("restart");
1099                         if(...(0,string) == "edit")
1100                                 minigame_cmd("edit");
1101                         if(...(0,string) == "save")
1102                                 minigame_cmd("save");
1103                         return false;
1104                 }
1105         }
1106
1107         return false;
1108 }
1109
1110 #endif