qcsrc/server/world.qc

   1 #include "world.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/gamemodes/sv_rules.qh>
   7 #include <common/items/_mod.qh>
   8 #include <common/mapinfo.qh>
   9 #include <common/mapobjects/target/music.qh>
  10 #include <common/mapobjects/trigger/hurt.qh>
  11 #include <common/mapobjects/trigger/secret.qh>
  12 #include <common/mapobjects/triggers.qh>
  13 #include <common/monsters/_mod.qh>
  14 #include <common/monsters/sv_monsters.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/notifications/all.qh>
  17 #include <common/physics/player.qh>
  18 #include <common/playerstats.qh>
  19 #include <common/state.qh>
  20 #include <common/stats.qh>
  21 #include <common/teams.qh>
  22 #include <common/util.qh>
  23 #include <common/vehicles/all.qh>
  24 #include <common/weapons/_all.qh>
  25 #include <server/anticheat.qh>
  26 #include <server/antilag.qh>
  27 #include <server/bot/api.qh>
  28 #include <server/campaign.qh>
  29 #include <server/cheats.qh>
  30 #include <server/client.qh>
  31 #include <server/command/common.qh>
  32 #include <server/command/getreplies.qh>
  33 #include <server/command/sv_cmd.qh>
  34 #include <server/command/vote.qh>
  35 #include <server/damage.qh>
  36 #include <server/gamelog.qh>
  37 #include <server/hook.qh>
  38 #include <server/intermission.qh>
  39 #include <server/ipban.qh>
  40 #include <server/main.qh>
  41 #include <server/mapvoting.qh>
  42 #include <server/mutators/_mod.qh>
  43 #include <server/race.qh>
  44 #include <server/scores.qh>
  45 #include <server/scores_rules.qh>
  46 #include <server/spawnpoints.qh>
  47 #include <server/teamplay.qh>
  48 #include <server/weapons/common.qh>
  49 #include <server/weapons/weaponstats.qh>
  50
  51 const float LATENCY_THINKRATE = 10;
  52 .float latency_sum;
  53 .float latency_cnt;
  54 .float latency_time;
  55 entity pingplreport;
  56 void PingPLReport_Think(entity this)
  57 {
  58         float delta;
  59         entity e;
  60
  61         delta = 3 / maxclients;
  62         if(delta < sys_frametime)
  63                 delta = 0;
  64         this.nextthink = time + delta;
  65
  66         e = edict_num(this.cnt + 1);
  67         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
  68         {
  69                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  70                 WriteByte(MSG_BROADCAST, this.cnt);
  71                 WriteShort(MSG_BROADCAST, bound(1, CS(e).ping, 65535));
  72                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
  73                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
  74
  75                 // record latency times for clients throughout the match so we can report it to playerstats
  76                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
  77                 {
  78                         CS(e).latency_sum += CS(e).ping;
  79                         CS(e).latency_cnt += 1;
  80                         CS(e).latency_time = time;
  81                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
  82                 }
  83         }
  84         else
  85         {
  86                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  87                 WriteByte(MSG_BROADCAST, this.cnt);
  88                 WriteShort(MSG_BROADCAST, 0);
  89                 WriteByte(MSG_BROADCAST, 0);
  90                 WriteByte(MSG_BROADCAST, 0);
  91         }
  92         this.cnt = (this.cnt + 1) % maxclients;
  93 }
  94 void PingPLReport_Spawn()
  95 {
  96         pingplreport = new_pure(pingplreport);
  97         setthink(pingplreport, PingPLReport_Think);
  98         pingplreport.nextthink = time;
  99 }
 100
 101 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
 102 float world_initialized;
 103
 104 void SetDefaultAlpha()
 105 {
 106         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
 107         {
 108                 default_player_alpha = autocvar_g_player_alpha;
 109                 if(default_player_alpha == 0)
 110                         default_player_alpha = 1;
 111                 default_weapon_alpha = default_player_alpha;
 112         }
 113 }
 114
 115 void GotoFirstMap(entity this)
 116 {
 117         float n;
 118         if(autocvar__sv_init)
 119         {
 120                 // cvar_set("_sv_init", "0");
 121                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 122                 // to this "init" map on a dedicated server will cause no permanent
 123                 // harm
 124                 if(autocvar_g_maplist_shuffle)
 125                         ShuffleMaplist();
 126                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 127                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 128
 129                 MapInfo_Enumerate();
 130                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 131
 132                 if(!DoNextMapOverride(1))
 133                         GotoNextMap(1);
 134
 135                 return;
 136         }
 137
 138         if(time < 5)
 139         {
 140                 this.nextthink = time;
 141         }
 142         else
 143         {
 144                 this.nextthink = time + 1;
 145                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
 146         }
 147 }
 148
 149 void cvar_changes_init()
 150 {
 151         float h;
 152         string k, v, d;
 153         float n, i, adding, pureadding;
 154
 155         strfree(cvar_changes);
 156         strfree(cvar_purechanges);
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = true;
 164         pureadding = true;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("halflifebsp");
 183                 BADCVAR("sv_mapformat_is_quake2");
 184                 BADCVAR("sv_mapformat_is_quake3");
 185                 BADPREFIX("sv_world");
 186
 187                 // client
 188                 BADPREFIX("chase_");
 189                 BADPREFIX("cl_");
 190                 BADPREFIX("con_");
 191                 BADPREFIX("scoreboard_");
 192                 BADPREFIX("g_campaign");
 193                 BADPREFIX("g_waypointsprite_");
 194                 BADPREFIX("gl_");
 195                 BADPREFIX("joy");
 196                 BADPREFIX("hud_");
 197                 BADPREFIX("m_");
 198                 BADPREFIX("menu_");
 199                 BADPREFIX("net_slist_");
 200                 BADPREFIX("r_");
 201                 BADPREFIX("sbar_");
 202                 BADPREFIX("scr_");
 203                 BADPREFIX("snd_");
 204                 BADPREFIX("show");
 205                 BADPREFIX("sensitivity");
 206                 BADPREFIX("userbind");
 207                 BADPREFIX("v_");
 208                 BADPREFIX("vid_");
 209                 BADPREFIX("crosshair");
 210                 BADCVAR("mod_q3bsp_lightmapmergepower");
 211                 BADCVAR("mod_q3bsp_nolightmaps");
 212                 BADCVAR("fov");
 213                 BADCVAR("mastervolume");
 214                 BADCVAR("volume");
 215                 BADCVAR("bgmvolume");
 216                 BADCVAR("in_pitch_min");
 217                 BADCVAR("in_pitch_max");
 218
 219                 // private
 220                 BADCVAR("developer");
 221                 BADCVAR("log_dest_udp");
 222                 BADCVAR("net_address");
 223                 BADCVAR("net_address_ipv6");
 224                 BADCVAR("port");
 225                 BADCVAR("savedgamecfg");
 226                 BADCVAR("serverconfig");
 227                 BADCVAR("sv_autoscreenshot");
 228                 BADCVAR("sv_heartbeatperiod");
 229                 BADCVAR("sv_vote_master_password");
 230                 BADCVAR("sys_colortranslation");
 231                 BADCVAR("sys_specialcharactertranslation");
 232                 BADCVAR("timeformat");
 233                 BADCVAR("timestamps");
 234                 BADCVAR("g_require_stats");
 235                 BADPREFIX("developer_");
 236                 BADPREFIX("g_ban_");
 237                 BADPREFIX("g_banned_list");
 238                 BADPREFIX("g_require_stats_");
 239                 BADPREFIX("g_chat_flood_");
 240                 BADPREFIX("g_ghost_items");
 241                 BADPREFIX("g_playerstats_");
 242                 BADPREFIX("g_voice_flood_");
 243                 BADPREFIX("log_file");
 244                 BADPREFIX("quit_");
 245                 BADPREFIX("rcon_");
 246                 BADPREFIX("sv_allowdownloads");
 247                 BADPREFIX("sv_autodemo");
 248                 BADPREFIX("sv_curl_");
 249                 BADPREFIX("sv_eventlog");
 250                 BADPREFIX("sv_logscores_");
 251                 BADPREFIX("sv_master");
 252                 BADPREFIX("sv_weaponstats_");
 253                 BADPREFIX("sv_waypointsprite_");
 254                 BADCVAR("rescan_pending");
 255
 256                 // these can contain player IDs, so better hide
 257                 BADPREFIX("g_forced_team_");
 258                 BADCVAR("sv_muteban_list");
 259                 BADCVAR("sv_voteban_list");
 260                 BADCVAR("sv_allow_customplayermodels_idlist");
 261                 BADCVAR("sv_allow_customplayermodels_speciallist");
 262
 263                 // mapinfo
 264                 BADCVAR("fraglimit");
 265                 BADCVAR("g_arena");
 266                 BADCVAR("g_assault");
 267                 BADCVAR("g_ca");
 268                 BADCVAR("g_ca_teams");
 269                 BADCVAR("g_conquest");
 270                 BADCVAR("g_conquest_teams");
 271                 BADCVAR("g_ctf");
 272                 BADCVAR("g_cts");
 273                 BADCVAR("g_dotc");
 274                 BADCVAR("g_dm");
 275                 BADCVAR("g_domination");
 276                 BADCVAR("g_domination_default_teams");
 277                 BADCVAR("g_duel");
 278                 BADCVAR("g_duel_not_dm_maps");
 279                 BADCVAR("g_freezetag");
 280                 BADCVAR("g_freezetag_teams");
 281                 BADCVAR("g_invasion_teams");
 282                 BADCVAR("g_invasion_type");
 283                 BADCVAR("g_jailbreak");
 284                 BADCVAR("g_jailbreak_teams");
 285                 BADCVAR("g_keepaway");
 286                 BADCVAR("g_keyhunt");
 287                 BADCVAR("g_keyhunt_teams");
 288                 BADCVAR("g_lms");
 289                 BADCVAR("g_nexball");
 290                 BADCVAR("g_onslaught");
 291                 BADCVAR("g_race");
 292                 BADCVAR("g_race_laps_limit");
 293                 BADCVAR("g_race_qualifying_timelimit");
 294                 BADCVAR("g_race_qualifying_timelimit_override");
 295                 BADCVAR("g_runematch");
 296                 BADCVAR("g_shootfromeye");
 297                 BADCVAR("g_snafu");
 298                 BADCVAR("g_survival");
 299                 BADCVAR("g_survival_not_dm_maps");
 300                 BADCVAR("g_tdm");
 301                 BADCVAR("g_tdm_on_dm_maps");
 302                 BADCVAR("g_tdm_teams");
 303                 BADCVAR("g_vip");
 304                 BADCVAR("leadlimit");
 305                 BADCVAR("nextmap");
 306                 BADCVAR("teamplay");
 307                 BADCVAR("timelimit");
 308                 BADCVAR("g_mapinfo_settemp_acl");
 309                 BADCVAR("g_mapinfo_ignore_warnings");
 310                 BADCVAR("g_maplist_ignore_sizes");
 311                 BADCVAR("g_maplist_sizes_count_bots");
 312
 313                 // long
 314                 BADCVAR("hostname");
 315                 BADCVAR("g_maplist");
 316                 BADCVAR("g_maplist_mostrecent");
 317                 BADCVAR("sv_motd");
 318
 319                 v = cvar_string(k);
 320                 d = cvar_defstring(k);
 321                 if(v == d)
 322                         continue;
 323
 324                 if(adding)
 325                 {
 326                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 327                         if(strlen(cvar_changes) > 16384)
 328                         {
 329                                 cvar_changes = "// too many settings have been changed to show them here\n";
 330                                 adding = 0;
 331                         }
 332                 }
 333
 334                 // now check if the changes are actually gameplay relevant
 335
 336                 // does nothing gameplay relevant
 337                 BADCVAR("captureleadlimit_override");
 338                 BADCVAR("condump_stripcolors");
 339                 BADCVAR("gameversion");
 340                 BADCVAR("fs_gamedir");
 341                 BADCVAR("g_allow_oldvortexbeam");
 342                 BADCVAR("g_balance_kill_delay");
 343                 BADCVAR("g_buffs_pickup_anyway");
 344                 BADCVAR("g_buffs_randomize");
 345                 BADCVAR("g_buffs_randomize_teamplay");
 346                 BADCVAR("g_campcheck_distance");
 347                 BADCVAR("g_chatsounds");
 348                 BADCVAR("g_ca_point_leadlimit");
 349                 BADCVAR("g_ca_point_limit");
 350                 BADCVAR("g_ctf_captimerecord_always");
 351                 BADCVAR("g_ctf_flag_glowtrails");
 352                 BADCVAR("g_ctf_dynamiclights");
 353                 BADCVAR("g_ctf_flag_pickup_verbosename");
 354                 BADPRESUFFIX("g_ctf_flag_", "_model");
 355                 BADPRESUFFIX("g_ctf_flag_", "_skin");
 356                 BADCVAR("g_domination_point_leadlimit");
 357                 BADCVAR("g_forced_respawn");
 358                 BADCVAR("g_freezetag_point_leadlimit");
 359                 BADCVAR("g_freezetag_point_limit");
 360                 BADCVAR("g_glowtrails");
 361                 BADCVAR("g_hats");
 362                 BADCVAR("g_casings");
 363                 BADCVAR("g_invasion_point_limit");
 364                 BADCVAR("g_jump_grunt");
 365                 BADCVAR("g_keepaway_ballcarrier_effects");
 366                 BADCVAR("g_keepawayball_effects");
 367                 BADCVAR("g_keyhunt_point_leadlimit");
 368                 BADCVAR("g_nexball_goalleadlimit");
 369                 BADCVAR("g_new_toys_autoreplace");
 370                 BADCVAR("g_new_toys_use_pickupsound");
 371                 BADCVAR("g_physics_predictall");
 372                 BADCVAR("g_piggyback");
 373                 BADCVAR("g_playerclip_collisions");
 374                 BADCVAR("g_spawn_alloweffects");
 375                 BADCVAR("g_tdm_point_leadlimit");
 376                 BADCVAR("g_tdm_point_limit");
 377                 BADCVAR("leadlimit_and_fraglimit");
 378                 BADCVAR("leadlimit_override");
 379                 BADCVAR("pausable");
 380                 BADCVAR("sv_announcer");
 381                 BADCVAR("sv_checkforpacketsduringsleep");
 382                 BADCVAR("sv_damagetext");
 383                 BADCVAR("sv_db_saveasdump");
 384                 BADCVAR("sv_intermission_cdtrack");
 385                 BADCVAR("sv_mapchange_delay");
 386                 BADCVAR("sv_minigames");
 387                 BADCVAR("sv_namechangetimer");
 388                 BADCVAR("sv_precacheplayermodels");
 389                 BADCVAR("sv_radio");
 390                 BADCVAR("sv_stepheight");
 391                 BADCVAR("sv_timeout");
 392                 BADCVAR("sv_weapons_modeloverride");
 393                 BADCVAR("w_prop_interval");
 394                 BADPREFIX("chat_");
 395                 BADPREFIX("crypto_");
 396                 BADPREFIX("gameversion_");
 397                 BADPREFIX("g_chat_");
 398                 BADPREFIX("g_ctf_captimerecord_");
 399                 BADPREFIX("g_hats_");
 400                 BADPREFIX("g_maplist_");
 401                 BADPREFIX("g_mod_");
 402                 BADPREFIX("g_respawn_");
 403                 BADPREFIX("net_");
 404                 BADPREFIX("notification_");
 405                 BADPREFIX("prvm_");
 406                 BADPREFIX("skill_");
 407                 BADPREFIX("sv_allow_");
 408                 BADPREFIX("sv_cullentities_");
 409                 BADPREFIX("sv_maxidle_");
 410                 BADPREFIX("sv_minigames_");
 411                 BADPREFIX("sv_radio_");
 412                 BADPREFIX("sv_timeout_");
 413                 BADPREFIX("sv_vote_");
 414                 BADPREFIX("timelimit_");
 415
 416                 // allowed changes to server admins (please sync this to server.cfg)
 417                 // vi commands:
 418                 //   :/"impure"/,$d
 419                 //   :g!,^\/\/[^ /],d
 420                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 421                 //   :%!sort
 422                 // yes, this does contain some redundant stuff, don't really care
 423                 BADPREFIX("bot_ai_");
 424                 BADCVAR("bot_config_file");
 425                 BADCVAR("bot_number");
 426                 BADCVAR("bot_prefix");
 427                 BADCVAR("bot_suffix");
 428                 BADCVAR("capturelimit_override");
 429                 BADCVAR("fraglimit_override");
 430                 BADCVAR("gametype");
 431                 BADCVAR("g_antilag");
 432                 BADCVAR("g_balance_teams");
 433                 BADCVAR("g_balance_teams_prevent_imbalance");
 434                 BADCVAR("g_balance_teams_scorefactor");
 435                 BADCVAR("g_ban_sync_trusted_servers");
 436                 BADCVAR("g_ban_sync_uri");
 437                 BADCVAR("g_buffs");
 438                 BADCVAR("g_ca_teams_override");
 439                 BADCVAR("g_ctf_fullbrightflags");
 440                 BADCVAR("g_ctf_ignore_frags");
 441                 BADCVAR("g_ctf_leaderboard");
 442                 BADCVAR("g_domination_point_limit");
 443                 BADCVAR("g_domination_teams_override");
 444                 BADCVAR("g_freezetag_teams_override");
 445                 BADCVAR("g_friendlyfire");
 446                 BADCVAR("g_fullbrightitems");
 447                 BADCVAR("g_fullbrightplayers");
 448                 BADCVAR("g_keyhunt_point_limit");
 449                 BADCVAR("g_keyhunt_teams_override");
 450                 BADCVAR("g_lms_lives_override");
 451                 BADCVAR("g_maplist");
 452                 BADCVAR("g_maxplayers");
 453                 BADCVAR("g_mirrordamage");
 454                 BADCVAR("g_nexball_goallimit");
 455                 BADCVAR("g_norecoil");
 456                 BADCVAR("g_physics_clientselect");
 457                 BADCVAR("g_pinata");
 458                 BADCVAR("g_powerups");
 459                 BADCVAR("g_player_brightness");
 460                 BADCVAR("g_rocket_flying");
 461                 BADCVAR("g_rocket_flying_disabledelays");
 462                 BADCVAR("g_spawnshieldtime");
 463                 BADCVAR("g_start_delay");
 464                 BADCVAR("g_superspectate");
 465                 BADCVAR("g_tdm_teams_override");
 466                 BADCVAR("g_warmup");
 467                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 468                 BADCVAR("hostname");
 469                 BADCVAR("log_file");
 470                 BADCVAR("maxplayers");
 471                 BADCVAR("minplayers");
 472                 BADCVAR("minplayers_per_team");
 473                 BADCVAR("net_address");
 474                 BADCVAR("port");
 475                 BADCVAR("rcon_password");
 476                 BADCVAR("rcon_restricted_commands");
 477                 BADCVAR("rcon_restricted_password");
 478                 BADCVAR("skill");
 479                 BADCVAR("sv_adminnick");
 480                 BADCVAR("sv_autoscreenshot");
 481                 BADCVAR("sv_autotaunt");
 482                 BADCVAR("sv_curl_defaulturl");
 483                 BADCVAR("sv_defaultcharacter");
 484                 BADCVAR("sv_defaultcharacterskin");
 485                 BADCVAR("sv_defaultplayercolors");
 486                 BADCVAR("sv_defaultplayermodel");
 487                 BADCVAR("sv_defaultplayerskin");
 488                 BADCVAR("sv_maxidle");
 489                 BADCVAR("sv_maxrate");
 490                 BADCVAR("sv_motd");
 491                 BADCVAR("sv_public");
 492                 BADCVAR("sv_ready_restart");
 493                 BADCVAR("sv_status_privacy");
 494                 BADCVAR("sv_taunt");
 495                 BADCVAR("sv_vote_call");
 496                 BADCVAR("sv_vote_commands");
 497                 BADCVAR("sv_vote_majority_factor");
 498                 BADCVAR("sv_vote_master");
 499                 BADCVAR("sv_vote_master_commands");
 500                 BADCVAR("sv_vote_master_password");
 501                 BADCVAR("sv_vote_simple_majority_factor");
 502                 BADCVAR("teamplay_mode");
 503                 BADCVAR("timelimit_override");
 504                 BADPREFIX("g_warmup_");
 505                 BADPREFIX("sv_info_");
 506                 BADPREFIX("sv_ready_restart_");
 507
 508                 // mutators that announce themselves properly to the server browser
 509                 BADCVAR("g_instagib");
 510                 BADCVAR("g_new_toys");
 511                 BADCVAR("g_nix");
 512                 BADCVAR("g_grappling_hook");
 513                 BADCVAR("g_jetpack");
 514
 515                 // temporary for testing
 516                 // TODO remove before 0.8.3 release
 517                 BADCVAR("g_ca_weaponarena");
 518                 BADCVAR("g_freezetag_weaponarena");
 519                 BADCVAR("g_lms_weaponarena");
 520                 BADCVAR("g_ctf_stalemate_time");
 521
 522                 if(cvar_string("g_mod_balance") == "Testing")
 523                 {
 524                         // (temporary) while using the Testing balance, any weapon balance cvars are allowed to be changed
 525                         BADPREFIX("g_balance_");
 526                 }
 527
 528 #undef BADPRESUFFIX
 529 #undef BADPREFIX
 530 #undef BADCVAR
 531
 532                 if(pureadding)
 533                 {
 534                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 535                         if(strlen(cvar_purechanges) > 16384)
 536                         {
 537                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 538                                 pureadding = 0;
 539                         }
 540                 }
 541                 ++cvar_purechanges_count;
 542                 // WARNING: this variable is used for the server list
 543                 // NEVER dare to skip this code!
 544                 // Hacks to intentionally appearing as "pure server" even though you DO have
 545                 // modified settings may be punished by removal from the server list.
 546                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 547                 // though.
 548         }
 549         buf_del(h);
 550         if(cvar_changes == "")
 551                 cvar_changes = "// this server runs at default server settings\n";
 552         else
 553                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 554         cvar_changes = strzone(cvar_changes);
 555         if(cvar_purechanges == "")
 556                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 557         else
 558                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 559         cvar_purechanges = strzone(cvar_purechanges);
 560 }
 561
 562 entity randomseed;
 563 bool RandomSeed_Send(entity this, entity to, int sf)
 564 {
 565         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 566         WriteShort(MSG_ENTITY, this.cnt);
 567         return true;
 568 }
 569 void RandomSeed_Think(entity this)
 570 {
 571         this.cnt = bound(0, floor(random() * 65536), 65535);
 572         this.nextthink = time + 5;
 573
 574         this.SendFlags |= 1;
 575 }
 576 void RandomSeed_Spawn()
 577 {
 578         randomseed = new_pure(randomseed);
 579         setthink(randomseed, RandomSeed_Think);
 580         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 581
 582         getthink(randomseed)(randomseed); // sets random seed and nextthink
 583 }
 584
 585 spawnfunc(__init_dedicated_server)
 586 {
 587         // handler for _init/_init map (only for dedicated server initialization)
 588
 589         world_initialized = -1; // don't complain
 590
 591         delete_fn = remove_unsafely;
 592
 593         entity e = new(GotoFirstMap);
 594         setthink(e, GotoFirstMap);
 595         e.nextthink = time; // this is usually 1 at this point
 596
 597         e = new(info_player_deathmatch);  // safeguard against player joining
 598
 599     // assign reflectively to avoid "assignment to world" warning
 600     for (int i = 0, n = numentityfields(); i < n; ++i) {
 601         string k = entityfieldname(i);
 602         if (k == "classname") {
 603             // safeguard against various stuff ;)
 604             putentityfieldstring(i, this, "worldspawn");
 605             break;
 606         }
 607     }
 608
 609         // needs to be done so early because of the constants they create
 610         static_init();
 611         static_init_late();
 612         static_init_precache();
 613
 614         IL_PUSH(g_spawnpoints, e); // just incase
 615
 616         MapInfo_Enumerate();
 617         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 618 }
 619
 620 void __init_dedicated_server_shutdown() {
 621         MapInfo_Shutdown();
 622 }
 623
 624 STATIC_INIT_EARLY(maxclients)
 625 {
 626         maxclients = 0;
 627         for (entity head = nextent(NULL); head; head = nextent(head)) {
 628                 ++maxclients;
 629         }
 630 }
 631
 632 void GameplayMode_DelayedInit(entity this)
 633 {
 634         if(!scores_initialized)
 635                 ScoreRules_generic();
 636 }
 637
 638 void InitGameplayMode()
 639 {
 640         VoteReset();
 641
 642         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 643         get_mi_min_max(1);
 644         // assign reflectively to avoid "assignment to world" warning
 645         int done = 0; for (int i = 0, n = numentityfields(); i < n; ++i) {
 646             string k = entityfieldname(i); vector v = (k == "mins") ? mi_min : (k == "maxs") ? mi_max : '0 0 0';
 647             if (v) {
 648             putentityfieldstring(i, world, sprintf("%v", v));
 649             if (++done == 2) break;
 650         }
 651         }
 652         // currently, NetRadiant's limit is 131072 qu for each side
 653         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
 654         // set the distance according to map size but don't go over the limit to avoid issues with float precision
 655         // in case somebody makes extremely large maps
 656         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
 657
 658         MapInfo_LoadMapSettings(mapname);
 659         GameRules_teams(false);
 660
 661         if (!cvar_value_issafe(world.fog))
 662         {
 663                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored");
 664                 world.fog = string_null;
 665         }
 666         if(MapInfo_Map_fog != "")
 667         {
 668                 if(MapInfo_Map_fog == "none")
 669                         world.fog = string_null;
 670                 else
 671                         world.fog = strzone(MapInfo_Map_fog);
 672         }
 673         clientstuff = strzone(MapInfo_Map_clientstuff);
 674
 675         MapInfo_ClearTemps();
 676
 677         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 678
 679         cache_mutatormsg = strzone("");
 680         cache_lastmutatormsg = strzone("");
 681
 682         InitializeEntity(NULL, GameplayMode_DelayedInit, INITPRIO_GAMETYPE_FALLBACK);
 683 }
 684
 685 bool world_already_spawned;
 686 spawnfunc(worldspawn)
 687 {
 688         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 689
 690         bool wantrestart = false;
 691         {
 692                 if (!server_is_dedicated)
 693                 {
 694                         // force unloading of server pk3 files when starting a listen server
 695                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 696                         // restore csqc_progname too
 697                         string expect = "csprogs.dat";
 698                         wantrestart = cvar_string("csqc_progname") != expect;
 699                         cvar_set("csqc_progname", expect);
 700                 }
 701                 else
 702                 {
 703                         // Try to use versioned csprogs from pk3
 704                         // Only ever use versioned csprogs.dat files on dedicated servers;
 705                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 706                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 707                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 708                         string select = "csprogs.dat";
 709                         if (fexists(pk3csprogs)) select = pk3csprogs;
 710                         if (cvar_string("csqc_progname") != select)
 711                         {
 712                                 cvar_set("csqc_progname", select);
 713                                 wantrestart = true;
 714                         }
 715                         // Check for updates on startup
 716                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 717                         int sentinel = fopen("progs.txt", FILE_READ);
 718                         if (sentinel >= 0)
 719                         {
 720                                 string switchversion = fgets(sentinel);
 721                                 fclose(sentinel);
 722                                 if (switchversion != "" && switchversion != WATERMARK)
 723                                 {
 724                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
 725                                         // if it doesn't exist, assume either:
 726                                         //   a) the current program was overwritten
 727                                         //   b) this is a client only update
 728                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 729                                         if (fexists(newprogs))
 730                                         {
 731                                                 cvar_set("sv_progs", newprogs);
 732                                                 wantrestart = true;
 733                                         }
 734                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 735                                         if (fexists(newcsprogs))
 736                                         {
 737                                                 cvar_set("csqc_progname", newcsprogs);
 738                                                 wantrestart = true;
 739                                         }
 740                                 }
 741                         }
 742                 }
 743                 if (wantrestart)
 744                 {
 745                         LOG_INFO("Restart requested");
 746                         changelevel(mapname);
 747                         // let initialization continue, shutdown depends on it
 748                 }
 749         }
 750
 751         if(world_already_spawned)
 752                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 753         world_already_spawned = true;
 754
 755         delete_fn = remove_safely; // during spawning, watch what you remove!
 756
 757         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 758
 759         // needs to be done so early because of the constants they create
 760         static_init();
 761
 762         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 763
 764         TemporaryDB = db_create();
 765
 766         // 0 normal
 767         lightstyle(0, "m");
 768
 769         // 1 FLICKER (first variety)
 770         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 771
 772         // 2 SLOW STRONG PULSE
 773         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 774
 775         // 3 CANDLE (first variety)
 776         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 777
 778         // 4 FAST STROBE
 779         lightstyle(4, "mamamamamama");
 780
 781         // 5 GENTLE PULSE 1
 782         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 783
 784         // 6 FLICKER (second variety)
 785         lightstyle(6, "nmonqnmomnmomomno");
 786
 787         // 7 CANDLE (second variety)
 788         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 789
 790         // 8 CANDLE (third variety)
 791         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 792
 793         // 9 SLOW STROBE (fourth variety)
 794         lightstyle(9, "aaaaaaaazzzzzzzz");
 795
 796         // 10 FLUORESCENT FLICKER
 797         lightstyle(10, "mmamammmmammamamaaamammma");
 798
 799         // 11 SLOW PULSE NOT FADE TO BLACK
 800         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 801
 802         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 803
 804         // 63 testing
 805         lightstyle(63, "a");
 806
 807         if(autocvar_g_campaign)
 808                 CampaignPreInit();
 809
 810         Map_MarkAsRecent(mapname);
 811
 812         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 813
 814         InitGameplayMode();
 815         static_init_late();
 816         static_init_precache();
 817         readlevelcvars();
 818
 819         GameRules_limit_fallbacks();
 820
 821         if(warmup_limit == 0)
 822                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 823
 824         player_count = 0;
 825         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 826         if(bot_waypoints_for_items == 1)
 827                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 828                         bot_waypoints_for_items = 0;
 829
 830         WaypointSprite_Init();
 831
 832         GameLogInit(); // prepare everything
 833         // NOTE for matchid:
 834         // changing the logic generating it is okay. But:
 835         // it HAS to stay <= 64 chars
 836         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 837         if(autocvar_sv_eventlog)
 838         {
 839                 string s = sprintf("%s.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 840                 matchid = strzone(s);
 841
 842                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 843                 s = ":gameinfo:mutators:LIST";
 844
 845                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 846                 s = M_ARGV(0, string);
 847
 848                 // initialiation stuff, not good in the mutator system
 849                 if(!autocvar_g_use_ammunition)
 850                         s = strcat(s, ":no_use_ammunition");
 851
 852                 // initialiation stuff, not good in the mutator system
 853                 if(autocvar_g_pickup_items == 0)
 854                         s = strcat(s, ":no_pickup_items");
 855                 if(autocvar_g_pickup_items > 0)
 856                         s = strcat(s, ":pickup_items");
 857
 858                 // initialiation stuff, not good in the mutator system
 859                 if(autocvar_g_weaponarena != "0")
 860                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 861
 862                 // TODO to mutator system
 863                 if(autocvar_g_norecoil)
 864                         s = strcat(s, ":norecoil");
 865
 866                 // TODO to mutator system
 867                 if(autocvar_g_powerups == 0)
 868                         s = strcat(s, ":no_powerups");
 869                 if(autocvar_g_powerups > 0)
 870                         s = strcat(s, ":powerups");
 871
 872                 GameLogEcho(s);
 873                 GameLogEcho(":gameinfo:end");
 874         }
 875         else
 876                 matchid = strzone(ftos(random()));
 877
 878         cvar_set("nextmap", "");
 879
 880         SetDefaultAlpha();
 881
 882         if(autocvar_g_campaign)
 883                 CampaignPostInit();
 884
 885         Ban_LoadBans();
 886
 887         MapInfo_Enumerate();
 888         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 889
 890         if(fexists(_MapInfo_FindArenaFile(mapname, ".arena")))
 891                 cvar_settemp("sv_q3acompat_machineshotgunswap", "1");
 892
 893         if(fexists(_MapInfo_FindArenaFile(mapname, ".defi")))
 894                 cvar_settemp("sv_q3defragcompat", "1");
 895
 896         // quake 3 music support
 897         if(world.music || world.noise)
 898         {
 899                 // prefer .music over .noise
 900                 string chosen_music;
 901                 string oldstuff;
 902                 if(world.music)
 903                         chosen_music = world.music;
 904                 else
 905                         chosen_music = world.noise;
 906                 if(
 907                         substring(chosen_music, strlen(chosen_music) - 4, 4) == ".wav"
 908                         ||
 909                         substring(chosen_music, strlen(chosen_music) - 4, 4) == ".ogg"
 910                 )
 911                         oldstuff = strcat(clientstuff, "cd loop \"", chosen_music, "\"\n");
 912                 else
 913                         oldstuff = strcat(clientstuff, "cd loop \"", chosen_music, "\"\n");
 914
 915                 strcpy(clientstuff, oldstuff);
 916         }
 917
 918         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 919         {
 920                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 921                 if(fd != -1)
 922                 {
 923                         string s;
 924                         while((s = fgets(fd)))
 925                         {
 926                                 int l = tokenize_console(s);
 927                                 if(l < 2)
 928                                         continue;
 929                                 if(argv(0) == "cd")
 930                                 {
 931                                         string trackname = argv(2);
 932                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
 933                                         LOG_INFO("  cdtrack ", trackname);
 934                                         if (cvar_value_issafe(trackname))
 935                                         {
 936                                                 string newstuff = strcat(clientstuff, "cd loop \"", trackname, "\"\n");
 937                                                 strcpy(clientstuff, newstuff);
 938                                         }
 939                                 }
 940                                 else if(argv(0) == "fog")
 941                                 {
 942                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
 943                                         LOG_INFO("  \"fog\" \"", s, "\"");
 944                                 }
 945                                 else if(argv(0) == "set")
 946                                 {
 947                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 948                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
 949                                 }
 950                                 else if(argv(0) != "//")
 951                                 {
 952                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 953                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
 954                                 }
 955                         }
 956                         fclose(fd);
 957                 }
 958         }
 959
 960         WeaponStats_Init();
 961
 962         Nagger_Init();
 963
 964         // set up information replies for clients and server to use
 965         maplist_reply = strzone(getmaplist());
 966         lsmaps_reply = strzone(getlsmaps());
 967         monsterlist_reply = strzone(getmonsterlist());
 968         for(int i = 0; i < 10; ++i)
 969         {
 970                 string s = getrecords(i);
 971                 if (s)
 972                         records_reply[i] = strzone(s);
 973         }
 974         ladder_reply = strzone(getladder());
 975         rankings_reply = strzone(getrankings());
 976
 977         // begin other init
 978         ClientInit_Spawn();
 979         RandomSeed_Spawn();
 980         PingPLReport_Spawn();
 981
 982         CheatInit();
 983
 984         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 985
 986         // fill sv_curl_serverpackages from .serverpackage files
 987         if (autocvar_sv_curl_serverpackages_auto)
 988         {
 989                 string s = "csprogs-" WATERMARK ".dat";
 990                 // remove automatically managed files from the list to prevent duplicates
 991                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 992                 {
 993                         string pkg = argv(i);
 994                         if (startsWith(pkg, "csprogs-")) continue;
 995                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 996                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 997                         s = cons(s, pkg);
 998                 }
 999                 // add automatically managed files to the list
1000                 #define X(match) MACRO_BEGIN \
1001                         int fd = search_begin(match, true, false); \
1002                         if (fd >= 0) \
1003                         { \
1004                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
1005                                 { \
1006                                         s = cons(s, search_getfilename(fd, i)); \
1007                                 } \
1008                                 search_end(fd); \
1009                         } \
1010                 MACRO_END
1011                 X("*-serverpackage.txt");
1012                 X("*.serverpackage");
1013                 #undef X
1014                 cvar_set("sv_curl_serverpackages", s);
1015         }
1016
1017         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
1018         modname = "Xonotic";
1019         // physics/balance/config changes that count as mod
1020         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
1021                 modname = cvar_string("g_mod_physics");
1022         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance") && cvar_string("g_mod_balance") != "Testing")
1023                 modname = cvar_string("g_mod_balance");
1024         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
1025                 modname = cvar_string("g_mod_config");
1026         // extra mutators that deserve to count as mod
1027         MUTATOR_CALLHOOK(SetModname, modname);
1028         modname = M_ARGV(0, string);
1029
1030         // save it for later
1031         modname = strzone(modname);
1032
1033         WinningConditionHelper(this); // set worldstatus
1034
1035         world_initialized = 1;
1036         __spawnfunc_spawn_all();
1037 }
1038
1039 spawnfunc(light)
1040 {
1041         //makestatic (this); // Who the f___ did that?
1042         delete(this);
1043 }
1044
1045 bool MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, int attempts, float maxaboveground, float minviewdistance)
1046 {
1047     float m = e.dphitcontentsmask;
1048     e.dphitcontentsmask = goodcontents | badcontents;
1049
1050     vector org = boundmin;
1051     vector delta = boundmax - boundmin;
1052
1053     vector start, end;
1054     start = end = org;
1055     int j; // used after the loop
1056     for(j = 0; j < attempts; ++j)
1057     {
1058         start.x = org.x + random() * delta.x;
1059         start.y = org.y + random() * delta.y;
1060         start.z = org.z + random() * delta.z;
1061
1062         // rule 1: start inside world bounds, and outside
1063         // solid, and don't start from somewhere where you can
1064         // fall down to evil
1065         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1066         if (trace_fraction >= 1)
1067             continue;
1068         if (trace_startsolid)
1069             continue;
1070         if (trace_dphitcontents & badcontents)
1071             continue;
1072         if (trace_dphitq3surfaceflags & badsurfaceflags)
1073             continue;
1074
1075         // rule 2: if we are too high, lower the point
1076         if (trace_fraction * delta.z > maxaboveground)
1077             start = trace_endpos + '0 0 1' * maxaboveground;
1078         vector enddown = trace_endpos;
1079
1080         // rule 3: make sure we aren't outside the map. This only works
1081         // for somewhat well formed maps. A good rule of thumb is that
1082         // the map should have a convex outside hull.
1083         // these can be traceLINES as we already verified the starting box
1084         vector mstart = start + 0.5 * (e.mins + e.maxs);
1085         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1086         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1087             continue;
1088         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1089         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1090             continue;
1091         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1092         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1093             continue;
1094         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1095         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1096             continue;
1097         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1098         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1099             continue;
1100
1101                 // rule 4: we must "see" some spawnpoint or item
1102             entity sp = NULL;
1103             IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1104             {
1105                 if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1106                 {
1107                         sp = it;
1108                         break;
1109                 }
1110             });
1111                 if(!sp)
1112                 {
1113                         int items_checked = 0;
1114                         IL_EACH(g_items, checkpvs(mstart, it),
1115                         {
1116                                 if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1117                                 {
1118                                         sp = it;
1119                                         break;
1120                                 }
1121
1122                                 ++items_checked;
1123                                 if(items_checked >= attempts)
1124                                         break; // sanity
1125                         });
1126
1127                         if(!sp)
1128                                 continue;
1129                 }
1130
1131         // find a random vector to "look at"
1132         end.x = org.x + random() * delta.x;
1133         end.y = org.y + random() * delta.y;
1134         end.z = org.z + random() * delta.z;
1135         end = start + normalize(end - start) * vlen(delta);
1136
1137         // rule 4: start TO end must not be too short
1138         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1139         if(trace_startsolid)
1140             continue;
1141         if(trace_fraction < minviewdistance / vlen(delta))
1142             continue;
1143
1144         // rule 5: don't want to look at sky
1145         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1146             continue;
1147
1148         // rule 6: we must not end up in trigger_hurt
1149         if(tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1150             continue;
1151
1152         break;
1153     }
1154
1155     e.dphitcontentsmask = m;
1156
1157     if(j < attempts)
1158     {
1159         setorigin(e, start);
1160         e.angles = vectoangles(end - start);
1161         LOG_DEBUG("Needed ", ftos(j + 1), " attempts");
1162         return true;
1163     }
1164     return false;
1165 }
1166
1167 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1168 {
1169         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1170 }
1171
1172 /*
1173 ===============================================================================
1174
1175 RULES
1176
1177 ===============================================================================
1178 */
1179
1180 void DumpStats(float final)
1181 {
1182         float file;
1183         string s;
1184         float to_console;
1185         float to_eventlog;
1186         float to_file;
1187         float i;
1188
1189         to_console = autocvar_sv_logscores_console;
1190         to_eventlog = autocvar_sv_eventlog;
1191         to_file = autocvar_sv_logscores_file;
1192
1193         if(!final)
1194         {
1195                 to_console = true; // always print printstats replies
1196                 to_eventlog = false; // but never print them to the event log
1197         }
1198
1199         if(to_eventlog)
1200                 if(autocvar_sv_eventlog_console)
1201                         to_console = false; // otherwise we get the output twice
1202
1203         if(final)
1204                 s = ":scores:";
1205         else
1206                 s = ":status:";
1207         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1208
1209         if(to_console)
1210                 LOG_INFO(s);
1211         if(to_eventlog)
1212                 GameLogEcho(s);
1213
1214         file = -1;
1215         if(to_file)
1216         {
1217                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1218                 if(file == -1)
1219                         to_file = false;
1220                 else
1221                         fputs(file, strcat(s, "\n"));
1222         }
1223
1224         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1225         if(to_console)
1226                 LOG_INFO(s);
1227         if(to_eventlog)
1228                 GameLogEcho(s);
1229         if(to_file)
1230                 fputs(file, strcat(s, "\n"));
1231
1232         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1233                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1234                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1235                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1236                         s = strcat(s, ftos(it.team), ":");
1237                 else
1238                         s = strcat(s, "spectator:");
1239
1240                 if(to_console)
1241                         LOG_INFO(s, playername(it.netname, it.team, false));
1242                 if(to_eventlog)
1243                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it.netname, it.team, false)));
1244                 if(to_file)
1245                         fputs(file, strcat(s, playername(it.netname, it.team, false), "\n"));
1246         });
1247
1248         if(teamplay)
1249         {
1250                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1251                 if(to_console)
1252                         LOG_INFO(s);
1253                 if(to_eventlog)
1254                         GameLogEcho(s);
1255                 if(to_file)
1256                         fputs(file, strcat(s, "\n"));
1257
1258                 for(i = 1; i < 16; ++i)
1259                 {
1260                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1261                         s = strcat(s, ":", ftos(i));
1262                         if(to_console)
1263                                 LOG_INFO(s);
1264                         if(to_eventlog)
1265                                 GameLogEcho(s);
1266                         if(to_file)
1267                                 fputs(file, strcat(s, "\n"));
1268                 }
1269         }
1270
1271         if(to_console)
1272                 LOG_INFO(":end");
1273         if(to_eventlog)
1274                 GameLogEcho(":end");
1275         if(to_file)
1276         {
1277                 fputs(file, ":end\n");
1278                 fclose(file);
1279         }
1280 }
1281
1282 /*
1283 go to the next level for deathmatch
1284 only called if a time or frag limit has expired
1285 */
1286 void NextLevel()
1287 {
1288         game_stopped = true;
1289         intermission_running = 1; // game over
1290
1291         // enforce a wait time before allowing changelevel
1292         if(player_count > 0)
1293                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1294         else
1295                 intermission_exittime = -1;
1296
1297         /*
1298         WriteByte (MSG_ALL, SVC_CDTRACK);
1299         WriteByte (MSG_ALL, 3);
1300         WriteByte (MSG_ALL, 3);
1301         // done in FixIntermission
1302         */
1303
1304         //pos = FindIntermission ();
1305
1306         VoteReset();
1307
1308         DumpStats(true);
1309
1310         // send statistics
1311         PlayerStats_GameReport(true);
1312         WeaponStats_Shutdown();
1313
1314         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1315
1316         if(autocvar_sv_eventlog)
1317                 GameLogEcho(":gameover");
1318
1319         GameLogClose();
1320
1321         FOREACH_CLIENT(IS_PLAYER(it), {
1322                 FixIntermissionClient(it);
1323                 if(it.winning)
1324                         bprint(playername(it.netname, it.team, false), " ^7wins.\n");
1325         });
1326
1327         target_music_kill();
1328
1329         if(autocvar_g_campaign)
1330                 CampaignPreIntermission();
1331
1332         MUTATOR_CALLHOOK(MatchEnd);
1333
1334         localcmd("\nsv_hook_gameend\n");
1335 }
1336
1337
1338 float InitiateSuddenDeath()
1339 {
1340         // Check first whether normal overtimes could be added before initiating suddendeath mode
1341         // - for this timelimit_overtime needs to be >0 of course
1342         // - also check the winning condition calculated in the previous frame and only add normal overtime
1343         //   again, if at the point at which timelimit would be extended again, still no winner was found
1344         if (!autocvar_g_campaign && checkrules_overtimesadded >= 0
1345                 && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0)
1346                 && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1347         {
1348                 return 1; // need to call InitiateOvertime later
1349         }
1350         else
1351         {
1352                 if(!checkrules_suddendeathend)
1353                 {
1354                         if(autocvar_g_campaign)
1355                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1356                         else
1357                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1358                         if(g_race && !g_race_qualifying)
1359                                 race_StartCompleting();
1360                 }
1361                 return 0;
1362         }
1363 }
1364
1365 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1366 {
1367         ++checkrules_overtimesadded;
1368         //add one more overtime by simply extending the timelimit
1369         cvar_set("timelimit", ftos(autocvar_timelimit + autocvar_timelimit_overtime));
1370         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1371 }
1372
1373 float GetWinningCode(float fraglimitreached, float equality)
1374 {
1375         if(autocvar_g_campaign == 1)
1376         {
1377                 if(fraglimitreached)
1378                         return WINNING_YES;
1379                 else
1380                         return WINNING_NO;
1381         }
1382         else
1383         {
1384                 if(equality)
1385                 {
1386                         if(fraglimitreached)
1387                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1388                         else
1389                                 return WINNING_NEVER;
1390                 }
1391                 else
1392                 {
1393                         if(fraglimitreached)
1394                                 return WINNING_YES;
1395                         else
1396                                 return WINNING_NO;
1397                 }
1398         }
1399 }
1400
1401 // set the .winning flag for exactly those players with a given field value
1402 void SetWinners(.float field, float value)
1403 {
1404         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = (it.(field) == value); });
1405 }
1406
1407 // set the .winning flag for those players with a given field value
1408 void AddWinners(.float field, float value)
1409 {
1410         FOREACH_CLIENT(IS_PLAYER(it), {
1411                 if(it.(field) == value)
1412                         it.winning = 1;
1413         });
1414 }
1415
1416 // clear the .winning flags
1417 void ClearWinners()
1418 {
1419         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = 0; });
1420 }
1421
1422 int fragsleft_last;
1423 float WinningCondition_Scores(float limit, float leadlimit)
1424 {
1425         // TODO make everything use THIS winning condition (except LMS)
1426         WinningConditionHelper(NULL);
1427
1428         if(teamplay)
1429         {
1430                 for (int i = 1; i < 5; ++i)
1431                 {
1432                         Team_SetTeamScore(Team_GetTeamFromIndex(i),
1433                                 TeamScore_GetCompareValue(Team_IndexToTeam(i)));
1434                 }
1435         }
1436
1437         ClearWinners();
1438         if(WinningConditionHelper_winner)
1439                 WinningConditionHelper_winner.winning = 1;
1440         if(WinningConditionHelper_winnerteam >= 0)
1441                 SetWinners(team, WinningConditionHelper_winnerteam);
1442
1443         if(WinningConditionHelper_lowerisbetter)
1444         {
1445                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1446                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1447                 limit = -limit;
1448         }
1449
1450         if(WinningConditionHelper_zeroisworst)
1451                 leadlimit = 0; // not supported in this mode
1452
1453         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1454         {
1455                 float fragsleft;
1456                 if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1457                 {
1458                         fragsleft = 1;
1459                 }
1460                 else
1461                 {
1462                         fragsleft = FLOAT_MAX;
1463                         float leadingfragsleft = FLOAT_MAX;
1464                         if (limit)
1465                                 fragsleft = limit - WinningConditionHelper_topscore;
1466                         if (leadlimit)
1467                                 leadingfragsleft = WinningConditionHelper_secondscore + leadlimit - WinningConditionHelper_topscore;
1468
1469                         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1470                                 fragsleft = max(fragsleft, leadingfragsleft);
1471                         else
1472                                 fragsleft = min(fragsleft, leadingfragsleft);
1473                 }
1474
1475                 if (fragsleft_last != fragsleft) // do not announce same remaining frags multiple times
1476                 {
1477                         if (fragsleft == 1)
1478                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1479                         else if (fragsleft == 2)
1480                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1481                         else if (fragsleft == 3)
1482                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1483
1484                         fragsleft_last = fragsleft;
1485                 }
1486         }
1487
1488         bool fraglimit_reached = (limit && WinningConditionHelper_topscore >= limit);
1489         bool leadlimit_reached = (leadlimit && WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1490
1491         bool limit_reached;
1492         // only respect leadlimit_and_fraglimit when both limits are set or the game will never end
1493         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1494                 limit_reached = (fraglimit_reached && leadlimit_reached);
1495         else
1496                 limit_reached = (fraglimit_reached || leadlimit_reached);
1497
1498         return GetWinningCode(
1499                 WinningConditionHelper_topscore && limit_reached,
1500                 WinningConditionHelper_equality
1501         );
1502 }
1503
1504 float WinningCondition_RanOutOfSpawns()
1505 {
1506         if(have_team_spawns <= 0)
1507                 return WINNING_NO;
1508
1509         if(!autocvar_g_spawn_useallspawns)
1510                 return WINNING_NO;
1511
1512         if(!some_spawn_has_been_used)
1513                 return WINNING_NO;
1514
1515         for (int i = 1; i < 5; ++i)
1516         {
1517                 Team_SetTeamScore(Team_GetTeamFromIndex(i), 0);
1518         }
1519
1520         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
1521         {
1522                 if (Team_IsValidTeam(it.team))
1523                 {
1524                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1525                 }
1526         });
1527
1528         IL_EACH(g_spawnpoints, true,
1529         {
1530                 if (Team_IsValidTeam(it.team))
1531                 {
1532                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1533                 }
1534         });
1535
1536         ClearWinners();
1537         float team1_score = Team_GetTeamScore(Team_GetTeamFromIndex(1));
1538         float team2_score = Team_GetTeamScore(Team_GetTeamFromIndex(2));
1539         float team3_score = Team_GetTeamScore(Team_GetTeamFromIndex(3));
1540         float team4_score = Team_GetTeamScore(Team_GetTeamFromIndex(4));
1541         if(team1_score + team2_score + team3_score + team4_score == 0)
1542         {
1543                 checkrules_equality = true;
1544                 return WINNING_YES;
1545         }
1546         else if(team1_score + team2_score + team3_score + team4_score == 1)
1547         {
1548                 float t, i;
1549                 if(team1_score)
1550                         t = 1;
1551                 else if(team2_score)
1552                         t = 2;
1553                 else if(team3_score)
1554                         t = 3;
1555                 else // if(team4_score)
1556                         t = 4;
1557                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
1558                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1559                 {
1560                         for (int j = 1; j <= NUM_TEAMS; ++j)
1561                         {
1562                                 if (t == j)
1563                                 {
1564                                         continue;
1565                                 }
1566                                 if (!TeamBalance_IsTeamAllowed(balance, j))
1567                                 {
1568                                         continue;
1569                                 }
1570                                 TeamScore_AddToTeam(Team_IndexToTeam(j), i, -1000);
1571                         }
1572                 }
1573
1574                 AddWinners(team, t);
1575                 return WINNING_YES;
1576         }
1577         else
1578                 return WINNING_NO;
1579 }
1580
1581 /*
1582 ============
1583 CheckRules_World
1584
1585 Exit deathmatch games upon conditions
1586 ============
1587 */
1588 void CheckRules_World()
1589 {
1590         VoteThink();
1591         MapVote_Think();
1592
1593         SetDefaultAlpha();
1594
1595         if (intermission_running) // someone else quit the game already
1596         {
1597                 if(player_count == 0) // Nobody there? Then let's go to the next map
1598                         MapVote_Start();
1599                         // this will actually check the player count in the next frame
1600                         // again, but this shouldn't hurt
1601                 return;
1602         }
1603
1604         float timelimit = autocvar_timelimit * 60;
1605         float fraglimit = autocvar_fraglimit;
1606         float leadlimit = autocvar_leadlimit;
1607         if (leadlimit < 0) leadlimit = 0;
1608
1609         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1610         {
1611                 if(timelimit > 0)
1612                         timelimit = 0; // timelimit is not made for warmup
1613                 if(fraglimit > 0)
1614                         fraglimit = 0; // no fraglimit for now
1615                 leadlimit = 0; // no leadlimit for now
1616         }
1617
1618         if(timelimit > 0)
1619         {
1620                 timelimit += game_starttime;
1621         }
1622         else if (timelimit < 0)
1623         {
1624                 // endmatch
1625                 NextLevel();
1626                 return;
1627         }
1628
1629         float wantovertime;
1630         wantovertime = 0;
1631
1632         if(checkrules_suddendeathend)
1633         {
1634                 if(!checkrules_suddendeathwarning)
1635                 {
1636                         checkrules_suddendeathwarning = true;
1637                         if(g_race && !g_race_qualifying)
1638                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1639                         else
1640                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1641                 }
1642         }
1643         else
1644         {
1645                 if (timelimit && time >= timelimit)
1646                 {
1647                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1648                         {
1649                                 float totalplayers;
1650                                 float playerswithlaps;
1651                                 float readyplayers;
1652                                 totalplayers = playerswithlaps = readyplayers = 0;
1653                                 FOREACH_CLIENT(IS_PLAYER(it), {
1654                                         ++totalplayers;
1655                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1656                                                 ++playerswithlaps;
1657                                         if(it.ready)
1658                                                 ++readyplayers;
1659                                 });
1660
1661                                 // at least 2 of the players have completed a lap: start the RACE
1662                                 // otherwise, the players should end the qualifying on their own
1663                                 if(readyplayers || playerswithlaps >= 2)
1664                                 {
1665                                         checkrules_suddendeathend = 0;
1666                                         ReadyRestart(); // go to race
1667                                         return;
1668                                 }
1669                                 else
1670                                         wantovertime |= InitiateSuddenDeath();
1671                         }
1672                         else
1673                                 wantovertime |= InitiateSuddenDeath();
1674                 }
1675         }
1676
1677         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1678         {
1679                 NextLevel();
1680                 return;
1681         }
1682
1683         int checkrules_status = WinningCondition_RanOutOfSpawns();
1684         if(checkrules_status == WINNING_YES)
1685                 bprint("Hey! Someone ran out of spawns!\n");
1686         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1687                 checkrules_status = M_ARGV(0, float);
1688         else
1689                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1690
1691         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1692         {
1693                 checkrules_status = WINNING_NEVER;
1694                 checkrules_overtimesadded = -1;
1695                 wantovertime |= InitiateSuddenDeath();
1696         }
1697
1698         if(checkrules_status == WINNING_NEVER)
1699                 // equality cases! Nobody wins if the overtime ends in a draw.
1700                 ClearWinners();
1701
1702         if(wantovertime)
1703         {
1704                 if(checkrules_status == WINNING_NEVER)
1705                         InitiateOvertime();
1706                 else
1707                         checkrules_status = WINNING_YES;
1708         }
1709
1710         if(checkrules_suddendeathend)
1711                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1712                         checkrules_status = WINNING_YES;
1713
1714         if(checkrules_status == WINNING_YES)
1715         {
1716                 //print("WINNING\n");
1717                 NextLevel();
1718         }
1719 }
1720
1721 float want_weapon(entity weaponinfo, float allguns)
1722 {
1723         int d = 0;
1724         bool allow_mutatorblocked = false;
1725
1726         if(!weaponinfo.m_id)
1727                 return 0;
1728
1729         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
1730         d = M_ARGV(1, float);
1731         allguns = M_ARGV(2, bool);
1732         allow_mutatorblocked = M_ARGV(3, bool);
1733
1734         if(allguns)
1735                 d = boolean((weaponinfo.spawnflags & WEP_FLAG_NORMAL) && !(weaponinfo.spawnflags & (WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)));
1736         else if(!mutator_returnvalue)
1737                 d = !(!weaponinfo.weaponstart);
1738
1739         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
1740                 d = 0;
1741
1742         float t = weaponinfo.weaponstartoverride;
1743
1744         //LOG_INFOF("want_weapon: %s - d: %d t: %d\n", weaponinfo.netname, d, t);
1745
1746         // bit order in t:
1747         // 1: want or not
1748         // 2: is default?
1749         // 4: is set by default?
1750         if(t < 0)
1751                 t = 4 | (3 * d);
1752         else
1753                 t |= (2 * d);
1754
1755         return t;
1756 }
1757
1758 /// Weapons the player normally starts with outside weapon arena.
1759 WepSet weapons_start()
1760 {
1761         WepSet ret = '0 0 0';
1762         FOREACH(Weapons, it != WEP_Null, {
1763                 int w = want_weapon(it, false);
1764                 if (w & 1)
1765                         ret |= it.m_wepset;
1766         });
1767         return ret;
1768 }
1769
1770 WepSet weapons_all()
1771 {
1772         WepSet ret = '0 0 0';
1773         FOREACH(Weapons, it != WEP_Null, {
1774                 if (!(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_SPECIALATTACK)))
1775                         ret |= it.m_wepset;
1776         });
1777         return ret;
1778 }
1779
1780 WepSet weapons_devall()
1781 {
1782         WepSet ret = '0 0 0';
1783         FOREACH(Weapons, it != WEP_Null,
1784         {
1785                 ret |= it.m_wepset;
1786         });
1787         return ret;
1788 }
1789
1790 WepSet weapons_most()
1791 {
1792         WepSet ret = '0 0 0';
1793         FOREACH(Weapons, it != WEP_Null, {
1794                 if ((it.spawnflags & WEP_FLAG_NORMAL) && !(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)))
1795                         ret |= it.m_wepset;
1796         });
1797         return ret;
1798 }
1799
1800 void weaponarena_available_all_update(entity this)
1801 {
1802         if (weaponsInMapAll)
1803         {
1804                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_all());
1805         }
1806         else
1807         {
1808                 // if no weapons are available on the map, just fall back to all weapons arena
1809                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_all();
1810         }
1811 }
1812
1813 void weaponarena_available_devall_update(entity this)
1814 {
1815         if (weaponsInMapAll)
1816         {
1817                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | weaponsInMapAll;
1818         }
1819         else
1820         {
1821                 // if no weapons are available on the map, just fall back to devall weapons arena
1822                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_devall();
1823         }
1824 }
1825
1826 void weaponarena_available_most_update(entity this)
1827 {
1828         if (weaponsInMapAll)
1829         {
1830                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_most());
1831         }
1832         else
1833         {
1834                 // if no weapons are available on the map, just fall back to most weapons arena
1835                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_most();
1836         }
1837 }
1838
1839 void readplayerstartcvars()
1840 {
1841         // initialize starting values for players
1842         start_weapons = '0 0 0';
1843         start_weapons_default = '0 0 0';
1844         start_weapons_defaultmask = '0 0 0';
1845         start_items = 0;
1846         start_ammo_shells = 0;
1847         start_ammo_nails = 0;
1848         start_ammo_rockets = 0;
1849         start_ammo_cells = 0;
1850         start_ammo_plasma = 0;
1851         if (random_start_ammo == NULL)
1852         {
1853                 random_start_ammo = new(random_start_ammo);
1854         }
1855         start_health = cvar("g_balance_health_start");
1856         start_armorvalue = cvar("g_balance_armor_start");
1857
1858         g_weaponarena = 0;
1859         g_weaponarena_weapons = '0 0 0';
1860
1861         string s = cvar_string("g_weaponarena");
1862
1863         MUTATOR_CALLHOOK(SetWeaponArena, s);
1864         s = M_ARGV(0, string);
1865
1866         if (s == "0" || s == "")
1867         {
1868                 // no arena
1869         }
1870         else if (s == "off")
1871         {
1872                 // forcibly turn off weaponarena
1873         }
1874         else if (s == "all" || s == "1")
1875         {
1876                 g_weaponarena = 1;
1877                 g_weaponarena_list = "All Weapons";
1878                 g_weaponarena_weapons = weapons_all();
1879         }
1880         else if (s == "devall")
1881         {
1882                 g_weaponarena = 1;
1883                 g_weaponarena_list = "Dev All Weapons";
1884                 g_weaponarena_weapons = weapons_devall();
1885         }
1886         else if (s == "most")
1887         {
1888                 g_weaponarena = 1;
1889                 g_weaponarena_list = "Most Weapons";
1890                 g_weaponarena_weapons = weapons_most();
1891         }
1892         else if (s == "all_available")
1893         {
1894                 g_weaponarena = 1;
1895                 g_weaponarena_list = "All Available Weapons";
1896
1897                 // this needs to run after weaponsInMapAll is initialized
1898                 InitializeEntity(NULL, weaponarena_available_all_update, INITPRIO_FINDTARGET);
1899         }
1900         else if (s == "devall_available")
1901         {
1902                 g_weaponarena = 1;
1903                 g_weaponarena_list = "Dev All Available Weapons";
1904
1905                 // this needs to run after weaponsInMapAll is initialized
1906                 InitializeEntity(NULL, weaponarena_available_devall_update, INITPRIO_FINDTARGET);
1907         }
1908         else if (s == "most_available")
1909         {
1910                 g_weaponarena = 1;
1911                 g_weaponarena_list = "Most Available Weapons";
1912
1913                 // this needs to run after weaponsInMapAll is initialized
1914                 InitializeEntity(NULL, weaponarena_available_most_update, INITPRIO_FINDTARGET);
1915         }
1916         else if (s == "none")
1917         {
1918                 g_weaponarena = 1;
1919                 g_weaponarena_list = "No Weapons";
1920         }
1921         else
1922         {
1923                 g_weaponarena = 1;
1924                 float t = tokenize_console(s);
1925                 g_weaponarena_list = "";
1926                 for (int j = 0; j < t; ++j)
1927                 {
1928                         s = argv(j);
1929                         Weapon wep = Weapon_from_name(s);
1930                         if(wep != WEP_Null)
1931                         {
1932                                 g_weaponarena_weapons |= (wep.m_wepset);
1933                                 g_weaponarena_list = strcat(g_weaponarena_list, wep.m_name, " & ");
1934                         }
1935                 }
1936                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
1937         }
1938
1939         if (g_weaponarena)
1940         {
1941                 g_weapon_stay = 0; // incompatible
1942                 start_weapons = g_weaponarena_weapons;
1943                 start_items |= IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS;
1944         }
1945         else
1946         {
1947                 FOREACH(Weapons, it != WEP_Null, {
1948                         int w = want_weapon(it, false);
1949                         WepSet s = it.m_wepset;
1950                         if(w & 1)
1951                                 start_weapons |= s;
1952                         if(w & 2)
1953                                 start_weapons_default |= s;
1954                         if(w & 4)
1955                                 start_weapons_defaultmask |= s;
1956                 });
1957         }
1958
1959         if(cvar("g_balance_superweapons_time") < 0)
1960                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
1961
1962         if(!cvar("g_use_ammunition"))
1963                 start_items |= IT_UNLIMITED_AMMO;
1964
1965         if(start_items & IT_UNLIMITED_AMMO)
1966         {
1967                 start_ammo_shells = 999;
1968                 start_ammo_nails = 999;
1969                 start_ammo_rockets = 999;
1970                 start_ammo_cells = 999;
1971                 start_ammo_plasma = 999;
1972                 start_ammo_fuel = 999;
1973         }
1974         else
1975         {
1976                 start_ammo_shells = cvar("g_start_ammo_shells");
1977                 start_ammo_nails = cvar("g_start_ammo_nails");
1978                 start_ammo_rockets = cvar("g_start_ammo_rockets");
1979                 start_ammo_cells = cvar("g_start_ammo_cells");
1980                 start_ammo_plasma = cvar("g_start_ammo_plasma");
1981                 start_ammo_fuel = cvar("g_start_ammo_fuel");
1982                 random_start_weapons_count = cvar("g_random_start_weapons_count");
1983                 SetResource(random_start_ammo, RES_SHELLS, cvar("g_random_start_shells"));
1984                 SetResource(random_start_ammo, RES_BULLETS, cvar("g_random_start_bullets"));
1985                 SetResource(random_start_ammo, RES_ROCKETS,cvar("g_random_start_rockets"));
1986                 SetResource(random_start_ammo, RES_CELLS, cvar("g_random_start_cells"));
1987                 SetResource(random_start_ammo, RES_PLASMA, cvar("g_random_start_plasma"));
1988         }
1989
1990         warmup_start_ammo_shells = start_ammo_shells;
1991         warmup_start_ammo_nails = start_ammo_nails;
1992         warmup_start_ammo_rockets = start_ammo_rockets;
1993         warmup_start_ammo_cells = start_ammo_cells;
1994         warmup_start_ammo_plasma = start_ammo_plasma;
1995         warmup_start_ammo_fuel = start_ammo_fuel;
1996         warmup_start_health = start_health;
1997         warmup_start_armorvalue = start_armorvalue;
1998         warmup_start_weapons = start_weapons;
1999         warmup_start_weapons_default = start_weapons_default;
2000         warmup_start_weapons_defaultmask = start_weapons_defaultmask;
2001
2002         if (!g_weaponarena)
2003         {
2004                 warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
2005                 warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
2006                 warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
2007                 warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
2008                 warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
2009                 warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
2010                 warmup_start_health = cvar("g_warmup_start_health");
2011                 warmup_start_armorvalue = cvar("g_warmup_start_armor");
2012                 warmup_start_weapons = '0 0 0';
2013                 warmup_start_weapons_default = '0 0 0';
2014                 warmup_start_weapons_defaultmask = '0 0 0';
2015                 FOREACH(Weapons, it != WEP_Null, {
2016                         int w = want_weapon(it, autocvar_g_warmup_allguns);
2017                         WepSet s = it.m_wepset;
2018                         if(w & 1)
2019                                 warmup_start_weapons |= s;
2020                         if(w & 2)
2021                                 warmup_start_weapons_default |= s;
2022                         if(w & 4)
2023                                 warmup_start_weapons_defaultmask |= s;
2024                 });
2025         }
2026
2027         if (autocvar_g_jetpack)
2028                 start_items |= ITEM_Jetpack.m_itemid;
2029
2030         MUTATOR_CALLHOOK(SetStartItems);
2031
2032         if (start_items & ITEM_Jetpack.m_itemid)
2033         {
2034                 start_items |= ITEM_JetpackRegen.m_itemid;
2035                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
2036                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
2037         }
2038
2039         start_ammo_shells = max(0, start_ammo_shells);
2040         start_ammo_nails = max(0, start_ammo_nails);
2041         start_ammo_rockets = max(0, start_ammo_rockets);
2042         start_ammo_cells = max(0, start_ammo_cells);
2043         start_ammo_plasma = max(0, start_ammo_plasma);
2044         start_ammo_fuel = max(0, start_ammo_fuel);
2045         SetResource(random_start_ammo, RES_SHELLS,
2046                 max(0, GetResource(random_start_ammo, RES_SHELLS)));
2047         SetResource(random_start_ammo, RES_BULLETS,
2048                 max(0, GetResource(random_start_ammo, RES_BULLETS)));
2049         SetResource(random_start_ammo, RES_ROCKETS,
2050                 max(0, GetResource(random_start_ammo, RES_ROCKETS)));
2051         SetResource(random_start_ammo, RES_CELLS,
2052                 max(0, GetResource(random_start_ammo, RES_CELLS)));
2053         SetResource(random_start_ammo, RES_PLASMA,
2054                 max(0, GetResource(random_start_ammo, RES_PLASMA)));
2055
2056         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
2057         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
2058         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
2059         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
2060         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
2061         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
2062 }
2063
2064 void readlevelcvars()
2065 {
2066         if(cvar("sv_allow_fullbright"))
2067                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
2068
2069         sv_ready_restart_after_countdown = cvar("sv_ready_restart_after_countdown");
2070
2071         warmup_stage = cvar("g_warmup");
2072         warmup_limit = cvar("g_warmup_limit");
2073
2074         if(cvar("g_campaign"))
2075                 warmup_stage = 0; // no warmup during campaign
2076
2077         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
2078         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
2079         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
2080         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
2081         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
2082         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
2083         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
2084         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
2085         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
2086         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
2087         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
2088         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
2089         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
2090         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
2091
2092         g_pickup_shells = cvar("g_pickup_shells");
2093         g_pickup_shells_max = cvar("g_pickup_shells_max");
2094         g_pickup_nails = cvar("g_pickup_nails");
2095         g_pickup_nails_max = cvar("g_pickup_nails_max");
2096         g_pickup_rockets = cvar("g_pickup_rockets");
2097         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
2098         g_pickup_cells = cvar("g_pickup_cells");
2099         g_pickup_cells_max = cvar("g_pickup_cells_max");
2100         g_pickup_plasma = cvar("g_pickup_plasma");
2101         g_pickup_plasma_max = cvar("g_pickup_plasma_max");
2102         g_pickup_fuel = cvar("g_pickup_fuel");
2103         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
2104         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
2105         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
2106         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
2107         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
2108         g_pickup_armormedium = cvar("g_pickup_armormedium");
2109         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
2110         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
2111         g_pickup_armorbig = cvar("g_pickup_armorbig");
2112         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
2113         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
2114         g_pickup_armormega = cvar("g_pickup_armormega");
2115         g_pickup_armormega_max = cvar("g_pickup_armormega_max");
2116         g_pickup_armormega_anyway = cvar("g_pickup_armormega_anyway");
2117         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
2118         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
2119         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
2120         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
2121         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
2122         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
2123         g_pickup_healthbig = cvar("g_pickup_healthbig");
2124         g_pickup_healthbig_max = cvar("g_pickup_healthbig_max");
2125         g_pickup_healthbig_anyway = cvar("g_pickup_healthbig_anyway");
2126         g_pickup_healthmega = cvar("g_pickup_healthmega");
2127         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
2128         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
2129
2130         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
2131         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
2132
2133     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
2134     if(!g_weapon_stay)
2135         g_weapon_stay = cvar("g_weapon_stay");
2136
2137     MUTATOR_CALLHOOK(ReadLevelCvars);
2138
2139         if (!warmup_stage)
2140                 game_starttime = time + cvar("g_start_delay");
2141
2142         FOREACH(Weapons, it != WEP_Null, { it.wr_init(it); });
2143
2144         readplayerstartcvars();
2145 }
2146
2147 void InitializeEntity(entity e, void(entity this) func, int order)
2148 {
2149     entity prev, cur;
2150
2151     if (!e || e.initialize_entity)
2152     {
2153         // make a proxy initializer entity
2154         entity e_old = e;
2155         e = new(initialize_entity);
2156         e.enemy = e_old;
2157     }
2158
2159     e.initialize_entity = func;
2160     e.initialize_entity_order = order;
2161
2162     cur = initialize_entity_first;
2163     prev = NULL;
2164     for (;;)
2165     {
2166         if (!cur || cur.initialize_entity_order > order)
2167         {
2168             // insert between prev and cur
2169             if (prev)
2170                 prev.initialize_entity_next = e;
2171             else
2172                 initialize_entity_first = e;
2173             e.initialize_entity_next = cur;
2174             return;
2175         }
2176         prev = cur;
2177         cur = cur.initialize_entity_next;
2178     }
2179 }
2180 void InitializeEntitiesRun()
2181 {
2182     entity startoflist = initialize_entity_first;
2183     initialize_entity_first = NULL;
2184     delete_fn = remove_except_protected;
2185     for (entity e = startoflist; e; e = e.initialize_entity_next)
2186     {
2187                 e.remove_except_protected_forbidden = 1;
2188     }
2189     for (entity e = startoflist; e; )
2190     {
2191                 e.remove_except_protected_forbidden = 0;
2192         e.initialize_entity_order = 0;
2193         entity next = e.initialize_entity_next;
2194         e.initialize_entity_next = NULL;
2195         var void(entity this) func = e.initialize_entity;
2196         e.initialize_entity = func_null;
2197         if (e.classname == "initialize_entity")
2198         {
2199             entity wrappee = e.enemy;
2200             builtin_remove(e);
2201             e = wrappee;
2202         }
2203         //dprint("Delayed initialization: ", e.classname, "\n");
2204         if (func)
2205         {
2206                 func(e);
2207         }
2208         else
2209         {
2210             eprint(e);
2211             backtrace(strcat("Null function in: ", e.classname, "\n"));
2212         }
2213         e = next;
2214     }
2215     delete_fn = remove_unsafely;
2216 }
2217
2218 // deferred dropping
2219 void DropToFloor_Handler(entity this)
2220 {
2221         WITHSELF(this, builtin_droptofloor());
2222         this.dropped_origin = this.origin;
2223 }
2224
2225 void droptofloor(entity this)
2226 {
2227         InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
2228 }
2229
2230 bool autocvar_sv_gameplayfix_multiplethinksperframe = true;
2231 void RunThink(entity this)
2232 {
2233         // don't let things stay in the past.
2234         // it is possible to start that way by a trigger with a local time.
2235         if(this.nextthink <= 0 || this.nextthink > time + frametime)
2236                 return;
2237
2238         float oldtime = time; // do we need to save this?
2239
2240         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2241         {
2242                 time = max(oldtime, this.nextthink);
2243                 this.nextthink = 0;
2244
2245                 if(getthink(this))
2246                         getthink(this)(this);
2247                 // mods often set nextthink to time to cause a think every frame,
2248                 // we don't want to loop in that case, so exit if the new nextthink is
2249                 // <= the time the qc was told, also exit if it is past the end of the
2250                 // frame
2251                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2252                         break;
2253         }
2254
2255         time = oldtime;
2256 }
2257
2258 bool autocvar_sv_freezenonclients;
2259 void Physics_Frame()
2260 {
2261         if(autocvar_sv_freezenonclients)
2262                 return;
2263
2264         IL_EACH(g_moveables, true,
2265         {
2266                 if(IS_CLIENT(it) || it.move_movetype == MOVETYPE_PHYSICS)
2267                         continue;
2268
2269                 //set_movetype(it, it.move_movetype);
2270                 // inline the set_movetype function, since this is called a lot
2271                 it.movetype = (it.move_qcphysics) ? MOVETYPE_QCENTITY : it.move_movetype;
2272
2273                 if(it.move_qcphysics && it.move_movetype != MOVETYPE_NONE)
2274                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2275
2276                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2277                 {
2278                         if(it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH)
2279                                 continue; // these movetypes have no regular think function
2280                         // handle thinking here
2281                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2282                                 RunThink(it);
2283                 }
2284         });
2285
2286         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2287                 return;
2288
2289         // make a second pass to see if any ents spawned this frame and make
2290         // sure they run their move/think. this is verified by checking .move_time, which will never be 0 if the entity has moved
2291         // MOVETYPE_NONE is also checked as .move_time WILL be 0 with that movetype
2292         IL_EACH(g_moveables, it.move_qcphysics,
2293         {
2294                 if(IS_CLIENT(it) || it.move_time || it.move_movetype == MOVETYPE_NONE || it.move_movetype == MOVETYPE_PHYSICS)
2295                         continue;
2296                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2297         });
2298 }
2299
2300 void systems_update();
2301 void EndFrame()
2302 {
2303         anticheat_endframe();
2304
2305         Physics_Frame();
2306
2307         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2308                 entity e = IS_SPEC(it) ? it.enemy : it;
2309                 if (e.typehitsound) {
2310                         STAT(TYPEHIT_TIME, it) = time;
2311                 } else if (e.killsound) {
2312                         STAT(KILL_TIME, it) = time;
2313                 } else if (e.damage_dealt) {
2314                         STAT(HIT_TIME, it) = time;
2315                         STAT(DAMAGE_DEALT_TOTAL, it) += ceil(e.damage_dealt);
2316                 }
2317         });
2318         // add 1 frametime because after this, engine SV_Physics
2319         // increases time by a frametime and then networks the frame
2320         // add another frametime because client shows everything with
2321         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2322         // needed!
2323         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2324         FOREACH_CLIENT(true, {
2325                 it.typehitsound = false;
2326                 it.damage_dealt = 0;
2327                 it.killsound = false;
2328                 antilag_record(it, CS(it), altime);
2329         });
2330         IL_EACH(g_monsters, true,
2331         {
2332                 antilag_record(it, it, altime);
2333         });
2334         IL_EACH(g_projectiles, it.classname == "nade",
2335         {
2336                 antilag_record(it, it, altime);
2337         });
2338         systems_update();
2339         IL_ENDFRAME();
2340 }
2341
2342
2343 /*
2344  * RedirectionThink:
2345  * returns true if redirecting
2346  */
2347 float redirection_timeout;
2348 float redirection_nextthink;
2349 float RedirectionThink()
2350 {
2351         float clients_found;
2352
2353         if(redirection_target == "")
2354                 return false;
2355
2356         if(!redirection_timeout)
2357         {
2358                 cvar_set("sv_public", "-2");
2359                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2360                 if(redirection_target == "self")
2361                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2362                 else
2363                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2364         }
2365
2366         if(time < redirection_nextthink)
2367                 return true;
2368
2369         redirection_nextthink = time + 1;
2370
2371         clients_found = 0;
2372         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2373                 // TODO add timer
2374                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2375                 if(redirection_target == "self")
2376                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2377                 else
2378                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2379                 ++clients_found;
2380         });
2381
2382         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2383
2384         if(time > redirection_timeout || clients_found == 0)
2385                 localcmd("\nwait; wait; wait; quit\n");
2386
2387         return true;
2388 }
2389
2390 void RestoreGame()
2391 {
2392         // Loaded from a save game
2393         // some things then break, so let's work around them...
2394
2395         // Progs DB (capture records)
2396         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2397
2398         // Mapinfo
2399         MapInfo_Shutdown();
2400         MapInfo_Enumerate();
2401         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2402         WeaponStats_Init();
2403
2404         TargetMusic_RestoreGame();
2405 }
2406
2407 void Shutdown()
2408 {
2409         game_stopped = 2;
2410
2411         if(world_initialized > 0)
2412         {
2413                 world_initialized = 0;
2414
2415                 // if a timeout is active, reset the slowmo value to normal
2416                 if(timeout_status == TIMEOUT_ACTIVE)
2417                         cvar_set("slowmo", ftos(orig_slowmo));
2418
2419                 LOG_TRACE("Saving persistent data...");
2420                 Ban_SaveBans();
2421
2422                 // playerstats with unfinished match
2423                 PlayerStats_GameReport(false);
2424
2425                 if(!cheatcount_total)
2426                 {
2427                         if(autocvar_sv_db_saveasdump)
2428                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2429                         else
2430                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2431                 }
2432                 if(autocvar_developer > 0)
2433                 {
2434                         if(autocvar_sv_db_saveasdump)
2435                                 db_dump(TemporaryDB, "server-temp.db");
2436                         else
2437                                 db_save(TemporaryDB, "server-temp.db");
2438                 }
2439                 CheatShutdown(); // must be after cheatcount check
2440                 db_close(ServerProgsDB);
2441                 db_close(TemporaryDB);
2442                 LOG_TRACE("Saving persistent data... done!");
2443                 // tell the bot system the game is ending now
2444                 bot_endgame();
2445
2446                 WeaponStats_Shutdown();
2447                 MapInfo_Shutdown();
2448         }
2449         else if(world_initialized == 0)
2450         {
2451                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2452         }
2453         else
2454         {
2455                 __init_dedicated_server_shutdown();
2456         }
2457 }