qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 void Porto_Draw()
   4 {
   5         vector p, dir, ang, q, nextdir;
   6         float idx, portal_number, portal1_idx;
   7
   8         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
   9                 return;
  10         if(g_balance_porto_secondary)
  11                 return;
  12         if(intermission == 1)
  13                 return;
  14         if(intermission == 2)
  15                 return;
  16         if (getstati(STAT_HEALTH) <= 0)
  17                 return;
  18
  19         dir = view_forward;
  20
  21         if(angles_held_status)
  22         {
  23                 makevectors(angles_held);
  24                 dir = v_forward;
  25         }
  26
  27         p = view_origin;
  28
  29         polyline[0] = p;
  30         idx = 1;
  31         portal_number = 0;
  32         nextdir = dir;
  33
  34         for(;;)
  35         {
  36                 dir = nextdir;
  37                 traceline(p, p + 65536 * dir, TRUE, porto);
  38                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  39                         return;
  40                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  41                 p = trace_endpos;
  42                 polyline[idx] = p;
  43                 ++idx;
  44                 if(idx >= 16)
  45                         return;
  46                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  47                         continue;
  48                 ++portal_number;
  49                 ang = vectoangles2(trace_plane_normal, dir);
  50                 ang_x = -ang_x;
  51                 makevectors(ang);
  52                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  53                         return;
  54                 if(portal_number == 1)
  55                 {
  56                         portal1_idx = idx;
  57                         if(portal_number >= 2)
  58                                 break;
  59                 }
  60         }
  61
  62         while(idx >= 2)
  63         {
  64                 p = polyline[idx-2];
  65                 q = polyline[idx-1];
  66                 if(idx == 2)
  67                         p = p - view_up * 16;
  68                 if(idx-1 >= portal1_idx)
  69                 {
  70                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  71                 }
  72                 else
  73                 {
  74                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  75                 }
  76                 --idx;
  77         }
  78 }
  79
  80 void Porto_Init()
  81 {
  82         porto = spawn();
  83         porto.classname = "porto";
  84         porto.draw = Porto_Draw;
  85         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  86 }
  87
  88 float drawtime;
  89 float avgspeed;
  90 vector GetCurrentFov(float fov)
  91 {
  92         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  93         float velocityzoom, curspeed;
  94         vector v;
  95
  96         zoomsensitivity = autocvar_cl_zoomsensitivity;
  97         zoomfactor = autocvar_cl_zoomfactor;
  98         if(zoomfactor < 1 || zoomfactor > 16)
  99                 zoomfactor = 2.5;
 100         zoomspeed = autocvar_cl_zoomspeed;
 101         if(zoomspeed >= 0)
 102         if(zoomspeed < 0.5 || zoomspeed > 16)
 103                         zoomspeed = 3.5;
 104
 105         zoomdir = button_zoom;
 106         if(hud == HUD_NORMAL)
 107         if((activeweapon == WEP_VORTEX && vortex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 108                 zoomdir += button_attack2;
 109         if(spectatee_status > 0 || isdemo())
 110         {
 111                 if(spectatorbutton_zoom)
 112                 {
 113                         if(zoomdir)
 114                                 zoomdir = 0;
 115                         else
 116                                 zoomdir = 1;
 117                 }
 118                 // fteqcc failed twice here already, don't optimize this
 119         }
 120
 121         if(zoomdir) { zoomin_effect = 0; }
 122
 123         if(camera_active)
 124         {
 125                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 126         }
 127         else if(autocvar_cl_spawnzoom && zoomin_effect)
 128         {
 129                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 130
 131                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 132                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 133                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 134         }
 135         else
 136         {
 137                 if(zoomspeed < 0) // instant zoom
 138                 {
 139                         if(zoomdir)
 140                                 current_viewzoom = 1 / zoomfactor;
 141                         else
 142                                 current_viewzoom = 1;
 143                 }
 144                 else
 145                 {
 146                         if(zoomdir)
 147                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 148                         else
 149                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 150                 }
 151         }
 152
 153         if(almost_equals(current_viewzoom, 1))
 154                 current_zoomfraction = 0;
 155         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 156                 current_zoomfraction = 1;
 157         else
 158                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 159
 160         if(zoomsensitivity < 1)
 161                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 162         else
 163                 setsensitivityscale(1);
 164
 165         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 166         {
 167                 if(intermission) { curspeed = 0; }
 168                 else
 169                 {
 170
 171                         makevectors(view_angles);
 172                         v = pmove_vel;
 173                         if(csqcplayer)
 174                                 v = csqcplayer.velocity;
 175
 176                         switch(autocvar_cl_velocityzoom_type)
 177                         {
 178                                 case 3: curspeed = max(0, v_forward * v); break;
 179                                 case 2: curspeed = (v_forward * v); break;
 180                                 case 1: default: curspeed = vlen(v); break;
 181                         }
 182                 }
 183
 184                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 185                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 186                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 187
 188                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 189         }
 190         else
 191                 velocityzoom = 1;
 192
 193         float frustumx, frustumy, fovx, fovy;
 194         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 195         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 196         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 197         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 198
 199         return '1 0 0' * fovx + '0 1 0' * fovy;
 200 }
 201
 202 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 203 {
 204         float fovx, fovy;
 205         float width = (ov_worldmax_x - ov_worldmin_x);
 206         float height = (ov_worldmax_y - ov_worldmin_y);
 207         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 208         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 209         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 210         return '1 0 0' * fovx + '0 1 0' * fovy;
 211 }
 212
 213 // this function must match W_SetupShot!
 214 float zoomscript_caught;
 215
 216 vector wcross_origin;
 217 float wcross_scale_prev, wcross_alpha_prev;
 218 vector wcross_color_prev;
 219 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 220 vector wcross_color_goal_prev;
 221 float wcross_changedonetime;
 222
 223 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 224 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 225 float wcross_name_changestarttime, wcross_name_changedonetime;
 226 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 227
 228 float wcross_ring_prev;
 229
 230 entity trueaim;
 231 entity trueaim_rifle;
 232
 233 #define SHOTTYPE_HITTEAM 1
 234 #define SHOTTYPE_HITOBSTRUCTION 2
 235 #define SHOTTYPE_HITWORLD 3
 236 #define SHOTTYPE_HITENEMY 4
 237
 238 void TrueAim_Init()
 239 {
 240         trueaim = spawn();
 241         trueaim.classname = "trueaim";
 242         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 243         trueaim_rifle = spawn();
 244         trueaim_rifle.classname = "trueaim_rifle";
 245         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 246 }
 247
 248 float EnemyHitCheck()
 249 {
 250         float t, n;
 251         wcross_origin = project_3d_to_2d(trace_endpos);
 252         wcross_origin_z = 0;
 253         if(trace_ent)
 254                 n = trace_ent.entnum;
 255         else
 256                 n = trace_networkentity;
 257         if(n < 1)
 258                 return SHOTTYPE_HITWORLD;
 259         if(n > maxclients)
 260                 return SHOTTYPE_HITWORLD;
 261         t = GetPlayerColor(n - 1);
 262         if(teamplay)
 263                 if(t == myteam)
 264                         return SHOTTYPE_HITTEAM;
 265         if(t == NUM_SPECTATOR)
 266                 return SHOTTYPE_HITWORLD;
 267         return SHOTTYPE_HITENEMY;
 268 }
 269
 270 float TrueAimCheck()
 271 {
 272         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 273         vector vecs, trueaimpoint, w_shotorg;
 274         vector mi, ma, dv;
 275         float shottype;
 276         entity ta;
 277         float mv;
 278
 279         mi = ma = '0 0 0';
 280         ta = trueaim;
 281         mv = MOVE_NOMONSTERS;
 282
 283         switch(activeweapon) // WEAPONTODO
 284         {
 285                 case WEP_TUBA: // no aim
 286                 case WEP_PORTO: // shoots from eye
 287                 case WEP_HOOK: // no trueaim
 288                 case WEP_MORTAR: // toss curve
 289                         return SHOTTYPE_HITWORLD;
 290                 case WEP_VORTEX:
 291                 case WEP_VAPORIZER:
 292                         mv = MOVE_NORMAL;
 293                         break;
 294                 case WEP_RIFLE:
 295                         ta = trueaim_rifle;
 296                         mv = MOVE_NORMAL;
 297                         if(zoomscript_caught)
 298                         {
 299                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 300                                 return EnemyHitCheck();
 301                         }
 302                         break;
 303                 case WEP_DEVASTATOR: // projectile has a size!
 304                         mi = '-3 -3 -3';
 305                         ma = '3 3 3';
 306                         break;
 307                 case WEP_FIREBALL: // projectile has a size!
 308                         mi = '-16 -16 -16';
 309                         ma = '16 16 16';
 310                         break;
 311                 case WEP_SEEKER: // projectile has a size!
 312                         mi = '-2 -2 -2';
 313                         ma = '2 2 2';
 314                         break;
 315                 case WEP_ELECTRO: // projectile has a size!
 316                         mi = '0 0 -3';
 317                         ma = '0 0 -3';
 318                         break;
 319         }
 320
 321         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 322
 323         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 324
 325         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 326         trueaimpoint = trace_endpos;
 327
 328         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 329                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 330
 331         if(vecs_x > 0)
 332                 vecs_y = -vecs_y;
 333         else
 334                 vecs = '0 0 0';
 335
 336         dv = view_right * vecs_y + view_up * vecs_z;
 337         w_shotorg = traceorigin + dv;
 338
 339         // now move the vecs forward as much as requested if possible
 340         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 341         w_shotorg = trace_endpos - view_forward * nudge;
 342
 343         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 344         shottype = EnemyHitCheck();
 345         if(shottype != SHOTTYPE_HITWORLD)
 346                 return shottype;
 347
 348 #if 0
 349         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 350         // or rather, I know why, but see no fix
 351         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 352                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 353                 return SHOTTYPE_HITOBSTRUCTION;
 354 #endif
 355
 356         return SHOTTYPE_HITWORLD;
 357 }
 358
 359 void CSQC_common_hud(void);
 360
 361 void PostInit(void);
 362 void CSQC_Demo_Camera();
 363 float HUD_WouldDrawScoreboard();
 364 float camera_mode;
 365 const float CAMERA_FREE = 1;
 366 const float CAMERA_CHASE = 2;
 367 float reticle_type;
 368 string reticle_image;
 369 string NextFrameCommand;
 370 void CSQC_SPIDER_HUD();
 371 void CSQC_RAPTOR_HUD();
 372
 373 vector freeze_org, freeze_ang;
 374 entity nightvision_noise, nightvision_noise2;
 375
 376 #define MAX_TIME_DIFF 5
 377 float pickup_crosshair_time, pickup_crosshair_size;
 378 float hitindication_crosshair_size;
 379 float use_vortex_chargepool;
 380
 381 float myhealth, myhealth_prev;
 382 float myhealth_flash;
 383
 384 float old_blurradius, old_bluralpha;
 385 float old_sharpen_intensity;
 386
 387 vector myhealth_gentlergb;
 388
 389 float contentavgalpha, liquidalpha_prev;
 390 vector liquidcolor_prev;
 391
 392 float eventchase_current_distance;
 393 float eventchase_running;
 394 float WantEventchase()
 395 {
 396         if(autocvar_cl_orthoview)
 397                 return FALSE;
 398         if(intermission)
 399                 return TRUE;
 400         if(spectatee_status >= 0)
 401         {
 402                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WepSet_FromWeapon(WEP_PORTO)))
 403                         return TRUE;
 404                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
 405                 {
 406                         if(autocvar_cl_eventchase_death == 2)
 407                         {
 408                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 409                                 if(self.velocity == '0 0 0' || eventchase_running)
 410                                         return TRUE;
 411                         }
 412                         else return TRUE;
 413                 }
 414         }
 415         return FALSE;
 416 }
 417
 418 vector damage_blurpostprocess, content_blurpostprocess;
 419
 420 float checkfail[16];
 421
 422 float rainbow_last_flicker;
 423 vector rainbow_prev_color;
 424
 425 #define BUTTON_3 4
 426 #define BUTTON_4 8
 427 float cl_notice_run();
 428 float prev_myteam;
 429 void CSQC_UpdateView(float w, float h)
 430 {
 431         entity e;
 432         float fov;
 433         float f, i, j;
 434         vector v;
 435         vector vf_size, vf_min;
 436         float a;
 437
 438         execute_next_frame();
 439
 440         ++framecount;
 441
 442         hud = getstati(STAT_HUD);
 443
 444         if(autocvar__hud_showbinds_reload) // menu can set this one
 445         {
 446                 db_close(binddb);
 447                 binddb = db_create();
 448                 cvar_set("_hud_showbinds_reload", "0");
 449         }
 450
 451         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 452                 view_quality = getproperty(VF_MINFPS_QUALITY);
 453         else
 454                 view_quality = 1;
 455
 456         button_attack2 = (input_buttons & BUTTON_3);
 457         button_zoom = (input_buttons & BUTTON_4);
 458
 459 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 460         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 461         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 462         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 463         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 464         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 465         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 466         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 467
 468         vf_size = getpropertyvec(VF_SIZE);
 469         vf_min = getpropertyvec(VF_MIN);
 470         vid_width = vf_size_x;
 471         vid_height = vf_size_y;
 472
 473         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 474         vector splash_pos = '0 0 0', splash_size = '0 0 0';
 475
 476         WaypointSprite_Load();
 477
 478         CSQCPlayer_SetCamera();
 479
 480 #ifdef COMPAT_XON050_ENGINE
 481         if(spectatee_status)
 482                 myteam = GetPlayerColor(spectatee_status - 1);
 483         else
 484 #endif
 485                 myteam = GetPlayerColor(player_localentnum - 1);
 486
 487         if(myteam != prev_myteam)
 488         {
 489                 myteamcolors = colormapPaletteColor(myteam, 1);
 490                 for(i = 0; i < HUD_PANEL_NUM; ++i)
 491                         hud_panel[i].update_time = time;
 492                 prev_myteam = myteam;
 493         }
 494
 495         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 496
 497         float is_dead = (getstati(STAT_HEALTH) <= 0);
 498
 499         // FIXME do we need this hack?
 500         if(isdemo())
 501         {
 502                 // in demos, input_buttons do not work
 503                 button_zoom = (autocvar__togglezoom == "-");
 504         }
 505         else if(button_zoom
 506                 && autocvar_cl_unpress_zoom_on_death
 507                 && (spectatee_status >= 0)
 508                 && (is_dead || intermission))
 509         {
 510                 // no zoom while dead or in intermission please
 511                 localcmd("-zoom\n");
 512                 button_zoom = FALSE;
 513         }
 514
 515         // event chase camera
 516         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 517         {
 518                 if(WantEventchase())
 519                 {
 520                         eventchase_running = TRUE;
 521
 522                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 523                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
 524
 525                         // detect maximum viewoffset and use it
 526                         if(autocvar_cl_eventchase_viewoffset)
 527                         {
 528                                 WarpZone_TraceLine(current_view_origin, current_view_origin + autocvar_cl_eventchase_viewoffset + ('0 0 1' * autocvar_cl_eventchase_maxs_z), MOVE_WORLDONLY, self);
 529                                 if(trace_fraction == 1) { current_view_origin += autocvar_cl_eventchase_viewoffset; }
 530                                 else { current_view_origin_z += max(0, (trace_endpos_z - current_view_origin_z) - autocvar_cl_eventchase_maxs_z); }
 531                         }
 532
 533                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 534                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 535                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 536                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 537
 538                         // make the camera smooth back
 539                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 540                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 541                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 542                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 543
 544                         makevectors(view_angles);
 545
 546                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 547                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
 548
 549                         // If the boxtrace fails, revert back to line tracing.
 550                         if(trace_startsolid)
 551                         {
 552                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 553                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 554                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins_z)));
 555                         }
 556                         else { setproperty(VF_ORIGIN, trace_endpos); }
 557
 558                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 559                 }
 560                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 561                 {
 562                         eventchase_running = FALSE;
 563                         cvar_set("chase_active", "0");
 564                         eventchase_current_distance = 0; // start from 0 next time
 565                 }
 566         }
 567         // workaround for camera stuck between player's legs when using chase_active 1
 568         // because the engine stops updating the chase_active camera when the game ends
 569         else if(intermission)
 570         {
 571                 cvar_settemp("chase_active", "-1");
 572                 eventchase_current_distance = 0;
 573         }
 574
 575         // do lockview after event chase camera so that it still applies whenever necessary.
 576         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
 577         {
 578                 setproperty(VF_ORIGIN, freeze_org);
 579                 setproperty(VF_ANGLES, freeze_ang);
 580         }
 581         else
 582         {
 583                 freeze_org = getpropertyvec(VF_ORIGIN);
 584                 freeze_ang = getpropertyvec(VF_ANGLES);
 585         }
 586
 587         WarpZone_FixView();
 588         //WarpZone_FixPMove();
 589
 590         vector ov_org = '0 0 0';
 591         vector ov_mid = '0 0 0';
 592         vector ov_worldmin = '0 0 0';
 593         vector ov_worldmax = '0 0 0';
 594         if(autocvar_cl_orthoview)
 595         {
 596                 ov_worldmin = mi_picmin;
 597                 ov_worldmax = mi_picmax;
 598
 599                 float ov_width = (ov_worldmax_x - ov_worldmin_x);
 600                 float ov_height = (ov_worldmax_y - ov_worldmin_y);
 601                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
 602
 603                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
 604                 ov_org = vec3(ov_mid_x, ov_mid_y, (ov_mid_z + ov_distance));
 605
 606                 float ov_nearest = vlen(ov_org - vec3(
 607                         bound(ov_worldmin_x, ov_org_x, ov_worldmax_x),
 608                         bound(ov_worldmin_y, ov_org_y, ov_worldmax_y),
 609                         bound(ov_worldmin_z, ov_org_z, ov_worldmax_z)
 610                 ));
 611
 612                 float ov_furthest = 0;
 613                 float dist = 0;
 614
 615                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmin_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 616                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmin_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 617                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmax_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 618                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmin_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 619                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmax_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 620                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmax_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 621                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmin_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 622                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmax_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 623
 624                 cvar_settemp("r_nearclip", ftos(ov_nearest));
 625                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
 626                 cvar_settemp("r_farclip_world", "0");
 627                 cvar_settemp("r_novis", "1");
 628                 cvar_settemp("r_useportalculling", "0");
 629                 cvar_settemp("r_useinfinitefarclip", "0");
 630
 631                 setproperty(VF_ORIGIN, ov_org);
 632                 setproperty(VF_ANGLES, '90 0 0');
 633
 634                 #if 0
 635                 printf("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
 636                         vtos(ov_org),
 637                         vtos(getpropertyvec(VF_ANGLES)),
 638                         ov_distance,
 639                         ov_nearest,
 640                         ov_furthest);
 641                 #endif
 642         }
 643
 644         // Render the Scene
 645         view_origin = getpropertyvec(VF_ORIGIN);
 646         view_angles = getpropertyvec(VF_ANGLES);
 647         makevectors(view_angles);
 648         view_forward = v_forward;
 649         view_right = v_right;
 650         view_up = v_up;
 651
 652 #ifdef BLURTEST
 653         if(time > blurtest_time0 && time < blurtest_time1)
 654         {
 655                 float r, t;
 656
 657                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 658                 r = t * blurtest_radius;
 659                 f = 1 / pow(t, blurtest_power) - 1;
 660
 661                 cvar_set("r_glsl_postprocess", "1");
 662                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 663         }
 664         else
 665         {
 666                 cvar_set("r_glsl_postprocess", "0");
 667                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 668         }
 669 #endif
 670
 671         TargetMusic_Advance();
 672         Fog_Force();
 673
 674         if(drawtime == 0)
 675                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 676         else
 677                 drawframetime = bound(0.000001, time - drawtime, 1);
 678         drawtime = time;
 679
 680         // watch for gametype changes here...
 681         // in ParseStuffCMD the cmd isn't executed yet :/
 682         // might even be better to add the gametype to TE_CSQC_INIT...?
 683         if(!postinit)
 684                 PostInit();
 685
 686         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 687         {
 688                 if(calledhooks & HOOK_START)
 689                 {
 690                         localcmd("\ncl_hook_gameend\n");
 691                         calledhooks |= HOOK_END;
 692                 }
 693         }
 694
 695         Announcer();
 696
 697         fov = autocvar_fov;
 698         if(fov <= 59.5)
 699         {
 700                 if(!zoomscript_caught)
 701                 {
 702                         localcmd("+button9\n");
 703                         zoomscript_caught = 1;
 704                 }
 705         }
 706         else
 707         {
 708                 if(zoomscript_caught)
 709                 {
 710                         localcmd("-button9\n");
 711                         zoomscript_caught = 0;
 712                 }
 713         }
 714
 715         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 716
 717         // next WANTED weapon (for HUD)
 718         switchweapon = getstati(STAT_SWITCHWEAPON);
 719
 720         // currently switching-to weapon (for crosshair)
 721         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 722
 723         // actually active weapon (for zoom)
 724         activeweapon = getstati(STAT_ACTIVEWEAPON);
 725
 726         f = (serverflags & SERVERFLAG_TEAMPLAY);
 727         if(f != teamplay)
 728         {
 729                 teamplay = f;
 730                 HUD_InitScores();
 731         }
 732
 733         if(last_switchweapon != switchweapon)
 734         {
 735                 weapontime = time;
 736                 last_switchweapon = switchweapon;
 737                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
 738                 {
 739                         localcmd("-zoom\n");
 740                         button_zoom = FALSE;
 741                 }
 742                 if(autocvar_cl_unpress_attack_on_weapon_switch)
 743                 {
 744                         localcmd("-fire\n");
 745                         localcmd("-fire2\n");
 746                         button_attack2 = FALSE;
 747                 }
 748         }
 749         if(last_activeweapon != activeweapon)
 750         {
 751                 last_activeweapon = activeweapon;
 752
 753                 e = get_weaponinfo(activeweapon);
 754                 if(e.netname != "")
 755                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 756                 else
 757                         localcmd("\ncl_hook_activeweapon none\n");
 758         }
 759
 760         // ALWAYS Clear Current Scene First
 761         clearscene();
 762 #ifdef WORKAROUND_XON010
 763         if(checkextension("DP_CSQC_ROTATEMOVES"))
 764         {
 765 #endif
 766         setproperty(VF_ORIGIN, view_origin);
 767         setproperty(VF_ANGLES, view_angles);
 768 #ifdef WORKAROUND_XON010
 769         }
 770 #endif
 771
 772         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 773         setproperty(VF_SIZE, vf_size);
 774         setproperty(VF_MIN, vf_min);
 775
 776         // Assign Standard Viewflags
 777         // Draw the World (and sky)
 778         setproperty(VF_DRAWWORLD, 1);
 779
 780         // Set the console size vars
 781         vid_conwidth = autocvar_vid_conwidth;
 782         vid_conheight = autocvar_vid_conheight;
 783         vid_pixelheight = autocvar_vid_pixelheight;
 784
 785         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
 786         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
 787
 788         // Camera for demo playback
 789         if(camera_active)
 790         {
 791                 if(autocvar_camera_enable)
 792                         CSQC_Demo_Camera();
 793                 else
 794                 {
 795                         cvar_set("chase_active", ftos(chase_active_backup));
 796                         cvar_set("cl_demo_mousegrab", "0");
 797                         camera_active = FALSE;
 798                 }
 799         }
 800 #ifdef CAMERATEST
 801         else if(autocvar_camera_enable)
 802 #else
 803         else if(autocvar_camera_enable && isdemo())
 804 #endif
 805         {
 806                 // Enable required Darkplaces cvars
 807                 chase_active_backup = autocvar_chase_active;
 808                 cvar_set("chase_active", "2");
 809                 cvar_set("cl_demo_mousegrab", "1");
 810                 camera_active = TRUE;
 811                 camera_mode = FALSE;
 812         }
 813
 814         // Draw the Crosshair
 815         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 816
 817         // Draw the Engine Status Bar (the default Quake HUD)
 818         setproperty(VF_DRAWENGINESBAR, 0);
 819
 820         // Update the mouse position
 821         /*
 822            mousepos_x = vid_conwidth;
 823            mousepos_y = vid_conheight;
 824            mousepos = mousepos*0.5 + getmousepos();
 825          */
 826
 827         e = self;
 828         for(self = world; (self = nextent(self)); )
 829                 if(self.draw)
 830                         self.draw();
 831         self = e;
 832
 833         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 834         renderscene();
 835
 836         // now switch to 2D drawing mode by calling a 2D drawing function
 837         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 838         // next R_RenderScene call
 839         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 840
 841         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 842         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
 843         {
 844                 // apply night vision effect
 845                 vector tc_00, tc_01, tc_10, tc_11;
 846                 vector rgb = '0 0 0';
 847
 848                 if(!nightvision_noise)
 849                 {
 850                         nightvision_noise = spawn();
 851                         nightvision_noise.classname = "nightvision_noise";
 852                 }
 853                 if(!nightvision_noise2)
 854                 {
 855                         nightvision_noise2 = spawn();
 856                         nightvision_noise2.classname = "nightvision_noise2";
 857                 }
 858
 859                 // color tint in yellow
 860                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 861
 862                 // draw BG
 863                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 864                 rgb = '1 1 1';
 865                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 866                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 867                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 868                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 869                 tc_11 = tc_01 + tc_10 - tc_00;
 870                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 871                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 872                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 873                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 874                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 875                 R_EndPolygon();
 876
 877                 // draw FG
 878                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 879                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 880                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 881                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 882                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 883                 tc_11 = tc_01 + tc_10 - tc_00;
 884                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 885                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 886                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 887                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 888                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 889                 R_EndPolygon();
 890         }
 891
 892         if(autocvar_cl_reticle)
 893         {
 894                 // Draw the aiming reticle for weapons that use it
 895                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 896                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 897                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
 898                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
 899                 {
 900                         // no zoom reticle while dead
 901                         reticle_type = 0;
 902                 }
 903                 else if(WEP_ACTION(activeweapon, WR_ZOOMRETICLE) && autocvar_cl_reticle_weapon)
 904                 {
 905                         if(reticle_image != "") { reticle_type = 2; }
 906                         else { reticle_type = 0; }
 907                 }
 908                 else if(button_zoom || zoomscript_caught)
 909                 {
 910                         // normal zoom
 911                         reticle_type = 1;
 912                 }
 913
 914                 if(reticle_type)
 915                 {
 916                         if(autocvar_cl_reticle_stretch)
 917                         {
 918                                 reticle_size_x = vid_conwidth;
 919                                 reticle_size_y = vid_conheight;
 920                                 reticle_pos_x = 0;
 921                                 reticle_pos_y = 0;
 922                         }
 923                         else
 924                         {
 925                                 reticle_size_x = max(vid_conwidth, vid_conheight);
 926                                 reticle_size_y = max(vid_conwidth, vid_conheight);
 927                                 reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 928                                 reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 929                         }
 930
 931                         if(zoomscript_caught)
 932                                 f = 1;
 933                         else
 934                                 f = current_zoomfraction;
 935
 936                         if(f)
 937                         {
 938                                 switch(reticle_type)
 939                                 {
 940                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
 941                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
 942                                 }
 943                         }
 944                 }
 945         }
 946         else
 947         {
 948                 if(reticle_type != 0) { reticle_type = 0; }
 949         }
 950
 951
 952         // improved polyblend
 953         if(autocvar_hud_contents)
 954         {
 955                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 956                 vector liquidcolor;
 957
 958                 switch(pointcontents(view_origin))
 959                 {
 960                         case CONTENT_WATER:
 961                                 liquidalpha = autocvar_hud_contents_water_alpha;
 962                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 963                                 incontent = 1;
 964                                 break;
 965
 966                         case CONTENT_LAVA:
 967                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 968                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 969                                 incontent = 1;
 970                                 break;
 971
 972                         case CONTENT_SLIME:
 973                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 974                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 975                                 incontent = 1;
 976                                 break;
 977
 978                         default:
 979                                 liquidalpha = 0;
 980                                 liquidcolor = '0 0 0';
 981                                 incontent = 0;
 982                                 break;
 983                 }
 984
 985                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 986                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 987                         contentfadetime = autocvar_hud_contents_fadeintime;
 988                         liquidalpha_prev = liquidalpha;
 989                         liquidcolor_prev = liquidcolor;
 990                 }
 991                 else
 992                         contentfadetime = autocvar_hud_contents_fadeouttime;
 993
 994                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 995                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 996
 997                 if(contentavgalpha)
 998                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 999
1000                 if(autocvar_hud_postprocessing)
1001                 {
1002                         if(autocvar_hud_contents_blur && contentavgalpha)
1003                         {
1004                                 content_blurpostprocess_x = 1;
1005                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
1006                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1007                         }
1008                         else
1009                         {
1010                                 content_blurpostprocess_x = 0;
1011                                 content_blurpostprocess_y = 0;
1012                                 content_blurpostprocess_z = 0;
1013                         }
1014                 }
1015         }
1016
1017         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
1018         {
1019                 splash_size_x = max(vid_conwidth, vid_conheight);
1020                 splash_size_y = max(vid_conwidth, vid_conheight);
1021                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
1022                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
1023
1024                 float myhealth_flash_temp;
1025                 myhealth = getstati(STAT_HEALTH);
1026
1027                 // fade out
1028                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1029                 // add new damage
1030                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1031
1032                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1033                 pain_threshold = autocvar_hud_damage_pain_threshold;
1034                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1035                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1036
1037                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1038                 {
1039                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1040                 }
1041
1042                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1043
1044                 if(myhealth_prev < 1)
1045                 {
1046                         if(myhealth >= 1)
1047                         {
1048                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1049                                 myhealth_flash_temp = 0;
1050                         }
1051                         else
1052                         {
1053                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1054                         }
1055                 }
1056
1057                 if(spectatee_status == -1 || intermission)
1058                 {
1059                         myhealth_flash = 0; // observing, or match ended
1060                         myhealth_flash_temp = 0;
1061                 }
1062
1063                 myhealth_prev = myhealth;
1064
1065                 // IDEA: change damage color/picture based on player model for robot/alien species?
1066                 // pro: matches model better
1067                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1068                 // maybe different reddish pics?
1069                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1070                 {
1071                         if(autocvar_cl_gentle_damage == 2)
1072                         {
1073                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1074                                 {
1075                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1076                                 }
1077                         }
1078                         else
1079                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1080
1081                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1082                 }
1083                 else
1084                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1085
1086                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1087                 {
1088                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1089                         {
1090                                 damage_blurpostprocess_x = 1;
1091                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1092                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1093                         }
1094                         else
1095                         {
1096                                 damage_blurpostprocess_x = 0;
1097                                 damage_blurpostprocess_y = 0;
1098                                 damage_blurpostprocess_z = 0;
1099                         }
1100                 }
1101         }
1102
1103         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1104         float e2 = (autocvar_hud_powerup != 0);
1105         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1106         {
1107                 // enable or disable rendering types if they are used or not
1108                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1109                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1110
1111                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1112                 if((damage_blurpostprocess_x || content_blurpostprocess_x))
1113                 {
1114                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
1115                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
1116                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1117                         {
1118                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1119                                 old_blurradius = blurradius;
1120                                 old_bluralpha = bluralpha;
1121                         }
1122                 }
1123                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1124                 {
1125                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1126                         old_blurradius = 0;
1127                         old_bluralpha = 0;
1128                 }
1129
1130                 // edge detection postprocess handling done second (used by hud_powerup)
1131                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1132                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1133                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1134
1135                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1136
1137                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1138                 {
1139                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1140                         {
1141                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1142                                 old_sharpen_intensity = sharpen_intensity;
1143                         }
1144                 }
1145                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1146                 {
1147                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1148                         old_sharpen_intensity = 0;
1149                 }
1150
1151                 if(cvar("r_glsl_postprocess") == 0)
1152                         cvar_set("r_glsl_postprocess", "2");
1153         }
1154         else if(cvar("r_glsl_postprocess") == 2)
1155                 cvar_set("r_glsl_postprocess", "0");
1156
1157         if(menu_visible)
1158                 menu_show();
1159
1160         /*if(gametype == MAPINFO_TYPE_CTF)
1161           {
1162           ctf_view();
1163           } else */
1164
1165         // draw 2D entities
1166         e = self;
1167         for(self = world; (self = nextent(self)); )
1168                 if(self.draw2d)
1169                         self.draw2d();
1170         self = e;
1171         Draw_ShowNames_All();
1172
1173         scoreboard_active = HUD_WouldDrawScoreboard();
1174
1175         // varying sound pitch
1176
1177         // accumulate damage with each stat update
1178         static float unaccounted_damage = 0;
1179         float unaccounted_damage_new = getstati(STAT_DAMAGE_DEALT_TOTAL);
1180         static float damage_dealt_time_prev = 0;
1181         float damage_dealt_time = getstatf(STAT_HIT_TIME);
1182         if (damage_dealt_time != damage_dealt_time_prev)
1183         {
1184                 unaccounted_damage += unaccounted_damage_new;
1185                 dprint("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
1186         }
1187         damage_dealt_time_prev = damage_dealt_time;
1188
1189         // prevent hitsound when switching spectatee
1190         static float spectatee_status_prev = 0;
1191         if (spectatee_status != spectatee_status_prev)
1192                 unaccounted_damage = 0;
1193         spectatee_status_prev = spectatee_status;
1194
1195         static float hitsound_time_prev = 0;
1196         if (COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
1197         {
1198                 if (autocvar_cl_hitsound && unaccounted_damage)
1199                 {
1200                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
1201                         float a = autocvar_cl_hitsound_max_pitch;
1202                         float b = autocvar_cl_hitsound_min_pitch;
1203                         float c = autocvar_cl_hitsound_nom_damage;
1204                         float x = unaccounted_damage;
1205                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
1206
1207                         // if sound variation is disabled, set pitch_shift to 1
1208                         if (autocvar_cl_hitsound == 1)
1209                                 pitch_shift = 1;
1210
1211                         // if pitch shift is reversed, mirror in (max-min)/2 + min
1212                         if (autocvar_cl_hitsound == 3)
1213                         {
1214                                 float mirror_value = (a-b)/2 + b;
1215                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
1216                         }
1217
1218                         dprint("dmg total (dmg): ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), "), pitch shift: ", ftos(pitch_shift), "\n");
1219
1220                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
1221                         // todo: normalize sound pressure levels? seems unnecessary
1222
1223                         sound7(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
1224                 }
1225                 unaccounted_damage = 0;
1226                 hitsound_time_prev = time;
1227         }
1228
1229         static float typehit_time_prev = 0;
1230         float typehit_time = getstatf(STAT_TYPEHIT_TIME);
1231         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
1232         {
1233                 sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
1234                 typehit_time_prev = typehit_time;
1235         }
1236
1237         //else
1238         {
1239                 if(getstati(STAT_FROZEN))
1240                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1241                 else if (getstatf(STAT_HEALING_ORB)>time)
1242                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, Nade_Color(NADE_TYPE_HEAL), autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
1243                 if(!intermission)
1244                 if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1245                 {
1246                         DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1247                         drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1248                 }
1249                 else if(getstatf(STAT_REVIVE_PROGRESS))
1250                 {
1251                         DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1252                         drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1253                 }
1254
1255                 if(autocvar_r_letterbox == 0)
1256                         if(autocvar_viewsize < 120)
1257                                 CSQC_common_hud();
1258
1259                 // crosshair goes VERY LAST
1260                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1261                 {
1262                         if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
1263                                 return;
1264
1265                         string wcross_style;
1266                         float wcross_alpha, wcross_resolution;
1267                         wcross_style = autocvar_crosshair;
1268                         if (wcross_style == "0")
1269                                 return;
1270                         wcross_resolution = autocvar_crosshair_size;
1271                         if (wcross_resolution == 0)
1272                                 return;
1273                         wcross_alpha = autocvar_crosshair_alpha;
1274                         if (wcross_alpha == 0)
1275                                 return;
1276
1277                         // TrueAim check
1278                         float shottype;
1279
1280                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1281                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1282                         wcross_origin_z = 0;
1283                         if(autocvar_crosshair_hittest)
1284                         {
1285                                 vector wcross_oldorigin;
1286                                 wcross_oldorigin = wcross_origin;
1287                                 shottype = TrueAimCheck();
1288                                 if(shottype == SHOTTYPE_HITWORLD)
1289                                 {
1290                                         v = wcross_origin - wcross_oldorigin;
1291                                         v_x /= vid_conwidth;
1292                                         v_y /= vid_conheight;
1293                                         if(vlen(v) > 0.01)
1294                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1295                                 }
1296                                 if(!autocvar_crosshair_hittest_showimpact)
1297                                         wcross_origin = wcross_oldorigin;
1298                         }
1299                         else
1300                                 shottype = SHOTTYPE_HITWORLD;
1301
1302                         vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1303                         string wcross_name = "";
1304                         float wcross_scale, wcross_blur;
1305
1306                         if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1307                         {
1308                                 e = get_weaponinfo(switchingweapon);
1309                                 if(e)
1310                                 {
1311                                         if(autocvar_crosshair_per_weapon)
1312                                         {
1313                                                 // WEAPONTODO: access these through some general settings (with non-balance config settings)
1314                                                 //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1315                                                 //if (wcross_resolution == 0)
1316                                                         //return;
1317
1318                                                 //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1319                                                 wcross_resolution *= e.w_crosshair_size;
1320                                                 wcross_name = e.w_crosshair;
1321                                         }
1322                                 }
1323                         }
1324
1325                         if(wcross_name == "")
1326                                 wcross_name = strcat("gfx/crosshair", wcross_style);
1327
1328                         // MAIN CROSSHAIR COLOR DECISION
1329                         switch(autocvar_crosshair_color_special)
1330                         {
1331                                 case 1: // crosshair_color_per_weapon
1332                                 {
1333                                         if(e)
1334                                         {
1335                                                 wcross_color = e.wpcolor;
1336                                                 break;
1337                                         }
1338                                         else { goto normalcolor; }
1339                                 }
1340
1341                                 case 2: // crosshair_color_by_health
1342                                 {
1343                                         float x = getstati(STAT_HEALTH);
1344
1345                                         //x = red
1346                                         //y = green
1347                                         //z = blue
1348
1349                                         wcross_color_z = 0;
1350
1351                                         if(x > 200)
1352                                         {
1353                                                 wcross_color_x = 0;
1354                                                 wcross_color_y = 1;
1355                                         }
1356                                         else if(x > 150)
1357                                         {
1358                                                 wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1359                                                 wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1360                                         }
1361                                         else if(x > 100)
1362                                         {
1363                                                 wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1364                                                 wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1365                                                 wcross_color_z = 1 - (x-100)*0.02;
1366                                         }
1367                                         else if(x > 50)
1368                                         {
1369                                                 wcross_color_x = 1;
1370                                                 wcross_color_y = 1;
1371                                                 wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1372                                         }
1373                                         else if(x > 20)
1374                                         {
1375                                                 wcross_color_x = 1;
1376                                                 wcross_color_y = (x-20)*90/27/100;
1377                                                 wcross_color_z = (x-20)*90/27/100 * 0.2;
1378                                         }
1379                                         else
1380                                         {
1381                                                 wcross_color_x = 1;
1382                                                 wcross_color_y = 0;
1383                                         }
1384                                         break;
1385                                 }
1386
1387                                 case 3: // crosshair_color_rainbow
1388                                 {
1389                                         if(time >= rainbow_last_flicker)
1390                                         {
1391                                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1392                                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1393                                         }
1394                                         wcross_color = rainbow_prev_color;
1395                                         break;
1396                                 }
1397                                 :normalcolor
1398                                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1399                         }
1400
1401                         if(autocvar_crosshair_effect_scalefade)
1402                         {
1403                                 wcross_scale = wcross_resolution;
1404                                 wcross_resolution = 1;
1405                         }
1406                         else
1407                         {
1408                                 wcross_scale = 1;
1409                         }
1410
1411                         if(autocvar_crosshair_pickup)
1412                         {
1413                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1414
1415                                 if(pickup_crosshair_time < stat_pickup_time)
1416                                 {
1417                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1418                                                 pickup_crosshair_size = 1;
1419
1420                                         pickup_crosshair_time = stat_pickup_time;
1421                                 }
1422
1423                                 if(pickup_crosshair_size > 0)
1424                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1425                                 else
1426                                         pickup_crosshair_size = 0;
1427
1428                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1429                         }
1430
1431                         // todo: make crosshair hit indication dependent on damage dealt
1432                         if(autocvar_crosshair_hitindication)
1433                         {
1434                                 vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1435
1436                                 if(unaccounted_damage)
1437                                 {
1438                                         hitindication_crosshair_size = 1;
1439                                 }
1440
1441                                 if(hitindication_crosshair_size > 0)
1442                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1443                                 else
1444                                         hitindication_crosshair_size = 0;
1445
1446                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1447                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1448                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1449                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1450                         }
1451
1452                         if(shottype == SHOTTYPE_HITENEMY)
1453                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1454                         if(shottype == SHOTTYPE_HITTEAM)
1455                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1456
1457                         f = fabs(autocvar_crosshair_effect_time);
1458                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1459                         {
1460                                 wcross_changedonetime = time + f;
1461                         }
1462                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1463                         {
1464                                 wcross_name_changestarttime = time;
1465                                 wcross_name_changedonetime = time + f;
1466                                 if(wcross_name_goal_prev_prev)
1467                                         strunzone(wcross_name_goal_prev_prev);
1468                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1469                                 wcross_name_goal_prev = strzone(wcross_name);
1470                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1471                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1472                                 wcross_resolution_goal_prev = wcross_resolution;
1473                         }
1474
1475                         wcross_scale_goal_prev = wcross_scale;
1476                         wcross_alpha_goal_prev = wcross_alpha;
1477                         wcross_color_goal_prev = wcross_color;
1478
1479                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1480                         {
1481                                 wcross_blur = 1;
1482                                 wcross_alpha *= 0.75;
1483                         }
1484                         else
1485                                 wcross_blur = 0;
1486                         // *_prev is at time-frametime
1487                         // * is at wcross_changedonetime+f
1488                         // what do we have at time?
1489                         if(time < wcross_changedonetime)
1490                         {
1491                                 f = frametime / (wcross_changedonetime - time + frametime);
1492                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1493                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1494                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1495                         }
1496
1497                         wcross_scale_prev = wcross_scale;
1498                         wcross_alpha_prev = wcross_alpha;
1499                         wcross_color_prev = wcross_color;
1500
1501                         wcross_scale *= 1 - autocvar__menu_alpha;
1502                         wcross_alpha *= 1 - autocvar__menu_alpha;
1503                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1504
1505                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1506                         {
1507                                 // crosshair rings for weapon stats
1508                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1509                                 {
1510                                         // declarations and stats
1511                                         float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1512                                         string ring_image = string_null, ring_inner_image = string_null;
1513                                         vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1514
1515                                         ring_scale = autocvar_crosshair_ring_size;
1516
1517                                         float weapon_clipload, weapon_clipsize;
1518                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1519                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1520
1521                                         float ok_ammo_charge, ok_ammo_chargepool;
1522                                         ok_ammo_charge = getstatf(STAT_OK_AMMO_CHARGE);
1523                                         ok_ammo_chargepool = getstatf(STAT_OK_AMMO_CHARGEPOOl);
1524
1525                                         float vortex_charge, vortex_chargepool;
1526                                         vortex_charge = getstatf(STAT_VORTEX_CHARGE);
1527                                         vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
1528
1529                                         float arc_heat = getstatf(STAT_ARC_HEAT);
1530
1531                                         if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1532                                                 vortex_charge_movingavg = vortex_charge;
1533
1534
1535                                         // handle the values
1536                                         if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1537                                         {
1538                                                 if (vortex_chargepool || use_vortex_chargepool) {
1539                                                         use_vortex_chargepool = 1;
1540                                                         ring_inner_value = vortex_chargepool;
1541                                                 } else {
1542                                                         vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1543                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1544                                                 }
1545
1546                                                 ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1547                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1548                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1549
1550                                                 // draw the outer ring to show the current charge of the weapon
1551                                                 ring_value = vortex_charge;
1552                                                 ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1553                                                 ring_rgb = wcross_color;
1554                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1555                                         }
1556                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1557                                         {
1558                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1559                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1560                                                 ring_rgb = wcross_color;
1561                                                 ring_image = "gfx/crosshair_ring.tga";
1562                                         }
1563                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1564                                         {
1565                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1566                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1567                                                 ring_rgb = wcross_color;
1568                                                 ring_image = "gfx/crosshair_ring.tga";
1569                                         }
1570                                         else if (ok_ammo_charge)
1571                                         {
1572                                                 ring_value = ok_ammo_chargepool;
1573                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1574                                                 ring_rgb = wcross_color;
1575                                                 ring_image = "gfx/crosshair_ring.tga";
1576                                         }
1577                                         else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1578                                         {
1579                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1580                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1581                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1582                                                 ring_rgb = wcross_color;
1583
1584                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1585                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1586                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1587                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1588                                                 else
1589                                                         ring_image = "gfx/crosshair_ring.tga";
1590                                         }
1591                                         else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
1592                                         {
1593                                                 ring_value = arc_heat;
1594                                                 ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1595                                                         arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1596                                                 ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1597                                                 ring_image = "gfx/crosshair_ring.tga";
1598                                         }
1599
1600                                         // if in weapon switch animation, fade ring out/in
1601                                         if(autocvar_crosshair_effect_time > 0)
1602                                         {
1603                                                 f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1604                                                 if (!(f < 1))
1605                                                 {
1606                                                         wcross_ring_prev = ((ring_image) ? TRUE : FALSE);
1607                                                 }
1608
1609                                                 if(wcross_ring_prev)
1610                                                 {
1611                                                         if(f < 1)
1612                                                                 ring_alpha *= fabs(1 - bound(0, f, 1));
1613                                                 }
1614                                                 else
1615                                                 {
1616                                                         if(f < 1)
1617                                                                 ring_alpha *= bound(0, f, 1);
1618                                                 }
1619                                         }
1620
1621                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1622                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1623
1624                                         if (ring_value)
1625                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1626                                 }
1627
1628 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1629                                 do \
1630                                 { \
1631                                         if(wcross_blur > 0) \
1632                                         { \
1633                                                 for(i = -2; i <= 2; ++i) \
1634                                                 for(j = -2; j <= 2; ++j) \
1635                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1636                                         } \
1637                                         else \
1638                                         { \
1639                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1640                                         } \
1641                                 } \
1642                                 while(0)
1643
1644 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1645                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1646
1647 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1648                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1649
1650                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1651                                 {
1652                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1653                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1654                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1655                                         f = 1 - f;
1656                                 }
1657                                 else
1658                                 {
1659                                         f = 1;
1660                                 }
1661                                 wcross_name_alpha_goal_prev = f;
1662
1663                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1664                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1665
1666                                 if(autocvar_crosshair_dot)
1667                                 {
1668                                         vector wcross_color_old;
1669                                         wcross_color_old = wcross_color;
1670
1671                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1672                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1673
1674                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1675                                         // FIXME why don't we use wcross_alpha here?cl_notice_run();
1676                                         wcross_color = wcross_color_old;
1677                                 }
1678                         }
1679                 }
1680                 else
1681                 {
1682                         wcross_scale_prev = 0;
1683                         wcross_alpha_prev = 0;
1684                         wcross_scale_goal_prev = 0;
1685                         wcross_alpha_goal_prev = 0;
1686                         wcross_changedonetime = 0;
1687                         if(wcross_name_goal_prev)
1688                                 strunzone(wcross_name_goal_prev);
1689                         wcross_name_goal_prev = string_null;
1690                         if(wcross_name_goal_prev_prev)
1691                                 strunzone(wcross_name_goal_prev_prev);
1692                         wcross_name_goal_prev_prev = string_null;
1693                         wcross_name_changestarttime = 0;
1694                         wcross_name_changedonetime = 0;
1695                         wcross_name_alpha_goal_prev = 0;
1696                         wcross_name_alpha_goal_prev_prev = 0;
1697                         wcross_resolution_goal_prev = 0;
1698                         wcross_resolution_goal_prev_prev = 0;
1699                 }
1700         }
1701
1702         if(NextFrameCommand)
1703         {
1704                 localcmd("\n", NextFrameCommand, "\n");
1705                 NextFrameCommand = string_null;
1706         }
1707
1708         // we must do this check AFTER a frame was rendered, or it won't work
1709         if(cs_project_is_b0rked == 0)
1710         {
1711                 string w0, h0;
1712                 w0 = ftos(autocvar_vid_conwidth);
1713                 h0 = ftos(autocvar_vid_conheight);
1714                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1715                 //setproperty(VF_FOV, '90 90 0');
1716                 setproperty(VF_ORIGIN, '0 0 0');
1717                 setproperty(VF_ANGLES, '0 0 0');
1718                 setproperty(VF_PERSPECTIVE, 1);
1719                 makevectors('0 0 0');
1720                 vector v1, v2;
1721                 cvar_set("vid_conwidth", "800");
1722                 cvar_set("vid_conheight", "600");
1723                 v1 = cs_project(v_forward);
1724                 cvar_set("vid_conwidth", "640");
1725                 cvar_set("vid_conheight", "480");
1726                 v2 = cs_project(v_forward);
1727                 if(v1 == v2)
1728                         cs_project_is_b0rked = 1;
1729                 else
1730                         cs_project_is_b0rked = -1;
1731                 cvar_set("vid_conwidth", w0);
1732                 cvar_set("vid_conheight", h0);
1733         }
1734
1735         if(autocvar__hud_configure)
1736                 HUD_Panel_Mouse();
1737
1738     if(hud && !intermission)
1739     {
1740         if(hud == HUD_SPIDERBOT)
1741             CSQC_SPIDER_HUD();
1742         else if(hud == HUD_WAKIZASHI)
1743             CSQC_WAKIZASHI_HUD();
1744         else if(hud == HUD_RAPTOR)
1745             CSQC_RAPTOR_HUD();
1746         else if(hud == HUD_BUMBLEBEE)
1747             CSQC_BUMBLE_HUD();
1748         else if(hud == HUD_BUMBLEBEE_GUN)
1749             CSQC_BUMBLE_GUN_HUD();
1750     }
1751
1752         cl_notice_run();
1753
1754         // let's reset the view back to normal for the end
1755         setproperty(VF_MIN, '0 0 0');
1756         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1757 }
1758
1759
1760 void CSQC_common_hud(void)
1761 {
1762         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1763                 Accuracy_LoadLevels();
1764
1765         HUD_Main(); // always run these functions for alpha checks
1766         HUD_DrawScoreboard();
1767
1768         if (scoreboard_active) // scoreboard/accuracy
1769                 HUD_Reset();
1770         else if (intermission == 2) // map voting screen
1771         {
1772                 MapVote_Draw();
1773                 HUD_Reset();
1774         }
1775 }
1776
1777
1778 // following vectors must be global to allow seamless switching between camera modes
1779 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1780 void CSQC_Demo_Camera()
1781 {
1782         float speed, attenuation, dimensions;
1783         vector tmp, delta;
1784
1785         if( autocvar_camera_reset || !camera_mode )
1786         {
1787                 camera_offset = '0 0 0';
1788                 current_angles = '0 0 0';
1789                 camera_direction = '0 0 0';
1790                 camera_offset_z += 30;
1791                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1792                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1793                 current_origin = view_origin;
1794                 current_camera_offset  = camera_offset;
1795                 cvar_set("camera_reset", "0");
1796                 camera_mode = CAMERA_CHASE;
1797         }
1798
1799         // Camera angles
1800         if( camera_roll )
1801                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1802
1803         if(autocvar_camera_look_player)
1804         {
1805                 vector dir;
1806                 float n;
1807
1808                 dir = normalize(view_origin - current_position);
1809                 n = mouse_angles_z;
1810                 mouse_angles = vectoangles(dir);
1811                 mouse_angles_x = mouse_angles_x * -1;
1812                 mouse_angles_z = n;
1813         }
1814         else
1815         {
1816                 tmp = getmousepos() * 0.1;
1817                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1818                 {
1819                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1820                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1821                 }
1822         }
1823
1824         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1825         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1826         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1827         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1828
1829         // Fix difference when angles don't have the same sign
1830         delta = '0 0 0';
1831         if(mouse_angles_y < -60 && current_angles_y > 60)
1832                 delta = '0 360 0';
1833         if(mouse_angles_y > 60 && current_angles_y < -60)
1834                 delta = '0 -360 0';
1835
1836         if(autocvar_camera_look_player)
1837                 attenuation = autocvar_camera_look_attenuation;
1838         else
1839                 attenuation = autocvar_camera_speed_attenuation;
1840
1841         attenuation = 1 / max(1, attenuation);
1842         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1843
1844         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1845         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1846         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1847         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1848
1849         // Camera position
1850         tmp = '0 0 0';
1851         dimensions = 0;
1852
1853         if( camera_direction_x )
1854         {
1855                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1856                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1857                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1858                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1859                 ++dimensions;
1860         }
1861
1862         if( camera_direction_y )
1863         {
1864                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1865                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1866                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1867                 ++dimensions;
1868         }
1869
1870         if( camera_direction_z )
1871         {
1872                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1873                 ++dimensions;
1874         }
1875
1876         if(autocvar_camera_free)
1877                 speed = autocvar_camera_speed_free;
1878         else
1879                 speed = autocvar_camera_speed_chase;
1880
1881         if(dimensions)
1882         {
1883                 speed = speed * sqrt(1 / dimensions);
1884                 camera_offset += tmp * speed;
1885         }
1886
1887         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1888
1889         // Camera modes
1890         if( autocvar_camera_free )
1891         {
1892                 if ( camera_mode == CAMERA_CHASE )
1893                 {
1894                         current_camera_offset = current_origin + current_camera_offset;
1895                         camera_offset = current_origin + camera_offset;
1896                 }
1897
1898                 camera_mode = CAMERA_FREE;
1899                 current_position = current_camera_offset;
1900         }
1901         else
1902         {
1903                 if ( camera_mode == CAMERA_FREE )
1904                 {
1905                         current_origin = view_origin;
1906                         camera_offset = camera_offset - current_origin;
1907                         current_camera_offset = current_camera_offset - current_origin;
1908                 }
1909
1910                 camera_mode = CAMERA_CHASE;
1911
1912                 if(autocvar_camera_chase_smoothly)
1913                         current_origin += (view_origin - current_origin) * attenuation;
1914                 else
1915                         current_origin = view_origin;
1916
1917                 current_position = current_origin + current_camera_offset;
1918         }
1919
1920         setproperty(VF_ANGLES, current_angles);
1921         setproperty(VF_ORIGIN, current_position);
1922 }