qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/items/inventory.qh>
   7 #include <common/mapinfo.qh>
   8 #include <common/net_linked.qh>
   9 #include <common/notifications/all.qh>
  10 #include <common/playerstats.qh>
  11 #include <common/stats.qh>
  12 #include <common/util.qh>
  13 #include <common/weapons/_all.qh>
  14 #include <server/client.qh>
  15 #include <server/command/banning.qh>
  16 #include <server/command/common.qh>
  17 #include <server/command/vote.qh>
  18 #include <server/damage.qh>
  19 #include <server/gamelog.qh>
  20 #include <server/intermission.qh>
  21 #include <server/mutators/_mod.qh>
  22 #include <server/race.qh>
  23 #include <server/round_handler.qh>
  24 #include <server/scores.qh>
  25 #include <server/teamplay.qh>
  26 #include <server/world.qh>
  27
  28 // =============================================
  29 //  Server side voting code, reworked by Samual
  30 //  Last updated: December 27th, 2011
  31 // =============================================
  32
  33 //  Nagger for players to know status of voting
  34 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  35 {
  36         int nags, i, f, b;
  37         entity e;
  38         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  39
  40         // bits:
  41         //   1 = ready
  42         //   2 = player needs to ready up
  43         //   4 = vote
  44         //   8 = player needs to vote
  45         //  16 = warmup
  46         // sendflags:
  47         //  64 = vote counts
  48         // 128 = vote string
  49
  50         nags = 0;
  51         if (readycount)
  52         {
  53                 nags |= BIT(0);
  54                 if (to.ready == 0) nags |= BIT(1);
  55         }
  56         if (vote_called)
  57         {
  58                 nags |= BIT(2);
  59                 if (to.vote_selection == 0) nags |= BIT(3);
  60         }
  61         if (warmup_stage) nags |= BIT(4);
  62
  63         if (sendflags & BIT(6)) nags |= BIT(6);
  64
  65         if (sendflags & BIT(7)) nags |= BIT(7);
  66
  67         if (!(nags & 4))  // no vote called? send no string
  68                 nags &= ~(BIT(6) | BIT(7));
  69
  70         WriteByte(MSG_ENTITY, nags);
  71
  72         if (nags & BIT(6))
  73         {
  74                 WriteByte(MSG_ENTITY, vote_accept_count);
  75                 WriteByte(MSG_ENTITY, vote_reject_count);
  76                 WriteByte(MSG_ENTITY, vote_needed_overall);
  77                 WriteChar(MSG_ENTITY, to.vote_selection);
  78         }
  79
  80         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  81
  82         if (nags & 1)
  83         {
  84                 for (i = 1; i <= maxclients; i += 8)
  85                 {
  86                         for (f = 0, e = edict_num(i), b = BIT(0); b < BIT(8); b <<= 1, e = nextent(e))
  87                                 if (!IS_REAL_CLIENT(e) || e.ready)
  88                                         f |= b;
  89                         WriteByte(MSG_ENTITY, f);
  90                 }
  91         }
  92
  93         return true;
  94 }
  95
  96 void Nagger_Init()
  97 {
  98         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
  99 }
 100
 101 void Nagger_VoteChanged()
 102 {
 103         if (nagger) nagger.SendFlags |= BIT(7);
 104 }
 105
 106 void Nagger_VoteCountChanged()
 107 {
 108         if (nagger) nagger.SendFlags |= BIT(6);
 109 }
 110
 111 void Nagger_ReadyCounted()
 112 {
 113         if (nagger) nagger.SendFlags |= BIT(0);
 114 }
 115
 116 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 117 string OriginalCallerName()
 118 {
 119         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller.netname, vote_caller.team, false);
 120         return vote_caller_name;
 121 }
 122
 123 // =======================
 124 //  Game logic for voting
 125 // =======================
 126
 127 void VoteReset()
 128 {
 129         FOREACH_CLIENT(true, { it.vote_selection = 0; });
 130
 131         if (vote_called)
 132         {
 133                 strfree(vote_called_command);
 134                 strfree(vote_called_display);
 135                 strfree(vote_caller_name);
 136         }
 137
 138         vote_called = VOTE_NULL;
 139         vote_caller = NULL;
 140         vote_endtime = 0;
 141
 142         vote_parsed_command = string_null;
 143         vote_parsed_display = string_null;
 144
 145         Nagger_VoteChanged();
 146 }
 147
 148 void VoteStop(entity stopper)
 149 {
 150         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 151         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 152         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 153         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 154         VoteReset();
 155 }
 156
 157 void VoteAccept()
 158 {
 159         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 160
 161         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 162         else localcmd(strcat(vote_called_command, "\n"));
 163
 164         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 165
 166         VoteReset();
 167         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 168 }
 169
 170 void VoteReject()
 171 {
 172         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 173         VoteReset();
 174         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 175 }
 176
 177 void VoteTimeout()
 178 {
 179         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 180         VoteReset();
 181         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 182 }
 183
 184 void VoteSpam(float notvoters, float mincount, string result)
 185 {
 186         bprint(strcat(
 187                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 188                 strcat("^2:^1", ftos(vote_reject_count)),
 189                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 190                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 191                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 192
 193         if (autocvar_sv_eventlog)
 194         {
 195                 GameLogEcho(strcat(
 196                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 197                         strcat(":", ftos(vote_reject_count)),
 198                         strcat(":", ftos(vote_abstain_count)),
 199                         strcat(":", ftos(notvoters)),
 200                         strcat(":", ftos(mincount))));
 201         }
 202 }
 203
 204 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
 205
 206 void VoteCount(float first_count)
 207 {
 208         // declarations
 209         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 210
 211         float vote_player_count = 0, notvoters = 0;
 212         float vote_real_player_count = 0, vote_real_accept_count = 0;
 213         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 214         float vote_needed_of_voted, final_needed_votes;
 215         float vote_factor_overall, vote_factor_of_voted;
 216
 217         Nagger_VoteCountChanged();
 218
 219         // add up all the votes from each connected client
 220         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), {
 221                 ++vote_player_count;
 222                 if (IS_PLAYER(it))   ++vote_real_player_count;
 223                 switch (it.vote_selection)
 224                 {
 225                         case VOTE_SELECT_REJECT:
 226                         { ++vote_reject_count;
 227                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 228                         }
 229                         case VOTE_SELECT_ACCEPT:
 230                         { ++vote_accept_count;
 231                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 232                         }
 233                         case VOTE_SELECT_ABSTAIN:
 234                         { ++vote_abstain_count;
 235                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 236                         }
 237                         default: break;
 238                 }
 239         });
 240
 241         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 242         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 243         {
 244                 if (vote_caller)   vote_caller.vote_waittime = 0;
 245                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 246                 VoteReset();
 247                 return;
 248         }
 249
 250         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 251         if (!spectators_allowed && (vote_real_player_count > 0))
 252         {
 253                 vote_accept_count = vote_real_accept_count;
 254                 vote_reject_count = vote_real_reject_count;
 255                 vote_abstain_count = vote_real_abstain_count;
 256                 vote_player_count = vote_real_player_count;
 257         }
 258
 259         // people who have no opinion in any way :D
 260         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 261
 262         // determine the goal for the vote to be passed or rejected normally
 263         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 264         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 265
 266         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 267         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 268         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 269
 270         // are there any players at all on the server? it could be an admin vote
 271         if (vote_player_count == 0 && first_count)
 272         {
 273                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 274                 VoteAccept();
 275                 return;
 276         }
 277
 278         // since there ARE players, finally calculate the result of the vote
 279         if (vote_accept_count >= vote_needed_overall)
 280         {
 281                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 282                 VoteAccept();
 283                 return;
 284         }
 285
 286         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 287         {
 288                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 289                 VoteReject();
 290                 return;
 291         }
 292
 293         // there is not enough votes in either direction, now lets just calculate what the voters have said
 294         if (time > vote_endtime)
 295         {
 296                 final_needed_votes = vote_needed_overall;
 297
 298                 if (autocvar_sv_vote_majority_factor_of_voted)
 299                 {
 300                         if (vote_accept_count >= vote_needed_of_voted)
 301                         {
 302                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 303                                 VoteAccept();
 304                                 return;
 305                         }
 306
 307                         if (vote_accept_count + vote_reject_count > 0)
 308                         {
 309                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 310                                 VoteReject();
 311                                 return;
 312                         }
 313
 314                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 315                 }
 316
 317                 // it didn't pass or fail, so not enough votes to even make a decision.
 318                 VoteSpam(notvoters, final_needed_votes, "timeout");
 319                 VoteTimeout();
 320         }
 321 }
 322
 323 void VoteThink()
 324 {
 325         if (vote_endtime > 0)        // a vote was called
 326         {
 327                 if (time > vote_endtime) // time is up
 328                         VoteCount(false);
 329         }
 330 }
 331
 332
 333 // =======================
 334 //  Game logic for warmup
 335 // =======================
 336
 337 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 338 void reset_map(bool dorespawn)
 339 {
 340         if (time <= game_starttime)
 341         {
 342                 if (game_stopped)
 343                         return;
 344                 if (round_handler_IsActive())
 345                         round_handler_Reset(game_starttime);
 346         }
 347
 348         if (shuffleteams_on_reset_map)
 349         {
 350                 shuffleteams();
 351                 shuffleteams_on_reset_map = false;
 352         }
 353
 354         FOREACH_CLIENT(IS_PLAYER(it),
 355         {
 356                 if (STAT(FROZEN, it))
 357                         Unfreeze(it, false);
 358                 player_powerups_remove_all(it);
 359                 entity store = PS(it);
 360                 if (store)
 361                 {
 362                         Inventory_clear(store.inventory);
 363                         Inventory_update(store);
 364                 }
 365         });
 366
 367         MUTATOR_CALLHOOK(reset_map_global);
 368
 369         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
 370         {
 371                 if(IS_CLIENT(it))
 372                         continue;
 373                 if (it.reset)
 374                 {
 375                         it.reset(it);
 376                         continue;
 377                 }
 378                 if (it.team_saved) it.team = it.team_saved;
 379                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 380         });
 381
 382         // Waypoints and assault start come LAST
 383         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 384                 if (it.reset2) it.reset2(it);
 385         });
 386
 387         // Moving the player reset code here since the player-reset depends
 388         // on spawnpoint entities which have to be reset first --blub
 389         if (dorespawn)
 390         {
 391                 if (!MUTATOR_CALLHOOK(reset_map_players))
 392                 {
 393                         FOREACH_CLIENT(IS_PLAYER(it),
 394                         {
 395                                 // PlayerScore_Clear(it);
 396                                 CS(it).killcount = 0;
 397                                 // stop the player from moving so that he stands still once he gets respawned
 398                                 it.velocity = '0 0 0';
 399                                 it.avelocity = '0 0 0';
 400                                 CS(it).movement = '0 0 0';
 401                                 PutClientInServer(it);
 402                         });
 403                 }
 404         }
 405 }
 406
 407 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 408 void ReadyRestart_think(entity this)
 409 {
 410         reset_map(true);
 411         Score_ClearAll();
 412         delete(this);
 413 }
 414
 415 // Forces a restart of the game without actually reloading the map // this is a mess...
 416 void ReadyRestart_force()
 417 {
 418         if (time <= game_starttime && game_stopped)
 419                 return;
 420
 421         bprint("^1Match is restarting...\n");
 422
 423         VoteReset();
 424
 425         // clear overtime, we have to decrease timelimit to its original value again.
 426         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 427                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 428         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 429
 430         if(warmup_stage)
 431                 game_starttime = time; // Warmup: No countdown in warmup
 432         else
 433                 game_starttime = time + RESTART_COUNTDOWN; // Go into match mode
 434
 435         // clear player attributes
 436         FOREACH_CLIENT(IS_PLAYER(it), {
 437                 it.alivetime = 0;
 438                 CS(it).killcount = 0;
 439                 float val = PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_ALIVETIME, 0);
 440                 PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_ALIVETIME, -val);
 441         });
 442
 443         // if we're ending the warmup stage call the corresponding hook
 444         if(!warmup_stage)
 445                 localcmd("\nsv_hook_warmupend\n");
 446
 447         // reset the .ready status of all players (also spectators)
 448         FOREACH_CLIENT(IS_REAL_CLIENT(it), { it.ready = false; });
 449         readycount = 0;
 450         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 451
 452         // lock teams with lockonrestart
 453         if (autocvar_teamplay_lockonrestart && teamplay)
 454                 lockteams = !warmup_stage;
 455
 456         // initiate the restart-countdown-announcer entity
 457         if (sv_ready_restart_after_countdown && !warmup_stage)
 458         {
 459                 entity restart_timer = new_pure(restart_timer);
 460                 setthink(restart_timer, ReadyRestart_think);
 461                 restart_timer.nextthink = game_starttime;
 462         }
 463
 464         // after a restart every players number of allowed timeouts gets reset, too
 465         if (autocvar_sv_timeout)
 466         {
 467                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
 468         }
 469
 470         if (!sv_ready_restart_after_countdown || warmup_stage) reset_map(true);
 471         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 472 }
 473
 474 void ReadyRestart(bool forceWarmupEnd)
 475 {
 476         if (MUTATOR_CALLHOOK(ReadyRestart_Deny) || intermission_running || race_completing) localcmd("restart\n");
 477         else localcmd("\nsv_hook_readyrestart\n");
 478
 479         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 480         // Otherwise scores could be manipulated during the countdown.
 481         if (!sv_ready_restart_after_countdown) Score_ClearAll();
 482
 483         if(forceWarmupEnd)
 484                 warmup_stage = 0; // forcefully end warmup and go to match stage
 485         else
 486                 warmup_stage = cvar("g_warmup"); // go into warmup if it's enabled, otherwise restart into match stage
 487
 488         ReadyRestart_force();
 489 }
 490
 491 // Count the players who are ready and determine whether or not to restart the match
 492 void ReadyCount()
 493 {
 494         float ready_needed_factor, ready_needed_count;
 495         float t_ready = 0, t_players = 0;
 496
 497         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || it.caplayer == 1), {
 498                 ++t_players;
 499                 if (it.ready) ++t_ready;
 500         });
 501
 502         readycount = t_ready;
 503
 504         Nagger_ReadyCounted();
 505
 506         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 507         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 508
 509         if (readycount >= ready_needed_count) ReadyRestart(true);
 510 }
 511
 512
 513 // ======================================
 514 //  Supporting functions for VoteCommand
 515 // ======================================
 516
 517 float Votecommand_check_assignment(entity caller, float assignment)
 518 {
 519         float from_server = (!caller);
 520
 521         if ((assignment == VC_ASGNMNT_BOTH)
 522             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 523             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 524
 525         return false;
 526 }
 527
 528 string VoteCommand_extractcommand(string input, float startpos, int argc)
 529 {
 530         string output;
 531
 532         if ((argc - 1) < startpos) output = "";
 533         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 534
 535         return output;
 536 }
 537
 538 float VoteCommand_checknasty(string vote_command)
 539 {
 540         if ((strstrofs(vote_command, ";", 0) >= 0)
 541             || (strstrofs(vote_command, "\n", 0) >= 0)
 542             || (strstrofs(vote_command, "\r", 0) >= 0)
 543             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 544
 545         return true;
 546 }
 547
 548 // NOTE: requires input to be surrounded by spaces
 549 string VoteCommand_checkreplacements(string input)
 550 {
 551         string output = input;
 552         // allow gotomap replacements
 553         output = strreplace(" map ", " gotomap ", output);
 554         output = strreplace(" chmap ", " gotomap ", output);
 555         return output;
 556 }
 557
 558 float VoteCommand_checkinlist(string vote_command, string list)
 559 {
 560         string l = VoteCommand_checkreplacements(strcat(" ", list, " "));
 561
 562         if (strstrofs(l, VoteCommand_checkreplacements(strcat(" ", vote_command, " ")), 0) >= 0) return true;
 563
 564         return false;
 565 }
 566
 567 string ValidateMap(string validated_map, entity caller)
 568 {
 569         validated_map = MapInfo_FixName(validated_map);
 570
 571         if (!validated_map)
 572         {
 573                 print_to(caller, "This map is not available on this server.");
 574                 return string_null;
 575         }
 576
 577         if (!autocvar_sv_vote_override_mostrecent && caller)
 578         {
 579                 if (Map_IsRecent(validated_map))
 580                 {
 581                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 582                         return string_null;
 583                 }
 584         }
 585
 586         if (!MapInfo_CheckMap(validated_map))
 587         {
 588                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 589                 return string_null;
 590         }
 591
 592         return validated_map;
 593 }
 594
 595 float VoteCommand_checkargs(float startpos, int argc)
 596 {
 597         float p, q, check, minargs;
 598         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 599         string cmdrestriction = "";  // No we don't.
 600         string charlist, arg;
 601         float checkmate;
 602
 603         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 604                 cmdrestriction = cvar_string(cvarname);
 605         else
 606                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 607
 608         if (cmdrestriction == "") return true;
 609
 610         ++startpos;  // skip command name
 611
 612         // check minimum arg count
 613
 614         // 0 args: argc == startpos
 615         // 1 args: argc == startpos + 1
 616         // ...
 617
 618         minargs = stof(cmdrestriction);
 619         if (argc - startpos < minargs) return false;
 620
 621         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 622
 623         for ( ; ; )
 624         {
 625                 // we know that at any time, startpos <= argc - minargs
 626                 // so this means: argc-minargs >= startpos >= argc, thus
 627                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 628                 // have been seen already
 629
 630                 if (startpos >= argc) // all args checked? GOOD
 631                         break;
 632
 633                 if (p < 0)            // no more args? FAIL
 634                 {
 635                         // exception: exactly minargs left, this one included
 636                         if (argc - startpos == minargs) break;
 637
 638                         // otherwise fail
 639                         return false;
 640                 }
 641
 642                 // cut to next semicolon
 643                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 644                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 645                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 646
 647                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 648                 // charlist = strreplace("^^", ";", charlist);
 649
 650                 if (charlist != "")
 651                 {
 652                         // verify the arg only contains allowed chars
 653                         arg = argv(startpos);
 654                         checkmate = strlen(arg);
 655                         for (check = 0; check < checkmate; ++check)
 656                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 657                         // not allowed character
 658                         // all characters are allowed. FINE.
 659                 }
 660
 661                 ++startpos;
 662                 --minargs;
 663                 p = q;
 664         }
 665
 666         return true;
 667 }
 668
 669 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, int argc)
 670 {
 671         string first_command = argv(startpos);
 672         int missing_chars = argv_start_index(startpos);
 673
 674         if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
 675                 return 0;
 676
 677         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
 678
 679         if (!VoteCommand_checkargs(startpos, argc)) return 0;
 680
 681         switch (MUTATOR_CALLHOOK(VoteCommand_Parse, caller, first_command, vote_command, startpos, argc))
 682         {
 683                 case MUT_VOTEPARSE_CONTINUE: { break; }
 684                 case MUT_VOTEPARSE_SUCCESS: { return 1; }
 685                 case MUT_VOTEPARSE_INVALID: { return -1; }
 686                 case MUT_VOTEPARSE_UNACCEPTABLE: { return 0; }
 687         }
 688
 689         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 690         {
 691                 case "kick":
 692                 case "kickban":    // catch all kick/kickban commands
 693                 {
 694                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 695                         float accepted = VerifyClientEntity(victim, true, false);
 696
 697                         if (accepted > 0)
 698                         {
 699                                 string reason = "No reason provided";
 700                                 if(argc > next_token)
 701                                         reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
 702
 703                                 string command_arguments = reason;
 704                                 if (first_command == "kickban")
 705                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 706
 707                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 708                                 vote_parsed_display = sprintf("^1%s #%d ^7%s^1 %s", first_command, etof(victim), victim.netname, reason);
 709                         }
 710                         else
 711                         {
 712                                 print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n"));
 713                                 return 0;
 714                         }
 715
 716                         break;
 717                 }
 718
 719                 case "map":
 720                 case "chmap":
 721                 case "gotomap":  // re-direct all map selection commands to gotomap
 722                 {
 723                         vote_command = ValidateMap(argv(startpos + 1), caller);
 724                         if (!vote_command)  return -1;
 725                         vote_parsed_command = strcat("gotomap ", vote_command);
 726                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 727
 728                         break;
 729                 }
 730
 731                 // TODO: replicate the old behaviour of being able to vote for maps from different modes on multimode servers (possibly support it in gotomap too)
 732                 // maybe fallback instead of aborting if map name is invalid?
 733                 case "nextmap":
 734                 {
 735                         vote_command = ValidateMap(argv(startpos + 1), caller);
 736                         if (!vote_command)  return -1;
 737                         vote_parsed_command = strcat("nextmap ", vote_command);
 738                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 739
 740                         break;
 741                 }
 742
 743                 case "timelimit": // include restrictions on the maximum votable time limit
 744                 {
 745                         float timelimit_vote = stof(argv(startpos + 1));
 746                         if(timelimit_vote > autocvar_timelimit_max || timelimit_vote < autocvar_timelimit_min)
 747                         {
 748                                 print_to(caller, strcat("Invalid timelimit vote, accepted values are between ", ftos(autocvar_timelimit_min), " and ", ftos(autocvar_timelimit_max), "."));
 749                                 return -1;
 750                         }
 751                         timelimit_vote = bound(autocvar_timelimit_min, timelimit_vote, autocvar_timelimit_max);
 752                         vote_parsed_command = strcat("timelimit ", ftos(timelimit_vote));
 753                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 754
 755                         break;
 756                 }
 757
 758                 case "restart":
 759                 {
 760                         // add a delay so that vote result can be seen and announcer can be heard
 761                         // if the vote is accepted
 762                         vote_parsed_command = strcat("defer 1 ", vote_command);
 763                         vote_parsed_display = strzone(strcat("^1", vote_command));
 764
 765                         break;
 766                 }
 767
 768                 case "allready":
 769                 {
 770                         if(!warmup_stage) {
 771                                 print_to(caller, "Game already started. Use the resetmatch command to restart the match.");
 772                                 return -1;
 773                         }
 774
 775                         vote_parsed_command = vote_command;
 776                         vote_parsed_display = strzone(strcat("^1", vote_command));
 777                         break;
 778                 }
 779
 780                 default:
 781                 {
 782                         vote_parsed_command = vote_command;
 783                         vote_parsed_display = strzone(strcat("^1", vote_command));
 784
 785                         break;
 786                 }
 787         }
 788
 789         return 1;
 790 }
 791
 792
 793 // =======================
 794 //  Command Sub-Functions
 795 // =======================
 796
 797 void VoteCommand_abstain(int request, entity caller)  // CLIENT ONLY
 798 {
 799         switch (request)
 800         {
 801                 case CMD_REQUEST_COMMAND:
 802                 {
 803                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 804                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 805                         {
 806                                 print_to(caller, "^1You have already voted.");
 807                         }
 808
 809                         else  // everything went okay, continue changing vote
 810                         {
 811                                 print_to(caller, "^1You abstained from your vote.");
 812                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 813                                 msg_entity = caller;
 814                                 if (!autocvar_sv_vote_singlecount)
 815                                         VoteCount(false);
 816                         }
 817
 818                         return;
 819                 }
 820
 821                 default:
 822                 case CMD_REQUEST_USAGE:
 823                 {
 824                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 825                         print_to(caller, "  No arguments required.");
 826                         return;
 827                 }
 828         }
 829 }
 830
 831 void print_available_commands_to(entity caller)
 832 {
 833         print_to(caller, strcat("You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
 834 }
 835
 836 void VoteCommand_call(int request, entity caller, int argc, string vote_command)  // BOTH
 837 {
 838         switch (request)
 839         {
 840                 case CMD_REQUEST_COMMAND:
 841                 {
 842                         float tmp_playercount = 0;
 843                         int parse_error;
 844
 845                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 846
 847                         if (!autocvar_sv_vote_call && caller)
 848                         {
 849                                 print_to(caller, "^1Vote calling is not allowed.");
 850                         }
 851                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 852                         {
 853                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 854                         }
 855                         else if (vote_called)
 856                         {
 857                                 print_to(caller, "^1There is already a vote called.");
 858                         }
 859                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 860                         {
 861                                 print_to(caller, "^1Only players can call a vote.");
 862                         }
 863                         else if (caller && !IS_CLIENT(caller))
 864                         {
 865                                 print_to(caller, "^1Only connected clients can vote.");
 866                         }
 867                         else if (timeout_status && vote_command != "timein")
 868                         {
 869                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 870                         }
 871                         else if (caller && (time < caller.vote_waittime))
 872                         {
 873                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 874                         }
 875                         else if (!VoteCommand_checknasty(vote_command))
 876                         {
 877                                 print_to(caller, "^1Syntax error in command.");
 878                         }
 879                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
 880                         {
 881                                 if(parse_error == 0)
 882                                 {
 883                                         if (vote_called_command == "")
 884                                                 VoteCommand_call(CMD_REQUEST_USAGE, caller, argc, vote_command);
 885                                         else
 886                                                 print_to(caller, "^1This command is not acceptable or not available.");
 887                                 }
 888                         }
 889                         else  // everything went okay, continue with calling the vote
 890                         {
 891                                 vote_caller = caller;  // remember who called the vote
 892                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 893                                 vote_called = VOTE_NORMAL;
 894                                 vote_called_command = strzone(vote_parsed_command);
 895                                 vote_called_display = strzone(vote_parsed_display);
 896                                 vote_endtime = time + autocvar_sv_vote_timeout;
 897
 898                                 if (caller)
 899                                 {
 900                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 901                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 902                                         msg_entity = caller;
 903                                 }
 904
 905                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
 906
 907                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 908                                 if (autocvar_sv_eventlog)
 909                                         GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 910                                 Nagger_VoteChanged();
 911                                 VoteCount(true);  // needed if you are the only one
 912
 913                                 if (tmp_playercount > 1 && vote_called != VOTE_NULL)
 914                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
 915                         }
 916
 917                         return;
 918                 }
 919
 920                 default:
 921                 case CMD_REQUEST_USAGE:
 922                 {
 923                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call <command>"));
 924                         print_to(caller, "  Where <command> is the command to request a vote upon.");
 925                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 926                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 927                         print_available_commands_to(caller);
 928                         print_to(caller, "Shortcuts: ^2vcall <command>, vend, vmap, vkick, ...");
 929                         return;
 930                 }
 931         }
 932 }
 933
 934 void VoteCommand_master(int request, entity caller, int argc, string vote_command)  // CLIENT ONLY
 935 {
 936         switch (request)
 937         {
 938                 case CMD_REQUEST_COMMAND:
 939                 {
 940                         if (autocvar_sv_vote_master)
 941                         {
 942                                 switch (strtolower(argv(2)))
 943                                 {
 944                                         case "do":
 945                                         {
 946                                                 int parse_error;
 947                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 948
 949                                                 if (!caller.vote_master)
 950                                                         print_to(caller, "^1You do not have vote master privileges.");
 951                                                 else if (!VoteCommand_checknasty(vote_command))
 952                                                 {
 953                                                         print_to(caller, "^1Syntax error in command.");
 954                                                 }
 955                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
 956                                                 {
 957                                                         if(parse_error == 0)
 958                                                         {
 959                                                                 if (vote_called_command == "")
 960                                                                         VoteCommand_master(CMD_REQUEST_USAGE, caller, argc, vote_command);
 961                                                                 else
 962                                                                         print_to(caller, "^1This command is not acceptable or not available.");
 963                                                         }
 964                                                 }
 965                                                 else  // everything went okay, proceed with command
 966                                                 {
 967                                                         localcmd(strcat(vote_parsed_command, "\n"));
 968                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 969                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 970                                                         if (autocvar_sv_eventlog)
 971                                                                 GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display));
 972                                                 }
 973
 974                                                 return;
 975                                         }
 976
 977                                         case "login":
 978                                         {
 979                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 980                                                 else if (caller.vote_master)
 981                                                 {
 982                                                         print_to(caller, "^1You are already logged in as vote master.");
 983                                                 }
 984                                                 else if (autocvar_sv_vote_master_password != argv(3))
 985                                                 {
 986                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
 987                                                 }
 988                                                 else  // everything went okay, proceed with giving this player master privilages
 989                                                 {
 990                                                         caller.vote_master = true;
 991                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 992                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 993                                                         if (autocvar_sv_eventlog)
 994                                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid)));
 995                                                 }
 996
 997                                                 return;
 998                                         }
 999
1000                                         default:  // calling a vote for master
1001                                         {
1002                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
1003                                                 else if (vote_called)
1004                                                 {
1005                                                         print_to(caller, "^1There is already a vote called.");
1006                                                 }
1007                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
1008                                                 {
1009                                                         print_to(caller, "^1Only players can call a vote.");
1010                                                 }
1011                                                 else if (timeout_status)
1012                                                 {
1013                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
1014                                                 }
1015                                                 else  // everything went okay, continue with creating vote
1016                                                 {
1017                                                         vote_caller = caller;
1018                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
1019                                                         vote_called = VOTE_MASTER;
1020                                                         vote_called_command = strzone("XXX");
1021                                                         vote_called_display = strzone("^3master");
1022                                                         vote_endtime = time + autocvar_sv_vote_timeout;
1023
1024                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
1025                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
1026
1027                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
1028                                                         if (autocvar_sv_eventlog)
1029                                                                 GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
1030                                                         Nagger_VoteChanged();
1031                                                         VoteCount(true);  // needed if you are the only one
1032                                                 }
1033
1034                                                 return;
1035                                         }
1036                                 }
1037                         }
1038                         else { print_to(caller, "^1Master control of voting is not allowed."); }
1039
1040                         return;
1041                 }
1042
1043                 default:
1044                 case CMD_REQUEST_USAGE:
1045                 {
1046                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [<action> [<command> | <password>]]"));
1047                         print_to(caller, "  If <action> is left blank, it calls a vote for you to become master.");
1048                         print_to(caller, "  Otherwise it can be either 'do' (to run <command>) or 'login' as master.");
1049                         return;
1050                 }
1051         }
1052 }
1053
1054 void VoteCommand_no(int request, entity caller)  // CLIENT ONLY
1055 {
1056         switch (request)
1057         {
1058                 case CMD_REQUEST_COMMAND:
1059                 {
1060                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1061                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1062                         {
1063                                 print_to(caller, "^1You have already voted.");
1064                         }
1065                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1066                         {
1067                                 VoteStop(caller);
1068                         }
1069
1070                         else  // everything went okay, continue changing vote
1071                         {
1072                                 print_to(caller, "^1You rejected the vote.");
1073                                 caller.vote_selection = VOTE_SELECT_REJECT;
1074                                 msg_entity = caller;
1075                                 if (!autocvar_sv_vote_singlecount)
1076                                         VoteCount(false);
1077                         }
1078
1079                         return;
1080                 }
1081
1082                 default:
1083                 case CMD_REQUEST_USAGE:
1084                 {
1085                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1086                         print_to(caller, "  No arguments required.");
1087                         return;
1088                 }
1089         }
1090 }
1091
1092 void VoteCommand_status(int request, entity caller)  // BOTH
1093 {
1094         switch (request)
1095         {
1096                 case CMD_REQUEST_COMMAND:
1097                 {
1098                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1099                         else print_to(caller, "^1No vote called.");
1100
1101                         return;
1102                 }
1103
1104                 default:
1105                 case CMD_REQUEST_USAGE:
1106                 {
1107                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1108                         print_to(caller, "  No arguments required.");
1109                         return;
1110                 }
1111         }
1112 }
1113
1114 void VoteCommand_stop(int request, entity caller)  // BOTH
1115 {
1116         switch (request)
1117         {
1118                 case CMD_REQUEST_COMMAND:
1119                 {
1120                         if (!vote_called)   print_to(caller, "^1No vote called.");
1121                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1122                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1123                         return;
1124                 }
1125
1126                 default:
1127                 case CMD_REQUEST_USAGE:
1128                 {
1129                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1130                         print_to(caller, "  No arguments required.");
1131                         return;
1132                 }
1133         }
1134 }
1135
1136 void VoteCommand_yes(int request, entity caller)  // CLIENT ONLY
1137 {
1138         switch (request)
1139         {
1140                 case CMD_REQUEST_COMMAND:
1141                 {
1142                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1143                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1144                         {
1145                                 print_to(caller, "^1You have already voted.");
1146                         }
1147                         else  // everything went okay, continue changing vote
1148                         {
1149                                 print_to(caller, "^1You accepted the vote.");
1150                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1151                                 msg_entity = caller;
1152                                 if (!autocvar_sv_vote_singlecount)
1153                                         VoteCount(false);
1154                         }
1155
1156                         return;
1157                 }
1158
1159                 default:
1160                 case CMD_REQUEST_USAGE:
1161                 {
1162                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1163                         print_to(caller, "  No arguments required.");
1164                         return;
1165                 }
1166         }
1167 }
1168
1169 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1170 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1171 void VoteCommand_(int request)
1172 {
1173     switch(request)
1174     {
1175         case CMD_REQUEST_COMMAND:
1176         {
1177
1178             return;
1179         }
1180
1181         default:
1182         case CMD_REQUEST_USAGE:
1183         {
1184             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1185             print_to(caller, "  No arguments required.");
1186             return;
1187         }
1188     }
1189 }
1190 */
1191
1192
1193 // ================================
1194 //  Macro system for vote commands
1195 // ================================
1196
1197 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1198 #define VOTE_COMMANDS(request, caller, arguments, command) \
1199         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1200         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1201         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1202         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1203         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1204         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1205         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1206         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1207         /* nothing */
1208
1209 void VoteCommand_macro_help(entity caller, int argc)
1210 {
1211         string command_origin = GetCommandPrefix(caller);
1212
1213         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1214         {
1215                 print_to(caller, "\nVoting commands:\n");
1216                 #define VOTE_COMMAND(name, function, description, assignment) \
1217                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1218
1219                 VOTE_COMMANDS(0, caller, 0, "");
1220                 #undef VOTE_COMMAND
1221
1222                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote <command>^7, where possible commands are listed above.\n"));
1223                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help <command>"));
1224                 print_available_commands_to(caller);
1225         }
1226         else  // usage for individual command
1227         {
1228                 #define VOTE_COMMAND(name, function, description, assignment) \
1229                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1230
1231                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1232                 #undef VOTE_COMMAND
1233
1234                 string cvarname = strcat("sv_vote_command_help_", argv(2));
1235                 if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
1236                         wordwrap_sprint(caller, cvar_string(cvarname), 1000);
1237                 else if (argv(2) != "")
1238                         print_to(caller, "No documentation exists for this vote");
1239         }
1240 }
1241
1242 float VoteCommand_macro_command(entity caller, int argc, string vote_command)
1243 {
1244         #define VOTE_COMMAND(name, function, description, assignment) \
1245                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1246
1247         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1248         #undef VOTE_COMMAND
1249
1250         return false;
1251 }
1252
1253
1254 // ======================================
1255 //  Main function handling vote commands
1256 // ======================================
1257
1258 void VoteCommand(int request, entity caller, int argc, string vote_command)
1259 {
1260         // Guide for working with argc arguments by example:
1261         // argc:   1    - 2      - 3     - 4
1262         // argv:   0    - 1      - 2     - 3
1263         // cmd     vote - master - login - password
1264
1265         switch (request)
1266         {
1267                 case CMD_REQUEST_COMMAND:
1268                 {
1269                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1270                 }
1271
1272                 default:
1273                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1274                 case CMD_REQUEST_USAGE:
1275                 {
1276                         VoteCommand_macro_help(caller, argc);
1277                         return;
1278                 }
1279         }
1280 }