qcsrc/server/mutators/mutator_overkill.qc

   1 void ok_DecreaseCharge(entity ent, float wep)
   2 {
   3         if(!ent.ok_use_ammocharge) return;
   4
   5         entity wepent = get_weaponinfo(wep);
   6
   7         if(wepent.weapon == 0)
   8                 return; // dummy
   9
  10         ent.ammo_charge[wep] -= max(0, cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  11 }
  12
  13 void ok_IncreaseCharge(entity ent, float wep)
  14 {
  15         entity wepent = get_weaponinfo(wep);
  16
  17         if(wepent.weapon == 0)
  18                 return; // dummy
  19
  20         if(ent.ok_use_ammocharge)
  21         if(!ent.BUTTON_ATCK) // not while attacking?
  22                 ent.ammo_charge[wep] = min(autocvar_g_overkill_ammo_charge_limit, ent.ammo_charge[wep] + cvar(sprintf("g_overkill_ammo_charge_rate_%s", wepent.netname)) * frametime / W_TICSPERFRAME);
  23 }
  24
  25 float ok_CheckWeaponCharge(entity ent, float wep)
  26 {
  27         if(!ent.ok_use_ammocharge) return true;
  28
  29         entity wepent = get_weaponinfo(wep);
  30
  31         if(wepent.weapon == 0)
  32                 return 0; // dummy
  33
  34         return (ent.ammo_charge[wep] >= cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  35 }
  36
  37 MUTATOR_HOOKFUNCTION(ok_PlayerDamage_Calculate)
  38 {
  39         if(IS_PLAYER(frag_attacker) && IS_PLAYER(frag_target))
  40         if(DEATH_ISWEAPON(frag_deathtype, WEP_BLASTER))
  41         {
  42                 frag_damage = 0;
  43
  44                 if(frag_attacker != frag_target)
  45                 if(frag_target.health > 0)
  46                 if(frag_target.frozen == 0)
  47                 if(frag_target.deadflag == DEAD_NO)
  48                 {
  49                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_SECONDARY_NODAMAGE);
  50                         frag_force = '0 0 0';
  51                 }
  52         }
  53
  54         return false;
  55 }
  56
  57 MUTATOR_HOOKFUNCTION(ok_PlayerDamage_SplitHealthArmor)
  58 {
  59         if(damage_take)
  60                 self.ok_pauseregen_finished = max(self.ok_pauseregen_finished, time + 2);
  61         return false;
  62 }
  63
  64 MUTATOR_HOOKFUNCTION(ok_PlayerDies)
  65 {
  66         entity oldself = self;
  67         entity targ = ((frag_attacker) ? frag_attacker : frag_target);
  68
  69         if(self.flags & FL_MONSTER)
  70         {
  71                 remove(other); // remove default item
  72                 other = world;
  73         }
  74
  75         self = spawn();
  76         self.ok_item = true;
  77         self.noalign = true;
  78         self.pickup_anyway = true;
  79         spawnfunc_item_armor_small();
  80         self.movetype = MOVETYPE_TOSS;
  81         self.gravity = 1;
  82         self.reset = SUB_Remove;
  83         setorigin(self, frag_target.origin + '0 0 32');
  84         self.velocity = '0 0 200' + normalize(targ.origin - self.origin) * 500;
  85         self.classname = "droppedweapon"; // hax
  86         SUB_SetFade(self, time + 5, 1);
  87         self = oldself;
  88
  89         self.ok_lastwep = self.switchweapon;
  90
  91         return false;
  92 }
  93
  94 MUTATOR_HOOKFUNCTION(ok_PlayerRegen)
  95 {
  96         // overkill's values are different, so use custom regen
  97         if(!self.frozen)
  98         {
  99                 self.armorvalue = CalcRotRegen(self.armorvalue, autocvar_g_balance_armor_regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, 1 * frametime * (time > self.ok_pauseregen_finished), 0, 0, 1, 1 * frametime * (time > self.pauserotarmor_finished), autocvar_g_balance_armor_limit);
 100                 self.health = CalcRotRegen(self.health, autocvar_g_balance_health_regenstable, 0, 100, 1 * frametime * (time > self.ok_pauseregen_finished), 200, 0, autocvar_g_balance_health_rotlinear, 1 * frametime * (time > self.pauserothealth_finished), autocvar_g_balance_health_limit);
 101
 102                 float minf, maxf, limitf;
 103
 104                 maxf = autocvar_g_balance_fuel_rotstable;
 105                 minf = autocvar_g_balance_fuel_regenstable;
 106                 limitf = autocvar_g_balance_fuel_limit;
 107
 108                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
 109         }
 110         return true; // return true anyway, as frozen uses no regen
 111 }
 112
 113 MUTATOR_HOOKFUNCTION(ok_ForbidThrowCurrentWeapon)
 114 {
 115         return true;
 116 }
 117
 118 MUTATOR_HOOKFUNCTION(ok_PlayerPreThink)
 119 {
 120         if(intermission_running || gameover)
 121                 return false;
 122
 123         if(self.deadflag != DEAD_NO || !IS_PLAYER(self) || self.frozen)
 124                 return false;
 125
 126         if(self.ok_lastwep)
 127         {
 128                 self.switchweapon = self.ok_lastwep;
 129                 self.ok_lastwep = 0;
 130         }
 131
 132         ok_IncreaseCharge(self, self.weapon);
 133
 134         if(self.BUTTON_ATCK2)
 135         if(!forbidWeaponUse() || self.weapon_blocked) // allow if weapon is blocked
 136         if(time >= self.jump_interval)
 137         {
 138                 self.jump_interval = time + WEP_CVAR_PRI(blaster, refire) * W_WeaponRateFactor();
 139                 makevectors(self.v_angle);
 140
 141                 W_Blaster_Attack(
 142                         WEP_BLASTER | HITTYPE_SECONDARY,
 143                         WEP_CVAR_SEC(vaporizer, shotangle),
 144                         WEP_CVAR_SEC(vaporizer, damage),
 145                         WEP_CVAR_SEC(vaporizer, edgedamage),
 146                         WEP_CVAR_SEC(vaporizer, radius),
 147                         WEP_CVAR_SEC(vaporizer, force),
 148                         WEP_CVAR_SEC(vaporizer, speed),
 149                         WEP_CVAR_SEC(vaporizer, spread),
 150                         WEP_CVAR_SEC(vaporizer, delay),
 151                         WEP_CVAR_SEC(vaporizer, lifetime)
 152                 );
 153         }
 154
 155         self.weapon_blocked = false;
 156
 157         self.ok_ammo_charge = self.ammo_charge[self.weapon];
 158
 159         if(self.ok_use_ammocharge)
 160         if(!ok_CheckWeaponCharge(self, self.weapon))
 161         {
 162                 if(autocvar_g_overkill_ammo_charge_notice && time > self.ok_notice_time && self.BUTTON_ATCK && IS_REAL_CLIENT(self) && self.weapon == self.switchweapon)
 163                 {
 164                         //Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_OVERKILL_CHARGE);
 165                         self.ok_notice_time = time + 2;
 166                         play2(self, "weapons/dryfire.wav");
 167                 }
 168                 if(self.weaponentity.state != WS_CLEAR)
 169                         w_ready();
 170
 171                 self.weapon_blocked = true;
 172         }
 173
 174         self.BUTTON_ATCK2 = 0;
 175
 176         return false;
 177 }
 178
 179 MUTATOR_HOOKFUNCTION(ok_PlayerSpawn)
 180 {
 181         if(autocvar_g_overkill_ammo_charge)
 182         {
 183                 float i;
 184
 185                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 186                         self.ammo_charge[i] = autocvar_g_overkill_ammo_charge_limit;
 187
 188                 self.ok_use_ammocharge = 1;
 189                 self.ok_notice_time = time;
 190         }
 191         else
 192                 self.ok_use_ammocharge = 0;
 193
 194         self.ok_pauseregen_finished = time + 2;
 195
 196         return false;
 197 }
 198
 199 MUTATOR_HOOKFUNCTION(ok_OnEntityPreSpawn)
 200 {
 201         if(autocvar_g_powerups)
 202         if(autocvar_g_overkill_powerups_replace)
 203         {
 204                 if(self.classname == "item_strength")
 205                 {
 206                         entity wep = spawn();
 207                         setorigin(wep, self.origin);
 208                         setmodel(wep, "models/weapons/g_ok_hmg.md3");
 209                         wep.classname = "weapon_hmg";
 210                         wep.ok_item = true;
 211                         wep.noalign = self.noalign;
 212                         wep.cnt = self.cnt;
 213                         wep.team = self.team;
 214                         wep.respawntime = autocvar_g_overkill_superguns_respawn_time;
 215                         wep.pickup_anyway = true;
 216                         wep.think = spawnfunc_weapon_hmg;
 217                         wep.nextthink = time + 0.1;
 218                         return true;
 219                 }
 220
 221                 if(self.classname == "item_invincible")
 222                 {
 223                         entity wep = spawn();
 224                         setorigin(wep, self.origin);
 225                         setmodel(wep, "models/weapons/g_ok_rl.md3");
 226                         wep.classname = "weapon_rpc";
 227                         wep.ok_item = true;
 228                         wep.noalign = self.noalign;
 229                         wep.cnt = self.cnt;
 230                         wep.team = self.team;
 231                         wep.respawntime = autocvar_g_overkill_superguns_respawn_time;
 232                         wep.pickup_anyway = true;
 233                         wep.think = spawnfunc_weapon_rpc;
 234                         wep.nextthink = time + 0.1;
 235                         return true;
 236                 }
 237         }
 238
 239         return false;
 240 }
 241
 242 MUTATOR_HOOKFUNCTION(ok_ItemRemove)
 243 {
 244         if(self.ok_item)
 245                 return false;
 246
 247         switch(self.items)
 248         {
 249                 case IT_HEALTH: return !(autocvar_g_overkill_100h_anyway);
 250                 case IT_ARMOR: return !(autocvar_g_overkill_100a_anyway);
 251         }
 252
 253         return true;
 254 }
 255
 256 MUTATOR_HOOKFUNCTION(ok_SpectateCopy)
 257 {
 258         self.ammo_charge[self.weapon] = other.ammo_charge[other.weapon];
 259         self.ok_use_ammocharge = other.ok_use_ammocharge;
 260
 261         return false;
 262 }
 263
 264 MUTATOR_HOOKFUNCTION(ok_StartItems)
 265 {
 266         WepSet ok_start_items = (WEPSET_MACHINEGUN | WEPSET_VORTEX | WEPSET_SHOTGUN);
 267
 268         if((get_weaponinfo(WEP_RPC)).weaponstart > 0) { ok_start_items |= WEPSET_RPC; }
 269         if((get_weaponinfo(WEP_HMG)).weaponstart > 0) { ok_start_items |= WEPSET_HMG; }
 270
 271         start_items |= IT_UNLIMITED_WEAPON_AMMO;
 272         start_weapons = warmup_start_weapons = ok_start_items;
 273
 274         return false;
 275 }
 276
 277 MUTATOR_HOOKFUNCTION(ok_BuildMutatorsString)
 278 {
 279         ret_string = strcat(ret_string, ":OK");
 280         return false;
 281 }
 282
 283 MUTATOR_HOOKFUNCTION(ok_BuildMutatorsPrettyString)
 284 {
 285         ret_string = strcat(ret_string, ", Overkill");
 286         return false;
 287 }
 288
 289 MUTATOR_HOOKFUNCTION(ok_SetModname)
 290 {
 291         modname = "Overkill";
 292         return true;
 293 }
 294
 295 void ok_SetCvars()
 296 {
 297         // hack to force overkill playermodels
 298         cvar_settemp("sv_defaultcharacter", "1");
 299         cvar_settemp("sv_defaultplayermodel", "models/ok_player/okrobot1.dpm models/ok_player/okrobot2.dpm models/ok_player/okrobot3.dpm models/ok_player/okrobot4.dpm models/ok_player/okmale1.dpm models/ok_player/okmale2.dpm models/ok_player/okmale3.dpm models/ok_player/okmale4.dpm");
 300         cvar_settemp("sv_defaultplayermodel_red", "models/ok_player/okrobot1.dpm models/ok_player/okrobot2.dpm models/ok_player/okrobot3.dpm models/ok_player/okrobot4.dpm");
 301         cvar_settemp("sv_defaultplayermodel_blue", "models/ok_player/okmale1.dpm models/ok_player/okmale2.dpm models/ok_player/okmale3.dpm models/ok_player/okmale4.dpm");
 302 }
 303
 304 void ok_Initialize()
 305 {
 306         ok_SetCvars();
 307
 308         precache_all_playermodels("models/ok_player/*.dpm");
 309
 310         precache_model("models/weapons/h_ok_mg.iqm");
 311         precache_model("models/weapons/v_ok_mg.md3");
 312         precache_model("models/weapons/g_ok_mg.md3");
 313
 314         precache_model("models/weapons/h_ok_shotgun.iqm");
 315         precache_model("models/weapons/v_ok_shotgun.md3");
 316         precache_model("models/weapons/g_ok_shotgun.md3");
 317
 318         precache_model("models/weapons/h_ok_sniper.iqm");
 319         precache_model("models/weapons/v_ok_sniper.md3");
 320         precache_model("models/weapons/g_ok_sniper.md3");
 321
 322         precache_sound("weapons/dryfire.wav");
 323
 324         addstat(STAT_OK_AMMO_CHARGE, AS_FLOAT, ok_use_ammocharge);
 325         addstat(STAT_OK_AMMO_CHARGEPOOL, AS_FLOAT, ok_ammo_charge);
 326
 327         (get_weaponinfo(WEP_RPC)).spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 328         (get_weaponinfo(WEP_HMG)).spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 329
 330         (get_weaponinfo(WEP_SHOTGUN)).mdl = "ok_shotgun";
 331         (get_weaponinfo(WEP_MACHINEGUN)).mdl = "ok_mg";
 332         (get_weaponinfo(WEP_VORTEX)).mdl = "ok_sniper";
 333 }
 334
 335 MUTATOR_DEFINITION(mutator_overkill)
 336 {
 337         MUTATOR_HOOK(ForbidThrowCurrentWeapon, ok_ForbidThrowCurrentWeapon, CBC_ORDER_ANY);
 338         MUTATOR_HOOK(PlayerPreThink, ok_PlayerPreThink, CBC_ORDER_LAST);
 339         MUTATOR_HOOK(PlayerSpawn, ok_PlayerSpawn, CBC_ORDER_ANY);
 340         MUTATOR_HOOK(PlayerDamage_Calculate, ok_PlayerDamage_Calculate, CBC_ORDER_LAST);
 341         MUTATOR_HOOK(PlayerDamage_SplitHealthArmor, ok_PlayerDamage_SplitHealthArmor, CBC_ORDER_ANY);
 342         MUTATOR_HOOK(PlayerDies, ok_PlayerDies, CBC_ORDER_ANY);
 343         MUTATOR_HOOK(PlayerRegen, ok_PlayerRegen, CBC_ORDER_ANY);
 344         MUTATOR_HOOK(OnEntityPreSpawn, ok_OnEntityPreSpawn, CBC_ORDER_ANY);
 345         MUTATOR_HOOK(FilterItem, ok_ItemRemove, CBC_ORDER_ANY);
 346         MUTATOR_HOOK(MonsterDropItem, ok_PlayerDies, CBC_ORDER_ANY);
 347         MUTATOR_HOOK(SpectateCopy, ok_SpectateCopy, CBC_ORDER_ANY);
 348         MUTATOR_HOOK(SetStartItems, ok_StartItems, CBC_ORDER_ANY);
 349         MUTATOR_HOOK(BuildMutatorsString, ok_BuildMutatorsString, CBC_ORDER_ANY);
 350         MUTATOR_HOOK(BuildMutatorsPrettyString, ok_BuildMutatorsPrettyString, CBC_ORDER_ANY);
 351         MUTATOR_HOOK(SetModname, ok_SetModname, CBC_ORDER_ANY);
 352
 353         MUTATOR_ONADD
 354         {
 355                 ok_Initialize();
 356         }
 357
 358         MUTATOR_ONREMOVE
 359         {
 360                 (get_weaponinfo(WEP_RPC)).spawnflags |= WEP_FLAG_MUTATORBLOCKED;
 361                 (get_weaponinfo(WEP_HMG)).spawnflags |= WEP_FLAG_MUTATORBLOCKED;
 362         }
 363
 364         return false;
 365 }