qcsrc/server/world.qc

   1 #include "world.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/gamemodes/sv_rules.qh>
   7 #include <common/items/_mod.qh>
   8 #include <common/mapinfo.qh>
   9 #include <common/mapobjects/target/music.qh>
  10 #include <common/mapobjects/trigger/hurt.qh>
  11 #include <common/mapobjects/trigger/secret.qh>
  12 #include <common/mapobjects/triggers.qh>
  13 #include <common/monsters/_mod.qh>
  14 #include <common/monsters/sv_monsters.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/notifications/all.qh>
  17 #include <common/physics/player.qh>
  18 #include <common/playerstats.qh>
  19 #include <common/state.qh>
  20 #include <common/stats.qh>
  21 #include <common/teams.qh>
  22 #include <common/util.qh>
  23 #include <common/vehicles/all.qh>
  24 #include <common/weapons/_all.qh>
  25 #include <server/anticheat.qh>
  26 #include <server/antilag.qh>
  27 #include <server/bot/api.qh>
  28 #include <server/campaign.qh>
  29 #include <server/cheats.qh>
  30 #include <server/client.qh>
  31 #include <server/command/common.qh>
  32 #include <server/command/getreplies.qh>
  33 #include <server/command/sv_cmd.qh>
  34 #include <server/command/vote.qh>
  35 #include <server/damage.qh>
  36 #include <server/gamelog.qh>
  37 #include <server/hook.qh>
  38 #include <server/intermission.qh>
  39 #include <server/ipban.qh>
  40 #include <server/items/items.qh>
  41 #include <server/main.qh>
  42 #include <server/mapvoting.qh>
  43 #include <server/mutators/_mod.qh>
  44 #include <server/race.qh>
  45 #include <server/scores.qh>
  46 #include <server/scores_rules.qh>
  47 #include <server/spawnpoints.qh>
  48 #include <server/teamplay.qh>
  49 #include <server/weapons/common.qh>
  50 #include <server/weapons/weaponstats.qh>
  51
  52 const float LATENCY_THINKRATE = 10;
  53 .float latency_sum;
  54 .float latency_cnt;
  55 .float latency_time;
  56 entity pingplreport;
  57 void PingPLReport_Think(entity this)
  58 {
  59         float delta;
  60         entity e;
  61
  62         delta = 3 / maxclients;
  63         if(delta < sys_frametime)
  64                 delta = 0;
  65         this.nextthink = time + delta;
  66
  67         e = edict_num(this.cnt + 1);
  68         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
  69         {
  70                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  71                 WriteByte(MSG_BROADCAST, this.cnt);
  72                 WriteShort(MSG_BROADCAST, bound(1, CS(e).ping, 32767));
  73                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
  74                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
  75
  76                 // record latency times for clients throughout the match so we can report it to playerstats
  77                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
  78                 {
  79                         CS(e).latency_sum += CS(e).ping;
  80                         CS(e).latency_cnt += 1;
  81                         CS(e).latency_time = time;
  82                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
  83                 }
  84         }
  85         else
  86         {
  87                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  88                 WriteByte(MSG_BROADCAST, this.cnt);
  89                 WriteShort(MSG_BROADCAST, 0);
  90                 WriteByte(MSG_BROADCAST, 0);
  91                 WriteByte(MSG_BROADCAST, 0);
  92         }
  93         this.cnt = (this.cnt + 1) % maxclients;
  94 }
  95 void PingPLReport_Spawn()
  96 {
  97         pingplreport = new_pure(pingplreport);
  98         setthink(pingplreport, PingPLReport_Think);
  99         pingplreport.nextthink = time;
 100 }
 101
 102 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
 103
 104 void SetDefaultAlpha()
 105 {
 106         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
 107         {
 108                 default_player_alpha = autocvar_g_player_alpha;
 109                 if(default_player_alpha == 0)
 110                         default_player_alpha = 1;
 111                 default_weapon_alpha = default_player_alpha;
 112         }
 113 }
 114
 115 void GotoFirstMap(entity this)
 116 {
 117         float n;
 118         if(autocvar__sv_init)
 119         {
 120                 // cvar_set("_sv_init", "0");
 121                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 122                 // to this "init" map on a dedicated server will cause no permanent
 123                 // harm
 124                 if(autocvar_g_maplist_shuffle)
 125                         ShuffleMaplist();
 126                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 127                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 128
 129                 MapInfo_Enumerate();
 130                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 131
 132                 if(!DoNextMapOverride(1))
 133                         GotoNextMap(1);
 134
 135                 return;
 136         }
 137
 138         if(time < 5)
 139         {
 140                 this.nextthink = time;
 141         }
 142         else
 143         {
 144                 this.nextthink = time + 1;
 145                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
 146         }
 147 }
 148
 149 void cvar_changes_init()
 150 {
 151         float h;
 152         string k, v, d;
 153         float n, i, adding, pureadding;
 154
 155         strfree(cvar_changes);
 156         strfree(cvar_purechanges);
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = true;
 164         pureadding = true;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173 #define BADVALUE(p, val) if (k == p && v == val) continue
 174
 175                 // general excludes and namespaces for server admin used cvars
 176                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 177
 178                 // internal
 179                 BADPREFIX("csqc_");
 180                 BADPREFIX("cvar_check_");
 181                 BADCVAR("gamecfg");
 182                 BADCVAR("g_configversion");
 183                 BADCVAR("halflifebsp");
 184                 BADCVAR("sv_mapformat_is_quake2");
 185                 BADCVAR("sv_mapformat_is_quake3");
 186                 BADPREFIX("sv_world");
 187
 188                 // client
 189                 BADPREFIX("chase_");
 190                 BADPREFIX("cl_");
 191                 BADPREFIX("con_");
 192                 BADPREFIX("scoreboard_");
 193                 BADPREFIX("g_campaign");
 194                 BADPREFIX("g_waypointsprite_");
 195                 BADPREFIX("gl_");
 196                 BADPREFIX("joy");
 197                 BADPREFIX("hud_");
 198                 BADPREFIX("m_");
 199                 BADPREFIX("menu_");
 200                 BADPREFIX("net_slist_");
 201                 BADPREFIX("r_");
 202                 BADPREFIX("sbar_");
 203                 BADPREFIX("scr_");
 204                 BADPREFIX("snd_");
 205                 BADPREFIX("show");
 206                 BADPREFIX("sensitivity");
 207                 BADPREFIX("userbind");
 208                 BADPREFIX("v_");
 209                 BADPREFIX("vid_");
 210                 BADPREFIX("crosshair");
 211                 BADCVAR("mod_q3bsp_lightmapmergepower");
 212                 BADCVAR("mod_q3bsp_nolightmaps");
 213                 BADCVAR("fov");
 214                 BADCVAR("mastervolume");
 215                 BADCVAR("volume");
 216                 BADCVAR("bgmvolume");
 217                 BADCVAR("in_pitch_min");
 218                 BADCVAR("in_pitch_max");
 219
 220                 // private
 221                 BADCVAR("developer");
 222                 BADCVAR("log_dest_udp");
 223                 BADCVAR("net_address");
 224                 BADCVAR("net_address_ipv6");
 225                 BADCVAR("port");
 226                 BADCVAR("savedgamecfg");
 227                 BADCVAR("serverconfig");
 228                 BADCVAR("sv_autoscreenshot");
 229                 BADCVAR("sv_heartbeatperiod");
 230                 BADCVAR("sv_vote_master_password");
 231                 BADCVAR("sys_colortranslation");
 232                 BADCVAR("sys_specialcharactertranslation");
 233                 BADCVAR("timeformat");
 234                 BADCVAR("timestamps");
 235                 BADCVAR("g_require_stats");
 236                 BADPREFIX("developer_");
 237                 BADPREFIX("g_ban_");
 238                 BADPREFIX("g_banned_list");
 239                 BADPREFIX("g_require_stats_");
 240                 BADPREFIX("g_chat_flood_");
 241                 BADPREFIX("g_ghost_items");
 242                 BADPREFIX("g_playerstats_");
 243                 BADPREFIX("g_voice_flood_");
 244                 BADPREFIX("log_file");
 245                 BADPREFIX("quit_");
 246                 BADPREFIX("rcon_");
 247                 BADPREFIX("sv_allowdownloads");
 248                 BADPREFIX("sv_autodemo");
 249                 BADPREFIX("sv_curl_");
 250                 BADPREFIX("sv_eventlog");
 251                 BADPREFIX("sv_logscores_");
 252                 BADPREFIX("sv_master");
 253                 BADPREFIX("sv_weaponstats_");
 254                 BADPREFIX("sv_waypointsprite_");
 255                 BADCVAR("rescan_pending");
 256
 257                 // these can contain player IDs, so better hide
 258                 BADPREFIX("g_forced_team_");
 259                 BADCVAR("sv_muteban_list");
 260                 BADCVAR("sv_voteban_list");
 261                 BADCVAR("sv_allow_customplayermodels_idlist");
 262                 BADCVAR("sv_allow_customplayermodels_speciallist");
 263
 264                 // mapinfo
 265                 BADCVAR("fraglimit");
 266                 BADCVAR("g_arena");
 267                 BADCVAR("g_assault");
 268                 BADCVAR("g_ca");
 269                 BADCVAR("g_ca_teams");
 270                 BADCVAR("g_conquest");
 271                 BADCVAR("g_conquest_teams");
 272                 BADCVAR("g_ctf");
 273                 BADCVAR("g_cts");
 274                 BADCVAR("g_dotc");
 275                 BADCVAR("g_dm");
 276                 BADCVAR("g_domination");
 277                 BADCVAR("g_domination_default_teams");
 278                 BADCVAR("g_duel");
 279                 BADCVAR("g_duel_not_dm_maps");
 280                 BADCVAR("g_freezetag");
 281                 BADCVAR("g_freezetag_teams");
 282                 BADCVAR("g_invasion_teams");
 283                 BADCVAR("g_invasion_type");
 284                 BADCVAR("g_jailbreak");
 285                 BADCVAR("g_jailbreak_teams");
 286                 BADCVAR("g_keepaway");
 287                 BADCVAR("g_keyhunt");
 288                 BADCVAR("g_keyhunt_teams");
 289                 BADCVAR("g_lms");
 290                 BADCVAR("g_nexball");
 291                 BADCVAR("g_onslaught");
 292                 BADCVAR("g_race");
 293                 BADCVAR("g_race_laps_limit");
 294                 BADCVAR("g_race_qualifying_timelimit");
 295                 BADCVAR("g_race_qualifying_timelimit_override");
 296                 BADCVAR("g_runematch");
 297                 BADCVAR("g_shootfromeye");
 298                 BADCVAR("g_snafu");
 299                 BADCVAR("g_survival");
 300                 BADCVAR("g_survival_not_dm_maps");
 301                 BADCVAR("g_tdm");
 302                 BADCVAR("g_tdm_on_dm_maps");
 303                 BADCVAR("g_tdm_teams");
 304                 BADCVAR("g_vip");
 305                 BADCVAR("leadlimit");
 306                 BADCVAR("nextmap");
 307                 BADCVAR("teamplay");
 308                 BADCVAR("timelimit");
 309                 BADCVAR("g_mapinfo_settemp_acl");
 310                 BADCVAR("g_mapinfo_ignore_warnings");
 311                 BADCVAR("g_maplist_ignore_sizes");
 312                 BADCVAR("g_maplist_sizes_count_bots");
 313
 314                 // long
 315                 BADCVAR("hostname");
 316                 BADCVAR("g_maplist");
 317                 BADCVAR("g_maplist_mostrecent");
 318                 BADCVAR("sv_motd");
 319
 320                 v = cvar_string(k);
 321                 d = cvar_defstring(k);
 322                 if(v == d)
 323                         continue;
 324
 325                 if(adding)
 326                 {
 327                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 328                         if(strlen(cvar_changes) > 16384)
 329                         {
 330                                 cvar_changes = "// too many settings have been changed to show them here\n";
 331                                 adding = 0;
 332                         }
 333                 }
 334
 335                 // now check if the changes are actually gameplay relevant
 336
 337                 // does nothing gameplay relevant
 338                 BADCVAR("captureleadlimit_override");
 339                 BADCVAR("condump_stripcolors");
 340                 BADCVAR("gameversion");
 341                 BADCVAR("fs_gamedir");
 342                 BADCVAR("g_allow_oldvortexbeam");
 343                 BADCVAR("g_balance_kill_delay");
 344                 BADCVAR("g_buffs_pickup_anyway");
 345                 BADCVAR("g_buffs_randomize");
 346                 BADCVAR("g_buffs_randomize_teamplay");
 347                 BADCVAR("g_campcheck_distance");
 348                 BADCVAR("g_chatsounds");
 349                 BADCVAR("g_ca_point_leadlimit");
 350                 BADCVAR("g_ca_point_limit");
 351                 BADCVAR("g_ca_spectate_enemies");
 352                 BADCVAR("g_ctf_captimerecord_always");
 353                 BADCVAR("g_ctf_flag_glowtrails");
 354                 BADCVAR("g_ctf_dynamiclights");
 355                 BADCVAR("g_ctf_flag_pickup_verbosename");
 356                 BADPRESUFFIX("g_ctf_flag_", "_model");
 357                 BADPRESUFFIX("g_ctf_flag_", "_skin");
 358                 BADCVAR("g_domination_point_leadlimit");
 359                 BADCVAR("g_forced_respawn");
 360                 BADCVAR("g_freezetag_point_leadlimit");
 361                 BADCVAR("g_freezetag_point_limit");
 362                 BADCVAR("g_glowtrails");
 363                 BADCVAR("g_hats");
 364                 BADCVAR("g_casings");
 365                 BADCVAR("g_invasion_point_limit");
 366                 BADCVAR("g_jump_grunt");
 367                 BADCVAR("g_keepaway_ballcarrier_effects");
 368                 BADCVAR("g_keepawayball_effects");
 369                 BADCVAR("g_keyhunt_point_leadlimit");
 370                 BADCVAR("g_nexball_goalleadlimit");
 371                 BADCVAR("g_new_toys_autoreplace");
 372                 BADCVAR("g_new_toys_use_pickupsound");
 373                 BADCVAR("g_physics_predictall");
 374                 BADCVAR("g_piggyback");
 375                 BADCVAR("g_playerclip_collisions");
 376                 BADCVAR("g_spawn_alloweffects");
 377                 BADCVAR("g_tdm_point_leadlimit");
 378                 BADCVAR("g_tdm_point_limit");
 379                 BADCVAR("leadlimit_and_fraglimit");
 380                 BADCVAR("leadlimit_override");
 381                 BADCVAR("pausable");
 382                 BADCVAR("sv_announcer");
 383                 BADCVAR("sv_checkforpacketsduringsleep");
 384                 BADCVAR("sv_damagetext");
 385                 BADCVAR("sv_db_saveasdump");
 386                 BADCVAR("sv_intermission_cdtrack");
 387                 BADCVAR("sv_mapchange_delay");
 388                 BADCVAR("sv_minigames");
 389                 BADCVAR("sv_namechangetimer");
 390                 BADCVAR("sv_precacheplayermodels");
 391                 BADCVAR("sv_radio");
 392                 BADCVAR("sv_stepheight");
 393                 BADCVAR("sv_timeout");
 394                 BADCVAR("sv_weapons_modeloverride");
 395                 BADCVAR("w_prop_interval");
 396                 BADPREFIX("chat_");
 397                 BADPREFIX("crypto_");
 398                 BADPREFIX("gameversion_");
 399                 BADPREFIX("g_chat_");
 400                 BADPREFIX("g_ctf_captimerecord_");
 401                 BADPREFIX("g_hats_");
 402                 BADPREFIX("g_maplist_");
 403                 BADPREFIX("g_mod_");
 404                 BADPREFIX("g_respawn_");
 405                 BADPREFIX("net_");
 406                 BADPREFIX("notification_");
 407                 BADPREFIX("prvm_");
 408                 BADPREFIX("skill_");
 409                 BADPREFIX("sv_allow_");
 410                 BADPREFIX("sv_cullentities_");
 411                 BADPREFIX("sv_maxidle");
 412                 BADPREFIX("sv_minigames_");
 413                 BADPREFIX("sv_radio_");
 414                 BADPREFIX("sv_timeout_");
 415                 BADPREFIX("sv_vote_");
 416                 BADPREFIX("timelimit_");
 417
 418                 // allowed changes to server admins (please sync this to server.cfg)
 419                 // vi commands:
 420                 //   :/"impure"/,$d
 421                 //   :g!,^\/\/[^ /],d
 422                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 423                 //   :%!sort
 424                 // yes, this does contain some redundant stuff, don't really care
 425                 BADPREFIX("bot_ai_");
 426                 BADCVAR("bot_config_file");
 427                 BADCVAR("bot_number");
 428                 BADCVAR("bot_prefix");
 429                 BADCVAR("bot_suffix");
 430                 BADCVAR("capturelimit_override");
 431                 BADCVAR("fraglimit_override");
 432                 BADCVAR("gametype");
 433                 BADCVAR("g_antilag");
 434                 BADCVAR("g_balance_teams");
 435                 BADCVAR("g_balance_teams_prevent_imbalance");
 436                 BADCVAR("g_balance_teams_scorefactor");
 437                 BADCVAR("g_ban_sync_trusted_servers");
 438                 BADCVAR("g_ban_sync_uri");
 439                 BADCVAR("g_buffs");
 440                 BADCVAR("g_ca_teams_override");
 441                 BADCVAR("g_ctf_fullbrightflags");
 442                 BADCVAR("g_ctf_ignore_frags");
 443                 BADCVAR("g_ctf_leaderboard");
 444                 BADCVAR("g_domination_point_limit");
 445                 BADCVAR("g_domination_teams_override");
 446                 BADCVAR("g_freezetag_teams_override");
 447                 BADCVAR("g_friendlyfire");
 448                 BADCVAR("g_fullbrightitems");
 449                 BADCVAR("g_fullbrightplayers");
 450                 BADCVAR("g_keyhunt_point_limit");
 451                 BADCVAR("g_keyhunt_teams_override");
 452                 BADCVAR("g_lms_lives_override");
 453                 BADCVAR("g_maplist");
 454                 BADCVAR("g_maxplayers");
 455                 BADCVAR("g_mirrordamage");
 456                 BADCVAR("g_nexball_goallimit");
 457                 BADCVAR("g_norecoil");
 458                 BADCVAR("g_physics_clientselect");
 459                 BADCVAR("g_pinata");
 460                 BADCVAR("g_powerups");
 461                 BADCVAR("g_player_brightness");
 462                 BADCVAR("g_rocket_flying");
 463                 BADCVAR("g_rocket_flying_disabledelays");
 464                 BADCVAR("g_spawnshieldtime");
 465                 BADCVAR("g_start_delay");
 466                 BADCVAR("g_superspectate");
 467                 BADCVAR("g_tdm_teams_override");
 468                 BADCVAR("g_warmup");
 469                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 470                 BADCVAR("hostname");
 471                 BADCVAR("log_file");
 472                 BADCVAR("maxplayers");
 473                 BADCVAR("minplayers");
 474                 BADCVAR("minplayers_per_team");
 475                 BADCVAR("net_address");
 476                 BADCVAR("port");
 477                 BADCVAR("rcon_password");
 478                 BADCVAR("rcon_restricted_commands");
 479                 BADCVAR("rcon_restricted_password");
 480                 BADCVAR("skill");
 481                 BADCVAR("sv_adminnick");
 482                 BADCVAR("sv_autoscreenshot");
 483                 BADCVAR("sv_autotaunt");
 484                 BADCVAR("sv_curl_defaulturl");
 485                 BADCVAR("sv_defaultcharacter");
 486                 BADCVAR("sv_defaultcharacterskin");
 487                 BADCVAR("sv_defaultplayercolors");
 488                 BADCVAR("sv_defaultplayermodel");
 489                 BADCVAR("sv_defaultplayerskin");
 490                 BADCVAR("sv_maxrate");
 491                 BADCVAR("sv_motd");
 492                 BADCVAR("sv_public");
 493                 BADCVAR("sv_ready_restart");
 494                 BADCVAR("sv_showfps");
 495                 BADCVAR("sv_status_privacy");
 496                 BADCVAR("sv_taunt");
 497                 BADCVAR("sv_vote_call");
 498                 BADCVAR("sv_vote_commands");
 499                 BADCVAR("sv_vote_majority_factor");
 500                 BADCVAR("sv_vote_master");
 501                 BADCVAR("sv_vote_master_commands");
 502                 BADCVAR("sv_vote_master_password");
 503                 BADCVAR("sv_vote_simple_majority_factor");
 504                 BADVALUE("sys_ticrate", "0.0166667");
 505                 BADVALUE("sys_ticrate", "0.0333333");
 506                 BADCVAR("teamplay_mode");
 507                 BADCVAR("timelimit_override");
 508                 BADPREFIX("g_warmup_");
 509                 BADPREFIX("sv_info_");
 510                 BADPREFIX("sv_ready_restart_");
 511
 512                 // mutators that announce themselves properly to the server browser
 513                 BADCVAR("g_instagib");
 514                 BADCVAR("g_new_toys");
 515                 BADCVAR("g_nix");
 516                 BADCVAR("g_grappling_hook");
 517                 BADCVAR("g_jetpack");
 518
 519                 // temporary for testing
 520                 // TODO remove before 0.8.3 release
 521                 BADCVAR("g_ca_weaponarena");
 522                 BADCVAR("g_freezetag_weaponarena");
 523                 BADCVAR("g_lms_weaponarena");
 524                 BADCVAR("g_ctf_stalemate_time");
 525
 526 #undef BADPRESUFFIX
 527 #undef BADPREFIX
 528 #undef BADCVAR
 529 #undef BADVALUE
 530
 531                 if(pureadding)
 532                 {
 533                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 534                         if(strlen(cvar_purechanges) > 16384)
 535                         {
 536                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 537                                 pureadding = 0;
 538                         }
 539                 }
 540                 ++cvar_purechanges_count;
 541                 // WARNING: this variable is used for the server list
 542                 // NEVER dare to skip this code!
 543                 // Hacks to intentionally appearing as "pure server" even though you DO have
 544                 // modified settings may be punished by removal from the server list.
 545                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 546                 // though.
 547         }
 548         buf_del(h);
 549         if(cvar_changes == "")
 550                 cvar_changes = "// this server runs at default server settings\n";
 551         else
 552                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 553         cvar_changes = strzone(cvar_changes);
 554         if(cvar_purechanges == "")
 555                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 556         else
 557                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 558         cvar_purechanges = strzone(cvar_purechanges);
 559 }
 560
 561 entity randomseed;
 562 bool RandomSeed_Send(entity this, entity to, int sf)
 563 {
 564         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 565         WriteShort(MSG_ENTITY, this.cnt);
 566         return true;
 567 }
 568 void RandomSeed_Think(entity this)
 569 {
 570         this.cnt = bound(0, floor(random() * 65536), 65535);
 571         this.nextthink = time + 5;
 572
 573         this.SendFlags |= 1;
 574 }
 575 void RandomSeed_Spawn()
 576 {
 577         randomseed = new_pure(randomseed);
 578         setthink(randomseed, RandomSeed_Think);
 579         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 580
 581         getthink(randomseed)(randomseed); // sets random seed and nextthink
 582 }
 583
 584 spawnfunc(__init_dedicated_server)
 585 {
 586         // handler for _init/_init map (only for dedicated server initialization)
 587
 588         world_initialized = -1; // don't complain
 589
 590         delete_fn = remove_unsafely;
 591
 592         entity e = new(GotoFirstMap);
 593         setthink(e, GotoFirstMap);
 594         e.nextthink = time; // this is usually 1 at this point
 595
 596         e = new(info_player_deathmatch);  // safeguard against player joining
 597
 598     // assign reflectively to avoid "assignment to world" warning
 599     for (int i = 0, n = numentityfields(); i < n; ++i) {
 600         string k = entityfieldname(i);
 601         if (k == "classname") {
 602             // safeguard against various stuff ;)
 603             putentityfieldstring(i, this, "worldspawn");
 604             break;
 605         }
 606     }
 607
 608         // needs to be done so early because of the constants they create
 609         static_init();
 610         static_init_late();
 611         static_init_precache();
 612
 613         IL_PUSH(g_spawnpoints, e); // just incase
 614
 615         MapInfo_Enumerate();
 616         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 617 }
 618
 619 void __init_dedicated_server_shutdown() {
 620         MapInfo_Shutdown();
 621 }
 622
 623 STATIC_INIT_EARLY(maxclients)
 624 {
 625         maxclients = 0;
 626         for (entity head = nextent(NULL); head; head = nextent(head)) {
 627                 ++maxclients;
 628         }
 629 }
 630
 631 void GameplayMode_DelayedInit(entity this)
 632 {
 633         if(!scores_initialized)
 634                 ScoreRules_generic();
 635 }
 636
 637 void InitGameplayMode()
 638 {
 639         VoteReset();
 640
 641         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 642         get_mi_min_max(1);
 643         // assign reflectively to avoid "assignment to world" warning
 644         int done = 0; for (int i = 0, n = numentityfields(); i < n; ++i) {
 645             string k = entityfieldname(i); vector v = (k == "mins") ? mi_min : (k == "maxs") ? mi_max : '0 0 0';
 646             if (v) {
 647             putentityfieldstring(i, world, sprintf("%v", v));
 648             if (++done == 2) break;
 649         }
 650         }
 651         // currently, NetRadiant's limit is 131072 qu for each side
 652         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
 653         // set the distance according to map size but don't go over the limit to avoid issues with float precision
 654         // in case somebody makes extremely large maps
 655         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
 656
 657         MapInfo_LoadMapSettings(mapname);
 658         GameRules_teams(false);
 659
 660         if (!cvar_value_issafe(world.fog))
 661         {
 662                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored");
 663                 world.fog = string_null;
 664         }
 665         if(MapInfo_Map_fog != "")
 666         {
 667                 if(MapInfo_Map_fog == "none")
 668                         world.fog = string_null;
 669                 else
 670                         world.fog = strzone(MapInfo_Map_fog);
 671         }
 672         clientstuff = strzone(MapInfo_Map_clientstuff);
 673
 674         MapInfo_ClearTemps();
 675
 676         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 677
 678         cache_mutatormsg = strzone("");
 679         cache_lastmutatormsg = strzone("");
 680
 681         InitializeEntity(NULL, GameplayMode_DelayedInit, INITPRIO_GAMETYPE_FALLBACK);
 682 }
 683
 684 bool world_already_spawned;
 685 spawnfunc(worldspawn)
 686 {
 687         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 688
 689         bool wantrestart = false;
 690         {
 691                 if (!server_is_dedicated)
 692                 {
 693                         // force unloading of server pk3 files when starting a listen server
 694                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 695                         // restore csqc_progname too
 696                         string expect = "csprogs.dat";
 697                         wantrestart = cvar_string("csqc_progname") != expect;
 698                         cvar_set("csqc_progname", expect);
 699                 }
 700                 else
 701                 {
 702                         // Try to use versioned csprogs from pk3
 703                         // Only ever use versioned csprogs.dat files on dedicated servers;
 704                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 705                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 706                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 707                         string select = "csprogs.dat";
 708                         if (fexists(pk3csprogs)) select = pk3csprogs;
 709                         if (cvar_string("csqc_progname") != select)
 710                         {
 711                                 cvar_set("csqc_progname", select);
 712                                 wantrestart = true;
 713                         }
 714                         // Check for updates on startup
 715                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 716                         int sentinel = fopen("progs.txt", FILE_READ);
 717                         if (sentinel >= 0)
 718                         {
 719                                 string switchversion = fgets(sentinel);
 720                                 fclose(sentinel);
 721                                 if (switchversion != "" && switchversion != WATERMARK)
 722                                 {
 723                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
 724                                         // if it doesn't exist, assume either:
 725                                         //   a) the current program was overwritten
 726                                         //   b) this is a client only update
 727                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 728                                         if (fexists(newprogs))
 729                                         {
 730                                                 cvar_set("sv_progs", newprogs);
 731                                                 wantrestart = true;
 732                                         }
 733                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 734                                         if (fexists(newcsprogs))
 735                                         {
 736                                                 cvar_set("csqc_progname", newcsprogs);
 737                                                 wantrestart = true;
 738                                         }
 739                                 }
 740                         }
 741                 }
 742                 if (wantrestart)
 743                 {
 744                         LOG_INFO("Restart requested");
 745                         changelevel(mapname);
 746                         // let initialization continue, shutdown depends on it
 747                 }
 748         }
 749
 750         if(world_already_spawned)
 751                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 752         world_already_spawned = true;
 753
 754         delete_fn = remove_safely; // during spawning, watch what you remove!
 755
 756         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 757
 758         // default to RACE_RECORD, can be overwritten by gamemodes
 759         record_type = RACE_RECORD;
 760
 761         // needs to be done so early because of the constants they create
 762         static_init();
 763
 764         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 765
 766         TemporaryDB = db_create();
 767
 768         // 0 normal
 769         lightstyle(0, "m");
 770
 771         // 1 FLICKER (first variety)
 772         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 773
 774         // 2 SLOW STRONG PULSE
 775         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 776
 777         // 3 CANDLE (first variety)
 778         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 779
 780         // 4 FAST STROBE
 781         lightstyle(4, "mamamamamama");
 782
 783         // 5 GENTLE PULSE 1
 784         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 785
 786         // 6 FLICKER (second variety)
 787         lightstyle(6, "nmonqnmomnmomomno");
 788
 789         // 7 CANDLE (second variety)
 790         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 791
 792         // 8 CANDLE (third variety)
 793         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 794
 795         // 9 SLOW STROBE (fourth variety)
 796         lightstyle(9, "aaaaaaaazzzzzzzz");
 797
 798         // 10 FLUORESCENT FLICKER
 799         lightstyle(10, "mmamammmmammamamaaamammma");
 800
 801         // 11 SLOW PULSE NOT FADE TO BLACK
 802         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 803
 804         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 805
 806         // 63 testing
 807         lightstyle(63, "a");
 808
 809         if(autocvar_g_campaign)
 810                 CampaignPreInit();
 811
 812         Map_MarkAsRecent(mapname);
 813
 814         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 815
 816         InitGameplayMode();
 817         static_init_late();
 818         static_init_precache();
 819         readlevelcvars();
 820
 821         GameRules_limit_fallbacks();
 822
 823         if(warmup_limit == 0)
 824                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 825
 826         player_count = 0;
 827         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 828         if(bot_waypoints_for_items == 1)
 829                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 830                         bot_waypoints_for_items = 0;
 831
 832         WaypointSprite_Init();
 833
 834         GameLogInit(); // prepare everything
 835         // NOTE for matchid:
 836         // changing the logic generating it is okay. But:
 837         // it HAS to stay <= 64 chars
 838         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 839         if(autocvar_sv_eventlog)
 840         {
 841                 string s = sprintf("%s.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 842                 matchid = strzone(s);
 843
 844                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 845                 s = ":gameinfo:mutators:LIST";
 846
 847                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 848                 s = M_ARGV(0, string);
 849
 850                 // initialiation stuff, not good in the mutator system
 851                 if(!autocvar_g_use_ammunition)
 852                         s = strcat(s, ":no_use_ammunition");
 853
 854                 // initialiation stuff, not good in the mutator system
 855                 if(autocvar_g_pickup_items == 0)
 856                         s = strcat(s, ":no_pickup_items");
 857                 if(autocvar_g_pickup_items > 0)
 858                         s = strcat(s, ":pickup_items");
 859
 860                 // initialiation stuff, not good in the mutator system
 861                 if(autocvar_g_weaponarena != "0")
 862                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 863
 864                 // TODO to mutator system
 865                 if(autocvar_g_norecoil)
 866                         s = strcat(s, ":norecoil");
 867
 868                 // TODO to mutator system
 869                 if(autocvar_g_powerups == 0)
 870                         s = strcat(s, ":no_powerups");
 871                 if(autocvar_g_powerups > 0)
 872                         s = strcat(s, ":powerups");
 873
 874                 GameLogEcho(s);
 875                 GameLogEcho(":gameinfo:end");
 876         }
 877         else
 878                 matchid = strzone(ftos(random()));
 879
 880         cvar_set("nextmap", "");
 881
 882         SetDefaultAlpha();
 883
 884         if(autocvar_g_campaign)
 885                 CampaignPostInit();
 886
 887         Ban_LoadBans();
 888
 889         MapInfo_Enumerate();
 890         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 891
 892         q3compat = BITSET(q3compat, Q3COMPAT_ARENA, fexists(strcat("scripts/", mapname, ".arena")));
 893         q3compat = BITSET(q3compat, Q3COMPAT_DEFI, fexists(strcat("scripts/", mapname, ".defi")));
 894
 895         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 896         {
 897                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 898                 if(fd != -1)
 899                 {
 900                         string s;
 901                         while((s = fgets(fd)))
 902                         {
 903                                 int l = tokenize_console(s);
 904                                 if(l < 2)
 905                                         continue;
 906                                 if(argv(0) == "cd")
 907                                 {
 908                                         string trackname = argv(2);
 909                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
 910                                         LOG_INFO("  cdtrack ", trackname);
 911                                         if (cvar_value_issafe(trackname))
 912                                         {
 913                                                 string newstuff = strcat(clientstuff, "cd loop \"", trackname, "\"\n");
 914                                                 strcpy(clientstuff, newstuff);
 915                                         }
 916                                 }
 917                                 else if(argv(0) == "fog")
 918                                 {
 919                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
 920                                         LOG_INFO("  \"fog\" \"", s, "\"");
 921                                 }
 922                                 else if(argv(0) == "set")
 923                                 {
 924                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 925                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
 926                                 }
 927                                 else if(argv(0) != "//")
 928                                 {
 929                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 930                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
 931                                 }
 932                         }
 933                         fclose(fd);
 934                 }
 935         }
 936
 937         WeaponStats_Init();
 938
 939         Nagger_Init();
 940
 941         // set up information replies for clients and server to use
 942         maplist_reply = strzone(getmaplist());
 943         lsmaps_reply = strzone(getlsmaps());
 944         monsterlist_reply = strzone(getmonsterlist());
 945         bool records_available = false;
 946         for(int i = 0; i < 10; ++i)
 947         {
 948                 string s = getrecords(i);
 949                 if (s != "")
 950                 {
 951                         records_reply[i] = strzone(s);
 952                         records_available = true;
 953                 }
 954         }
 955         if (!records_available)
 956                 records_reply[0] = "No records available for the current game mode.\n";
 957         ladder_reply = strzone(getladder());
 958         rankings_reply = strzone(getrankings());
 959
 960         // begin other init
 961         ClientInit_Spawn();
 962         RandomSeed_Spawn();
 963         PingPLReport_Spawn();
 964
 965         CheatInit();
 966
 967         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 968
 969         // fill sv_curl_serverpackages from .serverpackage files
 970         if (autocvar_sv_curl_serverpackages_auto)
 971         {
 972                 string s = "csprogs-" WATERMARK ".dat";
 973                 // remove automatically managed files from the list to prevent duplicates
 974                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 975                 {
 976                         string pkg = argv(i);
 977                         if (startsWith(pkg, "csprogs-")) continue;
 978                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 979                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 980                         s = cons(s, pkg);
 981                 }
 982                 // add automatically managed files to the list
 983                 #define X(match) MACRO_BEGIN \
 984                         int fd = search_begin(match, true, false); \
 985                         if (fd >= 0) \
 986                         { \
 987                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 988                                 { \
 989                                         s = cons(s, search_getfilename(fd, i)); \
 990                                 } \
 991                                 search_end(fd); \
 992                         } \
 993                 MACRO_END
 994                 X("*-serverpackage.txt");
 995                 X("*.serverpackage");
 996                 #undef X
 997                 cvar_set("sv_curl_serverpackages", s);
 998         }
 999
1000         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
1001         modname = "Xonotic";
1002         // physics/balance/config changes that count as mod
1003         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
1004                 modname = cvar_string("g_mod_physics");
1005         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance") && cvar_string("g_mod_balance") != "Testing")
1006                 modname = cvar_string("g_mod_balance");
1007         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
1008                 modname = cvar_string("g_mod_config");
1009         // extra mutators that deserve to count as mod
1010         MUTATOR_CALLHOOK(SetModname, modname);
1011         modname = M_ARGV(0, string);
1012
1013         // save it for later
1014         modname = strzone(modname);
1015
1016         WinningConditionHelper(this); // set worldstatus
1017
1018         world_initialized = 1;
1019         __spawnfunc_spawn_all();
1020 }
1021
1022 spawnfunc(light)
1023 {
1024         //makestatic (this); // Who the f___ did that?
1025         delete(this);
1026 }
1027
1028 bool MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, int attempts, float maxaboveground, float minviewdistance)
1029 {
1030     float m = e.dphitcontentsmask;
1031     e.dphitcontentsmask = goodcontents | badcontents;
1032
1033     vector org = boundmin;
1034     vector delta = boundmax - boundmin;
1035
1036     vector start, end;
1037     start = end = org;
1038     int j; // used after the loop
1039     for(j = 0; j < attempts; ++j)
1040     {
1041         start.x = org.x + random() * delta.x;
1042         start.y = org.y + random() * delta.y;
1043         start.z = org.z + random() * delta.z;
1044
1045         // rule 1: start inside world bounds, and outside
1046         // solid, and don't start from somewhere where you can
1047         // fall down to evil
1048         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1049         if (trace_fraction >= 1)
1050             continue;
1051         if (trace_startsolid)
1052             continue;
1053         if (trace_dphitcontents & badcontents)
1054             continue;
1055         if (trace_dphitq3surfaceflags & badsurfaceflags)
1056             continue;
1057
1058         // rule 2: if we are too high, lower the point
1059         if (trace_fraction * delta.z > maxaboveground)
1060             start = trace_endpos + '0 0 1' * maxaboveground;
1061         vector enddown = trace_endpos;
1062
1063         // rule 3: make sure we aren't outside the map. This only works
1064         // for somewhat well formed maps. A good rule of thumb is that
1065         // the map should have a convex outside hull.
1066         // these can be traceLINES as we already verified the starting box
1067         vector mstart = start + 0.5 * (e.mins + e.maxs);
1068         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1069         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1070             continue;
1071         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1072         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1073             continue;
1074         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1075         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1076             continue;
1077         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1078         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1079             continue;
1080         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1081         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1082             continue;
1083
1084                 // rule 4: we must "see" some spawnpoint or item
1085             entity sp = NULL;
1086             IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1087             {
1088                 if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1089                 {
1090                         sp = it;
1091                         break;
1092                 }
1093             });
1094                 if(!sp)
1095                 {
1096                         int items_checked = 0;
1097                         IL_EACH(g_items, checkpvs(mstart, it),
1098                         {
1099                                 if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1100                                 {
1101                                         sp = it;
1102                                         break;
1103                                 }
1104
1105                                 ++items_checked;
1106                                 if(items_checked >= attempts)
1107                                         break; // sanity
1108                         });
1109
1110                         if(!sp)
1111                                 continue;
1112                 }
1113
1114         // find a random vector to "look at"
1115         end.x = org.x + random() * delta.x;
1116         end.y = org.y + random() * delta.y;
1117         end.z = org.z + random() * delta.z;
1118         end = start + normalize(end - start) * vlen(delta);
1119
1120         // rule 4: start TO end must not be too short
1121         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1122         if(trace_startsolid)
1123             continue;
1124         if(trace_fraction < minviewdistance / vlen(delta))
1125             continue;
1126
1127         // rule 5: don't want to look at sky
1128         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1129             continue;
1130
1131         // rule 6: we must not end up in trigger_hurt
1132         if(tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1133             continue;
1134
1135         break;
1136     }
1137
1138     e.dphitcontentsmask = m;
1139
1140     if(j < attempts)
1141     {
1142         setorigin(e, start);
1143         e.angles = vectoangles(end - start);
1144         LOG_DEBUG("Needed ", ftos(j + 1), " attempts");
1145         return true;
1146     }
1147     return false;
1148 }
1149
1150 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1151 {
1152         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1153 }
1154
1155 /*
1156 ===============================================================================
1157
1158 RULES
1159
1160 ===============================================================================
1161 */
1162
1163 void DumpStats(float final)
1164 {
1165         float file;
1166         string s;
1167         float to_console;
1168         float to_eventlog;
1169         float to_file;
1170         float i;
1171
1172         to_console = autocvar_sv_logscores_console;
1173         to_eventlog = autocvar_sv_eventlog;
1174         to_file = autocvar_sv_logscores_file;
1175
1176         if(!final)
1177         {
1178                 to_console = true; // always print printstats replies
1179                 to_eventlog = false; // but never print them to the event log
1180         }
1181
1182         if(to_eventlog)
1183                 if(autocvar_sv_eventlog_console)
1184                         to_console = false; // otherwise we get the output twice
1185
1186         if(final)
1187                 s = ":scores:";
1188         else
1189                 s = ":status:";
1190         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1191
1192         if(to_console)
1193                 LOG_HELP(s);
1194         if(to_eventlog)
1195                 GameLogEcho(s);
1196
1197         file = -1;
1198         if(to_file)
1199         {
1200                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1201                 if(file == -1)
1202                         to_file = false;
1203                 else
1204                         fputs(file, strcat(s, "\n"));
1205         }
1206
1207         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1208         if(to_console)
1209                 LOG_HELP(s);
1210         if(to_eventlog)
1211                 GameLogEcho(s);
1212         if(to_file)
1213                 fputs(file, strcat(s, "\n"));
1214
1215         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1216                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1217                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1218                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1219                         s = strcat(s, ftos(it.team), ":");
1220                 else
1221                         s = strcat(s, "spectator:");
1222
1223                 if(to_console)
1224                         LOG_HELP(s, playername(it.netname, it.team, false));
1225                 if(to_eventlog)
1226                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it.netname, it.team, false)));
1227                 if(to_file)
1228                         fputs(file, strcat(s, playername(it.netname, it.team, false), "\n"));
1229         });
1230
1231         if(teamplay)
1232         {
1233                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1234                 if(to_console)
1235                         LOG_HELP(s);
1236                 if(to_eventlog)
1237                         GameLogEcho(s);
1238                 if(to_file)
1239                         fputs(file, strcat(s, "\n"));
1240
1241                 for(i = 1; i < 16; ++i)
1242                 {
1243                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1244                         s = strcat(s, ":", ftos(i));
1245                         if(to_console)
1246                                 LOG_HELP(s);
1247                         if(to_eventlog)
1248                                 GameLogEcho(s);
1249                         if(to_file)
1250                                 fputs(file, strcat(s, "\n"));
1251                 }
1252         }
1253
1254         if(to_console)
1255                 LOG_HELP(":end");
1256         if(to_eventlog)
1257                 GameLogEcho(":end");
1258         if(to_file)
1259         {
1260                 fputs(file, ":end\n");
1261                 fclose(file);
1262         }
1263 }
1264
1265 /*
1266 go to the next level for deathmatch
1267 only called if a time or frag limit has expired
1268 */
1269 void NextLevel()
1270 {
1271         game_stopped = true;
1272         intermission_running = true; // game over
1273
1274         // enforce a wait time before allowing changelevel
1275         if(player_count > 0)
1276                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1277         else
1278                 intermission_exittime = -1;
1279
1280         /*
1281         WriteByte (MSG_ALL, SVC_CDTRACK);
1282         WriteByte (MSG_ALL, 3);
1283         WriteByte (MSG_ALL, 3);
1284         // done in FixIntermission
1285         */
1286
1287         //pos = FindIntermission ();
1288
1289         VoteReset();
1290
1291         DumpStats(true);
1292
1293         // send statistics
1294         PlayerStats_GameReport(true);
1295         WeaponStats_Shutdown();
1296
1297         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1298
1299         if(autocvar_sv_eventlog)
1300                 GameLogEcho(":gameover");
1301
1302         GameLogClose();
1303
1304         FOREACH_CLIENT(IS_PLAYER(it), {
1305                 FixIntermissionClient(it);
1306                 if(it.winning)
1307                         bprint(playername(it.netname, it.team, false), " ^7wins.\n");
1308         });
1309
1310         target_music_kill();
1311
1312         if(autocvar_g_campaign)
1313                 CampaignPreIntermission();
1314
1315         MUTATOR_CALLHOOK(MatchEnd);
1316
1317         localcmd("\nsv_hook_gameend\n");
1318 }
1319
1320
1321 float InitiateSuddenDeath()
1322 {
1323         // Check first whether normal overtimes could be added before initiating suddendeath mode
1324         // - for this timelimit_overtime needs to be >0 of course
1325         // - also check the winning condition calculated in the previous frame and only add normal overtime
1326         //   again, if at the point at which timelimit would be extended again, still no winner was found
1327         if (!autocvar_g_campaign && checkrules_overtimesadded >= 0
1328                 && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0)
1329                 && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1330         {
1331                 return 1; // need to call InitiateOvertime later
1332         }
1333         else
1334         {
1335                 if(!checkrules_suddendeathend)
1336                 {
1337                         if(autocvar_g_campaign)
1338                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1339                         else
1340                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1341                         if(g_race && !g_race_qualifying)
1342                                 race_StartCompleting();
1343                 }
1344                 return 0;
1345         }
1346 }
1347
1348 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1349 {
1350         ++checkrules_overtimesadded;
1351         //add one more overtime by simply extending the timelimit
1352         cvar_set("timelimit", ftos(autocvar_timelimit + autocvar_timelimit_overtime));
1353         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1354 }
1355
1356 float GetWinningCode(float fraglimitreached, float equality)
1357 {
1358         if(autocvar_g_campaign == 1)
1359         {
1360                 if(fraglimitreached)
1361                         return WINNING_YES;
1362                 else
1363                         return WINNING_NO;
1364         }
1365         else
1366         {
1367                 if(equality)
1368                 {
1369                         if(fraglimitreached)
1370                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1371                         else
1372                                 return WINNING_NEVER;
1373                 }
1374                 else
1375                 {
1376                         if(fraglimitreached)
1377                                 return WINNING_YES;
1378                         else
1379                                 return WINNING_NO;
1380                 }
1381         }
1382 }
1383
1384 // set the .winning flag for exactly those players with a given field value
1385 void SetWinners(.float field, float value)
1386 {
1387         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = (it.(field) == value); });
1388 }
1389
1390 // set the .winning flag for those players with a given field value
1391 void AddWinners(.float field, float value)
1392 {
1393         FOREACH_CLIENT(IS_PLAYER(it), {
1394                 if(it.(field) == value)
1395                         it.winning = 1;
1396         });
1397 }
1398
1399 // clear the .winning flags
1400 void ClearWinners()
1401 {
1402         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = 0; });
1403 }
1404
1405 int fragsleft_last;
1406 float WinningCondition_Scores(float limit, float leadlimit)
1407 {
1408         // TODO make everything use THIS winning condition (except LMS)
1409         WinningConditionHelper(NULL);
1410
1411         if(teamplay)
1412         {
1413                 for (int i = 1; i < 5; ++i)
1414                 {
1415                         Team_SetTeamScore(Team_GetTeamFromIndex(i),
1416                                 TeamScore_GetCompareValue(Team_IndexToTeam(i)));
1417                 }
1418         }
1419
1420         ClearWinners();
1421         if(WinningConditionHelper_winner)
1422                 WinningConditionHelper_winner.winning = 1;
1423         if(WinningConditionHelper_winnerteam >= 0)
1424                 SetWinners(team, WinningConditionHelper_winnerteam);
1425
1426         if(WinningConditionHelper_lowerisbetter)
1427         {
1428                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1429                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1430                 limit = -limit;
1431         }
1432
1433         if(WinningConditionHelper_zeroisworst)
1434                 leadlimit = 0; // not supported in this mode
1435
1436         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1437         {
1438                 float fragsleft;
1439                 if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1440                 {
1441                         fragsleft = 1;
1442                 }
1443                 else
1444                 {
1445                         fragsleft = FLOAT_MAX;
1446                         float leadingfragsleft = FLOAT_MAX;
1447                         if (limit)
1448                                 fragsleft = limit - WinningConditionHelper_topscore;
1449                         if (leadlimit)
1450                                 leadingfragsleft = WinningConditionHelper_secondscore + leadlimit - WinningConditionHelper_topscore;
1451
1452                         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1453                                 fragsleft = max(fragsleft, leadingfragsleft);
1454                         else
1455                                 fragsleft = min(fragsleft, leadingfragsleft);
1456                 }
1457
1458                 if (fragsleft_last != fragsleft) // do not announce same remaining frags multiple times
1459                 {
1460                         if (fragsleft == 1)
1461                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1462                         else if (fragsleft == 2)
1463                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1464                         else if (fragsleft == 3)
1465                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1466
1467                         fragsleft_last = fragsleft;
1468                 }
1469         }
1470
1471         bool fraglimit_reached = (limit && WinningConditionHelper_topscore >= limit);
1472         bool leadlimit_reached = (leadlimit && WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1473
1474         bool limit_reached;
1475         // only respect leadlimit_and_fraglimit when both limits are set or the game will never end
1476         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1477                 limit_reached = (fraglimit_reached && leadlimit_reached);
1478         else
1479                 limit_reached = (fraglimit_reached || leadlimit_reached);
1480
1481         return GetWinningCode(
1482                 WinningConditionHelper_topscore && limit_reached,
1483                 WinningConditionHelper_equality
1484         );
1485 }
1486
1487 float WinningCondition_RanOutOfSpawns()
1488 {
1489         if(have_team_spawns <= 0)
1490                 return WINNING_NO;
1491
1492         if(!autocvar_g_spawn_useallspawns)
1493                 return WINNING_NO;
1494
1495         if(!some_spawn_has_been_used)
1496                 return WINNING_NO;
1497
1498         for (int i = 1; i < 5; ++i)
1499         {
1500                 Team_SetTeamScore(Team_GetTeamFromIndex(i), 0);
1501         }
1502
1503         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
1504         {
1505                 if (Team_IsValidTeam(it.team))
1506                 {
1507                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1508                 }
1509         });
1510
1511         IL_EACH(g_spawnpoints, true,
1512         {
1513                 if (Team_IsValidTeam(it.team))
1514                 {
1515                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1516                 }
1517         });
1518
1519         ClearWinners();
1520         float team1_score = Team_GetTeamScore(Team_GetTeamFromIndex(1));
1521         float team2_score = Team_GetTeamScore(Team_GetTeamFromIndex(2));
1522         float team3_score = Team_GetTeamScore(Team_GetTeamFromIndex(3));
1523         float team4_score = Team_GetTeamScore(Team_GetTeamFromIndex(4));
1524         if(team1_score + team2_score + team3_score + team4_score == 0)
1525         {
1526                 checkrules_equality = true;
1527                 return WINNING_YES;
1528         }
1529         else if(team1_score + team2_score + team3_score + team4_score == 1)
1530         {
1531                 float t, i;
1532                 if(team1_score)
1533                         t = 1;
1534                 else if(team2_score)
1535                         t = 2;
1536                 else if(team3_score)
1537                         t = 3;
1538                 else // if(team4_score)
1539                         t = 4;
1540                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
1541                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1542                 {
1543                         for (int j = 1; j <= NUM_TEAMS; ++j)
1544                         {
1545                                 if (t == j)
1546                                 {
1547                                         continue;
1548                                 }
1549                                 if (!TeamBalance_IsTeamAllowed(balance, j))
1550                                 {
1551                                         continue;
1552                                 }
1553                                 TeamScore_AddToTeam(Team_IndexToTeam(j), i, -1000);
1554                         }
1555                 }
1556
1557                 AddWinners(team, t);
1558                 return WINNING_YES;
1559         }
1560         else
1561                 return WINNING_NO;
1562 }
1563
1564 /*
1565 ============
1566 CheckRules_World
1567
1568 Exit deathmatch games upon conditions
1569 ============
1570 */
1571 void CheckRules_World()
1572 {
1573         VoteThink();
1574         MapVote_Think();
1575
1576         SetDefaultAlpha();
1577
1578         if (intermission_running) // someone else quit the game already
1579         {
1580                 if(player_count == 0) // Nobody there? Then let's go to the next map
1581                         MapVote_Start();
1582                         // this will actually check the player count in the next frame
1583                         // again, but this shouldn't hurt
1584                 return;
1585         }
1586
1587         float timelimit = autocvar_timelimit * 60;
1588         float fraglimit = autocvar_fraglimit;
1589         float leadlimit = autocvar_leadlimit;
1590         if (leadlimit < 0) leadlimit = 0;
1591
1592         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1593         {
1594                 if(timelimit > 0)
1595                         timelimit = 0; // timelimit is not made for warmup
1596                 if(fraglimit > 0)
1597                         fraglimit = 0; // no fraglimit for now
1598                 leadlimit = 0; // no leadlimit for now
1599         }
1600
1601         if(timelimit > 0)
1602         {
1603                 timelimit += game_starttime;
1604         }
1605         else if (timelimit < 0)
1606         {
1607                 // endmatch
1608                 NextLevel();
1609                 return;
1610         }
1611
1612         float wantovertime;
1613         wantovertime = 0;
1614
1615         if(checkrules_suddendeathend)
1616         {
1617                 if(!checkrules_suddendeathwarning)
1618                 {
1619                         checkrules_suddendeathwarning = true;
1620                         if(g_race && !g_race_qualifying)
1621                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1622                         else
1623                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1624                 }
1625         }
1626         else
1627         {
1628                 if (timelimit && time >= timelimit)
1629                 {
1630                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1631                         {
1632                                 float totalplayers;
1633                                 float playerswithlaps;
1634                                 float readyplayers;
1635                                 totalplayers = playerswithlaps = readyplayers = 0;
1636                                 FOREACH_CLIENT(IS_PLAYER(it), {
1637                                         ++totalplayers;
1638                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1639                                                 ++playerswithlaps;
1640                                         if(it.ready)
1641                                                 ++readyplayers;
1642                                 });
1643
1644                                 // at least 2 of the players have completed a lap: start the RACE
1645                                 // otherwise, the players should end the qualifying on their own
1646                                 if(readyplayers || playerswithlaps >= 2)
1647                                 {
1648                                         checkrules_suddendeathend = 0;
1649                                         ReadyRestart(); // go to race
1650                                         return;
1651                                 }
1652                                 else
1653                                         wantovertime |= InitiateSuddenDeath();
1654                         }
1655                         else
1656                                 wantovertime |= InitiateSuddenDeath();
1657                 }
1658         }
1659
1660         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1661         {
1662                 NextLevel();
1663                 return;
1664         }
1665
1666         int checkrules_status = WinningCondition_RanOutOfSpawns();
1667         if(checkrules_status == WINNING_YES)
1668                 bprint("Hey! Someone ran out of spawns!\n");
1669         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1670                 checkrules_status = M_ARGV(0, float);
1671         else
1672                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1673
1674         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1675         {
1676                 checkrules_status = WINNING_NEVER;
1677                 checkrules_overtimesadded = -1;
1678                 wantovertime |= InitiateSuddenDeath();
1679         }
1680
1681         if(checkrules_status == WINNING_NEVER)
1682                 // equality cases! Nobody wins if the overtime ends in a draw.
1683                 ClearWinners();
1684
1685         if(wantovertime)
1686         {
1687                 if(checkrules_status == WINNING_NEVER)
1688                         InitiateOvertime();
1689                 else
1690                         checkrules_status = WINNING_YES;
1691         }
1692
1693         if(checkrules_suddendeathend)
1694                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1695                         checkrules_status = WINNING_YES;
1696
1697         if(checkrules_status == WINNING_YES)
1698         {
1699                 //print("WINNING\n");
1700                 NextLevel();
1701         }
1702 }
1703
1704 float want_weapon(entity weaponinfo, float allguns)
1705 {
1706         int d = 0;
1707         bool allow_mutatorblocked = false;
1708
1709         if(!weaponinfo.m_id)
1710                 return 0;
1711
1712         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
1713         d = M_ARGV(1, float);
1714         allguns = M_ARGV(2, bool);
1715         allow_mutatorblocked = M_ARGV(3, bool);
1716
1717         if(allguns)
1718                 d = boolean((weaponinfo.spawnflags & WEP_FLAG_NORMAL) && !(weaponinfo.spawnflags & (WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)));
1719         else if(!mutator_returnvalue)
1720                 d = !(!weaponinfo.weaponstart);
1721
1722         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
1723                 d = 0;
1724
1725         float t = weaponinfo.weaponstartoverride;
1726
1727         //LOG_INFOF("want_weapon: %s - d: %d t: %d\n", weaponinfo.netname, d, t);
1728
1729         // bit order in t:
1730         // 1: want or not
1731         // 2: is default?
1732         // 4: is set by default?
1733         if(t < 0)
1734                 t = 4 | (3 * d);
1735         else
1736                 t |= (2 * d);
1737
1738         return t;
1739 }
1740
1741 /// Weapons the player normally starts with outside weapon arena.
1742 WepSet weapons_start()
1743 {
1744         WepSet ret = '0 0 0';
1745         FOREACH(Weapons, it != WEP_Null, {
1746                 int w = want_weapon(it, false);
1747                 if (w & 1)
1748                         ret |= it.m_wepset;
1749         });
1750         return ret;
1751 }
1752
1753 WepSet weapons_all()
1754 {
1755         WepSet ret = '0 0 0';
1756         FOREACH(Weapons, it != WEP_Null, {
1757                 if (!(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_SPECIALATTACK)))
1758                         ret |= it.m_wepset;
1759         });
1760         return ret;
1761 }
1762
1763 WepSet weapons_devall()
1764 {
1765         WepSet ret = '0 0 0';
1766         FOREACH(Weapons, it != WEP_Null,
1767         {
1768                 ret |= it.m_wepset;
1769         });
1770         return ret;
1771 }
1772
1773 WepSet weapons_most()
1774 {
1775         WepSet ret = '0 0 0';
1776         FOREACH(Weapons, it != WEP_Null, {
1777                 if ((it.spawnflags & WEP_FLAG_NORMAL) && !(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)))
1778                         ret |= it.m_wepset;
1779         });
1780         return ret;
1781 }
1782
1783 void weaponarena_available_all_update(entity this)
1784 {
1785         if (weaponsInMapAll)
1786         {
1787                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_all());
1788         }
1789         else
1790         {
1791                 // if no weapons are available on the map, just fall back to all weapons arena
1792                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_all();
1793         }
1794 }
1795
1796 void weaponarena_available_devall_update(entity this)
1797 {
1798         if (weaponsInMapAll)
1799         {
1800                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | weaponsInMapAll;
1801         }
1802         else
1803         {
1804                 // if no weapons are available on the map, just fall back to devall weapons arena
1805                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_devall();
1806         }
1807 }
1808
1809 void weaponarena_available_most_update(entity this)
1810 {
1811         if (weaponsInMapAll)
1812         {
1813                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_most());
1814         }
1815         else
1816         {
1817                 // if no weapons are available on the map, just fall back to most weapons arena
1818                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_most();
1819         }
1820 }
1821
1822 void readplayerstartcvars()
1823 {
1824         // initialize starting values for players
1825         start_weapons = '0 0 0';
1826         start_weapons_default = '0 0 0';
1827         start_weapons_defaultmask = '0 0 0';
1828         start_items = 0;
1829         start_ammo_shells = 0;
1830         start_ammo_nails = 0;
1831         start_ammo_rockets = 0;
1832         start_ammo_cells = 0;
1833         start_ammo_plasma = 0;
1834         if (random_start_ammo == NULL)
1835         {
1836                 random_start_ammo = new_pure(random_start_ammo);
1837         }
1838         start_health = cvar("g_balance_health_start");
1839         start_armorvalue = cvar("g_balance_armor_start");
1840
1841         g_weaponarena = 0;
1842         g_weaponarena_weapons = '0 0 0';
1843
1844         string s = cvar_string("g_weaponarena");
1845
1846         MUTATOR_CALLHOOK(SetWeaponArena, s);
1847         s = M_ARGV(0, string);
1848
1849         if (s == "0" || s == "")
1850         {
1851                 // no arena
1852         }
1853         else if (s == "off")
1854         {
1855                 // forcibly turn off weaponarena
1856         }
1857         else if (s == "all" || s == "1")
1858         {
1859                 g_weaponarena = 1;
1860                 g_weaponarena_list = "All Weapons";
1861                 g_weaponarena_weapons = weapons_all();
1862         }
1863         else if (s == "devall")
1864         {
1865                 g_weaponarena = 1;
1866                 g_weaponarena_list = "Dev All Weapons";
1867                 g_weaponarena_weapons = weapons_devall();
1868         }
1869         else if (s == "most")
1870         {
1871                 g_weaponarena = 1;
1872                 g_weaponarena_list = "Most Weapons";
1873                 g_weaponarena_weapons = weapons_most();
1874         }
1875         else if (s == "all_available")
1876         {
1877                 g_weaponarena = 1;
1878                 g_weaponarena_list = "All Available Weapons";
1879
1880                 // this needs to run after weaponsInMapAll is initialized
1881                 InitializeEntity(NULL, weaponarena_available_all_update, INITPRIO_FINDTARGET);
1882         }
1883         else if (s == "devall_available")
1884         {
1885                 g_weaponarena = 1;
1886                 g_weaponarena_list = "Dev All Available Weapons";
1887
1888                 // this needs to run after weaponsInMapAll is initialized
1889                 InitializeEntity(NULL, weaponarena_available_devall_update, INITPRIO_FINDTARGET);
1890         }
1891         else if (s == "most_available")
1892         {
1893                 g_weaponarena = 1;
1894                 g_weaponarena_list = "Most Available Weapons";
1895
1896                 // this needs to run after weaponsInMapAll is initialized
1897                 InitializeEntity(NULL, weaponarena_available_most_update, INITPRIO_FINDTARGET);
1898         }
1899         else if (s == "none")
1900         {
1901                 g_weaponarena = 1;
1902                 g_weaponarena_list = "No Weapons";
1903         }
1904         else
1905         {
1906                 g_weaponarena = 1;
1907                 float t = tokenize_console(s);
1908                 g_weaponarena_list = "";
1909                 for (int j = 0; j < t; ++j)
1910                 {
1911                         s = argv(j);
1912                         Weapon wep = Weapon_from_name(s);
1913                         if(wep != WEP_Null)
1914                         {
1915                                 g_weaponarena_weapons |= (wep.m_wepset);
1916                                 g_weaponarena_list = strcat(g_weaponarena_list, wep.m_name, " & ");
1917                         }
1918                 }
1919                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
1920         }
1921
1922         if (g_weaponarena)
1923         {
1924                 g_weapon_stay = 0; // incompatible
1925                 start_weapons = g_weaponarena_weapons;
1926                 start_items |= IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS;
1927         }
1928         else
1929         {
1930                 FOREACH(Weapons, it != WEP_Null, {
1931                         int w = want_weapon(it, false);
1932                         WepSet s = it.m_wepset;
1933                         if(w & 1)
1934                                 start_weapons |= s;
1935                         if(w & 2)
1936                                 start_weapons_default |= s;
1937                         if(w & 4)
1938                                 start_weapons_defaultmask |= s;
1939                 });
1940         }
1941
1942         if(cvar("g_balance_superweapons_time") < 0)
1943                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
1944
1945         if(!cvar("g_use_ammunition"))
1946                 start_items |= IT_UNLIMITED_AMMO;
1947
1948         if(start_items & IT_UNLIMITED_AMMO)
1949         {
1950                 start_ammo_shells = 999;
1951                 start_ammo_nails = 999;
1952                 start_ammo_rockets = 999;
1953                 start_ammo_cells = 999;
1954                 start_ammo_plasma = 999;
1955                 start_ammo_fuel = 999;
1956         }
1957         else
1958         {
1959                 start_ammo_shells = cvar("g_start_ammo_shells");
1960                 start_ammo_nails = cvar("g_start_ammo_nails");
1961                 start_ammo_rockets = cvar("g_start_ammo_rockets");
1962                 start_ammo_cells = cvar("g_start_ammo_cells");
1963                 start_ammo_plasma = cvar("g_start_ammo_plasma");
1964                 start_ammo_fuel = cvar("g_start_ammo_fuel");
1965                 random_start_weapons_count = cvar("g_random_start_weapons_count");
1966                 SetResource(random_start_ammo, RES_SHELLS, cvar("g_random_start_shells"));
1967                 SetResource(random_start_ammo, RES_BULLETS, cvar("g_random_start_bullets"));
1968                 SetResource(random_start_ammo, RES_ROCKETS, cvar("g_random_start_rockets"));
1969                 SetResource(random_start_ammo, RES_CELLS, cvar("g_random_start_cells"));
1970                 SetResource(random_start_ammo, RES_PLASMA, cvar("g_random_start_plasma"));
1971         }
1972
1973         warmup_start_ammo_shells = start_ammo_shells;
1974         warmup_start_ammo_nails = start_ammo_nails;
1975         warmup_start_ammo_rockets = start_ammo_rockets;
1976         warmup_start_ammo_cells = start_ammo_cells;
1977         warmup_start_ammo_plasma = start_ammo_plasma;
1978         warmup_start_ammo_fuel = start_ammo_fuel;
1979         warmup_start_health = start_health;
1980         warmup_start_armorvalue = start_armorvalue;
1981         warmup_start_weapons = start_weapons;
1982         warmup_start_weapons_default = start_weapons_default;
1983         warmup_start_weapons_defaultmask = start_weapons_defaultmask;
1984
1985         if (!g_weaponarena)
1986         {
1987                 warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1988                 warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1989                 warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1990                 warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1991                 warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
1992                 warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1993                 warmup_start_health = cvar("g_warmup_start_health");
1994                 warmup_start_armorvalue = cvar("g_warmup_start_armor");
1995                 warmup_start_weapons = '0 0 0';
1996                 warmup_start_weapons_default = '0 0 0';
1997                 warmup_start_weapons_defaultmask = '0 0 0';
1998                 FOREACH(Weapons, it != WEP_Null, {
1999                         int w = want_weapon(it, autocvar_g_warmup_allguns);
2000                         WepSet s = it.m_wepset;
2001                         if(w & 1)
2002                                 warmup_start_weapons |= s;
2003                         if(w & 2)
2004                                 warmup_start_weapons_default |= s;
2005                         if(w & 4)
2006                                 warmup_start_weapons_defaultmask |= s;
2007                 });
2008         }
2009
2010         if (autocvar_g_jetpack)
2011                 start_items |= ITEM_Jetpack.m_itemid;
2012
2013         MUTATOR_CALLHOOK(SetStartItems);
2014
2015         if (start_items & ITEM_Jetpack.m_itemid)
2016         {
2017                 start_items |= ITEM_JetpackRegen.m_itemid;
2018                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
2019                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
2020         }
2021
2022         start_ammo_shells = max(0, start_ammo_shells);
2023         start_ammo_nails = max(0, start_ammo_nails);
2024         start_ammo_rockets = max(0, start_ammo_rockets);
2025         start_ammo_cells = max(0, start_ammo_cells);
2026         start_ammo_plasma = max(0, start_ammo_plasma);
2027         start_ammo_fuel = max(0, start_ammo_fuel);
2028         SetResource(random_start_ammo, RES_SHELLS, max(0, GetResource(random_start_ammo, RES_SHELLS)));
2029         SetResource(random_start_ammo, RES_BULLETS, max(0, GetResource(random_start_ammo, RES_BULLETS)));
2030         SetResource(random_start_ammo, RES_ROCKETS, max(0, GetResource(random_start_ammo, RES_ROCKETS)));
2031         SetResource(random_start_ammo, RES_CELLS, max(0, GetResource(random_start_ammo, RES_CELLS)));
2032         SetResource(random_start_ammo, RES_PLASMA, max(0, GetResource(random_start_ammo, RES_PLASMA)));
2033
2034         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
2035         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
2036         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
2037         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
2038         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
2039         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
2040 }
2041
2042 void readlevelcvars()
2043 {
2044         if(cvar("sv_allow_fullbright"))
2045                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
2046
2047         sv_ready_restart_after_countdown = cvar("sv_ready_restart_after_countdown");
2048
2049         warmup_stage = cvar("g_warmup");
2050         warmup_limit = cvar("g_warmup_limit");
2051
2052         if(cvar("g_campaign"))
2053                 warmup_stage = 0; // no warmup during campaign
2054
2055         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
2056         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
2057         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
2058         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
2059         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
2060         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
2061         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
2062         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
2063         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
2064         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
2065         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
2066         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
2067         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
2068         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
2069
2070         g_pickup_shells = cvar("g_pickup_shells");
2071         g_pickup_shells_max = cvar("g_pickup_shells_max");
2072         g_pickup_nails = cvar("g_pickup_nails");
2073         g_pickup_nails_max = cvar("g_pickup_nails_max");
2074         g_pickup_rockets = cvar("g_pickup_rockets");
2075         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
2076         g_pickup_cells = cvar("g_pickup_cells");
2077         g_pickup_cells_max = cvar("g_pickup_cells_max");
2078         g_pickup_plasma = cvar("g_pickup_plasma");
2079         g_pickup_plasma_max = cvar("g_pickup_plasma_max");
2080         g_pickup_fuel = cvar("g_pickup_fuel");
2081         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
2082         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
2083         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
2084         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
2085         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
2086         g_pickup_armormedium = cvar("g_pickup_armormedium");
2087         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
2088         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
2089         g_pickup_armorbig = cvar("g_pickup_armorbig");
2090         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
2091         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
2092         g_pickup_armormega = cvar("g_pickup_armormega");
2093         g_pickup_armormega_max = cvar("g_pickup_armormega_max");
2094         g_pickup_armormega_anyway = cvar("g_pickup_armormega_anyway");
2095         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
2096         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
2097         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
2098         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
2099         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
2100         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
2101         g_pickup_healthbig = cvar("g_pickup_healthbig");
2102         g_pickup_healthbig_max = cvar("g_pickup_healthbig_max");
2103         g_pickup_healthbig_anyway = cvar("g_pickup_healthbig_anyway");
2104         g_pickup_healthmega = cvar("g_pickup_healthmega");
2105         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
2106         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
2107
2108         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
2109         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
2110
2111     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
2112     if(!g_weapon_stay)
2113         g_weapon_stay = cvar("g_weapon_stay");
2114
2115     MUTATOR_CALLHOOK(ReadLevelCvars);
2116
2117         if (!warmup_stage)
2118                 game_starttime = time + cvar("g_start_delay");
2119
2120         FOREACH(Weapons, it != WEP_Null, { it.wr_init(it); });
2121
2122         readplayerstartcvars();
2123 }
2124
2125 void InitializeEntity(entity e, void(entity this) func, int order)
2126 {
2127     entity prev, cur;
2128
2129     if (!e || e.initialize_entity)
2130     {
2131         // make a proxy initializer entity
2132         entity e_old = e;
2133         e = new(initialize_entity);
2134         e.enemy = e_old;
2135     }
2136
2137     e.initialize_entity = func;
2138     e.initialize_entity_order = order;
2139
2140     cur = initialize_entity_first;
2141     prev = NULL;
2142     for (;;)
2143     {
2144         if (!cur || cur.initialize_entity_order > order)
2145         {
2146             // insert between prev and cur
2147             if (prev)
2148                 prev.initialize_entity_next = e;
2149             else
2150                 initialize_entity_first = e;
2151             e.initialize_entity_next = cur;
2152             return;
2153         }
2154         prev = cur;
2155         cur = cur.initialize_entity_next;
2156     }
2157 }
2158 void InitializeEntitiesRun()
2159 {
2160     entity startoflist = initialize_entity_first;
2161     initialize_entity_first = NULL;
2162     delete_fn = remove_except_protected;
2163     for (entity e = startoflist; e; e = e.initialize_entity_next)
2164     {
2165                 e.remove_except_protected_forbidden = 1;
2166     }
2167     for (entity e = startoflist; e; )
2168     {
2169                 e.remove_except_protected_forbidden = 0;
2170         e.initialize_entity_order = 0;
2171         entity next = e.initialize_entity_next;
2172         e.initialize_entity_next = NULL;
2173         var void(entity this) func = e.initialize_entity;
2174         e.initialize_entity = func_null;
2175         if (e.classname == "initialize_entity")
2176         {
2177             entity wrappee = e.enemy;
2178             builtin_remove(e);
2179             e = wrappee;
2180         }
2181         //dprint("Delayed initialization: ", e.classname, "\n");
2182         if (func)
2183         {
2184                 func(e);
2185         }
2186         else
2187         {
2188             eprint(e);
2189             backtrace(strcat("Null function in: ", e.classname, "\n"));
2190         }
2191         e = next;
2192     }
2193     delete_fn = remove_unsafely;
2194 }
2195
2196 // deferred dropping
2197 void DropToFloor_Handler(entity this)
2198 {
2199         WITHSELF(this, builtin_droptofloor());
2200         this.dropped_origin = this.origin;
2201 }
2202
2203 void droptofloor(entity this)
2204 {
2205         InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
2206 }
2207
2208 bool autocvar_sv_gameplayfix_multiplethinksperframe = true;
2209 void RunThink(entity this)
2210 {
2211         // don't let things stay in the past.
2212         // it is possible to start that way by a trigger with a local time.
2213         if(this.nextthink <= 0 || this.nextthink > time + frametime)
2214                 return;
2215
2216         float oldtime = time; // do we need to save this?
2217
2218         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2219         {
2220                 time = max(oldtime, this.nextthink);
2221                 this.nextthink = 0;
2222
2223                 if(getthink(this))
2224                         getthink(this)(this);
2225                 // mods often set nextthink to time to cause a think every frame,
2226                 // we don't want to loop in that case, so exit if the new nextthink is
2227                 // <= the time the qc was told, also exit if it is past the end of the
2228                 // frame
2229                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2230                         break;
2231         }
2232
2233         time = oldtime;
2234 }
2235
2236 bool autocvar_sv_freezenonclients;
2237 void Physics_Frame()
2238 {
2239         if(autocvar_sv_freezenonclients)
2240                 return;
2241
2242         IL_EACH(g_moveables, true,
2243         {
2244                 if(IS_CLIENT(it) || it.move_movetype == MOVETYPE_PHYSICS)
2245                         continue;
2246
2247                 //set_movetype(it, it.move_movetype);
2248                 // inline the set_movetype function, since this is called a lot
2249                 it.movetype = (it.move_qcphysics) ? MOVETYPE_QCENTITY : it.move_movetype;
2250
2251                 if(it.move_qcphysics && it.move_movetype != MOVETYPE_NONE)
2252                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2253
2254                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2255                 {
2256                         if(it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH)
2257                                 continue; // these movetypes have no regular think function
2258                         // handle thinking here
2259                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2260                                 RunThink(it);
2261                 }
2262         });
2263
2264         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2265                 return;
2266
2267         // make a second pass to see if any ents spawned this frame and make
2268         // sure they run their move/think. this is verified by checking .move_time, which will never be 0 if the entity has moved
2269         // MOVETYPE_NONE is also checked as .move_time WILL be 0 with that movetype
2270         IL_EACH(g_moveables, it.move_qcphysics,
2271         {
2272                 if(IS_CLIENT(it) || it.move_time || it.move_movetype == MOVETYPE_NONE || it.move_movetype == MOVETYPE_PHYSICS)
2273                         continue;
2274                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2275         });
2276 }
2277
2278 void systems_update();
2279 void EndFrame()
2280 {
2281         anticheat_endframe();
2282
2283         Physics_Frame();
2284
2285         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2286                 entity e = IS_SPEC(it) ? it.enemy : it;
2287                 if (e.typehitsound) {
2288                         STAT(TYPEHIT_TIME, it) = time;
2289                 } else if (e.killsound) {
2290                         STAT(KILL_TIME, it) = time;
2291                 } else if (e.damage_dealt) {
2292                         STAT(HIT_TIME, it) = time;
2293                         STAT(DAMAGE_DEALT_TOTAL, it) += ceil(e.damage_dealt);
2294                 }
2295         });
2296         // add 1 frametime because after this, engine SV_Physics
2297         // increases time by a frametime and then networks the frame
2298         // add another frametime because client shows everything with
2299         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2300         // needed!
2301         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2302         FOREACH_CLIENT(true, {
2303                 it.typehitsound = false;
2304                 it.damage_dealt = 0;
2305                 it.killsound = false;
2306                 antilag_record(it, CS(it), altime);
2307         });
2308         IL_EACH(g_monsters, true,
2309         {
2310                 antilag_record(it, it, altime);
2311         });
2312         IL_EACH(g_projectiles, it.classname == "nade",
2313         {
2314                 antilag_record(it, it, altime);
2315         });
2316         systems_update();
2317         IL_ENDFRAME();
2318 }
2319
2320
2321 /*
2322  * RedirectionThink:
2323  * returns true if redirecting
2324  */
2325 float redirection_timeout;
2326 float redirection_nextthink;
2327 float RedirectionThink()
2328 {
2329         float clients_found;
2330
2331         if(redirection_target == "")
2332                 return false;
2333
2334         if(!redirection_timeout)
2335         {
2336                 cvar_set("sv_public", "-2");
2337                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2338                 if(redirection_target == "self")
2339                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2340                 else
2341                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2342         }
2343
2344         if(time < redirection_nextthink)
2345                 return true;
2346
2347         redirection_nextthink = time + 1;
2348
2349         clients_found = 0;
2350         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2351                 // TODO add timer
2352                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2353                 if(redirection_target == "self")
2354                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2355                 else
2356                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2357                 ++clients_found;
2358         });
2359
2360         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2361
2362         if(time > redirection_timeout || clients_found == 0)
2363                 localcmd("\nwait; wait; wait; quit\n");
2364
2365         return true;
2366 }
2367
2368 void RestoreGame()
2369 {
2370         // Loaded from a save game
2371         // some things then break, so let's work around them...
2372
2373         // Progs DB (capture records)
2374         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2375
2376         // Mapinfo
2377         MapInfo_Shutdown();
2378         MapInfo_Enumerate();
2379         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2380         WeaponStats_Init();
2381
2382         TargetMusic_RestoreGame();
2383 }
2384
2385 void Shutdown()
2386 {
2387         game_stopped = 2;
2388
2389         if(world_initialized > 0)
2390         {
2391                 world_initialized = 0;
2392
2393                 // if a timeout is active, reset the slowmo value to normal
2394                 if(timeout_status == TIMEOUT_ACTIVE)
2395                         cvar_set("slowmo", ftos(orig_slowmo));
2396
2397                 LOG_TRACE("Saving persistent data...");
2398                 Ban_SaveBans();
2399
2400                 // playerstats with unfinished match
2401                 PlayerStats_GameReport(false);
2402
2403                 if(!cheatcount_total)
2404                 {
2405                         if(autocvar_sv_db_saveasdump)
2406                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2407                         else
2408                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2409                 }
2410                 if(autocvar_developer > 0)
2411                 {
2412                         if(autocvar_sv_db_saveasdump)
2413                                 db_dump(TemporaryDB, "server-temp.db");
2414                         else
2415                                 db_save(TemporaryDB, "server-temp.db");
2416                 }
2417                 CheatShutdown(); // must be after cheatcount check
2418                 db_close(ServerProgsDB);
2419                 db_close(TemporaryDB);
2420                 LOG_TRACE("Saving persistent data... done!");
2421                 // tell the bot system the game is ending now
2422                 bot_endgame();
2423
2424                 WeaponStats_Shutdown();
2425                 MapInfo_Shutdown();
2426         }
2427         else if(world_initialized == 0)
2428         {
2429                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2430         }
2431         else
2432         {
2433                 __init_dedicated_server_shutdown();
2434         }
2435 }