qcsrc/client/hud_config.qc

   1 #define HUD_Write(s) fputs(fh, s)
   2 // q: quoted, n: not quoted
   3 #define HUD_Write_Cvar_n(cvar) HUD_Write(strcat("seta ", cvar, " ", cvar_string(cvar), "\n"))
   4 #define HUD_Write_Cvar_q(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
   5 #define HUD_Write_PanelCvar_n(cvar_suf) HUD_Write_Cvar_n(strcat("hud_panel_", panel_name, cvar_suf))
   6 #define HUD_Write_PanelCvar_q(cvar_suf) HUD_Write_Cvar_q(strcat("hud_panel_", panel_name, cvar_suf))
   7 // Save the config
   8 void HUD_Panel_ExportCfg(string cfgname)
   9 {
  10         float fh;
  11         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
  12         fh = fopen(filename, FILE_WRITE);
  13         if(fh >= 0)
  14         {
  15                 HUD_Write_Cvar_q("hud_skin");
  16                 HUD_Write_Cvar_q("hud_panel_bg");
  17                 HUD_Write_Cvar_q("hud_panel_bg_color");
  18                 HUD_Write_Cvar_q("hud_panel_bg_color_team");
  19                 HUD_Write_Cvar_q("hud_panel_bg_alpha");
  20                 HUD_Write_Cvar_q("hud_panel_bg_border");
  21                 HUD_Write_Cvar_q("hud_panel_bg_padding");
  22                 HUD_Write_Cvar_q("hud_panel_fg_alpha");
  23                 HUD_Write("\n");
  24
  25                 HUD_Write_Cvar_q("hud_dock");
  26                 HUD_Write_Cvar_q("hud_dock_color");
  27                 HUD_Write_Cvar_q("hud_dock_color_team");
  28                 HUD_Write_Cvar_q("hud_dock_alpha");
  29                 HUD_Write("\n");
  30
  31                 HUD_Write_Cvar_q("hud_progressbar_alpha");
  32                 HUD_Write_Cvar_q("hud_progressbar_strength_color");
  33                 HUD_Write_Cvar_q("hud_progressbar_shield_color");
  34                 HUD_Write_Cvar_q("hud_progressbar_health_color");
  35                 HUD_Write_Cvar_q("hud_progressbar_armor_color");
  36                 HUD_Write_Cvar_q("hud_progressbar_fuel_color");
  37                 HUD_Write_Cvar_q("hud_progressbar_nexball_color");
  38                 HUD_Write_Cvar_q("hud_progressbar_speed_color");
  39                 HUD_Write_Cvar_q("hud_progressbar_acceleration_color");
  40                 HUD_Write_Cvar_q("hud_progressbar_acceleration_neg_color");
  41                 HUD_Write("\n");
  42
  43                 HUD_Write_Cvar_q("_hud_panelorder");
  44                 HUD_Write("\n");
  45
  46                 HUD_Write_Cvar_q("hud_configure_grid");
  47                 HUD_Write_Cvar_q("hud_configure_grid_xsize");
  48                 HUD_Write_Cvar_q("hud_configure_grid_ysize");
  49                 HUD_Write("\n");
  50
  51                 // common cvars for all panels
  52                 float i;
  53                 for (i = 0; i < HUD_PANEL_NUM; ++i)
  54                 {
  55                         HUD_Panel_GetName(i);
  56
  57                         HUD_Write_PanelCvar_n("");
  58                         HUD_Write_PanelCvar_q("_pos");
  59                         HUD_Write_PanelCvar_q("_size");
  60                         HUD_Write_PanelCvar_q("_bg");
  61                         HUD_Write_PanelCvar_q("_bg_color");
  62                         HUD_Write_PanelCvar_q("_bg_color_team");
  63                         HUD_Write_PanelCvar_q("_bg_alpha");
  64                         HUD_Write_PanelCvar_q("_bg_border");
  65                         HUD_Write_PanelCvar_q("_bg_padding");
  66                         switch(i) {
  67                                 case HUD_PANEL_WEAPONS:
  68                                         HUD_Write_PanelCvar_q("_accuracy");
  69                                         HUD_Write_PanelCvar_q("_label");
  70                                         HUD_Write_PanelCvar_q("_complainbubble");
  71                                         HUD_Write_PanelCvar_q("_complainbubble_padding");
  72                                         HUD_Write_PanelCvar_q("_complainbubble_time");
  73                                         HUD_Write_PanelCvar_q("_complainbubble_fadetime");
  74                                         HUD_Write_PanelCvar_q("_complainbubble_color_outofammo");
  75                                         HUD_Write_PanelCvar_q("_complainbubble_color_donthave");
  76                                         HUD_Write_PanelCvar_q("_complainbubble_color_unavailable");
  77                                         HUD_Write_PanelCvar_q("_ammo");
  78                                         HUD_Write_PanelCvar_q("_ammo_color");
  79                                         HUD_Write_PanelCvar_q("_ammo_alpha");
  80                                         HUD_Write_PanelCvar_q("_aspect");
  81                                         HUD_Write_PanelCvar_q("_timeout");
  82                                         HUD_Write_PanelCvar_q("_timeout_effect");
  83                                         HUD_Write_PanelCvar_q("_timeout_fadebgmin");
  84                                         HUD_Write_PanelCvar_q("_timeout_fadefgmin");
  85                                         HUD_Write_PanelCvar_q("_timeout_speed_in");
  86                                         HUD_Write_PanelCvar_q("_timeout_speed_out");
  87                                         HUD_Write_PanelCvar_q("_onlyowned");
  88                                         break;
  89                                 case HUD_PANEL_AMMO:
  90                                         HUD_Write_PanelCvar_q("_onlycurrent");
  91                                         HUD_Write_PanelCvar_q("_iconalign");
  92                                         HUD_Write_PanelCvar_q("_progressbar");
  93                                         HUD_Write_PanelCvar_q("_progressbar_name");
  94                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
  95                                         HUD_Write_PanelCvar_q("_text");
  96                                         break;
  97                                 case HUD_PANEL_POWERUPS:
  98                                         HUD_Write_PanelCvar_q("_flip");
  99                                         HUD_Write_PanelCvar_q("_iconalign");
 100                                         HUD_Write_PanelCvar_q("_baralign");
 101                                         HUD_Write_PanelCvar_q("_progressbar");
 102                                         HUD_Write_PanelCvar_q("_progressbar_strength");
 103                                         HUD_Write_PanelCvar_q("_progressbar_shield");
 104                                         HUD_Write_PanelCvar_q("_text");
 105                                         break;
 106                                 case HUD_PANEL_HEALTHARMOR:
 107                                         HUD_Write_PanelCvar_q("_flip");
 108                                         HUD_Write_PanelCvar_q("_iconalign");
 109                                         HUD_Write_PanelCvar_q("_baralign");
 110                                         HUD_Write_PanelCvar_q("_progressbar");
 111                                         HUD_Write_PanelCvar_q("_progressbar_health");
 112                                         HUD_Write_PanelCvar_q("_progressbar_armor");
 113                                         HUD_Write_PanelCvar_q("_progressbar_gfx");
 114                                         HUD_Write_PanelCvar_q("_progressbar_gfx_smooth");
 115                                         HUD_Write_PanelCvar_q("_text");
 116                                         break;
 117                                 case HUD_PANEL_NOTIFY:
 118                                         HUD_Write_PanelCvar_q("_flip");
 119                                         HUD_Write_PanelCvar_q("_fontsize");
 120                                         HUD_Write_PanelCvar_q("_time");
 121                                         HUD_Write_PanelCvar_q("_fadetime");
 122                                         break;
 123                                 case HUD_PANEL_TIMER:
 124                                         HUD_Write_PanelCvar_q("_increment");
 125                                         break;
 126                                 case HUD_PANEL_RADAR:
 127                                         HUD_Write_PanelCvar_q("_foreground_alpha");
 128                                         HUD_Write_PanelCvar_q("_rotation");
 129                                         HUD_Write_PanelCvar_q("_zoommode");
 130                                         HUD_Write_PanelCvar_q("_scale");
 131                                         HUD_Write_PanelCvar_q("_maximized_scale");
 132                                         HUD_Write_PanelCvar_q("_maximized_size");
 133                                         HUD_Write_PanelCvar_q("_maximized_rotation");
 134                                         HUD_Write_PanelCvar_q("_maximized_zoommode");
 135                                         break;
 136                                 case HUD_PANEL_SCORE:
 137                                         HUD_Write_PanelCvar_q("_rankings");
 138                                         break;
 139                                 case HUD_PANEL_VOTE:
 140                                         HUD_Write_PanelCvar_q("_alreadyvoted_alpha");
 141                                         break;
 142                                 case HUD_PANEL_MODICONS:
 143                                         HUD_Write_PanelCvar_q("_ca_layout");
 144                                         HUD_Write_PanelCvar_q("_dom_layout");
 145                                         HUD_Write_PanelCvar_q("_freezetag_layout");
 146                                         break;
 147                                 case HUD_PANEL_PRESSEDKEYS:
 148                                         HUD_Write_PanelCvar_q("_aspect");
 149                                         HUD_Write_PanelCvar_q("_attack");
 150                                         break;
 151                                 case HUD_PANEL_ENGINEINFO:
 152                                         HUD_Write_PanelCvar_q("_framecounter_time");
 153                                         HUD_Write_PanelCvar_q("_framecounter_decimals");
 154                                         break;
 155                                 case HUD_PANEL_INFOMESSAGES:
 156                                         HUD_Write_PanelCvar_q("_flip");
 157                                         break;
 158                                 case HUD_PANEL_PHYSICS:
 159                                         HUD_Write_PanelCvar_q("_speed_unit");
 160                                         HUD_Write_PanelCvar_q("_speed_unit_show");
 161                                         HUD_Write_PanelCvar_q("_speed_max");
 162                                         HUD_Write_PanelCvar_q("_speed_vertical");
 163                                         HUD_Write_PanelCvar_q("_topspeed");
 164                                         HUD_Write_PanelCvar_q("_topspeed_time");
 165                                         HUD_Write_PanelCvar_q("_acceleration_max");
 166                                         HUD_Write_PanelCvar_q("_acceleration_vertical");
 167                                         HUD_Write_PanelCvar_q("_flip");
 168                                         HUD_Write_PanelCvar_q("_baralign");
 169                                         HUD_Write_PanelCvar_q("_progressbar");
 170                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_mode");
 171                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_scale");
 172                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_nonlinear");
 173                                         HUD_Write_PanelCvar_q("_text");
 174                                         HUD_Write_PanelCvar_q("_text_scale");
 175                                         break;
 176                                 case HUD_PANEL_CENTERPRINT:
 177                                         HUD_Write_PanelCvar_q("_align");
 178                                         HUD_Write_PanelCvar_q("_flip");
 179                                         HUD_Write_PanelCvar_q("_fontscale");
 180                                         HUD_Write_PanelCvar_q("_time");
 181                                         HUD_Write_PanelCvar_q("_fade_in");
 182                                         HUD_Write_PanelCvar_q("_fade_out");
 183                                         HUD_Write_PanelCvar_q("_fade_subsequent");
 184                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone");
 185                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone_minalpha");
 186                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo");
 187                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo_minalpha");
 188                                         HUD_Write_PanelCvar_q("_fade_subsequent_minfontsize");
 189                                         HUD_Write_PanelCvar_q("_fade_minfontsize");
 190                                         break;
 191                         }
 192                         HUD_Write("\n");
 193                 }
 194                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
 195
 196                 print(sprintf(_("^2Successfully exported to %s! (Note: It's saved in data/data/)\n"), filename));
 197                 fclose(fh);
 198         }
 199         else
 200                 print(sprintf(_("^1Couldn't write to %s\n"), filename));
 201 }
 202
 203 void HUD_Configure_Exit_Force()
 204 {
 205         if (menu_enabled)
 206         {
 207                 menu_enabled = 0;
 208                 localcmd("togglemenu\n");
 209         }
 210         cvar_set("_hud_configure", "0");
 211 }
 212
 213 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 214 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
 215 {
 216         float i;
 217         float myCenter_x, myCenter_y, targCenter_x, targCenter_y;
 218         vector myTarget;
 219         myTarget = myPos;
 220
 221         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 222                 if(i == highlightedPanel || !panel_enabled)
 223                         continue;
 224
 225                 HUD_Panel_UpdatePosSizeForId(i);
 226
 227                 panel_pos -= '1 1 0' * panel_bg_border;
 228                 panel_size += '2 2 0' * panel_bg_border;
 229
 230                 if(myPos_y + mySize_y < panel_pos_y)
 231                         continue;
 232                 if(myPos_y > panel_pos_y + panel_size_y)
 233                         continue;
 234
 235                 if(myPos_x + mySize_x < panel_pos_x)
 236                         continue;
 237                 if(myPos_x > panel_pos_x + panel_size_x)
 238                         continue;
 239
 240                 // OK, there IS a collision.
 241
 242                 myCenter_x = myPos_x + 0.5 * mySize_x;
 243                 myCenter_y = myPos_y + 0.5 * mySize_y;
 244
 245                 targCenter_x = panel_pos_x + 0.5 * panel_size_x;
 246                 targCenter_y = panel_pos_y + 0.5 * panel_size_y;
 247
 248                 if(myCenter_x < targCenter_x && myCenter_y < targCenter_y) // top left (of the target panel)
 249                 {
 250                         if(myPos_x + mySize_x - panel_pos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 251                                 myTarget_x = panel_pos_x - mySize_x;
 252                         else // push it upwards
 253                                 myTarget_y = panel_pos_y - mySize_y;
 254                 }
 255                 else if(myCenter_x > targCenter_x && myCenter_y < targCenter_y) // top right
 256                 {
 257                         if(panel_pos_x + panel_size_x - myPos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 258                                 myTarget_x = panel_pos_x + panel_size_x;
 259                         else // push it upwards
 260                                 myTarget_y = panel_pos_y - mySize_y;
 261                 }
 262                 else if(myCenter_x < targCenter_x && myCenter_y > targCenter_y) // bottom left
 263                 {
 264                         if(myPos_x + mySize_x - panel_pos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 265                                 myTarget_x = panel_pos_x - mySize_x;
 266                         else // push it downwards
 267                                 myTarget_y = panel_pos_y + panel_size_y;
 268                 }
 269                 else if(myCenter_x > targCenter_x && myCenter_y > targCenter_y) // bottom right
 270                 {
 271                         if(panel_pos_x + panel_size_x - myPos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 272                                 myTarget_x = panel_pos_x + panel_size_x;
 273                         else // push it downwards
 274                                 myTarget_y = panel_pos_y + panel_size_y;
 275                 }
 276                 //if(cvar("hud_configure_checkcollisions_debug"))
 277                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 278         }
 279
 280         return myTarget;
 281 }
 282
 283 void HUD_Panel_SetPos(vector pos)
 284 {
 285         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 286         vector mySize;
 287         mySize = panel_size;
 288
 289         //if(cvar("hud_configure_checkcollisions_debug"))
 290                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 291
 292         if(autocvar_hud_configure_grid)
 293         {
 294                 pos_x = floor((pos_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 295                 pos_y = floor((pos_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 296         }
 297
 298         if(hud_configure_checkcollisions)
 299                 pos = HUD_Panel_CheckMove(pos, mySize);
 300
 301         pos_x = bound(0, pos_x, vid_conwidth - mySize_x);
 302         pos_y = bound(0, pos_y, vid_conheight - mySize_y);
 303
 304         string s;
 305         s = strcat(ftos(pos_x/vid_conwidth), " ", ftos(pos_y/vid_conheight));
 306
 307         HUD_Panel_GetName(highlightedPanel);
 308         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 309 }
 310
 311 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 312 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
 313         float i;
 314
 315         vector targEndPos;
 316
 317         float dist_x, dist_y;
 318         float ratio;
 319         ratio = mySize_x/mySize_y;
 320
 321         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 322                 if(i == highlightedPanel || !panel_enabled)
 323                         continue;
 324
 325                 HUD_Panel_UpdatePosSizeForId(i);
 326
 327                 panel_pos -= '1 1 0' * panel_bg_border;
 328                 panel_size += '2 2 0' * panel_bg_border;
 329
 330                 targEndPos = panel_pos + panel_size;
 331
 332                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
 333                 if(resizeorigin_x > panel_pos_x && resizeorigin_x < targEndPos_x && resizeorigin_y > panel_pos_y && resizeorigin_y < targEndPos_y)
 334                         continue;
 335
 336                 if (resizeCorner == 1)
 337                 {
 338                         // check if this panel is on our way
 339                         if (resizeorigin_x <= panel_pos_x)
 340                                 continue;
 341                         if (resizeorigin_y <= panel_pos_y)
 342                                 continue;
 343                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 344                                 continue;
 345                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 346                                 continue;
 347
 348                         // there is a collision:
 349                         // detect which side of the panel we are facing is actually limiting the resizing
 350                         // (which side the resize direction finds for first) and reduce the size up to there
 351                         //
 352                         // dist is the distance between resizeorigin and the "analogous" point of the panel
 353                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
 354                         dist_x = resizeorigin_x - targEndPos_x;
 355                         dist_y = resizeorigin_y - targEndPos_y;
 356                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 357                                 mySize_x = min(mySize_x, dist_x);
 358                         else
 359                                 mySize_y = min(mySize_y, dist_y);
 360                 }
 361                 else if (resizeCorner == 2)
 362                 {
 363                         if (resizeorigin_x >= targEndPos_x)
 364                                 continue;
 365                         if (resizeorigin_y <= panel_pos_y)
 366                                 continue;
 367                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 368                                 continue;
 369                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 370                                 continue;
 371
 372                         dist_x = panel_pos_x - resizeorigin_x;
 373                         dist_y = resizeorigin_y - targEndPos_y;
 374                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 375                                 mySize_x = min(mySize_x, dist_x);
 376                         else
 377                                 mySize_y = min(mySize_y, dist_y);
 378                 }
 379                 else if (resizeCorner == 3)
 380                 {
 381                         if (resizeorigin_x <= panel_pos_x)
 382                                 continue;
 383                         if (resizeorigin_y >= targEndPos_y)
 384                                 continue;
 385                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 386                                 continue;
 387                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 388                                 continue;
 389
 390                         dist_x = resizeorigin_x - targEndPos_x;
 391                         dist_y = panel_pos_y - resizeorigin_y;
 392                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 393                                 mySize_x = min(mySize_x, dist_x);
 394                         else
 395                                 mySize_y = min(mySize_y, dist_y);
 396                 }
 397                 else if (resizeCorner == 4)
 398                 {
 399                         if (resizeorigin_x >= targEndPos_x)
 400                                 continue;
 401                         if (resizeorigin_y >= targEndPos_y)
 402                                 continue;
 403                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 404                                 continue;
 405                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 406                                 continue;
 407
 408                         dist_x = panel_pos_x - resizeorigin_x;
 409                         dist_y = panel_pos_y - resizeorigin_y;
 410                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 411                                 mySize_x = min(mySize_x, dist_x);
 412                         else
 413                                 mySize_y = min(mySize_y, dist_y);
 414                 }
 415                 //if(cvar("hud_configure_checkcollisions_debug"))
 416                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 417         }
 418
 419         return mySize;
 420 }
 421
 422 void HUD_Panel_SetPosSize(vector mySize)
 423 {
 424         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 425         vector resizeorigin;
 426         resizeorigin = panel_click_resizeorigin;
 427         local noref vector myPos; // fteqcc sucks
 428
 429         // minimum panel size cap
 430         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 431         mySize_y = max(0.025 * vid_conheight, mySize_y);
 432
 433         if(highlightedPanel == HUD_PANEL_CHAT) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
 434         {
 435                 mySize_x = max(17 * autocvar_con_chatsize, mySize_x);
 436                 mySize_y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize_y);
 437         }
 438
 439         // collision testing|
 440         // -----------------+
 441
 442         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
 443         if(resizeCorner == 1) {
 444                 myPos_x = resizeorigin_x - mySize_x;
 445                 myPos_y = resizeorigin_y - mySize_y;
 446         } else if(resizeCorner == 2) {
 447                 myPos_x = resizeorigin_x;
 448                 myPos_y = resizeorigin_y - mySize_y;
 449         } else if(resizeCorner == 3) {
 450                 myPos_x = resizeorigin_x - mySize_x;
 451                 myPos_y = resizeorigin_y;
 452         } else { // resizeCorner == 4
 453                 myPos_x = resizeorigin_x;
 454                 myPos_y = resizeorigin_y;
 455         }
 456
 457         // left/top screen edges
 458         if(myPos_x < 0)
 459                 mySize_x = mySize_x + myPos_x;
 460         if(myPos_y < 0)
 461                 mySize_y = mySize_y + myPos_y;
 462
 463         // bottom/right screen edges
 464         if(myPos_x + mySize_x > vid_conwidth)
 465                 mySize_x = vid_conwidth - myPos_x;
 466         if(myPos_y + mySize_y > vid_conheight)
 467                 mySize_y = vid_conheight - myPos_y;
 468
 469         //if(cvar("hud_configure_checkcollisions_debug"))
 470                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 471
 472         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
 473         if(autocvar_hud_configure_grid)
 474         {
 475                 mySize_x = floor((mySize_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 476                 mySize_y = floor((mySize_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 477         }
 478
 479         if(hud_configure_checkcollisions)
 480                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
 481
 482         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
 483         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 484         mySize_y = max(0.025 * vid_conheight, mySize_y);
 485
 486         // do another pos check, as size might have changed by now
 487         if(resizeCorner == 1) {
 488                 myPos_x = resizeorigin_x - mySize_x;
 489                 myPos_y = resizeorigin_y - mySize_y;
 490         } else if(resizeCorner == 2) {
 491                 myPos_x = resizeorigin_x;
 492                 myPos_y = resizeorigin_y - mySize_y;
 493         } else if(resizeCorner == 3) {
 494                 myPos_x = resizeorigin_x - mySize_x;
 495                 myPos_y = resizeorigin_y;
 496         } else { // resizeCorner == 4
 497                 myPos_x = resizeorigin_x;
 498                 myPos_y = resizeorigin_y;
 499         }
 500
 501         //if(cvar("hud_configure_checkcollisions_debug"))
 502                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
 503
 504         HUD_Panel_GetName(highlightedPanel);
 505         string s;
 506         s = strcat(ftos(mySize_x/vid_conwidth), " ", ftos(mySize_y/vid_conheight));
 507         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 508
 509         s = strcat(ftos(myPos_x/vid_conwidth), " ", ftos(myPos_y/vid_conheight));
 510         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 511 }
 512
 513 float pressed_key_time;
 514 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
 515 void HUD_Panel_Arrow_Action(float nPrimary)
 516 {
 517         if (highlightedPanel == -1)
 518                 return;
 519
 520         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
 521
 522         float step;
 523         if(autocvar_hud_configure_grid)
 524         {
 525                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 526                 {
 527                         if (hudShiftState & S_SHIFT)
 528                                 step = hud_configure_realGridSize_y;
 529                         else
 530                                 step = 2 * hud_configure_realGridSize_y;
 531                 }
 532                 else
 533                 {
 534                         if (hudShiftState & S_SHIFT)
 535                                 step = hud_configure_realGridSize_x;
 536                         else
 537                                 step = 2 * hud_configure_realGridSize_x;
 538                 }
 539         }
 540         else
 541         {
 542                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 543                         step = vid_conheight;
 544                 else
 545                         step = vid_conwidth;
 546                 if (hudShiftState & S_SHIFT)
 547                         step = (step / 256); // more precision
 548                 else
 549                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
 550         }
 551
 552         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 553
 554         highlightedPanel_initial_pos = panel_pos;
 555         highlightedPanel_initial_size = panel_size;
 556
 557         if (hudShiftState & S_ALT) // resize
 558         {
 559                 highlightedAction = 1;
 560                 if(nPrimary == K_UPARROW)
 561                         resizeCorner = 1;
 562                 else if(nPrimary == K_RIGHTARROW)
 563                         resizeCorner = 2;
 564                 else if(nPrimary == K_LEFTARROW)
 565                         resizeCorner = 3;
 566                 else // if(nPrimary == K_DOWNARROW)
 567                         resizeCorner = 4;
 568
 569                 // ctrl+arrow reduces the size, instead of increasing it
 570                 // Note that ctrl disables collisions check too, but it's fine
 571                 // since we don't collide with anything reducing the size
 572                 if (hudShiftState & S_CTRL) {
 573                         step = -step;
 574                         resizeCorner = 5 - resizeCorner;
 575                 }
 576
 577                 vector mySize;
 578                 mySize = panel_size;
 579                 panel_click_resizeorigin = panel_pos;
 580                 if(resizeCorner == 1) {
 581                         panel_click_resizeorigin += mySize;
 582                         mySize_y += step;
 583                 } else if(resizeCorner == 2) {
 584                         panel_click_resizeorigin_y += mySize_y;
 585                         mySize_x += step;
 586                 } else if(resizeCorner == 3) {
 587                         panel_click_resizeorigin_x += mySize_x;
 588                         mySize_x += step;
 589                 } else { // resizeCorner == 4
 590                         mySize_y += step;
 591                 }
 592                 HUD_Panel_SetPosSize(mySize);
 593         }
 594         else // move
 595         {
 596                 highlightedAction = 2;
 597                 vector pos;
 598                 pos = panel_pos;
 599                 if(nPrimary == K_UPARROW)
 600                         pos_y -= step;
 601                 else if(nPrimary == K_DOWNARROW)
 602                         pos_y += step;
 603                 else if(nPrimary == K_LEFTARROW)
 604                         pos_x -= step;
 605                 else // if(nPrimary == K_RIGHTARROW)
 606                         pos_x += step;
 607
 608                 HUD_Panel_SetPos(pos);
 609         }
 610
 611         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 612
 613         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
 614         {
 615                 // backup!
 616                 panel_pos_backup = highlightedPanel_initial_pos;
 617                 panel_size_backup = highlightedPanel_initial_size;
 618                 highlightedPanel_backup = highlightedPanel;
 619         }
 620 }
 621
 622 const float S_MOUSE1 = 1;
 623 const float S_MOUSE2 = 2;
 624 const float S_MOUSE3 = 4;
 625 float mouseClicked;
 626 float prevMouseClicked; // previous state
 627 float prevMouseClickedTime; // time during previous left mouse click, to check for doubleclicks
 628 vector prevMouseClickedPos; // pos during previous left mouse click, to check for doubleclicks
 629
 630 void HUD_Panel_EnableMenu();
 631 float tab_panels[HUD_PANEL_NUM];
 632 float tab_panel, tab_backward;
 633 vector tab_panel_pos;
 634 void HUD_Panel_FirstInDrawQ(float id);
 635 void reset_tab_panels()
 636 {
 637         int i;
 638         for(i = 0; i < HUD_PANEL_NUM; ++i)
 639                 tab_panels[i] = -1;
 640 }
 641 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
 642 {
 643         string s;
 644
 645         if(bInputType == 2)
 646                 return false;
 647
 648         if(!autocvar__hud_configure)
 649                 return false;
 650
 651         // block any input while a menu dialog is fading
 652         if(autocvar__menu_alpha)
 653                 return true;
 654
 655         if(bInputType == 3)
 656         {
 657                 mousepos_x = nPrimary;
 658                 mousepos_y = nSecondary;
 659                 return true;
 660         }
 661
 662         // allow console bind to work
 663         string con_keys;
 664         float keys;
 665         con_keys = findkeysforcommand("toggleconsole", 0);
 666         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 667
 668         float hit_con_bind = 0, i;
 669         for (i = 0; i < keys; ++i)
 670         {
 671                 if(nPrimary == stof(argv(i)))
 672                         hit_con_bind = 1;
 673         }
 674
 675         if(bInputType == 0) {
 676                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 677                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 678                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 679         }
 680         else if(bInputType == 1) {
 681                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 682                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 683                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 684         }
 685
 686         if(nPrimary == K_CTRL)
 687         {
 688                 if (bInputType == 1) //ctrl has been released
 689                 {
 690                         if (tab_panel != -1)
 691                         {
 692                                 //switch to selected panel
 693                                 highlightedPanel = tab_panel;
 694                                 highlightedAction = 0;
 695                                 HUD_Panel_FirstInDrawQ(highlightedPanel);
 696                         }
 697                         tab_panel = -1;
 698                         reset_tab_panels();
 699                 }
 700         }
 701
 702         if(nPrimary == K_MOUSE1)
 703         {
 704                 if(bInputType == 0) // key pressed
 705                         mouseClicked |= S_MOUSE1;
 706                 else if(bInputType == 1) // key released
 707                         mouseClicked -= (mouseClicked & S_MOUSE1);
 708         }
 709         else if(nPrimary == K_MOUSE2)
 710         {
 711                 if(bInputType == 0) // key pressed
 712                         mouseClicked |= S_MOUSE2;
 713                 else if(bInputType == 1) // key released
 714                         mouseClicked -= (mouseClicked & S_MOUSE2);
 715         }
 716         else if(nPrimary == K_ESCAPE)
 717         {
 718                 if (bInputType == 1)
 719                         return true;
 720                 menu_enabled = 1;
 721                 menu_enabled_time = time;
 722                 localcmd("menu_showhudexit\n");
 723         }
 724         else if(nPrimary == K_BACKSPACE && hudShiftState & S_CTRL)
 725         {
 726                 if (bInputType == 1)
 727                         return true;
 728                 if (!menu_enabled)
 729                         cvar_set("_hud_configure", "0");
 730         }
 731         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // select and highlight another panel
 732         {
 733                 if (bInputType == 1 || mouseClicked)
 734                         return true;
 735
 736                 //FIXME: if a panel is highlighted, has the same pos_x and lays in the same level
 737                 //of other panels then next consecutive ctrl-tab will select the highlighted panel too
 738                 //(it should only after every other panel of the hud)
 739                 //It's a minor bug anyway, we can live with it
 740
 741                 float starting_panel;
 742                 float old_tab_panel = tab_panel;
 743                 if (tab_panel == -1) //first press of TAB
 744                 {
 745                         if (highlightedPanel != -1)
 746                                 HUD_Panel_UpdatePosSizeForId(highlightedPanel)
 747                         else
 748                                 panel_pos = '0 0 0';
 749                         starting_panel = highlightedPanel; //can be -1, it means no starting panel
 750                         tab_panel_pos = panel_pos; //to compute level
 751                 }
 752                 else
 753                 {
 754                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
 755                                 reset_tab_panels();
 756                         starting_panel = tab_panel;
 757                 }
 758                 tab_backward = (hudShiftState & S_SHIFT);
 759
 760                 float k, level = 0, start_pos_x;
 761                 vector candidate_pos = '0 0 0';
 762                 const float LEVELS_NUM = 4;
 763                 float level_height = vid_conheight / LEVELS_NUM;
 764 :find_tab_panel
 765                 level = floor(tab_panel_pos_y / level_height) * level_height; //starting level
 766                 candidate_pos_x = (!tab_backward) ? vid_conwidth : 0;
 767                 start_pos_x = tab_panel_pos_x;
 768                 tab_panel = -1;
 769                 k=0;
 770                 while(++k)
 771                 {
 772                         for(i = 0; i < HUD_PANEL_NUM; ++i)
 773                         {
 774                                 if (i == tab_panels[i] || i == starting_panel)
 775                                         continue;
 776                                 HUD_Panel_UpdatePosSizeForId(i)
 777                                 if (panel_pos_y >= level && (panel_pos_y - level) < level_height)
 778                                 if (  ( !tab_backward && panel_pos_x >= start_pos_x && (panel_pos_x < candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y <= candidate_pos_y)) )
 779                                         || ( tab_backward && panel_pos_x <= start_pos_x && (panel_pos_x > candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y >= candidate_pos_y)) )  )
 780                                 {
 781                                         tab_panel = i;
 782                                         tab_panel_pos = candidate_pos = panel_pos;
 783                                 }
 784                         }
 785                         if (tab_panel != -1)
 786                                 break;
 787                         if (k == LEVELS_NUM) //tab_panel not found
 788                         {
 789                                 reset_tab_panels();
 790                                 if (old_tab_panel == -2) //this prevents an infinite loop (should not happen normally)
 791                                 {
 792                                         tab_panel = -1;
 793                                         return true;
 794                                 }
 795                                 starting_panel = old_tab_panel;
 796                                 old_tab_panel = -2;
 797                                 goto find_tab_panel; //u must find tab_panel!
 798                         }
 799                         if (!tab_backward)
 800                         {
 801                                 level = mod(level + level_height, vid_conheight);
 802                                 start_pos_x = 0;
 803                                 candidate_pos_x = vid_conwidth;
 804                         }
 805                         else
 806                         {
 807                                 level = mod(level - level_height, vid_conheight);
 808                                 start_pos_x = vid_conwidth;
 809                                 candidate_pos_x = 0;
 810                         }
 811                 }
 812
 813                 tab_panels[tab_panel] = tab_panel;
 814         }
 815         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
 816         {
 817                 if (bInputType == 1 || mouseClicked)
 818                         return true;
 819
 820                 if (highlightedPanel != -1)
 821                 {
 822                         HUD_Panel_GetName(highlightedPanel);
 823                         cvar_set(strcat("hud_panel_", panel_name), ftos(!(panel_enabled)));
 824                 }
 825                 else
 826                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
 827         }
 828         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
 829         {
 830                 if (bInputType == 1 || mouseClicked)
 831                         return true;
 832
 833                 if (highlightedPanel != -1)
 834                 {
 835                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 836                         panel_size_copied = panel_size;
 837                         highlightedPanel_copied = highlightedPanel;
 838                 }
 839         }
 840         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
 841         {
 842                 if (bInputType == 1 || mouseClicked)
 843                         return true;
 844
 845                 if (highlightedPanel_copied == -1 || highlightedPanel == -1)
 846                         return true;
 847
 848                 HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 849
 850                 // reduce size if it'd go beyond screen boundaries
 851                 vector tmp_size = panel_size_copied;
 852                 if (panel_pos_x + panel_size_copied_x > vid_conwidth)
 853                         tmp_size_x = vid_conwidth - panel_pos_x;
 854                 if (panel_pos_y + panel_size_copied_y > vid_conheight)
 855                         tmp_size_y = vid_conheight - panel_pos_y;
 856
 857                 if (panel_size == tmp_size)
 858                         return true;
 859
 860                 // backup first!
 861                 panel_pos_backup = panel_pos;
 862                 panel_size_backup = panel_size;
 863                 highlightedPanel_backup = highlightedPanel;
 864
 865                 s = strcat(ftos(tmp_size_x/vid_conwidth), " ", ftos(tmp_size_y/vid_conheight));
 866                 HUD_Panel_GetName(highlightedPanel);
 867                 cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 868         }
 869         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
 870         {
 871                 if (bInputType == 1 || mouseClicked)
 872                         return true;
 873                 //restore previous values
 874                 if (highlightedPanel_backup != -1)
 875                 {
 876                         HUD_Panel_GetName(highlightedPanel_backup);
 877                         s = strcat(ftos(panel_pos_backup_x/vid_conwidth), " ", ftos(panel_pos_backup_y/vid_conheight));
 878                         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 879                         s = strcat(ftos(panel_size_backup_x/vid_conwidth), " ", ftos(panel_size_backup_y/vid_conheight));
 880                         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 881                         highlightedPanel_backup = -1;
 882                 }
 883         }
 884         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
 885         {
 886                 if (bInputType == 1)
 887                 {
 888                         pressed_key_time = 0;
 889                         return true;
 890                 }
 891                 else if (pressed_key_time == 0)
 892                         pressed_key_time = time;
 893
 894                 if (!mouseClicked)
 895                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
 896         }
 897         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
 898         {
 899                 if (bInputType == 1)
 900                         return true;
 901                 if (highlightedPanel != -1)
 902                         HUD_Panel_EnableMenu();
 903         }
 904         else if(hit_con_bind)
 905                 return false;
 906
 907         return true;
 908 }
 909
 910 float HUD_Panel_Check_Mouse_Pos(float allow_move)
 911 {
 912         float i, j = 0, border;
 913
 914         while(j < HUD_PANEL_NUM)
 915         {
 916                 i = panel_order[j];
 917                 j += 1;
 918
 919                 HUD_Panel_UpdatePosSizeForId(i);
 920
 921                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 922
 923                 // move
 924                 if(allow_move && mousepos_x > panel_pos_x && mousepos_y > panel_pos_y && mousepos_x < panel_pos_x + panel_size_x && mousepos_y < panel_pos_y + panel_size_y)
 925                 {
 926                         return 1;
 927                 }
 928                 // resize from topleft border
 929                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 930                 {
 931                         return 2;
 932                 }
 933                 // resize from topright border
 934                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 935                 {
 936                         return 3;
 937                 }
 938                 // resize from bottomleft border
 939                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
 940                 {
 941                         return 3;
 942                 }
 943                 // resize from bottomright border
 944                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
 945                 {
 946                         return 2;
 947                 }
 948         }
 949         return 0;
 950 }
 951
 952 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
 953 void HUD_Panel_FirstInDrawQ(float id)
 954 {
 955         float i;
 956         var float place = -1;
 957         // find out where in the array our current id is, save into place
 958         for(i = 0; i < HUD_PANEL_NUM; ++i)
 959         {
 960                 if(panel_order[i] == id)
 961                 {
 962                         place = i;
 963                         break;
 964                 }
 965         }
 966         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
 967         if(place == -1)
 968                 place = HUD_PANEL_NUM - 1;
 969
 970         // move all ids up by one step in the array until "place"
 971         for(i = place; i > 0; --i)
 972         {
 973                 panel_order[i] = panel_order[i-1];
 974         }
 975         // now save the new top id
 976         panel_order[0] = id;
 977
 978         // let's save them into the cvar by some strcat trickery
 979         string s = "";
 980         for(i = 0; i < HUD_PANEL_NUM; ++i)
 981         {
 982                 s = strcat(s, ftos(panel_order[i]), " ");
 983         }
 984         cvar_set("_hud_panelorder", s);
 985         if(hud_panelorder_prev)
 986                 strunzone(hud_panelorder_prev);
 987         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
 988 }
 989
 990 void HUD_Panel_Highlight(float allow_move)
 991 {
 992         float i, j = 0, border;
 993
 994         while(j < HUD_PANEL_NUM)
 995         {
 996                 i = panel_order[j];
 997                 j += 1;
 998
 999                 HUD_Panel_UpdatePosSizeForId(i);
1000
1001                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
1002
1003                 // move
1004                 if(allow_move && mousepos_x > panel_pos_x && mousepos_y > panel_pos_y && mousepos_x < panel_pos_x + panel_size_x && mousepos_y < panel_pos_y + panel_size_y)
1005                 {
1006                         highlightedPanel = i;
1007                         HUD_Panel_FirstInDrawQ(i);
1008                         highlightedAction = 1;
1009                         panel_click_distance = mousepos - panel_pos;
1010                         return;
1011                 }
1012                 // resize from topleft border
1013                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1014                 {
1015                         highlightedPanel = i;
1016                         HUD_Panel_FirstInDrawQ(i);
1017                         highlightedAction = 2;
1018                         resizeCorner = 1;
1019                         panel_click_distance = mousepos - panel_pos;
1020                         panel_click_resizeorigin = panel_pos + panel_size;
1021                         return;
1022                 }
1023                 // resize from topright border
1024                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1025                 {
1026                         highlightedPanel = i;
1027                         HUD_Panel_FirstInDrawQ(i);
1028                         highlightedAction = 2;
1029                         resizeCorner = 2;
1030                         panel_click_distance_x = panel_size_x - mousepos_x + panel_pos_x;
1031                         panel_click_distance_y = mousepos_y - panel_pos_y;
1032                         panel_click_resizeorigin = panel_pos + eY * panel_size_y;
1033                         return;
1034                 }
1035                 // resize from bottomleft border
1036                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
1037                 {
1038                         highlightedPanel = i;
1039                         HUD_Panel_FirstInDrawQ(i);
1040                         highlightedAction = 2;
1041                         resizeCorner = 3;
1042                         panel_click_distance_x = mousepos_x - panel_pos_x;
1043                         panel_click_distance_y = panel_size_y - mousepos_y + panel_pos_y;
1044                         panel_click_resizeorigin = panel_pos + eX * panel_size_x;
1045                         return;
1046                 }
1047                 // resize from bottomright border
1048                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
1049                 {
1050                         highlightedPanel = i;
1051                         HUD_Panel_FirstInDrawQ(i);
1052                         highlightedAction = 2;
1053                         resizeCorner = 4;
1054                         panel_click_distance = panel_size - mousepos + panel_pos;
1055                         panel_click_resizeorigin = panel_pos;
1056                         return;
1057                 }
1058         }
1059         highlightedPanel = -1;
1060         highlightedAction = 0;
1061 }
1062
1063 void HUD_Panel_EnableMenu()
1064 {
1065         menu_enabled = 2;
1066         menu_enabled_time = time;
1067         HUD_Panel_GetName(highlightedPanel);
1068         localcmd("menu_showhudoptions ", panel_name, "\n");
1069 }
1070 float mouse_over_panel;
1071 void HUD_Panel_Mouse()
1072 {
1073         // TODO: needs better check... is there any float that contains the current state of the menu? _menu_alpha isn't apparently updated the frame the menu gets enabled
1074         if (autocvar__menu_alpha == 0 && time - menu_enabled_time > 0.5)
1075                 menu_enabled = 0;
1076
1077         /*
1078         print("menu_enabled: ", ftos(menu_enabled), "\n");
1079         print("Highlighted: ", ftos(highlightedPanel), "\n");
1080         print("Menu theAlpha: ", ftos(autocvar__menu_alpha), "\n");
1081         */
1082
1083         if(autocvar__menu_alpha == 1)
1084                 return;
1085
1086         if not(autocvar_hud_cursormode)
1087         {
1088                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
1089
1090                 mousepos_x = bound(0, mousepos_x, vid_conwidth);
1091                 mousepos_y = bound(0, mousepos_y, vid_conheight);
1092         }
1093
1094         if(mouseClicked)
1095         {
1096                 if(prevMouseClicked == 0)
1097                 {
1098                         if (tab_panel != -1)
1099                         {
1100                                 //stop ctrl-tab selection
1101                                 tab_panel = -1;
1102                                 reset_tab_panels();
1103                         }
1104                         HUD_Panel_Highlight(mouseClicked & S_MOUSE1); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1105                                                                         // and calls HUD_Panel_UpdatePosSizeForId() for the highlighted panel
1106                         if (highlightedPanel != -1)
1107                         {
1108                                 highlightedPanel_initial_pos = panel_pos;
1109                                 highlightedPanel_initial_size = panel_size;
1110                         }
1111                         // doubleclick check
1112                         if ((mouseClicked & S_MOUSE1) && time - prevMouseClickedTime < 0.4 && highlightedPanel != -1 && prevMouseClickedPos == mousepos)
1113                         {
1114                                 mouseClicked = 0; // to prevent spam, I guess.
1115                                 HUD_Panel_EnableMenu();
1116                         }
1117                         else
1118                         {
1119                                 if (mouseClicked & S_MOUSE1)
1120                                 {
1121                                         prevMouseClickedTime = time;
1122                                         prevMouseClickedPos = mousepos;
1123                                 }
1124                                 mouse_over_panel = HUD_Panel_Check_Mouse_Pos(mouseClicked & S_MOUSE1);
1125                         }
1126                 }
1127                 else
1128                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
1129
1130                 if (highlightedPanel != -1)
1131                 {
1132                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1133                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
1134                         {
1135                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
1136                                 // backup!
1137                                 panel_pos_backup = highlightedPanel_initial_pos;
1138                                 panel_size_backup = highlightedPanel_initial_size;
1139                                 highlightedPanel_backup = highlightedPanel;
1140                         }
1141                         else
1142                                 // in case the clicked panel is inside another panel and we aren't
1143                                 // moving it, avoid the immediate "fix" of its position/size
1144                                 // (often unwanted and hateful) by disabling collisions check
1145                                 hud_configure_checkcollisions = false;
1146                 }
1147
1148                 if(highlightedAction == 1)
1149                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1150                 else if(highlightedAction == 2)
1151                 {
1152                         vector mySize = '0 0 0';
1153                         if(resizeCorner == 1) {
1154                                 mySize_x = panel_click_resizeorigin_x - (mousepos_x - panel_click_distance_x);
1155                                 mySize_y = panel_click_resizeorigin_y - (mousepos_y - panel_click_distance_y);
1156                         } else if(resizeCorner == 2) {
1157                                 mySize_x = mousepos_x + panel_click_distance_x - panel_click_resizeorigin_x;
1158                                 mySize_y = panel_click_distance_y + panel_click_resizeorigin_y - mousepos_y;
1159                         } else if(resizeCorner == 3) {
1160                                 mySize_x = panel_click_resizeorigin_x + panel_click_distance_x - mousepos_x;
1161                                 mySize_y = mousepos_y + panel_click_distance_y - panel_click_resizeorigin_y;
1162                         } else { // resizeCorner == 4
1163                                 mySize_x = mousepos_x - (panel_click_resizeorigin_x - panel_click_distance_x);
1164                                 mySize_y = mousepos_y - (panel_click_resizeorigin_y - panel_click_distance_y);
1165                         }
1166                         HUD_Panel_SetPosSize(mySize);
1167                 }
1168         }
1169         else
1170         {
1171                 if(menu_enabled == 2)
1172                         mouse_over_panel = 0;
1173                 else
1174                         mouse_over_panel = HUD_Panel_Check_Mouse_Pos(TRUE);
1175                 if (mouse_over_panel && tab_panel == -1)
1176                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1177         }
1178         // draw cursor after performing move/resize to have the panel pos/size updated before mouse_over_panel
1179         const vector cursorsize = '32 32 0';
1180         float cursor_alpha = 1 - autocvar__menu_alpha;
1181
1182         if(!mouse_over_panel)
1183                 drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1184         else if(mouse_over_panel == 1)
1185                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_move.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1186         else if(mouse_over_panel == 2)
1187                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1188         else
1189                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize2.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1190
1191         prevMouseClicked = mouseClicked;
1192 }
1193
1194 const float hlBorderSize = 4;
1195 const string hlBorder = "gfx/hud/default/border_highlighted";
1196 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1197 void HUD_Panel_HlBorder(float myBorder, vector color, float theAlpha)
1198 {
1199         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * theAlpha, DRAWFLAG_NORMAL);
1200         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1201         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size_y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1202         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1203         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size_x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1204 }