qcsrc/client/mapvoting.qc

   1 float mv_num_maps;
   2
   3 float mv_active;
   4 string mv_maps[MAPVOTE_COUNT];
   5 string mv_pics[MAPVOTE_COUNT];
   6 string mv_pk3[MAPVOTE_COUNT];
   7 float mv_preview[MAPVOTE_COUNT];
   8 float mv_votes[MAPVOTE_COUNT];
   9 entity mv_pk3list;
  10 float mv_abstain;
  11 float mv_ownvote;
  12 float mv_detail;
  13 float mv_timeout;
  14 float mv_maps_mask;
  15 float mv_top2_time;
  16 float mv_top2_alpha;
  17
  18 vector mv_mousepos;
  19 float mv_selection;
  20
  21 string MapVote_FormatMapItem(float id, string map, float count, float maxwidth, vector fontsize)
  22 {
  23         string pre, post;
  24         pre = sprintf("%d. ", id+1);
  25         if(mv_detail)
  26         {
  27                 if(count == 1)
  28                         post = _(" (1 vote)");
  29                 else if(count >= 0)
  30                         post = sprintf(_(" (%d votes)"), count);
  31         }
  32         else
  33                 post = "";
  34         maxwidth -= stringwidth(pre, FALSE, fontsize) + stringwidth(post, FALSE, fontsize);
  35         map = textShortenToWidth(map, maxwidth, fontsize, stringwidth_nocolors);
  36         return strcat(pre, map, post);
  37 }
  38
  39 vector MapVote_RGB(float id, float count)
  40 {
  41         if(count < 0)
  42                 return '1 1 1';
  43         if(id == mv_ownvote)
  44                 return '0 1 0';
  45         else if (id == mv_selection)
  46                 return '1 1 0';
  47         else
  48                 return '1 1 1';
  49 }
  50
  51 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float count, float id)
  52 {
  53         vector img_size;
  54         vector rgb;
  55         string label;
  56         float text_size;
  57
  58         isize -= hud_fontsize_y; // respect the text when calculating the image size
  59
  60         rgb = MapVote_RGB(id, count);
  61
  62         img_size_y = isize;
  63         img_size_x = isize / 0.75; // 4:3 x can be stretched easily, height is defined in isize
  64
  65         pos_y = pos_y + img_size_y;
  66
  67         label = MapVote_FormatMapItem(id, map, count, tsize, hud_fontsize);
  68
  69         text_size = stringwidth(label, false, hud_fontsize);
  70
  71         float theAlpha;
  72         if (count < 0 && mv_top2_alpha)
  73                 theAlpha = mv_top2_alpha;
  74         else
  75                 theAlpha = 1;
  76
  77         pos_x -= text_size*0.5;
  78         drawstring(pos, label, hud_fontsize, rgb, theAlpha, DRAWFLAG_NORMAL);
  79
  80         pos_x = pos_x + text_size*0.5 - img_size_x*0.5;
  81         pos_y = pos_y - img_size_y;
  82
  83         pos += autocvar_scoreboard_border_thickness * '1 1 0';
  84         img_size -= (autocvar_scoreboard_border_thickness * 2) * '1 1 0';
  85         if(pic == "")
  86         {
  87                 drawfill(pos, img_size, '.5 .5 .5', .7 * theAlpha, DRAWFLAG_NORMAL);
  88         }
  89         else
  90         {
  91                 if(drawgetimagesize(pic) == '0 0 0')
  92                         drawpic(pos, draw_UseSkinFor("nopreview_map"), img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
  93                 else
  94                         drawpic(pos, pic, img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
  95         }
  96
  97         if(id == mv_ownvote)
  98                 drawborderlines(autocvar_scoreboard_border_thickness, pos, img_size, rgb, theAlpha, DRAWFLAG_NORMAL);
  99         else
 100                 drawborderlines(autocvar_scoreboard_border_thickness, pos, img_size, '0 0 0', theAlpha, DRAWFLAG_NORMAL);
 101
 102         if(id == mv_selection && count >= 0)
 103                 drawfill(pos, img_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
 104 }
 105
 106 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float count, float id)
 107 {
 108         vector rgb;
 109         float text_size;
 110         string label;
 111
 112         rgb = MapVote_RGB(id, count);
 113
 114         pos_y = pos_y + hud_fontsize_y;
 115
 116         label = MapVote_FormatMapItem(id, _("Don't care"), count, tsize, hud_fontsize);
 117
 118         text_size = stringwidth(label, false, hud_fontsize);
 119
 120         pos_x -= text_size*0.5;
 121         drawstring(pos, label, hud_fontsize, rgb, 1, DRAWFLAG_NORMAL);
 122 }
 123
 124 vector MapVote_GridVec(vector gridspec, float i, float m)
 125 {
 126         float r;
 127         r = mod(i, m);
 128         return
 129                 '1 0 0' * (gridspec_x * r)
 130                 +
 131                 '0 1 0' * (gridspec_y * (i - r) / m);
 132 }
 133
 134 float MapVote_Selection(vector topleft, vector cellsize, float rows, float columns)
 135 {
 136         float cell;
 137         float c, r;
 138
 139         cell = -1;
 140
 141         for (r = 0; r < rows; ++r)
 142                 for (c = 0; c < columns; ++c)
 143                 {
 144                         if (mv_mousepos_x >= topleft_x + cellsize_x *  c &&
 145                                 mv_mousepos_x <= topleft_x + cellsize_x * (c + 1) &&
 146                                 mv_mousepos_y >= topleft_y + cellsize_y *  r &&
 147                                 mv_mousepos_y <= topleft_y + cellsize_y * (r + 1))
 148                         {
 149                                 cell = r * columns + c;
 150                                 break;
 151                         }
 152                 }
 153
 154         if (cell >= mv_num_maps)
 155                 cell = -1;
 156
 157         if (mv_abstain && cell < 0)
 158                 return mv_num_maps;
 159
 160         return cell;
 161 }
 162
 163 void MapVote_Draw()
 164 {
 165         string map;
 166         float i, tmp;
 167         vector pos;
 168         float isize;
 169         float center;
 170         float columns, rows;
 171         float tsize;
 172         vector dist;
 173
 174         if(!mv_active)
 175                 return;
 176
 177         center = (vid_conwidth - 1)/2;
 178         xmin = vid_conwidth*0.05; // 5% border must suffice
 179         xmax = vid_conwidth - xmin;
 180         ymin = 20;
 181         i = autocvar_con_chatpos; //*autocvar_con_chatsize;
 182         if(i < 0)
 183                 ymax = vid_conheight + (i - autocvar_con_chat) * autocvar_con_chatsize;
 184         if(i >= 0 || ymax < (vid_conheight*0.5))
 185                 ymax = vid_conheight - ymin;
 186
 187         hud_fontsize = HUD_GetFontsize("hud_fontsize");
 188
 189         pos_y = ymin;
 190         pos_z = 0;
 191
 192         draw_beginBoldFont();
 193         map = _("Vote for a map");
 194         pos_x = center - stringwidth(map, false, '12 0 0');
 195         drawstring(pos, map, '24 24 0', '1 1 1', 1, DRAWFLAG_NORMAL);
 196         pos_y += 26;
 197
 198         i = ceil(max(0, mv_timeout - time));
 199         map = sprintf(_("%d seconds left"), i);
 200         pos_x = center - stringwidth(map, false, '8 0 0');
 201         drawstring(pos, map, '16 16 0', '0 1 0', 1, DRAWFLAG_NORMAL);
 202         pos_y += 22;
 203         pos_x = xmin;
 204         draw_endBoldFont();
 205
 206         // base for multi-column stuff...
 207         ymin = pos_y;
 208         if(mv_abstain)
 209                 mv_num_maps -= 1;
 210
 211         if(mv_num_maps > 3)
 212         {
 213                 columns = 3;
 214         } else {
 215                 columns = mv_num_maps;
 216         }
 217         rows = ceil(mv_num_maps / columns);
 218
 219         dist_x = (xmax - xmin) / columns;
 220         dist_y = (ymax - pos_y) / rows;
 221         tsize = dist_x - 10;
 222         isize = min(dist_y - 10, 0.75 * tsize);
 223
 224         mv_selection = MapVote_Selection(pos, dist, rows, columns);
 225
 226         pos_x += (xmax - xmin) / (2 * columns);
 227         pos_y += (dist_y - isize) / 2;
 228         ymax -= isize;
 229
 230         if (mv_top2_time)
 231                 mv_top2_alpha = max(0.2, 1 - (time - mv_top2_time)*(time - mv_top2_time));
 232
 233         for(i = 0; i < mv_num_maps; ++i)
 234         {
 235                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 236                 map = mv_maps[i];
 237                 if(mv_preview[i])
 238                         MapVote_DrawMapItem(pos + MapVote_GridVec(dist, i, columns), isize, tsize, map, mv_pics[i], tmp, i);
 239                 else
 240                         MapVote_DrawMapItem(pos + MapVote_GridVec(dist, i, columns), isize, tsize, map, "", tmp, i);
 241         }
 242
 243         if(mv_abstain)
 244                 ++mv_num_maps;
 245
 246         if(mv_abstain && i < mv_num_maps) {
 247                 tmp = mv_votes[i];
 248                 pos_y = ymax + isize - hud_fontsize_y;
 249                 pos_x = (xmax+xmin)*0.5;
 250                 MapVote_DrawAbstain(pos, isize, xmax - xmin, tmp, i);
 251         }
 252
 253         drawpic(mv_mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), '32 32 0', '1 1 1', autocvar_hud_panel_fg_alpha, DRAWFLAG_NORMAL);
 254 }
 255
 256 void Cmd_MapVote_MapDownload(float argc)
 257 {
 258         float id;
 259         entity pak;
 260
 261         if(argc != 2 || !mv_pk3list)
 262         {
 263                 print(_("mv_mapdownload: ^3You're not supposed to use this command on your own!\n"));
 264                 return;
 265         }
 266
 267         id = stof(argv(1));
 268         for(pak = mv_pk3list; pak; pak = pak.chain)
 269                 if(pak.sv_entnum == id)
 270                         break;
 271
 272         if(!pak || pak.sv_entnum != id) {
 273                 print(_("^1Error:^7 Couldn't find pak index.\n"));
 274                 return;
 275         }
 276
 277         if(PreviewExists(pak.message))
 278         {
 279                 mv_preview[id] = true;
 280                 return;
 281         } else {
 282                 print(_("Requesting preview...\n"));
 283                 localcmd(strcat("\ncmd mv_getpicture ", ftos(id), "\n"));
 284         }
 285 }
 286
 287 void MapVote_CheckPK3(string pic, string pk3, float id)
 288 {
 289         entity pak;
 290         pak = spawn();
 291         pak.netname = pk3;
 292         pak.message = pic;
 293         pak.sv_entnum = id;
 294
 295         pak.chain = mv_pk3list;
 296         mv_pk3list = pak;
 297
 298         if(pk3 != "")
 299         {
 300                 localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 301         }
 302         else
 303         {
 304                 Cmd_MapVote_MapDownload(tokenize_console(strcat("mv_download ", ftos(id))));
 305         }
 306 }
 307
 308 void MapVote_CheckPic(string pic, string pk3, float id)
 309 {
 310         // never try to retrieve a pic for the "don't care" 'map'
 311         if(mv_abstain && id == mv_num_maps - 1)
 312                 return;
 313
 314         if(PreviewExists(pic))
 315         {
 316                 mv_preview[id] = true;
 317                 return;
 318         }
 319         MapVote_CheckPK3(pic, pk3, id);
 320 }
 321
 322 #define NUM_SSDIRS 4
 323 string ssdirs[NUM_SSDIRS];
 324 float n_ssdirs;
 325 void MapVote_Init()
 326 {
 327         float i, j, power;
 328         string map, pk3, s;
 329
 330         precache_sound ("misc/invshot.wav");
 331
 332         mv_active = 1;
 333         setcursormode(1);
 334         mv_selection = -1;
 335
 336         for(n_ssdirs = 0; ; ++n_ssdirs)
 337         {
 338                 s = ReadString();
 339                 if(s == "")
 340                         break;
 341                 if(n_ssdirs < NUM_SSDIRS)
 342                         ssdirs[n_ssdirs] = s;
 343         }
 344         n_ssdirs = min(n_ssdirs, NUM_SSDIRS);
 345
 346         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 347         mv_abstain = ReadByte();
 348         if(mv_abstain)
 349                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 350         mv_detail = ReadByte();
 351
 352         mv_ownvote = -1;
 353         mv_timeout = ReadCoord();
 354
 355         if(mv_num_maps <= 8)
 356                 mv_maps_mask = ReadByte();
 357         else
 358                 mv_maps_mask = ReadShort();
 359
 360         // Assume mv_pk3list is world, there should only be 1 mapvote per round
 361         mv_pk3list = world; // I'm still paranoid!
 362
 363         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 364         {
 365                 mv_votes[i] = 0;
 366
 367                 if(mv_maps_mask & power)
 368                 {
 369                         map = strzone(ReadString());
 370                         pk3 = strzone(ReadString());
 371                         j = bound(0, ReadByte(), n_ssdirs - 1);
 372
 373                         mv_maps[i] = map;
 374                         mv_pk3[i] = pk3;
 375                         map = strzone(strcat(ssdirs[j], "/", map));
 376                         mv_pics[i] = map;
 377
 378                         mv_preview[i] = false;
 379
 380                         MapVote_CheckPic(map, pk3, i);
 381                 }
 382                 else
 383                 {
 384                         mv_maps[i] = strzone("if-you-see-this-the-code-is-broken");
 385                         mv_pk3[i] = strzone("if-you-see-this-the-code-is-broken");
 386                         mv_pics[i] = strzone("if-you-see-this-the-code-is-broken");
 387                         mv_preview[i] = false;
 388                 }
 389         }
 390
 391         for(i = 0; i < n_ssdirs; ++i)
 392                 ssdirs[n_ssdirs] = string_null;
 393         n_ssdirs = 0;
 394 }
 395
 396 float MapVote_InputEvent(float bInputType, float nPrimary, float nSecondary)
 397 {
 398         float imp;
 399
 400         if (!mv_active)
 401                 return false;
 402
 403         if(bInputType == 3)
 404         {
 405                 mv_mousepos_x = nPrimary;
 406                 mv_mousepos_y = nSecondary;
 407                 return true;
 408         }
 409
 410         if (bInputType != 0)
 411                 return false;
 412
 413         if ('0' <= nPrimary && nPrimary <= '9')
 414         {
 415                 imp = nPrimary - '0';
 416                 if (imp == 0) imp = 10;
 417                 localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 418                 return true;
 419         }
 420         switch(nPrimary)
 421         {
 422                 case K_KP_1: localcmd("\nimpulse 1\n"); return true;
 423                 case K_KP_2: localcmd("\nimpulse 2\n"); return true;
 424                 case K_KP_3: localcmd("\nimpulse 3\n"); return true;
 425                 case K_KP_4: localcmd("\nimpulse 4\n"); return true;
 426                 case K_KP_5: localcmd("\nimpulse 5\n"); return true;
 427                 case K_KP_6: localcmd("\nimpulse 6\n"); return true;
 428                 case K_KP_7: localcmd("\nimpulse 7\n"); return true;
 429                 case K_KP_8: localcmd("\nimpulse 8\n"); return true;
 430                 case K_KP_9: localcmd("\nimpulse 9\n"); return true;
 431                 case K_KP_0: localcmd("\nimpulse 10\n"); return true;
 432         }
 433
 434         if (nPrimary == K_MOUSE1)
 435                 if (mv_selection >= 0)
 436                 {
 437                         imp = min(mv_selection + 1, mv_num_maps);
 438                         localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 439                         return true;
 440                 }
 441
 442         return false;
 443 }
 444
 445 void MapVote_UpdateMask()
 446 {
 447         float i, power;
 448         float oldmask;
 449
 450         oldmask = mv_maps_mask;
 451         if(mv_num_maps <= 8)
 452                 mv_maps_mask = ReadByte();
 453         else
 454                 mv_maps_mask = ReadShort();
 455
 456         if(oldmask & mv_maps_mask != oldmask)
 457                 if(oldmask & mv_maps_mask == mv_maps_mask)
 458                          sound(world, CH_INFO, "misc_invshot.wav", VOL_BASE, ATTN_NONE);
 459
 460         // remove votes that no longer apply
 461         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 462                 if not(mv_maps_mask & power)
 463                         mv_votes[i] = -1;
 464
 465         mv_top2_time = time;
 466 }
 467
 468 void MapVote_UpdateVotes()
 469 {
 470         float i, power;
 471         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 472         {
 473                 if(mv_maps_mask & power)
 474                 {
 475                         if(mv_detail)
 476                                 mv_votes[i] = ReadByte();
 477                         else
 478                                 mv_votes[i] = 0;
 479                 }
 480                 else
 481                         mv_votes[i] = -1;
 482         }
 483
 484         mv_ownvote = ReadByte()-1;
 485 }
 486
 487 void Ent_MapVote()
 488 {
 489         float sf;
 490
 491         sf = ReadByte();
 492
 493         if(sf & 1)
 494                 MapVote_Init();
 495
 496         if(sf & 2)
 497                 MapVote_UpdateMask();
 498
 499         if(sf & 4)
 500                 MapVote_UpdateVotes();
 501 }
 502
 503 void Net_MapVote_Picture()
 504 {
 505         float type;
 506         type = ReadByte();
 507         mv_preview[type] = true;
 508         mv_pics[type] = strzone(ReadPicture());
 509 }