qcsrc/server/command/sv_cmd.qc

   1 #include "sv_cmd.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/effects/all.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/mapinfo.qh>
   7 #include <common/monsters/sv_monsters.qh>
   8 #include <common/net_linked.qh>
   9 #include <common/notifications/all.qh>
  10 #include <common/teams.qh>
  11 #include <common/util.qh>
  12 #include <server/anticheat.qh>
  13 #include <server/bot/api.qh>
  14 #include <server/campaign.qh>
  15 #include <server/client.qh>
  16 #include <server/command/_mod.qh>
  17 #include <server/command/banning.qh>
  18 #include <server/command/cmd.qh>
  19 #include <server/command/common.qh>
  20 #include <server/command/getreplies.qh>
  21 #include <server/command/radarmap.qh>
  22 #include <server/intermission.qh>
  23 #include <server/ipban.qh>
  24 #include <server/mutators/_mod.qh>
  25 #include <server/player.qh>
  26 #include <server/teamplay.qh>
  27 #include <server/world.qh>
  28
  29 //  used by GameCommand_make_mapinfo()
  30 void make_mapinfo_Think(entity this)
  31 {
  32         if (_MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
  33         {
  34                 LOG_INFO("Done rebuiling mapinfos.");
  35                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  36                 delete(this);
  37         }
  38         else
  39         {
  40                 setthink(this, make_mapinfo_Think);
  41                 this.nextthink = time;
  42         }
  43 }
  44
  45 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
  46 void changematchtime(float delta, float mi, float ma)
  47 {
  48         float cur;
  49         float update;
  50         float lim;
  51
  52         if (delta == 0) return;
  53         if (autocvar_timelimit < 0) return;
  54
  55         if (mi <= 10) mi = 10;  // at least ten sec in the future
  56         cur = time - game_starttime;
  57         if (cur > 0) mi += cur; // from current time!
  58
  59         lim = autocvar_timelimit * 60;
  60
  61         if (delta > 0)
  62         {
  63                 if (lim == 0) return; // cannot increase any further
  64                 else if (lim < ma) update = min(ma, lim + delta);
  65                 else                  // already above maximum: FAIL
  66                         return;
  67         }
  68         else
  69         {
  70                 if (lim == 0)      // infinite: try reducing to max, if we are allowed to
  71                         update = max(mi, ma);
  72                 else if (lim > mi) // above minimum: decrease
  73                         update = max(mi, lim + delta);
  74                 else               // already below minimum: FAIL
  75                         return;
  76         }
  77
  78         cvar_set("timelimit", ftos(update / 60));
  79 }
  80
  81
  82 // =======================
  83 //  Command Sub-Functions
  84 // =======================
  85
  86 void GameCommand_adminmsg(int request, int argc)
  87 {
  88         switch (request)
  89         {
  90                 case CMD_REQUEST_COMMAND:
  91                 {
  92                         entity client;
  93                         float accepted;
  94
  95                         string targets = strreplace(",", " ", argv(1));
  96                         string original_targets = strreplace(" ", ", ", targets);
  97                         string admin_message = argv(2);
  98                         float infobartime = stof(argv(3));
  99
 100                         string successful, t;
 101                         successful = string_null;
 102
 103                         if ((targets) && (admin_message))
 104                         {
 105                                 for ( ; targets; )
 106                                 {
 107                                         t = car(targets);
 108                                         targets = cdr(targets);
 109
 110                                         // Check to see if the player is a valid target
 111                                         client = GetFilteredEntity(t);
 112                                         accepted = VerifyClientEntity(client, true, false);
 113
 114                                         if (accepted <= 0)
 115                                         {
 116                                                 LOG_INFO("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : "."));
 117                                                 continue;
 118                                         }
 119
 120                                         // send the centerprint/console print or infomessage
 121                                         if (infobartime)
 122                                         {
 123                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
 124                                         }
 125                                         else
 126                                         {
 127                                                 centerprint(client, strcat("^3", GetCallerName(NULL), ":\n^7", admin_message));
 128                                                 sprint(client, strcat("\{1}\{13}^3", GetCallerName(NULL), "^7: ", admin_message, "\n"));
 129                                         }
 130
 131                                         successful = strcat(successful, (successful ? ", " : ""), playername(client.netname, client.team, false));
 132                                         LOG_TRACE("Message sent to ", playername(client.netname, client.team, false));
 133                                         continue;
 134                                 }
 135
 136                                 if (successful) bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
 137                                 else LOG_INFO("No players given (", original_targets, ") could receive the message.");
 138
 139                                 return;
 140                         }
 141                 }
 142
 143                 default:
 144                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 145                 case CMD_REQUEST_USAGE:
 146                 {
 147                         LOG_HELP("Usage:^3 sv_cmd adminmsg <clients> \"<message>\" [<infobartime>]");
 148                         LOG_HELP("  <clients> is a list (separated by commas) of player entity ID's or nicknames");
 149                         LOG_HELP("  If <infobartime> is provided, the message will be sent to infobar.");
 150                         LOG_HELP("  Otherwise, it will just be sent as a centerprint message.");
 151                         LOG_HELP("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10");
 152                         LOG_HELP("          adminmsg 2,5 \"this message will be a centerprint\"");
 153                         return;
 154                 }
 155         }
 156 }
 157
 158 void GameCommand_allready(int request)
 159 {
 160         switch (request)
 161         {
 162                 case CMD_REQUEST_COMMAND:
 163                 {
 164                         ReadyRestart();
 165                         return;
 166                 }
 167
 168                 default:
 169                 case CMD_REQUEST_USAGE:
 170                 {
 171                         LOG_HELP("Usage:^3 sv_cmd allready");
 172                         LOG_HELP("  No arguments required.");
 173                         return;
 174                 }
 175         }
 176 }
 177
 178 void GameCommand_allspec(int request, int argc)
 179 {
 180         switch (request)
 181         {
 182                 case CMD_REQUEST_COMMAND:
 183                 {
 184                         string reason = argv(1);
 185                         int n = 0;
 186                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 187                                 if (it.caplayer) it.caplayer = 0;
 188                                 PutObserverInServer(it);
 189                                 ++n;
 190                         });
 191                         if (n)   bprint(strcat("Successfully forced all (", ftos(n), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n"));
 192                         else   LOG_INFO("No players found to spectate.");
 193                         return;
 194                 }
 195
 196                 default:
 197                 case CMD_REQUEST_USAGE:
 198                 {
 199                         LOG_HELP("Usage:^3 sv_cmd allspec [<reason>]");
 200                         LOG_HELP("  Where <reason> is an optional argument for explanation of allspec command.");
 201                         LOG_HELP("See also: ^2moveplayer, shuffleteams^7");
 202                         return;
 203                 }
 204         }
 205 }
 206
 207 void GameCommand_anticheat(int request, int argc)
 208 {
 209         switch (request)
 210         {
 211                 case CMD_REQUEST_COMMAND:
 212                 {
 213                         entity client = GetIndexedEntity(argc, 1);
 214                         float accepted = VerifyClientEntity(client, false, false);
 215
 216                         if (accepted > 0)
 217                         {
 218                                 anticheat_report_to_eventlog(client);
 219                                 return;
 220                         }
 221                         else
 222                         {
 223                                 LOG_INFO("anticheat: ", GetClientErrorString(accepted, argv(1)), ".");
 224                         }
 225                 }
 226
 227                 default:
 228                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 229                 case CMD_REQUEST_USAGE:
 230                 {
 231                         LOG_HELP("Usage:^3 sv_cmd anticheat <client>");
 232                         LOG_HELP("  <client> is the entity number or name of the player.");
 233                         return;
 234                 }
 235         }
 236 }
 237
 238 void GameCommand_bbox(int request)
 239 {
 240         switch (request)
 241         {
 242                 case CMD_REQUEST_COMMAND:
 243                 {
 244                         vector size_min = '0 0 0';
 245                         vector size_max = '0 0 0';
 246                         tracebox('1 0 0' * world.absmin.x,
 247                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 248                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 249                                 '1 0 0' * world.absmax.x,
 250                                 MOVE_WORLDONLY,
 251                                 NULL);
 252                         size_min.x = (trace_startsolid) ? world.absmin.x : trace_endpos.x;
 253
 254                         tracebox('0 1 0' * world.absmin.y,
 255                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 256                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 257                                 '0 1 0' * world.absmax.y,
 258                                 MOVE_WORLDONLY,
 259                                 NULL);
 260                         size_min.y = (trace_startsolid) ? world.absmin.y : trace_endpos.y;
 261
 262                         tracebox('0 0 1' * world.absmin.z,
 263                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 264                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 265                                 '0 0 1' * world.absmax.z,
 266                                 MOVE_WORLDONLY,
 267                                 NULL);
 268                         size_min.z = (trace_startsolid) ? world.absmin.z : trace_endpos.z;
 269
 270                         tracebox('1 0 0' * world.absmax.x,
 271                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 272                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 273                                 '1 0 0' * world.absmin.x,
 274                                 MOVE_WORLDONLY,
 275                                 NULL);
 276                         size_max.x = (trace_startsolid) ? world.absmax.x : trace_endpos.x;
 277
 278                         tracebox('0 1 0' * world.absmax.y,
 279                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 280                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 281                                 '0 1 0' * world.absmin.y,
 282                                 MOVE_WORLDONLY,
 283                                 NULL);
 284                         size_max.y = (trace_startsolid) ? world.absmax.y : trace_endpos.y;
 285
 286                         tracebox('0 0 1' * world.absmax.z,
 287                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 288                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 289                                 '0 0 1' * world.absmin.z,
 290                                 MOVE_WORLDONLY,
 291                                 NULL);
 292                         size_max.z = (trace_startsolid) ? world.absmax.z : trace_endpos.z;
 293
 294                         LOG_INFOF("Original size: %v %v", world.absmin, world.absmax);
 295                         LOG_INFOF("Currently set size: %v %v", world.mins, world.maxs);
 296                         LOG_INFOF("Solid bounding box size: %v %v", size_min, size_max);
 297                         return;
 298                 }
 299
 300                 default:
 301                 case CMD_REQUEST_USAGE:
 302                 {
 303                         LOG_HELP("Usage:^3 sv_cmd bbox");
 304                         LOG_HELP("  No arguments required.");
 305                         LOG_HELP("See also: ^2gettaginfo, trace^7");
 306                         return;
 307                 }
 308         }
 309 }
 310
 311 void GameCommand_bot_cmd(int request, int argc, string command)
 312 {
 313         switch (request)
 314         {
 315                 case CMD_REQUEST_COMMAND:
 316                 {
 317                         entity bot;
 318
 319                         if (argv(1) == "reset")
 320                         {
 321                                 bot_resetqueues();
 322                                 return;
 323                         }
 324                         else if (argv(1) == "setbots")
 325                         {
 326                                 cvar_settemp("bot_vs_human", "0");
 327                                 cvar_settemp("minplayers", "0");
 328                                 cvar_settemp("minplayers_per_team", "0");
 329                                 cvar_settemp("bot_number", "0");
 330                                 bot_fixcount();
 331                                 cvar_settemp("bot_number", argv(2));
 332                                 if (!bot_fixcount()) LOG_INFO("Sorry, could not set requested bot count");
 333                                 return;
 334                         }
 335                         else if (argv(1) == "load" && argc == 3)
 336                         {
 337                                 float fh, i;
 338                                 string s;
 339                                 fh = fopen(argv(2), FILE_READ);
 340                                 if (fh < 0)
 341                                 {
 342                                         LOG_INFO("cannot open the file");
 343                                         return;
 344                                 }
 345
 346                                 i = 0;
 347                                 while ((s = fgets(fh)))
 348                                 {
 349                                         argc = tokenize_console(s);
 350
 351                                         if (argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 352                                         {
 353                                                 if (argv(2) == "reset")
 354                                                 {
 355                                                         bot_resetqueues();
 356                                                 }
 357                                                 else if (argv(2) == "setbots")
 358                                                 {
 359                                                         cvar_settemp("bot_vs_human", "0");
 360                                                         cvar_settemp("minplayers", "0");
 361                                                         cvar_settemp("minplayers_per_team", "0");
 362                                                         cvar_settemp("bot_number", "0");
 363                                                         bot_fixcount();
 364                                                         cvar_settemp("bot_number", argv(3));
 365                                                         if (!bot_fixcount()) LOG_INFO("Sorry, could not set requested bot count");
 366                                                 }
 367                                                 else
 368                                                 {
 369                                                         if(argv(2) == "*" || argv(2) == "all")
 370                                                                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 371                                                                         bot_queuecommand(it, substring(s, argv_start_index(3), -1));
 372                                                                 });
 373                                                         else
 374                                                         {
 375                                                                 bot = find_bot_by_number(stof(argv(2)));
 376                                                                 if (bot == NULL) bot = find_bot_by_name(argv(2));
 377                                                                 if (bot) bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
 378                                                         }
 379                                                 }
 380                                         }
 381                                         else
 382                                         {
 383                                                 localcmd(strcat(s, "\n"));
 384                                         }
 385
 386                                         ++i;
 387                                 }
 388                                 LOG_INFO(ftos(i), " commands read");
 389                                 fclose(fh);
 390                                 return;
 391                         }
 392                         else if (argv(1) == "help")
 393                         {
 394                                 if (argv(2)) bot_cmdhelp(argv(2));
 395                                 else bot_list_commands();
 396                                 return;
 397                         }
 398                         else if (argc >= 3)  // this comes last
 399                         {
 400                                 if(argv(1) == "*" || argv(1) == "all")
 401                                 {
 402                                         int bot_num = 0;
 403                                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 404                                                 bot_queuecommand(it, substring(command, argv_start_index(2), -1));
 405                                                 bot_num++;
 406                                         });
 407                                         if(bot_num)
 408                                                 LOG_INFO("Command '", substring(command, argv_start_index(2), -1), "' sent to all bots (", ftos(bot_num), ")");
 409                                         return;
 410                                 }
 411                                 else
 412                                 {
 413                                         bot = find_bot_by_number(stof(argv(1)));
 414                                         if (bot == NULL) bot = find_bot_by_name(argv(1));
 415                                         if (bot)
 416                                         {
 417                                                 LOG_INFO("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname);
 418                                                 bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
 419                                                 return;
 420                                         }
 421                                         else
 422                                         {
 423                                                 LOG_INFO("Error: Can't find bot with the name or id '", argv(1), "' - Did you mistype the command?");  // don't return so that usage is shown
 424                                         }
 425                                 }
 426                         }
 427                 }
 428
 429                 default:
 430                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 431                 case CMD_REQUEST_USAGE:
 432                 {
 433                         LOG_HELP("Usage:^3 sv_cmd bot_cmd <client> <command> [<arguments>]");
 434                         LOG_HELP("  <client> can be either the name of the bot or a progressive number (not the entity number!)");
 435                         LOG_HELP("           can also be '*' or 'all' to allow sending the command to all the bots");
 436                         LOG_HELP("  For full list of commands, see bot_cmd help [<command>].");
 437                         LOG_HELP("Examples: sv_cmd bot_cmd 1 cc \"say something\"");
 438                         LOG_HELP("          sv_cmd bot_cmd 1 presskey jump");
 439                         LOG_HELP("          sv_cmd bot_cmd * pause");
 440                         return;
 441                 }
 442         }
 443 }
 444
 445 void GameCommand_cointoss(int request, int argc)
 446 {
 447         switch (request)
 448         {
 449                 case CMD_REQUEST_COMMAND:
 450                 {
 451                         string result1 = (argv(2) ? strcat("^7", argv(1)) : "^1HEADS");
 452                         string result2 = (argv(2) ? strcat("^7", argv(2)) : "^4TAILS");
 453                         string choice = ((random() > 0.5) ? result1 : result2);
 454
 455                         Send_Notification(NOTIF_ALL, NULL, MSG_MULTI, MULTI_COINTOSS, choice);
 456                         return;
 457                 }
 458
 459                 default:
 460                 case CMD_REQUEST_USAGE:
 461                 {
 462                         LOG_HELP("Usage:^3 sv_cmd cointoss [<result1> <result2>]");
 463                         LOG_HELP("  Where <result1> and <result2> are user created options.");
 464                         return;
 465                 }
 466         }
 467 }
 468
 469 void GameCommand_database(int request, int argc)
 470 {
 471         switch (request)
 472         {
 473                 case CMD_REQUEST_COMMAND:
 474                 {
 475                         if (argc == 3)
 476                         {
 477                                 if (argv(1) == "save")
 478                                 {
 479                                         db_save(ServerProgsDB, argv(2));
 480                                         LOG_INFO("Copied serverprogs database to '", argv(2), "' in the data directory.");
 481                                         return;
 482                                 }
 483                                 else if (argv(1) == "dump")
 484                                 {
 485                                         db_dump(ServerProgsDB, argv(2));
 486                                         LOG_INFO("DB dumped.");  // wtf does this do?
 487                                         return;
 488                                 }
 489                                 else if (argv(1) == "load")
 490                                 {
 491                                         db_close(ServerProgsDB);
 492                                         ServerProgsDB = db_load(argv(2));
 493                                         LOG_INFO("Loaded '", argv(2), "' as new serverprogs database.");
 494                                         return;
 495                                 }
 496                         }
 497                 }
 498
 499                 default:
 500                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 501                 case CMD_REQUEST_USAGE:
 502                 {
 503                         LOG_HELP("Usage:^3 sv_cmd database <action> <filename>");
 504                         LOG_HELP("  Where <action> is the command to complete,");
 505                         LOG_HELP("  and <filename> is what it acts upon.");
 506                         LOG_HELP("  Full list of commands here: save, dump, load.");
 507                         return;
 508                 }
 509         }
 510 }
 511
 512 void GameCommand_defer_clear(int request, int argc)
 513 {
 514         switch (request)
 515         {
 516                 case CMD_REQUEST_COMMAND:
 517                 {
 518                         entity client;
 519                         float accepted;
 520
 521                         if (argc >= 2)
 522                         {
 523                                 client = GetIndexedEntity(argc, 1);
 524                                 accepted = VerifyClientEntity(client, true, false);
 525
 526                                 if (accepted > 0)
 527                                 {
 528                                         stuffcmd(client, "defer clear\n");
 529                                         LOG_INFO("defer clear stuffed to ", playername(client.netname, client.team, false));
 530                                 }
 531                                 else { LOG_INFO("defer_clear: ", GetClientErrorString(accepted, argv(1)), "."); }
 532
 533                                 return;
 534                         }
 535                 }
 536
 537                 default:
 538                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 539                 case CMD_REQUEST_USAGE:
 540                 {
 541                         LOG_HELP("Usage:^3 sv_cmd defer_clear <client>");
 542                         LOG_HELP("  <client> is the entity number or name of the player.");
 543                         LOG_HELP("See also: ^2defer_clear_all^7");
 544                         return;
 545                 }
 546         }
 547 }
 548
 549 void GameCommand_defer_clear_all(int request)
 550 {
 551         switch (request)
 552         {
 553                 case CMD_REQUEST_COMMAND:
 554                 {
 555                         int n = 0;
 556                         int argc;
 557
 558                         FOREACH_CLIENT(true, {
 559                                 argc = tokenize_console(strcat("defer_clear ", ftos(etof(it))));
 560                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
 561                                 ++n;
 562                         });
 563                         if (n)   LOG_INFO("Successfully stuffed defer clear to all clients (", ftos(n), ")");  // should a message be added if no players were found?
 564                         return;
 565                 }
 566
 567                 default:
 568                 case CMD_REQUEST_USAGE:
 569                 {
 570                         LOG_HELP("Usage:^3 sv_cmd defer_clear_all");
 571                         LOG_HELP("  No arguments required.");
 572                         LOG_HELP("See also: ^2defer_clear^7");
 573                         return;
 574                 }
 575         }
 576 }
 577
 578 void GameCommand_delrec(int request, int argc)  // perhaps merge later with records and printstats and such?
 579 {
 580         switch (request)
 581         {
 582                 case CMD_REQUEST_COMMAND:
 583                 {
 584                         if (argv(1))
 585                         {
 586                                 if (argv(2)) race_deleteTime(argv(2), stof(argv(1)));
 587                                 else race_deleteTime(GetMapname(), stof(argv(1)));
 588                                 return;
 589                         }
 590                 }
 591
 592                 default:
 593                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 594                 case CMD_REQUEST_USAGE:
 595                 {
 596                         LOG_HELP("Usage:^3 sv_cmd delrec <ranking> [<map>]");
 597                         LOG_HELP("  <ranking> is which ranking level to clear up to, ");
 598                         LOG_HELP("  it will clear all records up to nth place.");
 599                         LOG_HELP("  if <map> is not provided it will use current map.");
 600                         return;
 601                 }
 602         }
 603 }
 604
 605 void print_Effect_Index(int d, string effect_name)
 606 {
 607         // this is inside a function to avoid expanding it on compilation everytime
 608         LOG_INFO("effect ", effect_name, " is ", ftos(_particleeffectnum(effect_name)), "\n");
 609         db_put(d, effect_name, "1");
 610 }
 611
 612 void GameCommand_effectindexdump(int request)
 613 {
 614         switch (request)
 615         {
 616                 case CMD_REQUEST_COMMAND:
 617                 {
 618                         float fh, d;
 619                         string s;
 620
 621                         d = db_create();
 622                         LOG_INFO("begin of effects list");
 623
 624                         print_Effect_Index(d, "TE_GUNSHOT");
 625                         print_Effect_Index(d, "TE_GUNSHOTQUAD");
 626                         print_Effect_Index(d, "TE_SPIKE");
 627                         print_Effect_Index(d, "TE_SPIKEQUAD");
 628                         print_Effect_Index(d, "TE_SUPERSPIKE");
 629                         print_Effect_Index(d, "TE_SUPERSPIKEQUAD");
 630                         print_Effect_Index(d, "TE_WIZSPIKE");
 631                         print_Effect_Index(d, "TE_KNIGHTSPIKE");
 632                         print_Effect_Index(d, "TE_EXPLOSION");
 633                         print_Effect_Index(d, "TE_EXPLOSIONQUAD");
 634                         print_Effect_Index(d, "TE_TAREXPLOSION");
 635                         print_Effect_Index(d, "TE_TELEPORT");
 636                         print_Effect_Index(d, "TE_LAVASPLASH");
 637                         print_Effect_Index(d, "TE_SMALLFLASH");
 638                         print_Effect_Index(d, "TE_FLAMEJET");
 639                         print_Effect_Index(d, "EF_FLAME");
 640                         print_Effect_Index(d, "TE_BLOOD");
 641                         print_Effect_Index(d, "TE_SPARK");
 642                         print_Effect_Index(d, "TE_PLASMABURN");
 643                         print_Effect_Index(d, "TE_TEI_G3");
 644                         print_Effect_Index(d, "TE_TEI_SMOKE");
 645                         print_Effect_Index(d, "TE_TEI_BIGEXPLOSION");
 646                         print_Effect_Index(d, "TE_TEI_PLASMAHIT");
 647                         print_Effect_Index(d, "EF_STARDUST");
 648                         print_Effect_Index(d, "TR_ROCKET");
 649                         print_Effect_Index(d, "TR_GRENADE");
 650                         print_Effect_Index(d, "TR_BLOOD");
 651                         print_Effect_Index(d, "TR_WIZSPIKE");
 652                         print_Effect_Index(d, "TR_SLIGHTBLOOD");
 653                         print_Effect_Index(d, "TR_KNIGHTSPIKE");
 654                         print_Effect_Index(d, "TR_VORESPIKE");
 655                         print_Effect_Index(d, "TR_NEHAHRASMOKE");
 656                         print_Effect_Index(d, "TR_NEXUIZPLASMA");
 657                         print_Effect_Index(d, "TR_GLOWTRAIL");
 658                         print_Effect_Index(d, "TR_SEEKER");
 659                         print_Effect_Index(d, "SVC_PARTICLE");
 660
 661                         fh = fopen("effectinfo.txt", FILE_READ);
 662                         while ((s = fgets(fh)))
 663                         {
 664                                 tokenize_console(s);
 665                                 if (argv(0) == "effect")
 666                                 {
 667                                         if (db_get(d, argv(1)) != "1")
 668                                         {
 669                                                 int i = _particleeffectnum(argv(1));
 670                                                 if (i >= 0) LOG_INFO("effect ", argv(1), " is ", ftos(i));
 671                                                 db_put(d, argv(1), "1");
 672                                         }
 673                                 }
 674                         }
 675                         LOG_INFO("end of effects list");
 676
 677                         db_close(d);
 678                         return;
 679                 }
 680
 681                 default:
 682                 case CMD_REQUEST_USAGE:
 683                 {
 684                         LOG_HELP("Usage:^3 sv_cmd effectindexdump");
 685                         LOG_HELP("  No arguments required.");
 686                         return;
 687                 }
 688         }
 689 }
 690
 691 void GameCommand_extendmatchtime(int request)
 692 {
 693         switch (request)
 694         {
 695                 case CMD_REQUEST_COMMAND:
 696                 {
 697                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
 698                         return;
 699                 }
 700
 701                 default:
 702                 case CMD_REQUEST_USAGE:
 703                 {
 704                         LOG_HELP("Usage:^3 sv_cmd extendmatchtime");
 705                         LOG_HELP("  No arguments required.");
 706                         LOG_HELP("See also: ^2reducematchtime^7");
 707                         return;
 708                 }
 709         }
 710 }
 711
 712 void GameCommand_gametype(int request, int argc)
 713 {
 714         switch (request)
 715         {
 716                 case CMD_REQUEST_COMMAND:
 717                 {
 718                         if (!world_initialized)
 719                         {
 720                                 LOG_INFOF("This command works only when the server is running.");
 721                                 return;
 722                         }
 723                         if (argv(1) != "")
 724                         {
 725                                 string s = argv(1);
 726                                 Gametype t = MapInfo_Type_FromString(s, false), tsave = MapInfo_CurrentGametype();
 727
 728                                 if (t)
 729                                 {
 730                                         MapInfo_SwitchGameType(t);
 731                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 732                                         if (MapInfo_count > 0)
 733                                         {
 734                                                 // update lsmaps in case the gametype changed, this way people can easily list maps for it
 735                                                 if (lsmaps_reply != "")   strunzone(lsmaps_reply);
 736                                                 lsmaps_reply = strzone(getlsmaps());
 737                                                 bprint("Game type successfully switched to ", s, "\n");
 738                                         }
 739                                         else
 740                                         {
 741                                                 bprint("Cannot use this game type: no map for it found\n");
 742                                                 MapInfo_SwitchGameType(tsave);
 743                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 744                                         }
 745                                 }
 746                                 else
 747                                 {
 748                                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 749                                 }
 750
 751                                 return;
 752                         }
 753                 }
 754
 755                 default:
 756                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 757                 case CMD_REQUEST_USAGE:
 758                 {
 759                         LOG_HELP("Usage:^3 sv_cmd gametype <mode>");
 760                         LOG_HELP("  Where <mode> is the gametype mode to switch to.");
 761                         LOG_HELP("See also: ^2gotomap^7");
 762                         return;
 763                 }
 764         }
 765 }
 766
 767 void GameCommand_gettaginfo(int request, int argc)
 768 {
 769         switch (request)
 770         {
 771                 case CMD_REQUEST_COMMAND:
 772                 {
 773                         entity tmp_entity;
 774                         float i;
 775                         vector v;
 776
 777                         if (argc >= 4)
 778                         {
 779                                 tmp_entity = spawn();
 780                                 if (argv(1) == "w")
 781                                 {
 782                                         .entity weaponentity = weaponentities[0];
 783                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
 784                                 }
 785                                 else
 786                                 {
 787                                         precache_model(argv(1));
 788                                         _setmodel(tmp_entity, argv(1));
 789                                 }
 790                                 tmp_entity.frame = stof(argv(2));
 791                                 if (substring(argv(3), 0, 1) == "#") i = stof(substring(argv(3), 1, -1));
 792                                 else i = gettagindex(tmp_entity, argv(3));
 793                                 if (i)
 794                                 {
 795                                         v = gettaginfo(tmp_entity, i);
 796                                         LOG_HELPF("model %s frame %s tag %s index %s parent %s",
 797                                                 tmp_entity.model, ftos(tmp_entity.frame), gettaginfo_name, ftos(i), ftos(gettaginfo_parent)
 798                                         );
 799                                         LOG_HELPF(" vector = %s %s %s", ftos(v.x), ftos(v.y), ftos(v.z));
 800                                         LOG_HELPF(" offset = %s %s %s", ftos(gettaginfo_offset.x), ftos(gettaginfo_offset.y), ftos(gettaginfo_offset.z));
 801                                         LOG_HELPF(" forward = %s %s %s", ftos(gettaginfo_forward.x), ftos(gettaginfo_forward.y), ftos(gettaginfo_forward.z));
 802                                         LOG_HELPF(" right = %s %s %s", ftos(gettaginfo_right.x), ftos(gettaginfo_right.y), ftos(gettaginfo_right.z));
 803                                         LOG_HELPF(" up = %s %s %s", ftos(gettaginfo_up.x), ftos(gettaginfo_up.y), ftos(gettaginfo_up.z));
 804                                         if (argc >= 6)
 805                                         {
 806                                                 v.y = -v.y;
 807                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
 808                                         }
 809                                 }
 810                                 else
 811                                 {
 812                                         LOG_INFO("bone not found");
 813                                 }
 814
 815                                 delete(tmp_entity);
 816                                 return;
 817                         }
 818                 }
 819
 820                 default:
 821                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 822                 case CMD_REQUEST_USAGE:
 823                 {
 824                         LOG_HELP("Usage:^3 sv_cmd gettaginfo <model> <frame> <index> [<command1>] [<command2>]");
 825                         LOG_HELP("See also: ^2bbox, trace^7");
 826                         return;
 827                 }
 828         }
 829 }
 830
 831 void GameCommand_animbench(int request, int argc)
 832 {
 833         switch (request)
 834         {
 835                 case CMD_REQUEST_COMMAND:
 836                 {
 837                         entity tmp_entity;
 838
 839                         if (argc >= 4)
 840                         {
 841                                 tmp_entity = spawn();
 842                                 if (argv(1) == "w")
 843                                 {
 844                                         .entity weaponentity = weaponentities[0];
 845                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
 846                                 }
 847                                 else
 848                                 {
 849                                         precache_model(argv(1));
 850                                         _setmodel(tmp_entity, argv(1));
 851                                 }
 852                                 float f1 = stof(argv(2));
 853                                 float f2 = stof(argv(3));
 854                                 float t0;
 855                                 float t1 = 0;
 856                                 float t2 = 0;
 857                                 float n = 0;
 858
 859                                 while (t1 + t2 < 1)
 860                                 {
 861                                         tmp_entity.frame = f1;
 862                                         t0 = gettime(GETTIME_HIRES);
 863                                         getsurfacepoint(tmp_entity, 0, 0);
 864                                         t1 += gettime(GETTIME_HIRES) - t0;
 865                                         tmp_entity.frame = f2;
 866                                         t0 = gettime(GETTIME_HIRES);
 867                                         getsurfacepoint(tmp_entity, 0, 0);
 868                                         t2 += gettime(GETTIME_HIRES) - t0;
 869                                         n += 1;
 870                                 }
 871                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s");
 872                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s");
 873
 874                                 delete(tmp_entity);
 875                                 return;
 876                         }
 877                 }
 878
 879                 default:
 880                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 881                 case CMD_REQUEST_USAGE:
 882                 {
 883                         LOG_HELP("Usage:^3 sv_cmd animbench <model> <frame1> <frame2>");
 884                         LOG_HELP("See also: ^2bbox, trace^7");
 885                         return;
 886                 }
 887         }
 888 }
 889
 890 void GameCommand_gotomap(int request, int argc)
 891 {
 892         switch (request)
 893         {
 894                 case CMD_REQUEST_COMMAND:
 895                 {
 896                         if (!world_initialized)
 897                         {
 898                                 LOG_INFOF("This command works only when the server is running.");
 899                                 return;
 900                         }
 901                         if (argv(1))
 902                         {
 903                                 LOG_INFO(GotoMap(argv(1)));
 904                                 return;
 905                         }
 906                 }
 907
 908                 default:
 909                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 910                 case CMD_REQUEST_USAGE:
 911                 {
 912                         LOG_HELP("Usage:^3 sv_cmd gotomap <map>");
 913                         LOG_HELP("  Where <map> is the *.bsp file to change to.");
 914                         LOG_HELP("See also: ^2gametype^7");
 915                         return;
 916                 }
 917         }
 918 }
 919
 920 void GameCommand_lockteams(int request)
 921 {
 922         switch (request)
 923         {
 924                 case CMD_REQUEST_COMMAND:
 925                 {
 926                         if (teamplay)
 927                         {
 928                                 lockteams = 1;
 929                                 bprint("^1The teams are now locked.\n");
 930                         }
 931                         else
 932                         {
 933                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
 934                         }
 935                         return;
 936                 }
 937
 938                 default:
 939                 case CMD_REQUEST_USAGE:
 940                 {
 941                         LOG_HELP("Usage:^3 sv_cmd lockteams");
 942                         LOG_HELP("  No arguments required.");
 943                         LOG_HELP("See also: ^2unlockteams^7");
 944                         return;
 945                 }
 946         }
 947 }
 948
 949 void GameCommand_make_mapinfo(int request)
 950 {
 951         switch (request)
 952         {
 953                 case CMD_REQUEST_COMMAND:
 954                 {
 955                         entity tmp_entity;
 956
 957                         tmp_entity = new(make_mapinfo);
 958                         setthink(tmp_entity, make_mapinfo_Think);
 959                         tmp_entity.nextthink = time;
 960                         MapInfo_Enumerate();
 961                         return;
 962                 }
 963
 964                 default:
 965                 case CMD_REQUEST_USAGE:
 966                 {
 967                         LOG_HELP("Usage:^3 sv_cmd make_mapinfo");
 968                         LOG_HELP("  No arguments required.");
 969                         LOG_HELP("See also: ^2radarmap^7");
 970                         return;
 971                 }
 972         }
 973 }
 974
 975 void GameCommand_moveplayer(int request, int argc)
 976 {
 977         switch (request)
 978         {
 979                 case CMD_REQUEST_COMMAND:
 980                 {
 981                         float accepted;
 982                         entity client;
 983
 984                         string targets = strreplace(",", " ", argv(1));
 985                         string original_targets = strreplace(" ", ", ", targets);
 986                         string destination = argv(2);
 987                         if (destination == "spec")
 988                                 destination = "spectator";
 989
 990                         if ((targets) && (destination))
 991                         {
 992                                 string successful = string_null;
 993                                 string t;
 994                                 for ( ; targets; )
 995                                 {
 996                                         t = car(targets);
 997                                         targets = cdr(targets);
 998
 999                                         // Check to see if the player is a valid target
1000                                         client = GetFilteredEntity(t);
1001                                         accepted = VerifyClientEntity(client, false, false);
1002
1003                                         if (accepted <= 0)
1004                                         {
1005                                                 LOG_INFO("moveplayer: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : "."));
1006                                         }
1007                                         else if (destination == "spectator")
1008                                         {
1009                                                 string pl_name = playername(client.netname, client.team, false);
1010                                                 if (!IS_SPEC(client) && !IS_OBSERVER(client))
1011                                                 {
1012                                                         if (client.caplayer) client.caplayer = 0;
1013                                                         PutObserverInServer(client);
1014
1015                                                         successful = strcat(successful, (successful ? ", " : ""), pl_name);
1016                                                 }
1017                                                 else
1018                                                 {
1019                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", pl_name, ") is already spectating.");
1020                                                 }
1021                                         }
1022                                         else
1023                                         {
1024                                                 string pl_name = playername(client.netname, client.team, false);
1025                                                 if (IS_SPEC(client) || IS_OBSERVER(client))
1026                                                 {
1027                                                         // well technically we could, but should we allow that? :P
1028                                                         LOG_INFO("Can't change teams if the player isn't in the game.");
1029                                                         return;
1030                                                 }
1031                                                 if (!teamplay)
1032                                                 {
1033                                                         LOG_INFO("Can't change teams when currently not playing a team game.");
1034                                                         return;
1035                                                 }
1036
1037                                                 // set up
1038                                                 int save = Player_GetForcedTeamIndex(client);
1039                                                 Player_SetForcedTeamIndex(client, TEAM_FORCE_DEFAULT);
1040
1041                                                 // find the team to move the player to
1042                                                 int team_num = Team_ColorToTeam(destination);
1043                                                 entity balance;
1044                                                 if (team_num == client.team)  // already on the destination team
1045                                                 {
1046                                                         // keep the forcing undone
1047                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", pl_name, ") is already on the ", Team_ColoredFullName(team_num), (targets ? "^7, skipping to next player.\n" : "^7."));
1048                                                         continue;
1049                                                 }
1050                                                 else if (team_num == 0)  // auto team
1051                                                 {
1052                                                         balance = TeamBalance_CheckAllowedTeams(client);
1053                                                         team_num = Team_IndexToTeam(TeamBalance_FindBestTeam(balance, client, false));
1054                                                 }
1055                                                 else
1056                                                 {
1057                                                         balance = TeamBalance_CheckAllowedTeams(client);
1058                                                 }
1059                                                 Player_SetForcedTeamIndex(client, save);
1060
1061                                                 // Check to see if the destination team is even available
1062                                                 int team_id = Team_TeamToIndex(team_num);
1063                                                 if (team_id == -1)
1064                                                 {
1065                                                         LOG_INFO("Sorry, can't move player here if team ", destination, " doesn't exist.");
1066                                                         TeamBalance_Destroy(balance);
1067                                                         return;
1068                                                 }
1069                                                 if (!TeamBalance_IsTeamAllowed(balance, team_id))
1070                                                 {
1071                                                         LOG_INFOF("Sorry, can't move player to %s team if it doesn't exist.", destination);
1072                                                         TeamBalance_Destroy(balance);
1073                                                         return;
1074                                                 }
1075                                                 TeamBalance_Destroy(balance);
1076
1077                                                 // If so, lets continue and finally move the player
1078                                                 Player_SetForcedTeamIndex(client, TEAM_FORCE_DEFAULT);
1079                                                 if (MoveToTeam(client, team_id, 6))
1080                                                 {
1081                                                         successful = strcat(successful, (successful ? ", " : ""), pl_name);
1082                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", pl_name, ") has been moved to the ", Team_ColoredFullName(team_num), "^7.");
1083                                                 }
1084                                                 else
1085                                                 {
1086                                                         LOG_INFO("Unable to move player ", ftos(GetFilteredNumber(t)), " (", pl_name, ")");
1087                                                 }
1088                                         }
1089                                 } // loop end
1090
1091                                 if (successful) bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1092                                 else LOG_INFO("No players given (", original_targets, ") are able to move.");
1093
1094                                 return;  // still correct parameters so return to avoid usage print
1095                         }
1096                 }
1097
1098                 default:
1099                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1100                 case CMD_REQUEST_USAGE:
1101                 {
1102                         LOG_HELP("Usage:^3 sv_cmd moveplayer <clients> <destination>");
1103                         LOG_HELP("  <clients> is a list (separated by commas) of player entity ID's or nicknames");
1104                         LOG_HELP("  <destination> is what to send the player to, be it team or spectating");
1105                         LOG_HELP("  Full list of destinations here: spec, spectator, red, blue, yellow, pink, auto.");
1106                         LOG_HELP("Examples: sv_cmd moveplayer 1,3,5 red");
1107                         LOG_HELP("          sv_cmd moveplayer 2 spec");
1108                         LOG_HELP("See also: ^2allspec, shuffleteams^7");
1109                         return;
1110                 }
1111         }
1112 }
1113
1114 void GameCommand_nospectators(int request)
1115 {
1116         switch (request)
1117         {
1118                 case CMD_REQUEST_COMMAND:
1119                 {
1120                         blockSpectators = 1;
1121                         // give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1122                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_SPEC(it) || IS_OBSERVER(it)) && !it.caplayer, {
1123                                 if(!it.caplayer)
1124                                 {
1125                                         CS(it).spectatortime = time;
1126                                         Send_Notification(NOTIF_ONE_ONLY, it, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1127                                 }
1128                         });
1129                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1130                         return;
1131                 }
1132
1133                 default:
1134                 case CMD_REQUEST_USAGE:
1135                 {
1136                         LOG_HELP("Usage:^3 sv_cmd nospectators");
1137                         LOG_HELP("  No arguments required.");
1138                         return;
1139                 }
1140         }
1141 }
1142
1143 void GameCommand_printstats(int request)
1144 {
1145         switch (request)
1146         {
1147                 case CMD_REQUEST_COMMAND:
1148                 {
1149                         DumpStats(false);
1150                         LOG_INFO("stats dumped.");
1151                         return;
1152                 }
1153
1154                 default:
1155                 case CMD_REQUEST_USAGE:
1156                 {
1157                         LOG_HELP("Usage:^3 sv_cmd printstats");
1158                         LOG_HELP("  No arguments required.");
1159                         return;
1160                 }
1161         }
1162 }
1163
1164 void GameCommand_radarmap(int request, int argc)
1165 {
1166         switch (request)
1167         {
1168                 case CMD_REQUEST_COMMAND:
1169                 {
1170                         if (RadarMap_Make(argc)) return;
1171                 }
1172
1173                 default:
1174                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1175                 case CMD_REQUEST_USAGE:
1176                 {
1177                         LOG_HELP("Usage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]");
1178                         LOG_HELP("  The quality factor Q is roughly proportional to the time taken.");
1179                         LOG_HELP("  trace supports no quality factor; its result should look like --block with infinite quality factor.");
1180                         LOG_HELP("See also: ^2make_mapinfo^7");
1181                         return;
1182                 }
1183         }
1184 }
1185
1186 void GameCommand_reducematchtime(int request)
1187 {
1188         switch (request)
1189         {
1190                 case CMD_REQUEST_COMMAND:
1191                 {
1192                         changematchtime(autocvar_timelimit_decrement * -60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1193                         return;
1194                 }
1195
1196                 default:
1197                 case CMD_REQUEST_USAGE:
1198                 {
1199                         LOG_HELP("Usage:^3 sv_cmd reducematchtime");
1200                         LOG_HELP("  No arguments required.");
1201                         LOG_HELP("See also: ^2extendmatchtime^7");
1202                         return;
1203                 }
1204         }
1205 }
1206
1207 void GameCommand_setbots(int request, int argc)
1208 {
1209         switch (request)
1210         {
1211                 case CMD_REQUEST_COMMAND:
1212                 {
1213                         if (argc >= 2)
1214                         {
1215                                 cvar_settemp("minplayers", "0");
1216                                 cvar_settemp("minplayers_per_team", "0");
1217                                 cvar_settemp("bot_number", argv(1));
1218                                 bot_fixcount();
1219                                 return;
1220                         }
1221                 }
1222
1223                 default:
1224                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1225                 case CMD_REQUEST_USAGE:
1226                 {
1227                         LOG_HELP("Usage:^3 sv_cmd setbots <botnumber>");
1228                         LOG_HELP("  Where <botnumber> is the amount of bots to set bot_number cvar to.");
1229                         LOG_HELP("See also: ^2bot_cmd^7");
1230                         return;
1231                 }
1232         }
1233 }
1234
1235 void shuffleteams()
1236 {
1237         if (!teamplay)
1238         {
1239                 LOG_INFO("Can't shuffle teams when currently not playing a team game.");
1240                 return;
1241         }
1242
1243         FOREACH_CLIENT(IS_PLAYER(it) || it.caplayer, {
1244                 if (Player_HasRealForcedTeam(it)) {
1245                         // we could theoretically assign forced players to their teams
1246                         // and shuffle the rest to fill the empty spots but in practise
1247                         // either all players or none are gonna have forced teams
1248                         LOG_INFO("Can't shuffle teams because at least one player has a forced team.");
1249                         return;
1250                 }
1251         });
1252
1253         int number_of_teams = 0;
1254         entity balance = TeamBalance_CheckAllowedTeams(NULL);
1255         for (int i = 1; i <= NUM_TEAMS; ++i)
1256         {
1257                 if (TeamBalance_IsTeamAllowed(balance, i))
1258                 {
1259                         number_of_teams = max(i, number_of_teams);
1260                 }
1261         }
1262         TeamBalance_Destroy(balance);
1263
1264         int team_index = 0;
1265         FOREACH_CLIENT_RANDOM(IS_PLAYER(it) || it.caplayer, {
1266                 int target_team_index = team_index + 1;
1267                 if (Entity_GetTeamIndex(it) != target_team_index)
1268                 {
1269                         MoveToTeam(it, target_team_index, 6);
1270                 }
1271                 team_index = (team_index + 1) % number_of_teams;
1272         });
1273
1274         bprint("Successfully shuffled the players around randomly.\n");
1275 }
1276
1277 void GameCommand_shuffleteams(int request)
1278 {
1279         switch (request)
1280         {
1281                 case CMD_REQUEST_COMMAND:
1282                 {
1283                         if (shuffleteams_on_reset_map)
1284                         {
1285                                 bprint("Players will be shuffled when this round is over.\n");
1286                                 shuffleteams_on_reset_map = true;
1287                         }
1288                         else
1289                                 shuffleteams();
1290                         return;
1291                 }
1292
1293                 default:
1294                 case CMD_REQUEST_USAGE:
1295                 {
1296                         LOG_HELP("Usage:^3 sv_cmd shuffleteams");
1297                         LOG_HELP("  No arguments required.");
1298                         LOG_HELP("See also: ^2moveplayer, allspec^7");
1299                         return;
1300                 }
1301         }
1302 }
1303
1304 void GameCommand_stuffto(int request, int argc)
1305 {
1306         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1307         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1308         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1309
1310 #ifdef STUFFTO_ENABLED
1311                 switch (request)
1312                 {
1313                         case CMD_REQUEST_COMMAND:
1314                         {
1315                                 if (argv(2))
1316                                 {
1317                                         entity client = GetIndexedEntity(argc, 1);
1318                                         float accepted = VerifyClientEntity(client, true, false);
1319
1320                                         if (accepted > 0)
1321                                         {
1322                                                 stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1323                                                 LOG_INFO("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1), ").");
1324                                         }
1325                                         else
1326                                         {
1327                                                 LOG_INFO("stuffto: ", GetClientErrorString(accepted, argv(1)), ".");
1328                                         }
1329
1330                                         return;
1331                                 }
1332                         }
1333
1334                         default:
1335                                 LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1336                         case CMD_REQUEST_USAGE:
1337                         {
1338                                 LOG_HELP("Usage:^3 sv_cmd stuffto <client> \"<command>\"");
1339                                 LOG_HELP("  <client> is the entity number or name of the player,");
1340                                 LOG_HELP("  and <command> is the command to be sent to that player.");
1341                                 return;
1342                         }
1343                 }
1344 #else
1345                 if (request)
1346                 {
1347                         LOG_HELP("stuffto command is not enabled on this server.");
1348                         return;
1349                 }
1350 #endif
1351 }
1352
1353 void GameCommand_trace(int request, int argc)
1354 {
1355         switch (request)
1356         {
1357                 case CMD_REQUEST_COMMAND:
1358                 {
1359                         entity e;
1360                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1361                         float i, f, safe, unsafe, dq, dqf;
1362
1363                         switch (argv(1))
1364                         {
1365                                 case "debug":
1366                                 {
1367                                         float hitcount = 0;
1368                                         LOG_INFO("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.");
1369                                         float worst_endpos_bug = 0;
1370                                         for ( ; ; )
1371                                         {
1372                                                 org = world.mins;
1373                                                 delta = world.maxs - world.mins;
1374
1375                                                 start.x = org.x + random() * delta.x;
1376                                                 start.y = org.y + random() * delta.y;
1377                                                 start.z = org.z + random() * delta.z;
1378
1379                                                 end.x = org.x + random() * delta.x;
1380                                                 end.y = org.y + random() * delta.y;
1381                                                 end.z = org.z + random() * delta.z;
1382
1383                                                 start = stov(vtos(start));
1384                                                 end = stov(vtos(end));
1385
1386                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1387                                                 if (!trace_startsolid && trace_fraction < 1)
1388                                                 {
1389                                                         p = trace_endpos;
1390                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, p, MOVE_NOMONSTERS, NULL);
1391                                                         if (trace_startsolid)
1392                                                         {
1393                                                                 rint(42);  // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1394                                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1395
1396                                                                 // how much do we need to back off?
1397                                                                 safe = 1;
1398                                                                 unsafe = 0;
1399                                                                 for ( ; ; )
1400                                                                 {
1401                                                                         pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1402                                                                         tracebox(pos, PL_MIN_CONST, PL_MAX_CONST, pos, MOVE_NOMONSTERS, NULL);
1403                                                                         if (trace_startsolid)
1404                                                                         {
1405                                                                                 if ((safe + unsafe) * 0.5 == unsafe) break;
1406                                                                                 unsafe = (safe + unsafe) * 0.5;
1407                                                                         }
1408                                                                         else
1409                                                                         {
1410                                                                                 if ((safe + unsafe) * 0.5 == safe) break;
1411                                                                                 safe = (safe + unsafe) * 0.5;
1412                                                                         }
1413                                                                 }
1414
1415                                                                 LOG_INFO("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu");
1416                                                                 LOG_INFO("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu");
1417
1418                                                                 tracebox(p, PL_MIN_CONST + '0.1 0.1 0.1', PL_MAX_CONST - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, NULL);
1419                                                                 if (trace_startsolid) LOG_INFO("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1420                                                                 else LOG_INFO("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1421                                                                 if (++hitcount >= 10) break;
1422                                                         }
1423                                                         else
1424                                                         {
1425                                                                 q0 = p;
1426                                                                 dq = 0;
1427                                                                 dqf = 1;
1428                                                                 for ( ; ; )
1429                                                                 {
1430                                                                         q = p + normalize(end - p) * (dq + dqf);
1431                                                                         if (q == q0) break;
1432                                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, q, MOVE_NOMONSTERS, NULL);
1433                                                                         if (trace_startsolid) error("THIS ONE cannot happen");
1434                                                                         if (trace_fraction > 0) dq += dqf * trace_fraction;
1435                                                                         dqf *= 0.5;
1436                                                                         q0 = q;
1437                                                                 }
1438                                                                 if (dq > worst_endpos_bug)
1439                                                                 {
1440                                                                         worst_endpos_bug = dq;
1441                                                                         LOG_INFO("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1442                                                                         LOG_INFO("could go ", ftos(dq), " units further to ", vtos(q));
1443                                                                         if (++hitcount >= 10) break;
1444                                                                 }
1445                                                         }
1446                                                 }
1447                                         }
1448                                         return;
1449                                 }
1450
1451                                 case "debug2":
1452                                 {
1453                                         e = nextent(NULL);
1454                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1455                                         vv = trace_endpos;
1456                                         if (trace_fraction == 1)
1457                                         {
1458                                                 LOG_INFO("not above ground, aborting");
1459                                                 return;
1460                                         }
1461                                         f = 0;
1462                                         for (i = 0; i < 100000; ++i)
1463                                         {
1464                                                 dv = randomvec();
1465                                                 if (dv.z > 0) dv = -1 * dv;
1466                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1467                                                 if (trace_startsolid) LOG_INFO("bug 1");
1468                                                 if (trace_fraction == 1)
1469                                                 {
1470                                                         if (dv.z < f)
1471                                                         {
1472                                                                 LOG_INFO("bug 2: ", ftos(dv.x), " ", ftos(dv.y), " ", ftos(dv.z));
1473                                                                 LOG_INFO(" (", ftos(asin(dv.z / vlen(dv)) * 180 / M_PI), " degrees)");
1474                                                                 f = dv.z;
1475                                                         }
1476                                                 }
1477                                         }
1478                                         LOG_INFO("highest possible dist: ", ftos(f));
1479                                         return;
1480                                 }
1481
1482                                 case "walk":
1483                                 {
1484                                         if (argc == 4 || argc == 5)
1485                                         {
1486                                                 e = nextent(NULL);
1487                                                 int dphitcontentsmask_save = e.dphitcontentsmask;
1488                                                 e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
1489                                                 if (tracewalk(e, stov(argv(2)), e.mins, e.maxs, stov(argv(3)), stof(argv(4)), MOVE_NORMAL))
1490                                                         LOG_INFO("can walk");
1491                                                 else
1492                                                         LOG_INFO("cannot walk");
1493                                                 e.dphitcontentsmask = dphitcontentsmask_save;
1494                                                 return;
1495                                         }
1496                                 }
1497
1498                                 case "showline":
1499                                 {
1500                                         if (argc == 4)
1501                                         {
1502                                                 vv = stov(argv(2));
1503                                                 dv = stov(argv(3));
1504                                                 traceline(vv, dv, MOVE_NORMAL, NULL);
1505                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_NEXUIZPLASMA), vv, trace_endpos);
1506                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_CRYLINKPLASMA), trace_endpos, dv);
1507                                                 return;
1508                                         }
1509                                 }
1510
1511                                 // no default case, just go straight to invalid
1512                         }
1513                 }
1514
1515                 default:
1516                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1517                 case CMD_REQUEST_USAGE:
1518                 {
1519                         LOG_HELP("Usage:^3 sv_cmd trace <command> [<startpos> <endpos>] [<endpos_height>]");
1520                         LOG_HELP("  Where <startpos> and <endpos> are parameters for the 'walk' and 'showline' commands,");
1521                         LOG_HELP("  <endpos_height> is an optional parameter for the 'walk' command,");
1522                         LOG_HELP("  Full list of commands here: debug, debug2, walk, showline.");
1523                         LOG_HELP("See also: ^2bbox, gettaginfo^7");
1524                         return;
1525                 }
1526         }
1527 }
1528
1529 void GameCommand_unlockteams(int request)
1530 {
1531         switch (request)
1532         {
1533                 case CMD_REQUEST_COMMAND:
1534                 {
1535                         if (teamplay)
1536                         {
1537                                 lockteams = 0;
1538                                 bprint("^1The teams are now unlocked.\n");
1539                         }
1540                         else
1541                         {
1542                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1543                         }
1544                         return;
1545                 }
1546
1547                 default:
1548                 case CMD_REQUEST_USAGE:
1549                 {
1550                         LOG_HELP("Usage:^3 sv_cmd unlockteams");
1551                         LOG_HELP("  No arguments required.");
1552                         LOG_HELP("See also: ^2lockteams^7");
1553                         return;
1554                 }
1555         }
1556 }
1557
1558 void GameCommand_warp(int request, int argc)
1559 {
1560         switch (request)
1561         {
1562                 case CMD_REQUEST_COMMAND:
1563                 {
1564                         if (autocvar_g_campaign)
1565                         {
1566                                 if (argc >= 2)
1567                                 {
1568                                         CampaignLevelWarp(stof(argv(1)));
1569                                         LOG_INFO("Successfully warped to campaign level ", argv(1), ".");
1570                                 }
1571                                 else
1572                                 {
1573                                         CampaignLevelWarp(-1);
1574                                         LOG_INFO("Successfully warped to next campaign level.");
1575                                 }
1576                         }
1577                         else
1578                         {
1579                                 LOG_INFO("Not in campaign, can't level warp");
1580                         }
1581                         return;
1582                 }
1583
1584                 default:
1585                 case CMD_REQUEST_USAGE:
1586                 {
1587                         LOG_HELP("Usage:^3 sv_cmd warp [<level>]");
1588                         LOG_HELP("  <level> is the level to change campaign mode to.");
1589                         LOG_HELP("  if <level> is not provided it will change to the next level.");
1590                         return;
1591                 }
1592         }
1593 }
1594
1595 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1596 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1597 void GameCommand_(int request)
1598 {
1599     switch(request)
1600     {
1601         case CMD_REQUEST_COMMAND:
1602         {
1603
1604             return;
1605         }
1606
1607         default:
1608         case CMD_REQUEST_USAGE:
1609         {
1610             LOG_HELP("Usage:^3 sv_cmd ");
1611             LOG_HELP("  No arguments required.");
1612             return;
1613         }
1614     }
1615 }
1616 */
1617
1618
1619 // ==================================
1620 //  Macro system for server commands
1621 // ==================================
1622
1623 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1624 SERVER_COMMAND(adminmsg, "Send an admin message to a client directly") { GameCommand_adminmsg(request, arguments); }
1625 SERVER_COMMAND(allready, "Restart the server and reset the players") { GameCommand_allready(request); }
1626 SERVER_COMMAND(allspec, "Force all players to spectate") { GameCommand_allspec(request, arguments); }
1627 SERVER_COMMAND(anticheat, "Create an anticheat report for a client") { GameCommand_anticheat(request, arguments); }
1628 SERVER_COMMAND(animbench, "Benchmark model animation (LAGS)") { GameCommand_animbench(request, arguments); }
1629 SERVER_COMMAND(bbox, "Print detailed information about world size") { GameCommand_bbox(request); }
1630 SERVER_COMMAND(bot_cmd, "Control and send commands to bots") { GameCommand_bot_cmd(request, arguments, command); }
1631 SERVER_COMMAND(cointoss, "Flip a virtual coin and give random result") { GameCommand_cointoss(request, arguments); }
1632 SERVER_COMMAND(database, "Extra controls of the serverprogs database") { GameCommand_database(request, arguments); }
1633 SERVER_COMMAND(defer_clear, "Clear all queued defer commands for a specific client") { GameCommand_defer_clear(request, arguments); }
1634 SERVER_COMMAND(defer_clear_all, "Clear all queued defer commands for all clients") { GameCommand_defer_clear_all(request); }
1635 SERVER_COMMAND(delrec, "Delete race time record for a map") { GameCommand_delrec(request, arguments); }
1636 SERVER_COMMAND(effectindexdump, "Dump list of effects from code and effectinfo.txt") { GameCommand_effectindexdump(request); }
1637 SERVER_COMMAND(extendmatchtime, "Increase the timelimit value incrementally") { GameCommand_extendmatchtime(request); }
1638 SERVER_COMMAND(gametype, "Simple command to change the active gametype") { GameCommand_gametype(request, arguments); }
1639 SERVER_COMMAND(gettaginfo, "Get specific information about a weapon model") { GameCommand_gettaginfo(request, arguments); }
1640 SERVER_COMMAND(gotomap, "Simple command to switch to another map") { GameCommand_gotomap(request, arguments); }
1641 SERVER_COMMAND(lockteams, "Disable the ability for players to switch or enter teams") { GameCommand_lockteams(request); }
1642 SERVER_COMMAND(make_mapinfo, "Automatically rebuild mapinfo files") { GameCommand_make_mapinfo(request); }
1643 SERVER_COMMAND(moveplayer, "Change the team/status of a player") { GameCommand_moveplayer(request, arguments); }
1644 SERVER_COMMAND(nospectators, "Automatically remove spectators from a match") { GameCommand_nospectators(request); }
1645 SERVER_COMMAND(printstats, "Dump eventlog player stats and other score information") { GameCommand_printstats(request); }
1646 SERVER_COMMAND(radarmap, "Generate a radar image of the map") { GameCommand_radarmap(request, arguments); }
1647 SERVER_COMMAND(reducematchtime, "Decrease the timelimit value incrementally") { GameCommand_reducematchtime(request); }
1648 SERVER_COMMAND(setbots, "Adjust how many bots are in the match") { GameCommand_setbots(request, arguments); }
1649 SERVER_COMMAND(shuffleteams, "Randomly move players to different teams") { GameCommand_shuffleteams(request); }
1650 SERVER_COMMAND(stuffto, "Send a command to be executed on a client") { GameCommand_stuffto(request, arguments); }
1651 SERVER_COMMAND(trace, "Various debugging tools with tracing") { GameCommand_trace(request, arguments); }
1652 SERVER_COMMAND(unlockteams, "Enable the ability for players to switch or enter teams") { GameCommand_unlockteams(request); }
1653 SERVER_COMMAND(warp, "Choose different level in campaign") { GameCommand_warp(request, arguments); }
1654
1655 void GameCommand_macro_help()
1656 {
1657         FOREACH(SERVER_COMMANDS, true, { LOG_HELPF("  ^2%s^7: %s", it.m_name, it.m_description); });
1658 }
1659
1660 float GameCommand_macro_command(int argc, string command)
1661 {
1662         string c = strtolower(argv(0));
1663         FOREACH(SERVER_COMMANDS, it.m_name == c, {
1664                 it.m_invokecmd(it, CMD_REQUEST_COMMAND, NULL, argc, command);
1665                 return true;
1666         });
1667         return false;
1668 }
1669
1670 float GameCommand_macro_usage(int argc)
1671 {
1672         string c = strtolower(argv(1));
1673         FOREACH(SERVER_COMMANDS, it.m_name == c, {
1674                 it.m_invokecmd(it, CMD_REQUEST_USAGE, NULL, argc, "");
1675                 return true;
1676         });
1677         return false;
1678 }
1679
1680 void GameCommand_macro_write_aliases(float fh)
1681 {
1682         FOREACH(SERVER_COMMANDS, true, { CMD_Write_Alias("qc_cmd_sv", it.m_name, it.m_description); });
1683 }
1684
1685
1686 // =========================================
1687 //  Main Function Called By Engine (sv_cmd)
1688 // =========================================
1689 // If this function exists, game code handles gamecommand instead of the engine code.
1690
1691 void GameCommand(string command)
1692 {
1693         int argc = tokenize_console(command);
1694
1695         // Guide for working with argc arguments by example:
1696         // argc:   1    - 2      - 3     - 4
1697         // argv:   0    - 1      - 2     - 3
1698         // cmd     vote - master - login - password
1699
1700         if (strtolower(argv(0)) == "help")
1701         {
1702                 if (argc == 1)
1703                 {
1704                         LOG_HELP("Server console commands:");
1705                         GameCommand_macro_help();
1706
1707                         LOG_HELP("\nBanning commands:");
1708                         BanCommand_macro_help();
1709
1710                         LOG_HELP("\nCommon networked commands:");
1711                         CommonCommand_macro_help(NULL);
1712
1713                         LOG_HELP("\nGeneric commands shared by all programs:");
1714                         GenericCommand_macro_help();
1715
1716                         LOG_HELP("\nUsage:^3 sv_cmd <command>^7, where possible commands are listed above.\n"
1717                                 "For help about a specific command, type sv_cmd help <command>");
1718
1719                         return;
1720                 }
1721                 else if (BanCommand_macro_usage(argc))  // Instead of trying to call a command, we're going to see detailed information about it
1722                 {
1723                         return;
1724                 }
1725                 else if (CommonCommand_macro_usage(argc, NULL))  // same here, but for common commands instead
1726                 {
1727                         return;
1728                 }
1729                 else if (GenericCommand_macro_usage(argc))  // same here, but for generic commands instead
1730                 {
1731                         return;
1732                 }
1733                 else if (GameCommand_macro_usage(argc))  // finally try for normal commands too
1734                 {
1735                         return;
1736                 }
1737         }
1738         else if (MUTATOR_CALLHOOK(SV_ParseServerCommand, strtolower(argv(0)), argc, command))
1739         {
1740                 return;  // handled by a mutator
1741         }
1742         else if (BanCommand(command))
1743         {
1744                 return;  // handled by server/command/ipban.qc
1745         }
1746         else if (CommonCommand_macro_command(argc, NULL, command))
1747         {
1748                 return;  // handled by server/command/common.qc
1749         }
1750         else if (GenericCommand(command))
1751         {
1752                 return;                                        // handled by common/command/generic.qc
1753         }
1754         else if (GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1755         {
1756                 return;                                        // handled by one of the above GameCommand_* functions
1757         }
1758
1759         // nothing above caught the command, must be invalid
1760         LOG_INFO(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.");
1761 }