qcsrc/client/hud/crosshair.qc

   1 #include "crosshair.qh"
   2
   3 #include <client/draw.qh>
   4 #include <client/hud/panel/scoreboard.qh>
   5 #include <client/view.qh>
   6 #include <common/deathtypes/all.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/mapobjects/trigger/viewloc.qh>
   9 #include <common/minigames/cl_minigames.qh>
  10 #include <common/minigames/cl_minigames_hud.qh>
  11 #include <common/mutators/mutator/overkill/oknex.qh>
  12 #include <common/vehicles/all.qh>
  13 #include <common/viewloc.qh>
  14 #include <common/wepent.qh>
  15 #include <lib/csqcmodel/cl_player.qh>
  16
  17 float pickup_crosshair_time, pickup_crosshair_size;
  18 float hitindication_crosshair_size;
  19 float use_vortex_chargepool;
  20
  21 float reticle_type;
  22
  23 vector wcross_origin;
  24 float wcross_scale_prev, wcross_alpha_prev;
  25 vector wcross_color_prev;
  26 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
  27 vector wcross_color_goal_prev;
  28 float wcross_changedonetime;
  29
  30 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
  31 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
  32 float wcross_name_changestarttime, wcross_name_changedonetime;
  33 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
  34
  35 float wcross_ring_prev;
  36
  37 entity trueaim;
  38 entity trueaim_rifle;
  39
  40 const float SHOTTYPE_HITTEAM = 1;
  41 const float SHOTTYPE_HITOBSTRUCTION = 2;
  42 const float SHOTTYPE_HITWORLD = 3;
  43 const float SHOTTYPE_HITENEMY = 4;
  44
  45 void TrueAim_Init()
  46 {
  47         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  48         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  49 }
  50
  51 float EnemyHitCheck()
  52 {
  53         float t, n;
  54         wcross_origin = project_3d_to_2d(trace_endpos);
  55         wcross_origin.z = 0;
  56         if(trace_ent)
  57                 n = trace_ent.entnum;
  58         else
  59                 n = trace_networkentity;
  60         if(n < 1)
  61                 return SHOTTYPE_HITWORLD;
  62         if(n > maxclients)
  63                 return SHOTTYPE_HITWORLD;
  64         t = entcs_GetTeam(n - 1);
  65         if(teamplay)
  66                 if(t == myteam)
  67                         return SHOTTYPE_HITTEAM;
  68         if(t == NUM_SPECTATOR)
  69                 return SHOTTYPE_HITWORLD;
  70         return SHOTTYPE_HITENEMY;
  71 }
  72
  73 float TrueAimCheck(entity wepent)
  74 {
  75         if(wepent.activeweapon.spawnflags & WEP_FLAG_NOTRUEAIM)
  76                 return SHOTTYPE_HITWORLD;
  77
  78         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
  79         vector vecs, trueaimpoint, w_shotorg;
  80         vector mi, ma, dv;
  81         float shottype;
  82         entity ta;
  83         float mv;
  84
  85         mi = ma = '0 0 0';
  86         ta = trueaim;
  87         mv = MOVE_NOMONSTERS;
  88
  89         switch(wepent.activeweapon) // WEAPONTODO
  90         {
  91                 case WEP_VORTEX:
  92                 case WEP_OVERKILL_NEX:
  93                 case WEP_VAPORIZER:
  94                         mv = MOVE_NORMAL;
  95                         break;
  96                 case WEP_RIFLE:
  97                         ta = trueaim_rifle;
  98                         mv = MOVE_NORMAL;
  99                         if(zoomscript_caught)
 100                         {
 101                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 102                                 return EnemyHitCheck();
 103                         }
 104                         break;
 105                 case WEP_DEVASTATOR: // projectile has a size!
 106                         mi = '-3 -3 -3';
 107                         ma = '3 3 3';
 108                         break;
 109                 case WEP_FIREBALL: // projectile has a size!
 110                         mi = '-16 -16 -16';
 111                         ma = '16 16 16';
 112                         break;
 113                 case WEP_SEEKER: // projectile has a size!
 114                         mi = '-2 -2 -2';
 115                         ma = '2 2 2';
 116                         break;
 117                 case WEP_ELECTRO: // projectile has a size!
 118                         mi = '0 0 -3';
 119                         ma = '0 0 -3';
 120                         break;
 121         }
 122
 123         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 124
 125         vecs = decompressShotOrigin(STAT(SHOTORG));
 126
 127         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 128         trueaimpoint = trace_endpos;
 129         // move trueaimpoint a little bit forward to make the final tracebox reliable
 130         // since it sometimes doesn't reach a teammate by a hair
 131         trueaimpoint += view_forward;
 132
 133         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 134                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 135
 136         if(vecs.x > 0)
 137                 vecs.y = -vecs.y;
 138         else
 139                 vecs = '0 0 0';
 140
 141         dv = view_right * vecs.y + view_up * vecs.z;
 142         w_shotorg = traceorigin + dv;
 143
 144         // now move the vecs forward as much as requested if possible
 145         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 146         w_shotorg = trace_endpos - view_forward * nudge;
 147
 148         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 149         shottype = EnemyHitCheck();
 150         if(shottype != SHOTTYPE_HITWORLD)
 151                 return shottype;
 152
 153 #if 0
 154         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 155         // or rather, I know why, but see no fix
 156         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 157                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 158                 return SHOTTYPE_HITOBSTRUCTION;
 159 #endif
 160
 161         return SHOTTYPE_HITWORLD;
 162 }
 163
 164 void HUD_Crosshair_Vehicle(entity this)
 165 {
 166         if(hud != HUD_BUMBLEBEE_GUN)
 167         {
 168                 Vehicle info = REGISTRY_GET(Vehicles, hud);
 169                 info.vr_crosshair(info, this);
 170         }
 171 }
 172
 173 vector crosshair_getcolor(entity this, float health_stat)
 174 {
 175         static float rainbow_last_flicker;
 176         static vector rainbow_prev_color;
 177         vector wcross_color = '0 0 0';
 178         switch(autocvar_crosshair_color_special)
 179         {
 180                 case 1: // weapon color
 181                 {
 182                         if(this != WEP_Null && hud == HUD_NORMAL)
 183                         {
 184                                 wcross_color = this.wpcolor;
 185                                 break;
 186                         }
 187                         else { goto normalcolor; }
 188                 }
 189
 190                 case 2: // color based on health and armor
 191                 {
 192                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
 193                         float health_and_armor = floor(v.x + 1);
 194                         wcross_color = HUD_Get_Num_Color(health_and_armor, 200, false);
 195                         break;
 196                 }
 197
 198                 case 3: // rainbow/random color
 199                 {
 200                         if(time >= rainbow_last_flicker)
 201                         {
 202                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 203                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 204                         }
 205                         wcross_color = rainbow_prev_color;
 206                         break;
 207                 }
 208 LABEL(normalcolor)
 209                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 210         }
 211
 212         return wcross_color;
 213 }
 214
 215 void HUD_Crosshair(entity this)
 216 {
 217         // reset player's alpha here upon death since forced scoreboard prevents running the crosshair_chase code
 218         if(autocvar_chase_active > 0 && autocvar_crosshair_chase && STAT(HEALTH) <= 0 && csqcplayer)
 219                 csqcplayer.alpha = csqcplayer.m_alpha;
 220
 221         float f, i, j;
 222         vector v;
 223         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) && !autocvar_cl_lockview
 224                 && spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair)
 225                 && !HUD_MinigameMenu_IsOpened())
 226         {
 227                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 228                         return;
 229
 230                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 231                         return;
 232
 233                 if (hud != HUD_NORMAL)
 234                 {
 235                         HUD_Crosshair_Vehicle(this);
 236                         return;
 237                 }
 238
 239                 string wcross_style;
 240                 float wcross_alpha, wcross_resolution;
 241                 wcross_style = autocvar_crosshair;
 242                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
 243                         wcross_style = autocvar_crosshair_2d;
 244                 if (wcross_style == "0")
 245                         return;
 246                 wcross_resolution = autocvar_crosshair_size;
 247                 if (wcross_resolution == 0)
 248                         return;
 249                 wcross_alpha = autocvar_crosshair_alpha;
 250                 if (wcross_alpha == 0)
 251                         return;
 252
 253                 // TrueAim check
 254                 float shottype;
 255
 256                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 257                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
 258                         wcross_origin = viewloc_mousepos;
 259                 else if(autocvar_chase_active > 0 && autocvar_crosshair_chase)
 260                 {
 261                         vector player_org = ((csqcplayer) ? csqcplayer.origin + csqcplayer.view_ofs : view_origin);
 262                         if(csqcplayer && autocvar_crosshair_chase_playeralpha && autocvar_crosshair_chase_playeralpha < 1)
 263                         {
 264                                 traceline(view_origin, view_origin + max_shot_distance * view_forward, MOVE_NORMAL, NULL);
 265                                 float myalpha = (!csqcplayer.m_alpha) ? 1 : csqcplayer.m_alpha;
 266                                 if(trace_ent == csqcplayer)
 267                                         csqcplayer.alpha = min(autocvar_crosshair_chase_playeralpha, myalpha);
 268                                 else
 269                                         csqcplayer.alpha = csqcplayer.m_alpha;
 270                         }
 271                         traceline(player_org, player_org + max_shot_distance * view_forward, MOVE_WORLDONLY, NULL);
 272                         wcross_origin = project_3d_to_2d(trace_endpos);
 273                 }
 274                 else
 275                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
 276                 wcross_origin.z = 0;
 277                 if(autocvar_crosshair_hittest)
 278                 {
 279                         vector wcross_oldorigin;
 280                         entity thiswep = viewmodels[0]; // TODO: unhardcode
 281                         wcross_oldorigin = wcross_origin;
 282                         shottype = TrueAimCheck(thiswep);
 283                         if(shottype == SHOTTYPE_HITWORLD)
 284                         {
 285                                 v = wcross_origin - wcross_oldorigin;
 286                                 v.x /= vid_conwidth;
 287                                 v.y /= vid_conheight;
 288                                 if(vdist(v, >, 0.01))
 289                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 290                         }
 291                         if(!autocvar_crosshair_hittest_showimpact)
 292                                 wcross_origin = wcross_oldorigin;
 293                 }
 294                 else
 295                         shottype = SHOTTYPE_HITWORLD;
 296
 297                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 298                 string wcross_name = "";
 299                 float wcross_scale, wcross_blur;
 300
 301                 entity e = WEP_Null;
 302                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 303                 {
 304                         entity wepent = viewmodels[0]; // TODO: unhardcode
 305                         e = wepent.switchingweapon;
 306                         if(e)
 307                         {
 308                                 if(autocvar_crosshair_per_weapon)
 309                                 {
 310                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 311                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 312                                         //if (wcross_resolution == 0)
 313                                                 //return;
 314
 315                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 316                                         wcross_resolution *= e.w_crosshair_size;
 317                                         wcross_name = e.w_crosshair;
 318                                 }
 319                         }
 320                 }
 321
 322                 if(wcross_name == "")
 323                         wcross_name = strcat("gfx/crosshair", wcross_style);
 324
 325                 // MAIN CROSSHAIR COLOR DECISION
 326                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
 327
 328                 if(autocvar_crosshair_effect_scalefade)
 329                 {
 330                         wcross_scale = wcross_resolution;
 331                         wcross_resolution = 1;
 332                 }
 333                 else
 334                 {
 335                         wcross_scale = 1;
 336                 }
 337
 338                 if(autocvar_crosshair_pickup)
 339                 {
 340                         float stat_pickup_time = STAT(LAST_PICKUP);
 341
 342                         if(pickup_crosshair_time < stat_pickup_time)
 343                         {
 344                                 if(time - stat_pickup_time < 5) // don't trigger the animation if it's too old
 345                                         pickup_crosshair_size = 1;
 346
 347                                 pickup_crosshair_time = stat_pickup_time;
 348                         }
 349
 350                         if(pickup_crosshair_size > 0)
 351                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 352                         else
 353                                 pickup_crosshair_size = 0;
 354
 355                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 356                 }
 357
 358                 // todo: make crosshair hit indication dependent on damage dealt
 359                 if(autocvar_crosshair_hitindication)
 360                 {
 361                         vector col = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
 362
 363                         if(unaccounted_damage)
 364                         {
 365                                 hitindication_crosshair_size = 1;
 366                         }
 367
 368                         if(hitindication_crosshair_size > 0)
 369                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
 370                         else
 371                                 hitindication_crosshair_size = 0;
 372
 373                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
 374                         wcross_color.x += sin(hitindication_crosshair_size) * col.x;
 375                         wcross_color.y += sin(hitindication_crosshair_size) * col.y;
 376                         wcross_color.z += sin(hitindication_crosshair_size) * col.z;
 377                 }
 378
 379                 // no effects needed for targeting enemies, this can't possibly span all valid targets!
 380                 // just show for teammates to give a sign that they're an invalid target
 381                 //if(shottype == SHOTTYPE_HITENEMY)
 382                         //wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
 383                 if(shottype == SHOTTYPE_HITTEAM)
 384                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
 385
 386                 f = fabs(autocvar_crosshair_effect_time);
 387                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 388                 {
 389                         wcross_changedonetime = time + f;
 390                 }
 391                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 392                 {
 393                         wcross_name_changestarttime = time;
 394                         wcross_name_changedonetime = time + f;
 395                         if(wcross_name_goal_prev_prev)
 396                                 strunzone(wcross_name_goal_prev_prev);
 397                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 398                         wcross_name_goal_prev = strzone(wcross_name);
 399                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 400                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 401                         wcross_resolution_goal_prev = wcross_resolution;
 402                 }
 403
 404                 wcross_scale_goal_prev = wcross_scale;
 405                 wcross_alpha_goal_prev = wcross_alpha;
 406                 wcross_color_goal_prev = wcross_color;
 407
 408                 if((shottype == SHOTTYPE_HITTEAM && autocvar_crosshair_hittest_blur_teammate)
 409                         || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur_wall && !autocvar_chase_active))
 410                 {
 411                         wcross_blur = 1;
 412                         wcross_alpha *= 0.75;
 413                 }
 414                 else
 415                         wcross_blur = 0;
 416                 // *_prev is at time-frametime
 417                 // * is at wcross_changedonetime+f
 418                 // what do we have at time?
 419                 if(time < wcross_changedonetime)
 420                 {
 421                         f = frametime / (wcross_changedonetime - time + frametime);
 422                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 423                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 424                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 425                 }
 426
 427                 wcross_scale_prev = wcross_scale;
 428                 wcross_alpha_prev = wcross_alpha;
 429                 wcross_color_prev = wcross_color;
 430
 431                 MUTATOR_CALLHOOK(UpdateCrosshair);
 432
 433                 wcross_scale *= 1 - autocvar__menu_alpha;
 434                 wcross_alpha *= 1 - autocvar__menu_alpha;
 435                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 436
 437                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
 438                 {
 439                         // crosshair rings for weapon stats
 440                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
 441                         {
 442                                 // declarations and stats
 443                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
 444                                 string ring_image = string_null, ring_inner_image = string_null;
 445                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
 446
 447                                 ring_scale = autocvar_crosshair_ring_size;
 448
 449                                 entity wepent = viewmodels[0]; // TODO: unhardcode
 450
 451                                 int weapon_clipload = wepent.clip_load;
 452                                 int weapon_clipsize = wepent.clip_size;
 453
 454                                 float arc_heat = wepent.arc_heat_percent;
 455
 456                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
 457                                         vortex_charge_movingavg = wepent.vortex_charge;
 458
 459                                 float charge = 0;
 460                                 float chargepool = 0;
 461                                 bool ring_vortex_enabled = false;
 462                                 if (autocvar_crosshair_ring && autocvar_crosshair_ring_vortex)
 463                                 {
 464                                         if (wepent.activeweapon == WEP_VORTEX)
 465                                         {
 466                                                 charge = wepent.vortex_charge;
 467                                                 chargepool = wepent.vortex_chargepool_ammo;
 468                                         }
 469                                         else if (wepent.activeweapon == WEP_OVERKILL_NEX)
 470                                         {
 471                                                 charge = wepent.oknex_charge;
 472                                                 chargepool = wepent.oknex_chargepool_ammo;
 473                                         }
 474                                         if (charge)
 475                                                 ring_vortex_enabled = true;
 476                                 }
 477
 478                                 if (ring_vortex_enabled)
 479                                 {
 480                                         if (chargepool || use_vortex_chargepool) {
 481                                                 use_vortex_chargepool = 1;
 482                                                 ring_inner_value = chargepool;
 483                                         } else {
 484                                                 float rate = autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate;
 485                                                 vortex_charge_movingavg = (1 - rate) * vortex_charge_movingavg + rate * charge;
 486                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (charge - vortex_charge_movingavg), 1);
 487                                         }
 488
 489                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
 490                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
 491                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
 492
 493                                         // draw the outer ring to show the current charge of the weapon
 494                                         ring_value = charge;
 495                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
 496                                         ring_rgb = wcross_color;
 497                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
 498                                 }
 499                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
 500                                 {
 501                                         ring_value = bound(0, wepent.minelayer_mines / WEP_CVAR(minelayer, limit), 1);
 502                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
 503                                         ring_rgb = wcross_color;
 504                                         ring_image = "gfx/crosshair_ring.tga";
 505                                 }
 506                                 else if (wepent.activeweapon == WEP_HAGAR && wepent.hagar_load && autocvar_crosshair_ring_hagar)
 507                                 {
 508                                         ring_value = bound(0, wepent.hagar_load / WEP_CVAR_SEC(hagar, load_max), 1);
 509                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
 510                                         ring_rgb = wcross_color;
 511                                         ring_image = "gfx/crosshair_ring.tga";
 512                                 }
 513                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
 514                                 {
 515                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
 516                                         ring_scale = autocvar_crosshair_ring_reload_size;
 517                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 518                                         ring_rgb = wcross_color;
 519
 520                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
 521                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
 522                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
 523                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
 524                                         else
 525                                                 ring_image = "gfx/crosshair_ring.tga";
 526                                 }
 527                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
 528                                 {
 529                                         ring_value = arc_heat;
 530                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
 531                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
 532                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
 533                                         ring_image = "gfx/crosshair_ring.tga";
 534                                 }
 535
 536                                 // if in weapon switch animation, fade ring out/in
 537                                 if(autocvar_crosshair_effect_time > 0)
 538                                 {
 539                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
 540                                         if (f >= 1)
 541                                         {
 542                                                 wcross_ring_prev = ((ring_image) ? true : false);
 543                                         }
 544
 545                                         if(wcross_ring_prev)
 546                                         {
 547                                                 if(f < 1)
 548                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
 549                                         }
 550                                         else
 551                                         {
 552                                                 if(f < 1)
 553                                                         ring_alpha *= bound(0, f, 1);
 554                                         }
 555                                 }
 556
 557                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
 558                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * wcross_resolution * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
 559
 560                                 if (ring_value)
 561                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * wcross_resolution * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
 562                         }
 563
 564 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 565                         MACRO_BEGIN \
 566                                 vector scaled_sz = sz * wcross_size; \
 567                                 if(wcross_blur > 0) \
 568                                 { \
 569                                         for(i = -2; i <= 2; ++i) \
 570                                         for(j = -2; j <= 2; ++j) \
 571                                         M(i,j,sz,scaled_sz,wcross_name,wcross_alpha*0.04); \
 572                                 } \
 573                                 else \
 574                                 { \
 575                                         M(0,0,sz,scaled_sz,wcross_name,wcross_alpha); \
 576                                 } \
 577                         MACRO_END
 578
 579 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,scaled_sz,wcross_name,wcross_alpha) \
 580                         drawpic(wcross_origin - ('0.5 0 0' * (scaled_sz.x + i * wcross_blur) + '0 0.5 0' * (scaled_sz.y + j * wcross_blur)), wcross_name, scaled_sz, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 581
 582 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 583                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 584
 585                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 586                         {
 587                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 588                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 589                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 590                                 f = 1 - f;
 591                         }
 592                         else
 593                         {
 594                                 f = 1;
 595                         }
 596                         wcross_name_alpha_goal_prev = f;
 597
 598                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 599                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 600
 601                         if(autocvar_crosshair_dot)
 602                         {
 603                                 vector wcross_color_old;
 604                                 wcross_color_old = wcross_color;
 605
 606                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
 607                                         wcross_color = stov(autocvar_crosshair_dot_color);
 608
 609                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
 610                                 // FIXME why don't we use wcross_alpha here?
 611                                 wcross_color = wcross_color_old;
 612                         }
 613                 }
 614         }
 615         else
 616         {
 617                 wcross_scale_prev = 0;
 618                 wcross_alpha_prev = 0;
 619                 wcross_scale_goal_prev = 0;
 620                 wcross_alpha_goal_prev = 0;
 621                 wcross_changedonetime = 0;
 622                 strfree(wcross_name_goal_prev);
 623                 strfree(wcross_name_goal_prev_prev);
 624                 wcross_name_changestarttime = 0;
 625                 wcross_name_changedonetime = 0;
 626                 wcross_name_alpha_goal_prev = 0;
 627                 wcross_name_alpha_goal_prev_prev = 0;
 628                 wcross_resolution_goal_prev = 0;
 629                 wcross_resolution_goal_prev_prev = 0;
 630         }
 631 }
 632
 633 void DrawReticle(entity this)
 634 {
 635         if(!autocvar_cl_reticle || MUTATOR_CALLHOOK(DrawReticle))
 636         {
 637                 reticle_type = 0;
 638                 return;
 639         }
 640
 641         float is_dead = (STAT(HEALTH) <= 0);
 642         string reticle_image = string_null;
 643         bool wep_zoomed = false;
 644         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 645         {
 646                 entity wepe = viewmodels[slot];
 647                 Weapon wep = wepe.activeweapon;
 648                 if(wep != WEP_Null && wep.wr_zoom)
 649                 {
 650                         bool do_zoom = wep.wr_zoom(wep, NULL);
 651                         if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
 652                                 reticle_image = wep.w_reticle;
 653                         wep_zoomed += do_zoom;
 654                 }
 655         }
 656         // Draw the aiming reticle for weapons that use it
 657         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 658         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 659         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 660         if(spectatee_status || is_dead || hud != HUD_NORMAL || this.viewloc)
 661         {
 662                 // no zoom reticle while dead
 663                 reticle_type = 0;
 664         }
 665         else if(wep_zoomed && autocvar_cl_reticle_weapon)
 666         {
 667                 if(reticle_image) { reticle_type = 2; }
 668                 else { reticle_type = 0; }
 669         }
 670         else if(button_zoom || zoomscript_caught)
 671         {
 672                 // normal zoom
 673                 reticle_type = 1;
 674         }
 675
 676         if(reticle_type)
 677         {
 678                 vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 679                 if(autocvar_cl_reticle_stretch)
 680                 {
 681                         reticle_size.x = vid_conwidth;
 682                         reticle_size.y = vid_conheight;
 683                         reticle_pos.x = 0;
 684                         reticle_pos.y = 0;
 685                 }
 686                 else
 687                 {
 688                         reticle_size.x = max(vid_conwidth, vid_conheight);
 689                         reticle_size.y = max(vid_conwidth, vid_conheight);
 690                         reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
 691                         reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
 692                 }
 693
 694                 float f = (zoomscript_caught) ? 1 : current_zoomfraction;
 695
 696                 if(f)
 697                 {
 698                         switch(reticle_type)
 699                         {
 700                                 case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
 701                                 case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
 702                         }
 703                 }
 704         }
 705 }