qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <common/effects/qc/all.qh>
   4 #include "hud/all.qh"
   5 #include "mapvoting.qh"
   6 #include "mutators/events.qh"
   7 #include "hud/panel/quickmenu.qh"
   8 #include "scoreboard.qh"
   9 #include "shownames.qh"
  10 #include <common/t_items.qh>
  11 #include "wall.qh"
  12 #include "weapons/projectile.qh"
  13 #include <common/deathtypes/all.qh>
  14 #include <common/items/all.qh>
  15 #include <common/mapinfo.qh>
  16 #include <common/minigames/cl_minigames.qh>
  17 #include <common/minigames/cl_minigames_hud.qh>
  18 #include <common/net_notice.qh>
  19 #include <common/triggers/include.qh>
  20 #include <common/vehicles/all.qh>
  21 #include <lib/csqcmodel/cl_model.qh>
  22 #include <lib/csqcmodel/interpolate.qh>
  23 #include <lib/warpzone/client.qh>
  24
  25 // --------------------------------------------------------------------------
  26 // BEGIN REQUIRED CSQC FUNCTIONS
  27 //include "main.qh"
  28
  29 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  30
  31 void draw_cursor(vector pos, vector ofs, string img, vector col, float a)
  32 {
  33         ofs = eX * (ofs.x * SIZE_CURSOR.x) + eY * (ofs.y * SIZE_CURSOR.y);
  34         drawpic(pos - ofs, strcat(draw_currentSkin, img), SIZE_CURSOR, col, a, DRAWFLAG_NORMAL);
  35 }
  36
  37 void draw_cursor_normal(vector pos, vector col, float a)
  38 {
  39         draw_cursor(pos, OFFSET_CURSOR, "/cursor", col, a);
  40 }
  41
  42 void LoadMenuSkinValues()
  43 {
  44         int fh = -1;
  45         if(cvar_string("menu_skin") != "")
  46         {
  47                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  48                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  49         }
  50         if(fh < 0 && cvar_defstring("menu_skin") != "")
  51         {
  52                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
  53                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  54                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  55         }
  56         if(fh < 0)
  57         {
  58                 draw_currentSkin = "gfx/menu/default";
  59                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  60         }
  61
  62         draw_currentSkin = strzone(draw_currentSkin);
  63
  64         if(fh >= 0)
  65         {
  66                 string s;
  67                 while((s = fgets(fh)))
  68                 {
  69                         int n = tokenize_console(s);
  70                         if (n < 2)
  71                                 continue;
  72                         if(substring(argv(0), 0, 2) == "//")
  73                                 continue;
  74                         if(argv(0) == "SIZE_CURSOR")
  75                                 SIZE_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  76                         else if(argv(0) == "OFFSET_CURSOR")
  77                                 OFFSET_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  78                 }
  79                 fclose(fh);
  80         }
  81 }
  82
  83 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  84 // Useful for precaching things
  85
  86 void ConsoleCommand_macro_init();
  87 void CSQC_Init()
  88 {
  89         prvm_language = strzone(cvar_string("prvm_language"));
  90
  91 #ifdef WATERMARK
  92         LOG_INFOF("^4CSQC Build information: ^1%s\n", WATERMARK);
  93 #endif
  94
  95         {
  96                 int i = 0;
  97                 for ( ; i < 255; ++i)
  98                         if (getplayerkeyvalue(i, "viewentity") == "")
  99                                 break;
 100                 maxclients = i;
 101         }
 102
 103         binddb = db_create();
 104         tempdb = db_create();
 105         ClientProgsDB = db_load("client.db");
 106         compressShortVector_init();
 107
 108         draw_endBoldFont();
 109
 110         //registercommand("hud_configure");
 111         //registercommand("hud_save");
 112         //registercommand("menu_action");
 113
 114         ConsoleCommand_macro_init();
 115
 116         registercvar("hud_usecsqc", "1");
 117         registercvar("scoreboard_columns", "default");
 118
 119         registercvar("cl_nade_type", "3");
 120         registercvar("cl_pokenade_type", "zombie");
 121
 122         registercvar("cl_jumpspeedcap_min", "");
 123         registercvar("cl_jumpspeedcap_max", "");
 124
 125         registercvar("cl_multijump", "1");
 126
 127         registercvar("cl_spawn_near_teammate", "1");
 128
 129         gametype = 0;
 130
 131         // hud_fields uses strunzone on the titles!
 132         for(int i = 0; i < MAX_HUD_FIELDS; ++i)
 133                 hud_title[i] = strzone("(null)");
 134
 135         Cmd_HUD_SetFields(0);
 136
 137         postinit = false;
 138
 139         calledhooks = 0;
 140
 141         teams = Sort_Spawn();
 142         players = Sort_Spawn();
 143
 144         GetTeam(NUM_SPECTATOR, true); // add specs first
 145
 146         // precaches
 147
 148         if(autocvar_cl_reticle)
 149         {
 150                 precache_pic("gfx/reticle_normal");
 151                 // weapon reticles are precached in weapon files
 152         }
 153
 154         {
 155                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 156                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 157                 shortmapname = mi_shortname;
 158
 159                 if (precache_pic(minimapname) == "")
 160                 {
 161                         // but maybe we have a non-clever minimap
 162                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 163                         if (precache_pic(minimapname) == "")
 164                                 minimapname = ""; // FAIL
 165                         else
 166                                 get_mi_min_max_texcoords(0); // load new texcoords
 167                 }
 168
 169                 mi_center = (mi_min + mi_max) * 0.5;
 170                 mi_scale = mi_max - mi_min;
 171                 minimapname = strzone(minimapname);
 172         }
 173
 174         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 175         LoadMenuSkinValues();
 176 }
 177
 178 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 179 void Shutdown()
 180 {
 181         WarpZone_Shutdown();
 182
 183         remove(teams);
 184         remove(players);
 185         db_close(binddb);
 186         db_close(tempdb);
 187         if(autocvar_cl_db_saveasdump)
 188                 db_dump(ClientProgsDB, "client.db");
 189         else
 190                 db_save(ClientProgsDB, "client.db");
 191         db_close(ClientProgsDB);
 192
 193         if(camera_active)
 194                 cvar_set("chase_active",ftos(chase_active_backup));
 195
 196         // unset the event chasecam's chase_active
 197         if(autocvar_chase_active < 0)
 198                 cvar_set("chase_active", "0");
 199
 200         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 201
 202         if (!isdemo())
 203         {
 204                 if (!(calledhooks & HOOK_START))
 205                         localcmd("\n_cl_hook_gamestart nop\n");
 206                 if (!(calledhooks & HOOK_END))
 207                         localcmd("\ncl_hook_gameend\n");
 208         }
 209
 210         deactivate_minigame();
 211         HUD_MinigameMenu_Close();
 212 }
 213
 214 .float has_team;
 215 float SetTeam(entity o, int Team)
 216 {
 217     TC(int, Team);
 218         devassert_once(Team);
 219         entity tm;
 220         if(teamplay)
 221         {
 222                 switch(Team)
 223                 {
 224                         case -1:
 225                         case NUM_TEAM_1:
 226                         case NUM_TEAM_2:
 227                         case NUM_TEAM_3:
 228                         case NUM_TEAM_4:
 229                                 break;
 230                         default:
 231                                 if(GetTeam(Team, false) == world)
 232                                 {
 233                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 234                                         Team = NUM_SPECTATOR;
 235                                 }
 236                                 break;
 237                 }
 238         }
 239         else
 240         {
 241                 switch(Team)
 242                 {
 243                         case -1:
 244                         case 0:
 245                                 break;
 246                         default:
 247                                 if(GetTeam(Team, false) == world)
 248                                 {
 249                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 250                                         Team = NUM_SPECTATOR;
 251                                 }
 252                                 break;
 253                 }
 254         }
 255         if(Team == -1) // leave
 256         {
 257                 if(o.has_team)
 258                 {
 259                         tm = GetTeam(o.team, false);
 260                         tm.team_size -= 1;
 261                         o.has_team = 0;
 262                         return true;
 263                 }
 264         }
 265         else
 266         {
 267                 if (!o.has_team)
 268                 {
 269                         o.team = Team;
 270                         tm = GetTeam(Team, true);
 271                         tm.team_size += 1;
 272                         o.has_team = 1;
 273                         return true;
 274                 }
 275                 else if(Team != o.team)
 276                 {
 277                         tm = GetTeam(o.team, false);
 278                         tm.team_size -= 1;
 279                         o.team = Team;
 280                         tm = GetTeam(Team, true);
 281                         tm.team_size += 1;
 282                         return true;
 283                 }
 284         }
 285         return false;
 286 }
 287
 288 void Playerchecker_Think()
 289 {
 290         SELFPARAM();
 291     int i;
 292         entity e;
 293         for(i = 0; i < maxclients; ++i)
 294         {
 295                 e = playerslots[i];
 296                 if(entcs_GetName(i) == "")
 297                 {
 298                         if(e.sort_prev)
 299                         {
 300                                 // player disconnected
 301                                 SetTeam(e, -1);
 302                                 RemovePlayer(e);
 303                                 e.sort_prev = world;
 304                                 //e.gotscores = 0;
 305                         }
 306                 }
 307                 else
 308                 {
 309                         if (!e.sort_prev)
 310                         {
 311                                 // player connected
 312                                 if (!e)
 313                                 {
 314                                         playerslots[i] = e = new_pure(playerslot);
 315                                 }
 316                                 e.sv_entnum = i;
 317                                 e.ping = 0;
 318                                 e.ping_packetloss = 0;
 319                                 e.ping_movementloss = 0;
 320                                 //e.gotscores = 0; // we might already have the scores...
 321                                 int t = entcs_GetScoreTeam(i);
 322                                 if (t) SetTeam(e, t); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 323                                 RegisterPlayer(e);
 324                                 HUD_UpdatePlayerPos(e);
 325                         }
 326                 }
 327         }
 328         this.nextthink = time + 0.2;
 329 }
 330
 331 void TrueAim_Init();
 332 void PostInit()
 333 {
 334         entity playerchecker = new_pure(playerchecker);
 335         playerchecker.think = Playerchecker_Think;
 336         playerchecker.nextthink = time + 0.2;
 337
 338         TrueAim_Init();
 339
 340         postinit = true;
 341 }
 342
 343 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 344 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 345 // All keys are in ascii.
 346 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 347 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 348 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 349 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 350 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 351 {
 352     TC(int, bInputType);
 353         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 354                 return true;
 355
 356         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 357                 return true;
 358
 359         if (HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary))
 360                 return true;
 361
 362         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 363                 return true;
 364
 365         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 366                 return true;
 367
 368         return false;
 369 }
 370
 371 // END REQUIRED CSQC FUNCTIONS
 372 // --------------------------------------------------------------------------
 373
 374 // --------------------------------------------------------------------------
 375 // BEGIN OPTIONAL CSQC FUNCTIONS
 376
 377 .void(entity) predraw_qc;
 378 void PreDraw_self()
 379 {
 380         SELFPARAM();
 381         if (this.predraw_qc) this.predraw_qc(this);
 382 }
 383
 384 void setpredraw(entity this, void(entity) pdfunc)
 385 {
 386         this.predraw = PreDraw_self;
 387         this.predraw_qc = pdfunc;
 388 }
 389
 390 void Ent_Remove(entity this);
 391
 392 void Ent_RemovePlayerScore(entity this)
 393 {
 394         if(this.owner) {
 395                 SetTeam(this.owner, -1);
 396                 this.owner.gotscores = 0;
 397                 for(int i = 0; i < MAX_SCORE; ++i) {
 398                         this.owner.(scores[i]) = 0; // clear all scores
 399                 }
 400         }
 401 }
 402
 403 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 404 {
 405         make_pure(this);
 406         int i, n;
 407         bool isNew;
 408         entity o;
 409
 410         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 411         // (no I've never heard of M-x replace-string, sed, or anything like that)
 412         isNew = !this.owner; // workaround for DP bug
 413         n = ReadByte()-1;
 414
 415 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 416         if(!isNew && n != this.sv_entnum)
 417         {
 418                 //print("A CSQC entity changed its owner!\n");
 419                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", etof(this), this.classname);
 420                 isNew = true;
 421                 Ent_Remove(this);
 422         }
 423 #endif
 424
 425         this.sv_entnum = n;
 426
 427         o = playerslots[this.sv_entnum];
 428         if (!o)
 429         {
 430                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 431         }
 432         this.owner = o;
 433         o.sv_entnum = this.sv_entnum;
 434         o.gotscores = 1;
 435
 436         //if (!o.sort_prev)
 437         //      RegisterPlayer(o);
 438         //playerchecker will do this for us later, if it has not already done so
 439
 440     int sf, lf;
 441 #if MAX_SCORE <= 8
 442         sf = ReadByte();
 443         lf = ReadByte();
 444 #else
 445         sf = ReadShort();
 446         lf = ReadShort();
 447 #endif
 448     int p;
 449         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 450                 if(sf & p)
 451                 {
 452                         if(lf & p)
 453                                 o.(scores[i]) = ReadInt24_t();
 454                         else
 455                                 o.(scores[i]) = ReadChar();
 456                 }
 457
 458         return = true;
 459
 460         if(o.sort_prev)
 461                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 462
 463         this.entremove = Ent_RemovePlayerScore;
 464 }
 465
 466 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 467 {
 468         make_pure(this);
 469         int i;
 470         entity o;
 471
 472         this.team = ReadByte();
 473         o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 474
 475     int sf, lf;
 476 #if MAX_TEAMSCORE <= 8
 477         sf = ReadByte();
 478         lf = ReadByte();
 479 #else
 480         sf = ReadShort();
 481         lf = ReadShort();
 482 #endif
 483         int p;
 484         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 485                 if(sf & p)
 486                 {
 487                         if(lf & p)
 488                                 o.(teamscores[i]) = ReadInt24_t();
 489                         else
 490                                 o.(teamscores[i]) = ReadChar();
 491                 }
 492
 493         return = true;
 494
 495         HUD_UpdateTeamPos(o);
 496 }
 497
 498 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 499 {
 500         make_pure(this);
 501         float newspectatee_status;
 502
 503     int f = ReadByte();
 504
 505         scoreboard_showscores_force = (f & 1);
 506
 507         if(f & 2)
 508         {
 509                 newspectatee_status = ReadByte();
 510                 if(newspectatee_status == player_localnum + 1)
 511                         newspectatee_status = -1; // observing
 512         }
 513         else
 514                 newspectatee_status = 0;
 515
 516         spectatorbutton_zoom = (f & 4);
 517
 518         if(f & 8)
 519         {
 520                 angles_held_status = 1;
 521                 angles_held.x = ReadAngle();
 522                 angles_held.y = ReadAngle();
 523                 angles_held.z = 0;
 524         }
 525         else
 526                 angles_held_status = 0;
 527
 528         return = true;
 529
 530         if(newspectatee_status != spectatee_status)
 531         {
 532                 // clear race stuff
 533                 race_laptime = 0;
 534                 race_checkpointtime = 0;
 535         }
 536         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 537         {
 538                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 539                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 540                 )
 541                         prev_p_health = -1;
 542                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 543                         prev_health = -1;
 544         }
 545         spectatee_status = newspectatee_status;
 546
 547         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 548 }
 549
 550 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 551 {
 552         make_pure(this);
 553     int i, j, b, f;
 554
 555     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 556
 557         if(!(nags & BIT(2)))
 558         {
 559                 if(vote_called_vote)
 560                         strunzone(vote_called_vote);
 561                 vote_called_vote = string_null;
 562                 vote_active = 0;
 563         }
 564         else
 565         {
 566                 vote_active = 1;
 567         }
 568
 569         if(nags & BIT(6))
 570         {
 571                 vote_yescount = ReadByte();
 572                 vote_nocount = ReadByte();
 573                 vote_needed = ReadByte();
 574                 vote_highlighted = ReadChar();
 575         }
 576
 577         if(nags & BIT(7))
 578         {
 579                 if(vote_called_vote)
 580                         strunzone(vote_called_vote);
 581                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 582         }
 583
 584         if(nags & 1)
 585         {
 586                 for(j = 0; j < maxclients; ++j)
 587                         if(playerslots[j])
 588                                 playerslots[j].ready = 1;
 589                 for(i = 1; i <= maxclients; i += 8)
 590                 {
 591                         f = ReadByte();
 592                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 593                                 if (!(f & b))
 594                                         if(playerslots[j])
 595                                                 playerslots[j].ready = 0;
 596                 }
 597         }
 598
 599         return = true;
 600
 601         ready_waiting = (nags & BIT(0));
 602         ready_waiting_for_me = (nags & BIT(1));
 603         vote_waiting = (nags & BIT(2));
 604         vote_waiting_for_me = (nags & BIT(3));
 605         warmup_stage = (nags & BIT(4));
 606 }
 607
 608 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 609 {
 610         make_pure(this);
 611     int i, j, b, f;
 612
 613     int sf = ReadByte();
 614         if(sf & 1)
 615         {
 616                 for(j = 0; j < maxclients; ++j)
 617                         if(playerslots[j])
 618                                 playerslots[j].eliminated = 1;
 619                 for(i = 1; i <= maxclients; i += 8)
 620                 {
 621                         f = ReadByte();
 622                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 623                                 if (!(f & b))
 624                                         if(playerslots[j])
 625                                                 playerslots[j].eliminated = 0;
 626                 }
 627         }
 628         return true;
 629 }
 630
 631 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 632 {
 633         make_pure(this);
 634         prandom_debug();
 635         float s = ReadShort();
 636         psrandom(s);
 637         return true;
 638 }
 639
 640 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 641 {
 642         make_pure(this);
 643     int sf = ReadInt24_t();
 644         if (sf == 0) {
 645                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 646                         weapon_accuracy[w] = -1;
 647                 return true;
 648         }
 649
 650         int f = 1;
 651         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 652                 if (sf & f) {
 653             int b = ReadByte();
 654                         if (b == 0)
 655                                 weapon_accuracy[w] = -1;
 656                         else if (b == 255)
 657                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 658                         else
 659                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 660                 }
 661                 f = (f == 0x800000) ? 1 : f * 2;
 662         }
 663         return true;
 664 }
 665
 666 void Spawn_Draw(entity this)
 667 {
 668         __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 669 }
 670
 671 void Spawn_PreDraw(entity this)
 672 {
 673         float alph;
 674         vector org = getpropertyvec(VF_ORIGIN);
 675         if(this.fade_start)
 676                 alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 677         else
 678                 alph = 1;
 679         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 680         this.alpha = alph;
 681         if(alph <= 0)
 682                 this.drawmask = 0;
 683         else
 684                 this.drawmask = MASK_NORMAL;
 685 }
 686
 687 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 688 {
 689         float teamnum = (ReadByte() - 1);
 690         vector spn_origin;
 691         spn_origin.x = ReadCoord();
 692         spn_origin.y = ReadCoord();
 693         spn_origin.z = ReadCoord();
 694
 695         //if(is_new)
 696         //{
 697                 this.origin = spn_origin;
 698                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 699                 //droptofloor();
 700
 701                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 702                 {
 703                         this.mdl = "models/spawnpoint.md3";
 704                         this.colormod = Team_ColorRGB(teamnum);
 705                         precache_model(this.mdl);
 706                         setmodel(this, this.mdl);
 707                         this.drawmask = MASK_NORMAL;
 708                         //this.movetype = MOVETYPE_NOCLIP;
 709                         //this.draw = Spawn_Draw;
 710                 }*/
 711                 if(autocvar_cl_spawn_point_particles)
 712                 {
 713                         if((serverflags & SERVERFLAG_TEAMPLAY))
 714                         {
 715                                 switch(teamnum)
 716                                 {
 717                                         case NUM_TEAM_1: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 718                                         case NUM_TEAM_2: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 719                                         case NUM_TEAM_3: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 720                                         case NUM_TEAM_4: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 721                                         default: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 722                                 }
 723                         }
 724                         else { this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 725
 726                         this.draw = Spawn_Draw;
 727                         setpredraw(this, Spawn_PreDraw);
 728                         this.fade_start = autocvar_cl_spawn_point_dist_min;
 729                         this.fade_end = autocvar_cl_spawn_point_dist_max;
 730                 }
 731         //}
 732
 733         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 734         return true;
 735 }
 736
 737 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 738 {
 739         // If entnum is 0, ONLY do the local spawn actions
 740         // this way the server can disable the sending of
 741         // spawn origin or such to clients if wanted.
 742         float entnum = ReadByte();
 743
 744         if(entnum)
 745         {
 746                 this.origin_x = ReadCoord();
 747                 this.origin_y = ReadCoord();
 748                 this.origin_z = ReadCoord();
 749
 750                 if(is_new)
 751                 {
 752                         float teamnum = entcs_GetTeam(entnum - 1);
 753
 754                         if(autocvar_cl_spawn_event_particles)
 755                         {
 756                                 switch(teamnum)
 757                                 {
 758                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 759                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 760                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 761                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 762                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 763                                 }
 764                         }
 765                         if(autocvar_cl_spawn_event_sound)
 766                         {
 767                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 768                         }
 769                 }
 770         }
 771         return = true;
 772
 773         // local spawn actions
 774         if(is_new && (!entnum || (entnum == player_localentnum)))
 775         {
 776                 zoomin_effect = 1;
 777                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 778
 779                 if(autocvar_cl_unpress_zoom_on_spawn)
 780                 {
 781                         localcmd("-zoom\n");
 782                         button_zoom = false;
 783                 }
 784         }
 785         HUD_Radar_Hide_Maximized();
 786         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 787 }
 788
 789 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 790 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 791 void CSQC_Ent_Update(bool isnew)
 792 {
 793         SELFPARAM();
 794         this.sourceLoc = __FILE__ ":" STR(__LINE__);
 795         int t = ReadByte();
 796
 797         // set up the "time" global for received entities to be correct for interpolation purposes
 798         float savetime = time;
 799         if(servertime)
 800         {
 801                 time = servertime;
 802         }
 803         else
 804         {
 805                 serverprevtime = time;
 806                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 807                 time = serverprevtime + serverdeltatime;
 808         }
 809
 810 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 811         if (this.enttype)
 812         {
 813                 if (t != this.enttype || isnew)
 814                 {
 815                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", etof(this), this.entnum, this.enttype, t);
 816                         Ent_Remove(this);
 817                         clearentity(this);
 818                         isnew = true;
 819                 }
 820         }
 821         else
 822         {
 823                 if (!isnew)
 824                 {
 825                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", etof(this), this.entnum, t);
 826                         isnew = true;
 827                 }
 828         }
 829 #endif
 830         this.enttype = t;
 831         bool done = false;
 832         FOREACH(LinkedEntities, it.m_id == t, {
 833                 if (isnew) this.classname = it.netname;
 834                 if (autocvar_developer_csqcentities)
 835             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)\n", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 836                 done = it.m_read(this, NULL, isnew);
 837                 break;
 838         });
 839         time = savetime;
 840         if (!done)
 841         {
 842                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)\n", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 843         }
 844 }
 845
 846 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 847 // used when an entity changes its type. For an entity that someone interacts
 848 // with others, make sure it can no longer do so.
 849 void Ent_Remove(entity this)
 850 {
 851         if(this.entremove) this.entremove(this);
 852
 853         if(this.skeletonindex)
 854         {
 855                 skel_delete(this.skeletonindex);
 856                 this.skeletonindex = 0;
 857         }
 858
 859         if(this.snd_looping > 0)
 860         {
 861                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_g_jetpack_attenuation);
 862                 this.snd_looping = 0;
 863         }
 864
 865         this.enttype = 0;
 866         this.classname = "";
 867         this.draw = func_null;
 868         this.entremove = func_null;
 869         // TODO possibly set more stuff to defaults
 870 }
 871 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 872 void CSQC_Ent_Remove()
 873 {
 874         SELFPARAM();
 875         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}\n", this, this.entnum, this.enttype);
 876         if (wasfreed(this))
 877         {
 878                 LOG_WARNING("CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 879                 return;
 880         }
 881         if (this.enttype) Ent_Remove(this);
 882         remove(this);
 883 }
 884
 885 void Gamemode_Init()
 886 {
 887         if (!isdemo())
 888         {
 889                 if(!(calledhooks & HOOK_START))
 890                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 891                 calledhooks |= HOOK_START;
 892         }
 893 }
 894 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 895 void CSQC_Parse_StuffCmd(string strMessage)
 896 {
 897         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 898         localcmd(strMessage);
 899 }
 900 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 901 void CSQC_Parse_Print(string strMessage)
 902 {
 903         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")\n", strMessage);
 904         print(ColorTranslateRGB(strMessage));
 905 }
 906
 907 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 908 void CSQC_Parse_CenterPrint(string strMessage)
 909 {
 910         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 911         centerprint_hud(strMessage);
 912 }
 913
 914 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 915 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 916 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 917 bool CSQC_Parse_TempEntity()
 918 {
 919         // Acquire TE ID
 920         int nTEID = ReadByte();
 921
 922         FOREACH(TempEntities, it.m_id == nTEID, {
 923                 if (autocvar_developer_csqcentities)
 924                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)\n", it.netname, nTEID);
 925                 return it.m_read(NULL, NULL, true);
 926         });
 927
 928         if (autocvar_developer_csqcentities)
 929                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
 930
 931         // No special logic for this temporary entity; return 0 so the engine can handle it
 932         return false;
 933 }
 934
 935 string forcefog;
 936 void Fog_Force()
 937 {
 938         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 939                 localcmd("\nr_drawfog 0\n");
 940         else if (forcefog != "")
 941                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
 942 }
 943
 944 void Gamemode_Init();
 945 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
 946 {
 947         make_pure(this);
 948         gametype = ReadInt24_t();
 949         HUD_ModIcons_SetFunc();
 950         for (int i = 0; i < MAX_SCORE; ++i)
 951         {
 952                 if (scores_label[i]) strunzone(scores_label[i]);
 953                 scores_label[i] = strzone(ReadString());
 954                 scores_flags[i] = ReadByte();
 955         }
 956         for (int i = 0; i < MAX_TEAMSCORE; ++i)
 957         {
 958                 if (teamscores_label[i]) strunzone(teamscores_label[i]);
 959                 teamscores_label[i] = strzone(ReadString());
 960                 teamscores_flags[i] = ReadByte();
 961         }
 962         return = true;
 963         HUD_InitScores();
 964         Gamemode_Init();
 965 }
 966
 967 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
 968 {
 969         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 970
 971         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 972         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 973         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 974         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 975         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 976         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 977         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 978         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 979
 980         if (forcefog) strunzone(forcefog);
 981         forcefog = strzone(ReadString());
 982
 983         armorblockpercent = ReadByte() / 255.0;
 984
 985         serverflags = ReadByte();
 986
 987         g_trueaim_minrange = ReadCoord();
 988
 989         return = true;
 990
 991         MUTATOR_CALLHOOK(Ent_Init);
 992
 993         if (!postinit) PostInit();
 994 }
 995
 996 NET_HANDLE(TE_CSQC_RACE, bool isNew)
 997 {
 998         int b = ReadByte();
 999
1000         switch (b)
1001         {
1002                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1003                         race_checkpoint = ReadByte();
1004                         race_time = ReadInt24_t();
1005                         race_previousbesttime = ReadInt24_t();
1006                         if(race_previousbestname)
1007                                 strunzone(race_previousbestname);
1008                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1009
1010                         race_checkpointtime = time;
1011
1012                         if(race_checkpoint == 0 || race_checkpoint == 254)
1013                         {
1014                                 race_penaltyaccumulator = 0;
1015                                 race_laptime = time; // valid
1016                         }
1017
1018                         break;
1019
1020                 case RACE_NET_CHECKPOINT_CLEAR:
1021                         race_laptime = 0;
1022                         race_checkpointtime = 0;
1023                         break;
1024
1025                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1026                         race_laptime = ReadCoord();
1027                         race_checkpointtime = -99999;
1028                         // fall through
1029                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1030                         race_nextcheckpoint = ReadByte();
1031
1032                         race_nextbesttime = ReadInt24_t();
1033                         if(race_nextbestname)
1034                                 strunzone(race_nextbestname);
1035                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1036                         break;
1037
1038                 case RACE_NET_CHECKPOINT_HIT_RACE:
1039                         race_mycheckpoint = ReadByte();
1040                         race_mycheckpointtime = time;
1041                         race_mycheckpointdelta = ReadInt24_t();
1042                         race_mycheckpointlapsdelta = ReadByte();
1043                         if(race_mycheckpointlapsdelta >= 128)
1044                                 race_mycheckpointlapsdelta -= 256;
1045                         if(race_mycheckpointenemy)
1046                                 strunzone(race_mycheckpointenemy);
1047                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1048                         break;
1049
1050                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1051                         race_othercheckpoint = ReadByte();
1052                         race_othercheckpointtime = time;
1053                         race_othercheckpointdelta = ReadInt24_t();
1054                         race_othercheckpointlapsdelta = ReadByte();
1055                         if(race_othercheckpointlapsdelta >= 128)
1056                                 race_othercheckpointlapsdelta -= 256;
1057                         if(race_othercheckpointenemy)
1058                                 strunzone(race_othercheckpointenemy);
1059                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1060                         break;
1061
1062                 case RACE_NET_PENALTY_RACE:
1063                         race_penaltyeventtime = time;
1064                         race_penaltytime = ReadShort();
1065                         //race_penaltyaccumulator += race_penaltytime;
1066                         if(race_penaltyreason)
1067                                 strunzone(race_penaltyreason);
1068                         race_penaltyreason = strzone(ReadString());
1069                         break;
1070
1071                 case RACE_NET_PENALTY_QUALIFYING:
1072                         race_penaltyeventtime = time;
1073                         race_penaltytime = ReadShort();
1074                         race_penaltyaccumulator += race_penaltytime;
1075                         if(race_penaltyreason)
1076                                 strunzone(race_penaltyreason);
1077                         race_penaltyreason = strzone(ReadString());
1078                         break;
1079
1080                 case RACE_NET_SERVER_RECORD:
1081                         race_server_record = ReadInt24_t();
1082                         break;
1083                 case RACE_NET_SPEED_AWARD:
1084                         race_speedaward = ReadInt24_t();
1085                         if(race_speedaward_holder)
1086                                 strunzone(race_speedaward_holder);
1087                         race_speedaward_holder = strzone(ReadString());
1088                         break;
1089                 case RACE_NET_SPEED_AWARD_BEST:
1090                         race_speedaward_alltimebest = ReadInt24_t();
1091                         if(race_speedaward_alltimebest_holder)
1092                                 strunzone(race_speedaward_alltimebest_holder);
1093                         race_speedaward_alltimebest_holder = strzone(ReadString());
1094                         break;
1095                 case RACE_NET_SERVER_RANKINGS:
1096                         float prevpos, del;
1097             int pos = ReadShort();
1098                         prevpos = ReadShort();
1099                         del = ReadShort();
1100
1101                         // move other rankings out of the way
1102             int i;
1103                         if (prevpos) {
1104                                 for (i=prevpos-1;i>pos-1;--i) {
1105                                         grecordtime[i] = grecordtime[i-1];
1106                                         if(grecordholder[i])
1107                                                 strunzone(grecordholder[i]);
1108                                         grecordholder[i] = strzone(grecordholder[i-1]);
1109                                 }
1110                         } else if (del) { // a record has been deleted by the admin
1111                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1112                                         if (i == RANKINGS_CNT-1) { // clear out last record
1113                                                 grecordtime[i] = 0;
1114                                                 if (grecordholder[i])
1115                                                         strunzone(grecordholder[i]);
1116                                                 grecordholder[i] = string_null;
1117                                         }
1118                                         else {
1119                                                 grecordtime[i] = grecordtime[i+1];
1120                                                 if (grecordholder[i])
1121                                                         strunzone(grecordholder[i]);
1122                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1123                                         }
1124                                 }
1125                         } else { // player has no ranked record yet
1126                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1127                                         grecordtime[i] = grecordtime[i-1];
1128                                         if(grecordholder[i])
1129                                                 strunzone(grecordholder[i]);
1130                                         grecordholder[i] = strzone(grecordholder[i-1]);
1131                                 }
1132                         }
1133
1134                         // store new ranking
1135                         if(grecordholder[pos-1] != "")
1136                                 strunzone(grecordholder[pos-1]);
1137                         grecordholder[pos-1] = strzone(ReadString());
1138                         grecordtime[pos-1] = ReadInt24_t();
1139                         if(grecordholder[pos-1] == entcs_GetName(player_localnum))
1140                                 race_myrank = pos;
1141                         break;
1142                 case RACE_NET_SERVER_STATUS:
1143                         race_status = ReadShort();
1144                         if(race_status_name)
1145                                 strunzone(race_status_name);
1146                         race_status_name = strzone(ReadString());
1147         }
1148         return true;
1149 }
1150
1151 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1152 {
1153         teamnagger = 1;
1154         return true;
1155 }
1156
1157 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1158 {
1159         int i = ReadByte();
1160         int pi = ReadShort();
1161         int pl = ReadByte();
1162         int ml = ReadByte();
1163         return = true;
1164         entity e = playerslots[i];
1165         if (!e) return;
1166         e.ping = pi;
1167         e.ping_packetloss = pl / 255.0;
1168         e.ping_movementloss = ml / 255.0;
1169 }
1170
1171 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1172 {
1173         complain_weapon = ReadByte();
1174         complain_weapon_type = ReadByte();
1175         return = true;
1176
1177         complain_weapon_time = time;
1178         weapontime = time; // ping the weapon panel
1179
1180         switch(complain_weapon_type)
1181         {
1182                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1183                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1184                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1185         }
1186 }
1187
1188 string getcommandkey(string text, string command)
1189 {
1190         string keys;
1191         float n, j, k, l = 0;
1192
1193         if (!autocvar_hud_showbinds)
1194                 return text;
1195
1196         keys = db_get(binddb, command);
1197         if (keys == "")
1198         {
1199                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1200                 for(j = 0; j < n; ++j)
1201                 {
1202                         k = stof(argv(j));
1203                         if(k != -1)
1204                         {
1205                                 if ("" == keys)
1206                                         keys = keynumtostring(k);
1207                                 else
1208                                         keys = strcat(keys, ", ", keynumtostring(k));
1209
1210                                 ++l;
1211                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1212                                         break;
1213                         }
1214
1215                 }
1216                 if (keys == "")
1217                         keys = "NO_KEY";
1218                 db_put(binddb, command, keys);
1219         }
1220
1221         if (keys == "NO_KEY") {
1222                 if (autocvar_hud_showbinds > 1)
1223                         return sprintf(_("%s (not bound)"), text);
1224                 else
1225                         return text;
1226         }
1227         else if (autocvar_hud_showbinds > 1)
1228                 return sprintf("%s (%s)", text, keys);
1229         else
1230                 return keys;
1231 }