qcsrc/server/t_items.qc

   1 float have_pickup_item(void)
   2 {
   3         // minstagib: only allow filtered items
   4         if(g_minstagib)
   5                 if(self.classname != "minstagib")
   6                         return FALSE;
   7
   8         if(self.items == IT_STRENGTH || self.items == IT_INVINCIBLE)
   9         {
  10                 if(autocvar_g_powerups > 0)
  11                         return TRUE;
  12                 if(autocvar_g_powerups == 0)
  13                         return FALSE;
  14                 if(g_lms)
  15                         return FALSE;
  16                 if(g_ca)
  17                         return FALSE;
  18                 if(g_arena)
  19                         return FALSE;
  20         }
  21         else
  22         {
  23                 if(autocvar_g_pickup_items > 0)
  24                         return TRUE;
  25                 if(autocvar_g_pickup_items == 0)
  26                         return FALSE;
  27                 if(g_lms)
  28                         return FALSE;
  29                 if(g_ca)
  30                         return FALSE;
  31                 if(g_weaponarena)
  32                         if((self.weapons & WEPBIT_ALL) || (self.items & IT_AMMO))
  33                                 return FALSE;
  34         }
  35         return TRUE;
  36 }
  37
  38 #define ITEM_RESPAWN_TICKS 10
  39
  40 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
  41         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
  42 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
  43         // range: 10 .. respawntime + respawntimejitter
  44
  45 floatfield Item_CounterField(float it)
  46 {
  47         switch(it)
  48         {
  49                 case IT_SHELLS:      return ammo_shells;
  50                 case IT_NAILS:       return ammo_nails;
  51                 case IT_ROCKETS:     return ammo_rockets;
  52                 case IT_CELLS:       return ammo_cells;
  53                 case IT_FUEL:        return ammo_fuel;
  54                 case IT_5HP:         return health;
  55                 case IT_25HP:        return health;
  56                 case IT_HEALTH:      return health;
  57                 case IT_ARMOR_SHARD: return armorvalue;
  58                 case IT_ARMOR:       return armorvalue;
  59                 // add more things here (health, armor)
  60                 default:             error("requested item has no counter field");
  61         }
  62 }
  63
  64 string Item_CounterFieldName(float it)
  65 {
  66         switch(it)
  67         {
  68                 case IT_SHELLS:      return "shells";
  69                 case IT_NAILS:       return "nails";
  70                 case IT_ROCKETS:     return "rockets";
  71                 case IT_CELLS:       return "cells";
  72                 case IT_FUEL:        return "fuel";
  73
  74                 // add more things here (health, armor)
  75                 default:             error("requested item has no counter field name");
  76         }
  77 }
  78
  79 .float max_armorvalue;
  80 .float pickup_anyway;
  81
  82 float Item_Customize()
  83 {
  84         if(self.spawnshieldtime)
  85                 return TRUE;
  86         if(self.weapons != (self.weapons & other.weapons))
  87         {
  88                 self.colormod = '0 0 0';
  89                 self.glowmod = self.colormod;
  90                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  91                 return TRUE;
  92         }
  93         else
  94         {
  95                 if(g_ghost_items)
  96                 {
  97                         self.colormod = stov(autocvar_g_ghost_items_color);
  98                         self.glowmod = self.colormod;
  99                         self.alpha = g_ghost_items;
 100                         return TRUE;
 101                 }
 102                 else
 103                         return FALSE;
 104         }
 105 }
 106
 107 void Item_Show (entity e, float mode)
 108 {
 109         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 110         if (mode > 0)
 111         {
 112                 // make the item look normal, and be touchable
 113                 e.model = e.mdl;
 114                 e.solid = SOLID_TRIGGER;
 115                 e.colormod = '0 0 0';
 116                 self.glowmod = self.colormod;
 117                 e.alpha = 0;
 118                 e.customizeentityforclient = func_null;
 119
 120                 e.spawnshieldtime = 1;
 121         }
 122         else if (mode < 0)
 123         {
 124                 // hide the item completely
 125                 e.model = string_null;
 126                 e.solid = SOLID_NOT;
 127                 e.colormod = '0 0 0';
 128                 self.glowmod = self.colormod;
 129                 e.alpha = 0;
 130                 e.customizeentityforclient = func_null;
 131
 132                 e.spawnshieldtime = 1;
 133         }
 134         else if((e.flags & FL_WEAPON) && g_weapon_stay)
 135         {
 136                 // make the item translucent and not touchable
 137                 e.model = e.mdl;
 138                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 139                 e.colormod = '0 0 0';
 140                 self.glowmod = self.colormod;
 141                 e.effects |= EF_STARDUST;
 142                 e.customizeentityforclient = Item_Customize;
 143
 144                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 145         }
 146         else if(g_ghost_items)
 147         {
 148                 // make the item translucent and not touchable
 149                 e.model = e.mdl;
 150                 e.solid = SOLID_NOT;
 151                 e.colormod = stov(autocvar_g_ghost_items_color);
 152                 e.glowmod = e.colormod;
 153                 e.alpha = g_ghost_items;
 154                 e.customizeentityforclient = func_null;
 155
 156                 e.spawnshieldtime = 1;
 157         }
 158         else
 159         {
 160                 // hide the item completely
 161                 e.model = string_null;
 162                 e.solid = SOLID_NOT;
 163                 e.colormod = '0 0 0';
 164                 e.glowmod = e.colormod;
 165                 e.alpha = 0;
 166                 e.customizeentityforclient = func_null;
 167
 168                 e.spawnshieldtime = 1;
 169         }
 170
 171         if (e.strength_finished || e.invincible_finished)
 172                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 173         if (autocvar_g_nodepthtestitems)
 174                 e.effects |= EF_NODEPTHTEST;
 175         if (autocvar_g_fullbrightitems)
 176                 e.effects |= EF_FULLBRIGHT;
 177
 178         // relink entity (because solid may have changed)
 179         setorigin(e, e.origin);
 180 }
 181
 182 void Item_Respawn (void)
 183 {
 184         Item_Show(self, 1);
 185         if(!g_minstagib && self.items == IT_STRENGTH)
 186                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 187         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 188                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 189         else
 190                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 191         setorigin (self, self.origin);
 192
 193         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 194         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 195 }
 196
 197 void Item_RespawnCountdown (void)
 198 {
 199         if(self.count >= ITEM_RESPAWN_TICKS)
 200         {
 201                 if(self.waypointsprite_attached)
 202                         WaypointSprite_Kill(self.waypointsprite_attached);
 203                 Item_Respawn();
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 self.count += 1;
 209                 if(self.count == 1)
 210                 {
 211                         string name;
 212                         vector rgb;
 213                         name = string_null;
 214                         if(g_minstagib)
 215                         {
 216                                 switch(self.items)
 217                                 {
 218                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 219                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 220                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 221                                 }
 222                         }
 223                         else
 224                         {
 225                                 switch(self.items)
 226                                 {
 227                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 228                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 229                                 }
 230                         }
 231                         switch(self.items)
 232                         {
 233                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 234                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 235                         }
 236                         if(name)
 237                         {
 238                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 239                                 if(self.waypointsprite_attached)
 240                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 241                         }
 242                 }
 243                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 244                 if(self.waypointsprite_attached)
 245                 {
 246                         WaypointSprite_Ping(self.waypointsprite_attached);
 247                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 248                 }
 249         }
 250 }
 251
 252 void Item_ScheduleRespawnIn(entity e, float t)
 253 {
 254         if(e.flags & FL_POWERUP)
 255         {
 256                 e.think = Item_RespawnCountdown;
 257                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 258                 e.count = 0;
 259         }
 260         else
 261         {
 262                 e.think = Item_Respawn;
 263                 e.nextthink = time + t;
 264         }
 265 }
 266
 267 void Item_ScheduleRespawn(entity e)
 268 {
 269         if(e.respawntime > 0)
 270         {
 271                 Item_Show(e, 0);
 272                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 273         }
 274         else // if respawntime is -1, this item does not respawn
 275                 Item_Show(e, -1);
 276 }
 277
 278 void Item_ScheduleInitialRespawn(entity e)
 279 {
 280         Item_Show(e, 0);
 281         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 282 }
 283
 284 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax)
 285 {
 286         if (!item.ammofield)
 287                 return FALSE;
 288
 289         if (item.spawnshieldtime)
 290         {
 291                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 292                 {
 293                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammo_cells);
 294                         goto YEAH;
 295                 }
 296         }
 297         else if(g_weapon_stay == 2)
 298         {
 299                 float mi = min(item.ammofield, ammomax);
 300                 if ((player.ammofield < mi) || item.pickup_anyway)
 301                 {
 302                         player.ammofield = max(player.ammofield, mi);
 303                         goto YEAH;
 304                 }
 305         }
 306
 307         return FALSE;
 308
 309 :YEAH
 310         if(ammofield == ammo_fuel)
 311                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 312         if(ammofield == health)
 313                 player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 314         if(ammofield == armorvalue)
 315                 player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 316         return TRUE;
 317 }
 318
 319 float Item_GiveTo(entity item, entity player)
 320 {
 321         float _switchweapon;
 322         float pickedup;
 323         float it;
 324         float i;
 325         entity e;
 326
 327         // if nothing happens to player, just return without taking the item
 328         pickedup = FALSE;
 329         _switchweapon = FALSE;
 330
 331         if (g_minstagib)
 332         {
 333                 float prevcells = player.ammo_cells;
 334
 335                 Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max);
 336                 Item_GiveAmmoTo(item, player, ammo_cells, 999);
 337
 338                 if(player.ammo_cells > prevcells)
 339                 {
 340                         _switchweapon = TRUE;
 341
 342                         // play some cool sounds ;)
 343                         if (clienttype(player) == CLIENTTYPE_REAL)
 344                         {
 345                                 if(player.health <= 5)
 346                                         AnnounceTo(player, "lastsecond");
 347                                 else if(player.health < 50)
 348                                         AnnounceTo(player, "narrowly");
 349                         }
 350                         // sound not available
 351                         // else if(item.items == IT_CELLS)
 352                         //      AnnounceTo(player, "ammo");
 353
 354                         if (item.weapons & WEPBIT_MINSTANEX)
 355                                 W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 356                         if (item.ammo_cells)
 357                                 player.ammo_cells = bound(player.ammo_cells, 999, player.ammo_cells + autocvar_g_minstagib_ammo_drop);
 358                         player.health = 100;
 359                 }
 360
 361                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 362                 {
 363                         pickedup = TRUE;
 364                         player.items |= it;
 365                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 366                 }
 367
 368                 // extralife powerup
 369                 if (item.max_health)
 370                 {
 371                         pickedup = TRUE;
 372                         // sound not available
 373                         // AnnounceTo(player, "_lives");
 374                         player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 375                         sprint(player, "^3You picked up some extra lives\n");
 376                 }
 377
 378                 // invis powerup
 379                 if (item.strength_finished)
 380                 {
 381                         pickedup = TRUE;
 382                         // sound not available
 383                         // AnnounceTo(player, "invisible");
 384                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 385                 }
 386
 387                 // speed powerup
 388                 if (item.invincible_finished)
 389                 {
 390                         pickedup = TRUE;
 391                         // sound not available
 392                         // AnnounceTo(player, "speed");
 393                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_strength_time;
 394                 }
 395         }
 396         else
 397         {
 398                 // in case the player has autoswitch enabled do the following:
 399                 // if the player is using their best weapon before items are given, they
 400                 // probably want to switch to an even better weapon after items are given
 401                 if (player.autoswitch)
 402                 if (player.switchweapon == w_getbestweapon(player))
 403                         _switchweapon = TRUE;
 404
 405                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 406                         _switchweapon = TRUE;
 407
 408                 Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max);
 409                 Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max);
 410                 Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max);
 411                 Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max);
 412                 Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max);
 413                 Item_GiveAmmoTo(item, player, health, item.max_health);
 414                 Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue);
 415
 416                 if (item.flags & FL_WEAPON)
 417                 if ((it = item.weapons - (item.weapons & player.weapons)) || (g_pickup_weapons_anyway))
 418                 {
 419                         pickedup = TRUE;
 420                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 421                         {
 422                                 e = get_weaponinfo(i);
 423                                 if(it & e.weapons)
 424                                         W_GiveWeapon (player, e.weapon, item.netname);
 425                         }
 426                 }
 427
 428                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 429                 {
 430                         pickedup = TRUE;
 431                         player.items |= it;
 432                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 433                 }
 434
 435                 if (item.strength_finished)
 436                 {
 437                         pickedup = TRUE;
 438                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 439                 }
 440                 if (item.invincible_finished)
 441                 {
 442                         pickedup = TRUE;
 443                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_invincible_time;
 444                 }
 445         }
 446
 447 :skip
 448         // always eat teamed entities
 449         if(item.team)
 450                 pickedup = TRUE;
 451
 452         if (!pickedup)
 453                 return 0;
 454
 455         sound (player, CH_TRIGGER, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 456         if (_switchweapon)
 457                 if (player.switchweapon != w_getbestweapon(player))
 458                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 459
 460         return 1;
 461 }
 462
 463 void Item_Touch (void)
 464 {
 465         entity e, head;
 466
 467         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 468         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 469         {
 470                 remove(self);
 471                 return;
 472         }
 473         if (other.classname != "player")
 474                 return;
 475         if (other.deadflag)
 476                 return;
 477         if (self.solid != SOLID_TRIGGER)
 478                 return;
 479         if (self.owner == other)
 480                 return;
 481
 482         if(!Item_GiveTo(self, other))
 483                 return;
 484
 485         other.last_pickup = time;
 486
 487         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 488
 489         if (self.classname == "droppedweapon")
 490                 remove (self);
 491         else if not(self.spawnshieldtime)
 492                 return;
 493         else
 494         {
 495                 if(self.team)
 496                 {
 497                         RandomSelection_Init();
 498                         for(head = world; (head = findfloat(head, team, self.team)); )
 499                         {
 500                                 if(head.flags & FL_ITEM)
 501                                 {
 502                                         Item_Show(head, -1);
 503                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 504                                 }
 505                         }
 506                         e = RandomSelection_chosen_ent;
 507                 }
 508                 else
 509                         e = self;
 510                 Item_ScheduleRespawn(e);
 511         }
 512 }
 513
 514 void Item_FindTeam()
 515 {
 516         entity head, e;
 517
 518         if(self.effects & EF_NODRAW)
 519         {
 520                 // marker for item team search
 521                 dprint("Initializing item team ", ftos(self.team), "\n");
 522                 RandomSelection_Init();
 523                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 524                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 525                 e = RandomSelection_chosen_ent;
 526                 e.state = 0;
 527                 Item_Show(e, 1);
 528
 529                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 530                 {
 531                         if(head != e)
 532                         {
 533                                 // make it a non-spawned item
 534                                 Item_Show(head, -1);
 535                                 head.state = 1; // state 1 = initially hidden item
 536                         }
 537                         head.effects &~= EF_NODRAW;
 538                 }
 539
 540                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 541                         Item_ScheduleInitialRespawn(e);
 542         }
 543 }
 544
 545 void Item_Reset()
 546 {
 547         Item_Show(self, !self.state);
 548         setorigin (self, self.origin);
 549         self.think = SUB_Null;
 550         self.nextthink = 0;
 551
 552         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 553                 Item_ScheduleInitialRespawn(self);
 554 }
 555
 556 // Savage: used for item garbage-collection
 557 // TODO: perhaps nice special effect?
 558 void RemoveItem(void)
 559 {
 560         remove(self);
 561 }
 562
 563 // pickup evaluation functions
 564 // these functions decide how desirable an item is to the bots
 565
 566 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 567
 568 float weapon_pickupevalfunc(entity player, entity item)
 569 {
 570         float c, i, j, position;
 571
 572         // See if I have it already
 573         if(player.weapons & item.weapons == item.weapons)
 574         {
 575                 // If I can pick it up
 576                 if(!item.spawnshieldtime)
 577                         c = 0;
 578                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 579                 {
 580                         // Skilled bots will grab more
 581                         c = bound(0, skill / 10, 1) * 0.5;
 582                 }
 583                 else
 584                         c = 0;
 585         }
 586         else
 587                 c = 1;
 588
 589         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 590         if( bot_custom_weapon && c )
 591         {
 592                 for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 593                 {
 594                         // Find weapon
 595                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 596                                 continue;
 597
 598                         // Find the highest position on any range
 599                         position = -1;
 600                         for(j = 0; j < WEP_LAST ; ++j){
 601                                 if(
 602                                                 bot_weapons_far[j] == i ||
 603                                                 bot_weapons_mid[j] == i ||
 604                                                 bot_weapons_close[j] == i
 605                                   )
 606                                 {
 607                                         position = j;
 608                                         break;
 609                                 }
 610                         }
 611
 612                         // Rate it
 613                         if (position >= 0 )
 614                         {
 615                                 position = WEP_LAST - position;
 616                                 // item.bot_pickupbasevalue is overwritten here
 617                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 618                         }
 619                 }
 620         }
 621
 622         return item.bot_pickupbasevalue * c;
 623 }
 624
 625 float commodity_pickupevalfunc(entity player, entity item)
 626 {
 627         float c, i, need_shells, need_nails, need_rockets, need_cells;
 628         entity wi;
 629         c = 0;
 630
 631         // Detect needed ammo
 632         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 633         {
 634                 wi = get_weaponinfo(i);
 635
 636                 if not(wi.weapons & player.weapons)
 637                         continue;
 638
 639                 if(wi.items & IT_SHELLS)
 640                         need_shells = TRUE;
 641                 else if(wi.items & IT_NAILS)
 642                         need_nails = TRUE;
 643                 else if(wi.items & IT_ROCKETS)
 644                         need_rockets = TRUE;
 645                 else if(wi.items & IT_CELLS)
 646                         need_cells = TRUE;
 647         }
 648
 649         // TODO: figure out if the player even has the weapon this ammo is for?
 650         // may not affect strategy much though...
 651         // find out how much more ammo/armor/health the player can hold
 652         if (need_shells)
 653         if (item.ammo_shells)
 654         if (player.ammo_shells < g_pickup_shells_max)
 655                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 656         if (need_nails)
 657         if (item.ammo_nails)
 658         if (player.ammo_nails < g_pickup_nails_max)
 659                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 660         if (need_rockets)
 661         if (item.ammo_rockets)
 662         if (player.ammo_rockets < g_pickup_rockets_max)
 663                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 664         if (need_cells)
 665         if (item.ammo_cells)
 666         if (player.ammo_cells < g_pickup_cells_max)
 667                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 668         if (item.armorvalue)
 669         if (player.armorvalue < item.max_armorvalue)
 670                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 671         if (item.health)
 672         if (player.health < item.max_health)
 673                 c = c + max(0, 1 - player.health / item.max_health);
 674
 675         return item.bot_pickupbasevalue * c;
 676 }
 677
 678
 679 .float is_item;
 680 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 681 {
 682         startitem_failed = FALSE;
 683
 684         self.items = itemid;
 685         self.weapons = weaponid;
 686
 687         // is it a dropped weapon?
 688         if (self.classname == "droppedweapon")
 689         {
 690                 self.reset = SUB_Remove;
 691                 // it's a dropped weapon
 692                 self.movetype = MOVETYPE_TOSS;
 693                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 694                 self.think = RemoveItem;
 695                 self.nextthink = time + 60;
 696                 // don't drop if in a NODROP zone (such as lava)
 697                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 698                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 699                 {
 700                         startitem_failed = TRUE;
 701                         remove(self);
 702                         return;
 703                 }
 704         }
 705         else
 706         {
 707                 if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 708                 {
 709                         startitem_failed = TRUE;
 710                         remove(self);
 711                         return;
 712                 }
 713
 714                 if(!have_pickup_item())
 715                 {
 716                         startitem_failed = TRUE;
 717                         remove (self);
 718                         return;
 719                 }
 720
 721                 self.reset = Item_Reset;
 722                 // it's a level item
 723                 if(self.spawnflags & 1)
 724                         self.noalign = 1;
 725                 if (self.noalign)
 726                         self.movetype = MOVETYPE_NONE;
 727                 else
 728                         self.movetype = MOVETYPE_TOSS;
 729                 // do item filtering according to game mode and other things
 730                 if (!self.noalign)
 731                 {
 732                         // first nudge it off the floor a little bit to avoid math errors
 733                         setorigin(self, self.origin + '0 0 1');
 734                         // set item size before we spawn a spawnfunc_waypoint
 735                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 736                                 setsize (self, '-16 -16 0', '16 16 48');
 737                         else
 738                                 setsize (self, '-16 -16 0', '16 16 32');
 739                         // note droptofloor returns FALSE if stuck/or would fall too far
 740                         droptofloor();
 741                         waypoint_spawnforitem(self);
 742                 }
 743
 744                 /*
 745                  * can't do it that way, as it would break maps
 746                  * TODO make a target_give like entity another way, that perhaps has
 747                  * the weapon name in a key
 748                 if(self.targetname)
 749                 {
 750                         // target_give not yet supported; maybe later
 751                         print("removed targeted ", self.classname, "\n");
 752                         startitem_failed = TRUE;
 753                         remove (self);
 754                         return;
 755                 }
 756                 */
 757
 758                 if(autocvar_spawn_debug >= 2)
 759                 {
 760                         entity otheritem;
 761                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 762                         {
 763                                 if(otheritem.is_item)
 764                                 {
 765                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 766                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 767                                         error("Mapper sucks.");
 768                                 }
 769                         }
 770                         self.is_item = TRUE;
 771                 }
 772
 773                 weaponsInMap |= weaponid;
 774
 775                 precache_model (itemmodel);
 776                 precache_sound (pickupsound);
 777
 778                 precache_sound ("misc/itemrespawncountdown.wav");
 779                 if(!g_minstagib && itemid == IT_STRENGTH)
 780                         precache_sound ("misc/strength_respawn.wav");
 781                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 782                         precache_sound ("misc/shield_respawn.wav");
 783                 else
 784                         precache_sound ("misc/itemrespawn.wav");
 785
 786                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 787                         self.target = "###item###"; // for finding the nearest item using find()
 788         }
 789
 790         self.bot_pickup = TRUE;
 791         self.bot_pickupevalfunc = pickupevalfunc;
 792         self.bot_pickupbasevalue = pickupbasevalue;
 793         self.mdl = itemmodel;
 794         self.item_pickupsound = pickupsound;
 795         // let mappers override respawntime
 796         if(!self.respawntime) // both set
 797         {
 798                 self.respawntime = defaultrespawntime;
 799                 self.respawntimejitter = defaultrespawntimejitter;
 800         }
 801         self.netname = itemname;
 802         self.flags = FL_ITEM | itemflags;
 803         self.touch = Item_Touch;
 804         setmodel (self, self.mdl); // precision set below
 805         self.effects |= EF_LOWPRECISION;
 806         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 807                 setsize (self, '-16 -16 0', '16 16 48');
 808         else
 809                 setsize (self, '-16 -16 0', '16 16 32');
 810         if(itemflags & FL_WEAPON)
 811                 self.modelflags |= MF_ROTATE;
 812
 813         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 814         if (itemflags & FL_WEAPON)
 815         {
 816                 // neutral team color for pickup weapons
 817                 self.colormap = 1024; // color shirt=0 pants=0 grey
 818         }
 819
 820         Item_Show(self, 1);
 821         self.state = 0;
 822         if(self.team)
 823         {
 824                 if(!self.cnt)
 825                         self.cnt = 1; // item probability weight
 826                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 827                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 828         }
 829         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 830                 Item_ScheduleInitialRespawn(self);
 831 }
 832
 833 /* replace items in minstagib
 834  * IT_STRENGTH   = invisibility
 835  * IT_NAILS      = extra lives
 836  * IT_INVINCIBLE = speed
 837  */
 838 void minstagib_items (float itemid)
 839 {
 840         float rnd;
 841         self.classname = "minstagib";
 842
 843         // replace rocket launchers and nex guns with ammo cells
 844         if (itemid == IT_CELLS)
 845         {
 846                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
 847                 StartItem ("models/items/a_cells.md3",
 848                         "misc/itempickup.wav", 45, 0,
 849                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 850                 return;
 851         }
 852
 853         // randomize
 854         rnd = random() * 3;
 855         if (rnd <= 1)
 856                 itemid = IT_STRENGTH;
 857         else if (rnd <= 2)
 858                 itemid = IT_NAILS;
 859         else
 860                 itemid = IT_INVINCIBLE;
 861
 862         // replace with invis
 863         if (itemid == IT_STRENGTH)
 864         {
 865                 self.strength_finished = 30;
 866                 StartItem ("models/items/g_strength.md3",
 867                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 868                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 869         }
 870         // replace with extra lives
 871         if (itemid == IT_NAILS)
 872         {
 873                 self.max_health = 1;
 874                 StartItem ("models/items/g_h100.md3",
 875                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 876                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 877         }
 878         // replace with speed
 879         if (itemid == IT_INVINCIBLE)
 880         {
 881                 self.invincible_finished = 30;
 882                 StartItem ("models/items/g_invincible.md3",
 883                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 884                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 885         }
 886 }
 887
 888 float minst_no_auto_cells;
 889 void minst_remove_item (void) {
 890         if(minst_no_auto_cells)
 891                 remove(self);
 892 }
 893
 894 float weaponswapping;
 895 float internalteam;
 896
 897 void weapon_defaultspawnfunc(float wpn)
 898 {
 899         entity e;
 900         float t;
 901         var .float ammofield;
 902         string s;
 903         entity oldself;
 904         float i, j;
 905
 906         // set the respawntime in advance (so replaced weapons can copy it)
 907
 908         if(!self.respawntime)
 909         {
 910                 e = get_weaponinfo(wpn);
 911                 if(e.items == IT_SUPERWEAPON)
 912                 {
 913                         self.respawntime = g_pickup_respawntime_powerup;
 914                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
 915                 }
 916                 else
 917                 {
 918                         self.respawntime = g_pickup_respawntime_weapon;
 919                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
 920                 }
 921         }
 922
 923         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 924         {
 925                 e = get_weaponinfo(wpn);
 926                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 927                 if(s == "0")
 928                 {
 929                         remove(self);
 930                         startitem_failed = TRUE;
 931                         return;
 932                 }
 933                 t = tokenize_console(s);
 934                 if(t >= 2)
 935                 {
 936                         self.team = --internalteam;
 937                         oldself = self;
 938                         for(i = 1; i < t; ++i)
 939                         {
 940                                 s = argv(i);
 941                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 942                                 {
 943                                         e = get_weaponinfo(j);
 944                                         if(e.netname == s)
 945                                         {
 946                                                 self = spawn();
 947                                                 copyentity(oldself, self);
 948                                                 self.classname = "replacedweapon";
 949                                                 weapon_defaultspawnfunc(j);
 950                                                 break;
 951                                         }
 952                                 }
 953                                 if(j > WEP_LAST)
 954                                 {
 955                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 956                                 }
 957                         }
 958                         self = oldself;
 959                 }
 960                 if(t >= 1)
 961                 {
 962                         s = argv(0);
 963                         wpn = 0;
 964                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 965                         {
 966                                 e = get_weaponinfo(j);
 967                                 if(e.netname == s)
 968                                 {
 969                                         wpn = j;
 970                                         break;
 971                                 }
 972                         }
 973                         if(j > WEP_LAST)
 974                         {
 975                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 976                         }
 977                 }
 978                 if(wpn == 0)
 979                 {
 980                         remove(self);
 981                         startitem_failed = TRUE;
 982                         return;
 983                 }
 984         }
 985
 986         e = get_weaponinfo(wpn);
 987
 988         if(e.items && e.items != IT_SUPERWEAPON)
 989         {
 990                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
 991                 {
 992                         if(e.items & j)
 993                         {
 994                                 ammofield = Item_CounterField(j);
 995                                 if(!self.ammofield)
 996                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
 997                         }
 998                 }
 999         }
1000         else
1001         {
1002                 self.flags |= FL_NO_WEAPON_STAY;
1003         }
1004
1005         // weapon stay isn't supported for teamed weapons
1006         if(self.team)
1007                 self.flags |= FL_NO_WEAPON_STAY;
1008
1009         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1010         if (self.modelindex) // don't precache if self was removed
1011                 weapon_action(e.weapon, WR_PRECACHE);
1012 }
1013
1014 void spawnfunc_weapon_shotgun (void);
1015 void spawnfunc_weapon_uzi (void) {
1016         if(autocvar_sv_q3acompat_machineshotgunswap)
1017         if(self.classname != "droppedweapon")
1018         {
1019                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1020                 return;
1021         }
1022         weapon_defaultspawnfunc(WEP_UZI);
1023 }
1024
1025 void spawnfunc_weapon_shotgun (void) {
1026         if(autocvar_sv_q3acompat_machineshotgunswap)
1027         if(self.classname != "droppedweapon")
1028         {
1029                 weapon_defaultspawnfunc(WEP_UZI);
1030                 return;
1031         }
1032         weapon_defaultspawnfunc(WEP_SHOTGUN);
1033 }
1034
1035 void spawnfunc_weapon_nex (void)
1036 {
1037         if (g_minstagib)
1038         {
1039                 minstagib_items(IT_CELLS);
1040                 self.think = minst_remove_item;
1041                 self.nextthink = time;
1042                 return;
1043         }
1044         weapon_defaultspawnfunc(WEP_NEX);
1045 }
1046
1047 void spawnfunc_weapon_minstanex (void)
1048 {
1049         if (g_minstagib)
1050         {
1051                 minstagib_items(IT_CELLS);
1052                 self.think = minst_remove_item;
1053                 self.nextthink = time;
1054                 return;
1055         }
1056         weapon_defaultspawnfunc(WEP_MINSTANEX);
1057 }
1058
1059 void spawnfunc_weapon_rocketlauncher (void)
1060 {
1061         if (g_minstagib)
1062         {
1063                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1064                 self.think = minst_remove_item;
1065                 self.nextthink = time;
1066                 return;
1067         }
1068         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1069 }
1070
1071 void spawnfunc_item_rockets (void) {
1072         if(!self.ammo_rockets)
1073                 self.ammo_rockets = g_pickup_rockets;
1074         if(!self.pickup_anyway)
1075                 self.pickup_anyway = g_pickup_ammo_anyway;
1076         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1077 }
1078
1079 void spawnfunc_item_shells (void);
1080 void spawnfunc_item_bullets (void) {
1081         if(!weaponswapping)
1082         if(autocvar_sv_q3acompat_machineshotgunswap)
1083         if(self.classname != "droppedweapon")
1084         {
1085                 weaponswapping = TRUE;
1086                 spawnfunc_item_shells();
1087                 weaponswapping = FALSE;
1088                 return;
1089         }
1090
1091         if(!self.ammo_nails)
1092                 self.ammo_nails = g_pickup_nails;
1093         if(!self.pickup_anyway)
1094                 self.pickup_anyway = g_pickup_ammo_anyway;
1095         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1096 }
1097
1098 void spawnfunc_item_cells (void) {
1099         if(!self.ammo_cells)
1100                 self.ammo_cells = g_pickup_cells;
1101         if(!self.pickup_anyway)
1102                 self.pickup_anyway = g_pickup_ammo_anyway;
1103         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1104 }
1105
1106 void spawnfunc_item_shells (void) {
1107         if(!weaponswapping)
1108         if(autocvar_sv_q3acompat_machineshotgunswap)
1109         if(self.classname != "droppedweapon")
1110         {
1111                 weaponswapping = TRUE;
1112                 spawnfunc_item_bullets();
1113                 weaponswapping = FALSE;
1114                 return;
1115         }
1116
1117         if(!self.ammo_shells)
1118                 self.ammo_shells = g_pickup_shells;
1119         if(!self.pickup_anyway)
1120                 self.pickup_anyway = g_pickup_ammo_anyway;
1121         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1122 }
1123
1124 void spawnfunc_item_armor_small (void) {
1125         if(!self.armorvalue)
1126                 self.armorvalue = g_pickup_armorsmall;
1127         if(!self.max_armorvalue)
1128                 self.max_armorvalue = g_pickup_armorsmall_max;
1129         if(!self.pickup_anyway)
1130                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1131         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1132 }
1133
1134 void spawnfunc_item_armor_medium (void) {
1135         if(!self.armorvalue)
1136                 self.armorvalue = g_pickup_armormedium;
1137         if(!self.max_armorvalue)
1138                 self.max_armorvalue = g_pickup_armormedium_max;
1139         if(!self.pickup_anyway)
1140                 self.pickup_anyway = g_pickup_armormedium_anyway;
1141         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1142 }
1143
1144 void spawnfunc_item_armor_big (void) {
1145         if(!self.armorvalue)
1146                 self.armorvalue = g_pickup_armorbig;
1147         if(!self.max_armorvalue)
1148                 self.max_armorvalue = g_pickup_armorbig_max;
1149         if(!self.pickup_anyway)
1150                 self.pickup_anyway = g_pickup_armorbig_anyway;
1151         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1152 }
1153
1154 void spawnfunc_item_armor_large (void) {
1155         if(!self.armorvalue)
1156                 self.armorvalue = g_pickup_armorlarge;
1157         if(!self.max_armorvalue)
1158                 self.max_armorvalue = g_pickup_armorlarge_max;
1159         if(!self.pickup_anyway)
1160                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1161         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1162 }
1163
1164 void spawnfunc_item_health_small (void) {
1165         if(!self.max_health)
1166                 self.max_health = g_pickup_healthsmall_max;
1167         if(!self.health)
1168                 self.health = g_pickup_healthsmall;
1169         if(!self.pickup_anyway)
1170                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1171         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1172 }
1173
1174 void spawnfunc_item_health_medium (void) {
1175         if(!self.max_health)
1176                 self.max_health = g_pickup_healthmedium_max;
1177         if(!self.health)
1178                 self.health = g_pickup_healthmedium;
1179         if(!self.pickup_anyway)
1180                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1181         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1182 }
1183
1184 void spawnfunc_item_health_large (void) {
1185         if(!self.max_health)
1186                 self.max_health = g_pickup_healthlarge_max;
1187         if(!self.health)
1188                 self.health = g_pickup_healthlarge;
1189         if(!self.pickup_anyway)
1190                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1191         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1192 }
1193
1194 void spawnfunc_item_health_mega (void) {
1195         if(g_minstagib) {
1196                 minstagib_items(IT_NAILS);
1197         } else {
1198                 if(!self.max_health)
1199                         self.max_health = g_pickup_healthmega_max;
1200                 if(!self.health)
1201                         self.health = g_pickup_healthmega;
1202                 if(!self.pickup_anyway)
1203                         self.pickup_anyway = g_pickup_healthmega_anyway;
1204                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1205         }
1206 }
1207
1208 // support old misnamed entities
1209 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1210 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1211 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1212 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1213 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1214
1215 void spawnfunc_item_strength (void) {
1216         if(g_minstagib) {
1217                 minstagib_items(IT_STRENGTH);
1218         } else {
1219                 precache_sound("weapons/strength_fire.wav");
1220                 self.strength_finished = 30;
1221                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1222         }
1223 }
1224
1225 void spawnfunc_item_invincible (void) {
1226         if(g_minstagib) {
1227                 minstagib_items(IT_INVINCIBLE);
1228         } else {
1229                 self.invincible_finished = 30;
1230                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1231         }
1232 }
1233
1234 void spawnfunc_item_minst_cells (void) {
1235         if (g_minstagib)
1236         {
1237                 minst_no_auto_cells = 1;
1238                 minstagib_items(IT_CELLS);
1239         }
1240         else
1241                 remove(self);
1242 }
1243
1244 // compatibility:
1245 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1246
1247 float GiveItems(entity e, float beginarg, float endarg);
1248 void target_items_use (void)
1249 {
1250         if(activator.classname == "droppedweapon")
1251         {
1252                 EXACTTRIGGER_TOUCH;
1253                 remove(activator);
1254                 return;
1255         }
1256
1257         if(activator.classname != "player")
1258                 return;
1259         if(activator.deadflag != DEAD_NO)
1260                 return;
1261         EXACTTRIGGER_TOUCH;
1262
1263         entity e;
1264         for(e = world; (e = find(e, classname, "droppedweapon")); )
1265                 if(e.enemy == activator)
1266                         remove(e);
1267
1268         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1269                 centerprint(activator, self.message);
1270 }
1271
1272 void spawnfunc_target_items (void)
1273 {
1274         float n, i, j;
1275         entity e;
1276
1277         self.use = target_items_use;
1278         if(!self.strength_finished)
1279                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1280         if(!self.invincible_finished)
1281                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1282
1283         precache_sound("misc/itempickup.wav");
1284         precache_sound("misc/megahealth.wav");
1285         precache_sound("misc/armor25.wav");
1286         precache_sound("misc/powerup.wav");
1287         precache_sound("misc/poweroff.wav");
1288         precache_sound("weapons/weaponpickup.wav");
1289
1290         n = tokenize_console(self.netname);
1291         if(argv(0) == "give")
1292         {
1293                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1294         }
1295         else
1296         {
1297                 for(i = 0; i < n; ++i)
1298                 {
1299                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1300                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1301                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1302                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1303                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1304                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1305                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1306                         else
1307                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1308                         {
1309                                 e = get_weaponinfo(j);
1310                                 if(argv(i) == e.netname)
1311                                 {
1312                                         self.weapons |= e.weapons;
1313                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1314                                                 weapon_action(e.weapon, WR_PRECACHE);
1315                                         break;
1316                                 }
1317                         }
1318                         if(j > WEP_LAST)
1319                                 print("target_items: invalid item ", argv(i), "\n");
1320                 }
1321
1322                 string itemprefix, valueprefix;
1323                 if(self.spawnflags == 0)
1324                 {
1325                         itemprefix = "";
1326                         valueprefix = "";
1327                 }
1328                 else if(self.spawnflags == 1)
1329                 {
1330                         itemprefix = "max ";
1331                         valueprefix = "max ";
1332                 }
1333                 else if(self.spawnflags == 2)
1334                 {
1335                         itemprefix = "min ";
1336                         valueprefix = "min ";
1337                 }
1338                 else if(self.spawnflags == 4)
1339                 {
1340                         itemprefix = "minus ";
1341                         valueprefix = "max ";
1342                 }
1343                 else
1344                         error("invalid spawnflags");
1345
1346                 self.netname = "";
1347                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1348                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1349                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1350                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1351                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1352                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1353                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1354                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1355                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1356                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1357                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1358                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1359                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1360                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1361                 {
1362                         e = get_weaponinfo(j);
1363                         if(e.weapons)
1364                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1365                 }
1366         }
1367         self.netname = strzone(self.netname);
1368         //print(self.netname, "\n");
1369
1370         n = tokenize_console(self.netname);
1371         for(i = 0; i < n; ++i)
1372         {
1373                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1374                 {
1375                         e = get_weaponinfo(j);
1376                         if(argv(i) == e.netname)
1377                         {
1378                                 weapon_action(e.weapon, WR_PRECACHE);
1379                                 break;
1380                         }
1381                 }
1382         }
1383 }
1384
1385 void spawnfunc_item_fuel(void)
1386 {
1387         if(!self.ammo_fuel)
1388                 self.ammo_fuel = g_pickup_fuel;
1389         if(!self.pickup_anyway)
1390                 self.pickup_anyway = g_pickup_ammo_anyway;
1391         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1392 }
1393
1394 void spawnfunc_item_fuel_regen(void)
1395 {
1396         if(start_items & IT_FUEL_REGEN)
1397         {
1398                 spawnfunc_item_fuel();
1399                 return;
1400         }
1401         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1402 }
1403
1404 void spawnfunc_item_jetpack(void)
1405 {
1406         if(g_grappling_hook)
1407                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1408         if(!self.ammo_fuel)
1409                 self.ammo_fuel = g_pickup_fuel_jetpack;
1410         if(start_items & IT_JETPACK)
1411         {
1412                 spawnfunc_item_fuel();
1413                 return;
1414         }
1415         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1416 }
1417
1418
1419 #define OP_SET 0
1420 #define OP_MIN 1
1421 #define OP_MAX 2
1422 #define OP_PLUS 3
1423 #define OP_MINUS 4
1424
1425 float GiveBit(entity e, .float fld, float bit, float op, float val)
1426 {
1427         float v0, v1;
1428         v0 = (e.fld & bit);
1429         switch(op)
1430         {
1431                 case OP_SET:
1432                         if(val > 0)
1433                                 e.fld |= bit;
1434                         else
1435                                 e.fld &~= bit;
1436                         break;
1437                 case OP_MIN:
1438                 case OP_PLUS:
1439                         if(val > 0)
1440                                 e.fld |= bit;
1441                         break;
1442                 case OP_MAX:
1443                         if(val <= 0)
1444                                 e.fld &~= bit;
1445                         break;
1446                 case OP_MINUS:
1447                         if(val > 0)
1448                                 e.fld &~= bit;
1449                         break;
1450         }
1451         v1 = (e.fld & bit);
1452         return (v0 != v1);
1453 }
1454
1455 float GiveValue(entity e, .float fld, float op, float val)
1456 {
1457         float v0, v1;
1458         v0 = e.fld;
1459         switch(op)
1460         {
1461                 case OP_SET:
1462                         e.fld = val;
1463                         break;
1464                 case OP_MIN:
1465                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1466                         break;
1467                 case OP_MAX:
1468                         e.fld = min(e.fld, val);
1469                         break;
1470                 case OP_PLUS:
1471                         e.fld += val;
1472                         break;
1473                 case OP_MINUS:
1474                         e.fld -= val;
1475                         break;
1476         }
1477         v1 = e.fld;
1478         return (v0 != v1);
1479 }
1480
1481 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1482 {
1483         if(v1 == v0)
1484                 return;
1485         if(v1 <= v0 - t)
1486         {
1487                 if(snd_decr != "")
1488                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1489         }
1490         else if(v0 >= v0 + t)
1491         {
1492                 if(snd_incr != "")
1493                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1494         }
1495 }
1496
1497 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1498 {
1499         if(v0 < v1)
1500                 e.rotfield = max(e.rotfield, time + rottime);
1501         else if(v0 > v1)
1502                 e.regenfield = max(e.regenfield, time + regentime);
1503 }
1504
1505 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1506 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1507 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1508 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1509
1510 float GiveItems(entity e, float beginarg, float endarg)
1511 {
1512         float got, i, j, val, op;
1513         float _switchweapon;
1514         entity wi;
1515         string cmd;
1516
1517         val = 999;
1518         op = OP_SET;
1519
1520         got = 0;
1521
1522         _switchweapon = FALSE;
1523         if (e.autoswitch)
1524                 if (e.switchweapon == w_getbestweapon(e))
1525                         _switchweapon = TRUE;
1526
1527         e.strength_finished = max(0, e.strength_finished - time);
1528         e.invincible_finished = max(0, e.invincible_finished - time);
1529
1530         PREGIVE(e, items);
1531         PREGIVE(e, weapons);
1532         PREGIVE(e, strength_finished);
1533         PREGIVE(e, invincible_finished);
1534         PREGIVE(e, ammo_nails);
1535         PREGIVE(e, ammo_cells);
1536         PREGIVE(e, ammo_shells);
1537         PREGIVE(e, ammo_rockets);
1538         PREGIVE(e, ammo_fuel);
1539         PREGIVE(e, armorvalue);
1540         PREGIVE(e, health);
1541
1542         for(i = beginarg; i < endarg; ++i)
1543         {
1544                 cmd = argv(i);
1545
1546                 if(cmd == "0" || stof(cmd))
1547                 {
1548                         val = stof(cmd);
1549                         continue;
1550                 }
1551                 switch(cmd)
1552                 {
1553                         case "no":
1554                                 op = OP_MAX;
1555                                 val = 0;
1556                                 continue;
1557                         case "max":
1558                                 op = OP_MAX;
1559                                 continue;
1560                         case "min":
1561                                 op = OP_MIN;
1562                                 continue;
1563                         case "plus":
1564                                 op = OP_PLUS;
1565                                 continue;
1566                         case "minus":
1567                                 op = OP_MINUS;
1568                                 continue;
1569                         case "ALL":
1570                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1571                                 got += GiveValue(e, strength_finished, op, time);
1572                                 got += GiveValue(e, invincible_finished, op, time);
1573                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1574                         case "all":
1575                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1576                                 got += GiveValue(e, health, op, val);
1577                                 got += GiveValue(e, armorvalue, op, val);
1578                         case "allweapons":
1579                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1580                                 {
1581                                         wi = get_weaponinfo(j);
1582                                         if(wi.weapons)
1583                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1584                                 }
1585                         case "allammo":
1586                                 got += GiveValue(e, ammo_cells, op, val);
1587                                 got += GiveValue(e, ammo_shells, op, val);
1588                                 got += GiveValue(e, ammo_nails, op, val);
1589                                 got += GiveValue(e, ammo_rockets, op, val);
1590                                 got += GiveValue(e, ammo_fuel, op, val);
1591                                 break;
1592                         case "unlimited_ammo":
1593                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1594                                 break;
1595                         case "unlimited_weapon_ammo":
1596                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1597                                 break;
1598                         case "unlimited_superweapons":
1599                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1600                                 break;
1601                         case "jetpack":
1602                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1603                                 break;
1604                         case "fuel_regen":
1605                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1606                                 break;
1607                         case "strength":
1608                                 got += GiveValue(e, strength_finished, op, val);
1609                                 break;
1610                         case "invincible":
1611                                 got += GiveValue(e, invincible_finished, op, val);
1612                                 break;
1613                         case "cells":
1614                                 got += GiveValue(e, ammo_cells, op, val);
1615                                 break;
1616                         case "shells":
1617                                 got += GiveValue(e, ammo_shells, op, val);
1618                                 break;
1619                         case "nails":
1620                         case "bullets":
1621                                 got += GiveValue(e, ammo_nails, op, val);
1622                                 break;
1623                         case "rockets":
1624                                 got += GiveValue(e, ammo_rockets, op, val);
1625                                 break;
1626                         case "health":
1627                                 got += GiveValue(e, health, op, val);
1628                                 break;
1629                         case "armor":
1630                                 got += GiveValue(e, armorvalue, op, val);
1631                                 break;
1632                         case "fuel":
1633                                 got += GiveValue(e, ammo_fuel, op, val);
1634                                 break;
1635                         default:
1636                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1637                                 {
1638                                         wi = get_weaponinfo(j);
1639                                         if(cmd == wi.netname)
1640                                         {
1641                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1642                                                 break;
1643                                         }
1644                                 }
1645                                 if(j > WEP_LAST)
1646                                         print("give: invalid item ", cmd, "\n");
1647                                 break;
1648                 }
1649                 val = 999;
1650                 op = OP_SET;
1651         }
1652
1653         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1654         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1655         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1656         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1657         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1658         {
1659                 wi = get_weaponinfo(j);
1660                 if(wi.weapons)
1661                 {
1662                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1663                         if not(save_weapons & wi.weapons)
1664                                 if(e.weapons & wi.weapons)
1665                                         weapon_action(wi.weapon, WR_PRECACHE);
1666                 }
1667         }
1668         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1669         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1670         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1671         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1672         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1673         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1674         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1675         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1676         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1677
1678         if (g_minstagib)
1679         {
1680                 e.health = bound(0, e.health, 100);
1681                 e.armorvalue = bound(0, e.armorvalue, 999);
1682         }
1683
1684         if(e.strength_finished <= 0)
1685                 e.strength_finished = 0;
1686         else
1687                 e.strength_finished += time;
1688         if(e.invincible_finished <= 0)
1689                 e.invincible_finished = 0;
1690         else
1691                 e.invincible_finished += time;
1692
1693         if not(e.weapons & W_WeaponBit(e.switchweapon))
1694                 _switchweapon = TRUE;
1695         if(_switchweapon)
1696                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1697
1698         return got;
1699 }