qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/items/inventory.qh>
   7 #include <common/mapinfo.qh>
   8 #include <common/net_linked.qh>
   9 #include <common/notifications/all.qh>
  10 #include <common/playerstats.qh>
  11 #include <common/stats.qh>
  12 #include <common/util.qh>
  13 #include <common/weapons/_all.qh>
  14 #include <server/campaign.qh>
  15 #include <server/client.qh>
  16 #include <server/command/banning.qh>
  17 #include <server/command/common.qh>
  18 #include <server/command/vote.qh>
  19 #include <server/damage.qh>
  20 #include <server/gamelog.qh>
  21 #include <server/intermission.qh>
  22 #include <server/mutators/_mod.qh>
  23 #include <server/race.qh>
  24 #include <server/round_handler.qh>
  25 #include <server/scores.qh>
  26 #include <server/teamplay.qh>
  27 #include <server/weapons/accuracy.qh>
  28 #include <server/world.qh>
  29
  30 // =============================================
  31 //  Server side voting code, reworked by Samual
  32 //  Last updated: December 27th, 2011
  33 // =============================================
  34
  35 //  Nagger for players to know status of voting
  36 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  37 {
  38         int nags = 0;
  39         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  40
  41         // bits:
  42         //   1 = ready
  43         //   2 = player needs to ready up
  44         //   4 = vote
  45         //   8 = player needs to vote
  46         //  16 = warmup
  47         // sendflags:
  48         //  64 = vote counts
  49         // 128 = vote string
  50
  51         if (warmup_stage)
  52         {
  53                 if (readycount)
  54                 {
  55                         nags |= BIT(0);
  56                         if (!to.ready) nags |= BIT(1);
  57                 }
  58                 nags |= BIT(4);
  59         }
  60
  61         if (vote_called)
  62         {
  63                 nags |= BIT(2);
  64                 if (to.vote_selection == 0) nags |= BIT(3);
  65                 nags |= sendflags & BIT(6);
  66                 nags |= sendflags & BIT(7);
  67         }
  68
  69         WriteByte(MSG_ENTITY, nags);
  70
  71         if (nags & BIT(6))
  72         {
  73                 WriteByte(MSG_ENTITY, vote_accept_count);
  74                 WriteByte(MSG_ENTITY, vote_reject_count);
  75                 WriteByte(MSG_ENTITY, vote_needed_overall);
  76                 WriteChar(MSG_ENTITY, to.vote_selection);
  77         }
  78
  79         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  80
  81         if (nags & BIT(0))
  82         {
  83                 for (int i = 1; i <= maxclients;)
  84                 {
  85                         int f = 0;
  86                         for (int b = 0; b < 8 && i <= maxclients; ++b, ++i)
  87                                 if (edict_num(i).ready)
  88                                         f |= BIT(b);
  89                         WriteByte(MSG_ENTITY, f);
  90                 }
  91         }
  92
  93         return true;
  94 }
  95
  96 void Nagger_Init()
  97 {
  98         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
  99 }
 100
 101 void Nagger_VoteChanged()
 102 {
 103         if (nagger) nagger.SendFlags |= BIT(7);
 104 }
 105
 106 void Nagger_VoteCountChanged()
 107 {
 108         if (nagger) nagger.SendFlags |= BIT(6);
 109 }
 110
 111 void Nagger_ReadyCounted()
 112 {
 113         if (nagger) nagger.SendFlags |= BIT(0);
 114 }
 115
 116 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 117 string OriginalCallerName()
 118 {
 119         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller.netname, vote_caller.team, false);
 120         return vote_caller_name;
 121 }
 122
 123 // =======================
 124 //  Game logic for voting
 125 // =======================
 126
 127 void VoteReset()
 128 {
 129         FOREACH_CLIENT(true, { it.vote_selection = 0; });
 130
 131         if (vote_called)
 132         {
 133                 strfree(vote_called_command);
 134                 strfree(vote_called_display);
 135                 strfree(vote_caller_name);
 136         }
 137
 138         vote_called = VOTE_NULL;
 139         vote_caller = NULL;
 140         vote_endtime = 0;
 141
 142         vote_parsed_command = string_null;
 143         vote_parsed_display = string_null;
 144
 145         Nagger_VoteChanged();
 146 }
 147
 148 void VoteStop(entity stopper)
 149 {
 150         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 151         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 152         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 153         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 154         VoteReset();
 155 }
 156
 157 void VoteAccept()
 158 {
 159         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 160
 161         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = true;
 162         else localcmd(strcat(vote_called_command, "\n"));
 163
 164         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 165
 166         VoteReset();
 167         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 168 }
 169
 170 void VoteReject()
 171 {
 172         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 173         VoteReset();
 174         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 175 }
 176
 177 void VoteTimeout()
 178 {
 179         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 180         VoteReset();
 181         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 182 }
 183
 184 void VoteSpam(float notvoters, float mincount, string result)
 185 {
 186         bprint(strcat(
 187                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 188                 strcat("^2:^1", ftos(vote_reject_count)),
 189                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 190                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 191                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 192
 193         if (autocvar_sv_eventlog)
 194         {
 195                 GameLogEcho(strcat(
 196                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 197                         strcat(":", ftos(vote_reject_count)),
 198                         strcat(":", ftos(vote_abstain_count)),
 199                         strcat(":", ftos(notvoters)),
 200                         strcat(":", ftos(mincount))));
 201         }
 202 }
 203
 204 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
 205
 206 void VoteCount(float first_count)
 207 {
 208         // declarations
 209         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 210
 211         float vote_player_count = 0, notvoters = 0;
 212         float vote_real_player_count = 0, vote_real_accept_count = 0;
 213         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 214         float vote_needed_of_voted, final_needed_votes;
 215         float vote_factor_overall, vote_factor_of_voted;
 216
 217         Nagger_VoteCountChanged();
 218
 219         // add up all the votes from each connected client
 220         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), {
 221                 ++vote_player_count;
 222                 if (IS_PLAYER(it))   ++vote_real_player_count;
 223                 switch (it.vote_selection)
 224                 {
 225                         case VOTE_SELECT_REJECT:
 226                         { ++vote_reject_count;
 227                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 228                         }
 229                         case VOTE_SELECT_ACCEPT:
 230                         { ++vote_accept_count;
 231                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 232                         }
 233                         case VOTE_SELECT_ABSTAIN:
 234                         { ++vote_abstain_count;
 235                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 236                         }
 237                         default: break;
 238                 }
 239         });
 240
 241         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 242         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 243         {
 244                 if (vote_caller)   vote_caller.vote_waittime = 0;
 245                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 246                 VoteReset();
 247                 return;
 248         }
 249
 250         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 251         if (!spectators_allowed && (vote_real_player_count > 0))
 252         {
 253                 vote_accept_count = vote_real_accept_count;
 254                 vote_reject_count = vote_real_reject_count;
 255                 vote_abstain_count = vote_real_abstain_count;
 256                 vote_player_count = vote_real_player_count;
 257         }
 258
 259         // people who have no opinion in any way :D
 260         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 261
 262         // determine the goal for the vote to be passed or rejected normally
 263         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 264         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 265
 266         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 267         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 268         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 269
 270         // are there any players at all on the server? it could be an admin vote
 271         if (vote_player_count == 0 && first_count)
 272         {
 273                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 274                 VoteAccept();
 275                 return;
 276         }
 277
 278         // since there ARE players, finally calculate the result of the vote
 279         if (vote_accept_count >= vote_needed_overall)
 280         {
 281                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 282                 VoteAccept();
 283                 return;
 284         }
 285
 286         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 287         {
 288                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 289                 VoteReject();
 290                 return;
 291         }
 292
 293         // there is not enough votes in either direction, now lets just calculate what the voters have said
 294         if (time > vote_endtime)
 295         {
 296                 final_needed_votes = vote_needed_overall;
 297
 298                 if (autocvar_sv_vote_majority_factor_of_voted)
 299                 {
 300                         if (vote_accept_count >= vote_needed_of_voted)
 301                         {
 302                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 303                                 VoteAccept();
 304                                 return;
 305                         }
 306
 307                         if (vote_accept_count + vote_reject_count > 0)
 308                         {
 309                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 310                                 VoteReject();
 311                                 return;
 312                         }
 313
 314                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 315                 }
 316
 317                 // it didn't pass or fail, so not enough votes to even make a decision.
 318                 VoteSpam(notvoters, final_needed_votes, "timeout");
 319                 VoteTimeout();
 320         }
 321 }
 322
 323 void VoteThink()
 324 {
 325         if (vote_endtime > 0)        // a vote was called
 326         {
 327                 if (time > vote_endtime) // time is up
 328                         VoteCount(false);
 329         }
 330 }
 331
 332
 333 // =======================
 334 //  Game logic for warmup
 335 // =======================
 336
 337 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 338 void reset_map(bool dorespawn, bool is_fake_round_start)
 339 {
 340         if (time <= game_starttime)
 341         {
 342                 if (game_stopped)
 343                         return;
 344
 345                 if (!is_fake_round_start)
 346                 {
 347                         Score_ClearAll();
 348                         PlayerStats_GameReport_Reset_All();
 349                 }
 350
 351                 if (round_handler_IsActive())
 352                         round_handler_Reset(game_starttime);
 353         }
 354
 355         if (shuffleteams_on_reset_map)
 356         {
 357                 shuffleteams();
 358                 shuffleteams_on_reset_map = false;
 359         }
 360
 361         FOREACH_CLIENT(true, {
 362                 if (time <= game_starttime)
 363                         accuracy_reset(it); // for spectators too because weapon accuracy is persistent
 364                 if (!IS_PLAYER(it))
 365                         continue;
 366                 if (STAT(FROZEN, it))
 367                         Unfreeze(it, false);
 368                 player_powerups_remove_all(it);
 369                 entity store = PS(it);
 370                 if (store)
 371                 {
 372                         Inventory_clear(store.inventory);
 373                         Inventory_update(store);
 374                 }
 375         });
 376
 377         MUTATOR_CALLHOOK(reset_map_global);
 378
 379         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
 380         {
 381                 if(IS_CLIENT(it))
 382                         continue;
 383                 if (it.reset)
 384                 {
 385                         it.reset(it);
 386                         continue;
 387                 }
 388                 if (it.team_saved) it.team = it.team_saved;
 389                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 390         });
 391
 392         // Waypoints and assault start come LAST
 393         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 394                 if (it.reset2) it.reset2(it);
 395         });
 396
 397         // Moving the player reset code here since the player-reset depends
 398         // on spawnpoint entities which have to be reset first --blub
 399         if (dorespawn)
 400         {
 401                 if (!MUTATOR_CALLHOOK(reset_map_players))
 402                 {
 403                         FOREACH_CLIENT(IS_PLAYER(it),
 404                         {
 405                                 // PlayerScore_Clear(it);
 406                                 CS(it).killcount = 0;
 407                                 // stop the player from moving so that he stands still once he gets respawned
 408                                 it.velocity = '0 0 0';
 409                                 it.avelocity = '0 0 0';
 410                                 CS(it).movement = '0 0 0';
 411                                 PutClientInServer(it);
 412                         });
 413                 }
 414         }
 415 }
 416
 417 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 418 void ReadyRestart_think(entity this)
 419 {
 420         if (!warmup_stage) // if the countdown was not aborted
 421                 reset_map(true, false);
 422         delete(this);
 423 }
 424
 425 // Forces a restart of the game without actually reloading the map // this is a mess...
 426 void ReadyRestart_force(bool is_fake_round_start)
 427 {
 428         if (time <= game_starttime && game_stopped)
 429                 return;
 430         if (!is_fake_round_start && !autocvar_g_campaign)
 431                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_COUNTDOWN_RESTART);
 432
 433         VoteReset();
 434
 435         // clear overtime, we have to decrease timelimit to its original value again.
 436         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 437                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 438         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = overtimes = 0;
 439
 440         if(warmup_stage)
 441                 game_starttime = time; // Warmup: No countdown in warmup
 442         else if (autocvar_g_campaign)
 443                 game_starttime = time + 3;
 444         else
 445                 game_starttime = time + RESTART_COUNTDOWN; // Go into match mode
 446
 447         // clear player attributes
 448         FOREACH_CLIENT(IS_PLAYER(it), {
 449                 it.alivetime = 0;
 450                 CS(it).killcount = 0;
 451         });
 452
 453         // if we're ending the warmup stage call the corresponding hook
 454         if(!is_fake_round_start && !warmup_stage)
 455                 localcmd("\nsv_hook_warmupend\n");
 456
 457         // reset the .ready status of all clients (including spectators and bots)
 458         FOREACH_CLIENT(true, { it.ready = false; });
 459         readycount = 0;
 460         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 461
 462         // lock teams with lockonrestart
 463         if (autocvar_teamplay_lockonrestart && teamplay)
 464                 lockteams = !warmup_stage;
 465
 466         // initiate the restart-countdown-announcer entity
 467         if (!is_fake_round_start && sv_ready_restart_after_countdown && !warmup_stage)
 468         {
 469                 entity restart_timer = new_pure(restart_timer);
 470                 setthink(restart_timer, ReadyRestart_think);
 471                 restart_timer.nextthink = game_starttime;
 472         }
 473
 474         // after a restart every players number of allowed timeouts gets reset, too
 475         if (autocvar_sv_timeout)
 476         {
 477                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
 478         }
 479
 480         if (!sv_ready_restart_after_countdown || warmup_stage)
 481                 reset_map(true, is_fake_round_start);
 482
 483         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 484 }
 485
 486 void ReadyRestart(bool forceWarmupEnd)
 487 {
 488         if (MUTATOR_CALLHOOK(ReadyRestart_Deny) || intermission_running || race_completing)
 489         {
 490                 // NOTE: ReadyRestart support is mandatory in campaign
 491                 if (autocvar_g_campaign)
 492                         error("ReadyRestart must be supported in campaign mode!");
 493                 localcmd("restart\n"); // if ReadyRestart is denied, restart the server
 494         }
 495         else localcmd("\nsv_hook_readyrestart\n");
 496
 497         if(forceWarmupEnd || autocvar_g_campaign)
 498                 warmup_stage = 0; // forcefully end warmup and go to match stage
 499         else
 500                 warmup_stage = autocvar_g_warmup; // go into warmup if it's enabled, otherwise restart into match stage
 501
 502         ReadyRestart_force(false);
 503 }
 504
 505 /* Count the players who are ready and determine whether or not to restart the match when:
 506  * a player presses F4                      server/command/cmd.qc  ClientCommand_ready()
 507  * a player switches from players to specs  server/client.qc       PutObserverInServer()
 508  * a player joins (from specs or directly)  server/client.qc       PutPlayerInServer()
 509  * a player disconnects                     server/client.qc       ClientDisconnect()   */
 510 void ReadyCount()
 511 {
 512         // cannot reset the game while a timeout is active or pending
 513         if (timeout_status) return;
 514
 515         int total_players = 0, human_players = 0, humans_ready = 0;
 516         readycount = 0;
 517
 518         FOREACH_CLIENT(IS_PLAYER(it) || INGAME_JOINED(it), {
 519                 ++total_players;
 520                 if (it.ready) ++readycount;
 521                 if (IS_REAL_CLIENT(it))
 522                 {
 523                         ++human_players;
 524                         if (it.ready) ++humans_ready;
 525                 }
 526         });
 527
 528         Nagger_ReadyCounted();
 529
 530         // can't read warmup_stage here as it could have been set to 0 by ReadyRestart()
 531         // and we need to use this when checking if we should abort the countdown
 532         // map_minplayers can only be > 0 if g_warmup was -1 at worldspawn
 533         int minplayers = autocvar_g_warmup > 1 ? autocvar_g_warmup : map_minplayers;
 534
 535         if (total_players < minplayers)
 536         {
 537                 if (game_starttime > time) // someone bailed during countdown, back to warmup
 538                 {
 539                         warmup_stage = autocvar_g_warmup; // CAN change it AFTER calling Nagger_ReadyCounted() this frame
 540                         game_starttime = time;
 541                         Send_Notification(NOTIF_ALL, NULL, MSG_MULTI, COUNTDOWN_STOP, minplayers);
 542                         if (!sv_ready_restart_after_countdown) // if we ran reset_map() at start of countdown
 543                                 FOREACH_CLIENT(IS_PLAYER(it), { GiveWarmupResources(it); });
 544                 }
 545                 if (warmup_limit > 0)
 546                         warmup_limit = -1;
 547                 return; // don't ReadyRestart if players are ready but too few
 548         }
 549         else if (minplayers && warmup_limit <= 0)
 550         {
 551                 // there's enough players now but we're still in infinite warmup
 552                 warmup_limit = cvar("g_warmup_limit");
 553                 if (warmup_limit == 0)
 554                         warmup_limit = autocvar_timelimit * 60;
 555                 if (warmup_limit > 0)
 556                         game_starttime = time;
 557                 // implicit else: g_warmup -1 && g_warmup_limit -1 means
 558                 // warmup continues until enough players AND enough RUPs (no time limit)
 559         }
 560
 561         if (humans_ready && humans_ready >= rint(human_players * bound(0.5, cvar("g_warmup_majority_factor"), 1)))
 562                 ReadyRestart(true);
 563 }
 564
 565
 566 // ======================================
 567 //  Supporting functions for VoteCommand
 568 // ======================================
 569
 570 bool Votecommand_check_assignment(entity caller, float assignment)
 571 {
 572         bool from_server = (!caller);
 573
 574         if ((assignment == VC_ASGNMNT_BOTH)
 575             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 576             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 577
 578         return false;
 579 }
 580
 581 string VoteCommand_extractcommand(string input, float startpos, int argc)
 582 {
 583         string output;
 584
 585         if ((argc - 1) < startpos) output = "";
 586         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 587
 588         return output;
 589 }
 590
 591 bool VoteCommand_checknasty(string vote_command)
 592 {
 593         return !((strstrofs(vote_command, ";", 0) >= 0)
 594             || (strstrofs(vote_command, "\n", 0) >= 0)
 595             || (strstrofs(vote_command, "\r", 0) >= 0)
 596             || (strstrofs(vote_command, "$", 0) >= 0));
 597 }
 598
 599 // NOTE: requires input to be surrounded by spaces
 600 string VoteCommand_checkreplacements(string input)
 601 {
 602         // add a space around the input so the start and end of the list is captured
 603         string output = strcat(" ", input, " ");
 604         // allow gotomap replacements
 605         output = strreplace(" map ", " gotomap ", output);
 606         output = strreplace(" chmap ", " gotomap ", output);
 607         return output;
 608 }
 609
 610 bool VoteCommand_checkinlist(string vote_command, string list)
 611 {
 612         if (vote_command == "" || list == "")
 613                 return false;
 614
 615         string l = VoteCommand_checkreplacements(list);
 616         return (strstrofs(l, VoteCommand_checkreplacements(vote_command), 0) >= 0);
 617 }
 618
 619 string ValidateMap(string validated_map, entity caller)
 620 {
 621         validated_map = MapInfo_FixName(validated_map);
 622
 623         if (!validated_map)
 624         {
 625                 print_to(caller, "This map is not available on this server.");
 626                 return string_null;
 627         }
 628
 629         if (!autocvar_sv_vote_override_mostrecent && caller)
 630         {
 631                 if (Map_IsRecent(validated_map))
 632                 {
 633                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 634                         return string_null;
 635                 }
 636         }
 637
 638         if (!MapInfo_CheckMap(validated_map))
 639         {
 640                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 641                 return string_null;
 642         }
 643
 644         return validated_map;
 645 }
 646
 647 float VoteCommand_checkargs(float startpos, int argc)
 648 {
 649         float p, q, check, minargs;
 650         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 651         string cmdrestriction = "";  // No we don't.
 652         string charlist, arg;
 653         float checkmate;
 654
 655         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 656                 cmdrestriction = cvar_string(cvarname);
 657         else
 658                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 659
 660         if (cmdrestriction == "") return true;
 661
 662         ++startpos;  // skip command name
 663
 664         // check minimum arg count
 665
 666         // 0 args: argc == startpos
 667         // 1 args: argc == startpos + 1
 668         // ...
 669
 670         minargs = stof(cmdrestriction);
 671         if (argc - startpos < minargs) return false;
 672
 673         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 674
 675         for ( ; ; )
 676         {
 677                 // we know that at any time, startpos <= argc - minargs
 678                 // so this means: argc-minargs >= startpos >= argc, thus
 679                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 680                 // have been seen already
 681
 682                 if (startpos >= argc) // all args checked? GOOD
 683                         break;
 684
 685                 if (p < 0)            // no more args? FAIL
 686                 {
 687                         // exception: exactly minargs left, this one included
 688                         if (argc - startpos == minargs) break;
 689
 690                         // otherwise fail
 691                         return false;
 692                 }
 693
 694                 // cut to next semicolon
 695                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 696                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 697                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 698
 699                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 700                 // charlist = strreplace("^^", ";", charlist);
 701
 702                 if (charlist != "")
 703                 {
 704                         // verify the arg only contains allowed chars
 705                         arg = argv(startpos);
 706                         checkmate = strlen(arg);
 707                         for (check = 0; check < checkmate; ++check)
 708                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 709                         // not allowed character
 710                         // all characters are allowed. FINE.
 711                 }
 712
 713                 ++startpos;
 714                 --minargs;
 715                 p = q;
 716         }
 717
 718         return true;
 719 }
 720
 721 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, int argc)
 722 {
 723         string first_command = argv(startpos);
 724         int missing_chars = argv_start_index(startpos);
 725
 726         if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
 727                 return 0;
 728
 729         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
 730
 731         if (!VoteCommand_checkargs(startpos, argc)) return 0;
 732
 733         switch (MUTATOR_CALLHOOK(VoteCommand_Parse, caller, first_command, vote_command, startpos, argc))
 734         {
 735                 case MUT_VOTEPARSE_CONTINUE: { break; }
 736                 case MUT_VOTEPARSE_SUCCESS: { return 1; }
 737                 case MUT_VOTEPARSE_INVALID: { return -1; }
 738                 case MUT_VOTEPARSE_UNACCEPTABLE: { return 0; }
 739         }
 740
 741         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 742         {
 743                 case "kick":
 744                 case "kickban":    // catch all kick/kickban commands
 745                 {
 746                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 747                         float accepted = VerifyClientEntity(victim, true, false);
 748
 749                         if (accepted > 0)
 750                         {
 751                                 string reason = "No reason provided";
 752                                 if(argc > next_token)
 753                                         reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
 754
 755                                 string command_arguments = reason;
 756                                 if (first_command == "kickban")
 757                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 758
 759                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 760                                 vote_parsed_display = sprintf("^1%s #%d ^7%s^1 %s", first_command, etof(victim), victim.netname, reason);
 761                         }
 762                         else
 763                         {
 764                                 print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n"));
 765                                 return 0;
 766                         }
 767
 768                         break;
 769                 }
 770
 771                 case "map":
 772                 case "chmap":
 773                 case "gotomap":  // re-direct all map selection commands to gotomap
 774                 {
 775                         vote_command = ValidateMap(argv(startpos + 1), caller);
 776                         if (!vote_command)  return -1;
 777                         vote_parsed_command = strcat("gotomap ", vote_command);
 778                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 779
 780                         break;
 781                 }
 782
 783                 // TODO: replicate the old behaviour of being able to vote for maps from different modes on multimode servers (possibly support it in gotomap too)
 784                 // maybe fallback instead of aborting if map name is invalid?
 785                 case "nextmap":
 786                 {
 787                         vote_command = ValidateMap(argv(startpos + 1), caller);
 788                         if (!vote_command)  return -1;
 789                         vote_parsed_command = strcat("nextmap ", vote_command);
 790                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 791
 792                         break;
 793                 }
 794
 795                 case "timelimit": // include restrictions on the maximum votable time limit
 796                 {
 797                         float timelimit_vote = stof(argv(startpos + 1));
 798                         if(timelimit_vote > autocvar_timelimit_max || timelimit_vote < autocvar_timelimit_min)
 799                         {
 800                                 print_to(caller, strcat("Invalid timelimit vote, accepted values are between ", ftos(autocvar_timelimit_min), " and ", ftos(autocvar_timelimit_max), "."));
 801                                 return -1;
 802                         }
 803                         timelimit_vote = bound(autocvar_timelimit_min, timelimit_vote, autocvar_timelimit_max);
 804                         vote_parsed_command = strcat("timelimit ", ftos(timelimit_vote));
 805                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 806
 807                         break;
 808                 }
 809
 810                 case "restart":
 811                 {
 812                         // add a delay so that vote result can be seen and announcer can be heard
 813                         // if the vote is accepted
 814                         vote_parsed_command = strcat("defer 1 ", vote_command);
 815                         vote_parsed_display = strzone(strcat("^1", vote_command));
 816
 817                         break;
 818                 }
 819
 820                 case "allready":
 821                 {
 822                         if(!warmup_stage) {
 823                                 print_to(caller, "Game already started. Use the resetmatch command to restart the match.");
 824                                 return -1;
 825                         }
 826
 827                         vote_parsed_command = vote_command;
 828                         vote_parsed_display = strzone(strcat("^1", vote_command));
 829                         break;
 830                 }
 831
 832                 default:
 833                 {
 834                         vote_parsed_command = vote_command;
 835                         vote_parsed_display = strzone(strcat("^1", vote_command));
 836
 837                         break;
 838                 }
 839         }
 840
 841         return 1;
 842 }
 843
 844
 845 // =======================
 846 //  Command Sub-Functions
 847 // =======================
 848
 849 void VoteCommand_abstain(int request, entity caller)  // CLIENT ONLY
 850 {
 851         switch (request)
 852         {
 853                 case CMD_REQUEST_COMMAND:
 854                 {
 855                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 856                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 857                         {
 858                                 print_to(caller, "^1You have already voted.");
 859                         }
 860
 861                         else  // everything went okay, continue changing vote
 862                         {
 863                                 print_to(caller, "^1You abstained from your vote.");
 864                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 865                                 msg_entity = caller;
 866                                 if (!autocvar_sv_vote_singlecount)
 867                                         VoteCount(false);
 868                         }
 869
 870                         return;
 871                 }
 872
 873                 default:
 874                 case CMD_REQUEST_USAGE:
 875                 {
 876                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 877                         print_to(caller, "  No arguments required.");
 878                         return;
 879                 }
 880         }
 881 }
 882
 883 void print_available_commands_to(entity caller)
 884 {
 885         print_to(caller, strcat("You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
 886 }
 887
 888 void VoteCommand_call(int request, entity caller, int argc, string vote_command)  // BOTH
 889 {
 890         switch (request)
 891         {
 892                 case CMD_REQUEST_COMMAND:
 893                 {
 894                         float tmp_playercount = 0;
 895                         int parse_error;
 896
 897                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 898
 899                         if (!autocvar_sv_vote_call && caller)
 900                         {
 901                                 print_to(caller, "^1Vote calling is not allowed.");
 902                         }
 903                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 904                         {
 905                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 906                         }
 907                         else if (vote_called)
 908                         {
 909                                 print_to(caller, "^1There is already a vote called.");
 910                         }
 911                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 912                         {
 913                                 print_to(caller, "^1Only players can call a vote.");
 914                         }
 915                         else if (caller && !IS_CLIENT(caller))
 916                         {
 917                                 print_to(caller, "^1Only connected clients can vote.");
 918                         }
 919                         else if (timeout_status && vote_command != "timein")
 920                         {
 921                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 922                         }
 923                         else if (caller && (time < caller.vote_waittime))
 924                         {
 925                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 926                         }
 927                         else if (!VoteCommand_checknasty(vote_command))
 928                         {
 929                                 print_to(caller, "^1Syntax error in command.");
 930                         }
 931                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
 932                         {
 933                                 if(parse_error == 0)
 934                                 {
 935                                         if (vote_called_command == "")
 936                                                 VoteCommand_call(CMD_REQUEST_USAGE, caller, argc, vote_command);
 937                                         else
 938                                                 print_to(caller, "^1This command is not acceptable or not available.");
 939                                 }
 940                         }
 941                         else  // everything went okay, continue with calling the vote
 942                         {
 943                                 vote_caller = caller;  // remember who called the vote
 944                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 945                                 vote_called = VOTE_NORMAL;
 946                                 vote_called_command = strzone(vote_parsed_command);
 947                                 vote_called_display = strzone(vote_parsed_display);
 948                                 vote_endtime = time + autocvar_sv_vote_timeout;
 949
 950                                 if (caller)
 951                                 {
 952                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 953                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 954                                         msg_entity = caller;
 955                                 }
 956
 957                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
 958
 959                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 960                                 if (autocvar_sv_eventlog)
 961                                         GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 962                                 Nagger_VoteChanged();
 963                                 VoteCount(true);  // needed if you are the only one
 964
 965                                 if (tmp_playercount > 1 && vote_called != VOTE_NULL)
 966                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
 967                         }
 968
 969                         return;
 970                 }
 971
 972                 default:
 973                 case CMD_REQUEST_USAGE:
 974                 {
 975                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call <command>"));
 976                         print_to(caller, "  Where <command> is the command to request a vote upon.");
 977                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 978                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 979                         print_available_commands_to(caller);
 980                         print_to(caller, "Shortcuts: ^2vcall <command>, vend, vmap, vkick, ...");
 981                         return;
 982                 }
 983         }
 984 }
 985
 986 void VoteCommand_master(int request, entity caller, int argc, string vote_command)  // CLIENT ONLY
 987 {
 988         switch (request)
 989         {
 990                 case CMD_REQUEST_COMMAND:
 991                 {
 992                         if (autocvar_sv_vote_master)
 993                         {
 994                                 switch (strtolower(argv(2)))
 995                                 {
 996                                         case "do":
 997                                         {
 998                                                 int parse_error;
 999                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
1000
1001                                                 if (!caller.vote_master)
1002                                                         print_to(caller, "^1You do not have vote master privileges.");
1003                                                 else if (!VoteCommand_checknasty(vote_command))
1004                                                 {
1005                                                         print_to(caller, "^1Syntax error in command.");
1006                                                 }
1007                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
1008                                                 {
1009                                                         if(parse_error == 0)
1010                                                         {
1011                                                                 if (vote_called_command == "")
1012                                                                         VoteCommand_master(CMD_REQUEST_USAGE, caller, argc, vote_command);
1013                                                                 else
1014                                                                         print_to(caller, "^1This command is not acceptable or not available.");
1015                                                         }
1016                                                 }
1017                                                 else  // everything went okay, proceed with command
1018                                                 {
1019                                                         localcmd(strcat(vote_parsed_command, "\n"));
1020                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
1021                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
1022                                                         if (autocvar_sv_eventlog)
1023                                                                 GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display));
1024                                                 }
1025
1026                                                 return;
1027                                         }
1028
1029                                         case "login":
1030                                         {
1031                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
1032                                                 else if (caller.vote_master)
1033                                                 {
1034                                                         print_to(caller, "^1You are already logged in as vote master.");
1035                                                 }
1036                                                 else if (autocvar_sv_vote_master_password != argv(3))
1037                                                 {
1038                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
1039                                                 }
1040                                                 else  // everything went okay, proceed with giving this player master privilages
1041                                                 {
1042                                                         caller.vote_master = true;
1043                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
1044                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
1045                                                         if (autocvar_sv_eventlog)
1046                                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid)));
1047                                                 }
1048
1049                                                 return;
1050                                         }
1051
1052                                         default:  // calling a vote for master
1053                                         {
1054                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
1055                                                 else if (vote_called)
1056                                                 {
1057                                                         print_to(caller, "^1There is already a vote called.");
1058                                                 }
1059                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
1060                                                 {
1061                                                         print_to(caller, "^1Only players can call a vote.");
1062                                                 }
1063                                                 else if (timeout_status)
1064                                                 {
1065                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
1066                                                 }
1067                                                 else  // everything went okay, continue with creating vote
1068                                                 {
1069                                                         vote_caller = caller;
1070                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
1071                                                         vote_called = VOTE_MASTER;
1072                                                         vote_called_command = strzone("XXX");
1073                                                         vote_called_display = strzone("^3master");
1074                                                         vote_endtime = time + autocvar_sv_vote_timeout;
1075
1076                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
1077                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
1078
1079                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
1080                                                         if (autocvar_sv_eventlog)
1081                                                                 GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
1082                                                         Nagger_VoteChanged();
1083                                                         VoteCount(true);  // needed if you are the only one
1084                                                 }
1085
1086                                                 return;
1087                                         }
1088                                 }
1089                         }
1090                         else { print_to(caller, "^1Master control of voting is not allowed."); }
1091
1092                         return;
1093                 }
1094
1095                 default:
1096                 case CMD_REQUEST_USAGE:
1097                 {
1098                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [<action> [<command> | <password>]]"));
1099                         print_to(caller, "  If <action> is left blank, it calls a vote for you to become master.");
1100                         print_to(caller, "  Otherwise it can be either 'do' (to run <command>) or 'login' as master.");
1101                         return;
1102                 }
1103         }
1104 }
1105
1106 void VoteCommand_no(int request, entity caller)  // CLIENT ONLY
1107 {
1108         switch (request)
1109         {
1110                 case CMD_REQUEST_COMMAND:
1111                 {
1112                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1113                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1114                         {
1115                                 print_to(caller, "^1You have already voted.");
1116                         }
1117                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1118                         {
1119                                 VoteStop(caller);
1120                         }
1121
1122                         else  // everything went okay, continue changing vote
1123                         {
1124                                 print_to(caller, "^1You rejected the vote.");
1125                                 caller.vote_selection = VOTE_SELECT_REJECT;
1126                                 msg_entity = caller;
1127                                 if (!autocvar_sv_vote_singlecount)
1128                                         VoteCount(false);
1129                         }
1130
1131                         return;
1132                 }
1133
1134                 default:
1135                 case CMD_REQUEST_USAGE:
1136                 {
1137                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1138                         print_to(caller, "  No arguments required.");
1139                         return;
1140                 }
1141         }
1142 }
1143
1144 void VoteCommand_status(int request, entity caller)  // BOTH
1145 {
1146         switch (request)
1147         {
1148                 case CMD_REQUEST_COMMAND:
1149                 {
1150                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1151                         else print_to(caller, "^1No vote called.");
1152
1153                         return;
1154                 }
1155
1156                 default:
1157                 case CMD_REQUEST_USAGE:
1158                 {
1159                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1160                         print_to(caller, "  No arguments required.");
1161                         return;
1162                 }
1163         }
1164 }
1165
1166 void VoteCommand_stop(int request, entity caller)  // BOTH
1167 {
1168         switch (request)
1169         {
1170                 case CMD_REQUEST_COMMAND:
1171                 {
1172                         if (!vote_called)   print_to(caller, "^1No vote called.");
1173                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1174                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1175                         return;
1176                 }
1177
1178                 default:
1179                 case CMD_REQUEST_USAGE:
1180                 {
1181                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1182                         print_to(caller, "  No arguments required.");
1183                         return;
1184                 }
1185         }
1186 }
1187
1188 void VoteCommand_yes(int request, entity caller)  // CLIENT ONLY
1189 {
1190         switch (request)
1191         {
1192                 case CMD_REQUEST_COMMAND:
1193                 {
1194                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1195                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1196                         {
1197                                 print_to(caller, "^1You have already voted.");
1198                         }
1199                         else  // everything went okay, continue changing vote
1200                         {
1201                                 print_to(caller, "^1You accepted the vote.");
1202                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1203                                 msg_entity = caller;
1204                                 if (!autocvar_sv_vote_singlecount)
1205                                         VoteCount(false);
1206                         }
1207
1208                         return;
1209                 }
1210
1211                 default:
1212                 case CMD_REQUEST_USAGE:
1213                 {
1214                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1215                         print_to(caller, "  No arguments required.");
1216                         return;
1217                 }
1218         }
1219 }
1220
1221 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1222 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1223 void VoteCommand_(int request)
1224 {
1225     switch(request)
1226     {
1227         case CMD_REQUEST_COMMAND:
1228         {
1229
1230             return;
1231         }
1232
1233         default:
1234         case CMD_REQUEST_USAGE:
1235         {
1236             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1237             print_to(caller, "  No arguments required.");
1238             return;
1239         }
1240     }
1241 }
1242 */
1243
1244
1245 // ================================
1246 //  Macro system for vote commands
1247 // ================================
1248
1249 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1250 #define VOTE_COMMANDS(request, caller, arguments, command) \
1251         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1252         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1253         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1254         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1255         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1256         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1257         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1258         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1259         /* nothing */
1260
1261 void VoteCommand_macro_help(entity caller, int argc)
1262 {
1263         string command_origin = GetCommandPrefix(caller);
1264
1265         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1266         {
1267                 print_to(caller, "\nVoting commands:\n");
1268                 #define VOTE_COMMAND(name, function, description, assignment) \
1269                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1270
1271                 VOTE_COMMANDS(0, caller, 0, "");
1272                 #undef VOTE_COMMAND
1273
1274                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote <command>^7, where possible commands are listed above.\n"));
1275                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help <command>"));
1276                 print_available_commands_to(caller);
1277         }
1278         else  // usage for individual command
1279         {
1280                 #define VOTE_COMMAND(name, function, description, assignment) \
1281                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1282
1283                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1284                 #undef VOTE_COMMAND
1285
1286                 string cvarname = strcat("sv_vote_command_help_", argv(2));
1287                 if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
1288                         wordwrap_sprint(caller, cvar_string(cvarname), 1000);
1289                 else if (argv(2) != "")
1290                         print_to(caller, "No documentation exists for this vote");
1291         }
1292 }
1293
1294 float VoteCommand_macro_command(entity caller, int argc, string vote_command)
1295 {
1296         #define VOTE_COMMAND(name, function, description, assignment) \
1297                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1298
1299         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1300         #undef VOTE_COMMAND
1301
1302         return false;
1303 }
1304
1305
1306 // ======================================
1307 //  Main function handling vote commands
1308 // ======================================
1309
1310 void VoteCommand(int request, entity caller, int argc, string vote_command)
1311 {
1312         // Guide for working with argc arguments by example:
1313         // argc:   1    - 2      - 3     - 4
1314         // argv:   0    - 1      - 2     - 3
1315         // cmd     vote - master - login - password
1316
1317         switch (request)
1318         {
1319                 case CMD_REQUEST_COMMAND:
1320                 {
1321                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1322                 }
1323
1324                 default:
1325                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1326                 case CMD_REQUEST_USAGE:
1327                 {
1328                         VoteCommand_macro_help(caller, argc);
1329                         return;
1330                 }
1331         }
1332 }