qcsrc/client/weapons/projectile.qc

   1 #include "projectile.qh"
   2
   3 #include "../autocvars.qh"
   4 #include <client/mutators/_mod.qh>
   5
   6 #include <common/constants.qh>
   7 #include <common/effects/effect.qh>
   8 #include <common/effects/all.qh>
   9 #include <common/net_linked.qh>
  10 #include <common/physics/movetypes/movetypes.qh>
  11
  12 #include <common/mutators/mutator/nades/nades.qh>
  13
  14 #include <lib/csqcmodel/interpolate.qh>
  15
  16 #include <lib/warpzone/anglestransform.qh>
  17
  18 .float alpha;
  19 .float scale;
  20 .vector colormod;
  21
  22 void SUB_Stop(entity this, entity toucher)
  23 {
  24         this.velocity = this.avelocity = '0 0 0';
  25         set_movetype(this, MOVETYPE_NONE);
  26 }
  27
  28 void Projectile_ResetTrail(entity this, vector to)
  29 {
  30         this.trail_oldorigin = to;
  31         this.trail_oldtime = time;
  32 }
  33
  34 void Projectile_DrawTrail(entity this, vector to)
  35 {
  36         vector from = this.trail_oldorigin;
  37         // float t0 = this.trail_oldtime;
  38         this.trail_oldorigin = to;
  39         this.trail_oldtime = time;
  40
  41         // force the effect even for stationary firemine
  42         if (this.cnt == PROJECTILE_FIREMINE)
  43                 if (from == to)
  44                         from.z += 1;
  45
  46         if (this.traileffect)
  47         {
  48                 particles_alphamin = particles_alphamax = particles_fade = sqrt(this.alpha);
  49                 entity eff = REGISTRY_GET(Effects, this.traileffect);
  50                 boxparticles(particleeffectnum(eff), this, from, to, this.velocity, this.velocity, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE | PARTICLES_DRAWASTRAIL);
  51         }
  52 }
  53
  54 void Projectile_Draw(entity this)
  55 {
  56         vector rot;
  57         vector trailorigin;
  58         int f;
  59         bool drawn;
  60         float t;
  61         float a;
  62
  63         f = this.flags;
  64
  65         if (this.count & 0x80)
  66         {
  67                 // UNSET_ONGROUND(this);
  68                 if (this.move_movetype == MOVETYPE_NONE || this.move_movetype == MOVETYPE_FLY)
  69                         Movetype_Physics_NoMatchServer(this);
  70                 // the trivial movetypes do not have to match the
  71                 // server's ticrate as they are ticrate independent
  72                 // NOTE: this assumption is only true if MOVETYPE_FLY
  73                 // projectiles detonate on impact. If they continue
  74                 // moving, we might still be ticrate dependent.
  75                 else
  76                         Movetype_Physics_MatchServer(this, autocvar_cl_projectiles_sloppy);
  77                 if (!IS_ONGROUND(this))
  78                         if (this.velocity != '0 0 0')
  79                                 this.angles = vectoangles(this.velocity);
  80         }
  81         else
  82         {
  83                 InterpolateOrigin_Do(this);
  84         }
  85
  86         if (this.count & 0x80)
  87         {
  88                 drawn = (time >= this.spawntime - 0.02);
  89                 t = max(time, this.spawntime);
  90         }
  91         else
  92         {
  93                 drawn = (this.iflags & IFLAG_VALID);
  94                 t = time;
  95         }
  96
  97         if (!(f & FL_ONGROUND))
  98         {
  99                 rot = '0 0 0';
 100                 switch (this.cnt)
 101                 {
 102                         /*
 103                         case PROJECTILE_GRENADE:
 104                             rot = '-2000 0 0'; // forward
 105                             break;
 106                         */
 107                         case PROJECTILE_GRENADE_BOUNCING:
 108                                 rot = '0 -1000 0'; // sideways
 109                                 break;
 110                         case PROJECTILE_HOOKBOMB:
 111                                 rot = '1000 0 0';  // forward
 112                                 break;
 113                         case PROJECTILE_ROCKET:
 114                                 rot = '0 0 720'; // spinning
 115                                 break;
 116                         default:
 117                                 break;
 118                 }
 119
 120                 if (Projectile_isnade(this.cnt))
 121                         rot = this.avelocity;
 122
 123                 this.angles = AnglesTransform_ToAngles(AnglesTransform_Multiply(AnglesTransform_FromAngles(this.angles), rot * (t - this.spawntime)));
 124         }
 125
 126         vector ang;
 127         ang = this.angles;
 128         ang.x = -ang.x;
 129         makevectors(ang);
 130
 131         a = 1 - (time - this.fade_time) * this.fade_rate;
 132         this.alpha = bound(0, this.alphamod * a, 1);
 133         if (this.alpha <= 0)
 134                 drawn = 0;
 135         this.renderflags = 0;
 136
 137         trailorigin = this.origin;
 138         switch (this.cnt)
 139         {
 140                 case PROJECTILE_GRENADE:
 141                 case PROJECTILE_GRENADE_BOUNCING:
 142                         trailorigin += v_right * 1 + v_forward * -10;
 143                         break;
 144                 default:
 145                         break;
 146         }
 147
 148         if (Projectile_isnade(this.cnt))
 149                 trailorigin += v_up * 4;
 150
 151         if (drawn)
 152                 Projectile_DrawTrail(this, trailorigin);
 153         else
 154                 Projectile_ResetTrail(this, trailorigin);
 155
 156         this.drawmask = 0;
 157
 158         if (!drawn)
 159                 return;
 160
 161         switch (this.cnt)
 162         {
 163                 // Possibly add dlights here.
 164                 default:
 165                         break;
 166         }
 167
 168         this.drawmask = MASK_NORMAL;
 169 }
 170
 171 void loopsound(entity e, int ch, Sound samp, float vol, float attn)
 172 {
 173         TC(int, ch);
 174         if (e.silent)
 175                 return;
 176
 177         sound(e, ch, samp, vol, attn);
 178         e.snd_looping = ch;
 179 }
 180
 181 void Ent_RemoveProjectile(entity this)
 182 {
 183         if (this.count & 0x80)
 184         {
 185                 tracebox(this.origin, this.mins, this.maxs, this.origin + this.velocity * 0.05, MOVE_NORMAL, this);
 186                 Projectile_DrawTrail(this, trace_endpos);
 187         }
 188 }
 189
 190 NET_HANDLE(ENT_CLIENT_PROJECTILE, bool isnew)
 191 {
 192         // projectile properties:
 193         //   kind (interpolated, or clientside)
 194         //
 195         //   modelindex
 196         //   origin
 197         //   scale
 198         //   if clientside:
 199         //     velocity
 200         //     gravity
 201         //   soundindex (hardcoded list)
 202         //   effects
 203         //
 204         // projectiles don't send angles, because they always follow the velocity
 205
 206         int f = ReadByte();
 207         this.count = (f & 0x80);
 208         this.flags |= FL_PROJECTILE;
 209         this.iflags = (this.iflags & IFLAG_INTERNALMASK) | IFLAG_AUTOANGLES | IFLAG_ANGLES | IFLAG_ORIGIN;
 210         this.solid = SOLID_TRIGGER;
 211         // this.effects = EF_NOMODELFLAGS;
 212
 213         // this should make collisions with bmodels more exact, but it leads to
 214         // projectiles no longer being able to lie on a bmodel
 215         this.move_nomonsters = MOVE_WORLDONLY;
 216         if (f & 0x40)
 217                 SET_ONGROUND(this);
 218         else
 219                 UNSET_ONGROUND(this);
 220
 221         if (!this.move_time)
 222         {
 223                 // for some unknown reason, we don't need to care for
 224                 // sv_gameplayfix_delayprojectiles here.
 225                 this.move_time = time;
 226                 this.spawntime = time;
 227         }
 228         else
 229         {
 230                 this.move_time = max(this.move_time, time);
 231         }
 232
 233         if (!(this.count & 0x80))
 234                 InterpolateOrigin_Undo(this);
 235
 236         if (f & 1)
 237         {
 238                 this.origin = ReadVector();
 239                 setorigin(this, this.origin);
 240                 if (this.count & 0x80)
 241                 {
 242                         this.velocity = ReadVector();
 243                         if (f & 0x10)
 244                                 this.gravity = ReadCoord();
 245                         else
 246                                 this.gravity = 0;  // none
 247                 }
 248
 249                 if (time == this.spawntime || (this.count & 0x80) || (f & 0x08))
 250                 {
 251                         this.trail_oldorigin = this.origin;
 252                         if (!(this.count & 0x80))
 253                                 InterpolateOrigin_Reset(this);
 254                 }
 255
 256                 if (f & 0x20)
 257                 {
 258                         this.fade_time = time + ReadByte() * ticrate;
 259                         this.fade_rate = 1 / (ReadByte() * ticrate);
 260                 }
 261                 else
 262                 {
 263                         this.fade_time = 0;
 264                         this.fade_rate = 0;
 265                 }
 266
 267                 int proj_team = ReadByte();
 268                 this.team = proj_team - 1;
 269
 270                 if(teamplay)
 271                 {
 272                         if(proj_team)
 273                                 this.colormap = (this.team) * 0x11; // note: team - 1 on server (client uses different numbers)
 274                         else
 275                                 this.colormap = 0x00;
 276                         this.colormap |= BIT(10); // RENDER_COLORMAPPED
 277                 }
 278                 else
 279                         this.colormap = proj_team;
 280                 // TODO: projectiles use glowmaps for their color, not teams
 281                 #if 0
 282                 if(this.colormap > 0)
 283                         this.glowmod = colormapPaletteColor(this.colormap & 0x0F, true) * 2;
 284                 else
 285                         this.glowmod = '1 1 1';
 286                 #endif
 287         }
 288
 289         if (f & 2)
 290         {
 291                 this.cnt = ReadByte();
 292
 293                 this.silent = (this.cnt & 0x80);
 294                 this.cnt = (this.cnt & 0x7F);
 295
 296                 this.scale = 1;
 297                 this.traileffect = 0;
 298                 switch (this.cnt)
 299                 {
 300 #define HANDLE(id) case PROJECTILE_##id: setmodel(this, MDL_PROJECTILE_##id);
 301                         HANDLE(ELECTRO)            this.traileffect = EFFECT_TR_NEXUIZPLASMA.m_id; break;
 302                         HANDLE(ROCKET)             this.traileffect = EFFECT_TR_ROCKET.m_id; this.scale = 2; break;
 303                         HANDLE(CRYLINK)            this.traileffect = EFFECT_TR_CRYLINKPLASMA.m_id; break;
 304                         HANDLE(CRYLINK_BOUNCING)   this.traileffect = EFFECT_TR_CRYLINKPLASMA.m_id; break;
 305                         HANDLE(ELECTRO_BEAM)       this.traileffect = EFFECT_TR_NEXUIZPLASMA.m_id; break;
 306                         HANDLE(GRENADE)            this.traileffect = EFFECT_TR_GRENADE.m_id; break;
 307                         HANDLE(GRENADE_BOUNCING)   this.traileffect = EFFECT_TR_GRENADE.m_id; break;
 308                         HANDLE(MINE)               this.traileffect = EFFECT_TR_GRENADE.m_id; break;
 309                         HANDLE(BLASTER)            this.traileffect = EFFECT_Null.m_id; break;
 310                         HANDLE(ARC_BOLT)           this.traileffect = EFFECT_Null.m_id; break;
 311                         HANDLE(HLAC)               this.traileffect = EFFECT_Null.m_id; break;
 312                         HANDLE(PORTO_RED)          this.traileffect = EFFECT_TR_WIZSPIKE.m_id; this.scale = 4; break;
 313                         HANDLE(PORTO_BLUE)         this.traileffect = EFFECT_TR_WIZSPIKE.m_id; this.scale = 4; break;
 314                         HANDLE(HOOKBOMB)           this.traileffect = EFFECT_TR_KNIGHTSPIKE.m_id; break;
 315                         HANDLE(HAGAR)              this.traileffect = EFFECT_HAGAR_ROCKET.m_id; this.scale = 0.75; break;
 316                         HANDLE(HAGAR_BOUNCING)     this.traileffect = EFFECT_HAGAR_ROCKET.m_id; this.scale = 0.75; break;
 317                         HANDLE(FIREBALL)           this.modelindex = 0; this.traileffect = EFFECT_FIREBALL.m_id; break; // particle effect is good enough
 318                         HANDLE(FIREMINE)           this.modelindex = 0; this.traileffect = EFFECT_FIREMINE.m_id; break; // particle effect is good enough
 319                         HANDLE(TAG)                this.traileffect = EFFECT_TR_ROCKET.m_id; break;
 320                         HANDLE(FLAC)               this.scale = 0.4; this.traileffect = EFFECT_FLAC_TRAIL.m_id; break;
 321                         HANDLE(SEEKER)             this.traileffect = EFFECT_SEEKER_TRAIL.m_id; break;
 322
 323                         HANDLE(MAGE_SPIKE)         this.traileffect = EFFECT_TR_VORESPIKE.m_id; break;
 324                         HANDLE(SHAMBLER_LIGHTNING) this.traileffect = EFFECT_TR_NEXUIZPLASMA.m_id; break;
 325
 326                         HANDLE(RAPTORBOMB)         this.gravity = 1; this.avelocity = '0 0 180'; this.traileffect = EFFECT_Null.m_id; break;
 327                         HANDLE(RAPTORBOMBLET)      this.gravity = 1; this.avelocity = '0 0 180'; this.traileffect = EFFECT_Null.m_id; break;
 328                         HANDLE(RAPTORCANNON)       this.traileffect = EFFECT_TR_CRYLINKPLASMA.m_id; break;
 329
 330                         HANDLE(SPIDERROCKET)       this.traileffect = EFFECT_SPIDERBOT_ROCKET_TRAIL.m_id; break;
 331                         HANDLE(WAKIROCKET)         this.traileffect = EFFECT_RACER_ROCKET_TRAIL.m_id; break;
 332                         HANDLE(WAKICANNON)         this.traileffect = EFFECT_Null.m_id; break;
 333
 334                         HANDLE(BUMBLE_GUN)         this.traileffect = EFFECT_TR_NEXUIZPLASMA.m_id; break;
 335                         HANDLE(BUMBLE_BEAM)        this.traileffect = EFFECT_TR_NEXUIZPLASMA.m_id; break;
 336
 337                         HANDLE(RPC)                this.traileffect = EFFECT_TR_ROCKET.m_id; break;
 338
 339                         HANDLE(ROCKETMINSTA_LASER) this.traileffect = EFFECT_ROCKETMINSTA_LASER(this.team).m_id; break;
 340 #undef HANDLE
 341                         default:
 342                                 if (MUTATOR_CALLHOOK(Ent_Projectile, this))
 343                                         break;
 344
 345                                 error("Received invalid CSQC projectile, can't work with this!");
 346                                 break;
 347                 }
 348
 349                 this.mins = '0 0 0';
 350                 this.maxs = '0 0 0';
 351                 this.colormod = '0 0 0';
 352                 settouch(this, SUB_Stop);
 353                 set_movetype(this, MOVETYPE_TOSS);
 354                 this.alphamod = 1;
 355
 356                 switch (this.cnt)
 357                 {
 358                         case PROJECTILE_ELECTRO:
 359                                 // only new engines support sound moving with object
 360                                 loopsound(this, CH_SHOTS_SINGLE, SND_ELECTRO_FLY, VOL_BASE, ATTEN_NORM);
 361                                 this.mins = '-4 -4 -4';
 362                                 this.maxs = '4 4 4';
 363                                 set_movetype(this, MOVETYPE_BOUNCE);
 364                                 settouch(this, func_null);
 365                                 this.bouncefactor = WEP_CVAR_SEC(electro, bouncefactor);
 366                                 this.bouncestop = WEP_CVAR_SEC(electro, bouncestop);
 367                                 break;
 368                         case PROJECTILE_RPC:
 369                         case PROJECTILE_ROCKET:
 370                                 loopsound(this, CH_SHOTS_SINGLE, SND_ROCKET_FLY, VOL_BASE, ATTEN_NORM);
 371                                 this.mins = '-3 -3 -3';
 372                                 this.maxs = '3 3 3';
 373                                 break;
 374                         case PROJECTILE_GRENADE:
 375                                 this.mins = '-3 -3 -3';
 376                                 this.maxs = '3 3 3';
 377                                 break;
 378                         case PROJECTILE_GRENADE_BOUNCING:
 379                                 this.mins = '-3 -3 -3';
 380                                 this.maxs = '3 3 3';
 381                                 set_movetype(this, MOVETYPE_BOUNCE);
 382                                 settouch(this, func_null);
 383                                 this.bouncefactor = WEP_CVAR(mortar, bouncefactor);
 384                                 this.bouncestop = WEP_CVAR(mortar, bouncestop);
 385                                 break;
 386                         case PROJECTILE_SHAMBLER_LIGHTNING:
 387                                 this.mins = '-8 -8 -8';
 388                                 this.maxs = '8 8 8';
 389                                 this.scale = 2.5;
 390                                 this.avelocity = randomvec() * 720;
 391                                 break;
 392                         case PROJECTILE_MINE:
 393                                 this.mins = '-4 -4 -4';
 394                                 this.maxs = '4 4 4';
 395                                 break;
 396                         case PROJECTILE_PORTO_RED:
 397                                 this.colormod = '2 1 1';
 398                                 this.alphamod = 0.5;
 399                                 set_movetype(this, MOVETYPE_BOUNCE);
 400                                 settouch(this, func_null);
 401                                 break;
 402                         case PROJECTILE_PORTO_BLUE:
 403                                 this.colormod = '1 1 2';
 404                                 this.alphamod = 0.5;
 405                                 set_movetype(this, MOVETYPE_BOUNCE);
 406                                 settouch(this, func_null);
 407                                 break;
 408                         case PROJECTILE_HAGAR_BOUNCING:
 409                                 set_movetype(this, MOVETYPE_BOUNCE);
 410                                 settouch(this, func_null);
 411                                 break;
 412                         case PROJECTILE_CRYLINK_BOUNCING:
 413                                 set_movetype(this, MOVETYPE_BOUNCE);
 414                                 settouch(this, func_null);
 415                                 break;
 416                         case PROJECTILE_FIREBALL:
 417                                 loopsound(this, CH_SHOTS_SINGLE, SND_FIREBALL_FLY2, VOL_BASE, ATTEN_NORM);
 418                                 this.mins = '-16 -16 -16';
 419                                 this.maxs = '16 16 16';
 420                                 break;
 421                         case PROJECTILE_FIREMINE:
 422                                 loopsound(this, CH_SHOTS_SINGLE, SND_FIREBALL_FLY, VOL_BASE, ATTEN_NORM);
 423                                 set_movetype(this, MOVETYPE_BOUNCE);
 424                                 settouch(this, func_null);
 425                                 this.mins = '-4 -4 -4';
 426                                 this.maxs = '4 4 4';
 427                                 break;
 428                         case PROJECTILE_TAG:
 429                                 this.mins = '-2 -2 -2';
 430                                 this.maxs = '2 2 2';
 431                                 break;
 432                         case PROJECTILE_FLAC:
 433                                 this.mins = '-2 -2 -2';
 434                                 this.maxs = '2 2 2';
 435                                 break;
 436                         case PROJECTILE_SEEKER:
 437                                 loopsound(this, CH_SHOTS_SINGLE, SND_TAG_ROCKET_FLY, VOL_BASE, ATTEN_NORM);
 438                                 this.mins = '-4 -4 -4';
 439                                 this.maxs = '4 4 4';
 440                                 break;
 441                         case PROJECTILE_RAPTORBOMB:
 442                                 this.mins = '-3 -3 -3';
 443                                 this.maxs = '3 3 3';
 444                                 break;
 445                         case PROJECTILE_RAPTORBOMBLET:
 446                                 break;
 447                         case PROJECTILE_RAPTORCANNON:
 448                                 break;
 449                         case PROJECTILE_SPIDERROCKET:
 450                                 loopsound(this, CH_SHOTS_SINGLE, SND_TAG_ROCKET_FLY, VOL_BASE, ATTEN_NORM);
 451                                 break;
 452                         case PROJECTILE_WAKIROCKET:
 453                                 loopsound(this, CH_SHOTS_SINGLE, SND_TAG_ROCKET_FLY, VOL_BASE, ATTEN_NORM);
 454                                 break;
 455                         /*
 456                         case PROJECTILE_WAKICANNON:
 457                             break;
 458                         case PROJECTILE_BUMBLE_GUN:
 459                             // only new engines support sound moving with object
 460                             loopsound(this, CH_SHOTS_SINGLE, SND_ELECTRO_FLY, VOL_BASE, ATTEN_NORM);
 461                             this.mins = '0 0 -4';
 462                             this.maxs = '0 0 -4';
 463                             this.move_movetype = MOVETYPE_BOUNCE;
 464                             settouch(this, func_null);
 465                             this.bouncefactor = WEP_CVAR_SEC(electro, bouncefactor);
 466                             this.bouncestop = WEP_CVAR_SEC(electro, bouncestop);
 467                             break;
 468                         */
 469                         default:
 470                                 break;
 471                 }
 472
 473                 MUTATOR_CALLHOOK(EditProjectile, this);
 474
 475                 setsize(this, this.mins, this.maxs);
 476         }
 477
 478         return = true;
 479
 480         if (this.gravity)
 481         {
 482                 if (this.move_movetype == MOVETYPE_FLY)
 483                         set_movetype(this, MOVETYPE_TOSS);
 484                 if (this.move_movetype == MOVETYPE_BOUNCEMISSILE)
 485                         set_movetype(this, MOVETYPE_BOUNCE);
 486         }
 487         else
 488         {
 489                 if (this.move_movetype == MOVETYPE_TOSS)
 490                         set_movetype(this, MOVETYPE_FLY);
 491                 if (this.move_movetype == MOVETYPE_BOUNCE)
 492                         set_movetype(this, MOVETYPE_BOUNCEMISSILE);
 493         }
 494
 495         if (!(this.count & 0x80))
 496                 InterpolateOrigin_Note(this);
 497
 498         this.classname = "csqcprojectile";
 499         this.draw = Projectile_Draw;
 500         if (isnew) IL_PUSH(g_drawables, this);
 501         this.entremove = Ent_RemoveProjectile;
 502 }
 503
 504 PRECACHE(Projectiles)
 505 {
 506         MUTATOR_CALLHOOK(PrecacheProjectiles);
 507 }