qcsrc/server/t_items.qc

   1 float have_pickup_item(void)
   2 {
   3         // minstagib: only allow filtered items
   4         if(g_minstagib)
   5                 if(self.classname != "minstagib")
   6                         return FALSE;
   7
   8         if(self.items == IT_STRENGTH || self.items == IT_INVINCIBLE)
   9         {
  10                 if(autocvar_g_powerups > 0)
  11                         return TRUE;
  12                 if(autocvar_g_powerups == 0)
  13                         return FALSE;
  14                 if(g_lms)
  15                         return FALSE;
  16                 if(g_ca)
  17                         return FALSE;
  18                 if(g_arena)
  19                         return FALSE;
  20         }
  21         else
  22         {
  23                 if(autocvar_g_pickup_items > 0)
  24                         return TRUE;
  25                 if(autocvar_g_pickup_items == 0)
  26                         return FALSE;
  27                 if(g_lms)
  28                         return FALSE;
  29                 if(g_ca)
  30                         return FALSE;
  31                 if(g_weaponarena)
  32                         if((self.weapons & WEPBIT_ALL) || (self.items & IT_AMMO))
  33                                 return FALSE;
  34         }
  35         return TRUE;
  36 }
  37
  38 #define ITEM_RESPAWN_TICKS 10
  39
  40 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
  41         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
  42 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
  43         // range: 10 .. respawntime + respawntimejitter
  44
  45 floatfield Item_CounterField(float it)
  46 {
  47         switch(it)
  48         {
  49                 case IT_SHELLS:      return ammo_shells;
  50                 case IT_NAILS:       return ammo_nails;
  51                 case IT_ROCKETS:     return ammo_rockets;
  52                 case IT_CELLS:       return ammo_cells;
  53                 case IT_FUEL:        return ammo_fuel;
  54                 case IT_5HP:         return health;
  55                 case IT_25HP:        return health;
  56                 case IT_HEALTH:      return health;
  57                 case IT_ARMOR_SHARD: return armorvalue;
  58                 case IT_ARMOR:       return armorvalue;
  59                 // add more things here (health, armor)
  60                 default:             error("requested item has no counter field");
  61         }
  62 }
  63
  64 string Item_CounterFieldName(float it)
  65 {
  66         switch(it)
  67         {
  68                 case IT_SHELLS:      return "shells";
  69                 case IT_NAILS:       return "nails";
  70                 case IT_ROCKETS:     return "rockets";
  71                 case IT_CELLS:       return "cells";
  72                 case IT_FUEL:        return "fuel";
  73
  74                 // add more things here (health, armor)
  75                 default:             error("requested item has no counter field name");
  76         }
  77 }
  78
  79 .float max_armorvalue;
  80 .float pickup_anyway;
  81
  82 float Item_Customize()
  83 {
  84         if(self.spawnshieldtime)
  85                 return TRUE;
  86         if(self.weapons != (self.weapons & other.weapons))
  87         {
  88                 self.colormod = '0 0 0';
  89                 self.glowmod = self.colormod;
  90                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  91                 return TRUE;
  92         }
  93         else
  94         {
  95                 if(g_ghost_items)
  96                 {
  97                         self.colormod = stov(autocvar_g_ghost_items_color);
  98                         self.glowmod = self.colormod;
  99                         self.alpha = g_ghost_items;
 100                         return TRUE;
 101                 }
 102                 else
 103                         return FALSE;
 104         }
 105 }
 106
 107 void Item_Show (entity e, float mode)
 108 {
 109         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 110         if (mode > 0)
 111         {
 112                 // make the item look normal, and be touchable
 113                 e.model = e.mdl;
 114                 e.solid = SOLID_TRIGGER;
 115                 e.colormod = '0 0 0';
 116                 self.glowmod = self.colormod;
 117                 e.alpha = 0;
 118                 e.customizeentityforclient = func_null;
 119
 120                 e.spawnshieldtime = 1;
 121         }
 122         else if (mode < 0)
 123         {
 124                 // hide the item completely
 125                 e.model = string_null;
 126                 e.solid = SOLID_NOT;
 127                 e.colormod = '0 0 0';
 128                 self.glowmod = self.colormod;
 129                 e.alpha = 0;
 130                 e.customizeentityforclient = func_null;
 131
 132                 e.spawnshieldtime = 1;
 133         }
 134         else if((e.flags & FL_WEAPON) && g_weapon_stay)
 135         {
 136                 // make the item translucent and not touchable
 137                 e.model = e.mdl;
 138                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 139                 e.colormod = '0 0 0';
 140                 self.glowmod = self.colormod;
 141                 e.effects |= EF_STARDUST;
 142                 e.customizeentityforclient = Item_Customize;
 143
 144                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 145         }
 146         else if(g_ghost_items)
 147         {
 148                 // make the item translucent and not touchable
 149                 e.model = e.mdl;
 150                 e.solid = SOLID_NOT;
 151                 e.colormod = stov(autocvar_g_ghost_items_color);
 152                 e.glowmod = e.colormod;
 153                 e.alpha = g_ghost_items;
 154                 e.customizeentityforclient = func_null;
 155
 156                 e.spawnshieldtime = 1;
 157         }
 158         else
 159         {
 160                 // hide the item completely
 161                 e.model = string_null;
 162                 e.solid = SOLID_NOT;
 163                 e.colormod = '0 0 0';
 164                 e.glowmod = e.colormod;
 165                 e.alpha = 0;
 166                 e.customizeentityforclient = func_null;
 167
 168                 e.spawnshieldtime = 1;
 169         }
 170
 171         if (e.strength_finished || e.invincible_finished)
 172                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 173         if (autocvar_g_nodepthtestitems)
 174                 e.effects |= EF_NODEPTHTEST;
 175         if (autocvar_g_fullbrightitems)
 176                 e.effects |= EF_FULLBRIGHT;
 177
 178         // relink entity (because solid may have changed)
 179         setorigin(e, e.origin);
 180 }
 181
 182 void Item_Respawn (void)
 183 {
 184         Item_Show(self, 1);
 185         if(!g_minstagib && self.items == IT_STRENGTH)
 186                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 187         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 188                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 189         else
 190                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 191         setorigin (self, self.origin);
 192
 193         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 194         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 195 }
 196
 197 void Item_RespawnCountdown (void)
 198 {
 199         if(self.count >= ITEM_RESPAWN_TICKS)
 200         {
 201                 if(self.waypointsprite_attached)
 202                         WaypointSprite_Kill(self.waypointsprite_attached);
 203                 Item_Respawn();
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 self.count += 1;
 209                 if(self.count == 1)
 210                 {
 211                         string name;
 212                         vector rgb;
 213                         name = string_null;
 214                         if(g_minstagib)
 215                         {
 216                                 switch(self.items)
 217                                 {
 218                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 219                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 220                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 221                                 }
 222                         }
 223                         else
 224                         {
 225                                 switch(self.items)
 226                                 {
 227                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 228                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 229                                 }
 230                         }
 231                         switch(self.items)
 232                         {
 233                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 234                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 235                         }
 236                         if(name)
 237                         {
 238                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 239                                 if(self.waypointsprite_attached)
 240                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 241                         }
 242                 }
 243                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 244                 if(self.waypointsprite_attached)
 245                 {
 246                         WaypointSprite_Ping(self.waypointsprite_attached);
 247                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 248                 }
 249         }
 250 }
 251
 252 void Item_ScheduleRespawnIn(entity e, float t)
 253 {
 254         if(e.flags & FL_POWERUP)
 255         {
 256                 e.think = Item_RespawnCountdown;
 257                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 258                 e.count = 0;
 259         }
 260         else
 261         {
 262                 e.think = Item_Respawn;
 263                 e.nextthink = time + t;
 264         }
 265 }
 266
 267 void Item_ScheduleRespawn(entity e)
 268 {
 269         if(e.respawntime > 0)
 270         {
 271                 Item_Show(e, 0);
 272                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 273         }
 274         else // if respawntime is -1, this item does not respawn
 275                 Item_Show(e, -1);
 276 }
 277
 278 void Item_ScheduleInitialRespawn(entity e)
 279 {
 280         Item_Show(e, 0);
 281         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 282 }
 283
 284 float Item_GiveTo(entity item, entity player)
 285 {
 286         float _switchweapon;
 287         float pickedup;
 288         float it;
 289         float i;
 290         entity e;
 291
 292         // if nothing happens to player, just return without taking the item
 293         pickedup = FALSE;
 294         _switchweapon = FALSE;
 295
 296         if (g_minstagib)
 297         {
 298                 float prevcells = player.ammo_cells;
 299
 300                 if(item.spawnshieldtime)
 301                 {
 302                         if (item.ammo_fuel)
 303                         if (player.ammo_fuel < g_pickup_fuel_max)
 304                         {
 305                                 pickedup = TRUE;
 306                                 player.ammo_fuel = bound(player.ammo_fuel, g_pickup_fuel_max, player.ammo_fuel + item.ammo_fuel);
 307                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 308                         }
 309
 310                         if (item.ammo_cells)
 311                         if (player.ammo_cells < g_pickup_cells_max)
 312                         {
 313                                 pickedup = TRUE;
 314                                 player.ammo_cells = bound(player.ammo_cells, g_pickup_cells_max, player.ammo_cells + item.ammo_cells);
 315                         }
 316                 }
 317
 318                 if(player.ammo_cells > prevcells)
 319                 {
 320                         _switchweapon = TRUE;
 321
 322                         // play some cool sounds ;)
 323                         if (clienttype(player) == CLIENTTYPE_REAL)
 324                         {
 325                                 if(player.health <= 5)
 326                                         AnnounceTo(player, "lastsecond");
 327                                 else if(player.health < 50)
 328                                         AnnounceTo(player, "narrowly");
 329                         }
 330                         // sound not available
 331                         // else if(item.items == IT_CELLS)
 332                         //      AnnounceTo(player, "ammo");
 333
 334                         if (item.weapons & WEPBIT_MINSTANEX)
 335                                 W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 336                         if (item.ammo_cells)
 337                                 player.ammo_cells = bound(player.ammo_cells, 999, player.ammo_cells + autocvar_g_minstagib_ammo_drop);
 338                         player.health = 100;
 339                 }
 340
 341                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 342                 {
 343                         pickedup = TRUE;
 344                         player.items |= it;
 345                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 346                 }
 347
 348                 // extralife powerup
 349                 if (item.max_health)
 350                 {
 351                         pickedup = TRUE;
 352                         // sound not available
 353                         // AnnounceTo(player, "_lives");
 354                         player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 355                         sprint(player, "^3You picked up some extra lives\n");
 356                 }
 357
 358                 // invis powerup
 359                 if (item.strength_finished)
 360                 {
 361                         pickedup = TRUE;
 362                         // sound not available
 363                         // AnnounceTo(player, "invisible");
 364                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 365                 }
 366
 367                 // speed powerup
 368                 if (item.invincible_finished)
 369                 {
 370                         pickedup = TRUE;
 371                         // sound not available
 372                         // AnnounceTo(player, "speed");
 373                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_strength_time;
 374                 }
 375         }
 376         else
 377         {
 378                 // in case the player has autoswitch enabled do the following:
 379                 // if the player is using their best weapon before items are given, they
 380                 // probably want to switch to an even better weapon after items are given
 381                 if (player.autoswitch)
 382                 if (player.switchweapon == w_getbestweapon(player))
 383                         _switchweapon = TRUE;
 384
 385                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 386                         _switchweapon = TRUE;
 387
 388                 if(item.spawnshieldtime)
 389                 {
 390                         if (item.ammo_shells)
 391                         if ((player.ammo_shells < g_pickup_shells_max) || item.pickup_anyway)
 392                         {
 393                                 pickedup = TRUE;
 394                                 player.ammo_shells = bound(player.ammo_shells, g_pickup_shells_max, player.ammo_shells + item.ammo_shells);
 395                         }
 396                         if (item.ammo_nails)
 397                         if ((player.ammo_nails < g_pickup_nails_max) || item.pickup_anyway)
 398                         {
 399                                 pickedup = TRUE;
 400                                 player.ammo_nails = bound(player.ammo_nails, g_pickup_nails_max, player.ammo_nails + item.ammo_nails);
 401                         }
 402                         if (item.ammo_rockets)
 403                         if ((player.ammo_rockets < g_pickup_rockets_max) || item.pickup_anyway)
 404                         {
 405                                 pickedup = TRUE;
 406                                 player.ammo_rockets = bound(player.ammo_rockets, g_pickup_rockets_max, player.ammo_rockets + item.ammo_rockets);
 407                         }
 408                         if (item.ammo_cells)
 409                         if ((player.ammo_cells < g_pickup_cells_max) || item.pickup_anyway)
 410                         {
 411                                 pickedup = TRUE;
 412                                 player.ammo_cells = bound(player.ammo_cells, g_pickup_cells_max, player.ammo_cells + item.ammo_cells);
 413                         }
 414                         if (item.ammo_fuel)
 415                         if ((player.ammo_fuel < g_pickup_fuel_max) || item.pickup_anyway)
 416                         {
 417                                 pickedup = TRUE;
 418                                 player.ammo_fuel = bound(player.ammo_fuel, g_pickup_fuel_max, player.ammo_fuel + item.ammo_fuel);
 419                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 420                         }
 421                 }
 422
 423                 if (item.flags & FL_WEAPON)
 424                 if ((it = item.weapons - (item.weapons & player.weapons)) || (g_pickup_weapons_anyway))
 425                 {
 426                         pickedup = TRUE;
 427                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 428                         {
 429                                 e = get_weaponinfo(i);
 430                                 if(it & e.weapons)
 431                                         W_GiveWeapon (player, e.weapon, item.netname);
 432                         }
 433                 }
 434
 435                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 436                 {
 437                         pickedup = TRUE;
 438                         player.items |= it;
 439                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 440                 }
 441
 442                         if (item.strength_finished)
 443                 {
 444                         pickedup = TRUE;
 445                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 446                 }
 447                 if (item.invincible_finished)
 448                 {
 449                         pickedup = TRUE;
 450                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_invincible_time;
 451                 }
 452
 453                 if (item.health)
 454                 if ((player.health < item.max_health) || item.pickup_anyway)
 455                 {
 456                         pickedup = TRUE;
 457                         player.health = bound(player.health, item.max_health, player.health + item.health);
 458                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 459                 }
 460                 if (item.armorvalue)
 461                 if ((player.armorvalue < item.max_armorvalue) || item.pickup_anyway)
 462                 {
 463                         pickedup = TRUE;
 464                         player.armorvalue = bound(player.armorvalue, item.max_armorvalue, player.armorvalue + item.armorvalue);
 465                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 466                 }
 467         }
 468
 469 :skip
 470         // always eat teamed entities
 471         if(item.team)
 472                 pickedup = TRUE;
 473
 474         if (!pickedup)
 475                 return 0;
 476
 477         sound (player, CH_TRIGGER, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 478         if (_switchweapon)
 479                 if (player.switchweapon != w_getbestweapon(player))
 480                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 481
 482         return 1;
 483 }
 484
 485 void Item_Touch (void)
 486 {
 487         entity e, head;
 488
 489         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 490         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 491         {
 492                 remove(self);
 493                 return;
 494         }
 495         if (other.classname != "player")
 496                 return;
 497         if (other.deadflag)
 498                 return;
 499         if (self.solid != SOLID_TRIGGER)
 500                 return;
 501         if (self.owner == other)
 502                 return;
 503
 504         if(!Item_GiveTo(self, other))
 505                 return;
 506
 507         other.last_pickup = time;
 508
 509         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 510
 511         if (self.classname == "droppedweapon")
 512                 remove (self);
 513         else if not(self.spawnshieldtime)
 514                 return;
 515         else
 516         {
 517                 if(self.team)
 518                 {
 519                         RandomSelection_Init();
 520                         for(head = world; (head = findfloat(head, team, self.team)); )
 521                         {
 522                                 if(head.flags & FL_ITEM)
 523                                 {
 524                                         Item_Show(head, -1);
 525                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 526                                 }
 527                         }
 528                         e = RandomSelection_chosen_ent;
 529                 }
 530                 else
 531                         e = self;
 532                 Item_ScheduleRespawn(e);
 533         }
 534 }
 535
 536 void Item_FindTeam()
 537 {
 538         entity head, e;
 539
 540         if(self.effects & EF_NODRAW)
 541         {
 542                 // marker for item team search
 543                 dprint("Initializing item team ", ftos(self.team), "\n");
 544                 RandomSelection_Init();
 545                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 546                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 547                 e = RandomSelection_chosen_ent;
 548                 e.state = 0;
 549                 Item_Show(e, 1);
 550
 551                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 552                 {
 553                         if(head != e)
 554                         {
 555                                 // make it a non-spawned item
 556                                 Item_Show(head, -1);
 557                                 head.state = 1; // state 1 = initially hidden item
 558                         }
 559                         head.effects &~= EF_NODRAW;
 560                 }
 561
 562                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 563                         Item_ScheduleInitialRespawn(e);
 564         }
 565 }
 566
 567 void Item_Reset()
 568 {
 569         Item_Show(self, !self.state);
 570         setorigin (self, self.origin);
 571         self.think = SUB_Null;
 572         self.nextthink = 0;
 573
 574         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 575                 Item_ScheduleInitialRespawn(self);
 576 }
 577
 578 // Savage: used for item garbage-collection
 579 // TODO: perhaps nice special effect?
 580 void RemoveItem(void)
 581 {
 582         remove(self);
 583 }
 584
 585 // pickup evaluation functions
 586 // these functions decide how desirable an item is to the bots
 587
 588 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 589
 590 float weapon_pickupevalfunc(entity player, entity item)
 591 {
 592         float c, i, j, position;
 593
 594         // See if I have it already
 595         if(player.weapons & item.weapons == item.weapons)
 596         {
 597                 // If I can pick it up
 598                 if(!item.spawnshieldtime)
 599                         c = 0;
 600                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 601                 {
 602                         // Skilled bots will grab more
 603                         c = bound(0, skill / 10, 1) * 0.5;
 604                 }
 605                 else
 606                         c = 0;
 607         }
 608         else
 609                 c = 1;
 610
 611         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 612         if( bot_custom_weapon && c )
 613         {
 614                 for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 615                 {
 616                         // Find weapon
 617                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 618                                 continue;
 619
 620                         // Find the highest position on any range
 621                         position = -1;
 622                         for(j = 0; j < WEP_LAST ; ++j){
 623                                 if(
 624                                                 bot_weapons_far[j] == i ||
 625                                                 bot_weapons_mid[j] == i ||
 626                                                 bot_weapons_close[j] == i
 627                                   )
 628                                 {
 629                                         position = j;
 630                                         break;
 631                                 }
 632                         }
 633
 634                         // Rate it
 635                         if (position >= 0 )
 636                         {
 637                                 position = WEP_LAST - position;
 638                                 // item.bot_pickupbasevalue is overwritten here
 639                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 640                         }
 641                 }
 642         }
 643
 644         return item.bot_pickupbasevalue * c;
 645 }
 646
 647 float commodity_pickupevalfunc(entity player, entity item)
 648 {
 649         float c, i, need_shells, need_nails, need_rockets, need_cells;
 650         entity wi;
 651         c = 0;
 652
 653         // Detect needed ammo
 654         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 655         {
 656                 wi = get_weaponinfo(i);
 657
 658                 if not(wi.weapons & player.weapons)
 659                         continue;
 660
 661                 if(wi.items & IT_SHELLS)
 662                         need_shells = TRUE;
 663                 else if(wi.items & IT_NAILS)
 664                         need_nails = TRUE;
 665                 else if(wi.items & IT_ROCKETS)
 666                         need_rockets = TRUE;
 667                 else if(wi.items & IT_CELLS)
 668                         need_cells = TRUE;
 669         }
 670
 671         // TODO: figure out if the player even has the weapon this ammo is for?
 672         // may not affect strategy much though...
 673         // find out how much more ammo/armor/health the player can hold
 674         if (need_shells)
 675         if (item.ammo_shells)
 676         if (player.ammo_shells < g_pickup_shells_max)
 677                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 678         if (need_nails)
 679         if (item.ammo_nails)
 680         if (player.ammo_nails < g_pickup_nails_max)
 681                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 682         if (need_rockets)
 683         if (item.ammo_rockets)
 684         if (player.ammo_rockets < g_pickup_rockets_max)
 685                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 686         if (need_cells)
 687         if (item.ammo_cells)
 688         if (player.ammo_cells < g_pickup_cells_max)
 689                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 690         if (item.armorvalue)
 691         if (player.armorvalue < item.max_armorvalue)
 692                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 693         if (item.health)
 694         if (player.health < item.max_health)
 695                 c = c + max(0, 1 - player.health / item.max_health);
 696
 697         return item.bot_pickupbasevalue * c;
 698 }
 699
 700
 701 .float is_item;
 702 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 703 {
 704         startitem_failed = FALSE;
 705
 706         self.items = itemid;
 707         self.weapons = weaponid;
 708
 709         // is it a dropped weapon?
 710         if (self.classname == "droppedweapon")
 711         {
 712                 self.reset = SUB_Remove;
 713                 // it's a dropped weapon
 714                 self.movetype = MOVETYPE_TOSS;
 715                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 716                 self.think = RemoveItem;
 717                 self.nextthink = time + 60;
 718                 // don't drop if in a NODROP zone (such as lava)
 719                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 720                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 721                 {
 722                         startitem_failed = TRUE;
 723                         remove(self);
 724                         return;
 725                 }
 726         }
 727         else
 728         {
 729                 if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 730                 {
 731                         startitem_failed = TRUE;
 732                         remove(self);
 733                         return;
 734                 }
 735
 736                 if(!have_pickup_item())
 737                 {
 738                         startitem_failed = TRUE;
 739                         remove (self);
 740                         return;
 741                 }
 742
 743                 self.reset = Item_Reset;
 744                 // it's a level item
 745                 if(self.spawnflags & 1)
 746                         self.noalign = 1;
 747                 if (self.noalign)
 748                         self.movetype = MOVETYPE_NONE;
 749                 else
 750                         self.movetype = MOVETYPE_TOSS;
 751                 // do item filtering according to game mode and other things
 752                 if (!self.noalign)
 753                 {
 754                         // first nudge it off the floor a little bit to avoid math errors
 755                         setorigin(self, self.origin + '0 0 1');
 756                         // set item size before we spawn a spawnfunc_waypoint
 757                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 758                                 setsize (self, '-16 -16 0', '16 16 48');
 759                         else
 760                                 setsize (self, '-16 -16 0', '16 16 32');
 761                         // note droptofloor returns FALSE if stuck/or would fall too far
 762                         droptofloor();
 763                         waypoint_spawnforitem(self);
 764                 }
 765
 766                 /*
 767                  * can't do it that way, as it would break maps
 768                  * TODO make a target_give like entity another way, that perhaps has
 769                  * the weapon name in a key
 770                 if(self.targetname)
 771                 {
 772                         // target_give not yet supported; maybe later
 773                         print("removed targeted ", self.classname, "\n");
 774                         startitem_failed = TRUE;
 775                         remove (self);
 776                         return;
 777                 }
 778                 */
 779
 780                 if(autocvar_spawn_debug >= 2)
 781                 {
 782                         entity otheritem;
 783                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 784                         {
 785                                 if(otheritem.is_item)
 786                                 {
 787                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 788                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 789                                         error("Mapper sucks.");
 790                                 }
 791                         }
 792                         self.is_item = TRUE;
 793                 }
 794
 795                 weaponsInMap |= weaponid;
 796
 797                 precache_model (itemmodel);
 798                 precache_sound (pickupsound);
 799
 800                 precache_sound ("misc/itemrespawncountdown.wav");
 801                 if(!g_minstagib && itemid == IT_STRENGTH)
 802                         precache_sound ("misc/strength_respawn.wav");
 803                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 804                         precache_sound ("misc/shield_respawn.wav");
 805                 else
 806                         precache_sound ("misc/itemrespawn.wav");
 807
 808                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 809                         self.target = "###item###"; // for finding the nearest item using find()
 810         }
 811
 812         self.bot_pickup = TRUE;
 813         self.bot_pickupevalfunc = pickupevalfunc;
 814         self.bot_pickupbasevalue = pickupbasevalue;
 815         self.mdl = itemmodel;
 816         self.item_pickupsound = pickupsound;
 817         // let mappers override respawntime
 818         if(!self.respawntime) // both set
 819         {
 820                 self.respawntime = defaultrespawntime;
 821                 self.respawntimejitter = defaultrespawntimejitter;
 822         }
 823         self.netname = itemname;
 824         self.flags = FL_ITEM | itemflags;
 825         self.touch = Item_Touch;
 826         setmodel (self, self.mdl); // precision set below
 827         self.effects |= EF_LOWPRECISION;
 828         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 829                 setsize (self, '-16 -16 0', '16 16 48');
 830         else
 831                 setsize (self, '-16 -16 0', '16 16 32');
 832         if(itemflags & FL_WEAPON)
 833                 self.modelflags |= MF_ROTATE;
 834
 835         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 836         if (itemflags & FL_WEAPON)
 837         {
 838                 // neutral team color for pickup weapons
 839                 self.colormap = 1024; // color shirt=0 pants=0 grey
 840         }
 841
 842         Item_Show(self, 1);
 843         self.state = 0;
 844         if(self.team)
 845         {
 846                 if(!self.cnt)
 847                         self.cnt = 1; // item probability weight
 848                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 849                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 850         }
 851         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 852                 Item_ScheduleInitialRespawn(self);
 853 }
 854
 855 /* replace items in minstagib
 856  * IT_STRENGTH   = invisibility
 857  * IT_NAILS      = extra lives
 858  * IT_INVINCIBLE = speed
 859  */
 860 void minstagib_items (float itemid)
 861 {
 862         float rnd;
 863         self.classname = "minstagib";
 864
 865         // replace rocket launchers and nex guns with ammo cells
 866         if (itemid == IT_CELLS)
 867         {
 868                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
 869                 StartItem ("models/items/a_cells.md3",
 870                         "misc/itempickup.wav", 45, 0,
 871                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 872                 return;
 873         }
 874
 875         // randomize
 876         rnd = random() * 3;
 877         if (rnd <= 1)
 878                 itemid = IT_STRENGTH;
 879         else if (rnd <= 2)
 880                 itemid = IT_NAILS;
 881         else
 882                 itemid = IT_INVINCIBLE;
 883
 884         // replace with invis
 885         if (itemid == IT_STRENGTH)
 886         {
 887                 self.strength_finished = 30;
 888                 StartItem ("models/items/g_strength.md3",
 889                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 890                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 891         }
 892         // replace with extra lives
 893         if (itemid == IT_NAILS)
 894         {
 895                 self.max_health = 1;
 896                 StartItem ("models/items/g_h100.md3",
 897                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 898                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 899         }
 900         // replace with speed
 901         if (itemid == IT_INVINCIBLE)
 902         {
 903                 self.invincible_finished = 30;
 904                 StartItem ("models/items/g_invincible.md3",
 905                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 906                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 907         }
 908 }
 909
 910 float minst_no_auto_cells;
 911 void minst_remove_item (void) {
 912         if(minst_no_auto_cells)
 913                 remove(self);
 914 }
 915
 916 float weaponswapping;
 917 float internalteam;
 918
 919 void weapon_defaultspawnfunc(float wpn)
 920 {
 921         entity e;
 922         float t;
 923         var .float ammofield;
 924         string s;
 925         entity oldself;
 926         float i, j;
 927
 928         // set the respawntime in advance (so replaced weapons can copy it)
 929
 930         if(!self.respawntime)
 931         {
 932                 e = get_weaponinfo(wpn);
 933                 if(e.items == IT_SUPERWEAPON)
 934                 {
 935                         self.respawntime = g_pickup_respawntime_powerup;
 936                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
 937                 }
 938                 else
 939                 {
 940                         self.respawntime = g_pickup_respawntime_weapon;
 941                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
 942                 }
 943         }
 944
 945         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 946         {
 947                 e = get_weaponinfo(wpn);
 948                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 949                 if(s == "0")
 950                 {
 951                         remove(self);
 952                         startitem_failed = TRUE;
 953                         return;
 954                 }
 955                 t = tokenize_console(s);
 956                 if(t >= 2)
 957                 {
 958                         self.team = --internalteam;
 959                         oldself = self;
 960                         for(i = 1; i < t; ++i)
 961                         {
 962                                 s = argv(i);
 963                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 964                                 {
 965                                         e = get_weaponinfo(j);
 966                                         if(e.netname == s)
 967                                         {
 968                                                 self = spawn();
 969                                                 copyentity(oldself, self);
 970                                                 self.classname = "replacedweapon";
 971                                                 weapon_defaultspawnfunc(j);
 972                                                 break;
 973                                         }
 974                                 }
 975                                 if(j > WEP_LAST)
 976                                 {
 977                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 978                                 }
 979                         }
 980                         self = oldself;
 981                 }
 982                 if(t >= 1)
 983                 {
 984                         s = argv(0);
 985                         wpn = 0;
 986                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 987                         {
 988                                 e = get_weaponinfo(j);
 989                                 if(e.netname == s)
 990                                 {
 991                                         wpn = j;
 992                                         break;
 993                                 }
 994                         }
 995                         if(j > WEP_LAST)
 996                         {
 997                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 998                         }
 999                 }
1000                 if(wpn == 0)
1001                 {
1002                         remove(self);
1003                         startitem_failed = TRUE;
1004                         return;
1005                 }
1006         }
1007
1008         e = get_weaponinfo(wpn);
1009
1010         if(e.items && e.items != IT_SUPERWEAPON)
1011         {
1012                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1013                 {
1014                         if(e.items & j)
1015                         {
1016                                 ammofield = Item_CounterField(j);
1017                                 if(!self.ammofield)
1018                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1019                         }
1020                 }
1021         }
1022         else
1023         {
1024                 self.flags |= FL_NO_WEAPON_STAY;
1025         }
1026
1027         // weapon stay isn't supported for teamed weapons
1028         if(self.team)
1029                 self.flags |= FL_NO_WEAPON_STAY;
1030
1031         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1032         if (self.modelindex) // don't precache if self was removed
1033                 weapon_action(e.weapon, WR_PRECACHE);
1034 }
1035
1036 void spawnfunc_weapon_shotgun (void);
1037 void spawnfunc_weapon_uzi (void) {
1038         if(autocvar_sv_q3acompat_machineshotgunswap)
1039         if(self.classname != "droppedweapon")
1040         {
1041                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1042                 return;
1043         }
1044         weapon_defaultspawnfunc(WEP_UZI);
1045 }
1046
1047 void spawnfunc_weapon_shotgun (void) {
1048         if(autocvar_sv_q3acompat_machineshotgunswap)
1049         if(self.classname != "droppedweapon")
1050         {
1051                 weapon_defaultspawnfunc(WEP_UZI);
1052                 return;
1053         }
1054         weapon_defaultspawnfunc(WEP_SHOTGUN);
1055 }
1056
1057 void spawnfunc_weapon_nex (void)
1058 {
1059         if (g_minstagib)
1060         {
1061                 minstagib_items(IT_CELLS);
1062                 self.think = minst_remove_item;
1063                 self.nextthink = time;
1064                 return;
1065         }
1066         weapon_defaultspawnfunc(WEP_NEX);
1067 }
1068
1069 void spawnfunc_weapon_minstanex (void)
1070 {
1071         if (g_minstagib)
1072         {
1073                 minstagib_items(IT_CELLS);
1074                 self.think = minst_remove_item;
1075                 self.nextthink = time;
1076                 return;
1077         }
1078         weapon_defaultspawnfunc(WEP_MINSTANEX);
1079 }
1080
1081 void spawnfunc_weapon_rocketlauncher (void)
1082 {
1083         if (g_minstagib)
1084         {
1085                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1086                 self.think = minst_remove_item;
1087                 self.nextthink = time;
1088                 return;
1089         }
1090         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1091 }
1092
1093 void spawnfunc_item_rockets (void) {
1094         if(!self.ammo_rockets)
1095                 self.ammo_rockets = g_pickup_rockets;
1096         if(!self.pickup_anyway)
1097                 self.pickup_anyway = g_pickup_ammo_anyway;
1098         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1099 }
1100
1101 void spawnfunc_item_shells (void);
1102 void spawnfunc_item_bullets (void) {
1103         if(!weaponswapping)
1104         if(autocvar_sv_q3acompat_machineshotgunswap)
1105         if(self.classname != "droppedweapon")
1106         {
1107                 weaponswapping = TRUE;
1108                 spawnfunc_item_shells();
1109                 weaponswapping = FALSE;
1110                 return;
1111         }
1112
1113         if(!self.ammo_nails)
1114                 self.ammo_nails = g_pickup_nails;
1115         if(!self.pickup_anyway)
1116                 self.pickup_anyway = g_pickup_ammo_anyway;
1117         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1118 }
1119
1120 void spawnfunc_item_cells (void) {
1121         if(!self.ammo_cells)
1122                 self.ammo_cells = g_pickup_cells;
1123         if(!self.pickup_anyway)
1124                 self.pickup_anyway = g_pickup_ammo_anyway;
1125         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1126 }
1127
1128 void spawnfunc_item_shells (void) {
1129         if(!weaponswapping)
1130         if(autocvar_sv_q3acompat_machineshotgunswap)
1131         if(self.classname != "droppedweapon")
1132         {
1133                 weaponswapping = TRUE;
1134                 spawnfunc_item_bullets();
1135                 weaponswapping = FALSE;
1136                 return;
1137         }
1138
1139         if(!self.ammo_shells)
1140                 self.ammo_shells = g_pickup_shells;
1141         if(!self.pickup_anyway)
1142                 self.pickup_anyway = g_pickup_ammo_anyway;
1143         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1144 }
1145
1146 void spawnfunc_item_armor_small (void) {
1147         if(!self.armorvalue)
1148                 self.armorvalue = g_pickup_armorsmall;
1149         if(!self.max_armorvalue)
1150                 self.max_armorvalue = g_pickup_armorsmall_max;
1151         if(!self.pickup_anyway)
1152                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1153         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1154 }
1155
1156 void spawnfunc_item_armor_medium (void) {
1157         if(!self.armorvalue)
1158                 self.armorvalue = g_pickup_armormedium;
1159         if(!self.max_armorvalue)
1160                 self.max_armorvalue = g_pickup_armormedium_max;
1161         if(!self.pickup_anyway)
1162                 self.pickup_anyway = g_pickup_armormedium_anyway;
1163         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1164 }
1165
1166 void spawnfunc_item_armor_big (void) {
1167         if(!self.armorvalue)
1168                 self.armorvalue = g_pickup_armorbig;
1169         if(!self.max_armorvalue)
1170                 self.max_armorvalue = g_pickup_armorbig_max;
1171         if(!self.pickup_anyway)
1172                 self.pickup_anyway = g_pickup_armorbig_anyway;
1173         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1174 }
1175
1176 void spawnfunc_item_armor_large (void) {
1177         if(!self.armorvalue)
1178                 self.armorvalue = g_pickup_armorlarge;
1179         if(!self.max_armorvalue)
1180                 self.max_armorvalue = g_pickup_armorlarge_max;
1181         if(!self.pickup_anyway)
1182                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1183         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1184 }
1185
1186 void spawnfunc_item_health_small (void) {
1187         if(!self.max_health)
1188                 self.max_health = g_pickup_healthsmall_max;
1189         if(!self.health)
1190                 self.health = g_pickup_healthsmall;
1191         if(!self.pickup_anyway)
1192                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1193         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1194 }
1195
1196 void spawnfunc_item_health_medium (void) {
1197         if(!self.max_health)
1198                 self.max_health = g_pickup_healthmedium_max;
1199         if(!self.health)
1200                 self.health = g_pickup_healthmedium;
1201         if(!self.pickup_anyway)
1202                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1203         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1204 }
1205
1206 void spawnfunc_item_health_large (void) {
1207         if(!self.max_health)
1208                 self.max_health = g_pickup_healthlarge_max;
1209         if(!self.health)
1210                 self.health = g_pickup_healthlarge;
1211         if(!self.pickup_anyway)
1212                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1213         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1214 }
1215
1216 void spawnfunc_item_health_mega (void) {
1217         if(g_minstagib) {
1218                 minstagib_items(IT_NAILS);
1219         } else {
1220                 if(!self.max_health)
1221                         self.max_health = g_pickup_healthmega_max;
1222                 if(!self.health)
1223                         self.health = g_pickup_healthmega;
1224                 if(!self.pickup_anyway)
1225                         self.pickup_anyway = g_pickup_healthmega_anyway;
1226                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1227         }
1228 }
1229
1230 // support old misnamed entities
1231 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1232 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1233 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1234 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1235 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1236
1237 void spawnfunc_item_strength (void) {
1238         if(g_minstagib) {
1239                 minstagib_items(IT_STRENGTH);
1240         } else {
1241                 precache_sound("weapons/strength_fire.wav");
1242                 self.strength_finished = 30;
1243                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1244         }
1245 }
1246
1247 void spawnfunc_item_invincible (void) {
1248         if(g_minstagib) {
1249                 minstagib_items(IT_INVINCIBLE);
1250         } else {
1251                 self.invincible_finished = 30;
1252                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1253         }
1254 }
1255
1256 void spawnfunc_item_minst_cells (void) {
1257         if (g_minstagib)
1258         {
1259                 minst_no_auto_cells = 1;
1260                 minstagib_items(IT_CELLS);
1261         }
1262         else
1263                 remove(self);
1264 }
1265
1266 // compatibility:
1267 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1268
1269 float GiveItems(entity e, float beginarg, float endarg);
1270 void target_items_use (void)
1271 {
1272         if(activator.classname == "droppedweapon")
1273         {
1274                 EXACTTRIGGER_TOUCH;
1275                 remove(activator);
1276                 return;
1277         }
1278
1279         if(activator.classname != "player")
1280                 return;
1281         if(activator.deadflag != DEAD_NO)
1282                 return;
1283         EXACTTRIGGER_TOUCH;
1284
1285         entity e;
1286         for(e = world; (e = find(e, classname, "droppedweapon")); )
1287                 if(e.enemy == activator)
1288                         remove(e);
1289
1290         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1291                 centerprint(activator, self.message);
1292 }
1293
1294 void spawnfunc_target_items (void)
1295 {
1296         float n, i, j;
1297         entity e;
1298
1299         self.use = target_items_use;
1300         if(!self.strength_finished)
1301                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1302         if(!self.invincible_finished)
1303                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1304
1305         precache_sound("misc/itempickup.wav");
1306         precache_sound("misc/megahealth.wav");
1307         precache_sound("misc/armor25.wav");
1308         precache_sound("misc/powerup.wav");
1309         precache_sound("misc/poweroff.wav");
1310         precache_sound("weapons/weaponpickup.wav");
1311
1312         n = tokenize_console(self.netname);
1313         if(argv(0) == "give")
1314         {
1315                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1316         }
1317         else
1318         {
1319                 for(i = 0; i < n; ++i)
1320                 {
1321                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1322                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1323                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1324                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1325                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1326                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1327                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1328                         else
1329                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1330                         {
1331                                 e = get_weaponinfo(j);
1332                                 if(argv(i) == e.netname)
1333                                 {
1334                                         self.weapons |= e.weapons;
1335                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1336                                                 weapon_action(e.weapon, WR_PRECACHE);
1337                                         break;
1338                                 }
1339                         }
1340                         if(j > WEP_LAST)
1341                                 print("target_items: invalid item ", argv(i), "\n");
1342                 }
1343
1344                 string itemprefix, valueprefix;
1345                 if(self.spawnflags == 0)
1346                 {
1347                         itemprefix = "";
1348                         valueprefix = "";
1349                 }
1350                 else if(self.spawnflags == 1)
1351                 {
1352                         itemprefix = "max ";
1353                         valueprefix = "max ";
1354                 }
1355                 else if(self.spawnflags == 2)
1356                 {
1357                         itemprefix = "min ";
1358                         valueprefix = "min ";
1359                 }
1360                 else if(self.spawnflags == 4)
1361                 {
1362                         itemprefix = "minus ";
1363                         valueprefix = "max ";
1364                 }
1365                 else
1366                         error("invalid spawnflags");
1367
1368                 self.netname = "";
1369                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1370                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1371                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1372                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1373                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1374                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1375                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1376                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1377                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1378                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1379                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1380                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1381                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1382                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1383                 {
1384                         e = get_weaponinfo(j);
1385                         if(e.weapons)
1386                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1387                 }
1388         }
1389         self.netname = strzone(self.netname);
1390         //print(self.netname, "\n");
1391
1392         n = tokenize_console(self.netname);
1393         for(i = 0; i < n; ++i)
1394         {
1395                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1396                 {
1397                         e = get_weaponinfo(j);
1398                         if(argv(i) == e.netname)
1399                         {
1400                                 weapon_action(e.weapon, WR_PRECACHE);
1401                                 break;
1402                         }
1403                 }
1404         }
1405 }
1406
1407 void spawnfunc_item_fuel(void)
1408 {
1409         if(!self.ammo_fuel)
1410                 self.ammo_fuel = g_pickup_fuel;
1411         if(!self.pickup_anyway)
1412                 self.pickup_anyway = g_pickup_ammo_anyway;
1413         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1414 }
1415
1416 void spawnfunc_item_fuel_regen(void)
1417 {
1418         if(start_items & IT_FUEL_REGEN)
1419         {
1420                 spawnfunc_item_fuel();
1421                 return;
1422         }
1423         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1424 }
1425
1426 void spawnfunc_item_jetpack(void)
1427 {
1428         if(g_grappling_hook)
1429                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1430         if(!self.ammo_fuel)
1431                 self.ammo_fuel = g_pickup_fuel_jetpack;
1432         if(start_items & IT_JETPACK)
1433         {
1434                 spawnfunc_item_fuel();
1435                 return;
1436         }
1437         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1438 }
1439
1440
1441 #define OP_SET 0
1442 #define OP_MIN 1
1443 #define OP_MAX 2
1444 #define OP_PLUS 3
1445 #define OP_MINUS 4
1446
1447 float GiveBit(entity e, .float fld, float bit, float op, float val)
1448 {
1449         float v0, v1;
1450         v0 = (e.fld & bit);
1451         switch(op)
1452         {
1453                 case OP_SET:
1454                         if(val > 0)
1455                                 e.fld |= bit;
1456                         else
1457                                 e.fld &~= bit;
1458                         break;
1459                 case OP_MIN:
1460                 case OP_PLUS:
1461                         if(val > 0)
1462                                 e.fld |= bit;
1463                         break;
1464                 case OP_MAX:
1465                         if(val <= 0)
1466                                 e.fld &~= bit;
1467                         break;
1468                 case OP_MINUS:
1469                         if(val > 0)
1470                                 e.fld &~= bit;
1471                         break;
1472         }
1473         v1 = (e.fld & bit);
1474         return (v0 != v1);
1475 }
1476
1477 float GiveValue(entity e, .float fld, float op, float val)
1478 {
1479         float v0, v1;
1480         v0 = e.fld;
1481         switch(op)
1482         {
1483                 case OP_SET:
1484                         e.fld = val;
1485                         break;
1486                 case OP_MIN:
1487                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1488                         break;
1489                 case OP_MAX:
1490                         e.fld = min(e.fld, val);
1491                         break;
1492                 case OP_PLUS:
1493                         e.fld += val;
1494                         break;
1495                 case OP_MINUS:
1496                         e.fld -= val;
1497                         break;
1498         }
1499         v1 = e.fld;
1500         return (v0 != v1);
1501 }
1502
1503 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1504 {
1505         if(v1 == v0)
1506                 return;
1507         if(v1 <= v0 - t)
1508         {
1509                 if(snd_decr != "")
1510                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1511         }
1512         else if(v0 >= v0 + t)
1513         {
1514                 if(snd_incr != "")
1515                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1516         }
1517 }
1518
1519 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1520 {
1521         if(v0 < v1)
1522                 e.rotfield = max(e.rotfield, time + rottime);
1523         else if(v0 > v1)
1524                 e.regenfield = max(e.regenfield, time + regentime);
1525 }
1526
1527 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1528 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1529 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1530 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1531
1532 float GiveItems(entity e, float beginarg, float endarg)
1533 {
1534         float got, i, j, val, op;
1535         float _switchweapon;
1536         entity wi;
1537         string cmd;
1538
1539         val = 999;
1540         op = OP_SET;
1541
1542         got = 0;
1543
1544         _switchweapon = FALSE;
1545         if (e.autoswitch)
1546                 if (e.switchweapon == w_getbestweapon(e))
1547                         _switchweapon = TRUE;
1548
1549         e.strength_finished = max(0, e.strength_finished - time);
1550         e.invincible_finished = max(0, e.invincible_finished - time);
1551
1552         PREGIVE(e, items);
1553         PREGIVE(e, weapons);
1554         PREGIVE(e, strength_finished);
1555         PREGIVE(e, invincible_finished);
1556         PREGIVE(e, ammo_nails);
1557         PREGIVE(e, ammo_cells);
1558         PREGIVE(e, ammo_shells);
1559         PREGIVE(e, ammo_rockets);
1560         PREGIVE(e, ammo_fuel);
1561         PREGIVE(e, armorvalue);
1562         PREGIVE(e, health);
1563
1564         for(i = beginarg; i < endarg; ++i)
1565         {
1566                 cmd = argv(i);
1567
1568                 if(cmd == "0" || stof(cmd))
1569                 {
1570                         val = stof(cmd);
1571                         continue;
1572                 }
1573                 switch(cmd)
1574                 {
1575                         case "no":
1576                                 op = OP_MAX;
1577                                 val = 0;
1578                                 continue;
1579                         case "max":
1580                                 op = OP_MAX;
1581                                 continue;
1582                         case "min":
1583                                 op = OP_MIN;
1584                                 continue;
1585                         case "plus":
1586                                 op = OP_PLUS;
1587                                 continue;
1588                         case "minus":
1589                                 op = OP_MINUS;
1590                                 continue;
1591                         case "ALL":
1592                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1593                                 got += GiveValue(e, strength_finished, op, time);
1594                                 got += GiveValue(e, invincible_finished, op, time);
1595                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1596                         case "all":
1597                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1598                                 got += GiveValue(e, health, op, val);
1599                                 got += GiveValue(e, armorvalue, op, val);
1600                         case "allweapons":
1601                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1602                                 {
1603                                         wi = get_weaponinfo(j);
1604                                         if(wi.weapons)
1605                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1606                                 }
1607                         case "allammo":
1608                                 got += GiveValue(e, ammo_cells, op, val);
1609                                 got += GiveValue(e, ammo_shells, op, val);
1610                                 got += GiveValue(e, ammo_nails, op, val);
1611                                 got += GiveValue(e, ammo_rockets, op, val);
1612                                 got += GiveValue(e, ammo_fuel, op, val);
1613                                 break;
1614                         case "unlimited_ammo":
1615                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1616                                 break;
1617                         case "unlimited_weapon_ammo":
1618                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1619                                 break;
1620                         case "unlimited_superweapons":
1621                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1622                                 break;
1623                         case "jetpack":
1624                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1625                                 break;
1626                         case "fuel_regen":
1627                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1628                                 break;
1629                         case "strength":
1630                                 got += GiveValue(e, strength_finished, op, val);
1631                                 break;
1632                         case "invincible":
1633                                 got += GiveValue(e, invincible_finished, op, val);
1634                                 break;
1635                         case "cells":
1636                                 got += GiveValue(e, ammo_cells, op, val);
1637                                 break;
1638                         case "shells":
1639                                 got += GiveValue(e, ammo_shells, op, val);
1640                                 break;
1641                         case "nails":
1642                         case "bullets":
1643                                 got += GiveValue(e, ammo_nails, op, val);
1644                                 break;
1645                         case "rockets":
1646                                 got += GiveValue(e, ammo_rockets, op, val);
1647                                 break;
1648                         case "health":
1649                                 got += GiveValue(e, health, op, val);
1650                                 break;
1651                         case "armor":
1652                                 got += GiveValue(e, armorvalue, op, val);
1653                                 break;
1654                         case "fuel":
1655                                 got += GiveValue(e, ammo_fuel, op, val);
1656                                 break;
1657                         default:
1658                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1659                                 {
1660                                         wi = get_weaponinfo(j);
1661                                         if(cmd == wi.netname)
1662                                         {
1663                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1664                                                 break;
1665                                         }
1666                                 }
1667                                 if(j > WEP_LAST)
1668                                         print("give: invalid item ", cmd, "\n");
1669                                 break;
1670                 }
1671                 val = 999;
1672                 op = OP_SET;
1673         }
1674
1675         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1676         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1677         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1678         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1679         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1680         {
1681                 wi = get_weaponinfo(j);
1682                 if(wi.weapons)
1683                 {
1684                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1685                         if not(save_weapons & wi.weapons)
1686                                 if(e.weapons & wi.weapons)
1687                                         weapon_action(wi.weapon, WR_PRECACHE);
1688                 }
1689         }
1690         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1691         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1692         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1693         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1694         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1695         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1696         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1697         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1698         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1699
1700         if (g_minstagib)
1701         {
1702                 e.health = bound(0, e.health, 100);
1703                 e.armorvalue = bound(0, e.armorvalue, 999);
1704         }
1705
1706         if(e.strength_finished <= 0)
1707                 e.strength_finished = 0;
1708         else
1709                 e.strength_finished += time;
1710         if(e.invincible_finished <= 0)
1711                 e.invincible_finished = 0;
1712         else
1713                 e.invincible_finished += time;
1714
1715         if not(e.weapons & W_WeaponBit(e.switchweapon))
1716                 _switchweapon = TRUE;
1717         if(_switchweapon)
1718                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1719
1720         return got;
1721 }