qcsrc/client/main.qc

   1 #include "main.qh"
   2 #include "_all.qh"
   3
   4 #include "casings.qh"
   5 #include "controlpoint.qh"
   6 #include "csqcmodel_hooks.qh"
   7 #include "damage.qh"
   8 #include "effects.qh"
   9 #include "generator.qh"
  10 #include "gibs.qh"
  11 #include "hook.qh"
  12 #include "hud.qh"
  13 #include "hud_config.qh"
  14 #include "laser.qh"
  15 #include "mapvoting.qh"
  16 #include "modeleffects.qh"
  17 #include "particles.qh"
  18 #include "prandom.qh"
  19 #include "scoreboard.qh"
  20 #include "shownames.qh"
  21 #include "sortlist.qh"
  22 #include "tuba.qh"
  23 #include "t_items.qh"
  24 #include "wall.qh"
  25
  26 #include "../common/vehicles/all.qh"
  27
  28 #include "mutators/events.qh"
  29
  30 #include "weapons/projectile.qh"
  31
  32 #include "../common/buffs.qh"
  33 #include "../common/deathtypes.qh"
  34 #include "../common/effects.qh"
  35 #include "../common/mapinfo.qh"
  36 #include "../common/monsters/all.qh"
  37 #include "../common/nades.qh"
  38 #include "../common/net_notice.qh"
  39 #include "../common/notifications.qh"
  40 #include "../common/stats.qh"
  41 #include "../common/teams.qh"
  42
  43 #include "../common/items/all.qh"
  44
  45 #include "../common/mutators/base.qh"
  46
  47 #include "../common/weapons/all.qh"
  48
  49 #include "../csqcmodellib/cl_model.qh"
  50 #include "../csqcmodellib/interpolate.qh"
  51
  52 #include "../common/triggers/include.qh"
  53
  54 #include "../common/turrets/cl_turrets.qh"
  55 #include "../common/turrets/turrets.qh"
  56
  57 #include "../warpzonelib/client.qh"
  58
  59 // --------------------------------------------------------------------------
  60 // BEGIN REQUIRED CSQC FUNCTIONS
  61 //include "main.qh"
  62
  63 entity clearentity_ent;
  64 void clearentity(entity e)
  65 {
  66         if (!clearentity_ent)
  67         {
  68                 clearentity_ent = spawn();
  69                 clearentity_ent.classname = "clearentity";
  70         }
  71         int n = e.entnum;
  72         copyentity(clearentity_ent, e);
  73         e.entnum = n;
  74 }
  75
  76 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  77 void menu_show_error()
  78 {
  79         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  80 }
  81
  82 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  83 // Useful for precaching things
  84
  85 void menu_sub_null()
  86 {
  87 }
  88
  89 string forcefog;
  90 void ConsoleCommand_macro_init();
  91 void CSQC_Init(void)
  92 {
  93         prvm_language = cvar_string("prvm_language");
  94
  95 #ifdef WATERMARK
  96         dprintf("^4CSQC Build information: ^1%s\n", WATERMARK);
  97 #endif
  98
  99         int i;
 100
 101         binddb = db_create();
 102         tempdb = db_create();
 103         ClientProgsDB = db_load("client.db");
 104         compressShortVector_init();
 105
 106         draw_endBoldFont();
 107         menu_visible = false;
 108         menu_show = menu_show_error;
 109         menu_action = func_null;
 110
 111         for(i = 0; i < 255; ++i)
 112                 if(getplayerkeyvalue(i, "viewentity") == "")
 113                         break;
 114         maxclients = i;
 115
 116         //registercommand("hud_configure");
 117         //registercommand("hud_save");
 118         //registercommand("menu_action");
 119
 120         ConsoleCommand_macro_init();
 121
 122         registercvar("hud_usecsqc", "1");
 123         registercvar("scoreboard_columns", "default");
 124
 125         registercvar("cl_nade_type", "3");
 126         registercvar("cl_pokenade_type", "zombie");
 127
 128         registercvar("cl_jumpspeedcap_min", "");
 129         registercvar("cl_jumpspeedcap_max", "");
 130
 131         gametype = 0;
 132
 133         // hud_fields uses strunzone on the titles!
 134         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 135                 hud_title[i] = strzone("(null)");
 136
 137         Cmd_HUD_SetFields(0);
 138
 139         postinit = false;
 140
 141         calledhooks = 0;
 142
 143         teams = Sort_Spawn();
 144         players = Sort_Spawn();
 145
 146         GetTeam(NUM_SPECTATOR, true); // add specs first
 147
 148         // needs to be done so early because of the constants they create
 149         static_init();
 150         CALL_ACCUMULATED_FUNCTION(RegisterTurrets);
 151         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 152         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 153         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 154         CALL_ACCUMULATED_FUNCTION(RegisterEffects);
 155
 156         initialize_minigames();
 157
 158         // precaches
 159         precache_model("null");
 160         precache_sound("misc/hit.wav");
 161         precache_sound("misc/typehit.wav");
 162
 163         generator_precache();
 164         Projectile_Precache();
 165         Hook_Precache();
 166         GibSplash_Precache();
 167         Casings_Precache();
 168         Tuba_Precache();
 169         CSQCPlayer_Precache();
 170
 171         if(autocvar_cl_reticle)
 172         {
 173                 precache_pic("gfx/reticle_normal");
 174                 // weapon reticles are precached in weapon files
 175         }
 176
 177         get_mi_min_max_texcoords(1); // try the CLEVER way first
 178         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 179         shortmapname = mi_shortname;
 180
 181         if(precache_pic(minimapname) == "")
 182         {
 183                 // but maybe we have a non-clever minimap
 184                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 185                 if(precache_pic(minimapname) == "")
 186                         minimapname = ""; // FAIL
 187                 else
 188                         get_mi_min_max_texcoords(0); // load new texcoords
 189         }
 190
 191         mi_center = (mi_min + mi_max) * 0.5;
 192         mi_scale = mi_max - mi_min;
 193         minimapname = strzone(minimapname);
 194
 195         WarpZone_Init();
 196
 197         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 198         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 199 }
 200
 201 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 202 void Shutdown(void)
 203 {
 204         WarpZone_Shutdown();
 205
 206         remove(teams);
 207         remove(players);
 208         db_close(binddb);
 209         db_close(tempdb);
 210         if(autocvar_cl_db_saveasdump)
 211                 db_dump(ClientProgsDB, "client.db");
 212         else
 213                 db_save(ClientProgsDB, "client.db");
 214         db_close(ClientProgsDB);
 215
 216         if(camera_active)
 217                 cvar_set("chase_active",ftos(chase_active_backup));
 218
 219         // unset the event chasecam's chase_active
 220         if(autocvar_chase_active < 0)
 221                 cvar_set("chase_active", "0");
 222
 223         if (!isdemo())
 224         {
 225                 if (!(calledhooks & HOOK_START))
 226                         localcmd("\n_cl_hook_gamestart nop\n");
 227                 if (!(calledhooks & HOOK_END))
 228                         localcmd("\ncl_hook_gameend\n");
 229         }
 230
 231         deactivate_minigame();
 232         HUD_MinigameMenu_Close();
 233 }
 234
 235 .float has_team;
 236 float SetTeam(entity o, int Team)
 237 {
 238         entity tm;
 239         if(teamplay)
 240         {
 241                 switch(Team)
 242                 {
 243                         case -1:
 244                         case NUM_TEAM_1:
 245                         case NUM_TEAM_2:
 246                         case NUM_TEAM_3:
 247                         case NUM_TEAM_4:
 248                                 break;
 249                         default:
 250                                 if(GetTeam(Team, false) == world)
 251                                 {
 252                                         dprintf("trying to switch to unsupported team %d\n", Team);
 253                                         Team = NUM_SPECTATOR;
 254                                 }
 255                                 break;
 256                 }
 257         }
 258         else
 259         {
 260                 switch(Team)
 261                 {
 262                         case -1:
 263                         case 0:
 264                                 break;
 265                         default:
 266                                 if(GetTeam(Team, false) == world)
 267                                 {
 268                                         dprintf("trying to switch to unsupported team %d\n", Team);
 269                                         Team = NUM_SPECTATOR;
 270                                 }
 271                                 break;
 272                 }
 273         }
 274         if(Team == -1) // leave
 275         {
 276                 if(o.has_team)
 277                 {
 278                         tm = GetTeam(o.team, false);
 279                         tm.team_size -= 1;
 280                         o.has_team = 0;
 281                         return true;
 282                 }
 283         }
 284         else
 285         {
 286                 if (!o.has_team)
 287                 {
 288                         o.team = Team;
 289                         tm = GetTeam(Team, true);
 290                         tm.team_size += 1;
 291                         o.has_team = 1;
 292                         return true;
 293                 }
 294                 else if(Team != o.team)
 295                 {
 296                         tm = GetTeam(o.team, false);
 297                         tm.team_size -= 1;
 298                         o.team = Team;
 299                         tm = GetTeam(Team, true);
 300                         tm.team_size += 1;
 301                         return true;
 302                 }
 303         }
 304         return false;
 305 }
 306
 307 void Playerchecker_Think()
 308 {
 309     int i;
 310         entity e;
 311         for(i = 0; i < maxclients; ++i)
 312         {
 313                 e = playerslots[i];
 314                 if(GetPlayerName(i) == "")
 315                 {
 316                         if(e.sort_prev)
 317                         {
 318                                 // player disconnected
 319                                 SetTeam(e, -1);
 320                                 RemovePlayer(e);
 321                                 e.sort_prev = world;
 322                                 //e.gotscores = 0;
 323                         }
 324                 }
 325                 else
 326                 {
 327                         if (!e.sort_prev)
 328                         {
 329                                 // player connected
 330                                 if (!e)
 331                                         playerslots[i] = e = spawn();
 332                                 e.sv_entnum = i;
 333                                 e.ping = 0;
 334                                 e.ping_packetloss = 0;
 335                                 e.ping_movementloss = 0;
 336                                 //e.gotscores = 0; // we might already have the scores...
 337                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 338                                 RegisterPlayer(e);
 339                                 HUD_UpdatePlayerPos(e);
 340                         }
 341                 }
 342         }
 343         self.nextthink = time + 0.2;
 344 }
 345
 346 void Porto_Init();
 347 void TrueAim_Init();
 348 void PostInit(void)
 349 {
 350         entity playerchecker;
 351         playerchecker = spawn();
 352         playerchecker.think = Playerchecker_Think;
 353         playerchecker.nextthink = time + 0.2;
 354
 355         Porto_Init();
 356         TrueAim_Init();
 357
 358         postinit = true;
 359 }
 360
 361 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 362 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 363 // All keys are in ascii.
 364 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 365 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 366 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 367 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 368 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 369 {
 370         float bSkipKey;
 371         bSkipKey = false;
 372
 373         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 374                 return true;
 375
 376         if ( HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary) )
 377                 return true;
 378
 379         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 380                 return true;
 381
 382         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 383                 return true;
 384
 385         if(menu_visible && menu_action)
 386                 if(menu_action(bInputType, nPrimary, nSecondary))
 387                         return true;
 388
 389         return bSkipKey;
 390 }
 391
 392 // END REQUIRED CSQC FUNCTIONS
 393 // --------------------------------------------------------------------------
 394
 395 // --------------------------------------------------------------------------
 396 // BEGIN OPTIONAL CSQC FUNCTIONS
 397
 398 void Ent_RemoveEntCS()
 399 {
 400         entcs_receiver[self.sv_entnum] = world;
 401 }
 402 void Ent_ReadEntCS()
 403 {
 404     int sf;
 405         InterpolateOrigin_Undo();
 406
 407         self.classname = "entcs_receiver";
 408         sf = ReadByte();
 409
 410         if(sf & 1)
 411                 self.sv_entnum = ReadByte();
 412         if(sf & 2)
 413         {
 414                 self.origin_x = ReadShort();
 415                 self.origin_y = ReadShort();
 416                 self.origin_z = ReadShort();
 417                 setorigin(self, self.origin);
 418         }
 419         if(sf & 4)
 420         {
 421                 self.angles_y = ReadByte() * 360.0 / 256;
 422                 self.angles_x = self.angles_z = 0;
 423         }
 424         if(sf & 8)
 425                 self.healthvalue = ReadByte() * 10;
 426         if(sf & 16)
 427                 self.armorvalue = ReadByte() * 10;
 428
 429         entcs_receiver[self.sv_entnum] = self;
 430         self.entremove = Ent_RemoveEntCS;
 431         self.iflags |= IFLAG_ORIGIN;
 432
 433         InterpolateOrigin_Note();
 434 }
 435
 436 void Ent_Remove();
 437
 438 void Ent_RemovePlayerScore()
 439 {
 440         if(self.owner) {
 441                 SetTeam(self.owner, -1);
 442                 self.owner.gotscores = 0;
 443                 for(int i = 0; i < MAX_SCORE; ++i) {
 444                         self.owner.(scores[i]) = 0; // clear all scores
 445                 }
 446         }
 447 }
 448
 449 void Ent_ReadPlayerScore()
 450 {
 451         int i, n;
 452         bool isNew;
 453         entity o;
 454
 455         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 456         // (no I've never heard of M-x replace-string, sed, or anything like that)
 457         isNew = !self.owner; // workaround for DP bug
 458         n = ReadByte()-1;
 459
 460 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 461         if(!isNew && n != self.sv_entnum)
 462         {
 463                 //print("A CSQC entity changed its owner!\n");
 464                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 465                 isNew = true;
 466                 Ent_Remove();
 467                 self.enttype = ENT_CLIENT_SCORES;
 468         }
 469 #endif
 470
 471         self.sv_entnum = n;
 472
 473         if (!(playerslots[self.sv_entnum]))
 474                 playerslots[self.sv_entnum] = spawn();
 475         o = self.owner = playerslots[self.sv_entnum];
 476         o.sv_entnum = self.sv_entnum;
 477         o.gotscores = 1;
 478
 479         //if (!o.sort_prev)
 480         //      RegisterPlayer(o);
 481         //playerchecker will do this for us later, if it has not already done so
 482
 483     int sf, lf;
 484 #if MAX_SCORE <= 8
 485         sf = ReadByte();
 486         lf = ReadByte();
 487 #else
 488         sf = ReadShort();
 489         lf = ReadShort();
 490 #endif
 491     int p;
 492         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 493                 if(sf & p)
 494                 {
 495                         if(lf & p)
 496                                 o.(scores[i]) = ReadInt24_t();
 497                         else
 498                                 o.(scores[i]) = ReadChar();
 499                 }
 500
 501         if(o.sort_prev)
 502                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 503
 504         self.entremove = Ent_RemovePlayerScore;
 505 }
 506
 507 void Ent_ReadTeamScore()
 508 {
 509         int i;
 510         entity o;
 511
 512         self.team = ReadByte();
 513         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 514
 515     int sf, lf;
 516 #if MAX_TEAMSCORE <= 8
 517         sf = ReadByte();
 518         lf = ReadByte();
 519 #else
 520         sf = ReadShort();
 521         lf = ReadShort();
 522 #endif
 523         int p;
 524         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 525                 if(sf & p)
 526                 {
 527                         if(lf & p)
 528                                 o.(teamscores[i]) = ReadInt24_t();
 529                         else
 530                                 o.(teamscores[i]) = ReadChar();
 531                 }
 532
 533         HUD_UpdateTeamPos(o);
 534 }
 535
 536 void Ent_ClientData()
 537 {
 538         float newspectatee_status;
 539
 540     int f = ReadByte();
 541
 542         scoreboard_showscores_force = (f & 1);
 543
 544         if(f & 2)
 545         {
 546                 newspectatee_status = ReadByte();
 547                 if(newspectatee_status == player_localnum + 1)
 548                         newspectatee_status = -1; // observing
 549         }
 550         else
 551                 newspectatee_status = 0;
 552
 553         spectatorbutton_zoom = (f & 4);
 554
 555         if(f & 8)
 556         {
 557                 angles_held_status = 1;
 558                 angles_held.x = ReadAngle();
 559                 angles_held.y = ReadAngle();
 560                 angles_held.z = 0;
 561         }
 562         else
 563                 angles_held_status = 0;
 564
 565         if(newspectatee_status != spectatee_status)
 566         {
 567                 // clear race stuff
 568                 race_laptime = 0;
 569                 race_checkpointtime = 0;
 570         }
 571         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 572         {
 573                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 574                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 575                 )
 576                         prev_p_health = -1;
 577                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 578                         prev_health = -1;
 579         }
 580         spectatee_status = newspectatee_status;
 581
 582         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 583 }
 584
 585 void Ent_Nagger()
 586 {
 587     int i, j, b, f;
 588
 589     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 590
 591         if(!(nags & 4))
 592         {
 593                 if(vote_called_vote)
 594                         strunzone(vote_called_vote);
 595                 vote_called_vote = string_null;
 596                 vote_active = 0;
 597         }
 598         else
 599         {
 600                 vote_active = 1;
 601         }
 602
 603         if(nags & 64)
 604         {
 605                 vote_yescount = ReadByte();
 606                 vote_nocount = ReadByte();
 607                 vote_needed = ReadByte();
 608                 vote_highlighted = ReadChar();
 609         }
 610
 611         if(nags & 128)
 612         {
 613                 if(vote_called_vote)
 614                         strunzone(vote_called_vote);
 615                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 616         }
 617
 618         if(nags & 1)
 619         {
 620                 for(j = 0; j < maxclients; ++j)
 621                         if(playerslots[j])
 622                                 playerslots[j].ready = 1;
 623                 for(i = 1; i <= maxclients; i += 8)
 624                 {
 625                         f = ReadByte();
 626                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 627                                 if (!(f & b))
 628                                         if(playerslots[j])
 629                                                 playerslots[j].ready = 0;
 630                 }
 631         }
 632
 633         ready_waiting = (nags & 1);
 634         ready_waiting_for_me = (nags & 2);
 635         vote_waiting = (nags & 4);
 636         vote_waiting_for_me = (nags & 8);
 637         warmup_stage = (nags & 16);
 638 }
 639
 640 void Ent_EliminatedPlayers()
 641 {
 642     int i, j, b, f;
 643
 644     int sf = ReadByte();
 645         if(sf & 1)
 646         {
 647                 for(j = 0; j < maxclients; ++j)
 648                         if(playerslots[j])
 649                                 playerslots[j].eliminated = 1;
 650                 for(i = 1; i <= maxclients; i += 8)
 651                 {
 652                         f = ReadByte();
 653                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 654                                 if (!(f & b))
 655                                         if(playerslots[j])
 656                                                 playerslots[j].eliminated = 0;
 657                 }
 658         }
 659 }
 660
 661 void Ent_RandomSeed()
 662 {
 663         float s;
 664         prandom_debug();
 665         s = ReadShort();
 666         psrandom(s);
 667 }
 668
 669 void Ent_ReadAccuracy(void)
 670 {
 671     int f, w;
 672     int sf = ReadInt24_t();
 673         if(sf == 0)
 674         {
 675                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 676                         weapon_accuracy[w] = -1;
 677                 return;
 678         }
 679
 680         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 681         {
 682                 if(sf & f)
 683                 {
 684             int b = ReadByte();
 685                         if(b == 0)
 686                                 weapon_accuracy[w] = -1;
 687                         else if(b == 255)
 688                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 689                         else
 690                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 691                 }
 692                 if(f == 0x800000)
 693                         f = 1;
 694                 else
 695                         f *= 2;
 696         }
 697 }
 698
 699 void Spawn_Draw(void)
 700 {
 701         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 702 }
 703
 704 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 705 {
 706         float teamnum = (ReadByte() - 1);
 707         vector spn_origin;
 708         spn_origin.x = ReadShort();
 709         spn_origin.y = ReadShort();
 710         spn_origin.z = ReadShort();
 711
 712         if(is_new)
 713         {
 714                 self.origin = spn_origin;
 715                 setsize(self, PL_MIN_CONST, PL_MAX_CONST);
 716                 droptofloor();
 717
 718                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 719                 {
 720                         self.mdl = "models/spawnpoint.md3";
 721                         self.colormod = Team_ColorRGB(teamnum);
 722                         precache_model(self.mdl);
 723                         setmodel(self, self.mdl);
 724                         self.drawmask = MASK_NORMAL;
 725                         //self.movetype = MOVETYPE_NOCLIP;
 726                         //self.draw = Spawn_Draw;
 727                 }*/
 728                 if(autocvar_cl_spawn_point_particles)
 729                 {
 730                         if((serverflags & SERVERFLAG_TEAMPLAY))
 731                         {
 732                                 switch(teamnum)
 733                                 {
 734                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 735                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 736                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 737                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 738                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 739                                 }
 740                         }
 741                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 742
 743                         self.draw = Spawn_Draw;
 744                 }
 745         }
 746
 747         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 748 }
 749
 750 void Ent_ReadSpawnEvent(float is_new)
 751 {
 752         // If entnum is 0, ONLY do the local spawn actions
 753         // this way the server can disable the sending of
 754         // spawn origin or such to clients if wanted.
 755         float entnum = ReadByte();
 756
 757         if(entnum)
 758         {
 759                 self.origin_x = ReadShort();
 760                 self.origin_y = ReadShort();
 761                 self.origin_z = ReadShort();
 762
 763                 if(is_new)
 764                 {
 765                         float teamnum = GetPlayerColor(entnum - 1);
 766
 767                         if(autocvar_cl_spawn_event_particles)
 768                         {
 769                                 switch(teamnum)
 770                                 {
 771                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 772                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 773                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 774                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 775                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 776                                 }
 777                         }
 778                         if(autocvar_cl_spawn_event_sound)
 779                         {
 780                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 781                         }
 782                 }
 783         }
 784
 785         // local spawn actions
 786         if(is_new && (!entnum || (entnum == player_localentnum)))
 787         {
 788                 zoomin_effect = 1;
 789                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 790
 791                 if(autocvar_cl_unpress_zoom_on_spawn)
 792                 {
 793                         localcmd("-zoom\n");
 794                         button_zoom = false;
 795                 }
 796         }
 797         HUD_Radar_Hide_Maximized();
 798         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 799 }
 800
 801 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 802 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 803 void Ent_RadarLink();
 804 void Ent_Init();
 805 void Ent_ScoresInfo();
 806 void CSQC_Ent_Update(float bIsNewEntity)
 807 {
 808         float t;
 809         float savetime;
 810         t = ReadByte();
 811
 812         if(autocvar_developer_csqcentities)
 813                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 814
 815         // set up the "time" global for received entities to be correct for interpolation purposes
 816         savetime = time;
 817         if(servertime)
 818         {
 819                 time = servertime;
 820         }
 821         else
 822         {
 823                 serverprevtime = time;
 824                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 825                 time = serverprevtime + serverdeltatime;
 826         }
 827
 828 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 829         if(self.enttype)
 830         {
 831                 if(t != self.enttype || bIsNewEntity)
 832                 {
 833                         //print("A CSQC entity changed its type!\n");
 834                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 835                         Ent_Remove();
 836                         clearentity(self);
 837                         bIsNewEntity = 1;
 838                 }
 839         }
 840         else
 841         {
 842                 if(!bIsNewEntity)
 843                 {
 844                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 845                         bIsNewEntity = 1;
 846                 }
 847         }
 848 #endif
 849         self.enttype = t;
 850         switch(t)
 851         {
 852                 case ENT_CLIENT_MUTATOR: {
 853                         int mutID = ReadMutator();
 854                         if (!MUTATOR_CALLHOOK(CSQC_Ent_Update, mutID, bIsNewEntity))
 855                         error(sprintf("Unknown mutator type in CSQC_Ent_Update (mutID: %d, edict: %d, classname: %s)\n", mutID, num_for_edict(self), self.classname));
 856                         break;
 857                 }
 858                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 859                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 860                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 861                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 862                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 863                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 864                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 865                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 866                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 867                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 868                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 869                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 870                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 871                 case ENT_CLIENT_INIT: Ent_Init(); break;
 872                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 873                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 874                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 875                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 876                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 877                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 878                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 879                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 880                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 881                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 882                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 883                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 884                 case ENT_CLIENT_INVENTORY: Inventory_Read(self); break;
 885                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 886                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 887                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 888                 case ENT_CLIENT_TURRET: ent_turret(); break;
 889                 case ENT_CLIENT_GENERATOR: ent_generator(); break;
 890                 case ENT_CLIENT_CONTROLPOINT_ICON: ent_cpicon(); break;
 891                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 892                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 893                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 894                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 895                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 896                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 897                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 898                 case ENT_CLIENT_MINIGAME: ent_read_minigame(); break;
 899                 case ENT_CLIENT_VIEWLOC: ent_viewloc(); break;
 900                 case ENT_CLIENT_VIEWLOC_TRIGGER: ent_viewloc_trigger(); break;
 901                 case ENT_CLIENT_LADDER: ent_func_ladder(); break;
 902                 case ENT_CLIENT_TRIGGER_PUSH: ent_trigger_push(); break;
 903                 case ENT_CLIENT_TARGET_PUSH: ent_target_push(); break;
 904                 case ENT_CLIENT_CONVEYOR: ent_conveyor(); break;
 905                 case ENT_CLIENT_DOOR: ent_door(); break;
 906                 case ENT_CLIENT_PLAT: ent_plat(); break;
 907                 case ENT_CLIENT_SWAMP: ent_swamp(); break;
 908                 case ENT_CLIENT_CORNER: ent_corner(); break;
 909                 case ENT_CLIENT_KEYLOCK: ent_keylock(); break;
 910                 case ENT_CLIENT_TRAIN: ent_train(); break;
 911                 case ENT_CLIENT_TRIGGER_IMPULSE: ent_trigger_impulse(); break;
 912                 case ENT_CLIENT_EFFECT: Read_Effect(bIsNewEntity); break;
 913
 914                 default:
 915                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 916                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 917                         break;
 918         }
 919
 920         time = savetime;
 921 }
 922 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 923 // used when an entity changes its type. For an entity that someone interacts
 924 // with others, make sure it can no longer do so.
 925 void Ent_Remove()
 926 {
 927         if(self.entremove)
 928                 self.entremove();
 929
 930         if(self.skeletonindex)
 931         {
 932                 skel_delete(self.skeletonindex);
 933                 self.skeletonindex = 0;
 934         }
 935
 936         if(self.snd_looping > 0)
 937         {
 938                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 939                 self.snd_looping = 0;
 940         }
 941
 942         self.enttype = 0;
 943         self.classname = "";
 944         self.draw = menu_sub_null;
 945         self.entremove = menu_sub_null;
 946         // TODO possibly set more stuff to defaults
 947 }
 948 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 949 void CSQC_Ent_Remove()
 950 {
 951         if(autocvar_developer_csqcentities)
 952                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 953
 954         if(wasfreed(self))
 955         {
 956                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 957                 return;
 958         }
 959         if(self.enttype)
 960                 Ent_Remove();
 961         remove(self);
 962 }
 963
 964 void Gamemode_Init()
 965 {
 966         if (!isdemo())
 967         {
 968                 if(!(calledhooks & HOOK_START))
 969                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 970                 calledhooks |= HOOK_START;
 971         }
 972 }
 973 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 974 void CSQC_Parse_StuffCmd(string strMessage)
 975 {
 976         if(autocvar_developer_csqcentities)
 977                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 978
 979         localcmd(strMessage);
 980 }
 981 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 982 void CSQC_Parse_Print(string strMessage)
 983 {
 984         if(autocvar_developer_csqcentities)
 985                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
 986
 987         print(ColorTranslateRGB(strMessage));
 988 }
 989
 990 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 991 void CSQC_Parse_CenterPrint(string strMessage)
 992 {
 993         if(autocvar_developer_csqcentities)
 994                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 995
 996         centerprint_hud(strMessage);
 997 }
 998
 999 string notranslate_fogcmd1 = "\nfog ";
1000 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1001 void Fog_Force()
1002 {
1003         // TODO somehow thwart prvm_globalset client ...
1004
1005         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1006                 { localcmd("\nr_drawfog 0\n"); }
1007         else if(forcefog != "")
1008                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
1009 }
1010
1011 void Gamemode_Init();
1012 void Ent_ScoresInfo()
1013 {
1014     int i;
1015         self.classname = "ent_client_scores_info";
1016         gametype = ReadInt24_t();
1017         HUD_ModIcons_SetFunc();
1018         for(i = 0; i < MAX_SCORE; ++i)
1019         {
1020                 if(scores_label[i])
1021                         strunzone(scores_label[i]);
1022                 scores_label[i] = strzone(ReadString());
1023                 scores_flags[i] = ReadByte();
1024         }
1025         for(i = 0; i < MAX_TEAMSCORE; ++i)
1026         {
1027                 if(teamscores_label[i])
1028                         strunzone(teamscores_label[i]);
1029                 teamscores_label[i] = strzone(ReadString());
1030                 teamscores_flags[i] = ReadByte();
1031         }
1032         HUD_InitScores();
1033         Gamemode_Init();
1034 }
1035
1036 void Ent_Init()
1037 {
1038         self.classname = "ent_client_init";
1039
1040         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1041
1042         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1043         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1044         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1045         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1046         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1047         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1048         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1049         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1050
1051         if(forcefog)
1052                 strunzone(forcefog);
1053         forcefog = strzone(ReadString());
1054
1055         armorblockpercent = ReadByte() / 255.0;
1056
1057         g_balance_mortar_bouncefactor = ReadCoord();
1058         g_balance_mortar_bouncestop = ReadCoord();
1059         g_balance_electro_secondary_bouncefactor = ReadCoord();
1060         g_balance_electro_secondary_bouncestop = ReadCoord();
1061
1062         vortex_scope = !ReadByte();
1063         rifle_scope = !ReadByte();
1064
1065         serverflags = ReadByte();
1066
1067         minelayer_maxmines = ReadByte();
1068
1069         hagar_maxrockets = ReadByte();
1070
1071         g_trueaim_minrange = ReadCoord();
1072         g_balance_porto_secondary = ReadByte();
1073
1074         if(!postinit)
1075                 PostInit();
1076 }
1077
1078 void Net_ReadRace()
1079 {
1080         float b;
1081
1082         b = ReadByte();
1083
1084         switch(b)
1085         {
1086                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1087                         race_checkpoint = ReadByte();
1088                         race_time = ReadInt24_t();
1089                         race_previousbesttime = ReadInt24_t();
1090                         if(race_previousbestname)
1091                                 strunzone(race_previousbestname);
1092                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1093
1094                         race_checkpointtime = time;
1095
1096                         if(race_checkpoint == 0 || race_checkpoint == 254)
1097                         {
1098                                 race_penaltyaccumulator = 0;
1099                                 race_laptime = time; // valid
1100                         }
1101
1102                         break;
1103
1104                 case RACE_NET_CHECKPOINT_CLEAR:
1105                         race_laptime = 0;
1106                         race_checkpointtime = 0;
1107                         break;
1108
1109                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1110                         race_laptime = ReadCoord();
1111                         race_checkpointtime = -99999;
1112                         // fall through
1113                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1114                         race_nextcheckpoint = ReadByte();
1115
1116                         race_nextbesttime = ReadInt24_t();
1117                         if(race_nextbestname)
1118                                 strunzone(race_nextbestname);
1119                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1120                         break;
1121
1122                 case RACE_NET_CHECKPOINT_HIT_RACE:
1123                         race_mycheckpoint = ReadByte();
1124                         race_mycheckpointtime = time;
1125                         race_mycheckpointdelta = ReadInt24_t();
1126                         race_mycheckpointlapsdelta = ReadByte();
1127                         if(race_mycheckpointlapsdelta >= 128)
1128                                 race_mycheckpointlapsdelta -= 256;
1129                         if(race_mycheckpointenemy)
1130                                 strunzone(race_mycheckpointenemy);
1131                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1132                         break;
1133
1134                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1135                         race_othercheckpoint = ReadByte();
1136                         race_othercheckpointtime = time;
1137                         race_othercheckpointdelta = ReadInt24_t();
1138                         race_othercheckpointlapsdelta = ReadByte();
1139                         if(race_othercheckpointlapsdelta >= 128)
1140                                 race_othercheckpointlapsdelta -= 256;
1141                         if(race_othercheckpointenemy)
1142                                 strunzone(race_othercheckpointenemy);
1143                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1144                         break;
1145
1146                 case RACE_NET_PENALTY_RACE:
1147                         race_penaltyeventtime = time;
1148                         race_penaltytime = ReadShort();
1149                         //race_penaltyaccumulator += race_penaltytime;
1150                         if(race_penaltyreason)
1151                                 strunzone(race_penaltyreason);
1152                         race_penaltyreason = strzone(ReadString());
1153                         break;
1154
1155                 case RACE_NET_PENALTY_QUALIFYING:
1156                         race_penaltyeventtime = time;
1157                         race_penaltytime = ReadShort();
1158                         race_penaltyaccumulator += race_penaltytime;
1159                         if(race_penaltyreason)
1160                                 strunzone(race_penaltyreason);
1161                         race_penaltyreason = strzone(ReadString());
1162                         break;
1163
1164                 case RACE_NET_SERVER_RECORD:
1165                         race_server_record = ReadInt24_t();
1166                         break;
1167                 case RACE_NET_SPEED_AWARD:
1168                         race_speedaward = ReadInt24_t();
1169                         if(race_speedaward_holder)
1170                                 strunzone(race_speedaward_holder);
1171                         race_speedaward_holder = strzone(ReadString());
1172                         break;
1173                 case RACE_NET_SPEED_AWARD_BEST:
1174                         race_speedaward_alltimebest = ReadInt24_t();
1175                         if(race_speedaward_alltimebest_holder)
1176                                 strunzone(race_speedaward_alltimebest_holder);
1177                         race_speedaward_alltimebest_holder = strzone(ReadString());
1178                         break;
1179                 case RACE_NET_SERVER_RANKINGS:
1180                         float prevpos, del;
1181             int pos = ReadShort();
1182                         prevpos = ReadShort();
1183                         del = ReadShort();
1184
1185                         // move other rankings out of the way
1186             int i;
1187                         if (prevpos) {
1188                                 for (i=prevpos-1;i>pos-1;--i) {
1189                                         grecordtime[i] = grecordtime[i-1];
1190                                         if(grecordholder[i])
1191                                                 strunzone(grecordholder[i]);
1192                                         grecordholder[i] = strzone(grecordholder[i-1]);
1193                                 }
1194                         } else if (del) { // a record has been deleted by the admin
1195                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1196                                         if (i == RANKINGS_CNT-1) { // clear out last record
1197                                                 grecordtime[i] = 0;
1198                                                 if (grecordholder[i])
1199                                                         strunzone(grecordholder[i]);
1200                                                 grecordholder[i] = string_null;
1201                                         }
1202                                         else {
1203                                                 grecordtime[i] = grecordtime[i+1];
1204                                                 if (grecordholder[i])
1205                                                         strunzone(grecordholder[i]);
1206                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1207                                         }
1208                                 }
1209                         } else { // player has no ranked record yet
1210                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1211                                         grecordtime[i] = grecordtime[i-1];
1212                                         if(grecordholder[i])
1213                                                 strunzone(grecordholder[i]);
1214                                         grecordholder[i] = strzone(grecordholder[i-1]);
1215                                 }
1216                         }
1217
1218                         // store new ranking
1219                         if(grecordholder[pos-1] != "")
1220                                 strunzone(grecordholder[pos-1]);
1221                         grecordholder[pos-1] = strzone(ReadString());
1222                         grecordtime[pos-1] = ReadInt24_t();
1223                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1224                                 race_myrank = pos;
1225                         break;
1226                 case RACE_NET_SERVER_STATUS:
1227                         race_status = ReadShort();
1228                         if(race_status_name)
1229                                 strunzone(race_status_name);
1230                         race_status_name = strzone(ReadString());
1231         }
1232 }
1233
1234 void Net_TeamNagger()
1235 {
1236         teamnagger = 1;
1237 }
1238
1239 void Net_ReadPingPLReport()
1240 {
1241         int e, pi, pl, ml;
1242         e = ReadByte();
1243         pi = ReadShort();
1244         pl = ReadByte();
1245         ml = ReadByte();
1246         if (!(playerslots[e]))
1247                 return;
1248         playerslots[e].ping = pi;
1249         playerslots[e].ping_packetloss = pl / 255.0;
1250         playerslots[e].ping_movementloss = ml / 255.0;
1251 }
1252
1253 void Net_WeaponComplain()
1254 {
1255         complain_weapon = ReadByte();
1256
1257         if(complain_weapon_name)
1258                 strunzone(complain_weapon_name);
1259         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1260
1261         complain_weapon_type = ReadByte();
1262
1263         complain_weapon_time = time;
1264         weapontime = time; // ping the weapon panel
1265
1266         switch(complain_weapon_type)
1267         {
1268                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1269                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1270                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1271         }
1272 }
1273
1274 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1275 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1276 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1277 float CSQC_Parse_TempEntity()
1278 {
1279         // Acquire TE ID
1280         int nTEID = ReadByte();
1281
1282         if (autocvar_developer_csqcentities)
1283                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1284
1285         switch (nTEID)
1286         {
1287                 case TE_CSQC_MUTATOR:
1288                         int mutID = ReadMutator();
1289                         if (MUTATOR_CALLHOOK(CSQC_Parse_TempEntity, mutID))
1290                         return true;
1291                 case TE_CSQC_TARGET_MUSIC:
1292                         Net_TargetMusic();
1293                         return true;
1294                 case TE_CSQC_PICTURE:
1295                         Net_MapVote_Picture();
1296                         return true;
1297                 case TE_CSQC_RACE:
1298                         Net_ReadRace();
1299                         return true;
1300                 case TE_CSQC_VORTEXBEAMPARTICLE:
1301                         Net_ReadVortexBeamParticle();
1302                         return true;
1303                 case TE_CSQC_TEAMNAGGER:
1304                         Net_TeamNagger();
1305                         return true;
1306                 case TE_CSQC_ARC:
1307                         Net_ReadArc();
1308                         return true;
1309                 case TE_CSQC_PINGPLREPORT:
1310                         Net_ReadPingPLReport();
1311                         return true;
1312                 case TE_CSQC_WEAPONCOMPLAIN:
1313                         Net_WeaponComplain();
1314                         return true;
1315                 case TE_CSQC_VEHICLESETUP:
1316                         Net_VehicleSetup();
1317                         return true;
1318                 case TE_CSQC_SVNOTICE:
1319                         cl_notice_read();
1320                         return true;
1321                 case TE_CSQC_SHOCKWAVEPARTICLE:
1322                         Net_ReadShockwaveParticle();
1323                         return true;
1324                 default:
1325                         // No special logic for this temporary entity; return 0 so the engine can handle it
1326                         return false;
1327         }
1328 }
1329
1330 string getcommandkey(string text, string command)
1331 {
1332         string keys;
1333         float n, j, k, l = 0;
1334
1335         if (!autocvar_hud_showbinds)
1336                 return text;
1337
1338         keys = db_get(binddb, command);
1339         if (keys == "")
1340         {
1341                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1342                 for(j = 0; j < n; ++j)
1343                 {
1344                         k = stof(argv(j));
1345                         if(k != -1)
1346                         {
1347                                 if ("" == keys)
1348                                         keys = keynumtostring(k);
1349                                 else
1350                                         keys = strcat(keys, ", ", keynumtostring(k));
1351
1352                                 ++l;
1353                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1354                                         break;
1355                         }
1356
1357                 }
1358                 if (keys == "")
1359                         keys = "NO_KEY";
1360                 db_put(binddb, command, keys);
1361         }
1362
1363         if (keys == "NO_KEY") {
1364                 if (autocvar_hud_showbinds > 1)
1365                         return sprintf(_("%s (not bound)"), text);
1366                 else
1367                         return text;
1368         }
1369         else if (autocvar_hud_showbinds > 1)
1370                 return sprintf("%s (%s)", text, keys);
1371         else
1372                 return keys;
1373 }