qcsrc/common/gamemodes/gamemode/keepaway/keepaway.qc

   1 #include "keepaway.qh"
   2
   3 // TODO: keepaway
   4 #ifdef SVQC
   5 #include <common/effects/all.qh>
   6
   7 .entity ballcarried;
   8
   9 int autocvar_g_keepaway_ballcarrier_effects;
  10 float autocvar_g_keepaway_ballcarrier_damage;
  11 float autocvar_g_keepaway_ballcarrier_force;
  12 float autocvar_g_keepaway_ballcarrier_highspeed;
  13 float autocvar_g_keepaway_ballcarrier_selfdamage;
  14 float autocvar_g_keepaway_ballcarrier_selfforce;
  15 float autocvar_g_keepaway_noncarrier_damage;
  16 float autocvar_g_keepaway_noncarrier_force;
  17 float autocvar_g_keepaway_noncarrier_selfdamage;
  18 float autocvar_g_keepaway_noncarrier_selfforce;
  19 bool autocvar_g_keepaway_noncarrier_warn;
  20 int autocvar_g_keepaway_score_bckill;
  21 int autocvar_g_keepaway_score_killac;
  22 int autocvar_g_keepaway_score_timepoints;
  23 float autocvar_g_keepaway_score_timeinterval;
  24 float autocvar_g_keepawayball_damageforcescale;
  25 int autocvar_g_keepawayball_effects;
  26 float autocvar_g_keepawayball_respawntime;
  27 int autocvar_g_keepawayball_trail_color;
  28
  29 bool ka_ballcarrier_waypointsprite_visible_for_player(entity this, entity player, entity view) // runs on waypoints which are attached to ballcarriers, updates once per frame
  30 {
  31         if(view.ballcarried)
  32                 if(IS_SPEC(player))
  33                         return false; // we don't want spectators of the ballcarrier to see the attached waypoint on the top of their screen
  34
  35         // TODO: Make the ballcarrier lack a waypointsprite whenever they have the invisibility powerup
  36
  37         return true;
  38 }
  39
  40 void ka_EventLog(string mode, entity actor) // use an alias for easy changing and quick editing later
  41 {
  42         if(autocvar_sv_eventlog)
  43                 GameLogEcho(strcat(":ka:", mode, ((actor != NULL) ? (strcat(":", ftos(actor.playerid))) : "")));
  44 }
  45
  46 void ka_TouchEvent(entity this, entity toucher);
  47 void ka_RespawnBall(entity this) // runs whenever the ball needs to be relocated
  48 {
  49         if(game_stopped) return;
  50         vector oldballorigin = this.origin;
  51
  52         if(!MoveToRandomMapLocation(this, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, 10, 1024, 256))
  53         {
  54                 entity spot = SelectSpawnPoint(this, true);
  55                 setorigin(this, spot.origin);
  56                 this.angles = spot.angles;
  57         }
  58
  59         makevectors(this.angles);
  60         set_movetype(this, MOVETYPE_BOUNCE);
  61         this.velocity = '0 0 200';
  62         this.angles = '0 0 0';
  63         this.effects = autocvar_g_keepawayball_effects;
  64         settouch(this, ka_TouchEvent);
  65         setthink(this, ka_RespawnBall);
  66         this.nextthink = time + autocvar_g_keepawayball_respawntime;
  67         navigation_dynamicgoal_set(this);
  68
  69         Send_Effect(EFFECT_ELECTRO_COMBO, oldballorigin, '0 0 0', 1);
  70         Send_Effect(EFFECT_ELECTRO_COMBO, this.origin, '0 0 0', 1);
  71
  72         WaypointSprite_Spawn(WP_KaBall, 0, 0, this, '0 0 64', NULL, this.team, this, waypointsprite_attachedforcarrier, false, RADARICON_FLAGCARRIER);
  73         WaypointSprite_Ping(this.waypointsprite_attachedforcarrier);
  74
  75         sound(this, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
  76 }
  77
  78 void ka_TimeScoring(entity this)
  79 {
  80         if(this.owner.ballcarried)
  81         { // add points for holding the ball after a certain amount of time
  82                 if(autocvar_g_keepaway_score_timepoints)
  83                         GameRules_scoring_add(this.owner, SCORE, autocvar_g_keepaway_score_timepoints);
  84
  85                 GameRules_scoring_add(this.owner, KEEPAWAY_BCTIME, (autocvar_g_keepaway_score_timeinterval / 1)); // interval is divided by 1 so that time always shows "seconds"
  86                 this.nextthink = time + autocvar_g_keepaway_score_timeinterval;
  87         }
  88 }
  89
  90 void ka_TouchEvent(entity this, entity toucher) // runs any time that the ball comes in contact with something
  91 {
  92         if (!this || game_stopped)
  93                 return;
  94
  95         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  96         { // The ball fell off the map, respawn it since players can't get to it
  97                 ka_RespawnBall(this);
  98                 return;
  99         }
 100         if(IS_DEAD(toucher)) { return; }
 101         if(STAT(FROZEN, toucher)) { return; }
 102         if (!IS_PLAYER(toucher))
 103         {  // The ball just touched an object, most likely the world
 104                 Send_Effect(EFFECT_BALL_SPARKS, this.origin, '0 0 0', 1);
 105                 sound(this, CH_TRIGGER, SND_KA_TOUCH, VOL_BASE, ATTEN_NORM);
 106                 return;
 107         }
 108         else if(this.wait > time) { return; }
 109
 110         // attach the ball to the player
 111         this.owner = toucher;
 112         toucher.ballcarried = this;
 113         GameRules_scoring_vip(toucher, true);
 114         setattachment(this, toucher, "");
 115         setorigin(this, '0 0 0');
 116
 117         // make the ball invisible/unable to do anything/set up time scoring
 118         this.velocity = '0 0 0';
 119         set_movetype(this, MOVETYPE_NONE);
 120         this.effects |= EF_NODRAW;
 121         settouch(this, func_null);
 122         setthink(this, ka_TimeScoring);
 123         this.nextthink = time + autocvar_g_keepaway_score_timeinterval;
 124         this.takedamage = DAMAGE_NO;
 125         navigation_dynamicgoal_unset(this);
 126
 127         // apply effects to player
 128         toucher.glow_color = autocvar_g_keepawayball_trail_color;
 129         toucher.glow_trail = true;
 130         toucher.effects |= autocvar_g_keepaway_ballcarrier_effects;
 131
 132         // messages and sounds
 133         ka_EventLog("pickup", toucher);
 134         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_KEEPAWAY_PICKUP, toucher.netname);
 135         Send_Notification(NOTIF_ALL_EXCEPT, toucher, MSG_CENTER, CENTER_KEEPAWAY_PICKUP, toucher.netname);
 136         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_KEEPAWAY_PICKUP_SELF);
 137         sound(this.owner, CH_TRIGGER, SND_KA_PICKEDUP, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
 138
 139         // scoring
 140         GameRules_scoring_add(toucher, KEEPAWAY_PICKUPS, 1);
 141
 142         // waypoints
 143         WaypointSprite_AttachCarrier(WP_KaBallCarrier, toucher, RADARICON_FLAGCARRIER);
 144         toucher.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = ka_ballcarrier_waypointsprite_visible_for_player;
 145         WaypointSprite_UpdateRule(toucher.waypointsprite_attachedforcarrier, 0, SPRITERULE_DEFAULT);
 146         WaypointSprite_Ping(toucher.waypointsprite_attachedforcarrier);
 147         WaypointSprite_Kill(this.waypointsprite_attachedforcarrier);
 148 }
 149
 150 void ka_PlayerReset(entity plyr)
 151 {
 152         plyr.ballcarried = NULL;
 153         GameRules_scoring_vip(plyr, false);
 154         WaypointSprite_Kill(plyr.waypointsprite_attachedforcarrier);
 155
 156         // reset the player effects
 157         plyr.glow_trail = false;
 158         plyr.effects &= ~autocvar_g_keepaway_ballcarrier_effects;
 159 }
 160
 161 void ka_DropEvent(entity plyr) // runs any time that a player is supposed to lose the ball
 162 {
 163         entity ball;
 164         ball = plyr.ballcarried;
 165
 166         if(!ball) { return; }
 167
 168         // reset the ball
 169         setattachment(ball, NULL, "");
 170         set_movetype(ball, MOVETYPE_BOUNCE);
 171         ball.wait = time + 1;
 172         settouch(ball, ka_TouchEvent);
 173         setthink(ball, ka_RespawnBall);
 174         ball.nextthink = time + autocvar_g_keepawayball_respawntime;
 175         ball.takedamage = DAMAGE_YES;
 176         ball.effects &= ~EF_NODRAW;
 177         setorigin(ball, plyr.origin + '0 0 10');
 178         ball.velocity = '0 0 200' + '0 100 0'*crandom() + '100 0 0'*crandom();
 179         ball.owner = NULL;
 180         navigation_dynamicgoal_set(ball);
 181
 182         // messages and sounds
 183         ka_EventLog("dropped", plyr);
 184         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_KEEPAWAY_DROPPED, plyr.netname);
 185         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEEPAWAY_DROPPED, plyr.netname);
 186         sound(NULL, CH_TRIGGER, SND_KA_DROPPED, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
 187
 188         // waypoints
 189         WaypointSprite_Spawn(WP_KaBall, 0, 0, ball, '0 0 64', NULL, ball.team, ball, waypointsprite_attachedforcarrier, false, RADARICON_FLAGCARRIER);
 190         WaypointSprite_UpdateRule(ball.waypointsprite_attachedforcarrier, 0, SPRITERULE_DEFAULT);
 191         WaypointSprite_Ping(ball.waypointsprite_attachedforcarrier);
 192
 193         ka_PlayerReset(plyr);
 194 }
 195
 196 .bool pushable;
 197
 198 MODEL(KA_BALL, "models/orbs/orbblue.md3");
 199
 200 void ka_RemoveBall()
 201 {
 202         entity plyr = ka_ball.owner;
 203         if (plyr) // it was attached
 204                 ka_PlayerReset(plyr);
 205         else
 206                 WaypointSprite_DetachCarrier(ka_ball);
 207         delete(ka_ball);
 208         ka_ball = NULL;
 209 }
 210
 211 void ka_SpawnBall()
 212 {
 213         entity e = new(keepawayball);
 214         setmodel(e, MDL_KA_BALL);
 215         setsize(e, '-16 -16 -20', '16 16 20'); // 20 20 20 was too big, player is only 16 16 24... gotta cheat with the Z (20) axis so that the particle isn't cut off
 216         e.damageforcescale = autocvar_g_keepawayball_damageforcescale;
 217         e.takedamage = DAMAGE_YES;
 218         e.solid = SOLID_TRIGGER;
 219         set_movetype(e, MOVETYPE_BOUNCE);
 220         e.glow_color = autocvar_g_keepawayball_trail_color;
 221         e.glow_trail = true;
 222         e.flags = FL_ITEM;
 223         IL_PUSH(g_items, e);
 224         e.pushable = true;
 225         settouch(e, ka_TouchEvent);
 226         e.owner = NULL;
 227         ka_ball = e;
 228         navigation_dynamicgoal_init(ka_ball, false);
 229
 230         InitializeEntity(e, ka_RespawnBall, INITPRIO_SETLOCATION); // is this the right priority? Neh, I have no idea.. Well-- it works! So.
 231 }
 232
 233 void ka_Handler_CheckBall(entity this)
 234 {
 235         if(time < game_starttime)
 236         {
 237                 if (ka_ball)
 238                         ka_RemoveBall();
 239         }
 240         else
 241         {
 242                 if (!ka_ball)
 243                         ka_SpawnBall();
 244         }
 245
 246         this.nextthink = time;
 247 }
 248
 249 void ka_Initialize() // run at the start of a match, initiates game mode
 250 {
 251         ka_Handler = new(ka_Handler);
 252         setthink(ka_Handler, ka_Handler_CheckBall);
 253         ka_Handler.nextthink = time;
 254 }
 255
 256
 257 // ================
 258 // Bot player logic
 259 // ================
 260
 261 void havocbot_goalrating_ball(entity this, float ratingscale, vector org)
 262 {
 263         float t;
 264         entity ball_owner;
 265         ball_owner = ka_ball.owner;
 266
 267         if (ball_owner == this)
 268                 return;
 269
 270         // If ball is carried by player then hunt them down.
 271         if (ball_owner)
 272         {
 273                 t = (GetResourceAmount(this, RESOURCE_HEALTH) + GetResourceAmount(this, RESOURCE_ARMOR)) / (GetResourceAmount(ball_owner, RESOURCE_HEALTH) + GetResourceAmount(ball_owner, RESOURCE_ARMOR));
 274                 navigation_routerating(this, ball_owner, t * ratingscale, 2000);
 275         }
 276         else // Ball has been dropped so collect.
 277                 navigation_routerating(this, ka_ball, ratingscale, 2000);
 278 }
 279
 280 void havocbot_role_ka_carrier(entity this)
 281 {
 282         if (IS_DEAD(this))
 283                 return;
 284
 285         if (navigation_goalrating_timeout(this))
 286         {
 287                 navigation_goalrating_start(this);
 288                 havocbot_goalrating_items(this, 10000, this.origin, 10000);
 289                 havocbot_goalrating_enemyplayers(this, 20000, this.origin, 10000);
 290                 havocbot_goalrating_waypoints(this, 1, this.origin, 3000);
 291                 navigation_goalrating_end(this);
 292
 293                 navigation_goalrating_timeout_set(this);
 294         }
 295
 296         if (!this.ballcarried)
 297         {
 298                 this.havocbot_role = havocbot_role_ka_collector;
 299                 navigation_goalrating_timeout_expire(this, 2);
 300         }
 301 }
 302
 303 void havocbot_role_ka_collector(entity this)
 304 {
 305         if (IS_DEAD(this))
 306                 return;
 307
 308         if (navigation_goalrating_timeout(this))
 309         {
 310                 navigation_goalrating_start(this);
 311                 havocbot_goalrating_items(this, 10000, this.origin, 10000);
 312                 havocbot_goalrating_enemyplayers(this, 1000, this.origin, 10000);
 313                 havocbot_goalrating_ball(this, 20000, this.origin);
 314                 navigation_goalrating_end(this);
 315
 316                 navigation_goalrating_timeout_set(this);
 317         }
 318
 319         if (this.ballcarried)
 320         {
 321                 this.havocbot_role = havocbot_role_ka_carrier;
 322                 navigation_goalrating_timeout_expire(this, 2);
 323         }
 324 }
 325
 326
 327 // ==============
 328 // Hook Functions
 329 // ==============
 330
 331 MUTATOR_HOOKFUNCTION(ka, PlayerDies)
 332 {
 333         entity frag_attacker = M_ARGV(1, entity);
 334         entity frag_target = M_ARGV(2, entity);
 335
 336         if((frag_attacker != frag_target) && (IS_PLAYER(frag_attacker)))
 337         {
 338                 if(frag_target.ballcarried) { // add to amount of times killing carrier
 339                         GameRules_scoring_add(frag_attacker, KEEPAWAY_CARRIERKILLS, 1);
 340                         if(autocvar_g_keepaway_score_bckill) // add bckills to the score
 341                                 GameRules_scoring_add(frag_attacker, SCORE, autocvar_g_keepaway_score_bckill);
 342                 }
 343                 else if(!frag_attacker.ballcarried)
 344                         if(autocvar_g_keepaway_noncarrier_warn)
 345                                 Send_Notification(NOTIF_ONE_ONLY, frag_attacker, MSG_CENTER, CENTER_KEEPAWAY_WARN);
 346
 347                 if(frag_attacker.ballcarried) // add to amount of kills while ballcarrier
 348                         GameRules_scoring_add(frag_attacker, SCORE, autocvar_g_keepaway_score_killac);
 349         }
 350
 351         if(frag_target.ballcarried) { ka_DropEvent(frag_target); } // a player with the ball has died, drop it
 352 }
 353
 354 MUTATOR_HOOKFUNCTION(ka, GiveFragsForKill)
 355 {
 356         M_ARGV(2, float) = 0; // no frags counted in keepaway
 357         return true; // you deceptive little bugger ;3 This needs to be true in order for this function to even count.
 358 }
 359
 360 MUTATOR_HOOKFUNCTION(ka, PlayerPreThink)
 361 {
 362         entity player = M_ARGV(0, entity);
 363
 364         // clear the item used for the ball in keepaway
 365         player.items &= ~IT_KEY1;
 366
 367         // if the player has the ball, make sure they have the item for it (Used for HUD primarily)
 368         if(player.ballcarried)
 369                 player.items |= IT_KEY1;
 370 }
 371
 372 MUTATOR_HOOKFUNCTION(ka, PlayerUseKey)
 373 {
 374         entity player = M_ARGV(0, entity);
 375
 376         if(MUTATOR_RETURNVALUE == 0)
 377         if(player.ballcarried)
 378         {
 379                 ka_DropEvent(player);
 380                 return true;
 381         }
 382 }
 383
 384 MUTATOR_HOOKFUNCTION(ka, Damage_Calculate) // for changing damage and force values that are applied to players in g_damage.qc
 385 {
 386         entity frag_attacker = M_ARGV(1, entity);
 387         entity frag_target = M_ARGV(2, entity);
 388         float frag_damage = M_ARGV(4, float);
 389         vector frag_force = M_ARGV(6, vector);
 390
 391         if(frag_attacker.ballcarried) // if the attacker is a ballcarrier
 392         {
 393                 if(frag_target == frag_attacker) // damage done to yourself
 394                 {
 395                         frag_damage *= autocvar_g_keepaway_ballcarrier_selfdamage;
 396                         frag_force *= autocvar_g_keepaway_ballcarrier_selfforce;
 397                 }
 398                 else // damage done to noncarriers
 399                 {
 400                         frag_damage *= autocvar_g_keepaway_ballcarrier_damage;
 401                         frag_force *= autocvar_g_keepaway_ballcarrier_force;
 402                 }
 403         }
 404         else if (!frag_target.ballcarried) // if the target is a noncarrier
 405         {
 406                 if(frag_target == frag_attacker) // damage done to yourself
 407                 {
 408                         frag_damage *= autocvar_g_keepaway_noncarrier_selfdamage;
 409                         frag_force *= autocvar_g_keepaway_noncarrier_selfforce;
 410                 }
 411                 else // damage done to other noncarriers
 412                 {
 413                         frag_damage *= autocvar_g_keepaway_noncarrier_damage;
 414                         frag_force *= autocvar_g_keepaway_noncarrier_force;
 415                 }
 416         }
 417
 418         M_ARGV(4, float) = frag_damage;
 419         M_ARGV(6, vector) = frag_force;
 420 }
 421
 422 MUTATOR_HOOKFUNCTION(ka, ClientDisconnect)
 423 {
 424         entity player = M_ARGV(0, entity);
 425
 426         if(player.ballcarried) { ka_DropEvent(player); } // a player with the ball has left the match, drop it
 427 }
 428
 429 MUTATOR_HOOKFUNCTION(ka, MakePlayerObserver)
 430 {
 431         entity player = M_ARGV(0, entity);
 432
 433         if(player.ballcarried) { ka_DropEvent(player); } // a player with the ball has left the match, drop it
 434 }
 435
 436 MUTATOR_HOOKFUNCTION(ka, PlayerPowerups)
 437 {
 438         entity player = M_ARGV(0, entity);
 439
 440         // In the future this hook is supposed to allow me to do some extra stuff with waypointsprites and invisibility powerup
 441         // So bare with me until I can fix a certain bug with ka_ballcarrier_waypointsprite_visible_for_player()
 442
 443         player.effects &= ~autocvar_g_keepaway_ballcarrier_effects;
 444
 445         if(player.ballcarried)
 446                 player.effects |= autocvar_g_keepaway_ballcarrier_effects;
 447 }
 448
 449
 450 MUTATOR_HOOKFUNCTION(ka, PlayerPhysics_UpdateStats)
 451 {
 452         entity player = M_ARGV(0, entity);
 453         // these automatically reset, no need to worry
 454
 455         if(player.ballcarried)
 456                 STAT(MOVEVARS_HIGHSPEED, player) *= autocvar_g_keepaway_ballcarrier_highspeed;
 457 }
 458
 459 MUTATOR_HOOKFUNCTION(ka, BotShouldAttack)
 460 {
 461         entity bot = M_ARGV(0, entity);
 462         entity targ = M_ARGV(1, entity);
 463
 464         // if neither player has ball then don't attack unless the ball is on the ground
 465         if(!targ.ballcarried && !bot.ballcarried && ka_ball.owner)
 466                 return true;
 467 }
 468
 469 MUTATOR_HOOKFUNCTION(ka, HavocBot_ChooseRole)
 470 {
 471         entity bot = M_ARGV(0, entity);
 472
 473         if (bot.ballcarried)
 474                 bot.havocbot_role = havocbot_role_ka_carrier;
 475         else
 476                 bot.havocbot_role = havocbot_role_ka_collector;
 477         return true;
 478 }
 479
 480 MUTATOR_HOOKFUNCTION(ka, DropSpecialItems)
 481 {
 482         entity frag_target = M_ARGV(0, entity);
 483
 484         if(frag_target.ballcarried)
 485                 ka_DropEvent(frag_target);
 486 }
 487
 488 #endif