qcsrc/client/mapvoting.qc

   1 float mv_num_maps;
   2
   3 float mv_active;
   4 string mv_maps[MAPVOTE_COUNT];
   5 string mv_pics[MAPVOTE_COUNT];
   6 string mv_pk3[MAPVOTE_COUNT];
   7 float mv_preview[MAPVOTE_COUNT];
   8 float mv_votes[MAPVOTE_COUNT];
   9 entity mv_pk3list;
  10 float mv_abstain;
  11 float mv_ownvote;
  12 float mv_detail;
  13 float mv_timeout;
  14 float mv_maps_mask;
  15 float mv_top2_time;
  16 float mv_top2_alpha;
  17
  18 vector mv_mousepos;
  19 float mv_selection;
  20
  21 string MapVote_FormatMapItem(float id, string map, float count, float maxwidth, vector fontsize)
  22 {
  23         string pre, post;
  24         pre = sprintf("%d. ", id+1);
  25         if(mv_detail)
  26         {
  27                 if(count == 1)
  28                         post = _(" (1 vote)");
  29                 else if(count >= 0)
  30                         post = sprintf(_(" (%d votes)"), count);
  31         }
  32         else
  33                 post = "";
  34         maxwidth -= stringwidth(pre, FALSE, fontsize) + stringwidth(post, FALSE, fontsize);
  35         map = textShortenToWidth(map, maxwidth, fontsize, stringwidth_nocolors);
  36         return strcat(pre, map, post);
  37 }
  38
  39 vector MapVote_RGB(float id, float count)
  40 {
  41         if(count < 0)
  42                 return '1 1 1';
  43         if(id == mv_ownvote)
  44                 return '0 1 0';
  45         else if (id == mv_selection)
  46                 return '1 1 0';
  47         else
  48                 return '1 1 1';
  49 }
  50
  51 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float count, float id)
  52 {
  53         vector img_size;
  54         vector rgb;
  55         string label;
  56         float text_size;
  57
  58         isize -= hud_fontsize_y; // respect the text when calculating the image size
  59
  60         rgb = MapVote_RGB(id, count);
  61
  62         img_size_y = isize;
  63         img_size_x = isize / 0.75; // 4:3 x can be stretched easily, height is defined in isize
  64
  65         pos_y = pos_y + img_size_y;
  66
  67         label = MapVote_FormatMapItem(id, map, count, tsize, hud_fontsize);
  68
  69         text_size = stringwidth(label, false, hud_fontsize);
  70
  71         float theAlpha;
  72         if (count < 0 && mv_top2_alpha)
  73                 theAlpha = mv_top2_alpha;
  74         else
  75                 theAlpha = 1;
  76
  77         pos_x -= text_size*0.5;
  78         drawstring(pos, label, hud_fontsize, rgb, theAlpha, DRAWFLAG_NORMAL);
  79
  80         pos_x = pos_x + text_size*0.5 - img_size_x*0.5;
  81         pos_y = pos_y - img_size_y;
  82
  83         pos += autocvar_scoreboard_border_thickness * '1 1 0';
  84         img_size -= (autocvar_scoreboard_border_thickness * 2) * '1 1 0';
  85         if(pic == "")
  86         {
  87                 drawfill(pos, img_size, '.5 .5 .5', .7 * theAlpha, DRAWFLAG_NORMAL);
  88         }
  89         else
  90         {
  91                 if(drawgetimagesize(pic) == '0 0 0')
  92                         drawpic(pos, draw_UseSkinFor("nopreview_map"), img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
  93                 else
  94                         drawpic(pos, pic, img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
  95         }
  96
  97         if(id == mv_ownvote)
  98                 drawborderlines(autocvar_scoreboard_border_thickness, pos, img_size, rgb, theAlpha, DRAWFLAG_NORMAL);
  99         else
 100                 drawborderlines(autocvar_scoreboard_border_thickness, pos, img_size, '0 0 0', theAlpha, DRAWFLAG_NORMAL);
 101
 102         if(id == mv_selection && count >= 0)
 103                 drawfill(pos, img_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
 104 }
 105
 106 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float count, float id)
 107 {
 108         vector rgb;
 109         float text_size;
 110         string label;
 111
 112         rgb = MapVote_RGB(id, count);
 113
 114         pos_y = pos_y + hud_fontsize_y;
 115
 116         label = MapVote_FormatMapItem(id, _("Don't care"), count, tsize, hud_fontsize);
 117
 118         text_size = stringwidth(label, false, hud_fontsize);
 119
 120         pos_x -= text_size*0.5;
 121         drawstring(pos, label, hud_fontsize, rgb, 1, DRAWFLAG_NORMAL);
 122 }
 123
 124 vector MapVote_GridVec(vector gridspec, float i, float m)
 125 {
 126         float r;
 127         r = mod(i, m);
 128         return
 129                 '1 0 0' * (gridspec_x * r)
 130                 +
 131                 '0 1 0' * (gridspec_y * (i - r) / m);
 132 }
 133
 134 float MapVote_Selection(vector topleft, vector cellsize, float rows, float columns)
 135 {
 136         float cell;
 137         float c, r;
 138
 139         cell = -1;
 140
 141         for (r = 0; r < rows; ++r)
 142                 for (c = 0; c < columns; ++c)
 143                 {
 144                         if (mv_mousepos_x >= topleft_x + cellsize_x *  c &&
 145                                 mv_mousepos_x <= topleft_x + cellsize_x * (c + 1) &&
 146                                 mv_mousepos_y >= topleft_y + cellsize_y *  r &&
 147                                 mv_mousepos_y <= topleft_y + cellsize_y * (r + 1))
 148                         {
 149                                 cell = r * columns + c;
 150                                 break;
 151                         }
 152                 }
 153
 154         if (cell >= mv_num_maps)
 155                 cell = -1;
 156
 157         if (mv_abstain && cell < 0)
 158                 return mv_num_maps;
 159
 160         return cell;
 161 }
 162
 163 void MapVote_Draw()
 164 {
 165         string map;
 166         float i, tmp;
 167         vector pos;
 168         float isize;
 169         float center;
 170         float columns, rows;
 171         float tsize;
 172         vector dist;
 173
 174         if(!mv_active)
 175                 return;
 176
 177         if not(autocvar_hud_cursormode)
 178         {
 179                 mv_mousepos = mv_mousepos + getmousepos();
 180
 181                 mv_mousepos_x = bound(0, mv_mousepos_x, vid_conwidth);
 182                 mv_mousepos_y = bound(0, mv_mousepos_y, vid_conheight);
 183         }
 184
 185         center = (vid_conwidth - 1)/2;
 186         xmin = vid_conwidth*0.05; // 5% border must suffice
 187         xmax = vid_conwidth - xmin;
 188         ymin = 20;
 189         i = autocvar_con_chatpos; //*autocvar_con_chatsize;
 190         if(i < 0)
 191                 ymax = vid_conheight + (i - autocvar_con_chat) * autocvar_con_chatsize;
 192         if(i >= 0 || ymax < (vid_conheight*0.5))
 193                 ymax = vid_conheight - ymin;
 194
 195         hud_fontsize = HUD_GetFontsize("hud_fontsize");
 196
 197         pos_y = ymin;
 198         pos_z = 0;
 199
 200         draw_beginBoldFont();
 201         map = _("Vote for a map");
 202         pos_x = center - stringwidth(map, false, '12 0 0');
 203         drawstring(pos, map, '24 24 0', '1 1 1', 1, DRAWFLAG_NORMAL);
 204         pos_y += 26;
 205
 206         i = ceil(max(0, mv_timeout - time));
 207         map = sprintf(_("%d seconds left"), i);
 208         pos_x = center - stringwidth(map, false, '8 0 0');
 209         drawstring(pos, map, '16 16 0', '0 1 0', 1, DRAWFLAG_NORMAL);
 210         pos_y += 22;
 211         pos_x = xmin;
 212         draw_endBoldFont();
 213
 214         // base for multi-column stuff...
 215         ymin = pos_y;
 216         if(mv_abstain)
 217                 mv_num_maps -= 1;
 218
 219         if(mv_num_maps > 3)
 220         {
 221                 columns = 3;
 222         } else {
 223                 columns = mv_num_maps;
 224         }
 225         rows = ceil(mv_num_maps / columns);
 226
 227         dist_x = (xmax - xmin) / columns;
 228         dist_y = (ymax - pos_y) / rows;
 229         tsize = dist_x - 10;
 230         isize = min(dist_y - 10, 0.75 * tsize);
 231
 232         mv_selection = MapVote_Selection(pos, dist, rows, columns);
 233
 234         pos_x += (xmax - xmin) / (2 * columns);
 235         pos_y += (dist_y - isize) / 2;
 236         ymax -= isize;
 237
 238         if (mv_top2_time)
 239                 mv_top2_alpha = max(0.2, 1 - (time - mv_top2_time)*(time - mv_top2_time));
 240
 241         for(i = 0; i < mv_num_maps; ++i)
 242         {
 243                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 244                 map = mv_maps[i];
 245                 if(mv_preview[i])
 246                         MapVote_DrawMapItem(pos + MapVote_GridVec(dist, i, columns), isize, tsize, map, mv_pics[i], tmp, i);
 247                 else
 248                         MapVote_DrawMapItem(pos + MapVote_GridVec(dist, i, columns), isize, tsize, map, "", tmp, i);
 249         }
 250
 251         if(mv_abstain)
 252                 ++mv_num_maps;
 253
 254         if(mv_abstain && i < mv_num_maps) {
 255                 tmp = mv_votes[i];
 256                 pos_y = ymax + isize - hud_fontsize_y;
 257                 pos_x = (xmax+xmin)*0.5;
 258                 MapVote_DrawAbstain(pos, isize, xmax - xmin, tmp, i);
 259         }
 260
 261         drawpic(mv_mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), '32 32 0', '1 1 1', autocvar_hud_panel_fg_alpha, DRAWFLAG_NORMAL);
 262 }
 263
 264 void Cmd_MapVote_MapDownload(float argc)
 265 {
 266         float id;
 267         entity pak;
 268
 269         if(argc != 2 || !mv_pk3list)
 270         {
 271                 print(_("mv_mapdownload: ^3You're not supposed to use this command on your own!\n"));
 272                 return;
 273         }
 274
 275         id = stof(argv(1));
 276         for(pak = mv_pk3list; pak; pak = pak.chain)
 277                 if(pak.sv_entnum == id)
 278                         break;
 279
 280         if(!pak || pak.sv_entnum != id) {
 281                 print(_("^1Error:^7 Couldn't find pak index.\n"));
 282                 return;
 283         }
 284
 285         if(PreviewExists(pak.message))
 286         {
 287                 mv_preview[id] = true;
 288                 return;
 289         } else {
 290                 print(_("Requesting preview...\n"));
 291                 localcmd(strcat("\ncmd mv_getpicture ", ftos(id), "\n"));
 292         }
 293 }
 294
 295 void MapVote_CheckPK3(string pic, string pk3, float id)
 296 {
 297         entity pak;
 298         pak = spawn();
 299         pak.netname = pk3;
 300         pak.message = pic;
 301         pak.sv_entnum = id;
 302
 303         pak.chain = mv_pk3list;
 304         mv_pk3list = pak;
 305
 306         if(pk3 != "")
 307         {
 308                 localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 309         }
 310         else
 311         {
 312                 Cmd_MapVote_MapDownload(tokenize_console(strcat("mv_download ", ftos(id))));
 313         }
 314 }
 315
 316 void MapVote_CheckPic(string pic, string pk3, float id)
 317 {
 318         // never try to retrieve a pic for the "don't care" 'map'
 319         if(mv_abstain && id == mv_num_maps - 1)
 320                 return;
 321
 322         if(PreviewExists(pic))
 323         {
 324                 mv_preview[id] = true;
 325                 return;
 326         }
 327         MapVote_CheckPK3(pic, pk3, id);
 328 }
 329
 330 #define NUM_SSDIRS 4
 331 string ssdirs[NUM_SSDIRS];
 332 float n_ssdirs;
 333 void MapVote_Init()
 334 {
 335         float i, j, power;
 336         string map, pk3, s;
 337
 338         precache_sound ("misc/invshot.wav");
 339
 340         mv_active = 1;
 341         if(autocvar_hud_cursormode) { setcursormode(1); }
 342         else { mv_mousepos = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight; }
 343         mv_selection = -1;
 344
 345         for(n_ssdirs = 0; ; ++n_ssdirs)
 346         {
 347                 s = ReadString();
 348                 if(s == "")
 349                         break;
 350                 if(n_ssdirs < NUM_SSDIRS)
 351                         ssdirs[n_ssdirs] = s;
 352         }
 353         n_ssdirs = min(n_ssdirs, NUM_SSDIRS);
 354
 355         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 356         mv_abstain = ReadByte();
 357         if(mv_abstain)
 358                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 359         mv_detail = ReadByte();
 360
 361         mv_ownvote = -1;
 362         mv_timeout = ReadCoord();
 363
 364         if(mv_num_maps <= 8)
 365                 mv_maps_mask = ReadByte();
 366         else
 367                 mv_maps_mask = ReadShort();
 368
 369         // Assume mv_pk3list is world, there should only be 1 mapvote per round
 370         mv_pk3list = world; // I'm still paranoid!
 371
 372         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 373         {
 374                 mv_votes[i] = 0;
 375
 376                 if(mv_maps_mask & power)
 377                 {
 378                         map = strzone(ReadString());
 379                         pk3 = strzone(ReadString());
 380                         j = bound(0, ReadByte(), n_ssdirs - 1);
 381
 382                         mv_maps[i] = map;
 383                         mv_pk3[i] = pk3;
 384                         map = strzone(strcat(ssdirs[j], "/", map));
 385                         mv_pics[i] = map;
 386
 387                         mv_preview[i] = false;
 388
 389                         MapVote_CheckPic(map, pk3, i);
 390                 }
 391                 else
 392                 {
 393                         mv_maps[i] = strzone("if-you-see-this-the-code-is-broken");
 394                         mv_pk3[i] = strzone("if-you-see-this-the-code-is-broken");
 395                         mv_pics[i] = strzone("if-you-see-this-the-code-is-broken");
 396                         mv_preview[i] = false;
 397                 }
 398         }
 399
 400         for(i = 0; i < n_ssdirs; ++i)
 401                 ssdirs[n_ssdirs] = string_null;
 402         n_ssdirs = 0;
 403 }
 404
 405 float MapVote_InputEvent(float bInputType, float nPrimary, float nSecondary)
 406 {
 407         float imp;
 408
 409         if (!mv_active)
 410                 return false;
 411
 412         if(bInputType == 3)
 413         {
 414                 mv_mousepos_x = nPrimary;
 415                 mv_mousepos_y = nSecondary;
 416                 return true;
 417         }
 418
 419         if (bInputType != 0)
 420                 return false;
 421
 422         if ('0' <= nPrimary && nPrimary <= '9')
 423         {
 424                 imp = nPrimary - '0';
 425                 if (imp == 0) imp = 10;
 426                 localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 427                 return true;
 428         }
 429         switch(nPrimary)
 430         {
 431                 case K_KP_1: localcmd("\nimpulse 1\n"); return true;
 432                 case K_KP_2: localcmd("\nimpulse 2\n"); return true;
 433                 case K_KP_3: localcmd("\nimpulse 3\n"); return true;
 434                 case K_KP_4: localcmd("\nimpulse 4\n"); return true;
 435                 case K_KP_5: localcmd("\nimpulse 5\n"); return true;
 436                 case K_KP_6: localcmd("\nimpulse 6\n"); return true;
 437                 case K_KP_7: localcmd("\nimpulse 7\n"); return true;
 438                 case K_KP_8: localcmd("\nimpulse 8\n"); return true;
 439                 case K_KP_9: localcmd("\nimpulse 9\n"); return true;
 440                 case K_KP_0: localcmd("\nimpulse 10\n"); return true;
 441         }
 442
 443         if (nPrimary == K_MOUSE1)
 444                 if (mv_selection >= 0)
 445                 {
 446                         imp = min(mv_selection + 1, mv_num_maps);
 447                         localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 448                         return true;
 449                 }
 450
 451         return false;
 452 }
 453
 454 void MapVote_UpdateMask()
 455 {
 456         float i, power;
 457         float oldmask;
 458
 459         oldmask = mv_maps_mask;
 460         if(mv_num_maps <= 8)
 461                 mv_maps_mask = ReadByte();
 462         else
 463                 mv_maps_mask = ReadShort();
 464
 465         if(oldmask & mv_maps_mask != oldmask)
 466                 if(oldmask & mv_maps_mask == mv_maps_mask)
 467                          sound(world, CH_INFO, "misc_invshot.wav", VOL_BASE, ATTN_NONE);
 468
 469         // remove votes that no longer apply
 470         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 471                 if not(mv_maps_mask & power)
 472                         mv_votes[i] = -1;
 473
 474         mv_top2_time = time;
 475 }
 476
 477 void MapVote_UpdateVotes()
 478 {
 479         float i, power;
 480         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 481         {
 482                 if(mv_maps_mask & power)
 483                 {
 484                         if(mv_detail)
 485                                 mv_votes[i] = ReadByte();
 486                         else
 487                                 mv_votes[i] = 0;
 488                 }
 489                 else
 490                         mv_votes[i] = -1;
 491         }
 492
 493         mv_ownvote = ReadByte()-1;
 494 }
 495
 496 void Ent_MapVote()
 497 {
 498         float sf;
 499
 500         sf = ReadByte();
 501
 502         if(sf & 1)
 503                 MapVote_Init();
 504
 505         if(sf & 2)
 506                 MapVote_UpdateMask();
 507
 508         if(sf & 4)
 509                 MapVote_UpdateVotes();
 510 }
 511
 512 void Net_MapVote_Picture()
 513 {
 514         float type;
 515         type = ReadByte();
 516         mv_preview[type] = true;
 517         mv_pics[type] = strzone(ReadPicture());
 518 }