qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 void Porto_Draw()
   4 {
   5         vector p, dir, ang, q, nextdir;
   6         float idx, portal_number, portal1_idx;
   7
   8         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
   9                 return;
  10         if(g_balance_porto_secondary)
  11                 return;
  12         if(intermission == 1)
  13                 return;
  14         if(intermission == 2)
  15                 return;
  16         if (getstati(STAT_HEALTH) <= 0)
  17                 return;
  18
  19         dir = view_forward;
  20
  21         if(angles_held_status)
  22         {
  23                 makevectors(angles_held);
  24                 dir = v_forward;
  25         }
  26
  27         p = view_origin;
  28
  29         polyline[0] = p;
  30         idx = 1;
  31         portal_number = 0;
  32         nextdir = dir;
  33
  34         for(;;)
  35         {
  36                 dir = nextdir;
  37                 traceline(p, p + 65536 * dir, TRUE, porto);
  38                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  39                         return;
  40                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  41                 p = trace_endpos;
  42                 polyline[idx] = p;
  43                 ++idx;
  44                 if(idx >= 16)
  45                         return;
  46                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  47                         continue;
  48                 ++portal_number;
  49                 ang = vectoangles2(trace_plane_normal, dir);
  50                 ang_x = -ang_x;
  51                 makevectors(ang);
  52                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  53                         return;
  54                 if(portal_number == 1)
  55                 {
  56                         portal1_idx = idx;
  57                         if(portal_number >= 2)
  58                                 break;
  59                 }
  60         }
  61
  62         while(idx >= 2)
  63         {
  64                 p = polyline[idx-2];
  65                 q = polyline[idx-1];
  66                 if(idx == 2)
  67                         p = p - view_up * 16;
  68                 if(idx-1 >= portal1_idx)
  69                 {
  70                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  71                 }
  72                 else
  73                 {
  74                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  75                 }
  76                 --idx;
  77         }
  78 }
  79
  80 void Porto_Init()
  81 {
  82         porto = spawn();
  83         porto.classname = "porto";
  84         porto.draw = Porto_Draw;
  85         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  86 }
  87
  88 float drawtime;
  89 float avgspeed;
  90 vector GetCurrentFov(float fov)
  91 {
  92         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  93         float velocityzoom, curspeed;
  94         vector v;
  95
  96         zoomsensitivity = autocvar_cl_zoomsensitivity;
  97         zoomfactor = autocvar_cl_zoomfactor;
  98         if(zoomfactor < 1 || zoomfactor > 16)
  99                 zoomfactor = 2.5;
 100         zoomspeed = autocvar_cl_zoomspeed;
 101         if(zoomspeed >= 0)
 102         if(zoomspeed < 0.5 || zoomspeed > 16)
 103                         zoomspeed = 3.5;
 104
 105         zoomdir = button_zoom;
 106         if(hud == HUD_NORMAL)
 107         if((activeweapon == WEP_VORTEX && vortex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 108                 zoomdir += button_attack2;
 109         if(spectatee_status > 0 || isdemo())
 110         {
 111                 if(spectatorbutton_zoom)
 112                 {
 113                         if(zoomdir)
 114                                 zoomdir = 0;
 115                         else
 116                                 zoomdir = 1;
 117                 }
 118                 // fteqcc failed twice here already, don't optimize this
 119         }
 120
 121         if(zoomdir) { zoomin_effect = 0; }
 122
 123         if(camera_active)
 124         {
 125                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 126         }
 127         else if(autocvar_cl_spawnzoom && zoomin_effect)
 128         {
 129                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 130
 131                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 132                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 133                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 134         }
 135         else
 136         {
 137                 if(zoomspeed < 0) // instant zoom
 138                 {
 139                         if(zoomdir)
 140                                 current_viewzoom = 1 / zoomfactor;
 141                         else
 142                                 current_viewzoom = 1;
 143                 }
 144                 else
 145                 {
 146                         if(zoomdir)
 147                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 148                         else
 149                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 150                 }
 151         }
 152
 153         if(almost_equals(current_viewzoom, 1))
 154                 current_zoomfraction = 0;
 155         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 156                 current_zoomfraction = 1;
 157         else
 158                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 159
 160         if(zoomsensitivity < 1)
 161                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 162         else
 163                 setsensitivityscale(1);
 164
 165         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 166         {
 167                 if(intermission) { curspeed = 0; }
 168                 else
 169                 {
 170
 171                         makevectors(view_angles);
 172                         v = pmove_vel;
 173                         if(csqcplayer)
 174                                 v = csqcplayer.velocity;
 175
 176                         switch(autocvar_cl_velocityzoom_type)
 177                         {
 178                                 case 3: curspeed = max(0, v_forward * v); break;
 179                                 case 2: curspeed = (v_forward * v); break;
 180                                 case 1: default: curspeed = vlen(v); break;
 181                         }
 182                 }
 183
 184                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 185                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 186                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 187
 188                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 189         }
 190         else
 191                 velocityzoom = 1;
 192
 193         float frustumx, frustumy, fovx, fovy;
 194         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 195         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 196         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 197         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 198
 199         return '1 0 0' * fovx + '0 1 0' * fovy;
 200 }
 201
 202 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 203 {
 204         float fovx, fovy;
 205         float width = (ov_worldmax_x - ov_worldmin_x);
 206         float height = (ov_worldmax_y - ov_worldmin_y);
 207         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 208         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 209         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 210         return '1 0 0' * fovx + '0 1 0' * fovy;
 211 }
 212
 213 // this function must match W_SetupShot!
 214 float zoomscript_caught;
 215
 216 vector wcross_origin;
 217 float wcross_scale_prev, wcross_alpha_prev;
 218 vector wcross_color_prev;
 219 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 220 vector wcross_color_goal_prev;
 221 float wcross_changedonetime;
 222
 223 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 224 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 225 float wcross_name_changestarttime, wcross_name_changedonetime;
 226 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 227
 228 float wcross_ring_prev;
 229
 230 entity trueaim;
 231 entity trueaim_rifle;
 232
 233 #define SHOTTYPE_HITTEAM 1
 234 #define SHOTTYPE_HITOBSTRUCTION 2
 235 #define SHOTTYPE_HITWORLD 3
 236 #define SHOTTYPE_HITENEMY 4
 237
 238 void TrueAim_Init()
 239 {
 240         trueaim = spawn();
 241         trueaim.classname = "trueaim";
 242         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 243         trueaim_rifle = spawn();
 244         trueaim_rifle.classname = "trueaim_rifle";
 245         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 246 }
 247
 248 float EnemyHitCheck()
 249 {
 250         float t, n;
 251         wcross_origin = project_3d_to_2d(trace_endpos);
 252         wcross_origin_z = 0;
 253         if(trace_ent)
 254                 n = trace_ent.entnum;
 255         else
 256                 n = trace_networkentity;
 257         if(n < 1)
 258                 return SHOTTYPE_HITWORLD;
 259         if(n > maxclients)
 260                 return SHOTTYPE_HITWORLD;
 261         t = GetPlayerColor(n - 1);
 262         if(teamplay)
 263                 if(t == myteam)
 264                         return SHOTTYPE_HITTEAM;
 265         if(t == NUM_SPECTATOR)
 266                 return SHOTTYPE_HITWORLD;
 267         return SHOTTYPE_HITENEMY;
 268 }
 269
 270 float TrueAimCheck()
 271 {
 272         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 273         vector vecs, trueaimpoint, w_shotorg;
 274         vector mi, ma, dv;
 275         float shottype;
 276         entity ta;
 277         float mv;
 278
 279         mi = ma = '0 0 0';
 280         ta = trueaim;
 281         mv = MOVE_NOMONSTERS;
 282
 283         switch(activeweapon) // WEAPONTODO
 284         {
 285                 case WEP_TUBA: // no aim
 286                 case WEP_PORTO: // shoots from eye
 287                 case WEP_HOOK: // no trueaim
 288                 case WEP_MORTAR: // toss curve
 289                         return SHOTTYPE_HITWORLD;
 290                 case WEP_VORTEX:
 291                 case WEP_VAPORIZER:
 292                         mv = MOVE_NORMAL;
 293                         break;
 294                 case WEP_RIFLE:
 295                         ta = trueaim_rifle;
 296                         mv = MOVE_NORMAL;
 297                         if(zoomscript_caught)
 298                         {
 299                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 300                                 return EnemyHitCheck();
 301                         }
 302                         break;
 303                 case WEP_DEVASTATOR: // projectile has a size!
 304                         mi = '-3 -3 -3';
 305                         ma = '3 3 3';
 306                         break;
 307                 case WEP_FIREBALL: // projectile has a size!
 308                         mi = '-16 -16 -16';
 309                         ma = '16 16 16';
 310                         break;
 311                 case WEP_SEEKER: // projectile has a size!
 312                         mi = '-2 -2 -2';
 313                         ma = '2 2 2';
 314                         break;
 315                 case WEP_ELECTRO: // projectile has a size!
 316                         mi = '0 0 -3';
 317                         ma = '0 0 -3';
 318                         break;
 319         }
 320
 321         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 322
 323         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 324
 325         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 326         trueaimpoint = trace_endpos;
 327
 328         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 329                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 330
 331         if(vecs_x > 0)
 332                 vecs_y = -vecs_y;
 333         else
 334                 vecs = '0 0 0';
 335
 336         dv = view_right * vecs_y + view_up * vecs_z;
 337         w_shotorg = traceorigin + dv;
 338
 339         // now move the vecs forward as much as requested if possible
 340         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 341         w_shotorg = trace_endpos - view_forward * nudge;
 342
 343         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 344         shottype = EnemyHitCheck();
 345         if(shottype != SHOTTYPE_HITWORLD)
 346                 return shottype;
 347
 348 #if 0
 349         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 350         // or rather, I know why, but see no fix
 351         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 352                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 353                 return SHOTTYPE_HITOBSTRUCTION;
 354 #endif
 355
 356         return SHOTTYPE_HITWORLD;
 357 }
 358
 359 void CSQC_common_hud(void);
 360
 361 void PostInit(void);
 362 void CSQC_Demo_Camera();
 363 float HUD_WouldDrawScoreboard();
 364 float camera_mode;
 365 const float CAMERA_FREE = 1;
 366 const float CAMERA_CHASE = 2;
 367 float reticle_type;
 368 string reticle_image;
 369 string NextFrameCommand;
 370 void CSQC_SPIDER_HUD();
 371 void CSQC_RAPTOR_HUD();
 372
 373 vector freeze_org, freeze_ang;
 374 entity nightvision_noise, nightvision_noise2;
 375
 376 #define MAX_TIME_DIFF 5
 377 float pickup_crosshair_time, pickup_crosshair_size;
 378 float hitindication_crosshair_size;
 379 float use_vortex_chargepool;
 380
 381 float myhealth, myhealth_prev;
 382 float myhealth_flash;
 383
 384 float old_blurradius, old_bluralpha;
 385 float old_sharpen_intensity;
 386
 387 vector myhealth_gentlergb;
 388
 389 float contentavgalpha, liquidalpha_prev;
 390 vector liquidcolor_prev;
 391
 392 float eventchase_current_distance;
 393 float eventchase_running;
 394 float WantEventchase()
 395 {
 396         if(autocvar_cl_orthoview)
 397                 return FALSE;
 398         if(intermission)
 399                 return TRUE;
 400         if(spectatee_status >= 0)
 401         {
 402                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WepSet_FromWeapon(WEP_PORTO)))
 403                         return TRUE;
 404                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
 405                 {
 406                         if(autocvar_cl_eventchase_death == 2)
 407                         {
 408                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 409                                 if(self.velocity == '0 0 0' || eventchase_running)
 410                                         return TRUE;
 411                         }
 412                         else return TRUE;
 413                 }
 414         }
 415         return FALSE;
 416 }
 417
 418 vector damage_blurpostprocess, content_blurpostprocess;
 419
 420 float checkfail[16];
 421
 422 float unaccounted_damage = 0;
 423 void UpdateDamage()
 424 {
 425         // accumulate damage with each stat update
 426         static float damage_total_prev = 0;
 427         float damage_total = getstati(STAT_DAMAGE_DEALT_TOTAL);
 428         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 429         damage_total_prev = damage_total;
 430
 431         static float damage_dealt_time_prev = 0;
 432         float damage_dealt_time = getstatf(STAT_HIT_TIME);
 433         if (damage_dealt_time != damage_dealt_time_prev)
 434         {
 435                 unaccounted_damage += unaccounted_damage_new;
 436                 dprint("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 437         }
 438         damage_dealt_time_prev = damage_dealt_time;
 439
 440         // prevent hitsound when switching spectatee
 441         static float spectatee_status_prev = 0;
 442         if (spectatee_status != spectatee_status_prev)
 443                 unaccounted_damage = 0;
 444         spectatee_status_prev = spectatee_status;
 445 }
 446
 447 void UpdateHitsound()
 448 {
 449         // varying sound pitch
 450
 451         static float hitsound_time_prev = 0;
 452         if (COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 453         {
 454                 if (autocvar_cl_hitsound && unaccounted_damage)
 455                 {
 456                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 457                         float a = autocvar_cl_hitsound_max_pitch;
 458                         float b = autocvar_cl_hitsound_min_pitch;
 459                         float c = autocvar_cl_hitsound_nom_damage;
 460                         float x = unaccounted_damage;
 461                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 462
 463                         // if sound variation is disabled, set pitch_shift to 1
 464                         if (autocvar_cl_hitsound == 1)
 465                                 pitch_shift = 1;
 466
 467                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 468                         if (autocvar_cl_hitsound == 3)
 469                         {
 470                                 float mirror_value = (a-b)/2 + b;
 471                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 472                         }
 473
 474                         dprint("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 475
 476                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 477                         // todo: normalize sound pressure levels? seems unnecessary
 478
 479                         sound7(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 480                 }
 481                 unaccounted_damage = 0;
 482                 hitsound_time_prev = time;
 483         }
 484
 485         static float typehit_time_prev = 0;
 486         float typehit_time = getstatf(STAT_TYPEHIT_TIME);
 487         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 488         {
 489                 sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 490                 typehit_time_prev = typehit_time;
 491         }
 492 }
 493
 494 void UpdateCrosshair()
 495 {
 496         static float rainbow_last_flicker;
 497     static vector rainbow_prev_color;
 498         entity e = self;
 499         float f, i, j;
 500         vector v;
 501         if(getstati(STAT_FROZEN))
 502                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 503         else if (getstatf(STAT_HEALING_ORB)>time)
 504                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, Nade_Color(NADE_TYPE_HEAL), autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
 505         if(!intermission)
 506         if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
 507         {
 508                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 509                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 510         }
 511         else if(getstatf(STAT_REVIVE_PROGRESS))
 512         {
 513                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 514                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 515         }
 516
 517         if(autocvar_r_letterbox == 0)
 518                 if(autocvar_viewsize < 120)
 519                         CSQC_common_hud();
 520
 521         // crosshair goes VERY LAST
 522         if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
 523         {
 524                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 525                         return;
 526
 527                 string wcross_style;
 528                 float wcross_alpha, wcross_resolution;
 529                 wcross_style = autocvar_crosshair;
 530                 if (wcross_style == "0")
 531                         return;
 532                 wcross_resolution = autocvar_crosshair_size;
 533                 if (wcross_resolution == 0)
 534                         return;
 535                 wcross_alpha = autocvar_crosshair_alpha;
 536                 if (wcross_alpha == 0)
 537                         return;
 538
 539                 // TrueAim check
 540                 float shottype;
 541
 542                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 543                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 544                 wcross_origin_z = 0;
 545                 if(autocvar_crosshair_hittest)
 546                 {
 547                         vector wcross_oldorigin;
 548                         wcross_oldorigin = wcross_origin;
 549                         shottype = TrueAimCheck();
 550                         if(shottype == SHOTTYPE_HITWORLD)
 551                         {
 552                                 v = wcross_origin - wcross_oldorigin;
 553                                 v_x /= vid_conwidth;
 554                                 v_y /= vid_conheight;
 555                                 if(vlen(v) > 0.01)
 556                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 557                         }
 558                         if(!autocvar_crosshair_hittest_showimpact)
 559                                 wcross_origin = wcross_oldorigin;
 560                 }
 561                 else
 562                         shottype = SHOTTYPE_HITWORLD;
 563
 564                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 565                 string wcross_name = "";
 566                 float wcross_scale, wcross_blur;
 567
 568                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 569                 {
 570                         e = get_weaponinfo(switchingweapon);
 571                         if(e)
 572                         {
 573                                 if(autocvar_crosshair_per_weapon)
 574                                 {
 575                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 576                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 577                                         //if (wcross_resolution == 0)
 578                                                 //return;
 579
 580                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 581                                         wcross_resolution *= e.w_crosshair_size;
 582                                         wcross_name = e.w_crosshair;
 583                                 }
 584                         }
 585                 }
 586
 587                 if(wcross_name == "")
 588                         wcross_name = strcat("gfx/crosshair", wcross_style);
 589
 590                 // MAIN CROSSHAIR COLOR DECISION
 591                 switch(autocvar_crosshair_color_special)
 592                 {
 593                         case 1: // crosshair_color_per_weapon
 594                         {
 595                                 if(e)
 596                                 {
 597                                         wcross_color = e.wpcolor;
 598                                         break;
 599                                 }
 600                                 else { goto normalcolor; }
 601                         }
 602
 603                         case 2: // crosshair_color_by_health
 604                         {
 605                                 float x = getstati(STAT_HEALTH);
 606
 607                                 //x = red
 608                                 //y = green
 609                                 //z = blue
 610
 611                                 wcross_color_z = 0;
 612
 613                                 if(x > 200)
 614                                 {
 615                                         wcross_color_x = 0;
 616                                         wcross_color_y = 1;
 617                                 }
 618                                 else if(x > 150)
 619                                 {
 620                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
 621                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
 622                                 }
 623                                 else if(x > 100)
 624                                 {
 625                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
 626                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
 627                                         wcross_color_z = 1 - (x-100)*0.02;
 628                                 }
 629                                 else if(x > 50)
 630                                 {
 631                                         wcross_color_x = 1;
 632                                         wcross_color_y = 1;
 633                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
 634                                 }
 635                                 else if(x > 20)
 636                                 {
 637                                         wcross_color_x = 1;
 638                                         wcross_color_y = (x-20)*90/27/100;
 639                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
 640                                 }
 641                                 else
 642                                 {
 643                                         wcross_color_x = 1;
 644                                         wcross_color_y = 0;
 645                                 }
 646                                 break;
 647                         }
 648
 649                         case 3: // crosshair_color_rainbow
 650                         {
 651                                 if(time >= rainbow_last_flicker)
 652                                 {
 653                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 654                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 655                                 }
 656                                 wcross_color = rainbow_prev_color;
 657                                 break;
 658                         }
 659                         :normalcolor
 660                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
 661                 }
 662
 663                 if(autocvar_crosshair_effect_scalefade)
 664                 {
 665                         wcross_scale = wcross_resolution;
 666                         wcross_resolution = 1;
 667                 }
 668                 else
 669                 {
 670                         wcross_scale = 1;
 671                 }
 672
 673                 if(autocvar_crosshair_pickup)
 674                 {
 675                         float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
 676
 677                         if(pickup_crosshair_time < stat_pickup_time)
 678                         {
 679                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
 680                                         pickup_crosshair_size = 1;
 681
 682                                 pickup_crosshair_time = stat_pickup_time;
 683                         }
 684
 685                         if(pickup_crosshair_size > 0)
 686                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 687                         else
 688                                 pickup_crosshair_size = 0;
 689
 690                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 691                 }
 692
 693                 // todo: make crosshair hit indication dependent on damage dealt
 694                 if(autocvar_crosshair_hitindication)
 695                 {
 696                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
 697
 698                         if(unaccounted_damage)
 699                         {
 700                                 hitindication_crosshair_size = 1;
 701                         }
 702
 703                         if(hitindication_crosshair_size > 0)
 704                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
 705                         else
 706                                 hitindication_crosshair_size = 0;
 707
 708                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
 709                         wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
 710                         wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
 711                         wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
 712                 }
 713
 714                 if(shottype == SHOTTYPE_HITENEMY)
 715                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
 716                 if(shottype == SHOTTYPE_HITTEAM)
 717                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
 718
 719                 f = fabs(autocvar_crosshair_effect_time);
 720                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 721                 {
 722                         wcross_changedonetime = time + f;
 723                 }
 724                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 725                 {
 726                         wcross_name_changestarttime = time;
 727                         wcross_name_changedonetime = time + f;
 728                         if(wcross_name_goal_prev_prev)
 729                                 strunzone(wcross_name_goal_prev_prev);
 730                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 731                         wcross_name_goal_prev = strzone(wcross_name);
 732                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 733                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 734                         wcross_resolution_goal_prev = wcross_resolution;
 735                 }
 736
 737                 wcross_scale_goal_prev = wcross_scale;
 738                 wcross_alpha_goal_prev = wcross_alpha;
 739                 wcross_color_goal_prev = wcross_color;
 740
 741                 if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
 742                 {
 743                         wcross_blur = 1;
 744                         wcross_alpha *= 0.75;
 745                 }
 746                 else
 747                         wcross_blur = 0;
 748                 // *_prev is at time-frametime
 749                 // * is at wcross_changedonetime+f
 750                 // what do we have at time?
 751                 if(time < wcross_changedonetime)
 752                 {
 753                         f = frametime / (wcross_changedonetime - time + frametime);
 754                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 755                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 756                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 757                 }
 758
 759                 wcross_scale_prev = wcross_scale;
 760                 wcross_alpha_prev = wcross_alpha;
 761                 wcross_color_prev = wcross_color;
 762
 763                 wcross_scale *= 1 - autocvar__menu_alpha;
 764                 wcross_alpha *= 1 - autocvar__menu_alpha;
 765                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 766
 767                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
 768                 {
 769                         // crosshair rings for weapon stats
 770                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
 771                         {
 772                                 // declarations and stats
 773                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
 774                                 string ring_image = string_null, ring_inner_image = string_null;
 775                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
 776
 777                                 ring_scale = autocvar_crosshair_ring_size;
 778
 779                                 float weapon_clipload, weapon_clipsize;
 780                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
 781                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
 782
 783                                 float ok_ammo_charge, ok_ammo_chargepool;
 784                                 ok_ammo_charge = getstatf(STAT_OK_AMMO_CHARGE);
 785                                 ok_ammo_chargepool = getstatf(STAT_OK_AMMO_CHARGEPOOl);
 786
 787                                 float vortex_charge, vortex_chargepool;
 788                                 vortex_charge = getstatf(STAT_VORTEX_CHARGE);
 789                                 vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
 790
 791                                 float arc_heat = getstatf(STAT_ARC_HEAT);
 792
 793                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
 794                                         vortex_charge_movingavg = vortex_charge;
 795
 796
 797                                 // handle the values
 798                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
 799                                 {
 800                                         if (vortex_chargepool || use_vortex_chargepool) {
 801                                                 use_vortex_chargepool = 1;
 802                                                 ring_inner_value = vortex_chargepool;
 803                                         } else {
 804                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
 805                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
 806                                         }
 807
 808                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
 809                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
 810                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
 811
 812                                         // draw the outer ring to show the current charge of the weapon
 813                                         ring_value = vortex_charge;
 814                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
 815                                         ring_rgb = wcross_color;
 816                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
 817                                 }
 818                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
 819                                 {
 820                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
 821                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
 822                                         ring_rgb = wcross_color;
 823                                         ring_image = "gfx/crosshair_ring.tga";
 824                                 }
 825                                 else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
 826                                 {
 827                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
 828                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
 829                                         ring_rgb = wcross_color;
 830                                         ring_image = "gfx/crosshair_ring.tga";
 831                                 }
 832                                 else if (ok_ammo_charge)
 833                                 {
 834                                         ring_value = ok_ammo_chargepool;
 835                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 836                                         ring_rgb = wcross_color;
 837                                         ring_image = "gfx/crosshair_ring.tga";
 838                                 }
 839                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
 840                                 {
 841                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
 842                                         ring_scale = autocvar_crosshair_ring_reload_size;
 843                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 844                                         ring_rgb = wcross_color;
 845
 846                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
 847                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
 848                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
 849                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
 850                                         else
 851                                                 ring_image = "gfx/crosshair_ring.tga";
 852                                 }
 853                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
 854                                 {
 855                                         ring_value = arc_heat;
 856                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
 857                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
 858                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
 859                                         ring_image = "gfx/crosshair_ring.tga";
 860                                 }
 861
 862                                 // if in weapon switch animation, fade ring out/in
 863                                 if(autocvar_crosshair_effect_time > 0)
 864                                 {
 865                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
 866                                         if (!(f < 1))
 867                                         {
 868                                                 wcross_ring_prev = ((ring_image) ? TRUE : FALSE);
 869                                         }
 870
 871                                         if(wcross_ring_prev)
 872                                         {
 873                                                 if(f < 1)
 874                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
 875                                         }
 876                                         else
 877                                         {
 878                                                 if(f < 1)
 879                                                         ring_alpha *= bound(0, f, 1);
 880                                         }
 881                                 }
 882
 883                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
 884                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
 885
 886                                 if (ring_value)
 887                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
 888                         }
 889
 890 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 891                         do \
 892                         { \
 893                                 if(wcross_blur > 0) \
 894                                 { \
 895                                         for(i = -2; i <= 2; ++i) \
 896                                         for(j = -2; j <= 2; ++j) \
 897                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 898                                 } \
 899                                 else \
 900                                 { \
 901                                         M(0,0,sz,wcross_name,wcross_alpha); \
 902                                 } \
 903                         } \
 904                         while(0)
 905
 906 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 907                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 908
 909 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 910                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 911
 912                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 913                         {
 914                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 915                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 916                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 917                                 f = 1 - f;
 918                         }
 919                         else
 920                         {
 921                                 f = 1;
 922                         }
 923                         wcross_name_alpha_goal_prev = f;
 924
 925                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 926                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 927
 928                         if(autocvar_crosshair_dot)
 929                         {
 930                                 vector wcross_color_old;
 931                                 wcross_color_old = wcross_color;
 932
 933                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
 934                                         wcross_color = stov(autocvar_crosshair_dot_color);
 935
 936                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
 937                                 // FIXME why don't we use wcross_alpha here?cl_notice_run();
 938                                 wcross_color = wcross_color_old;
 939                         }
 940                 }
 941         }
 942         else
 943         {
 944                 wcross_scale_prev = 0;
 945                 wcross_alpha_prev = 0;
 946                 wcross_scale_goal_prev = 0;
 947                 wcross_alpha_goal_prev = 0;
 948                 wcross_changedonetime = 0;
 949                 if(wcross_name_goal_prev)
 950                         strunzone(wcross_name_goal_prev);
 951                 wcross_name_goal_prev = string_null;
 952                 if(wcross_name_goal_prev_prev)
 953                         strunzone(wcross_name_goal_prev_prev);
 954                 wcross_name_goal_prev_prev = string_null;
 955                 wcross_name_changestarttime = 0;
 956                 wcross_name_changedonetime = 0;
 957                 wcross_name_alpha_goal_prev = 0;
 958                 wcross_name_alpha_goal_prev_prev = 0;
 959                 wcross_resolution_goal_prev = 0;
 960                 wcross_resolution_goal_prev_prev = 0;
 961         }
 962 }
 963
 964 #define BUTTON_3 4
 965 #define BUTTON_4 8
 966 float cl_notice_run();
 967 float prev_myteam;
 968 void CSQC_UpdateView(float w, float h)
 969 {
 970         entity e;
 971         float fov;
 972         float f, i;
 973         vector vf_size, vf_min;
 974         float a;
 975
 976         execute_next_frame();
 977
 978         ++framecount;
 979
 980         hud = getstati(STAT_HUD);
 981
 982         if(autocvar__hud_showbinds_reload) // menu can set this one
 983         {
 984                 db_close(binddb);
 985                 binddb = db_create();
 986                 cvar_set("_hud_showbinds_reload", "0");
 987         }
 988
 989         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 990                 view_quality = getproperty(VF_MINFPS_QUALITY);
 991         else
 992                 view_quality = 1;
 993
 994         button_attack2 = (input_buttons & BUTTON_3);
 995         button_zoom = (input_buttons & BUTTON_4);
 996
 997 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 998         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 999         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
1000         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
1001         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
1002         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
1003         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
1004         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
1005
1006         vf_size = getpropertyvec(VF_SIZE);
1007         vf_min = getpropertyvec(VF_MIN);
1008         vid_width = vf_size_x;
1009         vid_height = vf_size_y;
1010
1011         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1012         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1013
1014         WaypointSprite_Load();
1015
1016         CSQCPlayer_SetCamera();
1017
1018 #ifdef COMPAT_XON050_ENGINE
1019         if(spectatee_status)
1020                 myteam = GetPlayerColor(spectatee_status - 1);
1021         else
1022 #endif
1023                 myteam = GetPlayerColor(player_localentnum - 1);
1024
1025         if(myteam != prev_myteam)
1026         {
1027                 myteamcolors = colormapPaletteColor(myteam, 1);
1028                 for(i = 0; i < HUD_PANEL_NUM; ++i)
1029                         hud_panel[i].update_time = time;
1030                 prev_myteam = myteam;
1031         }
1032
1033         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
1034
1035         float is_dead = (getstati(STAT_HEALTH) <= 0);
1036
1037         // FIXME do we need this hack?
1038         if(isdemo())
1039         {
1040                 // in demos, input_buttons do not work
1041                 button_zoom = (autocvar__togglezoom == "-");
1042         }
1043         else if(button_zoom
1044                 && autocvar_cl_unpress_zoom_on_death
1045                 && (spectatee_status >= 0)
1046                 && (is_dead || intermission))
1047         {
1048                 // no zoom while dead or in intermission please
1049                 localcmd("-zoom\n");
1050                 button_zoom = FALSE;
1051         }
1052
1053         // event chase camera
1054         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1055         {
1056                 if(WantEventchase())
1057                 {
1058                         eventchase_running = TRUE;
1059
1060                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1061                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1062
1063                         // detect maximum viewoffset and use it
1064                         if(autocvar_cl_eventchase_viewoffset)
1065                         {
1066                                 WarpZone_TraceLine(current_view_origin, current_view_origin + autocvar_cl_eventchase_viewoffset + ('0 0 1' * autocvar_cl_eventchase_maxs_z), MOVE_WORLDONLY, self);
1067                                 if(trace_fraction == 1) { current_view_origin += autocvar_cl_eventchase_viewoffset; }
1068                                 else { current_view_origin_z += max(0, (trace_endpos_z - current_view_origin_z) - autocvar_cl_eventchase_maxs_z); }
1069                         }
1070
1071                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1072                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1073                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1074                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1075
1076                         // make the camera smooth back
1077                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
1078                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1079                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
1080                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
1081
1082                         makevectors(view_angles);
1083
1084                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1085                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1086
1087                         // If the boxtrace fails, revert back to line tracing.
1088                         if(trace_startsolid)
1089                         {
1090                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1091                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1092                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins_z)));
1093                         }
1094                         else { setproperty(VF_ORIGIN, trace_endpos); }
1095
1096                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1097                 }
1098                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1099                 {
1100                         eventchase_running = FALSE;
1101                         cvar_set("chase_active", "0");
1102                         eventchase_current_distance = 0; // start from 0 next time
1103                 }
1104         }
1105         // workaround for camera stuck between player's legs when using chase_active 1
1106         // because the engine stops updating the chase_active camera when the game ends
1107         else if(intermission)
1108         {
1109                 cvar_settemp("chase_active", "-1");
1110                 eventchase_current_distance = 0;
1111         }
1112
1113         // do lockview after event chase camera so that it still applies whenever necessary.
1114         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
1115         {
1116                 setproperty(VF_ORIGIN, freeze_org);
1117                 setproperty(VF_ANGLES, freeze_ang);
1118         }
1119         else
1120         {
1121                 freeze_org = getpropertyvec(VF_ORIGIN);
1122                 freeze_ang = getpropertyvec(VF_ANGLES);
1123         }
1124
1125         WarpZone_FixView();
1126         //WarpZone_FixPMove();
1127
1128         vector ov_org = '0 0 0';
1129         vector ov_mid = '0 0 0';
1130         vector ov_worldmin = '0 0 0';
1131         vector ov_worldmax = '0 0 0';
1132         if(autocvar_cl_orthoview)
1133         {
1134                 ov_worldmin = mi_picmin;
1135                 ov_worldmax = mi_picmax;
1136
1137                 float ov_width = (ov_worldmax_x - ov_worldmin_x);
1138                 float ov_height = (ov_worldmax_y - ov_worldmin_y);
1139                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1140
1141                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1142                 ov_org = vec3(ov_mid_x, ov_mid_y, (ov_mid_z + ov_distance));
1143
1144                 float ov_nearest = vlen(ov_org - vec3(
1145                         bound(ov_worldmin_x, ov_org_x, ov_worldmax_x),
1146                         bound(ov_worldmin_y, ov_org_y, ov_worldmax_y),
1147                         bound(ov_worldmin_z, ov_org_z, ov_worldmax_z)
1148                 ));
1149
1150                 float ov_furthest = 0;
1151                 float dist = 0;
1152
1153                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmin_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1154                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmin_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1155                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmax_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1156                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmin_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1157                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmax_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1158                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmax_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1159                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmin_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1160                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmax_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1161
1162                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1163                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1164                 cvar_settemp("r_farclip_world", "0");
1165                 cvar_settemp("r_novis", "1");
1166                 cvar_settemp("r_useportalculling", "0");
1167                 cvar_settemp("r_useinfinitefarclip", "0");
1168
1169                 setproperty(VF_ORIGIN, ov_org);
1170                 setproperty(VF_ANGLES, '90 0 0');
1171
1172                 #if 0
1173                 printf("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1174                         vtos(ov_org),
1175                         vtos(getpropertyvec(VF_ANGLES)),
1176                         ov_distance,
1177                         ov_nearest,
1178                         ov_furthest);
1179                 #endif
1180         }
1181
1182         // Render the Scene
1183         view_origin = getpropertyvec(VF_ORIGIN);
1184         view_angles = getpropertyvec(VF_ANGLES);
1185         makevectors(view_angles);
1186         view_forward = v_forward;
1187         view_right = v_right;
1188         view_up = v_up;
1189
1190 #ifdef BLURTEST
1191         if(time > blurtest_time0 && time < blurtest_time1)
1192         {
1193                 float r, t;
1194
1195                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1196                 r = t * blurtest_radius;
1197                 f = 1 / pow(t, blurtest_power) - 1;
1198
1199                 cvar_set("r_glsl_postprocess", "1");
1200                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1201         }
1202         else
1203         {
1204                 cvar_set("r_glsl_postprocess", "0");
1205                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1206         }
1207 #endif
1208
1209         TargetMusic_Advance();
1210         Fog_Force();
1211
1212         if(drawtime == 0)
1213                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1214         else
1215                 drawframetime = bound(0.000001, time - drawtime, 1);
1216         drawtime = time;
1217
1218         // watch for gametype changes here...
1219         // in ParseStuffCMD the cmd isn't executed yet :/
1220         // might even be better to add the gametype to TE_CSQC_INIT...?
1221         if(!postinit)
1222                 PostInit();
1223
1224         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1225         {
1226                 if(calledhooks & HOOK_START)
1227                 {
1228                         localcmd("\ncl_hook_gameend\n");
1229                         calledhooks |= HOOK_END;
1230                 }
1231         }
1232
1233         Announcer();
1234
1235         fov = autocvar_fov;
1236         if(fov <= 59.5)
1237         {
1238                 if(!zoomscript_caught)
1239                 {
1240                         localcmd("+button9\n");
1241                         zoomscript_caught = 1;
1242                 }
1243         }
1244         else
1245         {
1246                 if(zoomscript_caught)
1247                 {
1248                         localcmd("-button9\n");
1249                         zoomscript_caught = 0;
1250                 }
1251         }
1252
1253         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1254
1255         // next WANTED weapon (for HUD)
1256         switchweapon = getstati(STAT_SWITCHWEAPON);
1257
1258         // currently switching-to weapon (for crosshair)
1259         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
1260
1261         // actually active weapon (for zoom)
1262         activeweapon = getstati(STAT_ACTIVEWEAPON);
1263
1264         f = (serverflags & SERVERFLAG_TEAMPLAY);
1265         if(f != teamplay)
1266         {
1267                 teamplay = f;
1268                 HUD_InitScores();
1269         }
1270
1271         if(last_switchweapon != switchweapon)
1272         {
1273                 weapontime = time;
1274                 last_switchweapon = switchweapon;
1275                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1276                 {
1277                         localcmd("-zoom\n");
1278                         button_zoom = FALSE;
1279                 }
1280                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1281                 {
1282                         localcmd("-fire\n");
1283                         localcmd("-fire2\n");
1284                         button_attack2 = FALSE;
1285                 }
1286         }
1287         if(last_activeweapon != activeweapon)
1288         {
1289                 last_activeweapon = activeweapon;
1290
1291                 e = get_weaponinfo(activeweapon);
1292                 if(e.netname != "")
1293                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1294                 else
1295                         localcmd("\ncl_hook_activeweapon none\n");
1296         }
1297
1298         // ALWAYS Clear Current Scene First
1299         clearscene();
1300 #ifdef WORKAROUND_XON010
1301         if(checkextension("DP_CSQC_ROTATEMOVES"))
1302         {
1303 #endif
1304         setproperty(VF_ORIGIN, view_origin);
1305         setproperty(VF_ANGLES, view_angles);
1306 #ifdef WORKAROUND_XON010
1307         }
1308 #endif
1309
1310         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1311         setproperty(VF_SIZE, vf_size);
1312         setproperty(VF_MIN, vf_min);
1313
1314         // Assign Standard Viewflags
1315         // Draw the World (and sky)
1316         setproperty(VF_DRAWWORLD, 1);
1317
1318         // Set the console size vars
1319         vid_conwidth = autocvar_vid_conwidth;
1320         vid_conheight = autocvar_vid_conheight;
1321         vid_pixelheight = autocvar_vid_pixelheight;
1322
1323         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1324         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1325
1326         // Camera for demo playback
1327         if(camera_active)
1328         {
1329                 if(autocvar_camera_enable)
1330                         CSQC_Demo_Camera();
1331                 else
1332                 {
1333                         cvar_set("chase_active", ftos(chase_active_backup));
1334                         cvar_set("cl_demo_mousegrab", "0");
1335                         camera_active = FALSE;
1336                 }
1337         }
1338 #ifdef CAMERATEST
1339         else if(autocvar_camera_enable)
1340 #else
1341         else if(autocvar_camera_enable && isdemo())
1342 #endif
1343         {
1344                 // Enable required Darkplaces cvars
1345                 chase_active_backup = autocvar_chase_active;
1346                 cvar_set("chase_active", "2");
1347                 cvar_set("cl_demo_mousegrab", "1");
1348                 camera_active = TRUE;
1349                 camera_mode = FALSE;
1350         }
1351
1352         // Draw the Crosshair
1353         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1354
1355         // Draw the Engine Status Bar (the default Quake HUD)
1356         setproperty(VF_DRAWENGINESBAR, 0);
1357
1358         // Update the mouse position
1359         /*
1360            mousepos_x = vid_conwidth;
1361            mousepos_y = vid_conheight;
1362            mousepos = mousepos*0.5 + getmousepos();
1363          */
1364
1365         e = self;
1366         for(self = world; (self = nextent(self)); )
1367                 if(self.draw)
1368                         self.draw();
1369         self = e;
1370
1371         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1372         renderscene();
1373
1374         // now switch to 2D drawing mode by calling a 2D drawing function
1375         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1376         // next R_RenderScene call
1377         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1378
1379         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1380         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1381         {
1382                 // apply night vision effect
1383                 vector tc_00, tc_01, tc_10, tc_11;
1384                 vector rgb = '0 0 0';
1385
1386                 if(!nightvision_noise)
1387                 {
1388                         nightvision_noise = spawn();
1389                         nightvision_noise.classname = "nightvision_noise";
1390                 }
1391                 if(!nightvision_noise2)
1392                 {
1393                         nightvision_noise2 = spawn();
1394                         nightvision_noise2.classname = "nightvision_noise2";
1395                 }
1396
1397                 // color tint in yellow
1398                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1399
1400                 // draw BG
1401                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1402                 rgb = '1 1 1';
1403                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1404                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1405                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1406                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1407                 tc_11 = tc_01 + tc_10 - tc_00;
1408                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1409                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1410                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1411                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1412                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1413                 R_EndPolygon();
1414
1415                 // draw FG
1416                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1417                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1418                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1419                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1420                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1421                 tc_11 = tc_01 + tc_10 - tc_00;
1422                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1423                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1424                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1425                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1426                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1427                 R_EndPolygon();
1428         }
1429
1430         if(autocvar_cl_reticle)
1431         {
1432                 // Draw the aiming reticle for weapons that use it
1433                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1434                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1435                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1436                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1437                 {
1438                         // no zoom reticle while dead
1439                         reticle_type = 0;
1440                 }
1441                 else if(WEP_ACTION(activeweapon, WR_ZOOMRETICLE) && autocvar_cl_reticle_weapon)
1442                 {
1443                         if(reticle_image != "") { reticle_type = 2; }
1444                         else { reticle_type = 0; }
1445                 }
1446                 else if(button_zoom || zoomscript_caught)
1447                 {
1448                         // normal zoom
1449                         reticle_type = 1;
1450                 }
1451
1452                 if(reticle_type)
1453                 {
1454                         if(autocvar_cl_reticle_stretch)
1455                         {
1456                                 reticle_size_x = vid_conwidth;
1457                                 reticle_size_y = vid_conheight;
1458                                 reticle_pos_x = 0;
1459                                 reticle_pos_y = 0;
1460                         }
1461                         else
1462                         {
1463                                 reticle_size_x = max(vid_conwidth, vid_conheight);
1464                                 reticle_size_y = max(vid_conwidth, vid_conheight);
1465                                 reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
1466                                 reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
1467                         }
1468
1469                         if(zoomscript_caught)
1470                                 f = 1;
1471                         else
1472                                 f = current_zoomfraction;
1473
1474                         if(f)
1475                         {
1476                                 switch(reticle_type)
1477                                 {
1478                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1479                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1480                                 }
1481                         }
1482                 }
1483         }
1484         else
1485         {
1486                 if(reticle_type != 0) { reticle_type = 0; }
1487         }
1488
1489
1490         // improved polyblend
1491         if(autocvar_hud_contents)
1492         {
1493                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1494                 vector liquidcolor;
1495
1496                 switch(pointcontents(view_origin))
1497                 {
1498                         case CONTENT_WATER:
1499                                 liquidalpha = autocvar_hud_contents_water_alpha;
1500                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1501                                 incontent = 1;
1502                                 break;
1503
1504                         case CONTENT_LAVA:
1505                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1506                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1507                                 incontent = 1;
1508                                 break;
1509
1510                         case CONTENT_SLIME:
1511                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1512                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1513                                 incontent = 1;
1514                                 break;
1515
1516                         default:
1517                                 liquidalpha = 0;
1518                                 liquidcolor = '0 0 0';
1519                                 incontent = 0;
1520                                 break;
1521                 }
1522
1523                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1524                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1525                         contentfadetime = autocvar_hud_contents_fadeintime;
1526                         liquidalpha_prev = liquidalpha;
1527                         liquidcolor_prev = liquidcolor;
1528                 }
1529                 else
1530                         contentfadetime = autocvar_hud_contents_fadeouttime;
1531
1532                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1533                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1534
1535                 if(contentavgalpha)
1536                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1537
1538                 if(autocvar_hud_postprocessing)
1539                 {
1540                         if(autocvar_hud_contents_blur && contentavgalpha)
1541                         {
1542                                 content_blurpostprocess_x = 1;
1543                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
1544                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1545                         }
1546                         else
1547                         {
1548                                 content_blurpostprocess_x = 0;
1549                                 content_blurpostprocess_y = 0;
1550                                 content_blurpostprocess_z = 0;
1551                         }
1552                 }
1553         }
1554
1555         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
1556         {
1557                 splash_size_x = max(vid_conwidth, vid_conheight);
1558                 splash_size_y = max(vid_conwidth, vid_conheight);
1559                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
1560                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
1561
1562                 float myhealth_flash_temp;
1563                 myhealth = getstati(STAT_HEALTH);
1564
1565                 // fade out
1566                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1567                 // add new damage
1568                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1569
1570                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1571                 pain_threshold = autocvar_hud_damage_pain_threshold;
1572                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1573                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1574
1575                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1576                 {
1577                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1578                 }
1579
1580                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1581
1582                 if(myhealth_prev < 1)
1583                 {
1584                         if(myhealth >= 1)
1585                         {
1586                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1587                                 myhealth_flash_temp = 0;
1588                         }
1589                         else
1590                         {
1591                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1592                         }
1593                 }
1594
1595                 if(spectatee_status == -1 || intermission)
1596                 {
1597                         myhealth_flash = 0; // observing, or match ended
1598                         myhealth_flash_temp = 0;
1599                 }
1600
1601                 myhealth_prev = myhealth;
1602
1603                 // IDEA: change damage color/picture based on player model for robot/alien species?
1604                 // pro: matches model better
1605                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1606                 // maybe different reddish pics?
1607                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1608                 {
1609                         if(autocvar_cl_gentle_damage == 2)
1610                         {
1611                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1612                                 {
1613                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1614                                 }
1615                         }
1616                         else
1617                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1618
1619                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1620                 }
1621                 else
1622                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1623
1624                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1625                 {
1626                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1627                         {
1628                                 damage_blurpostprocess_x = 1;
1629                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1630                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1631                         }
1632                         else
1633                         {
1634                                 damage_blurpostprocess_x = 0;
1635                                 damage_blurpostprocess_y = 0;
1636                                 damage_blurpostprocess_z = 0;
1637                         }
1638                 }
1639         }
1640
1641         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1642         float e2 = (autocvar_hud_powerup != 0);
1643         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1644         {
1645                 // enable or disable rendering types if they are used or not
1646                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1647                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1648
1649                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1650                 if((damage_blurpostprocess_x || content_blurpostprocess_x))
1651                 {
1652                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
1653                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
1654                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1655                         {
1656                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1657                                 old_blurradius = blurradius;
1658                                 old_bluralpha = bluralpha;
1659                         }
1660                 }
1661                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1662                 {
1663                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1664                         old_blurradius = 0;
1665                         old_bluralpha = 0;
1666                 }
1667
1668                 // edge detection postprocess handling done second (used by hud_powerup)
1669                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1670                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1671                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1672
1673                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1674
1675                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1676                 {
1677                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1678                         {
1679                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1680                                 old_sharpen_intensity = sharpen_intensity;
1681                         }
1682                 }
1683                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1684                 {
1685                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1686                         old_sharpen_intensity = 0;
1687                 }
1688
1689                 if(cvar("r_glsl_postprocess") == 0)
1690                         cvar_set("r_glsl_postprocess", "2");
1691         }
1692         else if(cvar("r_glsl_postprocess") == 2)
1693                 cvar_set("r_glsl_postprocess", "0");
1694
1695         if(menu_visible)
1696                 menu_show();
1697
1698         /*if(gametype == MAPINFO_TYPE_CTF)
1699           {
1700           ctf_view();
1701           } else */
1702
1703         // draw 2D entities
1704         e = self;
1705         for(self = world; (self = nextent(self)); )
1706                 if(self.draw2d)
1707                         self.draw2d();
1708         self = e;
1709         Draw_ShowNames_All();
1710
1711         scoreboard_active = HUD_WouldDrawScoreboard();
1712
1713         UpdateDamage();
1714         UpdateHitsound();
1715         UpdateCrosshair();
1716
1717         if(NextFrameCommand)
1718         {
1719                 localcmd("\n", NextFrameCommand, "\n");
1720                 NextFrameCommand = string_null;
1721         }
1722
1723         // we must do this check AFTER a frame was rendered, or it won't work
1724         if(cs_project_is_b0rked == 0)
1725         {
1726                 string w0, h0;
1727                 w0 = ftos(autocvar_vid_conwidth);
1728                 h0 = ftos(autocvar_vid_conheight);
1729                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1730                 //setproperty(VF_FOV, '90 90 0');
1731                 setproperty(VF_ORIGIN, '0 0 0');
1732                 setproperty(VF_ANGLES, '0 0 0');
1733                 setproperty(VF_PERSPECTIVE, 1);
1734                 makevectors('0 0 0');
1735                 vector v1, v2;
1736                 cvar_set("vid_conwidth", "800");
1737                 cvar_set("vid_conheight", "600");
1738                 v1 = cs_project(v_forward);
1739                 cvar_set("vid_conwidth", "640");
1740                 cvar_set("vid_conheight", "480");
1741                 v2 = cs_project(v_forward);
1742                 if(v1 == v2)
1743                         cs_project_is_b0rked = 1;
1744                 else
1745                         cs_project_is_b0rked = -1;
1746                 cvar_set("vid_conwidth", w0);
1747                 cvar_set("vid_conheight", h0);
1748         }
1749
1750         if(autocvar__hud_configure)
1751                 HUD_Panel_Mouse();
1752
1753     if(hud && !intermission)
1754     {
1755         if(hud == HUD_SPIDERBOT)
1756             CSQC_SPIDER_HUD();
1757         else if(hud == HUD_WAKIZASHI)
1758             CSQC_WAKIZASHI_HUD();
1759         else if(hud == HUD_RAPTOR)
1760             CSQC_RAPTOR_HUD();
1761         else if(hud == HUD_BUMBLEBEE)
1762             CSQC_BUMBLE_HUD();
1763         else if(hud == HUD_BUMBLEBEE_GUN)
1764             CSQC_BUMBLE_GUN_HUD();
1765     }
1766
1767         cl_notice_run();
1768
1769         // let's reset the view back to normal for the end
1770         setproperty(VF_MIN, '0 0 0');
1771         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1772 }
1773
1774
1775 void CSQC_common_hud(void)
1776 {
1777         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1778                 Accuracy_LoadLevels();
1779
1780         HUD_Main(); // always run these functions for alpha checks
1781         HUD_DrawScoreboard();
1782
1783         if (scoreboard_active) // scoreboard/accuracy
1784                 HUD_Reset();
1785         else if (intermission == 2) // map voting screen
1786         {
1787                 MapVote_Draw();
1788                 HUD_Reset();
1789         }
1790 }
1791
1792
1793 // following vectors must be global to allow seamless switching between camera modes
1794 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1795 void CSQC_Demo_Camera()
1796 {
1797         float speed, attenuation, dimensions;
1798         vector tmp, delta;
1799
1800         if( autocvar_camera_reset || !camera_mode )
1801         {
1802                 camera_offset = '0 0 0';
1803                 current_angles = '0 0 0';
1804                 camera_direction = '0 0 0';
1805                 camera_offset_z += 30;
1806                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1807                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1808                 current_origin = view_origin;
1809                 current_camera_offset  = camera_offset;
1810                 cvar_set("camera_reset", "0");
1811                 camera_mode = CAMERA_CHASE;
1812         }
1813
1814         // Camera angles
1815         if( camera_roll )
1816                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1817
1818         if(autocvar_camera_look_player)
1819         {
1820                 vector dir;
1821                 float n;
1822
1823                 dir = normalize(view_origin - current_position);
1824                 n = mouse_angles_z;
1825                 mouse_angles = vectoangles(dir);
1826                 mouse_angles_x = mouse_angles_x * -1;
1827                 mouse_angles_z = n;
1828         }
1829         else
1830         {
1831                 tmp = getmousepos() * 0.1;
1832                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1833                 {
1834                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1835                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1836                 }
1837         }
1838
1839         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1840         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1841         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1842         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1843
1844         // Fix difference when angles don't have the same sign
1845         delta = '0 0 0';
1846         if(mouse_angles_y < -60 && current_angles_y > 60)
1847                 delta = '0 360 0';
1848         if(mouse_angles_y > 60 && current_angles_y < -60)
1849                 delta = '0 -360 0';
1850
1851         if(autocvar_camera_look_player)
1852                 attenuation = autocvar_camera_look_attenuation;
1853         else
1854                 attenuation = autocvar_camera_speed_attenuation;
1855
1856         attenuation = 1 / max(1, attenuation);
1857         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1858
1859         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1860         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1861         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1862         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1863
1864         // Camera position
1865         tmp = '0 0 0';
1866         dimensions = 0;
1867
1868         if( camera_direction_x )
1869         {
1870                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1871                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1872                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1873                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1874                 ++dimensions;
1875         }
1876
1877         if( camera_direction_y )
1878         {
1879                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1880                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1881                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1882                 ++dimensions;
1883         }
1884
1885         if( camera_direction_z )
1886         {
1887                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1888                 ++dimensions;
1889         }
1890
1891         if(autocvar_camera_free)
1892                 speed = autocvar_camera_speed_free;
1893         else
1894                 speed = autocvar_camera_speed_chase;
1895
1896         if(dimensions)
1897         {
1898                 speed = speed * sqrt(1 / dimensions);
1899                 camera_offset += tmp * speed;
1900         }
1901
1902         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1903
1904         // Camera modes
1905         if( autocvar_camera_free )
1906         {
1907                 if ( camera_mode == CAMERA_CHASE )
1908                 {
1909                         current_camera_offset = current_origin + current_camera_offset;
1910                         camera_offset = current_origin + camera_offset;
1911                 }
1912
1913                 camera_mode = CAMERA_FREE;
1914                 current_position = current_camera_offset;
1915         }
1916         else
1917         {
1918                 if ( camera_mode == CAMERA_FREE )
1919                 {
1920                         current_origin = view_origin;
1921                         camera_offset = camera_offset - current_origin;
1922                         current_camera_offset = current_camera_offset - current_origin;
1923                 }
1924
1925                 camera_mode = CAMERA_CHASE;
1926
1927                 if(autocvar_camera_chase_smoothly)
1928                         current_origin += (view_origin - current_origin) * attenuation;
1929                 else
1930                         current_origin = view_origin;
1931
1932                 current_position = current_origin + current_camera_offset;
1933         }
1934
1935         setproperty(VF_ANGLES, current_angles);
1936         setproperty(VF_ORIGIN, current_position);
1937 }