qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 void Porto_Draw()
   4 {
   5         vector p, dir, ang, q, nextdir;
   6         float idx, portal_number, portal1_idx;
   7
   8         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
   9                 return;
  10         if(g_balance_porto_secondary)
  11                 return;
  12         if(intermission == 1)
  13                 return;
  14         if(intermission == 2)
  15                 return;
  16         if (getstati(STAT_HEALTH) <= 0)
  17                 return;
  18
  19         dir = view_forward;
  20
  21         if(angles_held_status)
  22         {
  23                 makevectors(angles_held);
  24                 dir = v_forward;
  25         }
  26
  27         p = view_origin;
  28
  29         polyline[0] = p;
  30         idx = 1;
  31         portal_number = 0;
  32         nextdir = dir;
  33
  34         for(;;)
  35         {
  36                 dir = nextdir;
  37                 traceline(p, p + 65536 * dir, TRUE, porto);
  38                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  39                         return;
  40                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  41                 p = trace_endpos;
  42                 polyline[idx] = p;
  43                 ++idx;
  44                 if(idx >= 16)
  45                         return;
  46                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  47                         continue;
  48                 ++portal_number;
  49                 ang = vectoangles2(trace_plane_normal, dir);
  50                 ang_x = -ang_x;
  51                 makevectors(ang);
  52                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  53                         return;
  54                 if(portal_number == 1)
  55                 {
  56                         portal1_idx = idx;
  57                         if(portal_number >= 2)
  58                                 break;
  59                 }
  60         }
  61
  62         while(idx >= 2)
  63         {
  64                 p = polyline[idx-2];
  65                 q = polyline[idx-1];
  66                 if(idx == 2)
  67                         p = p - view_up * 16;
  68                 if(idx-1 >= portal1_idx)
  69                 {
  70                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  71                 }
  72                 else
  73                 {
  74                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  75                 }
  76                 --idx;
  77         }
  78 }
  79
  80 void Porto_Init()
  81 {
  82         porto = spawn();
  83         porto.classname = "porto";
  84         porto.draw = Porto_Draw;
  85         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  86 }
  87
  88 float drawtime;
  89 float avgspeed;
  90 vector GetCurrentFov(float fov)
  91 {
  92         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  93         float velocityzoom, curspeed;
  94         vector v;
  95
  96         zoomsensitivity = autocvar_cl_zoomsensitivity;
  97         zoomfactor = autocvar_cl_zoomfactor;
  98         if(zoomfactor < 1 || zoomfactor > 16)
  99                 zoomfactor = 2.5;
 100         zoomspeed = autocvar_cl_zoomspeed;
 101         if(zoomspeed >= 0)
 102         if(zoomspeed < 0.5 || zoomspeed > 16)
 103                         zoomspeed = 3.5;
 104
 105         zoomdir = button_zoom;
 106         if(hud == HUD_NORMAL)
 107         if((activeweapon == WEP_VORTEX && vortex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 108                 zoomdir += button_attack2;
 109         if(spectatee_status > 0 || isdemo())
 110         {
 111                 if(spectatorbutton_zoom)
 112                 {
 113                         if(zoomdir)
 114                                 zoomdir = 0;
 115                         else
 116                                 zoomdir = 1;
 117                 }
 118                 // fteqcc failed twice here already, don't optimize this
 119         }
 120
 121         if(zoomdir) { zoomin_effect = 0; }
 122
 123         if(camera_active)
 124         {
 125                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 126         }
 127         else if(autocvar_cl_spawnzoom && zoomin_effect)
 128         {
 129                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 130
 131                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 132                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 133                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 134         }
 135         else
 136         {
 137                 if(zoomspeed < 0) // instant zoom
 138                 {
 139                         if(zoomdir)
 140                                 current_viewzoom = 1 / zoomfactor;
 141                         else
 142                                 current_viewzoom = 1;
 143                 }
 144                 else
 145                 {
 146                         if(zoomdir)
 147                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 148                         else
 149                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 150                 }
 151         }
 152
 153         if(almost_equals(current_viewzoom, 1))
 154                 current_zoomfraction = 0;
 155         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 156                 current_zoomfraction = 1;
 157         else
 158                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 159
 160         if(zoomsensitivity < 1)
 161                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 162         else
 163                 setsensitivityscale(1);
 164
 165         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 166         {
 167                 if(intermission) { curspeed = 0; }
 168                 else
 169                 {
 170
 171                         makevectors(view_angles);
 172                         v = pmove_vel;
 173                         if(csqcplayer)
 174                                 v = csqcplayer.velocity;
 175
 176                         switch(autocvar_cl_velocityzoom_type)
 177                         {
 178                                 case 3: curspeed = max(0, v_forward * v); break;
 179                                 case 2: curspeed = (v_forward * v); break;
 180                                 case 1: default: curspeed = vlen(v); break;
 181                         }
 182                 }
 183
 184                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 185                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 186                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 187
 188                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 189         }
 190         else
 191                 velocityzoom = 1;
 192
 193         float frustumx, frustumy, fovx, fovy;
 194         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 195         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 196         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 197         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 198
 199         return '1 0 0' * fovx + '0 1 0' * fovy;
 200 }
 201
 202 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 203 {
 204         float fovx, fovy;
 205         float width = (ov_worldmax_x - ov_worldmin_x);
 206         float height = (ov_worldmax_y - ov_worldmin_y);
 207         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 208         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 209         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 210         return '1 0 0' * fovx + '0 1 0' * fovy;
 211 }
 212
 213 // this function must match W_SetupShot!
 214 float zoomscript_caught;
 215
 216 vector wcross_origin;
 217 float wcross_scale_prev, wcross_alpha_prev;
 218 vector wcross_color_prev;
 219 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 220 vector wcross_color_goal_prev;
 221 float wcross_changedonetime;
 222
 223 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 224 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 225 float wcross_name_changestarttime, wcross_name_changedonetime;
 226 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 227
 228 float wcross_ring_prev;
 229
 230 entity trueaim;
 231 entity trueaim_rifle;
 232
 233 #define SHOTTYPE_HITTEAM 1
 234 #define SHOTTYPE_HITOBSTRUCTION 2
 235 #define SHOTTYPE_HITWORLD 3
 236 #define SHOTTYPE_HITENEMY 4
 237
 238 void TrueAim_Init()
 239 {
 240         trueaim = spawn();
 241         trueaim.classname = "trueaim";
 242         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 243         trueaim_rifle = spawn();
 244         trueaim_rifle.classname = "trueaim_rifle";
 245         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 246 }
 247
 248 float EnemyHitCheck()
 249 {
 250         float t, n;
 251         wcross_origin = project_3d_to_2d(trace_endpos);
 252         wcross_origin_z = 0;
 253         if(trace_ent)
 254                 n = trace_ent.entnum;
 255         else
 256                 n = trace_networkentity;
 257         if(n < 1)
 258                 return SHOTTYPE_HITWORLD;
 259         if(n > maxclients)
 260                 return SHOTTYPE_HITWORLD;
 261         t = GetPlayerColor(n - 1);
 262         if(teamplay)
 263                 if(t == myteam)
 264                         return SHOTTYPE_HITTEAM;
 265         if(t == NUM_SPECTATOR)
 266                 return SHOTTYPE_HITWORLD;
 267         return SHOTTYPE_HITENEMY;
 268 }
 269
 270 float TrueAimCheck()
 271 {
 272         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 273         vector vecs, trueaimpoint, w_shotorg;
 274         vector mi, ma, dv;
 275         float shottype;
 276         entity ta;
 277         float mv;
 278
 279         mi = ma = '0 0 0';
 280         ta = trueaim;
 281         mv = MOVE_NOMONSTERS;
 282
 283         switch(activeweapon) // WEAPONTODO
 284         {
 285                 case WEP_TUBA: // no aim
 286                 case WEP_PORTO: // shoots from eye
 287                 case WEP_HOOK: // no trueaim
 288                 case WEP_MORTAR: // toss curve
 289                         return SHOTTYPE_HITWORLD;
 290                 case WEP_VORTEX:
 291                 case WEP_VAPORIZER:
 292                         mv = MOVE_NORMAL;
 293                         break;
 294                 case WEP_RIFLE:
 295                         ta = trueaim_rifle;
 296                         mv = MOVE_NORMAL;
 297                         if(zoomscript_caught)
 298                         {
 299                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 300                                 return EnemyHitCheck();
 301                         }
 302                         break;
 303                 case WEP_DEVASTATOR: // projectile has a size!
 304                         mi = '-3 -3 -3';
 305                         ma = '3 3 3';
 306                         break;
 307                 case WEP_FIREBALL: // projectile has a size!
 308                         mi = '-16 -16 -16';
 309                         ma = '16 16 16';
 310                         break;
 311                 case WEP_SEEKER: // projectile has a size!
 312                         mi = '-2 -2 -2';
 313                         ma = '2 2 2';
 314                         break;
 315                 case WEP_ELECTRO: // projectile has a size!
 316                         mi = '0 0 -3';
 317                         ma = '0 0 -3';
 318                         break;
 319         }
 320
 321         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 322
 323         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 324
 325         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 326         trueaimpoint = trace_endpos;
 327
 328         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 329                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 330
 331         if(vecs_x > 0)
 332                 vecs_y = -vecs_y;
 333         else
 334                 vecs = '0 0 0';
 335
 336         dv = view_right * vecs_y + view_up * vecs_z;
 337         w_shotorg = traceorigin + dv;
 338
 339         // now move the vecs forward as much as requested if possible
 340         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 341         w_shotorg = trace_endpos - view_forward * nudge;
 342
 343         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 344         shottype = EnemyHitCheck();
 345         if(shottype != SHOTTYPE_HITWORLD)
 346                 return shottype;
 347
 348 #if 0
 349         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 350         // or rather, I know why, but see no fix
 351         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 352                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 353                 return SHOTTYPE_HITOBSTRUCTION;
 354 #endif
 355
 356         return SHOTTYPE_HITWORLD;
 357 }
 358
 359 void CSQC_common_hud(void);
 360
 361 void PostInit(void);
 362 void CSQC_Demo_Camera();
 363 float HUD_WouldDrawScoreboard();
 364 float camera_mode;
 365 const float CAMERA_FREE = 1;
 366 const float CAMERA_CHASE = 2;
 367 float reticle_type;
 368 string reticle_image;
 369 string NextFrameCommand;
 370 void CSQC_SPIDER_HUD();
 371 void CSQC_RAPTOR_HUD();
 372
 373 vector freeze_org, freeze_ang;
 374 entity nightvision_noise, nightvision_noise2;
 375
 376 #define MAX_TIME_DIFF 5
 377 float pickup_crosshair_time, pickup_crosshair_size;
 378 float hitindication_crosshair_size;
 379 float use_vortex_chargepool;
 380
 381 float myhealth, myhealth_prev;
 382 float myhealth_flash;
 383
 384 float old_blurradius, old_bluralpha;
 385 float old_sharpen_intensity;
 386
 387 vector myhealth_gentlergb;
 388
 389 float contentavgalpha, liquidalpha_prev;
 390 vector liquidcolor_prev;
 391
 392 float eventchase_current_distance;
 393 float eventchase_running;
 394 float WantEventchase()
 395 {
 396         if(autocvar_cl_orthoview)
 397                 return FALSE;
 398         if(intermission)
 399                 return TRUE;
 400         if(spectatee_status >= 0)
 401         {
 402                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WepSet_FromWeapon(WEP_PORTO)))
 403                         return TRUE;
 404                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
 405                 {
 406                         if(autocvar_cl_eventchase_death == 2)
 407                         {
 408                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 409                                 if(self.velocity == '0 0 0' || eventchase_running)
 410                                         return TRUE;
 411                         }
 412                         else return TRUE;
 413                 }
 414         }
 415         return FALSE;
 416 }
 417
 418 vector damage_blurpostprocess, content_blurpostprocess;
 419
 420 float checkfail[16];
 421
 422 float unaccounted_damage = 0;
 423 void UpdateDamage()
 424 {
 425         // accumulate damage with each stat update
 426         static float damage_total_prev = 0;
 427         float damage_total = getstati(STAT_DAMAGE_DEALT_TOTAL);
 428         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 429         damage_total_prev = damage_total;
 430
 431         static float damage_dealt_time_prev = 0;
 432         float damage_dealt_time = getstatf(STAT_HIT_TIME);
 433         if (damage_dealt_time != damage_dealt_time_prev)
 434         {
 435                 unaccounted_damage += unaccounted_damage_new;
 436                 dprint("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 437         }
 438         damage_dealt_time_prev = damage_dealt_time;
 439
 440         // prevent hitsound when switching spectatee
 441         static float spectatee_status_prev = 0;
 442         if (spectatee_status != spectatee_status_prev)
 443                 unaccounted_damage = 0;
 444         spectatee_status_prev = spectatee_status;
 445 }
 446
 447 void UpdateHitsound()
 448 {
 449         // varying sound pitch
 450
 451         static float hitsound_time_prev = 0;
 452         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 453         float arc_hack = activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
 454         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 455         {
 456                 if (autocvar_cl_hitsound && unaccounted_damage)
 457                 {
 458                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 459                         float a = autocvar_cl_hitsound_max_pitch;
 460                         float b = autocvar_cl_hitsound_min_pitch;
 461                         float c = autocvar_cl_hitsound_nom_damage;
 462                         float x = unaccounted_damage;
 463                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 464
 465                         // if sound variation is disabled, set pitch_shift to 1
 466                         if (autocvar_cl_hitsound == 1)
 467                                 pitch_shift = 1;
 468
 469                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 470                         if (autocvar_cl_hitsound == 3)
 471                         {
 472                                 float mirror_value = (a-b)/2 + b;
 473                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 474                         }
 475
 476                         dprint("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 477
 478                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 479                         // todo: normalize sound pressure levels? seems unnecessary
 480
 481                         sound7(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 482                 }
 483                 unaccounted_damage = 0;
 484                 hitsound_time_prev = time;
 485         }
 486
 487         static float typehit_time_prev = 0;
 488         float typehit_time = getstatf(STAT_TYPEHIT_TIME);
 489         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 490         {
 491                 sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 492                 typehit_time_prev = typehit_time;
 493         }
 494 }
 495
 496 void UpdateCrosshair()
 497 {
 498         static float rainbow_last_flicker;
 499     static vector rainbow_prev_color;
 500         entity e = self;
 501         float f, i, j;
 502         vector v;
 503         if(getstati(STAT_FROZEN))
 504                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 505         else if (getstatf(STAT_HEALING_ORB)>time)
 506                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, Nade_Color(NADE_TYPE_HEAL), autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
 507         if(!intermission)
 508         if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
 509         {
 510                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 511                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 512         }
 513         else if(getstatf(STAT_REVIVE_PROGRESS))
 514         {
 515                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 516                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 517         }
 518
 519         if(autocvar_r_letterbox == 0)
 520                 if(autocvar_viewsize < 120)
 521                         CSQC_common_hud();
 522
 523         // crosshair goes VERY LAST
 524         if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
 525         {
 526                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 527                         return;
 528
 529                 string wcross_style;
 530                 float wcross_alpha, wcross_resolution;
 531                 wcross_style = autocvar_crosshair;
 532                 if (wcross_style == "0")
 533                         return;
 534                 wcross_resolution = autocvar_crosshair_size;
 535                 if (wcross_resolution == 0)
 536                         return;
 537                 wcross_alpha = autocvar_crosshair_alpha;
 538                 if (wcross_alpha == 0)
 539                         return;
 540
 541                 // TrueAim check
 542                 float shottype;
 543
 544                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 545                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 546                 wcross_origin_z = 0;
 547                 if(autocvar_crosshair_hittest)
 548                 {
 549                         vector wcross_oldorigin;
 550                         wcross_oldorigin = wcross_origin;
 551                         shottype = TrueAimCheck();
 552                         if(shottype == SHOTTYPE_HITWORLD)
 553                         {
 554                                 v = wcross_origin - wcross_oldorigin;
 555                                 v_x /= vid_conwidth;
 556                                 v_y /= vid_conheight;
 557                                 if(vlen(v) > 0.01)
 558                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 559                         }
 560                         if(!autocvar_crosshair_hittest_showimpact)
 561                                 wcross_origin = wcross_oldorigin;
 562                 }
 563                 else
 564                         shottype = SHOTTYPE_HITWORLD;
 565
 566                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 567                 string wcross_name = "";
 568                 float wcross_scale, wcross_blur;
 569
 570                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 571                 {
 572                         e = get_weaponinfo(switchingweapon);
 573                         if(e)
 574                         {
 575                                 if(autocvar_crosshair_per_weapon)
 576                                 {
 577                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 578                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 579                                         //if (wcross_resolution == 0)
 580                                                 //return;
 581
 582                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 583                                         wcross_resolution *= e.w_crosshair_size;
 584                                         wcross_name = e.w_crosshair;
 585                                 }
 586                         }
 587                 }
 588
 589                 if(wcross_name == "")
 590                         wcross_name = strcat("gfx/crosshair", wcross_style);
 591
 592                 // MAIN CROSSHAIR COLOR DECISION
 593                 switch(autocvar_crosshair_color_special)
 594                 {
 595                         case 1: // crosshair_color_per_weapon
 596                         {
 597                                 if(e)
 598                                 {
 599                                         wcross_color = e.wpcolor;
 600                                         break;
 601                                 }
 602                                 else { goto normalcolor; }
 603                         }
 604
 605                         case 2: // crosshair_color_by_health
 606                         {
 607                                 float x = getstati(STAT_HEALTH);
 608
 609                                 //x = red
 610                                 //y = green
 611                                 //z = blue
 612
 613                                 wcross_color_z = 0;
 614
 615                                 if(x > 200)
 616                                 {
 617                                         wcross_color_x = 0;
 618                                         wcross_color_y = 1;
 619                                 }
 620                                 else if(x > 150)
 621                                 {
 622                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
 623                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
 624                                 }
 625                                 else if(x > 100)
 626                                 {
 627                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
 628                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
 629                                         wcross_color_z = 1 - (x-100)*0.02;
 630                                 }
 631                                 else if(x > 50)
 632                                 {
 633                                         wcross_color_x = 1;
 634                                         wcross_color_y = 1;
 635                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
 636                                 }
 637                                 else if(x > 20)
 638                                 {
 639                                         wcross_color_x = 1;
 640                                         wcross_color_y = (x-20)*90/27/100;
 641                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
 642                                 }
 643                                 else
 644                                 {
 645                                         wcross_color_x = 1;
 646                                         wcross_color_y = 0;
 647                                 }
 648                                 break;
 649                         }
 650
 651                         case 3: // crosshair_color_rainbow
 652                         {
 653                                 if(time >= rainbow_last_flicker)
 654                                 {
 655                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 656                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 657                                 }
 658                                 wcross_color = rainbow_prev_color;
 659                                 break;
 660                         }
 661                         :normalcolor
 662                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
 663                 }
 664
 665                 if(autocvar_crosshair_effect_scalefade)
 666                 {
 667                         wcross_scale = wcross_resolution;
 668                         wcross_resolution = 1;
 669                 }
 670                 else
 671                 {
 672                         wcross_scale = 1;
 673                 }
 674
 675                 if(autocvar_crosshair_pickup)
 676                 {
 677                         float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
 678
 679                         if(pickup_crosshair_time < stat_pickup_time)
 680                         {
 681                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
 682                                         pickup_crosshair_size = 1;
 683
 684                                 pickup_crosshair_time = stat_pickup_time;
 685                         }
 686
 687                         if(pickup_crosshair_size > 0)
 688                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 689                         else
 690                                 pickup_crosshair_size = 0;
 691
 692                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 693                 }
 694
 695                 // todo: make crosshair hit indication dependent on damage dealt
 696                 if(autocvar_crosshair_hitindication)
 697                 {
 698                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
 699
 700                         if(unaccounted_damage)
 701                         {
 702                                 hitindication_crosshair_size = 1;
 703                         }
 704
 705                         if(hitindication_crosshair_size > 0)
 706                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
 707                         else
 708                                 hitindication_crosshair_size = 0;
 709
 710                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
 711                         wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
 712                         wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
 713                         wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
 714                 }
 715
 716                 if(shottype == SHOTTYPE_HITENEMY)
 717                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
 718                 if(shottype == SHOTTYPE_HITTEAM)
 719                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
 720
 721                 f = fabs(autocvar_crosshair_effect_time);
 722                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 723                 {
 724                         wcross_changedonetime = time + f;
 725                 }
 726                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 727                 {
 728                         wcross_name_changestarttime = time;
 729                         wcross_name_changedonetime = time + f;
 730                         if(wcross_name_goal_prev_prev)
 731                                 strunzone(wcross_name_goal_prev_prev);
 732                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 733                         wcross_name_goal_prev = strzone(wcross_name);
 734                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 735                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 736                         wcross_resolution_goal_prev = wcross_resolution;
 737                 }
 738
 739                 wcross_scale_goal_prev = wcross_scale;
 740                 wcross_alpha_goal_prev = wcross_alpha;
 741                 wcross_color_goal_prev = wcross_color;
 742
 743                 if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
 744                 {
 745                         wcross_blur = 1;
 746                         wcross_alpha *= 0.75;
 747                 }
 748                 else
 749                         wcross_blur = 0;
 750                 // *_prev is at time-frametime
 751                 // * is at wcross_changedonetime+f
 752                 // what do we have at time?
 753                 if(time < wcross_changedonetime)
 754                 {
 755                         f = frametime / (wcross_changedonetime - time + frametime);
 756                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 757                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 758                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 759                 }
 760
 761                 wcross_scale_prev = wcross_scale;
 762                 wcross_alpha_prev = wcross_alpha;
 763                 wcross_color_prev = wcross_color;
 764
 765                 wcross_scale *= 1 - autocvar__menu_alpha;
 766                 wcross_alpha *= 1 - autocvar__menu_alpha;
 767                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 768
 769                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
 770                 {
 771                         // crosshair rings for weapon stats
 772                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
 773                         {
 774                                 // declarations and stats
 775                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
 776                                 string ring_image = string_null, ring_inner_image = string_null;
 777                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
 778
 779                                 ring_scale = autocvar_crosshair_ring_size;
 780
 781                                 float weapon_clipload, weapon_clipsize;
 782                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
 783                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
 784
 785                                 float ok_ammo_charge, ok_ammo_chargepool;
 786                                 ok_ammo_charge = getstatf(STAT_OK_AMMO_CHARGE);
 787                                 ok_ammo_chargepool = getstatf(STAT_OK_AMMO_CHARGEPOOl);
 788
 789                                 float vortex_charge, vortex_chargepool;
 790                                 vortex_charge = getstatf(STAT_VORTEX_CHARGE);
 791                                 vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
 792
 793                                 float arc_heat = getstatf(STAT_ARC_HEAT);
 794
 795                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
 796                                         vortex_charge_movingavg = vortex_charge;
 797
 798
 799                                 // handle the values
 800                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
 801                                 {
 802                                         if (vortex_chargepool || use_vortex_chargepool) {
 803                                                 use_vortex_chargepool = 1;
 804                                                 ring_inner_value = vortex_chargepool;
 805                                         } else {
 806                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
 807                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
 808                                         }
 809
 810                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
 811                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
 812                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
 813
 814                                         // draw the outer ring to show the current charge of the weapon
 815                                         ring_value = vortex_charge;
 816                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
 817                                         ring_rgb = wcross_color;
 818                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
 819                                 }
 820                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
 821                                 {
 822                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
 823                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
 824                                         ring_rgb = wcross_color;
 825                                         ring_image = "gfx/crosshair_ring.tga";
 826                                 }
 827                                 else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
 828                                 {
 829                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
 830                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
 831                                         ring_rgb = wcross_color;
 832                                         ring_image = "gfx/crosshair_ring.tga";
 833                                 }
 834                                 else if (ok_ammo_charge)
 835                                 {
 836                                         ring_value = ok_ammo_chargepool;
 837                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 838                                         ring_rgb = wcross_color;
 839                                         ring_image = "gfx/crosshair_ring.tga";
 840                                 }
 841                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
 842                                 {
 843                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
 844                                         ring_scale = autocvar_crosshair_ring_reload_size;
 845                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 846                                         ring_rgb = wcross_color;
 847
 848                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
 849                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
 850                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
 851                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
 852                                         else
 853                                                 ring_image = "gfx/crosshair_ring.tga";
 854                                 }
 855                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
 856                                 {
 857                                         ring_value = arc_heat;
 858                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
 859                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
 860                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
 861                                         ring_image = "gfx/crosshair_ring.tga";
 862                                 }
 863
 864                                 // if in weapon switch animation, fade ring out/in
 865                                 if(autocvar_crosshair_effect_time > 0)
 866                                 {
 867                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
 868                                         if (!(f < 1))
 869                                         {
 870                                                 wcross_ring_prev = ((ring_image) ? TRUE : FALSE);
 871                                         }
 872
 873                                         if(wcross_ring_prev)
 874                                         {
 875                                                 if(f < 1)
 876                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
 877                                         }
 878                                         else
 879                                         {
 880                                                 if(f < 1)
 881                                                         ring_alpha *= bound(0, f, 1);
 882                                         }
 883                                 }
 884
 885                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
 886                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
 887
 888                                 if (ring_value)
 889                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
 890                         }
 891
 892 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 893                         do \
 894                         { \
 895                                 if(wcross_blur > 0) \
 896                                 { \
 897                                         for(i = -2; i <= 2; ++i) \
 898                                         for(j = -2; j <= 2; ++j) \
 899                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 900                                 } \
 901                                 else \
 902                                 { \
 903                                         M(0,0,sz,wcross_name,wcross_alpha); \
 904                                 } \
 905                         } \
 906                         while(0)
 907
 908 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 909                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 910
 911 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 912                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 913
 914                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 915                         {
 916                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 917                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 918                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 919                                 f = 1 - f;
 920                         }
 921                         else
 922                         {
 923                                 f = 1;
 924                         }
 925                         wcross_name_alpha_goal_prev = f;
 926
 927                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 928                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 929
 930                         if(autocvar_crosshair_dot)
 931                         {
 932                                 vector wcross_color_old;
 933                                 wcross_color_old = wcross_color;
 934
 935                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
 936                                         wcross_color = stov(autocvar_crosshair_dot_color);
 937
 938                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
 939                                 // FIXME why don't we use wcross_alpha here?cl_notice_run();
 940                                 wcross_color = wcross_color_old;
 941                         }
 942                 }
 943         }
 944         else
 945         {
 946                 wcross_scale_prev = 0;
 947                 wcross_alpha_prev = 0;
 948                 wcross_scale_goal_prev = 0;
 949                 wcross_alpha_goal_prev = 0;
 950                 wcross_changedonetime = 0;
 951                 if(wcross_name_goal_prev)
 952                         strunzone(wcross_name_goal_prev);
 953                 wcross_name_goal_prev = string_null;
 954                 if(wcross_name_goal_prev_prev)
 955                         strunzone(wcross_name_goal_prev_prev);
 956                 wcross_name_goal_prev_prev = string_null;
 957                 wcross_name_changestarttime = 0;
 958                 wcross_name_changedonetime = 0;
 959                 wcross_name_alpha_goal_prev = 0;
 960                 wcross_name_alpha_goal_prev_prev = 0;
 961                 wcross_resolution_goal_prev = 0;
 962                 wcross_resolution_goal_prev_prev = 0;
 963         }
 964 }
 965
 966 #define BUTTON_3 4
 967 #define BUTTON_4 8
 968 float cl_notice_run();
 969 float prev_myteam;
 970 void CSQC_UpdateView(float w, float h)
 971 {
 972         entity e;
 973         float fov;
 974         float f, i;
 975         vector vf_size, vf_min;
 976         float a;
 977
 978         execute_next_frame();
 979
 980         ++framecount;
 981
 982         hud = getstati(STAT_HUD);
 983
 984         if(autocvar__hud_showbinds_reload) // menu can set this one
 985         {
 986                 db_close(binddb);
 987                 binddb = db_create();
 988                 cvar_set("_hud_showbinds_reload", "0");
 989         }
 990
 991         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 992                 view_quality = getproperty(VF_MINFPS_QUALITY);
 993         else
 994                 view_quality = 1;
 995
 996         button_attack2 = (input_buttons & BUTTON_3);
 997         button_zoom = (input_buttons & BUTTON_4);
 998
 999 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
1000         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
1001         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
1002         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
1003         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
1004         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
1005         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
1006         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
1007
1008         vf_size = getpropertyvec(VF_SIZE);
1009         vf_min = getpropertyvec(VF_MIN);
1010         vid_width = vf_size_x;
1011         vid_height = vf_size_y;
1012
1013         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1014         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1015
1016         WaypointSprite_Load();
1017
1018         CSQCPlayer_SetCamera();
1019
1020         myteam = GetPlayerColor(player_localentnum - 1);
1021
1022         if(myteam != prev_myteam)
1023         {
1024                 myteamcolors = colormapPaletteColor(myteam, 1);
1025                 for(i = 0; i < HUD_PANEL_NUM; ++i)
1026                         hud_panel[i].update_time = time;
1027                 prev_myteam = myteam;
1028         }
1029
1030         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
1031
1032         float is_dead = (getstati(STAT_HEALTH) <= 0);
1033
1034         // FIXME do we need this hack?
1035         if(isdemo())
1036         {
1037                 // in demos, input_buttons do not work
1038                 button_zoom = (autocvar__togglezoom == "-");
1039         }
1040         else if(button_zoom
1041                 && autocvar_cl_unpress_zoom_on_death
1042                 && (spectatee_status >= 0)
1043                 && (is_dead || intermission))
1044         {
1045                 // no zoom while dead or in intermission please
1046                 localcmd("-zoom\n");
1047                 button_zoom = FALSE;
1048         }
1049
1050         // event chase camera
1051         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1052         {
1053                 if(WantEventchase())
1054                 {
1055                         eventchase_running = TRUE;
1056
1057                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1058                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1059
1060                         // detect maximum viewoffset and use it
1061                         if(autocvar_cl_eventchase_viewoffset)
1062                         {
1063                                 WarpZone_TraceLine(current_view_origin, current_view_origin + autocvar_cl_eventchase_viewoffset + ('0 0 1' * autocvar_cl_eventchase_maxs_z), MOVE_WORLDONLY, self);
1064                                 if(trace_fraction == 1) { current_view_origin += autocvar_cl_eventchase_viewoffset; }
1065                                 else { current_view_origin_z += max(0, (trace_endpos_z - current_view_origin_z) - autocvar_cl_eventchase_maxs_z); }
1066                         }
1067
1068                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1069                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1070                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1071                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1072
1073                         // make the camera smooth back
1074                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
1075                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1076                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
1077                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
1078
1079                         makevectors(view_angles);
1080
1081                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1082                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1083
1084                         // If the boxtrace fails, revert back to line tracing.
1085                         if(trace_startsolid)
1086                         {
1087                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1088                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1089                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins_z)));
1090                         }
1091                         else { setproperty(VF_ORIGIN, trace_endpos); }
1092
1093                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1094                 }
1095                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1096                 {
1097                         eventchase_running = FALSE;
1098                         cvar_set("chase_active", "0");
1099                         eventchase_current_distance = 0; // start from 0 next time
1100                 }
1101         }
1102         // workaround for camera stuck between player's legs when using chase_active 1
1103         // because the engine stops updating the chase_active camera when the game ends
1104         else if(intermission)
1105         {
1106                 cvar_settemp("chase_active", "-1");
1107                 eventchase_current_distance = 0;
1108         }
1109
1110         // do lockview after event chase camera so that it still applies whenever necessary.
1111         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
1112         {
1113                 setproperty(VF_ORIGIN, freeze_org);
1114                 setproperty(VF_ANGLES, freeze_ang);
1115         }
1116         else
1117         {
1118                 freeze_org = getpropertyvec(VF_ORIGIN);
1119                 freeze_ang = getpropertyvec(VF_ANGLES);
1120         }
1121
1122         WarpZone_FixView();
1123         //WarpZone_FixPMove();
1124
1125         vector ov_org = '0 0 0';
1126         vector ov_mid = '0 0 0';
1127         vector ov_worldmin = '0 0 0';
1128         vector ov_worldmax = '0 0 0';
1129         if(autocvar_cl_orthoview)
1130         {
1131                 ov_worldmin = mi_picmin;
1132                 ov_worldmax = mi_picmax;
1133
1134                 float ov_width = (ov_worldmax_x - ov_worldmin_x);
1135                 float ov_height = (ov_worldmax_y - ov_worldmin_y);
1136                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1137
1138                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1139                 ov_org = vec3(ov_mid_x, ov_mid_y, (ov_mid_z + ov_distance));
1140
1141                 float ov_nearest = vlen(ov_org - vec3(
1142                         bound(ov_worldmin_x, ov_org_x, ov_worldmax_x),
1143                         bound(ov_worldmin_y, ov_org_y, ov_worldmax_y),
1144                         bound(ov_worldmin_z, ov_org_z, ov_worldmax_z)
1145                 ));
1146
1147                 float ov_furthest = 0;
1148                 float dist = 0;
1149
1150                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmin_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1151                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmin_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1152                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmax_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1153                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmin_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1154                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmax_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1155                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmax_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1156                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmin_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1157                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmax_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1158
1159                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1160                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1161                 cvar_settemp("r_farclip_world", "0");
1162                 cvar_settemp("r_novis", "1");
1163                 cvar_settemp("r_useportalculling", "0");
1164                 cvar_settemp("r_useinfinitefarclip", "0");
1165
1166                 setproperty(VF_ORIGIN, ov_org);
1167                 setproperty(VF_ANGLES, '90 0 0');
1168
1169                 #if 0
1170                 printf("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1171                         vtos(ov_org),
1172                         vtos(getpropertyvec(VF_ANGLES)),
1173                         ov_distance,
1174                         ov_nearest,
1175                         ov_furthest);
1176                 #endif
1177         }
1178
1179         // Render the Scene
1180         view_origin = getpropertyvec(VF_ORIGIN);
1181         view_angles = getpropertyvec(VF_ANGLES);
1182         makevectors(view_angles);
1183         view_forward = v_forward;
1184         view_right = v_right;
1185         view_up = v_up;
1186
1187 #ifdef BLURTEST
1188         if(time > blurtest_time0 && time < blurtest_time1)
1189         {
1190                 float r, t;
1191
1192                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1193                 r = t * blurtest_radius;
1194                 f = 1 / pow(t, blurtest_power) - 1;
1195
1196                 cvar_set("r_glsl_postprocess", "1");
1197                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1198         }
1199         else
1200         {
1201                 cvar_set("r_glsl_postprocess", "0");
1202                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1203         }
1204 #endif
1205
1206         TargetMusic_Advance();
1207         Fog_Force();
1208
1209         if(drawtime == 0)
1210                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1211         else
1212                 drawframetime = bound(0.000001, time - drawtime, 1);
1213         drawtime = time;
1214
1215         // watch for gametype changes here...
1216         // in ParseStuffCMD the cmd isn't executed yet :/
1217         // might even be better to add the gametype to TE_CSQC_INIT...?
1218         if(!postinit)
1219                 PostInit();
1220
1221         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1222         {
1223                 if(calledhooks & HOOK_START)
1224                 {
1225                         localcmd("\ncl_hook_gameend\n");
1226                         calledhooks |= HOOK_END;
1227                 }
1228         }
1229
1230         Announcer();
1231
1232         fov = autocvar_fov;
1233         if(fov <= 59.5)
1234         {
1235                 if(!zoomscript_caught)
1236                 {
1237                         localcmd("+button9\n");
1238                         zoomscript_caught = 1;
1239                 }
1240         }
1241         else
1242         {
1243                 if(zoomscript_caught)
1244                 {
1245                         localcmd("-button9\n");
1246                         zoomscript_caught = 0;
1247                 }
1248         }
1249
1250         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1251
1252         // next WANTED weapon (for HUD)
1253         switchweapon = getstati(STAT_SWITCHWEAPON);
1254
1255         // currently switching-to weapon (for crosshair)
1256         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
1257
1258         // actually active weapon (for zoom)
1259         activeweapon = getstati(STAT_ACTIVEWEAPON);
1260
1261         f = (serverflags & SERVERFLAG_TEAMPLAY);
1262         if(f != teamplay)
1263         {
1264                 teamplay = f;
1265                 HUD_InitScores();
1266         }
1267
1268         if(last_switchweapon != switchweapon)
1269         {
1270                 weapontime = time;
1271                 last_switchweapon = switchweapon;
1272                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1273                 {
1274                         localcmd("-zoom\n");
1275                         button_zoom = FALSE;
1276                 }
1277                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1278                 {
1279                         localcmd("-fire\n");
1280                         localcmd("-fire2\n");
1281                         button_attack2 = FALSE;
1282                 }
1283         }
1284         if(last_activeweapon != activeweapon)
1285         {
1286                 last_activeweapon = activeweapon;
1287
1288                 e = get_weaponinfo(activeweapon);
1289                 if(e.netname != "")
1290                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1291                 else
1292                         localcmd("\ncl_hook_activeweapon none\n");
1293         }
1294
1295         // ALWAYS Clear Current Scene First
1296         clearscene();
1297
1298         setproperty(VF_ORIGIN, view_origin);
1299         setproperty(VF_ANGLES, view_angles);
1300
1301         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1302         setproperty(VF_SIZE, vf_size);
1303         setproperty(VF_MIN, vf_min);
1304
1305         // Assign Standard Viewflags
1306         // Draw the World (and sky)
1307         setproperty(VF_DRAWWORLD, 1);
1308
1309         // Set the console size vars
1310         vid_conwidth = autocvar_vid_conwidth;
1311         vid_conheight = autocvar_vid_conheight;
1312         vid_pixelheight = autocvar_vid_pixelheight;
1313
1314         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1315         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1316
1317         // Camera for demo playback
1318         if(camera_active)
1319         {
1320                 if(autocvar_camera_enable)
1321                         CSQC_Demo_Camera();
1322                 else
1323                 {
1324                         cvar_set("chase_active", ftos(chase_active_backup));
1325                         cvar_set("cl_demo_mousegrab", "0");
1326                         camera_active = FALSE;
1327                 }
1328         }
1329 #ifdef CAMERATEST
1330         else if(autocvar_camera_enable)
1331 #else
1332         else if(autocvar_camera_enable && isdemo())
1333 #endif
1334         {
1335                 // Enable required Darkplaces cvars
1336                 chase_active_backup = autocvar_chase_active;
1337                 cvar_set("chase_active", "2");
1338                 cvar_set("cl_demo_mousegrab", "1");
1339                 camera_active = TRUE;
1340                 camera_mode = FALSE;
1341         }
1342
1343         // Draw the Crosshair
1344         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1345
1346         // Draw the Engine Status Bar (the default Quake HUD)
1347         setproperty(VF_DRAWENGINESBAR, 0);
1348
1349         // Update the mouse position
1350         /*
1351            mousepos_x = vid_conwidth;
1352            mousepos_y = vid_conheight;
1353            mousepos = mousepos*0.5 + getmousepos();
1354          */
1355
1356         e = self;
1357         for(self = world; (self = nextent(self)); )
1358                 if(self.draw)
1359                         self.draw();
1360         self = e;
1361
1362         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1363         renderscene();
1364
1365         // now switch to 2D drawing mode by calling a 2D drawing function
1366         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1367         // next R_RenderScene call
1368         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1369
1370         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1371         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1372         {
1373                 // apply night vision effect
1374                 vector tc_00, tc_01, tc_10, tc_11;
1375                 vector rgb = '0 0 0';
1376
1377                 if(!nightvision_noise)
1378                 {
1379                         nightvision_noise = spawn();
1380                         nightvision_noise.classname = "nightvision_noise";
1381                 }
1382                 if(!nightvision_noise2)
1383                 {
1384                         nightvision_noise2 = spawn();
1385                         nightvision_noise2.classname = "nightvision_noise2";
1386                 }
1387
1388                 // color tint in yellow
1389                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1390
1391                 // draw BG
1392                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1393                 rgb = '1 1 1';
1394                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1395                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1396                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1397                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1398                 tc_11 = tc_01 + tc_10 - tc_00;
1399                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1400                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1401                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1402                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1403                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1404                 R_EndPolygon();
1405
1406                 // draw FG
1407                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1408                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1409                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1410                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1411                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1412                 tc_11 = tc_01 + tc_10 - tc_00;
1413                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1414                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1415                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1416                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1417                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1418                 R_EndPolygon();
1419         }
1420
1421         if(autocvar_cl_reticle)
1422         {
1423                 // Draw the aiming reticle for weapons that use it
1424                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1425                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1426                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1427                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1428                 {
1429                         // no zoom reticle while dead
1430                         reticle_type = 0;
1431                 }
1432                 else if(WEP_ACTION(activeweapon, WR_ZOOMRETICLE) && autocvar_cl_reticle_weapon)
1433                 {
1434                         if(reticle_image != "") { reticle_type = 2; }
1435                         else { reticle_type = 0; }
1436                 }
1437                 else if(button_zoom || zoomscript_caught)
1438                 {
1439                         // normal zoom
1440                         reticle_type = 1;
1441                 }
1442
1443                 if(reticle_type)
1444                 {
1445                         if(autocvar_cl_reticle_stretch)
1446                         {
1447                                 reticle_size_x = vid_conwidth;
1448                                 reticle_size_y = vid_conheight;
1449                                 reticle_pos_x = 0;
1450                                 reticle_pos_y = 0;
1451                         }
1452                         else
1453                         {
1454                                 reticle_size_x = max(vid_conwidth, vid_conheight);
1455                                 reticle_size_y = max(vid_conwidth, vid_conheight);
1456                                 reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
1457                                 reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
1458                         }
1459
1460                         if(zoomscript_caught)
1461                                 f = 1;
1462                         else
1463                                 f = current_zoomfraction;
1464
1465                         if(f)
1466                         {
1467                                 switch(reticle_type)
1468                                 {
1469                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1470                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1471                                 }
1472                         }
1473                 }
1474         }
1475         else
1476         {
1477                 if(reticle_type != 0) { reticle_type = 0; }
1478         }
1479
1480
1481         // improved polyblend
1482         if(autocvar_hud_contents)
1483         {
1484                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1485                 vector liquidcolor;
1486
1487                 switch(pointcontents(view_origin))
1488                 {
1489                         case CONTENT_WATER:
1490                                 liquidalpha = autocvar_hud_contents_water_alpha;
1491                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1492                                 incontent = 1;
1493                                 break;
1494
1495                         case CONTENT_LAVA:
1496                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1497                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1498                                 incontent = 1;
1499                                 break;
1500
1501                         case CONTENT_SLIME:
1502                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1503                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1504                                 incontent = 1;
1505                                 break;
1506
1507                         default:
1508                                 liquidalpha = 0;
1509                                 liquidcolor = '0 0 0';
1510                                 incontent = 0;
1511                                 break;
1512                 }
1513
1514                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1515                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1516                         contentfadetime = autocvar_hud_contents_fadeintime;
1517                         liquidalpha_prev = liquidalpha;
1518                         liquidcolor_prev = liquidcolor;
1519                 }
1520                 else
1521                         contentfadetime = autocvar_hud_contents_fadeouttime;
1522
1523                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1524                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1525
1526                 if(contentavgalpha)
1527                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1528
1529                 if(autocvar_hud_postprocessing)
1530                 {
1531                         if(autocvar_hud_contents_blur && contentavgalpha)
1532                         {
1533                                 content_blurpostprocess_x = 1;
1534                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
1535                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1536                         }
1537                         else
1538                         {
1539                                 content_blurpostprocess_x = 0;
1540                                 content_blurpostprocess_y = 0;
1541                                 content_blurpostprocess_z = 0;
1542                         }
1543                 }
1544         }
1545
1546         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
1547         {
1548                 splash_size_x = max(vid_conwidth, vid_conheight);
1549                 splash_size_y = max(vid_conwidth, vid_conheight);
1550                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
1551                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
1552
1553                 float myhealth_flash_temp;
1554                 myhealth = getstati(STAT_HEALTH);
1555
1556                 // fade out
1557                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1558                 // add new damage
1559                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1560
1561                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1562                 pain_threshold = autocvar_hud_damage_pain_threshold;
1563                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1564                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1565
1566                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1567                 {
1568                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1569                 }
1570
1571                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1572
1573                 if(myhealth_prev < 1)
1574                 {
1575                         if(myhealth >= 1)
1576                         {
1577                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1578                                 myhealth_flash_temp = 0;
1579                         }
1580                         else
1581                         {
1582                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1583                         }
1584                 }
1585
1586                 if(spectatee_status == -1 || intermission)
1587                 {
1588                         myhealth_flash = 0; // observing, or match ended
1589                         myhealth_flash_temp = 0;
1590                 }
1591
1592                 myhealth_prev = myhealth;
1593
1594                 // IDEA: change damage color/picture based on player model for robot/alien species?
1595                 // pro: matches model better
1596                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1597                 // maybe different reddish pics?
1598                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1599                 {
1600                         if(autocvar_cl_gentle_damage == 2)
1601                         {
1602                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1603                                 {
1604                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1605                                 }
1606                         }
1607                         else
1608                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1609
1610                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1611                 }
1612                 else
1613                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1614
1615                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1616                 {
1617                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1618                         {
1619                                 damage_blurpostprocess_x = 1;
1620                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1621                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1622                         }
1623                         else
1624                         {
1625                                 damage_blurpostprocess_x = 0;
1626                                 damage_blurpostprocess_y = 0;
1627                                 damage_blurpostprocess_z = 0;
1628                         }
1629                 }
1630         }
1631
1632         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1633         float e2 = (autocvar_hud_powerup != 0);
1634         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1635         {
1636                 // enable or disable rendering types if they are used or not
1637                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1638                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1639
1640                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1641                 if((damage_blurpostprocess_x || content_blurpostprocess_x))
1642                 {
1643                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
1644                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
1645                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1646                         {
1647                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1648                                 old_blurradius = blurradius;
1649                                 old_bluralpha = bluralpha;
1650                         }
1651                 }
1652                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1653                 {
1654                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1655                         old_blurradius = 0;
1656                         old_bluralpha = 0;
1657                 }
1658
1659                 // edge detection postprocess handling done second (used by hud_powerup)
1660                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1661                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1662                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1663
1664                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1665
1666                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1667                 {
1668                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1669                         {
1670                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1671                                 old_sharpen_intensity = sharpen_intensity;
1672                         }
1673                 }
1674                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1675                 {
1676                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1677                         old_sharpen_intensity = 0;
1678                 }
1679
1680                 if(cvar("r_glsl_postprocess") == 0)
1681                         cvar_set("r_glsl_postprocess", "2");
1682         }
1683         else if(cvar("r_glsl_postprocess") == 2)
1684                 cvar_set("r_glsl_postprocess", "0");
1685
1686         if(menu_visible)
1687                 menu_show();
1688
1689         /*if(gametype == MAPINFO_TYPE_CTF)
1690           {
1691           ctf_view();
1692           } else */
1693
1694         // draw 2D entities
1695         e = self;
1696         for(self = world; (self = nextent(self)); )
1697                 if(self.draw2d)
1698                         self.draw2d();
1699         self = e;
1700         Draw_ShowNames_All();
1701
1702         scoreboard_active = HUD_WouldDrawScoreboard();
1703
1704         UpdateDamage();
1705         UpdateHitsound();
1706         UpdateCrosshair();
1707
1708         if(NextFrameCommand)
1709         {
1710                 localcmd("\n", NextFrameCommand, "\n");
1711                 NextFrameCommand = string_null;
1712         }
1713
1714         // we must do this check AFTER a frame was rendered, or it won't work
1715         if(cs_project_is_b0rked == 0)
1716         {
1717                 string w0, h0;
1718                 w0 = ftos(autocvar_vid_conwidth);
1719                 h0 = ftos(autocvar_vid_conheight);
1720                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1721                 //setproperty(VF_FOV, '90 90 0');
1722                 setproperty(VF_ORIGIN, '0 0 0');
1723                 setproperty(VF_ANGLES, '0 0 0');
1724                 setproperty(VF_PERSPECTIVE, 1);
1725                 makevectors('0 0 0');
1726                 vector v1, v2;
1727                 cvar_set("vid_conwidth", "800");
1728                 cvar_set("vid_conheight", "600");
1729                 v1 = cs_project(v_forward);
1730                 cvar_set("vid_conwidth", "640");
1731                 cvar_set("vid_conheight", "480");
1732                 v2 = cs_project(v_forward);
1733                 if(v1 == v2)
1734                         cs_project_is_b0rked = 1;
1735                 else
1736                         cs_project_is_b0rked = -1;
1737                 cvar_set("vid_conwidth", w0);
1738                 cvar_set("vid_conheight", h0);
1739         }
1740
1741         if(autocvar__hud_configure)
1742                 HUD_Panel_Mouse();
1743
1744     if(hud && !intermission)
1745     {
1746         if(hud == HUD_SPIDERBOT)
1747             CSQC_SPIDER_HUD();
1748         else if(hud == HUD_WAKIZASHI)
1749             CSQC_WAKIZASHI_HUD();
1750         else if(hud == HUD_RAPTOR)
1751             CSQC_RAPTOR_HUD();
1752         else if(hud == HUD_BUMBLEBEE)
1753             CSQC_BUMBLE_HUD();
1754         else if(hud == HUD_BUMBLEBEE_GUN)
1755             CSQC_BUMBLE_GUN_HUD();
1756     }
1757
1758         cl_notice_run();
1759
1760         // let's reset the view back to normal for the end
1761         setproperty(VF_MIN, '0 0 0');
1762         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1763 }
1764
1765
1766 void CSQC_common_hud(void)
1767 {
1768         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1769                 Accuracy_LoadLevels();
1770
1771         HUD_Main(); // always run these functions for alpha checks
1772         HUD_DrawScoreboard();
1773
1774         if (scoreboard_active) // scoreboard/accuracy
1775                 HUD_Reset();
1776         else if (intermission == 2) // map voting screen
1777         {
1778                 MapVote_Draw();
1779                 HUD_Reset();
1780         }
1781 }
1782
1783
1784 // following vectors must be global to allow seamless switching between camera modes
1785 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1786 void CSQC_Demo_Camera()
1787 {
1788         float speed, attenuation, dimensions;
1789         vector tmp, delta;
1790
1791         if( autocvar_camera_reset || !camera_mode )
1792         {
1793                 camera_offset = '0 0 0';
1794                 current_angles = '0 0 0';
1795                 camera_direction = '0 0 0';
1796                 camera_offset_z += 30;
1797                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1798                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1799                 current_origin = view_origin;
1800                 current_camera_offset  = camera_offset;
1801                 cvar_set("camera_reset", "0");
1802                 camera_mode = CAMERA_CHASE;
1803         }
1804
1805         // Camera angles
1806         if( camera_roll )
1807                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1808
1809         if(autocvar_camera_look_player)
1810         {
1811                 vector dir;
1812                 float n;
1813
1814                 dir = normalize(view_origin - current_position);
1815                 n = mouse_angles_z;
1816                 mouse_angles = vectoangles(dir);
1817                 mouse_angles_x = mouse_angles_x * -1;
1818                 mouse_angles_z = n;
1819         }
1820         else
1821         {
1822                 tmp = getmousepos() * 0.1;
1823                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1824                 {
1825                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1826                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1827                 }
1828         }
1829
1830         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1831         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1832         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1833         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1834
1835         // Fix difference when angles don't have the same sign
1836         delta = '0 0 0';
1837         if(mouse_angles_y < -60 && current_angles_y > 60)
1838                 delta = '0 360 0';
1839         if(mouse_angles_y > 60 && current_angles_y < -60)
1840                 delta = '0 -360 0';
1841
1842         if(autocvar_camera_look_player)
1843                 attenuation = autocvar_camera_look_attenuation;
1844         else
1845                 attenuation = autocvar_camera_speed_attenuation;
1846
1847         attenuation = 1 / max(1, attenuation);
1848         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1849
1850         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1851         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1852         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1853         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1854
1855         // Camera position
1856         tmp = '0 0 0';
1857         dimensions = 0;
1858
1859         if( camera_direction_x )
1860         {
1861                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1862                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1863                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1864                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1865                 ++dimensions;
1866         }
1867
1868         if( camera_direction_y )
1869         {
1870                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1871                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1872                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1873                 ++dimensions;
1874         }
1875
1876         if( camera_direction_z )
1877         {
1878                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1879                 ++dimensions;
1880         }
1881
1882         if(autocvar_camera_free)
1883                 speed = autocvar_camera_speed_free;
1884         else
1885                 speed = autocvar_camera_speed_chase;
1886
1887         if(dimensions)
1888         {
1889                 speed = speed * sqrt(1 / dimensions);
1890                 camera_offset += tmp * speed;
1891         }
1892
1893         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1894
1895         // Camera modes
1896         if( autocvar_camera_free )
1897         {
1898                 if ( camera_mode == CAMERA_CHASE )
1899                 {
1900                         current_camera_offset = current_origin + current_camera_offset;
1901                         camera_offset = current_origin + camera_offset;
1902                 }
1903
1904                 camera_mode = CAMERA_FREE;
1905                 current_position = current_camera_offset;
1906         }
1907         else
1908         {
1909                 if ( camera_mode == CAMERA_FREE )
1910                 {
1911                         current_origin = view_origin;
1912                         camera_offset = camera_offset - current_origin;
1913                         current_camera_offset = current_camera_offset - current_origin;
1914                 }
1915
1916                 camera_mode = CAMERA_CHASE;
1917
1918                 if(autocvar_camera_chase_smoothly)
1919                         current_origin += (view_origin - current_origin) * attenuation;
1920                 else
1921                         current_origin = view_origin;
1922
1923                 current_position = current_origin + current_camera_offset;
1924         }
1925
1926         setproperty(VF_ANGLES, current_angles);
1927         setproperty(VF_ORIGIN, current_position);
1928 }