qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  14                 return;
  15         if(intermission == 1)
  16                 return;
  17         if(intermission == 2)
  18                 return;
  19         if (getstati(STAT_HEALTH) <= 0)
  20                 return;
  21
  22         dir = view_forward;
  23
  24         if(angles_held_status)
  25         {
  26                 makevectors(angles_held);
  27                 dir = v_forward;
  28         }
  29
  30         p = view_origin;
  31
  32         polyline[0] = p;
  33         idx = 1;
  34         portal_number = 0;
  35         nextdir = dir;
  36
  37         for(;;)
  38         {
  39                 dir = nextdir;
  40                 traceline(p, p + 65536 * dir, TRUE, porto);
  41                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  42                         return;
  43                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  44                 p = trace_endpos;
  45                 polyline[idx] = p;
  46                 ++idx;
  47                 if(idx >= 16)
  48                         return;
  49                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  50                         continue;
  51                 ++portal_number;
  52                 ang = vectoangles2(trace_plane_normal, dir);
  53                 ang_x = -ang_x;
  54                 makevectors(ang);
  55                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  56                         return;
  57                 if(portal_number == 1)
  58                         portal1_idx = idx;
  59                 if(portal_number >= 2)
  60                         break;
  61         }
  62
  63         while(idx >= 2)
  64         {
  65                 p = polyline[idx-2];
  66                 q = polyline[idx-1];
  67                 if(idx == 2)
  68                         p = p - view_up * 16;
  69                 if(idx-1 >= portal1_idx)
  70                 {
  71                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  72                 }
  73                 else
  74                 {
  75                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  76                 }
  77                 --idx;
  78         }
  79 }
  80
  81 void Porto_Init()
  82 {
  83         porto = spawn();
  84         porto.classname = "porto";
  85         porto.draw = Porto_Draw;
  86         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  87 }
  88
  89 float drawtime;
  90 float avgspeed;
  91 vector GetCurrentFov(float fov)
  92 {
  93         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  94         float velocityzoom, curspeed;
  95
  96         zoomsensitivity = autocvar_cl_zoomsensitivity;
  97         zoomfactor = autocvar_cl_zoomfactor;
  98         if(zoomfactor < 1 || zoomfactor > 16)
  99                 zoomfactor = 2.5;
 100         zoomspeed = autocvar_cl_zoomspeed;
 101         if(zoomspeed >= 0)
 102                 if(zoomspeed < 0.5 || zoomspeed > 16)
 103                         zoomspeed = 3.5;
 104
 105         zoomdir = button_zoom;
 106         if(hud == HUD_NORMAL)
 107         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 108                 zoomdir += button_attack2;
 109         if(spectatee_status > 0 || isdemo())
 110         {
 111                 if(spectatorbutton_zoom)
 112                 {
 113                         if(zoomdir)
 114                                 zoomdir = 0;
 115                         else
 116                                 zoomdir = 1;
 117                 }
 118                 // fteqcc failed twice here already, don't optimize this
 119         }
 120
 121         if(zoomdir)
 122                 zoomin_effect = 0;
 123
 124         if(zoomin_effect || camera_active)
 125         {
 126                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 127         }
 128         else
 129         {
 130                 if(zoomspeed < 0) // instant zoom
 131                 {
 132                         if(zoomdir)
 133                                 current_viewzoom = 1 / zoomfactor;
 134                         else
 135                                 current_viewzoom = 1;
 136                 }
 137                 else
 138                 {
 139                         if(zoomdir)
 140                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 141                         else
 142                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 143                 }
 144         }
 145
 146         if(almost_equals(current_viewzoom, 1))
 147                 current_zoomfraction = 0;
 148         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 149                 current_zoomfraction = 1;
 150         else
 151                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 152
 153         if(zoomsensitivity < 1)
 154                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 155         else
 156                 setsensitivityscale(1);
 157
 158         makevectors(view_angles);
 159
 160         if(autocvar_cl_velocityzoom)
 161         {
 162                 switch(autocvar_cl_velocityzoom_type)
 163                 {
 164                         case 3: curspeed = max(0, v_forward * pmove_vel); break;
 165                         case 2: curspeed = (v_forward * pmove_vel); break;
 166                         case 1: default: curspeed = vlen(pmove_vel); break;
 167                 }
 168
 169                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 170                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 171                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 172
 173                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 174         }
 175         else
 176                 velocityzoom = 1;
 177
 178         float frustumx, frustumy, fovx, fovy;
 179         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 180         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 181         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 182         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 183
 184         return '1 0 0' * fovx + '0 1 0' * fovy;
 185 }
 186
 187 // this function must match W_SetupShot!
 188 float zoomscript_caught;
 189
 190 vector wcross_origin;
 191 float wcross_scale_prev, wcross_alpha_prev;
 192 vector wcross_color_prev;
 193 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 194 vector wcross_color_goal_prev;
 195 float wcross_changedonetime;
 196
 197 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 198 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 199 float wcross_name_changestarttime, wcross_name_changedonetime;
 200 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 201 entity trueaim;
 202 entity trueaim_rifle;
 203
 204 #define SHOTTYPE_HITTEAM 1
 205 #define SHOTTYPE_HITOBSTRUCTION 2
 206 #define SHOTTYPE_HITWORLD 3
 207 #define SHOTTYPE_HITENEMY 4
 208
 209 void TrueAim_Init()
 210 {
 211         trueaim = spawn();
 212         trueaim.classname = "trueaim";
 213         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 214         trueaim_rifle = spawn();
 215         trueaim_rifle.classname = "trueaim_rifle";
 216         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 217 }
 218
 219 float EnemyHitCheck()
 220 {
 221         float t;
 222         wcross_origin = project_3d_to_2d(trace_endpos);
 223         wcross_origin_z = 0;
 224         if(trace_networkentity < 1)
 225                 return SHOTTYPE_HITWORLD;
 226         if(trace_networkentity > maxclients)
 227                 return SHOTTYPE_HITWORLD;
 228         t = GetPlayerColor(trace_networkentity - 1);
 229         if(teamplay)
 230                 if(t == myteam)
 231                         return SHOTTYPE_HITTEAM;
 232         if(t == COLOR_SPECTATOR)
 233                 return SHOTTYPE_HITWORLD;
 234         return SHOTTYPE_HITENEMY;
 235 }
 236
 237 float TrueAimCheck()
 238 {
 239         float nudge = 1; // added to traceline target and subtracted from result
 240         vector vecs, trueaimpoint, w_shotorg;
 241         vector mi, ma, dv;
 242         float shottype;
 243         entity ta;
 244         float mv;
 245
 246         mi = ma = '0 0 0';
 247         ta = trueaim;
 248         mv = MOVE_NOMONSTERS;
 249
 250         switch(activeweapon)
 251         {
 252                 case WEP_TUBA: // no aim
 253                 case WEP_PORTO: // shoots from eye
 254                 case WEP_HOOK: // no trueaim
 255                 case WEP_GRENADE_LAUNCHER: // toss curve
 256                         return SHOTTYPE_HITWORLD;
 257                 case WEP_NEX:
 258                 case WEP_MINSTANEX:
 259                         mv = MOVE_NORMAL;
 260                         break;
 261                 case WEP_RIFLE:
 262                         ta = trueaim_rifle;
 263                         mv = MOVE_NORMAL;
 264                         if(zoomscript_caught)
 265                         {
 266                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 267                                 return EnemyHitCheck();
 268                         }
 269                         break;
 270                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 271                         mi = '-3 -3 -3';
 272                         ma = '3 3 3';
 273                         break;
 274                 case WEP_FIREBALL: // projectile has a size!
 275                         mi = '-16 -16 -16';
 276                         ma = '16 16 16';
 277                         break;
 278                 case WEP_SEEKER: // projectile has a size!
 279                         mi = '-2 -2 -2';
 280                         ma = '2 2 2';
 281                         break;
 282                 case WEP_ELECTRO: // projectile has a size!
 283                         mi = '0 0 -3';
 284                         ma = '0 0 -3';
 285                         break;
 286         }
 287
 288         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 289
 290         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 291         trueaimpoint = trace_endpos;
 292
 293         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 294                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 295
 296         if(vecs_x > 0)
 297                 vecs_y = -vecs_y;
 298         else
 299                 vecs = '0 0 0';
 300
 301         dv = view_right * vecs_y + view_up * vecs_z;
 302         w_shotorg = view_origin + dv;
 303
 304         // now move the vecs forward as much as requested if possible
 305         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 306         w_shotorg = trace_endpos - view_forward * nudge;
 307
 308         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 309         shottype = EnemyHitCheck();
 310         if(shottype != SHOTTYPE_HITWORLD)
 311                 return shottype;
 312
 313 #if 0
 314         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 315         // or rather, I know why, but see no fix
 316         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 317                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 318                 return SHOTTYPE_HITOBSTRUCTION;
 319 #endif
 320
 321         return SHOTTYPE_HITWORLD;
 322 }
 323
 324 void CSQC_common_hud(void);
 325
 326 void PostInit(void);
 327 void CSQC_Demo_Camera();
 328 float HUD_WouldDrawScoreboard();
 329 float camera_mode;
 330 float CAMERA_FREE = 1;
 331 float CAMERA_CHASE = 2;
 332 float reticle_type;
 333 string NextFrameCommand;
 334 void CSQC_SPIDER_HUD();
 335 void CSQC_RAPTOR_HUD();
 336
 337 vector freeze_org, freeze_ang;
 338 entity nightvision_noise, nightvision_noise2;
 339
 340 #define MAX_TIME_DIFF 5
 341 float pickup_crosshair_time, pickup_crosshair_size;
 342 float hit_time, typehit_time;
 343 float nextsound_hit_time, nextsound_typehit_time;
 344 float hitindication_crosshair_time, hitindication_crosshair_size;
 345 float use_nex_chargepool;
 346
 347 float myhealth, myhealth_prev;
 348 float myhealth_flash;
 349
 350 float old_blurradius, old_bluralpha;
 351 float old_sharpen_intensity;
 352
 353 vector myhealth_gentlergb;
 354
 355 float contentavgalpha, liquidalpha_prev;
 356 vector liquidcolor_prev;
 357
 358 float eventchase_current_distance;
 359
 360 vector damage_blurpostprocess, content_blurpostprocess;
 361
 362 float checkfail[16];
 363
 364 #define BUTTON_3 4
 365 #define BUTTON_4 8
 366 void CSQC_UpdateView(float w, float h)
 367 {
 368         entity e;
 369         float fov;
 370         float f, i, j;
 371         vector v;
 372         vector vf_size, vf_min;
 373         float a;
 374
 375         hud = getstati(STAT_HUD);
 376         serverflags = getstati(STAT_ITEMS, 28, 4);
 377
 378         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 379                 view_quality = getproperty(VF_MINFPS_QUALITY);
 380         else
 381                 view_quality = 1;
 382
 383         button_attack2 = (input_buttons & BUTTON_3);
 384         button_zoom = (input_buttons & BUTTON_4);
 385
 386         // FIXME do we need this hack?
 387         if(isdemo())
 388         {
 389                 // in demos, input_buttons do not work
 390                 button_zoom = (autocvar__togglezoom == "-");
 391         }
 392
 393 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 394         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 395         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 396         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 397         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 398         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 399         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 400         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 401
 402         vf_size = getpropertyvec(VF_SIZE);
 403         vf_min = getpropertyvec(VF_MIN);
 404         vid_width = vf_size_x;
 405         vid_height = vf_size_y;
 406
 407         vector reticle_pos, reticle_size;
 408         vector splash_pos, splash_size;
 409
 410         WaypointSprite_Load();
 411
 412         CSQCPlayer_SetCamera();
 413
 414 #ifdef COMPAT_XON050_ENGINE
 415         if(spectatee_status)
 416                 myteam = GetPlayerColor(spectatee_status - 1);
 417         else
 418 #endif
 419                 myteam = GetPlayerColor(player_localentnum - 1);
 420
 421         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 422
 423         // event chase camera
 424         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 425         {
 426                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 427                 {
 428                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 429                         vector current_view_origin = getpropertyvec(VF_ORIGIN);
 430
 431                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 432                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 433                         if(!autocvar_chase_active)
 434                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 435
 436                         // make the camera smooth back
 437                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 438                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 439                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 440                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 441
 442                         vector eventchase_target_origin;
 443                         makevectors(view_angles);
 444                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 445                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance;
 446                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 447                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 448                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 449                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 450                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 451
 452                         setproperty(VF_ORIGIN, trace_endpos);
 453                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 454                 }
 455                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 456                 {
 457                         cvar_set("chase_active", "0");
 458                         eventchase_current_distance = 0; // start from 0 next time
 459                 }
 460         }
 461
 462         // do lockview after event chase camera so that it still applies whenever necessary.
 463         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 464         {
 465                 setproperty(VF_ORIGIN, freeze_org);
 466                 setproperty(VF_ANGLES, freeze_ang);
 467         }
 468         else
 469         {
 470                 freeze_org = getpropertyvec(VF_ORIGIN);
 471                 freeze_ang = getpropertyvec(VF_ANGLES);
 472         }
 473
 474         WarpZone_FixView();
 475         //WarpZone_FixPMove();
 476
 477         // Render the Scene
 478         view_origin = getpropertyvec(VF_ORIGIN);
 479         view_angles = getpropertyvec(VF_ANGLES);
 480         makevectors(view_angles);
 481         view_forward = v_forward;
 482         view_right = v_right;
 483         view_up = v_up;
 484
 485 #ifdef BLURTEST
 486         if(time > blurtest_time0 && time < blurtest_time1)
 487         {
 488                 float r, t;
 489
 490                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 491                 r = t * blurtest_radius;
 492                 f = 1 / pow(t, blurtest_power) - 1;
 493
 494                 cvar_set("r_glsl_postprocess", "1");
 495                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 496         }
 497         else
 498         {
 499                 cvar_set("r_glsl_postprocess", "0");
 500                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 501         }
 502 #endif
 503
 504         TargetMusic_Advance();
 505         Fog_Force();
 506
 507         if(drawtime == 0)
 508                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 509         else
 510                 drawframetime = bound(0.000001, time - drawtime, 1);
 511         drawtime = time;
 512
 513         // watch for gametype changes here...
 514         // in ParseStuffCMD the cmd isn't executed yet :/
 515         // might even be better to add the gametype to TE_CSQC_INIT...?
 516         if(!postinit)
 517                 PostInit();
 518
 519         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 520         {
 521                 if(calledhooks & HOOK_START)
 522                 {
 523                         localcmd("\ncl_hook_gameend\n");
 524                         calledhooks |= HOOK_END;
 525                 }
 526         }
 527
 528   Announcer();
 529
 530         fov = autocvar_fov;
 531         if(fov <= 59.5)
 532         {
 533                 if(!zoomscript_caught)
 534                 {
 535                         localcmd("+button9\n");
 536                         zoomscript_caught = 1;
 537                 }
 538         }
 539         else
 540         {
 541                 if(zoomscript_caught)
 542                 {
 543                         localcmd("-button9\n");
 544                         zoomscript_caught = 0;
 545                 }
 546         }
 547
 548         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 549
 550         // next WANTED weapon (for HUD)
 551         switchweapon = getstati(STAT_SWITCHWEAPON);
 552
 553         // currently switching-to weapon (for crosshair)
 554         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 555
 556         // actually active weapon (for zoom)
 557         activeweapon = getstati(STAT_ACTIVEWEAPON);
 558
 559         f = (serverflags & SERVERFLAG_TEAMPLAY);
 560         if(f != teamplay)
 561         {
 562                 teamplay = f;
 563                 HUD_InitScores();
 564         }
 565
 566         if(last_switchweapon != switchweapon) {
 567                 weapontime = time;
 568                 last_switchweapon = switchweapon;
 569         }
 570         if(last_activeweapon != activeweapon) {
 571                 last_activeweapon = activeweapon;
 572
 573                 e = get_weaponinfo(activeweapon);
 574                 if(e.netname != "")
 575                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 576                 else
 577                         localcmd("\ncl_hook_activeweapon none\n");
 578         }
 579
 580         // ALWAYS Clear Current Scene First
 581         clearscene();
 582 #ifdef WORKAROUND_XON010
 583         if(checkextension("DP_CSQC_ROTATEMOVES"))
 584         {
 585 #endif
 586         setproperty(VF_ORIGIN, view_origin);
 587         setproperty(VF_ANGLES, view_angles);
 588 #ifdef WORKAROUND_XON010
 589         }
 590 #endif
 591
 592         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 593         setproperty(VF_SIZE, vf_size);
 594         setproperty(VF_MIN, vf_min);
 595
 596         // Assign Standard Viewflags
 597         // Draw the World (and sky)
 598         setproperty(VF_DRAWWORLD, 1);
 599
 600         // Set the console size vars
 601         vid_conwidth = autocvar_vid_conwidth;
 602         vid_conheight = autocvar_vid_conheight;
 603         vid_pixelheight = autocvar_vid_pixelheight;
 604
 605         setproperty(VF_FOV, GetCurrentFov(fov));
 606
 607         // Camera for demo playback
 608         if(camera_active)
 609         {
 610                 if(autocvar_camera_enable)
 611                         CSQC_Demo_Camera();
 612                 else
 613                 {
 614                         cvar_set("chase_active", ftos(chase_active_backup));
 615                         cvar_set("cl_demo_mousegrab", "0");
 616                         camera_active = FALSE;
 617                 }
 618         }
 619 #ifdef CAMERATEST
 620         else if(autocvar_camera_enable)
 621 #else
 622         else if(autocvar_camera_enable && isdemo())
 623 #endif
 624         {
 625                 // Enable required Darkplaces cvars
 626                 chase_active_backup = autocvar_chase_active;
 627                 cvar_set("chase_active", "2");
 628                 cvar_set("cl_demo_mousegrab", "1");
 629                 camera_active = TRUE;
 630                 camera_mode = FALSE;
 631         }
 632
 633         // Draw the Crosshair
 634         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 635
 636         // Draw the Engine Status Bar (the default Quake HUD)
 637         setproperty(VF_DRAWENGINESBAR, 0);
 638
 639         // Update the mouse position
 640         /*
 641            mousepos_x = vid_conwidth;
 642            mousepos_y = vid_conheight;
 643            mousepos = mousepos*0.5 + getmousepos();
 644          */
 645
 646         e = self;
 647         for(self = world; (self = nextent(self)); )
 648                 if(self.draw)
 649                         self.draw();
 650         self = e;
 651
 652         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 653         renderscene();
 654
 655         // now switch to 2D drawing mode by calling a 2D drawing function
 656         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 657         // next R_RenderScene call
 658         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 659
 660         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 661         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 662         {
 663                 // apply night vision effect
 664                 vector tc_00, tc_01, tc_10, tc_11;
 665                 vector rgb;
 666                 rgb_x = 0; // fteqcc sucks
 667                 rgb_y = 0; // fteqcc sucks
 668                 rgb_z = 0; // fteqcc sucks
 669
 670                 if(!nightvision_noise)
 671                 {
 672                         nightvision_noise = spawn();
 673                         nightvision_noise.classname = "nightvision_noise";
 674                 }
 675                 if(!nightvision_noise2)
 676                 {
 677                         nightvision_noise2 = spawn();
 678                         nightvision_noise2.classname = "nightvision_noise2";
 679                 }
 680
 681                 // color tint in yellow
 682                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 683
 684                 // draw BG
 685                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 686                 rgb = '1 1 1';
 687                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 688                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 689                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 690                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 691                 tc_11 = tc_01 + tc_10 - tc_00;
 692                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 693                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 694                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 695                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 696                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 697                 R_EndPolygon();
 698
 699                 // draw FG
 700                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 701                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 702                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 703                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 704                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 705                 tc_11 = tc_01 + tc_10 - tc_00;
 706                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 707                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 708                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 709                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 710                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 711                 R_EndPolygon();
 712         }
 713
 714         // Draw the aiming reticle for weapons that use it
 715         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 716         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 717         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 718         if(spectatee_status || getstati(STAT_HEALTH) <= 0 || hud != HUD_NORMAL)
 719                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 720         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 721                 reticle_type = 2; // nex zoom
 722         else if(button_zoom || zoomscript_caught)
 723                 reticle_type = 1; // normal zoom
 724         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 725                 reticle_type = 2; // nex zoom
 726
 727         if(reticle_type && autocvar_cl_reticle)
 728         {
 729                 if(autocvar_cl_reticle_stretch)
 730                 {
 731                         reticle_size_x = vid_conwidth;
 732                         reticle_size_y = vid_conheight;
 733                         reticle_pos_x = 0;
 734                         reticle_pos_y = 0;
 735                 }
 736                 else
 737                 {
 738                         reticle_size_x = max(vid_conwidth, vid_conheight);
 739                         reticle_size_y = max(vid_conwidth, vid_conheight);
 740                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 741                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 742                 }
 743
 744                 f = current_zoomfraction;
 745                 if(zoomscript_caught)
 746                         f = 1;
 747                 if(autocvar_cl_reticle_item_normal)
 748                 {
 749                         if(reticle_type == 1 && f)
 750                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 751                 }
 752                 if(autocvar_cl_reticle_item_nex)
 753                 {
 754                         if(reticle_type == 2 && f)
 755                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 756                 }
 757         }
 758
 759
 760         // improved polyblend
 761         vector rgb;
 762         if(autocvar_hud_contents)
 763         {
 764                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 765                 vector liquidcolor;
 766
 767                 switch(pointcontents(view_origin))
 768                 {
 769                         case CONTENT_WATER:
 770                                 liquidalpha = autocvar_hud_contents_water_alpha;
 771                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 772                                 incontent = 1;
 773                                 break;
 774
 775                         case CONTENT_LAVA:
 776                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 777                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 778                                 incontent = 1;
 779                                 break;
 780
 781                         case CONTENT_SLIME:
 782                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 783                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 784                                 incontent = 1;
 785                                 break;
 786
 787                         default:
 788                                 liquidalpha = 0;
 789                                 liquidcolor = '0 0 0';
 790                                 incontent = 0;
 791                                 break;
 792                 }
 793
 794                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 795                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 796                         contentfadetime = autocvar_hud_contents_fadeintime;
 797                         liquidalpha_prev = liquidalpha;
 798                         liquidcolor_prev = liquidcolor;
 799                 }
 800                 else
 801                         contentfadetime = autocvar_hud_contents_fadeouttime;
 802
 803                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 804                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 805
 806                 if(contentavgalpha)
 807                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 808
 809                 if(autocvar_hud_postprocessing)
 810                 {
 811                         if(autocvar_hud_contents_blur && contentavgalpha)
 812                         {
 813                                 content_blurpostprocess_x = 1;
 814                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 815                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 816                         }
 817                         else
 818                         {
 819                                 content_blurpostprocess_x = 0;
 820                                 content_blurpostprocess_y = 0;
 821                                 content_blurpostprocess_z = 0;
 822                         }
 823                 }
 824         }
 825
 826         if(autocvar_hud_damage)
 827         {
 828                 splash_size_x = max(vid_conwidth, vid_conheight);
 829                 splash_size_y = max(vid_conwidth, vid_conheight);
 830                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 831                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 832
 833                 float myhealth_flash_temp;
 834                 myhealth = getstati(STAT_HEALTH);
 835
 836                 // fade out
 837                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 838                 // add new damage
 839                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 840
 841                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 842                 pain_threshold = autocvar_hud_damage_pain_threshold;
 843                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 844                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 845
 846                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 847                 {
 848                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 849                 }
 850
 851                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 852
 853                 if(myhealth_prev < 1)
 854                 {
 855                         if(myhealth >= 1)
 856                         {
 857                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 858                                 myhealth_flash_temp = 0;
 859                         }
 860                         else
 861                         {
 862                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 863                         }
 864                 }
 865
 866                 if(spectatee_status == -1 || intermission)
 867                 {
 868                         myhealth_flash = 0; // observing, or match ended
 869                         myhealth_flash_temp = 0;
 870                 }
 871
 872                 myhealth_prev = myhealth;
 873
 874                 // IDEA: change damage color/picture based on player model for robot/alien species?
 875                 // pro: matches model better
 876                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
 877                 // maybe different reddish pics?
 878                 if(autocvar_chase_active >= 0) // not while the event chase camera is active
 879                 {
 880                         if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 881                         {
 882                                 if(autocvar_cl_gentle_damage == 2)
 883                                 {
 884                                         if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 885                                         {
 886                                                 myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 887                                         }
 888                                 }
 889                                 else
 890                                         myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 891
 892                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 893                         }
 894                         else
 895                                 drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 896                 }
 897
 898                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
 899                 {
 900                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 901                         {
 902                                 damage_blurpostprocess_x = 1;
 903                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 904                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 905                         }
 906                         else
 907                         {
 908                                 damage_blurpostprocess_x = 0;
 909                                 damage_blurpostprocess_y = 0;
 910                                 damage_blurpostprocess_z = 0;
 911                         }
 912                 }
 913         }
 914
 915         if(autocvar_hud_postprocessing) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
 916         {
 917                 // enable or disable rendering types if they are used or not
 918                 if(cvar("r_glsl_postprocess_uservec1_enable") != (autocvar_hud_postprocessing_maxbluralpha != 0)) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(autocvar_hud_postprocessing_maxbluralpha != 0)); }
 919                 if(cvar("r_glsl_postprocess_uservec2_enable") != (autocvar_hud_powerup != 0)) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(autocvar_hud_powerup != 0)); }
 920
 921                 // blur postprocess handling done first (used by hud_damage and hud_contents)
 922                 if((damage_blurpostprocess_x || content_blurpostprocess_x) && autocvar_chase_active >= 0) // not while the event chase camera is active
 923                 {
 924                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 925                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 926                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 927                         {
 928                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 929                                 old_blurradius = blurradius;
 930                                 old_bluralpha = bluralpha;
 931                         }
 932                 }
 933                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 934                 {
 935                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 936                         old_blurradius = 0;
 937                         old_bluralpha = 0;
 938                 }
 939
 940                 // edge detection postprocess handling done second (used by hud_powerup)
 941                 float sharpen_intensity, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
 942                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
 943                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
 944
 945                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
 946
 947                 if(autocvar_hud_powerup && sharpen_intensity > 0 && autocvar_chase_active >= 0) // not while the event chase camera is active
 948                 {
 949                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 950                         {
 951                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
 952                                 old_sharpen_intensity = sharpen_intensity;
 953                         }
 954                 }
 955                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
 956                 {
 957                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 958                         old_sharpen_intensity = 0;
 959                 }
 960         }
 961
 962         if(menu_visible)
 963                 menu_show();
 964
 965         /*if(gametype == GAME_CTF)
 966           {
 967           ctf_view();
 968           } else */
 969
 970         // draw 2D entities
 971         e = self;
 972         for(self = world; (self = nextent(self)); )
 973                 if(self.draw2d)
 974                         self.draw2d();
 975         self = e;
 976         Draw_ShowNames_All();
 977
 978         scoreboard_active = HUD_WouldDrawScoreboard();
 979
 980         hit_time = getstatf(STAT_HIT_TIME);
 981         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 982         {
 983                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 984                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 985
 986                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 987         }
 988         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 989         if(typehit_time > nextsound_typehit_time)
 990         {
 991                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 992                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 993
 994                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 995         }
 996
 997         //else
 998         {
 999                 if(gametype == GAME_FREEZETAG)
1000                 {
1001                         if(getstati(STAT_FROZEN))
1002                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1003                         if(getstatf(STAT_REVIVE_PROGRESS))
1004                         {
1005                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1006                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1007                         }
1008                 }
1009
1010                 if(autocvar_r_letterbox == 0)
1011                         if(autocvar_viewsize < 120)
1012                                 CSQC_common_hud();
1013
1014                 // crosshair goes VERY LAST
1015                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL) {
1016                         string wcross_style;
1017                         float wcross_alpha, wcross_resolution;
1018                         wcross_style = autocvar_crosshair;
1019                         if (wcross_style == "0")
1020                                 return;
1021                         wcross_resolution = autocvar_crosshair_size;
1022                         if (wcross_resolution == 0)
1023                                 return;
1024                         wcross_alpha = autocvar_crosshair_alpha;
1025                         if (wcross_alpha == 0)
1026                                 return;
1027
1028                         // TrueAim check
1029                         float shottype;
1030
1031                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1032                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1033                         wcross_origin_z = 0;
1034                         if(autocvar_crosshair_hittest)
1035                         {
1036                                 vector wcross_oldorigin;
1037                                 wcross_oldorigin = wcross_origin;
1038                                 shottype = TrueAimCheck();
1039                                 if(shottype == SHOTTYPE_HITWORLD)
1040                                 {
1041                                         v = wcross_origin - wcross_oldorigin;
1042                                         v_x /= vid_conwidth;
1043                                         v_y /= vid_conheight;
1044                                         if(vlen(v) > 0.01)
1045                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1046                                 }
1047                                 if(!autocvar_crosshair_hittest_showimpact)
1048                                         wcross_origin = wcross_oldorigin;
1049                         }
1050                         else
1051                                 shottype = SHOTTYPE_HITWORLD;
1052
1053                         vector wcross_color, wcross_size;
1054                         string wcross_wep, wcross_name;
1055                         float wcross_scale, wcross_blur;
1056
1057                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1058                                 e = get_weaponinfo(switchingweapon);
1059                                 if (e && e.netname != "")
1060                                 {
1061                                         wcross_wep = e.netname;
1062                                         if(autocvar_crosshair_per_weapon)
1063                                         {
1064                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1065                                                 if (wcross_resolution == 0)
1066                                                         return;
1067                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1068                                                 if (wcross_alpha == 0)
1069                                                         return;
1070
1071                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1072                                                 if(wcross_style == "" || wcross_style == "0")
1073                                                         wcross_style = wcross_wep;
1074                                         }
1075                                 }
1076                         }
1077                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1078                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1079                         else if(autocvar_crosshair_color_by_health)
1080                         {
1081                                 float x = getstati(STAT_HEALTH);
1082
1083                                 //x = red
1084                                 //y = green
1085                                 //z = blue
1086
1087                                 wcross_color_z = 0;
1088
1089                                 if(x > 200)
1090                                 {
1091                                         wcross_color_x = 0;
1092                                         wcross_color_y = 1;
1093                                 }
1094                                 else if(x > 150)
1095                                 {
1096                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1097                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1098                                 }
1099                                 else if(x > 100)
1100                                 {
1101                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1102                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1103                                         wcross_color_z = 1 - (x-100)*0.02;
1104                                 }
1105                                 else if(x > 50)
1106                                 {
1107                                         wcross_color_x = 1;
1108                                         wcross_color_y = 1;
1109                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1110                                 }
1111                                 else if(x > 20)
1112                                 {
1113                                         wcross_color_x = 1;
1114                                         wcross_color_y = (x-20)*90/27/100;
1115                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1116                                 }
1117                                 else
1118                                 {
1119                                         wcross_color_x = 1;
1120                                         wcross_color_y = 0;
1121                                 }
1122                         }
1123                         else
1124                                 wcross_color = stov(autocvar_crosshair_color);
1125
1126                         wcross_name = strcat("gfx/crosshair", wcross_style);
1127
1128                         if(autocvar_crosshair_effect_scalefade)
1129                         {
1130                                 wcross_scale = wcross_resolution;
1131                                 wcross_resolution = 1;
1132                         }
1133                         else
1134                         {
1135                                 wcross_scale = 1;
1136                         }
1137
1138                         if(autocvar_crosshair_pickup)
1139                         {
1140                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1141
1142                                 if(pickup_crosshair_time < stat_pickup_time)
1143                                 {
1144                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1145                                                 pickup_crosshair_size = 1;
1146
1147                                         pickup_crosshair_time = stat_pickup_time;
1148                                 }
1149
1150                                 if(pickup_crosshair_size > 0)
1151                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1152                                 else
1153                                         pickup_crosshair_size = 0;
1154
1155                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1156                         }
1157
1158                         if(autocvar_crosshair_hitindication)
1159                         {
1160                                 vector hitindication_color = stov(autocvar_crosshair_hitindication_color);
1161                                 if(hitindication_crosshair_time < hit_time)
1162                                 {
1163                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1164                                                 hitindication_crosshair_size = 1;
1165
1166                                         hitindication_crosshair_time = hit_time;
1167                                 }
1168
1169                                 if(hitindication_crosshair_size > 0)
1170                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1171                                 else
1172                                         hitindication_crosshair_size = 0;
1173
1174                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1175                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1176                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1177                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1178                         }
1179
1180                         if(shottype == SHOTTYPE_HITENEMY)
1181                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1182                         if(shottype == SHOTTYPE_HITTEAM)
1183                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1184
1185                         f = autocvar_crosshair_effect_speed;
1186                         if(f < 0)
1187                                 f *= -2 * g_weaponswitchdelay; // anim starts when weapon has been lowered and new weapon comes up
1188                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1189                         {
1190                                 wcross_changedonetime = time + f;
1191                         }
1192                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1193                         {
1194                                 wcross_name_changestarttime = time;
1195                                 wcross_name_changedonetime = time + f;
1196                                 if(wcross_name_goal_prev_prev)
1197                                         strunzone(wcross_name_goal_prev_prev);
1198                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1199                                 wcross_name_goal_prev = strzone(wcross_name);
1200                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1201                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1202                                 wcross_resolution_goal_prev = wcross_resolution;
1203                         }
1204
1205                         wcross_scale_goal_prev = wcross_scale;
1206                         wcross_alpha_goal_prev = wcross_alpha;
1207                         wcross_color_goal_prev = wcross_color;
1208
1209                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1210                         {
1211                                 wcross_blur = 1;
1212                                 wcross_alpha *= 0.75;
1213                         }
1214                         else
1215                                 wcross_blur = 0;
1216                         // *_prev is at time-frametime
1217                         // * is at wcross_changedonetime+f
1218                         // what do we have at time?
1219                         if(time < wcross_changedonetime)
1220                         {
1221                                 f = frametime / (wcross_changedonetime - time + frametime);
1222                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1223                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1224                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1225                         }
1226
1227                         wcross_scale_prev = wcross_scale;
1228                         wcross_alpha_prev = wcross_alpha;
1229                         wcross_color_prev = wcross_color;
1230
1231                         wcross_scale *= 1 - autocvar__menu_alpha;
1232                         wcross_alpha *= 1 - autocvar__menu_alpha;
1233                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1234
1235                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1236                         {
1237                                 // crosshair rings for weapon stats
1238                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1239                                 {
1240                                         // declarations and stats
1241                                         float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1242                                         string ring_image, ring_inner_image;
1243                                         vector ring_rgb, ring_inner_rgb;
1244
1245                                         ring_scale = autocvar_crosshair_ring_size;
1246
1247                                         float weapon_clipload, weapon_clipsize;
1248                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1249                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1250
1251                                         float nex_charge, nex_chargepool;
1252                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1253                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1254
1255                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1256                                                 nex_charge_movingavg = nex_charge;
1257
1258
1259                                         // handle the values
1260                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1261                                         {
1262                                                 if (nex_chargepool || use_nex_chargepool) {
1263                                                         use_nex_chargepool = 1;
1264                                                         ring_inner_value = nex_chargepool;
1265                                                 } else {
1266                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1267                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1268                                                 }
1269
1270                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1271                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1272                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1273
1274                                                 // draw the outer ring to show the current charge of the weapon
1275                                                 ring_value = nex_charge;
1276                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1277                                                 ring_rgb = wcross_color;
1278                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1279                                         }
1280                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1281                                         {
1282                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1283                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1284                                                 ring_rgb = wcross_color;
1285                                                 ring_image = "gfx/crosshair_ring.tga";
1286                                         }
1287                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1288                                         {
1289                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1290                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1291                                                 ring_rgb = wcross_color;
1292                                                 ring_image = "gfx/crosshair_ring.tga";
1293                                         }
1294
1295                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1296                                         {
1297                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1298                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1299                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1300                                                 ring_rgb = wcross_color;
1301
1302                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1303                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1304                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1305                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1306                                                 else
1307                                                         ring_image = "gfx/crosshair_ring.tga";
1308                                         }
1309
1310                                         // if in weapon switch animation, fade ring out/in
1311                                         if(g_weaponswitchdelay > 0)
1312                                         {
1313                                                 f = (time - wcross_name_changestarttime) / g_weaponswitchdelay;
1314                                                 if(f > 0 && f < 2)
1315                                                         ring_alpha *= fabs(1 - f);
1316                                         }
1317
1318                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1319                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1320
1321                                         if (ring_value)
1322                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1323                                 }
1324
1325 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1326                                 do \
1327                                 { \
1328                                         if(wcross_blur > 0) \
1329                                         { \
1330                                                 for(i = -2; i <= 2; ++i) \
1331                                                 for(j = -2; j <= 2; ++j) \
1332                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1333                                         } \
1334                                         else \
1335                                         { \
1336                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1337                                         } \
1338                                 } \
1339                                 while(0)
1340
1341 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1342                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1343
1344 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1345                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1346
1347                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1348                                 {
1349                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1350                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1351                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1352                                         f = 1 - f;
1353                                 }
1354                                 else
1355                                 {
1356                                         f = 1;
1357                                 }
1358                                 wcross_name_alpha_goal_prev = f;
1359
1360                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1361                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1362
1363                                 if(autocvar_crosshair_dot)
1364                                 {
1365                                         vector wcross_color_old;
1366                                         wcross_color_old = wcross_color;
1367                                         if(autocvar_crosshair_dot_color != "0")
1368                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1369                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1370                                         // FIXME why don't we use wcross_alpha here?
1371                                         wcross_color = wcross_color_old;
1372                                 }
1373                         }
1374                 }
1375                 else
1376                 {
1377                         wcross_scale_prev = 0;
1378                         wcross_alpha_prev = 0;
1379                         wcross_scale_goal_prev = 0;
1380                         wcross_alpha_goal_prev = 0;
1381                         wcross_changedonetime = 0;
1382                         if(wcross_name_goal_prev)
1383                                 strunzone(wcross_name_goal_prev);
1384                         wcross_name_goal_prev = string_null;
1385                         if(wcross_name_goal_prev_prev)
1386                                 strunzone(wcross_name_goal_prev_prev);
1387                         wcross_name_goal_prev_prev = string_null;
1388                         wcross_name_changestarttime = 0;
1389                         wcross_name_changedonetime = 0;
1390                         wcross_name_alpha_goal_prev = 0;
1391                         wcross_name_alpha_goal_prev_prev = 0;
1392                         wcross_resolution_goal_prev = 0;
1393                         wcross_resolution_goal_prev_prev = 0;
1394                 }
1395         }
1396
1397         if(NextFrameCommand)
1398         {
1399                 localcmd("\n", NextFrameCommand, "\n");
1400                 NextFrameCommand = string_null;
1401         }
1402
1403         // we must do this check AFTER a frame was rendered, or it won't work
1404         if(cs_project_is_b0rked == 0)
1405         {
1406                 string w0, h0;
1407                 w0 = ftos(autocvar_vid_conwidth);
1408                 h0 = ftos(autocvar_vid_conheight);
1409                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1410                 //setproperty(VF_FOV, '90 90 0');
1411                 setproperty(VF_ORIGIN, '0 0 0');
1412                 setproperty(VF_ANGLES, '0 0 0');
1413                 setproperty(VF_PERSPECTIVE, 1);
1414                 makevectors('0 0 0');
1415                 vector v1, v2;
1416                 cvar_set("vid_conwidth", "800");
1417                 cvar_set("vid_conheight", "600");
1418                 v1 = cs_project(v_forward);
1419                 cvar_set("vid_conwidth", "640");
1420                 cvar_set("vid_conheight", "480");
1421                 v2 = cs_project(v_forward);
1422                 if(v1 == v2)
1423                         cs_project_is_b0rked = 1;
1424                 else
1425                         cs_project_is_b0rked = -1;
1426                 cvar_set("vid_conwidth", w0);
1427                 cvar_set("vid_conheight", h0);
1428         }
1429
1430         if(autocvar__hud_configure)
1431                 HUD_Panel_Mouse();
1432
1433     if(hud && !intermission)
1434     {
1435         if(hud == HUD_SPIDERBOT)
1436             CSQC_SPIDER_HUD();
1437         else if(hud == HUD_WAKIZASHI)
1438             CSQC_WAKIZASHI_HUD();
1439         else if(hud == HUD_RAPTOR)
1440             CSQC_RAPTOR_HUD();
1441         else if(hud == HUD_BUMBLEBEE)
1442             CSQC_BUMBLE_HUD();
1443     }
1444         // let's reset the view back to normal for the end
1445         setproperty(VF_MIN, '0 0 0');
1446         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1447 }
1448
1449
1450 void CSQC_common_hud(void)
1451 {
1452     // do some accuracy var caching
1453     float i;
1454     if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1455     {
1456         if(autocvar_accuracy_color_levels != acc_color_levels)
1457         {
1458             if(acc_color_levels)
1459                 strunzone(acc_color_levels);
1460             acc_color_levels = strzone(autocvar_accuracy_color_levels);
1461             acc_levels = tokenize_console(acc_color_levels);
1462             if (acc_levels > MAX_ACCURACY_LEVELS)
1463                 acc_levels = MAX_ACCURACY_LEVELS;
1464
1465             for (i = 0; i < acc_levels; ++i)
1466                 acc_lev[i] = stof(argv(i)) / 100.0;
1467         }
1468         // let know that acc_col[] needs to be loaded
1469         acc_col_x[0] = -1;
1470     }
1471
1472     HUD_Main(); // always run these functions for alpha checks
1473     HUD_DrawScoreboard();
1474
1475     if (scoreboard_active) // scoreboard/accuracy
1476         HUD_Reset();
1477     else if (intermission == 2) // map voting screen
1478     {
1479         HUD_FinaleOverlay();
1480         HUD_Reset();
1481     }
1482         /*
1483         switch(hud)
1484         {
1485                 case HUD_SPIDERBOT:
1486                         CSQC_SPIDER_HUD();
1487                         break;
1488
1489                 case HUD_WAKIZASHI:
1490                         CSQC_WAKIZASHI_HUD();
1491                         break;
1492
1493         case HUD_BUMBLEBEE:
1494             CSQC_BUMBLE_HUD();
1495             break;
1496         }
1497         */
1498 }
1499
1500
1501 // following vectors must be global to allow seamless switching between camera modes
1502 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1503 void CSQC_Demo_Camera()
1504 {
1505         float speed, attenuation, dimensions;
1506         vector tmp, delta;
1507
1508         if( autocvar_camera_reset || !camera_mode )
1509         {
1510                 camera_offset = '0 0 0';
1511                 current_angles = '0 0 0';
1512                 camera_direction = '0 0 0';
1513                 camera_offset_z += 30;
1514                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1515                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1516                 current_origin = view_origin;
1517                 current_camera_offset  = camera_offset;
1518                 cvar_set("camera_reset", "0");
1519                 camera_mode = CAMERA_CHASE;
1520         }
1521
1522         // Camera angles
1523         if( camera_roll )
1524                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1525
1526         if(autocvar_camera_look_player)
1527         {
1528                 vector dir;
1529                 float n;
1530
1531                 dir = normalize(view_origin - current_position);
1532                 n = mouse_angles_z;
1533                 mouse_angles = vectoangles(dir);
1534                 mouse_angles_x = mouse_angles_x * -1;
1535                 mouse_angles_z = n;
1536         }
1537         else
1538         {
1539                 tmp = getmousepos() * 0.1;
1540                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1541                 {
1542                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1543                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1544                 }
1545         }
1546
1547         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1548         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1549         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1550         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1551
1552         // Fix difference when angles don't have the same sign
1553         delta = '0 0 0';
1554         if(mouse_angles_y < -60 && current_angles_y > 60)
1555                 delta = '0 360 0';
1556         if(mouse_angles_y > 60 && current_angles_y < -60)
1557                 delta = '0 -360 0';
1558
1559         if(autocvar_camera_look_player)
1560                 attenuation = autocvar_camera_look_attenuation;
1561         else
1562                 attenuation = autocvar_camera_speed_attenuation;
1563
1564         attenuation = 1 / max(1, attenuation);
1565         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1566
1567         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1568         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1569         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1570         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1571
1572         // Camera position
1573         tmp = '0 0 0';
1574         dimensions = 0;
1575
1576         if( camera_direction_x )
1577         {
1578                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1579                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1580                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1581                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1582                 ++dimensions;
1583         }
1584
1585         if( camera_direction_y )
1586         {
1587                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1588                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1589                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1590                 ++dimensions;
1591         }
1592
1593         if( camera_direction_z )
1594         {
1595                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1596                 ++dimensions;
1597         }
1598
1599         if(autocvar_camera_free)
1600                 speed = autocvar_camera_speed_free;
1601         else
1602                 speed = autocvar_camera_speed_chase;
1603
1604         if(dimensions)
1605         {
1606                 speed = speed * sqrt(1 / dimensions);
1607                 camera_offset += tmp * speed;
1608         }
1609
1610         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1611
1612         // Camera modes
1613         if( autocvar_camera_free )
1614         {
1615                 if ( camera_mode == CAMERA_CHASE )
1616                 {
1617                         current_camera_offset = current_origin + current_camera_offset;
1618                         camera_offset = current_origin + camera_offset;
1619                 }
1620
1621                 camera_mode = CAMERA_FREE;
1622                 current_position = current_camera_offset;
1623         }
1624         else
1625         {
1626                 if ( camera_mode == CAMERA_FREE )
1627                 {
1628                         current_origin = view_origin;
1629                         camera_offset = camera_offset - current_origin;
1630                         current_camera_offset = current_camera_offset - current_origin;
1631                 }
1632
1633                 camera_mode = CAMERA_CHASE;
1634
1635                 if(autocvar_camera_chase_smoothly)
1636                         current_origin += (view_origin - current_origin) * attenuation;
1637                 else
1638                         current_origin = view_origin;
1639
1640                 current_position = current_origin + current_camera_offset;
1641         }
1642
1643         setproperty(VF_ANGLES, current_angles);
1644         setproperty(VF_ORIGIN, current_position);
1645 }