qcsrc/common/gamemodes/gamemode/onslaught/sv_onslaught.qc

   1 #include "sv_onslaught.qh"
   2 #include "sv_controlpoint.qh"
   3 #include "sv_generator.qh"
   4
   5 bool g_onslaught;
   6
   7 float autocvar_g_onslaught_teleport_wait;
   8 bool autocvar_g_onslaught_spawn_at_controlpoints;
   9 bool autocvar_g_onslaught_spawn_at_generator;
  10 float autocvar_g_onslaught_cp_proxydecap;
  11 float autocvar_g_onslaught_cp_proxydecap_distance = 512;
  12 float autocvar_g_onslaught_cp_proxydecap_dps = 100;
  13 float autocvar_g_onslaught_spawn_at_controlpoints_chance = 0.5;
  14 float autocvar_g_onslaught_spawn_at_controlpoints_random;
  15 float autocvar_g_onslaught_spawn_at_generator_chance;
  16 float autocvar_g_onslaught_spawn_at_generator_random;
  17 float autocvar_g_onslaught_cp_buildhealth;
  18 float autocvar_g_onslaught_cp_buildtime;
  19 float autocvar_g_onslaught_cp_health;
  20 float autocvar_g_onslaught_cp_regen;
  21 float autocvar_g_onslaught_gen_health;
  22 float autocvar_g_onslaught_shield_force = 100;
  23 float autocvar_g_onslaught_allow_vehicle_touch;
  24 float autocvar_g_onslaught_round_timelimit;
  25 float autocvar_g_onslaught_warmup;
  26 float autocvar_g_onslaught_teleport_radius;
  27 float autocvar_g_onslaught_spawn_choose;
  28 float autocvar_g_onslaught_click_radius;
  29
  30 void FixSize(entity e);
  31 entity cam;
  32
  33 // =======================
  34 // CaptureShield Functions
  35 // =======================
  36
  37 bool clientcamera_send(entity this, entity to, int sf)
  38 {
  39         WriteHeader(MSG_ENTITY, ENT_ONSCAMERA);
  40
  41         WriteVector(MSG_ENTITY, this.origin);
  42
  43         WriteAngle(MSG_ENTITY, this.angles_x);
  44         WriteAngle(MSG_ENTITY, this.angles_y);
  45         WriteAngle(MSG_ENTITY, this.angles_z);
  46
  47         return true;
  48 }
  49
  50 bool ons_CaptureShield_Customize(entity this, entity client)
  51 {
  52         entity e = WaypointSprite_getviewentity(client);
  53
  54         if(!this.enemy.isshielded && (ons_ControlPoint_Attackable(this.enemy, e.team) > 0 || this.enemy.classname != "onslaught_controlpoint")) { return false; }
  55         if(SAME_TEAM(this, e)) { return false; }
  56
  57         return true;
  58 }
  59
  60 void ons_CaptureShield_Touch(entity this, entity toucher)
  61 {
  62         if(!this.enemy.isshielded && (ons_ControlPoint_Attackable(this.enemy, toucher.team) > 0 || this.enemy.classname != "onslaught_controlpoint")) { return; }
  63         if(!IS_PLAYER(toucher)) { return; }
  64         if(SAME_TEAM(toucher, this)) { return; }
  65
  66         vector mymid = (this.absmin + this.absmax) * 0.5;
  67         vector theirmid = (toucher.absmin + toucher.absmax) * 0.5;
  68
  69         Damage(toucher, this, this, 0, DEATH_HURTTRIGGER.m_id, DMG_NOWEP, mymid, normalize(theirmid - mymid) * ons_captureshield_force);
  70
  71         if(IS_REAL_CLIENT(toucher))
  72         {
  73                 play2(toucher, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
  74
  75                 if(this.enemy.classname == "onslaught_generator")
  76                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_GENERATOR_SHIELDED);
  77                 else
  78                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_CONTROLPOINT_SHIELDED);
  79         }
  80 }
  81
  82 void ons_CaptureShield_Reset(entity this)
  83 {
  84         this.colormap = this.enemy.colormap;
  85         this.team = this.enemy.team;
  86 }
  87
  88 void ons_CaptureShield_Spawn(entity generator, bool is_generator)
  89 {
  90         entity shield = new(ons_captureshield);
  91         IL_PUSH(g_onsshields, shield);
  92
  93         shield.enemy = generator;
  94         shield.team = generator.team;
  95         shield.colormap = generator.colormap;
  96         shield.reset = ons_CaptureShield_Reset;
  97         settouch(shield, ons_CaptureShield_Touch);
  98         setcefc(shield, ons_CaptureShield_Customize);
  99         shield.effects = EF_ADDITIVE;
 100         set_movetype(shield, MOVETYPE_NOCLIP);
 101         shield.solid = SOLID_TRIGGER;
 102         shield.avelocity = '7 0 11';
 103         shield.scale = 1;
 104         shield.model = ((is_generator) ? "models/onslaught/generator_shield.md3" : "models/onslaught/controlpoint_shield.md3");
 105
 106         precache_model(shield.model);
 107         setorigin(shield, generator.origin);
 108         _setmodel(shield, shield.model);
 109         setsize(shield, shield.scale * shield.mins, shield.scale * shield.maxs);
 110 }
 111
 112
 113 // ==========
 114 // Junk Pile
 115 // ==========
 116
 117 void setmodel_fixsize(entity e, Model m)
 118 {
 119         setmodel(e, m);
 120         FixSize(e);
 121 }
 122
 123 void onslaught_updatelinks()
 124 {
 125         entity l;
 126         // first check if the game has ended
 127         LOG_DEBUG("--- updatelinks ---");
 128         // mark generators as being shielded and networked
 129         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
 130         {
 131                 if (l.iscaptured)
 132                         LOG_DEBUG(etos(l), " (generator) belongs to team ", ftos(l.team));
 133                 else
 134                         LOG_DEBUG(etos(l), " (generator) is destroyed");
 135                 l.islinked = l.iscaptured;
 136                 l.isshielded = l.iscaptured;
 137                 l.sprite.SendFlags |= 16;
 138         }
 139         // mark points as shielded and not networked
 140         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
 141         {
 142                 l.islinked = false;
 143                 l.isshielded = true;
 144                 l.aregensneighbor = 0;
 145                 l.arecpsneighbor = 0;
 146                 LOG_DEBUG(etos(l), " (point) belongs to team ", ftos(l.team));
 147                 l.sprite.SendFlags |= 16;
 148         }
 149         // flow power outward from the generators through the network
 150         bool stop = false;
 151         while (!stop)
 152         {
 153                 stop = true;
 154                 for(l = ons_worldlinklist; l; l = l.ons_worldlinknext)
 155                 {
 156                         // if both points are captured by the same team, and only one of
 157                         // them is powered, mark the other one as powered as well
 158                         if (l.enemy.iscaptured && l.goalentity.iscaptured)
 159                                 if (l.enemy.islinked != l.goalentity.islinked)
 160                                         if(SAME_TEAM(l.enemy, l.goalentity))
 161                                         {
 162                                                 if (!l.goalentity.islinked)
 163                                                 {
 164                                                         stop = false;
 165                                                         l.goalentity.islinked = true;
 166                                                         LOG_DEBUG(etos(l), " (link) is marking ", etos(l.goalentity), " (point) because its team matches ", etos(l.enemy), " (point)");
 167                                                 }
 168                                                 else if (!l.enemy.islinked)
 169                                                 {
 170                                                         stop = false;
 171                                                         l.enemy.islinked = true;
 172                                                         LOG_DEBUG(etos(l), " (link) is marking ", etos(l.enemy), " (point) because its team matches ", etos(l.goalentity), " (point)");
 173                                                 }
 174                                         }
 175                 }
 176         }
 177         // now that we know which points are powered we can mark their neighbors
 178         // as unshielded if team differs
 179         for(l = ons_worldlinklist; l; l = l.ons_worldlinknext)
 180         {
 181                 if (l.goalentity.islinked)
 182                 {
 183                         if(DIFF_TEAM(l.goalentity, l.enemy))
 184                         {
 185                                 LOG_DEBUG(etos(l), " (link) is unshielding ", etos(l.enemy), " (point) because its team does not match ", etos(l.goalentity), " (point)");
 186                                 l.enemy.isshielded = false;
 187                         }
 188                         if(l.goalentity.classname == "onslaught_generator")
 189                                 l.enemy.aregensneighbor |= BIT(l.goalentity.team);
 190                         else
 191                                 l.enemy.arecpsneighbor |= BIT(l.goalentity.team);
 192                 }
 193                 if (l.enemy.islinked)
 194                 {
 195                         if(DIFF_TEAM(l.goalentity, l.enemy))
 196                         {
 197                                 LOG_DEBUG(etos(l), " (link) is unshielding ", etos(l.goalentity), " (point) because its team does not match ", etos(l.enemy), " (point)");
 198                                 l.goalentity.isshielded = false;
 199                         }
 200                         if(l.enemy.classname == "onslaught_generator")
 201                                 l.goalentity.aregensneighbor |= BIT(l.enemy.team);
 202                         else
 203                                 l.goalentity.arecpsneighbor |= BIT(l.enemy.team);
 204                 }
 205         }
 206         // now update the generators
 207         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
 208         {
 209                 if (l.isshielded)
 210                 {
 211                         LOG_DEBUG(etos(l), " (generator) is shielded");
 212                         l.takedamage = DAMAGE_NO;
 213                         if(l.bot_attack)
 214                                 IL_REMOVE(g_bot_targets, l);
 215                         l.bot_attack = false;
 216                 }
 217                 else
 218                 {
 219                         LOG_DEBUG(etos(l), " (generator) is not shielded");
 220                         l.takedamage = DAMAGE_AIM;
 221                         if(!l.bot_attack)
 222                                 IL_PUSH(g_bot_targets, l);
 223                         l.bot_attack = true;
 224                 }
 225
 226                 ons_Generator_UpdateSprite(l);
 227         }
 228         // now update the takedamage and alpha variables on control point icons
 229         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
 230         {
 231                 if (l.isshielded)
 232                 {
 233                         LOG_DEBUG(etos(l), " (point) is shielded");
 234                         if (l.goalentity)
 235                         {
 236                                 l.goalentity.takedamage = DAMAGE_NO;
 237                                 if(l.goalentity.bot_attack)
 238                                         IL_REMOVE(g_bot_targets, l.goalentity);
 239                                 l.goalentity.bot_attack = false;
 240                         }
 241                 }
 242                 else
 243                 {
 244                         LOG_DEBUG(etos(l), " (point) is not shielded");
 245                         if (l.goalentity)
 246                         {
 247                                 l.goalentity.takedamage = DAMAGE_AIM;
 248                                 if(!l.goalentity.bot_attack)
 249                                         IL_PUSH(g_bot_targets, l.goalentity);
 250                                 l.goalentity.bot_attack = true;
 251                         }
 252                 }
 253                 ons_ControlPoint_UpdateSprite(l);
 254         }
 255         IL_EACH(g_onsshields, true,
 256         {
 257                 it.team = it.enemy.team;
 258                 it.colormap = it.enemy.colormap;
 259         });
 260 }
 261
 262
 263 // ===================
 264 // Main Link Functions
 265 // ===================
 266
 267 bool ons_Link_Send(entity this, entity to, int sendflags)
 268 {
 269         WriteHeader(MSG_ENTITY, ENT_CLIENT_RADARLINK);
 270         WriteByte(MSG_ENTITY, sendflags);
 271         if(sendflags & 1)
 272         {
 273                 WriteVector(MSG_ENTITY, this.goalentity.origin);
 274         }
 275         if(sendflags & 2)
 276         {
 277                 WriteVector(MSG_ENTITY, this.enemy.origin);
 278         }
 279         if(sendflags & 4)
 280         {
 281                 WriteByte(MSG_ENTITY, this.clientcolors); // which is goalentity's color + enemy's color * 16
 282         }
 283         return true;
 284 }
 285
 286 void ons_Link_CheckUpdate(entity this)
 287 {
 288         // TODO check if the two sides have moved (currently they won't move anyway)
 289         float cc = 0, cc1 = 0, cc2 = 0;
 290
 291         if(this.goalentity.islinked || this.goalentity.iscaptured) { cc1 = (this.goalentity.team - 1) * 0x01; }
 292         if(this.enemy.islinked || this.enemy.iscaptured) { cc2 = (this.enemy.team - 1) * 0x10; }
 293
 294         cc = cc1 + cc2;
 295
 296         if(cc != this.clientcolors)
 297         {
 298                 this.clientcolors = cc;
 299                 this.SendFlags |= 4;
 300         }
 301
 302         this.nextthink = time;
 303 }
 304
 305 void ons_DelayedLinkSetup(entity this)
 306 {
 307         this.goalentity = find(NULL, targetname, this.target);
 308         this.enemy = find(NULL, targetname, this.target2);
 309         if(!this.goalentity) { objerror(this, "can not find target\n"); }
 310         if(!this.enemy) { objerror(this, "can not find target2\n"); }
 311
 312         LOG_DEBUG(etos(this.goalentity), " linked with ", etos(this.enemy));
 313         this.SendFlags |= 3;
 314         setthink(this, ons_Link_CheckUpdate);
 315         this.nextthink = time;
 316 }
 317
 318
 319 // =============================
 320 // Main Control Point Functions
 321 // =============================
 322
 323 int ons_ControlPoint_CanBeLinked(entity cp, int teamnumber)
 324 {
 325         if(cp.aregensneighbor & BIT(teamnumber)) return 2;
 326         if(cp.arecpsneighbor & BIT(teamnumber)) return 1;
 327
 328         return 0;
 329 }
 330
 331 int ons_ControlPoint_Attackable(entity cp, int teamnumber)
 332         // -2: SAME TEAM, attackable by enemy!
 333         // -1: SAME TEAM!
 334         // 0: off limits
 335         // 1: attack it
 336         // 2: touch it
 337         // 3: attack it (HIGH PRIO)
 338         // 4: touch it (HIGH PRIO)
 339 {
 340         int a;
 341
 342         if(cp.isshielded)
 343         {
 344                 return 0;
 345         }
 346         else if(cp.goalentity)
 347         {
 348                 // if there's already an icon built, nothing happens
 349                 if(cp.team == teamnumber)
 350                 {
 351                         a = ons_ControlPoint_CanBeLinked(cp, teamnumber);
 352                         if(a) // attackable by enemy?
 353                                 return -2; // EMERGENCY!
 354                         return -1;
 355                 }
 356                 // we know it can be linked, so no need to check
 357                 // but...
 358                 a = ons_ControlPoint_CanBeLinked(cp, teamnumber);
 359                 if(a == 2) // near our generator?
 360                         return 3; // EMERGENCY!
 361                 return 1;
 362         }
 363         else
 364         {
 365                 // free point
 366                 if(ons_ControlPoint_CanBeLinked(cp, teamnumber))
 367                 {
 368                         a = ons_ControlPoint_CanBeLinked(cp, teamnumber); // why was this here NUM_TEAM_1 + NUM_TEAM_2 - t
 369                         if(a == 2)
 370                                 return 4; // GET THIS ONE NOW!
 371                         else
 372                                 return 2; // TOUCH ME
 373                 }
 374         }
 375         return 0;
 376 }
 377
 378 void ons_ControlPoint_Icon_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 379 {
 380         if(damage <= 0) { return; }
 381
 382         if (this.owner.isshielded)
 383         {
 384                 // this is protected by a shield, so ignore the damage
 385                 if (time > this.pain_finished)
 386                         if (IS_PLAYER(attacker))
 387                         {
 388                                 play2(attacker, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
 389                                 this.pain_finished = time + 1;
 390                                 attacker.typehitsound += 1; // play both sounds (shield is way too quiet)
 391                         }
 392
 393                 return;
 394         }
 395
 396         if(IS_PLAYER(attacker))
 397         if(time - ons_notification_time[this.team] > 10)
 398         {
 399                 play2team(this.team, SND(ONS_CONTROLPOINT_UNDERATTACK));
 400                 ons_notification_time[this.team] = time;
 401         }
 402
 403         TakeResource(this, RESOURCE_HEALTH, damage);
 404         if(this.owner.iscaptured)
 405                 WaypointSprite_UpdateHealth(this.owner.sprite, GetResourceAmount(this, RESOURCE_HEALTH));
 406         else
 407                 WaypointSprite_UpdateBuildFinished(this.owner.sprite, time + (this.max_health - GetResourceAmount(this, RESOURCE_HEALTH)) / (this.count / ONS_CP_THINKRATE));
 408         this.pain_finished = time + 1;
 409         // particles on every hit
 410         pointparticles(EFFECT_SPARKS, hitloc, force*-1, 1);
 411         //sound on every hit
 412         if (random() < 0.5)
 413                 sound(this, CH_TRIGGER, SND_ONS_HIT1, VOL_BASE+0.3, ATTEN_NORM);
 414         else
 415                 sound(this, CH_TRIGGER, SND_ONS_HIT2, VOL_BASE+0.3, ATTEN_NORM);
 416
 417         if (GetResourceAmount(this, RESOURCE_HEALTH) < 0)
 418         {
 419                 sound(this, CH_TRIGGER, SND_GRENADE_IMPACT, VOL_BASE, ATTEN_NORM);
 420                 pointparticles(EFFECT_ROCKET_EXPLODE, this.origin, '0 0 0', 1);
 421                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_CPDESTROYED), this.owner.message, attacker.netname);
 422
 423                 GameRules_scoring_add(attacker, ONS_TAKES, 1);
 424                 GameRules_scoring_add(attacker, SCORE, 10);
 425
 426                 this.owner.goalentity = NULL;
 427                 this.owner.islinked = false;
 428                 this.owner.iscaptured = false;
 429                 this.owner.team = 0;
 430                 this.owner.colormap = 1024;
 431
 432                 WaypointSprite_UpdateMaxHealth(this.owner.sprite, 0);
 433
 434                 onslaught_updatelinks();
 435
 436                 // Use targets now (somebody make sure this is in the right place..)
 437                 SUB_UseTargets(this.owner, this, NULL);
 438
 439                 this.owner.waslinked = this.owner.islinked;
 440                 if(this.owner.model != "models/onslaught/controlpoint_pad.md3")
 441                         setmodel_fixsize(this.owner, MDL_ONS_CP_PAD1);
 442                 //setsize(this, '-32 -32 0', '32 32 8');
 443
 444                 delete(this);
 445         }
 446
 447         this.SendFlags |= CPSF_STATUS;
 448 }
 449
 450 bool ons_ControlPoint_Icon_Heal(entity targ, entity inflictor, float amount, float limit)
 451 {
 452         float hlth = GetResourceAmount(targ, RESOURCE_HEALTH);
 453         float true_limit = ((limit != RESOURCE_LIMIT_NONE) ? limit : targ.max_health);
 454         if (hlth <= 0 || hlth >= true_limit)
 455                 return false;
 456
 457         GiveResourceWithLimit(targ, RESOURCE_HEALTH, amount, true_limit);
 458         hlth = GetResourceAmount(targ, RESOURCE_HEALTH);
 459         if(targ.owner.iscaptured)
 460                 WaypointSprite_UpdateHealth(targ.owner.sprite, hlth);
 461         else
 462                 WaypointSprite_UpdateBuildFinished(targ.owner.sprite, time + (targ.max_health - hlth) / (targ.count / ONS_CP_THINKRATE));
 463         targ.SendFlags |= CPSF_STATUS;
 464         return true;
 465 }
 466
 467 void ons_ControlPoint_Icon_Think(entity this)
 468 {
 469         this.nextthink = time + ONS_CP_THINKRATE;
 470
 471         if(autocvar_g_onslaught_cp_proxydecap)
 472         {
 473                 int _enemy_count = 0;
 474                 int _friendly_count = 0;
 475
 476                 FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), {
 477                         if(vdist(it.origin - this.origin, <, autocvar_g_onslaught_cp_proxydecap_distance))
 478                         {
 479                                 if(SAME_TEAM(it, this))
 480                                         ++_friendly_count;
 481                                 else
 482                                         ++_enemy_count;
 483                         }
 484                 });
 485
 486                 _friendly_count = _friendly_count * (autocvar_g_onslaught_cp_proxydecap_dps * ONS_CP_THINKRATE);
 487                 _enemy_count = _enemy_count * (autocvar_g_onslaught_cp_proxydecap_dps * ONS_CP_THINKRATE);
 488
 489                 GiveResourceWithLimit(this, RESOURCE_HEALTH, (_friendly_count - _enemy_count), this.max_health);
 490                 this.SendFlags |= CPSF_STATUS;
 491                 if(GetResourceAmount(this, RESOURCE_HEALTH) <= 0)
 492                 {
 493                         ons_ControlPoint_Icon_Damage(this, this, this, 1, 0, DMG_NOWEP, this.origin, '0 0 0');
 494                         return;
 495                 }
 496         }
 497
 498         if (time > this.pain_finished + 5)
 499         {
 500                 if(GetResourceAmount(this, RESOURCE_HEALTH) < this.max_health)
 501                 {
 502                         GiveResourceWithLimit(this, RESOURCE_HEALTH, this.count, this.max_health);
 503                         WaypointSprite_UpdateHealth(this.owner.sprite, GetResourceAmount(this, RESOURCE_HEALTH));
 504                 }
 505         }
 506
 507         if(this.owner.islinked != this.owner.waslinked)
 508         {
 509                 // unteam the spawnpoint if needed
 510                 int t = this.owner.team;
 511                 if(!this.owner.islinked)
 512                         this.owner.team = 0;
 513
 514                 SUB_UseTargets(this.owner, this, NULL);
 515
 516                 this.owner.team = t;
 517
 518                 this.owner.waslinked = this.owner.islinked;
 519         }
 520
 521         // damaged fx
 522         if(random() < 0.6 - GetResourceAmount(this, RESOURCE_HEALTH) / this.max_health)
 523         {
 524                 Send_Effect(EFFECT_ELECTRIC_SPARKS, this.origin + randompos('-10 -10 -20', '10 10 20'), '0 0 0', 1);
 525
 526                 if(random() > 0.8)
 527                         sound(this, CH_PAIN, SND_ONS_SPARK1, VOL_BASE, ATTEN_NORM);
 528                 else if (random() > 0.5)
 529                         sound(this, CH_PAIN, SND_ONS_SPARK2, VOL_BASE, ATTEN_NORM);
 530         }
 531 }
 532
 533 void ons_ControlPoint_Icon_BuildThink(entity this)
 534 {
 535         int a;
 536
 537         this.nextthink = time + ONS_CP_THINKRATE;
 538
 539         // only do this if there is power
 540         a = ons_ControlPoint_CanBeLinked(this.owner, this.owner.team);
 541         if(!a)
 542                 return;
 543
 544         GiveResource(this, RESOURCE_HEALTH, this.count);
 545
 546         this.SendFlags |= CPSF_STATUS;
 547
 548         if (GetResourceAmount(this, RESOURCE_HEALTH) >= this.max_health)
 549         {
 550                 SetResourceAmountExplicit(this, RESOURCE_HEALTH, this.max_health);
 551                 this.count = autocvar_g_onslaught_cp_regen * ONS_CP_THINKRATE; // slow repair rate from now on
 552                 setthink(this, ons_ControlPoint_Icon_Think);
 553                 sound(this, CH_TRIGGER, SND_ONS_CONTROLPOINT_BUILT, VOL_BASE, ATTEN_NORM);
 554                 this.owner.iscaptured = true;
 555                 this.solid = SOLID_BBOX;
 556
 557                 Send_Effect(EFFECT_CAP(this.owner.team), this.owner.origin, '0 0 0', 1);
 558
 559                 WaypointSprite_UpdateMaxHealth(this.owner.sprite, this.max_health);
 560                 WaypointSprite_UpdateHealth(this.owner.sprite, GetResourceAmount(this, RESOURCE_HEALTH));
 561
 562                 if(IS_PLAYER(this.owner.ons_toucher))
 563                 {
 564                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ONSLAUGHT_CAPTURE, this.owner.ons_toucher.netname, this.owner.message);
 565                         Send_Notification(NOTIF_ALL_EXCEPT, this.owner.ons_toucher, MSG_CENTER, APP_TEAM_NUM(this.owner.ons_toucher.team, CENTER_ONS_CAPTURE_TEAM), this.owner.message);
 566                         Send_Notification(NOTIF_ONE, this.owner.ons_toucher, MSG_CENTER, CENTER_ONS_CAPTURE, this.owner.message);
 567                         GameRules_scoring_add(this.owner.ons_toucher, ONS_CAPS, 1);
 568                         GameRules_scoring_add_team(this.owner.ons_toucher, SCORE, 10);
 569                 }
 570
 571                 this.owner.ons_toucher = NULL;
 572
 573                 onslaught_updatelinks();
 574
 575                 // Use targets now (somebody make sure this is in the right place..)
 576                 SUB_UseTargets(this.owner, this, NULL);
 577
 578                 this.SendFlags |= CPSF_SETUP;
 579         }
 580         if(this.owner.model != MDL_ONS_CP_PAD2.model_str())
 581                 setmodel_fixsize(this.owner, MDL_ONS_CP_PAD2);
 582
 583         if(random() < 0.9 - GetResourceAmount(this, RESOURCE_HEALTH) / this.max_health)
 584                 Send_Effect(EFFECT_RAGE, this.origin + 10 * randomvec(), '0 0 -1', 1);
 585 }
 586
 587 void onslaught_controlpoint_icon_link(entity e, void(entity this) spawnproc);
 588
 589 void ons_ControlPoint_Icon_Spawn(entity cp, entity player)
 590 {
 591         entity e = new(onslaught_controlpoint_icon);
 592
 593         setsize(e, CPICON_MIN, CPICON_MAX);
 594         setorigin(e, cp.origin + CPICON_OFFSET);
 595
 596         e.owner = cp;
 597         e.max_health = autocvar_g_onslaught_cp_health;
 598         SetResourceAmountExplicit(e, RESOURCE_HEALTH, autocvar_g_onslaught_cp_buildhealth);
 599         e.solid = SOLID_NOT;
 600         e.takedamage = DAMAGE_AIM;
 601         e.bot_attack = true;
 602         IL_PUSH(g_bot_targets, e);
 603         e.event_damage = ons_ControlPoint_Icon_Damage;
 604         e.event_heal = ons_ControlPoint_Icon_Heal;
 605         e.team = player.team;
 606         e.colormap = 1024 + (e.team - 1) * 17;
 607         e.count = (e.max_health - GetResourceAmount(e, RESOURCE_HEALTH)) * ONS_CP_THINKRATE / autocvar_g_onslaught_cp_buildtime; // how long it takes to build
 608
 609         sound(e, CH_TRIGGER, SND_ONS_CONTROLPOINT_BUILD, VOL_BASE, ATTEN_NORM);
 610
 611         cp.goalentity = e;
 612         cp.team = e.team;
 613         cp.colormap = e.colormap;
 614
 615         Send_Effect(EFFECT_FLAG_TOUCH(player.team), e.origin, '0 0 0', 1);
 616
 617         WaypointSprite_UpdateBuildFinished(cp.sprite, time + (e.max_health - GetResourceAmount(e, RESOURCE_HEALTH)) / (e.count / ONS_CP_THINKRATE));
 618         WaypointSprite_UpdateRule(cp.sprite,cp.team,SPRITERULE_TEAMPLAY);
 619         cp.sprite.SendFlags |= 16;
 620
 621         onslaught_controlpoint_icon_link(e, ons_ControlPoint_Icon_BuildThink);
 622 }
 623
 624 entity ons_ControlPoint_Waypoint(entity e)
 625 {
 626         if(e.team)
 627         {
 628                 int a = ons_ControlPoint_Attackable(e, e.team);
 629
 630                 if(a == -2) { return WP_OnsCPDefend; } // defend now
 631                 if(a == -1 || a == 1 || a == 2) { return WP_OnsCP; } // touch
 632                 if(a == 3 || a == 4) { return WP_OnsCPAttack; } // attack
 633         }
 634         else
 635                 return WP_OnsCP;
 636
 637         return WP_Null;
 638 }
 639
 640 void ons_ControlPoint_UpdateSprite(entity e)
 641 {
 642         entity s1 = ons_ControlPoint_Waypoint(e);
 643         WaypointSprite_UpdateSprites(e.sprite, s1, s1, s1);
 644
 645         bool sh;
 646         sh = !(ons_ControlPoint_CanBeLinked(e, NUM_TEAM_1) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_2) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_3) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_4));
 647
 648         if(e.lastteam != e.team + 2 || e.lastshielded != sh || e.iscaptured != e.lastcaptured)
 649         {
 650                 if(e.iscaptured) // don't mess up build bars!
 651                 {
 652                         if(sh)
 653                         {
 654                                 WaypointSprite_UpdateMaxHealth(e.sprite, 0);
 655                         }
 656                         else
 657                         {
 658                                 WaypointSprite_UpdateMaxHealth(e.sprite, e.goalentity.max_health);
 659                                 WaypointSprite_UpdateHealth(e.sprite, GetResourceAmount(e.goalentity, RESOURCE_HEALTH));
 660                         }
 661                 }
 662                 if(e.lastshielded)
 663                 {
 664                         if(e.team)
 665                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, 0.5 * colormapPaletteColor(e.team - 1, false));
 666                         else
 667                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0.5 0.5 0.5');
 668                 }
 669                 else
 670                 {
 671                         if(e.team)
 672                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, colormapPaletteColor(e.team - 1, false));
 673                         else
 674                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0.75 0.75 0.75');
 675                 }
 676                 WaypointSprite_Ping(e.sprite);
 677
 678                 e.lastteam = e.team + 2;
 679                 e.lastshielded = sh;
 680                 e.lastcaptured = e.iscaptured;
 681         }
 682 }
 683
 684 void ons_ControlPoint_Touch(entity this, entity toucher)
 685 {
 686         int attackable;
 687
 688         if(IS_VEHICLE(toucher) && toucher.owner)
 689         if(autocvar_g_onslaught_allow_vehicle_touch)
 690                 toucher = toucher.owner;
 691         else
 692                 return;
 693
 694         if(!IS_PLAYER(toucher)) { return; }
 695         if(STAT(FROZEN, toucher)) { return; }
 696         if(IS_DEAD(toucher)) { return; }
 697
 698         if ( SAME_TEAM(this,toucher) )
 699         if ( this.iscaptured )
 700         {
 701                 if(time <= toucher.teleport_antispam)
 702                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT_ANTISPAM, rint(toucher.teleport_antispam - time));
 703                 else
 704                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT);
 705         }
 706
 707         attackable = ons_ControlPoint_Attackable(this, toucher.team);
 708         if(attackable != 2 && attackable != 4)
 709                 return;
 710         // we've verified that this player has a legitimate claim to this point,
 711         // so start building the captured point icon (which only captures this
 712         // point if it successfully builds without being destroyed first)
 713         ons_ControlPoint_Icon_Spawn(this, toucher);
 714
 715         this.ons_toucher = toucher;
 716
 717         onslaught_updatelinks();
 718 }
 719
 720 void ons_ControlPoint_Think(entity this)
 721 {
 722         this.nextthink = time + ONS_CP_THINKRATE;
 723         CSQCMODEL_AUTOUPDATE(this);
 724 }
 725
 726 void ons_ControlPoint_Reset(entity this)
 727 {
 728         if(this.goalentity)
 729                 delete(this.goalentity);
 730
 731         this.goalentity = NULL;
 732         this.team = 0;
 733         this.colormap = 1024;
 734         this.iscaptured = false;
 735         this.islinked = false;
 736         this.isshielded = true;
 737         setthink(this, ons_ControlPoint_Think);
 738         this.ons_toucher = NULL;
 739         this.nextthink = time + ONS_CP_THINKRATE;
 740         setmodel_fixsize(this, MDL_ONS_CP_PAD1);
 741
 742         WaypointSprite_UpdateMaxHealth(this.sprite, 0);
 743         WaypointSprite_UpdateRule(this.sprite,this.team,SPRITERULE_TEAMPLAY);
 744
 745         onslaught_updatelinks();
 746
 747         SUB_UseTargets(this, this, NULL); // to reset the structures, playerspawns etc.
 748
 749         CSQCMODEL_AUTOUPDATE(this);
 750 }
 751
 752 void ons_DelayedControlPoint_Setup(entity this)
 753 {
 754         onslaught_updatelinks();
 755
 756         // captureshield setup
 757         ons_CaptureShield_Spawn(this, false);
 758
 759         CSQCMODEL_AUTOINIT(this);
 760 }
 761
 762 void ons_ControlPoint_Setup(entity cp)
 763 {
 764         // main setup
 765         cp.ons_worldcpnext = ons_worldcplist; // link control point into ons_worldcplist
 766         ons_worldcplist = cp;
 767
 768         cp.netname = "Control point";
 769         cp.team = 0;
 770         cp.solid = SOLID_BBOX;
 771         set_movetype(cp, MOVETYPE_NONE);
 772         settouch(cp, ons_ControlPoint_Touch);
 773         setthink(cp, ons_ControlPoint_Think);
 774         cp.nextthink = time + ONS_CP_THINKRATE;
 775         cp.reset = ons_ControlPoint_Reset;
 776         cp.colormap = 1024;
 777         cp.iscaptured = false;
 778         cp.islinked = false;
 779         cp.isshielded = true;
 780
 781         if(cp.message == "") { cp.message = "a"; }
 782
 783         // appearence
 784         setmodel_fixsize(cp, MDL_ONS_CP_PAD1);
 785
 786         // control point placement
 787         if((cp.spawnflags & 1) || cp.noalign) // don't drop to floor, just stay at fixed location
 788         {
 789                 cp.noalign = true;
 790                 set_movetype(cp, MOVETYPE_NONE);
 791         }
 792         else // drop to floor, automatically find a platform and set that as spawn origin
 793         {
 794                 setorigin(cp, cp.origin + '0 0 20');
 795                 cp.noalign = false;
 796                 droptofloor(cp);
 797                 set_movetype(cp, MOVETYPE_TOSS);
 798         }
 799
 800         // waypointsprites
 801         WaypointSprite_SpawnFixed(WP_Null, cp.origin + CPGEN_WAYPOINT_OFFSET, cp, sprite, RADARICON_NONE);
 802         WaypointSprite_UpdateRule(cp.sprite, cp.team, SPRITERULE_TEAMPLAY);
 803
 804         InitializeEntity(cp, ons_DelayedControlPoint_Setup, INITPRIO_SETLOCATION);
 805 }
 806
 807
 808 // =========================
 809 // Main Generator Functions
 810 // =========================
 811
 812 entity ons_Generator_Waypoint(entity e)
 813 {
 814         if (e.isshielded)
 815                 return WP_OnsGenShielded;
 816         return WP_OnsGen;
 817 }
 818
 819 void ons_Generator_UpdateSprite(entity e)
 820 {
 821         entity s1 = ons_Generator_Waypoint(e);
 822         WaypointSprite_UpdateSprites(e.sprite, s1, s1, s1);
 823
 824         if(e.lastteam != e.team + 2 || e.lastshielded != e.isshielded)
 825         {
 826                 e.lastteam = e.team + 2;
 827                 e.lastshielded = e.isshielded;
 828                 if(e.lastshielded)
 829                 {
 830                         if(e.team)
 831                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, 0.5 * colormapPaletteColor(e.team - 1, false));
 832                         else
 833                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0.5 0.5 0.5');
 834                 }
 835                 else
 836                 {
 837                         if(e.team)
 838                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, colormapPaletteColor(e.team - 1, false));
 839                         else
 840                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0.75 0.75 0.75');
 841                 }
 842                 WaypointSprite_Ping(e.sprite);
 843         }
 844 }
 845
 846 void ons_camSetup(entity this)
 847 {
 848         vector dir;
 849         vector ang = '0 0 0';
 850         vector best_ang = '0 0 0';
 851         float best_trace_fraction = 0;
 852         while(ang.y < 360)
 853         {
 854                 dir = vec2(cos(ang.y * DEG2RAD), sin(ang.y * DEG2RAD));
 855                 dir *= 500;
 856                 traceline(this.origin, this.origin - dir, MOVE_WORLDONLY, this);
 857                 if(trace_fraction > best_trace_fraction)
 858                 {
 859                         best_trace_fraction = trace_fraction;
 860                         best_ang = ang;
 861                         if(trace_fraction == 1)
 862                                 break;
 863                 }
 864                 ang.y += 90;
 865                 if(ang.y == 360)
 866                         ang.y = 45;
 867         }
 868         cam.origin = this.origin;
 869         setorigin(cam, cam.origin);
 870         cam.angles = best_ang;
 871         Net_LinkEntity(cam, false, 0, clientcamera_send);
 872
 873         FOREACH_CLIENT(true, it.clientcamera = cam;);
 874
 875         WriteByte(MSG_ALL, SVC_SETVIEWANGLES);
 876         WriteAngle(MSG_ALL, cam.angles_x);
 877         WriteAngle(MSG_ALL, cam.angles_y);
 878         WriteAngle(MSG_ALL, cam.angles_z);
 879 }
 880
 881 void ons_GeneratorDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 882 {
 883         if(damage <= 0) return;
 884         if(warmup_stage || game_stopped) return;
 885         if(!round_handler_IsRoundStarted()) return;
 886
 887         if (attacker != this)
 888         {
 889                 if (this.isshielded)
 890                 {
 891                         // generator is protected by a shield, so ignore the damage
 892                         if (time > this.pain_finished)
 893                                 if (IS_PLAYER(attacker))
 894                                 {
 895                                         play2(attacker, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
 896                                         attacker.typehitsound += 1;
 897                                         this.pain_finished = time + 1;
 898                                 }
 899                         return;
 900                 }
 901                 if (time > this.pain_finished)
 902                 {
 903                         this.pain_finished = time + 10;
 904                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && SAME_TEAM(it, this), Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_GENERATOR_UNDERATTACK));
 905                         play2team(this.team, SND(ONS_GENERATOR_UNDERATTACK));
 906                 }
 907         }
 908         TakeResource(this, RESOURCE_HEALTH, damage);
 909         float hlth = GetResourceAmount(this, RESOURCE_HEALTH);
 910         WaypointSprite_UpdateHealth(this.sprite, hlth);
 911         // choose an animation frame based on health
 912         this.frame = 10 * bound(0, (1 - hlth / this.max_health), 1);
 913         // see if the generator is still functional, or dying
 914         if (hlth > 0)
 915         {
 916                 this.lasthealth = hlth;
 917         }
 918         else
 919         {
 920                 if (attacker == this)
 921                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_GENDESTROYED_OVERTIME));
 922                 else
 923                 {
 924                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_GENDESTROYED));
 925                         GameRules_scoring_add(attacker, SCORE, 100);
 926                 }
 927                 this.iscaptured = false;
 928                 this.islinked = false;
 929                 this.isshielded = false;
 930                 this.takedamage = DAMAGE_NO; // can't be hurt anymore
 931                 this.event_damage = func_null; // won't do anything if hurt
 932                 this.event_heal = func_null;
 933                 this.count = 0; // reset counter
 934                 setthink(this, func_null);
 935                 this.nextthink = 0;
 936                 //this.think(); // do the first explosion now
 937
 938                 WaypointSprite_UpdateMaxHealth(this.sprite, 0);
 939                 WaypointSprite_Ping(this.sprite);
 940                 //WaypointSprite_Kill(this.sprite); // can't do this yet, code too poor
 941
 942                 onslaught_updatelinks();
 943
 944                 ons_camSetup(this);
 945         }
 946
 947         // Throw some flaming gibs on damage, more damage = more chance for gib
 948         if(random() < damage/220)
 949         {
 950                 sound(this, CH_TRIGGER, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 951         }
 952         else
 953         {
 954                 // particles on every hit
 955                 Send_Effect(EFFECT_SPARKS, hitloc, force * -1, 1);
 956
 957                 //sound on every hit
 958                 if (random() < 0.5)
 959                         sound(this, CH_TRIGGER, SND_ONS_HIT1, VOL_BASE, ATTEN_NORM);
 960                 else
 961                         sound(this, CH_TRIGGER, SND_ONS_HIT2, VOL_BASE, ATTEN_NORM);
 962         }
 963
 964         this.SendFlags |= GSF_STATUS;
 965 }
 966
 967 bool ons_GeneratorHeal(entity targ, entity inflictor, float amount, float limit)
 968 {
 969         float true_limit = ((limit != RESOURCE_LIMIT_NONE) ? limit : targ.max_health);
 970         float hlth = GetResourceAmount(targ, RESOURCE_HEALTH);
 971         if (hlth <= 0 || hlth >= true_limit)
 972                 return false;
 973
 974         GiveResourceWithLimit(targ, RESOURCE_HEALTH, amount, true_limit);
 975         hlth = GetResourceAmount(targ, RESOURCE_HEALTH);
 976         WaypointSprite_UpdateHealth(targ.sprite, hlth);
 977         targ.frame = 10 * bound(0, (1 - hlth / targ.max_health), 1);
 978         targ.lasthealth = hlth;
 979         targ.SendFlags |= GSF_STATUS;
 980         return true;
 981 }
 982
 983 void ons_GeneratorThink(entity this)
 984 {
 985         this.nextthink = time + GEN_THINKRATE;
 986
 987         if (game_stopped || this.isshielded || time < this.wait)
 988                 return;
 989
 990         this.wait = time + 5;
 991         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it),
 992         {
 993                 if (SAME_TEAM(it, this))
 994                 {
 995                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_ONS_NOTSHIELDED_TEAM);
 996                         msg_entity = it;
 997                         soundto(MSG_ONE, this, CHAN_AUTO, SND(KH_ALARM), VOL_BASE, ATTEN_NONE); // FIXME: unique sound?
 998                 }
 999                 else
1000                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, APP_TEAM_NUM(this.team, CENTER_ONS_NOTSHIELDED));
1001         });
1002 }
1003
1004 void ons_GeneratorReset(entity this)
1005 {
1006         this.team = this.team_saved;
1007         SetResourceAmountExplicit(this, RESOURCE_HEALTH, autocvar_g_onslaught_gen_health);
1008         this.lasthealth = this.max_health = autocvar_g_onslaught_gen_health;
1009         this.takedamage = DAMAGE_AIM;
1010         this.bot_attack = true;
1011         if(!IL_CONTAINS(g_bot_targets, this))
1012                 IL_PUSH(g_bot_targets, this);
1013         this.iscaptured = true;
1014         this.islinked = true;
1015         this.isshielded = true;
1016         this.event_damage = ons_GeneratorDamage;
1017         this.event_heal = ons_GeneratorHeal;
1018         setthink(this, ons_GeneratorThink);
1019         this.nextthink = time + GEN_THINKRATE;
1020
1021         Net_LinkEntity(this, false, 0, generator_send);
1022
1023         this.SendFlags = GSF_SETUP; // just incase
1024         this.SendFlags |= GSF_STATUS;
1025
1026         WaypointSprite_UpdateMaxHealth(this.sprite, this.max_health);
1027         WaypointSprite_UpdateHealth(this.sprite, GetResourceAmount(this, RESOURCE_HEALTH));
1028         WaypointSprite_UpdateRule(this.sprite,this.team,SPRITERULE_TEAMPLAY);
1029
1030         onslaught_updatelinks();
1031 }
1032
1033 void ons_DelayedGeneratorSetup(entity this)
1034 {
1035         // bot waypoints
1036         waypoint_spawnforitem_force(this, this.origin);
1037         this.nearestwaypointtimeout = 0; // activate waypointing again
1038         this.bot_basewaypoint = this.nearestwaypoint;
1039
1040         // captureshield setup
1041         ons_CaptureShield_Spawn(this, true);
1042
1043         onslaught_updatelinks();
1044
1045         Net_LinkEntity(this, false, 0, generator_send);
1046 }
1047
1048
1049 void onslaught_generator_touch(entity this, entity toucher)
1050 {
1051         if ( IS_PLAYER(toucher) )
1052         if ( SAME_TEAM(this,toucher) )
1053         if ( this.iscaptured )
1054         {
1055                 Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT);
1056         }
1057 }
1058
1059 void ons_GeneratorSetup(entity gen) // called when spawning a generator entity on the map as a spawnfunc
1060 {
1061         // declarations
1062         int teamnumber = gen.team;
1063
1064         // main setup
1065         gen.ons_worldgeneratornext = ons_worldgeneratorlist; // link generator into ons_worldgeneratorlist
1066         ons_worldgeneratorlist = gen;
1067
1068         gen.netname = sprintf("%s generator", Team_ColoredFullName(teamnumber));
1069         gen.classname = "onslaught_generator";
1070         gen.solid = SOLID_BBOX;
1071         gen.team_saved = teamnumber;
1072         IL_PUSH(g_saved_team, gen);
1073         set_movetype(gen, MOVETYPE_NONE);
1074         gen.lasthealth = gen.max_health = autocvar_g_onslaught_gen_health;
1075         SetResourceAmountExplicit(gen, RESOURCE_HEALTH, autocvar_g_onslaught_gen_health);
1076         gen.takedamage = DAMAGE_AIM;
1077         gen.bot_attack = true;
1078         IL_PUSH(g_bot_targets, gen);
1079         gen.event_damage = ons_GeneratorDamage;
1080         gen.event_heal = ons_GeneratorHeal;
1081         gen.reset = ons_GeneratorReset;
1082         setthink(gen, ons_GeneratorThink);
1083         gen.nextthink = time + GEN_THINKRATE;
1084         gen.iscaptured = true;
1085         gen.islinked = true;
1086         gen.isshielded = true;
1087         settouch(gen, onslaught_generator_touch);
1088
1089         // appearence
1090         // model handled by CSQC
1091         setsize(gen, GENERATOR_MIN, GENERATOR_MAX);
1092         setorigin(gen, (gen.origin + CPGEN_SPAWN_OFFSET));
1093         gen.colormap = 1024 + (teamnumber - 1) * 17;
1094
1095         // generator placement
1096         droptofloor(gen);
1097
1098         // waypointsprites
1099         WaypointSprite_SpawnFixed(WP_Null, gen.origin + CPGEN_WAYPOINT_OFFSET, gen, sprite, RADARICON_NONE);
1100         WaypointSprite_UpdateRule(gen.sprite, gen.team, SPRITERULE_TEAMPLAY);
1101         WaypointSprite_UpdateMaxHealth(gen.sprite, gen.max_health);
1102         WaypointSprite_UpdateHealth(gen.sprite, GetResourceAmount(gen, RESOURCE_HEALTH));
1103
1104         InitializeEntity(gen, ons_DelayedGeneratorSetup, INITPRIO_SETLOCATION);
1105 }
1106
1107
1108 // ===============
1109 //  Round Handler
1110 // ===============
1111
1112 int total_generators;
1113 void Onslaught_count_generators()
1114 {
1115         entity e;
1116         total_generators = redowned = blueowned = yellowowned = pinkowned = 0;
1117         for(e = ons_worldgeneratorlist; e; e = e.ons_worldgeneratornext)
1118         {
1119                 ++total_generators;
1120                 redowned += (e.team == NUM_TEAM_1 && GetResourceAmount(e, RESOURCE_HEALTH) > 0);
1121                 blueowned += (e.team == NUM_TEAM_2 && GetResourceAmount(e, RESOURCE_HEALTH) > 0);
1122                 yellowowned += (e.team == NUM_TEAM_3 && GetResourceAmount(e, RESOURCE_HEALTH) > 0);
1123                 pinkowned += (e.team == NUM_TEAM_4 && GetResourceAmount(e, RESOURCE_HEALTH) > 0);
1124         }
1125 }
1126
1127 int Onslaught_GetWinnerTeam()
1128 {
1129         int winner_team = 0;
1130         if(redowned > 0)
1131                 winner_team = NUM_TEAM_1;
1132         if(blueowned > 0)
1133         {
1134                 if(winner_team) return 0;
1135                 winner_team = NUM_TEAM_2;
1136         }
1137         if(yellowowned > 0)
1138         {
1139                 if(winner_team) return 0;
1140                 winner_team = NUM_TEAM_3;
1141         }
1142         if(pinkowned > 0)
1143         {
1144                 if(winner_team) return 0;
1145                 winner_team = NUM_TEAM_4;
1146         }
1147         if(winner_team)
1148                 return winner_team;
1149         return -1; // no generators left?
1150 }
1151
1152 void nades_Clear(entity e);
1153
1154 #define ONS_OWNED_GENERATORS() ((redowned > 0) + (blueowned > 0) + (yellowowned > 0) + (pinkowned > 0))
1155 #define ONS_OWNED_GENERATORS_OK() (ONS_OWNED_GENERATORS() > 1)
1156 bool Onslaught_CheckWinner()
1157 {
1158         if ((autocvar_timelimit && time > game_starttime + autocvar_timelimit * 60) || (round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0))
1159         {
1160                 ons_stalemate = true;
1161
1162                 if (!wpforenemy_announced)
1163                 {
1164                         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_CONTROLPOINT);
1165                         sound(NULL, CH_INFO, SND_ONS_GENERATOR_DECAY, VOL_BASE, ATTEN_NONE);
1166
1167                         wpforenemy_announced = true;
1168                 }
1169
1170                 entity tmp_entity; // temporary entity
1171                 float d;
1172                 for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext) if(time >= tmp_entity.ons_overtime_damagedelay)
1173                 {
1174                         // tmp_entity.max_health / 300 gives 5 minutes of overtime.
1175                         // control points reduce the overtime duration.
1176                         d = 1;
1177                         entity e;
1178                         for(e = ons_worldcplist; e; e = e.ons_worldcpnext)
1179                         {
1180                                 if(DIFF_TEAM(e, tmp_entity))
1181                                 if(e.islinked)
1182                                         d = d + 1;
1183                         }
1184
1185                         if(autocvar_g_campaign && autocvar__campaign_testrun)
1186                                 d = d * tmp_entity.max_health;
1187                         else
1188                                 d = d * tmp_entity.max_health / max(30, 60 * autocvar_timelimit_suddendeath);
1189
1190                         Damage(tmp_entity, tmp_entity, tmp_entity, d, DEATH_HURTTRIGGER.m_id, DMG_NOWEP, tmp_entity.origin, '0 0 0');
1191
1192                         tmp_entity.sprite.SendFlags |= 16;
1193
1194                         tmp_entity.ons_overtime_damagedelay = time + 1;
1195                 }
1196         }
1197         else { wpforenemy_announced = false; ons_stalemate = false; }
1198
1199         Onslaught_count_generators();
1200
1201         if(ONS_OWNED_GENERATORS_OK())
1202                 return 0;
1203
1204         int winner_team = Onslaught_GetWinnerTeam();
1205
1206         if(winner_team > 0)
1207         {
1208                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
1209                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
1210                 TeamScore_AddToTeam(winner_team, ST_ONS_CAPS, +1);
1211         }
1212         else if(winner_team == -1)
1213         {
1214                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_TIED);
1215                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_TIED);
1216         }
1217
1218         ons_stalemate = false;
1219
1220         play2all(SND(CTF_CAPTURE(winner_team)));
1221
1222         round_handler_Init(7, autocvar_g_onslaught_warmup, autocvar_g_onslaught_round_timelimit);
1223
1224         FOREACH_CLIENT(IS_PLAYER(it), {
1225                 STAT(ROUNDLOST, it) = true;
1226                 it.player_blocked = true;
1227
1228                 nades_Clear(it);
1229         });
1230
1231         game_stopped = true;
1232         return 1;
1233 }
1234
1235 bool Onslaught_CheckPlayers()
1236 {
1237         return 1;
1238 }
1239
1240 void Onslaught_RoundStart()
1241 {
1242         entity tmp_entity;
1243         FOREACH_CLIENT(IS_PLAYER(it), it.player_blocked = false);
1244
1245         for(tmp_entity = ons_worldcplist; tmp_entity; tmp_entity = tmp_entity.ons_worldcpnext)
1246                 tmp_entity.sprite.SendFlags |= 16;
1247
1248         for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1249                 tmp_entity.sprite.SendFlags |= 16;
1250 }
1251
1252
1253 // ================
1254 // Bot player logic
1255 // ================
1256
1257 // NOTE: LEGACY CODE, needs to be re-written!
1258
1259 void havocbot_goalrating_ons_offenseitems(entity this, float ratingscale, vector org, float sradius)
1260 {
1261         bool needarmor = false, needweapons = false;
1262
1263         // Needs armor/health?
1264         if(GetResourceAmount(this, RESOURCE_HEALTH) < 100)
1265                 needarmor = true;
1266
1267         // Needs weapons?
1268         int c = 0;
1269         FOREACH(Weapons, it != WEP_Null, {
1270                 if(STAT(WEAPONS, this) & (it.m_wepset))
1271                 if(++c >= 4)
1272                         break;
1273         });
1274
1275         if(c<4)
1276                 needweapons = true;
1277
1278         if(!needweapons && !needarmor)
1279                 return;
1280
1281         LOG_DEBUG(this.netname, " needs weapons ", ftos(needweapons));
1282         LOG_DEBUG(this.netname, " needs armor ", ftos(needarmor));
1283
1284         // See what is around
1285         IL_EACH(g_items, it.bot_pickup,
1286         {
1287                 // gather health and armor only
1288                 if (it.solid)
1289                 if ( ((GetResourceAmount(it, RESOURCE_HEALTH) || GetResourceAmount(it, RESOURCE_ARMOR)) && needarmor) || (STAT(WEAPONS, it) && needweapons ) )
1290                 if (vdist(it.origin - org, <, sradius))
1291                 {
1292                         int t = it.bot_pickupevalfunc(this, it);
1293                         if (t > 0)
1294                                 navigation_routerating(this, it, t * ratingscale, 500);
1295                 }
1296         });
1297 }
1298
1299 void havocbot_role_ons_setrole(entity this, int role)
1300 {
1301         LOG_DEBUG(this.netname," switched to ");
1302         switch(role)
1303         {
1304                 case HAVOCBOT_ONS_ROLE_DEFENSE:
1305                         LOG_DEBUG("defense");
1306                         this.havocbot_role = havocbot_role_ons_defense;
1307                         this.havocbot_role_flags = HAVOCBOT_ONS_ROLE_DEFENSE;
1308                         this.havocbot_role_timeout = 0;
1309                         break;
1310                 case HAVOCBOT_ONS_ROLE_ASSISTANT:
1311                         LOG_DEBUG("assistant");
1312                         this.havocbot_role = havocbot_role_ons_assistant;
1313                         this.havocbot_role_flags = HAVOCBOT_ONS_ROLE_ASSISTANT;
1314                         this.havocbot_role_timeout = 0;
1315                         break;
1316                 case HAVOCBOT_ONS_ROLE_OFFENSE:
1317                         LOG_DEBUG("offense");
1318                         this.havocbot_role = havocbot_role_ons_offense;
1319                         this.havocbot_role_flags = HAVOCBOT_ONS_ROLE_OFFENSE;
1320                         this.havocbot_role_timeout = 0;
1321                         break;
1322         }
1323         LOG_DEBUG("");
1324 }
1325
1326 void havocbot_goalrating_ons_controlpoints_attack(entity this, float ratingscale)
1327 {
1328         entity cp, cp1, cp2, best, wp;
1329         float radius, bestvalue;
1330         int c;
1331         bool found;
1332
1333         // Filter control points
1334         for(cp2 = ons_worldcplist; cp2; cp2 = cp2.ons_worldcpnext)
1335         {
1336                 cp2.wpcost = c = 0;
1337                 cp2.wpconsidered = false;
1338
1339                 if(cp2.isshielded)
1340                         continue;
1341
1342                 // Ignore owned controlpoints
1343                 if(!((cp2.aregensneighbor & BIT(this.team)) || (cp2.arecpsneighbor & BIT(this.team))))
1344                         continue;
1345
1346                 // Count team mates interested in this control point
1347                 // (easier and cleaner than keeping counters per cp and teams)
1348                 FOREACH_CLIENT(IS_PLAYER(it), {
1349                         if(SAME_TEAM(it, this))
1350                         if(it.havocbot_role_flags & HAVOCBOT_ONS_ROLE_OFFENSE)
1351                         if(it.havocbot_ons_target == cp2)
1352                                 ++c;
1353                 });
1354
1355                 // NOTE: probably decrease the cost of attackable control points
1356                 cp2.wpcost = c;
1357                 cp2.wpconsidered = true;
1358         }
1359
1360         // We'll consider only the best case
1361         bestvalue = 99999999999;
1362         cp = NULL;
1363         for(cp1 = ons_worldcplist; cp1; cp1 = cp1.ons_worldcpnext)
1364         {
1365                 if (!cp1.wpconsidered)
1366                         continue;
1367
1368                 if(cp1.wpcost<bestvalue)
1369                 {
1370                         bestvalue = cp1.wpcost;
1371                         cp = cp1;
1372                         this.havocbot_ons_target = cp1;
1373                 }
1374         }
1375
1376         if (!cp)
1377                 return;
1378
1379         LOG_DEBUG(this.netname, " chose cp ranked ", ftos(bestvalue));
1380
1381         if(cp.goalentity)
1382         {
1383                 // Should be attacked
1384                 // Rate waypoints near it
1385                 found = false;
1386                 best = NULL;
1387                 bestvalue = 99999999999;
1388                 for(radius=0; radius<1000 && !found; radius+=500)
1389                 {
1390                         for(wp=findradius(cp.origin,radius); wp; wp=wp.chain)
1391                         {
1392                                 if(!(wp.wpflags & WAYPOINTFLAG_GENERATED))
1393                                 if(wp.classname=="waypoint")
1394                                 if(checkpvs(wp.origin,cp))
1395                                 {
1396                                         found = true;
1397                                         if(wp.cnt<bestvalue)
1398                                         {
1399                                                 best = wp;
1400                                                 bestvalue = wp.cnt;
1401                                         }
1402                                 }
1403                         }
1404                 }
1405
1406                 if(best)
1407                 {
1408                         navigation_routerating(this, best, ratingscale, 10000);
1409                         best.cnt += 1;
1410
1411                         this.havocbot_attack_time = 0;
1412                         if(checkpvs(this.origin + this.view_ofs, cp))
1413                         if(checkpvs(this.origin + this.view_ofs, best))
1414                                 this.havocbot_attack_time = time + 2;
1415                 }
1416                 else
1417                 {
1418                         navigation_routerating(this, cp, ratingscale, 10000);
1419                 }
1420                 LOG_DEBUG(this.netname, " found an attackable controlpoint at ", vtos(cp.origin));
1421         }
1422         else
1423         {
1424                 // Should be touched
1425                 LOG_DEBUG(this.netname, " found a touchable controlpoint at ", vtos(cp.origin));
1426                 found = false;
1427
1428                 // Look for auto generated waypoint
1429                 if (!bot_waypoints_for_items)
1430                 for (wp = findradius(cp.origin,100); wp; wp = wp.chain)
1431                 {
1432                         if(wp.classname=="waypoint")
1433                         {
1434                                 navigation_routerating(this, wp, ratingscale, 10000);
1435                                 found = true;
1436                         }
1437                 }
1438
1439                 // Nothing found, rate the controlpoint itself
1440                 if (!found)
1441                         navigation_routerating(this, cp, ratingscale, 10000);
1442         }
1443 }
1444
1445 bool havocbot_goalrating_ons_generator_attack(entity this, float ratingscale)
1446 {
1447         entity g, wp, bestwp;
1448         bool found;
1449         int best;
1450
1451         for(g = ons_worldgeneratorlist; g; g = g.ons_worldgeneratornext)
1452         {
1453                 if(SAME_TEAM(g, this) || g.isshielded)
1454                         continue;
1455
1456                 // Should be attacked
1457                 // Rate waypoints near it
1458                 found = false;
1459                 bestwp = NULL;
1460                 best = 99999999999;
1461
1462                 for(wp=findradius(g.origin,400); wp; wp=wp.chain)
1463                 {
1464                         if(wp.classname=="waypoint")
1465                         if(checkpvs(wp.origin,g))
1466                         {
1467                                 found = true;
1468                                 if(wp.cnt<best)
1469                                 {
1470                                         bestwp = wp;
1471                                         best = wp.cnt;
1472                                 }
1473                         }
1474                 }
1475
1476                 if(bestwp)
1477                 {
1478                         LOG_DEBUG("waypoints found around generator");
1479                         navigation_routerating(this, bestwp, ratingscale, 10000);
1480                         bestwp.cnt += 1;
1481
1482                         this.havocbot_attack_time = 0;
1483                         if(checkpvs(this.origin + this.view_ofs, g))
1484                         if(checkpvs(this.origin + this.view_ofs, bestwp))
1485                                 this.havocbot_attack_time = time + 5;
1486
1487                         return true;
1488                 }
1489                 else
1490                 {
1491                         LOG_DEBUG("generator found without waypoints around");
1492                         // if there aren't waypoints near the generator go straight to it
1493                         navigation_routerating(this, g, ratingscale, 10000);
1494                         this.havocbot_attack_time = 0;
1495                         return true;
1496                 }
1497         }
1498         return false;
1499 }
1500
1501 void havocbot_role_ons_offense(entity this)
1502 {
1503         if(IS_DEAD(this))
1504         {
1505                 this.havocbot_attack_time = 0;
1506                 havocbot_ons_reset_role(this);
1507                 return;
1508         }
1509
1510         // Set the role timeout if necessary
1511         if (!this.havocbot_role_timeout)
1512                 this.havocbot_role_timeout = time + 120;
1513
1514         if (time > this.havocbot_role_timeout)
1515         {
1516                 havocbot_ons_reset_role(this);
1517                 return;
1518         }
1519
1520         if(this.havocbot_attack_time>time)
1521                 return;
1522
1523         if (navigation_goalrating_timeout(this))
1524         {
1525                 navigation_goalrating_start(this);
1526                 havocbot_goalrating_enemyplayers(this, 20000, this.origin, 650);
1527                 if(!havocbot_goalrating_ons_generator_attack(this, 20000))
1528                         havocbot_goalrating_ons_controlpoints_attack(this, 20000);
1529                 havocbot_goalrating_ons_offenseitems(this, 10000, this.origin, 10000);
1530                 navigation_goalrating_end(this);
1531
1532                 navigation_goalrating_timeout_set(this);
1533         }
1534 }
1535
1536 void havocbot_role_ons_assistant(entity this)
1537 {
1538         havocbot_ons_reset_role(this);
1539 }
1540
1541 void havocbot_role_ons_defense(entity this)
1542 {
1543         havocbot_ons_reset_role(this);
1544 }
1545
1546 void havocbot_ons_reset_role(entity this)
1547 {
1548         if(IS_DEAD(this))
1549                 return;
1550
1551         this.havocbot_ons_target = NULL;
1552
1553         // TODO: Defend control points or generator if necessary
1554
1555         havocbot_role_ons_setrole(this, HAVOCBOT_ONS_ROLE_OFFENSE);
1556 }
1557
1558
1559 /*
1560  * Find control point or generator owned by the same team self which is nearest to pos
1561  * if max_dist is positive, only control points within this range will be considered
1562  */
1563 entity ons_Nearest_ControlPoint(entity this, vector pos, float max_dist)
1564 {
1565         entity closest_target = NULL;
1566         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1567         {
1568                 if(SAME_TEAM(cp, this))
1569                 if(cp.iscaptured)
1570                 if(max_dist <= 0 || vdist(cp.origin - pos, <=, max_dist))
1571                 if(vlen2(cp.origin - pos) <= vlen2(closest_target.origin - pos) || closest_target == NULL)
1572                         closest_target = cp;
1573         }
1574         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1575         {
1576                 if(SAME_TEAM(gen, this))
1577                 if(max_dist <= 0 || vdist(gen.origin - pos, <, max_dist))
1578                 if(vlen2(gen.origin - pos) <= vlen2(closest_target.origin - pos) || closest_target == NULL)
1579                         closest_target = gen;
1580         }
1581
1582         return closest_target;
1583 }
1584
1585 /*
1586  * Find control point or generator owned by the same team self which is nearest to pos
1587  * if max_dist is positive, only control points within this range will be considered
1588  * This function only check distances on the XY plane, disregarding Z
1589  */
1590 entity ons_Nearest_ControlPoint_2D(entity this, vector pos, float max_dist)
1591 {
1592         entity closest_target = NULL;
1593         vector delta;
1594         float smallest_distance = 0, distance;
1595
1596         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1597         {
1598                 delta = cp.origin - pos;
1599                 delta_z = 0;
1600                 distance = vlen(delta);
1601
1602                 if(SAME_TEAM(cp, this))
1603                 if(cp.iscaptured)
1604                 if(max_dist <= 0 || distance <= max_dist)
1605                 if(closest_target == NULL || distance <= smallest_distance )
1606                 {
1607                         closest_target = cp;
1608                         smallest_distance = distance;
1609                 }
1610         }
1611         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1612         {
1613                 delta = gen.origin - pos;
1614                 delta_z = 0;
1615                 distance = vlen(delta);
1616
1617                 if(SAME_TEAM(gen, this))
1618                 if(max_dist <= 0 || distance <= max_dist)
1619                 if(closest_target == NULL || distance <= smallest_distance )
1620                 {
1621                         closest_target = gen;
1622                         smallest_distance = distance;
1623                 }
1624         }
1625
1626         return closest_target;
1627 }
1628 /**
1629  * find the number of control points and generators in the same team as this
1630  */
1631 int ons_Count_SelfControlPoints(entity this)
1632 {
1633         int n = 0;
1634         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1635         {
1636                 if(SAME_TEAM(cp, this))
1637                 if(cp.iscaptured)
1638                         n++;
1639         }
1640         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1641         {
1642                 if(SAME_TEAM(gen, this))
1643                         n++;
1644         }
1645         return n;
1646 }
1647
1648 /**
1649  * Teleport player to a random position near tele_target
1650  * if tele_effects is true, teleport sound+particles are created
1651  * return false on failure
1652  */
1653 bool ons_Teleport(entity player, entity tele_target, float range, bool tele_effects)
1654 {
1655         if ( !tele_target )
1656                 return false;
1657
1658         int i;
1659         vector loc;
1660         float theta;
1661         // narrow the range for each iteration to increase chances that a spawnpoint
1662         // can be found even if there's little room around the control point
1663         float iteration_scale = 1;
1664         for(i = 0; i < 16; ++i)
1665         {
1666                 iteration_scale -= i / 16;
1667                 theta = random() * 2 * M_PI;
1668                 loc_y = sin(theta);
1669                 loc_x = cos(theta);
1670                 loc_z = 0;
1671                 loc *= random() * range * iteration_scale;
1672
1673                 loc += tele_target.origin + '0 0 128' * iteration_scale;
1674
1675                 tracebox(loc, STAT(PL_MIN, player), STAT(PL_MAX, player), loc, MOVE_NORMAL, player);
1676                 if(trace_fraction == 1.0 && !trace_startsolid)
1677                 {
1678                         traceline(tele_target.origin, loc, MOVE_NOMONSTERS, tele_target); // double check to make sure we're not spawning outside the NULL
1679                         if(trace_fraction == 1.0 && !trace_startsolid)
1680                         {
1681                                 if ( tele_effects )
1682                                 {
1683                                         Send_Effect(EFFECT_TELEPORT, player.origin, '0 0 0', 1);
1684                                         sound (player, CH_TRIGGER, SND_TELEPORT, VOL_BASE, ATTEN_NORM);
1685                                 }
1686                                 setorigin(player, loc);
1687                                 player.angles = '0 1 0' * ( theta * RAD2DEG + 180 );
1688                                 makevectors(player.angles);
1689                                 player.fixangle = true;
1690                                 player.teleport_antispam = time + autocvar_g_onslaught_teleport_wait;
1691
1692                                 if ( tele_effects )
1693                                         Send_Effect(EFFECT_TELEPORT, player.origin + v_forward * 32, '0 0 0', 1);
1694                                 return true;
1695                         }
1696                 }
1697         }
1698
1699         return false;
1700 }
1701
1702 // ==============
1703 // Hook Functions
1704 // ==============
1705
1706 MUTATOR_HOOKFUNCTION(ons, reset_map_global)
1707 {
1708         FOREACH_CLIENT(IS_PLAYER(it), {
1709                 STAT(ROUNDLOST, it) = false;
1710                 it.ons_deathloc = '0 0 0';
1711                 PutClientInServer(it);
1712                 it.clientcamera = it;
1713         });
1714         return false;
1715 }
1716
1717 MUTATOR_HOOKFUNCTION(ons, ClientDisconnect)
1718 {
1719         entity player = M_ARGV(0, entity);
1720
1721         player.ons_deathloc = '0 0 0';
1722 }
1723
1724 MUTATOR_HOOKFUNCTION(ons, MakePlayerObserver)
1725 {
1726         entity player = M_ARGV(0, entity);
1727
1728         player.ons_deathloc = '0 0 0';
1729 }
1730
1731 MUTATOR_HOOKFUNCTION(ons, PlayerSpawn)
1732 {
1733         entity player = M_ARGV(0, entity);
1734
1735         if(!round_handler_IsRoundStarted())
1736         {
1737                 player.player_blocked = true;
1738                 return false;
1739         }
1740
1741         entity l;
1742         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
1743         {
1744                 l.sprite.SendFlags |= 16;
1745         }
1746         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
1747         {
1748                 l.sprite.SendFlags |= 16;
1749         }
1750
1751         if(ons_stalemate) { Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_OVERTIME_CONTROLPOINT); }
1752
1753         if ( autocvar_g_onslaught_spawn_choose )
1754         if ( player.ons_spawn_by )
1755         if ( ons_Teleport(player,player.ons_spawn_by,autocvar_g_onslaught_teleport_radius,false) )
1756         {
1757                 player.ons_spawn_by = NULL;
1758                 return false;
1759         }
1760
1761         if(autocvar_g_onslaught_spawn_at_controlpoints)
1762         if(random() <= autocvar_g_onslaught_spawn_at_controlpoints_chance)
1763         {
1764                 float random_target = autocvar_g_onslaught_spawn_at_controlpoints_random;
1765                 entity tmp_entity, closest_target = NULL;
1766                 vector spawn_loc = player.ons_deathloc;
1767
1768                 // new joining player or round reset, don't bother checking
1769                 if(spawn_loc == '0 0 0') { return false; }
1770
1771                 if(random_target) { RandomSelection_Init(); }
1772
1773                 for(tmp_entity = ons_worldcplist; tmp_entity; tmp_entity = tmp_entity.ons_worldcpnext)
1774                 {
1775                         if(SAME_TEAM(tmp_entity, player))
1776                         if(random_target)
1777                                 RandomSelection_AddEnt(tmp_entity, 1, 1);
1778                         else if(vlen2(tmp_entity.origin - spawn_loc) <= vlen2(closest_target.origin - spawn_loc) || closest_target == NULL)
1779                                 closest_target = tmp_entity;
1780                 }
1781
1782                 if(random_target) { closest_target = RandomSelection_chosen_ent; }
1783
1784                 if(closest_target)
1785                 {
1786                         float i;
1787                         vector loc;
1788                         float iteration_scale = 1;
1789                         for(i = 0; i < 10; ++i)
1790                         {
1791                                 iteration_scale -= i / 10;
1792                                 loc = closest_target.origin + '0 0 96' * iteration_scale;
1793                                 loc += ('0 1 0' * random()) * 128 * iteration_scale;
1794                                 tracebox(loc, STAT(PL_MIN, player), STAT(PL_MAX, player), loc, MOVE_NORMAL, player);
1795                                 if(trace_fraction == 1.0 && !trace_startsolid)
1796                                 {
1797                                         traceline(closest_target.origin, loc, MOVE_NOMONSTERS, closest_target); // double check to make sure we're not spawning outside the NULL
1798                                         if(trace_fraction == 1.0 && !trace_startsolid)
1799                                         {
1800                                                 setorigin(player, loc);
1801                                                 player.angles = normalize(loc - closest_target.origin) * RAD2DEG;
1802                                                 return false;
1803                                         }
1804                                 }
1805                         }
1806                 }
1807         }
1808
1809         if(autocvar_g_onslaught_spawn_at_generator)
1810         if(random() <= autocvar_g_onslaught_spawn_at_generator_chance)
1811         {
1812                 float random_target = autocvar_g_onslaught_spawn_at_generator_random;
1813                 entity tmp_entity, closest_target = NULL;
1814                 vector spawn_loc = player.ons_deathloc;
1815
1816                 // new joining player or round reset, don't bother checking
1817                 if(spawn_loc == '0 0 0') { return false; }
1818
1819                 if(random_target) { RandomSelection_Init(); }
1820
1821                 for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1822                 {
1823                         if(random_target)
1824                                 RandomSelection_AddEnt(tmp_entity, 1, 1);
1825                         else
1826                         {
1827                                 if(SAME_TEAM(tmp_entity, player))
1828                                 if(vlen2(tmp_entity.origin - spawn_loc) <= vlen2(closest_target.origin - spawn_loc) || closest_target == NULL)
1829                                         closest_target = tmp_entity;
1830                         }
1831                 }
1832
1833                 if(random_target) { closest_target = RandomSelection_chosen_ent; }
1834
1835                 if(closest_target)
1836                 {
1837                         float i;
1838                         vector loc;
1839                         float iteration_scale = 1;
1840                         for(i = 0; i < 10; ++i)
1841                         {
1842                                 iteration_scale -= i / 10;
1843                                 loc = closest_target.origin + '0 0 128' * iteration_scale;
1844                                 loc += ('0 1 0' * random()) * 256 * iteration_scale;
1845                                 tracebox(loc, STAT(PL_MIN, player), STAT(PL_MAX, player), loc, MOVE_NORMAL, player);
1846                                 if(trace_fraction == 1.0 && !trace_startsolid)
1847                                 {
1848                                         traceline(closest_target.origin, loc, MOVE_NOMONSTERS, closest_target); // double check to make sure we're not spawning outside the NULL
1849                                         if(trace_fraction == 1.0 && !trace_startsolid)
1850                                         {
1851                                                 setorigin(player, loc);
1852                                                 player.angles = normalize(loc - closest_target.origin) * RAD2DEG;
1853                                                 return false;
1854                                         }
1855                                 }
1856                         }
1857                 }
1858         }
1859
1860         return false;
1861 }
1862
1863 MUTATOR_HOOKFUNCTION(ons, PlayerDies)
1864 {
1865         entity frag_target = M_ARGV(2, entity);
1866
1867         frag_target.ons_deathloc = frag_target.origin;
1868         entity l;
1869         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
1870         {
1871                 l.sprite.SendFlags |= 16;
1872         }
1873         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
1874         {
1875                 l.sprite.SendFlags |= 16;
1876         }
1877
1878         if ( autocvar_g_onslaught_spawn_choose )
1879         if ( ons_Count_SelfControlPoints(frag_target) > 1 )
1880                 stuffcmd(frag_target, "qc_cmd_cl hud clickradar\n");
1881
1882         return false;
1883 }
1884
1885 MUTATOR_HOOKFUNCTION(ons, MonsterMove)
1886 {
1887         entity mon = M_ARGV(0, entity);
1888
1889         entity e = find(NULL, targetname, mon.target);
1890         if (e != NULL)
1891                 mon.team = e.team;
1892 }
1893
1894 void ons_MonsterSpawn_Delayed(entity this)
1895 {
1896         entity own = this.owner;
1897
1898         if(!own) { delete(this); return; }
1899
1900         if(own.targetname)
1901         {
1902                 entity e = find(NULL, target, own.targetname);
1903                 if(e != NULL)
1904                 {
1905                         own.team = e.team;
1906
1907                         own.use(own, e, NULL);
1908                 }
1909         }
1910
1911         delete(this);
1912 }
1913
1914 MUTATOR_HOOKFUNCTION(ons, MonsterSpawn)
1915 {
1916         entity mon = M_ARGV(0, entity);
1917
1918         entity e = spawn();
1919         e.owner = mon;
1920         InitializeEntity(e, ons_MonsterSpawn_Delayed, INITPRIO_FINDTARGET);
1921 }
1922
1923 void ons_TurretSpawn_Delayed(entity this)
1924 {
1925         entity own = this.owner;
1926
1927         if(!own) { delete(this); return; }
1928
1929         if(own.targetname)
1930         {
1931                 entity e = find(NULL, target, own.targetname);
1932                 if(e != NULL)
1933                 {
1934                         own.team = e.team;
1935                         own.active = ACTIVE_NOT;
1936
1937                         own.use(own, e, NULL);
1938                 }
1939         }
1940
1941         delete(this);
1942 }
1943
1944 MUTATOR_HOOKFUNCTION(ons, TurretSpawn)
1945 {
1946         entity turret = M_ARGV(0, entity);
1947
1948         entity e = spawn();
1949         e.owner = turret;
1950         InitializeEntity(e, ons_TurretSpawn_Delayed, INITPRIO_FINDTARGET);
1951
1952         return false;
1953 }
1954
1955 MUTATOR_HOOKFUNCTION(ons, HavocBot_ChooseRole)
1956 {
1957         entity bot = M_ARGV(0, entity);
1958
1959         havocbot_ons_reset_role(bot);
1960         return true;
1961 }
1962
1963 MUTATOR_HOOKFUNCTION(ons, CheckAllowedTeams)
1964 {
1965         // onslaught is special
1966         for(entity tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1967         {
1968                 switch(tmp_entity.team)
1969                 {
1970                         case NUM_TEAM_1: c1 = 0; break;
1971                         case NUM_TEAM_2: c2 = 0; break;
1972                         case NUM_TEAM_3: c3 = 0; break;
1973                         case NUM_TEAM_4: c4 = 0; break;
1974                 }
1975         }
1976
1977         return true;
1978 }
1979
1980 MUTATOR_HOOKFUNCTION(ons, SpectateCopy)
1981 {
1982         entity spectatee = M_ARGV(0, entity);
1983         entity client = M_ARGV(1, entity);
1984
1985         STAT(ROUNDLOST, client) = STAT(ROUNDLOST, spectatee); // make spectators see it too
1986 }
1987
1988 MUTATOR_HOOKFUNCTION(ons, SV_ParseClientCommand)
1989 {
1990         if(MUTATOR_RETURNVALUE) // command was already handled?
1991                 return false;
1992
1993         entity player = M_ARGV(0, entity);
1994         string cmd_name = M_ARGV(1, string);
1995         int cmd_argc = M_ARGV(2, int);
1996
1997         if ( cmd_name == "ons_spawn" )
1998         {
1999                 vector pos = player.origin;
2000                 if(cmd_argc > 1)
2001                         pos_x = stof(argv(1));
2002                 if(cmd_argc > 2)
2003                         pos_y = stof(argv(2));
2004                 if(cmd_argc > 3)
2005                         pos_z = stof(argv(3));
2006
2007                 if ( IS_PLAYER(player) )
2008                 {
2009                         if ( !STAT(FROZEN, player) )
2010                         {
2011                                 entity source_point = ons_Nearest_ControlPoint(player, player.origin, autocvar_g_onslaught_teleport_radius);
2012
2013                                 if ( !source_point && GetResourceAmount(player, RESOURCE_HEALTH) > 0 )
2014                                 {
2015                                         sprint(player, "\nYou need to be next to a control point\n");
2016                                         return true;
2017                                 }
2018
2019
2020                                 entity closest_target = ons_Nearest_ControlPoint_2D(player, pos, autocvar_g_onslaught_click_radius);
2021
2022                                 if ( closest_target == NULL )
2023                                 {
2024                                         sprint(player, "\nNo control point found\n");
2025                                         return true;
2026                                 }
2027
2028                                 if ( GetResourceAmount(player, RESOURCE_HEALTH) <= 0 )
2029                                 {
2030                                         player.ons_spawn_by = closest_target;
2031                                         player.respawn_flags = player.respawn_flags | RESPAWN_FORCE;
2032                                 }
2033                                 else
2034                                 {
2035                                         if ( source_point == closest_target )
2036                                         {
2037                                                 sprint(player, "\nTeleporting to the same point\n");
2038                                                 return true;
2039                                         }
2040
2041                                         if ( !ons_Teleport(player,closest_target,autocvar_g_onslaught_teleport_radius,true) )
2042                                                 sprint(player, "\nUnable to teleport there\n");
2043                                 }
2044
2045                                 return true;
2046                         }
2047
2048                         sprint(player, "\nNo teleportation for you\n");
2049                 }
2050
2051                 return true;
2052         }
2053         return false;
2054 }
2055
2056 MUTATOR_HOOKFUNCTION(ons, PlayerUseKey)
2057 {
2058         if(MUTATOR_RETURNVALUE || game_stopped) return false;
2059
2060         entity player = M_ARGV(0, entity);
2061
2062         if((time > player.teleport_antispam) && (!IS_DEAD(player)) && !player.vehicle)
2063         {
2064                 entity source_point = ons_Nearest_ControlPoint(player, player.origin, autocvar_g_onslaught_teleport_radius);
2065                 if ( source_point )
2066                 {
2067                         stuffcmd(player, "qc_cmd_cl hud clickradar\n");
2068                         return true;
2069                 }
2070         }
2071 }
2072
2073 MUTATOR_HOOKFUNCTION(ons, PlayHitsound)
2074 {
2075         entity frag_victim = M_ARGV(0, entity);
2076
2077         return (frag_victim.classname == "onslaught_generator" && !frag_victim.isshielded)
2078                 || (frag_victim.classname == "onslaught_controlpoint_icon" && !frag_victim.owner.isshielded);
2079 }
2080
2081 MUTATOR_HOOKFUNCTION(ons, SendWaypoint)
2082 {
2083     entity wp = M_ARGV(0, entity);
2084     entity to = M_ARGV(1, entity);
2085     int sf = M_ARGV(2, int);
2086     int wp_flag = M_ARGV(3, int);
2087
2088         if(sf & 16)
2089         {
2090                 if(wp.owner.classname == "onslaught_controlpoint")
2091                 {
2092                         entity wp_owner = wp.owner;
2093                         entity e = WaypointSprite_getviewentity(to);
2094                         if(SAME_TEAM(e, wp_owner) && GetResourceAmount(wp_owner.goalentity, RESOURCE_HEALTH) >= wp_owner.goalentity.max_health) { wp_flag |= 2; }
2095                         if(!ons_ControlPoint_Attackable(wp_owner, e.team)) { wp_flag |= 2; }
2096                 }
2097                 if(wp.owner.classname == "onslaught_generator")
2098                 {
2099                         entity wp_owner = wp.owner;
2100                         if(wp_owner.isshielded && GetResourceAmount(wp_owner, RESOURCE_HEALTH) >= wp_owner.max_health) { wp_flag |= 2; }
2101                         if(GetResourceAmount(wp_owner, RESOURCE_HEALTH) <= 0) { wp_flag |= 2; }
2102                 }
2103         }
2104
2105         M_ARGV(3, int) = wp_flag;
2106 }
2107
2108 MUTATOR_HOOKFUNCTION(ons, TurretValidateTarget)
2109 {
2110         entity turret_target = M_ARGV(1, entity);
2111
2112         if(substring(turret_target.classname, 0, 10) == "onslaught_") // don't attack onslaught targets, that's the player's job!
2113         {
2114                 M_ARGV(3, float) = -3;
2115                 return true;
2116         }
2117
2118         return false;
2119 }
2120
2121 MUTATOR_HOOKFUNCTION(ons, TurretThink)
2122 {
2123     entity turret = M_ARGV(0, entity);
2124
2125         // ONS uses somewhat backwards linking.
2126         if(turret.target)
2127         {
2128                 entity e = find(NULL, targetname, turret.target);
2129                 if (e != NULL)
2130                         turret.team = e.team;
2131         }
2132
2133         if(turret.team != turret.tur_head.team)
2134                 turret_respawn(turret);
2135 }
2136
2137
2138 // ==========
2139 // Spawnfuncs
2140 // ==========
2141
2142 /*QUAKED spawnfunc_onslaught_link (0 .5 .8) (-16 -16 -16) (16 16 16)
2143   Link between control points.
2144
2145   This entity targets two different spawnfunc_onslaught_controlpoint or spawnfunc_onslaught_generator entities, and suppresses shielding on both if they are owned by different teams.
2146
2147 keys:
2148 "target" - first control point.
2149 "target2" - second control point.
2150  */
2151 spawnfunc(onslaught_link)
2152 {
2153         if(!g_onslaught) { delete(this); return; }
2154
2155         if (this.target == "" || this.target2 == "")
2156                 objerror(this, "target and target2 must be set\n");
2157
2158         this.ons_worldlinknext = ons_worldlinklist; // link into ons_worldlinklist
2159         ons_worldlinklist = this;
2160
2161         InitializeEntity(this, ons_DelayedLinkSetup, INITPRIO_FINDTARGET);
2162         Net_LinkEntity(this, false, 0, ons_Link_Send);
2163 }
2164
2165 /*QUAKED spawnfunc_onslaught_controlpoint (0 .5 .8) (-32 -32 0) (32 32 128)
2166   Control point. Be sure to give this enough clearance so that the shootable part has room to exist
2167
2168   This should link to an spawnfunc_onslaught_controlpoint entity or spawnfunc_onslaught_generator entity.
2169
2170 keys:
2171 "targetname" - name that spawnfunc_onslaught_link entities will use to target this.
2172 "target" - target any entities that are tied to this control point, such as vehicles and buildable structure entities.
2173 "message" - name of this control point (should reflect the location in the map, such as "center bridge", "north tower", etc)
2174  */
2175
2176 spawnfunc(onslaught_controlpoint)
2177 {
2178         if(!g_onslaught) { delete(this); return; }
2179
2180         ons_ControlPoint_Setup(this);
2181 }
2182
2183 /*QUAKED spawnfunc_onslaught_generator (0 .5 .8) (-32 -32 -24) (32 32 64)
2184   Base generator.
2185
2186   spawnfunc_onslaught_link entities can target this.
2187
2188 keys:
2189 "team" - team that owns this generator (5 = red, 14 = blue, etc), MUST BE SET.
2190 "targetname" - name that spawnfunc_onslaught_link entities will use to target this.
2191  */
2192 spawnfunc(onslaught_generator)
2193 {
2194         if(!g_onslaught) { delete(this); return; }
2195         if(!this.team) { objerror(this, "team must be set"); }
2196
2197         ons_GeneratorSetup(this);
2198 }
2199
2200 // scoreboard setup
2201 void ons_ScoreRules()
2202 {
2203         CheckAllowedTeams(NULL);
2204         int teams = 0;
2205         if(c1 >= 0) teams |= BIT(0);
2206         if(c2 >= 0) teams |= BIT(1);
2207         if(c3 >= 0) teams |= BIT(2);
2208         if(c4 >= 0) teams |= BIT(3);
2209         GameRules_scoring(teams, SFL_SORT_PRIO_PRIMARY, 0, {
2210             field_team(ST_ONS_CAPS, "destroyed", SFL_SORT_PRIO_PRIMARY);
2211             field(SP_ONS_CAPS, "caps", SFL_SORT_PRIO_SECONDARY);
2212             field(SP_ONS_TAKES, "takes", 0);
2213         });
2214 }
2215
2216 void ons_DelayedInit(entity this) // Do this check with a delay so we can wait for teams to be set up
2217 {
2218         ons_ScoreRules();
2219
2220         round_handler_Spawn(Onslaught_CheckPlayers, Onslaught_CheckWinner, Onslaught_RoundStart);
2221         round_handler_Init(5, autocvar_g_onslaught_warmup, autocvar_g_onslaught_round_timelimit);
2222 }
2223
2224 void ons_Initialize()
2225 {
2226         g_onslaught = true;
2227         ons_captureshield_force = autocvar_g_onslaught_shield_force;
2228
2229         cam = new(objective_camera);
2230
2231         InitializeEntity(NULL, ons_DelayedInit, INITPRIO_GAMETYPE);
2232 }