qcsrc/client/hud.qc

   1 #include "hud.qh"
   2 #include "_all.qh"
   3
   4 #include "hud_config.qh"
   5 #include "scoreboard.qh"
   6 #include "sortlist.qh"
   7 #include "teamradar.qh"
   8 #include "t_items.qh"
   9
  10 #include "../common/buffs.qh"
  11 #include "../common/constants.qh"
  12 #include "../common/counting.qh"
  13 #include "../common/deathtypes.qh"
  14 #include "../common/mapinfo.qh"
  15 #include "../common/nades.qh"
  16 #include "../common/stats.qh"
  17
  18 #include "../csqcmodellib/cl_player.qh"
  19
  20 #include "../warpzonelib/mathlib.qh"
  21
  22 /*
  23 ==================
  24 Misc HUD functions
  25 ==================
  26 */
  27
  28 // a border picture is a texture containing nine parts:
  29 //   1/4 width: left part
  30 //   1/2 width: middle part (stretched)
  31 //   1/4 width: right part
  32 // divided into
  33 //   1/4 height: top part
  34 //   1/2 height: middle part (stretched)
  35 //   1/4 height: bottom part
  36 void draw_BorderPicture(vector theOrigin, string pic, vector theSize, vector theColor, float theAlpha, vector theBorderSize)
  37 {
  38     if (theBorderSize.x < 0 && theBorderSize.y < 0) // draw whole image as it is
  39     {
  40                 drawpic(theOrigin, pic, theSize, theColor, theAlpha, 0);
  41                 return;
  42     }
  43         if (theBorderSize.x == 0 && theBorderSize.y == 0) // no border
  44         {
  45                 // draw only the central part
  46                 drawsubpic(theOrigin, theSize, pic, '0.25 0.25 0', '0.5 0.5 0', theColor, theAlpha, 0);
  47                 return;
  48         }
  49
  50         vector dX, dY;
  51         vector width, height;
  52         vector bW, bH;
  53         //pic = draw_UseSkinFor(pic);
  54         width = eX * theSize.x;
  55         height = eY * theSize.y;
  56         if(theSize.x <= theBorderSize.x * 2)
  57         {
  58                 // not wide enough... draw just left and right then
  59                 bW = eX * (0.25 * theSize.x / (theBorderSize.x * 2));
  60                 if(theSize.y <= theBorderSize.y * 2)
  61                 {
  62                         // not high enough... draw just corners
  63                         bH = eY * (0.25 * theSize.y / (theBorderSize.y * 2));
  64                         drawsubpic(theOrigin,                 width * 0.5 + height * 0.5, pic, '0 0 0',           bW + bH, theColor, theAlpha, 0);
  65                         drawsubpic(theOrigin + width   * 0.5, width * 0.5 + height * 0.5, pic, eX - bW,           bW + bH, theColor, theAlpha, 0);
  66                         drawsubpic(theOrigin + height  * 0.5, width * 0.5 + height * 0.5, pic, eY - bH,           bW + bH, theColor, theAlpha, 0);
  67                         drawsubpic(theOrigin + theSize * 0.5, width * 0.5 + height * 0.5, pic, eX + eY - bW - bH, bW + bH, theColor, theAlpha, 0);
  68                 }
  69                 else
  70                 {
  71                         dY = theBorderSize.x * eY;
  72                         drawsubpic(theOrigin,                             width * 0.5          +     dY, pic, '0 0    0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  73                         drawsubpic(theOrigin + width * 0.5,               width * 0.5          +     dY, pic, '0 0    0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  74                         drawsubpic(theOrigin                        + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0',           '0 0.5  0' + bW, theColor, theAlpha, 0);
  75                         drawsubpic(theOrigin + width * 0.5          + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0' + eX - bW, '0 0.5  0' + bW, theColor, theAlpha, 0);
  76                         drawsubpic(theOrigin               + height - dY, width * 0.5          +     dY, pic, '0 0.75 0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  77                         drawsubpic(theOrigin + width * 0.5 + height - dY, width * 0.5          +     dY, pic, '0 0.75 0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  78                 }
  79         }
  80         else
  81         {
  82                 if(theSize.y <= theBorderSize.y * 2)
  83                 {
  84                         // not high enough... draw just top and bottom then
  85                         bH = eY * (0.25 * theSize.y / (theBorderSize.y * 2));
  86                         dX = theBorderSize.x * eX;
  87                         drawsubpic(theOrigin,                                         dX + height * 0.5, pic, '0    0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  88                         drawsubpic(theOrigin + dX,                        width - 2 * dX + height * 0.5, pic, '0.25 0 0',           '0.5  0 0' + bH, theColor, theAlpha, 0);
  89                         drawsubpic(theOrigin + width - dX,                            dX + height * 0.5, pic, '0.75 0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  90                         drawsubpic(theOrigin              + height * 0.5,             dX + height * 0.5, pic, '0    0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  91                         drawsubpic(theOrigin + dX         + height * 0.5, width - 2 * dX + height * 0.5, pic, '0.25 0 0' + eY - bH, '0.5  0 0' + bH, theColor, theAlpha, 0);
  92                         drawsubpic(theOrigin + width - dX + height * 0.5,             dX + height * 0.5, pic, '0.75 0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  93                 }
  94                 else
  95                 {
  96                         dX = theBorderSize.x * eX;
  97                         dY = theBorderSize.x * eY;
  98                         drawsubpic(theOrigin,                                        dX          +     dY, pic, '0    0    0', '0.25 0.25 0', theColor, theAlpha, 0);
  99                         drawsubpic(theOrigin                  + dX,      width - 2 * dX          +     dY, pic, '0.25 0    0', '0.5  0.25 0', theColor, theAlpha, 0);
 100                         drawsubpic(theOrigin          + width - dX,                  dX          +     dY, pic, '0.75 0    0', '0.25 0.25 0', theColor, theAlpha, 0);
 101                         drawsubpic(theOrigin          + dY,                          dX + height - 2 * dY, pic, '0    0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
 102                         drawsubpic(theOrigin          + dY         + dX, width - 2 * dX + height - 2 * dY, pic, '0.25 0.25 0', '0.5  0.5  0', theColor, theAlpha, 0);
 103                         drawsubpic(theOrigin          + dY + width - dX,             dX + height - 2 * dY, pic, '0.75 0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
 104                         drawsubpic(theOrigin + height - dY,                          dX          +     dY, pic, '0    0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
 105                         drawsubpic(theOrigin + height - dY         + dX, width - 2 * dX          +     dY, pic, '0.25 0.75 0', '0.5  0.25 0', theColor, theAlpha, 0);
 106                         drawsubpic(theOrigin + height - dY + width - dX,             dX          +     dY, pic, '0.75 0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
 107                 }
 108         }
 109 }
 110
 111 vector HUD_Get_Num_Color (float x, float maxvalue)
 112 {
 113         float blinkingamt;
 114         vector color;
 115         if(x >= maxvalue) {
 116                 color.x = sin(2*M_PI*time);
 117                 color.y = 1;
 118                 color.z = sin(2*M_PI*time);
 119         }
 120         else if(x > maxvalue * 0.75) {
 121                 color.x = 0.4 - (x-150)*0.02 * 0.4; //red value between 0.4 -> 0
 122                 color.y = 0.9 + (x-150)*0.02 * 0.1; // green value between 0.9 -> 1
 123                 color.z = 0;
 124         }
 125         else if(x > maxvalue * 0.5) {
 126                 color.x = 1 - (x-100)*0.02 * 0.6; //red value between 1 -> 0.4
 127                 color.y = 1 - (x-100)*0.02 * 0.1; // green value between 1 -> 0.9
 128                 color.z = 1 - (x-100)*0.02; // blue value between 1 -> 0
 129         }
 130         else if(x > maxvalue * 0.25) {
 131                 color.x = 1;
 132                 color.y = 1;
 133                 color.z = 0.2 + (x-50)*0.02 * 0.8; // blue value between 0.2 -> 1
 134         }
 135         else if(x > maxvalue * 0.1) {
 136                 color.x = 1;
 137                 color.y = (x-20)*90/27/100; // green value between 0 -> 1
 138                 color.z = (x-20)*90/27/100 * 0.2; // blue value between 0 -> 0.2
 139         }
 140         else {
 141                 color.x = 1;
 142                 color.y = 0;
 143                 color.z = 0;
 144         }
 145
 146         blinkingamt = (1 - x/maxvalue/0.25);
 147         if(blinkingamt > 0)
 148         {
 149                 color.x = color.x - color.x * blinkingamt * sin(2*M_PI*time);
 150                 color.y = color.y - color.y * blinkingamt * sin(2*M_PI*time);
 151                 color.z = color.z - color.z * blinkingamt * sin(2*M_PI*time);
 152         }
 153         return color;
 154 }
 155
 156 float HUD_GetRowCount(int item_count, vector size, float item_aspect)
 157 {
 158         float aspect = size_y / size_x;
 159         return bound(1, floor((sqrt(4 * item_aspect * aspect * item_count + aspect * aspect) + aspect + 0.5) / 2), item_count);
 160 }
 161
 162 vector HUD_GetTableSize(int item_count, vector psize, float item_aspect)
 163 {
 164         float columns, rows;
 165         float ratio, best_ratio = 0;
 166         float best_columns = 1, best_rows = 1;
 167         bool vertical = (psize.x / psize.y >= item_aspect);
 168         if(vertical)
 169         {
 170                 psize = eX * psize.y + eY * psize.x;
 171                 item_aspect = 1 / item_aspect;
 172         }
 173
 174         rows = ceil(sqrt(item_count));
 175         columns = ceil(item_count/rows);
 176         while(columns >= 1)
 177         {
 178                 ratio = (psize.x/columns) / (psize.y/rows);
 179                 if(ratio > item_aspect)
 180                         ratio = item_aspect * item_aspect / ratio;
 181
 182                 if(ratio <= best_ratio)
 183                         break; // ratio starts decreasing by now, skip next configurations
 184
 185                 best_columns = columns;
 186                 best_rows = rows;
 187                 best_ratio = ratio;
 188
 189                 if(columns == 1)
 190                         break;
 191
 192                 --columns;
 193                 rows = ceil(item_count/columns);
 194         }
 195
 196         if(vertical)
 197                 return eX * best_rows + eY * best_columns;
 198         else
 199                 return eX * best_columns + eY * best_rows;
 200 }
 201
 202 float stringwidth_colors(string s, vector theSize)
 203 {
 204         return stringwidth(s, true, theSize);
 205 }
 206
 207 float stringwidth_nocolors(string s, vector theSize)
 208 {
 209         return stringwidth(s, false, theSize);
 210 }
 211
 212 void drawstringright(vector position, string text, vector theScale, vector rgb, float theAlpha, int flag)
 213 {
 214         position.x -= 2 / 3 * strlen(text) * theScale.x;
 215         drawstring(position, text, theScale, rgb, theAlpha, flag);
 216 }
 217
 218 void drawstringcenter(vector position, string text, vector theScale, vector rgb, float theAlpha, int flag)
 219 {
 220         position.x = 0.5 * (vid_conwidth - 0.6025 * strlen(text) * theScale.x);
 221         drawstring(position, text, theScale, rgb, theAlpha, flag);
 222 }
 223
 224 // return the string of the onscreen race timer
 225 string MakeRaceString(int cp, float mytime, float theirtime, float lapdelta, string theirname)
 226 {
 227         string col;
 228         string timestr;
 229         string cpname;
 230         string lapstr;
 231         lapstr = "";
 232
 233         if(theirtime == 0) // goal hit
 234         {
 235                 if(mytime > 0)
 236                 {
 237                         timestr = strcat("+", ftos_decimals(+mytime, TIME_DECIMALS));
 238                         col = "^1";
 239                 }
 240                 else if(mytime == 0)
 241                 {
 242                         timestr = "+0.0";
 243                         col = "^3";
 244                 }
 245                 else
 246                 {
 247                         timestr = strcat("-", ftos_decimals(-mytime, TIME_DECIMALS));
 248                         col = "^2";
 249                 }
 250
 251                 if(lapdelta > 0)
 252                 {
 253                         lapstr = sprintf(_(" (-%dL)"), lapdelta);
 254                         col = "^2";
 255                 }
 256                 else if(lapdelta < 0)
 257                 {
 258                         lapstr = sprintf(_(" (+%dL)"), -lapdelta);
 259                         col = "^1";
 260                 }
 261         }
 262         else if(theirtime > 0) // anticipation
 263         {
 264                 if(mytime >= theirtime)
 265                         timestr = strcat("+", ftos_decimals(mytime - theirtime, TIME_DECIMALS));
 266                 else
 267                         timestr = TIME_ENCODED_TOSTRING(TIME_ENCODE(theirtime));
 268                 col = "^3";
 269         }
 270         else
 271         {
 272                 col = "^7";
 273                 timestr = "";
 274         }
 275
 276         if(cp == 254)
 277                 cpname = _("Start line");
 278         else if(cp == 255)
 279                 cpname = _("Finish line");
 280         else if(cp)
 281                 cpname = sprintf(_("Intermediate %d"), cp);
 282         else
 283                 cpname = _("Finish line");
 284
 285         if(theirtime < 0)
 286                 return strcat(col, cpname);
 287         else if(theirname == "")
 288                 return strcat(col, sprintf("%s (%s)", cpname, timestr));
 289         else
 290                 return strcat(col, sprintf("%s (%s %s)", cpname, timestr, strcat(theirname, col, lapstr)));
 291 }
 292
 293 // Check if the given name already exist in race rankings? In that case, where? (otherwise return 0)
 294 int race_CheckName(string net_name)
 295 {
 296         int i;
 297         for (i=RANKINGS_CNT-1;i>=0;--i)
 298                 if(grecordholder[i] == net_name)
 299                         return i+1;
 300         return 0;
 301 }
 302
 303 int GetPlayerColorForce(int i)
 304 {
 305         if(!teamplay)
 306                 return 0;
 307         else
 308                 return stof(getplayerkeyvalue(i, "colors")) & 15;
 309 }
 310
 311 int GetPlayerColor(int i)
 312 {
 313         if(!playerslots[i].gotscores) // unconnected
 314                 return NUM_SPECTATOR;
 315         else if(stof(getplayerkeyvalue(i, "frags")) == FRAGS_SPECTATOR)
 316                 return NUM_SPECTATOR;
 317         else
 318                 return GetPlayerColorForce(i);
 319 }
 320
 321 string GetPlayerName(int i)
 322 {
 323         return ColorTranslateRGB(getplayerkeyvalue(i, "name"));
 324 }
 325
 326
 327 /*
 328 ==================
 329 HUD panels
 330 ==================
 331 */
 332
 333 // draw the background/borders
 334 #define HUD_Panel_DrawBg(theAlpha) do {                                                                                                                                                         \
 335         if(panel.current_panel_bg != "0" && panel.current_panel_bg != "")                                                                                               \
 336                 draw_BorderPicture(panel_pos - '1 1 0' * panel_bg_border, panel.current_panel_bg, panel_size + '1 1 0' * 2 * panel_bg_border, panel_bg_color, panel_bg_alpha * theAlpha, '1 1 0' * (panel_bg_border/BORDER_MULTIPLIER));\
 337 } while(0)
 338
 339 //basically the same code of draw_ButtonPicture and draw_VertButtonPicture for the menu
 340 void HUD_Panel_DrawProgressBar(vector theOrigin, vector theSize, string pic, float length_ratio, bool vertical, float baralign, vector theColor, float theAlpha, int drawflag)
 341 {
 342         if(!length_ratio || !theAlpha)
 343                 return;
 344         if(length_ratio > 1)
 345                 length_ratio = 1;
 346         if (baralign == 3)
 347         {
 348                 if(length_ratio < -1)
 349                         length_ratio = -1;
 350         }
 351         else if(length_ratio < 0)
 352                 return;
 353
 354         vector square;
 355         vector width, height;
 356         if(vertical) {
 357                 pic = strcat(hud_skin_path, "/", pic, "_vertical");
 358                 if(precache_pic(pic) == "") {
 359                         pic = "gfx/hud/default/progressbar_vertical";
 360                 }
 361
 362         if (baralign == 1) // bottom align
 363                         theOrigin.y += (1 - length_ratio) * theSize.y;
 364         else if (baralign == 2) // center align
 365             theOrigin.y += 0.5 * (1 - length_ratio) * theSize.y;
 366         else if (baralign == 3) // center align, positive values down, negative up
 367                 {
 368                         theSize.y *= 0.5;
 369                         if (length_ratio > 0)
 370                                 theOrigin.y += theSize.y;
 371                         else
 372                         {
 373                                 theOrigin.y += (1 + length_ratio) * theSize.y;
 374                                 length_ratio = -length_ratio;
 375                         }
 376                 }
 377                 theSize.y *= length_ratio;
 378
 379                 vector bH;
 380                 width = eX * theSize.x;
 381                 height = eY * theSize.y;
 382                 if(theSize.y <= theSize.x * 2)
 383                 {
 384                         // button not high enough
 385                         // draw just upper and lower part then
 386                         square = eY * theSize.y * 0.5;
 387                         bH = eY * (0.25 * theSize.y / (theSize.x * 2));
 388                         drawsubpic(theOrigin,          square + width, pic, '0 0 0', eX + bH, theColor, theAlpha, drawflag);
 389                         drawsubpic(theOrigin + square, square + width, pic, eY - bH, eX + bH, theColor, theAlpha, drawflag);
 390                 }
 391                 else
 392                 {
 393                         square = eY * theSize.x;
 394                         drawsubpic(theOrigin,                   width   +     square, pic, '0 0    0', '1 0.25 0', theColor, theAlpha, drawflag);
 395                         drawsubpic(theOrigin +          square, theSize - 2 * square, pic, '0 0.25 0', '1 0.5  0', theColor, theAlpha, drawflag);
 396                         drawsubpic(theOrigin + height - square, width   +     square, pic, '0 0.75 0', '1 0.25 0', theColor, theAlpha, drawflag);
 397                 }
 398         } else {
 399                 pic = strcat(hud_skin_path, "/", pic);
 400                 if(precache_pic(pic) == "") {
 401                         pic = "gfx/hud/default/progressbar";
 402                 }
 403
 404                 if (baralign == 1) // right align
 405                         theOrigin.x += (1 - length_ratio) * theSize.x;
 406         else if (baralign == 2) // center align
 407             theOrigin.x += 0.5 * (1 - length_ratio) * theSize.x;
 408         else if (baralign == 3) // center align, positive values on the right, negative on the left
 409                 {
 410                         theSize.x *= 0.5;
 411                         if (length_ratio > 0)
 412                                 theOrigin.x += theSize.x;
 413                         else
 414                         {
 415                                 theOrigin.x += (1 + length_ratio) * theSize.x;
 416                                 length_ratio = -length_ratio;
 417                         }
 418                 }
 419                 theSize.x *= length_ratio;
 420
 421                 vector bW;
 422                 width = eX * theSize.x;
 423                 height = eY * theSize.y;
 424                 if(theSize.x <= theSize.y * 2)
 425                 {
 426                         // button not wide enough
 427                         // draw just left and right part then
 428                         square = eX * theSize.x * 0.5;
 429                         bW = eX * (0.25 * theSize.x / (theSize.y * 2));
 430                         drawsubpic(theOrigin,          square + height, pic, '0 0 0', eY + bW, theColor, theAlpha, drawflag);
 431                         drawsubpic(theOrigin + square, square + height, pic, eX - bW, eY + bW, theColor, theAlpha, drawflag);
 432                 }
 433                 else
 434                 {
 435                         square = eX * theSize.y;
 436                         drawsubpic(theOrigin,                  height  +     square, pic, '0    0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 437                         drawsubpic(theOrigin +         square, theSize - 2 * square, pic, '0.25 0 0', '0.5  1 0', theColor, theAlpha, drawflag);
 438                         drawsubpic(theOrigin + width - square, height  +     square, pic, '0.75 0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 439                 }
 440         }
 441 }
 442
 443 void HUD_Panel_DrawHighlight(vector pos, vector mySize, vector color, float theAlpha, int drawflag)
 444 {
 445         if(!theAlpha)
 446                 return;
 447
 448         string pic;
 449         pic = strcat(hud_skin_path, "/num_leading");
 450         if(precache_pic(pic) == "") {
 451                 pic = "gfx/hud/default/num_leading";
 452         }
 453
 454         drawsubpic(pos, eX * min(mySize.x * 0.5, mySize.y) + eY * mySize.y, pic, '0 0 0', '0.25 1 0', color, theAlpha, drawflag);
 455         if(mySize.x/mySize.y > 2)
 456                 drawsubpic(pos + eX * mySize.y, eX * (mySize.x - 2 * mySize.y) + eY * mySize.y, pic, '0.25 0 0', '0.5 1 0', color, theAlpha, drawflag);
 457         drawsubpic(pos + eX * mySize.x - eX * min(mySize.x * 0.5, mySize.y), eX * min(mySize.x * 0.5, mySize.y) + eY * mySize.y, pic, '0.75 0 0', '0.25 1 0', color, theAlpha, drawflag);
 458 }
 459
 460 // Weapon icons (#0)
 461 //
 462 entity weaponorder[WEP_MAXCOUNT];
 463 void weaponorder_swap(int i, int j, entity pass)
 464 {
 465         entity h = weaponorder[i];
 466         weaponorder[i] = weaponorder[j];
 467         weaponorder[j] = h;
 468 }
 469
 470 string weaponorder_cmp_str;
 471 int weaponorder_cmp(int i, int j, entity pass)
 472 {
 473         int ai, aj;
 474         ai = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[i].weapon), 0);
 475         aj = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[j].weapon), 0);
 476         return aj - ai; // the string is in REVERSE order (higher prio at the right is what we want, but higher prio first is the string)
 477 }
 478
 479 void HUD_Weapons(void)
 480 {
 481         // declarations
 482         WepSet weapons_stat = WepSet_GetFromStat();
 483         int i;
 484         float f, a;
 485         float screen_ar;
 486         vector center = '0 0 0';
 487         int weapon_count, weapon_id;
 488         int row, column, rows = 0, columns = 0;
 489         bool vertical_order = true;
 490         float aspect = autocvar_hud_panel_weapons_aspect;
 491
 492         float timeout = autocvar_hud_panel_weapons_timeout;
 493         float timein_effect_length = autocvar_hud_panel_weapons_timeout_speed_in; //? 0.375 : 0);
 494         float timeout_effect_length = autocvar_hud_panel_weapons_timeout_speed_out; //? 0.75 : 0);
 495
 496         vector barsize = '0 0 0', baroffset = '0 0 0';
 497         vector ammo_color = '1 0 1';
 498         float ammo_alpha = 1;
 499
 500         float when = max(1, autocvar_hud_panel_weapons_complainbubble_time);
 501         float fadetime = max(0, autocvar_hud_panel_weapons_complainbubble_fadetime);
 502
 503         vector weapon_pos, weapon_size = '0 0 0';
 504         vector color;
 505
 506         // check to see if we want to continue
 507         if(hud != HUD_NORMAL) { return; }
 508
 509         if(!autocvar__hud_configure)
 510         {
 511                 if((!autocvar_hud_panel_weapons) || (spectatee_status == -1))
 512                         return;
 513                 if(timeout && time >= weapontime + timeout + timeout_effect_length)
 514                 if(autocvar_hud_panel_weapons_timeout_effect == 3 || (autocvar_hud_panel_weapons_timeout_effect == 1 && !(autocvar_hud_panel_weapons_timeout_fadebgmin + autocvar_hud_panel_weapons_timeout_fadefgmin)))
 515                 {
 516                         weaponprevtime = time;
 517                         return;
 518                 }
 519         }
 520
 521         // update generic hud functions
 522         HUD_Panel_UpdateCvars();
 523
 524         // figure out weapon order (how the weapons are sorted) // TODO make this configurable
 525         if(weaponorder_bypriority != autocvar_cl_weaponpriority || !weaponorder[0])
 526         {
 527                 int weapon_cnt;
 528                 if(weaponorder_bypriority)
 529                         strunzone(weaponorder_bypriority);
 530                 if(weaponorder_byimpulse)
 531                         strunzone(weaponorder_byimpulse);
 532
 533                 weaponorder_bypriority = strzone(autocvar_cl_weaponpriority);
 534                 weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(W_FixWeaponOrder_ForceComplete(W_NumberWeaponOrder(weaponorder_bypriority))));
 535                 weaponorder_cmp_str = strcat(" ", weaponorder_byimpulse, " ");
 536
 537                 weapon_cnt = 0;
 538                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 539                 {
 540                         self = get_weaponinfo(i);
 541                         if(self.impulse >= 0)
 542                         {
 543                                 weaponorder[weapon_cnt] = self;
 544                                 ++weapon_cnt;
 545                         }
 546                 }
 547                 for(i = weapon_cnt; i < WEP_MAXCOUNT; ++i)
 548                         weaponorder[i] = world;
 549                 heapsort(weapon_cnt, weaponorder_swap, weaponorder_cmp, world);
 550
 551                 weaponorder_cmp_str = string_null;
 552         }
 553
 554         if(!autocvar_hud_panel_weapons_complainbubble || autocvar__hud_configure || time - complain_weapon_time >= when + fadetime)
 555                 complain_weapon = 0;
 556
 557         if(autocvar__hud_configure)
 558         {
 559                 if(!weapons_stat)
 560                         for(i = WEP_FIRST; i <= WEP_LAST; i += floor((WEP_LAST-WEP_FIRST)/5))
 561                                 weapons_stat |= WepSet_FromWeapon(i);
 562
 563                 #if 0
 564                 /// debug code
 565                 if(cvar("wep_add"))
 566                 {
 567                         weapons_stat = '0 0 0';
 568                         float countw = 1 + floor((floor(time * cvar("wep_add"))) % WEP_COUNT);
 569                         for(i = WEP_FIRST; i <= countw; ++i)
 570                                 weapons_stat |= WepSet_FromWeapon(i);
 571                 }
 572                 #endif
 573         }
 574
 575         // determine which weapons are going to be shown
 576         if (autocvar_hud_panel_weapons_onlyowned)
 577         {
 578                 if(autocvar__hud_configure)
 579                 {
 580                         if(menu_enabled != 2)
 581                                 HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
 582                 }
 583
 584                 // do we own this weapon?
 585                 weapon_count = 0;
 586                 for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 587                         if((weapons_stat & WepSet_FromWeapon(weaponorder[i].weapon)) || (weaponorder[i].weapon == complain_weapon))
 588                                 ++weapon_count;
 589
 590
 591                 // might as well commit suicide now, no reason to live ;)
 592                 if (weapon_count == 0)
 593                         return;
 594
 595                 vector old_panel_size = panel_size;
 596                 vector padded_panel_size = panel_size - '2 2 0' * panel_bg_padding;
 597
 598                 // get the all-weapons layout
 599                 vector table_size = HUD_GetTableSize(WEP_COUNT, padded_panel_size, aspect);
 600                 columns = table_size.x;
 601                 rows = table_size.y;
 602                 weapon_size.x = padded_panel_size.x / columns;
 603                 weapon_size.y = padded_panel_size.y / rows;
 604
 605                 // NOTE: although weapons should aways look the same even if onlyowned is enabled,
 606                 // we enlarge them a bit when possible to better match the desired aspect ratio
 607                 if(padded_panel_size.x / padded_panel_size.y < aspect)
 608                 {
 609                         // maximum number of rows that allows to display items with the desired aspect ratio
 610                         int max_rows = floor(padded_panel_size.y / (weapon_size.x / aspect));
 611                         columns = min(columns, ceil(weapon_count / max_rows));
 612                         rows = ceil(weapon_count / columns);
 613                         weapon_size.y = min(padded_panel_size.y / rows, weapon_size.x / aspect);
 614                         weapon_size.x = min(padded_panel_size.x / columns, aspect * weapon_size.y);
 615                         vertical_order = false;
 616                 }
 617                 else
 618                 {
 619                         int max_columns = floor(padded_panel_size.x / (weapon_size.y * aspect));
 620                         rows = min(rows, ceil(weapon_count / max_columns));
 621                         columns = ceil(weapon_count / rows);
 622                         weapon_size.x = min(padded_panel_size.x / columns, aspect * weapon_size.y);
 623                         weapon_size.y = min(padded_panel_size.y / rows, weapon_size.x / aspect);
 624                         vertical_order = true;
 625                 }
 626
 627                 // reduce size of the panel
 628                 panel_size.x = columns * weapon_size.x;
 629                 panel_size.y = rows * weapon_size.y;
 630                 panel_size += '2 2 0' * panel_bg_padding;
 631
 632                 // center the resized panel, or snap it to the screen edge when close enough
 633                 if(panel_pos.x > vid_conwidth * 0.001)
 634                 {
 635                         if(panel_pos.x + old_panel_size.x > vid_conwidth * 0.999)
 636                                 panel_pos.x += old_panel_size.x - panel_size.x;
 637                         else
 638                                 panel_pos.x += (old_panel_size.x - panel_size.x) / 2;
 639                 }
 640                 else if(old_panel_size.x > vid_conwidth * 0.999)
 641                         panel_pos.x += (old_panel_size.x - panel_size.x) / 2;
 642
 643                 if(panel_pos.y > vid_conheight * 0.001)
 644                 {
 645                         if(panel_pos.y + old_panel_size.y > vid_conheight * 0.999)
 646                                 panel_pos.y += old_panel_size.y - panel_size.y;
 647                         else
 648                                 panel_pos.y += (old_panel_size.y - panel_size.y) / 2;
 649                 }
 650                 else if(old_panel_size.y > vid_conheight * 0.999)
 651                         panel_pos.y += (old_panel_size.y - panel_size.y) / 2;
 652         }
 653         else
 654                 weapon_count = WEP_COUNT;
 655
 656         // animation for fading in/out the panel respectively when not in use
 657         if(!autocvar__hud_configure)
 658         {
 659                 if (timeout && time >= weapontime + timeout) // apply timeout effect if needed
 660                 {
 661                         f = bound(0, (time - (weapontime + timeout)) / timeout_effect_length, 1);
 662
 663                         // fade the panel alpha
 664                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 665                         {
 666                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * f + (1 - f));
 667                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * f + (1 - f));
 668                         }
 669                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 670                         {
 671                                 panel_bg_alpha *= (1 - f);
 672                                 panel_fg_alpha *= (1 - f);
 673                         }
 674
 675                         // move the panel off the screen
 676                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 677                         {
 678                                 f *= f; // for a cooler movement
 679                                 center.x = panel_pos.x + panel_size.x/2;
 680                                 center.y = panel_pos.y + panel_size.y/2;
 681                                 screen_ar = vid_conwidth/vid_conheight;
 682                                 if (center.x/center.y < screen_ar) //bottom left
 683                                 {
 684                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //bottom
 685                                                 panel_pos.y += f * (vid_conheight - panel_pos.y);
 686                                         else //left
 687                                                 panel_pos.x -= f * (panel_pos.x + panel_size.x);
 688                                 }
 689                                 else //top right
 690                                 {
 691                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //right
 692                                                 panel_pos.x += f * (vid_conwidth - panel_pos.x);
 693                                         else //top
 694                                                 panel_pos.y -= f * (panel_pos.y + panel_size.y);
 695                                 }
 696                                 if(f == 1)
 697                                         center.x = -1; // mark the panel as off screen
 698                         }
 699                         weaponprevtime = time - (1 - f) * timein_effect_length;
 700                 }
 701                 else if (timeout && time < weaponprevtime + timein_effect_length) // apply timein effect if needed
 702                 {
 703                         f = bound(0, (time - weaponprevtime) / timein_effect_length, 1);
 704
 705                         // fade the panel alpha
 706                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 707                         {
 708                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * (1 - f) + f);
 709                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * (1 - f) + f);
 710                         }
 711                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 712                         {
 713                                 panel_bg_alpha *= (f);
 714                                 panel_fg_alpha *= (f);
 715                         }
 716
 717                         // move the panel back on screen
 718                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 719                         {
 720                                 f *= f; // for a cooler movement
 721                                 f = 1 - f;
 722                                 center.x = panel_pos.x + panel_size.x/2;
 723                                 center.y = panel_pos.y + panel_size.y/2;
 724                                 screen_ar = vid_conwidth/vid_conheight;
 725                                 if (center.x/center.y < screen_ar) //bottom left
 726                                 {
 727                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //bottom
 728                                                 panel_pos.y += f * (vid_conheight - panel_pos.y);
 729                                         else //left
 730                                                 panel_pos.x -= f * (panel_pos.x + panel_size.x);
 731                                 }
 732                                 else //top right
 733                                 {
 734                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //right
 735                                                 panel_pos.x += f * (vid_conwidth - panel_pos.x);
 736                                         else //top
 737                                                 panel_pos.y -= f * (panel_pos.y + panel_size.y);
 738                                 }
 739                         }
 740                 }
 741         }
 742
 743         // draw the background, then change the virtual size of it to better fit other items inside
 744         HUD_Panel_DrawBg(1);
 745
 746         if(center.x == -1)
 747                 return;
 748
 749         if(panel_bg_padding)
 750         {
 751                 panel_pos += '1 1 0' * panel_bg_padding;
 752                 panel_size -= '2 2 0' * panel_bg_padding;
 753         }
 754
 755         // after the sizing and animations are done, update the other values
 756
 757         if(!rows) // if rows is > 0 onlyowned code has already updated these vars
 758         {
 759                 vector table_size = HUD_GetTableSize(WEP_COUNT, panel_size, aspect);
 760                 columns = table_size.x;
 761                 rows = table_size.y;
 762                 weapon_size.x = panel_size.x / columns;
 763                 weapon_size.y = panel_size.y / rows;
 764                 vertical_order = (panel_size.x / panel_size.y >= aspect);
 765         }
 766
 767         // calculate position/size for visual bar displaying ammount of ammo status
 768         if (autocvar_hud_panel_weapons_ammo)
 769         {
 770                 ammo_color = stov(autocvar_hud_panel_weapons_ammo_color);
 771                 ammo_alpha = panel_fg_alpha * autocvar_hud_panel_weapons_ammo_alpha;
 772
 773                 if(weapon_size.x/weapon_size.y > aspect)
 774                 {
 775                         barsize.x = aspect * weapon_size.y;
 776                         barsize.y = weapon_size.y;
 777                         baroffset.x = (weapon_size.x - barsize.x) / 2;
 778                 }
 779                 else
 780                 {
 781                         barsize.y = 1/aspect * weapon_size.x;
 782                         barsize.x = weapon_size.x;
 783                         baroffset.y = (weapon_size.y - barsize.y) / 2;
 784                 }
 785         }
 786         if(autocvar_hud_panel_weapons_accuracy)
 787                 Accuracy_LoadColors();
 788
 789         // draw items
 790         row = column = 0;
 791         vector label_size = '1 1 0' * min(weapon_size.x, weapon_size.y) * bound(0, autocvar_hud_panel_weapons_label_scale, 1);
 792         for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 793         {
 794                 // retrieve information about the current weapon to be drawn
 795                 self = weaponorder[i];
 796                 weapon_id = self.impulse;
 797
 798                 // skip if this weapon doesn't exist
 799                 if(!self || weapon_id < 0) { continue; }
 800
 801                 // skip this weapon if we don't own it (and onlyowned is enabled)-- or if weapons_complainbubble is showing for this weapon
 802                 if(autocvar_hud_panel_weapons_onlyowned)
 803                 if (!((weapons_stat & WepSet_FromWeapon(self.weapon)) || (self.weapon == complain_weapon)))
 804                         continue;
 805
 806                 // figure out the drawing position of weapon
 807                 weapon_pos = (panel_pos
 808                         + eX * column * weapon_size.x
 809                         + eY * row * weapon_size.y);
 810
 811                 // draw background behind currently selected weapon
 812                 if(self.weapon == switchweapon)
 813                         drawpic_aspect_skin(weapon_pos, "weapon_current_bg", weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 814
 815                 // draw the weapon accuracy
 816                 if(autocvar_hud_panel_weapons_accuracy)
 817                 {
 818                         float panel_weapon_accuracy = weapon_accuracy[self.weapon-WEP_FIRST];
 819                         if(panel_weapon_accuracy >= 0)
 820                         {
 821                                 color = Accuracy_GetColor(panel_weapon_accuracy);
 822                                 drawpic_aspect_skin(weapon_pos, "weapon_accuracy", weapon_size, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 823                         }
 824                 }
 825
 826                 // drawing all the weapon items
 827                 if(weapons_stat & WepSet_FromWeapon(self.weapon))
 828                 {
 829                         // draw the weapon image
 830                         drawpic_aspect_skin(weapon_pos, self.model2, weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 831
 832                         // draw weapon label string
 833                         switch(autocvar_hud_panel_weapons_label)
 834                         {
 835                                 case 1: // weapon number
 836                                         drawstring(weapon_pos, ftos(weapon_id), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 837                                         break;
 838
 839                                 case 2: // bind
 840                                         drawstring(weapon_pos, getcommandkey(ftos(weapon_id), strcat("weapon_group_", ftos(weapon_id))), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 841                                         break;
 842
 843                                 case 3: // weapon name
 844                                         drawstring(weapon_pos, strtolower(self.message), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 845                                         break;
 846
 847                                 default: // nothing
 848                                         break;
 849                         }
 850
 851                         // draw ammo status bar
 852                         if(autocvar_hud_panel_weapons_ammo && (self.ammo_field != ammo_none))
 853                         {
 854                                 float ammo_full;
 855                                 a = getstati(GetAmmoStat(self.ammo_field)); // how much ammo do we have?
 856
 857                                 if(a > 0)
 858                                 {
 859                                         switch(self.ammo_field)
 860                                         {
 861                                                 case ammo_shells:  ammo_full = autocvar_hud_panel_weapons_ammo_full_shells;  break;
 862                                                 case ammo_nails:   ammo_full = autocvar_hud_panel_weapons_ammo_full_nails;   break;
 863                                                 case ammo_rockets: ammo_full = autocvar_hud_panel_weapons_ammo_full_rockets; break;
 864                                                 case ammo_cells:   ammo_full = autocvar_hud_panel_weapons_ammo_full_cells;   break;
 865                                                 case ammo_plasma:  ammo_full = autocvar_hud_panel_weapons_ammo_full_plasma;  break;
 866                                                 case ammo_fuel:    ammo_full = autocvar_hud_panel_weapons_ammo_full_fuel;    break;
 867                                                 default: ammo_full = 60;
 868                                         }
 869
 870                                         drawsetcliparea(
 871                                                 weapon_pos.x + baroffset.x,
 872                                                 weapon_pos.y + baroffset.y,
 873                                                 barsize.x * bound(0, a/ammo_full, 1),
 874                                                 barsize.y
 875                                         );
 876
 877                                         drawpic_aspect_skin(
 878                                                 weapon_pos,
 879                                                 "weapon_ammo",
 880                                                 weapon_size,
 881                                                 ammo_color,
 882                                                 ammo_alpha,
 883                                                 DRAWFLAG_NORMAL
 884                                         );
 885
 886                                         drawresetcliparea();
 887                                 }
 888                         }
 889                 }
 890                 else // draw a "ghost weapon icon" if you don't have the weapon
 891                 {
 892                         drawpic_aspect_skin(weapon_pos, self.model2, weapon_size, '0 0 0', panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
 893                 }
 894
 895                 // draw the complain message
 896                 if(self.weapon == complain_weapon)
 897                 {
 898                         if(fadetime)
 899                                 a = ((complain_weapon_time + when > time) ? 1 : bound(0, (complain_weapon_time + when + fadetime - time) / fadetime, 1));
 900                         else
 901                                 a = ((complain_weapon_time + when > time) ? 1 : 0);
 902
 903                         string s;
 904                         if(complain_weapon_type == 0) {
 905                                 s = _("Out of ammo");
 906                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_outofammo);
 907                         }
 908                         else if(complain_weapon_type == 1) {
 909                                 s = _("Don't have");
 910                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_donthave);
 911                         }
 912                         else {
 913                                 s = _("Unavailable");
 914                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_unavailable);
 915                         }
 916                         float padding = autocvar_hud_panel_weapons_complainbubble_padding;
 917                         drawpic_aspect_skin(weapon_pos + '1 1 0' * padding, "weapon_complainbubble", weapon_size - '2 2 0' * padding, color, a * panel_fg_alpha, DRAWFLAG_NORMAL);
 918                         drawstring_aspect(weapon_pos + '1 1 0' * padding, s, weapon_size - '2 2 0' * padding, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 919                 }
 920
 921                 #if 0
 922                 /// debug code
 923                 if(!autocvar_hud_panel_weapons_onlyowned)
 924                 {
 925                         drawfill(weapon_pos + '1 1 0', weapon_size - '2 2 0', '1 1 1', panel_fg_alpha * 0.2, DRAWFLAG_NORMAL);
 926                         drawstring(weapon_pos, ftos(i + 1), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 927                 }
 928                 #endif
 929
 930                 // continue with new position for the next weapon
 931                 if(vertical_order)
 932                 {
 933                         ++column;
 934                         if(column >= columns)
 935                         {
 936                                 column = 0;
 937                                 ++row;
 938                         }
 939                 }
 940                 else
 941                 {
 942                         ++row;
 943                         if(row >= rows)
 944                         {
 945                                 row = 0;
 946                                 ++column;
 947                         }
 948                 }
 949         }
 950 }
 951
 952 // Ammo (#1)
 953 void DrawNadeProgressBar(vector myPos, vector mySize, float progress, vector color)
 954 {
 955         HUD_Panel_DrawProgressBar(
 956                 myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x,
 957                 mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x,
 958                 autocvar_hud_panel_ammo_progressbar_name,
 959                 progress, 0, 0, color,
 960                 autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 961 }
 962
 963 void DrawAmmoNades(vector myPos, vector mySize, bool draw_expanding, float expand_time)
 964 {
 965         float bonusNades    = getstatf(STAT_NADE_BONUS);
 966         float bonusProgress = getstatf(STAT_NADE_BONUS_SCORE);
 967         float bonusType     = getstati(STAT_NADE_BONUS_TYPE);
 968         vector nadeColor    = Nade_Color(bonusType);
 969         string nadeIcon     = Nade_Icon(bonusType);
 970
 971         vector iconPos, textPos;
 972
 973         if(autocvar_hud_panel_ammo_iconalign)
 974         {
 975                 iconPos = myPos + eX * 2 * mySize.y;
 976                 textPos = myPos;
 977         }
 978         else
 979         {
 980                 iconPos = myPos;
 981                 textPos = myPos + eX * mySize.y;
 982         }
 983
 984         if(bonusNades > 0 || bonusProgress > 0)
 985         {
 986                 DrawNadeProgressBar(myPos, mySize, bonusProgress, nadeColor);
 987
 988                 if(autocvar_hud_panel_ammo_text)
 989                         drawstring_aspect(textPos, ftos(bonusNades), eX * (2/3) * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 990
 991                 if(draw_expanding)
 992                         drawpic_aspect_skin_expanding(iconPos, nadeIcon, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, expand_time);
 993
 994                 drawpic_aspect_skin(iconPos, nadeIcon, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 995         }
 996 }
 997
 998 void DrawAmmoItem(vector myPos, vector mySize, .int ammoType, bool isCurrent, bool isInfinite)
 999 {
1000         if(ammoType == ammo_none)
1001                 return;
1002
1003         // Initialize variables
1004
1005         int ammo;
1006         if(autocvar__hud_configure)
1007         {
1008                 isCurrent = (ammoType == ammo_rockets); // Rockets always current
1009                 ammo = 60;
1010         }
1011         else
1012                 ammo = getstati(GetAmmoStat(ammoType));
1013
1014         if(!isCurrent)
1015         {
1016                 float scale = bound(0, autocvar_hud_panel_ammo_noncurrent_scale, 1);
1017                 myPos = myPos + (mySize - mySize * scale) * 0.5;
1018                 mySize = mySize * scale;
1019         }
1020
1021         vector iconPos, textPos;
1022         if(autocvar_hud_panel_ammo_iconalign)
1023         {
1024                 iconPos = myPos + eX * 2 * mySize.y;
1025                 textPos = myPos;
1026         }
1027         else
1028         {
1029                 iconPos = myPos;
1030                 textPos = myPos + eX * mySize.y;
1031         }
1032
1033         bool isShadowed = (ammo <= 0 && !isCurrent && !isInfinite);
1034
1035         vector iconColor = isShadowed ? '0 0 0' : '1 1 1';
1036         vector textColor;
1037         if(isInfinite)
1038                 textColor = '0.2 0.95 0';
1039         else if(isShadowed)
1040                 textColor = '0 0 0';
1041         else if(ammo < 10)
1042                 textColor = '0.8 0.04 0';
1043         else
1044                 textColor = '1 1 1';
1045
1046         float alpha;
1047         if(isCurrent)
1048                 alpha = panel_fg_alpha;
1049         else if(isShadowed)
1050                 alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_ammo_noncurrent_alpha, 1) * 0.5;
1051         else
1052                 alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_ammo_noncurrent_alpha, 1);
1053
1054         string text = isInfinite ? "\xE2\x88\x9E" : ftos(ammo); // Use infinity symbol (U+221E)
1055
1056         // Draw item
1057
1058         if(isCurrent)
1059                 drawpic_aspect_skin(myPos, "ammo_current_bg", mySize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1060
1061         if(ammo > 0 && autocvar_hud_panel_ammo_progressbar)
1062                 HUD_Panel_DrawProgressBar(myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x, mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x, autocvar_hud_panel_ammo_progressbar_name, ammo/autocvar_hud_panel_ammo_maxammo, 0, 0, textColor, autocvar_hud_progressbar_alpha * alpha, DRAWFLAG_NORMAL);
1063
1064         if(autocvar_hud_panel_ammo_text)
1065                 drawstring_aspect(textPos, text, eX * (2/3) * mySize.x + eY * mySize.y, textColor, alpha, DRAWFLAG_NORMAL);
1066
1067         drawpic_aspect_skin(iconPos, GetAmmoPicture(ammoType), '1 1 0' * mySize.y, iconColor, alpha, DRAWFLAG_NORMAL);
1068 }
1069
1070 int nade_prevstatus;
1071 int nade_prevframe;
1072 float nade_statuschange_time;
1073 void HUD_Ammo(void)
1074 {
1075         if(hud != HUD_NORMAL) return;
1076         if(!autocvar__hud_configure)
1077         {
1078                 if(!autocvar_hud_panel_ammo) return;
1079                 if(spectatee_status == -1) return;
1080         }
1081
1082         HUD_Panel_UpdateCvars();
1083
1084         draw_beginBoldFont();
1085
1086         vector pos, mySize;
1087         pos = panel_pos;
1088         mySize = panel_size;
1089
1090         HUD_Panel_DrawBg(1);
1091         if(panel_bg_padding)
1092         {
1093                 pos += '1 1 0' * panel_bg_padding;
1094                 mySize -= '2 2 0' * panel_bg_padding;
1095         }
1096
1097         int rows = 0, columns, row, column;
1098         float nade_cnt = getstatf(STAT_NADE_BONUS), nade_score = getstatf(STAT_NADE_BONUS_SCORE);
1099         bool draw_nades = (nade_cnt > 0 || nade_score > 0);
1100         float nade_statuschange_elapsedtime;
1101         int total_ammo_count;
1102
1103         vector ammo_size;
1104         if (autocvar_hud_panel_ammo_onlycurrent)
1105                 total_ammo_count = 1;
1106         else
1107                 total_ammo_count = AMMO_COUNT;
1108
1109         if(draw_nades)
1110         {
1111                 ++total_ammo_count;
1112                 if (nade_cnt != nade_prevframe)
1113                 {
1114                         nade_statuschange_time = time;
1115                         nade_prevstatus = nade_prevframe;
1116                         nade_prevframe = nade_cnt;
1117                 }
1118         }
1119         else
1120                 nade_prevstatus = nade_prevframe = nade_statuschange_time = 0;
1121
1122         rows = HUD_GetRowCount(total_ammo_count, mySize, 3);
1123         columns = ceil((total_ammo_count)/rows);
1124         ammo_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
1125
1126         vector offset = '0 0 0'; // fteqcc sucks
1127         float newSize;
1128         if(ammo_size.x/ammo_size.y > 3)
1129         {
1130                 newSize = 3 * ammo_size.y;
1131                 offset.x = ammo_size.x - newSize;
1132                 pos.x += offset.x/2;
1133                 ammo_size.x = newSize;
1134         }
1135         else
1136         {
1137                 newSize = 1/3 * ammo_size.x;
1138                 offset.y = ammo_size.y - newSize;
1139                 pos.y += offset.y/2;
1140                 ammo_size.y = newSize;
1141         }
1142
1143         int i;
1144         bool infinite_ammo = (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_WEAPON_AMMO);
1145         row = column = 0;
1146         if(autocvar_hud_panel_ammo_onlycurrent)
1147         {
1148                 if(autocvar__hud_configure)
1149                 {
1150                         DrawAmmoItem(pos, ammo_size, ammo_rockets, true, false);
1151                 }
1152                 else
1153                 {
1154                         DrawAmmoItem(
1155                                 pos,
1156                                 ammo_size,
1157                                 (get_weaponinfo(switchweapon)).ammo_field,
1158                                 true,
1159                                 infinite_ammo
1160                         );
1161                 }
1162
1163                 ++row;
1164                 if(row >= rows)
1165                 {
1166                         row = 0;
1167                         column = column + 1;
1168                 }
1169         }
1170         else
1171         {
1172                 .int ammotype;
1173                 row = column = 0;
1174                 for(i = 0; i < AMMO_COUNT; ++i)
1175                 {
1176                         ammotype = GetAmmoFieldFromNum(i);
1177                         DrawAmmoItem(
1178                                 pos + eX * column * (ammo_size.x + offset.x) + eY * row * (ammo_size.y + offset.y),
1179                                 ammo_size,
1180                                 ammotype,
1181                                 ((get_weaponinfo(switchweapon)).ammo_field == ammotype),
1182                                 infinite_ammo
1183                         );
1184
1185                         ++row;
1186                         if(row >= rows)
1187                         {
1188                                 row = 0;
1189                                 column = column + 1;
1190                         }
1191                 }
1192         }
1193
1194         if (draw_nades)
1195         {
1196                 nade_statuschange_elapsedtime = time - nade_statuschange_time;
1197
1198                 float f = bound(0, nade_statuschange_elapsedtime*2, 1);
1199
1200                 DrawAmmoNades(pos + eX * column * (ammo_size.x + offset.x) + eY * row * (ammo_size.y + offset.y), ammo_size, nade_prevstatus < nade_cnt && nade_cnt != 0 && f < 1, f);
1201         }
1202
1203         draw_endBoldFont();
1204 }
1205
1206 void DrawNumIcon_expanding(vector myPos, vector mySize, float x, string icon, bool vertical, bool icon_right_align, vector color, float theAlpha, float fadelerp)
1207 {
1208         vector newPos = '0 0 0', newSize = '0 0 0';
1209         vector picpos, numpos;
1210
1211         if (vertical)
1212         {
1213                 if(mySize.y/mySize.x > 2)
1214                 {
1215                         newSize.y = 2 * mySize.x;
1216                         newSize.x = mySize.x;
1217
1218                         newPos.y = myPos.y + (mySize.y - newSize.y) / 2;
1219                         newPos.x = myPos.x;
1220                 }
1221                 else
1222                 {
1223                         newSize.x = 1/2 * mySize.y;
1224                         newSize.y = mySize.y;
1225
1226                         newPos.x = myPos.x + (mySize.x - newSize.x) / 2;
1227                         newPos.y = myPos.y;
1228                 }
1229
1230                 if(icon_right_align)
1231                 {
1232                         numpos = newPos;
1233                         picpos = newPos + eY * newSize.x;
1234                 }
1235                 else
1236                 {
1237                         picpos = newPos;
1238                         numpos = newPos + eY * newSize.x;
1239                 }
1240
1241                 newSize.y /= 2;
1242                 drawpic_aspect_skin(picpos, icon, newSize, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1243                 // make number smaller than icon, it looks better
1244                 // reduce only y to draw numbers with different number of digits with the same y size
1245                 numpos.y += newSize.y * ((1 - 0.7) / 2);
1246                 newSize.y *= 0.7;
1247                 drawstring_aspect(numpos, ftos(x), newSize, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1248                 return;
1249         }
1250
1251         if(mySize.x/mySize.y > 3)
1252         {
1253                 newSize.x = 3 * mySize.y;
1254                 newSize.y = mySize.y;
1255
1256                 newPos.x = myPos.x + (mySize.x - newSize.x) / 2;
1257                 newPos.y = myPos.y;
1258         }
1259         else
1260         {
1261                 newSize.y = 1/3 * mySize.x;
1262                 newSize.x = mySize.x;
1263
1264                 newPos.y = myPos.y + (mySize.y - newSize.y) / 2;
1265                 newPos.x = myPos.x;
1266         }
1267
1268         if(icon_right_align) // right align
1269         {
1270                 numpos = newPos;
1271                 picpos = newPos + eX * 2 * newSize.y;
1272         }
1273         else // left align
1274         {
1275                 numpos = newPos + eX * newSize.y;
1276                 picpos = newPos;
1277         }
1278
1279         // NOTE: newSize_x is always equal to 3 * mySize_y so we can use
1280         // '2 1 0' * newSize_y instead of eX * (2/3) * newSize_x + eY * newSize_y
1281         drawstring_aspect_expanding(numpos, ftos(x), '2 1 0' * newSize.y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1282         drawpic_aspect_skin_expanding(picpos, icon, '1 1 0' * newSize.y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1283 }
1284
1285 void DrawNumIcon(vector myPos, vector mySize, float x, string icon, bool vertical, bool icon_right_align, vector color, float theAlpha)
1286 {
1287         DrawNumIcon_expanding(myPos, mySize, x, icon, vertical, icon_right_align, color, theAlpha, 0);
1288 }
1289
1290 // Powerups (#2)
1291 //
1292 void HUD_Powerups(void)
1293 {
1294         float strength_time, shield_time, superweapons_time;
1295         if(!autocvar__hud_configure)
1296         {
1297                 if(!autocvar_hud_panel_powerups) return;
1298                 if(spectatee_status == -1) return;
1299                 if(!(getstati(STAT_ITEMS, 0, 24) & (IT_STRENGTH | IT_INVINCIBLE | IT_SUPERWEAPON))) return;
1300                 if (getstati(STAT_HEALTH) <= 0) return;
1301
1302                 strength_time = bound(0, getstatf(STAT_STRENGTH_FINISHED) - time, 99);
1303                 shield_time = bound(0, getstatf(STAT_INVINCIBLE_FINISHED) - time, 99);
1304                 superweapons_time = bound(0, getstatf(STAT_SUPERWEAPONS_FINISHED) - time, 99);
1305
1306                 if (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_SUPERWEAPONS)
1307                         superweapons_time = 99; // force max
1308
1309                 // prevent stuff to show up on mismatch that will be fixed next frame
1310                 if (!(getstati(STAT_ITEMS, 0, 24) & IT_SUPERWEAPON))
1311                         superweapons_time = 0;
1312         }
1313         else
1314         {
1315                 strength_time = 15;
1316                 shield_time = 27;
1317                 superweapons_time = 13;
1318         }
1319
1320         HUD_Panel_UpdateCvars();
1321
1322         draw_beginBoldFont();
1323
1324         vector pos, mySize;
1325         pos = panel_pos;
1326         mySize = panel_size;
1327
1328         HUD_Panel_DrawBg(bound(0, max(strength_time, shield_time, superweapons_time), 1));
1329         if(panel_bg_padding)
1330         {
1331                 pos += '1 1 0' * panel_bg_padding;
1332                 mySize -= '2 2 0' * panel_bg_padding;
1333         }
1334
1335         float panel_ar = mySize.x/mySize.y;
1336         bool is_vertical = (panel_ar < 1);
1337         vector shield_offset = '0 0 0', strength_offset = '0 0 0', superweapons_offset = '0 0 0';
1338
1339         int superweapons_is = -1;
1340
1341         if(superweapons_time)
1342         {
1343                 if(strength_time)
1344                 {
1345                         if(shield_time)
1346                                 superweapons_is = 0;
1347                         else
1348                                 superweapons_is = 2;
1349                 }
1350                 else
1351                 {
1352                         if(shield_time)
1353                                 superweapons_is = 1;
1354                         else
1355                                 superweapons_is = 2;
1356                 }
1357         }
1358
1359         // FIXME handle superweapons here
1360         if(superweapons_is == 0)
1361         {
1362                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1363                 {
1364                         mySize.x *= (1.0 / 3.0);
1365                         superweapons_offset.x = mySize.x;
1366                         if (autocvar_hud_panel_powerups_flip)
1367                                 shield_offset.x = 2*mySize.x;
1368                         else
1369                                 strength_offset.x = 2*mySize.x;
1370                 }
1371                 else
1372                 {
1373                         mySize.y *= (1.0 / 3.0);
1374                         superweapons_offset.y = mySize.y;
1375                         if (autocvar_hud_panel_powerups_flip)
1376                                 shield_offset.y = 2*mySize.y;
1377                         else
1378                                 strength_offset.y = 2*mySize.y;
1379                 }
1380         }
1381         else
1382         {
1383                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1384                 {
1385                         mySize.x *= 0.5;
1386                         if (autocvar_hud_panel_powerups_flip)
1387                                 shield_offset.x = mySize.x;
1388                         else
1389                                 strength_offset.x = mySize.x;
1390                 }
1391                 else
1392                 {
1393                         mySize.y *= 0.5;
1394                         if (autocvar_hud_panel_powerups_flip)
1395                                 shield_offset.y = mySize.y;
1396                         else
1397                                 strength_offset.y = mySize.y;
1398                 }
1399         }
1400
1401         bool shield_baralign, strength_baralign, superweapons_baralign;
1402         bool shield_iconalign, strength_iconalign, superweapons_iconalign;
1403
1404         if (autocvar_hud_panel_powerups_flip)
1405         {
1406                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1407                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1408                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1409                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1410         }
1411         else
1412         {
1413                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1414                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1415                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1416                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1417         }
1418
1419         if(superweapons_is == 0)
1420         {
1421                 superweapons_iconalign = strength_iconalign;
1422                 superweapons_baralign = 2;
1423         }
1424         else if(superweapons_is == 1)
1425         {
1426                 superweapons_offset = strength_offset;
1427                 superweapons_iconalign = strength_iconalign;
1428                 superweapons_baralign = strength_baralign;
1429         }
1430         else // if(superweapons_is == 2)
1431         {
1432                 superweapons_offset = shield_offset;
1433                 superweapons_iconalign = shield_iconalign;
1434                 superweapons_baralign = shield_baralign;
1435         }
1436
1437         if(shield_time)
1438         {
1439                 const float maxshield = 30;
1440                 float shield = ceil(shield_time);
1441                 if(autocvar_hud_panel_powerups_progressbar)
1442                         HUD_Panel_DrawProgressBar(pos + shield_offset, mySize, autocvar_hud_panel_powerups_progressbar_shield, shield/maxshield, is_vertical, shield_baralign, autocvar_hud_progressbar_shield_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1443                 if(autocvar_hud_panel_powerups_text)
1444                 {
1445                         if(shield > 1)
1446                                 DrawNumIcon(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1);
1447                         if(shield <= 5)
1448                                 DrawNumIcon_expanding(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1, bound(0, (shield - shield_time) / 0.5, 1));
1449                 }
1450         }
1451
1452         if(strength_time)
1453         {
1454                 const float maxstrength = 30;
1455                 float strength = ceil(strength_time);
1456                 if(autocvar_hud_panel_powerups_progressbar)
1457                         HUD_Panel_DrawProgressBar(pos + strength_offset, mySize, autocvar_hud_panel_powerups_progressbar_strength, strength/maxstrength, is_vertical, strength_baralign, autocvar_hud_progressbar_strength_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1458                 if(autocvar_hud_panel_powerups_text)
1459                 {
1460                         if(strength > 1)
1461                                 DrawNumIcon(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1);
1462                         if(strength <= 5)
1463                                 DrawNumIcon_expanding(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1, bound(0, (strength - strength_time) / 0.5, 1));
1464                 }
1465         }
1466
1467         if(superweapons_time)
1468         {
1469                 const float maxsuperweapons = 30;
1470                 float superweapons = ceil(superweapons_time);
1471                 if(autocvar_hud_panel_powerups_progressbar)
1472                         HUD_Panel_DrawProgressBar(pos + superweapons_offset, mySize, autocvar_hud_panel_powerups_progressbar_superweapons, superweapons/maxsuperweapons, is_vertical, superweapons_baralign, autocvar_hud_progressbar_superweapons_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1473                 if(autocvar_hud_panel_powerups_text)
1474                 {
1475                         if(superweapons > 1)
1476                                 DrawNumIcon(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1);
1477                         if(superweapons <= 5)
1478                                 DrawNumIcon_expanding(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1, bound(0, (superweapons - superweapons_time) / 0.5, 1));
1479                 }
1480         }
1481
1482         draw_endBoldFont();
1483 }
1484
1485 // Health/armor (#3)
1486 //
1487
1488
1489 void HUD_HealthArmor(void)
1490 {
1491         int armor, health, fuel;
1492         if(!autocvar__hud_configure)
1493         {
1494                 if(!autocvar_hud_panel_healtharmor) return;
1495                 if(hud != HUD_NORMAL) return;
1496                 if(spectatee_status == -1) return;
1497
1498                 health = getstati(STAT_HEALTH);
1499                 if(health <= 0)
1500                 {
1501                         prev_health = -1;
1502                         return;
1503                 }
1504                 armor = getstati(STAT_ARMOR);
1505
1506                 // code to check for spectatee_status changes is in Ent_ClientData()
1507                 // prev_p_health and prev_health can be set to -1 there
1508
1509                 if (prev_p_health == -1)
1510                 {
1511                         // no effect
1512                         health_beforedamage = 0;
1513                         armor_beforedamage = 0;
1514                         health_damagetime = 0;
1515                         armor_damagetime = 0;
1516                         prev_health = health;
1517                         prev_armor = armor;
1518                         old_p_health = health;
1519                         old_p_armor = armor;
1520                         prev_p_health = health;
1521                         prev_p_armor = armor;
1522                 }
1523                 else if (prev_health == -1)
1524                 {
1525                         //start the load effect
1526                         health_damagetime = 0;
1527                         armor_damagetime = 0;
1528                         prev_health = 0;
1529                         prev_armor = 0;
1530                 }
1531                 fuel = getstati(STAT_FUEL);
1532         }
1533         else
1534         {
1535                 health = 150;
1536                 armor = 75;
1537                 fuel = 20;
1538         }
1539
1540         HUD_Panel_UpdateCvars();
1541
1542         draw_beginBoldFont();
1543
1544         vector pos, mySize;
1545         pos = panel_pos;
1546         mySize = panel_size;
1547
1548         HUD_Panel_DrawBg(1);
1549         if(panel_bg_padding)
1550         {
1551                 pos += '1 1 0' * panel_bg_padding;
1552                 mySize -= '2 2 0' * panel_bg_padding;
1553         }
1554
1555         int baralign = autocvar_hud_panel_healtharmor_baralign;
1556         int iconalign = autocvar_hud_panel_healtharmor_iconalign;
1557
1558     int maxhealth = autocvar_hud_panel_healtharmor_maxhealth;
1559     int maxarmor = autocvar_hud_panel_healtharmor_maxarmor;
1560         if(autocvar_hud_panel_healtharmor == 2) // combined health and armor display
1561         {
1562                 vector v;
1563                 v = healtharmor_maxdamage(health, armor, armorblockpercent, DEATH_WEAPON);
1564
1565                 float x;
1566                 x = floor(v.x + 1);
1567
1568         float maxtotal = maxhealth + maxarmor;
1569                 string biggercount;
1570                 if(v.z) // NOT fully armored
1571                 {
1572                         biggercount = "health";
1573                         if(autocvar_hud_panel_healtharmor_progressbar)
1574                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_health, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1575                         if(armor)
1576             if(autocvar_hud_panel_healtharmor_text)
1577                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "armor", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha * armor / health, DRAWFLAG_NORMAL);
1578                 }
1579                 else
1580                 {
1581                         biggercount = "armor";
1582                         if(autocvar_hud_panel_healtharmor_progressbar)
1583                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1584                         if(health)
1585             if(autocvar_hud_panel_healtharmor_text)
1586                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "health", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1587                 }
1588         if(autocvar_hud_panel_healtharmor_text)
1589                         DrawNumIcon(pos, mySize, x, biggercount, 0, iconalign, HUD_Get_Num_Color(x, maxtotal), 1);
1590
1591                 if(fuel)
1592                         HUD_Panel_DrawProgressBar(pos, eX * mySize.x + eY * 0.2 * mySize.y, "progressbar", fuel/100, 0, (baralign == 1 || baralign == 3), autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1593         }
1594         else
1595         {
1596                 float panel_ar = mySize.x/mySize.y;
1597                 bool is_vertical = (panel_ar < 1);
1598                 vector health_offset = '0 0 0', armor_offset = '0 0 0';
1599                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1600                 {
1601                         mySize.x *= 0.5;
1602                         if (autocvar_hud_panel_healtharmor_flip)
1603                                 health_offset.x = mySize.x;
1604                         else
1605                                 armor_offset.x = mySize.x;
1606                 }
1607                 else
1608                 {
1609                         mySize.y *= 0.5;
1610                         if (autocvar_hud_panel_healtharmor_flip)
1611                                 health_offset.y = mySize.y;
1612                         else
1613                                 armor_offset.y = mySize.y;
1614                 }
1615
1616                 bool health_baralign, armor_baralign, fuel_baralign;
1617                 bool health_iconalign, armor_iconalign;
1618                 if (autocvar_hud_panel_healtharmor_flip)
1619                 {
1620                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1621                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1622                         fuel_baralign = health_baralign;
1623                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1624                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1625                 }
1626                 else
1627                 {
1628                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1629                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1630                         fuel_baralign = armor_baralign;
1631                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1632                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1633                 }
1634
1635                 //if(health)
1636                 {
1637                         if(autocvar_hud_panel_healtharmor_progressbar)
1638                         {
1639                                 float p_health, pain_health_alpha;
1640                                 p_health = health;
1641                                 pain_health_alpha = 1;
1642                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1643                                 {
1644                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1645                                         {
1646                                                 if (fabs(prev_health - health) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1647                                                 {
1648                                                         if (time - old_p_healthtime < 1)
1649                                                                 old_p_health = prev_p_health;
1650                                                         else
1651                                                                 old_p_health = prev_health;
1652                                                         old_p_healthtime = time;
1653                                                 }
1654                                                 if (time - old_p_healthtime < 1)
1655                                                 {
1656                                                         p_health += (old_p_health - health) * (1 - (time - old_p_healthtime));
1657                                                         prev_p_health = p_health;
1658                                                 }
1659                                         }
1660                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1661                                         {
1662                                                 if (prev_health - health >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1663                                                 {
1664                                                         if (time - health_damagetime >= 1)
1665                                                                 health_beforedamage = prev_health;
1666                                                         health_damagetime = time;
1667                                                 }
1668                                                 if (time - health_damagetime < 1)
1669                                                 {
1670                                                         float health_damagealpha = 1 - (time - health_damagetime)*(time - health_damagetime);
1671                                                         HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, health_beforedamage/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * health_damagealpha, DRAWFLAG_NORMAL);
1672                                                 }
1673                                         }
1674                                         prev_health = health;
1675
1676                                         if (health <= autocvar_hud_panel_healtharmor_progressbar_gfx_lowhealth)
1677                                         {
1678                                                 float BLINK_FACTOR = 0.15;
1679                                                 float BLINK_BASE = 0.85;
1680                                                 float BLINK_FREQ = 9;
1681                                                 pain_health_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
1682                                         }
1683                                 }
1684                                 HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, p_health/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * pain_health_alpha, DRAWFLAG_NORMAL);
1685                         }
1686                         if(autocvar_hud_panel_healtharmor_text)
1687                                 DrawNumIcon(pos + health_offset, mySize, health, "health", is_vertical, health_iconalign, HUD_Get_Num_Color(health, maxhealth), 1);
1688                 }
1689
1690                 if(armor)
1691                 {
1692                         if(autocvar_hud_panel_healtharmor_progressbar)
1693                         {
1694                                 float p_armor;
1695                                 p_armor = armor;
1696                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1697                                 {
1698                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1699                                         {
1700                                                 if (fabs(prev_armor - armor) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1701                                                 {
1702                                                         if (time - old_p_armortime < 1)
1703                                                                 old_p_armor = prev_p_armor;
1704                                                         else
1705                                                                 old_p_armor = prev_armor;
1706                                                         old_p_armortime = time;
1707                                                 }
1708                                                 if (time - old_p_armortime < 1)
1709                                                 {
1710                                                         p_armor += (old_p_armor - armor) * (1 - (time - old_p_armortime));
1711                                                         prev_p_armor = p_armor;
1712                                                 }
1713                                         }
1714                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1715                                         {
1716                                                 if (prev_armor - armor >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1717                                                 {
1718                                                         if (time - armor_damagetime >= 1)
1719                                                                 armor_beforedamage = prev_armor;
1720                                                         armor_damagetime = time;
1721                                                 }
1722                                                 if (time - armor_damagetime < 1)
1723                                                 {
1724                                                         float armor_damagealpha = 1 - (time - armor_damagetime)*(time - armor_damagetime);
1725                                                         HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, armor_beforedamage/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * armor_damagealpha, DRAWFLAG_NORMAL);
1726                                                 }
1727                                         }
1728                                         prev_armor = armor;
1729                                 }
1730                                 HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, p_armor/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1731                         }
1732                         if(autocvar_hud_panel_healtharmor_text)
1733                                 DrawNumIcon(pos + armor_offset, mySize, armor, "armor", is_vertical, armor_iconalign, HUD_Get_Num_Color(armor, maxarmor), 1);
1734                 }
1735
1736                 if(fuel)
1737                 {
1738                         if (is_vertical)
1739                                 mySize.x *= 0.2 / 2; //if vertical always halve x to not cover too much numbers with 3 digits
1740                         else
1741                                 mySize.y *= 0.2;
1742                         if (panel_ar >= 4)
1743                                 mySize.x *= 2; //restore full panel size
1744                         else if (panel_ar < 1/4)
1745                                 mySize.y *= 2; //restore full panel size
1746                         HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", fuel/100, is_vertical, fuel_baralign, autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1747                 }
1748         }
1749
1750         draw_endBoldFont();
1751 }
1752
1753 // Notification area (#4)
1754 //
1755
1756 void HUD_Notify_Push(string icon, string attacker, string victim)
1757 {
1758         if (icon == "")
1759                 return;
1760
1761         ++notify_count;
1762         --notify_index;
1763
1764         if (notify_index == -1)
1765                 notify_index = NOTIFY_MAX_ENTRIES-1;
1766
1767         // Free old strings
1768         if (notify_attackers[notify_index])
1769                 strunzone(notify_attackers[notify_index]);
1770
1771         if (notify_victims[notify_index])
1772                 strunzone(notify_victims[notify_index]);
1773
1774         if (notify_icons[notify_index])
1775                 strunzone(notify_icons[notify_index]);
1776
1777         // Allocate new strings
1778         if (victim != "")
1779         {
1780                 notify_attackers[notify_index] = strzone(attacker);
1781                 notify_victims[notify_index] = strzone(victim);
1782         }
1783         else
1784         {
1785                 // In case of a notification without a victim, the attacker
1786                 // is displayed on the victim's side. Instead of special
1787                 // treatment later on, we can simply switch them here.
1788                 notify_attackers[notify_index] = string_null;
1789                 notify_victims[notify_index] = strzone(attacker);
1790         }
1791
1792         notify_icons[notify_index] = strzone(icon);
1793         notify_times[notify_index] = time;
1794 }
1795
1796 void HUD_Notify(void)
1797 {
1798         if (!autocvar__hud_configure)
1799                 if (!autocvar_hud_panel_notify)
1800                         return;
1801
1802         HUD_Panel_UpdateCvars();
1803         HUD_Panel_DrawBg(1);
1804
1805         if (!autocvar__hud_configure)
1806                 if (notify_count == 0)
1807                         return;
1808
1809         vector pos, size;
1810         pos  = panel_pos;
1811         size = panel_size;
1812
1813         if (panel_bg_padding)
1814         {
1815                 pos  += '1 1 0' * panel_bg_padding;
1816                 size -= '2 2 0' * panel_bg_padding;
1817         }
1818
1819         float fade_start = max(0, autocvar_hud_panel_notify_time);
1820         float fade_time = max(0, autocvar_hud_panel_notify_fadetime);
1821         float icon_aspect = max(1, autocvar_hud_panel_notify_icon_aspect);
1822
1823         int entry_count = bound(1, floor(NOTIFY_MAX_ENTRIES * size.y / size.x), NOTIFY_MAX_ENTRIES);
1824         float entry_height = size.y / entry_count;
1825
1826         float panel_width_half = size.x * 0.5;
1827         float icon_width_half = entry_height * icon_aspect / 2;
1828         float name_maxwidth = panel_width_half - icon_width_half - size.x * NOTIFY_ICON_MARGIN;
1829
1830         vector font_size = '0.5 0.5 0' * entry_height * autocvar_hud_panel_notify_fontsize;
1831         vector icon_size = (eX * icon_aspect + eY) * entry_height;
1832         vector icon_left = eX * (panel_width_half - icon_width_half);
1833         vector attacker_right = eX * name_maxwidth;
1834         vector victim_left = eX * (size.x - name_maxwidth);
1835
1836         vector attacker_pos, victim_pos, icon_pos;
1837         string attacker, victim, icon;
1838         int i, j, count, step, limit;
1839         float alpha;
1840
1841         if (autocvar_hud_panel_notify_flip)
1842         {
1843                 // Order items from the top down
1844                 i = 0;
1845                 step = +1;
1846                 limit = entry_count;
1847         }
1848         else
1849         {
1850                 // Order items from the bottom up
1851                 i = entry_count - 1;
1852                 step = -1;
1853                 limit = -1;
1854         }
1855
1856         for (j = notify_index, count = 0; i != limit; i += step, ++j, ++count)
1857         {
1858                 if(autocvar__hud_configure)
1859                 {
1860                         attacker = sprintf(_("Player %d"), count + 1);
1861                         victim = sprintf(_("Player %d"), count + 2);
1862                         icon = get_weaponinfo(min(WEP_FIRST + count * 2, WEP_LAST)).model2;
1863                         alpha = bound(0, 1.2 - count / entry_count, 1);
1864                 }
1865                 else
1866                 {
1867                         if (j == NOTIFY_MAX_ENTRIES)
1868                                 j = 0;
1869
1870                         if (notify_times[j] + fade_start > time)
1871                                 alpha = 1;
1872                         else if (fade_time != 0)
1873                         {
1874                                 alpha = bound(0, (notify_times[j] + fade_start + fade_time - time) / fade_time, 1);
1875                                 if (alpha == 0)
1876                                         break;
1877                         }
1878                         else
1879                                 break;
1880
1881                         attacker = notify_attackers[j];
1882                         victim = notify_victims[j];
1883                         icon = notify_icons[j];
1884                 }
1885
1886                 if (icon != "" && victim != "")
1887                 {
1888                         vector name_top = eY * (i * entry_height + 0.5 * (entry_height - font_size.y));
1889
1890                         icon_pos = pos + icon_left + eY * i * entry_height;
1891                         drawpic_aspect_skin(icon_pos, icon, icon_size, '1 1 1', panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1892
1893                         victim = textShortenToWidth(victim, name_maxwidth, font_size, stringwidth_colors);
1894                         victim_pos = pos + victim_left + name_top;
1895                         drawcolorcodedstring(victim_pos, victim, font_size, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1896
1897                         if (attacker != "")
1898                         {
1899                                 attacker = textShortenToWidth(attacker, name_maxwidth, font_size, stringwidth_colors);
1900                                 attacker_pos = pos + attacker_right - eX * stringwidth(attacker, true, font_size) + name_top;
1901                                 drawcolorcodedstring(attacker_pos, attacker, font_size, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1902                         }
1903                 }
1904         }
1905
1906         notify_count = count;
1907 }
1908
1909 // Timer (#5)
1910 //
1911 // TODO: macro
1912 string seconds_tostring(float sec)
1913 {
1914         float minutes;
1915         minutes = floor(sec / 60);
1916
1917         sec -= minutes * 60;
1918         return sprintf("%d:%02d", minutes, sec);
1919 }
1920
1921 void HUD_Timer(void)
1922 {
1923         if(!autocvar__hud_configure)
1924         {
1925                 if(!autocvar_hud_panel_timer) return;
1926         }
1927
1928         HUD_Panel_UpdateCvars();
1929
1930         draw_beginBoldFont();
1931
1932         vector pos, mySize;
1933         pos = panel_pos;
1934         mySize = panel_size;
1935
1936         HUD_Panel_DrawBg(1);
1937         if(panel_bg_padding)
1938         {
1939                 pos += '1 1 0' * panel_bg_padding;
1940                 mySize -= '2 2 0' * panel_bg_padding;
1941         }
1942
1943         string timer;
1944         float timelimit, elapsedTime, timeleft, minutesLeft;
1945
1946         timelimit = getstatf(STAT_TIMELIMIT);
1947
1948         timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
1949         timeleft = ceil(timeleft);
1950
1951         minutesLeft = floor(timeleft / 60);
1952
1953         vector timer_color;
1954         if(minutesLeft >= 5 || warmup_stage || timelimit == 0) //don't use red or yellow in warmup or when there is no timelimit
1955                 timer_color = '1 1 1'; //white
1956         else if(minutesLeft >= 1)
1957                 timer_color = '1 1 0'; //yellow
1958         else
1959                 timer_color = '1 0 0'; //red
1960
1961         if (autocvar_hud_panel_timer_increment || timelimit == 0 || warmup_stage) {
1962                 if (time < getstatf(STAT_GAMESTARTTIME)) {
1963                         //while restart is still active, show 00:00
1964                         timer = seconds_tostring(0);
1965                 } else {
1966                         elapsedTime = floor(time - getstatf(STAT_GAMESTARTTIME)); //127
1967                         timer = seconds_tostring(elapsedTime);
1968                 }
1969         } else {
1970                 timer = seconds_tostring(timeleft);
1971         }
1972
1973         drawstring_aspect(pos, timer, mySize, timer_color, panel_fg_alpha, DRAWFLAG_NORMAL);
1974
1975         draw_endBoldFont();
1976 }
1977
1978 // Radar (#6)
1979 //
1980 void HUD_Radar(void)
1981 {
1982         if (!autocvar__hud_configure)
1983         {
1984                 if (hud_panel_radar_maximized)
1985                 {
1986                         if (!hud_draw_maximized) return;
1987                 }
1988                 else
1989                 {
1990                         if (autocvar_hud_panel_radar == 0) return;
1991                         if (autocvar_hud_panel_radar != 2 && !teamplay) return;
1992                         if(radar_panel_modified)
1993                         {
1994                                 panel.update_time = time; // forces reload of panel attributes
1995                                 radar_panel_modified = false;
1996                         }
1997                 }
1998         }
1999
2000         HUD_Panel_UpdateCvars();
2001
2002         float f = 0;
2003
2004         if (hud_panel_radar_maximized && !autocvar__hud_configure)
2005         {
2006                 panel_size = autocvar_hud_panel_radar_maximized_size;
2007                 panel_size.x = bound(0.2, panel_size.x, 1) * vid_conwidth;
2008                 panel_size.y = bound(0.2, panel_size.y, 1) * vid_conheight;
2009                 panel_pos.x = (vid_conwidth - panel_size.x) / 2;
2010                 panel_pos.y = (vid_conheight - panel_size.y) / 2;
2011
2012                 string panel_bg;
2013                 panel_bg = strcat(hud_skin_path, "/border_default"); // always use the default border when maximized
2014                 if(precache_pic(panel_bg) == "")
2015                         panel_bg = "gfx/hud/default/border_default"; // fallback
2016                 if(!radar_panel_modified && panel_bg != panel.current_panel_bg)
2017                         radar_panel_modified = true;
2018                 if(panel.current_panel_bg)
2019                         strunzone(panel.current_panel_bg);
2020                 panel.current_panel_bg = strzone(panel_bg);
2021
2022                 switch(hud_panel_radar_maximized_zoommode)
2023                 {
2024                         default:
2025                         case 0:
2026                                 f = current_zoomfraction;
2027                                 break;
2028                         case 1:
2029                                 f = 1 - current_zoomfraction;
2030                                 break;
2031                         case 2:
2032                                 f = 0;
2033                                 break;
2034                         case 3:
2035                                 f = 1;
2036                                 break;
2037                 }
2038
2039                 switch(hud_panel_radar_maximized_rotation)
2040                 {
2041                         case 0:
2042                                 teamradar_angle = view_angles.y - 90;
2043                                 break;
2044                         default:
2045                                 teamradar_angle = 90 * hud_panel_radar_maximized_rotation;
2046                                 break;
2047                 }
2048         }
2049         if (!hud_panel_radar_maximized && !autocvar__hud_configure)
2050         {
2051                 switch(hud_panel_radar_zoommode)
2052                 {
2053                         default:
2054                         case 0:
2055                                 f = current_zoomfraction;
2056                                 break;
2057                         case 1:
2058                                 f = 1 - current_zoomfraction;
2059                                 break;
2060                         case 2:
2061                                 f = 0;
2062                                 break;
2063                         case 3:
2064                                 f = 1;
2065                                 break;
2066                 }
2067
2068                 switch(hud_panel_radar_rotation)
2069                 {
2070                         case 0:
2071                                 teamradar_angle = view_angles.y - 90;
2072                                 break;
2073                         default:
2074                                 teamradar_angle = 90 * hud_panel_radar_rotation;
2075                                 break;
2076                 }
2077         }
2078
2079         vector pos, mySize;
2080         pos = panel_pos;
2081         mySize = panel_size;
2082
2083         HUD_Panel_DrawBg(1);
2084         if(panel_bg_padding)
2085         {
2086                 pos += '1 1 0' * panel_bg_padding;
2087                 mySize -= '2 2 0' * panel_bg_padding;
2088         }
2089
2090         int color2;
2091         entity tm;
2092         float scale2d, normalsize, bigsize;
2093
2094         teamradar_origin2d = pos + 0.5 * mySize;
2095         teamradar_size2d = mySize;
2096
2097         if(minimapname == "")
2098                 return;
2099
2100         teamradar_loadcvars();
2101
2102         scale2d = vlen_maxnorm2d(mi_picmax - mi_picmin);
2103         teamradar_size2d = mySize;
2104
2105         teamradar_extraclip_mins = teamradar_extraclip_maxs = '0 0 0'; // we always center
2106
2107         // pixels per world qu to match the teamradar_size2d_x range in the longest dimension
2108         if((hud_panel_radar_rotation == 0 && !hud_panel_radar_maximized) || (hud_panel_radar_maximized_rotation == 0 && hud_panel_radar_maximized))
2109         {
2110                 // max-min distance must fit the radar in any rotation
2111                 bigsize = vlen_minnorm2d(teamradar_size2d) * scale2d / (1.05 * vlen2d(mi_scale));
2112         }
2113         else
2114         {
2115                 vector c0, c1, c2, c3, span;
2116                 c0 = rotate(mi_min, teamradar_angle * DEG2RAD);
2117                 c1 = rotate(mi_max, teamradar_angle * DEG2RAD);
2118                 c2 = rotate('1 0 0' * mi_min.x + '0 1 0' * mi_max.y, teamradar_angle * DEG2RAD);
2119                 c3 = rotate('1 0 0' * mi_max.x + '0 1 0' * mi_min.y, teamradar_angle * DEG2RAD);
2120                 span = '0 0 0';
2121                 span.x = max(c0_x, c1_x, c2_x, c3_x) - min(c0_x, c1_x, c2_x, c3_x);
2122                 span.y = max(c0_y, c1_y, c2_y, c3_y) - min(c0_y, c1_y, c2_y, c3_y);
2123
2124                 // max-min distance must fit the radar in x=x, y=y
2125                 bigsize = min(
2126                         teamradar_size2d.x * scale2d / (1.05 * span.x),
2127                         teamradar_size2d.y * scale2d / (1.05 * span.y)
2128                 );
2129         }
2130
2131         normalsize = vlen_maxnorm2d(teamradar_size2d) * scale2d / hud_panel_radar_scale;
2132         if(bigsize > normalsize)
2133                 normalsize = bigsize;
2134
2135         teamradar_size =
2136                   f * bigsize
2137                 + (1 - f) * normalsize;
2138         teamradar_origin3d_in_texcoord = teamradar_3dcoord_to_texcoord(
2139                   f * mi_center
2140                 + (1 - f) * view_origin);
2141
2142         drawsetcliparea(
2143                 pos.x,
2144                 pos.y,
2145                 mySize.x,
2146                 mySize.y
2147         );
2148
2149         draw_teamradar_background(hud_panel_radar_foreground_alpha);
2150
2151         for(tm = world; (tm = find(tm, classname, "radarlink")); )
2152                 draw_teamradar_link(tm.origin, tm.velocity, tm.team);
2153         for(tm = world; (tm = findflags(tm, teamradar_icon, 0xFFFFFF)); )
2154                 draw_teamradar_icon(tm.origin, tm.teamradar_icon, tm, tm.teamradar_color, panel_fg_alpha);
2155         for(tm = world; (tm = find(tm, classname, "entcs_receiver")); )
2156         {
2157                 color2 = GetPlayerColor(tm.sv_entnum);
2158                 //if(color == NUM_SPECTATOR || color == color2)
2159                         draw_teamradar_player(tm.origin, tm.angles, Team_ColorRGB(color2));
2160         }
2161         draw_teamradar_player(view_origin, view_angles, '1 1 1');
2162
2163         drawresetcliparea();
2164 }
2165
2166 // Score (#7)
2167 //
2168 void HUD_UpdatePlayerTeams();
2169 void HUD_Score_Rankings(vector pos, vector mySize, entity me)
2170 {
2171         float score;
2172         entity tm = world, pl;
2173         int SCOREPANEL_MAX_ENTRIES = 6;
2174         float SCOREPANEL_ASPECTRATIO = 2;
2175         int entries = bound(1, floor(SCOREPANEL_MAX_ENTRIES * mySize.y/mySize.x * SCOREPANEL_ASPECTRATIO), SCOREPANEL_MAX_ENTRIES);
2176         vector fontsize = '1 1 0' * (mySize.y/entries);
2177
2178         vector rgb, score_color;
2179         rgb = '1 1 1';
2180         score_color = '1 1 1';
2181
2182         float name_size = mySize.x*0.75;
2183         float spacing_size = mySize.x*0.04;
2184         const float highlight_alpha = 0.2;
2185         int i = 0, first_pl = 0;
2186         bool me_printed = false;
2187         string s;
2188         if (autocvar__hud_configure)
2189         {
2190                 float players_per_team = 0;
2191                 if (team_count)
2192                 {
2193                         // show team scores in the first line
2194                         float score_size = mySize.x / team_count;
2195                         players_per_team = max(2, ceil((entries - 1) / team_count));
2196                         for(i=0; i<team_count; ++i) {
2197                                 if (i == floor((entries - 2) / players_per_team) || (entries == 1 && i == 0))
2198                                         HUD_Panel_DrawHighlight(pos + eX * score_size * i, eX * score_size + eY * fontsize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2199                                 drawstring_aspect(pos + eX * score_size * i, ftos(175 - 23*i), eX * score_size + eY * fontsize.y, Team_ColorRGB(ColorByTeam(i)) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2200                         }
2201                         first_pl = 1;
2202                         pos.y += fontsize.y;
2203                 }
2204                 score = 10 + SCOREPANEL_MAX_ENTRIES * 3;
2205                 for (i=first_pl; i<entries; ++i)
2206                 {
2207                         //simulate my score is lower than all displayed players,
2208                         //so that I don't appear at all showing pure rankings.
2209                         //This is to better show the difference between the 2 ranking views
2210                         if (i == entries-1 && autocvar_hud_panel_score_rankings == 1)
2211                         {
2212                                 rgb = '1 1 0';
2213                                 drawfill(pos, eX * mySize.x + eY * fontsize.y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2214                                 s = GetPlayerName(player_localnum);
2215                                 score = 7;
2216                         }
2217                         else
2218                         {
2219                                 s = sprintf(_("Player %d"), i + 1 - first_pl);
2220                                 score -= 3;
2221                         }
2222
2223                         if (team_count)
2224                                 score_color = Team_ColorRGB(ColorByTeam(floor((i - first_pl) / players_per_team))) * 0.8;
2225                         s = textShortenToWidth(s, name_size, fontsize, stringwidth_colors);
2226                         drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, true, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2227                         drawstring(pos + eX * (name_size + spacing_size), ftos(score), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2228                         pos.y += fontsize.y;
2229                 }
2230                 return;
2231         }
2232
2233         if (!scoreboard_fade_alpha) // the scoreboard too calls HUD_UpdatePlayerTeams
2234                 HUD_UpdatePlayerTeams();
2235         if (team_count)
2236         {
2237                 // show team scores in the first line
2238                 float score_size = mySize.x / team_count;
2239                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2240                         if(tm.team == NUM_SPECTATOR)
2241                                 continue;
2242                         if (tm.team == myteam)
2243                                 drawfill(pos + eX * score_size * i, eX * score_size + eY * fontsize.y, '1 1 1', highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2244                         drawstring_aspect(pos + eX * score_size * i, ftos(tm.(teamscores[ts_primary])), eX * score_size + eY * fontsize.y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2245                         ++i;
2246                 }
2247                 first_pl = 1;
2248                 pos.y += fontsize.y;
2249                 tm = teams.sort_next;
2250         }
2251         i = first_pl;
2252
2253         do
2254         for (pl = players.sort_next; pl && i<entries; pl = pl.sort_next)
2255         {
2256                 if ((team_count && pl.team != tm.team) || pl.team == NUM_SPECTATOR)
2257                         continue;
2258
2259                 if (i == entries-1 && !me_printed && pl != me)
2260                 if (autocvar_hud_panel_score_rankings == 1 && spectatee_status != -1)
2261                 {
2262                         for (pl = me.sort_next; pl; pl = pl.sort_next)
2263                                 if (pl.team != NUM_SPECTATOR)
2264                                         break;
2265
2266                         if (pl)
2267                                 rgb = '1 1 0'; //not last but not among the leading players: yellow
2268                         else
2269                                 rgb = '1 0 0'; //last: red
2270                         pl = me;
2271                 }
2272
2273                 if (pl == me)
2274                 {
2275                         if (i == first_pl)
2276                                 rgb = '0 1 0'; //first: green
2277                         me_printed = true;
2278                         drawfill(pos, eX * mySize.x + eY * fontsize.y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2279                 }
2280                 if (team_count)
2281                         score_color = Team_ColorRGB(pl.team) * 0.8;
2282                 s = textShortenToWidth(GetPlayerName(pl.sv_entnum), name_size, fontsize, stringwidth_colors);
2283                 drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, true, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2284                 drawstring(pos + eX * (name_size + spacing_size), ftos(pl.(scores[ps_primary])), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2285                 pos.y += fontsize.y;
2286                 ++i;
2287         }
2288         while (i<entries && team_count && (tm = tm.sort_next) && (tm.team != NUM_SPECTATOR || (tm = tm.sort_next)));
2289 }
2290
2291 void HUD_Score(void)
2292 {
2293         if(!autocvar__hud_configure)
2294         {
2295                 if(!autocvar_hud_panel_score) return;
2296                 if(spectatee_status == -1 && (gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2297         }
2298
2299         HUD_Panel_UpdateCvars();
2300         vector pos, mySize;
2301         pos = panel_pos;
2302         mySize = panel_size;
2303
2304         HUD_Panel_DrawBg(1);
2305         if(panel_bg_padding)
2306         {
2307                 pos += '1 1 0' * panel_bg_padding;
2308                 mySize -= '2 2 0' * panel_bg_padding;
2309         }
2310
2311         float score, distribution = 0;
2312         string sign;
2313         vector distribution_color;
2314         entity tm, pl, me;
2315
2316         me = playerslots[current_player];
2317
2318         if((scores_flags[ps_primary] & SFL_TIME) && !teamplay) { // race/cts record display on HUD
2319                 string timer, distrtimer;
2320
2321                 pl = players.sort_next;
2322                 if(pl == me)
2323                         pl = pl.sort_next;
2324                 if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
2325                         if(pl.scores[ps_primary] == 0)
2326                                 pl = world;
2327
2328                 score = me.(scores[ps_primary]);
2329                 timer = TIME_ENCODED_TOSTRING(score);
2330
2331                 draw_beginBoldFont();
2332                 if (pl && ((!(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)) || score)) {
2333                         // distribution display
2334                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2335
2336                         distrtimer = ftos_decimals(fabs(distribution/pow(10, TIME_DECIMALS)), TIME_DECIMALS);
2337
2338                         if (distribution <= 0) {
2339                                 distribution_color = '0 1 0';
2340                                 sign = "-";
2341                         }
2342                         else {
2343                                 distribution_color = '1 0 0';
2344                                 sign = "+";
2345                         }
2346                         drawstring_aspect(pos + eX * 0.75 * mySize.x, strcat(sign, distrtimer), eX * 0.25 * mySize.x + eY * (1/3) * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2347                 }
2348                 // race record display
2349                 if (distribution <= 0)
2350                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2351                 drawstring_aspect(pos, timer, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2352                 draw_endBoldFont();
2353         } else if (!teamplay) { // non-teamgames
2354                 if ((spectatee_status == -1 && !autocvar__hud_configure) || autocvar_hud_panel_score_rankings)
2355                 {
2356                         HUD_Score_Rankings(pos, mySize, me);
2357                         return;
2358                 }
2359                 // me vector := [team/connected frags id]
2360                 pl = players.sort_next;
2361                 if(pl == me)
2362                         pl = pl.sort_next;
2363
2364                 if(autocvar__hud_configure)
2365                         distribution = 42;
2366                 else if(pl)
2367                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2368                 else
2369                         distribution = 0;
2370
2371                 score = me.(scores[ps_primary]);
2372                 if(autocvar__hud_configure)
2373                         score = 123;
2374
2375                 if(distribution >= 5)
2376                         distribution_color = eY;
2377                 else if(distribution >= 0)
2378                         distribution_color = '1 1 1';
2379                 else if(distribution >= -5)
2380                         distribution_color = '1 1 0';
2381                 else
2382                         distribution_color = eX;
2383
2384                 string distribution_str;
2385                 distribution_str = ftos(distribution);
2386                 draw_beginBoldFont();
2387                 if (distribution >= 0)
2388                 {
2389                         if (distribution > 0)
2390                                 distribution_str = strcat("+", distribution_str);
2391                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2392                 }
2393                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize.x + eY * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2394                 drawstring_aspect(pos + eX * 0.75 * mySize.x, distribution_str, eX * 0.25 * mySize.x + eY * (1/3) * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2395                 draw_endBoldFont();
2396         } else { // teamgames
2397                 float row, column, rows = 0, columns = 0;
2398                 vector offset = '0 0 0';
2399                 vector score_pos, score_size; //for scores other than myteam
2400                 if(autocvar_hud_panel_score_rankings)
2401                 {
2402                         HUD_Score_Rankings(pos, mySize, me);
2403                         return;
2404                 }
2405                 if(spectatee_status == -1)
2406                 {
2407                         rows = HUD_GetRowCount(team_count, mySize, 3);
2408                         columns = ceil(team_count/rows);
2409                         score_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
2410
2411                         float newSize;
2412                         if(score_size.x/score_size.y > 3)
2413                         {
2414                                 newSize = 3 * score_size.y;
2415                                 offset.x = score_size.x - newSize;
2416                                 pos.x += offset.x/2;
2417                                 score_size.x = newSize;
2418                         }
2419                         else
2420                         {
2421                                 newSize = 1/3 * score_size.x;
2422                                 offset.y = score_size.y - newSize;
2423                                 pos.y += offset.y/2;
2424                                 score_size.y = newSize;
2425                         }
2426                 }
2427                 else
2428                         score_size = eX * mySize.x*(1/4) + eY * mySize.y*(1/3);
2429
2430                 float max_fragcount;
2431                 max_fragcount = -99;
2432                 draw_beginBoldFont();
2433                 row = column = 0;
2434                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2435                         if(tm.team == NUM_SPECTATOR)
2436                                 continue;
2437                         score = tm.(teamscores[ts_primary]);
2438                         if(autocvar__hud_configure)
2439                                 score = 123;
2440
2441                         if (score > max_fragcount)
2442                                 max_fragcount = score;
2443
2444                         if (spectatee_status == -1)
2445                         {
2446                                 score_pos = pos + eX * column * (score_size.x + offset.x) + eY * row * (score_size.y + offset.y);
2447                                 if (max_fragcount == score)
2448                                         HUD_Panel_DrawHighlight(score_pos, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2449                                 drawstring_aspect(score_pos, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2450                                 ++row;
2451                                 if(row >= rows)
2452                                 {
2453                                         row = 0;
2454                                         ++column;
2455                                 }
2456                         }
2457                         else if(tm.team == myteam) {
2458                                 if (max_fragcount == score)
2459                                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2460                                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize.x + eY * mySize.y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2461                         } else {
2462                                 if (max_fragcount == score)
2463                                         HUD_Panel_DrawHighlight(pos + eX * 0.75 * mySize.x + eY * (1/3) * rows * mySize.y, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2464                                 drawstring_aspect(pos + eX * 0.75 * mySize.x + eY * (1/3) * rows * mySize.y, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2465                                 ++rows;
2466                         }
2467                 }
2468                 draw_endBoldFont();
2469         }
2470 }
2471
2472 // Race timer (#8)
2473 //
2474 void HUD_RaceTimer (void)
2475 {
2476         if(!autocvar__hud_configure)
2477         {
2478                 if(!autocvar_hud_panel_racetimer) return;
2479                 if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2480                 if(spectatee_status == -1) return;
2481         }
2482
2483         HUD_Panel_UpdateCvars();
2484
2485         vector pos, mySize;
2486         pos = panel_pos;
2487         mySize = panel_size;
2488
2489         HUD_Panel_DrawBg(1);
2490         if(panel_bg_padding)
2491         {
2492                 pos += '1 1 0' * panel_bg_padding;
2493                 mySize -= '2 2 0' * panel_bg_padding;
2494         }
2495
2496         // always force 4:1 aspect
2497         vector newSize = '0 0 0';
2498         if(mySize.x/mySize.y > 4)
2499         {
2500                 newSize.x = 4 * mySize.y;
2501                 newSize.y = mySize.y;
2502
2503                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
2504         }
2505         else
2506         {
2507                 newSize.y = 1/4 * mySize.x;
2508                 newSize.x = mySize.x;
2509
2510                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
2511         }
2512         mySize = newSize;
2513
2514         float a, t;
2515         string s, forcetime;
2516
2517         if(autocvar__hud_configure)
2518         {
2519                 s = "0:13:37";
2520                 draw_beginBoldFont();
2521                 drawstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, false, '0.60 0.60 0' * mySize.y), s, '0.60 0.60 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2522                 draw_endBoldFont();
2523                 s = _("^1Intermediate 1 (+15.42)");
2524                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.20 * mySize.y) + eY * 0.60 * mySize.y, s, '1 1 0' * 0.20 * mySize.y, panel_fg_alpha, DRAWFLAG_NORMAL);
2525                 s = sprintf(_("^1PENALTY: %.1f (%s)"), 2, "missing a checkpoint");
2526                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.20 * mySize.y) + eY * 0.80 * mySize.y, s, '1 1 0' * 0.20 * mySize.y, panel_fg_alpha, DRAWFLAG_NORMAL);
2527         }
2528         else if(race_checkpointtime)
2529         {
2530                 a = bound(0, 2 - (time - race_checkpointtime), 1);
2531                 s = "";
2532                 forcetime = "";
2533                 if(a > 0) // just hit a checkpoint?
2534                 {
2535                         if(race_checkpoint != 254)
2536                         {
2537                                 if(race_time && race_previousbesttime)
2538                                         s = MakeRaceString(race_checkpoint, TIME_DECODE(race_time) - TIME_DECODE(race_previousbesttime), 0, 0, race_previousbestname);
2539                                 else
2540                                         s = MakeRaceString(race_checkpoint, 0, -1, 0, race_previousbestname);
2541                                 if(race_time)
2542                                         forcetime = TIME_ENCODED_TOSTRING(race_time);
2543                         }
2544                 }
2545                 else
2546                 {
2547                         if(race_laptime && race_nextbesttime && race_nextcheckpoint != 254)
2548                         {
2549                                 a = bound(0, 2 - ((race_laptime + TIME_DECODE(race_nextbesttime)) - (time + TIME_DECODE(race_penaltyaccumulator))), 1);
2550                                 if(a > 0) // next one?
2551                                 {
2552                                         s = MakeRaceString(race_nextcheckpoint, (time + TIME_DECODE(race_penaltyaccumulator)) - race_laptime, TIME_DECODE(race_nextbesttime), 0, race_nextbestname);
2553                                 }
2554                         }
2555                 }
2556
2557                 if(s != "" && a > 0)
2558                 {
2559                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2560                 }
2561
2562                 if(race_penaltytime)
2563                 {
2564                         a = bound(0, 2 - (time - race_penaltyeventtime), 1);
2565                         if(a > 0)
2566                         {
2567                                 s = sprintf(_("^1PENALTY: %.1f (%s)"), race_penaltytime * 0.1, race_penaltyreason);
2568                                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.8 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2569                         }
2570                 }
2571
2572                 draw_beginBoldFont();
2573
2574                 if(forcetime != "")
2575                 {
2576                         a = bound(0, (time - race_checkpointtime) / 0.5, 1);
2577                         drawstring_expanding(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(forcetime, false, '1 1 0' * 0.6 * mySize.y), forcetime, '1 1 0' * 0.6 * mySize.y, '1 1 1', panel_fg_alpha, 0, a);
2578                 }
2579                 else
2580                         a = 1;
2581
2582                 if(race_laptime && race_checkpoint != 255)
2583                 {
2584                         s = TIME_ENCODED_TOSTRING(TIME_ENCODE(time + TIME_DECODE(race_penaltyaccumulator) - race_laptime));
2585                         drawstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, false, '0.6 0.6 0' * mySize.y), s, '0.6 0.6 0' * mySize.y, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
2586                 }
2587
2588                 draw_endBoldFont();
2589         }
2590         else
2591         {
2592                 if(race_mycheckpointtime)
2593                 {
2594                         a = bound(0, 2 - (time - race_mycheckpointtime), 1);
2595                         s = MakeRaceString(race_mycheckpoint, TIME_DECODE(race_mycheckpointdelta), -(race_mycheckpointenemy == ""), race_mycheckpointlapsdelta, race_mycheckpointenemy);
2596                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2597                 }
2598                 if(race_othercheckpointtime && race_othercheckpointenemy != "")
2599                 {
2600                         a = bound(0, 2 - (time - race_othercheckpointtime), 1);
2601                         s = MakeRaceString(race_othercheckpoint, -TIME_DECODE(race_othercheckpointdelta), -(race_othercheckpointenemy == ""), race_othercheckpointlapsdelta, race_othercheckpointenemy);
2602                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2603                 }
2604
2605                 if(race_penaltytime && !race_penaltyaccumulator)
2606                 {
2607                         t = race_penaltytime * 0.1 + race_penaltyeventtime;
2608                         a = bound(0, (1 + t - time), 1);
2609                         if(a > 0)
2610                         {
2611                                 if(time < t)
2612                                         s = sprintf(_("^1PENALTY: %.1f (%s)"), (t - time) * 0.1, race_penaltyreason);
2613                                 else
2614                                         s = sprintf(_("^2PENALTY: %.1f (%s)"), 0, race_penaltyreason);
2615                                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2616                         }
2617                 }
2618         }
2619 }
2620
2621 // Vote window (#9)
2622 //
2623
2624 void HUD_Vote(void)
2625 {
2626         if(autocvar_cl_allow_uid2name == -1 && (gametype == MAPINFO_TYPE_CTS || gametype == MAPINFO_TYPE_RACE || (serverflags & SERVERFLAG_PLAYERSTATS)))
2627         {
2628                 vote_active = 1;
2629                 if (autocvar__hud_configure)
2630                 {
2631                         vote_yescount = 0;
2632                         vote_nocount = 0;
2633                         print(_("^1You must answer before entering hud configure mode\n"));
2634                         cvar_set("_hud_configure", "0");
2635                 }
2636                 if(vote_called_vote)
2637                         strunzone(vote_called_vote);
2638                 vote_called_vote = strzone(_("^2Name ^7instead of \"^1Anonymous player^7\" in stats"));
2639                 uid2name_dialog = 1;
2640         }
2641
2642         if(!autocvar__hud_configure)
2643         {
2644                 if(!autocvar_hud_panel_vote) return;
2645
2646                 panel_fg_alpha = autocvar_hud_panel_fg_alpha;
2647                 panel_bg_alpha_str = autocvar_hud_panel_vote_bg_alpha;
2648
2649                 if(panel_bg_alpha_str == "") {
2650                         panel_bg_alpha_str = ftos(autocvar_hud_panel_bg_alpha);
2651                 }
2652                 panel_bg_alpha = stof(panel_bg_alpha_str);
2653         }
2654         else
2655         {
2656                 vote_yescount = 3;
2657                 vote_nocount = 2;
2658                 vote_needed = 4;
2659         }
2660
2661         string s;
2662         float a;
2663         if(vote_active != vote_prev) {
2664                 vote_change = time;
2665                 vote_prev = vote_active;
2666         }
2667
2668         if(vote_active || autocvar__hud_configure)
2669                 vote_alpha = bound(0, (time - vote_change) * 2, 1);
2670         else
2671                 vote_alpha = bound(0, 1 - (time - vote_change) * 2, 1);
2672
2673         if(!vote_alpha)
2674                 return;
2675
2676         HUD_Panel_UpdateCvars();
2677
2678         if(uid2name_dialog)
2679         {
2680                 panel_pos = eX * 0.3 * vid_conwidth + eY * 0.1 * vid_conheight;
2681                 panel_size = eX * 0.4 * vid_conwidth + eY * 0.3 * vid_conheight;
2682         }
2683
2684     // these must be below above block
2685         vector pos, mySize;
2686         pos = panel_pos;
2687         mySize = panel_size;
2688
2689         a = vote_alpha * (vote_highlighted ? autocvar_hud_panel_vote_alreadyvoted_alpha : 1);
2690         HUD_Panel_DrawBg(a);
2691         a = panel_fg_alpha * a;
2692
2693         if(panel_bg_padding)
2694         {
2695                 pos += '1 1 0' * panel_bg_padding;
2696                 mySize -= '2 2 0' * panel_bg_padding;
2697         }
2698
2699         // always force 3:1 aspect
2700         vector newSize = '0 0 0';
2701         if(mySize.x/mySize.y > 3)
2702         {
2703                 newSize.x = 3 * mySize.y;
2704                 newSize.y = mySize.y;
2705
2706                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
2707         }
2708         else
2709         {
2710                 newSize.y = 1/3 * mySize.x;
2711                 newSize.x = mySize.x;
2712
2713                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
2714         }
2715         mySize = newSize;
2716
2717         s = _("A vote has been called for:");
2718         if(uid2name_dialog)
2719                 s = _("Allow servers to store and display your name?");
2720         drawstring_aspect(pos, s, eX * mySize.x + eY * (2/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2721         s = textShortenToWidth(vote_called_vote, mySize.x, '1 1 0' * mySize.y * (1/8), stringwidth_colors);
2722         if(autocvar__hud_configure)
2723                 s = _("^1Configure the HUD");
2724         drawcolorcodedstring_aspect(pos + eY * (2/8) * mySize.y, s, eX * mySize.x + eY * (1.75/8) * mySize.y, a, DRAWFLAG_NORMAL);
2725
2726         // print the yes/no counts
2727     s = sprintf(_("Yes (%s): %d"), getcommandkey("vyes", "vyes"), vote_yescount);
2728         drawstring_aspect(pos + eY * (4/8) * mySize.y, s, eX * 0.5 * mySize.x + eY * (1.5/8) * mySize.y, '0 1 0', a, DRAWFLAG_NORMAL);
2729     s = sprintf(_("No (%s): %d"), getcommandkey("vno", "vno"), vote_nocount);
2730         drawstring_aspect(pos + eX * 0.5 * mySize.x + eY * (4/8) * mySize.y, s, eX * 0.5 * mySize.x + eY * (1.5/8) * mySize.y, '1 0 0', a, DRAWFLAG_NORMAL);
2731
2732         // draw the progress bar backgrounds
2733         drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_back", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2734
2735         // draw the highlights
2736         if(vote_highlighted == 1) {
2737                 drawsetcliparea(pos.x, pos.y, mySize.x * 0.5, mySize.y);
2738                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_voted", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2739         }
2740         else if(vote_highlighted == -1) {
2741                 drawsetcliparea(pos.x + 0.5 * mySize.x, pos.y, mySize.x * 0.5, mySize.y);
2742                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_voted", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2743         }
2744
2745         // draw the progress bars
2746         if(vote_yescount && vote_needed)
2747         {
2748                 drawsetcliparea(pos.x, pos.y, mySize.x * 0.5 * (vote_yescount/vote_needed), mySize.y);
2749                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_prog", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2750         }
2751
2752         if(vote_nocount && vote_needed)
2753         {
2754                 drawsetcliparea(pos.x + mySize.x - mySize.x * 0.5 * (vote_nocount/vote_needed), pos.y, mySize.x * 0.5, mySize.y);
2755                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_prog", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2756         }
2757
2758         drawresetcliparea();
2759 }
2760
2761 // Mod icons panel (#10)
2762 //
2763
2764 bool mod_active; // is there any active mod icon?
2765
2766 void DrawCAItem(vector myPos, vector mySize, float aspect_ratio, int layout, int i)
2767 {
2768         int stat = -1;
2769         string pic = "";
2770         vector color = '0 0 0';
2771         switch(i)
2772         {
2773                 case 0:
2774                         stat = getstati(STAT_REDALIVE);
2775                         pic = "player_red.tga";
2776                         color = '1 0 0';
2777                         break;
2778                 case 1:
2779                         stat = getstati(STAT_BLUEALIVE);
2780                         pic = "player_blue.tga";
2781                         color = '0 0 1';
2782                         break;
2783                 case 2:
2784                         stat = getstati(STAT_YELLOWALIVE);
2785                         pic = "player_yellow.tga";
2786                         color = '1 1 0';
2787                         break;
2788                 default:
2789                 case 3:
2790                         stat = getstati(STAT_PINKALIVE);
2791                         pic = "player_pink.tga";
2792                         color = '1 0 1';
2793                         break;
2794         }
2795
2796         if(mySize.x/mySize.y > aspect_ratio)
2797         {
2798                 i = aspect_ratio * mySize.y;
2799                 myPos.x = myPos.x + (mySize.x - i) / 2;
2800                 mySize.x = i;
2801         }
2802         else
2803         {
2804                 i = 1/aspect_ratio * mySize.x;
2805                 myPos.y = myPos.y + (mySize.y - i) / 2;
2806                 mySize.y = i;
2807         }
2808
2809         if(layout)
2810         {
2811                 drawpic_aspect_skin(myPos, pic, eX * 0.7 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2812                 drawstring_aspect(myPos + eX * 0.7 * mySize.x, ftos(stat), eX * 0.3 * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2813         }
2814         else
2815                 drawstring_aspect(myPos, ftos(stat), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2816 }
2817
2818 // Clan Arena and Freeze Tag HUD modicons
2819 void HUD_Mod_CA(vector myPos, vector mySize)
2820 {
2821         mod_active = 1; // required in each mod function that always shows something
2822
2823         int layout;
2824         if(gametype == MAPINFO_TYPE_CA)
2825                 layout = autocvar_hud_panel_modicons_ca_layout;
2826         else //if(gametype == MAPINFO_TYPE_FREEZETAG)
2827                 layout = autocvar_hud_panel_modicons_freezetag_layout;
2828         int rows, columns;
2829         float aspect_ratio;
2830         aspect_ratio = (layout) ? 2 : 1;
2831         rows = HUD_GetRowCount(team_count, mySize, aspect_ratio);
2832         columns = ceil(team_count/rows);
2833
2834         int i;
2835         float row = 0, column = 0;
2836         vector pos, itemSize;
2837         itemSize = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
2838         for(i=0; i<team_count; ++i)
2839         {
2840                 pos = myPos + eX * column * itemSize.x + eY * row * itemSize.y;
2841
2842                 DrawCAItem(pos, itemSize, aspect_ratio, layout, i);
2843
2844                 ++row;
2845                 if(row >= rows)
2846                 {
2847                         row = 0;
2848                         ++column;
2849                 }
2850         }
2851 }
2852
2853 // CTF HUD modicon section
2854 float redflag_prevframe, blueflag_prevframe; // status during previous frame
2855 int redflag_prevstatus, blueflag_prevstatus; // last remembered status
2856 float redflag_statuschange_time, blueflag_statuschange_time; // time when the status changed
2857
2858 void HUD_Mod_CTF_Reset(void)
2859 {
2860         redflag_prevstatus = blueflag_prevstatus = redflag_prevframe = blueflag_prevframe = redflag_statuschange_time = blueflag_statuschange_time = 0;
2861 }
2862
2863 void HUD_Mod_CTF(vector pos, vector mySize)
2864 {
2865         vector redflag_pos, blueflag_pos;
2866         vector flag_size;
2867         float f; // every function should have that
2868
2869         int redflag, blueflag; // current status
2870         float redflag_statuschange_elapsedtime, blueflag_statuschange_elapsedtime; // time since the status changed
2871         int stat_items;
2872
2873         stat_items = getstati(STAT_ITEMS, 0, 24);
2874         redflag = (stat_items/IT_RED_FLAG_TAKEN) & 3;
2875         blueflag = (stat_items/IT_BLUE_FLAG_TAKEN) & 3;
2876
2877         if(redflag || blueflag)
2878                 mod_active = 1;
2879         else
2880                 mod_active = 0;
2881
2882         if(autocvar__hud_configure)
2883         {
2884                 redflag = 1;
2885                 blueflag = 2;
2886         }
2887
2888         // when status CHANGES, set old status into prevstatus and current status into status
2889         if (redflag != redflag_prevframe)
2890         {
2891                 redflag_statuschange_time = time;
2892                 redflag_prevstatus = redflag_prevframe;
2893                 redflag_prevframe = redflag;
2894         }
2895
2896         if (blueflag != blueflag_prevframe)
2897         {
2898                 blueflag_statuschange_time = time;
2899                 blueflag_prevstatus = blueflag_prevframe;
2900                 blueflag_prevframe = blueflag;
2901         }
2902
2903         redflag_statuschange_elapsedtime = time - redflag_statuschange_time;
2904         blueflag_statuschange_elapsedtime = time - blueflag_statuschange_time;
2905
2906         float BLINK_FACTOR = 0.15;
2907         float BLINK_BASE = 0.85;
2908         // note:
2909         //   RMS = sqrt(BLINK_BASE^2 + 0.5 * BLINK_FACTOR^2)
2910         // thus
2911         //   BLINK_BASE = sqrt(RMS^2 - 0.5 * BLINK_FACTOR^2)
2912         // ensure RMS == 1
2913         float BLINK_FREQ = 5; // circle frequency, = 2*pi*frequency in hertz
2914
2915         string red_icon, red_icon_prevstatus;
2916         float red_alpha, red_alpha_prevstatus;
2917         red_alpha = red_alpha_prevstatus = 1;
2918         switch(redflag) {
2919                 case 1: red_icon = "flag_red_taken"; break;
2920                 case 2: red_icon = "flag_red_lost"; break;
2921                 case 3: red_icon = "flag_red_carrying"; red_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2922                 default:
2923                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2924                                 red_icon = "flag_red_shielded";
2925                         else
2926                                 red_icon = string_null;
2927                         break;
2928         }
2929         switch(redflag_prevstatus) {
2930                 case 1: red_icon_prevstatus = "flag_red_taken"; break;
2931                 case 2: red_icon_prevstatus = "flag_red_lost"; break;
2932                 case 3: red_icon_prevstatus = "flag_red_carrying"; red_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2933                 default:
2934                         if(redflag == 3)
2935                                 red_icon_prevstatus = "flag_red_carrying"; // make it more visible
2936                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2937                                 red_icon_prevstatus = "flag_red_shielded";
2938                         else
2939                                 red_icon_prevstatus = string_null;
2940                         break;
2941         }
2942
2943         string blue_icon, blue_icon_prevstatus;
2944         float blue_alpha, blue_alpha_prevstatus;
2945         blue_alpha = blue_alpha_prevstatus = 1;
2946         switch(blueflag) {
2947                 case 1: blue_icon = "flag_blue_taken"; break;
2948                 case 2: blue_icon = "flag_blue_lost"; break;
2949                 case 3: blue_icon = "flag_blue_carrying"; blue_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2950                 default:
2951                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2952                                 blue_icon = "flag_blue_shielded";
2953                         else
2954                                 blue_icon = string_null;
2955                         break;
2956         }
2957         switch(blueflag_prevstatus) {
2958                 case 1: blue_icon_prevstatus = "flag_blue_taken"; break;
2959                 case 2: blue_icon_prevstatus = "flag_blue_lost"; break;
2960                 case 3: blue_icon_prevstatus = "flag_blue_carrying"; blue_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2961                 default:
2962                         if(blueflag == 3)
2963                                 blue_icon_prevstatus = "flag_blue_carrying"; // make it more visible
2964                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2965                                 blue_icon_prevstatus = "flag_blue_shielded";
2966                         else
2967                                 blue_icon_prevstatus = string_null;
2968                         break;
2969         }
2970
2971         if(mySize.x > mySize.y) {
2972                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2973                         redflag_pos = pos;
2974                         blueflag_pos = pos + eX * 0.5 * mySize.x;
2975                 } else {
2976                         blueflag_pos = pos;
2977                         redflag_pos = pos + eX * 0.5 * mySize.x;
2978                 }
2979                 flag_size = eX * 0.5 * mySize.x + eY * mySize.y;
2980         } else {
2981                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2982                         redflag_pos = pos;
2983                         blueflag_pos = pos + eY * 0.5 * mySize.y;
2984                 } else {
2985                         blueflag_pos = pos;
2986                         redflag_pos = pos + eY * 0.5 * mySize.y;
2987                 }
2988                 flag_size = eY * 0.5 * mySize.y + eX * mySize.x;
2989         }
2990
2991         f = bound(0, redflag_statuschange_elapsedtime*2, 1);
2992         if(red_icon_prevstatus && f < 1)
2993                 drawpic_aspect_skin_expanding(redflag_pos, red_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * red_alpha_prevstatus, DRAWFLAG_NORMAL, f);
2994         if(red_icon)
2995                 drawpic_aspect_skin(redflag_pos, red_icon, flag_size, '1 1 1', panel_fg_alpha * red_alpha * f, DRAWFLAG_NORMAL);
2996
2997         f = bound(0, blueflag_statuschange_elapsedtime*2, 1);
2998         if(blue_icon_prevstatus && f < 1)
2999                 drawpic_aspect_skin_expanding(blueflag_pos, blue_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * blue_alpha_prevstatus, DRAWFLAG_NORMAL, f);
3000         if(blue_icon)
3001                 drawpic_aspect_skin(blueflag_pos, blue_icon, flag_size, '1 1 1', panel_fg_alpha * blue_alpha * f, DRAWFLAG_NORMAL);
3002 }
3003
3004 // Keyhunt HUD modicon section
3005 vector KH_SLOTS[4];
3006
3007 void HUD_Mod_KH(vector pos, vector mySize)
3008 {
3009         mod_active = 1; // keyhunt should never hide the mod icons panel
3010
3011         // Read current state
3012
3013         int state = getstati(STAT_KH_KEYS);
3014         int i, key_state;
3015         int all_keys, team1_keys, team2_keys, team3_keys, team4_keys, dropped_keys, carrying_keys;
3016         all_keys = team1_keys = team2_keys = team3_keys = team4_keys = dropped_keys = carrying_keys = 0;
3017
3018         for(i = 0; i < 4; ++i)
3019         {
3020                 key_state = (bitshift(state, i * -5) & 31) - 1;
3021
3022                 if(key_state == -1)
3023                         continue;
3024
3025                 if(key_state == 30)
3026                 {
3027                         ++carrying_keys;
3028                         key_state = myteam;
3029                 }
3030
3031                 switch(key_state)
3032                 {
3033                         case NUM_TEAM_1: ++team1_keys; break;
3034                         case NUM_TEAM_2: ++team2_keys; break;
3035                         case NUM_TEAM_3: ++team3_keys; break;
3036                         case NUM_TEAM_4: ++team4_keys; break;
3037                         case 29: ++dropped_keys; break;
3038                 }
3039
3040                 ++all_keys;
3041         }
3042
3043         // Calculate slot measurements
3044
3045         vector slot_size;
3046
3047         if(all_keys == 4 && mySize.x * 0.5 < mySize.y && mySize.y * 0.5 < mySize.x)
3048         {
3049                 // Quadratic arrangement
3050                 slot_size = eX * mySize.x * 0.5 + eY * mySize.y * 0.5;
3051                 KH_SLOTS[0] = pos;
3052                 KH_SLOTS[1] = pos + eX * slot_size.x;
3053                 KH_SLOTS[2] = pos + eY * slot_size.y;
3054                 KH_SLOTS[3] = pos + eX * slot_size.x + eY * slot_size.y;
3055         }
3056         else
3057         {
3058                 if(mySize.x > mySize.y)
3059                 {
3060                         // Horizontal arrangement
3061                         slot_size = eX * mySize.x / all_keys + eY * mySize.y;
3062                         for(i = 0; i < all_keys; ++i)
3063                                 KH_SLOTS[i] = pos + eX * slot_size.x * i;
3064                 }
3065                 else
3066                 {
3067                         // Vertical arrangement
3068                         slot_size = eX * mySize.x + eY * mySize.y / all_keys;
3069                         for(i = 0; i < all_keys; ++i)
3070                                 KH_SLOTS[i] = pos + eY * slot_size.y * i;
3071                 }
3072         }
3073
3074         // Make icons blink in case of RUN HERE
3075
3076         float blink = 0.6 + sin(2*M_PI*time) / 2.5; // Oscillate between 0.2 and 1
3077         float alpha;
3078         alpha = 1;
3079
3080         if(carrying_keys)
3081                 switch(myteam)
3082                 {
3083                         case NUM_TEAM_1: if(team1_keys == all_keys) alpha = blink; break;
3084                         case NUM_TEAM_2: if(team2_keys == all_keys) alpha = blink; break;
3085                         case NUM_TEAM_3: if(team3_keys == all_keys) alpha = blink; break;
3086                         case NUM_TEAM_4: if(team4_keys == all_keys) alpha = blink; break;
3087                 }
3088
3089         // Draw icons
3090
3091         i = 0;
3092
3093         while(team1_keys--)
3094                 if(myteam == NUM_TEAM_1 && carrying_keys)
3095                 {
3096                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_red_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3097                         --carrying_keys;
3098                 }
3099                 else
3100                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_red_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3101
3102         while(team2_keys--)
3103                 if(myteam == NUM_TEAM_2 && carrying_keys)
3104                 {
3105                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_blue_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3106                         --carrying_keys;
3107                 }
3108                 else
3109                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_blue_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3110
3111         while(team3_keys--)
3112                 if(myteam == NUM_TEAM_3 && carrying_keys)
3113                 {
3114                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_yellow_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3115                         --carrying_keys;
3116                 }
3117                 else
3118                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_yellow_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3119
3120         while(team4_keys--)
3121                 if(myteam == NUM_TEAM_4 && carrying_keys)
3122                 {
3123                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_pink_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3124                         --carrying_keys;
3125                 }
3126                 else
3127                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_pink_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3128
3129         while(dropped_keys--)
3130                 drawpic_aspect_skin(KH_SLOTS[i++], "kh_dropped", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3131 }
3132
3133 // Keepaway HUD mod icon
3134 int kaball_prevstatus; // last remembered status
3135 float kaball_statuschange_time; // time when the status changed
3136
3137 // we don't need to reset for keepaway since it immediately
3138 // autocorrects prevstatus as to if the player has the ball or not
3139
3140 void HUD_Mod_Keepaway(vector pos, vector mySize)
3141 {
3142         mod_active = 1; // keepaway should always show the mod HUD
3143
3144         float BLINK_FACTOR = 0.15;
3145         float BLINK_BASE = 0.85;
3146         float BLINK_FREQ = 5;
3147         float kaball_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
3148
3149         int stat_items = getstati(STAT_ITEMS, 0, 24);
3150         int kaball = (stat_items/IT_KEY1) & 1;
3151
3152         if(kaball != kaball_prevstatus)
3153         {
3154                 kaball_statuschange_time = time;
3155                 kaball_prevstatus = kaball;
3156         }
3157
3158         vector kaball_pos, kaball_size;
3159
3160         if(mySize.x > mySize.y) {
3161                 kaball_pos = pos + eX * 0.25 * mySize.x;
3162                 kaball_size = eX * 0.5 * mySize.x + eY * mySize.y;
3163         } else {
3164                 kaball_pos = pos + eY * 0.25 * mySize.y;
3165                 kaball_size = eY * 0.5 * mySize.y + eX * mySize.x;
3166         }
3167
3168         float kaball_statuschange_elapsedtime = time - kaball_statuschange_time;
3169         float f = bound(0, kaball_statuschange_elapsedtime*2, 1);
3170
3171         if(kaball_prevstatus && f < 1)
3172                 drawpic_aspect_skin_expanding(kaball_pos, "keepawayball_carrying", kaball_size, '1 1 1', panel_fg_alpha * kaball_alpha, DRAWFLAG_NORMAL, f);
3173
3174         if(kaball)
3175                 drawpic_aspect_skin(pos, "keepawayball_carrying", eX * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha * kaball_alpha * f, DRAWFLAG_NORMAL);
3176 }
3177
3178
3179 // Nexball HUD mod icon
3180 void HUD_Mod_NexBall(vector pos, vector mySize)
3181 {
3182         float nb_pb_starttime, dt, p;
3183         int stat_items;
3184
3185         stat_items = getstati(STAT_ITEMS, 0, 24);
3186         nb_pb_starttime = getstatf(STAT_NB_METERSTART);
3187
3188         if (stat_items & IT_KEY1)
3189                 mod_active = 1;
3190         else
3191                 mod_active = 0;
3192
3193         //Manage the progress bar if any
3194         if (nb_pb_starttime > 0)
3195         {
3196                 dt = (time - nb_pb_starttime) % nb_pb_period;
3197                 // one period of positive triangle
3198                 p = 2 * dt / nb_pb_period;
3199                 if (p > 1)
3200                         p = 2 - p;
3201
3202                 HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", p, (mySize.x <= mySize.y), 0, autocvar_hud_progressbar_nexball_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3203         }
3204
3205         if (stat_items & IT_KEY1)
3206                 drawpic_aspect_skin(pos, "nexball_carrying", eX * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3207 }
3208
3209 // Race/CTS HUD mod icons
3210 float crecordtime_prev; // last remembered crecordtime
3211 float crecordtime_change_time; // time when crecordtime last changed
3212 float srecordtime_prev; // last remembered srecordtime
3213 float srecordtime_change_time; // time when srecordtime last changed
3214
3215 float race_status_time;
3216 int race_status_prev;
3217 string race_status_name_prev;
3218 void HUD_Mod_Race(vector pos, vector mySize)
3219 {
3220         mod_active = 1; // race should never hide the mod icons panel
3221         entity me;
3222         me = playerslots[player_localnum];
3223         float t, score;
3224         float f; // yet another function has this
3225         score = me.(scores[ps_primary]);
3226
3227         if(!(scores_flags[ps_primary] & SFL_TIME) || teamplay) // race/cts record display on HUD
3228                 return; // no records in the actual race
3229
3230         // clientside personal record
3231         string rr;
3232         if(gametype == MAPINFO_TYPE_CTS)
3233                 rr = CTS_RECORD;
3234         else
3235                 rr = RACE_RECORD;
3236         t = stof(db_get(ClientProgsDB, strcat(shortmapname, rr, "time")));
3237
3238         if(score && (score < t || !t)) {
3239                 db_put(ClientProgsDB, strcat(shortmapname, rr, "time"), ftos(score));
3240                 if(autocvar_cl_autodemo_delete_keeprecords)
3241                 {
3242                         f = autocvar_cl_autodemo_delete;
3243                         f &= ~1;
3244                         cvar_set("cl_autodemo_delete", ftos(f)); // don't delete demo with new record!
3245                 }
3246         }
3247
3248         if(t != crecordtime_prev) {
3249                 crecordtime_prev = t;
3250                 crecordtime_change_time = time;
3251         }
3252
3253         vector textPos, medalPos;
3254         float squareSize;
3255         if(mySize.x > mySize.y) {
3256                 // text on left side
3257                 squareSize = min(mySize.y, mySize.x/2);
3258                 textPos = pos + eX * 0.5 * max(0, mySize.x/2 - squareSize) + eY * 0.5 * (mySize.y - squareSize);
3259                 medalPos = pos + eX * 0.5 * max(0, mySize.x/2 - squareSize) + eX * 0.5 * mySize.x + eY * 0.5 * (mySize.y - squareSize);
3260         } else {
3261                 // text on top
3262                 squareSize = min(mySize.x, mySize.y/2);
3263                 textPos = pos + eY * 0.5 * max(0, mySize.y/2 - squareSize) + eX * 0.5 * (mySize.x - squareSize);
3264                 medalPos = pos + eY * 0.5 * max(0, mySize.y/2 - squareSize) + eY * 0.5 * mySize.y + eX * 0.5 * (mySize.x - squareSize);
3265         }
3266
3267         f = time - crecordtime_change_time;
3268
3269         if (f > 1) {
3270                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3271                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3272         } else {
3273                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3274                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3275                 drawstring_aspect_expanding(pos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3276                 drawstring_aspect_expanding(pos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3277         }
3278
3279         // server record
3280         t = race_server_record;
3281         if(t != srecordtime_prev) {
3282                 srecordtime_prev = t;
3283                 srecordtime_change_time = time;
3284         }
3285         f = time - srecordtime_change_time;
3286
3287         if (f > 1) {
3288                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3289                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3290         } else {
3291                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3292                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3293                 drawstring_aspect_expanding(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3294                 drawstring_aspect_expanding(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3295         }
3296
3297         if (race_status != race_status_prev || race_status_name != race_status_name_prev) {
3298                 race_status_time = time + 5;
3299                 race_status_prev = race_status;
3300                 if (race_status_name_prev)
3301                         strunzone(race_status_name_prev);
3302                 race_status_name_prev = strzone(race_status_name);
3303         }
3304
3305         // race "awards"
3306         float a;
3307         a = bound(0, race_status_time - time, 1);
3308
3309         string s;
3310         s = textShortenToWidth(race_status_name, squareSize, '1 1 0' * 0.1 * squareSize, stringwidth_colors);
3311
3312         float rank;
3313         if(race_status > 0)
3314                 rank = race_CheckName(race_status_name);
3315         else
3316                 rank = 0;
3317         string rankname;
3318         rankname = count_ordinal(rank);
3319
3320         vector namepos;
3321         namepos = medalPos + '0 0.8 0' * squareSize;
3322         vector rankpos;
3323         rankpos = medalPos + '0 0.15 0' * squareSize;
3324
3325         if(race_status == 0)
3326                 drawpic_aspect_skin(medalPos, "race_newfail", '1 1 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3327         else if(race_status == 1) {
3328                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newtime", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3329                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3330                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3331         } else if(race_status == 2) {
3332                 if(race_status_name == GetPlayerName(player_localnum) || !race_myrank || race_myrank < rank)
3333                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankgreen", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3334                 else
3335                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankyellow", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3336                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3337                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3338         } else if(race_status == 3) {
3339                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrecordserver", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3340                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3341                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3342         }
3343
3344         if (race_status_time - time <= 0) {
3345                 race_status_prev = -1;
3346                 race_status = -1;
3347                 if(race_status_name)
3348                         strunzone(race_status_name);
3349                 race_status_name = string_null;
3350                 if(race_status_name_prev)
3351                         strunzone(race_status_name_prev);
3352                 race_status_name_prev = string_null;
3353         }
3354 }
3355
3356 void DrawDomItem(vector myPos, vector mySize, float aspect_ratio, int layout, int i)
3357 {
3358         float stat = -1;
3359         string pic = "";
3360         vector color = '0 0 0';
3361         switch(i)
3362         {
3363                 case 0:
3364                         stat = getstatf(STAT_DOM_PPS_RED);
3365                         pic = "dom_icon_red";
3366                         color = '1 0 0';
3367                         break;
3368                 case 1:
3369                         stat = getstatf(STAT_DOM_PPS_BLUE);
3370                         pic = "dom_icon_blue";
3371                         color = '0 0 1';
3372                         break;
3373                 case 2:
3374                         stat = getstatf(STAT_DOM_PPS_YELLOW);
3375                         pic = "dom_icon_yellow";
3376                         color = '1 1 0';
3377                         break;
3378                 default:
3379                 case 3:
3380                         stat = getstatf(STAT_DOM_PPS_PINK);
3381                         pic = "dom_icon_pink";
3382                         color = '1 0 1';
3383                         break;
3384         }
3385         float pps_ratio = stat / getstatf(STAT_DOM_TOTAL_PPS);
3386
3387         if(mySize.x/mySize.y > aspect_ratio)
3388         {
3389                 i = aspect_ratio * mySize.y;
3390                 myPos.x = myPos.x + (mySize.x - i) / 2;
3391                 mySize.x = i;
3392         }
3393         else
3394         {
3395                 i = 1/aspect_ratio * mySize.x;
3396                 myPos.y = myPos.y + (mySize.y - i) / 2;
3397                 mySize.y = i;
3398         }
3399
3400         if (layout) // show text too
3401         {
3402                 //draw the text
3403                 color *= 0.5 + pps_ratio * (1 - 0.5); // half saturated color at min, full saturated at max
3404                 if (layout == 2) // average pps
3405                         drawstring_aspect(myPos + eX * mySize.y, ftos_decimals(stat, 2), eX * (2/3) * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3406                 else // percentage of average pps
3407                         drawstring_aspect(myPos + eX * mySize.y, strcat( ftos(floor(pps_ratio*100 + 0.5)), "%" ), eX * (2/3) * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3408         }
3409
3410         //draw the icon
3411         drawpic_aspect_skin(myPos, pic, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3412         if (stat > 0)
3413         {
3414                 drawsetcliparea(myPos.x, myPos.y + mySize.y * (1 - pps_ratio), mySize.y, mySize.y * pps_ratio);
3415                 drawpic_aspect_skin(myPos, strcat(pic, "-highlighted"), '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3416                 drawresetcliparea();
3417         }
3418 }
3419
3420 void HUD_Mod_Dom(vector myPos, vector mySize)
3421 {
3422         mod_active = 1; // required in each mod function that always shows something
3423
3424         int layout = autocvar_hud_panel_modicons_dom_layout;
3425         int rows, columns;
3426         float aspect_ratio;
3427         aspect_ratio = (layout) ? 3 : 1;
3428         rows = HUD_GetRowCount(team_count, mySize, aspect_ratio);
3429         columns = ceil(team_count/rows);
3430
3431         int i;
3432         float row = 0, column = 0;
3433         vector pos, itemSize;
3434         itemSize = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
3435         for(i=0; i<team_count; ++i)
3436         {
3437                 pos = myPos + eX * column * itemSize.x + eY * row * itemSize.y;
3438
3439                 DrawDomItem(pos, itemSize, aspect_ratio, layout, i);
3440
3441                 ++row;
3442                 if(row >= rows)
3443                 {
3444                         row = 0;
3445                         ++column;
3446                 }
3447         }
3448 }
3449
3450 void HUD_ModIcons_SetFunc()
3451 {
3452         switch(gametype)
3453         {
3454                 case MAPINFO_TYPE_KEYHUNT:              HUD_ModIcons_GameType = HUD_Mod_KH; break;
3455                 case MAPINFO_TYPE_CTF:                  HUD_ModIcons_GameType = HUD_Mod_CTF; break;
3456                 case MAPINFO_TYPE_NEXBALL:              HUD_ModIcons_GameType = HUD_Mod_NexBall; break;
3457                 case MAPINFO_TYPE_CTS:
3458                 case MAPINFO_TYPE_RACE:         HUD_ModIcons_GameType = HUD_Mod_Race; break;
3459                 case MAPINFO_TYPE_CA:
3460                 case MAPINFO_TYPE_FREEZETAG:    HUD_ModIcons_GameType = HUD_Mod_CA; break;
3461                 case MAPINFO_TYPE_DOMINATION:   HUD_ModIcons_GameType = HUD_Mod_Dom; break;
3462                 case MAPINFO_TYPE_KEEPAWAY:     HUD_ModIcons_GameType = HUD_Mod_Keepaway; break;
3463         }
3464 }
3465
3466 int mod_prev; // previous state of mod_active to check for a change
3467 float mod_alpha;
3468 float mod_change; // "time" when mod_active changed
3469
3470 void HUD_ModIcons(void)
3471 {
3472         if(!autocvar__hud_configure)
3473         {
3474                 if(!autocvar_hud_panel_modicons) return;
3475                 if(!HUD_ModIcons_GameType) return;
3476         }
3477
3478         HUD_Panel_UpdateCvars();
3479
3480         draw_beginBoldFont();
3481
3482         if(mod_active != mod_prev) {
3483                 mod_change = time;
3484                 mod_prev = mod_active;
3485         }
3486
3487         if(mod_active || autocvar__hud_configure)
3488                 mod_alpha = bound(0, (time - mod_change) * 2, 1);
3489         else
3490                 mod_alpha = bound(0, 1 - (time - mod_change) * 2, 1);
3491
3492         if(mod_alpha)
3493                 HUD_Panel_DrawBg(mod_alpha);
3494
3495         if(panel_bg_padding)
3496         {
3497                 panel_pos += '1 1 0' * panel_bg_padding;
3498                 panel_size -= '2 2 0' * panel_bg_padding;
3499         }
3500
3501         if(autocvar__hud_configure)
3502                 HUD_Mod_CTF(panel_pos, panel_size);
3503         else
3504                 HUD_ModIcons_GameType(panel_pos, panel_size);
3505
3506         draw_endBoldFont();
3507 }
3508
3509 // Draw pressed keys (#11)
3510 //
3511 void HUD_PressedKeys(void)
3512 {
3513         if(!autocvar__hud_configure)
3514         {
3515                 if(!autocvar_hud_panel_pressedkeys) return;
3516                 if(spectatee_status <= 0 && autocvar_hud_panel_pressedkeys < 2) return;
3517         }
3518
3519         HUD_Panel_UpdateCvars();
3520         vector pos, mySize;
3521         pos = panel_pos;
3522         mySize = panel_size;
3523
3524         HUD_Panel_DrawBg(1);
3525         if(panel_bg_padding)
3526         {
3527                 pos += '1 1 0' * panel_bg_padding;
3528                 mySize -= '2 2 0' * panel_bg_padding;
3529         }
3530
3531         // force custom aspect
3532         float aspect = autocvar_hud_panel_pressedkeys_aspect;
3533         if(aspect)
3534         {
3535                 vector newSize = '0 0 0';
3536                 if(mySize.x/mySize.y > aspect)
3537                 {
3538                         newSize.x = aspect * mySize.y;
3539                         newSize.y = mySize.y;
3540
3541                         pos.x = pos.x + (mySize.x - newSize.x) / 2;
3542                 }
3543                 else
3544                 {
3545                         newSize.y = 1/aspect * mySize.x;
3546                         newSize.x = mySize.x;
3547
3548                         pos.y = pos.y + (mySize.y - newSize.y) / 2;
3549                 }
3550                 mySize = newSize;
3551         }
3552
3553         vector keysize;
3554         keysize = eX * mySize.x * (1/3.0) + eY * mySize.y * (1/(3.0 - !autocvar_hud_panel_pressedkeys_attack));
3555         float pressedkeys;
3556         pressedkeys = getstatf(STAT_PRESSED_KEYS);
3557
3558         if(autocvar_hud_panel_pressedkeys_attack)
3559         {
3560                 drawpic_aspect_skin(pos + eX * keysize.x * 0.5, ((pressedkeys & KEY_ATCK) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3561                 drawpic_aspect_skin(pos + eX * keysize.x * 1.5, ((pressedkeys & KEY_ATCK2) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3562                 pos.y += keysize.y;
3563         }
3564
3565         drawpic_aspect_skin(pos, ((pressedkeys & KEY_CROUCH) ? "key_crouch_inv.tga" : "key_crouch.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3566         drawpic_aspect_skin(pos + eX * keysize.x, ((pressedkeys & KEY_FORWARD) ? "key_forward_inv.tga" : "key_forward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3567         drawpic_aspect_skin(pos + eX * keysize.x * 2, ((pressedkeys & KEY_JUMP) ? "key_jump_inv.tga" : "key_jump.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3568         pos.y += keysize.y;
3569         drawpic_aspect_skin(pos, ((pressedkeys & KEY_LEFT) ? "key_left_inv.tga" : "key_left.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3570         drawpic_aspect_skin(pos + eX * keysize.x, ((pressedkeys & KEY_BACKWARD) ? "key_backward_inv.tga" : "key_backward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3571         drawpic_aspect_skin(pos + eX * keysize.x * 2, ((pressedkeys & KEY_RIGHT) ? "key_right_inv.tga" : "key_right.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3572 }
3573
3574 // Handle chat as a panel (#12)
3575 //
3576 void HUD_Chat(void)
3577 {
3578         if(!autocvar__hud_configure)
3579         {
3580                 if (!autocvar_hud_panel_chat)
3581                 {
3582                         if (!autocvar_con_chatrect)
3583                                 cvar_set("con_chatrect", "0");
3584                         return;
3585                 }
3586                 if(autocvar__con_chat_maximized)
3587                 {
3588                         if(!hud_draw_maximized) return;
3589                 }
3590                 else if(chat_panel_modified)
3591                 {
3592                         panel.update_time = time; // forces reload of panel attributes
3593                         chat_panel_modified = false;
3594                 }
3595         }
3596
3597         HUD_Panel_UpdateCvars();
3598
3599         if(autocvar__con_chat_maximized && !autocvar__hud_configure) // draw at full screen height if maximized
3600         {
3601                 panel_pos.y = panel_bg_border;
3602                 panel_size.y = vid_conheight - panel_bg_border * 2;
3603                 if(panel.current_panel_bg == "0") // force a border when maximized
3604                 {
3605                         string panel_bg;
3606                         panel_bg = strcat(hud_skin_path, "/border_default");
3607                         if(precache_pic(panel_bg) == "")
3608                                 panel_bg = "gfx/hud/default/border_default";
3609                         if(panel.current_panel_bg)
3610                                 strunzone(panel.current_panel_bg);
3611                         panel.current_panel_bg = strzone(panel_bg);
3612                         chat_panel_modified = true;
3613                 }
3614                 panel_bg_alpha = max(0.75, panel_bg_alpha); // force an theAlpha of at least 0.75
3615         }
3616
3617         vector pos, mySize;
3618         pos = panel_pos;
3619         mySize = panel_size;
3620
3621         HUD_Panel_DrawBg(1);
3622
3623         if(panel_bg_padding)
3624         {
3625                 pos += '1 1 0' * panel_bg_padding;
3626                 mySize -= '2 2 0' * panel_bg_padding;
3627         }
3628
3629         if (!autocvar_con_chatrect)
3630                 cvar_set("con_chatrect", "1");
3631
3632         cvar_set("con_chatrect_x", ftos(pos.x/vid_conwidth));
3633         cvar_set("con_chatrect_y", ftos(pos.y/vid_conheight));
3634
3635         cvar_set("con_chatwidth", ftos(mySize.x/vid_conwidth));
3636         cvar_set("con_chat", ftos(floor(mySize.y/autocvar_con_chatsize - 0.5)));
3637
3638         if(autocvar__hud_configure)
3639         {
3640                 vector chatsize;
3641                 chatsize = '1 1 0' * autocvar_con_chatsize;
3642                 cvar_set("con_chatrect_x", "9001"); // over 9000, we'll fake it instead for more control over theAlpha and such
3643                 float i, a;
3644                 for(i = 0; i < autocvar_con_chat; ++i)
3645                 {
3646                         if(i == autocvar_con_chat - 1)
3647                                 a = panel_fg_alpha;
3648                         else
3649                                 a = panel_fg_alpha * floor(((i + 1) * 7 + autocvar_con_chattime)/45);
3650                         drawcolorcodedstring(pos, textShortenToWidth(_("^3Player^7: This is the chat area."), mySize.x, chatsize, stringwidth_colors), chatsize, a, DRAWFLAG_NORMAL);
3651                         pos.y += chatsize.y;
3652                 }
3653         }
3654 }
3655
3656 // Engine info panel (#13)
3657 //
3658 float prevfps;
3659 float prevfps_time;
3660 int framecounter;
3661
3662 float frametimeavg;
3663 float frametimeavg1; // 1 frame ago
3664 float frametimeavg2; // 2 frames ago
3665 void HUD_EngineInfo(void)
3666 {
3667         if(!autocvar__hud_configure)
3668         {
3669                 if(!autocvar_hud_panel_engineinfo) return;
3670         }
3671
3672         HUD_Panel_UpdateCvars();
3673         vector pos, mySize;
3674         pos = panel_pos;
3675         mySize = panel_size;
3676
3677         HUD_Panel_DrawBg(1);
3678         if(panel_bg_padding)
3679         {
3680                 pos += '1 1 0' * panel_bg_padding;
3681                 mySize -= '2 2 0' * panel_bg_padding;
3682         }
3683
3684         float currentTime = gettime(GETTIME_REALTIME);
3685         if(cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage"))
3686         {
3687                 float currentframetime = currentTime - prevfps_time;
3688                 frametimeavg = (frametimeavg + frametimeavg1 + frametimeavg2 + currentframetime)/4; // average three frametimes into framecounter for slightly more stable fps readings :P
3689                 frametimeavg2 = frametimeavg1;
3690                 frametimeavg1 = frametimeavg;
3691
3692                 float weight;
3693                 weight = cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_new_weight");
3694                 if(currentframetime > 0.0001) // filter out insane values which sometimes seem to occur and throw off the average? If you are getting 10,000 fps or more, then you don't need a framerate counter.
3695                 {
3696                         if(fabs(prevfps - (1/frametimeavg)) > prevfps * cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_instantupdate_change_threshold")) // if there was a big jump in fps, just force prevfps at current (1/currentframetime) to make big updates instant
3697                                 prevfps = (1/currentframetime);
3698                         prevfps = (1 - weight) * prevfps + weight * (1/frametimeavg); // framecounter just used so there's no need for a new variable, think of it as "frametime average"
3699                 }
3700                 prevfps_time = currentTime;
3701         }
3702         else
3703         {
3704                 framecounter += 1;
3705                 if(currentTime - prevfps_time > autocvar_hud_panel_engineinfo_framecounter_time)
3706                 {
3707                         prevfps = framecounter/(currentTime - prevfps_time);
3708                         framecounter = 0;
3709                         prevfps_time = currentTime;
3710                 }
3711         }
3712
3713         vector color;
3714         color = HUD_Get_Num_Color (prevfps, 100);
3715         drawstring_aspect(pos, sprintf(_("FPS: %.*f"), autocvar_hud_panel_engineinfo_framecounter_decimals, prevfps), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3716 }
3717
3718 // Info messages panel (#14)
3719 //
3720 #define drawInfoMessage(s) do {                                                                                                                                                                         \
3721         if(autocvar_hud_panel_infomessages_flip)                                                                                                                                                \
3722                 o.x = pos.x + mySize.x - stringwidth(s, true, fontsize);                                                                                                        \
3723         drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);                                                                                                               \
3724         o.y += fontsize.y;                                                                                                                                                                                              \
3725 } while(0)
3726 void HUD_InfoMessages(void)
3727 {
3728         if(!autocvar__hud_configure)
3729         {
3730                 if(!autocvar_hud_panel_infomessages) return;
3731         }
3732
3733         HUD_Panel_UpdateCvars();
3734         vector pos, mySize;
3735         pos = panel_pos;
3736         mySize = panel_size;
3737
3738         HUD_Panel_DrawBg(1);
3739         if(panel_bg_padding)
3740         {
3741                 pos += '1 1 0' * panel_bg_padding;
3742                 mySize -= '2 2 0' * panel_bg_padding;
3743         }
3744
3745         // always force 5:1 aspect
3746         vector newSize = '0 0 0';
3747         if(mySize.x/mySize.y > 5)
3748         {
3749                 newSize.x = 5 * mySize.y;
3750                 newSize.y = mySize.y;
3751
3752                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
3753         }
3754         else
3755         {
3756                 newSize.y = 1/5 * mySize.x;
3757                 newSize.x = mySize.x;
3758
3759                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
3760         }
3761
3762         mySize = newSize;
3763         entity tm;
3764         vector o;
3765         o = pos;
3766
3767         vector fontsize;
3768         fontsize = '0.20 0.20 0' * mySize.y;
3769
3770         float a;
3771         a = panel_fg_alpha;
3772
3773         string s;
3774         if(!autocvar__hud_configure)
3775         {
3776                 if(spectatee_status && !intermission)
3777                 {
3778                         a = 1;
3779                         if(spectatee_status == -1)
3780                                 s = _("^1Observing");
3781                         else
3782                                 s = sprintf(_("^1Spectating: ^7%s"), GetPlayerName(current_player));
3783                         drawInfoMessage(s);
3784
3785                         if(spectatee_status == -1)
3786                                 s = sprintf(_("^1Press ^3%s^1 to spectate"), getcommandkey("primary fire", "+fire"));
3787                         else
3788                                 s = sprintf(_("^1Press ^3%s^1 or ^3%s^1 for next or previous player"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3789                         drawInfoMessage(s);
3790
3791                         if(spectatee_status == -1)
3792                                 s = sprintf(_("^1Use ^3%s^1 or ^3%s^1 to change the speed"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3793                         else
3794                                 s = sprintf(_("^1Press ^3%s^1 to observe"), getcommandkey("secondary fire", "+fire2"));
3795                         drawInfoMessage(s);
3796
3797                         s = sprintf(_("^1Press ^3%s^1 for gamemode info"), getcommandkey("server info", "+show_info"));
3798                         drawInfoMessage(s);
3799
3800                         if(gametype == MAPINFO_TYPE_LMS)
3801                         {
3802                                 entity sk;
3803                                 sk = playerslots[player_localnum];
3804                                 if(sk.(scores[ps_primary]) >= 666)
3805                                         s = _("^1Match has already begun");
3806                                 else if(sk.(scores[ps_primary]) > 0)
3807                                         s = _("^1You have no more lives left");
3808                                 else
3809                                         s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3810                         }
3811                         else
3812                                 s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3813                         drawInfoMessage(s);
3814
3815                         //show restart countdown:
3816                         if (time < getstatf(STAT_GAMESTARTTIME)) {
3817                                 float countdown;
3818                                 //we need to ceil, otherwise the countdown would be off by .5 when using round()
3819                                 countdown = ceil(getstatf(STAT_GAMESTARTTIME) - time);
3820                                 s = sprintf(_("^1Game starts in ^3%d^1 seconds"), countdown);
3821                                 drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);
3822                                 o.y += fontsize.y;
3823                         }
3824                 }
3825                 if(warmup_stage && !intermission)
3826                 {
3827                         s = _("^2Currently in ^1warmup^2 stage!");
3828                         drawInfoMessage(s);
3829                 }
3830
3831                 string blinkcolor;
3832                 if(time % 1 >= 0.5)
3833                         blinkcolor = "^1";
3834                 else
3835                         blinkcolor = "^3";
3836
3837                 if(ready_waiting && !intermission && !spectatee_status)
3838                 {
3839                         if(ready_waiting_for_me)
3840                         {
3841                                 if(warmup_stage)
3842                                         s = sprintf(_("%sPress ^3%s%s to end warmup"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3843                                 else
3844                                         s = sprintf(_("%sPress ^3%s%s once you are ready"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3845                         }
3846                         else
3847                         {
3848                                 if(warmup_stage)
3849                                         s = _("^2Waiting for others to ready up to end warmup...");
3850                                 else
3851                                         s = _("^2Waiting for others to ready up...");
3852                         }
3853                         drawInfoMessage(s);
3854                 }
3855                 else if(warmup_stage && !intermission && !spectatee_status)
3856                 {
3857                         s = sprintf(_("^2Press ^3%s^2 to end warmup"), getcommandkey("ready", "ready"));
3858                         drawInfoMessage(s);
3859                 }
3860
3861                 if(teamplay && !intermission && !spectatee_status && gametype != MAPINFO_TYPE_CA && teamnagger)
3862                 {
3863                         float ts_min = 0, ts_max = 0;
3864                         tm = teams.sort_next;
3865                         if (tm)
3866                         {
3867                                 for (; tm.sort_next; tm = tm.sort_next)
3868                                 {
3869                                         if(!tm.team_size || tm.team == NUM_SPECTATOR)
3870                                                 continue;
3871                                         if(!ts_min) ts_min = tm.team_size;
3872                                         else ts_min = min(ts_min, tm.team_size);
3873                                         if(!ts_max) ts_max = tm.team_size;
3874                                         else ts_max = max(ts_max, tm.team_size);
3875                                 }
3876                                 if ((ts_max - ts_min) > 1)
3877                                 {
3878                                         s = strcat(blinkcolor, _("Teamnumbers are unbalanced!"));
3879                                         tm = GetTeam(myteam, false);
3880                                         if (tm)
3881                                         if (tm.team != NUM_SPECTATOR)
3882                                         if (tm.team_size == ts_max)
3883                                                 s = strcat(s, sprintf(_(" Press ^3%s%s to adjust"), getcommandkey("team menu", "menu_showteamselect"), blinkcolor));
3884                                         drawInfoMessage(s);
3885                                 }
3886                         }
3887                 }
3888         }
3889         else
3890         {
3891                 s = _("^7Press ^3ESC ^7to show HUD options.");
3892                 drawInfoMessage(s);
3893                 s = _("^3Doubleclick ^7a panel for panel-specific options.");
3894                 drawInfoMessage(s);
3895                 s = _("^3CTRL ^7to disable collision testing, ^3SHIFT ^7and");
3896                 drawInfoMessage(s);
3897                 s = _("^3ALT ^7+ ^3ARROW KEYS ^7for fine adjustments.");
3898                 drawInfoMessage(s);
3899         }
3900 }
3901
3902 // Physics panel (#15)
3903 //
3904 vector acc_prevspeed;
3905 float acc_prevtime, acc_avg, top_speed, top_speed_time;
3906 float physics_update_time, discrete_speed, discrete_acceleration;
3907 void HUD_Physics(void)
3908 {
3909         if(!autocvar__hud_configure)
3910         {
3911                 if(!autocvar_hud_panel_physics) return;
3912                 if(spectatee_status == -1 && (autocvar_hud_panel_physics == 1 || autocvar_hud_panel_physics == 3)) return;
3913                 if(autocvar_hud_panel_physics == 3 && !(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
3914         }
3915
3916         HUD_Panel_UpdateCvars();
3917
3918         draw_beginBoldFont();
3919
3920         HUD_Panel_DrawBg(1);
3921         if(panel_bg_padding)
3922         {
3923                 panel_pos += '1 1 0' * panel_bg_padding;
3924                 panel_size -= '2 2 0' * panel_bg_padding;
3925         }
3926
3927         float acceleration_progressbar_scale = 0;
3928         if(autocvar_hud_panel_physics_progressbar && autocvar_hud_panel_physics_acceleration_progressbar_scale > 1)
3929                 acceleration_progressbar_scale = autocvar_hud_panel_physics_acceleration_progressbar_scale;
3930
3931         float text_scale;
3932         if (autocvar_hud_panel_physics_text_scale <= 0)
3933                 text_scale = 1;
3934         else
3935                 text_scale = min(autocvar_hud_panel_physics_text_scale, 1);
3936
3937         //compute speed
3938         float speed, conversion_factor;
3939         string unit;
3940
3941         switch(autocvar_hud_panel_physics_speed_unit)
3942         {
3943                 default:
3944                 case 1:
3945                         unit = _(" qu/s");
3946                         conversion_factor = 1.0;
3947                         break;
3948                 case 2:
3949                         unit = _(" m/s");
3950                         conversion_factor = 0.0254;
3951                         break;
3952                 case 3:
3953                         unit = _(" km/h");
3954                         conversion_factor = 0.0254 * 3.6;
3955                         break;
3956                 case 4:
3957                         unit = _(" mph");
3958                         conversion_factor = 0.0254 * 3.6 * 0.6213711922;
3959                         break;
3960                 case 5:
3961                         unit = _(" knots");
3962                         conversion_factor = 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
3963                         break;
3964         }
3965
3966         vector vel = (csqcplayer ? csqcplayer.velocity : pmove_vel);
3967
3968         float max_speed = floor( autocvar_hud_panel_physics_speed_max * conversion_factor + 0.5 );
3969         if (autocvar__hud_configure)
3970                 speed = floor( max_speed * 0.65 + 0.5 );
3971         else if(autocvar_hud_panel_physics_speed_vertical)
3972                 speed = floor( vlen(vel) * conversion_factor + 0.5 );
3973         else
3974                 speed = floor( vlen(vel - vel.z * '0 0 1') * conversion_factor + 0.5 );
3975
3976         //compute acceleration
3977         float acceleration, f;
3978         if (autocvar__hud_configure)
3979                 acceleration = autocvar_hud_panel_physics_acceleration_max * 0.3;
3980         else
3981         {
3982                 // 1 m/s = 0.0254 qu/s; 1 g = 9.80665 m/s^2
3983                 f = time - acc_prevtime;
3984                 if(autocvar_hud_panel_physics_acceleration_vertical)
3985                         acceleration = (vlen(vel) - vlen(acc_prevspeed));
3986                 else
3987                         acceleration = (vlen(vel - '0 0 1' * vel.z) - vlen(acc_prevspeed - '0 0 1' * acc_prevspeed.z));
3988
3989                 acceleration = acceleration * (1 / max(0.0001, f)) * (0.0254 / 9.80665);
3990
3991                 acc_prevspeed = vel;
3992                 acc_prevtime = time;
3993
3994                 if(autocvar_hud_panel_physics_acceleration_movingaverage)
3995                 {
3996                         f = bound(0, f * 10, 1);
3997                         acc_avg = acc_avg * (1 - f) + acceleration * f;
3998                         acceleration = acc_avg;
3999                 }
4000         }
4001
4002         int acc_decimals = 2;
4003         if(time > physics_update_time)
4004         {
4005                 // workaround for ftos_decimals returning a negative 0
4006                 if(discrete_acceleration > -1 / pow(10, acc_decimals) && discrete_acceleration < 0)
4007                         discrete_acceleration = 0;
4008                 discrete_acceleration = acceleration;
4009                 discrete_speed = speed;
4010                 physics_update_time += autocvar_hud_panel_physics_update_interval;
4011         }
4012
4013         //compute layout
4014         float panel_ar = panel_size.x/panel_size.y;
4015         vector speed_offset = '0 0 0', acceleration_offset = '0 0 0';
4016         if (panel_ar >= 5 && !acceleration_progressbar_scale)
4017         {
4018                 panel_size.x *= 0.5;
4019                 if (autocvar_hud_panel_physics_flip)
4020                         speed_offset.x = panel_size.x;
4021                 else
4022                         acceleration_offset.x = panel_size.x;
4023         }
4024         else
4025         {
4026                 panel_size.y *= 0.5;
4027                 if (autocvar_hud_panel_physics_flip)
4028                         speed_offset.y = panel_size.y;
4029                 else
4030                         acceleration_offset.y = panel_size.y;
4031         }
4032         int speed_baralign, acceleration_baralign;
4033         if (autocvar_hud_panel_physics_baralign == 1)
4034                 acceleration_baralign = speed_baralign = 1;
4035     else if(autocvar_hud_panel_physics_baralign == 4)
4036                 acceleration_baralign = speed_baralign = 2;
4037         else if (autocvar_hud_panel_physics_flip)
4038         {
4039                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 2);
4040                 speed_baralign = (autocvar_hud_panel_physics_baralign == 3);
4041         }
4042         else
4043         {
4044                 speed_baralign = (autocvar_hud_panel_physics_baralign == 2);
4045                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 3);
4046         }
4047         if (autocvar_hud_panel_physics_acceleration_progressbar_mode == 0)
4048                 acceleration_baralign = 3; //override hud_panel_physics_baralign value for acceleration
4049
4050         //draw speed
4051         if(speed)
4052         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
4053                 HUD_Panel_DrawProgressBar(panel_pos + speed_offset, panel_size, "progressbar", speed/max_speed, 0, speed_baralign, autocvar_hud_progressbar_speed_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4054         vector tmp_offset = '0 0 0', tmp_size = '0 0 0';
4055         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
4056         {
4057                 tmp_size.x = panel_size.x * 0.75;
4058                 tmp_size.y = panel_size.y * text_scale;
4059                 if (speed_baralign)
4060                         tmp_offset.x = panel_size.x - tmp_size.x;
4061                 //else
4062                         //tmp_offset_x = 0;
4063                 tmp_offset.y = (panel_size.y - tmp_size.y) / 2;
4064                 drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(discrete_speed), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4065
4066                 //draw speed unit
4067                 if (speed_baralign)
4068                         tmp_offset.x = 0;
4069                 else
4070                         tmp_offset.x = tmp_size.x;
4071                 if (autocvar_hud_panel_physics_speed_unit_show)
4072                 {
4073                         //tmp_offset_y = 0;
4074                         tmp_size.x = panel_size.x * (1 - 0.75);
4075                         tmp_size.y = panel_size.y * 0.4 * text_scale;
4076                         tmp_offset.y = (panel_size.y * 0.4 - tmp_size.y) / 2;
4077                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, unit, tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4078                 }
4079         }
4080
4081         //compute and draw top speed
4082         if (autocvar_hud_panel_physics_topspeed)
4083         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
4084         {
4085                 if (autocvar__hud_configure)
4086                 {
4087                         top_speed = floor( max_speed * 0.75 + 0.5 );
4088                         f = 1;
4089                 }
4090                 else
4091                 {
4092                         if (speed >= top_speed)
4093                         {
4094                                 top_speed = speed;
4095                                 top_speed_time = time;
4096                         }
4097                         if (top_speed != 0)
4098                         {
4099                                 f = max(1, autocvar_hud_panel_physics_topspeed_time);
4100                                 // divide by f to make it start from 1
4101                                 f = cos( ((time - top_speed_time) / f) * PI/2 );
4102                         }
4103             else //hide top speed 0, it would be stupid
4104                                 f = 0;
4105                 }
4106                 if (f > 0)
4107                 {
4108                         //top speed progressbar peak
4109                         if(speed < top_speed)
4110                         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
4111                         {
4112                                 float peak_offsetX;
4113                                 vector peak_size = '0 0 0';
4114                                 if (speed_baralign == 0)
4115                                         peak_offsetX = min(top_speed, max_speed)/max_speed * panel_size.x;
4116                 else if (speed_baralign == 1)
4117                                         peak_offsetX = (1 - min(top_speed, max_speed)/max_speed) * panel_size.x;
4118                 else // if (speed_baralign == 2)
4119                     peak_offsetX = min(top_speed, max_speed)/max_speed * panel_size.x * 0.5;
4120                                 peak_size.x = floor(panel_size.x * 0.01 + 1.5);
4121                 peak_size.y = panel_size.y;
4122                 if (speed_baralign == 2) // draw two peaks, on both sides
4123                 {
4124                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size.x + peak_offsetX - peak_size.x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4125                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size.x - peak_offsetX + peak_size.x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4126                 }
4127                 else
4128                     drawfill(panel_pos + speed_offset + eX * (peak_offsetX - peak_size.x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4129                         }
4130
4131                         //top speed
4132                         tmp_offset.y = panel_size.y * 0.4;
4133                         tmp_size.x = panel_size.x * (1 - 0.75);
4134                         tmp_size.y = (panel_size.y - tmp_offset.y) * text_scale;
4135                         tmp_offset.y += (panel_size.y - tmp_offset.y - tmp_size.y) / 2;
4136                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(top_speed), tmp_size, '1 0 0', f * panel_fg_alpha, DRAWFLAG_NORMAL);
4137                 }
4138                 else
4139                         top_speed = 0;
4140         }
4141
4142         //draw acceleration
4143         if(acceleration)
4144         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 3)
4145         {
4146                 vector progressbar_color;
4147                 if(acceleration < 0)
4148                         progressbar_color = autocvar_hud_progressbar_acceleration_neg_color;
4149                 else
4150                         progressbar_color = autocvar_hud_progressbar_acceleration_color;
4151
4152                 f = acceleration/autocvar_hud_panel_physics_acceleration_max;
4153                 if (autocvar_hud_panel_physics_acceleration_progressbar_nonlinear)
4154                         f = (f >= 0 ? sqrt(f) : -sqrt(-f));
4155
4156                 if (acceleration_progressbar_scale) // allow progressbar to go out of panel bounds
4157                 {
4158                         tmp_size = acceleration_progressbar_scale * panel_size.x * eX + panel_size.y * eY;
4159
4160                         if (acceleration_baralign == 1)
4161                                 tmp_offset.x = panel_size.x - tmp_size.x;
4162                         else if (acceleration_baralign == 2 || acceleration_baralign == 3)
4163                                 tmp_offset.x = (panel_size.x - tmp_size.x) / 2;
4164                         else
4165                                 tmp_offset.x = 0;
4166                         tmp_offset.y = 0;
4167                 }
4168                 else
4169                 {
4170                         tmp_size = panel_size;
4171                         tmp_offset = '0 0 0';
4172                 }
4173
4174                 HUD_Panel_DrawProgressBar(panel_pos + acceleration_offset + tmp_offset, tmp_size, "accelbar", f, 0, acceleration_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4175         }
4176
4177         if(autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 3)
4178         {
4179                 tmp_size.x = panel_size.x;
4180                 tmp_size.y = panel_size.y * text_scale;
4181                 tmp_offset.x = 0;
4182                 tmp_offset.y = (panel_size.y - tmp_size.y) / 2;
4183
4184                 drawstring_aspect(panel_pos + acceleration_offset + tmp_offset, strcat(ftos_decimals(discrete_acceleration, acc_decimals), "g"), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4185         }
4186
4187         draw_endBoldFont();
4188 }
4189
4190 // CenterPrint (#16)
4191 //
4192 const int CENTERPRINT_MAX_MSGS = 10;
4193 const int CENTERPRINT_MAX_ENTRIES = 50;
4194 const float CENTERPRINT_SPACING = 0.7;
4195 int cpm_index;
4196 string centerprint_messages[CENTERPRINT_MAX_MSGS];
4197 int centerprint_msgID[CENTERPRINT_MAX_MSGS];
4198 float centerprint_time[CENTERPRINT_MAX_MSGS];
4199 float centerprint_expire_time[CENTERPRINT_MAX_MSGS];
4200 int centerprint_countdown_num[CENTERPRINT_MAX_MSGS];
4201 bool centerprint_showing;
4202
4203 void centerprint_generic(int new_id, string strMessage, float duration, int countdown_num)
4204 {
4205         //printf("centerprint_generic(%d, '%s^7', %d, %d);\n", new_id, strMessage, duration, countdown_num);
4206         int i, j;
4207
4208         if(strMessage == "" && new_id == 0)
4209                 return;
4210
4211         // strip trailing newlines
4212         j = strlen(strMessage) - 1;
4213         while(substring(strMessage, j, 1) == "\n" && j >= 0)
4214                 --j;
4215         if (j < strlen(strMessage) - 1)
4216                 strMessage = substring(strMessage, 0, j + 1);
4217
4218         if(strMessage == "" && new_id == 0)
4219                 return;
4220
4221         // strip leading newlines
4222         j = 0;
4223         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
4224                 ++j;
4225         if (j > 0)
4226                 strMessage = substring(strMessage, j, strlen(strMessage) - j);
4227
4228         if(strMessage == "" && new_id == 0)
4229                 return;
4230
4231         if (!centerprint_showing)
4232                 centerprint_showing = true;
4233
4234         for (i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4235         {
4236                 if (j == CENTERPRINT_MAX_MSGS)
4237                         j = 0;
4238                 if (new_id && new_id == centerprint_msgID[j])
4239                 {
4240                         if (strMessage == "" && centerprint_messages[j] != "" && centerprint_countdown_num[j] == 0)
4241                         {
4242                                 // fade out the current msg (duration and countdown_num are ignored)
4243                                 centerprint_time[j] = min(5, autocvar_hud_panel_centerprint_fade_out);
4244                                 if (centerprint_expire_time[j] > time + min(5, autocvar_hud_panel_centerprint_fade_out) || centerprint_expire_time[j] < time)
4245                                         centerprint_expire_time[j] = time + min(5, autocvar_hud_panel_centerprint_fade_out);
4246                                 return;
4247                         }
4248                         break; // found a msg with the same id, at position j
4249                 }
4250         }
4251
4252         if (i == CENTERPRINT_MAX_MSGS)
4253         {
4254                 // a msg with the same id was not found, add the msg at the next position
4255                 --cpm_index;
4256                 if (cpm_index == -1)
4257                         cpm_index = CENTERPRINT_MAX_MSGS - 1;
4258                 j = cpm_index;
4259         }
4260         if(centerprint_messages[j])
4261                 strunzone(centerprint_messages[j]);
4262         centerprint_messages[j] = strzone(strMessage);
4263         centerprint_msgID[j] = new_id;
4264         if (duration < 0)
4265         {
4266                 centerprint_time[j] = -1;
4267                 centerprint_expire_time[j] = time;
4268         }
4269         else
4270         {
4271                 if(duration == 0)
4272                         duration = max(1, autocvar_hud_panel_centerprint_time);
4273                 centerprint_time[j] = duration;
4274                 centerprint_expire_time[j] = time + duration;
4275         }
4276         centerprint_countdown_num[j] = countdown_num;
4277 }
4278
4279 void centerprint_hud(string strMessage)
4280 {
4281         centerprint_generic(0, strMessage, autocvar_hud_panel_centerprint_time, 0);
4282 }
4283
4284 void reset_centerprint_messages(void)
4285 {
4286         int i;
4287         for (i=0; i<CENTERPRINT_MAX_MSGS; ++i)
4288         {
4289                 centerprint_expire_time[i] = 0;
4290                 centerprint_time[i] = 1;
4291                 centerprint_msgID[i] = 0;
4292                 if(centerprint_messages[i])
4293                         strunzone(centerprint_messages[i]);
4294                 centerprint_messages[i] = string_null;
4295         }
4296 }
4297 float hud_configure_cp_generation_time;
4298 void HUD_CenterPrint (void)
4299 {
4300         if(!autocvar__hud_configure)
4301         {
4302                 if(!autocvar_hud_panel_centerprint) return;
4303
4304                 if(hud_configure_prev)
4305                         reset_centerprint_messages();
4306         }
4307         else
4308         {
4309                 if(!hud_configure_prev)
4310                         reset_centerprint_messages();
4311                 if (time > hud_configure_cp_generation_time)
4312                 {
4313                         if(HUD_PANEL(CENTERPRINT) == highlightedPanel)
4314                         {
4315                                 float r;
4316                                 r = random();
4317                                 if (r > 0.8)
4318                                         centerprint_generic(floor(r*1000), strcat(sprintf("^3Countdown message at time %s", seconds_tostring(time)), ", seconds left: ^COUNT"), 1, 10);
4319                                 else if (r > 0.55)
4320                                         centerprint_generic(0, sprintf("^1Multiline message at time %s that\n^1lasts longer than normal", seconds_tostring(time)), 20, 0);
4321                                 else
4322                                         centerprint_hud(sprintf("Message at time %s", seconds_tostring(time)));
4323                                 hud_configure_cp_generation_time = time + 1 + random()*4;
4324                         }
4325                         else
4326                         {
4327                                 centerprint_generic(0, sprintf("Centerprint message", seconds_tostring(time)), 10, 0);
4328                                 hud_configure_cp_generation_time = time + 10 - random()*3;
4329                         }
4330                 }
4331         }
4332
4333         // this panel fades only when the menu does
4334         float hud_fade_alpha_save = 0;
4335         if(scoreboard_fade_alpha)
4336         {
4337                 hud_fade_alpha_save = hud_fade_alpha;
4338                 hud_fade_alpha = 1 - autocvar__menu_alpha;
4339         }
4340         HUD_Panel_UpdateCvars();
4341
4342         if(scoreboard_fade_alpha)
4343         {
4344                 hud_fade_alpha = hud_fade_alpha_save;
4345
4346                 // move the panel below the scoreboard
4347                 if (scoreboard_bottom >= 0.96 * vid_conheight)
4348                         return;
4349                 vector target_pos;
4350
4351                 target_pos = eY * scoreboard_bottom + eX * 0.5 * (vid_conwidth - panel_size.x);
4352
4353                 if(target_pos.y > panel_pos.y)
4354                 {
4355                         panel_pos = panel_pos + (target_pos - panel_pos) * sqrt(scoreboard_fade_alpha);
4356                         panel_size.y = min(panel_size.y, vid_conheight - scoreboard_bottom);
4357                 }
4358         }
4359
4360         HUD_Panel_DrawBg(1);
4361
4362         if (!centerprint_showing)
4363                 return;
4364
4365         if(panel_bg_padding)
4366         {
4367                 panel_pos += '1 1 0' * panel_bg_padding;
4368                 panel_size -= '2 2 0' * panel_bg_padding;
4369         }
4370
4371         int entries;
4372         float height;
4373         vector fontsize;
4374         // entries = bound(1, floor(CENTERPRINT_MAX_ENTRIES * 4 * panel_size_y/panel_size_x), CENTERPRINT_MAX_ENTRIES);
4375         // height = panel_size_y/entries;
4376         // fontsize = '1 1 0' * height;
4377         height = vid_conheight/50 * autocvar_hud_panel_centerprint_fontscale;
4378         fontsize = '1 1 0' * height;
4379         entries = bound(1, floor(panel_size.y/height), CENTERPRINT_MAX_ENTRIES);
4380
4381         int i, j, k, n, g;
4382         float a, sz, align, current_msg_posY = 0, msg_size;
4383         vector pos;
4384         string ts;
4385         bool all_messages_expired = true;
4386
4387         pos = panel_pos;
4388         if (autocvar_hud_panel_centerprint_flip)
4389                 pos.y += panel_size.y;
4390         align = bound(0, autocvar_hud_panel_centerprint_align, 1);
4391         for (g=0, i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4392         {
4393                 if (j == CENTERPRINT_MAX_MSGS)
4394                         j = 0;
4395                 if (centerprint_expire_time[j] <= time)
4396                 {
4397                         if (centerprint_countdown_num[j] && centerprint_time[j] > 0)
4398                         {
4399                                 centerprint_countdown_num[j] = centerprint_countdown_num[j] - 1;
4400                                 if (centerprint_countdown_num[j] == 0)
4401                                         continue;
4402                                 centerprint_expire_time[j] = centerprint_expire_time[j] + centerprint_time[j];
4403                         }
4404                         else if(centerprint_time[j] != -1)
4405                                 continue;
4406                 }
4407
4408                 all_messages_expired = false;
4409
4410                 // fade the centerprint_hud in/out
4411                 if(centerprint_time[j] < 0)  // Expired but forced. Expire time is the fade-in time.
4412                         a = (time - centerprint_expire_time[j]) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
4413                 else if(centerprint_expire_time[j] - autocvar_hud_panel_centerprint_fade_out > time)  // Regularily printed. Not fading out yet.
4414                         a = (time - (centerprint_expire_time[j] - centerprint_time[j])) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
4415                 else // Expiring soon, so fade it out.
4416                         a = (centerprint_expire_time[j] - time) / max(0.0001, autocvar_hud_panel_centerprint_fade_out);
4417
4418                 // while counting down show it anyway in order to hold the current message position
4419                 if (a <= 0.5/255.0 && centerprint_countdown_num[j] == 0)  // Guaranteed invisible - don't show.
4420                         continue;
4421                 if (a > 1)
4422                         a = 1;
4423
4424                 // set the size from fading in/out before subsequent fading
4425                 sz = autocvar_hud_panel_centerprint_fade_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_minfontsize);
4426
4427                 // also fade it based on positioning
4428                 if(autocvar_hud_panel_centerprint_fade_subsequent)
4429                 {
4430                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passone_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passone))), 1); // pass one: all messages after the first have half theAlpha
4431                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passtwo_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passtwo))), 1); // pass two: after that, gradually lower theAlpha even more for each message
4432                 }
4433                 a *= panel_fg_alpha;
4434
4435                 // finally set the size based on the new theAlpha from subsequent fading
4436                 sz = sz * (autocvar_hud_panel_centerprint_fade_subsequent_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_subsequent_minfontsize));
4437                 drawfontscale = sz * '1 1 0';
4438
4439                 if (centerprint_countdown_num[j])
4440                         n = tokenizebyseparator(strreplace("^COUNT", count_seconds(centerprint_countdown_num[j]), centerprint_messages[j]), "\n");
4441                 else
4442                         n = tokenizebyseparator(centerprint_messages[j], "\n");
4443
4444                 if (autocvar_hud_panel_centerprint_flip)
4445                 {
4446                         // check if the message can be entirely shown
4447                         for(k = 0; k < n; ++k)
4448                         {
4449                                 getWrappedLine_remaining = argv(k);
4450                                 while(getWrappedLine_remaining)
4451                                 {
4452                                         ts = getWrappedLine(panel_size.x * sz, fontsize, stringwidth_colors);
4453                                         if (ts != "")
4454                                                 pos.y -= fontsize.y;
4455                                         else
4456                                                 pos.y -= fontsize.y * CENTERPRINT_SPACING/2;
4457                                 }
4458                         }
4459                         current_msg_posY = pos.y; // save starting pos (first line) of the current message
4460                 }
4461
4462                 msg_size = pos.y;
4463                 for(k = 0; k < n; ++k)
4464                 {
4465                         getWrappedLine_remaining = argv(k);
4466                         while(getWrappedLine_remaining)
4467                         {
4468                                 ts = getWrappedLine(panel_size.x * sz, fontsize, stringwidth_colors);
4469                                 if (ts != "")
4470                                 {
4471                                         if (align)
4472                                                 pos.x = panel_pos.x + (panel_size.x - stringwidth(ts, true, fontsize)) * align;
4473                                         if (a > 0.5/255.0)  // Otherwise guaranteed invisible - don't show. This is checked a second time after some multiplications with other factors were done so temporary changes of these cannot cause flicker.
4474                                                 drawcolorcodedstring(pos + eY * 0.5 * (1 - sz) * fontsize.y, ts, fontsize, a, DRAWFLAG_NORMAL);
4475                                         pos.y += fontsize.y;
4476                                 }
4477                                 else
4478                                         pos.y += fontsize.y * CENTERPRINT_SPACING/2;
4479                         }
4480                 }
4481
4482                 ++g; // move next position number up
4483
4484                 msg_size = pos.y - msg_size;
4485                 if (autocvar_hud_panel_centerprint_flip)
4486                 {
4487                         pos.y = current_msg_posY - CENTERPRINT_SPACING * fontsize.y;
4488                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4489                                 pos.y += (msg_size + CENTERPRINT_SPACING * fontsize.y) * (1 - sqrt(sz));
4490
4491                         if (pos.y < panel_pos.y) // check if the next message can be shown
4492                         {
4493                                 drawfontscale = '1 1 0';
4494                                 return;
4495                         }
4496                 }
4497                 else
4498                 {
4499                         pos.y += CENTERPRINT_SPACING * fontsize.y;
4500                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4501                                 pos.y -= (msg_size + CENTERPRINT_SPACING * fontsize.y) * (1 - sqrt(sz));
4502
4503                         if(pos.y > panel_pos.y + panel_size.y - fontsize.y) // check if the next message can be shown
4504                         {
4505                                 drawfontscale = '1 1 0';
4506                                 return;
4507                         }
4508                 }
4509         }
4510         drawfontscale = '1 1 0';
4511         if (all_messages_expired)
4512         {
4513                 centerprint_showing = false;
4514                 reset_centerprint_messages();
4515         }
4516 }
4517
4518 // Buffs (#18)
4519 //
4520 void HUD_Buffs(void)
4521 {
4522         int buffs = getstati(STAT_BUFFS, 0, 24);
4523         if(!autocvar__hud_configure)
4524         {
4525                 if(!autocvar_hud_panel_buffs) return;
4526                 if(spectatee_status == -1) return;
4527                 if(getstati(STAT_HEALTH) <= 0) return;
4528                 if(!buffs) return;
4529         }
4530         else
4531         {
4532                 buffs = Buff_Type_first.items; // force first buff
4533         }
4534
4535         int b = 0; // counter to tell other functions that we have buffs
4536         entity e;
4537         string s = "";
4538         for(e = Buff_Type_first; e; e = e.enemy) if(buffs & e.items)
4539         {
4540                 ++b;
4541                 string o = strcat(rgb_to_hexcolor(Buff_Color(e.items)), Buff_PrettyName(e.items));
4542                 if(s == "")
4543                         s = o;
4544                 else
4545                         s = strcat(s, " ", o);
4546         }
4547
4548         HUD_Panel_UpdateCvars();
4549
4550         draw_beginBoldFont();
4551
4552         vector pos, mySize;
4553         pos = panel_pos;
4554         mySize = panel_size;
4555
4556         HUD_Panel_DrawBg(bound(0, b, 1));
4557         if(panel_bg_padding)
4558         {
4559                 pos += '1 1 0' * panel_bg_padding;
4560                 mySize -= '2 2 0' * panel_bg_padding;
4561         }
4562
4563         //float panel_ar = mySize_x/mySize_y;
4564         //bool is_vertical = (panel_ar < 1);
4565         //float buff_iconalign = autocvar_hud_panel_buffs_iconalign;
4566         vector buff_offset = '0 0 0';
4567
4568         for(e = Buff_Type_first; e; e = e.enemy) if(buffs & e.items)
4569         {
4570                 //DrawNumIcon(pos + buff_offset, mySize, shield, "shield", is_vertical, buff_iconalign, '1 1 1', 1);
4571                 drawcolorcodedstring_aspect(pos + buff_offset, s, mySize, panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
4572         }
4573
4574         draw_endBoldFont();
4575 }
4576
4577
4578 /*
4579 ==================
4580 Main HUD system
4581 ==================
4582 */
4583
4584 void HUD_Reset (void)
4585 {
4586         // reset gametype specific icons
4587         if(gametype == MAPINFO_TYPE_CTF)
4588                 HUD_Mod_CTF_Reset();
4589 }
4590
4591 void HUD_Main (void)
4592 {
4593         int i;
4594         // global hud theAlpha fade
4595         if(menu_enabled == 1)
4596                 hud_fade_alpha = 1;
4597         else
4598                 hud_fade_alpha = (1 - autocvar__menu_alpha);
4599
4600         if(scoreboard_fade_alpha)
4601                 hud_fade_alpha = (1 - scoreboard_fade_alpha);
4602
4603         HUD_Configure_Frame();
4604
4605         if(intermission == 2) // no hud during mapvote
4606                 hud_fade_alpha = 0;
4607
4608         // panels that we want to be active together with the scoreboard
4609         // they must fade only when the menu does
4610         if(scoreboard_fade_alpha == 1)
4611         {
4612                 (panel = HUD_PANEL(CENTERPRINT)).panel_draw();
4613                 return;
4614         }
4615
4616         if(!autocvar__hud_configure && !hud_fade_alpha)
4617                 return;
4618
4619         // Drawing stuff
4620         if (hud_skin_prev != autocvar_hud_skin)
4621         {
4622                 if (hud_skin_path)
4623                         strunzone(hud_skin_path);
4624                 hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
4625                 if (hud_skin_prev)
4626                         strunzone(hud_skin_prev);
4627                 hud_skin_prev = strzone(autocvar_hud_skin);
4628         }
4629
4630         // draw the dock
4631         if(autocvar_hud_dock != "" && autocvar_hud_dock != "0")
4632         {
4633                 int f;
4634                 vector color;
4635                 float hud_dock_color_team = autocvar_hud_dock_color_team;
4636                 if((teamplay) && hud_dock_color_team) {
4637                         if(autocvar__hud_configure && myteam == NUM_SPECTATOR)
4638                                 color = '1 0 0' * hud_dock_color_team;
4639                         else
4640                                 color = myteamcolors * hud_dock_color_team;
4641                 }
4642                 else if(autocvar_hud_configure_teamcolorforced && autocvar__hud_configure && hud_dock_color_team) {
4643                         color = '1 0 0' * hud_dock_color_team;
4644                 }
4645                 else
4646                 {
4647                         string hud_dock_color = autocvar_hud_dock_color;
4648                         if(hud_dock_color == "shirt") {
4649                                 f = stof(getplayerkeyvalue(current_player, "colors"));
4650                                 color = colormapPaletteColor(floor(f / 16), 0);
4651                         }
4652                         else if(hud_dock_color == "pants") {
4653                                 f = stof(getplayerkeyvalue(current_player, "colors"));
4654                                 color = colormapPaletteColor(f % 16, 1);
4655                         }
4656                         else
4657                                 color = stov(hud_dock_color);
4658                 }
4659
4660                 string pic;
4661                 pic = strcat(hud_skin_path, "/", autocvar_hud_dock);
4662                 if(precache_pic(pic) == "") {
4663                         pic = strcat(hud_skin_path, "/dock_medium");
4664                         if(precache_pic(pic) == "") {
4665                                 pic = "gfx/hud/default/dock_medium";
4666                         }
4667                 }
4668                 drawpic('0 0 0', pic, eX * vid_conwidth + eY * vid_conheight, color, autocvar_hud_dock_alpha * hud_fade_alpha, DRAWFLAG_NORMAL); // no aspect ratio forcing on dock...
4669         }
4670
4671         // cache the panel order into the panel_order array
4672         if(autocvar__hud_panelorder != hud_panelorder_prev) {
4673                 for(i = 0; i < HUD_PANEL_NUM; ++i)
4674                         panel_order[i] = -1;
4675                 string s = "";
4676                 int p_num;
4677                 bool warning = false;
4678                 int argc = tokenize_console(autocvar__hud_panelorder);
4679                 if (argc > HUD_PANEL_NUM)
4680                         warning = true;
4681                 //first detect wrong/missing panel numbers
4682                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4683                         p_num = stoi(argv(i));
4684                         if (p_num >= 0 && p_num < HUD_PANEL_NUM) { //correct panel number?
4685                                 if (panel_order[p_num] == -1) //found for the first time?
4686                                         s = strcat(s, ftos(p_num), " ");
4687                                 panel_order[p_num] = 1; //mark as found
4688                         }
4689                         else
4690                                 warning = true;
4691                 }
4692                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4693                         if (panel_order[i] == -1) {
4694                                 warning = true;
4695                                 s = strcat(s, ftos(i), " "); //add missing panel number
4696                         }
4697                 }
4698                 if (warning)
4699                         dprint("Automatically fixed wrong/missing panel numbers in _hud_panelorder\n");
4700
4701                 cvar_set("_hud_panelorder", s);
4702                 if(hud_panelorder_prev)
4703                         strunzone(hud_panelorder_prev);
4704                 hud_panelorder_prev = strzone(s);
4705
4706                 //now properly set panel_order
4707                 tokenize_console(s);
4708                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4709                         panel_order[i] = stof(argv(i));
4710                 }
4711         }
4712
4713         hud_draw_maximized = 0;
4714         // draw panels in order specified by panel_order array
4715         for(i = HUD_PANEL_NUM - 1; i >= 0; --i)
4716                 (panel = hud_panel[panel_order[i]]).panel_draw();
4717
4718         hud_draw_maximized = 1; // panels that may be maximized must check this var
4719         // draw maximized panels on top
4720         if(hud_panel_radar_maximized)
4721                 (panel = HUD_PANEL(RADAR)).panel_draw();
4722         if(autocvar__con_chat_maximized)
4723                 (panel = HUD_PANEL(CHAT)).panel_draw();
4724
4725         HUD_Configure_PostDraw();
4726
4727         hud_configure_prev = autocvar__hud_configure;
4728 }