qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/items/inventory.qh>
   7 #include <common/mapinfo.qh>
   8 #include <common/net_linked.qh>
   9 #include <common/notifications/all.qh>
  10 #include <common/playerstats.qh>
  11 #include <common/stats.qh>
  12 #include <common/util.qh>
  13 #include <common/weapons/_all.qh>
  14 #include <server/campaign.qh>
  15 #include <server/client.qh>
  16 #include <server/command/banning.qh>
  17 #include <server/command/common.qh>
  18 #include <server/command/vote.qh>
  19 #include <server/damage.qh>
  20 #include <server/gamelog.qh>
  21 #include <server/intermission.qh>
  22 #include <server/mutators/_mod.qh>
  23 #include <server/race.qh>
  24 #include <server/round_handler.qh>
  25 #include <server/scores.qh>
  26 #include <server/teamplay.qh>
  27 #include <server/weapons/accuracy.qh>
  28 #include <server/world.qh>
  29
  30 // =============================================
  31 //  Server side voting code, reworked by Samual
  32 //  Last updated: December 27th, 2011
  33 // =============================================
  34
  35 //  Nagger for players to know status of voting
  36 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  37 {
  38         int nags, i, f, b;
  39         entity e;
  40         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  41
  42         // bits:
  43         //   1 = ready
  44         //   2 = player needs to ready up
  45         //   4 = vote
  46         //   8 = player needs to vote
  47         //  16 = warmup
  48         // sendflags:
  49         //  64 = vote counts
  50         // 128 = vote string
  51
  52         nags = 0;
  53         if (readycount)
  54         {
  55                 nags |= BIT(0);
  56                 if (to.ready == 0) nags |= BIT(1);
  57         }
  58         if (vote_called)
  59         {
  60                 nags |= BIT(2);
  61                 if (to.vote_selection == 0) nags |= BIT(3);
  62         }
  63         if (warmup_stage) nags |= BIT(4);
  64
  65         if (sendflags & BIT(6)) nags |= BIT(6);
  66
  67         if (sendflags & BIT(7)) nags |= BIT(7);
  68
  69         if (!(nags & 4))  // no vote called? send no string
  70                 nags &= ~(BIT(6) | BIT(7));
  71
  72         WriteByte(MSG_ENTITY, nags);
  73
  74         if (nags & BIT(6))
  75         {
  76                 WriteByte(MSG_ENTITY, vote_accept_count);
  77                 WriteByte(MSG_ENTITY, vote_reject_count);
  78                 WriteByte(MSG_ENTITY, vote_needed_overall);
  79                 WriteChar(MSG_ENTITY, to.vote_selection);
  80         }
  81
  82         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  83
  84         if (nags & 1)
  85         {
  86                 for (i = 1; i <= maxclients; i += 8)
  87                 {
  88                         for (f = 0, e = edict_num(i), b = BIT(0); b < BIT(8); b <<= 1, e = nextent(e))
  89                                 if (!IS_REAL_CLIENT(e) || e.ready)
  90                                         f |= b;
  91                         WriteByte(MSG_ENTITY, f);
  92                 }
  93         }
  94
  95         return true;
  96 }
  97
  98 void Nagger_Init()
  99 {
 100         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
 101 }
 102
 103 void Nagger_VoteChanged()
 104 {
 105         if (nagger) nagger.SendFlags |= BIT(7);
 106 }
 107
 108 void Nagger_VoteCountChanged()
 109 {
 110         if (nagger) nagger.SendFlags |= BIT(6);
 111 }
 112
 113 void Nagger_ReadyCounted()
 114 {
 115         if (nagger) nagger.SendFlags |= BIT(0);
 116 }
 117
 118 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 119 string OriginalCallerName()
 120 {
 121         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller.netname, vote_caller.team, false);
 122         return vote_caller_name;
 123 }
 124
 125 // =======================
 126 //  Game logic for voting
 127 // =======================
 128
 129 void VoteReset()
 130 {
 131         FOREACH_CLIENT(true, { it.vote_selection = 0; });
 132
 133         if (vote_called)
 134         {
 135                 strfree(vote_called_command);
 136                 strfree(vote_called_display);
 137                 strfree(vote_caller_name);
 138         }
 139
 140         vote_called = VOTE_NULL;
 141         vote_caller = NULL;
 142         vote_endtime = 0;
 143
 144         vote_parsed_command = string_null;
 145         vote_parsed_display = string_null;
 146
 147         Nagger_VoteChanged();
 148 }
 149
 150 void VoteStop(entity stopper)
 151 {
 152         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 153         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 154         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 155         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 156         VoteReset();
 157 }
 158
 159 void VoteAccept()
 160 {
 161         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 162
 163         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 164         else localcmd(strcat(vote_called_command, "\n"));
 165
 166         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 167
 168         VoteReset();
 169         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 170 }
 171
 172 void VoteReject()
 173 {
 174         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 175         VoteReset();
 176         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 177 }
 178
 179 void VoteTimeout()
 180 {
 181         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 182         VoteReset();
 183         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 184 }
 185
 186 void VoteSpam(float notvoters, float mincount, string result)
 187 {
 188         bprint(strcat(
 189                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 190                 strcat("^2:^1", ftos(vote_reject_count)),
 191                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 192                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 193                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 194
 195         if (autocvar_sv_eventlog)
 196         {
 197                 GameLogEcho(strcat(
 198                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 199                         strcat(":", ftos(vote_reject_count)),
 200                         strcat(":", ftos(vote_abstain_count)),
 201                         strcat(":", ftos(notvoters)),
 202                         strcat(":", ftos(mincount))));
 203         }
 204 }
 205
 206 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
 207
 208 void VoteCount(float first_count)
 209 {
 210         // declarations
 211         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 212
 213         float vote_player_count = 0, notvoters = 0;
 214         float vote_real_player_count = 0, vote_real_accept_count = 0;
 215         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 216         float vote_needed_of_voted, final_needed_votes;
 217         float vote_factor_overall, vote_factor_of_voted;
 218
 219         Nagger_VoteCountChanged();
 220
 221         // add up all the votes from each connected client
 222         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), {
 223                 ++vote_player_count;
 224                 if (IS_PLAYER(it))   ++vote_real_player_count;
 225                 switch (it.vote_selection)
 226                 {
 227                         case VOTE_SELECT_REJECT:
 228                         { ++vote_reject_count;
 229                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 230                         }
 231                         case VOTE_SELECT_ACCEPT:
 232                         { ++vote_accept_count;
 233                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 234                         }
 235                         case VOTE_SELECT_ABSTAIN:
 236                         { ++vote_abstain_count;
 237                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 238                         }
 239                         default: break;
 240                 }
 241         });
 242
 243         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 244         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 245         {
 246                 if (vote_caller)   vote_caller.vote_waittime = 0;
 247                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 248                 VoteReset();
 249                 return;
 250         }
 251
 252         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 253         if (!spectators_allowed && (vote_real_player_count > 0))
 254         {
 255                 vote_accept_count = vote_real_accept_count;
 256                 vote_reject_count = vote_real_reject_count;
 257                 vote_abstain_count = vote_real_abstain_count;
 258                 vote_player_count = vote_real_player_count;
 259         }
 260
 261         // people who have no opinion in any way :D
 262         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 263
 264         // determine the goal for the vote to be passed or rejected normally
 265         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 266         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 267
 268         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 269         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 270         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 271
 272         // are there any players at all on the server? it could be an admin vote
 273         if (vote_player_count == 0 && first_count)
 274         {
 275                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 276                 VoteAccept();
 277                 return;
 278         }
 279
 280         // since there ARE players, finally calculate the result of the vote
 281         if (vote_accept_count >= vote_needed_overall)
 282         {
 283                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 284                 VoteAccept();
 285                 return;
 286         }
 287
 288         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 289         {
 290                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 291                 VoteReject();
 292                 return;
 293         }
 294
 295         // there is not enough votes in either direction, now lets just calculate what the voters have said
 296         if (time > vote_endtime)
 297         {
 298                 final_needed_votes = vote_needed_overall;
 299
 300                 if (autocvar_sv_vote_majority_factor_of_voted)
 301                 {
 302                         if (vote_accept_count >= vote_needed_of_voted)
 303                         {
 304                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 305                                 VoteAccept();
 306                                 return;
 307                         }
 308
 309                         if (vote_accept_count + vote_reject_count > 0)
 310                         {
 311                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 312                                 VoteReject();
 313                                 return;
 314                         }
 315
 316                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 317                 }
 318
 319                 // it didn't pass or fail, so not enough votes to even make a decision.
 320                 VoteSpam(notvoters, final_needed_votes, "timeout");
 321                 VoteTimeout();
 322         }
 323 }
 324
 325 void VoteThink()
 326 {
 327         if (vote_endtime > 0)        // a vote was called
 328         {
 329                 if (time > vote_endtime) // time is up
 330                         VoteCount(false);
 331         }
 332 }
 333
 334
 335 // =======================
 336 //  Game logic for warmup
 337 // =======================
 338
 339 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 340 void reset_map(bool dorespawn, bool is_fake_round_start)
 341 {
 342         if (time <= game_starttime)
 343         {
 344                 if (game_stopped)
 345                         return;
 346
 347                 if (!is_fake_round_start)
 348                 {
 349                         Score_ClearAll();
 350                         PlayerStats_GameReport_Reset_All();
 351                 }
 352
 353                 if (round_handler_IsActive())
 354                         round_handler_Reset(game_starttime);
 355         }
 356
 357         if (shuffleteams_on_reset_map)
 358         {
 359                 shuffleteams();
 360                 shuffleteams_on_reset_map = false;
 361         }
 362
 363         FOREACH_CLIENT(true, {
 364                 if (time <= game_starttime)
 365                         accuracy_reset(it); // for spectators too because weapon accuracy is persistent
 366                 if (!IS_PLAYER(it))
 367                         continue;
 368                 if (STAT(FROZEN, it))
 369                         Unfreeze(it, false);
 370                 player_powerups_remove_all(it);
 371                 entity store = PS(it);
 372                 if (store)
 373                 {
 374                         Inventory_clear(store.inventory);
 375                         Inventory_update(store);
 376                 }
 377         });
 378
 379         MUTATOR_CALLHOOK(reset_map_global);
 380
 381         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
 382         {
 383                 if(IS_CLIENT(it))
 384                         continue;
 385                 if (it.reset)
 386                 {
 387                         it.reset(it);
 388                         continue;
 389                 }
 390                 if (it.team_saved) it.team = it.team_saved;
 391                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 392         });
 393
 394         // Waypoints and assault start come LAST
 395         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 396                 if (it.reset2) it.reset2(it);
 397         });
 398
 399         // Moving the player reset code here since the player-reset depends
 400         // on spawnpoint entities which have to be reset first --blub
 401         if (dorespawn)
 402         {
 403                 if (!MUTATOR_CALLHOOK(reset_map_players))
 404                 {
 405                         FOREACH_CLIENT(IS_PLAYER(it),
 406                         {
 407                                 // PlayerScore_Clear(it);
 408                                 CS(it).killcount = 0;
 409                                 // stop the player from moving so that he stands still once he gets respawned
 410                                 it.velocity = '0 0 0';
 411                                 it.avelocity = '0 0 0';
 412                                 CS(it).movement = '0 0 0';
 413                                 PutClientInServer(it);
 414                         });
 415                 }
 416         }
 417 }
 418
 419 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 420 void ReadyRestart_think(entity this)
 421 {
 422         if (!warmup_stage) // if the countdown was not aborted
 423                 reset_map(true, false);
 424         delete(this);
 425 }
 426
 427 // Forces a restart of the game without actually reloading the map // this is a mess...
 428 void ReadyRestart_force(bool is_fake_round_start)
 429 {
 430         if (time <= game_starttime && game_stopped)
 431                 return;
 432         if (!is_fake_round_start)
 433                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_COUNTDOWN_RESTART);
 434
 435         VoteReset();
 436
 437         // clear overtime, we have to decrease timelimit to its original value again.
 438         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 439                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 440         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = overtimes = 0;
 441
 442         if(warmup_stage)
 443                 game_starttime = time; // Warmup: No countdown in warmup
 444         else if (autocvar_g_campaign)
 445                 game_starttime = time + 3;
 446         else
 447                 game_starttime = time + RESTART_COUNTDOWN; // Go into match mode
 448
 449         // clear player attributes
 450         FOREACH_CLIENT(IS_PLAYER(it), {
 451                 it.alivetime = 0;
 452                 CS(it).killcount = 0;
 453         });
 454
 455         // if we're ending the warmup stage call the corresponding hook
 456         if(!is_fake_round_start && !warmup_stage)
 457                 localcmd("\nsv_hook_warmupend\n");
 458
 459         // reset the .ready status of all players (also spectators)
 460         FOREACH_CLIENT(IS_REAL_CLIENT(it), { it.ready = false; });
 461         readycount = 0;
 462         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 463
 464         // lock teams with lockonrestart
 465         if (autocvar_teamplay_lockonrestart && teamplay)
 466                 lockteams = !warmup_stage;
 467
 468         // initiate the restart-countdown-announcer entity
 469         if (!is_fake_round_start && sv_ready_restart_after_countdown && !warmup_stage)
 470         {
 471                 entity restart_timer = new_pure(restart_timer);
 472                 setthink(restart_timer, ReadyRestart_think);
 473                 restart_timer.nextthink = game_starttime;
 474         }
 475
 476         // after a restart every players number of allowed timeouts gets reset, too
 477         if (autocvar_sv_timeout)
 478         {
 479                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
 480         }
 481
 482         if (!sv_ready_restart_after_countdown || warmup_stage)
 483                 reset_map(true, is_fake_round_start);
 484
 485         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 486 }
 487
 488 void ReadyRestart(bool forceWarmupEnd)
 489 {
 490         if (MUTATOR_CALLHOOK(ReadyRestart_Deny) || intermission_running || race_completing)
 491         {
 492                 // NOTE: ReadyRestart support is mandatory in campaign
 493                 if (autocvar_g_campaign)
 494                         error("ReadyRestart must be supported in campaign mode!");
 495                 localcmd("restart\n"); // if ReadyRestart is denied, restart the server
 496         }
 497         else localcmd("\nsv_hook_readyrestart\n");
 498
 499         if(forceWarmupEnd || autocvar_g_campaign)
 500                 warmup_stage = 0; // forcefully end warmup and go to match stage
 501         else
 502                 warmup_stage = autocvar_g_warmup; // go into warmup if it's enabled, otherwise restart into match stage
 503
 504         ReadyRestart_force(false);
 505 }
 506
 507 /* Count the players who are ready and determine whether or not to restart the match when:
 508  * a player presses F4                      server/command/cmd.qc  ClientCommand_ready()
 509  * a player switches from players to specs  server/client.qc       PutObserverInServer()
 510  * a player joins (from specs or directly)  server/client.qc       PutPlayerInServer()
 511  * a player disconnects                     server/client.qc       ClientDisconnect()   */
 512 void ReadyCount()
 513 {
 514         // cannot reset the game while a timeout is active or pending
 515         if (timeout_status) return;
 516
 517         int total_players = 0, human_players = 0, humans_ready = 0;
 518         readycount = 0;
 519
 520         FOREACH_CLIENT(IS_PLAYER(it) || INGAME_JOINED(it), {
 521                 ++total_players;
 522                 if (it.ready) ++readycount;
 523                 if (IS_REAL_CLIENT(it))
 524                 {
 525                         ++human_players;
 526                         if (it.ready) ++humans_ready;
 527                 }
 528         });
 529
 530         Nagger_ReadyCounted();
 531
 532         // can't read warmup_stage here as it could have been set to 0 by ReadyRestart()
 533         // and we need to use this when checking if we should abort the countdown
 534         // map_minplayers can only be > 0 if g_warmup was -1 at worldspawn
 535         int minplayers = autocvar_g_warmup > 1 ? autocvar_g_warmup : map_minplayers;
 536
 537         if (total_players < minplayers)
 538         {
 539                 if (game_starttime > time) // someone bailed during countdown, back to warmup
 540                 {
 541                         warmup_stage = autocvar_g_warmup; // CAN change it AFTER calling Nagger_ReadyCounted() this frame
 542                         game_starttime = time;
 543                         Send_Notification(NOTIF_ALL, NULL, MSG_MULTI, COUNTDOWN_STOP, minplayers);
 544                         if (!sv_ready_restart_after_countdown) // if we ran reset_map() at start of countdown
 545                                 FOREACH_CLIENT(IS_PLAYER(it), { GiveWarmupResources(it); });
 546                 }
 547                 if (warmup_limit > 0)
 548                         warmup_limit = -1;
 549                 return; // don't ReadyRestart if players are ready but too few
 550         }
 551         else if (minplayers && warmup_limit <= 0)
 552         {
 553                 // there's enough players now but we're still in infinite warmup
 554                 warmup_limit = cvar("g_warmup_limit");
 555                 if (warmup_limit == 0)
 556                         warmup_limit = autocvar_timelimit * 60;
 557                 if (warmup_limit > 0)
 558                         game_starttime = time;
 559                 // implicit else: g_warmup -1 && g_warmup_limit -1 means
 560                 // warmup continues until enough players AND enough RUPs (no time limit)
 561         }
 562
 563         if (humans_ready && humans_ready >= rint(human_players * bound(0.5, cvar("g_warmup_majority_factor"), 1)))
 564                 ReadyRestart(true);
 565 }
 566
 567
 568 // ======================================
 569 //  Supporting functions for VoteCommand
 570 // ======================================
 571
 572 bool Votecommand_check_assignment(entity caller, float assignment)
 573 {
 574         bool from_server = (!caller);
 575
 576         if ((assignment == VC_ASGNMNT_BOTH)
 577             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 578             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 579
 580         return false;
 581 }
 582
 583 string VoteCommand_extractcommand(string input, float startpos, int argc)
 584 {
 585         string output;
 586
 587         if ((argc - 1) < startpos) output = "";
 588         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 589
 590         return output;
 591 }
 592
 593 bool VoteCommand_checknasty(string vote_command)
 594 {
 595         return !((strstrofs(vote_command, ";", 0) >= 0)
 596             || (strstrofs(vote_command, "\n", 0) >= 0)
 597             || (strstrofs(vote_command, "\r", 0) >= 0)
 598             || (strstrofs(vote_command, "$", 0) >= 0));
 599 }
 600
 601 // NOTE: requires input to be surrounded by spaces
 602 string VoteCommand_checkreplacements(string input)
 603 {
 604         // add a space around the input so the start and end of the list is captured
 605         string output = strcat(" ", input, " ");
 606         // allow gotomap replacements
 607         output = strreplace(" map ", " gotomap ", output);
 608         output = strreplace(" chmap ", " gotomap ", output);
 609         return output;
 610 }
 611
 612 bool VoteCommand_checkinlist(string vote_command, string list)
 613 {
 614         if (vote_command == "" || list == "")
 615                 return false;
 616
 617         string l = VoteCommand_checkreplacements(list);
 618         return (strstrofs(l, VoteCommand_checkreplacements(vote_command), 0) >= 0);
 619 }
 620
 621 string ValidateMap(string validated_map, entity caller)
 622 {
 623         validated_map = MapInfo_FixName(validated_map);
 624
 625         if (!validated_map)
 626         {
 627                 print_to(caller, "This map is not available on this server.");
 628                 return string_null;
 629         }
 630
 631         if (!autocvar_sv_vote_override_mostrecent && caller)
 632         {
 633                 if (Map_IsRecent(validated_map))
 634                 {
 635                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 636                         return string_null;
 637                 }
 638         }
 639
 640         if (!MapInfo_CheckMap(validated_map))
 641         {
 642                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 643                 return string_null;
 644         }
 645
 646         return validated_map;
 647 }
 648
 649 float VoteCommand_checkargs(float startpos, int argc)
 650 {
 651         float p, q, check, minargs;
 652         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 653         string cmdrestriction = "";  // No we don't.
 654         string charlist, arg;
 655         float checkmate;
 656
 657         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 658                 cmdrestriction = cvar_string(cvarname);
 659         else
 660                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 661
 662         if (cmdrestriction == "") return true;
 663
 664         ++startpos;  // skip command name
 665
 666         // check minimum arg count
 667
 668         // 0 args: argc == startpos
 669         // 1 args: argc == startpos + 1
 670         // ...
 671
 672         minargs = stof(cmdrestriction);
 673         if (argc - startpos < minargs) return false;
 674
 675         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 676
 677         for ( ; ; )
 678         {
 679                 // we know that at any time, startpos <= argc - minargs
 680                 // so this means: argc-minargs >= startpos >= argc, thus
 681                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 682                 // have been seen already
 683
 684                 if (startpos >= argc) // all args checked? GOOD
 685                         break;
 686
 687                 if (p < 0)            // no more args? FAIL
 688                 {
 689                         // exception: exactly minargs left, this one included
 690                         if (argc - startpos == minargs) break;
 691
 692                         // otherwise fail
 693                         return false;
 694                 }
 695
 696                 // cut to next semicolon
 697                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 698                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 699                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 700
 701                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 702                 // charlist = strreplace("^^", ";", charlist);
 703
 704                 if (charlist != "")
 705                 {
 706                         // verify the arg only contains allowed chars
 707                         arg = argv(startpos);
 708                         checkmate = strlen(arg);
 709                         for (check = 0; check < checkmate; ++check)
 710                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 711                         // not allowed character
 712                         // all characters are allowed. FINE.
 713                 }
 714
 715                 ++startpos;
 716                 --minargs;
 717                 p = q;
 718         }
 719
 720         return true;
 721 }
 722
 723 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, int argc)
 724 {
 725         string first_command = argv(startpos);
 726         int missing_chars = argv_start_index(startpos);
 727
 728         if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
 729                 return 0;
 730
 731         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
 732
 733         if (!VoteCommand_checkargs(startpos, argc)) return 0;
 734
 735         switch (MUTATOR_CALLHOOK(VoteCommand_Parse, caller, first_command, vote_command, startpos, argc))
 736         {
 737                 case MUT_VOTEPARSE_CONTINUE: { break; }
 738                 case MUT_VOTEPARSE_SUCCESS: { return 1; }
 739                 case MUT_VOTEPARSE_INVALID: { return -1; }
 740                 case MUT_VOTEPARSE_UNACCEPTABLE: { return 0; }
 741         }
 742
 743         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 744         {
 745                 case "kick":
 746                 case "kickban":    // catch all kick/kickban commands
 747                 {
 748                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 749                         float accepted = VerifyClientEntity(victim, true, false);
 750
 751                         if (accepted > 0)
 752                         {
 753                                 string reason = "No reason provided";
 754                                 if(argc > next_token)
 755                                         reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
 756
 757                                 string command_arguments = reason;
 758                                 if (first_command == "kickban")
 759                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 760
 761                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 762                                 vote_parsed_display = sprintf("^1%s #%d ^7%s^1 %s", first_command, etof(victim), victim.netname, reason);
 763                         }
 764                         else
 765                         {
 766                                 print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n"));
 767                                 return 0;
 768                         }
 769
 770                         break;
 771                 }
 772
 773                 case "map":
 774                 case "chmap":
 775                 case "gotomap":  // re-direct all map selection commands to gotomap
 776                 {
 777                         vote_command = ValidateMap(argv(startpos + 1), caller);
 778                         if (!vote_command)  return -1;
 779                         vote_parsed_command = strcat("gotomap ", vote_command);
 780                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 781
 782                         break;
 783                 }
 784
 785                 // TODO: replicate the old behaviour of being able to vote for maps from different modes on multimode servers (possibly support it in gotomap too)
 786                 // maybe fallback instead of aborting if map name is invalid?
 787                 case "nextmap":
 788                 {
 789                         vote_command = ValidateMap(argv(startpos + 1), caller);
 790                         if (!vote_command)  return -1;
 791                         vote_parsed_command = strcat("nextmap ", vote_command);
 792                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 793
 794                         break;
 795                 }
 796
 797                 case "timelimit": // include restrictions on the maximum votable time limit
 798                 {
 799                         float timelimit_vote = stof(argv(startpos + 1));
 800                         if(timelimit_vote > autocvar_timelimit_max || timelimit_vote < autocvar_timelimit_min)
 801                         {
 802                                 print_to(caller, strcat("Invalid timelimit vote, accepted values are between ", ftos(autocvar_timelimit_min), " and ", ftos(autocvar_timelimit_max), "."));
 803                                 return -1;
 804                         }
 805                         timelimit_vote = bound(autocvar_timelimit_min, timelimit_vote, autocvar_timelimit_max);
 806                         vote_parsed_command = strcat("timelimit ", ftos(timelimit_vote));
 807                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 808
 809                         break;
 810                 }
 811
 812                 case "restart":
 813                 {
 814                         // add a delay so that vote result can be seen and announcer can be heard
 815                         // if the vote is accepted
 816                         vote_parsed_command = strcat("defer 1 ", vote_command);
 817                         vote_parsed_display = strzone(strcat("^1", vote_command));
 818
 819                         break;
 820                 }
 821
 822                 case "allready":
 823                 {
 824                         if(!warmup_stage) {
 825                                 print_to(caller, "Game already started. Use the resetmatch command to restart the match.");
 826                                 return -1;
 827                         }
 828
 829                         vote_parsed_command = vote_command;
 830                         vote_parsed_display = strzone(strcat("^1", vote_command));
 831                         break;
 832                 }
 833
 834                 default:
 835                 {
 836                         vote_parsed_command = vote_command;
 837                         vote_parsed_display = strzone(strcat("^1", vote_command));
 838
 839                         break;
 840                 }
 841         }
 842
 843         return 1;
 844 }
 845
 846
 847 // =======================
 848 //  Command Sub-Functions
 849 // =======================
 850
 851 void VoteCommand_abstain(int request, entity caller)  // CLIENT ONLY
 852 {
 853         switch (request)
 854         {
 855                 case CMD_REQUEST_COMMAND:
 856                 {
 857                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 858                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 859                         {
 860                                 print_to(caller, "^1You have already voted.");
 861                         }
 862
 863                         else  // everything went okay, continue changing vote
 864                         {
 865                                 print_to(caller, "^1You abstained from your vote.");
 866                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 867                                 msg_entity = caller;
 868                                 if (!autocvar_sv_vote_singlecount)
 869                                         VoteCount(false);
 870                         }
 871
 872                         return;
 873                 }
 874
 875                 default:
 876                 case CMD_REQUEST_USAGE:
 877                 {
 878                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 879                         print_to(caller, "  No arguments required.");
 880                         return;
 881                 }
 882         }
 883 }
 884
 885 void print_available_commands_to(entity caller)
 886 {
 887         print_to(caller, strcat("You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
 888 }
 889
 890 void VoteCommand_call(int request, entity caller, int argc, string vote_command)  // BOTH
 891 {
 892         switch (request)
 893         {
 894                 case CMD_REQUEST_COMMAND:
 895                 {
 896                         float tmp_playercount = 0;
 897                         int parse_error;
 898
 899                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 900
 901                         if (!autocvar_sv_vote_call && caller)
 902                         {
 903                                 print_to(caller, "^1Vote calling is not allowed.");
 904                         }
 905                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 906                         {
 907                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 908                         }
 909                         else if (vote_called)
 910                         {
 911                                 print_to(caller, "^1There is already a vote called.");
 912                         }
 913                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 914                         {
 915                                 print_to(caller, "^1Only players can call a vote.");
 916                         }
 917                         else if (caller && !IS_CLIENT(caller))
 918                         {
 919                                 print_to(caller, "^1Only connected clients can vote.");
 920                         }
 921                         else if (timeout_status && vote_command != "timein")
 922                         {
 923                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 924                         }
 925                         else if (caller && (time < caller.vote_waittime))
 926                         {
 927                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 928                         }
 929                         else if (!VoteCommand_checknasty(vote_command))
 930                         {
 931                                 print_to(caller, "^1Syntax error in command.");
 932                         }
 933                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
 934                         {
 935                                 if(parse_error == 0)
 936                                 {
 937                                         if (vote_called_command == "")
 938                                                 VoteCommand_call(CMD_REQUEST_USAGE, caller, argc, vote_command);
 939                                         else
 940                                                 print_to(caller, "^1This command is not acceptable or not available.");
 941                                 }
 942                         }
 943                         else  // everything went okay, continue with calling the vote
 944                         {
 945                                 vote_caller = caller;  // remember who called the vote
 946                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 947                                 vote_called = VOTE_NORMAL;
 948                                 vote_called_command = strzone(vote_parsed_command);
 949                                 vote_called_display = strzone(vote_parsed_display);
 950                                 vote_endtime = time + autocvar_sv_vote_timeout;
 951
 952                                 if (caller)
 953                                 {
 954                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 955                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 956                                         msg_entity = caller;
 957                                 }
 958
 959                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
 960
 961                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 962                                 if (autocvar_sv_eventlog)
 963                                         GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 964                                 Nagger_VoteChanged();
 965                                 VoteCount(true);  // needed if you are the only one
 966
 967                                 if (tmp_playercount > 1 && vote_called != VOTE_NULL)
 968                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
 969                         }
 970
 971                         return;
 972                 }
 973
 974                 default:
 975                 case CMD_REQUEST_USAGE:
 976                 {
 977                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call <command>"));
 978                         print_to(caller, "  Where <command> is the command to request a vote upon.");
 979                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 980                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 981                         print_available_commands_to(caller);
 982                         print_to(caller, "Shortcuts: ^2vcall <command>, vend, vmap, vkick, ...");
 983                         return;
 984                 }
 985         }
 986 }
 987
 988 void VoteCommand_master(int request, entity caller, int argc, string vote_command)  // CLIENT ONLY
 989 {
 990         switch (request)
 991         {
 992                 case CMD_REQUEST_COMMAND:
 993                 {
 994                         if (autocvar_sv_vote_master)
 995                         {
 996                                 switch (strtolower(argv(2)))
 997                                 {
 998                                         case "do":
 999                                         {
1000                                                 int parse_error;
1001                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
1002
1003                                                 if (!caller.vote_master)
1004                                                         print_to(caller, "^1You do not have vote master privileges.");
1005                                                 else if (!VoteCommand_checknasty(vote_command))
1006                                                 {
1007                                                         print_to(caller, "^1Syntax error in command.");
1008                                                 }
1009                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
1010                                                 {
1011                                                         if(parse_error == 0)
1012                                                         {
1013                                                                 if (vote_called_command == "")
1014                                                                         VoteCommand_master(CMD_REQUEST_USAGE, caller, argc, vote_command);
1015                                                                 else
1016                                                                         print_to(caller, "^1This command is not acceptable or not available.");
1017                                                         }
1018                                                 }
1019                                                 else  // everything went okay, proceed with command
1020                                                 {
1021                                                         localcmd(strcat(vote_parsed_command, "\n"));
1022                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
1023                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
1024                                                         if (autocvar_sv_eventlog)
1025                                                                 GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display));
1026                                                 }
1027
1028                                                 return;
1029                                         }
1030
1031                                         case "login":
1032                                         {
1033                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
1034                                                 else if (caller.vote_master)
1035                                                 {
1036                                                         print_to(caller, "^1You are already logged in as vote master.");
1037                                                 }
1038                                                 else if (autocvar_sv_vote_master_password != argv(3))
1039                                                 {
1040                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
1041                                                 }
1042                                                 else  // everything went okay, proceed with giving this player master privilages
1043                                                 {
1044                                                         caller.vote_master = true;
1045                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
1046                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
1047                                                         if (autocvar_sv_eventlog)
1048                                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid)));
1049                                                 }
1050
1051                                                 return;
1052                                         }
1053
1054                                         default:  // calling a vote for master
1055                                         {
1056                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
1057                                                 else if (vote_called)
1058                                                 {
1059                                                         print_to(caller, "^1There is already a vote called.");
1060                                                 }
1061                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
1062                                                 {
1063                                                         print_to(caller, "^1Only players can call a vote.");
1064                                                 }
1065                                                 else if (timeout_status)
1066                                                 {
1067                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
1068                                                 }
1069                                                 else  // everything went okay, continue with creating vote
1070                                                 {
1071                                                         vote_caller = caller;
1072                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
1073                                                         vote_called = VOTE_MASTER;
1074                                                         vote_called_command = strzone("XXX");
1075                                                         vote_called_display = strzone("^3master");
1076                                                         vote_endtime = time + autocvar_sv_vote_timeout;
1077
1078                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
1079                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
1080
1081                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
1082                                                         if (autocvar_sv_eventlog)
1083                                                                 GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
1084                                                         Nagger_VoteChanged();
1085                                                         VoteCount(true);  // needed if you are the only one
1086                                                 }
1087
1088                                                 return;
1089                                         }
1090                                 }
1091                         }
1092                         else { print_to(caller, "^1Master control of voting is not allowed."); }
1093
1094                         return;
1095                 }
1096
1097                 default:
1098                 case CMD_REQUEST_USAGE:
1099                 {
1100                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [<action> [<command> | <password>]]"));
1101                         print_to(caller, "  If <action> is left blank, it calls a vote for you to become master.");
1102                         print_to(caller, "  Otherwise it can be either 'do' (to run <command>) or 'login' as master.");
1103                         return;
1104                 }
1105         }
1106 }
1107
1108 void VoteCommand_no(int request, entity caller)  // CLIENT ONLY
1109 {
1110         switch (request)
1111         {
1112                 case CMD_REQUEST_COMMAND:
1113                 {
1114                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1115                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1116                         {
1117                                 print_to(caller, "^1You have already voted.");
1118                         }
1119                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1120                         {
1121                                 VoteStop(caller);
1122                         }
1123
1124                         else  // everything went okay, continue changing vote
1125                         {
1126                                 print_to(caller, "^1You rejected the vote.");
1127                                 caller.vote_selection = VOTE_SELECT_REJECT;
1128                                 msg_entity = caller;
1129                                 if (!autocvar_sv_vote_singlecount)
1130                                         VoteCount(false);
1131                         }
1132
1133                         return;
1134                 }
1135
1136                 default:
1137                 case CMD_REQUEST_USAGE:
1138                 {
1139                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1140                         print_to(caller, "  No arguments required.");
1141                         return;
1142                 }
1143         }
1144 }
1145
1146 void VoteCommand_status(int request, entity caller)  // BOTH
1147 {
1148         switch (request)
1149         {
1150                 case CMD_REQUEST_COMMAND:
1151                 {
1152                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1153                         else print_to(caller, "^1No vote called.");
1154
1155                         return;
1156                 }
1157
1158                 default:
1159                 case CMD_REQUEST_USAGE:
1160                 {
1161                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1162                         print_to(caller, "  No arguments required.");
1163                         return;
1164                 }
1165         }
1166 }
1167
1168 void VoteCommand_stop(int request, entity caller)  // BOTH
1169 {
1170         switch (request)
1171         {
1172                 case CMD_REQUEST_COMMAND:
1173                 {
1174                         if (!vote_called)   print_to(caller, "^1No vote called.");
1175                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1176                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1177                         return;
1178                 }
1179
1180                 default:
1181                 case CMD_REQUEST_USAGE:
1182                 {
1183                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1184                         print_to(caller, "  No arguments required.");
1185                         return;
1186                 }
1187         }
1188 }
1189
1190 void VoteCommand_yes(int request, entity caller)  // CLIENT ONLY
1191 {
1192         switch (request)
1193         {
1194                 case CMD_REQUEST_COMMAND:
1195                 {
1196                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1197                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1198                         {
1199                                 print_to(caller, "^1You have already voted.");
1200                         }
1201                         else  // everything went okay, continue changing vote
1202                         {
1203                                 print_to(caller, "^1You accepted the vote.");
1204                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1205                                 msg_entity = caller;
1206                                 if (!autocvar_sv_vote_singlecount)
1207                                         VoteCount(false);
1208                         }
1209
1210                         return;
1211                 }
1212
1213                 default:
1214                 case CMD_REQUEST_USAGE:
1215                 {
1216                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1217                         print_to(caller, "  No arguments required.");
1218                         return;
1219                 }
1220         }
1221 }
1222
1223 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1224 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1225 void VoteCommand_(int request)
1226 {
1227     switch(request)
1228     {
1229         case CMD_REQUEST_COMMAND:
1230         {
1231
1232             return;
1233         }
1234
1235         default:
1236         case CMD_REQUEST_USAGE:
1237         {
1238             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1239             print_to(caller, "  No arguments required.");
1240             return;
1241         }
1242     }
1243 }
1244 */
1245
1246
1247 // ================================
1248 //  Macro system for vote commands
1249 // ================================
1250
1251 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1252 #define VOTE_COMMANDS(request, caller, arguments, command) \
1253         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1254         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1255         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1256         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1257         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1258         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1259         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1260         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1261         /* nothing */
1262
1263 void VoteCommand_macro_help(entity caller, int argc)
1264 {
1265         string command_origin = GetCommandPrefix(caller);
1266
1267         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1268         {
1269                 print_to(caller, "\nVoting commands:\n");
1270                 #define VOTE_COMMAND(name, function, description, assignment) \
1271                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1272
1273                 VOTE_COMMANDS(0, caller, 0, "");
1274                 #undef VOTE_COMMAND
1275
1276                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote <command>^7, where possible commands are listed above.\n"));
1277                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help <command>"));
1278                 print_available_commands_to(caller);
1279         }
1280         else  // usage for individual command
1281         {
1282                 #define VOTE_COMMAND(name, function, description, assignment) \
1283                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1284
1285                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1286                 #undef VOTE_COMMAND
1287
1288                 string cvarname = strcat("sv_vote_command_help_", argv(2));
1289                 if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
1290                         wordwrap_sprint(caller, cvar_string(cvarname), 1000);
1291                 else if (argv(2) != "")
1292                         print_to(caller, "No documentation exists for this vote");
1293         }
1294 }
1295
1296 float VoteCommand_macro_command(entity caller, int argc, string vote_command)
1297 {
1298         #define VOTE_COMMAND(name, function, description, assignment) \
1299                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1300
1301         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1302         #undef VOTE_COMMAND
1303
1304         return false;
1305 }
1306
1307
1308 // ======================================
1309 //  Main function handling vote commands
1310 // ======================================
1311
1312 void VoteCommand(int request, entity caller, int argc, string vote_command)
1313 {
1314         // Guide for working with argc arguments by example:
1315         // argc:   1    - 2      - 3     - 4
1316         // argv:   0    - 1      - 2     - 3
1317         // cmd     vote - master - login - password
1318
1319         switch (request)
1320         {
1321                 case CMD_REQUEST_COMMAND:
1322                 {
1323                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1324                 }
1325
1326                 default:
1327                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1328                 case CMD_REQUEST_USAGE:
1329                 {
1330                         VoteCommand_macro_help(caller, argc);
1331                         return;
1332                 }
1333         }
1334 }