qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "announcer.qh"
   6 #include "hud/_mod.qh"
   7 #include "mapvoting.qh"
   8 #include "shownames.qh"
   9 #include "hud/panel/scoreboard.qh"
  10 #include "hud/panel/quickmenu.qh"
  11
  12 #include <client/mutators/_mod.qh>
  13
  14 #include <common/animdecide.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/ent_cs.qh>
  17 #include <common/anim.qh>
  18 #include <common/constants.qh>
  19 #include <common/net_linked.qh>
  20 #include <common/net_notice.qh>
  21 #include <common/debug.qh>
  22 #include <common/mapinfo.qh>
  23 #include <common/gamemodes/_mod.qh>
  24 #include <common/physics/player.qh>
  25 #include <common/stats.qh>
  26 #include <common/mapobjects/target/music.qh>
  27 #include <common/teams.qh>
  28 #include <common/wepent.qh>
  29
  30 #include <common/weapons/weapon/tuba.qh>
  31
  32 #include <common/vehicles/all.qh>
  33 #include <common/weapons/_all.qh>
  34 #include <common/mutators/mutator/overkill/oknex.qh>
  35 #include <common/mutators/mutator/waypoints/all.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/mapobjects/trigger/viewloc.qh>
  38 #include <common/minigames/cl_minigames.qh>
  39 #include <common/minigames/cl_minigames_hud.qh>
  40
  41 #include <lib/csqcmodel/cl_player.qh>
  42 #include <lib/csqcmodel/cl_model.qh>
  43 #include "csqcmodel_hooks.qh"
  44
  45 #include <lib/warpzone/client.qh>
  46 #include <lib/warpzone/common.qh>
  47
  48 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  49
  50 float autocvar_cl_viewmodel_scale;
  51 float autocvar_cl_viewmodel_alpha;
  52
  53 bool autocvar_cl_bobmodel;
  54 float autocvar_cl_bobmodel_speed;
  55 float autocvar_cl_bobmodel_side;
  56 float autocvar_cl_bobmodel_up;
  57
  58 float autocvar_cl_followmodel;
  59 float autocvar_cl_followmodel_speed = 0.3;
  60 float autocvar_cl_followmodel_limit = 135;
  61 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  62 float autocvar_cl_followmodel_highpass = 0.05;
  63 float autocvar_cl_followmodel_lowpass = 0.03;
  64 bool autocvar_cl_followmodel_velocity_absolute;
  65
  66 float autocvar_cl_leanmodel;
  67 float autocvar_cl_leanmodel_speed = 0.3;
  68 float autocvar_cl_leanmodel_limit = 30;
  69 float autocvar_cl_leanmodel_highpass1 = 0.2;
  70 float autocvar_cl_leanmodel_highpass = 0.2;
  71 float autocvar_cl_leanmodel_lowpass = 0.05;
  72
  73 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  74
  75 #define lowpass(value, frac, ref_store, ret) \
  76         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  77
  78 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  79         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  80         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  81 MACRO_END
  82
  83 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  84         float __f = 0; lowpass(value, frac, ref_store, __f); \
  85         ret = (value) - __f; \
  86 MACRO_END
  87
  88 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  89         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  90         ret = (value) - __f; \
  91 MACRO_END
  92
  93 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  94         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  95         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  96 MACRO_END
  97
  98 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  99         highpass(value.x, frac, ref_store.x, ref_out.x); \
 100         highpass(value.y, frac, ref_store.y, ref_out.y); \
 101 MACRO_END
 102
 103 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 104         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 105         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 106 MACRO_END
 107
 108 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 109         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 110         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 111         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 112 MACRO_END
 113
 114 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 115         highpass(value.x, frac, ref_store.x, ref_out.x); \
 116         highpass(value.y, frac, ref_store.y, ref_out.y); \
 117         highpass(value.z, frac, ref_store.z, ref_out.z); \
 118 MACRO_END
 119
 120 void calc_followmodel_ofs(entity view)
 121 {
 122         if(cl_followmodel_time == time)
 123                 return; // cl_followmodel_ofs already calculated for this frame
 124
 125         float frac;
 126         vector gunorg = '0 0 0';
 127         static vector vel_average;
 128         static vector gunorg_adjustment_highpass;
 129         static vector gunorg_adjustment_lowpass;
 130
 131         vector vel;
 132         if (autocvar_cl_followmodel_velocity_absolute)
 133                 vel = view.velocity;
 134         else
 135         {
 136                 MAKE_VECTORS_NEW(view_angles, forward, right, up);
 137                 vel.x = view.velocity * forward;
 138                 vel.y = view.velocity * right * -1;
 139                 vel.z = view.velocity * up;
 140         }
 141
 142         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 143         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 144         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 145
 146         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 147         lowpass3(vel, frac, vel_average, gunorg);
 148
 149         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 150
 151         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 152         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 153         frac = avg_factor(autocvar_cl_followmodel_highpass);
 154         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 155         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 156         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 157
 158         if (autocvar_cl_followmodel_velocity_absolute)
 159         {
 160                 vector fixed_gunorg;
 161                 MAKE_VECTORS_NEW(view_angles, forward, right, up);
 162                 fixed_gunorg.x = gunorg * forward;
 163                 fixed_gunorg.y = gunorg * right * -1;
 164                 fixed_gunorg.z = gunorg * up;
 165                 gunorg = fixed_gunorg;
 166         }
 167
 168         cl_followmodel_ofs = gunorg;
 169         cl_followmodel_time = time;
 170 }
 171
 172 vector leanmodel_ofs(entity view)
 173 {
 174         float frac;
 175         vector gunangles = '0 0 0';
 176         static vector gunangles_prev = '0 0 0';
 177         static vector gunangles_highpass = '0 0 0';
 178         static vector gunangles_adjustment_highpass;
 179         static vector gunangles_adjustment_lowpass;
 180
 181         if (view.csqcmodel_teleported)
 182                 gunangles_prev = view_angles;
 183
 184         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 185         gunangles_highpass += gunangles_prev;
 186         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 187         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 188         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 189         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 190         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 191         gunangles_prev = view_angles;
 192         gunangles_highpass -= gunangles_prev;
 193
 194         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 195         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 196
 197         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 198         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 199         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 200         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 201         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 202
 203         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 204
 205         return gunangles;
 206 }
 207
 208 vector bobmodel_ofs(entity view)
 209 {
 210         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 211         static bool oldonground;
 212         static float hitgroundtime;
 213         if (clonground)
 214         {
 215                 float f = time; // cl.movecmd[0].time
 216                 if (!oldonground)
 217                         hitgroundtime = f;
 218         }
 219         oldonground = clonground;
 220
 221         // calculate for swinging gun model
 222         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 223         vector gunorg = '0 0 0';
 224         static float bobmodel_scale = 0;
 225         static float time_ofs = 0; // makes the effect always restart in the same way
 226         if (clonground)
 227         {
 228                 if (time - hitgroundtime > 0.05)
 229                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 230         }
 231         else
 232                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 233
 234         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 235         if (bobmodel_scale && xyspeed)
 236         {
 237                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 238                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 239                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 240                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 241         }
 242         else
 243                 time_ofs = time;
 244
 245         return gunorg;
 246 }
 247
 248 void viewmodel_animate(entity this)
 249 {
 250         if (autocvar_chase_active) return;
 251         if (STAT(HEALTH) <= 0) return;
 252
 253         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 254
 255         if (autocvar_cl_followmodel)
 256         {
 257                 calc_followmodel_ofs(view);
 258                 this.origin += cl_followmodel_ofs;
 259         }
 260
 261         if (autocvar_cl_leanmodel)
 262                 this.angles += leanmodel_ofs(view);
 263
 264         // vertical view bobbing code
 265         // TODO: cl_bob
 266
 267         // horizontal view bobbing code
 268         // TODO: cl_bob2
 269
 270         // fall bobbing code
 271         // causes the view to swing down and back up when touching the ground
 272         // TODO: cl_bobfall
 273
 274         // gun model bobbing code
 275         if (autocvar_cl_bobmodel)
 276                 this.origin += bobmodel_ofs(view);
 277 }
 278
 279 .vector viewmodel_origin, viewmodel_angles;
 280 .float weapon_nextthink;
 281 .float weapon_eta_last;
 282 .float weapon_switchdelay;
 283
 284 .string name_last;
 285
 286 void viewmodel_draw(entity this)
 287 {
 288         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 289                 return;
 290         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 291         float a = ((autocvar_cl_viewmodel_alpha) ? bound(-1, autocvar_cl_viewmodel_alpha, this.m_alpha) : this.m_alpha);
 292         bool invehicle = player_localentnum > maxclients;
 293         if (invehicle) a = -1;
 294         Weapon wep = this.activeweapon;
 295         int c = entcs_GetClientColors(current_player);
 296         vector g = weaponentity_glowmod(wep, NULL, c, this);
 297         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 298         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 299                 | EF_NODEPTHTEST)
 300                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 301         for (entity e = this; e; e = e.weaponchild)
 302         {
 303                 e.drawmask = mask;
 304                 e.alpha = a;
 305                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 306                 e.glowmod = g;
 307                 e.csqcmodel_effects = fx;
 308                 CSQCModel_Effects_Apply(e);
 309         }
 310         if(a >= 0)
 311         {
 312                 string name = wep.mdl;
 313                 string newname = wep.wr_viewmodel(wep, this);
 314                 if(newname)
 315                         name = newname;
 316                 bool swap = name != this.name_last;
 317                 // if (swap)
 318                 {
 319                         this.name_last = name;
 320                         CL_WeaponEntity_SetModel(this, name, swap);
 321                         this.viewmodel_origin = this.origin;
 322                         this.viewmodel_angles = this.angles;
 323                 }
 324                 anim_update(this);
 325                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 326                         anim_set(this, this.anim_idle, true, false, false);
 327         }
 328         float f = 0; // 0..1; 0: fully active
 329         float rate = STAT(WEAPONRATEFACTOR);
 330         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 331         if (eta <= 0) f = this.weapon_eta_last;
 332         else switch (this.state)
 333         {
 334                 case WS_RAISE:
 335                 {
 336                         f = eta / max(eta, this.weapon_switchdelay);
 337                         break;
 338                 }
 339                 case WS_DROP:
 340                 {
 341                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 342                         break;
 343                 }
 344                 case WS_CLEAR:
 345                 {
 346                         f = 1;
 347                         break;
 348                 }
 349         }
 350         this.weapon_eta_last = f;
 351         this.origin = this.viewmodel_origin;
 352         this.angles = this.viewmodel_angles;
 353         this.angles_x = (-90 * f * f);
 354         viewmodel_animate(this);
 355         MUTATOR_CALLHOOK(DrawViewModel, this);
 356         setorigin(this, this.origin);
 357 }
 358
 359 STATIC_INIT(viewmodel) {
 360     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 361         viewmodels[slot] = new(viewmodel);
 362 }
 363
 364 float showfps_prevfps;
 365 float showfps_prevfps_time;
 366 int showfps_framecounter;
 367
 368 void fpscounter_update()
 369 {
 370         if(!STAT(SHOWFPS))
 371                 return;
 372
 373         float currentTime = gettime(GETTIME_REALTIME);
 374         showfps_framecounter += 1;
 375         if(currentTime - showfps_prevfps_time > STAT(SHOWFPS))
 376         {
 377                 showfps_prevfps = showfps_framecounter/(currentTime - showfps_prevfps_time);
 378                 showfps_framecounter = 0;
 379                 showfps_prevfps_time = currentTime;
 380
 381                 int channel = MSG_C2S;
 382                 WriteHeader(channel, fpsreport);
 383                 WriteShort(channel, bound(0, rint(showfps_prevfps), 65535)); // prevent insane fps values
 384         }
 385 }
 386
 387 STATIC_INIT(fpscounter_init)
 388 {
 389         float currentTime = gettime(GETTIME_REALTIME);
 390         showfps_prevfps_time = currentTime; // we must initialize it to avoid an instant low frame sending
 391 }
 392
 393 STATIC_INIT(Porto)
 394 {
 395         entity e = new_pure(porto);
 396         e.draw = Porto_Draw;
 397         IL_PUSH(g_drawables, e);
 398         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 399 }
 400
 401 const int polyline_length = 16;
 402 .vector polyline[polyline_length];
 403 void Porto_Draw(entity this)
 404 {
 405         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 406         {
 407                 entity wepent = viewmodels[slot];
 408
 409                 if (wepent.activeweapon != WEP_PORTO) continue;
 410                 if (spectatee_status) continue;
 411                 if (WEP_CVAR(porto, secondary)) continue;
 412                 if (intermission == 1) continue;
 413                 if (intermission == 2) continue;
 414                 if (STAT(HEALTH) <= 0) continue;
 415
 416                 vector pos = view_origin;
 417                 vector dir = view_forward;
 418                 MAKE_VECTORS_NEW(autocvar_chase_active ? warpzone_save_view_angles : view_angles, forward, right, up);
 419                 pos += right * -wepent.movedir.y
 420                         +  up * wepent.movedir.z;
 421
 422                 if (wepent.angles_held_status)
 423                 {
 424                         MAKE_VECTORS(wepent.angles_held, forward, right, up);
 425                         dir = forward;
 426                 }
 427
 428                 wepent.polyline[0] = pos;
 429
 430                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
 431                 int n = 1 + 2;  // 2 lines == 3 points
 432                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
 433                 {
 434                         traceline(pos, pos + 65536 * dir, true, this);
 435                         dir = reflect(dir, trace_plane_normal);
 436                         pos = trace_endpos;
 437                         wepent.polyline[++idx] = pos;
 438                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 439                         {
 440                                 n += 1;
 441                                 continue;
 442                         }
 443                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 444                         {
 445                                 n = max(2, idx);
 446                                 break;
 447                         }
 448                         // check size
 449                         {
 450                                 vector ang = vectoangles2(trace_plane_normal, dir);
 451                                 ang.x = -ang.x;
 452                                 MAKE_VECTORS(ang, forward, right, up);
 453                                 if (!CheckWireframeBox(this, pos - 48 * right - 48 * up + 16 * forward, 96 * right, 96 * up, 96 * forward))
 454                                 {
 455                                         n = max(2, idx);
 456                                         break;
 457                                 }
 458                         }
 459                         portal_number += 1;
 460                         if (portal_number >= portal_max) break;
 461                         if (portal_number == 1) portal1_idx = idx;
 462                 }
 463                 for (int idx = 0; idx < n - 1; ++idx)
 464                 {
 465                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
 466                         if (idx == 0) p -= view_up * 16;  // line from player
 467                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 468                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 469                 }
 470         }
 471 }
 472
 473 float drawtime;
 474 float avgspeed;
 475 vector GetCurrentFov(float fov)
 476 {
 477         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 478         float velocityzoom, curspeed;
 479         vector v;
 480
 481         zoomsensitivity = autocvar_cl_zoomsensitivity;
 482         zoomfactor = autocvar_cl_zoomfactor;
 483         if(zoomfactor < 1 || zoomfactor > 30)
 484                 zoomfactor = 2.5;
 485         zoomspeed = autocvar_cl_zoomspeed;
 486         if (zoomspeed >= 0 && (zoomspeed < 0.5 || zoomspeed > 16))
 487                 zoomspeed = 3.5;
 488
 489         zoomdir = button_zoom;
 490
 491         if(hud == HUD_NORMAL && !spectatee_status)
 492         {
 493                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 494                 {
 495                         entity wepent = viewmodels[slot];
 496                         if(wepent.switchweapon != wepent.activeweapon)
 497                                 continue;
 498                         Weapon wep = wepent.activeweapon;
 499                         if(wep != WEP_Null && wep.wr_zoomdir)
 500                         {
 501                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
 502                                 zoomdir += do_zoom;
 503                         }
 504                 }
 505         }
 506         if(spectatee_status > 0 || isdemo())
 507         {
 508                 if(spectatorbutton_zoom)
 509                 {
 510                         if(zoomdir)
 511                                 zoomdir = 0;
 512                         else
 513                                 zoomdir = 1;
 514                 }
 515                 // fteqcc failed twice here already, don't optimize this
 516         }
 517
 518         if(zoomdir) { zoomin_effect = 0; }
 519
 520         if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 521         {
 522                 current_viewzoom = 1;
 523         }
 524         else if (camera_active)
 525         {
 526                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 527         }
 528         else if(autocvar_cl_spawnzoom && zoomin_effect)
 529         {
 530                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 531
 532                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 533                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 534                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 535         }
 536         else
 537         {
 538                 if(zoomspeed < 0) // instant zoom
 539                 {
 540                         if(zoomdir)
 541                                 current_viewzoom = 1 / zoomfactor;
 542                         else
 543                                 current_viewzoom = 1;
 544                 }
 545                 else
 546                 {
 547                         if(zoomdir)
 548                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 549                         else
 550                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 551                 }
 552         }
 553
 554         if(almost_equals(current_viewzoom, 1))
 555                 current_zoomfraction = 0;
 556         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 557                 current_zoomfraction = 1;
 558         else
 559                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 560
 561         if(zoomsensitivity < 1)
 562                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 563         else
 564                 setsensitivityscale(1);
 565
 566         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 567         {
 568                 if (intermission || (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2))
 569                         curspeed = 0;
 570                 else
 571                 {
 572                         MAKE_VECTORS_NEW(view_angles, forward, right, up);
 573                         v = pmove_vel;
 574                         if(csqcplayer)
 575                                 v = csqcplayer.velocity;
 576
 577                         switch(autocvar_cl_velocityzoom_type)
 578                         {
 579                                 case 3: curspeed = max(0, forward * v); break;
 580                                 case 2: curspeed = (forward * v); break;
 581                                 case 1: default: curspeed = vlen(v); break;
 582                         }
 583                 }
 584
 585                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 586                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 587                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 588
 589                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 590         }
 591         else
 592                 velocityzoom = 1;
 593
 594         float frustumx, frustumy, fovx, fovy;
 595         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 596         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 597         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 598         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 599
 600         return '1 0 0' * fovx + '0 1 0' * fovy;
 601 }
 602
 603 vector GetViewLocationFOV(float fov)
 604 {
 605         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 606         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 607         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 608         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 609         return '1 0 0' * fovx + '0 1 0' * fovy;
 610 }
 611
 612 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 613 {
 614         float fovx, fovy;
 615         float width = (ov_worldmax.x - ov_worldmin.x);
 616         float height = (ov_worldmax.y - ov_worldmin.y);
 617         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 618         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 619         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 620         return '1 0 0' * fovx + '0 1 0' * fovy;
 621 }
 622
 623 // this function must match W_SetupShot!
 624 float zoomscript_caught;
 625
 626 bool minigame_wasactive;
 627
 628 vector wcross_origin;
 629 float wcross_scale_prev, wcross_alpha_prev;
 630 vector wcross_color_prev;
 631 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 632 vector wcross_color_goal_prev;
 633 float wcross_changedonetime;
 634
 635 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 636 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 637 float wcross_name_changestarttime, wcross_name_changedonetime;
 638 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 639
 640 float wcross_ring_prev;
 641
 642 entity trueaim;
 643 entity trueaim_rifle;
 644
 645 const float SHOTTYPE_HITTEAM = 1;
 646 const float SHOTTYPE_HITOBSTRUCTION = 2;
 647 const float SHOTTYPE_HITWORLD = 3;
 648 const float SHOTTYPE_HITENEMY = 4;
 649
 650 void TrueAim_Init()
 651 {
 652         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 653         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 654 }
 655
 656 float EnemyHitCheck()
 657 {
 658         float t, n;
 659         wcross_origin = project_3d_to_2d(trace_endpos);
 660         wcross_origin.z = 0;
 661         if(trace_ent)
 662                 n = trace_ent.entnum;
 663         else
 664                 n = trace_networkentity;
 665         if(n < 1)
 666                 return SHOTTYPE_HITWORLD;
 667         if(n > maxclients)
 668                 return SHOTTYPE_HITWORLD;
 669         t = entcs_GetTeam(n - 1);
 670         if(teamplay)
 671                 if(t == myteam)
 672                         return SHOTTYPE_HITTEAM;
 673         if(t == NUM_SPECTATOR)
 674                 return SHOTTYPE_HITWORLD;
 675         return SHOTTYPE_HITENEMY;
 676 }
 677
 678 float TrueAimCheck(entity wepent)
 679 {
 680         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 681         vector vecs, trueaimpoint, w_shotorg;
 682         vector mi, ma, dv;
 683         float shottype;
 684         entity ta;
 685         float mv;
 686
 687         mi = ma = '0 0 0';
 688         ta = trueaim;
 689         mv = MOVE_NOMONSTERS;
 690
 691         switch(wepent.activeweapon) // WEAPONTODO
 692         {
 693                 case WEP_TUBA: // no aim
 694                 case WEP_PORTO: // shoots from eye
 695                 case WEP_NEXBALL: // shoots from eye
 696                 case WEP_HOOK: // no trueaim
 697                 case WEP_MORTAR: // toss curve
 698                         return SHOTTYPE_HITWORLD;
 699                 case WEP_VORTEX:
 700                 case WEP_OVERKILL_NEX:
 701                 case WEP_VAPORIZER:
 702                         mv = MOVE_NORMAL;
 703                         break;
 704                 case WEP_RIFLE:
 705                         ta = trueaim_rifle;
 706                         mv = MOVE_NORMAL;
 707                         if(zoomscript_caught)
 708                         {
 709                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 710                                 return EnemyHitCheck();
 711                         }
 712                         break;
 713                 case WEP_DEVASTATOR: // projectile has a size!
 714                         mi = '-3 -3 -3';
 715                         ma = '3 3 3';
 716                         break;
 717                 case WEP_FIREBALL: // projectile has a size!
 718                         mi = '-16 -16 -16';
 719                         ma = '16 16 16';
 720                         break;
 721                 case WEP_SEEKER: // projectile has a size!
 722                         mi = '-2 -2 -2';
 723                         ma = '2 2 2';
 724                         break;
 725                 case WEP_ELECTRO: // projectile has a size!
 726                         mi = '0 0 -3';
 727                         ma = '0 0 -3';
 728                         break;
 729         }
 730
 731         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 732
 733         vecs = decompressShotOrigin(STAT(SHOTORG));
 734
 735         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 736         trueaimpoint = trace_endpos;
 737
 738         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 739                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 740
 741         if(vecs.x > 0)
 742                 vecs.y = -vecs.y;
 743         else
 744                 vecs = '0 0 0';
 745
 746         dv = view_right * vecs.y + view_up * vecs.z;
 747         w_shotorg = traceorigin + dv;
 748
 749         // now move the vecs forward as much as requested if possible
 750         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 751         w_shotorg = trace_endpos - view_forward * nudge;
 752
 753         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 754         shottype = EnemyHitCheck();
 755         if(shottype != SHOTTYPE_HITWORLD)
 756                 return shottype;
 757
 758 #if 0
 759         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 760         // or rather, I know why, but see no fix
 761         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 762                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 763                 return SHOTTYPE_HITOBSTRUCTION;
 764 #endif
 765
 766         return SHOTTYPE_HITWORLD;
 767 }
 768
 769 float camera_mode;
 770 const float CAMERA_FREE = 1;
 771 const float CAMERA_CHASE = 2;
 772 float reticle_type;
 773 string NextFrameCommand;
 774
 775 vector freeze_org, freeze_ang;
 776 entity nightvision_noise, nightvision_noise2;
 777
 778 const float MAX_TIME_DIFF = 5;
 779 float pickup_crosshair_time, pickup_crosshair_size;
 780 float hitindication_crosshair_size;
 781 float use_vortex_chargepool;
 782
 783 float myhealth, myhealth_prev;
 784 float myhealth_flash;
 785
 786 float old_blurradius, old_bluralpha;
 787 float old_sharpen_intensity;
 788
 789 vector myhealth_gentlergb;
 790
 791 float contentavgalpha, liquidalpha_prev;
 792 vector liquidcolor_prev;
 793
 794 float eventchase_current_distance;
 795 float eventchase_running;
 796 int WantEventchase(entity this)
 797 {
 798         if(autocvar_cl_orthoview)
 799                 return 0;
 800         if(STAT(GAME_STOPPED) || intermission)
 801                 return 1;
 802         if(this.viewloc)
 803                 return 1;
 804         if(spectatee_status >= 0)
 805         {
 806                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 807                         return 1;
 808                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 809                         return 1;
 810                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 811                         return 1;
 812                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 813                 {
 814                         if(autocvar_cl_eventchase_death == 2)
 815                         {
 816                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 817                                 if(this.velocity == '0 0 0' || eventchase_running)
 818                                         return 1;
 819                         }
 820                         else return 1;
 821                 }
 822                 if (spectatee_status > 0 && autocvar_cl_eventchase_spectated_change)
 823                 {
 824                         if (time <= spectatee_status_changed_time + min(3, autocvar_cl_eventchase_spectated_change_time))
 825                                 return 1;
 826                         else if (eventchase_running)
 827                                 return -1; // disable chase_active while eventchase is still enabled so to avoid a glicth
 828                 }
 829         }
 830         return 0;
 831 }
 832
 833 void HUD_Crosshair_Vehicle(entity this)
 834 {
 835         if(hud != HUD_BUMBLEBEE_GUN)
 836         {
 837                 Vehicle info = Vehicles_from(hud);
 838                 info.vr_crosshair(info, this);
 839         }
 840 }
 841
 842 vector damage_blurpostprocess, content_blurpostprocess;
 843
 844 float unaccounted_damage = 0;
 845 void UpdateDamage()
 846 {
 847         // accumulate damage with each stat update
 848         static float damage_total_prev = 0;
 849         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 850         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 851         damage_total_prev = damage_total;
 852
 853         static float damage_dealt_time_prev = 0;
 854         float damage_dealt_time = STAT(HIT_TIME);
 855         if (damage_dealt_time != damage_dealt_time_prev)
 856         {
 857                 unaccounted_damage += unaccounted_damage_new;
 858                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 859         }
 860         damage_dealt_time_prev = damage_dealt_time;
 861
 862         // prevent hitsound when switching spectatee
 863         static float spectatee_status_prev = 0;
 864         if (spectatee_status != spectatee_status_prev)
 865                 unaccounted_damage = 0;
 866         spectatee_status_prev = spectatee_status;
 867 }
 868
 869 void HitSound()
 870 {
 871         // varying sound pitch
 872
 873         bool have_arc = false;
 874         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 875         {
 876                 entity wepent = viewmodels[slot];
 877
 878                 if(wepent.activeweapon == WEP_ARC)
 879                         have_arc = true;
 880         }
 881
 882         static float hitsound_time_prev = 0;
 883         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 884         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 885         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 886         {
 887                 if (autocvar_cl_hitsound && unaccounted_damage)
 888                 {
 889                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 890                         float a = autocvar_cl_hitsound_max_pitch;
 891                         float b = autocvar_cl_hitsound_min_pitch;
 892                         float c = autocvar_cl_hitsound_nom_damage;
 893                         float d = unaccounted_damage;
 894                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 895
 896                         // if sound variation is disabled, set pitch_shift to 1
 897                         if (autocvar_cl_hitsound == 1)
 898                                 pitch_shift = 1;
 899
 900                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 901                         if (autocvar_cl_hitsound == 3)
 902                         {
 903                                 float mirror_value = (a-b)/2 + b;
 904                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 905                         }
 906
 907                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 908
 909                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 910                         // todo: normalize sound pressure levels? seems unnecessary
 911
 912                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 913                 }
 914                 unaccounted_damage = 0;
 915                 hitsound_time_prev = time;
 916         }
 917
 918         static float typehit_time_prev = 0;
 919         float typehit_time = STAT(TYPEHIT_TIME);
 920         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 921         {
 922                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 923                 typehit_time_prev = typehit_time;
 924         }
 925
 926         static float kill_time_prev = 0;
 927         float kill_time = STAT(KILL_TIME);
 928         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 929         {
 930                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 931                 kill_time_prev = kill_time;
 932         }
 933 }
 934
 935 vector crosshair_getcolor(entity this, float health_stat)
 936 {
 937         static float rainbow_last_flicker;
 938         static vector rainbow_prev_color;
 939         vector wcross_color = '0 0 0';
 940         switch(autocvar_crosshair_color_special)
 941         {
 942                 case 1: // crosshair_color_per_weapon
 943                 {
 944                         if(this != WEP_Null && hud == HUD_NORMAL)
 945                         {
 946                                 wcross_color = this.wpcolor;
 947                                 break;
 948                         }
 949                         else { goto normalcolor; }
 950                 }
 951
 952                 case 2: // crosshair_color_by_health
 953                 {
 954                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
 955                         float hp = floor(v.x + 1);
 956
 957                         //x = red
 958                         //y = green
 959                         //z = blue
 960
 961                         wcross_color.z = 0;
 962
 963                         if(hp > 200)
 964                         {
 965                                 wcross_color.x = 0;
 966                                 wcross_color.y = 1;
 967                         }
 968                         else if(hp > 150)
 969                         {
 970                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 971                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 972                         }
 973                         else if(hp > 100)
 974                         {
 975                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 976                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 977                                 wcross_color.z = 1 - (hp-100)*0.02;
 978                         }
 979                         else if(hp > 50)
 980                         {
 981                                 wcross_color.x = 1;
 982                                 wcross_color.y = 1;
 983                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 984                         }
 985                         else if(hp > 20)
 986                         {
 987                                 wcross_color.x = 1;
 988                                 wcross_color.y = (hp-20)*90/27/100;
 989                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 990                         }
 991                         else
 992                         {
 993                                 wcross_color.x = 1;
 994                                 wcross_color.y = 0;
 995                         }
 996                         break;
 997                 }
 998
 999                 case 3: // crosshair_color_rainbow
1000                 {
1001                         if(time >= rainbow_last_flicker)
1002                         {
1003                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1004                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1005                         }
1006                         wcross_color = rainbow_prev_color;
1007                         break;
1008                 }
1009 LABEL(normalcolor)
1010                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1011         }
1012
1013         return wcross_color;
1014 }
1015
1016 void HUD_Crosshair(entity this)
1017 {
1018         float f, i, j;
1019         vector v;
1020         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
1021                 spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair) &&
1022                 !HUD_MinigameMenu_IsOpened() )
1023         {
1024                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
1025                         return;
1026
1027                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
1028                         return;
1029
1030                 if (hud != HUD_NORMAL)
1031                 {
1032                         HUD_Crosshair_Vehicle(this);
1033                         return;
1034                 }
1035
1036                 string wcross_style;
1037                 float wcross_alpha, wcross_resolution;
1038                 wcross_style = autocvar_crosshair;
1039                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
1040                         wcross_style = autocvar_crosshair_2d;
1041                 if (wcross_style == "0")
1042                         return;
1043                 wcross_resolution = autocvar_crosshair_size;
1044                 if (wcross_resolution == 0)
1045                         return;
1046                 wcross_alpha = autocvar_crosshair_alpha;
1047                 if (wcross_alpha == 0)
1048                         return;
1049
1050                 // TrueAim check
1051                 float shottype;
1052
1053                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1054                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
1055                         wcross_origin = viewloc_mousepos;
1056                 else
1057                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1058                 wcross_origin.z = 0;
1059                 if(autocvar_crosshair_hittest)
1060                 {
1061                         vector wcross_oldorigin;
1062                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1063                         wcross_oldorigin = wcross_origin;
1064                         shottype = TrueAimCheck(thiswep);
1065                         if(shottype == SHOTTYPE_HITWORLD)
1066                         {
1067                                 v = wcross_origin - wcross_oldorigin;
1068                                 v.x /= vid_conwidth;
1069                                 v.y /= vid_conheight;
1070                                 if(vdist(v, >, 0.01))
1071                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1072                         }
1073                         if(!autocvar_crosshair_hittest_showimpact)
1074                                 wcross_origin = wcross_oldorigin;
1075                 }
1076                 else
1077                         shottype = SHOTTYPE_HITWORLD;
1078
1079                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1080                 string wcross_name = "";
1081                 float wcross_scale, wcross_blur;
1082
1083         entity e = WEP_Null;
1084                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1085                 {
1086                         entity wepent = viewmodels[0]; // TODO: unhardcode
1087                         e = wepent.switchingweapon;
1088                         if(e)
1089                         {
1090                                 if(autocvar_crosshair_per_weapon)
1091                                 {
1092                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1093                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1094                                         //if (wcross_resolution == 0)
1095                                                 //return;
1096
1097                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1098                                         wcross_resolution *= e.w_crosshair_size;
1099                                         wcross_name = e.w_crosshair;
1100                                 }
1101                         }
1102                 }
1103
1104                 if(wcross_name == "")
1105                         wcross_name = strcat("gfx/crosshair", wcross_style);
1106
1107                 // MAIN CROSSHAIR COLOR DECISION
1108                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1109
1110                 if(autocvar_crosshair_effect_scalefade)
1111                 {
1112                         wcross_scale = wcross_resolution;
1113                         wcross_resolution = 1;
1114                 }
1115                 else
1116                 {
1117                         wcross_scale = 1;
1118                 }
1119
1120                 if(autocvar_crosshair_pickup)
1121                 {
1122                         float stat_pickup_time = STAT(LAST_PICKUP);
1123
1124                         if(pickup_crosshair_time < stat_pickup_time)
1125                         {
1126                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1127                                         pickup_crosshair_size = 1;
1128
1129                                 pickup_crosshair_time = stat_pickup_time;
1130                         }
1131
1132                         if(pickup_crosshair_size > 0)
1133                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1134                         else
1135                                 pickup_crosshair_size = 0;
1136
1137                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1138                 }
1139
1140                 // todo: make crosshair hit indication dependent on damage dealt
1141                 if(autocvar_crosshair_hitindication)
1142                 {
1143                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1144
1145                         if(unaccounted_damage)
1146                         {
1147                                 hitindication_crosshair_size = 1;
1148                         }
1149
1150                         if(hitindication_crosshair_size > 0)
1151                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1152                         else
1153                                 hitindication_crosshair_size = 0;
1154
1155                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1156                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1157                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1158                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1159                 }
1160
1161                 if(shottype == SHOTTYPE_HITENEMY)
1162                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1163                 if(shottype == SHOTTYPE_HITTEAM)
1164                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1165
1166                 f = fabs(autocvar_crosshair_effect_time);
1167                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1168                 {
1169                         wcross_changedonetime = time + f;
1170                 }
1171                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1172                 {
1173                         wcross_name_changestarttime = time;
1174                         wcross_name_changedonetime = time + f;
1175                         if(wcross_name_goal_prev_prev)
1176                                 strunzone(wcross_name_goal_prev_prev);
1177                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1178                         wcross_name_goal_prev = strzone(wcross_name);
1179                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1180                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1181                         wcross_resolution_goal_prev = wcross_resolution;
1182                 }
1183
1184                 wcross_scale_goal_prev = wcross_scale;
1185                 wcross_alpha_goal_prev = wcross_alpha;
1186                 wcross_color_goal_prev = wcross_color;
1187
1188                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1189                 {
1190                         wcross_blur = 1;
1191                         wcross_alpha *= 0.75;
1192                 }
1193                 else
1194                         wcross_blur = 0;
1195                 // *_prev is at time-frametime
1196                 // * is at wcross_changedonetime+f
1197                 // what do we have at time?
1198                 if(time < wcross_changedonetime)
1199                 {
1200                         f = frametime / (wcross_changedonetime - time + frametime);
1201                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1202                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1203                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1204                 }
1205
1206                 wcross_scale_prev = wcross_scale;
1207                 wcross_alpha_prev = wcross_alpha;
1208                 wcross_color_prev = wcross_color;
1209
1210                 MUTATOR_CALLHOOK(UpdateCrosshair);
1211
1212                 wcross_scale *= 1 - autocvar__menu_alpha;
1213                 wcross_alpha *= 1 - autocvar__menu_alpha;
1214                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1215
1216                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1217                 {
1218                         // crosshair rings for weapon stats
1219                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1220                         {
1221                                 // declarations and stats
1222                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1223                                 string ring_image = string_null, ring_inner_image = string_null;
1224                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1225
1226                                 ring_scale = autocvar_crosshair_ring_size;
1227
1228                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1229
1230                                 int weapon_clipload = wepent.clip_load;
1231                                 int weapon_clipsize = wepent.clip_size;
1232
1233                                 float arc_heat = wepent.arc_heat_percent;
1234                                 float vcharge = wepent.vortex_charge;
1235                                 float vchargepool = wepent.vortex_chargepool_ammo;
1236                                 float oknex_charge_ = wepent.oknex_charge;
1237                                 float oknex_chargepool_ = wepent.oknex_chargepool_ammo;
1238
1239                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1240                                         vortex_charge_movingavg = vcharge;
1241
1242                                 // handle the values
1243                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vcharge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1244                                 {
1245                                         if (vchargepool || use_vortex_chargepool) {
1246                                                 use_vortex_chargepool = 1;
1247                                                 ring_inner_value = vchargepool;
1248                                         } else {
1249                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vcharge;
1250                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vcharge - vortex_charge_movingavg), 1);
1251                                         }
1252
1253                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1254                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1255                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1256
1257                                         // draw the outer ring to show the current charge of the weapon
1258                                         ring_value = vcharge;
1259                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1260                                         ring_rgb = wcross_color;
1261                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1262                                 }
1263                                 else if (autocvar_crosshair_ring && (wepent.activeweapon == WEP_OVERKILL_NEX) && oknex_charge_ && autocvar_crosshair_ring_vortex)
1264                                 {
1265                                         if (oknex_chargepool_ || use_vortex_chargepool) {
1266                                                 use_vortex_chargepool = 1;
1267                                                 ring_inner_value = oknex_chargepool_;
1268                                         } else {
1269                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * oknex_charge_;
1270                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (oknex_charge_ - vortex_charge_movingavg), 1);
1271                                         }
1272
1273                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1274                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1275                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1276
1277                                         // draw the outer ring to show the current charge of the weapon
1278                                         ring_value = oknex_charge_;
1279                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1280                                         ring_rgb = wcross_color;
1281                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1282                                 }
1283                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1284                                 {
1285                                         ring_value = bound(0, wepent.minelayer_mines / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1286                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1287                                         ring_rgb = wcross_color;
1288                                         ring_image = "gfx/crosshair_ring.tga";
1289                                 }
1290                                 else if (wepent.activeweapon == WEP_HAGAR && wepent.hagar_load && autocvar_crosshair_ring_hagar)
1291                                 {
1292                                         ring_value = bound(0, wepent.hagar_load / WEP_CVAR_SEC(hagar, load_max), 1);
1293                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1294                                         ring_rgb = wcross_color;
1295                                         ring_image = "gfx/crosshair_ring.tga";
1296                                 }
1297                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1298                                 {
1299                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1300                                         ring_scale = autocvar_crosshair_ring_reload_size;
1301                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1302                                         ring_rgb = wcross_color;
1303
1304                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1305                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1306                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1307                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1308                                         else
1309                                                 ring_image = "gfx/crosshair_ring.tga";
1310                                 }
1311                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1312                                 {
1313                                         ring_value = arc_heat;
1314                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1315                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1316                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1317                                         ring_image = "gfx/crosshair_ring.tga";
1318                                 }
1319
1320                                 // if in weapon switch animation, fade ring out/in
1321                                 if(autocvar_crosshair_effect_time > 0)
1322                                 {
1323                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1324                                         if (f >= 1)
1325                                         {
1326                                                 wcross_ring_prev = ((ring_image) ? true : false);
1327                                         }
1328
1329                                         if(wcross_ring_prev)
1330                                         {
1331                                                 if(f < 1)
1332                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1333                                         }
1334                                         else
1335                                         {
1336                                                 if(f < 1)
1337                                                         ring_alpha *= bound(0, f, 1);
1338                                         }
1339                                 }
1340
1341                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1342                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1343
1344                                 if (ring_value)
1345                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1346                         }
1347
1348 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1349                         MACRO_BEGIN \
1350                                 vector scaled_sz = sz * wcross_size; \
1351                                 if(wcross_blur > 0) \
1352                                 { \
1353                                         for(i = -2; i <= 2; ++i) \
1354                                         for(j = -2; j <= 2; ++j) \
1355                                         M(i,j,sz,scaled_sz,wcross_name,wcross_alpha*0.04); \
1356                                 } \
1357                                 else \
1358                                 { \
1359                                         M(0,0,sz,scaled_sz,wcross_name,wcross_alpha); \
1360                                 } \
1361                         MACRO_END
1362
1363 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,scaled_sz,wcross_name,wcross_alpha) \
1364                         drawpic(wcross_origin - ('0.5 0 0' * (scaled_sz.x + i * wcross_blur) + '0 0.5 0' * (scaled_sz.y + j * wcross_blur)), wcross_name, scaled_sz, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1365
1366 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1367                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1368
1369                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1370                         {
1371                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1372                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1373                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1374                                 f = 1 - f;
1375                         }
1376                         else
1377                         {
1378                                 f = 1;
1379                         }
1380                         wcross_name_alpha_goal_prev = f;
1381
1382                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1383                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1384
1385                         if(autocvar_crosshair_dot)
1386                         {
1387                                 vector wcross_color_old;
1388                                 wcross_color_old = wcross_color;
1389
1390                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1391                                         wcross_color = stov(autocvar_crosshair_dot_color);
1392
1393                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1394                                 // FIXME why don't we use wcross_alpha here?
1395                                 wcross_color = wcross_color_old;
1396                         }
1397                 }
1398         }
1399         else
1400         {
1401                 wcross_scale_prev = 0;
1402                 wcross_alpha_prev = 0;
1403                 wcross_scale_goal_prev = 0;
1404                 wcross_alpha_goal_prev = 0;
1405                 wcross_changedonetime = 0;
1406                 strfree(wcross_name_goal_prev);
1407                 strfree(wcross_name_goal_prev_prev);
1408                 wcross_name_changestarttime = 0;
1409                 wcross_name_changedonetime = 0;
1410                 wcross_name_alpha_goal_prev = 0;
1411                 wcross_name_alpha_goal_prev_prev = 0;
1412                 wcross_resolution_goal_prev = 0;
1413                 wcross_resolution_goal_prev_prev = 0;
1414         }
1415 }
1416
1417 const int MAX_SPECIALCOMMAND = 15;
1418 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1419 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1420 const float SPECIALCOMMAND_SPEED = 150;
1421 const float SPECIALCOMMAND_TURNSPEED = 2;
1422 const float SPECIALCOMMAND_SIZE = 0.025;
1423 const float SPECIALCOMMAND_CHANCE = 0.35;
1424 float sc_spawntime, sc_changetime;
1425 vector sc_color = '1 1 1';
1426 void SpecialCommand()
1427 {
1428         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1429                 return;
1430
1431         if(time >= sc_changetime)
1432         {
1433                 sc_changetime = time + 1;
1434                 sc_color = randomvec() * 1.5;
1435                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1436                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1437                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1438         }
1439         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1440
1441         if(!precache_pic("gfx/smile"))
1442                 return; // damn party poopers
1443
1444         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1445         {
1446                 vector slot = specialcommand_slots[j];
1447                 if(slot.y)
1448                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1449                 //if(slot.z)
1450                         //slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1451                 if(slot.y >= vid_conheight)
1452                         slot = '0 0 0';
1453
1454                 if(slot == '0 0 0')
1455                 {
1456                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1457                         {
1458                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1459                                 slot.y = 1; // start it off 0 so we can use it
1460                                 slot.z = floor(random() * Weapons_MAX);
1461                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1462                                 vector newcolor = randomvec() * 2;
1463                                 newcolor.x = bound(0.4, newcolor.x, 1);
1464                                 newcolor.y = bound(0.4, newcolor.y, 1);
1465                                 newcolor.z = bound(0.4, newcolor.z, 1);
1466                                 specialcommand_colors[j] = newcolor;
1467                         }
1468                 }
1469                 else
1470                 {
1471                         vector splash_size = '0 0 0';
1472                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1473                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1474                         entity wep = Weapons_from(slot.z);
1475                         if(wep == WEP_Null)
1476                                 drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1477                         else
1478                                 drawpic_skin(vec2(slot), wep.model2, vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1479                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1480                 }
1481
1482                 specialcommand_slots[j] = slot;
1483         }
1484 }
1485
1486 void HUD_Draw(entity this)
1487 {
1488         // if we don't know gametype and scores yet avoid drawing the scoreboard
1489         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1490         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1491         // cl_deathscoreboard would show the scoreboard and so on
1492         if(!gametype)
1493                 return;
1494
1495         Hud_Dynamic_Frame();
1496
1497         if(!intermission)
1498         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1499         {
1500                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1501         }
1502         else if(STAT(FROZEN))
1503         {
1504                 vector col = '0.25 0.90 1';
1505                 if(STAT(REVIVE_PROGRESS))
1506                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1507                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1508         }
1509
1510         HUD_Scale_Enable();
1511         if(!intermission)
1512         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1513         {
1514                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1515                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1516                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1517         }
1518         else if(STAT(CAPTURE_PROGRESS))
1519         {
1520                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1521                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1522         }
1523         else if(STAT(REVIVE_PROGRESS))
1524         {
1525                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1526                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1527         }
1528         HUD_Scale_Disable();
1529
1530         if(autocvar_r_letterbox == 0)
1531                 if(autocvar_viewsize < 120)
1532                 {
1533                         if(!(ISGAMETYPE(RACE) || ISGAMETYPE(CTS)))
1534                                 Accuracy_LoadLevels();
1535
1536                         HUD_Main();
1537                         HUD_Scale_Disable();
1538                 }
1539
1540         // crosshair goes VERY LAST
1541         SpecialCommand();
1542         UpdateDamage();
1543         HUD_Crosshair(this);
1544         HitSound();
1545 }
1546
1547 void ViewLocation_Mouse()
1548 {
1549         if(spectatee_status)
1550                 return; // don't draw it as spectator!
1551
1552         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1553         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1554         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1555
1556         //float cursor_alpha = 1 - autocvar__menu_alpha;
1557         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1558 }
1559
1560 void HUD_Cursor_Show()
1561 {
1562         float cursor_alpha = 1 - autocvar__menu_alpha;
1563         if(cursor_type == CURSOR_NORMAL)
1564                 draw_cursor_normal(mousepos, '1 1 1', cursor_alpha);
1565         else if(cursor_type == CURSOR_MOVE)
1566                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1567         else if(cursor_type == CURSOR_RESIZE)
1568                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize", '1 1 1', cursor_alpha);
1569         else if(cursor_type == CURSOR_RESIZE2)
1570                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize2", '1 1 1', cursor_alpha);
1571 }
1572
1573 void HUD_Mouse(entity player)
1574 {
1575         if(autocvar__menu_alpha == 1)
1576                 return;
1577
1578         if(!cursor_active)
1579         {
1580                 if(player.viewloc && (player.viewloc.spawnflags & VIEWLOC_FREEAIM))
1581                         ViewLocation_Mouse(); // NOTE: doesn't use cursormode
1582                 return;
1583         }
1584
1585         if (cursor_active == -1) // starting to display the cursor
1586         {
1587                 // since HUD_Mouse is called by CSQC_UpdateView before CSQC_InputEvent,
1588                 // in the first frame mousepos is the mouse position of the last time
1589                 // the cursor was displayed, thus we ignore it to avoid a glictch
1590                 cursor_active = 1;
1591                 return;
1592         }
1593
1594         if(!autocvar_hud_cursormode)
1595                 update_mousepos();
1596
1597         if(autocvar__hud_configure)
1598                 HUD_Panel_Mouse();
1599         else
1600         {
1601                 if (HUD_MinigameMenu_IsOpened())
1602                         HUD_Minigame_Mouse();
1603                 if (QuickMenu_IsOpened())
1604                         QuickMenu_Mouse();
1605                 if (HUD_Radar_Clickable())
1606                         HUD_Radar_Mouse();
1607         }
1608
1609         prevMouseClicked = mouseClicked;
1610
1611         HUD_Cursor_Show();
1612 }
1613
1614 bool ov_enabled;
1615 float oldr_nearclip;
1616 float oldr_farclip_base;
1617 float oldr_farclip_world;
1618 float oldr_novis;
1619 float oldr_useportalculling;
1620 float oldr_useinfinitefarclip;
1621
1622 float prev_myteam;
1623 int lasthud;
1624 float vh_notice_time;
1625 void CSQC_UpdateView(entity this, float w, float h)
1626 {
1627         TC(int, w); TC(int, h);
1628         entity e;
1629         float fov;
1630         float f;
1631         vector vf_size, vf_min;
1632         float a;
1633
1634         execute_next_frame();
1635
1636         ++framecount;
1637
1638         stats_get();
1639         hud = STAT(HUD);
1640
1641         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1642                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1643
1644         lasthud = hud;
1645
1646         HUD_Scale_Disable();
1647
1648         if(autocvar__hud_showbinds_reload) // menu can set this one
1649         {
1650                 db_close(binddb);
1651                 binddb = db_create();
1652                 cvar_set("_hud_showbinds_reload", "0");
1653         }
1654
1655         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1656                 view_quality = getproperty(VF_MINFPS_QUALITY);
1657         else
1658                 view_quality = 1;
1659
1660         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1661         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1662
1663         vf_size = getpropertyvec(VF_SIZE);
1664         vf_min = getpropertyvec(VF_MIN);
1665         vid_width = vf_size.x;
1666         vid_height = vf_size.y;
1667
1668         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1669         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1670
1671         WaypointSprite_Load();
1672
1673         CSQCPlayer_SetCamera();
1674
1675         if(player_localentnum <= maxclients) // is it a client?
1676                 current_player = player_localentnum - 1;
1677         else // then player_localentnum is the vehicle I'm driving
1678                 current_player = player_localnum;
1679         myteam = entcs_GetTeam(current_player);
1680
1681         if(myteam != prev_myteam)
1682         {
1683                 myteamcolors = colormapPaletteColor(myteam, 1);
1684                 FOREACH(hud_panels, true, it.update_time = time);
1685                 prev_myteam = myteam;
1686         }
1687
1688         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1689
1690         float is_dead = (STAT(HEALTH) <= 0);
1691
1692         // FIXME do we need this hack?
1693         if(isdemo())
1694         {
1695                 // in demos, input_buttons do not work
1696                 button_zoom = (autocvar__togglezoom == "-");
1697         }
1698         else if(button_zoom
1699                 && autocvar_cl_unpress_zoom_on_death
1700                 && (spectatee_status >= 0)
1701                 && (is_dead || intermission))
1702         {
1703                 // no zoom while dead or in intermission please
1704                 localcmd("-zoom\n");
1705                 button_zoom = false;
1706         }
1707
1708         // abused multiple places below
1709         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1710         if(!local_player)
1711                 local_player = this; // fall back!
1712
1713         // event chase camera
1714         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1715         {
1716                 if(STAT(CAMERA_SPECTATOR))
1717                 {
1718                         if(spectatee_status > 0)
1719                         {
1720                                 if(!autocvar_chase_active)
1721                                 {
1722                                         cvar_set("chase_active", "-2");
1723                                         goto skip_eventchase_death;
1724                                 }
1725                         }
1726                         else if(autocvar_chase_active == -2)
1727                                 cvar_set("chase_active", "0");
1728
1729                         if(autocvar_chase_active == -2)
1730                                 goto skip_eventchase_death;
1731                 }
1732                 else if(autocvar_chase_active == -2)
1733                         cvar_set("chase_active", "0");
1734
1735                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1736
1737                 float vehicle_viewdist = 0;
1738                 vector vehicle_viewofs = '0 0 0';
1739
1740                 if(vehicle_chase)
1741                 {
1742                         if(hud != HUD_BUMBLEBEE_GUN)
1743                         {
1744                                 Vehicle info = Vehicles_from(hud);
1745                                 vehicle_viewdist = info.height;
1746                                 vehicle_viewofs = info.view_ofs;
1747                         }
1748                 }
1749
1750                 int eventchase = WantEventchase(this);
1751                 if (eventchase)
1752                 {
1753                         vector current_view_origin_override = '0 0 0';
1754                         vector view_offset_override = '0 0 0';
1755                         float chase_distance_override = 0;
1756                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1757                         if(custom_eventchase)
1758                         {
1759                                 current_view_origin_override = M_ARGV(0, vector);
1760                                 view_offset_override = M_ARGV(1, vector);
1761                                 chase_distance_override = M_ARGV(0, float);
1762                         }
1763                         eventchase_running = true;
1764
1765                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1766                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1767                         if (custom_eventchase)
1768                                 current_view_origin = current_view_origin_override;
1769
1770                         // detect maximum viewoffset and use it
1771                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1772                         if(vehicle_chase)
1773                         {
1774                                 if(vehicle_viewofs)
1775                                         view_offset = vehicle_viewofs;
1776                                 else
1777                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1778                         }
1779                         if (custom_eventchase)
1780                                 view_offset = view_offset_override;
1781
1782                         if(view_offset)
1783                         {
1784                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1785                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1786                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1787                         }
1788
1789                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1790                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1791                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1792                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1793
1794                         // make the camera smooth back
1795                         float chase_distance = autocvar_cl_eventchase_distance;
1796                         if(vehicle_chase)
1797                         {
1798                                 if(vehicle_viewofs)
1799                                         chase_distance = vehicle_viewdist;
1800                                 else
1801                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1802                         }
1803                         if (custom_eventchase)
1804                                 chase_distance = chase_distance_override;
1805
1806                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1807                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1808                         else if(eventchase_current_distance != chase_distance)
1809                                 eventchase_current_distance = chase_distance;
1810
1811                         MAKE_VECTORS_NEW(view_angles, forward, right, up);
1812
1813                         vector eventchase_target_origin = (current_view_origin - (forward * eventchase_current_distance));
1814                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1815
1816                         // If the boxtrace fails, revert back to line tracing.
1817                         if(!local_player.viewloc)
1818                         if(trace_startsolid)
1819                         {
1820                                 eventchase_target_origin = (current_view_origin - (forward * eventchase_current_distance));
1821                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1822                                 setproperty(VF_ORIGIN, (trace_endpos - (forward * autocvar_cl_eventchase_mins.z)));
1823                         }
1824                         else { setproperty(VF_ORIGIN, trace_endpos); }
1825
1826                         if(!local_player.viewloc)
1827                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1828                 }
1829
1830                 if (eventchase <= 0 && autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1831                 {
1832                         eventchase_running = false;
1833                         cvar_set("chase_active", "0");
1834                         eventchase_current_distance = 0; // start from 0 next time
1835                 }
1836         }
1837         // workaround for camera stuck between player's legs when using chase_active 1
1838         // because the engine stops updating the chase_active camera when the game ends
1839         else if(intermission)
1840         {
1841                 cvar_settemp("chase_active", "-1");
1842                 eventchase_current_distance = 0;
1843         }
1844
1845         LABEL(skip_eventchase_death);
1846
1847         // do lockview after event chase camera so that it still applies whenever necessary.
1848         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1849         {
1850                 setproperty(VF_ORIGIN, freeze_org);
1851                 setproperty(VF_ANGLES, freeze_ang);
1852         }
1853         else
1854         {
1855                 freeze_org = getpropertyvec(VF_ORIGIN);
1856                 freeze_ang = getpropertyvec(VF_ANGLES);
1857         }
1858
1859         WarpZone_FixView();
1860         //WarpZone_FixPMove();
1861
1862         vector ov_org = '0 0 0';
1863         vector ov_mid = '0 0 0';
1864         vector ov_worldmin = '0 0 0';
1865         vector ov_worldmax = '0 0 0';
1866         if(autocvar_cl_orthoview)
1867         {
1868                 ov_worldmin = mi_picmin;
1869                 ov_worldmax = mi_picmax;
1870
1871                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1872                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1873                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1874
1875                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1876                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1877
1878                 float ov_nearest = vlen(ov_org - vec3(
1879                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1880                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1881                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1882                 ));
1883
1884                 float ov_furthest = 0;
1885                 float dist = 0;
1886
1887                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1888                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1889                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1890                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1891                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1892                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1893                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1894                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1895
1896                 if(!ov_enabled)
1897                 {
1898                         oldr_nearclip = cvar("r_nearclip");
1899                         oldr_farclip_base = cvar("r_farclip_base");
1900                         oldr_farclip_world = cvar("r_farclip_world");
1901                         oldr_novis = cvar("r_novis");
1902                         oldr_useportalculling = cvar("r_useportalculling");
1903                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1904                 }
1905
1906                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1907                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1908                 cvar_settemp("r_farclip_world", "0");
1909                 cvar_settemp("r_novis", "1");
1910                 cvar_settemp("r_useportalculling", "0");
1911                 cvar_settemp("r_useinfinitefarclip", "0");
1912
1913                 setproperty(VF_ORIGIN, ov_org);
1914                 setproperty(VF_ANGLES, '90 0 0');
1915
1916                 ov_enabled = true;
1917
1918                 #if 0
1919                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1920                         vtos(ov_org),
1921                         vtos(getpropertyvec(VF_ANGLES)),
1922                         ov_distance,
1923                         ov_nearest,
1924                         ov_furthest);
1925                 #endif
1926         }
1927         else
1928         {
1929                 if(ov_enabled)
1930                 {
1931                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1932                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1933                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1934                         cvar_set("r_novis", ftos(oldr_novis));
1935                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1936                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1937                 }
1938                 ov_enabled = false;
1939         }
1940
1941         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1942         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1943         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1944                 viewmodel_draw(viewmodels[slot]);
1945
1946         // Render the Scene
1947         view_origin = getpropertyvec(VF_ORIGIN);
1948         view_angles = getpropertyvec(VF_ANGLES);
1949         MAKE_VECTORS(view_angles, view_forward, view_right, view_up);
1950
1951 #ifdef BLURTEST
1952         if(time > blurtest_time0 && time < blurtest_time1)
1953         {
1954                 float r, t;
1955
1956                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1957                 r = t * blurtest_radius;
1958                 f = 1 / (t ** blurtest_power) - 1;
1959
1960                 cvar_set("r_glsl_postprocess", "1");
1961                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1962         }
1963         else
1964         {
1965                 cvar_set("r_glsl_postprocess", "0");
1966                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1967         }
1968 #endif
1969
1970         TargetMusic_Advance();
1971         Fog_Force();
1972         fpscounter_update();
1973
1974         if(drawtime == 0)
1975                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1976         else
1977                 drawframetime = bound(0.000001, time - drawtime, 1);
1978         drawtime = time;
1979
1980         // watch for gametype changes here...
1981         // in ParseStuffCMD the cmd isn't executed yet :/
1982         // might even be better to add the gametype to TE_CSQC_INIT...?
1983         if(!postinit)
1984                 PostInit();
1985
1986         if(intermission && !intermission_time)
1987                 intermission_time = time;
1988
1989         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1990         {
1991                 if(calledhooks & HOOK_START)
1992                 {
1993                         localcmd("\ncl_hook_gameend\n");
1994                         calledhooks |= HOOK_END;
1995                 }
1996         }
1997
1998         Announcer();
1999
2000         fov = autocvar_fov;
2001         if(fov <= 59.5)
2002         {
2003                 if(!zoomscript_caught)
2004                 {
2005                         localcmd("+button9\n");
2006                         zoomscript_caught = 1;
2007                 }
2008         }
2009         else
2010         {
2011                 if(zoomscript_caught)
2012                 {
2013                         localcmd("-button9\n");
2014                         zoomscript_caught = 0;
2015                 }
2016         }
2017
2018         if(active_minigame && HUD_MinigameMenu_IsOpened())
2019         {
2020                 if(!minigame_wasactive)
2021                 {
2022                         localcmd("+button12\n");
2023                         minigame_wasactive = true;
2024                 }
2025         }
2026         else if(minigame_wasactive)
2027         {
2028                 localcmd("-button12\n");
2029                 minigame_wasactive = false;
2030         }
2031
2032         ColorTranslateMode = autocvar_cl_stripcolorcodes;
2033
2034         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2035         {
2036                 entity wepent = viewmodels[slot];
2037
2038                 if(wepent.last_switchweapon != wepent.switchweapon)
2039                 {
2040                         weapontime = time;
2041                         wepent.last_switchweapon = wepent.switchweapon;
2042                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
2043                         {
2044                                 localcmd("-zoom\n");
2045                                 button_zoom = false;
2046                         }
2047                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
2048                         {
2049                                 localcmd("-fire\n");
2050                                 localcmd("-fire2\n");
2051                                 button_attack2 = false;
2052                         }
2053                 }
2054                 if(wepent.last_activeweapon != wepent.activeweapon)
2055                 {
2056                         wepent.last_activeweapon = wepent.activeweapon;
2057
2058                         e = wepent.activeweapon;
2059                         if(e.netname != "")
2060                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
2061                         else if(slot == 0)
2062                                 localcmd("\ncl_hook_activeweapon none\n");
2063                 }
2064         }
2065
2066         // ALWAYS Clear Current Scene First
2067         clearscene();
2068
2069         setproperty(VF_ORIGIN, view_origin);
2070         setproperty(VF_ANGLES, view_angles);
2071
2072         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
2073         setproperty(VF_SIZE, vf_size);
2074         setproperty(VF_MIN, vf_min);
2075
2076         // Assign Standard Viewflags
2077         // Draw the World (and sky)
2078         setproperty(VF_DRAWWORLD, 1);
2079
2080         // Set the console size vars
2081         vid_conwidth = autocvar_vid_conwidth;
2082         vid_conheight = autocvar_vid_conheight;
2083         vid_pixelheight = autocvar_vid_pixelheight;
2084
2085         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
2086         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
2087         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
2088
2089         if(camera_active) // Camera for demo playback
2090         {
2091                 if(autocvar_camera_enable)
2092                         CSQC_Demo_Camera();
2093                 else
2094                 {
2095                         cvar_set("chase_active", ftos(chase_active_backup));
2096                         cvar_set("cl_demo_mousegrab", "0");
2097                         camera_active = false;
2098                 }
2099         }
2100         else
2101         {
2102 #ifdef CAMERATEST
2103                 if(autocvar_camera_enable)
2104 #else
2105                 if(autocvar_camera_enable && isdemo())
2106 #endif
2107                 {
2108                         // Enable required Darkplaces cvars
2109                         chase_active_backup = autocvar_chase_active;
2110                         cvar_set("chase_active", "2");
2111                         cvar_set("cl_demo_mousegrab", "1");
2112                         camera_active = true;
2113                         camera_mode = false;
2114                 }
2115         }
2116
2117         // Draw the Crosshair
2118         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
2119
2120         // Draw the Engine Status Bar (the default Quake HUD)
2121         setproperty(VF_DRAWENGINESBAR, 0);
2122
2123         // Update the mouse position
2124         /*
2125            mousepos_x = vid_conwidth;
2126            mousepos_y = vid_conheight;
2127            mousepos = mousepos*0.5 + getmousepos();
2128          */
2129
2130         IL_EACH(g_drawables, it.draw, it.draw(it));
2131
2132         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS); // TODO: .health is used in cl_deathfade (a feature we have turned off currently)
2133         renderscene();
2134
2135         // now switch to 2D drawing mode by calling a 2D drawing function
2136         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
2137         // next R_RenderScene call
2138         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
2139
2140         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
2141         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
2142         {
2143                 // apply night vision effect
2144                 vector tc_00, tc_01, tc_10, tc_11;
2145                 vector rgb = '0 0 0';
2146
2147                 if(!nightvision_noise)
2148                 {
2149                         nightvision_noise = new(nightvision_noise);
2150                 }
2151                 if(!nightvision_noise2)
2152                 {
2153                         nightvision_noise2 = new(nightvision_noise2);
2154                 }
2155
2156                 // color tint in yellow
2157                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2158
2159                 // draw BG
2160                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2161                 rgb = '1 1 1';
2162                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2163                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2164                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2165                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2166                 tc_11 = tc_01 + tc_10 - tc_00;
2167                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2168                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2169                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2170                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2171                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2172                 R_EndPolygon();
2173
2174                 // draw FG
2175                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2176                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2177                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2178                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2179                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2180                 tc_11 = tc_01 + tc_10 - tc_00;
2181                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2182                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2183                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2184                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2185                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2186                 R_EndPolygon();
2187         }
2188
2189         if(autocvar_cl_reticle && !MUTATOR_CALLHOOK(DrawReticle))
2190         {
2191                 string reticle_image = string_null;
2192                 bool wep_zoomed = false;
2193                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2194                 {
2195                         entity wepe = viewmodels[slot];
2196                         Weapon wep = wepe.activeweapon;
2197                         if(wep != WEP_Null && wep.wr_zoom)
2198                         {
2199                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2200                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2201                                         reticle_image = wep.w_reticle;
2202                                 wep_zoomed += do_zoom;
2203                         }
2204                 }
2205                 // Draw the aiming reticle for weapons that use it
2206                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2207                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2208                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2209                 if(spectatee_status || is_dead || hud != HUD_NORMAL || local_player.viewloc)
2210                 {
2211                         // no zoom reticle while dead
2212                         reticle_type = 0;
2213                 }
2214                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2215                 {
2216                         if(reticle_image) { reticle_type = 2; }
2217                         else { reticle_type = 0; }
2218                 }
2219                 else if(button_zoom || zoomscript_caught)
2220                 {
2221                         // normal zoom
2222                         reticle_type = 1;
2223                 }
2224
2225                 if(reticle_type)
2226                 {
2227                         if(autocvar_cl_reticle_stretch)
2228                         {
2229                                 reticle_size.x = vid_conwidth;
2230                                 reticle_size.y = vid_conheight;
2231                                 reticle_pos.x = 0;
2232                                 reticle_pos.y = 0;
2233                         }
2234                         else
2235                         {
2236                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2237                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2238                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2239                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2240                         }
2241
2242                         if(zoomscript_caught)
2243                                 f = 1;
2244                         else
2245                                 f = current_zoomfraction;
2246
2247                         if(f)
2248                         {
2249                                 switch(reticle_type)
2250                                 {
2251                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2252                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2253                                 }
2254                         }
2255                 }
2256         }
2257         else
2258         {
2259                 if(reticle_type != 0) { reticle_type = 0; }
2260         }
2261
2262
2263         // improved polyblend
2264         if(autocvar_hud_contents && !MUTATOR_CALLHOOK(HUD_Contents))
2265         {
2266                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2267                 vector liquidcolor;
2268
2269                 switch(pointcontents(view_origin))
2270                 {
2271                         case CONTENT_WATER:
2272                                 liquidalpha = autocvar_hud_contents_water_alpha;
2273                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2274                                 incontent = 1;
2275                                 break;
2276
2277                         case CONTENT_LAVA:
2278                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2279                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2280                                 incontent = 1;
2281                                 break;
2282
2283                         case CONTENT_SLIME:
2284                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2285                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2286                                 incontent = 1;
2287                                 break;
2288
2289                         default:
2290                                 liquidalpha = 0;
2291                                 liquidcolor = '0 0 0';
2292                                 incontent = 0;
2293                                 break;
2294                 }
2295
2296                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2297                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2298                         contentfadetime = autocvar_hud_contents_fadeintime;
2299                         liquidalpha_prev = liquidalpha;
2300                         liquidcolor_prev = liquidcolor;
2301                 }
2302                 else
2303                         contentfadetime = autocvar_hud_contents_fadeouttime;
2304
2305                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2306                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2307
2308                 if(contentavgalpha)
2309                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2310
2311                 if(autocvar_hud_postprocessing)
2312                 {
2313                         if(autocvar_hud_contents_blur && contentavgalpha)
2314                         {
2315                                 content_blurpostprocess.x = 1;
2316                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2317                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2318                         }
2319                         else
2320                         {
2321                                 content_blurpostprocess.x = 0;
2322                                 content_blurpostprocess.y = 0;
2323                                 content_blurpostprocess.z = 0;
2324                         }
2325                 }
2326         }
2327
2328         if(autocvar_hud_damage && !STAT(FROZEN))
2329         {
2330                 splash_size.x = max(vid_conwidth, vid_conheight);
2331                 splash_size.y = max(vid_conwidth, vid_conheight);
2332                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2333                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2334
2335                 float myhealth_flash_temp;
2336                 myhealth = STAT(HEALTH);
2337
2338                 // fade out
2339                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2340                 // add new damage
2341                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2342
2343                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2344                 pain_threshold = autocvar_hud_damage_pain_threshold;
2345                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2346                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2347
2348                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2349                 {
2350                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2351                 }
2352
2353                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2354
2355                 if(myhealth_prev < 1)
2356                 {
2357                         if(myhealth >= 1)
2358                         {
2359                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2360                                 myhealth_flash_temp = 0;
2361                         }
2362                         else
2363                         {
2364                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2365                         }
2366                 }
2367
2368                 if(spectatee_status == -1 || intermission)
2369                 {
2370                         myhealth_flash = 0; // observing, or match ended
2371                         myhealth_flash_temp = 0;
2372                 }
2373
2374                 myhealth_prev = myhealth;
2375
2376                 // IDEA: change damage color/picture based on player model for robot/alien species?
2377                 // pro: matches model better
2378                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2379                 // maybe different reddish pics?
2380                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2381                 {
2382                         if(autocvar_cl_gentle_damage == 2)
2383                         {
2384                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2385                                         myhealth_gentlergb = randomvec();
2386                         }
2387                         else
2388                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2389
2390                         if(myhealth_flash_temp > 0)
2391                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2392                 }
2393                 else if(myhealth_flash_temp > 0)
2394                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2395
2396                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2397                 {
2398                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2399                         {
2400                                 damage_blurpostprocess.x = 1;
2401                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2402                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2403                         }
2404                         else
2405                         {
2406                                 damage_blurpostprocess.x = 0;
2407                                 damage_blurpostprocess.y = 0;
2408                                 damage_blurpostprocess.z = 0;
2409                         }
2410                 }
2411         }
2412
2413         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2414         float e2 = (autocvar_hud_powerup != 0);
2415         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2416         {
2417                 // enable or disable rendering types if they are used or not
2418                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2419                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2420
2421                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2422                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2423                 {
2424                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2425                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2426                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2427                         {
2428                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2429                                 old_blurradius = blurradius;
2430                                 old_bluralpha = bluralpha;
2431                         }
2432                 }
2433                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2434                 {
2435                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2436                         old_blurradius = 0;
2437                         old_bluralpha = 0;
2438                 }
2439
2440                 // edge detection postprocess handling done second (used by hud_powerup)
2441                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2442                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2443                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2444
2445                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2446
2447                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2448                 {
2449                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2450                         {
2451                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2452                                 old_sharpen_intensity = sharpen_intensity;
2453                         }
2454                 }
2455                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2456                 {
2457                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2458                         old_sharpen_intensity = 0;
2459                 }
2460
2461                 if(cvar("r_glsl_postprocess") == 0)
2462                         cvar_set("r_glsl_postprocess", "2");
2463         }
2464         else if(cvar("r_glsl_postprocess") == 2)
2465                 cvar_set("r_glsl_postprocess", "0");
2466
2467         /*if(ISGAMETYPE(CTF))
2468           {
2469           ctf_view();
2470           } else */
2471
2472         // draw 2D entities
2473         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2474         Draw_ShowNames_All();
2475 #if ENABLE_DEBUGDRAW
2476         Debug_Draw();
2477 #endif
2478
2479         scoreboard_active = Scoreboard_WouldDraw();
2480
2481         HUD_Draw(this); // this parameter for deep vehicle function
2482
2483         if(NextFrameCommand)
2484         {
2485                 localcmd("\n", NextFrameCommand, "\n");
2486                 NextFrameCommand = string_null;
2487         }
2488
2489         // we must do this check AFTER a frame was rendered, or it won't work
2490         if(cs_project_is_b0rked == 0)
2491         {
2492                 string w0, h0;
2493                 w0 = ftos(autocvar_vid_conwidth);
2494                 h0 = ftos(autocvar_vid_conheight);
2495                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2496                 //setproperty(VF_FOV, '90 90 0');
2497                 setproperty(VF_ORIGIN, '0 0 0');
2498                 setproperty(VF_ANGLES, '0 0 0');
2499                 setproperty(VF_PERSPECTIVE, 1);
2500                 MAKE_VECTORS_NEW('0 0 0', forward, right, up);
2501                 vector v1, v2;
2502                 cvar_set("vid_conwidth", "800");
2503                 cvar_set("vid_conheight", "600");
2504                 v1 = cs_project(forward);
2505                 cvar_set("vid_conwidth", "640");
2506                 cvar_set("vid_conheight", "480");
2507                 v2 = cs_project(forward);
2508                 if(v1 == v2)
2509                         cs_project_is_b0rked = 1;
2510                 else
2511                         cs_project_is_b0rked = -1;
2512                 cvar_set("vid_conwidth", w0);
2513                 cvar_set("vid_conheight", h0);
2514         }
2515
2516         HUD_Mouse(local_player);
2517
2518         cl_notice_run();
2519         unpause_update();
2520         Net_Flush();
2521
2522         // let's reset the view back to normal for the end
2523         setproperty(VF_MIN, '0 0 0');
2524         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2525
2526         IL_ENDFRAME();
2527 }
2528
2529
2530 // following vectors must be global to allow seamless switching between camera modes
2531 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2532 void CSQC_Demo_Camera()
2533 {
2534         float speed, attenuation, dimensions;
2535         vector tmp, delta;
2536
2537         if( autocvar_camera_reset || !camera_mode )
2538         {
2539                 camera_offset = '0 0 0';
2540                 current_angles = '0 0 0';
2541                 camera_direction = '0 0 0';
2542                 camera_offset.z += 30;
2543                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2544                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2545                 current_origin = view_origin;
2546                 current_camera_offset  = camera_offset;
2547                 cvar_set("camera_reset", "0");
2548                 camera_mode = CAMERA_CHASE;
2549         }
2550
2551         // Camera angles
2552         if( camera_roll )
2553                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2554
2555         if(autocvar_camera_look_player)
2556         {
2557                 vector dir;
2558                 float n;
2559
2560                 dir = normalize(view_origin - current_position);
2561                 n = mouse_angles.z;
2562                 mouse_angles = vectoangles(dir);
2563                 mouse_angles.x = mouse_angles.x * -1;
2564                 mouse_angles.z = n;
2565         }
2566         else
2567         {
2568                 tmp = getmousepos() * 0.1;
2569                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2570                 {
2571                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2572                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2573                 }
2574         }
2575
2576         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2577         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2578         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2579         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2580
2581         // Fix difference when angles don't have the same sign
2582         delta = '0 0 0';
2583         if(mouse_angles.y < -60 && current_angles.y > 60)
2584                 delta = '0 360 0';
2585         if(mouse_angles.y > 60 && current_angles.y < -60)
2586                 delta = '0 -360 0';
2587
2588         if(autocvar_camera_look_player)
2589                 attenuation = autocvar_camera_look_attenuation;
2590         else
2591                 attenuation = autocvar_camera_speed_attenuation;
2592
2593         attenuation = 1 / max(1, attenuation);
2594         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2595
2596         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2597         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2598         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2599         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2600
2601         // Camera position
2602         tmp = '0 0 0';
2603         dimensions = 0;
2604
2605         if( camera_direction.x )
2606         {
2607                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2608                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2609                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2610                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2611                 ++dimensions;
2612         }
2613
2614         if( camera_direction.y )
2615         {
2616                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2617                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2618                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2619                 ++dimensions;
2620         }
2621
2622         if( camera_direction.z )
2623         {
2624                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2625                 ++dimensions;
2626         }
2627
2628         if(autocvar_camera_free)
2629                 speed = autocvar_camera_speed_free;
2630         else
2631                 speed = autocvar_camera_speed_chase;
2632
2633         if(dimensions)
2634         {
2635                 speed = speed * sqrt(1 / dimensions);
2636                 camera_offset += tmp * speed;
2637         }
2638
2639         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2640
2641         // Camera modes
2642         if( autocvar_camera_free )
2643         {
2644                 if ( camera_mode == CAMERA_CHASE )
2645                 {
2646                         current_camera_offset = current_origin + current_camera_offset;
2647                         camera_offset = current_origin + camera_offset;
2648                 }
2649
2650                 camera_mode = CAMERA_FREE;
2651                 current_position = current_camera_offset;
2652         }
2653         else
2654         {
2655                 if ( camera_mode == CAMERA_FREE )
2656                 {
2657                         current_origin = view_origin;
2658                         camera_offset = camera_offset - current_origin;
2659                         current_camera_offset = current_camera_offset - current_origin;
2660                 }
2661
2662                 camera_mode = CAMERA_CHASE;
2663
2664                 if(autocvar_camera_chase_smoothly)
2665                         current_origin += (view_origin - current_origin) * attenuation;
2666                 else
2667                         current_origin = view_origin;
2668
2669                 current_position = current_origin + current_camera_offset;
2670         }
2671
2672         setproperty(VF_ANGLES, current_angles);
2673         setproperty(VF_ORIGIN, current_position);
2674 }