qcsrc/server/t_items.qc

   1 float have_pickup_item(void)
   2 {
   3         // minstagib: only allow filtered items
   4         if(g_minstagib)
   5                 if(self.classname != "minstagib")
   6                         return FALSE;
   7
   8         if(self.flags & FL_POWERUP)
   9         {
  10                 if(autocvar_g_powerups > 0)
  11                         return TRUE;
  12                 if(autocvar_g_powerups == 0)
  13                         return FALSE;
  14                 if(g_lms)
  15                         return FALSE;
  16                 if(g_ca)
  17                         return FALSE;
  18                 if(g_arena)
  19                         return FALSE;
  20         }
  21         else
  22         {
  23                 if(autocvar_g_pickup_items > 0)
  24                         return TRUE;
  25                 if(autocvar_g_pickup_items == 0)
  26                         return FALSE;
  27                 if(g_lms)
  28                         return FALSE;
  29                 if(g_ca)
  30                         return FALSE;
  31                 if(g_weaponarena)
  32                         if((self.weapons & WEPBIT_ALL) || (self.items & IT_AMMO))
  33                                 return FALSE;
  34         }
  35         return TRUE;
  36 }
  37
  38 #define ITEM_RESPAWN_TICKS 10
  39
  40 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
  41         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
  42 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
  43         // range: 10 .. respawntime + respawntimejitter
  44
  45 floatfield Item_CounterField(float it)
  46 {
  47         switch(it)
  48         {
  49                 case IT_SHELLS:      return ammo_shells;
  50                 case IT_NAILS:       return ammo_nails;
  51                 case IT_ROCKETS:     return ammo_rockets;
  52                 case IT_CELLS:       return ammo_cells;
  53                 case IT_FUEL:        return ammo_fuel;
  54                 case IT_5HP:         return health;
  55                 case IT_25HP:        return health;
  56                 case IT_HEALTH:      return health;
  57                 case IT_ARMOR_SHARD: return armorvalue;
  58                 case IT_ARMOR:       return armorvalue;
  59                 // add more things here (health, armor)
  60                 default:             error("requested item has no counter field");
  61         }
  62 }
  63
  64 string Item_CounterFieldName(float it)
  65 {
  66         switch(it)
  67         {
  68                 case IT_SHELLS:      return "shells";
  69                 case IT_NAILS:       return "nails";
  70                 case IT_ROCKETS:     return "rockets";
  71                 case IT_CELLS:       return "cells";
  72                 case IT_FUEL:        return "fuel";
  73
  74                 // add more things here (health, armor)
  75                 default:             error("requested item has no counter field name");
  76         }
  77 }
  78
  79 .float max_armorvalue;
  80 .float pickup_anyway;
  81
  82 float Item_Customize()
  83 {
  84         if(self.spawnshieldtime)
  85                 return TRUE;
  86         if(self.weapons != (self.weapons & other.weapons))
  87         {
  88                 self.colormod = '0 0 0';
  89                 self.glowmod = self.colormod;
  90                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  91                 return TRUE;
  92         }
  93         else
  94         {
  95                 if(g_ghost_items)
  96                 {
  97                         self.colormod = stov(autocvar_g_ghost_items_color);
  98                         self.glowmod = self.colormod;
  99                         self.alpha = g_ghost_items;
 100                         return TRUE;
 101                 }
 102                 else
 103                         return FALSE;
 104         }
 105 }
 106
 107 void Item_Show (entity e, float mode)
 108 {
 109         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 110         if (mode > 0)
 111         {
 112                 // make the item look normal, and be touchable
 113                 e.model = e.mdl;
 114                 e.solid = SOLID_TRIGGER;
 115                 e.colormod = '0 0 0';
 116                 self.glowmod = self.colormod;
 117                 e.alpha = 0;
 118                 e.customizeentityforclient = func_null;
 119
 120                 e.spawnshieldtime = 1;
 121         }
 122         else if (mode < 0)
 123         {
 124                 // hide the item completely
 125                 e.model = string_null;
 126                 e.solid = SOLID_NOT;
 127                 e.colormod = '0 0 0';
 128                 self.glowmod = self.colormod;
 129                 e.alpha = 0;
 130                 e.customizeentityforclient = func_null;
 131
 132                 e.spawnshieldtime = 1;
 133         }
 134         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 135         {
 136                 // make the item translucent and not touchable
 137                 e.model = e.mdl;
 138                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 139                 e.colormod = '0 0 0';
 140                 self.glowmod = self.colormod;
 141                 e.effects |= EF_STARDUST;
 142                 e.customizeentityforclient = Item_Customize;
 143
 144                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 145         }
 146         else if(g_ghost_items)
 147         {
 148                 // make the item translucent and not touchable
 149                 e.model = e.mdl;
 150                 e.solid = SOLID_NOT;
 151                 e.colormod = stov(autocvar_g_ghost_items_color);
 152                 e.glowmod = e.colormod;
 153                 e.alpha = g_ghost_items;
 154                 e.customizeentityforclient = func_null;
 155
 156                 e.spawnshieldtime = 1;
 157         }
 158         else
 159         {
 160                 // hide the item completely
 161                 e.model = string_null;
 162                 e.solid = SOLID_NOT;
 163                 e.colormod = '0 0 0';
 164                 e.glowmod = e.colormod;
 165                 e.alpha = 0;
 166                 e.customizeentityforclient = func_null;
 167
 168                 e.spawnshieldtime = 1;
 169         }
 170
 171         if (e.strength_finished || e.invincible_finished)
 172                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 173         if (autocvar_g_nodepthtestitems)
 174                 e.effects |= EF_NODEPTHTEST;
 175         if (autocvar_g_fullbrightitems)
 176                 e.effects |= EF_FULLBRIGHT;
 177
 178         // relink entity (because solid may have changed)
 179         setorigin(e, e.origin);
 180 }
 181
 182 void Item_Respawn (void)
 183 {
 184         Item_Show(self, 1);
 185         if(!g_minstagib && self.items == IT_STRENGTH)
 186                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 187         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 188                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 189         else
 190                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 191         setorigin (self, self.origin);
 192
 193         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 194         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 195 }
 196
 197 void Item_RespawnCountdown (void)
 198 {
 199         if(self.count >= ITEM_RESPAWN_TICKS)
 200         {
 201                 if(self.waypointsprite_attached)
 202                         WaypointSprite_Kill(self.waypointsprite_attached);
 203                 Item_Respawn();
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 self.count += 1;
 209                 if(self.count == 1)
 210                 {
 211                         string name;
 212                         vector rgb;
 213                         name = string_null;
 214                         if(g_minstagib)
 215                         {
 216                                 switch(self.items)
 217                                 {
 218                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 219                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 220                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 221                                 }
 222                         }
 223                         else
 224                         {
 225                                 switch(self.items)
 226                                 {
 227                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 228                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 229                                 }
 230                         }
 231                         switch(self.items)
 232                         {
 233                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 234                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 235                         }
 236                         if(self.flags & FL_WEAPON)
 237                         {
 238                                 entity wi = get_weaponinfo(self.weapon);
 239                                 if(wi)
 240                                 {
 241                                         name = wi.model2;
 242                                         rgb = '0 0 0';
 243                                 }
 244                         }
 245                         if(!name)
 246                         {
 247                                 print("Unknown powerup-marked item is wanting to respawn\n");
 248                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 249                         }
 250                         if(name)
 251                         {
 252                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 253                                 if(self.waypointsprite_attached)
 254                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 255                         }
 256                 }
 257                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 258                 if(self.waypointsprite_attached)
 259                 {
 260                         WaypointSprite_Ping(self.waypointsprite_attached);
 261                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 262                 }
 263         }
 264 }
 265
 266 void Item_ScheduleRespawnIn(entity e, float t)
 267 {
 268         if((e.flags & FL_POWERUP) || (e.weapons & WEPBIT_SUPERWEAPONS))
 269         {
 270                 e.think = Item_RespawnCountdown;
 271                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 272                 e.count = 0;
 273         }
 274         else
 275         {
 276                 e.think = Item_Respawn;
 277                 e.nextthink = time + t;
 278         }
 279 }
 280
 281 void Item_ScheduleRespawn(entity e)
 282 {
 283         if(e.respawntime > 0)
 284         {
 285                 Item_Show(e, 0);
 286                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 287         }
 288         else // if respawntime is -1, this item does not respawn
 289                 Item_Show(e, -1);
 290 }
 291
 292 void Item_ScheduleInitialRespawn(entity e)
 293 {
 294         Item_Show(e, 0);
 295         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 296 }
 297
 298 float ITEM_MODE_NONE = 0;
 299 float ITEM_MODE_HEALTH = 1;
 300 float ITEM_MODE_ARMOR = 2;
 301 float ITEM_MODE_FUEL = 3;
 302 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 303 {
 304         if (!item.ammofield)
 305                 return FALSE;
 306
 307         if (item.spawnshieldtime)
 308         {
 309                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 310                 {
 311                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 312                         goto YEAH;
 313                 }
 314         }
 315         else if(g_weapon_stay == 2)
 316         {
 317                 float mi = min(item.ammofield, ammomax);
 318                 if (player.ammofield < mi)
 319                 {
 320                         player.ammofield = mi;
 321                         goto YEAH;
 322                 }
 323         }
 324
 325         return FALSE;
 326
 327 :YEAH
 328         switch(mode)
 329         {
 330                 case ITEM_MODE_FUEL:
 331                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 332                         break;
 333                 case ITEM_MODE_HEALTH:
 334                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 335                         break;
 336                 case ITEM_MODE_ARMOR:
 337                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 338                         break;
 339                 default:
 340                         break;
 341         }
 342         return TRUE;
 343 }
 344
 345 float Item_GiveTo(entity item, entity player)
 346 {
 347         float _switchweapon;
 348         float pickedup;
 349         float it;
 350         float i;
 351         entity e;
 352
 353         // if nothing happens to player, just return without taking the item
 354         pickedup = FALSE;
 355         _switchweapon = FALSE;
 356
 357         if (g_minstagib)
 358         {
 359                 float prevcells = player.ammo_cells;
 360
 361                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 362                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, 999, ITEM_MODE_NONE);
 363
 364                 if(player.ammo_cells > prevcells)
 365                 {
 366                         _switchweapon = TRUE;
 367
 368                         // play some cool sounds ;)
 369                         if (clienttype(player) == CLIENTTYPE_REAL)
 370                         {
 371                                 if(player.health <= 5)
 372                                         AnnounceTo(player, "lastsecond");
 373                                 else if(player.health < 50)
 374                                         AnnounceTo(player, "narrowly");
 375                         }
 376                         // sound not available
 377                         // else if(item.items == IT_CELLS)
 378                         //      AnnounceTo(player, "ammo");
 379
 380                         if (item.weapons & WEPBIT_MINSTANEX)
 381                                 W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 382                         if (item.ammo_cells)
 383                                 player.ammo_cells = bound(player.ammo_cells, 999, player.ammo_cells + autocvar_g_minstagib_ammo_drop);
 384                         player.health = 100;
 385                 }
 386
 387                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 388                 {
 389                         pickedup = TRUE;
 390                         player.items |= it;
 391                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 392                 }
 393
 394                 // extralife powerup
 395                 if (item.max_health)
 396                 {
 397                         pickedup = TRUE;
 398                         // sound not available
 399                         // AnnounceTo(player, "_lives");
 400                         player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 401                         sprint(player, "^3You picked up some extra lives\n");
 402                 }
 403
 404                 // invis powerup
 405                 if (item.strength_finished)
 406                 {
 407                         pickedup = TRUE;
 408                         // sound not available
 409                         // AnnounceTo(player, "invisible");
 410                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 411                 }
 412
 413                 // speed powerup
 414                 if (item.invincible_finished)
 415                 {
 416                         pickedup = TRUE;
 417                         // sound not available
 418                         // AnnounceTo(player, "speed");
 419                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_strength_time;
 420                 }
 421         }
 422         else
 423         {
 424                 // in case the player has autoswitch enabled do the following:
 425                 // if the player is using their best weapon before items are given, they
 426                 // probably want to switch to an even better weapon after items are given
 427                 if (player.autoswitch)
 428                 if (player.switchweapon == w_getbestweapon(player))
 429                         _switchweapon = TRUE;
 430
 431                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 432                         _switchweapon = TRUE;
 433
 434                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 435                 pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 436                 pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 437                 pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 438                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 439                 pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 440                 pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 441
 442                 if (item.flags & FL_WEAPON)
 443                 if ((it = item.weapons - (item.weapons & player.weapons)) || (item.spawnshieldtime && g_pickup_weapons_anyway))
 444                 {
 445                         pickedup = TRUE;
 446                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 447                         {
 448                                 e = get_weaponinfo(i);
 449                                 if(it & e.weapons)
 450                                         W_GiveWeapon (player, e.weapon, item.netname);
 451                         }
 452                 }
 453
 454                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 455                 {
 456                         pickedup = TRUE;
 457                         player.items |= it;
 458                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 459                 }
 460
 461                 if (item.strength_finished)
 462                 {
 463                         pickedup = TRUE;
 464                         player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 465                 }
 466                 if (item.invincible_finished)
 467                 {
 468                         pickedup = TRUE;
 469                         player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 470                 }
 471                 if (item.superweapons_finished)
 472                 {
 473                         pickedup = TRUE;
 474                         player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 475                 }
 476         }
 477
 478 :skip
 479         // always eat teamed entities
 480         if(item.team)
 481                 pickedup = TRUE;
 482
 483         if (!pickedup)
 484                 return 0;
 485
 486         sound (player, CH_TRIGGER, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 487         if (_switchweapon)
 488                 if (player.switchweapon != w_getbestweapon(player))
 489                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 490
 491         return 1;
 492 }
 493
 494 void Item_Touch (void)
 495 {
 496         entity e, head;
 497
 498         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 499         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 500         {
 501                 remove(self);
 502                 return;
 503         }
 504         if (other.classname != "player")
 505                 return;
 506         if (other.deadflag)
 507                 return;
 508         if (self.solid != SOLID_TRIGGER)
 509                 return;
 510         if (self.owner == other)
 511                 return;
 512
 513         if(!Item_GiveTo(self, other))
 514                 return;
 515
 516         other.last_pickup = time;
 517
 518         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 519
 520         if (self.classname == "droppedweapon")
 521                 remove (self);
 522         else if not(self.spawnshieldtime)
 523                 return;
 524         else
 525         {
 526                 if(self.team)
 527                 {
 528                         RandomSelection_Init();
 529                         for(head = world; (head = findfloat(head, team, self.team)); )
 530                         {
 531                                 if(head.flags & FL_ITEM)
 532                                 {
 533                                         Item_Show(head, -1);
 534                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 535                                 }
 536                         }
 537                         e = RandomSelection_chosen_ent;
 538                 }
 539                 else
 540                         e = self;
 541                 Item_ScheduleRespawn(e);
 542         }
 543 }
 544
 545 void Item_FindTeam()
 546 {
 547         entity head, e;
 548
 549         if(self.effects & EF_NODRAW)
 550         {
 551                 // marker for item team search
 552                 dprint("Initializing item team ", ftos(self.team), "\n");
 553                 RandomSelection_Init();
 554                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 555                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 556                 e = RandomSelection_chosen_ent;
 557                 e.state = 0;
 558                 Item_Show(e, 1);
 559
 560                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 561                 {
 562                         if(head != e)
 563                         {
 564                                 // make it a non-spawned item
 565                                 Item_Show(head, -1);
 566                                 head.state = 1; // state 1 = initially hidden item
 567                         }
 568                         head.effects &~= EF_NODRAW;
 569                 }
 570
 571                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 572                         Item_ScheduleInitialRespawn(e);
 573         }
 574 }
 575
 576 void Item_Reset()
 577 {
 578         Item_Show(self, !self.state);
 579         setorigin (self, self.origin);
 580         self.think = SUB_Null;
 581         self.nextthink = 0;
 582
 583         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 584                 Item_ScheduleInitialRespawn(self);
 585 }
 586
 587 // Savage: used for item garbage-collection
 588 // TODO: perhaps nice special effect?
 589 void RemoveItem(void)
 590 {
 591         remove(self);
 592 }
 593
 594 // pickup evaluation functions
 595 // these functions decide how desirable an item is to the bots
 596
 597 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 598
 599 float weapon_pickupevalfunc(entity player, entity item)
 600 {
 601         float c, i, j, position;
 602
 603         // See if I have it already
 604         if(player.weapons & item.weapons == item.weapons)
 605         {
 606                 // If I can pick it up
 607                 if(!item.spawnshieldtime)
 608                         c = 0;
 609                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 610                 {
 611                         // Skilled bots will grab more
 612                         c = bound(0, skill / 10, 1) * 0.5;
 613                 }
 614                 else
 615                         c = 0;
 616         }
 617         else
 618                 c = 1;
 619
 620         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 621         if( bot_custom_weapon && c )
 622         {
 623                 for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 624                 {
 625                         // Find weapon
 626                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 627                                 continue;
 628
 629                         // Find the highest position on any range
 630                         position = -1;
 631                         for(j = 0; j < WEP_LAST ; ++j){
 632                                 if(
 633                                                 bot_weapons_far[j] == i ||
 634                                                 bot_weapons_mid[j] == i ||
 635                                                 bot_weapons_close[j] == i
 636                                   )
 637                                 {
 638                                         position = j;
 639                                         break;
 640                                 }
 641                         }
 642
 643                         // Rate it
 644                         if (position >= 0 )
 645                         {
 646                                 position = WEP_LAST - position;
 647                                 // item.bot_pickupbasevalue is overwritten here
 648                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 649                         }
 650                 }
 651         }
 652
 653         return item.bot_pickupbasevalue * c;
 654 }
 655
 656 float commodity_pickupevalfunc(entity player, entity item)
 657 {
 658         float c, i, need_shells, need_nails, need_rockets, need_cells;
 659         entity wi;
 660         c = 0;
 661
 662         // Detect needed ammo
 663         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 664         {
 665                 wi = get_weaponinfo(i);
 666
 667                 if not(wi.weapons & player.weapons)
 668                         continue;
 669
 670                 if(wi.items & IT_SHELLS)
 671                         need_shells = TRUE;
 672                 else if(wi.items & IT_NAILS)
 673                         need_nails = TRUE;
 674                 else if(wi.items & IT_ROCKETS)
 675                         need_rockets = TRUE;
 676                 else if(wi.items & IT_CELLS)
 677                         need_cells = TRUE;
 678         }
 679
 680         // TODO: figure out if the player even has the weapon this ammo is for?
 681         // may not affect strategy much though...
 682         // find out how much more ammo/armor/health the player can hold
 683         if (need_shells)
 684         if (item.ammo_shells)
 685         if (player.ammo_shells < g_pickup_shells_max)
 686                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 687         if (need_nails)
 688         if (item.ammo_nails)
 689         if (player.ammo_nails < g_pickup_nails_max)
 690                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 691         if (need_rockets)
 692         if (item.ammo_rockets)
 693         if (player.ammo_rockets < g_pickup_rockets_max)
 694                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 695         if (need_cells)
 696         if (item.ammo_cells)
 697         if (player.ammo_cells < g_pickup_cells_max)
 698                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 699         if (item.armorvalue)
 700         if (player.armorvalue < item.max_armorvalue)
 701                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 702         if (item.health)
 703         if (player.health < item.max_health)
 704                 c = c + max(0, 1 - player.health / item.max_health);
 705
 706         return item.bot_pickupbasevalue * c;
 707 }
 708
 709
 710 .float is_item;
 711 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 712 {
 713         startitem_failed = FALSE;
 714
 715         self.items = itemid;
 716         self.weapons = weaponid;
 717         self.flags = FL_ITEM | itemflags;
 718
 719         // is it a dropped weapon?
 720         if (self.classname == "droppedweapon")
 721         {
 722                 self.reset = SUB_Remove;
 723                 // it's a dropped weapon
 724                 self.movetype = MOVETYPE_TOSS;
 725                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 726                 self.think = RemoveItem;
 727                 self.nextthink = time + 60;
 728                 // don't drop if in a NODROP zone (such as lava)
 729                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 730                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 731                 {
 732                         startitem_failed = TRUE;
 733                         remove(self);
 734                         return;
 735                 }
 736         }
 737         else
 738         {
 739                 if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 740                 {
 741                         startitem_failed = TRUE;
 742                         remove(self);
 743                         return;
 744                 }
 745
 746                 if(!have_pickup_item())
 747                 {
 748                         startitem_failed = TRUE;
 749                         remove (self);
 750                         return;
 751                 }
 752
 753                 if(self.model != "")
 754                         itemmodel = self.model;
 755                 if(self.item_pickupsound != "")
 756                         pickupsound = self.item_pickupsound;
 757
 758                 self.reset = Item_Reset;
 759                 // it's a level item
 760                 if(self.spawnflags & 1)
 761                         self.noalign = 1;
 762                 if (self.noalign)
 763                         self.movetype = MOVETYPE_NONE;
 764                 else
 765                         self.movetype = MOVETYPE_TOSS;
 766                 // do item filtering according to game mode and other things
 767                 if (!self.noalign)
 768                 {
 769                         // first nudge it off the floor a little bit to avoid math errors
 770                         setorigin(self, self.origin + '0 0 1');
 771                         // set item size before we spawn a spawnfunc_waypoint
 772                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 773                                 setsize (self, '-16 -16 0', '16 16 48');
 774                         else
 775                                 setsize (self, '-16 -16 0', '16 16 32');
 776                         // note droptofloor returns FALSE if stuck/or would fall too far
 777                         droptofloor();
 778                         waypoint_spawnforitem(self);
 779                 }
 780
 781                 /*
 782                  * can't do it that way, as it would break maps
 783                  * TODO make a target_give like entity another way, that perhaps has
 784                  * the weapon name in a key
 785                 if(self.targetname)
 786                 {
 787                         // target_give not yet supported; maybe later
 788                         print("removed targeted ", self.classname, "\n");
 789                         startitem_failed = TRUE;
 790                         remove (self);
 791                         return;
 792                 }
 793                 */
 794
 795                 if(autocvar_spawn_debug >= 2)
 796                 {
 797                         entity otheritem;
 798                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 799                         {
 800                                 if(otheritem.is_item)
 801                                 {
 802                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 803                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 804                                         error("Mapper sucks.");
 805                                 }
 806                         }
 807                         self.is_item = TRUE;
 808                 }
 809
 810                 weaponsInMap |= weaponid;
 811
 812                 precache_model (itemmodel);
 813                 precache_sound (pickupsound);
 814
 815                 precache_sound ("misc/itemrespawncountdown.wav");
 816                 if(!g_minstagib && itemid == IT_STRENGTH)
 817                         precache_sound ("misc/strength_respawn.wav");
 818                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 819                         precache_sound ("misc/shield_respawn.wav");
 820                 else
 821                         precache_sound ("misc/itemrespawn.wav");
 822
 823                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 824                         self.target = "###item###"; // for finding the nearest item using find()
 825         }
 826
 827         self.bot_pickup = TRUE;
 828         self.bot_pickupevalfunc = pickupevalfunc;
 829         self.bot_pickupbasevalue = pickupbasevalue;
 830         self.mdl = itemmodel;
 831         self.item_pickupsound = pickupsound;
 832         // let mappers override respawntime
 833         if(!self.respawntime) // both set
 834         {
 835                 self.respawntime = defaultrespawntime;
 836                 self.respawntimejitter = defaultrespawntimejitter;
 837         }
 838         self.netname = itemname;
 839         self.touch = Item_Touch;
 840         setmodel (self, self.mdl); // precision set below
 841         self.effects |= EF_LOWPRECISION;
 842         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 843                 setsize (self, '-16 -16 0', '16 16 48');
 844         else
 845                 setsize (self, '-16 -16 0', '16 16 32');
 846         if(itemflags & FL_WEAPON)
 847                 self.modelflags |= MF_ROTATE;
 848
 849         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 850         if (itemflags & FL_WEAPON)
 851         {
 852                 // neutral team color for pickup weapons
 853                 self.colormap = 1024; // color shirt=0 pants=0 grey
 854         }
 855
 856         Item_Show(self, 1);
 857         self.state = 0;
 858         if(self.team)
 859         {
 860                 if(!self.cnt)
 861                         self.cnt = 1; // item probability weight
 862                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 863                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 864         }
 865         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 866                 Item_ScheduleInitialRespawn(self);
 867 }
 868
 869 /* replace items in minstagib
 870  * IT_STRENGTH   = invisibility
 871  * IT_NAILS      = extra lives
 872  * IT_INVINCIBLE = speed
 873  */
 874 void minstagib_items (float itemid)
 875 {
 876         float rnd;
 877         self.classname = "minstagib";
 878
 879         // replace rocket launchers and nex guns with ammo cells
 880         if (itemid == IT_CELLS)
 881         {
 882                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
 883                 StartItem ("models/items/a_cells.md3",
 884                         "misc/itempickup.wav", 45, 0,
 885                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 886                 return;
 887         }
 888
 889         // randomize
 890         rnd = random() * 3;
 891         if (rnd <= 1)
 892                 itemid = IT_STRENGTH;
 893         else if (rnd <= 2)
 894                 itemid = IT_NAILS;
 895         else
 896                 itemid = IT_INVINCIBLE;
 897
 898         // replace with invis
 899         if (itemid == IT_STRENGTH)
 900         {
 901                 if(!self.strength_finished)
 902                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
 903                 StartItem ("models/items/g_strength.md3",
 904                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 905                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 906         }
 907         // replace with extra lives
 908         if (itemid == IT_NAILS)
 909         {
 910                 self.max_health = 1;
 911                 StartItem ("models/items/g_h100.md3",
 912                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 913                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 914         }
 915         // replace with speed
 916         if (itemid == IT_INVINCIBLE)
 917         {
 918                 if(!self.invincible_finished)
 919                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
 920                 StartItem ("models/items/g_invincible.md3",
 921                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 922                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 923         }
 924 }
 925
 926 float minst_no_auto_cells;
 927 void minst_remove_item (void) {
 928         if(minst_no_auto_cells)
 929                 remove(self);
 930 }
 931
 932 float weaponswapping;
 933 float internalteam;
 934
 935 void weapon_defaultspawnfunc(float wpn)
 936 {
 937         entity e;
 938         float t;
 939         var .float ammofield;
 940         string s;
 941         entity oldself;
 942         float i, j;
 943
 944         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 945         {
 946                 e = get_weaponinfo(wpn);
 947                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 948                 if(s == "0")
 949                 {
 950                         remove(self);
 951                         startitem_failed = TRUE;
 952                         return;
 953                 }
 954                 t = tokenize_console(s);
 955                 if(t >= 2)
 956                 {
 957                         self.team = --internalteam;
 958                         oldself = self;
 959                         for(i = 1; i < t; ++i)
 960                         {
 961                                 s = argv(i);
 962                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 963                                 {
 964                                         e = get_weaponinfo(j);
 965                                         if(e.netname == s)
 966                                         {
 967                                                 self = spawn();
 968                                                 copyentity(oldself, self);
 969                                                 self.classname = "replacedweapon";
 970                                                 weapon_defaultspawnfunc(j);
 971                                                 break;
 972                                         }
 973                                 }
 974                                 if(j > WEP_LAST)
 975                                 {
 976                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 977                                 }
 978                         }
 979                         self = oldself;
 980                 }
 981                 if(t >= 1)
 982                 {
 983                         s = argv(0);
 984                         wpn = 0;
 985                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 986                         {
 987                                 e = get_weaponinfo(j);
 988                                 if(e.netname == s)
 989                                 {
 990                                         wpn = j;
 991                                         break;
 992                                 }
 993                         }
 994                         if(j > WEP_LAST)
 995                         {
 996                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 997                         }
 998                 }
 999                 if(wpn == 0)
1000                 {
1001                         remove(self);
1002                         startitem_failed = TRUE;
1003                         return;
1004                 }
1005         }
1006
1007         e = get_weaponinfo(wpn);
1008
1009         if(!self.respawntime)
1010         {
1011                 if(self.weapons & WEPBIT_SUPERWEAPONS)
1012                 {
1013                         self.respawntime = g_pickup_respawntime_superweapon;
1014                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1015                 }
1016                 else
1017                 {
1018                         self.respawntime = g_pickup_respawntime_weapon;
1019                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1020                 }
1021         }
1022
1023         if(self.weapons & WEPBIT_SUPERWEAPONS)
1024                 if(!self.superweapons_finished)
1025                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1026
1027         if(e.items)
1028         {
1029                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1030                 {
1031                         if(e.items & j)
1032                         {
1033                                 ammofield = Item_CounterField(j);
1034                                 if(!self.ammofield)
1035                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1036                         }
1037                 }
1038         }
1039
1040         // no weapon-stay on superweapons
1041         if(self.weapons & WEPBIT_SUPERWEAPONS)
1042                 self.flags |= FL_NO_WEAPON_STAY;
1043
1044         // weapon stay isn't supported for teamed weapons
1045         if(self.team)
1046                 self.flags |= FL_NO_WEAPON_STAY;
1047
1048         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1049         if (self.modelindex) // don't precache if self was removed
1050                 weapon_action(e.weapon, WR_PRECACHE);
1051 }
1052
1053 void spawnfunc_weapon_shotgun (void);
1054 void spawnfunc_weapon_uzi (void) {
1055         if(autocvar_sv_q3acompat_machineshotgunswap)
1056         if(self.classname != "droppedweapon")
1057         {
1058                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1059                 return;
1060         }
1061         weapon_defaultspawnfunc(WEP_UZI);
1062 }
1063
1064 void spawnfunc_weapon_shotgun (void) {
1065         if(autocvar_sv_q3acompat_machineshotgunswap)
1066         if(self.classname != "droppedweapon")
1067         {
1068                 weapon_defaultspawnfunc(WEP_UZI);
1069                 return;
1070         }
1071         weapon_defaultspawnfunc(WEP_SHOTGUN);
1072 }
1073
1074 void spawnfunc_weapon_nex (void)
1075 {
1076         if (g_minstagib)
1077         {
1078                 minstagib_items(IT_CELLS);
1079                 self.think = minst_remove_item;
1080                 self.nextthink = time;
1081                 return;
1082         }
1083         weapon_defaultspawnfunc(WEP_NEX);
1084 }
1085
1086 void spawnfunc_weapon_minstanex (void)
1087 {
1088         if (g_minstagib)
1089         {
1090                 minstagib_items(IT_CELLS);
1091                 self.think = minst_remove_item;
1092                 self.nextthink = time;
1093                 return;
1094         }
1095         weapon_defaultspawnfunc(WEP_MINSTANEX);
1096 }
1097
1098 void spawnfunc_weapon_rocketlauncher (void)
1099 {
1100         if (g_minstagib)
1101         {
1102                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1103                 self.think = minst_remove_item;
1104                 self.nextthink = time;
1105                 return;
1106         }
1107         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1108 }
1109
1110 void spawnfunc_item_rockets (void) {
1111         if(!self.ammo_rockets)
1112                 self.ammo_rockets = g_pickup_rockets;
1113         if(!self.pickup_anyway)
1114                 self.pickup_anyway = g_pickup_ammo_anyway;
1115         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1116 }
1117
1118 void spawnfunc_item_shells (void);
1119 void spawnfunc_item_bullets (void) {
1120         if(!weaponswapping)
1121         if(autocvar_sv_q3acompat_machineshotgunswap)
1122         if(self.classname != "droppedweapon")
1123         {
1124                 weaponswapping = TRUE;
1125                 spawnfunc_item_shells();
1126                 weaponswapping = FALSE;
1127                 return;
1128         }
1129
1130         if(!self.ammo_nails)
1131                 self.ammo_nails = g_pickup_nails;
1132         if(!self.pickup_anyway)
1133                 self.pickup_anyway = g_pickup_ammo_anyway;
1134         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1135 }
1136
1137 void spawnfunc_item_cells (void) {
1138         if(!self.ammo_cells)
1139                 self.ammo_cells = g_pickup_cells;
1140         if(!self.pickup_anyway)
1141                 self.pickup_anyway = g_pickup_ammo_anyway;
1142         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1143 }
1144
1145 void spawnfunc_item_shells (void) {
1146         if(!weaponswapping)
1147         if(autocvar_sv_q3acompat_machineshotgunswap)
1148         if(self.classname != "droppedweapon")
1149         {
1150                 weaponswapping = TRUE;
1151                 spawnfunc_item_bullets();
1152                 weaponswapping = FALSE;
1153                 return;
1154         }
1155
1156         if(!self.ammo_shells)
1157                 self.ammo_shells = g_pickup_shells;
1158         if(!self.pickup_anyway)
1159                 self.pickup_anyway = g_pickup_ammo_anyway;
1160         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1161 }
1162
1163 void spawnfunc_item_armor_small (void) {
1164         if(!self.armorvalue)
1165                 self.armorvalue = g_pickup_armorsmall;
1166         if(!self.max_armorvalue)
1167                 self.max_armorvalue = g_pickup_armorsmall_max;
1168         if(!self.pickup_anyway)
1169                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1170         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1171 }
1172
1173 void spawnfunc_item_armor_medium (void) {
1174         if(!self.armorvalue)
1175                 self.armorvalue = g_pickup_armormedium;
1176         if(!self.max_armorvalue)
1177                 self.max_armorvalue = g_pickup_armormedium_max;
1178         if(!self.pickup_anyway)
1179                 self.pickup_anyway = g_pickup_armormedium_anyway;
1180         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1181 }
1182
1183 void spawnfunc_item_armor_big (void) {
1184         if(!self.armorvalue)
1185                 self.armorvalue = g_pickup_armorbig;
1186         if(!self.max_armorvalue)
1187                 self.max_armorvalue = g_pickup_armorbig_max;
1188         if(!self.pickup_anyway)
1189                 self.pickup_anyway = g_pickup_armorbig_anyway;
1190         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1191 }
1192
1193 void spawnfunc_item_armor_large (void) {
1194         if(!self.armorvalue)
1195                 self.armorvalue = g_pickup_armorlarge;
1196         if(!self.max_armorvalue)
1197                 self.max_armorvalue = g_pickup_armorlarge_max;
1198         if(!self.pickup_anyway)
1199                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1200         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1201 }
1202
1203 void spawnfunc_item_health_small (void) {
1204         if(!self.max_health)
1205                 self.max_health = g_pickup_healthsmall_max;
1206         if(!self.health)
1207                 self.health = g_pickup_healthsmall;
1208         if(!self.pickup_anyway)
1209                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1210         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1211 }
1212
1213 void spawnfunc_item_health_medium (void) {
1214         if(!self.max_health)
1215                 self.max_health = g_pickup_healthmedium_max;
1216         if(!self.health)
1217                 self.health = g_pickup_healthmedium;
1218         if(!self.pickup_anyway)
1219                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1220         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1221 }
1222
1223 void spawnfunc_item_health_large (void) {
1224         if(!self.max_health)
1225                 self.max_health = g_pickup_healthlarge_max;
1226         if(!self.health)
1227                 self.health = g_pickup_healthlarge;
1228         if(!self.pickup_anyway)
1229                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1230         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1231 }
1232
1233 void spawnfunc_item_health_mega (void) {
1234         if(g_minstagib) {
1235                 minstagib_items(IT_NAILS);
1236         } else {
1237                 if(!self.max_health)
1238                         self.max_health = g_pickup_healthmega_max;
1239                 if(!self.health)
1240                         self.health = g_pickup_healthmega;
1241                 if(!self.pickup_anyway)
1242                         self.pickup_anyway = g_pickup_healthmega_anyway;
1243                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1244         }
1245 }
1246
1247 // support old misnamed entities
1248 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1249 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1250 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1251 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1252 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1253
1254 void spawnfunc_item_strength (void) {
1255         if(g_minstagib) {
1256                 minstagib_items(IT_STRENGTH);
1257         } else {
1258                 precache_sound("weapons/strength_fire.wav");
1259                 if(!self.strength_finished)
1260                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1261                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1262         }
1263 }
1264
1265 void spawnfunc_item_invincible (void) {
1266         if(g_minstagib) {
1267                 minstagib_items(IT_INVINCIBLE);
1268         } else {
1269                 if(!self.invincible_finished)
1270                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1271                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1272         }
1273 }
1274
1275 void spawnfunc_item_minst_cells (void) {
1276         if (g_minstagib)
1277         {
1278                 minst_no_auto_cells = 1;
1279                 minstagib_items(IT_CELLS);
1280         }
1281         else
1282                 remove(self);
1283 }
1284
1285 // compatibility:
1286 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1287
1288 float GiveItems(entity e, float beginarg, float endarg);
1289 void target_items_use (void)
1290 {
1291         if(activator.classname == "droppedweapon")
1292         {
1293                 EXACTTRIGGER_TOUCH;
1294                 remove(activator);
1295                 return;
1296         }
1297
1298         if(activator.classname != "player")
1299                 return;
1300         if(activator.deadflag != DEAD_NO)
1301                 return;
1302         EXACTTRIGGER_TOUCH;
1303
1304         entity e;
1305         for(e = world; (e = find(e, classname, "droppedweapon")); )
1306                 if(e.enemy == activator)
1307                         remove(e);
1308
1309         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1310                 centerprint(activator, self.message);
1311 }
1312
1313 void spawnfunc_target_items (void)
1314 {
1315         float n, i, j;
1316         entity e;
1317
1318         self.use = target_items_use;
1319         if(!self.strength_finished)
1320                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1321         if(!self.invincible_finished)
1322                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1323
1324         precache_sound("misc/itempickup.wav");
1325         precache_sound("misc/megahealth.wav");
1326         precache_sound("misc/armor25.wav");
1327         precache_sound("misc/powerup.wav");
1328         precache_sound("misc/poweroff.wav");
1329         precache_sound("weapons/weaponpickup.wav");
1330
1331         n = tokenize_console(self.netname);
1332         if(argv(0) == "give")
1333         {
1334                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1335         }
1336         else
1337         {
1338                 for(i = 0; i < n; ++i)
1339                 {
1340                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1341                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1342                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1343                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1344                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1345                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1346                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1347                         else
1348                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1349                         {
1350                                 e = get_weaponinfo(j);
1351                                 if(argv(i) == e.netname)
1352                                 {
1353                                         self.weapons |= e.weapons;
1354                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1355                                                 weapon_action(e.weapon, WR_PRECACHE);
1356                                         break;
1357                                 }
1358                         }
1359                         if(j > WEP_LAST)
1360                                 print("target_items: invalid item ", argv(i), "\n");
1361                 }
1362
1363                 string itemprefix, valueprefix;
1364                 if(self.spawnflags == 0)
1365                 {
1366                         itemprefix = "";
1367                         valueprefix = "";
1368                 }
1369                 else if(self.spawnflags == 1)
1370                 {
1371                         itemprefix = "max ";
1372                         valueprefix = "max ";
1373                 }
1374                 else if(self.spawnflags == 2)
1375                 {
1376                         itemprefix = "min ";
1377                         valueprefix = "min ";
1378                 }
1379                 else if(self.spawnflags == 4)
1380                 {
1381                         itemprefix = "minus ";
1382                         valueprefix = "max ";
1383                 }
1384                 else
1385                         error("invalid spawnflags");
1386
1387                 self.netname = "";
1388                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1389                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1390                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1391                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1392                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1393                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1394                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1395                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1396                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1397                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1398                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1399                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1400                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1401                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1402                 {
1403                         e = get_weaponinfo(j);
1404                         if(e.weapons)
1405                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1406                 }
1407         }
1408         self.netname = strzone(self.netname);
1409         //print(self.netname, "\n");
1410
1411         n = tokenize_console(self.netname);
1412         for(i = 0; i < n; ++i)
1413         {
1414                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1415                 {
1416                         e = get_weaponinfo(j);
1417                         if(argv(i) == e.netname)
1418                         {
1419                                 weapon_action(e.weapon, WR_PRECACHE);
1420                                 break;
1421                         }
1422                 }
1423         }
1424 }
1425
1426 void spawnfunc_item_fuel(void)
1427 {
1428         if(!self.ammo_fuel)
1429                 self.ammo_fuel = g_pickup_fuel;
1430         if(!self.pickup_anyway)
1431                 self.pickup_anyway = g_pickup_ammo_anyway;
1432         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1433 }
1434
1435 void spawnfunc_item_fuel_regen(void)
1436 {
1437         if(start_items & IT_FUEL_REGEN)
1438         {
1439                 spawnfunc_item_fuel();
1440                 return;
1441         }
1442         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1443 }
1444
1445 void spawnfunc_item_jetpack(void)
1446 {
1447         if(g_grappling_hook)
1448                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1449         if(!self.ammo_fuel)
1450                 self.ammo_fuel = g_pickup_fuel_jetpack;
1451         if(start_items & IT_JETPACK)
1452         {
1453                 spawnfunc_item_fuel();
1454                 return;
1455         }
1456         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1457 }
1458
1459
1460 #define OP_SET 0
1461 #define OP_MIN 1
1462 #define OP_MAX 2
1463 #define OP_PLUS 3
1464 #define OP_MINUS 4
1465
1466 float GiveBit(entity e, .float fld, float bit, float op, float val)
1467 {
1468         float v0, v1;
1469         v0 = (e.fld & bit);
1470         switch(op)
1471         {
1472                 case OP_SET:
1473                         if(val > 0)
1474                                 e.fld |= bit;
1475                         else
1476                                 e.fld &~= bit;
1477                         break;
1478                 case OP_MIN:
1479                 case OP_PLUS:
1480                         if(val > 0)
1481                                 e.fld |= bit;
1482                         break;
1483                 case OP_MAX:
1484                         if(val <= 0)
1485                                 e.fld &~= bit;
1486                         break;
1487                 case OP_MINUS:
1488                         if(val > 0)
1489                                 e.fld &~= bit;
1490                         break;
1491         }
1492         v1 = (e.fld & bit);
1493         return (v0 != v1);
1494 }
1495
1496 float GiveValue(entity e, .float fld, float op, float val)
1497 {
1498         float v0, v1;
1499         v0 = e.fld;
1500         switch(op)
1501         {
1502                 case OP_SET:
1503                         e.fld = val;
1504                         break;
1505                 case OP_MIN:
1506                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1507                         break;
1508                 case OP_MAX:
1509                         e.fld = min(e.fld, val);
1510                         break;
1511                 case OP_PLUS:
1512                         e.fld += val;
1513                         break;
1514                 case OP_MINUS:
1515                         e.fld -= val;
1516                         break;
1517         }
1518         v1 = e.fld;
1519         return (v0 != v1);
1520 }
1521
1522 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1523 {
1524         if(v1 == v0)
1525                 return;
1526         if(v1 <= v0 - t)
1527         {
1528                 if(snd_decr != "")
1529                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1530         }
1531         else if(v0 >= v0 + t)
1532         {
1533                 if(snd_incr != "")
1534                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1535         }
1536 }
1537
1538 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1539 {
1540         if(v0 < v1)
1541                 e.rotfield = max(e.rotfield, time + rottime);
1542         else if(v0 > v1)
1543                 e.regenfield = max(e.regenfield, time + regentime);
1544 }
1545
1546 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1547 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1548 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1549 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1550
1551 float GiveItems(entity e, float beginarg, float endarg)
1552 {
1553         float got, i, j, val, op;
1554         float _switchweapon;
1555         entity wi;
1556         string cmd;
1557
1558         val = 999;
1559         op = OP_SET;
1560
1561         got = 0;
1562
1563         _switchweapon = FALSE;
1564         if (e.autoswitch)
1565                 if (e.switchweapon == w_getbestweapon(e))
1566                         _switchweapon = TRUE;
1567
1568         e.strength_finished = max(0, e.strength_finished - time);
1569         e.invincible_finished = max(0, e.invincible_finished - time);
1570
1571         PREGIVE(e, items);
1572         PREGIVE(e, weapons);
1573         PREGIVE(e, strength_finished);
1574         PREGIVE(e, invincible_finished);
1575         PREGIVE(e, ammo_nails);
1576         PREGIVE(e, ammo_cells);
1577         PREGIVE(e, ammo_shells);
1578         PREGIVE(e, ammo_rockets);
1579         PREGIVE(e, ammo_fuel);
1580         PREGIVE(e, armorvalue);
1581         PREGIVE(e, health);
1582
1583         for(i = beginarg; i < endarg; ++i)
1584         {
1585                 cmd = argv(i);
1586
1587                 if(cmd == "0" || stof(cmd))
1588                 {
1589                         val = stof(cmd);
1590                         continue;
1591                 }
1592                 switch(cmd)
1593                 {
1594                         case "no":
1595                                 op = OP_MAX;
1596                                 val = 0;
1597                                 continue;
1598                         case "max":
1599                                 op = OP_MAX;
1600                                 continue;
1601                         case "min":
1602                                 op = OP_MIN;
1603                                 continue;
1604                         case "plus":
1605                                 op = OP_PLUS;
1606                                 continue;
1607                         case "minus":
1608                                 op = OP_MINUS;
1609                                 continue;
1610                         case "ALL":
1611                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1612                                 got += GiveValue(e, strength_finished, op, time);
1613                                 got += GiveValue(e, invincible_finished, op, time);
1614                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1615                         case "all":
1616                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1617                                 got += GiveValue(e, health, op, val);
1618                                 got += GiveValue(e, armorvalue, op, val);
1619                         case "allweapons":
1620                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1621                                 {
1622                                         wi = get_weaponinfo(j);
1623                                         if(wi.weapons)
1624                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1625                                 }
1626                         case "allammo":
1627                                 got += GiveValue(e, ammo_cells, op, val);
1628                                 got += GiveValue(e, ammo_shells, op, val);
1629                                 got += GiveValue(e, ammo_nails, op, val);
1630                                 got += GiveValue(e, ammo_rockets, op, val);
1631                                 got += GiveValue(e, ammo_fuel, op, val);
1632                                 break;
1633                         case "unlimited_ammo":
1634                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1635                                 break;
1636                         case "unlimited_weapon_ammo":
1637                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1638                                 break;
1639                         case "unlimited_superweapons":
1640                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1641                                 break;
1642                         case "jetpack":
1643                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1644                                 break;
1645                         case "fuel_regen":
1646                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1647                                 break;
1648                         case "strength":
1649                                 got += GiveValue(e, strength_finished, op, val);
1650                                 break;
1651                         case "invincible":
1652                                 got += GiveValue(e, invincible_finished, op, val);
1653                                 break;
1654                         case "cells":
1655                                 got += GiveValue(e, ammo_cells, op, val);
1656                                 break;
1657                         case "shells":
1658                                 got += GiveValue(e, ammo_shells, op, val);
1659                                 break;
1660                         case "nails":
1661                         case "bullets":
1662                                 got += GiveValue(e, ammo_nails, op, val);
1663                                 break;
1664                         case "rockets":
1665                                 got += GiveValue(e, ammo_rockets, op, val);
1666                                 break;
1667                         case "health":
1668                                 got += GiveValue(e, health, op, val);
1669                                 break;
1670                         case "armor":
1671                                 got += GiveValue(e, armorvalue, op, val);
1672                                 break;
1673                         case "fuel":
1674                                 got += GiveValue(e, ammo_fuel, op, val);
1675                                 break;
1676                         default:
1677                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1678                                 {
1679                                         wi = get_weaponinfo(j);
1680                                         if(cmd == wi.netname)
1681                                         {
1682                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1683                                                 break;
1684                                         }
1685                                 }
1686                                 if(j > WEP_LAST)
1687                                         print("give: invalid item ", cmd, "\n");
1688                                 break;
1689                 }
1690                 val = 999;
1691                 op = OP_SET;
1692         }
1693
1694         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1695         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1696         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1697         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1698         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1699         {
1700                 wi = get_weaponinfo(j);
1701                 if(wi.weapons)
1702                 {
1703                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1704                         if not(save_weapons & wi.weapons)
1705                                 if(e.weapons & wi.weapons)
1706                                         weapon_action(wi.weapon, WR_PRECACHE);
1707                 }
1708         }
1709         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1710         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1711         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1712         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1713         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1714         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1715         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1716         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1717         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1718
1719         if (g_minstagib)
1720         {
1721                 e.health = bound(0, e.health, 100);
1722                 e.armorvalue = bound(0, e.armorvalue, 999);
1723         }
1724
1725         if(e.strength_finished <= 0)
1726                 e.strength_finished = 0;
1727         else
1728                 e.strength_finished += time;
1729         if(e.invincible_finished <= 0)
1730                 e.invincible_finished = 0;
1731         else
1732                 e.invincible_finished += time;
1733
1734         if not(e.weapons & W_WeaponBit(e.switchweapon))
1735                 _switchweapon = TRUE;
1736         if(_switchweapon)
1737                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1738
1739         return got;
1740 }