qcsrc/server/command/cmd.qc

   1 #include "cmd.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/deathtypes/all.qh>
   6 #include <common/effects/all.qh>
   7 #include <common/gamemodes/_mod.qh>
   8 #include <common/mapinfo.qh>
   9 #include <common/mapobjects/triggers.qh>
  10 #include <common/minigames/sv_minigames.qh>
  11 #include <common/monsters/_mod.qh>
  12 #include <common/monsters/sv_monsters.qh>
  13 #include <common/monsters/sv_spawn.qh>
  14 #include <common/notifications/all.qh>
  15 #include <common/physics/player.qh>
  16 #include <common/teams.qh>
  17 #include <common/util.qh>
  18 #include <common/vehicles/all.qh>
  19 #include <lib/warpzone/common.qh>
  20 #include <server/bot/api.qh>
  21 #include <server/bot/default/waypoints.qh>
  22 #include <server/campaign.qh>
  23 #include <server/chat.qh>
  24 #include <server/cheats.qh>
  25 #include <server/client.qh>
  26 #include <server/clientkill.qh>
  27 #include <server/command/common.qh>
  28 #include <server/command/getreplies.qh>
  29 #include <server/command/vote.qh>
  30 #include <server/ipban.qh>
  31 #include <server/mapvoting.qh>
  32 #include <server/mutators/_mod.qh>
  33 #include <server/player.qh>
  34 #include <server/scores.qh>
  35 #include <server/teamplay.qh>
  36 #include <server/world.qh>
  37
  38 // =========================================================
  39 //  Server side networked commands code, reworked by Samual
  40 //  Last updated: December 28th, 2011
  41 // =========================================================
  42
  43 bool SV_ParseClientCommand_floodcheck(entity this)
  44 {
  45         entity store = IS_CLIENT(this) ? CS(this) : this; // unfortunately, we need to store these on the client initially
  46
  47         if (!timeout_status)  // not while paused
  48         {
  49                 if (time <= (store.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  50                 {
  51                         store.cmd_floodcount += 1;
  52                         if (store.cmd_floodcount > autocvar_sv_clientcommand_antispam_count)   return false;  // too much spam, halt
  53                 }
  54                 else
  55                 {
  56                         store.cmd_floodtime = time;
  57                         store.cmd_floodcount = 1;
  58                 }
  59         }
  60         return true;  // continue, as we're not flooding yet
  61 }
  62
  63
  64 // =======================
  65 //  Command Sub-Functions
  66 // =======================
  67
  68 void ClientCommand_autoswitch(entity caller, int request, int argc)
  69 {
  70         switch (request)
  71         {
  72                 case CMD_REQUEST_COMMAND:
  73                 {
  74                         if (argv(1) != "")
  75                         {
  76                                 CS_CVAR(caller).autoswitch = InterpretBoolean(argv(1));
  77                                 sprint(caller, strcat("^1autoswitch is currently turned ", (CS_CVAR(caller).autoswitch ? "on" : "off"), ".\n"));
  78                                 return;
  79                         }
  80                 }
  81
  82                 default:
  83                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
  84                 case CMD_REQUEST_USAGE:
  85                 {
  86                         sprint(caller, "\nUsage:^3 cmd autoswitch selection\n");
  87                         sprint(caller, "  Where 'selection' controls if autoswitch is on or off.\n");
  88                         return;
  89                 }
  90         }
  91 }
  92
  93 void ClientCommand_clientversion(entity caller, int request, int argc)  // internal command, used only by code
  94 {
  95         switch (request)
  96         {
  97                 case CMD_REQUEST_COMMAND:
  98                 {
  99                         if (argv(1) != "")
 100                         {
 101                                 if (IS_CLIENT(caller))
 102                                 {
 103                                         CS(caller).version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
 104
 105                                         if (CS(caller).version < autocvar_gameversion_min || CS(caller).version > autocvar_gameversion_max)
 106                                         {
 107                                                 CS(caller).version_mismatch = true;
 108                                                 ClientKill_TeamChange(caller, -2);  // observe
 109                                         }
 110                                         else if (autocvar_g_campaign || autocvar_g_balance_teams)
 111                                         {
 112                                                 // JoinBestTeam(caller, false, true);
 113                                         }
 114                                         else if (teamplay && !autocvar_sv_spectate && !(Player_GetForcedTeamIndex(caller) > 0))
 115                                         {
 116                                                 TRANSMUTE(Observer, caller);  // really?
 117                                                 stuffcmd(caller, "menu_showteamselect\n");
 118                                         }
 119                                 }
 120
 121                                 return;
 122                         }
 123                 }
 124
 125                 default:
 126                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 127                 case CMD_REQUEST_USAGE:
 128                 {
 129                         sprint(caller, "\nUsage:^3 cmd clientversion version\n");
 130                         sprint(caller, "  Where 'version' is the game version reported by caller.\n");
 131                         return;
 132                 }
 133         }
 134 }
 135
 136 void ClientCommand_mv_getpicture(entity caller, int request, int argc)  // internal command, used only by code
 137 {
 138         switch (request)
 139         {
 140                 case CMD_REQUEST_COMMAND:
 141                 {
 142                         if (argv(1) != "")
 143                         {
 144                                 if (intermission_running) MapVote_SendPicture(caller, stof(argv(1)));
 145
 146                                 return;
 147                         }
 148                 }
 149
 150                 default:
 151                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 152                 case CMD_REQUEST_USAGE:
 153                 {
 154                         sprint(caller, "\nUsage:^3 cmd mv_getpicture mapid\n");
 155                         sprint(caller, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 156                         return;
 157                 }
 158         }
 159 }
 160
 161 void ClientCommand_wpeditor(entity caller, int request, int argc)
 162 {
 163         switch (request)
 164         {
 165                 case CMD_REQUEST_COMMAND:
 166                 {
 167                         if (!autocvar_g_waypointeditor)
 168                         {
 169                                 sprint(caller, "ERROR: this command works only if the waypoint editor is on\n");
 170                                 return;
 171                         }
 172
 173                         if (argv(1) != "")
 174                         {
 175                                 if (argv(1) == "spawn")
 176                                 {
 177                                         string s = argv(2);
 178                                         if (!IS_PLAYER(caller))
 179                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 180                                         else
 181                                                 waypoint_spawn_fromeditor(caller, (s == "crosshair"), (s == "jump"), (s == "crouch"), (s == "support"));
 182                                         return;
 183                                 }
 184                                 else if (argv(1) == "remove")
 185                                 {
 186                                         if (!IS_PLAYER(caller))
 187                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 188                                         else
 189                                                 waypoint_remove_fromeditor(caller);
 190                                         return;
 191                                 }
 192                                 else if (argv(1) == "hardwire")
 193                                 {
 194                                         string s = argv(2);
 195                                         waypoint_start_hardwiredlink(caller, (s == "crosshair"));
 196                                         return;
 197                                 }
 198                                 else if (argv(1) == "lock")
 199                                 {
 200                                         waypoint_lock(caller);
 201                                         return;
 202                                 }
 203                                 else if (argv(1) == "unreachable")
 204                                 {
 205                                         if (!IS_PLAYER(caller))
 206                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 207                                         else
 208                                                 waypoint_unreachable(caller);
 209                                         return;
 210                                 }
 211                                 else if (argv(1) == "saveall")
 212                                 {
 213                                         waypoint_saveall();
 214                                         return;
 215                                 }
 216                                 else if (argv(1) == "relinkall")
 217                                 {
 218                                         waypoint_schedulerelinkall();
 219                                         return;
 220                                 }
 221                                 else if (argv(1) == "symaxis")
 222                                 {
 223                                         if (argv(2) == "set" || argv(2) == "get")
 224                                         {
 225                                                 waypoint_getSymmetricalAxis_cmd(caller, (argv(2) == "set"), 3);
 226                                                 return;
 227                                         }
 228                                 }
 229                                 else if (argv(1) == "symorigin")
 230                                 {
 231                                         if (argv(2) == "set" || argv(2) == "get")
 232                                         {
 233                                                 waypoint_getSymmetricalOrigin_cmd(caller, (argv(2) == "set"), 3);
 234                                                 return;
 235                                         }
 236                                 }
 237                         }
 238                 }
 239
 240                 default:
 241                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 242                 case CMD_REQUEST_USAGE:
 243                 {
 244                         sprint(caller, "\nUsage:^3 cmd wpeditor action\n");
 245                         sprint(caller, "  Where 'action' can be:\n");
 246                         sprint(caller, "   ^5spawn^7: spawns a waypoint at player's position\n");
 247                         sprint(caller, "   ^5remove^7: removes player's nearest waypoint\n");
 248                         sprint(caller, "   ^5unreachable^7: reveals waypoints and items unreachable from the current position and spawnpoints without a nearest waypoint\n");
 249                         sprint(caller, "   ^5saveall^7: saves all waypoints and links to file\n");
 250                         sprint(caller, "   ^5relinkall^7: relinks all waypoints as if they were respawned\n");
 251                         sprint(caller, "   ^5spawn crosshair^7: spawns a waypoint at crosshair's position\n");
 252                         sprint(caller, "   ^7 in general useful to create special and hardwired links with ease from existing waypoints\n");
 253                         sprint(caller, "   ^7 in particular it's the only way to create custom jumppad waypoints (spawn another waypoint to create destination))\n");
 254                         sprint(caller, "   ^5spawn jump^7: spawns a jump waypoint (place it at least 60 qu before jump start, spawn another waypoint to create destination)\n");
 255                         sprint(caller, "   ^5spawn crouch^7: spawns a crouch waypoint (it links only to very close waypoints)\n");
 256                         sprint(caller, "   ^5spawn support^7: spawns a support waypoint (spawn another waypoint to create destination from which all incoming links are removed)\n");
 257                         sprint(caller, "   ^7 useful to replace links to problematic jumppad/teleport waypoints\n");
 258                         sprint(caller, "   ^5hardwire^7: marks the nearest waypoint as origin of a new hardwired link (spawn another waypoint over an existing one to create destination)\n");
 259                         sprint(caller, "   ^5hardwire crosshair^7: marks the waypoint at crosshair instead of the nearest waypoint\n");
 260                         sprint(caller, "   ^5lock^7: locks link display of the aimed waypoint (unlocks if no waypoint is found at crosshair's position)\n");
 261                         sprint(caller, "   ^5symorigin get|set\n");
 262                         sprint(caller, "   ^5symorigin get|set p1 p2 ... pX\n");
 263                         sprint(caller, "   ^5symaxis get|set p1 p2\n");
 264                         sprint(caller, "   ^7 where p1 p2 ... pX are positions (\"x y z\", z can be omitted) that you know are perfectly symmetrical"
 265                                                                 " so you can determine origin/axis of symmetry of maps without ctf flags or where flags aren't perfectly symmetrical\n");
 266                         sprint(caller, "  See 'wpeditor_menu' for a selectable list of various commands and useful settings to edit waypoints.\n");
 267                         return;
 268                 }
 269         }
 270 }
 271
 272 void ClientCommand_join(entity caller, int request)
 273 {
 274         switch (request)
 275         {
 276                 case CMD_REQUEST_COMMAND:
 277                 {
 278                         if (!game_stopped && IS_CLIENT(caller) && !IS_PLAYER(caller))
 279                         {
 280                                 if (joinAllowed(caller))
 281                                         Join(caller);
 282                                 else if(time < CS(caller).jointime + MIN_SPEC_TIME)
 283                                         CS(caller).autojoin_checked = -1;
 284                         }
 285
 286                         return;  // never fall through to usage
 287                 }
 288
 289                 default:
 290                 case CMD_REQUEST_USAGE:
 291                 {
 292                         sprint(caller, "\nUsage:^3 cmd join\n");
 293                         sprint(caller, "  No arguments required.\n");
 294                         return;
 295                 }
 296         }
 297 }
 298
 299 void ClientCommand_kill(entity caller, int request)
 300 {
 301         switch (request)
 302         {
 303                 case CMD_REQUEST_COMMAND:
 304                 {
 305                         if(IS_SPEC(caller) || IS_OBSERVER(caller))
 306                                 return; // no point warning about this, command does nothing
 307
 308                         if(GetResource(caller, RES_HEALTH) <= 0)
 309                         {
 310                                 sprint(caller, "Can't die - you are already dead!\n");
 311                                 return;
 312                         }
 313
 314                         ClientKill(caller);
 315
 316                         return;  // never fall through to usage
 317                 }
 318
 319                 default:
 320                 case CMD_REQUEST_USAGE:
 321                 {
 322                         sprint(caller, "\nUsage:^3 cmd kill\n");
 323                         sprint(caller, "  No arguments required.\n");
 324                         return;
 325                 }
 326         }
 327 }
 328
 329 void ClientCommand_physics(entity caller, int request, int argc)
 330 {
 331         switch (request)
 332         {
 333                 case CMD_REQUEST_COMMAND:
 334                 {
 335                         string command = strtolower(argv(1));
 336
 337                         if (!autocvar_g_physics_clientselect)
 338                         {
 339                                 sprint(caller, "Client physics selection is currently disabled.\n");
 340                                 return;
 341                         }
 342
 343                         if (command == "list" || command == "help")
 344                         {
 345                                 sprint(caller, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
 346                                 return;
 347                         }
 348
 349                         if (Physics_Valid(command) || command == "default")
 350                         {
 351                                 stuffcmd(caller, strcat("\nseta cl_physics ", command, "\n"));
 352                                 sprint(caller, strcat("^2Physics set successfully changed to ^3", command, "\n"));
 353                                 return;
 354                         }
 355                 }
 356
 357                 default:
 358                         sprint(caller, strcat("Current physics set: ^3", CS_CVAR(caller).cvar_cl_physics, "\n"));
 359                 case CMD_REQUEST_USAGE:
 360                 {
 361                         sprint(caller, "\nUsage:^3 cmd physics <physics>\n");
 362                         sprint(caller, "  See 'cmd physics list' for available physics sets.\n");
 363                         sprint(caller, "  Argument 'default' resets to standard physics.\n");
 364                         return;
 365                 }
 366         }
 367 }
 368
 369 void ClientCommand_ready(entity caller, int request)  // todo: anti-spam for toggling readyness
 370 {
 371         switch (request)
 372         {
 373                 case CMD_REQUEST_COMMAND:
 374                 {
 375                         if (IS_CLIENT(caller))
 376                         {
 377                                 if (warmup_stage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 378                                 {
 379                                         if (!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 380                                         {
 381                                                 if (time < game_starttime) // game is already restarting
 382                                                         return;
 383                                                 if (caller.ready)            // toggle
 384                                                 {
 385                                                         caller.ready = false;
 386                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 387                                                                 bprint(playername(caller.netname, caller.team, false), "^2 is ^1NOT^2 ready\n");
 388                                                 }
 389                                                 else
 390                                                 {
 391                                                         caller.ready = true;
 392                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 393                                                                 bprint(playername(caller.netname, caller.team, false), "^2 is ready\n");
 394                                                 }
 395
 396                                                 // cannot reset the game while a timeout is active!
 397                                                 if (!timeout_status) ReadyCount();
 398                                         }
 399                                         else
 400                                         {
 401                                                 sprint(caller, "^1Game has already been restarted\n");
 402                                         }
 403                                 }
 404                         }
 405                         return;  // never fall through to usage
 406                 }
 407
 408                 default:
 409                 case CMD_REQUEST_USAGE:
 410                 {
 411                         sprint(caller, "\nUsage:^3 cmd ready\n");
 412                         sprint(caller, "  No arguments required.\n");
 413                         return;
 414                 }
 415         }
 416 }
 417
 418 void ClientCommand_say(entity caller, int request, int argc, string command)
 419 {
 420         switch (request)
 421         {
 422                 case CMD_REQUEST_COMMAND:
 423                 {
 424                         if (argc >= 2)   Say(caller, false, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 425                         return;  // never fall through to usage
 426                 }
 427
 428                 default:
 429                 case CMD_REQUEST_USAGE:
 430                 {
 431                         sprint(caller, "\nUsage:^3 cmd say <message>\n");
 432                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 433                         return;
 434                 }
 435         }
 436 }
 437
 438 void ClientCommand_say_team(entity caller, int request, int argc, string command)
 439 {
 440         switch (request)
 441         {
 442                 case CMD_REQUEST_COMMAND:
 443                 {
 444                         if (argc >= 2)
 445                                 Say(caller, true, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 446                         return;  // never fall through to usage
 447                 }
 448
 449                 default:
 450                 case CMD_REQUEST_USAGE:
 451                 {
 452                         sprint(caller, "\nUsage:^3 cmd say_team <message>\n");
 453                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 454                         return;
 455                 }
 456         }
 457 }
 458
 459 .bool team_selected;
 460 void ClientCommand_selectteam(entity caller, int request, int argc)
 461 {
 462         switch (request)
 463         {
 464                 case CMD_REQUEST_COMMAND:
 465                 {
 466                         if (argv(1) == "")
 467                         {
 468                                 return;
 469                         }
 470                         if (!IS_CLIENT(caller))
 471                         {
 472                                 return;
 473                         }
 474                         if (!teamplay)
 475                         {
 476                                 sprint(caller, "^7selectteam can only be used in teamgames\n");
 477                                 return;
 478                         }
 479                         if (Player_GetForcedTeamIndex(caller) > 0)
 480                         {
 481                                 sprint(caller, "^7selectteam can not be used as your team is forced\n");
 482                                 return;
 483                         }
 484                         if (lockteams)
 485                         {
 486                                 sprint(caller, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 487                                 return;
 488                         }
 489                         float selection;
 490                         switch (argv(1))
 491                         {
 492                                 case "red":
 493                                 {
 494                                         selection = NUM_TEAM_1;
 495                                         break;
 496                                 }
 497                                 case "blue":
 498                                 {
 499                                         selection = NUM_TEAM_2;
 500                                         break;
 501                                 }
 502                                 case "yellow":
 503                                 {
 504                                         selection = NUM_TEAM_3;
 505                                         break;
 506                                 }
 507                                 case "pink":
 508                                 {
 509                                         selection = NUM_TEAM_4;
 510                                         break;
 511                                 }
 512                                 case "auto":
 513                                 {
 514                                         selection = (-1);
 515                                         break;
 516                                 }
 517                                 default:
 518                                 {
 519                                         return;
 520                                 }
 521                         }
 522                         if (caller.team == selection && selection != -1 && !IS_DEAD(caller))
 523                         {
 524                                 sprint(caller, "^7You already are on that team.\n");
 525                                 return;
 526                         }
 527                         if (CS(caller).wasplayer && autocvar_g_changeteam_banned)
 528                         {
 529                                 sprint(caller, "^1You cannot change team, forbidden by the server.\n");
 530                                 return;
 531                         }
 532                         if ((selection != -1) && autocvar_g_balance_teams &&
 533                                 autocvar_g_balance_teams_prevent_imbalance)
 534                         {
 535                                 entity balance = TeamBalance_CheckAllowedTeams(caller);
 536                                 TeamBalance_GetTeamCounts(balance, caller);
 537                                 if ((Team_IndexToBit(Team_TeamToIndex(selection)) &
 538                                         TeamBalance_FindBestTeams(balance, caller, false)) == 0)
 539                                 {
 540                                         Send_Notification(NOTIF_ONE, caller, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 541                                         TeamBalance_Destroy(balance);
 542                                         return;
 543                                 }
 544                                 TeamBalance_Destroy(balance);
 545                         }
 546                         ClientKill_TeamChange(caller, selection);
 547                         if (!IS_PLAYER(caller))
 548                         {
 549                                 caller.team_selected = true; // avoids asking again for team selection on join
 550                         }
 551                         return;
 552                 }
 553                 default:
 554                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 555                 case CMD_REQUEST_USAGE:
 556                 {
 557                         sprint(caller, "\nUsage:^3 cmd selectteam team\n");
 558                         sprint(caller, "  Where 'team' is the prefered team to try and join.\n");
 559                         sprint(caller, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 560                         return;
 561                 }
 562         }
 563 }
 564
 565 void ClientCommand_selfstuff(entity caller, int request, string command)
 566 {
 567         switch (request)
 568         {
 569                 case CMD_REQUEST_COMMAND:
 570                 {
 571                         if (argv(1) != "")
 572                         {
 573                                 stuffcmd(caller, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 574                                 return;
 575                         }
 576                 }
 577
 578                 default:
 579                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 580                 case CMD_REQUEST_USAGE:
 581                 {
 582                         sprint(caller, "\nUsage:^3 cmd selfstuff <command>\n");
 583                         sprint(caller, "  Where 'command' is the string to be stuffed to your client.\n");
 584                         return;
 585                 }
 586         }
 587 }
 588
 589 void ClientCommand_sentcvar(entity caller, int request, int argc, string command)
 590 {
 591         switch (request)
 592         {
 593                 case CMD_REQUEST_COMMAND:
 594                 {
 595                         if (argv(1) != "")
 596                         {
 597                                 // float tokens;
 598                                 string s;
 599
 600                                 if (argc == 2)  // undefined cvar: use the default value on the server then
 601                                 {
 602                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 603                                         tokenize_console(s);
 604                                 }
 605
 606                                 GetCvars(caller, CS_CVAR(caller), 1);
 607
 608                                 return;
 609                         }
 610                 }
 611
 612                 default:
 613                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 614                 case CMD_REQUEST_USAGE:
 615                 {
 616                         sprint(caller, "\nUsage:^3 cmd sentcvar <cvar>\n");
 617                         sprint(caller, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 618                         return;
 619                 }
 620         }
 621 }
 622
 623 void ClientCommand_spectate(entity caller, int request)
 624 {
 625         switch (request)
 626         {
 627                 case CMD_REQUEST_COMMAND:
 628                 {
 629                         if (!intermission_running && IS_CLIENT(caller))
 630                         {
 631                                 if(argv(1) != "")
 632                                 {
 633                                         if(IS_SPEC(caller) || IS_OBSERVER(caller))
 634                                         {
 635                                                 entity client = GetFilteredEntity(argv(1));
 636                                                 int spec_accepted = VerifyClientEntity(client, false, false);
 637                                                 if(spec_accepted > 0 && IS_PLAYER(client))
 638                                                 {
 639                                                         bool caller_is_observer = (IS_OBSERVER(caller));
 640                                                         Spectate(caller, client);
 641                                                         if (caller_is_observer)
 642                                                                 TRANSMUTE(Spectator, caller);
 643                                                 }
 644                                                 else
 645                                                         sprint(caller, "Can't spectate ", argv(1), "^7\n");
 646                                         }
 647                                         else
 648                                                 sprint(caller, "cmd spectate client only works when you are spectator/observer\n");
 649                                         return;
 650                                 }
 651
 652                                 int mutator_returnvalue = MUTATOR_CALLHOOK(ClientCommand_Spectate, caller);
 653
 654                                 if (mutator_returnvalue == MUT_SPECCMD_RETURN) return;
 655
 656                                 if ((IS_PLAYER(caller) || mutator_returnvalue == MUT_SPECCMD_FORCE))
 657                                 if (autocvar_sv_spectate == 1)
 658                                         ClientKill_TeamChange(caller, -2); // observe
 659                         }
 660                         return; // never fall through to usage
 661                 }
 662
 663                 default:
 664                 case CMD_REQUEST_USAGE:
 665                 {
 666                         sprint(caller, "\nUsage:^3 cmd spectate [client]\n");
 667                         sprint(caller, "  Where 'client' can be the player to spectate.\n");
 668                         return;
 669                 }
 670         }
 671 }
 672
 673 void ClientCommand_suggestmap(entity caller, int request, int argc)
 674 {
 675         switch (request)
 676         {
 677                 case CMD_REQUEST_COMMAND:
 678                 {
 679                         if (argv(1) != "")
 680                         {
 681                                 sprint(caller, strcat(MapVote_Suggest(caller, argv(1)), "\n"));
 682                                 return;
 683                         }
 684                 }
 685
 686                 default:
 687                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 688                 case CMD_REQUEST_USAGE:
 689                 {
 690                         sprint(caller, "\nUsage:^3 cmd suggestmap map\n");
 691                         sprint(caller, "  Where 'map' is the name of the map to suggest.\n");
 692                         return;
 693                 }
 694         }
 695 }
 696
 697 void ClientCommand_tell(entity caller, int request, int argc, string command)
 698 {
 699         switch (request)
 700         {
 701                 case CMD_REQUEST_COMMAND:
 702                 {
 703                         if (argc >= 3)
 704                         {
 705                                 if(!IS_CLIENT(caller) && IS_REAL_CLIENT(caller)) // connecting
 706                                 {
 707                                         print_to(caller, "You can't ^2tell^7 a message while connecting.");
 708                                         return;
 709                                 }
 710
 711                                 entity tell_to = GetIndexedEntity(argc, 1);
 712                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
 713
 714                                 if (tell_accepted > 0)   // the target is a real client
 715                                 {
 716                                         if (tell_to != caller) // and we're allowed to send to them :D
 717                                         {
 718                                                 // workaround for argv indexes indexing ascii chars instead of utf8 chars
 719                                                 // In this case when the player name contains utf8 chars
 720                                                 // the message gets partially trimmed in the beginning.
 721                                                 // Potentially this bug affects any substring call that uses
 722                                                 // argv_start_index and argv_end_index.
 723
 724                                                 string utf8_enable_save = cvar_string("utf8_enable");
 725                                                 cvar_set("utf8_enable", "0");
 726                                                 string msg = substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token));
 727                                                 cvar_set("utf8_enable", utf8_enable_save);
 728
 729                                                 Say(caller, false, tell_to, msg, true);
 730                                                 return;
 731                                         }
 732                                         else { print_to(caller, "You can't ^2tell^7 a message to yourself."); return; }
 733                                 }
 734                                 else if (argv(1) == "#0")
 735                                 {
 736                                         trigger_magicear_processmessage_forallears(caller, -1, NULL, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 737                                         return;
 738                                 }
 739                                 else { print_to(caller, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 740                         }
 741                 }
 742
 743                 default:
 744                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 745                 case CMD_REQUEST_USAGE:
 746                 {
 747                         sprint(caller, "\nUsage:^3 cmd tell client <message>\n");
 748                         sprint(caller, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 749                         return;
 750                 }
 751         }
 752 }
 753
 754 void ClientCommand_voice(entity caller, int request, int argc, string command)
 755 {
 756         switch (request)
 757         {
 758                 case CMD_REQUEST_COMMAND:
 759                 {
 760                         if (argv(1) != "")
 761                         {
 762                                 entity e = GetVoiceMessage(argv(1));
 763                                 if (!e)
 764                                 {
 765                                         sprint(caller, sprintf("Invalid voice. Use one of: %s\n", allvoicesamples));
 766                                         return;
 767                                 }
 768                                 if (IS_DEAD(caller))
 769                                 {
 770                                         // don't warn the caller when trying to taunt while dead, just don't play any sounds!
 771                                         // we still allow them to see warnings if it's invalid, so a dead player can find out the sounds in peace
 772                                         return;
 773                                 }
 774                                 if (IS_SPEC(caller) || IS_OBSERVER(caller))
 775                                 {
 776                                         // observers/spectators have no player model of their own to play taunts from
 777                                         // again, allow them to see warnings
 778                                         return;
 779                                 }
 780                                 string msg = "";
 781                                 if (argc >= 3)
 782                                         msg = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 783                                 VoiceMessage(caller, e, msg);
 784
 785                                 return;
 786                         }
 787                 }
 788
 789                 default:
 790                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 791                 case CMD_REQUEST_USAGE:
 792                 {
 793                         sprint(caller, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 794                         sprint(caller, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 795                         sprint(caller, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 796                         return;
 797                 }
 798         }
 799 }
 800
 801 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 802 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 803 void ClientCommand_(entity caller, int request)
 804 {
 805     switch(request)
 806     {
 807         case CMD_REQUEST_COMMAND:
 808         {
 809
 810             return; // never fall through to usage
 811         }
 812
 813         default:
 814         case CMD_REQUEST_USAGE:
 815         {
 816             sprint(caller, "\nUsage:^3 cmd \n");
 817             sprint(caller, "  No arguments required.\n");
 818             return;
 819         }
 820     }
 821 }
 822 */
 823
 824
 825 // =====================================
 826 //  Macro system for networked commands
 827 // =====================================
 828
 829 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 830 #define CLIENT_COMMANDS(ent, request, arguments, command) \
 831         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(ent, request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 832         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(ent, request, arguments), "Release version of the game") \
 833         CLIENT_COMMAND("join", ClientCommand_join(ent, request), "Become a player in the game") \
 834         CLIENT_COMMAND("kill", ClientCommand_kill(ent, request), "Become a member of the dead") \
 835         CLIENT_COMMAND("minigame", ClientCommand_minigame(ent, request, arguments, command), "Start a minigame") \
 836         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(ent, request, arguments), "Retrieve mapshot picture from the server") \
 837         CLIENT_COMMAND("physics", ClientCommand_physics(ent, request, arguments), "Change physics set") \
 838         CLIENT_COMMAND("ready", ClientCommand_ready(ent, request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 839         CLIENT_COMMAND("say", ClientCommand_say(ent, request, arguments, command), "Print a message to chat to all players") \
 840         CLIENT_COMMAND("say_team", ClientCommand_say_team(ent, request, arguments, command), "Print a message to chat to all team mates") \
 841         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(ent, request, arguments), "Attempt to choose a team to join into") \
 842         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(ent, request, command), "Stuffcmd a command to your own client") \
 843         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(ent, request, arguments, command), "New system for sending a client cvar to the server") \
 844         CLIENT_COMMAND("spectate", ClientCommand_spectate(ent, request), "Become an observer") \
 845         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(ent, request, arguments), "Suggest a map to the mapvote at match end") \
 846         CLIENT_COMMAND("tell", ClientCommand_tell(ent, request, arguments, command), "Send a message directly to a player") \
 847         CLIENT_COMMAND("voice", ClientCommand_voice(ent, request, arguments, command), "Send voice message via sound") \
 848         CLIENT_COMMAND("wpeditor", ClientCommand_wpeditor(ent, request, arguments), "Waypoint editor commands") \
 849         /* nothing */
 850
 851 void ClientCommand_macro_help(entity caller)
 852 {
 853         #define CLIENT_COMMAND(name, function, description) \
 854                 { sprint(caller, "  ^2", name, "^7: ", description, "\n"); }
 855
 856         CLIENT_COMMANDS(NULL, 0, 0, "");
 857 #undef CLIENT_COMMAND
 858 }
 859
 860 float ClientCommand_macro_command(int argc, entity caller, string command)
 861 {
 862         #define CLIENT_COMMAND(name, function, description) \
 863                 { if (name == strtolower(argv(0))) { function; return true; } }
 864
 865         CLIENT_COMMANDS(caller, CMD_REQUEST_COMMAND, argc, command);
 866 #undef CLIENT_COMMAND
 867
 868         return false;
 869 }
 870
 871 float ClientCommand_macro_usage(int argc, entity caller)
 872 {
 873         #define CLIENT_COMMAND(name, function, description) \
 874                 { if (name == strtolower(argv(1))) { function; return true; } }
 875
 876         CLIENT_COMMANDS(caller, CMD_REQUEST_USAGE, argc, "");
 877 #undef CLIENT_COMMAND
 878
 879         return false;
 880 }
 881
 882 void ClientCommand_macro_write_aliases(float fh)
 883 {
 884         #define CLIENT_COMMAND(name, function, description) \
 885                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 886
 887         CLIENT_COMMANDS(NULL, 0, 0, "");
 888 #undef CLIENT_COMMAND
 889 }
 890
 891 // ======================================
 892 //  Main Function Called By Engine (cmd)
 893 // ======================================
 894 // If this function exists, server game code parses clientcommand before the engine code gets it.
 895
 896 void SV_ParseClientCommand(entity this, string command)
 897 {
 898         // If invalid UTF-8, don't even parse it
 899         string command2 = "";
 900         float len = strlen(command);
 901         float i;
 902         for (i = 0; i < len; ++i)
 903                 command2 = strcat(command2, chr2str(str2chr(command, i)));
 904         if (command != command2) return;
 905
 906         // if we're banned, don't even parse the command
 907         if (Ban_MaybeEnforceBanOnce(this)) return;
 908
 909         int argc = tokenize_console(command);
 910
 911         // Guide for working with argc arguments by example:
 912         // argc:   1    - 2      - 3     - 4
 913         // argv:   0    - 1      - 2     - 3
 914         // cmd     vote - master - login - password
 915
 916         // for floodcheck
 917         switch (strtolower(argv(0)))
 918         {
 919                 // exempt commands which are not subject to floodcheck
 920                 case "begin": break;                               // handled by engine in host_cmd.c
 921                 case "download": break;                            // handled by engine in cl_parse.c
 922                 case "mv_getpicture": break;                       // handled by server in this file
 923                 case "wpeditor": break;                            // handled by server in this file
 924                 case "pause": break;                               // handled by engine in host_cmd.c
 925                 case "prespawn": break;                            // handled by engine in host_cmd.c
 926                 case "sentcvar": break;                            // handled by server in this file
 927                 case "spawn": break;                               // handled by engine in host_cmd.c
 928                 case "color": case "topcolor": case "bottomcolor": if(teamplay) return; else break; // handled by engine in host_cmd.c
 929                 case "c2s": Net_ClientCommand(this, command); return; // handled by net.qh
 930
 931                 default:
 932                         if (SV_ParseClientCommand_floodcheck(this)) break; // "true": continue, as we're not flooding yet
 933                         else return;                                   // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 934         }
 935
 936         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 937         if (argv(0) == "help")
 938         {
 939                 if (argc == 1)
 940                 {
 941                         sprint(this, "\nClient networked commands:\n");
 942                         ClientCommand_macro_help(this);
 943
 944                         sprint(this, "\nCommon networked commands:\n");
 945                         CommonCommand_macro_help(this);
 946
 947                         sprint(this, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 948                         sprint(this, "For help about a specific command, type cmd help COMMAND\n");
 949                         return;
 950                 }
 951                 else if (CommonCommand_macro_usage(argc, this))  // Instead of trying to call a command, we're going to see detailed information about it
 952                 {
 953                         return;
 954                 }
 955                 else if (ClientCommand_macro_usage(argc, this))  // same, but for normal commands now
 956                 {
 957                         return;
 958                 }
 959         }
 960         else if (MUTATOR_CALLHOOK(SV_ParseClientCommand, this, strtolower(argv(0)), argc, command))
 961         {
 962                 return;  // handled by a mutator
 963         }
 964         else if (CheatCommand(this, argc))
 965         {
 966                 return;  // handled by server/cheats.qc
 967         }
 968         else if (CommonCommand_macro_command(argc, this, command))
 969         {
 970                 return;                                          // handled by server/command/common.qc
 971         }
 972         else if (ClientCommand_macro_command(argc, this, command)) // continue as usual and scan for normal commands
 973         {
 974                 return;                                          // handled by one of the above ClientCommand_* functions
 975         }
 976         else
 977         {
 978                 clientcommand(this, command);
 979         }
 980 }