qcsrc/client/hud/panel/quickmenu.qc

   1 #include "quickmenu.qh"
   2
   3 #include <client/draw.qh>
   4 #include <client/hud/_mod.qh>
   5 #include <client/mapvoting.qh>
   6 #include <common/ent_cs.qh>
   7 #include <common/minigames/cl_minigames.qh>
   8
   9 // QuickMenu (#23)
  10
  11 void HUD_QuickMenu_Export(int fh)
  12 {
  13         // allow saving cvars that aesthetically change the panel into hud skin files
  14         HUD_Write_Cvar("hud_panel_quickmenu_align");
  15 }
  16
  17 // QUICKMENU_MAXLINES must be <= 10
  18 const int QUICKMENU_MAXLINES = 10;
  19 // visible entries are loaded from QuickMenu_Buffer into QuickMenu_Page_* arrays
  20 string QuickMenu_Page_Command[QUICKMENU_MAXLINES];
  21 string QuickMenu_Page_Description[QUICKMENU_MAXLINES];
  22 int QuickMenu_Page_Command_Type[QUICKMENU_MAXLINES];
  23 int QuickMenu_Page_Entries;
  24 int QuickMenu_Page;
  25 int QuickMenu_Page_ActivatedEntry = -1;
  26 bool QuickMenu_Page_ActivatedEntry_Close;
  27 float QuickMenu_Page_ActivatedEntry_Time;
  28 bool QuickMenu_IsLastPage;
  29 // all the entries are loaded into QuickMenu_Buffer
  30 // each entry (submenu or command) is composed of 2 entries
  31 const int QUICKMENU_MAXENTRIES = 256;
  32 const int QUICKMENU_BUFFER_MAXENTRIES = 2 * QUICKMENU_MAXENTRIES;
  33 int QuickMenu_Buffer = -1;
  34 int QuickMenu_Buffer_Size;
  35 int QuickMenu_Buffer_Index;
  36 string QuickMenu_CurrentSubMenu;
  37 float QuickMenu_TimeOut;
  38
  39 // QuickMenu_Buffer are labeled with these tags
  40 #define QM_TAG_TITLE "T"
  41 #define QM_TAG_SUBMENU "S"
  42 #define QM_TAG_COMMAND "C"
  43 #define QM_TAG_PLCOMMAND "P"
  44
  45 #define QuickMenu_Buffer_Set(tag, string) bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat(tag, string))
  46 #define QuickMenu_Buffer_Get() bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index)
  47
  48 // if s1 is not empty s will be displayed as command otherwise as submenu
  49 void QuickMenu_Page_LoadEntry(int i, string s, string s1)
  50 {
  51         TC(int, i);
  52         //LOG_INFOF("^xc80 entry %d: %s, %s\n", i, s, s1);
  53         strcpy(QuickMenu_Page_Description[i], s);
  54         strcpy(QuickMenu_Page_Command[i], s1);
  55 }
  56
  57 void QuickMenu_Page_ClearEntry(int i)
  58 {
  59         TC(int, i);
  60         strfree(QuickMenu_Page_Description[i]);
  61         strfree(QuickMenu_Page_Command[i]);
  62         QuickMenu_Page_Command_Type[i] = 0;
  63 }
  64
  65 bool HUD_QuickMenu_Forbidden()
  66 {
  67         return (mv_active
  68                 || (hud_configure_prev && hud_configure_prev != -1)
  69                 || HUD_MinigameMenu_IsOpened()
  70                 || (QuickMenu_TimeOut && time > QuickMenu_TimeOut));
  71 }
  72
  73 // returns true if succeded, false otherwise
  74 bool QuickMenu_Open(string mode, string submenu, string file)
  75 {
  76         QuickMenu_TimeOut = 0;
  77         if (HUD_QuickMenu_Forbidden())
  78                 return false;
  79
  80         int fh = -1;
  81         string s;
  82
  83         if(mode == "")
  84         {
  85                 if(file == "" || file == "0")
  86                         mode = "default";
  87                 else
  88                         mode = "file";
  89         }
  90
  91         if(mode == "file")
  92         {
  93                 if(file == "" || file == "0")
  94                         LOG_INFO("No file name is set in hud_panel_quickmenu_file, loading default quickmenu");
  95                 else
  96                 {
  97                         fh = fopen(file, FILE_READ);
  98                         if(fh < 0)
  99                                 LOG_INFOF("Couldn't open file \"%s\", loading default quickmenu", file);
 100                 }
 101                 if(fh < 0)
 102                         mode = "default";
 103         }
 104
 105         if(mode == "default")
 106         {
 107                 QuickMenu_Buffer = buf_create();
 108                 if(QuickMenu_Buffer < 0)
 109                         return false;
 110
 111                 QuickMenu_Default(submenu);
 112         }
 113         else if(mode == "file")
 114         {
 115                 QuickMenu_Buffer = buf_create();
 116                 if(QuickMenu_Buffer < 0)
 117                 {
 118                         fclose(fh);
 119                         return false;
 120                 }
 121
 122                 QuickMenu_Buffer_Size = 0;
 123                 while((s = fgets(fh)) && QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES)
 124                 {
 125                         // first skip invalid entries, so we don't check them anymore
 126                         int argc;
 127                         argc = tokenize_console(s);
 128                         if(argc == 0 || argv(0) == "")
 129                                 continue;
 130                         if(argc == 1)
 131                                 QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 132                         else if(argc == 2)
 133                         {
 134                                 if(argv(1) == "")
 135                                         continue;
 136                                 QuickMenu_Buffer_Set(QM_TAG_TITLE, argv(0));
 137                                 ++QuickMenu_Buffer_Size;
 138                                 QuickMenu_Buffer_Set(QM_TAG_COMMAND, argv(1));
 139                         }
 140                         else if(argc == 3)
 141                         {
 142                                 // check for special keywords
 143                                 float teamplayers = 0, without_me = 0;
 144                                 switch(argv(2))
 145                                 {
 146                                         case "ALLPLAYERS_BUT_ME":               without_me = 1; // fall through
 147                                         case "ALLPLAYERS":                              teamplayers = 0; break;
 148                                         case "OWNTEAMPLAYERS_BUT_ME":   without_me = 1; // fall through
 149                                         case "OWNTEAMPLAYERS":                  teamplayers = 1; break;
 150                                         case "ENEMYTEAMPLAYERS":                teamplayers = 2; break;
 151                                         default: continue;
 152                                 }
 153
 154                                 if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES)
 155                                 {
 156                                         QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 157                                         ++QuickMenu_Buffer_Size;
 158                                         QuickMenu_Buffer_Set(QM_TAG_TITLE, strcat(ftos(teamplayers), ftos(without_me))); // put PLCOMMAND arguments in the title string
 159                                         ++QuickMenu_Buffer_Size;
 160                                         QuickMenu_Buffer_Set(QM_TAG_PLCOMMAND, argv(1));
 161                                         ++QuickMenu_Buffer_Size;
 162                                         QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 163                                 }
 164                         }
 165                         ++QuickMenu_Buffer_Size;
 166                 }
 167                 fclose(fh);
 168         }
 169         else
 170         {
 171                 LOG_WARNF("Unrecognized mode %s", mode);
 172                 return false;
 173         }
 174
 175         if (QuickMenu_Buffer_Size <= 0)
 176         {
 177                 buf_del(QuickMenu_Buffer);
 178                 QuickMenu_Buffer = -1;
 179                 return false;
 180         }
 181
 182         if(mode == "file")
 183                 QuickMenu_Page_Load(submenu, 0);
 184         else
 185                 QuickMenu_Page_Load("", 0);
 186
 187         hudShiftState = 0;
 188
 189         QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 190         return true;
 191 }
 192
 193 void QuickMenu_Buffer_Close()
 194 {
 195         if (QuickMenu_Buffer >= 0)
 196         {
 197                 buf_del(QuickMenu_Buffer);
 198                 QuickMenu_Buffer = -1;
 199                 QuickMenu_Buffer_Size = 0;
 200         }
 201 }
 202
 203 void QuickMenu_Close()
 204 {
 205         strfree(QuickMenu_CurrentSubMenu);
 206         int i;
 207         for (i = 0; i < QUICKMENU_MAXLINES; ++i)
 208                 QuickMenu_Page_ClearEntry(i);
 209         QuickMenu_Page_Entries = 0;
 210         mouseClicked = 0;
 211         prevMouseClicked = 0;
 212         QuickMenu_Buffer_Close();
 213 }
 214
 215 // It assumes submenu open tag is already detected
 216 void QuickMenu_skip_submenu(string submenu)
 217 {
 218         string z_submenu = string_null; strcpy(z_submenu, submenu);
 219         for(++QuickMenu_Buffer_Index ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 220         {
 221                 string s = QuickMenu_Buffer_Get();
 222                 if(substring(s, 0, 1) != QM_TAG_SUBMENU)
 223                         continue;
 224                 if(substring(s, 1, -1) == z_submenu) // submenu end
 225                         break;
 226                 QuickMenu_skip_submenu(substring(s, 1, -1));
 227         }
 228         strfree(z_submenu);
 229 }
 230
 231 bool QuickMenu_IsOpened()
 232 {
 233         return (QuickMenu_Page_Entries > 0);
 234 }
 235
 236 bool HUD_Quickmenu_PlayerListEntries_Create(string cmd, int teamplayers, bool without_me)
 237 {
 238         TC(int, teamplayers); TC(bool, without_me);
 239         int i;
 240         for(i = 0; i < QUICKMENU_MAXLINES; ++i)
 241                 QuickMenu_Page_ClearEntry(i);
 242         QuickMenu_Buffer_Close();
 243
 244         QuickMenu_Buffer = buf_create();
 245         if(QuickMenu_Buffer < 0)
 246                 return false;
 247
 248         HUD_Quickmenu_PlayerListEntries(cmd, teamplayers, without_me);
 249
 250         if(QuickMenu_Buffer_Size <= 0)
 251         {
 252                 buf_del(QuickMenu_Buffer);
 253                 QuickMenu_Buffer = -1;
 254                 return false;
 255         }
 256         return true;
 257 }
 258
 259 // new_page 0 means page 0, new_page != 0 means next page
 260 int QuickMenu_Buffer_Index_Prev;
 261 bool QuickMenu_Page_Load(string target_submenu, bool new_page)
 262 {
 263         TC(bool, new_page);
 264         string s = string_null, cmd = string_null, z_submenu;
 265
 266         QuickMenu_Page_ActivatedEntry = -1;
 267         if (new_page == 0)
 268                 QuickMenu_Page = 0;
 269         else
 270                 ++QuickMenu_Page;
 271
 272         z_submenu = strzone(target_submenu);
 273         strcpy(QuickMenu_CurrentSubMenu, z_submenu);
 274
 275         QuickMenu_IsLastPage = true;
 276         QuickMenu_Page_Entries = 0;
 277
 278         QuickMenu_Buffer_Index = 0;
 279         if (z_submenu != "")
 280         {
 281                 // skip everything until the submenu open tag is found
 282                 for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 283                 {
 284                         s = QuickMenu_Buffer_Get();
 285                         if(substring(s, 0, 1) == QM_TAG_SUBMENU && substring(s, 1, -1) == z_submenu)
 286                         {
 287                                 //LOG_INFOF("^3 beginning of %s\n", z_submenu);
 288                                 ++QuickMenu_Buffer_Index;
 289                                 break; // target_submenu found!
 290                         }
 291                         //LOG_INFOF("^1 skipping %s\n", s);
 292                 }
 293                 if(QuickMenu_Buffer_Index == QuickMenu_Buffer_Size)
 294                         LOG_WARNF("Couldn't find submenu \"%s\"", z_submenu);
 295         }
 296
 297         // only the last page can contain up to QUICKMENU_MAXLINES entries
 298         // the other ones contain only (QUICKMENU_MAXLINES - 2) entries
 299         // so that the panel can show an empty row and "Continue..."
 300         float first_entry = QuickMenu_Page * (QUICKMENU_MAXLINES - 2);
 301         int entry_num = 0; // counts entries in target_submenu
 302         for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 303         {
 304                 s = QuickMenu_Buffer_Get();
 305
 306                 if(z_submenu != "" && substring(s, 1, -1) == z_submenu)
 307                 {
 308                         //LOG_INFOF("^3 end of %s\n", z_submenu);
 309                         break;
 310                 }
 311
 312                 if(entry_num >= first_entry)
 313                 {
 314                         ++QuickMenu_Page_Entries;
 315                         if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES - 2)
 316                                 QuickMenu_Buffer_Index_Prev = QuickMenu_Buffer_Index;
 317                         else if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES)
 318                         {
 319                                 QuickMenu_Page_ClearEntry(QUICKMENU_MAXLINES - 1);
 320                                 QuickMenu_Buffer_Index = QuickMenu_Buffer_Index_Prev;
 321                                 QuickMenu_IsLastPage = false;
 322                                 break;
 323                         }
 324                 }
 325
 326                 // NOTE: entries are loaded starting from 1, not from 0
 327                 if(substring(s, 0, 1) == QM_TAG_SUBMENU)
 328                 {
 329                         if(entry_num >= first_entry)
 330                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), "");
 331                         QuickMenu_skip_submenu(substring(s, 1, -1));
 332                 }
 333                 else if(substring(s, 0, 1) == QM_TAG_TITLE)
 334                 {
 335                         ++QuickMenu_Buffer_Index;
 336                         if(entry_num >= first_entry)
 337                         {
 338                                 cmd = QuickMenu_Buffer_Get();
 339                                 string command_code = substring(cmd, 0, 1);
 340                                 if(command_code == QM_TAG_COMMAND)
 341                                         cmd = substring(cmd, 1, -1);
 342                                 else if(command_code == QM_TAG_PLCOMMAND)
 343                                 {
 344                                         // throw away the current quickmenu buffer and load a new one
 345                                         cmd = substring(cmd, 1, -1);
 346                                         strunzone(z_submenu);
 347                                         if(HUD_Quickmenu_PlayerListEntries_Create(cmd, stof(substring(s, 1, 1)), stof(substring(s, 2, 1))))
 348                                                 return QuickMenu_Page_Load("", 0);
 349                                         QuickMenu_Close();
 350                                         return false;
 351                                 }
 352
 353                                 tokenize_console(cmd);
 354                                 QuickMenu_Page_Command_Type[QuickMenu_Page_Entries] = (argv(1) && argv(0) == "toggle");
 355
 356                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), cmd);
 357                         }
 358
 359                 }
 360
 361                 ++entry_num;
 362         }
 363         strunzone(z_submenu);
 364         if (QuickMenu_Page_Entries == 0)
 365         {
 366                 QuickMenu_Close();
 367                 return false;
 368         }
 369         QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 370         return true;
 371 }
 372
 373 bool QuickMenu_ActionForNumber(int num)
 374 {
 375         TC(int, num);
 376         if (!QuickMenu_IsLastPage)
 377         {
 378                 if (num < 0 || num >= QUICKMENU_MAXLINES)
 379                         return false;
 380                 if (num == QUICKMENU_MAXLINES - 1)
 381                         return false;
 382                 if (num == 0)
 383                 {
 384                         QuickMenu_Page_Load(QuickMenu_CurrentSubMenu, +1);
 385                         return false;
 386                 }
 387         } else if (num <= 0 || num > QuickMenu_Page_Entries)
 388                 return false;
 389
 390         if (QuickMenu_Page_Command[num] != "")
 391         {
 392                 QuickMenu_Page_ActivatedEntry_Time = time + 0.1;
 393                 localcmd(strcat("\n", QuickMenu_Page_Command[num], "\n"));
 394                 QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 395                 return true;
 396         }
 397         if (QuickMenu_Page_Description[num] != "")
 398                 QuickMenu_Page_Load(QuickMenu_Page_Description[num], 0);
 399         return false;
 400 }
 401
 402 void QuickMenu_Page_ActiveEntry(int entry_num)
 403 {
 404         TC(int, entry_num);
 405         QuickMenu_Page_ActivatedEntry = entry_num;
 406         if(QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 407         {
 408                 bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 409                 // toggle commands don't close the quickmenu
 410                 if(QuickMenu_Page_Command_Type[QuickMenu_Page_ActivatedEntry] == 1)
 411                         QuickMenu_Page_ActivatedEntry_Close = false;
 412                 else
 413                         QuickMenu_Page_ActivatedEntry_Close = (f && !(hudShiftState & S_CTRL));
 414         }
 415         else
 416                 QuickMenu_Page_ActivatedEntry_Close = (!(hudShiftState & S_CTRL));
 417 }
 418
 419 bool QuickMenu_InputEvent(int bInputType, float nPrimary, float nSecondary)
 420 {
 421         TC(int, bInputType);
 422         // we only care for keyboard events
 423         if(bInputType == 2)
 424                 return false;
 425
 426         if(!QuickMenu_IsOpened() || autocvar__hud_configure || mv_active)
 427                 return false;
 428
 429         if(bInputType == 3)
 430         {
 431                 mousepos.x = nPrimary;
 432                 mousepos.y = nSecondary;
 433                 return true;
 434         }
 435
 436         // allow console bind to work
 437         string con_keys = findkeysforcommand("toggleconsole", 0);
 438         int keys = tokenize(con_keys); // findkeysforcommand returns data for this
 439         bool hit_con_bind = false;
 440         int i;
 441         for (i = 0; i < keys; ++i)
 442         {
 443                 if(nPrimary == stof(argv(i)))
 444                         hit_con_bind = true;
 445         }
 446
 447         if(bInputType == 0) {
 448                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 449                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 450                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 451         }
 452         else if(bInputType == 1) {
 453                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 454                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 455                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 456         }
 457
 458         if(nPrimary == K_ESCAPE)
 459         {
 460                 if (bInputType == 1)
 461                         return true;
 462                 QuickMenu_Close();
 463         }
 464         else if(nPrimary >= '0' && nPrimary <= '9')
 465         {
 466                 if (bInputType == 1)
 467                         return true;
 468                 QuickMenu_Page_ActiveEntry(stof(chr2str(nPrimary)));
 469         }
 470         if(nPrimary == K_MOUSE1)
 471         {
 472                 if(bInputType == 0) // key pressed
 473                         mouseClicked |= S_MOUSE1;
 474                 else if(bInputType == 1) // key released
 475                         mouseClicked -= (mouseClicked & S_MOUSE1);
 476         }
 477         else if(nPrimary == K_MOUSE2)
 478         {
 479                 if(bInputType == 0) // key pressed
 480                         mouseClicked |= S_MOUSE2;
 481                 else if(bInputType == 1) // key released
 482                         mouseClicked -= (mouseClicked & S_MOUSE2);
 483         }
 484         else if(hit_con_bind)
 485                 return false;
 486
 487         return true;
 488 }
 489
 490 void QuickMenu_Mouse()
 491 {
 492         if(mv_active) return;
 493
 494         if(!mouseClicked)
 495         if(prevMouseClicked & S_MOUSE2)
 496         {
 497                 QuickMenu_Close();
 498                 return;
 499         }
 500
 501         panel = HUD_PANEL(QUICKMENU);
 502         HUD_Panel_LoadCvars();
 503
 504         if(panel_bg_padding)
 505         {
 506                 panel_pos += '1 1 0' * panel_bg_padding;
 507                 panel_size -= '2 2 0' * panel_bg_padding;
 508         }
 509
 510         float first_entry_pos, entries_height;
 511         vector fontsize;
 512         fontsize = '1 1 0' * (panel_size.y / QUICKMENU_MAXLINES);
 513         first_entry_pos = panel_pos.y + ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y) / 2;
 514         entries_height = panel_size.y - ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y);
 515
 516         if (mousepos.x >= panel_pos.x && mousepos.y >= first_entry_pos && mousepos.x <= panel_pos.x + panel_size.x && mousepos.y <= first_entry_pos + entries_height)
 517         {
 518                 int entry_num = min(QuickMenu_Page_Entries - 1, floor((mousepos.y - first_entry_pos) / fontsize.y));
 519                 if (QuickMenu_IsLastPage || entry_num != QUICKMENU_MAXLINES - 2)
 520                 {
 521                         if(!mouseClicked && (prevMouseClicked & S_MOUSE1))
 522                                 QuickMenu_Page_ActiveEntry((entry_num < QUICKMENU_MAXLINES - 1) ? entry_num + 1 : 0);
 523
 524                         if (time > QuickMenu_Page_ActivatedEntry_Time)
 525                         {
 526                                 vector entry_pos = panel_pos;
 527                                 entry_pos.y = first_entry_pos + entry_num * fontsize.y;
 528                                 vector color;
 529                                 if (mouseClicked & S_MOUSE1)
 530                                         color = '0.5 1 0.5';
 531                                 else if (hudShiftState & S_CTRL)
 532                                         color = '1 1 0.3';
 533                                 else
 534                                         color = '1 1 1';
 535                                 drawfill(entry_pos, vec2(panel_size.x, fontsize.y), color, .2, DRAWFLAG_NORMAL);
 536                         }
 537                 }
 538         }
 539 }
 540
 541 void HUD_Quickmenu_DrawEntry(vector pos, string desc, string option, vector fontsize)
 542 {
 543         string entry;
 544         float offset;
 545         float desc_width = panel_size.x;
 546         if(option)
 547         {
 548                 string pic = strcat(hud_skin_path, "/", option);
 549                 if(precache_pic(pic) == "")
 550                         pic = strcat("gfx/hud/default/", option);
 551                 vector option_size = '1 1 0' * fontsize.y * 0.8;
 552                 desc_width -= option_size.x;
 553                 drawpic(pos + vec2(desc_width, (fontsize.y - option_size.y) / 2), pic, option_size, '1 1 1', panel_fg_alpha, DRAWFLAG_ADDITIVE);
 554                 desc_width -= fontsize.x / 4;
 555         }
 556         entry = textShortenToWidth(desc, desc_width, fontsize, stringwidth_colors);
 557         if (autocvar_hud_panel_quickmenu_align > 0)
 558         {
 559                 float real_desc_width = stringwidth_colors(entry, fontsize);
 560                 offset = (desc_width - real_desc_width) * min(autocvar_hud_panel_quickmenu_align, 1);
 561
 562                 if(option)
 563                 {
 564                         // when there's enough room align description regardless the checkbox
 565                         float extra_offset = (panel_size.x - desc_width) * min(autocvar_hud_panel_quickmenu_align, 1);
 566                         if(offset + real_desc_width + extra_offset < desc_width)
 567                                 offset += extra_offset;
 568                         else
 569                                 offset = max(0, desc_width - real_desc_width);
 570                 }
 571                 drawcolorcodedstring(pos + eX * offset, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 572         }
 573         else
 574                 drawcolorcodedstring(pos, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 575 }
 576
 577 void HUD_QuickMenu()
 578 {
 579         if(!autocvar__hud_configure)
 580         {
 581                 if (!hud_draw_maximized || !QuickMenu_IsOpened())
 582                         return;
 583
 584                 if (HUD_QuickMenu_Forbidden())
 585                 {
 586                         QuickMenu_Close();
 587                         return;
 588                 }
 589         }
 590         else
 591         {
 592                 if(!QuickMenu_IsOpened())
 593                 {
 594                         QuickMenu_Page_Entries = 1;
 595                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 596                         ++QuickMenu_Page_Entries;
 597                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 598                         ++QuickMenu_Page_Entries;
 599                         // although real command doesn't matter here, it must not be empty
 600                         // otherwise the entry is displayed like a submenu
 601                         for (; QuickMenu_Page_Entries < QUICKMENU_MAXLINES - 1; ++QuickMenu_Page_Entries)
 602                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Command%d"), QuickMenu_Page_Entries), "-");
 603                         ++QuickMenu_Page_Entries;
 604                         QuickMenu_Page_ClearEntry(QuickMenu_Page_Entries);
 605                         QuickMenu_IsLastPage = false;
 606                 }
 607         }
 608
 609         HUD_Panel_LoadCvars();
 610
 611         HUD_Scale_Disable();
 612         HUD_Panel_DrawBg();
 613
 614         if(panel_bg_padding)
 615         {
 616                 panel_pos += '1 1 0' * panel_bg_padding;
 617                 panel_size -= '2 2 0' * panel_bg_padding;
 618         }
 619
 620         int i;
 621         vector fontsize;
 622         string color;
 623         fontsize = '1 1 0' * (panel_size.y / QUICKMENU_MAXLINES);
 624
 625         if (!QuickMenu_IsLastPage)
 626         {
 627                 color = "^5";
 628                 HUD_Quickmenu_DrawEntry(panel_pos + eY * (panel_size.y - fontsize.y), sprintf("%d: %s%s", 0, color, _("Continue...")), string_null, fontsize);
 629         }
 630         else
 631                 panel_pos.y += ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y) / 2;
 632
 633         for (i = 1; i <= QuickMenu_Page_Entries; ++i) {
 634                 if (QuickMenu_Page_Description[i] == "")
 635                         break;
 636                 string option = string_null;
 637                 if (QuickMenu_Page_Command[i] == "")
 638                         color = "^4";
 639                 else
 640                 {
 641                         color = "^3";
 642                         if(QuickMenu_Page_Command_Type[i] == 1) // toggle command
 643                         {
 644                                 int end = strstrofs(QuickMenu_Page_Command[i], ";", 0);
 645                                 if(end < 0)
 646                                         tokenize_console(QuickMenu_Page_Command[i]);
 647                                 else
 648                                         tokenize_console(substring(QuickMenu_Page_Command[i], 0, end));
 649
 650                                 if(argv(1) && argv(0) == "toggle")
 651                                 {
 652                                         // "enable feature xxx" "toggle xxx" (or "toggle xxx 1 0")
 653                                         // "disable feature xxx" "toggle xxx 0 1"
 654                                         float ON_value = 1, OFF_value = 0;
 655                                         if(argv(2))
 656                                                 ON_value = stof(argv(2));
 657
 658                                         if(argv(3))
 659                                                 OFF_value = stof(argv(3));
 660                                         else
 661                                                 OFF_value = !ON_value;
 662
 663                                         float value = cvar(argv(1));
 664                                         if(value == ON_value)
 665                                                 option = "checkbox_checked";
 666                                         else if(value == OFF_value)
 667                                                 option = "checkbox_empty";
 668                                         else
 669                                                 option = "checkbox_undefined";
 670                                 }
 671                         }
 672                 }
 673                 HUD_Quickmenu_DrawEntry(panel_pos, sprintf("%d: %s%s", i, color, QuickMenu_Page_Description[i]), option, fontsize);
 674
 675                 if (time < QuickMenu_Page_ActivatedEntry_Time && QuickMenu_Page_ActivatedEntry == i)
 676                         drawfill(panel_pos, vec2(panel_size.x, fontsize.y), '0.5 1 0.5', .2, DRAWFLAG_NORMAL);
 677
 678                 panel_pos.y += fontsize.y;
 679         }
 680
 681         if(QuickMenu_Page_ActivatedEntry >= 0 && time >= QuickMenu_Page_ActivatedEntry_Time)
 682         {
 683                 if(!QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 684                 {
 685                         bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 686                         if(f && QuickMenu_Page_ActivatedEntry_Close)
 687                                 QuickMenu_Close();
 688                 }
 689                 else if(QuickMenu_Page_ActivatedEntry_Close)
 690                         QuickMenu_Close();
 691                 QuickMenu_Page_ActivatedEntry = -1;
 692                 QuickMenu_Page_ActivatedEntry_Time = 0;
 693         }
 694 }
 695
 696
 697 #define QUICKMENU_SMENU(submenu,eng_submenu) { \
 698         if(target_submenu == eng_submenu && target_submenu_found) \
 699                 return; /* target_submenu entries are now loaded, exit */ \
 700         if(QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES) \
 701                 QuickMenu_Buffer_Set(QM_TAG_SUBMENU, submenu); \
 702         ++QuickMenu_Buffer_Size; \
 703         if(target_submenu == eng_submenu && !target_submenu_found) { \
 704                 QuickMenu_Buffer_Size = 0; /* enable load of next entries */ \
 705                 target_submenu_found = true; \
 706         } \
 707 }
 708
 709 #define QUICKMENU_ENTRY(title,command) { \
 710         if(QuickMenu_Buffer_Size + 1 < QUICKMENU_BUFFER_MAXENTRIES) \
 711         { \
 712                 QuickMenu_Buffer_Set(QM_TAG_TITLE, title); \
 713                 ++QuickMenu_Buffer_Size; \
 714                 QuickMenu_Buffer_Set(QM_TAG_COMMAND, command); \
 715         } \
 716         ++QuickMenu_Buffer_Size; \
 717 }
 718
 719 #define QUICKMENU_SMENU_PL(submenu,eng_submenu,command,teamplayers,without_me) { \
 720         if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES) {\
 721                 QUICKMENU_SMENU(submenu,eng_submenu) \
 722                 QuickMenu_Buffer_Set(QM_TAG_TITLE, strcat(ftos(teamplayers), ftos(without_me))); \
 723                 ++QuickMenu_Buffer_Size; \
 724                 QuickMenu_Buffer_Set(QM_TAG_PLCOMMAND, command); \
 725                 ++QuickMenu_Buffer_Size; \
 726                 QUICKMENU_SMENU(submenu,eng_submenu) \
 727         } \
 728 }
 729
 730
 731
 732 // useful to Translate a string inside the Command
 733 #define QUICKMENU_ENTRY_TC(title,command,text,translated_text) {\
 734         if(prvm_language == "en") { \
 735                 tc_title = title; \
 736                 tc_cmd = sprintf(command, text); \
 737         } \
 738         else if(!autocvar_hud_panel_quickmenu_translatecommands || translated_text == text) { \
 739                 tc_title = strcat("(en)", title); \
 740                 tc_cmd = sprintf(command, text); \
 741         } \
 742         else { \
 743                 tc_title = strcat("(", prvm_language, ")", title); \
 744                 tc_cmd = sprintf(command, translated_text); \
 745         } \
 746         QUICKMENU_ENTRY(tc_title, tc_cmd) \
 747 }
 748
 749 void HUD_Quickmenu_PlayerListEntries(string cmd, int teamplayers, bool without_me)
 750 {
 751         TC(int, teamplayers); TC(bool, without_me);
 752         entity pl;
 753         if(teamplayers && !team_count)
 754                 return;
 755
 756         for(pl = players.sort_next; pl; pl = pl.sort_next)
 757         {
 758                 if(teamplayers == 1 && (pl.team != myteam || pl.team == NUM_SPECTATOR)) // only own team players
 759                         continue;
 760                 if(teamplayers == 2 && (pl.team == myteam || pl.team == NUM_SPECTATOR)) // only enemy team players
 761                         continue;
 762                 if(without_me && pl.sv_entnum == player_localnum)
 763                         continue;
 764                 QUICKMENU_ENTRY(entcs_GetName(pl.sv_entnum), sprintf(cmd, entcs_GetName(pl.sv_entnum)))
 765         }
 766
 767         return;
 768 }
 769
 770
 771 // Specifying target_submenu, this function only loads entries inside target_submenu
 772 // NOTE: alternatively we could have loaded the whole default quickmenu and
 773 // then called QuickMenu_Page_Load(target_submenu, 0);
 774 // but this sytem is more reliable since we can always refer to target_submenu
 775 // with the English title even if a translation is active
 776 void QuickMenu_Default(string target_submenu)
 777 {
 778         bool target_submenu_found = false;
 779         if(target_submenu != "")
 780                 QuickMenu_Buffer_Size = QUICKMENU_BUFFER_MAXENTRIES; // forbids load of next entries until target_submenu
 781
 782         string tc_title;
 783         string tc_cmd;
 784
 785         QUICKMENU_SMENU(_("Chat"), "Chat")
 786                 QUICKMENU_SMENU_PL(CTX(_("QMCMD^Send public message to")), "Send public message to", "commandmode say %s:^7", 0, 1)
 787                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^nice one")), "say %s", ":-) / nice one", CTX(_("QMCMD^:-) / nice one")))
 788                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^good game")), "say %s", "good game", CTX(_("QMCMD^good game")))
 789                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^hi / good luck")), "say %s", "hi / good luck and have fun", CTX(_("QMCMD^hi / good luck and have fun")))
 790                 if(prvm_language != "en")
 791                 QUICKMENU_ENTRY(CTX(_("QMCMD^Send in English")), "toggle hud_panel_quickmenu_translatecommands 0 1; quickmenu; wait; quickmenu default Chat")
 792         QUICKMENU_SMENU(_("Chat"), "Chat")
 793
 794         if(teamplay)
 795         {
 796         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 797                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^strength soon")), "say_team %s", "strength soon", CTX(_("QMCMD^strength soon")))
 798                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^free item, icon")), "say_team %s; g_waypointsprite_team_here_p", "free item %x^7 (l:%y^7)", CTX(_("QMCMD^free item %x^7 (l:%y^7)")))
 799                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^took item, icon")), "say_team %s; g_waypointsprite_team_here", "took item (l:%l^7)", CTX(_("QMCMD^took item (l:%l^7)")))
 800                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^negative")), "say_team %s", "negative", CTX(_("QMCMD^negative")))
 801                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^positive")), "say_team %s", "positive", CTX(_("QMCMD^positive")))
 802                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^need help, icon")), "say_team %s; g_waypointsprite_team_helpme; cmd voice needhelp", "need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 803                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^enemy seen, icon")), "say_team %s; g_waypointsprite_team_danger_p; cmd voice incoming", "enemy seen (l:%y^7)", CTX(_("QMCMD^enemy seen (l:%y^7)")))
 804                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^flag seen, icon")), "say_team %s; g_waypointsprite_team_here_p; cmd voice seenflag", "flag seen (l:%y^7)", CTX(_("QMCMD^flag seen (l:%y^7)")))
 805                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^defending, icon")), "say_team %s; g_waypointsprite_team_here", "defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 806                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^roaming, icon")), "say_team %s; g_waypointsprite_team_here", "roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 807                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^attacking, icon")), "say_team %s; g_waypointsprite_team_here", "attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 808                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^killed flagcarrier, icon")), "say_team %s; g_waypointsprite_team_here_p", "killed flagcarrier (l:%y^7)", CTX(_("QMCMD^killed flagcarrier (l:%y^7)")))
 809                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^dropped flag, icon")), "say_team %s; g_waypointsprite_team_here_d", "dropped flag (l:%d^7)", CTX(_("QMCMD^dropped flag (l:%d^7)")))
 810                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop weapon, icon")), "say_team %s; g_waypointsprite_team_here; wait; dropweapon", "dropped gun %w^7 (l:%l^7)", CTX(_("QMCMD^dropped weapon %w^7 (l:%l^7)")))
 811                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop flag/key, icon")), "say_team %s; g_waypointsprite_team_here; wait; use", "dropped flag/key %w^7 (l:%l^7)", CTX(_("QMCMD^dropped flag/key %w^7 (l:%l^7)")))
 812         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 813         }
 814
 815         QUICKMENU_SMENU_PL(CTX(_("QMCMD^Send private message to")), "Send private message to", "commandmode tell \"%s^7\"", 0, 1)
 816
 817         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 818                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 819                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person view")), "toggle chase_active")
 820                         QUICKMENU_ENTRY(CTX(_("QMCMD^Player models like mine")), "toggle cl_forceplayermodels")
 821                         QUICKMENU_ENTRY(CTX(_("QMCMD^Names above players")), "toggle hud_shownames")
 822                         QUICKMENU_ENTRY(CTX(_("QMCMD^Crosshair per weapon")), "toggle crosshair_per_weapon")
 823                         QUICKMENU_ENTRY(CTX(_("QMCMD^FPS")), "toggle hud_panel_engineinfo")
 824                         QUICKMENU_ENTRY(CTX(_("QMCMD^Net graph")), "toggle shownetgraph")
 825                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 826
 827                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 828                         QUICKMENU_ENTRY(CTX(_("QMCMD^Hit sound")), "toggle cl_hitsound")
 829                         QUICKMENU_ENTRY(CTX(_("QMCMD^Chat sound")), "toggle con_chatsound")
 830                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 831
 832                 if(spectatee_status > 0)
 833                 {
 834                 QUICKMENU_ENTRY(CTX(_("QMCMD^Change spectator camera")), "dropweapon")
 835                 }
 836
 837                 if(spectatee_status == -1)
 838                 {
 839                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 840                         QUICKMENU_ENTRY(CTX(_("QMCMD^Increase speed")), "weapnext")
 841                         QUICKMENU_ENTRY(CTX(_("QMCMD^Decrease speed")), "weapprev")
 842                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision")), "toggle cl_clippedspectating")
 843                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 844                 }
 845
 846                 QUICKMENU_ENTRY(CTX(_("QMCMD^Fullscreen")), "toggle vid_fullscreen; vid_restart")
 847         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 848
 849         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 850                 QUICKMENU_ENTRY(CTX(_("QMCMD^Restart the map")), "vcall restart")
 851                 QUICKMENU_ENTRY(CTX(_("QMCMD^End match")), "vcall endmatch")
 852                 if(STAT(TIMELIMIT) > 0)
 853                 {
 854                 QUICKMENU_ENTRY(CTX(_("QMCMD^Reduce match time")), "vcall reducematchtime")
 855                 QUICKMENU_ENTRY(CTX(_("QMCMD^Extend match time")), "vcall extendmatchtime")
 856                 }
 857                 if(teamplay)
 858                 QUICKMENU_ENTRY(CTX(_("QMCMD^Shuffle teams")), "vcall shuffleteams")
 859         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 860
 861         if(spectatee_status != 0)
 862         {
 863         QUICKMENU_SMENU_PL(CTX(_("QMCMD^Spectate a player")), "Spectate a player", "spectate \"%s^7\"", 0, 1)
 864         }
 865
 866         if(target_submenu != "" && !target_submenu_found)
 867         {
 868                 LOG_INFOF("Couldn't find submenu \"%s\"", target_submenu);
 869                 if(prvm_language != "en")
 870                         LOG_INFO("^3Warning: submenu title must be in English");
 871                 QuickMenu_Buffer_Size = 0;
 872         }
 873 }
 874 #undef QUICKMENU_SMENU
 875 #undef QUICKMENU_ENTRY
 876 #undef QUICKMENU_ENTRY_TC