qcsrc/client/hud/panel/strafehud.qc

   1 // Author: Juhu
   2
   3 #include "strafehud.qh"
   4
   5 #include <client/autocvars.qh>
   6 #include <client/draw.qh>
   7 #include <client/hud/panel/racetimer.qh>
   8 #include <client/main.qh>
   9 #include <client/resources.qh>
  10 #include <common/animdecide.qh>
  11 #include <common/ent_cs.qh>
  12 #include <common/mapinfo.qh>
  13 #include <common/physics/movetypes/movetypes.qh>
  14 #include <common/physics/player.qh>
  15 #include <lib/csqcmodel/cl_player.qh>
  16
  17 // StrafeHUD (#25)
  18
  19 void HUD_StrafeHUD_Export(int fh)
  20 {
  21     // allow saving cvars that aesthetically change the panel into hud skin files
  22 }
  23
  24 float hidden_width;
  25 int direction;
  26 float demo_angle = -37;
  27 float demo_direction = 1;
  28 float demo_time = 0;
  29 bool state_onground = false;
  30 float state_onground_time = 0;
  31 bool state_strafekeys = false;
  32 float state_strafekeys_time = 0;
  33 bool turn = false;
  34 float turnangle;
  35 bool fwd = true;
  36 bool state_fwd = true;
  37 bool state_fwd_prev = true;
  38 float state_fwd_time = 0;
  39 float starttime = 0;
  40 float startspeed = -1;
  41 float jumptime = 0;
  42 float jumpheight = -1;
  43 float jumpheight_persistent = -1;
  44 float jumpheight_prev = 0;
  45 float jumpspeed_prev = 0;
  46 bool  jumprestart = true;
  47
  48 // provide basic panel cvars to old clients
  49 // TODO remove them after a future release (0.8.2+)
  50 noref string autocvar_hud_panel_strafehud_pos = "0.320000 0.570000";
  51 noref string autocvar_hud_panel_strafehud_size = "0.360000 0.020000";
  52 noref string autocvar_hud_panel_strafehud_bg = "0";
  53 noref string autocvar_hud_panel_strafehud_bg_color = "";
  54 noref string autocvar_hud_panel_strafehud_bg_color_team = "";
  55 noref string autocvar_hud_panel_strafehud_bg_alpha = "0.7";
  56 noref string autocvar_hud_panel_strafehud_bg_border = "";
  57 noref string autocvar_hud_panel_strafehud_bg_padding = "";
  58
  59 void HUD_StrafeHUD()
  60 {
  61     entity strafeplayer;
  62     bool islocal;
  63
  64     // generic hud routines
  65     if(!autocvar__hud_configure)
  66     {
  67         if(!autocvar_hud_panel_strafehud ||
  68            (spectatee_status == -1 && (autocvar_hud_panel_strafehud == 1 || autocvar_hud_panel_strafehud == 3)) ||
  69            (autocvar_hud_panel_strafehud == 3 && !MUTATOR_CALLHOOK(HUD_StrafeHUD_showoptional))) return;
  70     }
  71
  72     HUD_Panel_LoadCvars();
  73
  74     if(autocvar_hud_panel_strafehud_dynamichud)
  75     {
  76         HUD_Scale_Enable();
  77     }
  78     else
  79     {
  80         HUD_Scale_Disable();
  81     }
  82
  83     HUD_Panel_DrawBg();
  84
  85     if(panel_bg_padding)
  86     {
  87         panel_pos  += '1 1 0' * panel_bg_padding;
  88         panel_size -= '2 2 0' * panel_bg_padding;
  89     }
  90
  91     // find out whether the local csqcmodel entity is valid
  92     if(spectatee_status > 0 || isdemo())
  93     {
  94         islocal = false;
  95         strafeplayer = CSQCModel_server2csqc(player_localentnum - 1);
  96     }
  97     else
  98     {
  99         islocal = true;
 100         strafeplayer = csqcplayer;
 101     }
 102
 103     // draw strafehud
 104     if(csqcplayer && strafeplayer)
 105     {
 106         // physics
 107         bool   onground                      = islocal ? IS_ONGROUND(strafeplayer) : !(strafeplayer.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 108         bool   strafekeys;
 109         bool   swimming                      = strafeplayer.waterlevel >= WATERLEVEL_SWIMMING;
 110         bool   spectating                    = entcs_GetSpecState(strafeplayer.sv_entnum) == ENTCS_SPEC_PURE;
 111         float  speed                         = !autocvar__hud_configure ? vlen(vec2(csqcplayer.velocity)) : 1337; // use local csqcmodel entity for this even when spectating, flickers too much otherwise
 112         float  maxspeed_crouch_mod           = IS_DUCKED(strafeplayer) && !swimming ? .5 : 1;
 113         float  maxspeed_water_mod            = swimming ? .7 : 1; // very simplified water physics, the hud will not work well (and is not supposed to) while swimming
 114         float  maxspeed_phys                 = onground ? PHYS_MAXSPEED(strafeplayer) : PHYS_MAXAIRSPEED(strafeplayer);
 115         float  maxspeed                      = !autocvar__hud_configure ? maxspeed_phys * maxspeed_crouch_mod * maxspeed_water_mod : 320;
 116         float  vel_angle                     = vectoangles(strafeplayer.velocity).y;
 117         float  view_angle                    = PHYS_INPUT_ANGLES(strafeplayer).y + 180;
 118         float  angle;
 119         vector movement                      = PHYS_INPUT_MOVEVALUES(strafeplayer);
 120         int    keys                          = STAT(PRESSED_KEYS);
 121         int    keys_fwd;
 122         float  wishangle                     = 0;
 123
 124         // HUD
 125         int    mode                          = autocvar_hud_panel_strafehud_mode >= 0 && autocvar_hud_panel_strafehud_mode <= 1 ? autocvar_hud_panel_strafehud_mode : 0;
 126         float  speed_conversion_factor       = GetSpeedUnitFactor(autocvar_hud_panel_strafehud_unit);
 127         float  length_conversion_factor      = GetLengthUnitFactor(autocvar_hud_panel_strafehud_unit);
 128         string speed_unit                    = GetSpeedUnit(autocvar_hud_panel_strafehud_unit);
 129         string length_unit                   = GetLengthUnit(autocvar_hud_panel_strafehud_unit);
 130         int    length_decimals               = autocvar_hud_panel_strafehud_unit >= 3 && autocvar_hud_panel_strafehud_unit <= 5 ? 6 : 2; // use more decimals when displaying km or miles
 131         float  antiflicker_angle             = bound(0, autocvar_hud_panel_strafehud_antiflicker_angle, 180);
 132         float  antiflicker_speed             = max(0, autocvar_hud_panel_strafehud_antiflicker_speed);
 133         float  minspeed;
 134         float  shift_offset                  = 0;
 135         bool   straight_overturn             = false;
 136         bool   immobile                      = speed <= (swimming ? antiflicker_speed : 0);
 137         float  hudangle;
 138         float  neutral_offset;
 139         float  neutral_width;
 140         vector currentangle_color            = autocvar_hud_panel_strafehud_angle_neutral_color;
 141         float  currentangle_offset;
 142         vector currentangle_size             = '0 0 0';
 143         float  bestangle;
 144         float  odd_bestangle;
 145         bool   bestangle_anywhere            = false;
 146         float  bestangle_offset;
 147         float  switch_bestangle_offset;
 148         bool   odd_angles                    = false;
 149         float  odd_bestangle_offset          = 0;
 150         float  switch_odd_bestangle_offset   = 0;
 151         float  bestangle_width;
 152         float  accelzone_left_offset;
 153         float  accelzone_right_offset;
 154         float  accelzone_width;
 155         float  overturn_offset;
 156         float  overturn_width;
 157         float  slickdetector_height;
 158         vector direction_size_vertical       = '0 0 0';
 159         vector direction_size_horizontal     = '0 0 0';
 160         float  range_minangle;
 161
 162         // determine whether the player is pressing forwards or backwards keys
 163         if(islocal) // if entity is local player
 164         {
 165             if(movement.x > 0)
 166             {
 167                 keys_fwd = 1;
 168             }
 169             else if(movement.x < 0)
 170             {
 171                 keys_fwd = -1;
 172             }
 173             else
 174             {
 175                 keys_fwd = 0;
 176             }
 177         }
 178         else // alternatively determine direction by querying pressed keys
 179         {
 180             if((keys & KEY_FORWARD) && !(keys & KEY_BACKWARD))
 181             {
 182                 keys_fwd = 1;
 183             }
 184             else if(!(keys & KEY_FORWARD) && (keys & KEY_BACKWARD))
 185             {
 186                 keys_fwd = -1;
 187             }
 188             else
 189             {
 190                 keys_fwd = 0;
 191             }
 192         }
 193
 194         // determine player wishdir
 195         if(islocal) // if entity is local player
 196         {
 197             if(movement.x == 0)
 198             {
 199                 if(movement.y < 0)
 200                 {
 201                     wishangle = -90;
 202                 }
 203                 else if(movement.y > 0)
 204                 {
 205                     wishangle = 90;
 206                 }
 207                 else
 208                 {
 209                     wishangle = 0;
 210                 }
 211             }
 212             else
 213             {
 214                 if(movement.y == 0)
 215                 {
 216                     wishangle = 0;
 217                 }
 218                 else
 219                 {
 220                     wishangle = RAD2DEG * atan2(movement.y, movement.x);
 221                     // wrap the wish angle if it exceeds ±90°
 222                     if(fabs(wishangle) > 90)
 223                     {
 224                         if(wishangle < 0) wishangle += 180;
 225                         else wishangle -= 180;
 226                         wishangle = -wishangle;
 227                     }
 228                 }
 229             }
 230         }
 231         else // alternatively calculate wishdir by querying pressed keys
 232         {
 233             if(keys & KEY_FORWARD || keys & KEY_BACKWARD)
 234             {
 235                 wishangle = 45;
 236             }
 237             else
 238             {
 239                 wishangle = 90;
 240             }
 241             if(keys & KEY_LEFT)
 242             {
 243                 wishangle *= -1;
 244             }
 245             else if(!(keys & KEY_RIGHT))
 246             {
 247                 wishangle = 0; // wraps at 180°
 248             }
 249         }
 250
 251         strafekeys = fabs(wishangle) == 90;
 252
 253         // determine minimum required angle to display full strafe range
 254         range_minangle = fabs(wishangle) % 90; // maximum range is 90 degree
 255         if(range_minangle > 45) // minimum angle range is 45
 256         {
 257             range_minangle = 45 - fabs(wishangle) % 45;
 258         }
 259         range_minangle = 90 - range_minangle; // calculate value which is never >90 or <45
 260         range_minangle *= 2; // multiply to accommodate for both sides of the hud
 261
 262         if(autocvar_hud_panel_strafehud_range == 0)
 263         {
 264             if(autocvar__hud_configure)
 265             {
 266                 hudangle = 90;
 267             }
 268             else
 269             {
 270                 hudangle = range_minangle; // use minimum angle required if dynamically setting hud angle
 271             }
 272         }
 273         else
 274         {
 275             hudangle = bound(0, fabs(autocvar_hud_panel_strafehud_range), 360); // limit HUD range to 360 degrees, higher values don't make sense
 276         }
 277
 278         // detect air strafe turning
 279         if(onground != state_onground)
 280         {
 281             state_onground_time = time;
 282         }
 283         state_onground = onground;
 284
 285         if(strafekeys != state_strafekeys)
 286         {
 287             state_strafekeys_time = time;
 288         }
 289         state_strafekeys = strafekeys;
 290
 291         if((keys & KEY_FORWARD) || (keys & KEY_BACKWARD) || swimming || autocvar__hud_configure)
 292         {
 293             turn = false;
 294         }
 295         else if(onground)
 296         {
 297             if((time - state_onground_time) >= autocvar_hud_panel_strafehud_timeout_ground) // timeout for strafe jumping in general
 298             {
 299                 turn = false;
 300             }
 301         }
 302         else // air strafe only
 303         {
 304             if(strafekeys)
 305             {
 306                 if(((time - state_onground_time) >= autocvar_hud_panel_strafehud_timeout_air) || (keys & KEY_JUMP)) // timeout for slick ramps
 307                 {
 308                     turn = true; // CPMA turning
 309                     turnangle = wishangle;
 310                 }
 311             }
 312             else if((time - state_strafekeys_time) >= autocvar_hud_panel_strafehud_timeout_turn) // timeout for jumping with strafe keys only
 313             {
 314                 turn = false;
 315             }
 316         }
 317         if(turn)
 318         {
 319             maxspeed = PHYS_MAXAIRSTRAFESPEED(strafeplayer); // no modifiers here because they don't affect air strafing
 320             wishangle = turnangle;
 321         }
 322
 323         minspeed = autocvar_hud_panel_strafehud_switch_minspeed < 0 ? maxspeed + antiflicker_speed : autocvar_hud_panel_strafehud_switch_minspeed;
 324
 325         // get current strafing angle ranging from -180° to +180°
 326         if(!autocvar__hud_configure)
 327         {
 328             if(speed > 0)
 329             {
 330                 // calculate view angle relative to the players current velocity direction
 331                 angle = vel_angle - view_angle;
 332
 333                 // if the angle goes above 180° or below -180° wrap it to the opposite side
 334                 if (angle > 180) angle -= 360;
 335                 else if(angle < -180) angle += 360;
 336
 337                 // shift the strafe angle by 180° for hud calculations
 338                 if(angle < 0) angle += 180;
 339                 else angle -= 180;
 340
 341                 // determine whether the player is strafing forwards or backwards
 342                 // if the player isn't strafe turning use forwards/backwards keys to determine direction
 343                 if(!strafekeys)
 344                 {
 345                     if(keys_fwd > 0)
 346                     {
 347                         state_fwd = true;
 348                     }
 349                     else if(keys_fwd < 0)
 350                     {
 351                         state_fwd = false;
 352                     }
 353                     else
 354                     {
 355                         state_fwd = fabs(angle) <= 90;
 356                     }
 357                 }
 358                 // otherwise determine by examining the strafe angle
 359                 else
 360                 {
 361                     if(wishangle < 0) // detect direction using wishangle since the direction is not yet set
 362                     {
 363                         state_fwd = angle <= -wishangle;
 364                     }
 365                     else
 366                     {
 367                         state_fwd = angle >= -wishangle;
 368                     }
 369                 }
 370
 371                 if(state_fwd_prev != state_fwd)
 372                 {
 373                     state_fwd_time = time;
 374                 }
 375                 state_fwd_prev = state_fwd;
 376
 377                 if((time - state_fwd_time) >= autocvar_hud_panel_strafehud_timeout_direction || speed < maxspeed || (strafekeys && mode == 0)) // timeout when changing between forwards and backwards movement
 378                 {
 379                     fwd = state_fwd;
 380                 }
 381
 382                 // shift the strafe angle by 180° when strafing backwards
 383                 if(!fwd)
 384                 {
 385                     if(angle < 0) angle += 180;
 386                     else angle -= 180;
 387                 }
 388
 389                 // don't make the angle indicator switch side too much at ±180° if anti flicker is turned on
 390                 if(angle > (180 - antiflicker_angle) || angle < (-180 + antiflicker_angle))
 391                 {
 392                     straight_overturn = true;
 393                 }
 394             }
 395             else
 396             {
 397                 angle = 0;
 398             }
 399         }
 400         else // simulate turning for HUD setup
 401         {
 402             fwd = true;
 403             if(autocvar__hud_panel_strafehud_demo && ((time - demo_time) >= .025))
 404             {
 405                 demo_time = time;
 406                 demo_angle += demo_direction;
 407                 if(fabs(demo_angle) >= 55)
 408                 {
 409                     demo_direction = -demo_direction;
 410                 }
 411             }
 412             angle = demo_angle;
 413             wishangle = 45 * (demo_angle > 0 ? 1 : -1);
 414         }
 415
 416         // invert the wish angle when strafing backwards
 417         if(!fwd)
 418         {
 419             wishangle = -wishangle;
 420         }
 421
 422         // flip angles if v_flipped is enabled
 423         if(autocvar_v_flipped)
 424         {
 425             angle = -angle;
 426             wishangle = -wishangle;
 427         }
 428
 429         // determine whether the player is strafing left or right
 430         if(wishangle != 0)
 431         {
 432             direction = wishangle > 0 ? 1 : -1;
 433         }
 434         else
 435         {
 436             direction = (angle > antiflicker_angle && angle < (180 - antiflicker_angle)) ? 1 : (angle < -antiflicker_angle && angle > (-180 + antiflicker_angle)) ? -1 : 0;
 437         }
 438
 439         // best angle to strafe at
 440         bestangle = (speed > maxspeed ? acos(maxspeed / speed) : 0) * RAD2DEG * (direction < 0 ? -1 : 1);
 441         odd_bestangle = -bestangle - wishangle;
 442         bestangle -= wishangle;
 443
 444         // various offsets and size calculations of hud indicator elements
 445         // how much is hidden by the current hud angle
 446         hidden_width = (360 - hudangle) / hudangle * panel_size.x;
 447         // current angle
 448         currentangle_size.x = max(panel_size.x * autocvar_hud_panel_strafehud_angle_width, 1);
 449         if(mode == 0)
 450         {
 451             currentangle_offset = angle/hudangle * panel_size.x;
 452         }
 453         else
 454         {
 455             currentangle_offset = bound(-hudangle/2, angle, hudangle/2)/hudangle * panel_size.x + panel_size.x/2;
 456         }
 457         currentangle_size.y = max(panel_size.y * min(autocvar_hud_panel_strafehud_angle_height, 2), 1);
 458         // best strafe acceleration angle
 459         bestangle_offset        =  bestangle/hudangle * panel_size.x + panel_size.x/2;
 460         switch_bestangle_offset = -bestangle/hudangle * panel_size.x + panel_size.x/2;
 461         bestangle_width = max(panel_size.x * autocvar_hud_panel_strafehud_switch_width, 1);
 462
 463         if(((angle > -wishangle && direction < 0) || (angle < -wishangle && direction > 0)) && (direction != 0))
 464         {
 465             odd_angles = true;
 466             odd_bestangle_offset = odd_bestangle/hudangle * panel_size.x + panel_size.x/2;
 467             switch_odd_bestangle_offset = (odd_bestangle+bestangle*2)/hudangle * panel_size.x + panel_size.x/2;
 468         }
 469         // direction indicator
 470         direction_size_vertical.x = max(panel_size.y * min(autocvar_hud_panel_strafehud_direction_width, .5), 1);
 471         direction_size_vertical.y = panel_size.y;
 472         direction_size_horizontal.x = max(panel_size.x * min(autocvar_hud_panel_strafehud_direction_length, .5), direction_size_vertical.x);
 473         direction_size_horizontal.y = direction_size_vertical.x;
 474         // overturn
 475         overturn_width = 180/hudangle * panel_size.x;
 476
 477         // the neutral zone fills the whole strafe bar
 478         if(immobile)
 479         {
 480             // draw neutral zone
 481             if(panel_size.x > 0 && panel_size.y > 0 && autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha > 0)
 482             {
 483                 switch(autocvar_hud_panel_strafehud_style)
 484                 {
 485                     default:
 486                     case 0:
 487                         drawfill(panel_pos, panel_size, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 488                         break;
 489
 490                     case 1:
 491                         HUD_Panel_DrawProgressBar(panel_pos, panel_size, "progressbar", 1, 0, 0, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 492                 }
 493             }
 494         }
 495         else
 496         {
 497             // calculate various zones of the strafe-o-meter
 498             accelzone_width = overturn_offset = (90 - fabs(bestangle + wishangle))/hudangle * panel_size.x;
 499             accelzone_right_offset = 0;
 500             accelzone_left_offset = overturn_offset + overturn_width;
 501             neutral_width = 360/hudangle * panel_size.x - accelzone_width*2 - overturn_width;
 502             neutral_offset = direction < 0 ? accelzone_left_offset + accelzone_width : -neutral_width;
 503
 504             // remove switch indicator width from offset
 505             if(direction < 0)
 506             {
 507                 bestangle_offset -= bestangle_width;
 508                 switch_odd_bestangle_offset -= bestangle_width;
 509             }
 510             else
 511             {
 512                 switch_bestangle_offset -= bestangle_width;
 513                 odd_bestangle_offset -= bestangle_width;
 514             }
 515
 516             // shift hud if operating in view angle centered mode
 517             if(mode == 0)
 518             {
 519                 shift_offset = -currentangle_offset;
 520                 bestangle_offset += shift_offset;
 521                 switch_bestangle_offset += shift_offset;
 522                 odd_bestangle_offset += shift_offset;
 523                 switch_odd_bestangle_offset += shift_offset;
 524             }
 525             if(direction < 0) shift_offset += -360/hudangle * panel_size.x;
 526             // calculate how far off-center the strafe zones currently are
 527             shift_offset += (panel_size.x + neutral_width)/2 - wishangle/hudangle * panel_size.x;
 528             // shift strafe zones into correct place
 529             neutral_offset += shift_offset;
 530             accelzone_left_offset += shift_offset;
 531             accelzone_right_offset += shift_offset;
 532             overturn_offset += shift_offset;
 533
 534             // draw left acceleration zone
 535             HUD_Panel_DrawStrafeHUD(accelzone_left_offset, accelzone_width, autocvar_hud_panel_strafehud_bar_accel_color, autocvar_hud_panel_strafehud_bar_accel_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 1);
 536
 537             // draw right acceleration zone
 538             HUD_Panel_DrawStrafeHUD(accelzone_right_offset, accelzone_width, autocvar_hud_panel_strafehud_bar_accel_color, autocvar_hud_panel_strafehud_bar_accel_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 2);
 539
 540             // draw overturn zone
 541             HUD_Panel_DrawStrafeHUD(overturn_offset, overturn_width, autocvar_hud_panel_strafehud_bar_overturn_color, autocvar_hud_panel_strafehud_bar_overturn_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 3);
 542
 543             // draw neutral zone
 544             HUD_Panel_DrawStrafeHUD(neutral_offset, neutral_width, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 0);
 545
 546             if(direction != 0 && direction_size_vertical.x > 0 && autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha > 0)
 547             {
 548                 bool indicator_direction = direction < 0;
 549                 // invert left/right when strafing backwards or when strafing towards the opposite side indicated by the direction variable
 550                 // if both conditions are true then it's inverted twice hence not inverted at all
 551                 if(!fwd != odd_angles)
 552                 {
 553                     indicator_direction = !indicator_direction;
 554                 }
 555                 // draw the direction indicator caps at the sides of the hud
 556                 // vertical line
 557                 if(direction_size_vertical.y > 0) drawfill(panel_pos + eX * (indicator_direction ? -direction_size_vertical.x : panel_size.x), direction_size_vertical, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 558                 // top horizontal line
 559                 drawfill(panel_pos + eX * (indicator_direction ? -direction_size_vertical.x : panel_size.x - direction_size_horizontal.x + direction_size_vertical.x) - eY * direction_size_horizontal.y, direction_size_horizontal, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 560                 // bottom horizontal line
 561                 drawfill(panel_pos + eX * (indicator_direction ? -direction_size_vertical.x : panel_size.x - direction_size_horizontal.x + direction_size_vertical.x) + eY * panel_size.y, direction_size_horizontal, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 562             }
 563
 564             if(speed >= minspeed) // only draw indicators if minspeed is reached
 565             {
 566                 // draw best angles for acceleration
 567                 float offset = !odd_angles ? bestangle_offset : odd_bestangle_offset;
 568                 float switch_offset = !odd_angles ? switch_bestangle_offset : switch_odd_bestangle_offset;
 569                 // both indicators are inactive if no direction can be determined
 570                 vector switch_color = direction != 0 ? autocvar_hud_panel_strafehud_switch_active_color : autocvar_hud_panel_strafehud_switch_inactive_color;
 571                 float switch_alpha = direction != 0 ? autocvar_hud_panel_strafehud_switch_active_alpha : autocvar_hud_panel_strafehud_switch_inactive_alpha;
 572                 // draw the switch indicators
 573                 HUD_Panel_DrawStrafeHUD(switch_offset, bestangle_width, autocvar_hud_panel_strafehud_switch_inactive_color, autocvar_hud_panel_strafehud_switch_inactive_alpha * panel_fg_alpha, 0, 0);
 574                 HUD_Panel_DrawStrafeHUD(offset, bestangle_width, switch_color, switch_alpha * panel_fg_alpha, 0, 0);
 575             }
 576         }
 577
 578         // experimental: slick detector
 579         slickdetector_height = panel_size.y * bound(0, autocvar_hud_panel_strafehud_slickdetector_height, 0.5);
 580         if(autocvar_hud_panel_strafehud_slickdetector_range > 0 && autocvar_hud_panel_strafehud_slickdetector_alpha > 0 && slickdetector_height > 0 && panel_size.x > 0) // dunno if slick detection works in spectate
 581         {
 582             float slicksteps = 90 / pow(2, bound(0, autocvar_hud_panel_strafehud_slickdetector_granularity, 4));
 583             bool slickdetected = false;
 584
 585             slickdetected = IS_ONSLICK(strafeplayer); // don't need to traceline if already touching slick
 586
 587             // traceline into every direction
 588             trace_dphitq3surfaceflags = 0;
 589             for(float i = 0; i < 360 && !slickdetected; i += slicksteps)
 590             {
 591                 vector slickoffset;
 592                 float slickrotate;
 593                 slickoffset.z = -cos(i * DEG2RAD) * autocvar_hud_panel_strafehud_slickdetector_range;
 594                 slickrotate = sin(i * DEG2RAD) * autocvar_hud_panel_strafehud_slickdetector_range;
 595                 if(i != 0 && i != 180)
 596                 {
 597                     for(float j = 0; j < 180 && !slickdetected; j += slicksteps)
 598                     {
 599                         slickoffset.x = sin(j * DEG2RAD) * slickrotate;
 600                         slickoffset.y = cos(j * DEG2RAD) * slickrotate;
 601
 602                         traceline(strafeplayer.origin, strafeplayer.origin + slickoffset, MOVE_WORLDONLY, NULL);
 603                         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK) slickdetected = true;
 604                     }
 605                 }
 606                 else
 607                 {
 608                     slickoffset.x = slickoffset.y = 0;
 609                     traceline(strafeplayer.origin, strafeplayer.origin + slickoffset, MOVE_WORLDONLY, NULL);
 610                     if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK) slickdetected = true;
 611                 }
 612             }
 613
 614             // if a traceline hit a slick surface
 615             if(slickdetected)
 616             {
 617                 vector slickdetector_size = panel_size;
 618                 slickdetector_size.y = slickdetector_height;
 619                 // top horizontal line
 620                 drawfill(panel_pos - eY * slickdetector_size.y, slickdetector_size, autocvar_hud_panel_strafehud_slickdetector_color, autocvar_hud_panel_strafehud_slickdetector_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 621                 // bottom horizontal line
 622                 drawfill(panel_pos + eY * panel_size.y, slickdetector_size, autocvar_hud_panel_strafehud_slickdetector_color, autocvar_hud_panel_strafehud_slickdetector_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 623             }
 624         }
 625
 626         draw_beginBoldFont();
 627         // show speed when crossing the start trigger
 628         if(autocvar_hud_panel_strafehud_startspeed_fade > 0)
 629         {
 630             float text_alpha = 0;
 631             if(race_checkpoint == 254) // checkpoint 254 is the start trigger
 632             {
 633                 if(starttime != race_checkpointtime)
 634                 {
 635                     starttime = race_checkpointtime;
 636                     startspeed = speed;
 637                 }
 638             }
 639             if(startspeed >= 0)
 640             {
 641                 text_alpha = cos(((time - starttime) / autocvar_hud_panel_strafehud_startspeed_fade) * 90 * DEG2RAD); // fade non-linear like the physics panel does
 642                 if((time - starttime) > autocvar_hud_panel_strafehud_startspeed_fade)
 643                 {
 644                     startspeed = -1;
 645                 }
 646             }
 647             if(startspeed >= 0 && text_alpha > 0 && autocvar_hud_panel_strafehud_startspeed_size > 0)
 648             {
 649                 vector startspeed_size = panel_size;
 650                 startspeed_size.y = panel_size.y * min(autocvar_hud_panel_strafehud_startspeed_size, 5);
 651                 drawstring_aspect(panel_pos + eY * panel_size.y, strcat(ftos_decimals(startspeed * speed_conversion_factor, 2), autocvar_hud_panel_strafehud_unit_show ? speed_unit : ""), startspeed_size, autocvar_hud_panel_strafehud_startspeed_color, text_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 652             }
 653         }
 654         else
 655         {
 656             starttime = 0;
 657             startspeed = -1;
 658         }
 659
 660         // experimental: show height achieved by a single jump (doesn't work in low gravity and may not be 100% accurate)
 661         if(autocvar_hud_panel_strafehud_jumpheight_fade > 0)
 662         {
 663             float text_alpha = 0;
 664             float jumpheight_min = max(autocvar_hud_panel_strafehud_jumpheight_min, 0);
 665             float jumpheight_current = strafeplayer.origin.z;
 666             float jumpspeed_current = strafeplayer.velocity.z;
 667             if(jumpspeed_prev <= jumpspeed_current || jumpheight_prev > jumpheight_current || IS_ONGROUND(strafeplayer) || swimming || IS_DEAD(strafeplayer) || spectating)
 668             {
 669                 // tries to catch kill and spectate but those are not reliable, should just hook to kill/spectate/teleport and reset jump height there
 670                 jumprestart = true;
 671             }
 672             else
 673             {
 674                 if(jumpheight < 0 || jumprestart)
 675                 {
 676                     jumprestart = false;
 677                     jumpheight = 0;
 678                 }
 679                 else
 680                 {
 681                     jumpheight += jumpheight_current - jumpheight_prev;
 682                 }
 683                 if((jumpheight * length_conversion_factor) > jumpheight_min && jumpheight > jumpheight_persistent)
 684                 {
 685                     jumptime = time;
 686                     jumpheight_persistent = jumpheight;
 687                 }
 688             }
 689             jumpheight_prev = jumpheight_current;
 690             jumpspeed_prev = jumpspeed_current;
 691             if(jumpheight_persistent > 0)
 692             {
 693                 text_alpha = cos(((time - jumptime) / autocvar_hud_panel_strafehud_jumpheight_fade) * 90 * DEG2RAD); // fade non-linear like the physics panel does
 694                 if((time - jumptime) > autocvar_hud_panel_strafehud_jumpheight_fade)
 695                 {
 696                     jumpheight_persistent = -1;
 697                 }
 698             }
 699             if(jumpheight_persistent > 0 && text_alpha > 0 && autocvar_hud_panel_strafehud_jumpheight_size > 0)
 700             {
 701                 vector jumpheight_size = panel_size;
 702                 jumpheight_size.y = panel_size.y * min(autocvar_hud_panel_strafehud_jumpheight_size, 5);
 703                 drawstring_aspect(panel_pos - eY * jumpheight_size.y, strcat(ftos_decimals(jumpheight_persistent * length_conversion_factor, length_decimals), autocvar_hud_panel_strafehud_unit_show ? length_unit : ""), jumpheight_size, autocvar_hud_panel_strafehud_jumpheight_color, text_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 704             }
 705         }
 706         else
 707         {
 708             jumpheight_prev = jumpspeed_prev = 0;
 709             jumpheight = jumpheight_persistent = -1;
 710         }
 711         draw_endBoldFont();
 712
 713         if(speed < (maxspeed + antiflicker_speed) && !immobile)
 714         {
 715             bestangle_anywhere = true; // moving forward should suffice to gain speed
 716         }
 717
 718         // draw the actual strafe angle
 719         if(!bestangle_anywhere && !immobile) // player gains speed with strafing
 720         {
 721             if((direction > 0 && (angle >= bestangle || angle <= -(bestangle + wishangle*2))) ||
 722                (direction < 0 && (angle <= bestangle || angle >= -(bestangle + wishangle*2))))
 723             currentangle_color = autocvar_hud_panel_strafehud_angle_accel_color;
 724         }
 725
 726         if(fabs(angle + wishangle) > 90) // player is overturning
 727         {
 728             currentangle_color = autocvar_hud_panel_strafehud_angle_overturn_color;
 729         }
 730         else if(bestangle_anywhere) // player gains speed without strafing
 731         {
 732             currentangle_color = autocvar_hud_panel_strafehud_angle_accel_color;
 733         }
 734
 735         if(mode == 0 || straight_overturn)
 736         {
 737             currentangle_offset = panel_size.x/2;
 738         }
 739
 740         if(autocvar_hud_panel_strafehud_style == 2 && !immobile)
 741         {
 742             float moveangle = angle + wishangle;
 743             float strafeangle = (bestangle + wishangle) * (direction < 0 ? -1 : 1);
 744             float strafe_ratio = 0;
 745             if(fabs(moveangle) > 90)
 746             {
 747                 strafe_ratio = -((fabs(moveangle) - 90) / 90);
 748                 if(strafe_ratio < -1) strafe_ratio = -2 - strafe_ratio;
 749             }
 750             else
 751             {
 752                 if(moveangle >= strafeangle)
 753                 {
 754                     strafe_ratio = 1 - (moveangle - strafeangle) / (90 - strafeangle);
 755                 }
 756                 else if(moveangle <= -strafeangle)
 757                 {
 758                     strafe_ratio = 1 - (moveangle + strafeangle) / (-90 + strafeangle);
 759                 }
 760             }
 761             if(strafe_ratio < 0)
 762             {
 763                 currentangle_color = StrafeHUD_mixColors(autocvar_hud_panel_strafehud_angle_neutral_color, autocvar_hud_panel_strafehud_angle_overturn_color, -strafe_ratio);
 764             }
 765             else
 766             {
 767                 currentangle_color = StrafeHUD_mixColors(autocvar_hud_panel_strafehud_angle_neutral_color, autocvar_hud_panel_strafehud_angle_accel_color, strafe_ratio);
 768             }
 769         }
 770
 771         if(currentangle_size.x > 0 && currentangle_size.y > 0 && autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha > 0)
 772         {
 773             drawfill(panel_pos - eY * ((currentangle_size.y - panel_size.y) / 2) + eX * (currentangle_offset - currentangle_size.x/2), currentangle_size, currentangle_color, autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 774         }
 775     }
 776 }
 777
 778 // functions to make hud elements align perfectly in the hud area
 779 void HUD_Panel_DrawStrafeHUD(float offset, float width, vector color, float alpha, int type, int gradientType)
 780 {
 781     float mirror_offset, mirror_width;
 782     vector size = panel_size;
 783     vector mirror_size = panel_size;
 784
 785     float original_width = width;
 786     float hiddencolor_width;
 787
 788     if(alpha <= 0 && type != 2 || width <= 0) return;
 789
 790     if(type == 2 && gradientType == 0) type = 0;
 791
 792     if(offset < 0)
 793     {
 794         mirror_width = min(fabs(offset), width);
 795         mirror_offset = panel_size.x + hidden_width - fabs(offset);
 796         width += offset;
 797         offset = 0;
 798     }
 799     else
 800     {
 801         mirror_width = min(offset + width - panel_size.x - hidden_width, width);
 802         mirror_offset = max(offset - panel_size.x - hidden_width, 0);
 803     }
 804     if((offset + width) > panel_size.x)
 805     {
 806         width = panel_size.x - offset;
 807     }
 808     if(mirror_offset < 0)
 809     {
 810         mirror_width += mirror_offset;
 811         mirror_offset = 0;
 812     }
 813     if((mirror_offset + mirror_width) > panel_size.x)
 814     {
 815         mirror_width = panel_size.x - mirror_offset;
 816     }
 817
 818     if(width < 0) width = 0;
 819     if(mirror_width < 0) mirror_width = 0;
 820     hiddencolor_width = original_width - width - mirror_width;
 821
 822     if(direction < 0) // swap mirror and non-mirror values if direction points left
 823     {
 824         offset += mirror_offset;
 825         mirror_offset = offset - mirror_offset;
 826         offset -= mirror_offset;
 827
 828         width += mirror_width;
 829         mirror_width = width - mirror_width;
 830         width -= mirror_width;
 831     }
 832
 833     size.x = width;
 834     mirror_size.x = mirror_width;
 835
 836     switch(type)
 837     {
 838         default:
 839         case 0: // no styling (drawfill)
 840             if(mirror_size.x > 0 && mirror_size.y > 0) drawfill(panel_pos + eX * mirror_offset, mirror_size, color, alpha, DRAWFLAG_NORMAL);
 841             if(size.x > 0 && size.y > 0) drawfill(panel_pos + eX * offset, size, color, alpha, DRAWFLAG_NORMAL);
 842             break;
 843
 844         case 1: // progress bar style
 845             if(mirror_size.x > 0 && mirror_size.y > 0) HUD_Panel_DrawProgressBar(panel_pos + eX * mirror_offset, mirror_size, "progressbar", 1, 0, 0, color, alpha, DRAWFLAG_NORMAL);
 846             if(size.x > 0 && size.y > 0) HUD_Panel_DrawProgressBar(panel_pos + eX * offset, size, "progressbar", 1, 0, 0, color, alpha, DRAWFLAG_NORMAL);
 847             break;
 848
 849         case 2: // gradient style (types: 1 = left, 2 = right, 3 = both)
 850             StrafeHUD_drawGradient(color, autocvar_hud_panel_strafehud_bar_neutral_color, mirror_size, original_width, mirror_offset, alpha, width + (mirror_offset == 0 ? hiddencolor_width : 0), gradientType);
 851             StrafeHUD_drawGradient(color, autocvar_hud_panel_strafehud_bar_neutral_color, size, original_width, offset, alpha, (offset == 0 ? hiddencolor_width : 0), gradientType);
 852     }
 853 }
 854
 855 vector StrafeHUD_mixColors(vector color1, vector color2, float ratio)
 856 {
 857     vector mixedColor;
 858     if(ratio <= 0) return color1;
 859     if(ratio >= 1) return color2;
 860     mixedColor.x = color1.x + (color2.x - color1.x) * ratio;
 861     mixedColor.y = color1.y + (color2.y - color1.y) * ratio;
 862     mixedColor.z = color1.z + (color2.z - color1.z) * ratio;
 863     return mixedColor;
 864 }
 865
 866 void StrafeHUD_drawGradient(vector color1, vector color2, vector size, float original_width, float offset, float alpha, float gradientOffset, int gradientType)
 867 {
 868     float color_ratio, alpha1, alpha2;
 869     vector gradient_size = size;
 870     alpha1 = bound(0, alpha, 1);
 871     alpha2 = bound(0, autocvar_hud_panel_strafehud_bar_neutral_alpha, 1);
 872     if((alpha1+alpha2) == 0) return;
 873     color_ratio = alpha1/(alpha1+alpha2);
 874     for(int i = 0; i < size.x; ++i)
 875     {
 876         float ratio, alpha_ratio, combine_ratio1, combine_ratio2;
 877         gradient_size.x = size.x - i < 1 ? size.x - i : 1;
 878         ratio = (i + gradientOffset) / original_width * (gradientType == 3 ? 2 : 1);
 879         if(ratio > 1) ratio = 2 - ratio;
 880         if(gradientType != 2) ratio = 1 - ratio;
 881         alpha_ratio = alpha1 - (alpha1 - alpha2) * ratio;
 882         combine_ratio1 = ratio*(1-color_ratio);
 883         combine_ratio2 = (1-ratio)*color_ratio;
 884         ratio = (combine_ratio1 + combine_ratio2) == 0 ? 1 : combine_ratio1/(combine_ratio1 + combine_ratio2);
 885         if(alpha_ratio > 0) drawfill(panel_pos + eX * (offset + i), gradient_size, StrafeHUD_mixColors(color1, color2, ratio), alpha_ratio, DRAWFLAG_NORMAL);
 886     }
 887 }
 888
 889 // length unit conversion (km and miles are only included to match the GetSpeedUnit* functions)
 890 float GetLengthUnitFactor(int length_unit)
 891 {
 892         switch(length_unit)
 893         {
 894                 default:
 895                 case 1: return 1.0;
 896                 case 2: return 0.0254;
 897                 case 3: return 0.0254 * 0.001;
 898                 case 4: return 0.0254 * 0.001 * 0.6213711922;
 899                 case 5: return 0.0254 * 0.001 * 0.5399568035;
 900         }
 901 }
 902
 903 string GetLengthUnit(int length_unit)
 904 {
 905         switch(length_unit)
 906         {
 907                 // translator-friendly strings without the initial space
 908                 default:
 909                 case 1: return strcat(" ", _("qu"));
 910                 case 2: return strcat(" ", _("m"));
 911                 case 3: return strcat(" ", _("km"));
 912                 case 4: return strcat(" ", _("mi"));
 913                 case 5: return strcat(" ", _("nmi"));
 914         }
 915 }