qcsrc/server/t_items.qc

   1 float have_pickup_item(void)
   2 {
   3         // minstagib: only allow filtered items
   4         if(g_minstagib)
   5                 if(self.classname != "minstagib")
   6                         return FALSE;
   7
   8         if(self.flags & FL_POWERUP)
   9         {
  10                 if(autocvar_g_powerups > 0)
  11                         return TRUE;
  12                 if(autocvar_g_powerups == 0)
  13                         return FALSE;
  14                 if(g_lms)
  15                         return FALSE;
  16                 if(g_ca)
  17                         return FALSE;
  18                 if(g_arena)
  19                         return FALSE;
  20         }
  21         else
  22         {
  23                 if(autocvar_g_pickup_items > 0)
  24                         return TRUE;
  25                 if(autocvar_g_pickup_items == 0)
  26                         return FALSE;
  27                 if(g_lms)
  28                         return FALSE;
  29                 if(g_ca)
  30                         return FALSE;
  31                 if(g_weaponarena)
  32                         if(!WEPSET_EMPTY_E(self) || (self.items & IT_AMMO))
  33                                 return FALSE;
  34         }
  35         return TRUE;
  36 }
  37
  38 #define ITEM_RESPAWN_TICKS 10
  39
  40 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
  41         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
  42 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
  43         // range: 10 .. respawntime + respawntimejitter
  44
  45 floatfield Item_CounterField(float it)
  46 {
  47         switch(it)
  48         {
  49                 case IT_SHELLS:      return ammo_shells;
  50                 case IT_NAILS:       return ammo_nails;
  51                 case IT_ROCKETS:     return ammo_rockets;
  52                 case IT_CELLS:       return ammo_cells;
  53                 case IT_FUEL:        return ammo_fuel;
  54                 case IT_5HP:         return health;
  55                 case IT_25HP:        return health;
  56                 case IT_HEALTH:      return health;
  57                 case IT_ARMOR_SHARD: return armorvalue;
  58                 case IT_ARMOR:       return armorvalue;
  59                 // add more things here (health, armor)
  60                 default:             error("requested item has no counter field");
  61         }
  62 }
  63
  64 string Item_CounterFieldName(float it)
  65 {
  66         switch(it)
  67         {
  68                 case IT_SHELLS:      return "shells";
  69                 case IT_NAILS:       return "nails";
  70                 case IT_ROCKETS:     return "rockets";
  71                 case IT_CELLS:       return "cells";
  72                 case IT_FUEL:        return "fuel";
  73
  74                 // add more things here (health, armor)
  75                 default:             error("requested item has no counter field name");
  76         }
  77 }
  78
  79 .float max_armorvalue;
  80 .float pickup_anyway;
  81
  82 float Item_Customize()
  83 {
  84         if(self.spawnshieldtime)
  85                 return TRUE;
  86         if(!WEPSET_CONTAINS_ALL_EE(other, self))
  87         {
  88                 self.colormod = '0 0 0';
  89                 self.glowmod = self.colormod;
  90                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  91                 return TRUE;
  92         }
  93         else
  94         {
  95                 if(g_ghost_items)
  96                 {
  97                         self.colormod = stov(autocvar_g_ghost_items_color);
  98                         self.glowmod = self.colormod;
  99                         self.alpha = g_ghost_items;
 100                         return TRUE;
 101                 }
 102                 else
 103                         return FALSE;
 104         }
 105 }
 106
 107 void Item_Show (entity e, float mode)
 108 {
 109         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 110         if (mode > 0)
 111         {
 112                 // make the item look normal, and be touchable
 113                 e.model = e.mdl;
 114                 e.solid = SOLID_TRIGGER;
 115                 e.colormod = '0 0 0';
 116                 self.glowmod = self.colormod;
 117                 e.alpha = 0;
 118                 e.customizeentityforclient = func_null;
 119
 120                 e.spawnshieldtime = 1;
 121         }
 122         else if (mode < 0)
 123         {
 124                 // hide the item completely
 125                 e.model = string_null;
 126                 e.solid = SOLID_NOT;
 127                 e.colormod = '0 0 0';
 128                 self.glowmod = self.colormod;
 129                 e.alpha = 0;
 130                 e.customizeentityforclient = func_null;
 131
 132                 e.spawnshieldtime = 1;
 133         }
 134         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 135         {
 136                 // make the item translucent and not touchable
 137                 e.model = e.mdl;
 138                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 139                 e.colormod = '0 0 0';
 140                 self.glowmod = self.colormod;
 141                 e.effects |= EF_STARDUST;
 142                 e.customizeentityforclient = Item_Customize;
 143
 144                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 145         }
 146         else if(g_ghost_items)
 147         {
 148                 // make the item translucent and not touchable
 149                 e.model = e.mdl;
 150                 e.solid = SOLID_NOT;
 151                 e.colormod = stov(autocvar_g_ghost_items_color);
 152                 e.glowmod = e.colormod;
 153                 e.alpha = g_ghost_items;
 154                 e.customizeentityforclient = func_null;
 155
 156                 e.spawnshieldtime = 1;
 157         }
 158         else
 159         {
 160                 // hide the item completely
 161                 e.model = string_null;
 162                 e.solid = SOLID_NOT;
 163                 e.colormod = '0 0 0';
 164                 e.glowmod = e.colormod;
 165                 e.alpha = 0;
 166                 e.customizeentityforclient = func_null;
 167
 168                 e.spawnshieldtime = 1;
 169         }
 170
 171         if (e.items & (IT_STRENGTH | IT_INVINCIBLE))
 172                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 173         if (autocvar_g_nodepthtestitems)
 174                 e.effects |= EF_NODEPTHTEST;
 175         if (autocvar_g_fullbrightitems)
 176                 e.effects |= EF_FULLBRIGHT;
 177
 178         // relink entity (because solid may have changed)
 179         setorigin(e, e.origin);
 180 }
 181
 182 void Item_Respawn (void)
 183 {
 184         Item_Show(self, 1);
 185         if(!g_minstagib && self.items == IT_STRENGTH)
 186                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 187         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 188                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 189         else
 190                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 191         setorigin (self, self.origin);
 192
 193         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 194         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 195 }
 196
 197 void Item_RespawnCountdown (void)
 198 {
 199         if(self.count >= ITEM_RESPAWN_TICKS)
 200         {
 201                 if(self.waypointsprite_attached)
 202                         WaypointSprite_Kill(self.waypointsprite_attached);
 203                 Item_Respawn();
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 self.count += 1;
 209                 if(self.count == 1)
 210                 {
 211                         string name;
 212                         vector rgb;
 213                         name = string_null;
 214                         if(g_minstagib)
 215                         {
 216                                 switch(self.items)
 217                                 {
 218                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 219                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 220                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 221                                 }
 222                         }
 223                         else
 224                         {
 225                                 switch(self.items)
 226                                 {
 227                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 228                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 229                                 }
 230                         }
 231                         switch(self.items)
 232                         {
 233                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 234                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 235                         }
 236                         if(self.flags & FL_WEAPON)
 237                         {
 238                                 entity wi = get_weaponinfo(self.weapon);
 239                                 if(wi)
 240                                 {
 241                                         name = wi.model2;
 242                                         rgb = '1 0 0';
 243                                 }
 244                         }
 245                         if(!name)
 246                         {
 247                                 print("Unknown powerup-marked item is wanting to respawn\n");
 248                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 249                         }
 250                         if(name)
 251                         {
 252                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 253                                 if(self.waypointsprite_attached)
 254                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 255                         }
 256                 }
 257                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 258                 if(self.waypointsprite_attached)
 259                 {
 260                         WaypointSprite_Ping(self.waypointsprite_attached);
 261                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 262                 }
 263         }
 264 }
 265
 266 void Item_ScheduleRespawnIn(entity e, float t)
 267 {
 268         if((e.flags & FL_POWERUP) || WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
 269         {
 270                 e.think = Item_RespawnCountdown;
 271                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 272                 e.count = 0;
 273         }
 274         else
 275         {
 276                 e.think = Item_Respawn;
 277                 e.nextthink = time + t;
 278         }
 279 }
 280
 281 void Item_ScheduleRespawn(entity e)
 282 {
 283         if(e.respawntime > 0)
 284         {
 285                 Item_Show(e, 0);
 286                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 287         }
 288         else // if respawntime is -1, this item does not respawn
 289                 Item_Show(e, -1);
 290 }
 291
 292 void Item_ScheduleInitialRespawn(entity e)
 293 {
 294         Item_Show(e, 0);
 295         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 296 }
 297
 298 float ITEM_MODE_NONE = 0;
 299 float ITEM_MODE_HEALTH = 1;
 300 float ITEM_MODE_ARMOR = 2;
 301 float ITEM_MODE_FUEL = 3;
 302 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 303 {
 304         if (!item.ammofield)
 305                 return FALSE;
 306
 307         if (item.spawnshieldtime)
 308         {
 309                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 310                 {
 311                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 312                         goto YEAH;
 313                 }
 314         }
 315         else if(g_weapon_stay == 2)
 316         {
 317                 float mi = min(item.ammofield, ammomax);
 318                 if (player.ammofield < mi)
 319                 {
 320                         player.ammofield = mi;
 321                         goto YEAH;
 322                 }
 323         }
 324
 325         return FALSE;
 326
 327 :YEAH
 328         switch(mode)
 329         {
 330                 case ITEM_MODE_FUEL:
 331                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 332                         break;
 333                 case ITEM_MODE_HEALTH:
 334                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 335                         break;
 336                 case ITEM_MODE_ARMOR:
 337                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 338                         break;
 339                 default:
 340                         break;
 341         }
 342         return TRUE;
 343 }
 344
 345 float Item_GiveTo(entity item, entity player)
 346 {
 347         float _switchweapon;
 348         float pickedup;
 349         float it;
 350         float i;
 351
 352         // if nothing happens to player, just return without taking the item
 353         pickedup = FALSE;
 354         _switchweapon = FALSE;
 355
 356         if (g_minstagib)
 357         {
 358                 float prevcells = player.ammo_cells;
 359
 360                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 361                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, 999, ITEM_MODE_NONE);
 362
 363                 if(player.ammo_cells > prevcells)
 364                 {
 365                         _switchweapon = TRUE;
 366
 367                         // play some cool sounds ;)
 368                         if (clienttype(player) == CLIENTTYPE_REAL)
 369                         {
 370                                 if(player.health <= 5)
 371                                         AnnounceTo(player, "lastsecond");
 372                                 else if(player.health < 50)
 373                                         AnnounceTo(player, "narrowly");
 374                         }
 375                         // sound not available
 376                         // else if(item.items == IT_CELLS)
 377                         //      AnnounceTo(player, "ammo");
 378
 379                         if (WEPSET_CONTAINS_EW(item, WEP_MINSTANEX))
 380                                 W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 381                         if (item.ammo_cells)
 382                                 player.ammo_cells = bound(player.ammo_cells, 999, player.ammo_cells + autocvar_g_minstagib_ammo_drop);
 383                         player.health = 100;
 384                 }
 385
 386                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 387                 {
 388                         pickedup = TRUE;
 389                         player.items |= it;
 390                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 391                 }
 392
 393                 // extralife powerup
 394                 if (item.max_health)
 395                 {
 396                         pickedup = TRUE;
 397                         // sound not available
 398                         // AnnounceTo(player, "_lives");
 399                         player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 400                         sprint(player, "^3You picked up some extra lives\n");
 401                 }
 402
 403                 // invis powerup
 404                 if (item.strength_finished)
 405                 {
 406                         pickedup = TRUE;
 407                         // sound not available
 408                         // AnnounceTo(player, "invisible");
 409                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 410                 }
 411
 412                 // speed powerup
 413                 if (item.invincible_finished)
 414                 {
 415                         pickedup = TRUE;
 416                         // sound not available
 417                         // AnnounceTo(player, "speed");
 418                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_strength_time;
 419                 }
 420         }
 421         else
 422         {
 423                 // in case the player has autoswitch enabled do the following:
 424                 // if the player is using their best weapon before items are given, they
 425                 // probably want to switch to an even better weapon after items are given
 426                 if (player.autoswitch)
 427                 if (player.switchweapon == w_getbestweapon(player))
 428                         _switchweapon = TRUE;
 429
 430                 if not(WEPSET_CONTAINS_EW(player, player.switchweapon))
 431                         _switchweapon = TRUE;
 432
 433                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 434                 pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 435                 pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 436                 pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 437                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 438                 pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 439                 pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 440
 441                 if (item.flags & FL_WEAPON)
 442                 {
 443                         WEPSET_DECLARE_A(it);
 444                         WEPSET_COPY_AE(it, item);
 445                         WEPSET_ANDNOT_AE(it, player);
 446
 447                         if (!WEPSET_EMPTY_A(it) || (item.spawnshieldtime && self.pickup_anyway))
 448                         {
 449                                 pickedup = TRUE;
 450                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 451                                         if(WEPSET_CONTAINS_AW(it, i))
 452                                                 W_GiveWeapon (player, i, item.netname);
 453                         }
 454                 }
 455
 456                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 457                 {
 458                         pickedup = TRUE;
 459                         player.items |= it;
 460                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 461                 }
 462
 463                 if (item.strength_finished)
 464                 {
 465                         pickedup = TRUE;
 466                         player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 467                 }
 468                 if (item.invincible_finished)
 469                 {
 470                         pickedup = TRUE;
 471                         player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 472                 }
 473                 if (item.superweapons_finished)
 474                 {
 475                         pickedup = TRUE;
 476                         player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 477                 }
 478         }
 479
 480 :skip
 481         // always eat teamed entities
 482         if(item.team)
 483                 pickedup = TRUE;
 484
 485         if (!pickedup)
 486                 return 0;
 487
 488         if (_switchweapon)
 489                 if (player.switchweapon != w_getbestweapon(player))
 490                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 491
 492         return 1;
 493 }
 494
 495 void Item_Touch (void)
 496 {
 497         entity e, head;
 498
 499         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 500         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 501         {
 502                 remove(self);
 503                 return;
 504         }
 505         if (other.classname != "player")
 506                 return;
 507         if (other.deadflag)
 508                 return;
 509         if (self.solid != SOLID_TRIGGER)
 510                 return;
 511         if (self.owner == other)
 512                 return;
 513
 514         if (self.classname == "droppedweapon")
 515         {
 516                 self.strength_finished = max(0, self.strength_finished - time);
 517                 self.invincible_finished = max(0, self.invincible_finished - time);
 518                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 519         }
 520
 521         if(!Item_GiveTo(self, other))
 522         {
 523                 if (self.classname == "droppedweapon")
 524                 {
 525                         // undo what we did above
 526                         self.strength_finished += time;
 527                         self.invincible_finished += time;
 528                         self.superweapons_finished += time;
 529                 }
 530                 return;
 531         }
 532
 533         other.last_pickup = time;
 534
 535         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 536         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTN_NORM);
 537
 538         if (self.classname == "droppedweapon")
 539                 remove (self);
 540         else if not(self.spawnshieldtime)
 541                 return;
 542         else
 543         {
 544                 if(self.team)
 545                 {
 546                         RandomSelection_Init();
 547                         for(head = world; (head = findfloat(head, team, self.team)); )
 548                         {
 549                                 if(head.flags & FL_ITEM)
 550                                 {
 551                                         Item_Show(head, -1);
 552                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 553                                 }
 554                         }
 555                         e = RandomSelection_chosen_ent;
 556                 }
 557                 else
 558                         e = self;
 559                 Item_ScheduleRespawn(e);
 560         }
 561 }
 562
 563 void Item_Reset()
 564 {
 565         Item_Show(self, !self.state);
 566         setorigin (self, self.origin);
 567
 568         if(self.classname != "droppedweapon")
 569         {
 570                 self.think = SUB_Null;
 571                 self.nextthink = 0;
 572
 573                 if(self.waypointsprite_attached)
 574                         WaypointSprite_Kill(self.waypointsprite_attached);
 575
 576                 if((self.flags & FL_POWERUP) | WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // do not spawn powerups initially!
 577                         Item_ScheduleInitialRespawn(self);
 578         }
 579 }
 580
 581 void Item_FindTeam()
 582 {
 583         entity head, e;
 584
 585         if(self.effects & EF_NODRAW)
 586         {
 587                 // marker for item team search
 588                 dprint("Initializing item team ", ftos(self.team), "\n");
 589                 RandomSelection_Init();
 590                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 591                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 592                 e = RandomSelection_chosen_ent;
 593                 e.state = 0;
 594                 Item_Show(e, 1);
 595
 596                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 597                 {
 598                         if(head != e)
 599                         {
 600                                 // make it a non-spawned item
 601                                 Item_Show(head, -1);
 602                                 head.state = 1; // state 1 = initially hidden item
 603                         }
 604                         head.effects &~= EF_NODRAW;
 605                 }
 606
 607                 Item_Reset();
 608         }
 609 }
 610
 611 // Savage: used for item garbage-collection
 612 // TODO: perhaps nice special effect?
 613 void RemoveItem(void)
 614 {
 615         remove(self);
 616 }
 617
 618 // pickup evaluation functions
 619 // these functions decide how desirable an item is to the bots
 620
 621 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 622
 623 float weapon_pickupevalfunc(entity player, entity item)
 624 {
 625         float c, j, position;
 626
 627         // See if I have it already
 628         if(!WEPSET_CONTAINS_ALL_EE(player, item))
 629         {
 630                 // If I can pick it up
 631                 if(!item.spawnshieldtime)
 632                         c = 0;
 633                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 634                 {
 635                         // Skilled bots will grab more
 636                         c = bound(0, skill / 10, 1) * 0.5;
 637                 }
 638                 else
 639                         c = 0;
 640         }
 641         else
 642                 c = 1;
 643
 644         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 645         if( bot_custom_weapon && c )
 646         {
 647                 // Find the highest position on any range
 648                 position = -1;
 649                 for(j = 0; j < WEP_LAST ; ++j){
 650                         if(
 651                                         bot_weapons_far[j] == item.weapon ||
 652                                         bot_weapons_mid[j] == item.weapon ||
 653                                         bot_weapons_close[j] == item.weapon
 654                           )
 655                         {
 656                                 position = j;
 657                                 break;
 658                         }
 659                 }
 660
 661                 // Rate it
 662                 if (position >= 0 )
 663                 {
 664                         position = WEP_LAST - position;
 665                         // item.bot_pickupbasevalue is overwritten here
 666                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 667                 }
 668         }
 669
 670         return item.bot_pickupbasevalue * c;
 671 }
 672
 673 float commodity_pickupevalfunc(entity player, entity item)
 674 {
 675         float c, i, need_shells, need_nails, need_rockets, need_cells, need_fuel;
 676         entity wi;
 677         c = 0;
 678
 679         // Detect needed ammo
 680         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 681         {
 682                 wi = get_weaponinfo(i);
 683
 684                 if not(WEPSET_CONTAINS_EW(player, i))
 685                         continue;
 686
 687                 if(wi.items & IT_SHELLS)
 688                         need_shells = TRUE;
 689                 else if(wi.items & IT_NAILS)
 690                         need_nails = TRUE;
 691                 else if(wi.items & IT_ROCKETS)
 692                         need_rockets = TRUE;
 693                 else if(wi.items & IT_CELLS)
 694                         need_cells = TRUE;
 695                 else if(wi.items & IT_FUEL)
 696                         need_cells = TRUE;
 697         }
 698
 699         // TODO: figure out if the player even has the weapon this ammo is for?
 700         // may not affect strategy much though...
 701         // find out how much more ammo/armor/health the player can hold
 702         if (need_shells)
 703         if (item.ammo_shells)
 704         if (player.ammo_shells < g_pickup_shells_max)
 705                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 706         if (need_nails)
 707         if (item.ammo_nails)
 708         if (player.ammo_nails < g_pickup_nails_max)
 709                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 710         if (need_rockets)
 711         if (item.ammo_rockets)
 712         if (player.ammo_rockets < g_pickup_rockets_max)
 713                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 714         if (need_cells)
 715         if (item.ammo_cells)
 716         if (player.ammo_cells < g_pickup_cells_max)
 717                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 718         if (need_fuel)
 719         if (item.ammo_fuel)
 720         if (player.ammo_fuel < g_pickup_fuel_max)
 721                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 722         if (item.armorvalue)
 723         if (player.armorvalue < item.max_armorvalue)
 724                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 725         if (item.health)
 726         if (player.health < item.max_health)
 727                 c = c + max(0, 1 - player.health / item.max_health);
 728
 729         return item.bot_pickupbasevalue * c;
 730 }
 731
 732
 733 .float is_item;
 734 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 735 {
 736         startitem_failed = FALSE;
 737
 738         if(self.model == "")
 739                 self.model = itemmodel;
 740         if(self.item_pickupsound == "")
 741                 self.item_pickupsound = pickupsound;
 742         if(!self.respawntime) // both need to be set
 743         {
 744                 self.respawntime = defaultrespawntime;
 745                 self.respawntimejitter = defaultrespawntimejitter;
 746         }
 747
 748         self.items = itemid;
 749         self.weapon = weaponid;
 750
 751         if(weaponid)
 752                 WEPSET_COPY_EW(self, weaponid);
 753         self.flags = FL_ITEM | itemflags;
 754
 755         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 756         {
 757                 startitem_failed = TRUE;
 758                 remove(self);
 759                 return;
 760         }
 761
 762         // is it a dropped weapon?
 763         if (self.classname == "droppedweapon")
 764         {
 765                 self.reset = SUB_Remove;
 766                 // it's a dropped weapon
 767                 self.movetype = MOVETYPE_TOSS;
 768
 769                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 770                 self.think = RemoveItem;
 771                 self.nextthink = time + 20;
 772
 773                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
 774                 /*
 775                 if(self.items == 0)
 776                 if(WEPSET_CONTAINS_ALL_AE(WEPBIT_SUPERWEAPONS, self)) // only superweapons
 777                 if(self.ammo_nails == 0)
 778                 if(self.ammo_cells == 0)
 779                 if(self.ammo_rockets == 0)
 780                 if(self.ammo_shells == 0)
 781                 if(self.ammo_fuel == 0)
 782                 if(self.health == 0)
 783                 if(self.armorvalue == 0)
 784                 */
 785                 {
 786                         // if item is worthless after a timer, have it expire then
 787                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
 788                 }
 789
 790                 // don't drop if in a NODROP zone (such as lava)
 791                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 792                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 793                 {
 794                         startitem_failed = TRUE;
 795                         remove(self);
 796                         return;
 797                 }
 798         }
 799         else
 800         {
 801                 if(!have_pickup_item())
 802                 {
 803                         startitem_failed = TRUE;
 804                         remove (self);
 805                         return;
 806                 }
 807
 808                 self.reset = Item_Reset;
 809                 // it's a level item
 810                 if(self.spawnflags & 1)
 811                         self.noalign = 1;
 812                 if (self.noalign)
 813                         self.movetype = MOVETYPE_NONE;
 814                 else
 815                         self.movetype = MOVETYPE_TOSS;
 816                 // do item filtering according to game mode and other things
 817                 if (!self.noalign)
 818                 {
 819                         // first nudge it off the floor a little bit to avoid math errors
 820                         setorigin(self, self.origin + '0 0 1');
 821                         // set item size before we spawn a spawnfunc_waypoint
 822                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 823                                 setsize (self, '-16 -16 0', '16 16 48');
 824                         else
 825                                 setsize (self, '-16 -16 0', '16 16 32');
 826                         // note droptofloor returns FALSE if stuck/or would fall too far
 827                         droptofloor();
 828                         waypoint_spawnforitem(self);
 829                 }
 830
 831                 /*
 832                  * can't do it that way, as it would break maps
 833                  * TODO make a target_give like entity another way, that perhaps has
 834                  * the weapon name in a key
 835                 if(self.targetname)
 836                 {
 837                         // target_give not yet supported; maybe later
 838                         print("removed targeted ", self.classname, "\n");
 839                         startitem_failed = TRUE;
 840                         remove (self);
 841                         return;
 842                 }
 843                 */
 844
 845                 if(autocvar_spawn_debug >= 2)
 846                 {
 847                         entity otheritem;
 848                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 849                         {
 850                                 if(otheritem.is_item)
 851                                 {
 852                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 853                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 854                                         error("Mapper sucks.");
 855                                 }
 856                         }
 857                         self.is_item = TRUE;
 858                 }
 859
 860                 WEPSET_OR_AW(weaponsInMap, weaponid);
 861
 862                 precache_model (self.model);
 863                 precache_sound (self.item_pickupsound);
 864
 865                 precache_sound ("misc/itemrespawncountdown.wav");
 866                 if(!g_minstagib && itemid == IT_STRENGTH)
 867                         precache_sound ("misc/strength_respawn.wav");
 868                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 869                         precache_sound ("misc/shield_respawn.wav");
 870                 else
 871                         precache_sound ("misc/itemrespawn.wav");
 872
 873                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 874                         self.target = "###item###"; // for finding the nearest item using find()
 875         }
 876
 877         self.bot_pickup = TRUE;
 878         self.bot_pickupevalfunc = pickupevalfunc;
 879         self.bot_pickupbasevalue = pickupbasevalue;
 880         self.mdl = self.model;
 881         self.netname = itemname;
 882         self.touch = Item_Touch;
 883         setmodel (self, self.mdl); // precision set below
 884         self.effects |= EF_LOWPRECISION;
 885         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 886                 setsize (self, '-16 -16 0', '16 16 48');
 887         else
 888                 setsize (self, '-16 -16 0', '16 16 32');
 889         if(itemflags & FL_WEAPON)
 890                 self.modelflags |= MF_ROTATE;
 891
 892         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 893         if (itemflags & FL_WEAPON)
 894         {
 895                 // neutral team color for pickup weapons
 896                 self.colormap = 1024; // color shirt=0 pants=0 grey
 897         }
 898
 899         self.state = 0;
 900         if(self.team)
 901         {
 902                 if(!self.cnt)
 903                         self.cnt = 1; // item probability weight
 904                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 905                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 906         }
 907         else
 908                 Item_Reset();
 909 }
 910
 911 /* replace items in minstagib
 912  * IT_STRENGTH   = invisibility
 913  * IT_NAILS      = extra lives
 914  * IT_INVINCIBLE = speed
 915  */
 916 void minstagib_items (float itemid)
 917 {
 918         float rnd;
 919         self.classname = "minstagib";
 920
 921         // replace rocket launchers and nex guns with ammo cells
 922         if (itemid == IT_CELLS)
 923         {
 924                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
 925                 StartItem ("models/items/a_cells.md3",
 926                         "misc/itempickup.wav", 45, 0,
 927                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 928                 return;
 929         }
 930
 931         // randomize
 932         rnd = random() * 3;
 933         if (rnd <= 1)
 934                 itemid = IT_STRENGTH;
 935         else if (rnd <= 2)
 936                 itemid = IT_NAILS;
 937         else
 938                 itemid = IT_INVINCIBLE;
 939
 940         // replace with invis
 941         if (itemid == IT_STRENGTH)
 942         {
 943                 if(!self.strength_finished)
 944                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
 945                 StartItem ("models/items/g_strength.md3",
 946                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 947                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 948         }
 949         // replace with extra lives
 950         if (itemid == IT_NAILS)
 951         {
 952                 self.max_health = 1;
 953                 StartItem ("models/items/g_h100.md3",
 954                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 955                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 956         }
 957         // replace with speed
 958         if (itemid == IT_INVINCIBLE)
 959         {
 960                 if(!self.invincible_finished)
 961                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
 962                 StartItem ("models/items/g_invincible.md3",
 963                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 964                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 965         }
 966 }
 967
 968 float minst_no_auto_cells;
 969 void minst_remove_item (void) {
 970         if(minst_no_auto_cells)
 971                 remove(self);
 972 }
 973
 974 float weaponswapping;
 975 float internalteam;
 976
 977 void weapon_defaultspawnfunc(float wpn)
 978 {
 979         entity e;
 980         float t;
 981         var .float ammofield;
 982         string s;
 983         entity oldself;
 984         float i, j;
 985         float f;
 986
 987         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 988         {
 989                 e = get_weaponinfo(wpn);
 990
 991                 if(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 992                 {
 993                         objerror("Attempted to spawn a mutator-blocked weapon rejected");
 994                         startitem_failed = TRUE;
 995                         return;
 996                 }
 997
 998                 s = W_Apply_Weaponreplace(e.netname);
 999                 ret_string = s;
1000                 other = e;
1001                 MUTATOR_CALLHOOK(SetWeaponreplace);
1002                 s = ret_string;
1003                 if(s == "")
1004                 {
1005                         remove(self);
1006                         startitem_failed = TRUE;
1007                         return;
1008                 }
1009                 t = tokenize_console(s);
1010                 if(t >= 2)
1011                 {
1012                         self.team = --internalteam;
1013                         oldself = self;
1014                         for(i = 1; i < t; ++i)
1015                         {
1016                                 s = argv(i);
1017                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1018                                 {
1019                                         e = get_weaponinfo(j);
1020                                         if(e.netname == s)
1021                                         {
1022                                                 self = spawn();
1023                                                 copyentity(oldself, self);
1024                                                 self.classname = "replacedweapon";
1025                                                 weapon_defaultspawnfunc(j);
1026                                                 break;
1027                                         }
1028                                 }
1029                                 if(j > WEP_LAST)
1030                                 {
1031                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1032                                 }
1033                         }
1034                         self = oldself;
1035                 }
1036                 if(t >= 1) // always the case!
1037                 {
1038                         s = argv(0);
1039                         wpn = 0;
1040                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1041                         {
1042                                 e = get_weaponinfo(j);
1043                                 if(e.netname == s)
1044                                 {
1045                                         wpn = j;
1046                                         break;
1047                                 }
1048                         }
1049                         if(j > WEP_LAST)
1050                         {
1051                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1052                         }
1053                 }
1054                 if(wpn == 0)
1055                 {
1056                         remove(self);
1057                         startitem_failed = TRUE;
1058                         return;
1059                 }
1060         }
1061
1062         e = get_weaponinfo(wpn);
1063
1064         if(!self.respawntime)
1065         {
1066                 if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1067                 {
1068                         self.respawntime = g_pickup_respawntime_superweapon;
1069                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1070                 }
1071                 else
1072                 {
1073                         self.respawntime = g_pickup_respawntime_weapon;
1074                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1075                 }
1076         }
1077
1078         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1079                 if(!self.superweapons_finished)
1080                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1081
1082         if(e.items)
1083         {
1084                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1085                 {
1086                         if(e.items & j)
1087                         {
1088                                 ammofield = Item_CounterField(j);
1089                                 if(!self.ammofield)
1090                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1091                         }
1092                 }
1093         }
1094
1095         // pickup anyway
1096         if(g_pickup_weapons_anyway)
1097                 self.pickup_anyway = TRUE;
1098
1099         f = FL_WEAPON;
1100
1101         // no weapon-stay on superweapons
1102         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1103                 f |= FL_NO_WEAPON_STAY;
1104
1105         // weapon stay isn't supported for teamed weapons
1106         if(self.team)
1107                 f |= FL_NO_WEAPON_STAY;
1108
1109         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapon, f, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1110         if (self.modelindex) // don't precache if self was removed
1111                 weapon_action(e.weapon, WR_PRECACHE);
1112 }
1113
1114 void spawnfunc_weapon_shotgun (void);
1115 void spawnfunc_weapon_uzi (void) {
1116         if(autocvar_sv_q3acompat_machineshotgunswap)
1117         if(self.classname != "droppedweapon")
1118         {
1119                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1120                 return;
1121         }
1122         weapon_defaultspawnfunc(WEP_UZI);
1123 }
1124
1125 void spawnfunc_weapon_shotgun (void) {
1126         if(autocvar_sv_q3acompat_machineshotgunswap)
1127         if(self.classname != "droppedweapon")
1128         {
1129                 weapon_defaultspawnfunc(WEP_UZI);
1130                 return;
1131         }
1132         weapon_defaultspawnfunc(WEP_SHOTGUN);
1133 }
1134
1135 void spawnfunc_weapon_nex (void)
1136 {
1137         if (g_minstagib)
1138         {
1139                 minstagib_items(IT_CELLS);
1140                 self.think = minst_remove_item;
1141                 self.nextthink = time;
1142                 return;
1143         }
1144         weapon_defaultspawnfunc(WEP_NEX);
1145 }
1146
1147 void spawnfunc_weapon_minstanex (void)
1148 {
1149         if (g_minstagib)
1150         {
1151                 minstagib_items(IT_CELLS);
1152                 self.think = minst_remove_item;
1153                 self.nextthink = time;
1154                 return;
1155         }
1156         weapon_defaultspawnfunc(WEP_MINSTANEX);
1157 }
1158
1159 void spawnfunc_weapon_rocketlauncher (void)
1160 {
1161         if (g_minstagib)
1162         {
1163                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1164                 self.think = minst_remove_item;
1165                 self.nextthink = time;
1166                 return;
1167         }
1168         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1169 }
1170
1171 void spawnfunc_item_rockets (void) {
1172         if(!self.ammo_rockets)
1173                 self.ammo_rockets = g_pickup_rockets;
1174         if(!self.pickup_anyway)
1175                 self.pickup_anyway = g_pickup_ammo_anyway;
1176         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1177 }
1178
1179 void spawnfunc_item_shells (void);
1180 void spawnfunc_item_bullets (void) {
1181         if(!weaponswapping)
1182         if(autocvar_sv_q3acompat_machineshotgunswap)
1183         if(self.classname != "droppedweapon")
1184         {
1185                 weaponswapping = TRUE;
1186                 spawnfunc_item_shells();
1187                 weaponswapping = FALSE;
1188                 return;
1189         }
1190
1191         if(!self.ammo_nails)
1192                 self.ammo_nails = g_pickup_nails;
1193         if(!self.pickup_anyway)
1194                 self.pickup_anyway = g_pickup_ammo_anyway;
1195         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1196 }
1197
1198 void spawnfunc_item_cells (void) {
1199         if(!self.ammo_cells)
1200                 self.ammo_cells = g_pickup_cells;
1201         if(!self.pickup_anyway)
1202                 self.pickup_anyway = g_pickup_ammo_anyway;
1203         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1204 }
1205
1206 void spawnfunc_item_shells (void) {
1207         if(!weaponswapping)
1208         if(autocvar_sv_q3acompat_machineshotgunswap)
1209         if(self.classname != "droppedweapon")
1210         {
1211                 weaponswapping = TRUE;
1212                 spawnfunc_item_bullets();
1213                 weaponswapping = FALSE;
1214                 return;
1215         }
1216
1217         if(!self.ammo_shells)
1218                 self.ammo_shells = g_pickup_shells;
1219         if(!self.pickup_anyway)
1220                 self.pickup_anyway = g_pickup_ammo_anyway;
1221         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1222 }
1223
1224 void spawnfunc_item_armor_small (void) {
1225         if(!self.armorvalue)
1226                 self.armorvalue = g_pickup_armorsmall;
1227         if(!self.max_armorvalue)
1228                 self.max_armorvalue = g_pickup_armorsmall_max;
1229         if(!self.pickup_anyway)
1230                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1231         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1232 }
1233
1234 void spawnfunc_item_armor_medium (void) {
1235         if(!self.armorvalue)
1236                 self.armorvalue = g_pickup_armormedium;
1237         if(!self.max_armorvalue)
1238                 self.max_armorvalue = g_pickup_armormedium_max;
1239         if(!self.pickup_anyway)
1240                 self.pickup_anyway = g_pickup_armormedium_anyway;
1241         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1242 }
1243
1244 void spawnfunc_item_armor_big (void) {
1245         if(!self.armorvalue)
1246                 self.armorvalue = g_pickup_armorbig;
1247         if(!self.max_armorvalue)
1248                 self.max_armorvalue = g_pickup_armorbig_max;
1249         if(!self.pickup_anyway)
1250                 self.pickup_anyway = g_pickup_armorbig_anyway;
1251         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1252 }
1253
1254 void spawnfunc_item_armor_large (void) {
1255         if(!self.armorvalue)
1256                 self.armorvalue = g_pickup_armorlarge;
1257         if(!self.max_armorvalue)
1258                 self.max_armorvalue = g_pickup_armorlarge_max;
1259         if(!self.pickup_anyway)
1260                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1261         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1262 }
1263
1264 void spawnfunc_item_health_small (void) {
1265         if(!self.max_health)
1266                 self.max_health = g_pickup_healthsmall_max;
1267         if(!self.health)
1268                 self.health = g_pickup_healthsmall;
1269         if(!self.pickup_anyway)
1270                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1271         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1272 }
1273
1274 void spawnfunc_item_health_medium (void) {
1275         if(!self.max_health)
1276                 self.max_health = g_pickup_healthmedium_max;
1277         if(!self.health)
1278                 self.health = g_pickup_healthmedium;
1279         if(!self.pickup_anyway)
1280                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1281         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1282 }
1283
1284 void spawnfunc_item_health_large (void) {
1285         if(!self.max_health)
1286                 self.max_health = g_pickup_healthlarge_max;
1287         if(!self.health)
1288                 self.health = g_pickup_healthlarge;
1289         if(!self.pickup_anyway)
1290                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1291         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1292 }
1293
1294 void spawnfunc_item_health_mega (void) {
1295         if(g_minstagib) {
1296                 minstagib_items(IT_NAILS);
1297         } else {
1298                 if(!self.max_health)
1299                         self.max_health = g_pickup_healthmega_max;
1300                 if(!self.health)
1301                         self.health = g_pickup_healthmega;
1302                 if(!self.pickup_anyway)
1303                         self.pickup_anyway = g_pickup_healthmega_anyway;
1304                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1305         }
1306 }
1307
1308 // support old misnamed entities
1309 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1310 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1311 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1312 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1313 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1314
1315 void spawnfunc_item_strength (void) {
1316         if(g_minstagib) {
1317                 minstagib_items(IT_STRENGTH);
1318         } else {
1319                 precache_sound("weapons/strength_fire.wav");
1320                 if(!self.strength_finished)
1321                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1322                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1323         }
1324 }
1325
1326 void spawnfunc_item_invincible (void) {
1327         if(g_minstagib) {
1328                 minstagib_items(IT_INVINCIBLE);
1329         } else {
1330                 if(!self.invincible_finished)
1331                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1332                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1333         }
1334 }
1335
1336 void spawnfunc_item_minst_cells (void) {
1337         if (g_minstagib)
1338         {
1339                 minst_no_auto_cells = 1;
1340                 minstagib_items(IT_CELLS);
1341         }
1342         else
1343                 remove(self);
1344 }
1345
1346 // compatibility:
1347 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1348
1349 float GiveItems(entity e, float beginarg, float endarg);
1350 void target_items_use (void)
1351 {
1352         if(activator.classname == "droppedweapon")
1353         {
1354                 EXACTTRIGGER_TOUCH;
1355                 remove(activator);
1356                 return;
1357         }
1358
1359         if(activator.classname != "player")
1360                 return;
1361         if(activator.deadflag != DEAD_NO)
1362                 return;
1363         EXACTTRIGGER_TOUCH;
1364
1365         entity e;
1366         for(e = world; (e = find(e, classname, "droppedweapon")); )
1367                 if(e.enemy == activator)
1368                         remove(e);
1369
1370         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1371                 centerprint(activator, self.message);
1372 }
1373
1374 void spawnfunc_target_items (void)
1375 {
1376         float n, i, j;
1377         entity e;
1378
1379         self.use = target_items_use;
1380         if(!self.strength_finished)
1381                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1382         if(!self.invincible_finished)
1383                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1384         if(!self.superweapons_finished)
1385                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1386
1387         precache_sound("misc/itempickup.wav");
1388         precache_sound("misc/megahealth.wav");
1389         precache_sound("misc/armor25.wav");
1390         precache_sound("misc/powerup.wav");
1391         precache_sound("misc/poweroff.wav");
1392         precache_sound("weapons/weaponpickup.wav");
1393
1394         n = tokenize_console(self.netname);
1395         if(argv(0) == "give")
1396         {
1397                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1398         }
1399         else
1400         {
1401                 for(i = 0; i < n; ++i)
1402                 {
1403                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1404                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1405                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1406                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1407                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1408                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1409                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1410                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1411                         else
1412                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1413                         {
1414                                 e = get_weaponinfo(j);
1415                                 if(argv(i) == e.netname)
1416                                 {
1417                                         WEPSET_OR_EW(self, j);
1418                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1419                                                 weapon_action(e.weapon, WR_PRECACHE);
1420                                         break;
1421                                 }
1422                         }
1423                         if(j > WEP_LAST)
1424                                 print("target_items: invalid item ", argv(i), "\n");
1425                 }
1426
1427                 string itemprefix, valueprefix;
1428                 if(self.spawnflags == 0)
1429                 {
1430                         itemprefix = "";
1431                         valueprefix = "";
1432                 }
1433                 else if(self.spawnflags == 1)
1434                 {
1435                         itemprefix = "max ";
1436                         valueprefix = "max ";
1437                 }
1438                 else if(self.spawnflags == 2)
1439                 {
1440                         itemprefix = "min ";
1441                         valueprefix = "min ";
1442                 }
1443                 else if(self.spawnflags == 4)
1444                 {
1445                         itemprefix = "minus ";
1446                         valueprefix = "max ";
1447                 }
1448                 else
1449                         error("invalid spawnflags");
1450
1451                 self.netname = "";
1452                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1453                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1454                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1455                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1456                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1457                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1458                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1459                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1460                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1461                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1462                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1463                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1464                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1465                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1466                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1467                 {
1468                         e = get_weaponinfo(j);
1469                         if(e.weapon)
1470                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, WEPSET_CONTAINS_EW(self, j), e.netname);
1471                 }
1472         }
1473         self.netname = strzone(self.netname);
1474         //print(self.netname, "\n");
1475
1476         n = tokenize_console(self.netname);
1477         for(i = 0; i < n; ++i)
1478         {
1479                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1480                 {
1481                         e = get_weaponinfo(j);
1482                         if(argv(i) == e.netname)
1483                         {
1484                                 weapon_action(e.weapon, WR_PRECACHE);
1485                                 break;
1486                         }
1487                 }
1488         }
1489 }
1490
1491 void spawnfunc_item_fuel(void)
1492 {
1493         if(!self.ammo_fuel)
1494                 self.ammo_fuel = g_pickup_fuel;
1495         if(!self.pickup_anyway)
1496                 self.pickup_anyway = g_pickup_ammo_anyway;
1497         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1498 }
1499
1500 void spawnfunc_item_fuel_regen(void)
1501 {
1502         if(start_items & IT_FUEL_REGEN)
1503         {
1504                 spawnfunc_item_fuel();
1505                 return;
1506         }
1507         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1508 }
1509
1510 void spawnfunc_item_jetpack(void)
1511 {
1512         if(g_grappling_hook)
1513                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1514         if(!self.ammo_fuel)
1515                 self.ammo_fuel = g_pickup_fuel_jetpack;
1516         if(start_items & IT_JETPACK)
1517         {
1518                 spawnfunc_item_fuel();
1519                 return;
1520         }
1521         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1522 }
1523
1524
1525 #define OP_SET 0
1526 #define OP_MIN 1
1527 #define OP_MAX 2
1528 #define OP_PLUS 3
1529 #define OP_MINUS 4
1530
1531 float GiveWeapon(entity e, float wpn, float op, float val)
1532 {
1533         float v0, v1;
1534         v0 = WEPSET_CONTAINS_EW(e, wpn);
1535         switch(op)
1536         {
1537                 case OP_SET:
1538                         if(val > 0)
1539                                 WEPSET_OR_EW(e, wpn);
1540                         else
1541                                 WEPSET_ANDNOT_EW(e, wpn);
1542                         break;
1543                 case OP_MIN:
1544                 case OP_PLUS:
1545                         if(val > 0)
1546                                 WEPSET_OR_EW(e, wpn);
1547                         break;
1548                 case OP_MAX:
1549                         if(val <= 0)
1550                                 WEPSET_ANDNOT_EW(e, wpn);
1551                         break;
1552                 case OP_MINUS:
1553                         if(val > 0)
1554                                 WEPSET_ANDNOT_EW(e, wpn);
1555                         break;
1556         }
1557         v1 = WEPSET_CONTAINS_EW(e, wpn);
1558         return (v0 != v1);
1559 }
1560
1561 float GiveBit(entity e, .float fld, float bit, float op, float val)
1562 {
1563         float v0, v1;
1564         v0 = (e.fld & bit);
1565         switch(op)
1566         {
1567                 case OP_SET:
1568                         if(val > 0)
1569                                 e.fld |= bit;
1570                         else
1571                                 e.fld &~= bit;
1572                         break;
1573                 case OP_MIN:
1574                 case OP_PLUS:
1575                         if(val > 0)
1576                                 e.fld |= bit;
1577                         break;
1578                 case OP_MAX:
1579                         if(val <= 0)
1580                                 e.fld &~= bit;
1581                         break;
1582                 case OP_MINUS:
1583                         if(val > 0)
1584                                 e.fld &~= bit;
1585                         break;
1586         }
1587         v1 = (e.fld & bit);
1588         return (v0 != v1);
1589 }
1590
1591 float GiveValue(entity e, .float fld, float op, float val)
1592 {
1593         float v0, v1;
1594         v0 = e.fld;
1595         switch(op)
1596         {
1597                 case OP_SET:
1598                         e.fld = val;
1599                         break;
1600                 case OP_MIN:
1601                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1602                         break;
1603                 case OP_MAX:
1604                         e.fld = min(e.fld, val);
1605                         break;
1606                 case OP_PLUS:
1607                         e.fld += val;
1608                         break;
1609                 case OP_MINUS:
1610                         e.fld -= val;
1611                         break;
1612         }
1613         v1 = e.fld;
1614         return (v0 != v1);
1615 }
1616
1617 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1618 {
1619         if(v1 == v0)
1620                 return;
1621         if(v1 <= v0 - t)
1622         {
1623                 if(snd_decr != "")
1624                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1625         }
1626         else if(v0 >= v0 + t)
1627         {
1628                 if(snd_incr != "")
1629                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1630         }
1631 }
1632
1633 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1634 {
1635         if(v0 < v1)
1636                 e.rotfield = max(e.rotfield, time + rottime);
1637         else if(v0 > v1)
1638                 e.regenfield = max(e.regenfield, time + regentime);
1639 }
1640
1641 #define PREGIVE_WEAPONS(e) WEPSET_DECLARE_A(save_weapons); WEPSET_COPY_AE(save_weapons, e)
1642 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1643 #define POSTGIVE_WEAPON(e,b,snd_incr,snd_decr) GiveSound((e), WEPSET_CONTAINS_AW(save_weapons, b), WEPSET_CONTAINS_EW(e, b), 0, snd_incr, snd_decr)
1644 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1645 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1646 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1647
1648 float GiveItems(entity e, float beginarg, float endarg)
1649 {
1650         float got, i, j, val, op;
1651         float _switchweapon;
1652         entity wi;
1653         string cmd;
1654
1655         val = 999;
1656         op = OP_SET;
1657
1658         got = 0;
1659
1660         _switchweapon = FALSE;
1661         if (e.autoswitch)
1662                 if (e.switchweapon == w_getbestweapon(e))
1663                         _switchweapon = TRUE;
1664
1665         e.strength_finished = max(0, e.strength_finished - time);
1666         e.invincible_finished = max(0, e.invincible_finished - time);
1667         e.superweapons_finished = max(0, e.superweapons_finished - time);
1668
1669         PREGIVE(e, items);
1670         PREGIVE_WEAPONS(e);
1671         PREGIVE(e, strength_finished);
1672         PREGIVE(e, invincible_finished);
1673         PREGIVE(e, superweapons_finished);
1674         PREGIVE(e, ammo_nails);
1675         PREGIVE(e, ammo_cells);
1676         PREGIVE(e, ammo_shells);
1677         PREGIVE(e, ammo_rockets);
1678         PREGIVE(e, ammo_fuel);
1679         PREGIVE(e, armorvalue);
1680         PREGIVE(e, health);
1681
1682         for(i = beginarg; i < endarg; ++i)
1683         {
1684                 cmd = argv(i);
1685
1686                 if(cmd == "0" || stof(cmd))
1687                 {
1688                         val = stof(cmd);
1689                         continue;
1690                 }
1691                 switch(cmd)
1692                 {
1693                         case "no":
1694                                 op = OP_MAX;
1695                                 val = 0;
1696                                 continue;
1697                         case "max":
1698                                 op = OP_MAX;
1699                                 continue;
1700                         case "min":
1701                                 op = OP_MIN;
1702                                 continue;
1703                         case "plus":
1704                                 op = OP_PLUS;
1705                                 continue;
1706                         case "minus":
1707                                 op = OP_MINUS;
1708                                 continue;
1709                         case "ALL":
1710                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1711                                 got += GiveValue(e, strength_finished, op, val);
1712                                 got += GiveValue(e, invincible_finished, op, val);
1713                                 got += GiveValue(e, superweapons_finished, op, val);
1714                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1715                         case "all":
1716                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1717                                 got += GiveValue(e, health, op, val);
1718                                 got += GiveValue(e, armorvalue, op, val);
1719                         case "allweapons":
1720                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1721                                 {
1722                                         wi = get_weaponinfo(j);
1723                                         if(wi.weapon)
1724                                                 if not(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1725                                                         got += GiveWeapon(e, j, op, val);
1726                                 }
1727                         case "allammo":
1728                                 got += GiveValue(e, ammo_cells, op, val);
1729                                 got += GiveValue(e, ammo_shells, op, val);
1730                                 got += GiveValue(e, ammo_nails, op, val);
1731                                 got += GiveValue(e, ammo_rockets, op, val);
1732                                 got += GiveValue(e, ammo_fuel, op, val);
1733                                 break;
1734                         case "unlimited_ammo":
1735                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1736                                 break;
1737                         case "unlimited_weapon_ammo":
1738                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1739                                 break;
1740                         case "unlimited_superweapons":
1741                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1742                                 break;
1743                         case "jetpack":
1744                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1745                                 break;
1746                         case "fuel_regen":
1747                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1748                                 break;
1749                         case "strength":
1750                                 got += GiveValue(e, strength_finished, op, val);
1751                                 break;
1752                         case "invincible":
1753                                 got += GiveValue(e, invincible_finished, op, val);
1754                                 break;
1755                         case "superweapons":
1756                                 got += GiveValue(e, superweapons_finished, op, val);
1757                                 break;
1758                         case "cells":
1759                                 got += GiveValue(e, ammo_cells, op, val);
1760                                 break;
1761                         case "shells":
1762                                 got += GiveValue(e, ammo_shells, op, val);
1763                                 break;
1764                         case "nails":
1765                         case "bullets":
1766                                 got += GiveValue(e, ammo_nails, op, val);
1767                                 break;
1768                         case "rockets":
1769                                 got += GiveValue(e, ammo_rockets, op, val);
1770                                 break;
1771                         case "health":
1772                                 got += GiveValue(e, health, op, val);
1773                                 break;
1774                         case "armor":
1775                                 got += GiveValue(e, armorvalue, op, val);
1776                                 break;
1777                         case "fuel":
1778                                 got += GiveValue(e, ammo_fuel, op, val);
1779                                 break;
1780                         default:
1781                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1782                                 {
1783                                         wi = get_weaponinfo(j);
1784                                         if(cmd == wi.netname)
1785                                         {
1786                                                 got += GiveWeapon(e, j, op, val);
1787                                                 break;
1788                                         }
1789                                 }
1790                                 if(j > WEP_LAST)
1791                                         print("give: invalid item ", cmd, "\n");
1792                                 break;
1793                 }
1794                 val = 999;
1795                 op = OP_SET;
1796         }
1797
1798         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1799         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1800         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1801         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1802         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1803         {
1804                 wi = get_weaponinfo(j);
1805                 if(wi.weapon)
1806                 {
1807                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
1808                         if not(WEPSET_CONTAINS_AW(save_weapons, j))
1809                                 if(WEPSET_CONTAINS_EW(e, j))
1810                                         weapon_action(wi.weapon, WR_PRECACHE);
1811                 }
1812         }
1813         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1814         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1815         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1816         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1817         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1818         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1819         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1820         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1821         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1822
1823         if(e.superweapons_finished <= 0)
1824                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1825                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1826
1827         if (g_minstagib)
1828         {
1829                 e.health = bound(0, e.health, 100);
1830                 e.armorvalue = bound(0, e.armorvalue, 999);
1831         }
1832
1833         if(e.strength_finished <= 0)
1834                 e.strength_finished = 0;
1835         else
1836                 e.strength_finished += time;
1837         if(e.invincible_finished <= 0)
1838                 e.invincible_finished = 0;
1839         else
1840                 e.invincible_finished += time;
1841         if(e.superweapons_finished <= 0)
1842                 e.superweapons_finished = 0;
1843         else
1844                 e.superweapons_finished += time;
1845
1846         if not(WEPSET_CONTAINS_EW(e, e.switchweapon))
1847                 _switchweapon = TRUE;
1848         if(_switchweapon)
1849                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1850
1851         return got;
1852 }