qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  14                 return;
  15         if(g_balance_porto_secondary)
  16                 return;
  17         if(intermission == 1)
  18                 return;
  19         if(intermission == 2)
  20                 return;
  21         if (getstati(STAT_HEALTH) <= 0)
  22                 return;
  23
  24         dir = view_forward;
  25
  26         if(angles_held_status)
  27         {
  28                 makevectors(angles_held);
  29                 dir = v_forward;
  30         }
  31
  32         p = view_origin;
  33
  34         polyline[0] = p;
  35         idx = 1;
  36         portal_number = 0;
  37         nextdir = dir;
  38
  39         for(;;)
  40         {
  41                 dir = nextdir;
  42                 traceline(p, p + 65536 * dir, TRUE, porto);
  43                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  44                         return;
  45                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  46                 p = trace_endpos;
  47                 polyline[idx] = p;
  48                 ++idx;
  49                 if(idx >= 16)
  50                         return;
  51                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  52                         continue;
  53                 ++portal_number;
  54                 ang = vectoangles2(trace_plane_normal, dir);
  55                 ang_x = -ang_x;
  56                 makevectors(ang);
  57                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  58                         return;
  59                 if(portal_number == 1)
  60                 {
  61                         portal1_idx = idx;
  62                         if(portal_number >= 2)
  63                                 break;
  64                 }
  65         }
  66
  67         while(idx >= 2)
  68         {
  69                 p = polyline[idx-2];
  70                 q = polyline[idx-1];
  71                 if(idx == 2)
  72                         p = p - view_up * 16;
  73                 if(idx-1 >= portal1_idx)
  74                 {
  75                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  76                 }
  77                 else
  78                 {
  79                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  80                 }
  81                 --idx;
  82         }
  83 }
  84
  85 void Porto_Init()
  86 {
  87         porto = spawn();
  88         porto.classname = "porto";
  89         porto.draw = Porto_Draw;
  90         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  91 }
  92
  93 float drawtime;
  94 float avgspeed;
  95 vector GetCurrentFov(float fov)
  96 {
  97         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  98         float velocityzoom, curspeed;
  99         vector v;
 100
 101         zoomsensitivity = autocvar_cl_zoomsensitivity;
 102         zoomfactor = autocvar_cl_zoomfactor;
 103         if(zoomfactor < 1 || zoomfactor > 16)
 104                 zoomfactor = 2.5;
 105         zoomspeed = autocvar_cl_zoomspeed;
 106         if(zoomspeed >= 0)
 107                 if(zoomspeed < 0.5 || zoomspeed > 16)
 108                         zoomspeed = 3.5;
 109
 110         zoomdir = button_zoom;
 111         if(hud == HUD_NORMAL)
 112         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 113                 zoomdir += button_attack2;
 114         if(spectatee_status > 0 || isdemo())
 115         {
 116                 if(spectatorbutton_zoom)
 117                 {
 118                         if(zoomdir)
 119                                 zoomdir = 0;
 120                         else
 121                                 zoomdir = 1;
 122                 }
 123                 // fteqcc failed twice here already, don't optimize this
 124         }
 125
 126         if(zoomdir)
 127                 zoomin_effect = 0;
 128
 129         if(zoomin_effect || camera_active)
 130         {
 131                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 132         }
 133         else
 134         {
 135                 if(zoomspeed < 0) // instant zoom
 136                 {
 137                         if(zoomdir)
 138                                 current_viewzoom = 1 / zoomfactor;
 139                         else
 140                                 current_viewzoom = 1;
 141                 }
 142                 else
 143                 {
 144                         if(zoomdir)
 145                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 146                         else
 147                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 148                 }
 149         }
 150
 151         if(almost_equals(current_viewzoom, 1))
 152                 current_zoomfraction = 0;
 153         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 154                 current_zoomfraction = 1;
 155         else
 156                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 157
 158         if(zoomsensitivity < 1)
 159                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 160         else
 161                 setsensitivityscale(1);
 162
 163         makevectors(view_angles);
 164
 165         if(autocvar_cl_velocityzoom && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 166         {
 167                 v = pmove_vel;
 168                 if(csqcplayer)
 169                         v = csqcplayer.velocity;
 170
 171                 switch(autocvar_cl_velocityzoom_type)
 172                 {
 173                         case 3: curspeed = max(0, v_forward * v); break;
 174                         case 2: curspeed = (v_forward * v); break;
 175                         case 1: default: curspeed = vlen(v); break;
 176                 }
 177
 178                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 179                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 180                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 181
 182                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 183         }
 184         else
 185                 velocityzoom = 1;
 186
 187         float frustumx, frustumy, fovx, fovy;
 188         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 189         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 190         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 191         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 192
 193         return '1 0 0' * fovx + '0 1 0' * fovy;
 194 }
 195
 196 // this function must match W_SetupShot!
 197 float zoomscript_caught;
 198
 199 vector wcross_origin;
 200 float wcross_scale_prev, wcross_alpha_prev;
 201 vector wcross_color_prev;
 202 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 203 vector wcross_color_goal_prev;
 204 float wcross_changedonetime;
 205
 206 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 207 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 208 float wcross_name_changestarttime, wcross_name_changedonetime;
 209 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 210 entity trueaim;
 211 entity trueaim_rifle;
 212
 213 #define SHOTTYPE_HITTEAM 1
 214 #define SHOTTYPE_HITOBSTRUCTION 2
 215 #define SHOTTYPE_HITWORLD 3
 216 #define SHOTTYPE_HITENEMY 4
 217
 218 void TrueAim_Init()
 219 {
 220         trueaim = spawn();
 221         trueaim.classname = "trueaim";
 222         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 223         trueaim_rifle = spawn();
 224         trueaim_rifle.classname = "trueaim_rifle";
 225         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 226 }
 227
 228 float EnemyHitCheck()
 229 {
 230         float t, n;
 231         wcross_origin = project_3d_to_2d(trace_endpos);
 232         wcross_origin_z = 0;
 233         if(trace_ent)
 234                 n = trace_ent.entnum;
 235         else
 236                 n = trace_networkentity;
 237         if(n < 1)
 238                 return SHOTTYPE_HITWORLD;
 239         if(n > maxclients)
 240                 return SHOTTYPE_HITWORLD;
 241         t = GetPlayerColor(n - 1);
 242         if(teamplay)
 243                 if(t == myteam)
 244                         return SHOTTYPE_HITTEAM;
 245         if(t == FL_SPECTATOR)
 246                 return SHOTTYPE_HITWORLD;
 247         return SHOTTYPE_HITENEMY;
 248 }
 249
 250 float TrueAimCheck()
 251 {
 252         float nudge = 1; // added to traceline target and subtracted from result
 253         vector vecs, trueaimpoint, w_shotorg;
 254         vector mi, ma, dv;
 255         float shottype;
 256         entity ta;
 257         float mv;
 258
 259         mi = ma = '0 0 0';
 260         ta = trueaim;
 261         mv = MOVE_NOMONSTERS;
 262
 263         switch(activeweapon)
 264         {
 265                 case WEP_TUBA: // no aim
 266                 case WEP_PORTO: // shoots from eye
 267                 case WEP_HOOK: // no trueaim
 268                 case WEP_GRENADE_LAUNCHER: // toss curve
 269                         return SHOTTYPE_HITWORLD;
 270                 case WEP_NEX:
 271                 case WEP_MINSTANEX:
 272                         mv = MOVE_NORMAL;
 273                         break;
 274                 case WEP_RIFLE:
 275                         ta = trueaim_rifle;
 276                         mv = MOVE_NORMAL;
 277                         if(zoomscript_caught)
 278                         {
 279                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 280                                 return EnemyHitCheck();
 281                         }
 282                         break;
 283                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 284                         mi = '-3 -3 -3';
 285                         ma = '3 3 3';
 286                         break;
 287                 case WEP_FIREBALL: // projectile has a size!
 288                         mi = '-16 -16 -16';
 289                         ma = '16 16 16';
 290                         break;
 291                 case WEP_SEEKER: // projectile has a size!
 292                         mi = '-2 -2 -2';
 293                         ma = '2 2 2';
 294                         break;
 295                 case WEP_ELECTRO: // projectile has a size!
 296                         mi = '0 0 -3';
 297                         ma = '0 0 -3';
 298                         break;
 299         }
 300
 301         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 302
 303         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 304         trueaimpoint = trace_endpos;
 305
 306         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 307                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 308
 309         if(vecs_x > 0)
 310                 vecs_y = -vecs_y;
 311         else
 312                 vecs = '0 0 0';
 313
 314         dv = view_right * vecs_y + view_up * vecs_z;
 315         w_shotorg = view_origin + dv;
 316
 317         // now move the vecs forward as much as requested if possible
 318         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 319         w_shotorg = trace_endpos - view_forward * nudge;
 320
 321         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 322         shottype = EnemyHitCheck();
 323         if(shottype != SHOTTYPE_HITWORLD)
 324                 return shottype;
 325
 326 #if 0
 327         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 328         // or rather, I know why, but see no fix
 329         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 330                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 331                 return SHOTTYPE_HITOBSTRUCTION;
 332 #endif
 333
 334         return SHOTTYPE_HITWORLD;
 335 }
 336
 337 void CSQC_common_hud(void);
 338
 339 void PostInit(void);
 340 void CSQC_Demo_Camera();
 341 float HUD_WouldDrawScoreboard();
 342 float camera_mode;
 343 float CAMERA_FREE = 1;
 344 float CAMERA_CHASE = 2;
 345 float reticle_type;
 346 string NextFrameCommand;
 347 void CSQC_SPIDER_HUD();
 348 void CSQC_RAPTOR_HUD();
 349
 350 vector freeze_org, freeze_ang;
 351 entity nightvision_noise, nightvision_noise2;
 352
 353 #define MAX_TIME_DIFF 5
 354 float pickup_crosshair_time, pickup_crosshair_size;
 355 float hit_time, typehit_time;
 356 float nextsound_hit_time, nextsound_typehit_time;
 357 float hitindication_crosshair_time, hitindication_crosshair_size;
 358 float use_nex_chargepool;
 359
 360 float myhealth, myhealth_prev;
 361 float myhealth_flash;
 362
 363 float old_blurradius, old_bluralpha;
 364 float old_sharpen_intensity;
 365
 366 vector myhealth_gentlergb;
 367
 368 float contentavgalpha, liquidalpha_prev;
 369 vector liquidcolor_prev;
 370
 371 float eventchase_current_distance;
 372
 373 vector damage_blurpostprocess, content_blurpostprocess;
 374
 375 float checkfail[16];
 376
 377 #define BUTTON_3 4
 378 #define BUTTON_4 8
 379 float cl_notice_run();
 380 void CSQC_UpdateView(float w, float h)
 381 {
 382         entity e;
 383         float fov;
 384         float f, i, j;
 385         vector v;
 386         vector vf_size, vf_min;
 387         float a;
 388
 389         execute_next_frame();
 390
 391         ++framecount;
 392
 393         hud = getstati(STAT_HUD);
 394
 395         if(autocvar__hud_showbinds_reload) // menu can set this one
 396         {
 397                 db_close(binddb);
 398                 binddb = db_create();
 399                 cvar_set("_hud_showbinds_reload", "0");
 400         }
 401
 402         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 403                 view_quality = getproperty(VF_MINFPS_QUALITY);
 404         else
 405                 view_quality = 1;
 406
 407         button_attack2 = (input_buttons & BUTTON_3);
 408         button_zoom = (input_buttons & BUTTON_4);
 409
 410         // FIXME do we need this hack?
 411         if(isdemo())
 412         {
 413                 // in demos, input_buttons do not work
 414                 button_zoom = (autocvar__togglezoom == "-");
 415         }
 416
 417 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 418         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 419         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 420         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 421         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 422         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 423         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 424         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 425
 426         vf_size = getpropertyvec(VF_SIZE);
 427         vf_min = getpropertyvec(VF_MIN);
 428         vid_width = vf_size_x;
 429         vid_height = vf_size_y;
 430
 431         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 432         vector splash_pos = '0 0 0', splash_size = '0 0 0';
 433
 434         WaypointSprite_Load();
 435
 436         CSQCPlayer_SetCamera();
 437
 438 #ifdef COMPAT_XON050_ENGINE
 439         if(spectatee_status)
 440                 myteam = GetPlayerColor(spectatee_status - 1);
 441         else
 442 #endif
 443                 myteam = GetPlayerColor(player_localentnum - 1);
 444
 445         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 446
 447         // event chase camera
 448         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 449         {
 450                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 451                 {
 452                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 453                         vector current_view_origin = ((csqcplayer ? csqcplayer.origin : pmove_org) + autocvar_cl_eventchase_viewoffset);
 454
 455                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 456                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 457                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 458                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 459
 460                         // make the camera smooth back
 461                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 462                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 463                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 464                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 465
 466                         makevectors(view_angles);
 467
 468                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 469                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
 470
 471                         // If the boxtrace fails, revert back to line tracing.
 472                         if(trace_startsolid)
 473                         {
 474                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 475                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 476                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins_z)));
 477                         }
 478                         else { setproperty(VF_ORIGIN, trace_endpos); }
 479
 480                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 481                 }
 482                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 483                 {
 484                         cvar_set("chase_active", "0");
 485                         eventchase_current_distance = 0; // start from 0 next time
 486                 }
 487         }
 488         // workaround for camera stuck between player's legs when using chase_active 1
 489         // because the engine stops updating the chase_active camera when the game ends
 490         else if(intermission)
 491         {
 492                 cvar_settemp("chase_active", "-1");
 493                 eventchase_current_distance = 0;
 494         }
 495
 496         // do lockview after event chase camera so that it still applies whenever necessary.
 497         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
 498         {
 499                 setproperty(VF_ORIGIN, freeze_org);
 500                 setproperty(VF_ANGLES, freeze_ang);
 501         }
 502         else
 503         {
 504                 freeze_org = getpropertyvec(VF_ORIGIN);
 505                 freeze_ang = getpropertyvec(VF_ANGLES);
 506         }
 507
 508         WarpZone_FixView();
 509         //WarpZone_FixPMove();
 510
 511         // Render the Scene
 512         view_origin = getpropertyvec(VF_ORIGIN);
 513         view_angles = getpropertyvec(VF_ANGLES);
 514         makevectors(view_angles);
 515         view_forward = v_forward;
 516         view_right = v_right;
 517         view_up = v_up;
 518
 519 #ifdef BLURTEST
 520         if(time > blurtest_time0 && time < blurtest_time1)
 521         {
 522                 float r, t;
 523
 524                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 525                 r = t * blurtest_radius;
 526                 f = 1 / pow(t, blurtest_power) - 1;
 527
 528                 cvar_set("r_glsl_postprocess", "1");
 529                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 530         }
 531         else
 532         {
 533                 cvar_set("r_glsl_postprocess", "0");
 534                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 535         }
 536 #endif
 537
 538         TargetMusic_Advance();
 539         Fog_Force();
 540
 541         if(drawtime == 0)
 542                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 543         else
 544                 drawframetime = bound(0.000001, time - drawtime, 1);
 545         drawtime = time;
 546
 547         // watch for gametype changes here...
 548         // in ParseStuffCMD the cmd isn't executed yet :/
 549         // might even be better to add the gametype to TE_CSQC_INIT...?
 550         if(!postinit)
 551                 PostInit();
 552
 553         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 554         {
 555                 if(calledhooks & HOOK_START)
 556                 {
 557                         localcmd("\ncl_hook_gameend\n");
 558                         calledhooks |= HOOK_END;
 559                 }
 560         }
 561
 562         Announcer();
 563
 564         fov = autocvar_fov;
 565         if(fov <= 59.5)
 566         {
 567                 if(!zoomscript_caught)
 568                 {
 569                         localcmd("+button9\n");
 570                         zoomscript_caught = 1;
 571                 }
 572         }
 573         else
 574         {
 575                 if(zoomscript_caught)
 576                 {
 577                         localcmd("-button9\n");
 578                         zoomscript_caught = 0;
 579                 }
 580         }
 581
 582         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 583
 584         // next WANTED weapon (for HUD)
 585         switchweapon = getstati(STAT_SWITCHWEAPON);
 586
 587         // currently switching-to weapon (for crosshair)
 588         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 589
 590         // actually active weapon (for zoom)
 591         activeweapon = getstati(STAT_ACTIVEWEAPON);
 592
 593         f = (serverflags & SERVERFLAG_TEAMPLAY);
 594         if(f != teamplay)
 595         {
 596                 teamplay = f;
 597                 HUD_InitScores();
 598         }
 599
 600         if(last_switchweapon != switchweapon) {
 601                 weapontime = time;
 602                 last_switchweapon = switchweapon;
 603         }
 604         if(last_activeweapon != activeweapon) {
 605                 last_activeweapon = activeweapon;
 606
 607                 e = get_weaponinfo(activeweapon);
 608                 if(e.netname != "")
 609                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 610                 else
 611                         localcmd("\ncl_hook_activeweapon none\n");
 612         }
 613
 614         // ALWAYS Clear Current Scene First
 615         clearscene();
 616 #ifdef WORKAROUND_XON010
 617         if(checkextension("DP_CSQC_ROTATEMOVES"))
 618         {
 619 #endif
 620         setproperty(VF_ORIGIN, view_origin);
 621         setproperty(VF_ANGLES, view_angles);
 622 #ifdef WORKAROUND_XON010
 623         }
 624 #endif
 625
 626         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 627         setproperty(VF_SIZE, vf_size);
 628         setproperty(VF_MIN, vf_min);
 629
 630         // Assign Standard Viewflags
 631         // Draw the World (and sky)
 632         setproperty(VF_DRAWWORLD, 1);
 633
 634         // Set the console size vars
 635         vid_conwidth = autocvar_vid_conwidth;
 636         vid_conheight = autocvar_vid_conheight;
 637         vid_pixelheight = autocvar_vid_pixelheight;
 638
 639         setproperty(VF_FOV, GetCurrentFov(fov));
 640
 641         // Camera for demo playback
 642         if(camera_active)
 643         {
 644                 if(autocvar_camera_enable)
 645                         CSQC_Demo_Camera();
 646                 else
 647                 {
 648                         cvar_set("chase_active", ftos(chase_active_backup));
 649                         cvar_set("cl_demo_mousegrab", "0");
 650                         camera_active = FALSE;
 651                 }
 652         }
 653 #ifdef CAMERATEST
 654         else if(autocvar_camera_enable)
 655 #else
 656         else if(autocvar_camera_enable && isdemo())
 657 #endif
 658         {
 659                 // Enable required Darkplaces cvars
 660                 chase_active_backup = autocvar_chase_active;
 661                 cvar_set("chase_active", "2");
 662                 cvar_set("cl_demo_mousegrab", "1");
 663                 camera_active = TRUE;
 664                 camera_mode = FALSE;
 665         }
 666
 667         // Draw the Crosshair
 668         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 669
 670         // Draw the Engine Status Bar (the default Quake HUD)
 671         setproperty(VF_DRAWENGINESBAR, 0);
 672
 673         // Update the mouse position
 674         /*
 675            mousepos_x = vid_conwidth;
 676            mousepos_y = vid_conheight;
 677            mousepos = mousepos*0.5 + getmousepos();
 678          */
 679
 680         e = self;
 681         for(self = world; (self = nextent(self)); )
 682                 if(self.draw)
 683                         self.draw();
 684         self = e;
 685
 686         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 687         renderscene();
 688
 689         // now switch to 2D drawing mode by calling a 2D drawing function
 690         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 691         // next R_RenderScene call
 692         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 693
 694         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 695         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 696         {
 697                 // apply night vision effect
 698                 vector tc_00, tc_01, tc_10, tc_11;
 699                 vector rgb;
 700                 rgb_x = 0; // fteqcc sucks
 701                 rgb_y = 0; // fteqcc sucks
 702                 rgb_z = 0; // fteqcc sucks
 703
 704                 if(!nightvision_noise)
 705                 {
 706                         nightvision_noise = spawn();
 707                         nightvision_noise.classname = "nightvision_noise";
 708                 }
 709                 if(!nightvision_noise2)
 710                 {
 711                         nightvision_noise2 = spawn();
 712                         nightvision_noise2.classname = "nightvision_noise2";
 713                 }
 714
 715                 // color tint in yellow
 716                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 717
 718                 // draw BG
 719                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 720                 rgb = '1 1 1';
 721                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 722                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 723                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 724                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 725                 tc_11 = tc_01 + tc_10 - tc_00;
 726                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 727                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 728                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 729                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 730                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 731                 R_EndPolygon();
 732
 733                 // draw FG
 734                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 735                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 736                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 737                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 738                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 739                 tc_11 = tc_01 + tc_10 - tc_00;
 740                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 741                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 742                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 743                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 744                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 745                 R_EndPolygon();
 746         }
 747
 748         // Draw the aiming reticle for weapons that use it
 749         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 750         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 751         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 752         if(spectatee_status || getstati(STAT_HEALTH) <= 0 || hud != HUD_NORMAL)
 753                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 754         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 755                 reticle_type = 2; // nex zoom
 756         else if(button_zoom || zoomscript_caught)
 757                 reticle_type = 1; // normal zoom
 758         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 759                 reticle_type = 2; // nex zoom
 760
 761         if(reticle_type && autocvar_cl_reticle)
 762         {
 763                 if(autocvar_cl_reticle_stretch)
 764                 {
 765                         reticle_size_x = vid_conwidth;
 766                         reticle_size_y = vid_conheight;
 767                         reticle_pos_x = 0;
 768                         reticle_pos_y = 0;
 769                 }
 770                 else
 771                 {
 772                         reticle_size_x = max(vid_conwidth, vid_conheight);
 773                         reticle_size_y = max(vid_conwidth, vid_conheight);
 774                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 775                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 776                 }
 777
 778                 f = current_zoomfraction;
 779                 if(zoomscript_caught)
 780                         f = 1;
 781                 if(autocvar_cl_reticle_item_normal)
 782                 {
 783                         if(reticle_type == 1 && f)
 784                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 785                 }
 786                 if(autocvar_cl_reticle_item_nex)
 787                 {
 788                         if(reticle_type == 2 && f)
 789                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 790                 }
 791         }
 792
 793
 794         // improved polyblend
 795         if(autocvar_hud_contents)
 796         {
 797                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 798                 vector liquidcolor;
 799
 800                 switch(pointcontents(view_origin))
 801                 {
 802                         case CONTENT_WATER:
 803                                 liquidalpha = autocvar_hud_contents_water_alpha;
 804                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 805                                 incontent = 1;
 806                                 break;
 807
 808                         case CONTENT_LAVA:
 809                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 810                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 811                                 incontent = 1;
 812                                 break;
 813
 814                         case CONTENT_SLIME:
 815                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 816                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 817                                 incontent = 1;
 818                                 break;
 819
 820                         default:
 821                                 liquidalpha = 0;
 822                                 liquidcolor = '0 0 0';
 823                                 incontent = 0;
 824                                 break;
 825                 }
 826
 827                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 828                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 829                         contentfadetime = autocvar_hud_contents_fadeintime;
 830                         liquidalpha_prev = liquidalpha;
 831                         liquidcolor_prev = liquidcolor;
 832                 }
 833                 else
 834                         contentfadetime = autocvar_hud_contents_fadeouttime;
 835
 836                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 837                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 838
 839                 if(contentavgalpha)
 840                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 841
 842                 if(autocvar_hud_postprocessing)
 843                 {
 844                         if(autocvar_hud_contents_blur && contentavgalpha)
 845                         {
 846                                 content_blurpostprocess_x = 1;
 847                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 848                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 849                         }
 850                         else
 851                         {
 852                                 content_blurpostprocess_x = 0;
 853                                 content_blurpostprocess_y = 0;
 854                                 content_blurpostprocess_z = 0;
 855                         }
 856                 }
 857         }
 858
 859         if(autocvar_hud_damage)
 860         {
 861                 splash_size_x = max(vid_conwidth, vid_conheight);
 862                 splash_size_y = max(vid_conwidth, vid_conheight);
 863                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 864                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 865
 866                 float myhealth_flash_temp;
 867                 myhealth = getstati(STAT_HEALTH);
 868
 869                 // fade out
 870                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 871                 // add new damage
 872                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 873
 874                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 875                 pain_threshold = autocvar_hud_damage_pain_threshold;
 876                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 877                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 878
 879                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 880                 {
 881                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 882                 }
 883
 884                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 885
 886                 if(myhealth_prev < 1)
 887                 {
 888                         if(myhealth >= 1)
 889                         {
 890                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 891                                 myhealth_flash_temp = 0;
 892                         }
 893                         else
 894                         {
 895                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 896                         }
 897                 }
 898
 899                 if(spectatee_status == -1 || intermission)
 900                 {
 901                         myhealth_flash = 0; // observing, or match ended
 902                         myhealth_flash_temp = 0;
 903                 }
 904
 905                 myhealth_prev = myhealth;
 906
 907                 // IDEA: change damage color/picture based on player model for robot/alien species?
 908                 // pro: matches model better
 909                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
 910                 // maybe different reddish pics?
 911                 if(autocvar_chase_active >= 0) // not while the event chase camera is active
 912                 {
 913                         if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 914                         {
 915                                 if(autocvar_cl_gentle_damage == 2)
 916                                 {
 917                                         if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 918                                         {
 919                                                 myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 920                                         }
 921                                 }
 922                                 else
 923                                         myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 924
 925                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 926                         }
 927                         else
 928                                 drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 929                 }
 930
 931                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
 932                 {
 933                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 934                         {
 935                                 damage_blurpostprocess_x = 1;
 936                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 937                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 938                         }
 939                         else
 940                         {
 941                                 damage_blurpostprocess_x = 0;
 942                                 damage_blurpostprocess_y = 0;
 943                                 damage_blurpostprocess_z = 0;
 944                         }
 945                 }
 946         }
 947
 948         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
 949         float e2 = (autocvar_hud_powerup != 0);
 950         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
 951         {
 952                 // enable or disable rendering types if they are used or not
 953                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
 954                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
 955
 956                 // blur postprocess handling done first (used by hud_damage and hud_contents)
 957                 if((damage_blurpostprocess_x || content_blurpostprocess_x) && autocvar_chase_active >= 0) // not while the event chase camera is active
 958                 {
 959                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 960                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 961                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 962                         {
 963                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 964                                 old_blurradius = blurradius;
 965                                 old_bluralpha = bluralpha;
 966                         }
 967                 }
 968                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 969                 {
 970                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 971                         old_blurradius = 0;
 972                         old_bluralpha = 0;
 973                 }
 974
 975                 // edge detection postprocess handling done second (used by hud_powerup)
 976                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
 977                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
 978                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
 979
 980                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
 981
 982                 if(autocvar_hud_powerup && sharpen_intensity > 0 && autocvar_chase_active >= 0) // not while the event chase camera is active
 983                 {
 984                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 985                         {
 986                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
 987                                 old_sharpen_intensity = sharpen_intensity;
 988                         }
 989                 }
 990                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
 991                 {
 992                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 993                         old_sharpen_intensity = 0;
 994                 }
 995
 996                 if(cvar("r_glsl_postprocess") == 0)
 997                         cvar_set("r_glsl_postprocess", "2");
 998         }
 999         else if(cvar("r_glsl_postprocess") == 2)
1000                 cvar_set("r_glsl_postprocess", "0");
1001
1002         if(menu_visible)
1003                 menu_show();
1004
1005         /*if(gametype == MAPINFO_TYPE_CTF)
1006           {
1007           ctf_view();
1008           } else */
1009
1010         // draw 2D entities
1011         e = self;
1012         for(self = world; (self = nextent(self)); )
1013                 if(self.draw2d)
1014                         self.draw2d();
1015         self = e;
1016         Draw_ShowNames_All();
1017
1018         scoreboard_active = HUD_WouldDrawScoreboard();
1019
1020         hit_time = getstatf(STAT_HIT_TIME);
1021         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
1022         {
1023                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1024                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
1025
1026                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
1027         }
1028         typehit_time = getstatf(STAT_TYPEHIT_TIME);
1029         if(typehit_time > nextsound_typehit_time)
1030         {
1031                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1032                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
1033
1034                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
1035         }
1036
1037         //else
1038         {
1039                 if(gametype == MAPINFO_TYPE_FREEZETAG)
1040                 {
1041                         if(getstati(STAT_FROZEN))
1042                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1043                         if(getstatf(STAT_REVIVE_PROGRESS))
1044                         {
1045                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1046                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1047                         }
1048                 }
1049
1050                 if(autocvar_r_letterbox == 0)
1051                         if(autocvar_viewsize < 120)
1052                                 CSQC_common_hud();
1053
1054                 // crosshair goes VERY LAST
1055                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1056                 {
1057                         if not(autocvar_crosshair_enabled) // main toggle for crosshair rendering
1058                                 return;
1059
1060                         string wcross_style;
1061                         float wcross_alpha, wcross_resolution;
1062                         wcross_style = autocvar_crosshair;
1063                         if (wcross_style == "0")
1064                                 return;
1065                         wcross_resolution = autocvar_crosshair_size;
1066                         if (wcross_resolution == 0)
1067                                 return;
1068                         wcross_alpha = autocvar_crosshair_alpha;
1069                         if (wcross_alpha == 0)
1070                                 return;
1071
1072                         // TrueAim check
1073                         float shottype;
1074
1075                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1076                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1077                         wcross_origin_z = 0;
1078                         if(autocvar_crosshair_hittest)
1079                         {
1080                                 vector wcross_oldorigin;
1081                                 wcross_oldorigin = wcross_origin;
1082                                 shottype = TrueAimCheck();
1083                                 if(shottype == SHOTTYPE_HITWORLD)
1084                                 {
1085                                         v = wcross_origin - wcross_oldorigin;
1086                                         v_x /= vid_conwidth;
1087                                         v_y /= vid_conheight;
1088                                         if(vlen(v) > 0.01)
1089                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1090                                 }
1091                                 if(!autocvar_crosshair_hittest_showimpact)
1092                                         wcross_origin = wcross_oldorigin;
1093                         }
1094                         else
1095                                 shottype = SHOTTYPE_HITWORLD;
1096
1097                         vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1098                         string wcross_wep = "", wcross_name;
1099                         float wcross_scale, wcross_blur;
1100
1101                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1102                                 e = get_weaponinfo(switchingweapon);
1103                                 if (e && e.netname != "")
1104                                 {
1105                                         wcross_wep = e.netname;
1106                                         if(autocvar_crosshair_per_weapon)
1107                                         {
1108                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1109                                                 if (wcross_resolution == 0)
1110                                                         return;
1111                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1112                                                 if (wcross_alpha == 0)
1113                                                         return;
1114
1115                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1116                                                 if(wcross_style == "" || wcross_style == "0")
1117                                                         wcross_style = wcross_wep;
1118                                         }
1119                                 }
1120                         }
1121                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1122                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1123                         else if(autocvar_crosshair_color_by_health)
1124                         {
1125                                 float x = getstati(STAT_HEALTH);
1126
1127                                 //x = red
1128                                 //y = green
1129                                 //z = blue
1130
1131                                 wcross_color_z = 0;
1132
1133                                 if(x > 200)
1134                                 {
1135                                         wcross_color_x = 0;
1136                                         wcross_color_y = 1;
1137                                 }
1138                                 else if(x > 150)
1139                                 {
1140                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1141                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1142                                 }
1143                                 else if(x > 100)
1144                                 {
1145                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1146                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1147                                         wcross_color_z = 1 - (x-100)*0.02;
1148                                 }
1149                                 else if(x > 50)
1150                                 {
1151                                         wcross_color_x = 1;
1152                                         wcross_color_y = 1;
1153                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1154                                 }
1155                                 else if(x > 20)
1156                                 {
1157                                         wcross_color_x = 1;
1158                                         wcross_color_y = (x-20)*90/27/100;
1159                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1160                                 }
1161                                 else
1162                                 {
1163                                         wcross_color_x = 1;
1164                                         wcross_color_y = 0;
1165                                 }
1166                         }
1167                         else
1168                                 wcross_color = stov(autocvar_crosshair_color);
1169
1170                         wcross_name = strcat("gfx/crosshair", wcross_style);
1171
1172                         if(autocvar_crosshair_effect_scalefade)
1173                         {
1174                                 wcross_scale = wcross_resolution;
1175                                 wcross_resolution = 1;
1176                         }
1177                         else
1178                         {
1179                                 wcross_scale = 1;
1180                         }
1181
1182                         if(autocvar_crosshair_pickup)
1183                         {
1184                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1185
1186                                 if(pickup_crosshair_time < stat_pickup_time)
1187                                 {
1188                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1189                                                 pickup_crosshair_size = 1;
1190
1191                                         pickup_crosshair_time = stat_pickup_time;
1192                                 }
1193
1194                                 if(pickup_crosshair_size > 0)
1195                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1196                                 else
1197                                         pickup_crosshair_size = 0;
1198
1199                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1200                         }
1201
1202                         if(autocvar_crosshair_hitindication)
1203                         {
1204                                 vector hitindication_color = ((autocvar_crosshair_color_per_weapon) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1205
1206                                 if(hitindication_crosshair_time < hit_time)
1207                                 {
1208                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1209                                                 hitindication_crosshair_size = 1;
1210
1211                                         hitindication_crosshair_time = hit_time;
1212                                 }
1213
1214                                 if(hitindication_crosshair_size > 0)
1215                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1216                                 else
1217                                         hitindication_crosshair_size = 0;
1218
1219                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1220                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1221                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1222                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1223                         }
1224
1225                         if(shottype == SHOTTYPE_HITENEMY)
1226                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1227                         if(shottype == SHOTTYPE_HITTEAM)
1228                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1229
1230                         f = autocvar_crosshair_effect_speed;
1231                         if(f < 0)
1232                                 f *= -2 * g_weaponswitchdelay; // anim starts when weapon has been lowered and new weapon comes up
1233                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1234                         {
1235                                 wcross_changedonetime = time + f;
1236                         }
1237                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1238                         {
1239                                 wcross_name_changestarttime = time;
1240                                 wcross_name_changedonetime = time + f;
1241                                 if(wcross_name_goal_prev_prev)
1242                                         strunzone(wcross_name_goal_prev_prev);
1243                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1244                                 wcross_name_goal_prev = strzone(wcross_name);
1245                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1246                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1247                                 wcross_resolution_goal_prev = wcross_resolution;
1248                         }
1249
1250                         wcross_scale_goal_prev = wcross_scale;
1251                         wcross_alpha_goal_prev = wcross_alpha;
1252                         wcross_color_goal_prev = wcross_color;
1253
1254                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1255                         {
1256                                 wcross_blur = 1;
1257                                 wcross_alpha *= 0.75;
1258                         }
1259                         else
1260                                 wcross_blur = 0;
1261                         // *_prev is at time-frametime
1262                         // * is at wcross_changedonetime+f
1263                         // what do we have at time?
1264                         if(time < wcross_changedonetime)
1265                         {
1266                                 f = frametime / (wcross_changedonetime - time + frametime);
1267                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1268                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1269                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1270                         }
1271
1272                         wcross_scale_prev = wcross_scale;
1273                         wcross_alpha_prev = wcross_alpha;
1274                         wcross_color_prev = wcross_color;
1275
1276                         wcross_scale *= 1 - autocvar__menu_alpha;
1277                         wcross_alpha *= 1 - autocvar__menu_alpha;
1278                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1279
1280                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1281                         {
1282                                 // crosshair rings for weapon stats
1283                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1284                                 {
1285                                         // declarations and stats
1286                                         float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1287                                         string ring_image = string_null, ring_inner_image = string_null;
1288                                         vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1289
1290                                         ring_scale = autocvar_crosshair_ring_size;
1291
1292                                         float weapon_clipload, weapon_clipsize;
1293                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1294                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1295
1296                                         float nex_charge, nex_chargepool;
1297                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1298                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1299
1300                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1301                                                 nex_charge_movingavg = nex_charge;
1302
1303
1304                                         // handle the values
1305                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1306                                         {
1307                                                 if (nex_chargepool || use_nex_chargepool) {
1308                                                         use_nex_chargepool = 1;
1309                                                         ring_inner_value = nex_chargepool;
1310                                                 } else {
1311                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1312                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1313                                                 }
1314
1315                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1316                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1317                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1318
1319                                                 // draw the outer ring to show the current charge of the weapon
1320                                                 ring_value = nex_charge;
1321                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1322                                                 ring_rgb = wcross_color;
1323                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1324                                         }
1325                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1326                                         {
1327                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1328                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1329                                                 ring_rgb = wcross_color;
1330                                                 ring_image = "gfx/crosshair_ring.tga";
1331                                         }
1332                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1333                                         {
1334                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1335                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1336                                                 ring_rgb = wcross_color;
1337                                                 ring_image = "gfx/crosshair_ring.tga";
1338                                         }
1339
1340                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1341                                         {
1342                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1343                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1344                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1345                                                 ring_rgb = wcross_color;
1346
1347                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1348                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1349                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1350                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1351                                                 else
1352                                                         ring_image = "gfx/crosshair_ring.tga";
1353                                         }
1354
1355                                         // if in weapon switch animation, fade ring out/in
1356                                         if(g_weaponswitchdelay > 0)
1357                                         {
1358                                                 f = (time - wcross_name_changestarttime) / g_weaponswitchdelay;
1359                                                 if(f > 0 && f < 2)
1360                                                         ring_alpha *= fabs(1 - f);
1361                                         }
1362
1363                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1364                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1365
1366                                         if (ring_value)
1367                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1368                                 }
1369
1370 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1371                                 do \
1372                                 { \
1373                                         if(wcross_blur > 0) \
1374                                         { \
1375                                                 for(i = -2; i <= 2; ++i) \
1376                                                 for(j = -2; j <= 2; ++j) \
1377                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1378                                         } \
1379                                         else \
1380                                         { \
1381                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1382                                         } \
1383                                 } \
1384                                 while(0)
1385
1386 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1387                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1388
1389 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1390                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1391
1392                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1393                                 {
1394                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1395                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1396                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1397                                         f = 1 - f;
1398                                 }
1399                                 else
1400                                 {
1401                                         f = 1;
1402                                 }
1403                                 wcross_name_alpha_goal_prev = f;
1404
1405                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1406                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1407
1408                                 if(autocvar_crosshair_dot)
1409                                 {
1410                                         vector wcross_color_old;
1411                                         wcross_color_old = wcross_color;
1412
1413                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1414                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1415
1416                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1417                                         // FIXME why don't we use wcross_alpha here?cl_notice_run();
1418                                         wcross_color = wcross_color_old;
1419                                 }
1420                         }
1421                 }
1422                 else
1423                 {
1424                         wcross_scale_prev = 0;
1425                         wcross_alpha_prev = 0;
1426                         wcross_scale_goal_prev = 0;
1427                         wcross_alpha_goal_prev = 0;
1428                         wcross_changedonetime = 0;
1429                         if(wcross_name_goal_prev)
1430                                 strunzone(wcross_name_goal_prev);
1431                         wcross_name_goal_prev = string_null;
1432                         if(wcross_name_goal_prev_prev)
1433                                 strunzone(wcross_name_goal_prev_prev);
1434                         wcross_name_goal_prev_prev = string_null;
1435                         wcross_name_changestarttime = 0;
1436                         wcross_name_changedonetime = 0;
1437                         wcross_name_alpha_goal_prev = 0;
1438                         wcross_name_alpha_goal_prev_prev = 0;
1439                         wcross_resolution_goal_prev = 0;
1440                         wcross_resolution_goal_prev_prev = 0;
1441                 }
1442         }
1443
1444         if(NextFrameCommand)
1445         {
1446                 localcmd("\n", NextFrameCommand, "\n");
1447                 NextFrameCommand = string_null;
1448         }
1449
1450         // we must do this check AFTER a frame was rendered, or it won't work
1451         if(cs_project_is_b0rked == 0)
1452         {
1453                 string w0, h0;
1454                 w0 = ftos(autocvar_vid_conwidth);
1455                 h0 = ftos(autocvar_vid_conheight);
1456                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1457                 //setproperty(VF_FOV, '90 90 0');
1458                 setproperty(VF_ORIGIN, '0 0 0');
1459                 setproperty(VF_ANGLES, '0 0 0');
1460                 setproperty(VF_PERSPECTIVE, 1);
1461                 makevectors('0 0 0');
1462                 vector v1, v2;
1463                 cvar_set("vid_conwidth", "800");
1464                 cvar_set("vid_conheight", "600");
1465                 v1 = cs_project(v_forward);
1466                 cvar_set("vid_conwidth", "640");
1467                 cvar_set("vid_conheight", "480");
1468                 v2 = cs_project(v_forward);
1469                 if(v1 == v2)
1470                         cs_project_is_b0rked = 1;
1471                 else
1472                         cs_project_is_b0rked = -1;
1473                 cvar_set("vid_conwidth", w0);
1474                 cvar_set("vid_conheight", h0);
1475         }
1476
1477         if(autocvar__hud_configure)
1478                 HUD_Panel_Mouse();
1479
1480     if(hud && !intermission)
1481     {
1482         if(hud == HUD_SPIDERBOT)
1483             CSQC_SPIDER_HUD();
1484         else if(hud == HUD_WAKIZASHI)
1485             CSQC_WAKIZASHI_HUD();
1486         else if(hud == HUD_RAPTOR)
1487             CSQC_RAPTOR_HUD();
1488         else if(hud == HUD_BUMBLEBEE)
1489             CSQC_BUMBLE_HUD();
1490         else if(hud == HUD_BUMBLEBEE_GUN)
1491             CSQC_BUMBLE_GUN_HUD();
1492     }
1493
1494         cl_notice_run();
1495
1496         // let's reset the view back to normal for the end
1497         setproperty(VF_MIN, '0 0 0');
1498         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1499 }
1500
1501
1502 void CSQC_common_hud(void)
1503 {
1504     // do some accuracy var caching
1505     float i;
1506     if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1507     {
1508         if(autocvar_accuracy_color_levels != acc_color_levels)
1509         {
1510             if(acc_color_levels)
1511                 strunzone(acc_color_levels);
1512             acc_color_levels = strzone(autocvar_accuracy_color_levels);
1513             acc_levels = tokenize_console(acc_color_levels);
1514             if (acc_levels > MAX_ACCURACY_LEVELS)
1515                 acc_levels = MAX_ACCURACY_LEVELS;
1516
1517             for (i = 0; i < acc_levels; ++i)
1518                 acc_lev[i] = stof(argv(i)) / 100.0;
1519         }
1520         // let know that acc_col[] needs to be loaded
1521         acc_col[0] = '-1 0 0';
1522     }
1523
1524     HUD_Main(); // always run these functions for alpha checks
1525     HUD_DrawScoreboard();
1526
1527     if (scoreboard_active) // scoreboard/accuracy
1528         HUD_Reset();
1529     else if (intermission == 2) // map voting screen
1530     {
1531         HUD_FinaleOverlay();
1532         HUD_Reset();
1533     }
1534         /*
1535         switch(hud)
1536         {
1537                 case HUD_SPIDERBOT:
1538                         CSQC_SPIDER_HUD();
1539                         break;
1540
1541                 case HUD_WAKIZASHI:
1542                         CSQC_WAKIZASHI_HUD();
1543                         break;
1544
1545         case HUD_BUMBLEBEE:
1546             CSQC_BUMBLE_HUD();
1547             break;
1548         }
1549         */
1550 }
1551
1552
1553 // following vectors must be global to allow seamless switching between camera modes
1554 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1555 void CSQC_Demo_Camera()
1556 {
1557         float speed, attenuation, dimensions;
1558         vector tmp, delta;
1559
1560         if( autocvar_camera_reset || !camera_mode )
1561         {
1562                 camera_offset = '0 0 0';
1563                 current_angles = '0 0 0';
1564                 camera_direction = '0 0 0';
1565                 camera_offset_z += 30;
1566                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1567                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1568                 current_origin = view_origin;
1569                 current_camera_offset  = camera_offset;
1570                 cvar_set("camera_reset", "0");
1571                 camera_mode = CAMERA_CHASE;
1572         }
1573
1574         // Camera angles
1575         if( camera_roll )
1576                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1577
1578         if(autocvar_camera_look_player)
1579         {
1580                 vector dir;
1581                 float n;
1582
1583                 dir = normalize(view_origin - current_position);
1584                 n = mouse_angles_z;
1585                 mouse_angles = vectoangles(dir);
1586                 mouse_angles_x = mouse_angles_x * -1;
1587                 mouse_angles_z = n;
1588         }
1589         else
1590         {
1591                 tmp = getmousepos() * 0.1;
1592                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1593                 {
1594                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1595                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1596                 }
1597         }
1598
1599         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1600         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1601         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1602         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1603
1604         // Fix difference when angles don't have the same sign
1605         delta = '0 0 0';
1606         if(mouse_angles_y < -60 && current_angles_y > 60)
1607                 delta = '0 360 0';
1608         if(mouse_angles_y > 60 && current_angles_y < -60)
1609                 delta = '0 -360 0';
1610
1611         if(autocvar_camera_look_player)
1612                 attenuation = autocvar_camera_look_attenuation;
1613         else
1614                 attenuation = autocvar_camera_speed_attenuation;
1615
1616         attenuation = 1 / max(1, attenuation);
1617         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1618
1619         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1620         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1621         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1622         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1623
1624         // Camera position
1625         tmp = '0 0 0';
1626         dimensions = 0;
1627
1628         if( camera_direction_x )
1629         {
1630                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1631                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1632                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1633                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1634                 ++dimensions;
1635         }
1636
1637         if( camera_direction_y )
1638         {
1639                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1640                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1641                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1642                 ++dimensions;
1643         }
1644
1645         if( camera_direction_z )
1646         {
1647                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1648                 ++dimensions;
1649         }
1650
1651         if(autocvar_camera_free)
1652                 speed = autocvar_camera_speed_free;
1653         else
1654                 speed = autocvar_camera_speed_chase;
1655
1656         if(dimensions)
1657         {
1658                 speed = speed * sqrt(1 / dimensions);
1659                 camera_offset += tmp * speed;
1660         }
1661
1662         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1663
1664         // Camera modes
1665         if( autocvar_camera_free )
1666         {
1667                 if ( camera_mode == CAMERA_CHASE )
1668                 {
1669                         current_camera_offset = current_origin + current_camera_offset;
1670                         camera_offset = current_origin + camera_offset;
1671                 }
1672
1673                 camera_mode = CAMERA_FREE;
1674                 current_position = current_camera_offset;
1675         }
1676         else
1677         {
1678                 if ( camera_mode == CAMERA_FREE )
1679                 {
1680                         current_origin = view_origin;
1681                         camera_offset = camera_offset - current_origin;
1682                         current_camera_offset = current_camera_offset - current_origin;
1683                 }
1684
1685                 camera_mode = CAMERA_CHASE;
1686
1687                 if(autocvar_camera_chase_smoothly)
1688                         current_origin += (view_origin - current_origin) * attenuation;
1689                 else
1690                         current_origin = view_origin;
1691
1692                 current_position = current_origin + current_camera_offset;
1693         }
1694
1695         setproperty(VF_ANGLES, current_angles);
1696         setproperty(VF_ORIGIN, current_position);
1697 }