qcsrc/server/t_items.qc

   1 float have_pickup_item(void)
   2 {
   3         // minstagib: only allow filtered items
   4         if(g_minstagib)
   5                 if(self.classname != "minstagib")
   6                         return FALSE;
   7
   8         if(self.flags & FL_POWERUP)
   9         {
  10                 if(autocvar_g_powerups > 0)
  11                         return TRUE;
  12                 if(autocvar_g_powerups == 0)
  13                         return FALSE;
  14                 if(g_lms)
  15                         return FALSE;
  16                 if(g_ca)
  17                         return FALSE;
  18                 if(g_arena)
  19                         return FALSE;
  20         }
  21         else
  22         {
  23                 if(autocvar_g_pickup_items > 0)
  24                         return TRUE;
  25                 if(autocvar_g_pickup_items == 0)
  26                         return FALSE;
  27                 if(g_lms)
  28                         return FALSE;
  29                 if(g_ca)
  30                         return FALSE;
  31                 if(g_weaponarena)
  32                         if(!WEPSET_EMPTY_E(self) || (self.items & IT_AMMO))
  33                                 return FALSE;
  34         }
  35         return TRUE;
  36 }
  37
  38 #define ITEM_RESPAWN_TICKS 10
  39
  40 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
  41         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
  42 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
  43         // range: 10 .. respawntime + respawntimejitter
  44
  45 floatfield Item_CounterField(float it)
  46 {
  47         switch(it)
  48         {
  49                 case IT_SHELLS:      return ammo_shells;
  50                 case IT_NAILS:       return ammo_nails;
  51                 case IT_ROCKETS:     return ammo_rockets;
  52                 case IT_CELLS:       return ammo_cells;
  53                 case IT_FUEL:        return ammo_fuel;
  54                 case IT_5HP:         return health;
  55                 case IT_25HP:        return health;
  56                 case IT_HEALTH:      return health;
  57                 case IT_ARMOR_SHARD: return armorvalue;
  58                 case IT_ARMOR:       return armorvalue;
  59                 // add more things here (health, armor)
  60                 default:             error("requested item has no counter field");
  61         }
  62 }
  63
  64 string Item_CounterFieldName(float it)
  65 {
  66         switch(it)
  67         {
  68                 case IT_SHELLS:      return "shells";
  69                 case IT_NAILS:       return "nails";
  70                 case IT_ROCKETS:     return "rockets";
  71                 case IT_CELLS:       return "cells";
  72                 case IT_FUEL:        return "fuel";
  73
  74                 // add more things here (health, armor)
  75                 default:             error("requested item has no counter field name");
  76         }
  77 }
  78
  79 .float max_armorvalue;
  80 .float pickup_anyway;
  81
  82 float Item_Customize()
  83 {
  84         if(self.spawnshieldtime)
  85                 return TRUE;
  86         if(!WEPSET_CONTAINS_ALL_EE(other, self))
  87         {
  88                 self.colormod = '0 0 0';
  89                 self.glowmod = self.colormod;
  90                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  91                 return TRUE;
  92         }
  93         else
  94         {
  95                 if(g_ghost_items)
  96                 {
  97                         self.colormod = stov(autocvar_g_ghost_items_color);
  98                         self.glowmod = self.colormod;
  99                         self.alpha = g_ghost_items;
 100                         return TRUE;
 101                 }
 102                 else
 103                         return FALSE;
 104         }
 105 }
 106
 107 void Item_Show (entity e, float mode)
 108 {
 109         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 110         if (mode > 0)
 111         {
 112                 // make the item look normal, and be touchable
 113                 e.model = e.mdl;
 114                 e.solid = SOLID_TRIGGER;
 115                 e.colormod = '0 0 0';
 116                 self.glowmod = self.colormod;
 117                 e.alpha = 0;
 118                 e.customizeentityforclient = func_null;
 119
 120                 e.spawnshieldtime = 1;
 121         }
 122         else if (mode < 0)
 123         {
 124                 // hide the item completely
 125                 e.model = string_null;
 126                 e.solid = SOLID_NOT;
 127                 e.colormod = '0 0 0';
 128                 self.glowmod = self.colormod;
 129                 e.alpha = 0;
 130                 e.customizeentityforclient = func_null;
 131
 132                 e.spawnshieldtime = 1;
 133         }
 134         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 135         {
 136                 // make the item translucent and not touchable
 137                 e.model = e.mdl;
 138                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 139                 e.colormod = '0 0 0';
 140                 self.glowmod = self.colormod;
 141                 e.effects |= EF_STARDUST;
 142                 e.customizeentityforclient = Item_Customize;
 143
 144                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 145         }
 146         else if(g_ghost_items)
 147         {
 148                 // make the item translucent and not touchable
 149                 e.model = e.mdl;
 150                 e.solid = SOLID_NOT;
 151                 e.colormod = stov(autocvar_g_ghost_items_color);
 152                 e.glowmod = e.colormod;
 153                 e.alpha = g_ghost_items;
 154                 e.customizeentityforclient = func_null;
 155
 156                 e.spawnshieldtime = 1;
 157         }
 158         else
 159         {
 160                 // hide the item completely
 161                 e.model = string_null;
 162                 e.solid = SOLID_NOT;
 163                 e.colormod = '0 0 0';
 164                 e.glowmod = e.colormod;
 165                 e.alpha = 0;
 166                 e.customizeentityforclient = func_null;
 167
 168                 e.spawnshieldtime = 1;
 169         }
 170
 171         if (e.items & (IT_STRENGTH | IT_INVINCIBLE))
 172                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 173         if (autocvar_g_nodepthtestitems)
 174                 e.effects |= EF_NODEPTHTEST;
 175         if (autocvar_g_fullbrightitems)
 176                 e.effects |= EF_FULLBRIGHT;
 177
 178         // relink entity (because solid may have changed)
 179         setorigin(e, e.origin);
 180 }
 181
 182 void Item_Respawn (void)
 183 {
 184         Item_Show(self, 1);
 185         if(!g_minstagib && self.items == IT_STRENGTH)
 186                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 187         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 188                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 189         else
 190                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 191         setorigin (self, self.origin);
 192
 193         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 194         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 195 }
 196
 197 void Item_RespawnCountdown (void)
 198 {
 199         if(self.count >= ITEM_RESPAWN_TICKS)
 200         {
 201                 if(self.waypointsprite_attached)
 202                         WaypointSprite_Kill(self.waypointsprite_attached);
 203                 Item_Respawn();
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 self.count += 1;
 209                 if(self.count == 1)
 210                 {
 211                         string name;
 212                         vector rgb;
 213                         name = string_null;
 214                         if(g_minstagib)
 215                         {
 216                                 switch(self.items)
 217                                 {
 218                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 219                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 220                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 221                                 }
 222                         }
 223                         else
 224                         {
 225                                 switch(self.items)
 226                                 {
 227                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 228                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 229                                 }
 230                         }
 231                         switch(self.items)
 232                         {
 233                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 234                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 235                         }
 236                         if(self.flags & FL_WEAPON)
 237                         {
 238                                 entity wi = get_weaponinfo(self.weapon);
 239                                 if(wi)
 240                                 {
 241                                         name = wi.model2;
 242                                         rgb = '1 0 0';
 243                                 }
 244                         }
 245                         if(!name)
 246                         {
 247                                 print("Unknown powerup-marked item is wanting to respawn\n");
 248                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 249                         }
 250                         if(name)
 251                         {
 252                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 253                                 if(self.waypointsprite_attached)
 254                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 255                         }
 256                 }
 257                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 258                 if(self.waypointsprite_attached)
 259                 {
 260                         WaypointSprite_Ping(self.waypointsprite_attached);
 261                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 262                 }
 263         }
 264 }
 265
 266 void Item_ScheduleRespawnIn(entity e, float t)
 267 {
 268         if((e.flags & FL_POWERUP) || WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
 269         {
 270                 e.think = Item_RespawnCountdown;
 271                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 272                 e.count = 0;
 273         }
 274         else
 275         {
 276                 e.think = Item_Respawn;
 277                 e.nextthink = time + t;
 278         }
 279 }
 280
 281 void Item_ScheduleRespawn(entity e)
 282 {
 283         if(e.respawntime > 0)
 284         {
 285                 Item_Show(e, 0);
 286                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 287         }
 288         else // if respawntime is -1, this item does not respawn
 289                 Item_Show(e, -1);
 290 }
 291
 292 void Item_ScheduleInitialRespawn(entity e)
 293 {
 294         Item_Show(e, 0);
 295         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 296 }
 297
 298 float ITEM_MODE_NONE = 0;
 299 float ITEM_MODE_HEALTH = 1;
 300 float ITEM_MODE_ARMOR = 2;
 301 float ITEM_MODE_FUEL = 3;
 302 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 303 {
 304         if (!item.ammofield)
 305                 return FALSE;
 306
 307         if (item.spawnshieldtime)
 308         {
 309                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 310                 {
 311                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 312                         goto YEAH;
 313                 }
 314         }
 315         else if(g_weapon_stay == 2)
 316         {
 317                 float mi = min(item.ammofield, ammomax);
 318                 if (player.ammofield < mi)
 319                 {
 320                         player.ammofield = mi;
 321                         goto YEAH;
 322                 }
 323         }
 324
 325         return FALSE;
 326
 327 :YEAH
 328         switch(mode)
 329         {
 330                 case ITEM_MODE_FUEL:
 331                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 332                         break;
 333                 case ITEM_MODE_HEALTH:
 334                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 335                         break;
 336                 case ITEM_MODE_ARMOR:
 337                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 338                         break;
 339                 default:
 340                         break;
 341         }
 342         return TRUE;
 343 }
 344
 345 float Item_GiveTo(entity item, entity player)
 346 {
 347         float _switchweapon;
 348         float pickedup;
 349         float it;
 350         float i;
 351
 352         // if nothing happens to player, just return without taking the item
 353         pickedup = FALSE;
 354         _switchweapon = FALSE;
 355
 356         if (g_minstagib)
 357         {
 358                 float prevcells = player.ammo_cells;
 359
 360                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 361                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, 999, ITEM_MODE_NONE);
 362
 363                 if(player.ammo_cells > prevcells)
 364                 {
 365                         _switchweapon = TRUE;
 366
 367                         // play some cool sounds ;)
 368                         if (clienttype(player) == CLIENTTYPE_REAL)
 369                         {
 370                                 if(player.health <= 5)
 371                                         AnnounceTo(player, "lastsecond");
 372                                 else if(player.health < 50)
 373                                         AnnounceTo(player, "narrowly");
 374                         }
 375                         // sound not available
 376                         // else if(item.items == IT_CELLS)
 377                         //      AnnounceTo(player, "ammo");
 378
 379                         if (WEPSET_CONTAINS_EW(item, WEP_MINSTANEX))
 380                                 W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 381                         if (item.ammo_cells)
 382                                 player.ammo_cells = bound(player.ammo_cells, 999, player.ammo_cells + autocvar_g_minstagib_ammo_drop);
 383                         player.health = 100;
 384                 }
 385
 386                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 387                 {
 388                         pickedup = TRUE;
 389                         player.items |= it;
 390                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 391                 }
 392
 393                 // extralife powerup
 394                 if (item.max_health)
 395                 {
 396                         pickedup = TRUE;
 397                         // sound not available
 398                         // AnnounceTo(player, "_lives");
 399                         player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 400                         sprint(player, "^3You picked up some extra lives\n");
 401                 }
 402
 403                 // invis powerup
 404                 if (item.strength_finished)
 405                 {
 406                         pickedup = TRUE;
 407                         // sound not available
 408                         // AnnounceTo(player, "invisible");
 409                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 410                 }
 411
 412                 // speed powerup
 413                 if (item.invincible_finished)
 414                 {
 415                         pickedup = TRUE;
 416                         // sound not available
 417                         // AnnounceTo(player, "speed");
 418                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_strength_time;
 419                 }
 420         }
 421         else
 422         {
 423                 // in case the player has autoswitch enabled do the following:
 424                 // if the player is using their best weapon before items are given, they
 425                 // probably want to switch to an even better weapon after items are given
 426                 if (player.autoswitch)
 427                 if (player.switchweapon == w_getbestweapon(player))
 428                         _switchweapon = TRUE;
 429
 430                 if not(WEPSET_CONTAINS_EW(player, player.switchweapon))
 431                         _switchweapon = TRUE;
 432
 433                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 434                 pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 435                 pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 436                 pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 437                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 438                 pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 439                 pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 440
 441                 if (item.flags & FL_WEAPON)
 442                 {
 443                         WEPSET_DECLARE_A(it);
 444                         WEPSET_COPY_AE(it, item);
 445                         WEPSET_ANDNOT_AE(it, player);
 446
 447                         if (!WEPSET_EMPTY_A(it) || (item.spawnshieldtime && self.pickup_anyway))
 448                         {
 449                                 pickedup = TRUE;
 450                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 451                                         if(WEPSET_CONTAINS_AW(it, i))
 452                                                 W_GiveWeapon (player, i, item.netname);
 453                         }
 454                 }
 455
 456                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 457                 {
 458                         pickedup = TRUE;
 459                         player.items |= it;
 460                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 461                 }
 462
 463                 if (item.strength_finished)
 464                 {
 465                         pickedup = TRUE;
 466                         player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 467                 }
 468                 if (item.invincible_finished)
 469                 {
 470                         pickedup = TRUE;
 471                         player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 472                 }
 473                 if (item.superweapons_finished)
 474                 {
 475                         pickedup = TRUE;
 476                         player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 477                 }
 478         }
 479
 480 :skip
 481         // always eat teamed entities
 482         if(item.team)
 483                 pickedup = TRUE;
 484
 485         if (!pickedup)
 486                 return 0;
 487
 488         if (_switchweapon)
 489                 if (player.switchweapon != w_getbestweapon(player))
 490                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 491
 492         return 1;
 493 }
 494
 495 void Item_Touch (void)
 496 {
 497         entity e, head;
 498
 499         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 500         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 501         {
 502                 remove(self);
 503                 return;
 504         }
 505         if (other.classname != "player")
 506                 return;
 507         if (other.deadflag)
 508                 return;
 509         if (self.solid != SOLID_TRIGGER)
 510                 return;
 511         if (self.owner == other)
 512                 return;
 513
 514         if (self.classname == "droppedweapon")
 515         {
 516                 self.strength_finished = max(0, self.strength_finished - time);
 517                 self.invincible_finished = max(0, self.invincible_finished - time);
 518                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 519         }
 520
 521         if(!Item_GiveTo(self, other))
 522         {
 523                 if (self.classname == "droppedweapon")
 524                 {
 525                         // undo what we did above
 526                         self.strength_finished += time;
 527                         self.invincible_finished += time;
 528                         self.superweapons_finished += time;
 529                 }
 530                 return;
 531         }
 532
 533         other.last_pickup = time;
 534
 535         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 536         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTN_NORM);
 537
 538         if (self.classname == "droppedweapon")
 539                 remove (self);
 540         else if not(self.spawnshieldtime)
 541                 return;
 542         else
 543         {
 544                 if(self.team)
 545                 {
 546                         RandomSelection_Init();
 547                         for(head = world; (head = findfloat(head, team, self.team)); )
 548                         {
 549                                 if(head.flags & FL_ITEM)
 550                                 {
 551                                         Item_Show(head, -1);
 552                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 553                                 }
 554                         }
 555                         e = RandomSelection_chosen_ent;
 556                 }
 557                 else
 558                         e = self;
 559                 Item_ScheduleRespawn(e);
 560         }
 561 }
 562
 563 void Item_Reset()
 564 {
 565         Item_Show(self, !self.state);
 566         setorigin (self, self.origin);
 567
 568         if(self.classname != "droppedweapon")
 569         {
 570                 self.think = SUB_Null;
 571                 self.nextthink = 0;
 572
 573                 if(self.waypointsprite_attached)
 574                         WaypointSprite_Kill(self.waypointsprite_attached);
 575
 576                 if((self.flags & FL_POWERUP) | WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // do not spawn powerups initially!
 577                         Item_ScheduleInitialRespawn(self);
 578         }
 579 }
 580
 581 void Item_FindTeam()
 582 {
 583         entity head, e;
 584
 585         if(self.effects & EF_NODRAW)
 586         {
 587                 // marker for item team search
 588                 dprint("Initializing item team ", ftos(self.team), "\n");
 589                 RandomSelection_Init();
 590                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 591                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 592                 e = RandomSelection_chosen_ent;
 593                 e.state = 0;
 594                 Item_Show(e, 1);
 595
 596                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 597                 {
 598                         if(head != e)
 599                         {
 600                                 // make it a non-spawned item
 601                                 Item_Show(head, -1);
 602                                 head.state = 1; // state 1 = initially hidden item
 603                         }
 604                         head.effects &~= EF_NODRAW;
 605                 }
 606
 607                 Item_Reset();
 608         }
 609 }
 610
 611 // Savage: used for item garbage-collection
 612 // TODO: perhaps nice special effect?
 613 void RemoveItem(void)
 614 {
 615         remove(self);
 616 }
 617
 618 // pickup evaluation functions
 619 // these functions decide how desirable an item is to the bots
 620
 621 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 622
 623 float weapon_pickupevalfunc(entity player, entity item)
 624 {
 625         float c, j, position;
 626
 627         // See if I have it already
 628         if(!WEPSET_CONTAINS_ALL_EE(player, item))
 629         {
 630                 // If I can pick it up
 631                 if(!item.spawnshieldtime)
 632                         c = 0;
 633                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 634                 {
 635                         // Skilled bots will grab more
 636                         c = bound(0, skill / 10, 1) * 0.5;
 637                 }
 638                 else
 639                         c = 0;
 640         }
 641         else
 642                 c = 1;
 643
 644         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 645         if( bot_custom_weapon && c )
 646         {
 647                 // Find the highest position on any range
 648                 position = -1;
 649                 for(j = 0; j < WEP_LAST ; ++j){
 650                         if(
 651                                         bot_weapons_far[j] == item.weapon ||
 652                                         bot_weapons_mid[j] == item.weapon ||
 653                                         bot_weapons_close[j] == item.weapon
 654                           )
 655                         {
 656                                 position = j;
 657                                 break;
 658                         }
 659                 }
 660
 661                 // Rate it
 662                 if (position >= 0 )
 663                 {
 664                         position = WEP_LAST - position;
 665                         // item.bot_pickupbasevalue is overwritten here
 666                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 667                 }
 668         }
 669
 670         return item.bot_pickupbasevalue * c;
 671 }
 672
 673 float commodity_pickupevalfunc(entity player, entity item)
 674 {
 675         float c, i, need_shells, need_nails, need_rockets, need_cells, need_fuel;
 676         entity wi;
 677         c = 0;
 678
 679         // Detect needed ammo
 680         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 681         {
 682                 wi = get_weaponinfo(i);
 683
 684                 if not(WEPSET_CONTAINS_EW(player, i))
 685                         continue;
 686
 687                 if(wi.items & IT_SHELLS)
 688                         need_shells = TRUE;
 689                 else if(wi.items & IT_NAILS)
 690                         need_nails = TRUE;
 691                 else if(wi.items & IT_ROCKETS)
 692                         need_rockets = TRUE;
 693                 else if(wi.items & IT_CELLS)
 694                         need_cells = TRUE;
 695                 else if(wi.items & IT_FUEL)
 696                         need_cells = TRUE;
 697         }
 698
 699         // TODO: figure out if the player even has the weapon this ammo is for?
 700         // may not affect strategy much though...
 701         // find out how much more ammo/armor/health the player can hold
 702         if (need_shells)
 703         if (item.ammo_shells)
 704         if (player.ammo_shells < g_pickup_shells_max)
 705                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 706         if (need_nails)
 707         if (item.ammo_nails)
 708         if (player.ammo_nails < g_pickup_nails_max)
 709                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 710         if (need_rockets)
 711         if (item.ammo_rockets)
 712         if (player.ammo_rockets < g_pickup_rockets_max)
 713                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 714         if (need_cells)
 715         if (item.ammo_cells)
 716         if (player.ammo_cells < g_pickup_cells_max)
 717                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 718         if (need_fuel)
 719         if (item.ammo_fuel)
 720         if (player.ammo_fuel < g_pickup_fuel_max)
 721                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 722         if (item.armorvalue)
 723         if (player.armorvalue < item.max_armorvalue)
 724                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 725         if (item.health)
 726         if (player.health < item.max_health)
 727                 c = c + max(0, 1 - player.health / item.max_health);
 728
 729         return item.bot_pickupbasevalue * c;
 730 }
 731
 732
 733 .float is_item;
 734 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 735 {
 736         startitem_failed = FALSE;
 737
 738         self.items = itemid;
 739         self.weapon = weaponid;
 740         if(weaponid)
 741                 WEPSET_COPY_EW(self, weaponid);
 742         self.flags = FL_ITEM | itemflags;
 743
 744         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 745         {
 746                 startitem_failed = TRUE;
 747                 remove(self);
 748                 return;
 749         }
 750
 751         // is it a dropped weapon?
 752         if (self.classname == "droppedweapon")
 753         {
 754                 self.reset = SUB_Remove;
 755                 // it's a dropped weapon
 756                 self.movetype = MOVETYPE_TOSS;
 757
 758                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 759                 self.think = RemoveItem;
 760                 self.nextthink = time + 20;
 761
 762                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
 763                 /*
 764                 if(self.items == 0)
 765                 if(WEPSET_CONTAINS_ALL_AE(WEPBIT_SUPERWEAPONS, self)) // only superweapons
 766                 if(self.ammo_nails == 0)
 767                 if(self.ammo_cells == 0)
 768                 if(self.ammo_rockets == 0)
 769                 if(self.ammo_shells == 0)
 770                 if(self.ammo_fuel == 0)
 771                 if(self.health == 0)
 772                 if(self.armorvalue == 0)
 773                 */
 774                 {
 775                         // if item is worthless after a timer, have it expire then
 776                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
 777                 }
 778
 779                 // don't drop if in a NODROP zone (such as lava)
 780                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 781                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 782                 {
 783                         startitem_failed = TRUE;
 784                         remove(self);
 785                         return;
 786                 }
 787         }
 788         else
 789         {
 790                 if(!have_pickup_item())
 791                 {
 792                         startitem_failed = TRUE;
 793                         remove (self);
 794                         return;
 795                 }
 796
 797                 if(self.model != "")
 798                         itemmodel = self.model;
 799                 if(self.item_pickupsound != "")
 800                         pickupsound = self.item_pickupsound;
 801
 802                 self.reset = Item_Reset;
 803                 // it's a level item
 804                 if(self.spawnflags & 1)
 805                         self.noalign = 1;
 806                 if (self.noalign)
 807                         self.movetype = MOVETYPE_NONE;
 808                 else
 809                         self.movetype = MOVETYPE_TOSS;
 810                 // do item filtering according to game mode and other things
 811                 if (!self.noalign)
 812                 {
 813                         // first nudge it off the floor a little bit to avoid math errors
 814                         setorigin(self, self.origin + '0 0 1');
 815                         // set item size before we spawn a spawnfunc_waypoint
 816                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 817                                 setsize (self, '-16 -16 0', '16 16 48');
 818                         else
 819                                 setsize (self, '-16 -16 0', '16 16 32');
 820                         // note droptofloor returns FALSE if stuck/or would fall too far
 821                         droptofloor();
 822                         waypoint_spawnforitem(self);
 823                 }
 824
 825                 /*
 826                  * can't do it that way, as it would break maps
 827                  * TODO make a target_give like entity another way, that perhaps has
 828                  * the weapon name in a key
 829                 if(self.targetname)
 830                 {
 831                         // target_give not yet supported; maybe later
 832                         print("removed targeted ", self.classname, "\n");
 833                         startitem_failed = TRUE;
 834                         remove (self);
 835                         return;
 836                 }
 837                 */
 838
 839                 if(autocvar_spawn_debug >= 2)
 840                 {
 841                         entity otheritem;
 842                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 843                         {
 844                                 if(otheritem.is_item)
 845                                 {
 846                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 847                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 848                                         error("Mapper sucks.");
 849                                 }
 850                         }
 851                         self.is_item = TRUE;
 852                 }
 853
 854                 WEPSET_OR_AW(weaponsInMap, weaponid);
 855
 856                 precache_model (itemmodel);
 857                 precache_sound (pickupsound);
 858
 859                 precache_sound ("misc/itemrespawncountdown.wav");
 860                 if(!g_minstagib && itemid == IT_STRENGTH)
 861                         precache_sound ("misc/strength_respawn.wav");
 862                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 863                         precache_sound ("misc/shield_respawn.wav");
 864                 else
 865                         precache_sound ("misc/itemrespawn.wav");
 866
 867                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 868                         self.target = "###item###"; // for finding the nearest item using find()
 869         }
 870
 871         self.bot_pickup = TRUE;
 872         self.bot_pickupevalfunc = pickupevalfunc;
 873         self.bot_pickupbasevalue = pickupbasevalue;
 874         self.mdl = itemmodel;
 875         self.item_pickupsound = pickupsound;
 876         // let mappers override respawntime
 877         if(!self.respawntime) // both set
 878         {
 879                 self.respawntime = defaultrespawntime;
 880                 self.respawntimejitter = defaultrespawntimejitter;
 881         }
 882         self.netname = itemname;
 883         self.touch = Item_Touch;
 884         setmodel (self, self.mdl); // precision set below
 885         self.effects |= EF_LOWPRECISION;
 886         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 887                 setsize (self, '-16 -16 0', '16 16 48');
 888         else
 889                 setsize (self, '-16 -16 0', '16 16 32');
 890         if(itemflags & FL_WEAPON)
 891                 self.modelflags |= MF_ROTATE;
 892
 893         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 894         if (itemflags & FL_WEAPON)
 895         {
 896                 // neutral team color for pickup weapons
 897                 self.colormap = 1024; // color shirt=0 pants=0 grey
 898         }
 899
 900         self.state = 0;
 901         if(self.team)
 902         {
 903                 if(!self.cnt)
 904                         self.cnt = 1; // item probability weight
 905                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 906                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 907         }
 908         else
 909                 Item_Reset();
 910 }
 911
 912 /* replace items in minstagib
 913  * IT_STRENGTH   = invisibility
 914  * IT_NAILS      = extra lives
 915  * IT_INVINCIBLE = speed
 916  */
 917 void minstagib_items (float itemid)
 918 {
 919         float rnd;
 920         self.classname = "minstagib";
 921
 922         // replace rocket launchers and nex guns with ammo cells
 923         if (itemid == IT_CELLS)
 924         {
 925                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
 926                 StartItem ("models/items/a_cells.md3",
 927                         "misc/itempickup.wav", 45, 0,
 928                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 929                 return;
 930         }
 931
 932         // randomize
 933         rnd = random() * 3;
 934         if (rnd <= 1)
 935                 itemid = IT_STRENGTH;
 936         else if (rnd <= 2)
 937                 itemid = IT_NAILS;
 938         else
 939                 itemid = IT_INVINCIBLE;
 940
 941         // replace with invis
 942         if (itemid == IT_STRENGTH)
 943         {
 944                 if(!self.strength_finished)
 945                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
 946                 StartItem ("models/items/g_strength.md3",
 947                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 948                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 949         }
 950         // replace with extra lives
 951         if (itemid == IT_NAILS)
 952         {
 953                 self.max_health = 1;
 954                 StartItem ("models/items/g_h100.md3",
 955                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 956                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 957         }
 958         // replace with speed
 959         if (itemid == IT_INVINCIBLE)
 960         {
 961                 if(!self.invincible_finished)
 962                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
 963                 StartItem ("models/items/g_invincible.md3",
 964                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 965                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 966         }
 967 }
 968
 969 float minst_no_auto_cells;
 970 void minst_remove_item (void) {
 971         if(minst_no_auto_cells)
 972                 remove(self);
 973 }
 974
 975 float weaponswapping;
 976 float internalteam;
 977
 978 void weapon_defaultspawnfunc(float wpn)
 979 {
 980         entity e;
 981         float t;
 982         var .float ammofield;
 983         string s;
 984         entity oldself;
 985         float i, j;
 986         float f;
 987
 988         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 989         {
 990                 e = get_weaponinfo(wpn);
 991                 s = W_Apply_Weaponreplace(e.netname);
 992                 ret_string = s;
 993                 other = e;
 994                 MUTATOR_CALLHOOK(SetWeaponreplace);
 995                 s = ret_string;
 996                 if(s == "")
 997                 {
 998                         remove(self);
 999                         startitem_failed = TRUE;
1000                         return;
1001                 }
1002                 t = tokenize_console(s);
1003                 if(t >= 2)
1004                 {
1005                         self.team = --internalteam;
1006                         oldself = self;
1007                         for(i = 1; i < t; ++i)
1008                         {
1009                                 s = argv(i);
1010                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1011                                 {
1012                                         e = get_weaponinfo(j);
1013                                         if(e.netname == s)
1014                                         {
1015                                                 self = spawn();
1016                                                 copyentity(oldself, self);
1017                                                 self.classname = "replacedweapon";
1018                                                 weapon_defaultspawnfunc(j);
1019                                                 break;
1020                                         }
1021                                 }
1022                                 if(j > WEP_LAST)
1023                                 {
1024                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1025                                 }
1026                         }
1027                         self = oldself;
1028                 }
1029                 if(t >= 1) // always the case!
1030                 {
1031                         s = argv(0);
1032                         wpn = 0;
1033                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1034                         {
1035                                 e = get_weaponinfo(j);
1036                                 if(e.netname == s)
1037                                 {
1038                                         wpn = j;
1039                                         break;
1040                                 }
1041                         }
1042                         if(j > WEP_LAST)
1043                         {
1044                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1045                         }
1046                 }
1047                 if(wpn == 0)
1048                 {
1049                         remove(self);
1050                         startitem_failed = TRUE;
1051                         return;
1052                 }
1053         }
1054
1055         e = get_weaponinfo(wpn);
1056
1057         if(!self.respawntime)
1058         {
1059                 if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1060                 {
1061                         self.respawntime = g_pickup_respawntime_superweapon;
1062                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1063                 }
1064                 else
1065                 {
1066                         self.respawntime = g_pickup_respawntime_weapon;
1067                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1068                 }
1069         }
1070
1071         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1072                 if(!self.superweapons_finished)
1073                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1074
1075         if(e.items)
1076         {
1077                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1078                 {
1079                         if(e.items & j)
1080                         {
1081                                 ammofield = Item_CounterField(j);
1082                                 if(!self.ammofield)
1083                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1084                         }
1085                 }
1086         }
1087
1088         // pickup anyway
1089         if(g_pickup_weapons_anyway)
1090                 self.pickup_anyway = TRUE;
1091
1092         f = FL_WEAPON;
1093
1094         // no weapon-stay on superweapons
1095         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1096                 f |= FL_NO_WEAPON_STAY;
1097
1098         // weapon stay isn't supported for teamed weapons
1099         if(self.team)
1100                 f |= FL_NO_WEAPON_STAY;
1101
1102         self.item_pickupsound = "weapons/weaponpickup.wav";
1103         StartItem(e.model, self.item_pickupsound, self.respawntime, self.respawntimejitter, e.message, 0, e.weapon, f, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1104         if (self.modelindex) // don't precache if self was removed
1105                 weapon_action(e.weapon, WR_PRECACHE);
1106 }
1107
1108 void spawnfunc_weapon_shotgun (void);
1109 void spawnfunc_weapon_uzi (void) {
1110         if(autocvar_sv_q3acompat_machineshotgunswap)
1111         if(self.classname != "droppedweapon")
1112         {
1113                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1114                 return;
1115         }
1116         weapon_defaultspawnfunc(WEP_UZI);
1117 }
1118
1119 void spawnfunc_weapon_shotgun (void) {
1120         if(autocvar_sv_q3acompat_machineshotgunswap)
1121         if(self.classname != "droppedweapon")
1122         {
1123                 weapon_defaultspawnfunc(WEP_UZI);
1124                 return;
1125         }
1126         weapon_defaultspawnfunc(WEP_SHOTGUN);
1127 }
1128
1129 void spawnfunc_weapon_nex (void)
1130 {
1131         if (g_minstagib)
1132         {
1133                 minstagib_items(IT_CELLS);
1134                 self.think = minst_remove_item;
1135                 self.nextthink = time;
1136                 return;
1137         }
1138         weapon_defaultspawnfunc(WEP_NEX);
1139 }
1140
1141 void spawnfunc_weapon_minstanex (void)
1142 {
1143         if (g_minstagib)
1144         {
1145                 minstagib_items(IT_CELLS);
1146                 self.think = minst_remove_item;
1147                 self.nextthink = time;
1148                 return;
1149         }
1150         weapon_defaultspawnfunc(WEP_MINSTANEX);
1151 }
1152
1153 void spawnfunc_weapon_rocketlauncher (void)
1154 {
1155         if (g_minstagib)
1156         {
1157                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1158                 self.think = minst_remove_item;
1159                 self.nextthink = time;
1160                 return;
1161         }
1162         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1163 }
1164
1165 void spawnfunc_item_rockets (void) {
1166         if(!self.ammo_rockets)
1167                 self.ammo_rockets = g_pickup_rockets;
1168         if(!self.pickup_anyway)
1169                 self.pickup_anyway = g_pickup_ammo_anyway;
1170         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1171 }
1172
1173 void spawnfunc_item_shells (void);
1174 void spawnfunc_item_bullets (void) {
1175         if(!weaponswapping)
1176         if(autocvar_sv_q3acompat_machineshotgunswap)
1177         if(self.classname != "droppedweapon")
1178         {
1179                 weaponswapping = TRUE;
1180                 spawnfunc_item_shells();
1181                 weaponswapping = FALSE;
1182                 return;
1183         }
1184
1185         if(!self.ammo_nails)
1186                 self.ammo_nails = g_pickup_nails;
1187         if(!self.pickup_anyway)
1188                 self.pickup_anyway = g_pickup_ammo_anyway;
1189         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1190 }
1191
1192 void spawnfunc_item_cells (void) {
1193         if(!self.ammo_cells)
1194                 self.ammo_cells = g_pickup_cells;
1195         if(!self.pickup_anyway)
1196                 self.pickup_anyway = g_pickup_ammo_anyway;
1197         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1198 }
1199
1200 void spawnfunc_item_shells (void) {
1201         if(!weaponswapping)
1202         if(autocvar_sv_q3acompat_machineshotgunswap)
1203         if(self.classname != "droppedweapon")
1204         {
1205                 weaponswapping = TRUE;
1206                 spawnfunc_item_bullets();
1207                 weaponswapping = FALSE;
1208                 return;
1209         }
1210
1211         if(!self.ammo_shells)
1212                 self.ammo_shells = g_pickup_shells;
1213         if(!self.pickup_anyway)
1214                 self.pickup_anyway = g_pickup_ammo_anyway;
1215         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1216 }
1217
1218 void spawnfunc_item_armor_small (void) {
1219         if(!self.armorvalue)
1220                 self.armorvalue = g_pickup_armorsmall;
1221         if(!self.max_armorvalue)
1222                 self.max_armorvalue = g_pickup_armorsmall_max;
1223         if(!self.pickup_anyway)
1224                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1225         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1226 }
1227
1228 void spawnfunc_item_armor_medium (void) {
1229         if(!self.armorvalue)
1230                 self.armorvalue = g_pickup_armormedium;
1231         if(!self.max_armorvalue)
1232                 self.max_armorvalue = g_pickup_armormedium_max;
1233         if(!self.pickup_anyway)
1234                 self.pickup_anyway = g_pickup_armormedium_anyway;
1235         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1236 }
1237
1238 void spawnfunc_item_armor_big (void) {
1239         if(!self.armorvalue)
1240                 self.armorvalue = g_pickup_armorbig;
1241         if(!self.max_armorvalue)
1242                 self.max_armorvalue = g_pickup_armorbig_max;
1243         if(!self.pickup_anyway)
1244                 self.pickup_anyway = g_pickup_armorbig_anyway;
1245         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1246 }
1247
1248 void spawnfunc_item_armor_large (void) {
1249         if(!self.armorvalue)
1250                 self.armorvalue = g_pickup_armorlarge;
1251         if(!self.max_armorvalue)
1252                 self.max_armorvalue = g_pickup_armorlarge_max;
1253         if(!self.pickup_anyway)
1254                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1255         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1256 }
1257
1258 void spawnfunc_item_health_small (void) {
1259         if(!self.max_health)
1260                 self.max_health = g_pickup_healthsmall_max;
1261         if(!self.health)
1262                 self.health = g_pickup_healthsmall;
1263         if(!self.pickup_anyway)
1264                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1265         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1266 }
1267
1268 void spawnfunc_item_health_medium (void) {
1269         if(!self.max_health)
1270                 self.max_health = g_pickup_healthmedium_max;
1271         if(!self.health)
1272                 self.health = g_pickup_healthmedium;
1273         if(!self.pickup_anyway)
1274                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1275         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1276 }
1277
1278 void spawnfunc_item_health_large (void) {
1279         if(!self.max_health)
1280                 self.max_health = g_pickup_healthlarge_max;
1281         if(!self.health)
1282                 self.health = g_pickup_healthlarge;
1283         if(!self.pickup_anyway)
1284                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1285         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1286 }
1287
1288 void spawnfunc_item_health_mega (void) {
1289         if(g_minstagib) {
1290                 minstagib_items(IT_NAILS);
1291         } else {
1292                 if(!self.max_health)
1293                         self.max_health = g_pickup_healthmega_max;
1294                 if(!self.health)
1295                         self.health = g_pickup_healthmega;
1296                 if(!self.pickup_anyway)
1297                         self.pickup_anyway = g_pickup_healthmega_anyway;
1298                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1299         }
1300 }
1301
1302 // support old misnamed entities
1303 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1304 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1305 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1306 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1307 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1308
1309 void spawnfunc_item_strength (void) {
1310         if(g_minstagib) {
1311                 minstagib_items(IT_STRENGTH);
1312         } else {
1313                 precache_sound("weapons/strength_fire.wav");
1314                 if(!self.strength_finished)
1315                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1316                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1317         }
1318 }
1319
1320 void spawnfunc_item_invincible (void) {
1321         if(g_minstagib) {
1322                 minstagib_items(IT_INVINCIBLE);
1323         } else {
1324                 if(!self.invincible_finished)
1325                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1326                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1327         }
1328 }
1329
1330 void spawnfunc_item_minst_cells (void) {
1331         if (g_minstagib)
1332         {
1333                 minst_no_auto_cells = 1;
1334                 minstagib_items(IT_CELLS);
1335         }
1336         else
1337                 remove(self);
1338 }
1339
1340 // compatibility:
1341 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1342
1343 float GiveItems(entity e, float beginarg, float endarg);
1344 void target_items_use (void)
1345 {
1346         if(activator.classname == "droppedweapon")
1347         {
1348                 EXACTTRIGGER_TOUCH;
1349                 remove(activator);
1350                 return;
1351         }
1352
1353         if(activator.classname != "player")
1354                 return;
1355         if(activator.deadflag != DEAD_NO)
1356                 return;
1357         EXACTTRIGGER_TOUCH;
1358
1359         entity e;
1360         for(e = world; (e = find(e, classname, "droppedweapon")); )
1361                 if(e.enemy == activator)
1362                         remove(e);
1363
1364         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1365                 centerprint(activator, self.message);
1366 }
1367
1368 void spawnfunc_target_items (void)
1369 {
1370         float n, i, j;
1371         entity e;
1372
1373         self.use = target_items_use;
1374         if(!self.strength_finished)
1375                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1376         if(!self.invincible_finished)
1377                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1378         if(!self.superweapons_finished)
1379                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1380
1381         precache_sound("misc/itempickup.wav");
1382         precache_sound("misc/megahealth.wav");
1383         precache_sound("misc/armor25.wav");
1384         precache_sound("misc/powerup.wav");
1385         precache_sound("misc/poweroff.wav");
1386         precache_sound("weapons/weaponpickup.wav");
1387
1388         n = tokenize_console(self.netname);
1389         if(argv(0) == "give")
1390         {
1391                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1392         }
1393         else
1394         {
1395                 for(i = 0; i < n; ++i)
1396                 {
1397                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1398                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1399                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1400                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1401                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1402                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1403                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1404                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1405                         else
1406                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1407                         {
1408                                 e = get_weaponinfo(j);
1409                                 if(argv(i) == e.netname)
1410                                 {
1411                                         WEPSET_OR_EW(self, j);
1412                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1413                                                 weapon_action(e.weapon, WR_PRECACHE);
1414                                         break;
1415                                 }
1416                         }
1417                         if(j > WEP_LAST)
1418                                 print("target_items: invalid item ", argv(i), "\n");
1419                 }
1420
1421                 string itemprefix, valueprefix;
1422                 if(self.spawnflags == 0)
1423                 {
1424                         itemprefix = "";
1425                         valueprefix = "";
1426                 }
1427                 else if(self.spawnflags == 1)
1428                 {
1429                         itemprefix = "max ";
1430                         valueprefix = "max ";
1431                 }
1432                 else if(self.spawnflags == 2)
1433                 {
1434                         itemprefix = "min ";
1435                         valueprefix = "min ";
1436                 }
1437                 else if(self.spawnflags == 4)
1438                 {
1439                         itemprefix = "minus ";
1440                         valueprefix = "max ";
1441                 }
1442                 else
1443                         error("invalid spawnflags");
1444
1445                 self.netname = "";
1446                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1447                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1448                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1449                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1450                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1451                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1452                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1453                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1454                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1455                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1456                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1457                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1458                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1459                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1460                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1461                 {
1462                         e = get_weaponinfo(j);
1463                         if(e.weapon)
1464                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, WEPSET_CONTAINS_EW(self, j), e.netname);
1465                 }
1466         }
1467         self.netname = strzone(self.netname);
1468         //print(self.netname, "\n");
1469
1470         n = tokenize_console(self.netname);
1471         for(i = 0; i < n; ++i)
1472         {
1473                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1474                 {
1475                         e = get_weaponinfo(j);
1476                         if(argv(i) == e.netname)
1477                         {
1478                                 weapon_action(e.weapon, WR_PRECACHE);
1479                                 break;
1480                         }
1481                 }
1482         }
1483 }
1484
1485 void spawnfunc_item_fuel(void)
1486 {
1487         if(!self.ammo_fuel)
1488                 self.ammo_fuel = g_pickup_fuel;
1489         if(!self.pickup_anyway)
1490                 self.pickup_anyway = g_pickup_ammo_anyway;
1491         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1492 }
1493
1494 void spawnfunc_item_fuel_regen(void)
1495 {
1496         if(start_items & IT_FUEL_REGEN)
1497         {
1498                 spawnfunc_item_fuel();
1499                 return;
1500         }
1501         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1502 }
1503
1504 void spawnfunc_item_jetpack(void)
1505 {
1506         if(g_grappling_hook)
1507                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1508         if(!self.ammo_fuel)
1509                 self.ammo_fuel = g_pickup_fuel_jetpack;
1510         if(start_items & IT_JETPACK)
1511         {
1512                 spawnfunc_item_fuel();
1513                 return;
1514         }
1515         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1516 }
1517
1518
1519 #define OP_SET 0
1520 #define OP_MIN 1
1521 #define OP_MAX 2
1522 #define OP_PLUS 3
1523 #define OP_MINUS 4
1524
1525 float GiveWeapon(entity e, float wpn, float op, float val)
1526 {
1527         float v0, v1;
1528         v0 = WEPSET_CONTAINS_EW(e, wpn);
1529         switch(op)
1530         {
1531                 case OP_SET:
1532                         if(val > 0)
1533                                 WEPSET_OR_EW(e, wpn);
1534                         else
1535                                 WEPSET_ANDNOT_EW(e, wpn);
1536                         break;
1537                 case OP_MIN:
1538                 case OP_PLUS:
1539                         if(val > 0)
1540                                 WEPSET_OR_EW(e, wpn);
1541                         break;
1542                 case OP_MAX:
1543                         if(val <= 0)
1544                                 WEPSET_ANDNOT_EW(e, wpn);
1545                         break;
1546                 case OP_MINUS:
1547                         if(val > 0)
1548                                 WEPSET_ANDNOT_EW(e, wpn);
1549                         break;
1550         }
1551         v1 = WEPSET_CONTAINS_EW(e, wpn);
1552         return (v0 != v1);
1553 }
1554
1555 float GiveBit(entity e, .float fld, float bit, float op, float val)
1556 {
1557         float v0, v1;
1558         v0 = (e.fld & bit);
1559         switch(op)
1560         {
1561                 case OP_SET:
1562                         if(val > 0)
1563                                 e.fld |= bit;
1564                         else
1565                                 e.fld &~= bit;
1566                         break;
1567                 case OP_MIN:
1568                 case OP_PLUS:
1569                         if(val > 0)
1570                                 e.fld |= bit;
1571                         break;
1572                 case OP_MAX:
1573                         if(val <= 0)
1574                                 e.fld &~= bit;
1575                         break;
1576                 case OP_MINUS:
1577                         if(val > 0)
1578                                 e.fld &~= bit;
1579                         break;
1580         }
1581         v1 = (e.fld & bit);
1582         return (v0 != v1);
1583 }
1584
1585 float GiveValue(entity e, .float fld, float op, float val)
1586 {
1587         float v0, v1;
1588         v0 = e.fld;
1589         switch(op)
1590         {
1591                 case OP_SET:
1592                         e.fld = val;
1593                         break;
1594                 case OP_MIN:
1595                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1596                         break;
1597                 case OP_MAX:
1598                         e.fld = min(e.fld, val);
1599                         break;
1600                 case OP_PLUS:
1601                         e.fld += val;
1602                         break;
1603                 case OP_MINUS:
1604                         e.fld -= val;
1605                         break;
1606         }
1607         v1 = e.fld;
1608         return (v0 != v1);
1609 }
1610
1611 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1612 {
1613         if(v1 == v0)
1614                 return;
1615         if(v1 <= v0 - t)
1616         {
1617                 if(snd_decr != "")
1618                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1619         }
1620         else if(v0 >= v0 + t)
1621         {
1622                 if(snd_incr != "")
1623                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1624         }
1625 }
1626
1627 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1628 {
1629         if(v0 < v1)
1630                 e.rotfield = max(e.rotfield, time + rottime);
1631         else if(v0 > v1)
1632                 e.regenfield = max(e.regenfield, time + regentime);
1633 }
1634
1635 #define PREGIVE_WEAPONS(e) WEPSET_DECLARE_A(save_weapons); WEPSET_COPY_AE(save_weapons, e)
1636 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1637 #define POSTGIVE_WEAPON(e,b,snd_incr,snd_decr) GiveSound((e), WEPSET_CONTAINS_AW(save_weapons, b), WEPSET_CONTAINS_EW(e, b), 0, snd_incr, snd_decr)
1638 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1639 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1640 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1641
1642 float GiveItems(entity e, float beginarg, float endarg)
1643 {
1644         float got, i, j, val, op;
1645         float _switchweapon;
1646         entity wi;
1647         string cmd;
1648
1649         val = 999;
1650         op = OP_SET;
1651
1652         got = 0;
1653
1654         _switchweapon = FALSE;
1655         if (e.autoswitch)
1656                 if (e.switchweapon == w_getbestweapon(e))
1657                         _switchweapon = TRUE;
1658
1659         e.strength_finished = max(0, e.strength_finished - time);
1660         e.invincible_finished = max(0, e.invincible_finished - time);
1661         e.superweapons_finished = max(0, e.superweapons_finished - time);
1662
1663         PREGIVE(e, items);
1664         PREGIVE_WEAPONS(e);
1665         PREGIVE(e, strength_finished);
1666         PREGIVE(e, invincible_finished);
1667         PREGIVE(e, superweapons_finished);
1668         PREGIVE(e, ammo_nails);
1669         PREGIVE(e, ammo_cells);
1670         PREGIVE(e, ammo_shells);
1671         PREGIVE(e, ammo_rockets);
1672         PREGIVE(e, ammo_fuel);
1673         PREGIVE(e, armorvalue);
1674         PREGIVE(e, health);
1675
1676         for(i = beginarg; i < endarg; ++i)
1677         {
1678                 cmd = argv(i);
1679
1680                 if(cmd == "0" || stof(cmd))
1681                 {
1682                         val = stof(cmd);
1683                         continue;
1684                 }
1685                 switch(cmd)
1686                 {
1687                         case "no":
1688                                 op = OP_MAX;
1689                                 val = 0;
1690                                 continue;
1691                         case "max":
1692                                 op = OP_MAX;
1693                                 continue;
1694                         case "min":
1695                                 op = OP_MIN;
1696                                 continue;
1697                         case "plus":
1698                                 op = OP_PLUS;
1699                                 continue;
1700                         case "minus":
1701                                 op = OP_MINUS;
1702                                 continue;
1703                         case "ALL":
1704                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1705                                 got += GiveValue(e, strength_finished, op, val);
1706                                 got += GiveValue(e, invincible_finished, op, val);
1707                                 got += GiveValue(e, superweapons_finished, op, val);
1708                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1709                         case "all":
1710                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1711                                 got += GiveValue(e, health, op, val);
1712                                 got += GiveValue(e, armorvalue, op, val);
1713                         case "allweapons":
1714                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1715                                 {
1716                                         wi = get_weaponinfo(j);
1717                                         if(wi.weapon)
1718                                                 if not(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1719                                                         got += GiveWeapon(e, j, op, val);
1720                                 }
1721                         case "allammo":
1722                                 got += GiveValue(e, ammo_cells, op, val);
1723                                 got += GiveValue(e, ammo_shells, op, val);
1724                                 got += GiveValue(e, ammo_nails, op, val);
1725                                 got += GiveValue(e, ammo_rockets, op, val);
1726                                 got += GiveValue(e, ammo_fuel, op, val);
1727                                 break;
1728                         case "unlimited_ammo":
1729                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1730                                 break;
1731                         case "unlimited_weapon_ammo":
1732                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1733                                 break;
1734                         case "unlimited_superweapons":
1735                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1736                                 break;
1737                         case "jetpack":
1738                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1739                                 break;
1740                         case "fuel_regen":
1741                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1742                                 break;
1743                         case "strength":
1744                                 got += GiveValue(e, strength_finished, op, val);
1745                                 break;
1746                         case "invincible":
1747                                 got += GiveValue(e, invincible_finished, op, val);
1748                                 break;
1749                         case "superweapons":
1750                                 got += GiveValue(e, superweapons_finished, op, val);
1751                                 break;
1752                         case "cells":
1753                                 got += GiveValue(e, ammo_cells, op, val);
1754                                 break;
1755                         case "shells":
1756                                 got += GiveValue(e, ammo_shells, op, val);
1757                                 break;
1758                         case "nails":
1759                         case "bullets":
1760                                 got += GiveValue(e, ammo_nails, op, val);
1761                                 break;
1762                         case "rockets":
1763                                 got += GiveValue(e, ammo_rockets, op, val);
1764                                 break;
1765                         case "health":
1766                                 got += GiveValue(e, health, op, val);
1767                                 break;
1768                         case "armor":
1769                                 got += GiveValue(e, armorvalue, op, val);
1770                                 break;
1771                         case "fuel":
1772                                 got += GiveValue(e, ammo_fuel, op, val);
1773                                 break;
1774                         default:
1775                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1776                                 {
1777                                         wi = get_weaponinfo(j);
1778                                         if(cmd == wi.netname)
1779                                         {
1780                                                 got += GiveWeapon(e, j, op, val);
1781                                                 break;
1782                                         }
1783                                 }
1784                                 if(j > WEP_LAST)
1785                                         print("give: invalid item ", cmd, "\n");
1786                                 break;
1787                 }
1788                 val = 999;
1789                 op = OP_SET;
1790         }
1791
1792         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1793         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1794         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1795         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1796         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1797         {
1798                 wi = get_weaponinfo(j);
1799                 if(wi.weapon)
1800                 {
1801                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
1802                         if not(WEPSET_CONTAINS_AW(save_weapons, j))
1803                                 if(WEPSET_CONTAINS_EW(e, j))
1804                                         weapon_action(wi.weapon, WR_PRECACHE);
1805                 }
1806         }
1807         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1808         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1809         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1810         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1811         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1812         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1813         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1814         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1815         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1816
1817         if(e.superweapons_finished <= 0)
1818                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1819                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1820
1821         if (g_minstagib)
1822         {
1823                 e.health = bound(0, e.health, 100);
1824                 e.armorvalue = bound(0, e.armorvalue, 999);
1825         }
1826
1827         if(e.strength_finished <= 0)
1828                 e.strength_finished = 0;
1829         else
1830                 e.strength_finished += time;
1831         if(e.invincible_finished <= 0)
1832                 e.invincible_finished = 0;
1833         else
1834                 e.invincible_finished += time;
1835         if(e.superweapons_finished <= 0)
1836                 e.superweapons_finished = 0;
1837         else
1838                 e.superweapons_finished += time;
1839
1840         if not(WEPSET_CONTAINS_EW(e, e.switchweapon))
1841                 _switchweapon = TRUE;
1842         if(_switchweapon)
1843                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1844
1845         return got;
1846 }