qcsrc/server/items/items.qc

   1 #include "items.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/gamemodes/gamemode/cts/cts.qh>
   6 #include <common/items/_mod.qh>
   7 #include <common/mapobjects/subs.qh>
   8 #include <common/mapobjects/triggers.qh>
   9 #include <common/monsters/_mod.qh>
  10 #include <common/mutators/mutator/buffs/buffs.qh>
  11 #include <common/mutators/mutator/buffs/sv_buffs.qh>
  12 #include <common/mutators/mutator/powerups/_mod.qh>
  13 #include <common/mutators/mutator/status_effects/_mod.qh>
  14 #include <common/notifications/all.qh>
  15 #include <common/util.qh>
  16 #include <common/weapons/_all.qh>
  17 #include <common/wepent.qh>
  18 #include <lib/warpzone/common.qh>
  19 #include <lib/warpzone/util_server.qh>
  20 #include <server/bot/api.qh>
  21 #include <server/command/vote.qh>
  22 #include <server/damage.qh>
  23 #include <server/mutators/_mod.qh>
  24 #include <server/teamplay.qh>
  25 #include <server/weapons/common.qh>
  26 #include <server/weapons/selection.qh>
  27 #include <server/weapons/weaponsystem.qh>
  28 #include <server/world.qh>
  29
  30 bool ItemSend(entity this, entity to, int sf)
  31 {
  32         if(this.gravity)
  33                 sf |= ISF_DROP;
  34         else
  35                 sf &= ~ISF_DROP;
  36
  37         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
  38         WriteByte(MSG_ENTITY, sf);
  39
  40         //WriteByte(MSG_ENTITY, this.cnt);
  41         if(sf & ISF_LOCATION)
  42         {
  43                 WriteVector(MSG_ENTITY, this.origin);
  44         }
  45
  46         if(sf & ISF_ANGLES)
  47         {
  48                 WriteAngleVector(MSG_ENTITY, this.angles);
  49         }
  50
  51         // sets size on the client, unused on server
  52         //if(sf & ISF_SIZE)
  53
  54         if(sf & ISF_STATUS)
  55                 WriteByte(MSG_ENTITY, this.ItemStatus);
  56
  57         if(sf & ISF_MODEL)
  58         {
  59                 WriteShort(MSG_ENTITY, bound(0, this.fade_end, 32767));
  60                 WriteShort(MSG_ENTITY, bound(0, this.fade_start, 32767));
  61
  62                 if(this.mdl == "")
  63                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
  64
  65                 WriteString(MSG_ENTITY, this.mdl);
  66                 WriteByte(MSG_ENTITY, bound(0, this.skin, 255));
  67         }
  68
  69         if(sf & ISF_COLORMAP)
  70         {
  71                 WriteShort(MSG_ENTITY, this.colormap);
  72                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
  73                 WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
  74                 WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
  75         }
  76
  77         if(sf & ISF_DROP)
  78         {
  79                 WriteVector(MSG_ENTITY, this.velocity);
  80         }
  81
  82         return true;
  83 }
  84
  85 void ItemUpdate(entity this)
  86 {
  87         this.oldorigin = this.origin;
  88         this.SendFlags |= ISF_LOCATION;
  89 }
  90
  91 void UpdateItemAfterTeleport(entity this)
  92 {
  93         if(getSendEntity(this) == ItemSend)
  94                 ItemUpdate(this);
  95 }
  96
  97 bool have_pickup_item(entity this)
  98 {
  99         if(this.itemdef.instanceOfPowerup)
 100         {
 101                 if(autocvar_g_powerups > 0)
 102                         return true;
 103                 if(autocvar_g_powerups == 0)
 104                         return false;
 105         }
 106         else
 107         {
 108                 if(autocvar_g_pickup_items > 0)
 109                         return true;
 110                 if(autocvar_g_pickup_items == 0)
 111                         return false;
 112                 if(g_weaponarena)
 113                         if(STAT(WEAPONS, this) || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 114                                 return false;
 115         }
 116         return true;
 117 }
 118
 119 void Item_Show(entity e, int mode)
 120 {
 121         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 122         e.ItemStatus &= ~ITS_STAYWEP;
 123         entity def = e.itemdef;
 124         if (mode > 0)
 125         {
 126                 // make the item look normal, and be touchable
 127                 e.model = e.mdl;
 128                 e.solid = SOLID_TRIGGER;
 129                 e.spawnshieldtime = 1;
 130                 e.ItemStatus |= ITS_AVAILABLE;
 131         }
 132         else if (mode < 0)
 133         {
 134                 // hide the item completely
 135                 e.model = string_null;
 136                 e.solid = SOLID_NOT;
 137                 e.spawnshieldtime = 1;
 138                 e.ItemStatus &= ~ITS_AVAILABLE;
 139         }
 140         else
 141         {
 142                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.m_wepset & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 143                         || e.team // weapon stay isn't supported for teamed weapons
 144                         ;
 145                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 146                 {
 147                         // make the item translucent and not touchable
 148                         e.model = e.mdl;
 149                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
 150                         e.effects |= EF_STARDUST;
 151                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 152                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 153                 }
 154                 else
 155                 {
 156                         //setmodel(e, "null");
 157                         e.solid = SOLID_NOT;
 158                         e.colormod = '0 0 0';
 159                         //e.glowmod = e.colormod;
 160                         e.spawnshieldtime = 1;
 161                         e.ItemStatus &= ~ITS_AVAILABLE;
 162                 }
 163         }
 164
 165         if (def.m_glow)
 166                 e.ItemStatus |= ITS_GLOW;
 167
 168         if (autocvar_g_nodepthtestitems)
 169                 e.effects |= EF_NODEPTHTEST;
 170
 171         if (autocvar_g_fullbrightitems)
 172                 e.ItemStatus |= ITS_ALLOWFB;
 173         else
 174                 e.ItemStatus &= ~ITS_ALLOWFB;
 175
 176         if (autocvar_sv_simple_items)
 177                 e.ItemStatus |= ITS_ALLOWSI;
 178
 179         // relink entity (because solid may have changed)
 180         setorigin(e, e.origin);
 181         e.SendFlags |= ISF_STATUS;
 182 }
 183
 184 void Item_Think(entity this)
 185 {
 186         this.nextthink = time;
 187         if(this.origin != this.oldorigin)
 188                 ItemUpdate(this);
 189 }
 190
 191 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 192 bool Item_ItemsTime_Allow(GameItem it);
 193 float Item_ItemsTime_UpdateTime(entity e, float t);
 194 void Item_ItemsTime_SetTime(entity e, float t);
 195 void Item_ItemsTime_SetTimesForAllPlayers();
 196
 197 void Item_Respawn(entity this)
 198 {
 199         Item_Show(this, 1);
 200         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 201         setorigin(this, this.origin);
 202
 203         if (Item_ItemsTime_Allow(this.itemdef) || (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
 204         {
 205                 float t = Item_ItemsTime_UpdateTime(this, 0);
 206                 Item_ItemsTime_SetTime(this, t);
 207                 Item_ItemsTime_SetTimesForAllPlayers();
 208         }
 209
 210         setthink(this, Item_Think);
 211         this.nextthink = time;
 212
 213         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 214         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 215 }
 216
 217 void Item_RespawnCountdown(entity this)
 218 {
 219         if(this.item_respawncounter >= ITEM_RESPAWN_TICKS)
 220         {
 221                 if(this.waypointsprite_attached)
 222                         WaypointSprite_Kill(this.waypointsprite_attached);
 223                 Item_Respawn(this);
 224         }
 225         else
 226         {
 227                 this.nextthink = time + 1;
 228                 this.item_respawncounter += 1;
 229                 if(this.item_respawncounter == 1)
 230                 {
 231                         do {
 232                                 {
 233                                         entity wi = REGISTRY_GET(Weapons, this.weapon);
 234                                         if (wi != WEP_Null) {
 235                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 236                                                 wp.wp_extra = wi.m_id;
 237                                                 break;
 238                                         }
 239                                 }
 240                                 {
 241                                         entity ii = this.itemdef;
 242                                         if (ii != NULL) {
 243                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 244                                                 wp.wp_extra = ii.m_id;
 245                                                 break;
 246                                         }
 247                                 }
 248                         } while (0);
 249                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
 250             if(this.waypointsprite_attached)
 251             {
 252                 GameItem def = this.itemdef;
 253                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
 254                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 255                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 256             }
 257                 }
 258
 259                 if(this.waypointsprite_attached)
 260                 {
 261                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 262                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 263                                 {
 264                                         msg_entity = it;
 265                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM, 0); // play respawn sound
 266                                 }
 267                         });
 268
 269                         WaypointSprite_Ping(this.waypointsprite_attached);
 270                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.item_respawncounter);
 271                 }
 272         }
 273 }
 274
 275 void Item_RespawnThink(entity this)
 276 {
 277         this.nextthink = time;
 278         if(this.origin != this.oldorigin)
 279                 ItemUpdate(this);
 280
 281         if(time >= this.wait)
 282                 Item_Respawn(this);
 283 }
 284
 285 void Item_ScheduleRespawnIn(entity e, float t)
 286 {
 287         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 288         if ((Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
 289         {
 290                 setthink(e, Item_RespawnCountdown);
 291                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 292                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 293                 e.item_respawncounter = 0;
 294                 if(Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
 295                 {
 296                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 297                         Item_ItemsTime_SetTime(e, t);
 298                         Item_ItemsTime_SetTimesForAllPlayers();
 299                 }
 300         }
 301         else
 302         {
 303                 setthink(e, Item_RespawnThink);
 304                 e.nextthink = time;
 305                 e.scheduledrespawntime = time + t;
 306                 e.wait = time + t;
 307
 308                 if(Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
 309                 {
 310                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 311                         Item_ItemsTime_SetTime(e, t);
 312                         Item_ItemsTime_SetTimesForAllPlayers();
 313                 }
 314         }
 315 }
 316
 317 AUTOCVAR(g_pickup_respawntime_scaling_reciprocal, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `reciprocal` (with `offset` and `linear` set to 0) can be used to achieve a constant number of items spawned *per player*");
 318 AUTOCVAR(g_pickup_respawntime_scaling_offset, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `offset` offsets the curve left or right - the results are not intuitive and I recommend plotting the respawn time and the number of items per player to see what's happening");
 319 AUTOCVAR(g_pickup_respawntime_scaling_linear, float, 1.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `linear` can be used to simply scale the respawn time linearly");
 320
 321 /// Adjust respawn time according to the number of players.
 322 float adjust_respawntime(float normal_respawntime) {
 323         float r = autocvar_g_pickup_respawntime_scaling_reciprocal;
 324         float o = autocvar_g_pickup_respawntime_scaling_offset;
 325         float l = autocvar_g_pickup_respawntime_scaling_linear;
 326
 327         if (r == 0 && l == 1) {
 328                 return normal_respawntime;
 329         }
 330
 331         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 332         TeamBalance_GetTeamCounts(balance, NULL);
 333         int players = 0;
 334         for (int i = 1; i <= NUM_TEAMS; ++i)
 335         {
 336                 if (TeamBalance_IsTeamAllowed(balance, i))
 337                 {
 338                         players += TeamBalance_GetNumberOfPlayers(balance, i);
 339                 }
 340         }
 341         TeamBalance_Destroy(balance);
 342
 343         if (players >= 2) {
 344                 return normal_respawntime * (r / (players + o) + l);
 345         } else {
 346                 return normal_respawntime;
 347         }
 348 }
 349
 350 void Item_ScheduleRespawn(entity e)
 351 {
 352         if(e.respawntime > 0)
 353         {
 354                 Item_Show(e, 0);
 355
 356                 float adjusted_respawntime = adjust_respawntime(e.respawntime);
 357                 //LOG_INFOF("item %s will respawn in %f", e.classname, adjusted_respawntime);
 358
 359                 // range: adjusted_respawntime - respawntimejitter .. adjusted_respawntime + respawntimejitter
 360                 float respawn_in = adjusted_respawntime + crandom() * e.respawntimejitter;
 361                 Item_ScheduleRespawnIn(e, respawn_in);
 362         }
 363         else // if respawntime is -1, this item does not respawn
 364                 Item_Show(e, -1);
 365 }
 366
 367 AUTOCVAR(g_pickup_respawntime_initial_random, int, 1,
 368         "For items that don't start spawned: 0: spawn after their normal respawntime; 1: spawn after `random * respawntime` with the *same* random; 2: same as 1 but each item has separate random");
 369
 370 void Item_ScheduleInitialRespawn(entity e)
 371 {
 372         Item_Show(e, 0);
 373
 374         float spawn_in;
 375         if (autocvar_g_pickup_respawntime_initial_random == 0)
 376         {
 377                 // range: respawntime .. respawntime + respawntimejitter
 378                 spawn_in = e.respawntime + random() * e.respawntimejitter;
 379         }
 380         else
 381         {
 382                 float rnd;
 383                 if (autocvar_g_pickup_respawntime_initial_random == 1)
 384                 {
 385                         static float shared_random = 0;
 386                         // NOTE this code works only if items are scheduled at the same time (normal case)
 387                         // NOTE2 random() can't return exactly 1 so this check always work as intended
 388                         if (!shared_random || floor(time) > shared_random)
 389                                 shared_random = floor(time) + random();
 390                         rnd = shared_random - floor(time);
 391                 }
 392                 else
 393                         rnd = random();
 394
 395                 // range:
 396                 // if respawntime >= ITEM_RESPAWN_TICKS: ITEM_RESPAWN_TICKS .. respawntime + respawntimejitter
 397                 // else: 0 .. ITEM_RESPAWN_TICKS
 398                 // this is to prevent powerups spawning unexpectedly without waypoints
 399                 spawn_in = ITEM_RESPAWN_TICKS + rnd * (e.respawntime + e.respawntimejitter - ITEM_RESPAWN_TICKS);
 400         }
 401
 402         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : spawn_in));
 403 }
 404
 405 void GiveRandomWeapons(entity receiver, int num_weapons, string weapon_names,
 406         entity ammo_entity)
 407 {
 408         if (num_weapons == 0)
 409         {
 410                 return;
 411         }
 412         int num_potential_weapons = tokenize_console(weapon_names);
 413         for (int give_attempt = 0; give_attempt < num_weapons; ++give_attempt)
 414         {
 415                 RandomSelection_Init();
 416                 for (int weapon_index = 0; weapon_index < num_potential_weapons;
 417                         ++weapon_index)
 418                 {
 419                         string weapon = argv(weapon_index);
 420                         FOREACH(Weapons, it != WEP_Null,
 421                         {
 422                                 // Finding a weapon which player doesn't have.
 423                                 if (!(STAT(WEAPONS, receiver) & it.m_wepset) && (it.netname == weapon))
 424                                 {
 425                                         RandomSelection_AddEnt(it, 1, 1);
 426                                         break;
 427                                 }
 428                         });
 429                 }
 430                 if (RandomSelection_chosen_ent == NULL)
 431                 {
 432                         return;
 433                 }
 434                 STAT(WEAPONS, receiver) |= RandomSelection_chosen_ent.m_wepset;
 435                 if (RandomSelection_chosen_ent.ammo_type == RES_NONE)
 436                 {
 437                         continue;
 438                 }
 439                 if (GetResource(receiver,
 440                         RandomSelection_chosen_ent.ammo_type) != 0)
 441                 {
 442                         continue;
 443                 }
 444                 GiveResource(receiver, RandomSelection_chosen_ent.ammo_type,
 445                         GetResource(ammo_entity,
 446                         RandomSelection_chosen_ent.ammo_type));
 447         }
 448 }
 449
 450 bool Item_GiveAmmoTo(entity item, entity player, int res_type, float ammomax)
 451 {
 452         float amount = GetResource(item, res_type);
 453         if (amount == 0)
 454         {
 455                 return false;
 456         }
 457         float player_amount = GetResource(player, res_type);
 458         if (item.spawnshieldtime)
 459         {
 460                 if ((player_amount >= ammomax) && (item.pickup_anyway <= 0))
 461                         return false;
 462         }
 463         else if (g_weapon_stay == 2)
 464         {
 465                 ammomax = min(amount, ammomax);
 466                 if(player_amount >= ammomax)
 467                         return false;
 468         }
 469         else
 470                 return false;
 471         if (amount < 0)
 472                 TakeResourceWithLimit(player, res_type, -amount, ammomax);
 473         else
 474                 GiveResourceWithLimit(player, res_type, amount, ammomax);
 475         return true;
 476 }
 477
 478 bool Item_GiveTo(entity item, entity player)
 479 {
 480         // if nothing happens to player, just return without taking the item
 481         int _switchweapon = 0;
 482         // in case the player has autoswitch enabled do the following:
 483         // if the player is using their best weapon before items are given, they
 484         // probably want to switch to an even better weapon after items are given
 485
 486         if(CS_CVAR(player).autoswitch)
 487         {
 488                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 489                 {
 490                         .entity weaponentity = weaponentities[slot];
 491                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 492                         {
 493                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 494                                         _switchweapon |= BIT(slot);
 495
 496                                 if(!(STAT(WEAPONS, player) & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 497                                         _switchweapon |= BIT(slot);
 498                         }
 499                 }
 500         }
 501         bool pickedup = false;
 502         pickedup |= Item_GiveAmmoTo(item, player, RES_HEALTH, item.max_health);
 503         pickedup |= Item_GiveAmmoTo(item, player, RES_ARMOR, item.max_armorvalue);
 504         pickedup |= Item_GiveAmmoTo(item, player, RES_SHELLS, g_pickup_shells_max);
 505         pickedup |= Item_GiveAmmoTo(item, player, RES_BULLETS, g_pickup_nails_max);
 506         pickedup |= Item_GiveAmmoTo(item, player, RES_ROCKETS, g_pickup_rockets_max);
 507         pickedup |= Item_GiveAmmoTo(item, player, RES_CELLS, g_pickup_cells_max);
 508         pickedup |= Item_GiveAmmoTo(item, player, RES_PLASMA, g_pickup_plasma_max);
 509         pickedup |= Item_GiveAmmoTo(item, player, RES_FUEL, g_pickup_fuel_max);
 510         if (item.itemdef.instanceOfWeaponPickup)
 511         {
 512                 WepSet w;
 513                 w = STAT(WEAPONS, item);
 514                 w &= ~STAT(WEAPONS, player);
 515
 516                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 517                 {
 518                         pickedup = true;
 519                         FOREACH(Weapons, it != WEP_Null, {
 520                                 if(w & (it.m_wepset))
 521                                 {
 522                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 523                                         {
 524                                                 .entity weaponentity = weaponentities[slot];
 525                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 526                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 527                                         }
 528                                         W_GiveWeapon(player, it.m_id);
 529                                 }
 530                         });
 531                 }
 532         }
 533
 534         if (item.itemdef.instanceOfPowerup)
 535         {
 536                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 537                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 538                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 539                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 540         }
 541
 542         int its;
 543         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 544         {
 545                 pickedup = true;
 546                 player.items |= its;
 547                 // TODO: we probably want to show a message in the console, but not this one!
 548                 //Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 549         }
 550
 551         if (item.strength_finished)
 552         {
 553                 pickedup = true;
 554                 float t = max(StatusEffects_gettime(STATUSEFFECT_Strength, player), time);
 555                 if (autocvar_g_powerups_stack)
 556                         t += item.strength_finished;
 557                 else
 558                         t = max(t, time + item.strength_finished);
 559                 StatusEffects_apply(STATUSEFFECT_Strength, player, t, 0);
 560         }
 561         if (item.invincible_finished)
 562         {
 563                 pickedup = true;
 564                 float t = max(StatusEffects_gettime(STATUSEFFECT_Shield, player), time);
 565                 if (autocvar_g_powerups_stack)
 566                         t += item.invincible_finished;
 567                 else
 568                         t = max(t, time + item.invincible_finished);
 569                 StatusEffects_apply(STATUSEFFECT_Shield, player, t, 0);
 570         }
 571         if (item.speed_finished)
 572         {
 573                 pickedup = true;
 574                 float t = max(StatusEffects_gettime(STATUSEFFECT_Speed, player), time);
 575                 if (autocvar_g_powerups_stack)
 576                         t += item.speed_finished;
 577                 else
 578                         t = max(t, time + item.speed_finished);
 579                 StatusEffects_apply(STATUSEFFECT_Speed, player, t, 0);
 580         }
 581         if (item.invisibility_finished)
 582         {
 583                 pickedup = true;
 584                 float t = max(StatusEffects_gettime(STATUSEFFECT_Invisibility, player), time);
 585                 if (autocvar_g_powerups_stack)
 586                         t += item.invisibility_finished;
 587                 else
 588                         t = max(t, time + item.invisibility_finished);
 589                 StatusEffects_apply(STATUSEFFECT_Invisibility, player, t, 0);
 590         }
 591         if (item.superweapons_finished)
 592         {
 593                 pickedup = true;
 594                 StatusEffects_apply(STATUSEFFECT_Superweapons, player, max(StatusEffects_gettime(STATUSEFFECT_Superweapons, player), time) + item.superweapons_finished, 0);
 595         }
 596
 597         // always eat teamed entities
 598         if(item.team)
 599                 pickedup = true;
 600
 601         if (!pickedup)
 602                 return false;
 603
 604         // crude hack to enforce switching weapons
 605         if(g_cts && item.itemdef.instanceOfWeaponPickup && !CS_CVAR(player).cvar_cl_cts_noautoswitch)
 606         {
 607                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 608                 {
 609                         .entity weaponentity = weaponentities[slot];
 610                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 611                                 W_SwitchWeapon_Force(player, REGISTRY_GET(Weapons, item.weapon), weaponentity);
 612                 }
 613                 return true;
 614         }
 615
 616         if(_switchweapon)
 617         {
 618                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 619                 {
 620                         .entity weaponentity = weaponentities[slot];
 621                         if(_switchweapon & BIT(slot))
 622                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 623                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 624                 }
 625         }
 626
 627         return true;
 628 }
 629
 630 void Item_Touch(entity this, entity toucher)
 631 {
 632         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 633         if (Item_IsLoot(this))
 634         {
 635                 if (ITEM_TOUCH_NEEDKILL())
 636                 {
 637                         delete(this);
 638                         return;
 639                 }
 640         }
 641
 642         if(!(toucher.flags & FL_PICKUPITEMS)
 643         || STAT(FROZEN, toucher)
 644         || IS_DEAD(toucher)
 645         || (this.solid != SOLID_TRIGGER)
 646         || (this.owner == toucher)
 647         || (time < this.item_spawnshieldtime)
 648         ) { return; }
 649
 650         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 651         {
 652                 case MUT_ITEMTOUCH_RETURN: { return; }
 653                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 654         }
 655
 656         toucher = M_ARGV(1, entity);
 657
 658         if (Item_IsExpiring(this))
 659         {
 660                 this.strength_finished = max(0, this.strength_finished - time);
 661                 this.invincible_finished = max(0, this.invincible_finished - time);
 662                 this.speed_finished = max(0, this.speed_finished - time);
 663                 this.invisibility_finished = max(0, this.invisibility_finished - time);
 664                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 665         }
 666         bool gave = ITEM_HANDLE(Pickup, this.itemdef, this, toucher);
 667         if (!gave)
 668         {
 669                 if (Item_IsExpiring(this))
 670                 {
 671                         // undo what we did above
 672                         this.strength_finished += time;
 673                         this.invincible_finished += time;
 674                         this.speed_finished += time;
 675                         this.invisibility_finished += time;
 676                         this.superweapons_finished += time;
 677                 }
 678                 return;
 679         }
 680
 681 LABEL(pickup)
 682
 683         if(this.target && this.target != "" && this.target != "###item###") // defrag support
 684                 SUB_UseTargets(this, toucher, NULL);
 685
 686         STAT(LAST_PICKUP, toucher) = time;
 687
 688         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 689         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 690
 691         MUTATOR_CALLHOOK(ItemTouched, this, toucher);
 692         if (wasfreed(this))
 693         {
 694                 return;
 695         }
 696
 697         if (Item_IsLoot(this))
 698         {
 699                 delete(this);
 700                 return;
 701         }
 702         if (!this.spawnshieldtime)
 703         {
 704                 return;
 705         }
 706         entity e;
 707         if (this.team)
 708         {
 709                 RandomSelection_Init();
 710                 IL_EACH(g_items, it.team == this.team,
 711                 {
 712                         if (it.itemdef) // is a registered item
 713                         {
 714                                 Item_Show(it, -1);
 715                                 it.scheduledrespawntime = 0;
 716                                 RandomSelection_AddEnt(it, it.cnt, 0);
 717                         }
 718                 });
 719                 e = RandomSelection_chosen_ent;
 720                 Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
 721         }
 722         else
 723                 e = this;
 724         Item_ScheduleRespawn(e);
 725 }
 726
 727 void Item_Reset(entity this)
 728 {
 729         Item_Show(this, !this.state);
 730         setorigin(this, this.origin);
 731
 732         if (Item_IsLoot(this))
 733         {
 734                 return;
 735         }
 736         setthink(this, Item_Think);
 737         this.nextthink = time;
 738         if (this.waypointsprite_attached)
 739         {
 740                 WaypointSprite_Kill(this.waypointsprite_attached);
 741         }
 742         if (this.itemdef.instanceOfPowerup || (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 743         {
 744                 Item_ScheduleInitialRespawn(this);
 745         }
 746 }
 747
 748 void Item_FindTeam(entity this)
 749 {
 750         entity e;
 751
 752         if(this.effects & EF_NODRAW)
 753         {
 754                 // marker for item team search
 755                 LOG_TRACE("Initializing item team ", ftos(this.team));
 756                 RandomSelection_Init();
 757                 IL_EACH(g_items, it.team == this.team,
 758                 {
 759                         if(it.itemdef) // is a registered item
 760                                 RandomSelection_AddEnt(it, it.cnt, 0);
 761                 });
 762
 763                 e = RandomSelection_chosen_ent;
 764                 if (!e)
 765                         return;
 766
 767                 IL_EACH(g_items, it.team == this.team,
 768                 {
 769                         if(it.itemdef) // is a registered item
 770                         {
 771                                 if(it != e)
 772                                 {
 773                                         // make it non-spawned
 774                                         Item_Show(it, -1);
 775                                         it.state = 1; // state 1 = initially hidden item, apparently
 776                                 }
 777                                 else
 778                                         Item_Reset(it);
 779                                 it.effects &= ~EF_NODRAW;
 780                         }
 781                 });
 782         }
 783 }
 784
 785 // Savage: used for item garbage-collection
 786 void RemoveItem(entity this)
 787 {
 788         if(wasfreed(this) || !this) { return; }
 789         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 790         delete(this);
 791 }
 792
 793 // pickup evaluation functions
 794 // these functions decide how desirable an item is to the bots
 795
 796 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 797
 798 float weapon_pickupevalfunc(entity player, entity item)
 799 {
 800         // See if I have it already
 801         if(STAT(WEAPONS, player) & STAT(WEAPONS, item))
 802         {
 803                 // If I can pick it up
 804                 if(!item.spawnshieldtime)
 805                         return 0;
 806                 return ammo_pickupevalfunc(player, item);
 807         }
 808
 809         // reduce weapon value if bot already got a good arsenal
 810         float c = 1;
 811         int weapons_value = 0;
 812         FOREACH(Weapons, it != WEP_Null && (STAT(WEAPONS, player) & it.m_wepset), {
 813                 weapons_value += it.bot_pickupbasevalue;
 814         });
 815         c -= bound(0, weapons_value / 20000, 1) * 0.5;
 816
 817         return item.bot_pickupbasevalue * c;
 818 }
 819
 820 float ammo_pickupevalfunc(entity player, entity item)
 821 {
 822         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
 823         entity wpn = NULL;
 824         float c = 0;
 825         float rating = 0;
 826
 827         // Detect needed ammo
 828         if(item.itemdef.instanceOfWeaponPickup)
 829         {
 830                 entity ammo = NULL;
 831                 if(GetResource(item, RES_SHELLS))       { need_shells  = true; ammo = ITEM_Shells;      }
 832                 else if(GetResource(item, RES_BULLETS))   { need_nails   = true; ammo = ITEM_Bullets;     }
 833                 else if(GetResource(item, RES_ROCKETS)) { need_rockets = true; ammo = ITEM_Rockets;     }
 834                 else if(GetResource(item, RES_CELLS))   { need_cells   = true; ammo = ITEM_Cells;       }
 835                 else if(GetResource(item, RES_PLASMA))  { need_plasma  = true; ammo = ITEM_Plasma;      }
 836                 else if(GetResource(item, RES_FUEL))    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
 837
 838                 if(!ammo)
 839                         return 0;
 840                 wpn = item;
 841                 rating = ammo.m_botvalue;
 842         }
 843         else
 844         {
 845                 FOREACH(Weapons, it != WEP_Null, {
 846                         if(!(STAT(WEAPONS, player) & (it.m_wepset)))
 847                                 continue;
 848
 849                         switch(it.ammo_type)
 850                         {
 851                                 case RES_SHELLS:  need_shells  = true; break;
 852                                 case RES_BULLETS: need_nails   = true; break;
 853                                 case RES_ROCKETS: need_rockets = true; break;
 854                                 case RES_CELLS:   need_cells   = true; break;
 855                                 case RES_PLASMA:  need_plasma  = true; break;
 856                                 case RES_FUEL:    need_fuel    = true; break;
 857                         }
 858                 });
 859                 rating = item.bot_pickupbasevalue;
 860         }
 861
 862         float noammorating = 0.5;
 863
 864         if ((need_shells) && GetResource(item, RES_SHELLS) && (GetResource(player, RES_SHELLS) < g_pickup_shells_max))
 865                 c = GetResource(item, RES_SHELLS) / max(noammorating, GetResource(player, RES_SHELLS));
 866
 867         if ((need_nails) && GetResource(item, RES_BULLETS) && (GetResource(player, RES_BULLETS) < g_pickup_nails_max))
 868                 c = GetResource(item, RES_BULLETS) / max(noammorating, GetResource(player, RES_BULLETS));
 869
 870         if ((need_rockets) && GetResource(item, RES_ROCKETS) && (GetResource(player, RES_ROCKETS) < g_pickup_rockets_max))
 871                 c = GetResource(item, RES_ROCKETS) / max(noammorating, GetResource(player, RES_ROCKETS));
 872
 873         if ((need_cells) && GetResource(item, RES_CELLS) && (GetResource(player, RES_CELLS) < g_pickup_cells_max))
 874                 c = GetResource(item, RES_CELLS) / max(noammorating, GetResource(player, RES_CELLS));
 875
 876         if ((need_plasma) && GetResource(item, RES_PLASMA) && (GetResource(player, RES_PLASMA) < g_pickup_plasma_max))
 877                 c = GetResource(item, RES_PLASMA) / max(noammorating, GetResource(player, RES_PLASMA));
 878
 879         if ((need_fuel) && GetResource(item, RES_FUEL) && (GetResource(player, RES_FUEL) < g_pickup_fuel_max))
 880                 c = GetResource(item, RES_FUEL) / max(noammorating, GetResource(player, RES_FUEL));
 881
 882         rating *= min(c, 2);
 883         if(wpn)
 884                 rating += wpn.bot_pickupbasevalue * 0.1;
 885         return rating;
 886 }
 887
 888 float healtharmor_pickupevalfunc(entity player, entity item)
 889 {
 890         float c = 0;
 891         float rating = item.bot_pickupbasevalue;
 892
 893         float itemarmor = GetResource(item, RES_ARMOR);
 894         float itemhealth = GetResource(item, RES_HEALTH);
 895
 896         if(item.item_group)
 897         {
 898                 itemarmor *= min(4, item.item_group_count);
 899                 itemhealth *= min(4, item.item_group_count);
 900         }
 901
 902         if (itemarmor && (GetResource(player, RES_ARMOR) < item.max_armorvalue))
 903                 c = itemarmor / max(1, GetResource(player, RES_ARMOR) * 2/3 + GetResource(player, RES_HEALTH) * 1/3);
 904
 905         if (itemhealth && (GetResource(player, RES_HEALTH) < item.max_health))
 906                 c = itemhealth / max(1, GetResource(player, RES_HEALTH));
 907
 908         rating *= min(2, c);
 909         return rating;
 910 }
 911
 912 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 913 {
 914         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 915                 RemoveItem(this);
 916 }
 917
 918 void item_use(entity this, entity actor, entity trigger)
 919 {
 920         // use the touch function to handle collection
 921         gettouch(this)(this, actor);
 922 }
 923
 924 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
 925 {
 926         string itemname = def.m_name;
 927         Model itemmodel = def.m_model;
 928         Sound pickupsound = def.m_sound;
 929         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
 930         float pickupbasevalue = def.m_botvalue;
 931         int itemflags = def.m_itemflags;
 932
 933         startitem_failed = false;
 934
 935         this.item_model_ent = itemmodel;
 936         this.item_pickupsound_ent = pickupsound;
 937
 938         if(def.m_iteminit)
 939                 def.m_iteminit(def, this);
 940
 941         if(!this.respawntime) // both need to be set
 942         {
 943                 this.respawntime = defaultrespawntime;
 944                 this.respawntimejitter = defaultrespawntimejitter;
 945         }
 946
 947         if(!this.pickup_anyway && def.m_pickupanyway)
 948                 this.pickup_anyway = def.m_pickupanyway();
 949
 950         int itemid = def.m_itemid;
 951         this.items = itemid;
 952         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
 953         this.weapon = weaponid;
 954
 955         if(!this.fade_end)
 956         {
 957                 this.fade_start = autocvar_g_items_mindist;
 958                 this.fade_end = autocvar_g_items_maxdist;
 959         }
 960
 961         if(weaponid)
 962                 STAT(WEAPONS, this) = WepSet_FromWeapon(REGISTRY_GET(Weapons, weaponid));
 963
 964         this.flags = FL_ITEM | itemflags;
 965         IL_PUSH(g_items, this);
 966
 967         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
 968         {
 969                 startitem_failed = true;
 970                 delete(this);
 971                 return;
 972         }
 973
 974         precache_model(this.model);
 975         precache_sound(this.item_pickupsound);
 976
 977         if (Item_IsLoot(this))
 978         {
 979                 this.reset = SUB_Remove;
 980                 set_movetype(this, MOVETYPE_TOSS);
 981
 982                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 983                 setthink(this, RemoveItem);
 984                 this.nextthink = time + 20;
 985
 986                 this.takedamage = DAMAGE_YES;
 987                 this.event_damage = Item_Damage;
 988                 // enable this to have thrown items burn in lava
 989                 //this.damagedbycontents = true;
 990                 //IL_PUSH(g_damagedbycontents, this);
 991
 992                 if (Item_IsExpiring(this))
 993                 {
 994                         // if item is worthless after a timer, have it expire then
 995                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
 996                 }
 997
 998                 // don't drop if in a NODROP zone (such as lava)
 999                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1000                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1001                 {
1002                         startitem_failed = true;
1003                         delete(this);
1004                         return;
1005                 }
1006         }
1007         else
1008         {
1009                 if(!have_pickup_item(this))
1010                 {
1011                         startitem_failed = true;
1012                         delete(this);
1013                         return;
1014                 }
1015
1016                 if(this.angles != '0 0 0')
1017                         this.SendFlags |= ISF_ANGLES;
1018
1019                 this.reset = Item_Reset;
1020                 // it's a level item
1021                 if(this.spawnflags & 1)
1022                         this.noalign = 1;
1023                 if (this.noalign > 0)
1024                         set_movetype(this, MOVETYPE_NONE);
1025                 else
1026                         set_movetype(this, MOVETYPE_TOSS);
1027                 // do item filtering according to game mode and other things
1028                 if (this.noalign <= 0)
1029                 {
1030                         // first nudge it off the floor a little bit to avoid math errors
1031                         setorigin(this, this.origin + '0 0 1');
1032                         // set item size before we spawn a spawnfunc_waypoint
1033                         setsize(this, def.m_mins, def.m_maxs);
1034                         this.SendFlags |= ISF_SIZE;
1035                         // note droptofloor returns false if stuck/or would fall too far
1036                         if (!this.noalign)
1037                                 droptofloor(this);
1038                         waypoint_spawnforitem(this);
1039                 }
1040
1041                 /*
1042                  * can't do it that way, as it would break maps
1043                  * TODO make a target_give like entity another way, that perhaps has
1044                  * the weapon name in a key
1045                 if(this.targetname)
1046                 {
1047                         // target_give not yet supported; maybe later
1048                         print("removed targeted ", this.classname, "\n");
1049                         startitem_failed = true;
1050                         delete(this);
1051                         return;
1052                 }
1053                 */
1054
1055                 if(this.targetname != "" && (this.spawnflags & 16))
1056                         this.use = item_use;
1057
1058                 if(autocvar_spawn_debug >= 2)
1059                 {
1060                         // why not flags & fl_item?
1061                         FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1062                                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1063                                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1064                                 error("Mapper sucks.");
1065                         });
1066                         this.is_item = true;
1067                 }
1068
1069                 weaponsInMap |= WepSet_FromWeapon(REGISTRY_GET(Weapons, weaponid));
1070
1071                 if (        def.instanceOfPowerup
1072                         ||  def.instanceOfWeaponPickup
1073                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1074                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1075                         || (itemid & (IT_KEY1 | IT_KEY2))
1076                 )
1077                 {
1078                         if(!this.target || this.target == "")
1079                                 this.target = "###item###"; // for finding the nearest item using findnearest
1080                 }
1081
1082                 Item_ItemsTime_SetTime(this, 0);
1083         }
1084
1085         this.bot_pickup = true;
1086         this.bot_pickupevalfunc = pickupevalfunc;
1087         this.bot_pickupbasevalue = pickupbasevalue;
1088         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1089         this.netname = itemname;
1090         settouch(this, Item_Touch);
1091         setmodel(this, MDL_Null); // precision set below
1092         //this.effects |= EF_LOWPRECISION;
1093
1094         // support skinned models for powerups
1095         this.skin = def.m_skin;
1096         this.glowmod = def.m_color;
1097
1098         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1099
1100         this.SendFlags |= ISF_SIZE;
1101
1102         if (!(this.spawnflags & 1024)) {
1103                 if(def.instanceOfPowerup)
1104                         this.ItemStatus |= ITS_ANIMATE1;
1105
1106                 if(GetResource(this, RES_ARMOR) || GetResource(this, RES_HEALTH))
1107                         this.ItemStatus |= ITS_ANIMATE2;
1108         }
1109
1110         if(Item_IsLoot(this))
1111                 this.gravity = 1;
1112
1113         if(def.instanceOfWeaponPickup)
1114         {
1115                 if (!Item_IsLoot(this)) // if dropped, colormap is already set up nicely
1116                         this.colormap = 1024; // color shirt=0 pants=0 grey
1117                 if (!(this.spawnflags & 1024))
1118                         this.ItemStatus |= ITS_ANIMATE1;
1119                 this.SendFlags |= ISF_COLORMAP;
1120         }
1121
1122         this.state = 0;
1123         if(this.team)
1124         {
1125                 if(!this.cnt)
1126                         this.cnt = 1; // item probability weight
1127
1128                 this.effects |= EF_NODRAW; // marker for item team search
1129                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1130         }
1131         else
1132                 Item_Reset(this);
1133
1134         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1135
1136         // call this hook after everything else has been done
1137         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1138         {
1139                 startitem_failed = true;
1140                 delete(this);
1141                 return;
1142         }
1143
1144         setItemGroup(this);
1145 }
1146
1147 void StartItem(entity this, GameItem def)
1148 {
1149         def = def.m_spawnfunc_hookreplace(def, this);
1150
1151         if (def.spawnflags & ITEM_FLAG_MUTATORBLOCKED)
1152         {
1153                 delete(this);
1154                 return;
1155         }
1156
1157         this.classname = def.m_canonical_spawnfunc;
1158
1159         _StartItem(
1160                 this,
1161                 this.itemdef = def,
1162                 def.m_respawntime(), // defaultrespawntime
1163                 def.m_respawntimejitter() // defaultrespawntimejitter
1164         );
1165 }
1166
1167 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1168 int group_count = 1;
1169
1170 void setItemGroup(entity this)
1171 {
1172         if(!IS_SMALL(this.itemdef) || Item_IsLoot(this))
1173                 return;
1174
1175         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1176         {
1177                 if(!this.item_group)
1178                 {
1179                         if(!it.item_group)
1180                         {
1181                                 it.item_group = group_count;
1182                                 group_count++;
1183                         }
1184                         this.item_group = it.item_group;
1185                 }
1186                 else // spawning item is already part of a item_group X
1187                 {
1188                         if(!it.item_group)
1189                                 it.item_group = this.item_group;
1190                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1191                         {
1192                                 int grY = it.item_group;
1193                                 // move all items of item_group Y to item_group X
1194                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1195                                 {
1196                                         if(it.item_group == grY)
1197                                                 it.item_group = this.item_group;
1198                                 });
1199                         }
1200                 }
1201         });
1202 }
1203
1204 void setItemGroupCount()
1205 {
1206         for (int k = 1; k <= group_count; k++)
1207         {
1208                 int count = 0;
1209                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1210                 if (count)
1211                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1212         }
1213 }
1214
1215 void target_items_use(entity this, entity actor, entity trigger)
1216 {
1217         if(Item_IsLoot(actor))
1218         {
1219                 EXACTTRIGGER_TOUCH(this, trigger);
1220                 delete(actor);
1221                 return;
1222         }
1223
1224         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1225                 return;
1226
1227         if(trigger.solid == SOLID_TRIGGER)
1228         {
1229                 EXACTTRIGGER_TOUCH(this, trigger);
1230         }
1231
1232         IL_EACH(g_items, it.enemy == actor && Item_IsLoot(it),
1233         {
1234                 delete(it);
1235         });
1236
1237         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1238                 centerprint(actor, this.message);
1239 }
1240
1241 spawnfunc(target_items)
1242 {
1243         this.use = target_items_use;
1244         if(!this.strength_finished)
1245                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1246         if(!this.invincible_finished)
1247                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1248         if(!this.speed_finished)
1249                 this.speed_finished = autocvar_g_balance_powerup_speed_time;
1250         if(!this.invisibility_finished)
1251                 this.invisibility_finished = autocvar_g_balance_powerup_invisibility_time;
1252         if(!this.superweapons_finished)
1253                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1254
1255         string str;
1256         int n = tokenize_console(this.netname);
1257         if(argv(0) == "give")
1258         {
1259                 str = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1260         }
1261         else
1262         {
1263                 for(int j = 0; j < n; ++j)
1264                 {
1265                         // this is from a time when unlimited superweapons were handled together with ammo in some parts of the code
1266                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS;
1267                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_AMMO;
1268                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1269                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1270                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1271                         else if(argv(j) == "speed")                  this.items |= ITEM_Speed.m_itemid;
1272                         else if(argv(j) == "invisibility")           this.items |= ITEM_Invisibility.m_itemid;
1273                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1274                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1275                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1276                         else
1277                         {
1278                                 FOREACH(StatusEffect, it.instanceOfBuff,
1279                                 {
1280                                         string s = Buff_UndeprecateName(argv(j));
1281                                         if(s == it.netname)
1282                                         {
1283                                                 this.buffdef = it;
1284                                                 if(!this.buffs_finished)
1285                                                         this.buffs_finished = it.m_time(it);
1286                                                 break;
1287                                         }
1288                                 });
1289                                 FOREACH(Weapons, it != WEP_Null, {
1290                                         string s = W_UndeprecateName(argv(j));
1291                                         if(s == it.netname)
1292                                         {
1293                                                 STAT(WEAPONS, this) |= (it.m_wepset);
1294                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1295                                                         it.wr_init(it);
1296                                                 break;
1297                                         }
1298                                 });
1299                         }
1300                 }
1301
1302                 string itemprefix, valueprefix;
1303                 if(this.spawnflags == 0)
1304                 {
1305                         itemprefix = "";
1306                         valueprefix = "";
1307                 }
1308                 else if(this.spawnflags == 1)
1309                 {
1310                         itemprefix = "max ";
1311                         valueprefix = "max ";
1312                 }
1313                 else if(this.spawnflags == 2)
1314                 {
1315                         itemprefix = "min ";
1316                         valueprefix = "min ";
1317                 }
1318                 else if(this.spawnflags == 4)
1319                 {
1320                         itemprefix = "minus ";
1321                         valueprefix = "max ";
1322                 }
1323                 else
1324                 {
1325                         error("invalid spawnflags");
1326                         itemprefix = valueprefix = string_null;
1327                 }
1328
1329                 str = "";
1330                 str = sprintf("%s %s%d %s", str, itemprefix, boolean(this.items & IT_UNLIMITED_AMMO), "unlimited_weapon_ammo");
1331                 str = sprintf("%s %s%d %s", str, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1332                 str = sprintf("%s %s%d %s", str, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1333                 str = sprintf("%s %s%d %s", str, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1334                 str = sprintf("%s %s%d %s", str, valueprefix, this.invisibility_finished * boolean(this.items & ITEM_Invisibility.m_itemid), "invisibility");
1335                 str = sprintf("%s %s%d %s", str, valueprefix, this.speed_finished * boolean(this.items & ITEM_Speed.m_itemid), "speed");
1336                 str = sprintf("%s %s%d %s", str, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1337                 str = sprintf("%s %s%d %s", str, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1338                 str = sprintf("%s %s%d %s", str, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1339                 float res;
1340                 res = GetResource(this, RES_SHELLS);  if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "shells");
1341                 res = GetResource(this, RES_BULLETS); if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "nails");
1342                 res = GetResource(this, RES_ROCKETS); if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "rockets");
1343                 res = GetResource(this, RES_CELLS);   if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "cells");
1344                 res = GetResource(this, RES_PLASMA);  if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "plasma");
1345                 res = GetResource(this, RES_FUEL);    if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "fuel");
1346                 res = GetResource(this, RES_HEALTH);  if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "health");
1347                 res = GetResource(this, RES_ARMOR);   if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "armor");
1348                 FOREACH(StatusEffect, it.instanceOfBuff, str = sprintf("%s %s%d %s", str, valueprefix, this.buffs_finished * boolean(this.buffdef == it), it.netname));
1349                 FOREACH(Weapons, it != WEP_Null, str = sprintf("%s %s%d %s", str, itemprefix, !!(STAT(WEAPONS, this) & (it.m_wepset)), it.netname));
1350         }
1351         this.netname = strzone(str);
1352
1353         n = tokenize_console(this.netname);
1354         for(int j = 0; j < n; ++j)
1355         {
1356                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1357                         it.wr_init(it);
1358                         break;
1359                 });
1360         }
1361 }
1362
1363 float GiveWeapon(entity e, float wpn, float op, float val)
1364 {
1365         WepSet v0, v1;
1366         WepSet s = WepSet_FromWeapon(REGISTRY_GET(Weapons, wpn));
1367         v0 = (STAT(WEAPONS, e) & s);
1368         switch(op)
1369         {
1370                 case OP_SET:
1371                         if(val > 0)
1372                                 STAT(WEAPONS, e) |= s;
1373                         else
1374                                 STAT(WEAPONS, e) &= ~s;
1375                         break;
1376                 case OP_MIN:
1377                 case OP_PLUS:
1378                         if(val > 0)
1379                                 STAT(WEAPONS, e) |= s;
1380                         break;
1381                 case OP_MAX:
1382                         if(val <= 0)
1383                                 STAT(WEAPONS, e) &= ~s;
1384                         break;
1385                 case OP_MINUS:
1386                         if(val > 0)
1387                                 STAT(WEAPONS, e) &= ~s;
1388                         break;
1389         }
1390         v1 = (STAT(WEAPONS, e) & s);
1391         return (v0 != v1);
1392 }
1393
1394 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1395 {
1396         bool had_buff = StatusEffects_active(thebuff, e);
1397         float new_buff_time = ((had_buff) ? StatusEffects_gettime(thebuff, e) : 0);
1398         switch (op)
1399         {
1400                 case OP_SET:
1401                         new_buff_time = val;
1402                         break;
1403                 case OP_MIN:
1404                         new_buff_time = max(new_buff_time, val);
1405                         break;
1406                 case OP_MAX:
1407                         new_buff_time = min(new_buff_time, val);
1408                         break;
1409                 case OP_PLUS:
1410                         new_buff_time += val;
1411                         break;
1412                 case OP_MINUS:
1413                         new_buff_time -= val;
1414                         break;
1415         }
1416         if(new_buff_time <= 0)
1417         {
1418                 if(had_buff) // only trigger removal mechanics if there is an effect to remove!
1419                         StatusEffects_remove(thebuff, e, STATUSEFFECT_REMOVE_NORMAL);
1420         }
1421         else
1422         {
1423                 buff_RemoveAll(e, STATUSEFFECT_REMOVE_CLEAR); // clear old buffs on the player first!
1424                 StatusEffects_apply(thebuff, e, new_buff_time, 0);
1425         }
1426         bool have_buff = StatusEffects_active(thebuff, e);
1427         return (had_buff != have_buff);
1428 }
1429
1430 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1431 {
1432         if(v1 == v0)
1433                 return;
1434         if(v1 <= v0 - t)
1435         {
1436                 if(snd_decr != NULL)
1437                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1438         }
1439         else if(v0 >= v0 + t)
1440         {
1441                 if(snd_incr != NULL)
1442                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1443         }
1444 }
1445
1446 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1447 {
1448         if(v0 < v1)
1449                 e.(rotfield) = max(e.(rotfield), time + rottime);
1450         else if(v0 > v1)
1451                 e.(regenfield) = max(e.(regenfield), time + regentime);
1452 }
1453 bool GiveResourceValue(entity e, int res_type, int op, int val)
1454 {
1455         int v0 = GetResource(e, res_type);
1456         float new_val = 0;
1457         switch (op)
1458         {
1459                 // min 100 cells = at least 100 cells
1460                 case OP_SET: new_val = val; break;
1461                 case OP_MIN: new_val = max(v0, val); break;
1462                 case OP_MAX: new_val = min(v0, val); break;
1463                 case OP_PLUS: new_val = v0 + val; break;
1464                 case OP_MINUS: new_val = v0 - val; break;
1465                 default: return false;
1466         }
1467
1468         return SetResourceExplicit(e, res_type, new_val);
1469 }
1470 bool GiveStatusEffect(entity e, StatusEffects this, int op, float val)
1471 {
1472         bool had_eff = StatusEffects_active(this, e);
1473         float new_eff_time = ((had_eff) ? StatusEffects_gettime(this, e) : 0);
1474         switch (op)
1475         {
1476                 case OP_SET:
1477                         new_eff_time = val;
1478                         break;
1479                 case OP_MIN:
1480                         new_eff_time = max(new_eff_time, val);
1481                         break;
1482                 case OP_MAX:
1483                         new_eff_time = min(new_eff_time, val);
1484                         break;
1485                 case OP_PLUS:
1486                         new_eff_time += val;
1487                         break;
1488                 case OP_MINUS:
1489                         new_eff_time -= val;
1490                         break;
1491         }
1492         if(new_eff_time <= 0)
1493         {
1494                 if(had_eff) // only trigger removal mechanics if there is an effect to remove!
1495                         StatusEffects_remove(this, e, STATUSEFFECT_REMOVE_NORMAL);
1496         }
1497         else
1498                 StatusEffects_apply(this, e, new_eff_time, 0);
1499         bool have_eff = StatusEffects_active(this, e);
1500         return (had_eff != have_eff);
1501 }
1502
1503 float GiveItems(entity e, float beginarg, float endarg)
1504 {
1505         float got, i, val, op;
1506         string cmd;
1507
1508         val = 999;
1509         op = OP_SET;
1510
1511         got = 0;
1512
1513         int _switchweapon = 0;
1514
1515         if(CS_CVAR(e).autoswitch)
1516         {
1517                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1518                 {
1519                         .entity weaponentity = weaponentities[slot];
1520                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1521                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1522                                 _switchweapon |= BIT(slot);
1523                 }
1524         }
1525
1526         if(e.statuseffects)
1527         {
1528                 FOREACH(StatusEffect, true,
1529                 {
1530                         e.statuseffects.statuseffect_time[it.m_id] = max(0, e.statuseffects.statuseffect_time[it.m_id] - time);
1531                 });
1532         }
1533
1534         PREGIVE(e, items);
1535         PREGIVE_WEAPONS(e);
1536         PREGIVE_STATUSEFFECT(e, STATUSEFFECT_Strength);
1537         PREGIVE_STATUSEFFECT(e, STATUSEFFECT_Shield);
1538         PREGIVE_STATUSEFFECT(e, STATUSEFFECT_Speed);
1539         PREGIVE_STATUSEFFECT(e, STATUSEFFECT_Invisibility);
1540         //PREGIVE_STATUSEFFECT(e, STATUSEFFECT_Superweapons);
1541         PREGIVE_RESOURCE(e, RES_BULLETS);
1542         PREGIVE_RESOURCE(e, RES_CELLS);
1543         PREGIVE_RESOURCE(e, RES_PLASMA);
1544         PREGIVE_RESOURCE(e, RES_SHELLS);
1545         PREGIVE_RESOURCE(e, RES_ROCKETS);
1546         PREGIVE_RESOURCE(e, RES_FUEL);
1547         PREGIVE_RESOURCE(e, RES_ARMOR);
1548         PREGIVE_RESOURCE(e, RES_HEALTH);
1549
1550         for(i = beginarg; i < endarg; ++i)
1551         {
1552                 cmd = argv(i);
1553
1554                 if(cmd == "0" || stof(cmd))
1555                 {
1556                         val = stof(cmd);
1557                         continue;
1558                 }
1559                 switch(cmd)
1560                 {
1561                         case "no":
1562                                 op = OP_MAX;
1563                                 val = 0;
1564                                 continue;
1565                         case "max":
1566                                 op = OP_MAX;
1567                                 continue;
1568                         case "min":
1569                                 op = OP_MIN;
1570                                 continue;
1571                         case "plus":
1572                                 op = OP_PLUS;
1573                                 continue;
1574                         case "minus":
1575                                 op = OP_MINUS;
1576                                 continue;
1577                         case "ALL":
1578                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1579                                 FOREACH(StatusEffect, it.instanceOfPowerups, got += GiveStatusEffect(e, it, op, val));
1580                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS, op, val);
1581                         case "all":
1582                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1583                                 got += GiveResourceValue(e, RES_HEALTH, op, val);
1584                                 got += GiveResourceValue(e, RES_ARMOR, op, val);
1585                         case "allweapons":
1586                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_SPECIALATTACK)), got += GiveWeapon(e, it.m_id, op, val));
1587                         //case "allbuffs": // all buffs makes a player god, do not want!
1588                                 //FOREACH(StatusEffect, it.instanceOfBuff, got += GiveBuff(e, it, op, val));
1589                         case "allammo":
1590                                 got += GiveResourceValue(e, RES_CELLS, op, val);
1591                                 got += GiveResourceValue(e, RES_PLASMA, op, val);
1592                                 got += GiveResourceValue(e, RES_SHELLS, op, val);
1593                                 got += GiveResourceValue(e, RES_BULLETS, op, val);
1594                                 got += GiveResourceValue(e, RES_ROCKETS, op, val);
1595                                 got += GiveResourceValue(e, RES_FUEL, op, val);
1596                                 break;
1597                         case "unlimited_ammo":
1598                                 // this is from a time when unlimited superweapons were handled together with ammo in some parts of the code
1599                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS, op, val);
1600                                 break;
1601                         case "unlimited_weapon_ammo":
1602                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1603                                 break;
1604                         case "unlimited_superweapons":
1605                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1606                                 break;
1607                         case "jetpack":
1608                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1609                                 break;
1610                         case "fuel_regen":
1611                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1612                                 break;
1613                         case "strength":
1614                                 got += GiveStatusEffect(e, STATUSEFFECT_Strength, op, val);
1615                                 break;
1616                         case "invincible":
1617                         case "shield":
1618                                 got += GiveStatusEffect(e, STATUSEFFECT_Shield, op, val);
1619                                 break;
1620                         case "speed":
1621                                 got += GiveStatusEffect(e, STATUSEFFECT_Speed, op, val);
1622                                 break;
1623                         case "invisibility":
1624                                 got += GiveStatusEffect(e, STATUSEFFECT_Invisibility, op, val);
1625                                 break;
1626                         case "superweapons":
1627                                 got += GiveStatusEffect(e, STATUSEFFECT_Superweapons, op, val);
1628                                 break;
1629                         case "cells":
1630                                 got += GiveResourceValue(e, RES_CELLS, op, val);
1631                                 break;
1632                         case "plasma":
1633                                 got += GiveResourceValue(e, RES_PLASMA, op, val);
1634                                 break;
1635                         case "shells":
1636                                 got += GiveResourceValue(e, RES_SHELLS, op, val);
1637                                 break;
1638                         case "nails":
1639                         case "bullets":
1640                                 got += GiveResourceValue(e, RES_BULLETS, op, val);
1641                                 break;
1642                         case "rockets":
1643                                 got += GiveResourceValue(e, RES_ROCKETS, op, val);
1644                                 break;
1645                         case "health":
1646                                 got += GiveResourceValue(e, RES_HEALTH, op, val);
1647                                 break;
1648                         case "armor":
1649                                 got += GiveResourceValue(e, RES_ARMOR, op, val);
1650                                 break;
1651                         case "fuel":
1652                                 got += GiveResourceValue(e, RES_FUEL, op, val);
1653                                 break;
1654                         default:
1655                                 FOREACH(StatusEffect, it.instanceOfBuff && buff_Available(it) && Buff_UndeprecateName(cmd) == it.netname,
1656                                 {
1657                                         got += GiveBuff(e, it, op, val);
1658                                         break;
1659                                 });
1660                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1661                     got += GiveWeapon(e, it.m_id, op, val);
1662                     break;
1663                                 });
1664                                 break;
1665                 }
1666                 val = 999;
1667                 op = OP_SET;
1668         }
1669
1670         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1671         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1672         POSTGIVE_BIT(e, items, IT_UNLIMITED_AMMO, SND_POWERUP, SND_POWEROFF);
1673         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1674         FOREACH(Weapons, it != WEP_Null, {
1675                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1676                 if(!(save_weapons & (it.m_wepset)))
1677                         if(STAT(WEAPONS, e) & (it.m_wepset))
1678                                 it.wr_init(it);
1679         });
1680         POSTGIVE_STATUSEFFECT(e, STATUSEFFECT_Strength, SND_POWERUP, SND_POWEROFF);
1681         POSTGIVE_STATUSEFFECT(e, STATUSEFFECT_Shield, SND_POWERUP, SND_POWEROFF);
1682         POSTGIVE_STATUSEFFECT(e, STATUSEFFECT_Speed, SND_POWERUP, SND_POWEROFF);
1683         POSTGIVE_STATUSEFFECT(e, STATUSEFFECT_Invisibility, SND_POWERUP, SND_POWEROFF);
1684         POSTGIVE_RESOURCE(e, RES_BULLETS, 0, SND_ITEMPICKUP, SND_Null);
1685         POSTGIVE_RESOURCE(e, RES_CELLS, 0, SND_ITEMPICKUP, SND_Null);
1686         POSTGIVE_RESOURCE(e, RES_PLASMA, 0, SND_ITEMPICKUP, SND_Null);
1687         POSTGIVE_RESOURCE(e, RES_SHELLS, 0, SND_ITEMPICKUP, SND_Null);
1688         POSTGIVE_RESOURCE(e, RES_ROCKETS, 0, SND_ITEMPICKUP, SND_Null);
1689         POSTGIVE_RES_ROT(e, RES_FUEL, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1690         POSTGIVE_RES_ROT(e, RES_ARMOR, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1691         POSTGIVE_RES_ROT(e, RES_HEALTH, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1692
1693         if(!StatusEffects_active(STATUSEFFECT_Superweapons, e))
1694         {
1695                 if(!g_weaponarena && (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
1696                         StatusEffects_apply(STATUSEFFECT_Superweapons, e, autocvar_g_balance_superweapons_time, 0);
1697         }
1698
1699         if(e.statuseffects)
1700         {
1701                 FOREACH(StatusEffect, true,
1702                 {
1703                         if(e.statuseffects.statuseffect_time[it.m_id] <= 0)
1704                                 e.statuseffects.statuseffect_time[it.m_id] = 0;
1705                         else
1706                                 e.statuseffects.statuseffect_time[it.m_id] += time;
1707                 });
1708
1709                 StatusEffects_update(e);
1710         }
1711
1712         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1713         {
1714                 .entity weaponentity = weaponentities[slot];
1715                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1716                 if(!(STAT(WEAPONS, e) & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1717                         _switchweapon |= BIT(slot);
1718         }
1719
1720         if(_switchweapon)
1721         {
1722                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1723                 {
1724                         .entity weaponentity = weaponentities[slot];
1725                         if(_switchweapon & BIT(slot))
1726                         {
1727                                 Weapon wep = w_getbestweapon(e, weaponentity);
1728                                 if(wep != e.(weaponentity).m_switchweapon)
1729                                         W_SwitchWeapon_Force(e, wep, weaponentity);
1730                         }
1731                 }
1732         }
1733
1734         return got;
1735 }