qcsrc/server/world.qc

   1 #include "world.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/gamemodes/sv_rules.qh>
   7 #include <common/items/_mod.qh>
   8 #include <common/mapinfo.qh>
   9 #include <common/mapobjects/target/music.qh>
  10 #include <common/mapobjects/trigger/hurt.qh>
  11 #include <common/mapobjects/trigger/secret.qh>
  12 #include <common/mapobjects/triggers.qh>
  13 #include <common/monsters/_mod.qh>
  14 #include <common/monsters/sv_monsters.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/notifications/all.qh>
  17 #include <common/physics/player.qh>
  18 #include <common/playerstats.qh>
  19 #include <common/state.qh>
  20 #include <common/stats.qh>
  21 #include <common/teams.qh>
  22 #include <common/util.qh>
  23 #include <common/vehicles/all.qh>
  24 #include <common/weapons/_all.qh>
  25 #include <server/anticheat.qh>
  26 #include <server/antilag.qh>
  27 #include <server/bot/api.qh>
  28 #include <server/campaign.qh>
  29 #include <server/cheats.qh>
  30 #include <server/client.qh>
  31 #include <server/command/common.qh>
  32 #include <server/command/getreplies.qh>
  33 #include <server/command/sv_cmd.qh>
  34 #include <server/command/vote.qh>
  35 #include <server/damage.qh>
  36 #include <server/gamelog.qh>
  37 #include <server/hook.qh>
  38 #include <server/ipban.qh>
  39 #include <server/items/items.qh>
  40 #include <server/main.qh>
  41 #include <server/mapvoting.qh>
  42 #include <server/mutators/_mod.qh>
  43 #include <server/race.qh>
  44 #include <server/scores.qh>
  45 #include <server/scores_rules.qh>
  46 #include <server/spawnpoints.qh>
  47 #include <server/teamplay.qh>
  48 #include <server/weapons/weaponstats.qh>
  49
  50 const float LATENCY_THINKRATE = 10;
  51 .float latency_sum;
  52 .float latency_cnt;
  53 .float latency_time;
  54 entity pingplreport;
  55 void PingPLReport_Think(entity this)
  56 {
  57         float delta;
  58         entity e;
  59
  60         delta = 3 / maxclients;
  61         if(delta < sys_frametime)
  62                 delta = 0;
  63         this.nextthink = time + delta;
  64
  65         e = edict_num(this.cnt + 1);
  66         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
  67         {
  68                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  69                 WriteByte(MSG_BROADCAST, this.cnt);
  70                 WriteShort(MSG_BROADCAST, bound(1, rint(CS(e).ping), 32767));
  71                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
  72                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
  73
  74                 // record latency times for clients throughout the match so we can report it to playerstats
  75                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
  76                 {
  77                         CS(e).latency_sum += CS(e).ping;
  78                         CS(e).latency_cnt += 1;
  79                         CS(e).latency_time = time;
  80                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
  81                 }
  82         }
  83         else
  84         {
  85                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  86                 WriteByte(MSG_BROADCAST, this.cnt);
  87                 WriteShort(MSG_BROADCAST, 0);
  88                 WriteByte(MSG_BROADCAST, 0);
  89                 WriteByte(MSG_BROADCAST, 0);
  90         }
  91         this.cnt = (this.cnt + 1) % maxclients;
  92 }
  93 void PingPLReport_Spawn()
  94 {
  95         pingplreport = new_pure(pingplreport);
  96         setthink(pingplreport, PingPLReport_Think);
  97         pingplreport.nextthink = time;
  98 }
  99
 100 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
 101
 102 void SetDefaultAlpha()
 103 {
 104         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
 105         {
 106                 default_player_alpha = autocvar_g_player_alpha;
 107                 if(default_player_alpha == 0)
 108                         default_player_alpha = 1;
 109                 default_weapon_alpha = default_player_alpha;
 110         }
 111 }
 112
 113 void GotoFirstMap(entity this)
 114 {
 115         float n;
 116         if(autocvar__sv_init)
 117         {
 118                 // cvar_set("_sv_init", "0");
 119                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 120                 // to this "init" map on a dedicated server will cause no permanent
 121                 // harm
 122                 if(autocvar_g_maplist_shuffle)
 123                         ShuffleMaplist();
 124                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 125                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 126
 127                 MapInfo_Enumerate();
 128                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 129
 130                 if(!DoNextMapOverride(1))
 131                         GotoNextMap(1);
 132
 133                 return;
 134         }
 135
 136         if(time < 5)
 137         {
 138                 this.nextthink = time;
 139         }
 140         else
 141         {
 142                 this.nextthink = time + 1;
 143                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
 144         }
 145 }
 146
 147 void cvar_changes_init()
 148 {
 149         float h;
 150         string k, v, d;
 151         float n, i, adding, pureadding;
 152
 153         strfree(cvar_changes);
 154         strfree(cvar_purechanges);
 155         cvar_purechanges_count = 0;
 156
 157         h = buf_create();
 158         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 159         n = buf_getsize(h);
 160
 161         adding = true;
 162         pureadding = true;
 163
 164         for(i = 0; i < n; ++i)
 165         {
 166                 k = bufstr_get(h, i);
 167
 168 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 169 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 170 #define BADCVAR(p) if(k == p) continue
 171 #define BADVALUE(p, val) if (k == p && v == val) continue
 172
 173                 // general excludes and namespaces for server admin used cvars
 174                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 175
 176                 // internal
 177                 BADPREFIX("csqc_");
 178                 BADPREFIX("cvar_check_");
 179                 BADCVAR("gamecfg");
 180                 BADCVAR("g_configversion");
 181                 BADCVAR("halflifebsp");
 182                 BADCVAR("sv_mapformat_is_quake2");
 183                 BADCVAR("sv_mapformat_is_quake3");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215                 BADCVAR("in_pitch_min");
 216                 BADCVAR("in_pitch_max");
 217
 218                 // private
 219                 BADCVAR("developer");
 220                 BADCVAR("log_dest_udp");
 221                 BADCVAR("net_address");
 222                 BADCVAR("net_address_ipv6");
 223                 BADCVAR("port");
 224                 BADCVAR("savedgamecfg");
 225                 BADCVAR("serverconfig");
 226                 BADCVAR("sv_autoscreenshot");
 227                 BADCVAR("sv_heartbeatperiod");
 228                 BADCVAR("sv_vote_master_password");
 229                 BADCVAR("sys_colortranslation");
 230                 BADCVAR("sys_specialcharactertranslation");
 231                 BADCVAR("timeformat");
 232                 BADCVAR("timestamps");
 233                 BADCVAR("g_require_stats");
 234                 BADPREFIX("developer_");
 235                 BADPREFIX("g_ban_");
 236                 BADPREFIX("g_banned_list");
 237                 BADPREFIX("g_require_stats_");
 238                 BADPREFIX("g_chat_flood_");
 239                 BADPREFIX("g_ghost_items");
 240                 BADPREFIX("g_playerstats_");
 241                 BADPREFIX("g_voice_flood_");
 242                 BADPREFIX("log_file");
 243                 BADPREFIX("quit_");
 244                 BADPREFIX("rcon_");
 245                 BADPREFIX("sv_allowdownloads");
 246                 BADPREFIX("sv_autodemo");
 247                 BADPREFIX("sv_curl_");
 248                 BADPREFIX("sv_eventlog");
 249                 BADPREFIX("sv_logscores_");
 250                 BADPREFIX("sv_master");
 251                 BADPREFIX("sv_weaponstats_");
 252                 BADPREFIX("sv_waypointsprite_");
 253                 BADCVAR("rescan_pending");
 254
 255                 // these can contain player IDs, so better hide
 256                 BADPREFIX("g_forced_team_");
 257                 BADCVAR("sv_muteban_list");
 258                 BADCVAR("sv_voteban_list");
 259                 BADCVAR("sv_allow_customplayermodels_idlist");
 260                 BADCVAR("sv_allow_customplayermodels_speciallist");
 261
 262                 // mapinfo
 263                 BADCVAR("fraglimit");
 264                 BADCVAR("g_arena");
 265                 BADCVAR("g_assault");
 266                 BADCVAR("g_ca");
 267                 BADCVAR("g_ca_teams");
 268                 BADCVAR("g_conquest");
 269                 BADCVAR("g_conquest_teams");
 270                 BADCVAR("g_ctf");
 271                 BADCVAR("g_cts");
 272                 BADCVAR("g_dotc");
 273                 BADCVAR("g_dm");
 274                 BADCVAR("g_domination");
 275                 BADCVAR("g_domination_default_teams");
 276                 BADCVAR("g_duel");
 277                 BADCVAR("g_duel_not_dm_maps");
 278                 BADCVAR("g_freezetag");
 279                 BADCVAR("g_freezetag_teams");
 280                 BADCVAR("g_invasion_type");
 281                 BADCVAR("g_jailbreak");
 282                 BADCVAR("g_jailbreak_teams");
 283                 BADCVAR("g_keepaway");
 284                 BADCVAR("g_keyhunt");
 285                 BADCVAR("g_keyhunt_teams");
 286                 BADCVAR("g_lms");
 287                 BADCVAR("g_nexball");
 288                 BADCVAR("g_onslaught");
 289                 BADCVAR("g_race");
 290                 BADCVAR("g_race_laps_limit");
 291                 BADCVAR("g_race_qualifying_timelimit");
 292                 BADCVAR("g_race_qualifying_timelimit_override");
 293                 BADCVAR("g_runematch");
 294                 BADCVAR("g_shootfromeye");
 295                 BADCVAR("g_snafu");
 296                 BADCVAR("g_survival");
 297                 BADCVAR("g_survival_not_dm_maps");
 298                 BADCVAR("g_tdm");
 299                 BADCVAR("g_tdm_on_dm_maps");
 300                 BADCVAR("g_tdm_teams");
 301                 BADCVAR("g_vip");
 302                 BADCVAR("leadlimit");
 303                 BADCVAR("nextmap");
 304                 BADCVAR("teamplay");
 305                 BADCVAR("timelimit");
 306                 BADCVAR("g_mapinfo_q3compat");
 307                 BADCVAR("g_mapinfo_settemp_acl");
 308                 BADCVAR("g_mapinfo_ignore_warnings");
 309                 BADCVAR("g_maplist_ignore_sizes");
 310                 BADCVAR("g_maplist_sizes_count_bots");
 311
 312                 // long
 313                 BADCVAR("hostname");
 314                 BADCVAR("g_maplist");
 315                 BADCVAR("g_maplist_mostrecent");
 316                 BADCVAR("sv_motd");
 317                 BADCVAR("sv_termsofservice_url");
 318
 319                 v = cvar_string(k);
 320                 d = cvar_defstring(k);
 321                 if(v == d)
 322                         continue;
 323
 324                 if(adding)
 325                 {
 326                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 327                         if(strlen(cvar_changes) > 16384)
 328                         {
 329                                 cvar_changes = "// too many settings have been changed to show them here\n";
 330                                 adding = 0;
 331                         }
 332                 }
 333
 334                 // now check if the changes are actually gameplay relevant
 335
 336                 // does nothing gameplay relevant
 337                 BADCVAR("captureleadlimit_override");
 338                 BADCVAR("condump_stripcolors");
 339                 BADCVAR("fs_gamedir");
 340                 BADCVAR("g_allow_oldvortexbeam");
 341                 BADCVAR("g_balance_kill_delay");
 342                 BADCVAR("g_buffs_pickup_anyway");
 343                 BADCVAR("g_buffs_randomize");
 344                 BADCVAR("g_buffs_randomize_teamplay");
 345                 BADCVAR("g_campcheck_distance");
 346                 BADCVAR("g_chatsounds");
 347                 BADCVAR("g_ca_point_leadlimit");
 348                 BADCVAR("g_ca_point_limit");
 349                 BADCVAR("g_ca_spectate_enemies");
 350                 BADCVAR("g_ctf_captimerecord_always");
 351                 BADCVAR("g_ctf_flag_glowtrails");
 352                 BADCVAR("g_ctf_dynamiclights");
 353                 BADCVAR("g_ctf_flag_pickup_verbosename");
 354                 BADCVAR("g_ctf_flagcarrier_auto_helpme_damage");
 355                 BADPRESUFFIX("g_ctf_flag_", "_model");
 356                 BADPRESUFFIX("g_ctf_flag_", "_skin");
 357                 BADCVAR("g_domination_point_leadlimit");
 358                 BADCVAR("g_forced_respawn");
 359                 BADCVAR("g_freezetag_point_leadlimit");
 360                 BADCVAR("g_freezetag_point_limit");
 361                 BADCVAR("g_glowtrails");
 362                 BADCVAR("g_hats");
 363                 BADCVAR("g_casings");
 364                 BADCVAR("g_invasion_point_limit");
 365                 BADCVAR("g_jump_grunt");
 366                 BADCVAR("g_keepaway_ballcarrier_effects");
 367                 BADCVAR("g_keepawayball_effects");
 368                 BADCVAR("g_keyhunt_point_leadlimit");
 369                 BADCVAR("g_nexball_goalleadlimit");
 370                 BADCVAR("g_new_toys_autoreplace");
 371                 BADCVAR("g_new_toys_use_pickupsound");
 372                 BADCVAR("g_physics_predictall");
 373                 BADCVAR("g_piggyback");
 374                 BADCVAR("g_playerclip_collisions");
 375                 BADCVAR("g_spawn_alloweffects");
 376                 BADCVAR("g_tdm_point_leadlimit");
 377                 BADCVAR("g_tdm_point_limit");
 378                 BADCVAR("leadlimit_and_fraglimit");
 379                 BADCVAR("leadlimit_override");
 380                 BADCVAR("pausable");
 381                 BADCVAR("sv_announcer");
 382                 BADCVAR("sv_checkforpacketsduringsleep");
 383                 BADCVAR("sv_damagetext");
 384                 BADCVAR("sv_db_saveasdump");
 385                 BADCVAR("sv_intermission_cdtrack");
 386                 BADCVAR("sv_mapchange_delay");
 387                 BADCVAR("sv_minigames");
 388                 BADCVAR("sv_namechangetimer");
 389                 BADCVAR("sv_precacheplayermodels");
 390                 BADCVAR("sv_qcphysics");
 391                 BADCVAR("sv_radio");
 392                 BADCVAR("sv_stepheight");
 393                 BADCVAR("sv_timeout");
 394                 BADCVAR("sv_weapons_modeloverride");
 395                 BADCVAR("w_prop_interval");
 396                 BADPREFIX("chat_");
 397                 BADPREFIX("crypto_");
 398                 BADPREFIX("gameversion");
 399                 BADPREFIX("g_chat_");
 400                 BADPREFIX("g_ctf_captimerecord_");
 401                 BADPREFIX("g_hats_");
 402                 BADPREFIX("g_maplist_");
 403                 BADPREFIX("g_mod_");
 404                 BADPREFIX("g_respawn_");
 405                 BADPREFIX("net_");
 406                 BADPREFIX("notification_");
 407                 BADPREFIX("prvm_");
 408                 BADPREFIX("skill_");
 409                 BADPREFIX("sv_allow_");
 410                 BADPREFIX("sv_cullentities_");
 411                 BADPREFIX("sv_maxidle");
 412                 BADPREFIX("sv_minigames_");
 413                 BADPREFIX("sv_radio_");
 414                 BADPREFIX("sv_timeout_");
 415                 BADPREFIX("sv_vote_");
 416                 BADPREFIX("timelimit_");
 417                 BADPRESUFFIX("g_", "_round_timelimit");
 418
 419                 // allowed changes to server admins (please sync this to server.cfg)
 420                 // vi commands:
 421                 //   :/"impure"/,$d
 422                 //   :g!,^\/\/[^ /],d
 423                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 424                 //   :%!sort
 425                 // yes, this does contain some redundant stuff, don't really care
 426                 BADPREFIX("bot_ai_");
 427                 BADCVAR("bot_config_file");
 428                 BADCVAR("bot_number");
 429                 BADCVAR("bot_prefix");
 430                 BADCVAR("bot_suffix");
 431                 BADCVAR("capturelimit_override");
 432                 BADCVAR("fraglimit_override");
 433                 BADCVAR("gametype");
 434                 BADCVAR("g_antilag");
 435                 BADCVAR("g_balance_teams");
 436                 BADCVAR("g_balance_teams_prevent_imbalance");
 437                 BADCVAR("g_balance_teams_scorefactor");
 438                 BADCVAR("g_ban_sync_trusted_servers");
 439                 BADCVAR("g_ban_sync_uri");
 440                 BADCVAR("g_buffs");
 441                 BADCVAR("g_ca_teams_override");
 442                 BADCVAR("g_ctf_fullbrightflags");
 443                 BADCVAR("g_ctf_ignore_frags");
 444                 BADCVAR("g_ctf_leaderboard");
 445                 BADCVAR("g_domination_point_limit");
 446                 BADCVAR("g_domination_teams_override");
 447                 BADCVAR("g_freezetag_revive_spawnshield");
 448                 BADCVAR("g_freezetag_teams_override");
 449                 BADCVAR("g_friendlyfire");
 450                 BADCVAR("g_fullbrightitems");
 451                 BADCVAR("g_fullbrightplayers");
 452                 BADCVAR("g_keyhunt_point_limit");
 453                 BADCVAR("g_keyhunt_teams_override");
 454                 BADCVAR("g_lms_lives_override");
 455                 BADCVAR("g_maplist");
 456                 BADCVAR("g_maxplayers");
 457                 BADCVAR("g_mirrordamage");
 458                 BADCVAR("g_nexball_goallimit");
 459                 BADCVAR("g_norecoil");
 460                 BADCVAR("g_physics_clientselect");
 461                 BADCVAR("g_pinata");
 462                 BADCVAR("g_powerups");
 463                 BADCVAR("g_powerups_drop_ondeath");
 464                 BADCVAR("g_player_brightness");
 465                 BADCVAR("g_rocket_flying");
 466                 BADCVAR("g_rocket_flying_disabledelays");
 467                 BADPREFIX("g_spawnshield");
 468                 BADCVAR("g_start_delay");
 469                 BADCVAR("g_superspectate");
 470                 BADCVAR("g_tdm_teams_override");
 471                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 472                 BADCVAR("hostname");
 473                 BADCVAR("log_file");
 474                 BADCVAR("maxplayers");
 475                 BADCVAR("minplayers");
 476                 BADCVAR("minplayers_per_team");
 477                 BADCVAR("net_address");
 478                 BADCVAR("port");
 479                 BADCVAR("rcon_password");
 480                 BADCVAR("rcon_restricted_commands");
 481                 BADCVAR("rcon_restricted_password");
 482                 BADCVAR("skill");
 483                 BADCVAR("sv_adminnick");
 484                 BADCVAR("sv_autoscreenshot");
 485                 BADCVAR("sv_autotaunt");
 486                 BADCVAR("sv_curl_defaulturl");
 487                 BADCVAR("sv_defaultcharacter");
 488                 BADCVAR("sv_defaultcharacterskin");
 489                 BADCVAR("sv_defaultplayercolors");
 490                 BADCVAR("sv_defaultplayermodel");
 491                 BADCVAR("sv_defaultplayerskin");
 492                 BADCVAR("sv_maxrate");
 493                 BADCVAR("sv_motd");
 494                 BADCVAR("sv_public");
 495                 BADCVAR("sv_showfps");
 496                 BADCVAR("sv_showspectators");
 497                 BADCVAR("sv_status_privacy");
 498                 BADCVAR("sv_taunt");
 499                 BADCVAR("sv_vote_call");
 500                 BADCVAR("sv_vote_commands");
 501                 BADCVAR("sv_vote_majority_factor");
 502                 BADCVAR("sv_vote_master");
 503                 BADCVAR("sv_vote_master_commands");
 504                 BADCVAR("sv_vote_master_password");
 505                 BADCVAR("sv_vote_simple_majority_factor");
 506                 BADVALUE("sys_ticrate", "0.0166667");
 507                 BADVALUE("sys_ticrate", "0.0333333");
 508                 BADCVAR("teamplay_mode");
 509                 BADCVAR("timelimit_override");
 510                 BADPREFIX("g_warmup");
 511                 BADPREFIX("sv_info_");
 512                 BADPREFIX("sv_ready_restart_");
 513
 514                 // mutators that announce themselves properly to the server browser
 515                 BADCVAR("g_instagib");
 516                 BADCVAR("g_new_toys");
 517                 BADCVAR("g_nix");
 518                 BADCVAR("g_grappling_hook");
 519                 BADCVAR("g_jetpack");
 520
 521 #undef BADPRESUFFIX
 522 #undef BADPREFIX
 523 #undef BADCVAR
 524 #undef BADVALUE
 525
 526                 if(pureadding)
 527                 {
 528                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 529                         if(strlen(cvar_purechanges) > 16384)
 530                         {
 531                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 532                                 pureadding = 0;
 533                         }
 534                 }
 535                 ++cvar_purechanges_count;
 536                 // WARNING: this variable is used for the server list
 537                 // NEVER dare to skip this code!
 538                 // Hacks to intentionally appearing as "pure server" even though you DO have
 539                 // modified settings may be punished by removal from the server list.
 540                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 541                 // though.
 542         }
 543         buf_del(h);
 544         if(cvar_changes == "")
 545                 cvar_changes = "// this server runs at default server settings\n";
 546         else
 547                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 548         cvar_changes = strzone(cvar_changes);
 549         if(cvar_purechanges == "")
 550                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 551         else
 552                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 553         cvar_purechanges = strzone(cvar_purechanges);
 554 }
 555
 556 entity randomseed;
 557 bool RandomSeed_Send(entity this, entity to, int sf)
 558 {
 559         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 560         WriteShort(MSG_ENTITY, this.cnt);
 561         return true;
 562 }
 563 void RandomSeed_Think(entity this)
 564 {
 565         this.cnt = bound(0, floor(random() * 65536), 65535);
 566         this.nextthink = time + 5;
 567
 568         this.SendFlags |= 1;
 569 }
 570 void RandomSeed_Spawn()
 571 {
 572         randomseed = new_pure(randomseed);
 573         setthink(randomseed, RandomSeed_Think);
 574         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 575
 576         getthink(randomseed)(randomseed); // sets random seed and nextthink
 577 }
 578
 579 spawnfunc(__init_dedicated_server)
 580 {
 581         // handler for _init/_init map (only for dedicated server initialization)
 582
 583         world_initialized = -1; // don't complain
 584
 585         delete_fn = remove_unsafely;
 586
 587         entity e = new(GotoFirstMap);
 588         setthink(e, GotoFirstMap);
 589         e.nextthink = time; // this is usually 1 at this point
 590
 591         e = new(info_player_deathmatch);  // safeguard against player joining
 592
 593         // assign reflectively to avoid "assignment to world" warning
 594         for (int i = 0, n = numentityfields(); i < n; ++i)
 595         {
 596                 string k = entityfieldname(i);
 597                 if (k == "classname")
 598                 {
 599                         // safeguard against various stuff ;)
 600                         putentityfieldstring(i, this, "worldspawn");
 601                         break;
 602                 }
 603         }
 604
 605         // needs to be done so early because of the constants they create
 606         static_init();
 607         static_init_late();
 608         static_init_precache();
 609
 610         IL_PUSH(g_spawnpoints, e); // just incase
 611
 612         MapInfo_Enumerate();
 613         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 614 }
 615
 616 void __init_dedicated_server_shutdown() {
 617         MapInfo_Shutdown();
 618 }
 619
 620 STATIC_INIT_EARLY(maxclients)
 621 {
 622         maxclients = 0;
 623         for (entity head = nextent(NULL); head; head = nextent(head)) {
 624                 ++maxclients;
 625         }
 626 }
 627
 628 void GameplayMode_DelayedInit(entity this)
 629 {
 630         // at this stage team entities are spawned, teamplay contains the number of them
 631
 632         if(!scores_initialized)
 633                 ScoreRules_generic();
 634
 635         if (warmup_stage >= 0 && autocvar_g_maxplayers >= 0)
 636                 return;
 637         if (!g_duel)
 638                 MapReadSizes(mapname);
 639
 640         if (autocvar_g_maxplayers < 0 && teamplay)
 641         {
 642                 // automatic maxplayers should be a multiple of team count
 643                 if (map_maxplayers == 0 || map_maxplayers > maxclients)
 644                         map_maxplayers = maxclients; // unlimited, but may need rounding
 645                 int d = map_maxplayers % AVAILABLE_TEAMS;
 646                 int u = AVAILABLE_TEAMS - d;
 647                 map_maxplayers += (u <= d && u + map_maxplayers <= maxclients) ? u : -d;
 648         }
 649
 650         if (warmup_stage < 0)
 651         {
 652                 int m = GetPlayerLimit();
 653                 if (m <= 0) m = maxclients;
 654                 map_minplayers = bound(max(2, AVAILABLE_TEAMS * 2), map_minplayers, m);
 655                 if (teamplay)
 656                 {
 657                         // automatic minplayers should be a multiple of team count
 658                         int d = map_minplayers % AVAILABLE_TEAMS;
 659                         int u = AVAILABLE_TEAMS - d;
 660                         map_minplayers += (u < d && u + map_minplayers <= m) ? u : -d;
 661                 }
 662                 warmup_limit = -1;
 663         }
 664         else
 665                 map_minplayers = 0; // don't display a minimum if it's not used
 666 }
 667
 668 void InitGameplayMode()
 669 {
 670         VoteReset();
 671
 672         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 673         get_mi_min_max(1);
 674         // assign reflectively to avoid "assignment to world" warning
 675         for (int i = 0, done = 0, n = numentityfields(); i < n; ++i)
 676         {
 677                 string k = entityfieldname(i);
 678                 vector v = (k == "mins") ? mi_min : (k == "maxs") ? mi_max : '0 0 0';
 679                 if (v)
 680                 {
 681                         putentityfieldstring(i, world, sprintf("%v", v));
 682                         if (++done == 2) break;
 683                 }
 684         }
 685         // currently, NetRadiant's limit is 131072 qu for each side
 686         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
 687         // set the distance according to map size but don't go over the limit to avoid issues with float precision
 688         // in case somebody makes extremely large maps
 689         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
 690
 691         MapInfo_LoadMapSettings(mapname);
 692         GameRules_teams(false);
 693
 694         if (!cvar_value_issafe(world.fog))
 695         {
 696                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored");
 697                 world.fog = string_null;
 698         }
 699         if(MapInfo_Map_fog != "")
 700         {
 701                 if(MapInfo_Map_fog == "none")
 702                         world.fog = string_null;
 703                 else
 704                         world.fog = strzone(MapInfo_Map_fog);
 705         }
 706         clientstuff = strzone(MapInfo_Map_clientstuff);
 707
 708         MapInfo_ClearTemps();
 709
 710         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 711
 712         cache_mutatormsg = strzone("");
 713         cache_lastmutatormsg = strzone("");
 714
 715         InitializeEntity(NULL, GameplayMode_DelayedInit, INITPRIO_GAMETYPE_FALLBACK);
 716 }
 717
 718 bool world_already_spawned;
 719 spawnfunc(worldspawn)
 720 {
 721         cvar_set("_endmatch", "0");
 722         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 723
 724         if (autocvar_sv_termsofservice_url && autocvar_sv_termsofservice_url != "")
 725         {
 726                 strcpy(sv_termsofservice_url_escaped, strreplace(":", "|", autocvar_sv_termsofservice_url));
 727         }
 728         else
 729         {
 730                 strcpy(sv_termsofservice_url_escaped, "INVALID");
 731         }
 732
 733         bool wantrestart = false;
 734         {
 735                 if (!server_is_dedicated)
 736                 {
 737                         // force unloading of server pk3 files when starting a listen server
 738                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 739                         // restore csqc_progname too
 740                         string expect = "csprogs.dat";
 741                         wantrestart = cvar_string("csqc_progname") != expect;
 742                         cvar_set("csqc_progname", expect);
 743                 }
 744                 else
 745                 {
 746                         // Try to use versioned csprogs from pk3
 747                         // Only ever use versioned csprogs.dat files on dedicated servers;
 748                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 749                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 750                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 751                         string select = "csprogs.dat";
 752                         if (fexists(pk3csprogs)) select = pk3csprogs;
 753                         if (cvar_string("csqc_progname") != select)
 754                         {
 755                                 cvar_set("csqc_progname", select);
 756                                 wantrestart = true;
 757                         }
 758                         // Check for updates on startup
 759                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 760                         int sentinel = fopen("progs.txt", FILE_READ);
 761                         if (sentinel >= 0)
 762                         {
 763                                 string switchversion = fgets(sentinel);
 764                                 fclose(sentinel);
 765                                 if (switchversion != "" && switchversion != WATERMARK)
 766                                 {
 767                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
 768                                         // if it doesn't exist, assume either:
 769                                         //   a) the current program was overwritten
 770                                         //   b) this is a client only update
 771                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 772                                         if (fexists(newprogs))
 773                                         {
 774                                                 cvar_set("sv_progs", newprogs);
 775                                                 wantrestart = true;
 776                                         }
 777                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 778                                         if (fexists(newcsprogs))
 779                                         {
 780                                                 cvar_set("csqc_progname", newcsprogs);
 781                                                 wantrestart = true;
 782                                         }
 783                                 }
 784                         }
 785                 }
 786                 if (wantrestart)
 787                 {
 788                         LOG_INFO("Restart requested");
 789                         changelevel(mapname);
 790                         // let initialization continue, shutdown depends on it
 791                 }
 792         }
 793
 794         if(world_already_spawned)
 795                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 796         world_already_spawned = true;
 797
 798         delete_fn = remove_safely; // during spawning, watch what you remove!
 799
 800         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 801
 802         // default to RACE_RECORD, can be overwritten by gamemodes
 803         record_type = RACE_RECORD;
 804
 805         // needs to be done so early because of the constants they create
 806         static_init();
 807
 808         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 809
 810         TemporaryDB = db_create();
 811
 812         // 0 normal
 813         lightstyle(0, "m");
 814
 815         // 1 FLICKER (first variety)
 816         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 817
 818         // 2 SLOW STRONG PULSE
 819         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 820
 821         // 3 CANDLE (first variety)
 822         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 823
 824         // 4 FAST STROBE
 825         lightstyle(4, "mamamamamama");
 826
 827         // 5 GENTLE PULSE 1
 828         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 829
 830         // 6 FLICKER (second variety)
 831         lightstyle(6, "nmonqnmomnmomomno");
 832
 833         // 7 CANDLE (second variety)
 834         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 835
 836         // 8 CANDLE (third variety)
 837         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 838
 839         // 9 SLOW STROBE (fourth variety)
 840         lightstyle(9, "aaaaaaaazzzzzzzz");
 841
 842         // 10 FLUORESCENT FLICKER
 843         lightstyle(10, "mmamammmmammamamaaamammma");
 844
 845         // 11 SLOW PULSE NOT FADE TO BLACK
 846         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 847
 848         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 849
 850         // 63 testing
 851         lightstyle(63, "a");
 852
 853         if(autocvar_g_campaign)
 854                 CampaignPreInit();
 855         else
 856                 PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 857
 858         Map_MarkAsRecent(mapname);
 859
 860         InitGameplayMode();
 861         static_init_late();
 862         static_init_precache();
 863         readlevelcvars();
 864
 865         GameRules_limit_fallbacks();
 866
 867         if(warmup_limit == 0)
 868                 warmup_limit = autocvar_timelimit * 60;
 869
 870         player_count = 0;
 871         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 872         if(bot_waypoints_for_items == 1)
 873                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 874                         bot_waypoints_for_items = 0;
 875
 876         WaypointSprite_Init();
 877
 878         // NOTE for matchid:
 879         // changing the logic generating it is okay. But:
 880         // it HAS to stay <= 64 chars
 881         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 882         // strftime(false, "%s") isn't reliable, see strftime_s description
 883         matchid = strzone(sprintf("%d.%s.%06d", autocvar_sv_eventlog_files_counter, strftime_s(), random() * 1000000));
 884
 885         if(autocvar_sv_eventlog)
 886                 GameLogInit(); // requires matchid to be set
 887
 888         cvar_set("nextmap", "");
 889
 890         SetDefaultAlpha();
 891
 892         if(autocvar_g_campaign)
 893                 CampaignPostInit();
 894
 895         Ban_LoadBans();
 896
 897         MapInfo_Enumerate();
 898         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 899
 900         q3compat = BITSET(q3compat, Q3COMPAT_ARENA, _MapInfo_FindArenaFile(mapname, ".arena") != "");
 901         q3compat = BITSET(q3compat, Q3COMPAT_DEFI, _MapInfo_FindArenaFile(mapname, ".defi") != "");
 902
 903         // quake 3 music support
 904         if(world.music || world.noise)
 905         {
 906                 // prefer .music over .noise
 907                 string chosen_music;
 908                 if(world.music)
 909                         chosen_music = world.music;
 910                 else
 911                         chosen_music = world.noise;
 912
 913                 string newstuff = strcat(clientstuff, "cd loop \"", chosen_music, "\"\n");
 914                 strcpy(clientstuff, newstuff);
 915         }
 916
 917         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 918         {
 919                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 920                 if(fd != -1)
 921                 {
 922                         string s;
 923                         while((s = fgets(fd)))
 924                         {
 925                                 int l = tokenize_console(s);
 926                                 if(l < 2)
 927                                         continue;
 928                                 if(argv(0) == "cd")
 929                                 {
 930                                         string trackname = argv(2);
 931                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
 932                                         LOG_INFO("  cdtrack ", trackname);
 933                                         if (cvar_value_issafe(trackname))
 934                                         {
 935                                                 string newstuff = strcat(clientstuff, "cd loop \"", trackname, "\"\n");
 936                                                 strcpy(clientstuff, newstuff);
 937                                         }
 938                                 }
 939                                 else if(argv(0) == "fog")
 940                                 {
 941                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
 942                                         LOG_INFO("  \"fog\" \"", s, "\"");
 943                                 }
 944                                 else if(argv(0) == "set")
 945                                 {
 946                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 947                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
 948                                 }
 949                                 else if(argv(0) != "//")
 950                                 {
 951                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 952                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
 953                                 }
 954                         }
 955                         fclose(fd);
 956                 }
 957         }
 958
 959         WeaponStats_Init();
 960
 961         Nagger_Init();
 962
 963         // set up information replies for clients and server to use
 964         maplist_reply = strzone(getmaplist());
 965         lsmaps_reply = strzone(getlsmaps());
 966         monsterlist_reply = strzone(getmonsterlist());
 967         bool records_available = false;
 968         for(int i = 0; i < 10; ++i)
 969         {
 970                 string s = getrecords(i);
 971                 if (s != "")
 972                 {
 973                         records_reply[i] = strzone(s);
 974                         records_available = true;
 975                 }
 976         }
 977         if (!records_available)
 978                 records_reply[0] = "No records available for the current game mode.\n";
 979         ladder_reply = strzone(getladder());
 980         rankings_reply = strzone(getrankings());
 981
 982         // begin other init
 983         ClientInit_Spawn();
 984         RandomSeed_Spawn();
 985         PingPLReport_Spawn();
 986
 987         CheatInit();
 988
 989         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 990
 991         // fill sv_curl_serverpackages from .serverpackage files
 992         if (autocvar_sv_curl_serverpackages_auto)
 993         {
 994                 string s = "csprogs-" WATERMARK ".dat";
 995                 // remove automatically managed files from the list to prevent duplicates
 996                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 997                 {
 998                         string pkg = argv(i);
 999                         if (startsWith(pkg, "csprogs-")) continue;
1000                         if (endsWith(pkg, "-serverpackage.txt")) continue;
1001                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
1002                         s = cons(s, pkg);
1003                 }
1004                 // add automatically managed files to the list
1005                 #define X(match) MACRO_BEGIN \
1006                         int fd = search_begin(match, true, false); \
1007                         if (fd >= 0) \
1008                         { \
1009                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
1010                                 { \
1011                                         s = cons(s, search_getfilename(fd, i)); \
1012                                 } \
1013                                 search_end(fd); \
1014                         } \
1015                 MACRO_END
1016                 X("*-serverpackage.txt");
1017                 X("*.serverpackage");
1018                 #undef X
1019                 cvar_set("sv_curl_serverpackages", s);
1020         }
1021
1022         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
1023         modname = "Xonotic";
1024         // physics/balance/config changes that count as mod
1025         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
1026                 modname = cvar_string("g_mod_physics");
1027         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance") && cvar_string("g_mod_balance") != "Testing")
1028                 modname = cvar_string("g_mod_balance");
1029         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
1030                 modname = cvar_string("g_mod_config");
1031         // extra mutators that deserve to count as mod
1032         MUTATOR_CALLHOOK(SetModname, modname);
1033         modname = M_ARGV(0, string);
1034
1035         // save it for later
1036         modname = strzone(modname);
1037
1038         WinningConditionHelper(this); // set worldstatus
1039
1040         world_initialized = 1;
1041         __spawnfunc_spawn_all();
1042 }
1043
1044 spawnfunc(light)
1045 {
1046         //makestatic (this); // Who the f___ did that?
1047         delete(this);
1048 }
1049
1050 bool MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, int attempts, float maxaboveground, float minviewdistance, bool frompos)
1051 {
1052         float m = e.dphitcontentsmask;
1053         e.dphitcontentsmask = goodcontents | badcontents;
1054
1055         vector org = boundmin;
1056         vector delta = boundmax - boundmin;
1057
1058         vector start, end;
1059         start = end = org;
1060         int j; // used after the loop
1061         for(j = 0; j < attempts; ++j)
1062         {
1063                 start.x = org.x + random() * delta.x;
1064                 start.y = org.y + random() * delta.y;
1065                 start.z = org.z + random() * delta.z;
1066
1067                 // rule 1: start inside world bounds, and outside
1068                 // solid, and don't start from somewhere where you can
1069                 // fall down to evil
1070                 tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1071                 if (trace_fraction >= 1)
1072                         continue;
1073                 if (trace_startsolid)
1074                         continue;
1075                 if (trace_dphitcontents & badcontents)
1076                         continue;
1077                 if (trace_dphitq3surfaceflags & badsurfaceflags)
1078                         continue;
1079
1080                 // rule 2: if we are too high, lower the point
1081                 if (trace_fraction * delta.z > maxaboveground)
1082                         start = trace_endpos + '0 0 1' * maxaboveground;
1083                 vector enddown = trace_endpos;
1084
1085                 // rule 3: make sure we aren't outside the map. This only works
1086                 // for somewhat well formed maps. A good rule of thumb is that
1087                 // the map should have a convex outside hull.
1088                 // these can be traceLINES as we already verified the starting box
1089                 vector mstart = start + 0.5 * (e.mins + e.maxs);
1090                 traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1091                 if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1092                         continue;
1093                 traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1094                 if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1095                         continue;
1096                 traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1097                 if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1098                         continue;
1099                 traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1100                 if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1101                         continue;
1102                 traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1103                 if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1104                         continue;
1105
1106                 // rule 4: we must "see" some spawnpoint or item
1107                 entity sp = NULL;
1108                 if(frompos)
1109                 {
1110                         if((traceline(mstart, e.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1111                                 sp = e;
1112                 }
1113                 if(!sp)
1114                 {
1115                         IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1116                         {
1117                                 if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1118                                 {
1119                                         sp = it;
1120                                         break;
1121                                 }
1122                         });
1123                 }
1124                 if(!sp)
1125                 {
1126                         int items_checked = 0;
1127                         IL_EACH(g_items, checkpvs(mstart, it),
1128                         {
1129                                 if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1130                                 {
1131                                         sp = it;
1132                                         break;
1133                                 }
1134
1135                                 ++items_checked;
1136                                 if(items_checked >= attempts)
1137                                         break; // sanity
1138                         });
1139
1140                         if(!sp)
1141                                 continue;
1142                 }
1143
1144                 // find a random vector to "look at"
1145                 end.x = org.x + random() * delta.x;
1146                 end.y = org.y + random() * delta.y;
1147                 end.z = org.z + random() * delta.z;
1148                 end = start + normalize(end - start) * vlen(delta);
1149
1150                 // rule 4: start TO end must not be too short
1151                 tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1152                 if(trace_startsolid)
1153                         continue;
1154                 if(trace_fraction < minviewdistance / vlen(delta))
1155                         continue;
1156
1157                 // rule 5: don't want to look at sky
1158                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1159                         continue;
1160
1161                 // rule 6: we must not end up in trigger_hurt
1162                 if(tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1163                         continue;
1164
1165                 break;
1166         }
1167
1168         e.dphitcontentsmask = m;
1169
1170         if(j < attempts)
1171         {
1172                 setorigin(e, start);
1173                 e.angles = vectoangles(end - start);
1174                 LOG_DEBUG("Needed ", ftos(j + 1), " attempts");
1175                 return true;
1176         }
1177         return false;
1178 }
1179
1180 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1181 {
1182         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance, false);
1183 }
1184
1185 /*
1186 ===============================================================================
1187
1188 RULES
1189
1190 ===============================================================================
1191 */
1192
1193 void DumpStats(float final)
1194 {
1195         float file;
1196         string s;
1197         float to_console;
1198         float to_eventlog;
1199         float to_file;
1200         float i;
1201
1202         to_console = autocvar_sv_logscores_console;
1203         to_eventlog = autocvar_sv_eventlog;
1204         to_file = autocvar_sv_logscores_file;
1205
1206         if(!final)
1207         {
1208                 to_console = true; // always print printstats replies
1209                 to_eventlog = false; // but never print them to the event log
1210         }
1211
1212         if(to_eventlog)
1213                 if(autocvar_sv_eventlog_console)
1214                         to_console = false; // otherwise we get the output twice
1215
1216         if(final)
1217                 s = ":scores:";
1218         else
1219                 s = ":status:";
1220         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1221
1222         if(to_console)
1223                 LOG_HELP(s);
1224         if(to_eventlog)
1225                 GameLogEcho(s);
1226
1227         file = -1;
1228         if(to_file)
1229         {
1230                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1231                 if(file == -1)
1232                         to_file = false;
1233                 else
1234                         fputs(file, strcat(s, "\n"));
1235         }
1236
1237         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1238         if(to_console)
1239                 LOG_HELP(s);
1240         if(to_eventlog)
1241                 GameLogEcho(s);
1242         if(to_file)
1243                 fputs(file, strcat(s, "\n"));
1244
1245         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1246                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1247                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1248                 if(IS_PLAYER(it) || INGAME_JOINED(it))
1249                         s = strcat(s, ftos(it.team), ":");
1250                 else
1251                         s = strcat(s, "spectator:");
1252
1253                 if(to_console)
1254                         LOG_HELP(s, playername(it.netname, it.team, false));
1255                 if(to_eventlog)
1256                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it.netname, it.team, false)));
1257                 if(to_file)
1258                         fputs(file, strcat(s, playername(it.netname, it.team, false), "\n"));
1259         });
1260
1261         if(teamplay)
1262         {
1263                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1264                 if(to_console)
1265                         LOG_HELP(s);
1266                 if(to_eventlog)
1267                         GameLogEcho(s);
1268                 if(to_file)
1269                         fputs(file, strcat(s, "\n"));
1270
1271                 for(i = 1; i < 16; ++i)
1272                 {
1273                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1274                         s = strcat(s, ":", ftos(i));
1275                         if(to_console)
1276                                 LOG_HELP(s);
1277                         if(to_eventlog)
1278                                 GameLogEcho(s);
1279                         if(to_file)
1280                                 fputs(file, strcat(s, "\n"));
1281                 }
1282         }
1283
1284         if(to_console)
1285                 LOG_HELP(":end");
1286         if(to_eventlog)
1287                 GameLogEcho(":end");
1288         if(to_file)
1289         {
1290                 fputs(file, ":end\n");
1291                 fclose(file);
1292         }
1293 }
1294
1295 /*
1296 go to the next level for deathmatch
1297 only called if a time or frag limit has expired
1298 */
1299 void NextLevel()
1300 {
1301         cvar_set("_endmatch", "0");
1302         game_stopped = true;
1303         intermission_running = true; // game over
1304
1305         // enforce a wait time before allowing changelevel
1306         if(player_count > 0)
1307                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1308         else
1309                 intermission_exittime = -1;
1310
1311         /*
1312         WriteByte (MSG_ALL, SVC_CDTRACK);
1313         WriteByte (MSG_ALL, 3);
1314         WriteByte (MSG_ALL, 3);
1315         // done in FixIntermission
1316         */
1317
1318         //pos = FindIntermission ();
1319
1320         VoteReset();
1321
1322         DumpStats(true);
1323
1324         // send statistics
1325         PlayerStats_GameReport(true);
1326         WeaponStats_Shutdown();
1327
1328         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1329
1330         if(autocvar_sv_eventlog)
1331                 GameLogEcho(":gameover");
1332
1333         GameLogClose();
1334
1335         int winner_team = 0;
1336         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), {
1337                 FixIntermissionClient(it);
1338                 if(it.winning)
1339                 {
1340                         if (teamplay && !winner_team)
1341                         {
1342                                 winner_team = it.team;
1343                                 bprint(Team_ColorCode(winner_team), Team_ColorName_Upper(winner_team), "^7 team wins the match\n");
1344                         }
1345                         bprint(playername(it.netname, it.team, false), " ^7wins\n");
1346                 }
1347         });
1348
1349         target_music_kill();
1350
1351         if(autocvar_g_campaign)
1352                 CampaignPreIntermission();
1353
1354         MUTATOR_CALLHOOK(MatchEnd);
1355
1356         localcmd("\nsv_hook_gameend\n");
1357 }
1358
1359
1360 int InitiateSuddenDeath()
1361 {
1362         // Check first whether normal overtimes could be added before initiating suddendeath mode
1363         // - for this timelimit_overtime needs to be >0 of course
1364         // - also check the winning condition calculated in the previous frame and only add normal overtime
1365         //   again, if at the point at which timelimit would be extended again, still no winner was found
1366         if (!autocvar_g_campaign && checkrules_overtimesadded >= 0
1367                 && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0)
1368                 && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1369         {
1370                 return 1; // need to call InitiateOvertime later
1371         }
1372         else
1373         {
1374                 if(!checkrules_suddendeathend)
1375                 {
1376                         if(autocvar_g_campaign)
1377                         {
1378                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1379                         }
1380                         else
1381                         {
1382                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1383                                 overtimes = -1;
1384                         }
1385                         if(g_race && !g_race_qualifying)
1386                                 race_StartCompleting();
1387                 }
1388                 return 0;
1389         }
1390 }
1391
1392 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1393 {
1394         ++checkrules_overtimesadded;
1395         overtimes = checkrules_overtimesadded;
1396         //add one more overtime by simply extending the timelimit
1397         cvar_set("timelimit", ftos(autocvar_timelimit + autocvar_timelimit_overtime));
1398         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1399 }
1400
1401 float GetWinningCode(float fraglimitreached, float equality)
1402 {
1403         if(autocvar_g_campaign == 1)
1404         {
1405                 if(fraglimitreached)
1406                         return WINNING_YES;
1407                 else
1408                         return WINNING_NO;
1409         }
1410         else
1411         {
1412                 if(equality)
1413                 {
1414                         if(fraglimitreached)
1415                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1416                         else
1417                                 return WINNING_NEVER;
1418                 }
1419                 else
1420                 {
1421                         if(fraglimitreached)
1422                                 return WINNING_YES;
1423                         else
1424                                 return WINNING_NO;
1425                 }
1426         }
1427 }
1428
1429 // set the .winning flag for exactly those players with a given field value
1430 void SetWinners(.float field, float value)
1431 {
1432         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), { it.winning = (it.(field) == value); });
1433 }
1434
1435 // set the .winning flag for those players with a given field value
1436 void AddWinners(.float field, float value)
1437 {
1438         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), {
1439                 if(it.(field) == value)
1440                         it.winning = 1;
1441         });
1442 }
1443
1444 // clear the .winning flags
1445 void ClearWinners()
1446 {
1447         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), { it.winning = 0; });
1448 }
1449
1450 int fragsleft_last;
1451 float WinningCondition_Scores(float limit, float leadlimit)
1452 {
1453         // TODO make everything use THIS winning condition (except LMS)
1454         WinningConditionHelper(NULL);
1455
1456         if(teamplay)
1457         {
1458                 for (int i = 1; i < 5; ++i)
1459                 {
1460                         Team_SetTeamScore(Team_GetTeamFromIndex(i),
1461                                 TeamScore_GetCompareValue(Team_IndexToTeam(i)));
1462                 }
1463         }
1464
1465         ClearWinners();
1466         if(WinningConditionHelper_winner)
1467                 WinningConditionHelper_winner.winning = 1;
1468         if(WinningConditionHelper_winnerteam >= 0)
1469                 SetWinners(team, WinningConditionHelper_winnerteam);
1470
1471         if(WinningConditionHelper_lowerisbetter)
1472         {
1473                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1474                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1475                 limit = -limit;
1476         }
1477
1478         if(WinningConditionHelper_zeroisworst)
1479                 leadlimit = 0; // not supported in this mode
1480
1481         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1482         {
1483                 float fragsleft;
1484                 if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1485                 {
1486                         fragsleft = 1;
1487                 }
1488                 else
1489                 {
1490                         fragsleft = FLOAT_MAX;
1491                         float leadingfragsleft = FLOAT_MAX;
1492                         if (limit)
1493                                 fragsleft = limit - WinningConditionHelper_topscore;
1494                         if (leadlimit)
1495                                 leadingfragsleft = WinningConditionHelper_secondscore + leadlimit - WinningConditionHelper_topscore;
1496
1497                         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1498                                 fragsleft = max(fragsleft, leadingfragsleft);
1499                         else
1500                                 fragsleft = min(fragsleft, leadingfragsleft);
1501                 }
1502
1503                 if (fragsleft_last != fragsleft) // do not announce same remaining frags multiple times
1504                 {
1505                         if (fragsleft == 1)
1506                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1507                         else if (fragsleft == 2)
1508                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1509                         else if (fragsleft == 3)
1510                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1511
1512                         fragsleft_last = fragsleft;
1513                 }
1514         }
1515
1516         bool fraglimit_reached = (limit && WinningConditionHelper_topscore >= limit);
1517         bool leadlimit_reached = (leadlimit && WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1518
1519         bool limit_reached;
1520         // only respect leadlimit_and_fraglimit when both limits are set or the game will never end
1521         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1522                 limit_reached = (fraglimit_reached && leadlimit_reached);
1523         else
1524                 limit_reached = (fraglimit_reached || leadlimit_reached);
1525
1526         return GetWinningCode(
1527                 WinningConditionHelper_topscore && limit_reached,
1528                 WinningConditionHelper_equality
1529         );
1530 }
1531
1532 float WinningCondition_RanOutOfSpawns()
1533 {
1534         if(have_team_spawns <= 0)
1535                 return WINNING_NO;
1536
1537         if(!autocvar_g_spawn_useallspawns)
1538                 return WINNING_NO;
1539
1540         if(!some_spawn_has_been_used)
1541                 return WINNING_NO;
1542
1543         for (int i = 1; i < 5; ++i)
1544         {
1545                 Team_SetTeamScore(Team_GetTeamFromIndex(i), 0);
1546         }
1547
1548         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
1549         {
1550                 if (Team_IsValidTeam(it.team))
1551                 {
1552                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1553                 }
1554         });
1555
1556         IL_EACH(g_spawnpoints, true,
1557         {
1558                 if (Team_IsValidTeam(it.team))
1559                 {
1560                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1561                 }
1562         });
1563
1564         ClearWinners();
1565         float team1_score = Team_GetTeamScore(Team_GetTeamFromIndex(1));
1566         float team2_score = Team_GetTeamScore(Team_GetTeamFromIndex(2));
1567         float team3_score = Team_GetTeamScore(Team_GetTeamFromIndex(3));
1568         float team4_score = Team_GetTeamScore(Team_GetTeamFromIndex(4));
1569         if(team1_score + team2_score + team3_score + team4_score == 0)
1570         {
1571                 checkrules_equality = true;
1572                 return WINNING_YES;
1573         }
1574         else if(team1_score + team2_score + team3_score + team4_score == 1)
1575         {
1576                 float t, i;
1577                 if(team1_score)
1578                         t = 1;
1579                 else if(team2_score)
1580                         t = 2;
1581                 else if(team3_score)
1582                         t = 3;
1583                 else // if(team4_score)
1584                         t = 4;
1585                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
1586                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1587                 {
1588                         for (int j = 1; j <= NUM_TEAMS; ++j)
1589                         {
1590                                 if (t == j)
1591                                 {
1592                                         continue;
1593                                 }
1594                                 if (!TeamBalance_IsTeamAllowed(balance, j))
1595                                 {
1596                                         continue;
1597                                 }
1598                                 TeamScore_AddToTeam(Team_IndexToTeam(j), i, -1000);
1599                         }
1600                 }
1601
1602                 AddWinners(team, t);
1603                 return WINNING_YES;
1604         }
1605         else
1606                 return WINNING_NO;
1607 }
1608
1609 /*
1610 ============
1611 CheckRules_World
1612
1613 Exit deathmatch games upon conditions
1614 ============
1615 */
1616 void CheckRules_World()
1617 {
1618         VoteThink();
1619         MapVote_Think();
1620
1621         SetDefaultAlpha();
1622
1623         if (intermission_running) // someone else quit the game already
1624         {
1625                 if(player_count == 0) // Nobody there? Then let's go to the next map
1626                         MapVote_Start();
1627                         // this will actually check the player count in the next frame
1628                         // again, but this shouldn't hurt
1629                 return;
1630         }
1631
1632         float timelimit = autocvar_timelimit * 60;
1633         float fraglimit = autocvar_fraglimit;
1634         float leadlimit = autocvar_leadlimit;
1635         if (leadlimit < 0) leadlimit = 0;
1636
1637         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1638         {
1639                 if(timelimit > 0)
1640                         timelimit = 0; // timelimit is not made for warmup
1641                 if(fraglimit > 0)
1642                         fraglimit = 0; // no fraglimit for now
1643                 leadlimit = 0; // no leadlimit for now
1644         }
1645
1646         if (autocvar__endmatch || timelimit < 0)
1647         {
1648                 // endmatch
1649                 NextLevel();
1650                 return;
1651         }
1652
1653         if(timelimit > 0)
1654                 timelimit += game_starttime;
1655
1656         int overtimes_prev = overtimes;
1657         int wantovertime = 0;
1658
1659         if(checkrules_suddendeathend)
1660         {
1661                 if(!checkrules_suddendeathwarning)
1662                 {
1663                         checkrules_suddendeathwarning = true;
1664                         if(g_race && !g_race_qualifying)
1665                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1666                         else
1667                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1668                 }
1669         }
1670         else
1671         {
1672                 if (timelimit && time >= timelimit)
1673                 {
1674                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1675                         {
1676                                 float totalplayers;
1677                                 float playerswithlaps;
1678                                 float readyplayers;
1679                                 totalplayers = playerswithlaps = readyplayers = 0;
1680                                 FOREACH_CLIENT(IS_PLAYER(it), {
1681                                         ++totalplayers;
1682                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1683                                                 ++playerswithlaps;
1684                                         if(it.ready)
1685                                                 ++readyplayers;
1686                                 });
1687
1688                                 // at least 2 of the players have completed a lap: start the RACE
1689                                 // otherwise, the players should end the qualifying on their own
1690                                 if(readyplayers || playerswithlaps >= 2)
1691                                 {
1692                                         checkrules_suddendeathend = 0;
1693                                         ReadyRestart(true); // go to race
1694                                         return;
1695                                 }
1696                                 else
1697                                         wantovertime |= InitiateSuddenDeath();
1698                         }
1699                         else
1700                                 wantovertime |= InitiateSuddenDeath();
1701                 }
1702         }
1703
1704         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1705         {
1706                 NextLevel();
1707                 return;
1708         }
1709
1710         int checkrules_status = WinningCondition_RanOutOfSpawns();
1711         if(checkrules_status == WINNING_YES)
1712                 bprint("Hey! Someone ran out of spawns!\n");
1713         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1714                 checkrules_status = M_ARGV(0, float);
1715         else
1716                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1717
1718         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1719         {
1720                 checkrules_status = WINNING_NEVER;
1721                 checkrules_overtimesadded = -1;
1722                 wantovertime |= InitiateSuddenDeath();
1723         }
1724
1725         if(checkrules_status == WINNING_NEVER)
1726                 // equality cases! Nobody wins if the overtime ends in a draw.
1727                 ClearWinners();
1728
1729         if(wantovertime)
1730         {
1731                 if(checkrules_status == WINNING_NEVER)
1732                         InitiateOvertime();
1733                 else
1734                         checkrules_status = WINNING_YES;
1735         }
1736
1737         if(checkrules_suddendeathend)
1738                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1739                         checkrules_status = WINNING_YES;
1740
1741         if(checkrules_status == WINNING_YES)
1742         {
1743                 if (overtimes == -1 && overtimes != overtimes_prev)
1744                 {
1745                         // if suddendeathend overtime has just begun, revert it
1746                         checkrules_suddendeathend = 0;
1747                         overtimes = overtimes_prev;
1748                 }
1749                 //print("WINNING\n");
1750                 NextLevel();
1751         }
1752 }
1753
1754 float want_weapon(entity weaponinfo, float allguns)
1755 {
1756         int d = 0;
1757         bool allow_mutatorblocked = false;
1758
1759         if(!weaponinfo.m_id)
1760                 return 0;
1761
1762         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
1763         d = M_ARGV(1, float);
1764         allguns = M_ARGV(2, bool);
1765         allow_mutatorblocked = M_ARGV(3, bool);
1766
1767         if(allguns)
1768                 d = boolean((weaponinfo.spawnflags & WEP_FLAG_NORMAL) && !(weaponinfo.spawnflags & (WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)));
1769         else if(!mutator_returnvalue)
1770                 d = !(!weaponinfo.weaponstart);
1771
1772         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
1773                 d = 0;
1774
1775         float t = weaponinfo.weaponstartoverride;
1776
1777         //LOG_INFOF("want_weapon: %s - d: %d t: %d\n", weaponinfo.netname, d, t);
1778
1779         // bit order in t:
1780         // 1: want or not
1781         // 2: is default?
1782         // 4: is set by default?
1783         if(t < 0)
1784                 t = 4 | (3 * d);
1785         else
1786                 t |= (2 * d);
1787
1788         return t;
1789 }
1790
1791 /// Weapons the player normally starts with outside weapon arena.
1792 WepSet weapons_start()
1793 {
1794         WepSet ret = '0 0 0';
1795         FOREACH(Weapons, it != WEP_Null, {
1796                 int w = want_weapon(it, false);
1797                 if (w & 1)
1798                         ret |= it.m_wepset;
1799         });
1800         return ret;
1801 }
1802
1803 WepSet weapons_all()
1804 {
1805         WepSet ret = '0 0 0';
1806         FOREACH(Weapons, it != WEP_Null, {
1807                 if (!(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_SPECIALATTACK)))
1808                         ret |= it.m_wepset;
1809         });
1810         return ret;
1811 }
1812
1813 WepSet weapons_devall()
1814 {
1815         WepSet ret = '0 0 0';
1816         FOREACH(Weapons, it != WEP_Null,
1817         {
1818                 ret |= it.m_wepset;
1819         });
1820         return ret;
1821 }
1822
1823 WepSet weapons_most()
1824 {
1825         WepSet ret = '0 0 0';
1826         FOREACH(Weapons, it != WEP_Null, {
1827                 if ((it.spawnflags & WEP_FLAG_NORMAL) && !(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)))
1828                         ret |= it.m_wepset;
1829         });
1830         return ret;
1831 }
1832
1833 void weaponarena_available_all_update(entity this)
1834 {
1835         if (weaponsInMapAll)
1836         {
1837                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_all());
1838         }
1839         else
1840         {
1841                 // if no weapons are available on the map, just fall back to all weapons arena
1842                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_all();
1843         }
1844 }
1845
1846 void weaponarena_available_devall_update(entity this)
1847 {
1848         if (weaponsInMapAll)
1849         {
1850                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | weaponsInMapAll;
1851         }
1852         else
1853         {
1854                 // if no weapons are available on the map, just fall back to devall weapons arena
1855                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_devall();
1856         }
1857 }
1858
1859 void weaponarena_available_most_update(entity this)
1860 {
1861         if (weaponsInMapAll)
1862         {
1863                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_most());
1864         }
1865         else
1866         {
1867                 // if no weapons are available on the map, just fall back to most weapons arena
1868                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_most();
1869         }
1870 }
1871
1872 void readplayerstartcvars()
1873 {
1874         // initialize starting values for players
1875         start_weapons = '0 0 0';
1876         start_weapons_default = '0 0 0';
1877         start_weapons_defaultmask = '0 0 0';
1878         start_items = 0;
1879         start_ammo_shells = 0;
1880         start_ammo_nails = 0;
1881         start_ammo_rockets = 0;
1882         start_ammo_cells = 0;
1883         start_ammo_plasma = 0;
1884         if (random_start_ammo == NULL)
1885         {
1886                 random_start_ammo = new_pure(random_start_ammo);
1887         }
1888         start_health = cvar("g_balance_health_start");
1889         start_armorvalue = cvar("g_balance_armor_start");
1890
1891         g_weaponarena = 0;
1892         g_weaponarena_weapons = '0 0 0';
1893
1894         string s = cvar_string("g_weaponarena");
1895
1896         MUTATOR_CALLHOOK(SetWeaponArena, s);
1897         s = M_ARGV(0, string);
1898
1899         if (s == "0" || s == "")
1900         {
1901                 // no arena
1902         }
1903         else if (s == "off")
1904         {
1905                 // forcibly turn off weaponarena
1906         }
1907         else if (s == "all" || s == "1")
1908         {
1909                 g_weaponarena = 1;
1910                 g_weaponarena_list = "All Weapons Arena";
1911                 g_weaponarena_weapons = weapons_all();
1912         }
1913         else if (s == "devall")
1914         {
1915                 g_weaponarena = 1;
1916                 g_weaponarena_list = "Dev All Weapons Arena";
1917                 g_weaponarena_weapons = weapons_devall();
1918         }
1919         else if (s == "most")
1920         {
1921                 g_weaponarena = 1;
1922                 g_weaponarena_list = "Most Weapons Arena";
1923                 g_weaponarena_weapons = weapons_most();
1924         }
1925         else if (s == "all_available")
1926         {
1927                 g_weaponarena = 1;
1928                 g_weaponarena_list = "All Available Weapons Arena";
1929
1930                 // this needs to run after weaponsInMapAll is initialized
1931                 InitializeEntity(NULL, weaponarena_available_all_update, INITPRIO_FINDTARGET);
1932         }
1933         else if (s == "devall_available")
1934         {
1935                 g_weaponarena = 1;
1936                 g_weaponarena_list = "Dev All Available Weapons Arena";
1937
1938                 // this needs to run after weaponsInMapAll is initialized
1939                 InitializeEntity(NULL, weaponarena_available_devall_update, INITPRIO_FINDTARGET);
1940         }
1941         else if (s == "most_available")
1942         {
1943                 g_weaponarena = 1;
1944                 g_weaponarena_list = "Most Available Weapons Arena";
1945
1946                 // this needs to run after weaponsInMapAll is initialized
1947                 InitializeEntity(NULL, weaponarena_available_most_update, INITPRIO_FINDTARGET);
1948         }
1949         else if (s == "none")
1950         {
1951                 g_weaponarena = 1;
1952                 g_weaponarena_list = "No Weapons Arena";
1953         }
1954         else
1955         {
1956                 g_weaponarena = 1;
1957                 float t = tokenize_console(s);
1958                 g_weaponarena_list = "";
1959                 for (int j = 0; j < t; ++j)
1960                 {
1961                         s = argv(j);
1962                         Weapon wep = Weapon_from_name(s);
1963                         if(wep != WEP_Null)
1964                         {
1965                                 g_weaponarena_weapons |= (wep.m_wepset);
1966                                 g_weaponarena_list = strcat(g_weaponarena_list, wep.netname, " & ");
1967                         }
1968                 }
1969                 if (g_weaponarena_list != "") // remove trailing " & "
1970                         g_weaponarena_list = substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3);
1971                 else // no valid weapon found
1972                         g_weaponarena_list = "No Weapons Arena";
1973         }
1974
1975         if (g_weaponarena)
1976         {
1977                 g_weapon_stay = 0; // incompatible
1978                 start_weapons = g_weaponarena_weapons;
1979                 start_items |= IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS;
1980                 g_weaponarena_list = strzone(g_weaponarena_list);
1981         }
1982         else
1983         {
1984                 FOREACH(Weapons, it != WEP_Null, {
1985                         int w = want_weapon(it, false);
1986                         WepSet s = it.m_wepset;
1987                         if(w & 1)
1988                                 start_weapons |= s;
1989                         if(w & 2)
1990                                 start_weapons_default |= s;
1991                         if(w & 4)
1992                                 start_weapons_defaultmask |= s;
1993                 });
1994         }
1995
1996         if(cvar("g_balance_superweapons_time") < 0)
1997                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
1998
1999         if(!cvar("g_use_ammunition"))
2000                 start_items |= IT_UNLIMITED_AMMO;
2001
2002         if(start_items & IT_UNLIMITED_AMMO)
2003         {
2004                 start_ammo_shells = 999;
2005                 start_ammo_nails = 999;
2006                 start_ammo_rockets = 999;
2007                 start_ammo_cells = 999;
2008                 start_ammo_plasma = 999;
2009                 start_ammo_fuel = 999;
2010         }
2011         else
2012         {
2013                 start_ammo_shells = cvar("g_start_ammo_shells");
2014                 start_ammo_nails = cvar("g_start_ammo_nails");
2015                 start_ammo_rockets = cvar("g_start_ammo_rockets");
2016                 start_ammo_cells = cvar("g_start_ammo_cells");
2017                 start_ammo_plasma = cvar("g_start_ammo_plasma");
2018                 start_ammo_fuel = cvar("g_start_ammo_fuel");
2019                 random_start_weapons_count = cvar("g_random_start_weapons_count");
2020                 SetResource(random_start_ammo, RES_SHELLS, cvar("g_random_start_shells"));
2021                 SetResource(random_start_ammo, RES_BULLETS, cvar("g_random_start_bullets"));
2022                 SetResource(random_start_ammo, RES_ROCKETS, cvar("g_random_start_rockets"));
2023                 SetResource(random_start_ammo, RES_CELLS, cvar("g_random_start_cells"));
2024                 SetResource(random_start_ammo, RES_PLASMA, cvar("g_random_start_plasma"));
2025         }
2026
2027         warmup_start_ammo_shells = start_ammo_shells;
2028         warmup_start_ammo_nails = start_ammo_nails;
2029         warmup_start_ammo_rockets = start_ammo_rockets;
2030         warmup_start_ammo_cells = start_ammo_cells;
2031         warmup_start_ammo_plasma = start_ammo_plasma;
2032         warmup_start_ammo_fuel = start_ammo_fuel;
2033         warmup_start_health = start_health;
2034         warmup_start_armorvalue = start_armorvalue;
2035         warmup_start_weapons = start_weapons;
2036         warmup_start_weapons_default = start_weapons_default;
2037         warmup_start_weapons_defaultmask = start_weapons_defaultmask;
2038
2039         if (!g_weaponarena)
2040         {
2041                 warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
2042                 warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
2043                 warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
2044                 warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
2045                 warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
2046                 warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
2047                 warmup_start_health = cvar("g_warmup_start_health");
2048                 warmup_start_armorvalue = cvar("g_warmup_start_armor");
2049                 warmup_start_weapons = '0 0 0';
2050                 warmup_start_weapons_default = '0 0 0';
2051                 warmup_start_weapons_defaultmask = '0 0 0';
2052                 FOREACH(Weapons, it != WEP_Null, {
2053                         int w = want_weapon(it, autocvar_g_warmup_allguns);
2054                         WepSet s = it.m_wepset;
2055                         if(w & 1)
2056                                 warmup_start_weapons |= s;
2057                         if(w & 2)
2058                                 warmup_start_weapons_default |= s;
2059                         if(w & 4)
2060                                 warmup_start_weapons_defaultmask |= s;
2061                 });
2062         }
2063
2064         if (autocvar_g_jetpack)
2065                 start_items |= ITEM_Jetpack.m_itemid;
2066
2067         MUTATOR_CALLHOOK(SetStartItems);
2068
2069         if (start_items & ITEM_Jetpack.m_itemid)
2070         {
2071                 start_items |= ITEM_JetpackRegen.m_itemid;
2072                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
2073                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
2074         }
2075
2076         start_ammo_shells = max(0, start_ammo_shells);
2077         start_ammo_nails = max(0, start_ammo_nails);
2078         start_ammo_rockets = max(0, start_ammo_rockets);
2079         start_ammo_cells = max(0, start_ammo_cells);
2080         start_ammo_plasma = max(0, start_ammo_plasma);
2081         start_ammo_fuel = max(0, start_ammo_fuel);
2082         SetResource(random_start_ammo, RES_SHELLS, max(0, GetResource(random_start_ammo, RES_SHELLS)));
2083         SetResource(random_start_ammo, RES_BULLETS, max(0, GetResource(random_start_ammo, RES_BULLETS)));
2084         SetResource(random_start_ammo, RES_ROCKETS, max(0, GetResource(random_start_ammo, RES_ROCKETS)));
2085         SetResource(random_start_ammo, RES_CELLS, max(0, GetResource(random_start_ammo, RES_CELLS)));
2086         SetResource(random_start_ammo, RES_PLASMA, max(0, GetResource(random_start_ammo, RES_PLASMA)));
2087
2088         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
2089         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
2090         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
2091         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
2092         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
2093         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
2094 }
2095
2096 void readlevelcvars()
2097 {
2098         serverflags &= ~SERVERFLAG_ALLOW_FULLBRIGHT;
2099         if(cvar("sv_allow_fullbright"))
2100                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
2101
2102         sv_ready_restart_after_countdown = cvar("sv_ready_restart_after_countdown");
2103
2104         warmup_stage = cvar("g_warmup");
2105         warmup_limit = cvar("g_warmup_limit");
2106
2107         if(cvar("g_campaign"))
2108                 warmup_stage = 0; // no warmup during campaign
2109
2110         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
2111         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
2112         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
2113         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
2114         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
2115         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
2116         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
2117         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
2118         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
2119         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
2120         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
2121         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
2122         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
2123         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
2124
2125         g_pickup_shells = cvar("g_pickup_shells");
2126         g_pickup_shells_max = cvar("g_pickup_shells_max");
2127         g_pickup_nails = cvar("g_pickup_nails");
2128         g_pickup_nails_max = cvar("g_pickup_nails_max");
2129         g_pickup_rockets = cvar("g_pickup_rockets");
2130         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
2131         g_pickup_cells = cvar("g_pickup_cells");
2132         g_pickup_cells_max = cvar("g_pickup_cells_max");
2133         g_pickup_plasma = cvar("g_pickup_plasma");
2134         g_pickup_plasma_max = cvar("g_pickup_plasma_max");
2135         g_pickup_fuel = cvar("g_pickup_fuel");
2136         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
2137         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
2138         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
2139         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
2140         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
2141         g_pickup_armormedium = cvar("g_pickup_armormedium");
2142         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
2143         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
2144         g_pickup_armorbig = cvar("g_pickup_armorbig");
2145         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
2146         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
2147         g_pickup_armormega = cvar("g_pickup_armormega");
2148         g_pickup_armormega_max = cvar("g_pickup_armormega_max");
2149         g_pickup_armormega_anyway = cvar("g_pickup_armormega_anyway");
2150         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
2151         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
2152         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
2153         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
2154         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
2155         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
2156         g_pickup_healthbig = cvar("g_pickup_healthbig");
2157         g_pickup_healthbig_max = cvar("g_pickup_healthbig_max");
2158         g_pickup_healthbig_anyway = cvar("g_pickup_healthbig_anyway");
2159         g_pickup_healthmega = cvar("g_pickup_healthmega");
2160         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
2161         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
2162
2163         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
2164         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
2165
2166         g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
2167         if(!g_weapon_stay)
2168                 g_weapon_stay = cvar("g_weapon_stay");
2169
2170         MUTATOR_CALLHOOK(ReadLevelCvars);
2171
2172         if (!warmup_stage && !autocvar_g_campaign)
2173                 game_starttime = time + cvar("g_start_delay");
2174
2175         FOREACH(Weapons, it != WEP_Null, { it.wr_init(it); });
2176
2177         readplayerstartcvars();
2178 }
2179
2180 void InitializeEntity(entity e, void(entity this) func, int order)
2181 {
2182         entity prev, cur;
2183
2184         if (!e || e.initialize_entity)
2185         {
2186                 // make a proxy initializer entity
2187                 entity e_old = e;
2188                 e = new(initialize_entity);
2189                 e.enemy = e_old;
2190         }
2191
2192         e.initialize_entity = func;
2193         e.initialize_entity_order = order;
2194
2195         cur = initialize_entity_first;
2196         prev = NULL;
2197         for (;;)
2198         {
2199                 if (!cur || cur.initialize_entity_order > order)
2200                 {
2201                         // insert between prev and cur
2202                         if (prev)
2203                                 prev.initialize_entity_next = e;
2204                         else
2205                                 initialize_entity_first = e;
2206                         e.initialize_entity_next = cur;
2207                         return;
2208                 }
2209                 prev = cur;
2210                 cur = cur.initialize_entity_next;
2211         }
2212 }
2213 void InitializeEntitiesRun()
2214 {
2215         entity startoflist = initialize_entity_first;
2216         initialize_entity_first = NULL;
2217         delete_fn = remove_except_protected;
2218         for (entity e = startoflist; e; e = e.initialize_entity_next)
2219         {
2220                 e.remove_except_protected_forbidden = 1;
2221         }
2222         for (entity e = startoflist; e; )
2223         {
2224                 e.remove_except_protected_forbidden = 0;
2225                 e.initialize_entity_order = 0;
2226                 entity next = e.initialize_entity_next;
2227                 e.initialize_entity_next = NULL;
2228                 var void(entity this) func = e.initialize_entity;
2229                 e.initialize_entity = func_null;
2230                 if (e.classname == "initialize_entity")
2231                 {
2232                         entity wrappee = e.enemy;
2233                         builtin_remove(e);
2234                         e = wrappee;
2235                 }
2236                 //dprint("Delayed initialization: ", e.classname, "\n");
2237                 if (func)
2238                 {
2239                         func(e);
2240                 }
2241                 else
2242                 {
2243                         eprint(e);
2244                         backtrace(strcat("Null function in: ", e.classname, "\n"));
2245                 }
2246                 e = next;
2247         }
2248         delete_fn = remove_unsafely;
2249 }
2250
2251 // deferred dropping
2252 // ported from VM_SV_droptofloor TODO: make a common function for the client-side?
2253 void DropToFloor_Handler(entity this)
2254 {
2255         if(!this || wasfreed(this))
2256         {
2257                 // no modifying free entities
2258                 return;
2259         }
2260
2261         vector end = this.origin - '0 0 256';
2262
2263         // NOTE: NudgeOutOfSolid support is not added as Xonotic's physics do not use it!
2264         //if(autocvar_sv_gameplayfix_droptofloorstartsolid_nudgetocorrect)
2265                 //SV_NudgeOutOfSolid(this);
2266
2267         tracebox(this.origin, this.mins, this.maxs, end, MOVE_NORMAL, this);
2268
2269         if(trace_startsolid && autocvar_sv_gameplayfix_droptofloorstartsolid)
2270         {
2271                 vector offset, org;
2272                 offset = 0.5 * (this.mins + this.maxs);
2273                 offset.z = this.mins.z;
2274                 org = this.origin + offset;
2275                 traceline(org, end, MOVE_NORMAL, this);
2276                 trace_endpos = trace_endpos - offset;
2277                 if(trace_startsolid)
2278                 {
2279                         LOG_DEBUGF("DropToFloor_Handler: %v could not fix badly placed entity", this.origin);
2280                         _Movetype_LinkEdict(this, false);
2281                         SET_ONGROUND(this);
2282                         this.groundentity = NULL;
2283                 }
2284                 else if(trace_fraction < 1)
2285                 {
2286                         LOG_DEBUGF("DropToFloor_Handler: %v fixed badly placed entity", this.origin);
2287                         //if(autocvar_sv_gameplayfix_droptofloorstartsolid_nudgetocorrect)
2288                                 //SV_NudgeOutOfSolid(this);
2289                         setorigin(this, trace_endpos);
2290                         SET_ONGROUND(this);
2291                         this.groundentity = trace_ent;
2292                         // if support is destroyed, keep suspended (gross hack for floating items in various maps)
2293                         this.move_suspendedinair = true;
2294                 }
2295         }
2296         else
2297         {
2298                 if(!trace_allsolid && trace_fraction < 1)
2299                 {
2300                         setorigin(this, trace_endpos);
2301                         SET_ONGROUND(this);
2302                         this.groundentity = trace_ent;
2303                         // if support is destroyed, keep suspended (gross hack for floating items in various maps)
2304                         this.move_suspendedinair = true;
2305                 }
2306         }
2307         this.dropped_origin = this.origin;
2308 }
2309
2310 void droptofloor(entity this)
2311 {
2312         InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
2313 }
2314
2315 bool autocvar_sv_gameplayfix_multiplethinksperframe = true;
2316 void RunThink(entity this, float dt)
2317 {
2318         // don't let things stay in the past.
2319         // it is possible to start that way by a trigger with a local time.
2320         if(this.nextthink <= 0 || this.nextthink > time + dt)
2321                 return;
2322
2323         float oldtime = time; // do we need to save this?
2324
2325         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2326         {
2327                 time = max(oldtime, this.nextthink);
2328                 this.nextthink = 0;
2329
2330                 if(getthink(this))
2331                         getthink(this)(this);
2332                 // mods often set nextthink to time to cause a think every frame,
2333                 // we don't want to loop in that case, so exit if the new nextthink is
2334                 // <= the time the qc was told, also exit if it is past the end of the
2335                 // frame
2336                 if(this.nextthink <= time || this.nextthink > oldtime + dt || !autocvar_sv_gameplayfix_multiplethinksperframe)
2337                         break;
2338         }
2339
2340         time = oldtime;
2341 }
2342
2343 bool autocvar_sv_freezenonclients;
2344 void Physics_Frame()
2345 {
2346         if(autocvar_sv_freezenonclients)
2347                 return;
2348
2349         IL_EACH(g_moveables, true,
2350         {
2351                 if(IS_CLIENT(it) || it.move_movetype == MOVETYPE_PHYSICS)
2352                         continue;
2353
2354                 //set_movetype(it, it.move_movetype);
2355                 // inline the set_movetype function, since this is called a lot
2356                 it.movetype = (it.move_qcphysics) ? MOVETYPE_QCENTITY : it.move_movetype;
2357
2358                 if(it.move_qcphysics && it.move_movetype != MOVETYPE_NONE)
2359                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2360
2361                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2362                 {
2363                         if(it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH)
2364                                 continue; // these movetypes have no regular think function
2365                         // handle thinking here
2366                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + PHYS_INPUT_TIMELENGTH)
2367                                 RunThink(it, PHYS_INPUT_TIMELENGTH);
2368                 }
2369         });
2370
2371         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2372                 return;
2373
2374         // make a second pass to see if any ents spawned this frame and make
2375         // sure they run their move/think. this is verified by checking .move_time, which will never be 0 if the entity has moved
2376         // MOVETYPE_NONE is also checked as .move_time WILL be 0 with that movetype
2377         IL_EACH(g_moveables, it.move_qcphysics,
2378         {
2379                 if(IS_CLIENT(it) || it.move_time || it.move_movetype == MOVETYPE_NONE || it.move_movetype == MOVETYPE_PHYSICS)
2380                         continue;
2381                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2382         });
2383 }
2384
2385 void systems_update();
2386 void EndFrame()
2387 {
2388         anticheat_endframe();
2389
2390         Physics_Frame();
2391
2392         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2393                 entity e = IS_SPEC(it) ? it.enemy : it;
2394                 if (e.typehitsound) {
2395                         STAT(TYPEHIT_TIME, it) = time;
2396                 } else if (e.killsound) {
2397                         STAT(KILL_TIME, it) = time;
2398                 } else if (e.hitsound_damage_dealt) {
2399                         STAT(HIT_TIME, it) = time;
2400                         // NOTE: this is not accurate as client code doesn't need so much accuracy for its purposes
2401                         STAT(HITSOUND_DAMAGE_DEALT_TOTAL, it) += ceil(e.hitsound_damage_dealt);
2402                 }
2403         });
2404         // add 1 frametime because after this, engine SV_Physics
2405         // increases time by a frametime and then networks the frame
2406         // add another frametime because client shows everything with
2407         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2408         // needed!
2409         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2410         FOREACH_CLIENT(true, {
2411                 it.typehitsound = false;
2412                 it.hitsound_damage_dealt = 0;
2413                 it.killsound = false;
2414                 antilag_record(it, CS(it), altime);
2415         });
2416         IL_EACH(g_monsters, true,
2417         {
2418                 antilag_record(it, it, altime);
2419         });
2420         IL_EACH(g_projectiles, it.classname == "nade",
2421         {
2422                 antilag_record(it, it, altime);
2423         });
2424         systems_update();
2425         IL_ENDFRAME();
2426 }
2427
2428
2429 /*
2430  * RedirectionThink:
2431  * returns true if redirecting
2432  */
2433 float redirection_timeout;
2434 float redirection_nextthink;
2435 float RedirectionThink()
2436 {
2437         float clients_found;
2438
2439         if(redirection_target == "")
2440                 return false;
2441
2442         if(!redirection_timeout)
2443         {
2444                 cvar_set("sv_public", "-2");
2445                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2446                 if(redirection_target == "self")
2447                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2448                 else
2449                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2450         }
2451
2452         if(time < redirection_nextthink)
2453                 return true;
2454
2455         redirection_nextthink = time + 1;
2456
2457         clients_found = 0;
2458         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2459                 // TODO add timer
2460                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2461                 if(redirection_target == "self")
2462                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2463                 else
2464                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2465                 ++clients_found;
2466         });
2467
2468         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2469
2470         if(time > redirection_timeout || clients_found == 0)
2471                 localcmd("\nwait; wait; wait; quit\n");
2472
2473         return true;
2474 }
2475
2476 void RestoreGame()
2477 {
2478         // Loaded from a save game
2479         // some things then break, so let's work around them...
2480
2481         // Progs DB (capture records)
2482         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2483
2484         // Mapinfo
2485         MapInfo_Shutdown();
2486         MapInfo_Enumerate();
2487         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2488         WeaponStats_Init();
2489
2490         TargetMusic_RestoreGame();
2491 }
2492
2493 void Shutdown()
2494 {
2495         game_stopped = 2;
2496
2497         if(world_initialized > 0)
2498         {
2499                 world_initialized = 0;
2500
2501                 // if a timeout is active, reset the slowmo value to normal
2502                 if(timeout_status == TIMEOUT_ACTIVE)
2503                         cvar_set("slowmo", ftos(orig_slowmo));
2504
2505                 LOG_TRACE("Saving persistent data...");
2506                 Ban_SaveBans();
2507
2508                 // playerstats with unfinished match
2509                 PlayerStats_GameReport(false);
2510
2511                 if(!cheatcount_total)
2512                 {
2513                         if(autocvar_sv_db_saveasdump)
2514                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2515                         else
2516                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2517                 }
2518                 if(autocvar_developer > 0)
2519                 {
2520                         if(autocvar_sv_db_saveasdump)
2521                                 db_dump(TemporaryDB, "server-temp.db");
2522                         else
2523                                 db_save(TemporaryDB, "server-temp.db");
2524                 }
2525                 CheatShutdown(); // must be after cheatcount check
2526                 db_close(ServerProgsDB);
2527                 db_close(TemporaryDB);
2528                 LOG_TRACE("Saving persistent data... done!");
2529                 // tell the bot system the game is ending now
2530                 bot_endgame();
2531
2532                 WeaponStats_Shutdown();
2533                 MapInfo_Shutdown();
2534
2535                 strfree(sv_termsofservice_url_escaped);
2536         }
2537         else if(world_initialized == 0)
2538         {
2539                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2540         }
2541         else
2542         {
2543                 __init_dedicated_server_shutdown();
2544         }
2545 }