qcsrc/server/command/cmd.qc

   1 #include "cmd.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/deathtypes/all.qh>
   6 #include <common/effects/all.qh>
   7 #include <common/gamemodes/_mod.qh>
   8 #include <common/mapinfo.qh>
   9 #include <common/mapobjects/triggers.qh>
  10 #include <common/minigames/sv_minigames.qh>
  11 #include <common/monsters/_mod.qh>
  12 #include <common/monsters/sv_monsters.qh>
  13 #include <common/monsters/sv_spawn.qh>
  14 #include <common/notifications/all.qh>
  15 #include <common/physics/player.qh>
  16 #include <common/teams.qh>
  17 #include <common/util.qh>
  18 #include <common/vehicles/all.qh>
  19 #include <lib/warpzone/common.qh>
  20 #include <server/bot/api.qh>
  21 #include <server/bot/default/waypoints.qh>
  22 #include <server/campaign.qh>
  23 #include <server/chat.qh>
  24 #include <server/cheats.qh>
  25 #include <server/client.qh>
  26 #include <server/clientkill.qh>
  27 #include <server/command/common.qh>
  28 #include <server/command/getreplies.qh>
  29 #include <server/command/vote.qh>
  30 #include <server/ipban.qh>
  31 #include <server/mapvoting.qh>
  32 #include <server/mutators/_mod.qh>
  33 #include <server/player.qh>
  34 #include <server/scores.qh>
  35 #include <server/teamplay.qh>
  36 #include <server/world.qh>
  37
  38 // =========================================================
  39 //  Server side networked commands code, reworked by Samual
  40 //  Last updated: December 28th, 2011
  41 // =========================================================
  42
  43
  44 // =======================
  45 //  Command Sub-Functions
  46 // =======================
  47
  48 void ClientCommand_autoswitch(entity caller, int request, int argc)
  49 {
  50         switch (request)
  51         {
  52                 case CMD_REQUEST_COMMAND:
  53                 {
  54                         if (argv(1) != "")
  55                         {
  56                                 CS_CVAR(caller).cvar_cl_autoswitch = InterpretBoolean(argv(1));
  57                                 sprint(caller, strcat("^1autoswitch is currently turned ", (CS_CVAR(caller).cvar_cl_autoswitch ? "on" : "off"), ".\n"));
  58                                 return;
  59                         }
  60                 }
  61
  62                 default:
  63                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
  64                 case CMD_REQUEST_USAGE:
  65                 {
  66                         sprint(caller, "\nUsage:^3 cmd autoswitch <selection>\n");
  67                         sprint(caller, "  Where <selection> controls if autoswitch is on or off.\n");
  68                         return;
  69                 }
  70         }
  71 }
  72
  73 void ClientCommand_clear_ignores(entity caller, int request)
  74 {
  75         switch (request)
  76         {
  77                 case CMD_REQUEST_COMMAND:
  78                 {
  79                         bool advanced = (caller.crypto_idfp && caller.crypto_idfp != "");
  80
  81                         if(!advanced)
  82                         {
  83                                 sprint(caller, "You don't have a stats UID, unable to clear your ignore list.\n");
  84                                 return;
  85                         }
  86
  87                         ignore_clearall(caller);
  88                         sprint(caller, "All permanent ignores cleared!\n");
  89                         return;
  90                 }
  91
  92                 default:
  93                 case CMD_REQUEST_USAGE:
  94                 {
  95                         sprint(caller, "\nUsage:^3 cmd clear_ignores\n");
  96                         sprint(caller, "  Removes all existing ignored clients whose are kept out of personal chat log.\n");
  97                         return;
  98                 }
  99         }
 100 }
 101
 102 void ClientCommand_clientversion(entity caller, int request, int argc)  // internal command, used only by code
 103 {
 104         switch (request)
 105         {
 106                 case CMD_REQUEST_COMMAND:
 107                 {
 108                         if (argv(1) != "")
 109                         {
 110                                 if (IS_CLIENT(caller))
 111                                 {
 112                                         CS(caller).version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
 113
 114                                         if (CS(caller).version < autocvar_gameversion_min || CS(caller).version > autocvar_gameversion_max)
 115                                         {
 116                                                 CS(caller).version_mismatch = true;
 117                                                 ClientKill_TeamChange(caller, -2);  // observe
 118                                         }
 119                                         else if (autocvar_g_campaign || autocvar_g_balance_teams)
 120                                         {
 121                                                 // JoinBestTeam(caller, false, true);
 122                                         }
 123                                         else if (teamplay && !autocvar_sv_spectate && !(Player_GetForcedTeamIndex(caller) > 0))
 124                                         {
 125                                                 TRANSMUTE(Observer, caller);  // really?
 126                                                 stuffcmd(caller, "team_selection_show\n");
 127                                         }
 128                                 }
 129
 130                                 return;
 131                         }
 132                 }
 133
 134                 default:
 135                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 136                 case CMD_REQUEST_USAGE:
 137                 {
 138                         sprint(caller, "\nUsage:^3 cmd clientversion <version>\n");
 139                         sprint(caller, "  Where <version> is the game version reported by caller.\n");
 140                         return;
 141                 }
 142         }
 143 }
 144
 145 void ClientCommand_mv_getpicture(entity caller, int request, int argc)  // internal command, used only by code
 146 {
 147         switch (request)
 148         {
 149                 case CMD_REQUEST_COMMAND:
 150                 {
 151                         if (argv(1) != "")
 152                         {
 153                                 if (intermission_running) MapVote_SendPicture(caller, stof(argv(1)));
 154
 155                                 return;
 156                         }
 157                 }
 158
 159                 default:
 160                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 161                 case CMD_REQUEST_USAGE:
 162                 {
 163                         sprint(caller, "\nUsage:^3 cmd mv_getpicture <mapid>\n");
 164                         sprint(caller, "  Where <mapid> is the id number of the map to request an image of on the map vote selection menu.\n");
 165                         return;
 166                 }
 167         }
 168 }
 169
 170 void ClientCommand_wpeditor(entity caller, int request, int argc)
 171 {
 172         switch (request)
 173         {
 174                 case CMD_REQUEST_COMMAND:
 175                 {
 176                         if (!waypointeditor_enabled)
 177                         {
 178                                 sprint(caller, "ERROR: this command works only if the waypoint editor is on\n");
 179                                 return;
 180                         }
 181
 182                         if (argv(1) != "")
 183                         {
 184                                 if (argv(1) == "spawn")
 185                                 {
 186                                         string s = argv(2);
 187                                         if (!IS_PLAYER(caller))
 188                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 189                                         else
 190                                                 waypoint_spawn_fromeditor(caller, (s == "crosshair"), (s == "jump"), (s == "crouch"), (s == "support"));
 191                                         return;
 192                                 }
 193                                 else if (argv(1) == "remove")
 194                                 {
 195                                         if (!IS_PLAYER(caller))
 196                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 197                                         else
 198                                                 waypoint_remove_fromeditor(caller);
 199                                         return;
 200                                 }
 201                                 else if (argv(1) == "hardwire")
 202                                 {
 203                                         string s = argv(2);
 204                                         waypoint_start_hardwiredlink(caller, (s == "crosshair"));
 205                                         return;
 206                                 }
 207                                 else if (argv(1) == "lock")
 208                                 {
 209                                         waypoint_lock(caller);
 210                                         return;
 211                                 }
 212                                 else if (argv(1) == "unreachable")
 213                                 {
 214                                         if (!IS_PLAYER(caller))
 215                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 216                                         else
 217                                                 waypoint_unreachable(caller);
 218                                         return;
 219                                 }
 220                                 else if (argv(1) == "saveall")
 221                                 {
 222                                         waypoint_saveall();
 223                                         return;
 224                                 }
 225                                 else if (argv(1) == "relinkall")
 226                                 {
 227                                         waypoint_schedulerelinkall();
 228                                         return;
 229                                 }
 230                                 else if (argv(1) == "symaxis")
 231                                 {
 232                                         if (argv(2) == "set" || argv(2) == "get")
 233                                         {
 234                                                 waypoint_getSymmetricalAxis_cmd(caller, (argv(2) == "set"), 3);
 235                                                 return;
 236                                         }
 237                                 }
 238                                 else if (argv(1) == "symorigin")
 239                                 {
 240                                         if (argv(2) == "set" || argv(2) == "get")
 241                                         {
 242                                                 waypoint_getSymmetricalOrigin_cmd(caller, (argv(2) == "set"), 3);
 243                                                 return;
 244                                         }
 245                                 }
 246                         }
 247                 }
 248
 249                 default:
 250                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 251                 case CMD_REQUEST_USAGE:
 252                 {
 253                         sprint(caller, "\nUsage:^3 cmd wpeditor <action>\n");
 254                         sprint(caller, "  Where <action> can be:\n");
 255                         sprint(caller, "   ^2spawn^7: spawns a waypoint at player's position\n");
 256                         sprint(caller, "   ^2remove^7: removes player's nearest waypoint\n");
 257                         sprint(caller, "   ^2unreachable^7: reveals waypoints and items unreachable from the current position and spawnpoints without a nearest waypoint\n");
 258                         sprint(caller, "   ^2saveall^7: saves all waypoints and links to file\n");
 259                         sprint(caller, "   ^2relinkall^7: relinks all waypoints as if they were respawned\n");
 260                         sprint(caller, "   ^2spawn crosshair^7: spawns a waypoint at crosshair's position\n");
 261                         sprint(caller, "   ^7 in general useful to create special and hardwired links with ease from existing waypoints\n");
 262                         sprint(caller, "   ^7 in particular it's the only way to create custom jumppad waypoints (spawn another waypoint to create destination))\n");
 263                         sprint(caller, "   ^2spawn jump^7: spawns a jump waypoint (place it at least 60 qu before jump start, spawn another waypoint to create destination)\n");
 264                         sprint(caller, "   ^2spawn crouch^7: spawns a crouch waypoint (it links only to very close waypoints)\n");
 265                         sprint(caller, "   ^2spawn support^7: spawns a support waypoint (spawn another waypoint to create destination from which all incoming links are removed)\n");
 266                         sprint(caller, "   ^7 useful to replace links to problematic jumppad/teleport waypoints\n");
 267                         sprint(caller, "   ^2hardwire^7: marks the nearest waypoint as origin of a new hardwired link (spawn another waypoint over an existing one to create destination)\n");
 268                         sprint(caller, "   ^2hardwire crosshair^7: marks the waypoint at crosshair instead of the nearest waypoint\n");
 269                         sprint(caller, "   ^2lock^7: locks link display of the aimed waypoint (unlocks if no waypoint is found at crosshair's position)\n");
 270                         sprint(caller, "   ^2symorigin get|set\n");
 271                         sprint(caller, "   ^2symorigin get|set <p1> <p2> ... <pX>\n");
 272                         sprint(caller, "   ^2symaxis get|set <p1> <p2>\n");
 273                         sprint(caller, "   ^7 where <p1> <p2> ... <pX> are positions (\"x y z\", z can be omitted) that you know are perfectly symmetrical"
 274                                                                 " so you can determine origin/axis of symmetry of maps without ctf flags or where flags aren't perfectly symmetrical\n");
 275                         sprint(caller, "  See ^5wpeditor_menu^7 for a selectable list of various commands and useful settings to edit waypoints.\n");
 276                         return;
 277                 }
 278         }
 279 }
 280
 281 void ClientCommand_ignore(entity caller, int request, int argc, string command)
 282 {
 283         switch (request)
 284         {
 285                 case CMD_REQUEST_COMMAND:
 286                 {
 287                         if (argc >= 2)
 288                         {
 289                                 bool advanced = (caller.crypto_idfp && caller.crypto_idfp != "");
 290
 291                                 if(!argv(1) || argv(1) == "")
 292                                 {
 293                                         sprint(caller, "This command requires an argument. Use a player's name or their ID from the ^2status^7 command.\n");
 294                                         return;
 295                                 }
 296
 297                                 entity ignore_to = GetIndexedEntity(argc, 1);
 298                                 float ignore_accepted = VerifyClientEntity(ignore_to, true, false);
 299
 300                                 if (ignore_accepted > 0 && IS_REAL_CLIENT(ignore_to))   // the target is a real client
 301                                 {
 302                                         if (ignore_to != caller) // and we're allowed to ignore them heh
 303                                         {
 304                                                 if(ignore_playerinlist(ignore_to, caller))
 305                                                 {
 306                                                         sprint(caller, ignore_to.netname, " ^7is already ignored!\n");
 307                                                         return;
 308                                                 }
 309
 310                                                 // advanced ignore mode, works if both the player and the sender have a stats UID
 311                                                 if(advanced && ignore_to.crypto_idfp && ignore_to.crypto_idfp != "")
 312                                                 {
 313                                                         for(int j = 0; j < IGNORE_MAXPLAYERS; ++j)
 314                                                         {
 315                                                                 string pos = db_get(ServerProgsDB, strcat("/ignore/", caller.crypto_idfp, "/", ftos(j)));
 316                                                                 if(pos == "")
 317                                                                 {
 318                                                                         db_put(ServerProgsDB, strcat("/ignore/", caller.crypto_idfp, "/", ftos(j)), ignore_to.crypto_idfp);
 319                                                                         sprint(caller, "You will no longer receive messages from ", ignore_to.netname, "^7, use ^2unignore^7 to hear them again.\n");
 320                                                                         return;
 321                                                                 }
 322                                                         }
 323
 324                                                         sprint(caller, "You may only ignore up to ", ftos(IGNORE_MAXPLAYERS), " players, remove one before trying again.\n");
 325                                                         return;
 326                                                 }
 327
 328                                                 if(caller.ignore_list)
 329                                                         strunzone(caller.ignore_list);
 330                                                 caller.ignore_list = strzone(cons(caller.ignore_list, ftos(etof(ignore_to))));
 331
 332                                                 sprint(caller, "You no longer receive messages from ", ignore_to.netname, "^7, use ^2unignore^7 to hear them again.\n");
 333                                         }
 334                                         else { sprint(caller, "You can't ^2ignore^7 yourself.\n"); }
 335                                 }
 336                                 else { print_to(caller, strcat("ignore: ", GetClientErrorString(ignore_accepted, argv(1)), ".\nUnable to ignore this player, check their ID.")); }
 337
 338                                 return;
 339                         }
 340                 }
 341
 342                 default:
 343                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 344                 case CMD_REQUEST_USAGE:
 345                 {
 346                         sprint(caller, "\nUsage:^3 cmd ignore <client>\n");
 347                         sprint(caller, "  Where <client> is the entity number or name of the player to ignore keeping out of personal chat log.\n");
 348                         return;
 349                 }
 350         }
 351 }
 352
 353 void ClientCommand_join(entity caller, int request)
 354 {
 355         switch (request)
 356         {
 357                 case CMD_REQUEST_COMMAND:
 358                 {
 359                         if (!game_stopped && IS_CLIENT(caller) && !IS_PLAYER(caller))
 360                         {
 361                                 if (joinAllowed(caller))
 362                                         Join(caller, true);
 363                                 else if(time < CS(caller).jointime + MIN_SPEC_TIME)
 364                                         CS(caller).autojoin_checked = -1;
 365                         }
 366                         CS(caller).parm_idlesince = time;
 367
 368                         return;  // never fall through to usage
 369                 }
 370
 371                 default:
 372                 case CMD_REQUEST_USAGE:
 373                 {
 374                         sprint(caller, "\nUsage:^3 cmd join\n");
 375                         sprint(caller, "  No arguments required.\n");
 376                         return;
 377                 }
 378         }
 379 }
 380
 381 void ClientCommand_kill(entity caller, int request)
 382 {
 383         switch (request)
 384         {
 385                 case CMD_REQUEST_COMMAND:
 386                 {
 387                         if(IS_SPEC(caller) || IS_OBSERVER(caller))
 388                                 return; // no point warning about this, command does nothing
 389
 390                         if(GetResource(caller, RES_HEALTH) <= 0)
 391                         {
 392                                 sprint(caller, "Can't die - you are already dead!\n");
 393                                 return;
 394                         }
 395
 396                         ClientKill(caller);
 397
 398                         return;  // never fall through to usage
 399                 }
 400
 401                 default:
 402                 case CMD_REQUEST_USAGE:
 403                 {
 404                         sprint(caller, "\nUsage:^3 cmd kill\n");
 405                         sprint(caller, "  No arguments required.\n");
 406                         return;
 407                 }
 408         }
 409 }
 410
 411 void ClientCommand_physics(entity caller, int request, int argc)
 412 {
 413         switch (request)
 414         {
 415                 case CMD_REQUEST_COMMAND:
 416                 {
 417                         string command = strtolower(argv(1));
 418
 419                         if (!autocvar_g_physics_clientselect)
 420                         {
 421                                 sprint(caller, "Client physics selection is currently disabled.\n");
 422                                 return;
 423                         }
 424
 425                         if (command == "list" || command == "help")
 426                         {
 427                                 sprint(caller, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
 428                                 return;
 429                         }
 430
 431                         if (Physics_Valid(command) || command == "default")
 432                         {
 433                                 stuffcmd(caller, strcat("\nseta cl_physics ", command, "\n"));
 434                                 sprint(caller, strcat("^2Physics set successfully changed to ^3", command, "\n"));
 435                                 return;
 436                         }
 437                 }
 438
 439                 default:
 440                         sprint(caller, strcat("Current physics set: ^3", CS_CVAR(caller).cvar_cl_physics, "\n"));
 441                 case CMD_REQUEST_USAGE:
 442                 {
 443                         sprint(caller, "\nUsage:^3 cmd physics <physics>\n");
 444                         sprint(caller, "  See 'cmd physics list' for available physics sets.\n");
 445                         sprint(caller, "  Argument 'default' resets to standard physics.\n");
 446                         return;
 447                 }
 448         }
 449 }
 450
 451 void ClientCommand_ready(entity caller, int request)
 452 {
 453         switch (request)
 454         {
 455                 case CMD_REQUEST_COMMAND:
 456                 {
 457                         if (warmup_stage || g_race_qualifying == 2)
 458                         if (IS_PLAYER(caller) || INGAME_JOINED(caller))
 459                         {
 460                                 if (caller.ready) // toggle
 461                                 {
 462                                         caller.ready = false;
 463                                         bprint(playername(caller.netname, caller.team, false), "^2 is ^1NOT^2 ready\n");
 464                                 }
 465                                 else
 466                                 {
 467                                         caller.ready = true;
 468                                         bprint(playername(caller.netname, caller.team, false), "^2 is ready\n");
 469                                 }
 470                                 ReadyCount();
 471                         }
 472                         return;  // never fall through to usage
 473                 }
 474
 475                 default:
 476                 case CMD_REQUEST_USAGE:
 477                 {
 478                         sprint(caller, "\nUsage:^3 cmd ready\n");
 479                         sprint(caller, "  No arguments required.\n");
 480                         return;
 481                 }
 482         }
 483 }
 484
 485 void ClientCommand_say(entity caller, int request, int argc, string command)
 486 {
 487         switch (request)
 488         {
 489                 case CMD_REQUEST_COMMAND:
 490                 {
 491                         if (argc >= 2)   Say(caller, false, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 492                         return;  // never fall through to usage
 493                 }
 494
 495                 default:
 496                 case CMD_REQUEST_USAGE:
 497                 {
 498                         sprint(caller, "\nUsage:^3 cmd say <message>\n");
 499                         sprint(caller, "  Where <message> is the string of text to say.\n");
 500                         return;
 501                 }
 502         }
 503 }
 504
 505 void ClientCommand_say_team(entity caller, int request, int argc, string command)
 506 {
 507         switch (request)
 508         {
 509                 case CMD_REQUEST_COMMAND:
 510                 {
 511                         if (argc >= 2)
 512                                 Say(caller, true, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 513                         return;  // never fall through to usage
 514                 }
 515
 516                 default:
 517                 case CMD_REQUEST_USAGE:
 518                 {
 519                         sprint(caller, "\nUsage:^3 cmd say_team <message>\n");
 520                         sprint(caller, "  Where <message> is the string of text to say.\n");
 521                         return;
 522                 }
 523         }
 524 }
 525
 526 .bool team_selected;
 527 void ClientCommand_selectteam(entity caller, int request, int argc)
 528 {
 529         switch (request)
 530         {
 531                 case CMD_REQUEST_COMMAND:
 532                 {
 533                         if (argv(1) == "")
 534                         {
 535                                 return;
 536                         }
 537                         if (!IS_CLIENT(caller))
 538                         {
 539                                 return;
 540                         }
 541                         if (!teamplay)
 542                         {
 543                                 sprint(caller, "^7selectteam can only be used in teamgames\n");
 544                                 return;
 545                         }
 546                         if (Player_GetForcedTeamIndex(caller) > 0)
 547                         {
 548                                 sprint(caller, "^7selectteam can not be used as your team is forced\n");
 549                                 return;
 550                         }
 551                         if (lockteams)
 552                         {
 553                                 sprint(caller, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 554                                 return;
 555                         }
 556
 557                         float team_num = Team_ColorToTeam(argv(1));
 558                         if (team_num == -1) // invalid
 559                                 return;
 560                         if (caller.team == team_num && team_num && !IS_DEAD(caller))
 561                         {
 562                                 sprint(caller, "^7You already are on that team.\n");
 563                                 return;
 564                         }
 565                         if (CS(caller).wasplayer && autocvar_g_changeteam_banned)
 566                         {
 567                                 sprint(caller, "^1You cannot change team, forbidden by the server.\n");
 568                                 return;
 569                         }
 570                         if (team_num && autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 571                         {
 572                                 entity balance = TeamBalance_CheckAllowedTeams(caller);
 573                                 TeamBalance_GetTeamCounts(balance, caller);
 574                                 if ((Team_IndexToBit(Team_TeamToIndex(team_num)) &
 575                                         TeamBalance_FindBestTeams(balance, caller, false)) == 0)
 576                                 {
 577                                         Send_Notification(NOTIF_ONE, caller, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 578                                         TeamBalance_Destroy(balance);
 579                                         return;
 580                                 }
 581                                 TeamBalance_Destroy(balance);
 582                         }
 583                         if (team_num)
 584                                 ClientKill_TeamChange(caller, team_num);
 585                         else // auto
 586                                 if (!queuePlayer(caller, 0)) // the queue uses deferred autoselect
 587                                         ClientKill_TeamChange(caller, -1);
 588
 589                         return;
 590                 }
 591                 default:
 592                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 593                 case CMD_REQUEST_USAGE:
 594                 {
 595                         sprint(caller, "\nUsage:^3 cmd selectteam <team>\n");
 596                         sprint(caller, "  Where <team> is the prefered team to try and join.\n");
 597                         sprint(caller, "  Full list of options here: red, blue, yellow, pink, auto.\n");
 598                         return;
 599                 }
 600         }
 601 }
 602
 603 void ClientCommand_selfstuff(entity caller, int request, string command)
 604 {
 605         switch (request)
 606         {
 607                 case CMD_REQUEST_COMMAND:
 608                 {
 609                         if (argv(1) != "")
 610                         {
 611                                 stuffcmd(caller, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 612                                 return;
 613                         }
 614                 }
 615
 616                 default:
 617                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 618                 case CMD_REQUEST_USAGE:
 619                 {
 620                         sprint(caller, "\nUsage:^3 cmd selfstuff <command>\n");
 621                         sprint(caller, "  Where <command> is the string to be stuffed to your client.\n");
 622                         return;
 623                 }
 624         }
 625 }
 626
 627 void ClientCommand_sentcvar(entity caller, int request, int argc)
 628 {
 629         switch (request)
 630         {
 631                 case CMD_REQUEST_COMMAND:
 632                 {
 633                         if (argc >= 3)
 634                         {
 635                         // NOTE: client-side settings do not exist on the server, this functionality has been deprecated
 636                         #if 0
 637                                 if (argc == 2)  // undefined cvar: use the default value on the server then
 638                                 {
 639                                         string s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 640                                         tokenize_console(s);
 641                                 }
 642                         #endif
 643
 644                                 GetCvars(caller, CS_CVAR(caller), 1);
 645
 646                                 return;
 647                         }
 648                 }
 649
 650                 default:
 651                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 652                 case CMD_REQUEST_USAGE:
 653                 {
 654                         sprint(caller, "\nUsage:^3 cmd sentcvar <cvar> <arguments>\n");
 655                         sprint(caller, "  Where <cvar> is the cvar plus arguments to send to the server.\n");
 656                         return;
 657                 }
 658         }
 659 }
 660
 661 void ClientCommand_spectate(entity caller, int request)
 662 {
 663         switch (request)
 664         {
 665                 case CMD_REQUEST_COMMAND:
 666                 {
 667                         if (!intermission_running && IS_CLIENT(caller))
 668                         {
 669                                 if(argv(1) != "")
 670                                 {
 671                                         if(IS_SPEC(caller) || IS_OBSERVER(caller))
 672                                         {
 673                                                 entity client = GetFilteredEntity(argv(1));
 674                                                 float spec_accepted = VerifyClientEntity(client, false, false);
 675                                                 if(spec_accepted > 0 && IS_PLAYER(client))
 676                                                 {
 677                                                         bool caller_is_observer = (IS_OBSERVER(caller));
 678                                                         Spectate(caller, client);
 679                                                         if (caller_is_observer)
 680                                                                 TRANSMUTE(Spectator, caller);
 681                                                 }
 682                                                 else
 683                                                         sprint(caller, "Can't spectate ", argv(1), "^7\n");
 684                                         }
 685                                         else
 686                                                 sprint(caller, "cmd spectate <client> only works when you are spectator/observer\n");
 687                                         return;
 688                                 }
 689
 690                                 int mutator_returnvalue = MUTATOR_CALLHOOK(ClientCommand_Spectate, caller);
 691
 692                                 if (mutator_returnvalue == MUT_SPECCMD_RETURN) return;
 693
 694                                 if ((IS_PLAYER(caller) || mutator_returnvalue == MUT_SPECCMD_FORCE || caller.wants_join))
 695                                 if (autocvar_sv_spectate == 1)
 696                                         ClientKill_TeamChange(caller, -2); // observe
 697                         }
 698                         return; // never fall through to usage
 699                 }
 700
 701                 default:
 702                 case CMD_REQUEST_USAGE:
 703                 {
 704                         sprint(caller, "\nUsage:^3 cmd spectate [<client>]\n");
 705                         sprint(caller, "  Where <client> can be the player to spectate.\n");
 706                         return;
 707                 }
 708         }
 709 }
 710
 711 void ClientCommand_suggestmap(entity caller, int request, int argc)
 712 {
 713         switch (request)
 714         {
 715                 case CMD_REQUEST_COMMAND:
 716                 {
 717                         if (argv(1) != "")
 718                         {
 719                                 sprint(caller, strcat(MapVote_Suggest(caller, argv(1)), "\n"));
 720                                 return;
 721                         }
 722                 }
 723
 724                 default:
 725                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 726                 case CMD_REQUEST_USAGE:
 727                 {
 728                         sprint(caller, "\nUsage:^3 cmd suggestmap <map>\n");
 729                         sprint(caller, "  Where <map> is the name of the map to suggest.\n");
 730                         return;
 731                 }
 732         }
 733 }
 734
 735 void ClientCommand_tell(entity caller, int request, int argc, string command)
 736 {
 737         switch (request)
 738         {
 739                 case CMD_REQUEST_COMMAND:
 740                 {
 741                         if (argc >= 3)
 742                         {
 743                                 if(!IS_CLIENT(caller) && IS_REAL_CLIENT(caller)) // connecting
 744                                 {
 745                                         print_to(caller, "You can't ^2tell^7 a message while connecting.");
 746                                         return;
 747                                 }
 748
 749                                 entity tell_to = GetIndexedEntity(argc, 1);
 750                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
 751
 752                                 if (tell_accepted > 0)   // the target is a real client
 753                                 {
 754                                         if (tell_to != caller) // and we're allowed to send to them :D
 755                                         {
 756                                                 // workaround for argv indexes indexing ascii chars instead of utf8 chars
 757                                                 // In this case when the player name contains utf8 chars
 758                                                 // the message gets partially trimmed in the beginning.
 759                                                 // Potentially this bug affects any substring call that uses
 760                                                 // argv_start_index and argv_end_index.
 761
 762                                                 string utf8_enable_save = cvar_string("utf8_enable");
 763                                                 cvar_set("utf8_enable", "0");
 764                                                 string msg = substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token));
 765                                                 cvar_set("utf8_enable", utf8_enable_save);
 766
 767                                                 Say(caller, false, tell_to, msg, true);
 768                                                 return;
 769                                         }
 770                                         else { print_to(caller, "You can't ^2tell^7 a message to yourself."); return; }
 771                                 }
 772                                 else if (argv(1) == "#0")
 773                                 {
 774                                         trigger_magicear_processmessage_forallears(caller, -1, NULL, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 775                                         return;
 776                                 }
 777                                 else { print_to(caller, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 778                         }
 779                 }
 780
 781                 default:
 782                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 783                 case CMD_REQUEST_USAGE:
 784                 {
 785                         sprint(caller, "\nUsage:^3 cmd tell <client> <message>\n");
 786                         sprint(caller, "  Where <client> is the entity number or name of the player to send <message> to.\n");
 787                         return;
 788                 }
 789         }
 790 }
 791
 792 void ClientCommand_unignore(entity caller, int request, int argc, string command)
 793 {
 794         switch (request)
 795         {
 796                 case CMD_REQUEST_COMMAND:
 797                 {
 798                         if (argc >= 2)
 799                         {
 800                                 bool advanced = (caller.crypto_idfp && caller.crypto_idfp != "");
 801
 802                                 if(!argv(1) || argv(1) == "")
 803                                 {
 804                                         sprint(caller, "This command requires an argument. Use a player's name or their ID from the ^2status^7 command.\n");
 805                                         return;
 806                                 }
 807
 808                                 entity unignore_to = GetIndexedEntity(argc, 1);
 809                                 float unignore_accepted = VerifyClientEntity(unignore_to, true, false);
 810
 811                                 if (unignore_accepted > 0 && IS_REAL_CLIENT(unignore_to))   // the target is a real client
 812                                 {
 813                                         if (unignore_to != caller)
 814                                         {
 815                                                 string mylist = ignore_removefromlist(caller, unignore_to);
 816                                                 if(!advanced)
 817                                                 {
 818                                                         if(caller.ignore_list)
 819                                                                 strunzone(caller.ignore_list);
 820
 821                                                         caller.ignore_list = strzone(mylist);
 822                                                 }
 823
 824                                                 sprint(caller, "You can now receive messages from ", unignore_to.netname, " ^7again.\n");
 825                                                 return;
 826                                         }
 827                                         else { sprint(caller, "You can't ^2unignore^7 yourself.\n"); }
 828                                 }
 829                                 else {  print_to(caller, strcat("unignore: ", GetClientErrorString(unignore_accepted, argv(1)), ".\nUnable to stop ignoring this player, check their ID.")); }
 830
 831                                 return;
 832                         }
 833                 }
 834
 835                 default:
 836                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 837                 case CMD_REQUEST_USAGE:
 838                 {
 839                         sprint(caller, "\nUsage:^3 cmd unignore <client>\n");
 840                         sprint(caller, "  Where <client> is the entity number or name of the player to stop ignoring when is keeping out of personal chat log.\n");
 841                         return;
 842                 }
 843         }
 844 }
 845
 846 void ClientCommand_voice(entity caller, int request, int argc, string command)
 847 {
 848         switch (request)
 849         {
 850                 case CMD_REQUEST_COMMAND:
 851                 {
 852                         if (argv(1) != "")
 853                         {
 854                                 entity e = GetVoiceMessage(argv(1));
 855                                 if (!e)
 856                                 {
 857                                         sprint(caller, sprintf("Invalid voice. Use one of: %s\n", allvoicesamples));
 858                                         return;
 859                                 }
 860                                 if (IS_DEAD(caller))
 861                                 {
 862                                         // don't warn the caller when trying to taunt while dead, just don't play any sounds!
 863                                         // we still allow them to see warnings if it's invalid, so a dead player can find out the sounds in peace
 864                                         return;
 865                                 }
 866                                 if (IS_SPEC(caller) || IS_OBSERVER(caller))
 867                                 {
 868                                         // observers/spectators have no player model of their own to play taunts from
 869                                         // again, allow them to see warnings
 870                                         return;
 871                                 }
 872                                 string msg = "";
 873                                 if (argc >= 3)
 874                                         msg = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 875                                 VoiceMessage(caller, e, msg);
 876
 877                                 return;
 878                         }
 879                 }
 880
 881                 default:
 882                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 883                 case CMD_REQUEST_USAGE:
 884                 {
 885                         sprint(caller, "\nUsage:^3 cmd voice <voicetype> [<message>]\n");
 886                         sprint(caller, "  <voicetype> is the type of voice message, it can be one of these:\n");
 887                         sprint(caller, sprintf("   %s\n", allvoicesamples));
 888                         sprint(caller, "  and <message> is the text message to send.\n");
 889                         return;
 890                 }
 891         }
 892 }
 893
 894 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 895 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 896 void ClientCommand_(entity caller, int request)
 897 {
 898     switch(request)
 899     {
 900         case CMD_REQUEST_COMMAND:
 901         {
 902
 903             return; // never fall through to usage
 904         }
 905
 906         default:
 907         case CMD_REQUEST_USAGE:
 908         {
 909             sprint(caller, "\nUsage:^3 cmd \n");
 910             sprint(caller, "  No arguments required.\n");
 911             return;
 912         }
 913     }
 914 }
 915 */
 916
 917
 918 // =====================================
 919 //  Macro system for networked commands
 920 // =====================================
 921
 922 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 923 #define CLIENT_COMMANDS(ent, request, arguments, command) \
 924         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(ent, request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 925         CLIENT_COMMAND("clear_ignores", ClientCommand_clear_ignores(ent, request), "Remove all existing ignored clients") \
 926         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(ent, request, arguments), "Release version of the game") \
 927         CLIENT_COMMAND("ignore", ClientCommand_ignore(ent, request, arguments, command), "Ignore a client in the game keeping out of personal chat log for a match") \
 928         CLIENT_COMMAND("join", ClientCommand_join(ent, request), "Become a player in the game") \
 929         CLIENT_COMMAND("kill", ClientCommand_kill(ent, request), "Become a member of the dead") \
 930         CLIENT_COMMAND("minigame", ClientCommand_minigame(ent, request, arguments, command), "Start a minigame") \
 931         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(ent, request, arguments), "Retrieve mapshot picture from the server") \
 932         CLIENT_COMMAND("physics", ClientCommand_physics(ent, request, arguments), "Change physics set") \
 933         CLIENT_COMMAND("ready", ClientCommand_ready(ent, request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 934         CLIENT_COMMAND("say", ClientCommand_say(ent, request, arguments, command), "Print a message to chat to all players") \
 935         CLIENT_COMMAND("say_team", ClientCommand_say_team(ent, request, arguments, command), "Print a message to chat to all team mates") \
 936         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(ent, request, arguments), "Attempt to choose a team to join into") \
 937         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(ent, request, command), "Stuffcmd a command to your own client") \
 938         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(ent, request, arguments), "New system for sending a client cvar to the server") \
 939         CLIENT_COMMAND("spectate", ClientCommand_spectate(ent, request), "Become an observer") \
 940         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(ent, request, arguments), "Suggest a map to the mapvote at match end") \
 941         CLIENT_COMMAND("tell", ClientCommand_tell(ent, request, arguments, command), "Send a message directly to a player") \
 942         CLIENT_COMMAND("voice", ClientCommand_voice(ent, request, arguments, command), "Send voice message via sound") \
 943         CLIENT_COMMAND("unignore", ClientCommand_unignore(ent, request, arguments, command), "Remove an existing ignored player") \
 944         CLIENT_COMMAND("wpeditor", ClientCommand_wpeditor(ent, request, arguments), "Waypoint editor commands") \
 945         /* nothing */
 946
 947 void ClientCommand_macro_help(entity caller)
 948 {
 949         #define CLIENT_COMMAND(name, function, description) \
 950                 { sprint(caller, "  ^2", name, "^7: ", description, "\n"); }
 951
 952         CLIENT_COMMANDS(NULL, 0, 0, "");
 953 #undef CLIENT_COMMAND
 954 }
 955
 956 float ClientCommand_macro_command(int argc, entity caller, string command)
 957 {
 958         #define CLIENT_COMMAND(name, function, description) \
 959                 { if (name == strtolower(argv(0))) { function; return true; } }
 960
 961         CLIENT_COMMANDS(caller, CMD_REQUEST_COMMAND, argc, command);
 962 #undef CLIENT_COMMAND
 963
 964         return false;
 965 }
 966
 967 float ClientCommand_macro_usage(int argc, entity caller)
 968 {
 969         #define CLIENT_COMMAND(name, function, description) \
 970                 { if (name == strtolower(argv(1))) { function; return true; } }
 971
 972         CLIENT_COMMANDS(caller, CMD_REQUEST_USAGE, argc, "");
 973 #undef CLIENT_COMMAND
 974
 975         return false;
 976 }
 977
 978 void ClientCommand_macro_write_aliases(float fh)
 979 {
 980         #define CLIENT_COMMAND(name, function, description) \
 981                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 982
 983         CLIENT_COMMANDS(NULL, 0, 0, "");
 984 #undef CLIENT_COMMAND
 985 }
 986
 987 // ======================================
 988 //  Main Function Called By Engine (cmd)
 989 // ======================================
 990 // If this function exists, server game code parses clientcommand before the engine code gets it.
 991
 992 void SV_ParseClientCommand(entity this, string command)
 993 {
 994         // If invalid UTF-8, don't even parse it
 995         string command2 = "";
 996         float len = strlen(command);
 997         float i;
 998         for (i = 0; i < len; ++i)
 999                 command2 = strcat(command2, chr2str(str2chr(command, i)));
1000         if (command != command2) return;
1001
1002         // if we're banned, don't even parse the command
1003         if (Ban_MaybeEnforceBanOnce(this)) return;
1004
1005         int argc = tokenize_console(command);
1006
1007         // Guide for working with argc arguments by example:
1008         // argc:   1    - 2      - 3     - 4
1009         // argv:   0    - 1      - 2     - 3
1010         // cmd     vote - master - login - password
1011
1012         // for floodcheck
1013         switch (strtolower(argv(0)))
1014         {
1015                 // exempt commands which are not subject to floodcheck
1016                 case "begin": break;                               // handled by engine in host_cmd.c
1017                 case "download": break;                            // handled by engine in cl_parse.c
1018                 case "mv_getpicture": break;                       // handled by server in this file
1019                 case "wpeditor": break;                            // handled by server in this file
1020                 case "pause": break;                               // handled by engine in host_cmd.c
1021                 case "prespawn": break;                            // handled by engine in host_cmd.c
1022                 case "sentcvar": break;                            // handled by server in this file
1023                 case "spawn": break;                               // handled by engine in host_cmd.c
1024                 case "say": case "say_team": case "tell": break;   // chat has its own flood control in chat.qc
1025                 case "minigame":                                   // flood control only for common commands
1026                         string arg = argv(1);
1027                         if (arg == "")
1028                                 goto flood_control;
1029                         for (int i = 0; i < MINIGAME_COMMON_CMD_COUNT; ++i)
1030                         {
1031                                 if (MINIGAME_COMMON_CMD[i] == arg)
1032                                         goto flood_control;
1033                         }
1034                         // if we get here we haven't found any common command, so no flood control for other commands
1035                         // individual minigame commands shouldn't be limited for gameplay reasons
1036                         // FIXME unknown/wrong minigame commands have no flood control
1037                         break;
1038                 case "color": case "topcolor": case "bottomcolor": // handled by engine in host_cmd.c
1039                         if(!IS_CLIENT(this)) // on connection
1040                         {
1041                                 // since gamecode doesn't have any calls earlier than this, do the connecting message here
1042                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_CONNECTING, this.netname);
1043                         }
1044                         if(teamplay)
1045                                 return;
1046                         break;
1047                 case "c2s": Net_ClientCommand(this, command); return; // handled by net.qh
1048
1049                 // on connection, client sends all of these
1050                 case "name": case "rate": case "rate_burstsize": case "playermodel": case "playerskin": case "clientversion":
1051                         if(!IS_CLIENT(this)) break;
1052                         // else fall through to default: flood control
1053                 default:
1054                         LABEL(flood_control)
1055                         if (!timeout_status)  // not while paused
1056                         {
1057                                 entity store = IS_CLIENT(this) ? CS(this) : this; // unfortunately, we need to store these on the client initially
1058                                 // this is basically the same as the chat flood control
1059                                 if (time < store.cmd_floodtime)
1060                                 {
1061                                         sprint(this, strcat("^3CMD FLOOD CONTROL: wait ^1", ftos(store.cmd_floodtime - time), "^3 seconds, command was: ", command, "\n"));
1062                                         return;  // too much spam, halt
1063                                 }
1064                                 else
1065                                         store.cmd_floodtime = max(time - autocvar_sv_clientcommand_antispam_count * autocvar_sv_clientcommand_antispam_time, store.cmd_floodtime) + autocvar_sv_clientcommand_antispam_time;
1066                         }
1067                         break;  // continue, as we're not flooding yet
1068         }
1069
1070         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
1071         if (argv(0) == "help")
1072         {
1073                 if (argc == 1)
1074                 {
1075                         sprint(this, "\nClient networked commands:\n");
1076                         ClientCommand_macro_help(this);
1077
1078                         sprint(this, "\nCommon networked commands:\n");
1079                         CommonCommand_macro_help(this);
1080
1081                         sprint(this, "\nUsage:^3 cmd <command>^7, where possible commands are listed above.\n");
1082                         sprint(this, "For help about a specific command, type cmd help <command>\n");
1083                         return;
1084                 }
1085                 else if (CommonCommand_macro_usage(argc, this))  // Instead of trying to call a command, we're going to see detailed information about it
1086                 {
1087                         return;
1088                 }
1089                 else if (ClientCommand_macro_usage(argc, this))  // same, but for normal commands now
1090                 {
1091                         return;
1092                 }
1093         }
1094         else if (MUTATOR_CALLHOOK(SV_ParseClientCommand, this, strtolower(argv(0)), argc, command))
1095         {
1096                 return;  // handled by a mutator
1097         }
1098         else if (CheatCommand(this, argc))
1099         {
1100                 return;  // handled by server/cheats.qc
1101         }
1102         else if (CommonCommand_macro_command(argc, this, command))
1103         {
1104                 return;                                          // handled by server/command/common.qc
1105         }
1106         else if (ClientCommand_macro_command(argc, this, command)) // continue as usual and scan for normal commands
1107         {
1108                 return;                                          // handled by one of the above ClientCommand_* functions
1109         }
1110         else
1111         {
1112                 clientcommand(this, command);
1113         }
1114 }