qcsrc/common/gamemodes/gamemode/keepaway/sv_keepaway.qc

   1 #include "sv_keepaway.qh"
   2
   3 #include <common/effects/all.qh>
   4 #include <server/client.qh>
   5 #include <server/gamelog.qh>
   6 #include <server/damage.qh>
   7 #include <server/items/items.qh>
   8 #include <server/world.qh>
   9
  10 .entity ballcarried;
  11
  12 int autocvar_g_keepaway_ballcarrier_effects;
  13 float autocvar_g_keepaway_ballcarrier_damage;
  14 float autocvar_g_keepaway_ballcarrier_force;
  15 float autocvar_g_keepaway_ballcarrier_highspeed;
  16 float autocvar_g_keepaway_ballcarrier_selfdamage;
  17 float autocvar_g_keepaway_ballcarrier_selfforce;
  18 float autocvar_g_keepaway_noncarrier_damage;
  19 float autocvar_g_keepaway_noncarrier_force;
  20 float autocvar_g_keepaway_noncarrier_selfdamage;
  21 float autocvar_g_keepaway_noncarrier_selfforce;
  22 bool autocvar_g_keepaway_noncarrier_warn;
  23 int autocvar_g_keepaway_score_bckill;
  24 int autocvar_g_keepaway_score_killac;
  25 int autocvar_g_keepaway_score_timepoints;
  26 float autocvar_g_keepaway_score_timeinterval;
  27 float autocvar_g_keepawayball_damageforcescale;
  28 int autocvar_g_keepawayball_effects;
  29 float autocvar_g_keepawayball_respawntime;
  30 int autocvar_g_keepawayball_trail_color;
  31
  32 bool ka_ballcarrier_waypointsprite_visible_for_player(entity this, entity player, entity view) // runs on waypoints which are attached to ballcarriers, updates once per frame
  33 {
  34         if(view.ballcarried)
  35                 if(IS_SPEC(player))
  36                         return false; // we don't want spectators of the ballcarrier to see the attached waypoint on the top of their screen
  37
  38         // TODO: Make the ballcarrier lack a waypointsprite whenever they have the invisibility powerup
  39
  40         return true;
  41 }
  42
  43 void ka_EventLog(string mode, entity actor) // use an alias for easy changing and quick editing later
  44 {
  45         if(autocvar_sv_eventlog)
  46                 GameLogEcho(strcat(":ka:", mode, ((actor != NULL) ? (strcat(":", ftos(actor.playerid))) : "")));
  47 }
  48
  49 void ka_TouchEvent(entity this, entity toucher);
  50 void ka_RespawnBall(entity this) // runs whenever the ball needs to be relocated
  51 {
  52         if(game_stopped) return;
  53         vector oldballorigin = this.origin;
  54
  55         if(!MoveToRandomMapLocation(this, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, 10, 1024, 256))
  56         {
  57                 entity spot = SelectSpawnPoint(this, true);
  58                 setorigin(this, spot.origin);
  59                 this.angles = spot.angles;
  60         }
  61
  62         makevectors(this.angles);
  63         set_movetype(this, MOVETYPE_BOUNCE);
  64         this.velocity = '0 0 200';
  65         this.angles = '0 0 0';
  66         this.effects = autocvar_g_keepawayball_effects;
  67         settouch(this, ka_TouchEvent);
  68         setthink(this, ka_RespawnBall);
  69         this.nextthink = time + autocvar_g_keepawayball_respawntime;
  70         navigation_dynamicgoal_set(this, NULL);
  71
  72         Send_Effect(EFFECT_ELECTRO_COMBO, oldballorigin, '0 0 0', 1);
  73         Send_Effect(EFFECT_ELECTRO_COMBO, this.origin, '0 0 0', 1);
  74
  75         WaypointSprite_Spawn(WP_KaBall, 0, 0, this, '0 0 64', NULL, this.team, this, waypointsprite_attachedforcarrier, false, RADARICON_FLAGCARRIER);
  76         WaypointSprite_Ping(this.waypointsprite_attachedforcarrier);
  77
  78         sound(this, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
  79 }
  80
  81 void ka_TimeScoring(entity this)
  82 {
  83         if(this.owner.ballcarried)
  84         { // add points for holding the ball after a certain amount of time
  85                 if(autocvar_g_keepaway_score_timepoints)
  86                         GameRules_scoring_add(this.owner, SCORE, autocvar_g_keepaway_score_timepoints);
  87
  88                 GameRules_scoring_add(this.owner, KEEPAWAY_BCTIME, (autocvar_g_keepaway_score_timeinterval / 1)); // interval is divided by 1 so that time always shows "seconds"
  89                 this.nextthink = time + autocvar_g_keepaway_score_timeinterval;
  90         }
  91 }
  92
  93 void ka_TouchEvent(entity this, entity toucher) // runs any time that the ball comes in contact with something
  94 {
  95         if (!this || game_stopped)
  96                 return;
  97
  98         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  99         { // The ball fell off the map, respawn it since players can't get to it
 100                 ka_RespawnBall(this);
 101                 return;
 102         }
 103         if(toucher.ballcarried) { return; }
 104         if(IS_DEAD(toucher)) { return; }
 105         if(STAT(FROZEN, toucher)) { return; }
 106         if (!IS_PLAYER(toucher))
 107         {  // The ball just touched an object, most likely the world
 108                 Send_Effect(EFFECT_BALL_SPARKS, this.origin, '0 0 0', 1);
 109                 sound(this, CH_TRIGGER, SND_KA_TOUCH, VOL_BASE, ATTEN_NORM);
 110                 return;
 111         }
 112         else if(this.wait > time) { return; }
 113
 114         // attach the ball to the player
 115         this.owner = toucher;
 116         toucher.ballcarried = this;
 117         GameRules_scoring_vip(toucher, true);
 118         setattachment(this, toucher, "");
 119         setorigin(this, '0 0 0');
 120
 121         // make the ball invisible/unable to do anything/set up time scoring
 122         this.velocity = '0 0 0';
 123         set_movetype(this, MOVETYPE_NONE);
 124         this.effects |= EF_NODRAW;
 125         settouch(this, func_null);
 126         setthink(this, ka_TimeScoring);
 127         this.nextthink = time + autocvar_g_keepaway_score_timeinterval;
 128         this.takedamage = DAMAGE_NO;
 129         navigation_dynamicgoal_unset(this);
 130
 131         // apply effects to player
 132         toucher.glow_color = autocvar_g_keepawayball_trail_color;
 133         toucher.glow_trail = true;
 134         toucher.effects |= autocvar_g_keepaway_ballcarrier_effects;
 135
 136         // messages and sounds
 137         ka_EventLog("pickup", toucher);
 138         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_KEEPAWAY_PICKUP, toucher.netname);
 139         Send_Notification(NOTIF_ALL_EXCEPT, toucher, MSG_CENTER, CENTER_KEEPAWAY_PICKUP, toucher.netname);
 140         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_KEEPAWAY_PICKUP_SELF);
 141         sound(this.owner, CH_TRIGGER, SND_KA_PICKEDUP, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
 142
 143         // scoring
 144         GameRules_scoring_add(toucher, KEEPAWAY_PICKUPS, 1);
 145
 146         // waypoints
 147         WaypointSprite_AttachCarrier(WP_KaBallCarrier, toucher, RADARICON_FLAGCARRIER);
 148         toucher.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = ka_ballcarrier_waypointsprite_visible_for_player;
 149         WaypointSprite_UpdateRule(toucher.waypointsprite_attachedforcarrier, 0, SPRITERULE_DEFAULT);
 150         WaypointSprite_Ping(toucher.waypointsprite_attachedforcarrier);
 151         WaypointSprite_Kill(this.waypointsprite_attachedforcarrier);
 152 }
 153
 154 void ka_PlayerReset(entity player)
 155 {
 156         player.ballcarried = NULL;
 157         GameRules_scoring_vip(player, false);
 158         WaypointSprite_Kill(player.waypointsprite_attachedforcarrier);
 159
 160         // reset the player effects
 161         player.glow_trail = false;
 162         player.effects &= ~autocvar_g_keepaway_ballcarrier_effects;
 163 }
 164
 165 void ka_DropEvent(entity player) // runs any time that a player is supposed to lose the ball
 166 {
 167         entity ball = player.ballcarried;
 168
 169         if(!ball) { return; }
 170
 171         // reset the ball
 172         setattachment(ball, NULL, "");
 173         set_movetype(ball, MOVETYPE_BOUNCE);
 174         ball.wait = time + 1;
 175         settouch(ball, ka_TouchEvent);
 176         setthink(ball, ka_RespawnBall);
 177         ball.nextthink = time + autocvar_g_keepawayball_respawntime;
 178         ball.takedamage = DAMAGE_YES;
 179         ball.effects &= ~EF_NODRAW;
 180         setorigin(ball, player.origin + '0 0 10');
 181         ball.velocity = '0 0 200' + '0 100 0'*crandom() + '100 0 0'*crandom();
 182         ball.owner = NULL;
 183         navigation_dynamicgoal_set(ball, player);
 184
 185         // messages and sounds
 186         ka_EventLog("dropped", player);
 187         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_KEEPAWAY_DROPPED, player.netname);
 188         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEEPAWAY_DROPPED, player.netname);
 189         sound(NULL, CH_TRIGGER, SND_KA_DROPPED, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
 190
 191         // waypoints
 192         WaypointSprite_Spawn(WP_KaBall, 0, 0, ball, '0 0 64', NULL, ball.team, ball, waypointsprite_attachedforcarrier, false, RADARICON_FLAGCARRIER);
 193         WaypointSprite_UpdateRule(ball.waypointsprite_attachedforcarrier, 0, SPRITERULE_DEFAULT);
 194         WaypointSprite_Ping(ball.waypointsprite_attachedforcarrier);
 195
 196         ka_PlayerReset(player);
 197 }
 198
 199 .bool pushable;
 200
 201 MODEL(KA_BALL, "models/orbs/orbblue.md3");
 202
 203 void ka_RemoveBall(entity ball)
 204 {
 205         entity player = ball.owner;
 206         if (player) // it was attached
 207                 ka_PlayerReset(player);
 208         else
 209                 WaypointSprite_DetachCarrier(ball);
 210         delete(ball);
 211 }
 212
 213 void ka_RemoveBalls()
 214 {
 215         IL_EACH(g_kaballs, true,
 216         {
 217                 ka_RemoveBall(it);
 218         });
 219 }
 220
 221 void ka_SpawnBall()
 222 {
 223         entity e = new(keepawayball);
 224         setmodel(e, MDL_KA_BALL);
 225         setsize(e, '-16 -16 -20', '16 16 20'); // 20 20 20 was too big, player is only 16 16 24... gotta cheat with the Z (20) axis so that the particle isn't cut off
 226         e.damageforcescale = autocvar_g_keepawayball_damageforcescale;
 227         e.takedamage = DAMAGE_YES;
 228         e.solid = SOLID_TRIGGER;
 229         set_movetype(e, MOVETYPE_BOUNCE);
 230         e.glow_color = autocvar_g_keepawayball_trail_color;
 231         e.glow_trail = true;
 232         e.flags = FL_ITEM;
 233         IL_PUSH(g_items, e);
 234         e.pushable = true;
 235         settouch(e, ka_TouchEvent);
 236         e.owner = NULL;
 237         IL_PUSH(g_kaballs, e);
 238         navigation_dynamicgoal_init(e, false);
 239
 240         InitializeEntity(e, ka_RespawnBall, INITPRIO_SETLOCATION); // is this the right priority? Neh, I have no idea.. Well-- it works! So.
 241 }
 242
 243 void ka_SpawnBalls(int ballcount)
 244 {
 245         int realballcount = max(1, ballcount); // never allow less than 1 ball to spawn
 246         for(int j = 0; j < realballcount; ++j)
 247         {
 248                 ka_SpawnBall();
 249         }
 250 }
 251
 252 void ka_Handler_CheckBall(entity this)
 253 {
 254         if(time < game_starttime)
 255         {
 256                 if (!IL_EMPTY(g_kaballs))
 257                         ka_RemoveBalls();
 258         }
 259         else
 260         {
 261                 if (IL_EMPTY(g_kaballs))
 262                         ka_SpawnBalls(KA_BALL_COUNT); // ;)
 263         }
 264
 265         this.nextthink = time;
 266 }
 267
 268 void ka_Initialize() // run at the start of a match, initiates game mode
 269 {
 270         ka_Handler = new(ka_Handler);
 271         setthink(ka_Handler, ka_Handler_CheckBall);
 272         ka_Handler.nextthink = time;
 273 }
 274
 275
 276 // ================
 277 // Bot player logic
 278 // ================
 279
 280 void havocbot_goalrating_ball(entity this, float ratingscale, vector org)
 281 {
 282         entity ball = NULL, ball_carried = NULL;
 283
 284         // stops at last ball, prefers ball without carrier
 285         IL_EACH(g_kaballs, it.owner != this,
 286         {
 287                 if(it.owner)
 288                         ball_carried = it.owner;
 289                 else
 290                         ball = it;
 291         });
 292
 293         if(ball)
 294                 navigation_routerating(this, ball, ratingscale, 2000);
 295         else if(ball_carried)
 296                 navigation_routerating(this, ball_carried, ratingscale, 2000);
 297 }
 298
 299 void havocbot_role_ka_carrier(entity this)
 300 {
 301         if (IS_DEAD(this))
 302                 return;
 303
 304         if (navigation_goalrating_timeout(this))
 305         {
 306                 navigation_goalrating_start(this);
 307                 havocbot_goalrating_items(this, 10000, this.origin, 10000);
 308                 havocbot_goalrating_enemyplayers(this, 10000, this.origin, 10000);
 309                 havocbot_goalrating_waypoints(this, 1, this.origin, 3000);
 310                 navigation_goalrating_end(this);
 311
 312                 navigation_goalrating_timeout_set(this);
 313         }
 314
 315         if (!this.ballcarried)
 316         {
 317                 this.havocbot_role = havocbot_role_ka_collector;
 318                 navigation_goalrating_timeout_expire(this, 2);
 319         }
 320 }
 321
 322 void havocbot_role_ka_collector(entity this)
 323 {
 324         if (IS_DEAD(this))
 325                 return;
 326
 327         if (navigation_goalrating_timeout(this))
 328         {
 329                 navigation_goalrating_start(this);
 330                 havocbot_goalrating_items(this, 10000, this.origin, 10000);
 331                 havocbot_goalrating_enemyplayers(this, 500, this.origin, 10000);
 332                 havocbot_goalrating_ball(this, 8000, this.origin);
 333                 navigation_goalrating_end(this);
 334
 335                 navigation_goalrating_timeout_set(this);
 336         }
 337
 338         if (this.ballcarried)
 339         {
 340                 this.havocbot_role = havocbot_role_ka_carrier;
 341                 navigation_goalrating_timeout_expire(this, 2);
 342         }
 343 }
 344
 345
 346 // ==============
 347 // Hook Functions
 348 // ==============
 349
 350 MUTATOR_HOOKFUNCTION(ka, PlayerDies)
 351 {
 352         entity frag_attacker = M_ARGV(1, entity);
 353         entity frag_target = M_ARGV(2, entity);
 354
 355         if((frag_attacker != frag_target) && (IS_PLAYER(frag_attacker)))
 356         {
 357                 if(frag_target.ballcarried) { // add to amount of times killing carrier
 358                         GameRules_scoring_add(frag_attacker, KEEPAWAY_CARRIERKILLS, 1);
 359                         if(autocvar_g_keepaway_score_bckill) // add bckills to the score
 360                                 GameRules_scoring_add(frag_attacker, SCORE, autocvar_g_keepaway_score_bckill);
 361                 }
 362                 else if(!frag_attacker.ballcarried)
 363                         if(autocvar_g_keepaway_noncarrier_warn)
 364                                 Send_Notification(NOTIF_ONE_ONLY, frag_attacker, MSG_CENTER, CENTER_KEEPAWAY_WARN);
 365
 366                 if(frag_attacker.ballcarried) // add to amount of kills while ballcarrier
 367                         GameRules_scoring_add(frag_attacker, SCORE, autocvar_g_keepaway_score_killac);
 368         }
 369
 370         if(frag_target.ballcarried) { ka_DropEvent(frag_target); } // a player with the ball has died, drop it
 371 }
 372
 373 MUTATOR_HOOKFUNCTION(ka, GiveFragsForKill)
 374 {
 375         M_ARGV(2, float) = 0; // no frags counted in keepaway
 376         return true; // you deceptive little bugger ;3 This needs to be true in order for this function to even count.
 377 }
 378
 379 MUTATOR_HOOKFUNCTION(ka, Scores_CountFragsRemaining)
 380 {
 381         // announce remaining frags, but only when timed scoring is off
 382         return !autocvar_g_keepaway_score_timepoints;
 383 }
 384
 385 MUTATOR_HOOKFUNCTION(ka, PlayerPreThink)
 386 {
 387         entity player = M_ARGV(0, entity);
 388
 389         // clear the item used for the ball in keepaway
 390         player.items &= ~IT_KEY1;
 391
 392         // if the player has the ball, make sure they have the item for it (Used for HUD primarily)
 393         if(player.ballcarried)
 394                 player.items |= IT_KEY1;
 395 }
 396
 397 MUTATOR_HOOKFUNCTION(ka, PlayerUseKey)
 398 {
 399         entity player = M_ARGV(0, entity);
 400
 401         if(MUTATOR_RETURNVALUE == 0)
 402         if(player.ballcarried)
 403         {
 404                 ka_DropEvent(player);
 405                 return true;
 406         }
 407 }
 408
 409 MUTATOR_HOOKFUNCTION(ka, Damage_Calculate) // for changing damage and force values that are applied to players in damage.qc
 410 {
 411         entity frag_attacker = M_ARGV(1, entity);
 412         entity frag_target = M_ARGV(2, entity);
 413         float frag_damage = M_ARGV(4, float);
 414         vector frag_force = M_ARGV(6, vector);
 415
 416         if(frag_attacker.ballcarried) // if the attacker is a ballcarrier
 417         {
 418                 if(frag_target == frag_attacker) // damage done to yourself
 419                 {
 420                         frag_damage *= autocvar_g_keepaway_ballcarrier_selfdamage;
 421                         frag_force *= autocvar_g_keepaway_ballcarrier_selfforce;
 422                 }
 423                 else // damage done to noncarriers
 424                 {
 425                         frag_damage *= autocvar_g_keepaway_ballcarrier_damage;
 426                         frag_force *= autocvar_g_keepaway_ballcarrier_force;
 427                 }
 428         }
 429         else if (IS_PLAYER(frag_attacker) && !frag_target.ballcarried) // if the target is a noncarrier
 430         {
 431                 if(frag_target == frag_attacker) // damage done to yourself
 432                 {
 433                         frag_damage *= autocvar_g_keepaway_noncarrier_selfdamage;
 434                         frag_force *= autocvar_g_keepaway_noncarrier_selfforce;
 435                 }
 436                 else // damage done to other noncarriers
 437                 {
 438                         frag_damage *= autocvar_g_keepaway_noncarrier_damage;
 439                         frag_force *= autocvar_g_keepaway_noncarrier_force;
 440                 }
 441         }
 442
 443         M_ARGV(4, float) = frag_damage;
 444         M_ARGV(6, vector) = frag_force;
 445 }
 446
 447 MUTATOR_HOOKFUNCTION(ka, ClientDisconnect)
 448 {
 449         entity player = M_ARGV(0, entity);
 450
 451         if(player.ballcarried) { ka_DropEvent(player); } // a player with the ball has left the match, drop it
 452 }
 453
 454 MUTATOR_HOOKFUNCTION(ka, MakePlayerObserver)
 455 {
 456         entity player = M_ARGV(0, entity);
 457
 458         if(player.ballcarried) { ka_DropEvent(player); } // a player with the ball has left the match, drop it
 459 }
 460
 461 MUTATOR_HOOKFUNCTION(ka, PlayerPowerups)
 462 {
 463         entity player = M_ARGV(0, entity);
 464
 465         // In the future this hook is supposed to allow me to do some extra stuff with waypointsprites and invisibility powerup
 466         // So bare with me until I can fix a certain bug with ka_ballcarrier_waypointsprite_visible_for_player()
 467
 468         player.effects &= ~autocvar_g_keepaway_ballcarrier_effects;
 469
 470         if(player.ballcarried)
 471                 player.effects |= autocvar_g_keepaway_ballcarrier_effects;
 472 }
 473
 474
 475 MUTATOR_HOOKFUNCTION(ka, PlayerPhysics_UpdateStats)
 476 {
 477         entity player = M_ARGV(0, entity);
 478         // these automatically reset, no need to worry
 479
 480         if(player.ballcarried)
 481                 STAT(MOVEVARS_HIGHSPEED, player) *= autocvar_g_keepaway_ballcarrier_highspeed;
 482 }
 483
 484 MUTATOR_HOOKFUNCTION(ka, BotShouldAttack)
 485 {
 486         entity bot = M_ARGV(0, entity);
 487         entity targ = M_ARGV(1, entity);
 488
 489         // if neither player has ball then don't attack unless the ball is on the ground
 490         bool have_held_ball = false;
 491         IL_EACH(g_kaballs, it.owner,
 492         {
 493                 have_held_ball = true;
 494                 break;
 495         });
 496         if(!targ.ballcarried && !bot.ballcarried && have_held_ball)
 497                 return true;
 498 }
 499
 500 MUTATOR_HOOKFUNCTION(ka, HavocBot_ChooseRole)
 501 {
 502         entity bot = M_ARGV(0, entity);
 503
 504         if (bot.ballcarried)
 505                 bot.havocbot_role = havocbot_role_ka_carrier;
 506         else
 507                 bot.havocbot_role = havocbot_role_ka_collector;
 508         return true;
 509 }
 510
 511 MUTATOR_HOOKFUNCTION(ka, DropSpecialItems)
 512 {
 513         entity frag_target = M_ARGV(0, entity);
 514
 515         if(frag_target.ballcarried)
 516                 ka_DropEvent(frag_target);
 517 }