qcsrc/common/gamemodes/gamemode/cts/sv_cts.qc

   1 #include "sv_cts.qh"
   2
   3 #include <server/client.qh>
   4 #include <server/race.qh>
   5 #include <server/g_world.qh>
   6 #include <server/gamelog.qh>
   7 #include <server/items/spawning.qh>
   8 #include <common/mapobjects/triggers.qh>
   9
  10 float autocvar_g_cts_finish_kill_delay;
  11 bool autocvar_g_cts_selfdamage;
  12 bool autocvar_g_cts_removeprojectiles;
  13
  14 // legacy bot roles
  15 .float race_checkpoint;
  16 void havocbot_role_cts(entity this)
  17 {
  18         if(IS_DEAD(this))
  19                 return;
  20
  21         if (navigation_goalrating_timeout(this))
  22         {
  23                 navigation_goalrating_start(this);
  24
  25                 bool raw_touch_check = true;
  26                 int cp = this.race_checkpoint;
  27
  28                 LABEL(search_racecheckpoints)
  29                 IL_EACH(g_racecheckpoints, true,
  30                 {
  31                         if(it.cnt == cp || cp == -1)
  32                         {
  33                                 // redirect bot to next goal if it touched the waypoint of an untouchable checkpoint
  34                                 // e.g. checkpoint in front of Stormkeep's warpzone
  35                                 // the same workaround is applied in Race game mode
  36                                 if (raw_touch_check && vdist(this.origin - it.nearestwaypoint.origin, <, 30))
  37                                 {
  38                                         cp = race_NextCheckpoint(cp);
  39                                         raw_touch_check = false;
  40                                         goto search_racecheckpoints;
  41                                 }
  42                                 navigation_routerating(this, it, 1000000, 5000);
  43                         }
  44                 });
  45
  46                 navigation_goalrating_end(this);
  47
  48                 navigation_goalrating_timeout_set(this);
  49         }
  50 }
  51
  52 void cts_ScoreRules()
  53 {
  54     GameRules_score_enabled(false);
  55     GameRules_scoring(0, 0, 0, {
  56         if (g_race_qualifying) {
  57             field(SP_RACE_FASTEST, "fastest", SFL_SORT_PRIO_PRIMARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  58         } else {
  59             field(SP_RACE_LAPS, "laps", SFL_SORT_PRIO_PRIMARY);
  60             field(SP_RACE_TIME, "time", SFL_SORT_PRIO_SECONDARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  61             field(SP_RACE_FASTEST, "fastest", SFL_LOWER_IS_BETTER | SFL_TIME);
  62         }
  63     });
  64 }
  65
  66 void cts_EventLog(string mode, entity actor) // use an alias for easy changing and quick editing later
  67 {
  68         if(autocvar_sv_eventlog)
  69                 GameLogEcho(strcat(":cts:", mode, ":", ((actor != NULL) ? (strcat(":", ftos(actor.playerid))) : "")));
  70 }
  71
  72 MUTATOR_HOOKFUNCTION(cts, PlayerPhysics)
  73 {
  74         entity player = M_ARGV(0, entity);
  75         float dt = M_ARGV(1, float);
  76
  77         player.race_movetime_frac += dt;
  78         float f = floor(player.race_movetime_frac);
  79         player.race_movetime_frac -= f;
  80         player.race_movetime_count += f;
  81         player.race_movetime = player.race_movetime_frac + player.race_movetime_count;
  82
  83         if(IS_PLAYER(player))
  84         {
  85                 if (player.race_penalty)
  86                         if (time > player.race_penalty)
  87                                 player.race_penalty = 0;
  88                 if(player.race_penalty)
  89                 {
  90                         player.velocity = '0 0 0';
  91                         set_movetype(player, MOVETYPE_NONE);
  92                         player.disableclientprediction = 2;
  93                 }
  94         }
  95
  96         // force kbd movement for fairness
  97         float wishspeed;
  98         vector wishvel;
  99
 100         // if record times matter
 101         // ensure nothing EVIL is being done (i.e. div0_evade)
 102         // this hinders joystick users though
 103         // but it still gives SOME analog control
 104         wishvel.x = fabs(CS(player).movement.x);
 105         wishvel.y = fabs(CS(player).movement.y);
 106         if(wishvel.x != 0 && wishvel.y != 0 && wishvel.x != wishvel.y)
 107         {
 108                 wishvel.z = 0;
 109                 wishspeed = vlen(wishvel);
 110                 if(wishvel.x >= 2 * wishvel.y)
 111                 {
 112                         // pure X motion
 113                         if(CS(player).movement.x > 0)
 114                                 CS(player).movement_x = wishspeed;
 115                         else
 116                                 CS(player).movement_x = -wishspeed;
 117                         CS(player).movement_y = 0;
 118                 }
 119                 else if(wishvel.y >= 2 * wishvel.x)
 120                 {
 121                         // pure Y motion
 122                         CS(player).movement_x = 0;
 123                         if(CS(player).movement.y > 0)
 124                                 CS(player).movement_y = wishspeed;
 125                         else
 126                                 CS(player).movement_y = -wishspeed;
 127                 }
 128                 else
 129                 {
 130                         // diagonal
 131                         if(CS(player).movement.x > 0)
 132                                 CS(player).movement_x = M_SQRT1_2 * wishspeed;
 133                         else
 134                                 CS(player).movement_x = -M_SQRT1_2 * wishspeed;
 135                         if(CS(player).movement.y > 0)
 136                                 CS(player).movement_y = M_SQRT1_2 * wishspeed;
 137                         else
 138                                 CS(player).movement_y = -M_SQRT1_2 * wishspeed;
 139                 }
 140         }
 141 }
 142
 143 MUTATOR_HOOKFUNCTION(cts, reset_map_global)
 144 {
 145         float s;
 146
 147         Score_NicePrint(NULL);
 148
 149         race_ClearRecords();
 150         PlayerScore_Sort(race_place, 0, 1, 0);
 151
 152         FOREACH_CLIENT(true, {
 153                 if(it.race_place)
 154                 {
 155                         s = GameRules_scoring_add(it, RACE_FASTEST, 0);
 156                         if(!s)
 157                                 it.race_place = 0;
 158                 }
 159                 cts_EventLog(ftos(it.race_place), it);
 160         });
 161
 162         if(g_race_qualifying == 2)
 163         {
 164                 g_race_qualifying = 0;
 165                 independent_players = 0;
 166                 cvar_set("fraglimit", ftos(race_fraglimit));
 167                 cvar_set("leadlimit", ftos(race_leadlimit));
 168                 cvar_set("timelimit", ftos(race_timelimit));
 169                 cts_ScoreRules();
 170         }
 171 }
 172
 173 MUTATOR_HOOKFUNCTION(cts, ClientConnect)
 174 {
 175         entity player = M_ARGV(0, entity);
 176
 177         race_PreparePlayer(player);
 178         player.race_checkpoint = -1;
 179
 180         if(IS_REAL_CLIENT(player))
 181         {
 182                 string rr = CTS_RECORD;
 183
 184                 msg_entity = player;
 185                 race_send_recordtime(MSG_ONE);
 186                 race_send_speedaward(MSG_ONE);
 187
 188                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
 189                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
 190                 race_send_speedaward_alltimebest(MSG_ONE);
 191
 192                 float i;
 193                 int m = min(RANKINGS_CNT, autocvar_g_cts_send_rankings_cnt);
 194                 race_send_rankings_cnt(MSG_ONE);
 195                 for (i = 1; i <= m; ++i)
 196                 {
 197                         race_SendRankings(i, 0, 0, MSG_ONE);
 198                 }
 199         }
 200 }
 201
 202 MUTATOR_HOOKFUNCTION(cts, AbortSpeedrun)
 203 {
 204         entity player = M_ARGV(0, entity);
 205
 206         if(autocvar_g_allow_checkpoints)
 207                 race_PreparePlayer(player); // nice try
 208 }
 209
 210 MUTATOR_HOOKFUNCTION(cts, MakePlayerObserver)
 211 {
 212         entity player = M_ARGV(0, entity);
 213
 214         if(GameRules_scoring_add(player, RACE_FASTEST, 0))
 215                 player.frags = FRAGS_PLAYER_OUT_OF_GAME;
 216         else
 217                 player.frags = FRAGS_SPECTATOR;
 218
 219         race_PreparePlayer(player);
 220         player.race_checkpoint = -1;
 221 }
 222
 223 MUTATOR_HOOKFUNCTION(cts, PlayerSpawn)
 224 {
 225         entity player = M_ARGV(0, entity);
 226         entity spawn_spot = M_ARGV(1, entity);
 227
 228         if(spawn_spot.target == "")
 229                 // Emergency: this wasn't a real spawnpoint. Can this ever happen?
 230                 race_PreparePlayer(player);
 231
 232         // if we need to respawn, do it right
 233         player.race_respawn_checkpoint = player.race_checkpoint;
 234         player.race_respawn_spotref = spawn_spot;
 235
 236         player.race_place = 0;
 237 }
 238
 239 MUTATOR_HOOKFUNCTION(cts, PutClientInServer)
 240 {
 241         entity player = M_ARGV(0, entity);
 242
 243         if(IS_PLAYER(player))
 244         if(!game_stopped)
 245         {
 246                 if(CS(player).killcount == FRAGS_SPECTATOR /* initial spawn */ || g_race_qualifying) // spawn
 247                         race_PreparePlayer(player);
 248                 else // respawn
 249                         race_RetractPlayer(player);
 250
 251                 race_AbandonRaceCheck(player);
 252         }
 253 }
 254
 255 MUTATOR_HOOKFUNCTION(cts, PlayerDies)
 256 {
 257         entity frag_target = M_ARGV(2, entity);
 258
 259         frag_target.respawn_flags |= RESPAWN_FORCE;
 260         race_AbandonRaceCheck(frag_target);
 261
 262         if(autocvar_g_cts_removeprojectiles)
 263         {
 264                 IL_EACH(g_projectiles, it.owner == frag_target && (it.flags & FL_PROJECTILE),
 265                 {
 266                         delete(it);
 267                 });
 268         }
 269 }
 270
 271 MUTATOR_HOOKFUNCTION(cts, HavocBot_ChooseRole)
 272 {
 273         entity bot = M_ARGV(0, entity);
 274
 275         bot.havocbot_role = havocbot_role_cts;
 276         return true;
 277 }
 278
 279 MUTATOR_HOOKFUNCTION(cts, GetPressedKeys)
 280 {
 281         entity player = M_ARGV(0, entity);
 282
 283         if(CS(player).cvar_cl_allow_uidtracking == 1 && CS(player).cvar_cl_allow_uid2name == 1)
 284         {
 285                 if (!player.stored_netname)
 286                         player.stored_netname = strzone(uid2name(player.crypto_idfp));
 287                 if(player.stored_netname != player.netname)
 288                 {
 289                         db_put(ServerProgsDB, strcat("/uid2name/", player.crypto_idfp), player.netname);
 290                         strcpy(player.stored_netname, player.netname);
 291                 }
 292         }
 293
 294         if (!IS_OBSERVER(player))
 295         {
 296                 if(vdist(player.velocity - player.velocity_z * '0 0 1', >, speedaward_speed))
 297                 {
 298                         speedaward_speed = vlen(player.velocity - player.velocity_z * '0 0 1');
 299                         speedaward_holder = player.netname;
 300                         speedaward_uid = player.crypto_idfp;
 301                         speedaward_lastupdate = time;
 302                 }
 303                 if (speedaward_speed > speedaward_lastsent && time - speedaward_lastupdate > 1)
 304                 {
 305                         string rr = CTS_RECORD;
 306                         race_send_speedaward(MSG_ALL);
 307                         speedaward_lastsent = speedaward_speed;
 308                         if (speedaward_speed > speedaward_alltimebest && speedaward_uid != "")
 309                         {
 310                                 speedaward_alltimebest = speedaward_speed;
 311                                 speedaward_alltimebest_holder = speedaward_holder;
 312                                 speedaward_alltimebest_uid = speedaward_uid;
 313                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed"), ftos(speedaward_alltimebest));
 314                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp"), speedaward_alltimebest_uid);
 315                                 race_send_speedaward_alltimebest(MSG_ALL);
 316                         }
 317                 }
 318         }
 319 }
 320
 321 MUTATOR_HOOKFUNCTION(cts, ForbidThrowCurrentWeapon)
 322 {
 323         // no weapon dropping in CTS
 324         return true;
 325 }
 326
 327 MUTATOR_HOOKFUNCTION(cts, FilterItem)
 328 {
 329         entity item = M_ARGV(0, entity);
 330
 331         if (Item_IsLoot(item))
 332         {
 333                 return true;
 334         }
 335 }
 336
 337 MUTATOR_HOOKFUNCTION(cts, Damage_Calculate)
 338 {
 339         entity frag_attacker = M_ARGV(1, entity);
 340         entity frag_target = M_ARGV(2, entity);
 341         float frag_deathtype = M_ARGV(3, float);
 342         float frag_damage = M_ARGV(4, float);
 343
 344         if(frag_target == frag_attacker || frag_deathtype == DEATH_FALL.m_id)
 345         if(!autocvar_g_cts_selfdamage)
 346         {
 347                 frag_damage = 0;
 348                 M_ARGV(4, float) = frag_damage;
 349         }
 350 }
 351
 352 MUTATOR_HOOKFUNCTION(cts, ForbidPlayerScore_Clear)
 353 {
 354         return true; // in CTS, you don't lose score by observing
 355 }
 356
 357 MUTATOR_HOOKFUNCTION(cts, GetRecords)
 358 {
 359         int record_page = M_ARGV(0, int);
 360         string ret_string = M_ARGV(1, string);
 361
 362         for(int i = record_page * 200; i < MapInfo_count && i < record_page * 200 + 200; ++i)
 363         {
 364                 if(MapInfo_Get_ByID(i))
 365                 {
 366                         float r = race_readTime(MapInfo_Map_bspname, 1);
 367
 368                         if(!r)
 369                                 continue;
 370
 371                         string h = race_readName(MapInfo_Map_bspname, 1);
 372                         ret_string = strcat(ret_string, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
 373                 }
 374         }
 375
 376         M_ARGV(1, string) = ret_string;
 377 }
 378
 379 MUTATOR_HOOKFUNCTION(cts, ClientKill)
 380 {
 381         M_ARGV(1, float) = 0; // kill delay
 382 }
 383
 384 MUTATOR_HOOKFUNCTION(cts, Race_FinalCheckpoint)
 385 {
 386         entity player = M_ARGV(0, entity);
 387
 388         // useful to prevent cheating by running back to the start line and starting out with more speed
 389         if(autocvar_g_cts_finish_kill_delay)
 390                 ClientKill_Silent(player, autocvar_g_cts_finish_kill_delay);
 391 }
 392
 393 MUTATOR_HOOKFUNCTION(cts, HideTeamNagger)
 394 {
 395         return true; // doesn't work so well (but isn't cts a teamless mode?)
 396 }
 397
 398 MUTATOR_HOOKFUNCTION(cts, FixClientCvars)
 399 {
 400         entity player = M_ARGV(0, entity);
 401
 402         stuffcmd(player, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 403 }
 404
 405 MUTATOR_HOOKFUNCTION(cts, WantWeapon)
 406 {
 407         M_ARGV(1, float) = (M_ARGV(0, entity) == WEP_SHOTGUN); // want weapon = weapon info
 408         M_ARGV(3, bool) = true; // want mutator blocked
 409         return true;
 410 }
 411
 412 MUTATOR_HOOKFUNCTION(cts, ForbidDropCurrentWeapon)
 413 {
 414         return true;
 415 }
 416
 417 void cts_Initialize()
 418 {
 419         cts_ScoreRules();
 420 }