qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/waypoints/all.qh>
  27 #include <common/net_linked.qh>
  28 #include <common/net_notice.qh>
  29 #include <common/notifications/all.qh>
  30 #include <common/physics/player.qh>
  31 #include <common/playerstats.qh>
  32 #include <common/state.qh>
  33 #include <common/stats.qh>
  34 #include <common/vehicles/all.qh>
  35 #include <common/vehicles/sv_vehicles.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/weapons/_all.qh>
  38 #include <common/weapons/weapon/vortex.qh>
  39 #include <common/wepent.qh>
  40 #include <lib/csqcmodel/sv_model.qh>
  41 #include <lib/warpzone/common.qh>
  42 #include <lib/warpzone/server.qh>
  43 #include <server/anticheat.qh>
  44 #include <server/antilag.qh>
  45 #include <server/bot/api.qh>
  46 #include <server/bot/default/cvars.qh>
  47 #include <server/campaign.qh>
  48 #include <server/chat.qh>
  49 #include <server/cheats.qh>
  50 #include <server/clientkill.qh>
  51 #include <server/command/common.qh>
  52 #include <server/command/common.qh>
  53 #include <server/command/vote.qh>
  54 #include <server/compat/quake3.qh>
  55 #include <server/damage.qh>
  56 #include <server/gamelog.qh>
  57 #include <server/handicap.qh>
  58 #include <server/hook.qh>
  59 #include <server/impulse.qh>
  60 #include <server/intermission.qh>
  61 #include <server/ipban.qh>
  62 #include <server/main.qh>
  63 #include <server/mutators/_mod.qh>
  64 #include <server/player.qh>
  65 #include <server/portals.qh>
  66 #include <server/race.qh>
  67 #include <server/resources.qh>
  68 #include <server/scores.qh>
  69 #include <server/scores_rules.qh>
  70 #include <server/spawnpoints.qh>
  71 #include <server/teamplay.qh>
  72 #include <server/weapons/accuracy.qh>
  73 #include <server/weapons/common.qh>
  74 #include <server/weapons/hitplot.qh>
  75 #include <server/weapons/selection.qh>
  76 #include <server/weapons/tracing.qh>
  77 #include <server/weapons/weaponsystem.qh>
  78 #include <server/world.qh>
  79
  80 STATIC_METHOD(Client, Add, void(Client this, int _team))
  81 {
  82     ClientConnect(this);
  83     TRANSMUTE(Player, this);
  84     this.frame = 12; // 7
  85     this.team = _team;
  86     PutClientInServer(this);
  87 }
  88
  89 STATIC_METHOD(Client, Remove, void(Client this))
  90 {
  91     TRANSMUTE(Observer, this);
  92     PutClientInServer(this);
  93     ClientDisconnect(this);
  94 }
  95
  96 void send_CSQC_teamnagger() {
  97         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  98 }
  99
 100 int CountSpectators(entity player, entity to)
 101 {
 102         if(!player) { return 0; } // not sure how, but best to be safe
 103
 104         int spec_count = 0;
 105
 106         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 107         {
 108                 spec_count++;
 109         });
 110
 111         return spec_count;
 112 }
 113
 114 void WriteSpectators(entity player, entity to)
 115 {
 116         if(!player) { return; } // not sure how, but best to be safe
 117
 118         int spec_count = 0;
 119         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 120         {
 121                 if(spec_count >= MAX_SPECTATORS)
 122                         break;
 123                 WriteByte(MSG_ENTITY, num_for_edict(it));
 124                 ++spec_count;
 125         });
 126 }
 127
 128 bool ClientData_Send(entity this, entity to, int sf)
 129 {
 130         assert(to == this.owner, return false);
 131
 132         entity e = to;
 133         if (IS_SPEC(e)) e = e.enemy;
 134
 135         sf = 0;
 136         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 137         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 138         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 139         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 140
 141         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 142         WriteByte(MSG_ENTITY, sf);
 143
 144         if (sf & BIT(1))
 145                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 146
 147         if(sf & BIT(4))
 148         {
 149                 float specs = CountSpectators(e, to);
 150                 WriteByte(MSG_ENTITY, specs);
 151                 WriteSpectators(e, to);
 152         }
 153
 154         return true;
 155 }
 156
 157 void ClientData_Attach(entity this)
 158 {
 159         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 160         CS(this).clientdata.drawonlytoclient = this;
 161         CS(this).clientdata.owner = this;
 162 }
 163
 164 void ClientData_Detach(entity this)
 165 {
 166         delete(CS(this).clientdata);
 167         CS(this).clientdata = NULL;
 168 }
 169
 170 void ClientData_Touch(entity e)
 171 {
 172         entity cd = CS(e).clientdata;
 173         if (cd) { cd.SendFlags = 1; }
 174
 175         // make it spectatable
 176         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 177         {
 178                 entity cd = CS(it).clientdata;
 179                 if (cd) { cd.SendFlags = 1; }
 180         });
 181 }
 182
 183
 184 /*
 185 =============
 186 CheckPlayerModel
 187
 188 Checks if the argument string can be a valid playermodel.
 189 Returns a valid one in doubt.
 190 =============
 191 */
 192 string FallbackPlayerModel;
 193 string CheckPlayerModel(string plyermodel) {
 194         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 195         {
 196                 // note: we cannot summon Don Strunzone here, some player may
 197                 // still have the model string set. In case anyone manages how
 198                 // to change a cvar default, we'll have a small leak here.
 199                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 200         }
 201         // only in right path
 202         if(substring(plyermodel, 0, 14) != "models/player/")
 203                 return FallbackPlayerModel;
 204         // only good file extensions
 205         if(substring(plyermodel, -4, 4) != ".iqm"
 206                 && substring(plyermodel, -4, 4) != ".zym"
 207                 && substring(plyermodel, -4, 4) != ".dpm"
 208                 && substring(plyermodel, -4, 4) != ".md3"
 209                 && substring(plyermodel, -4, 4) != ".psk")
 210         {
 211                 return FallbackPlayerModel;
 212         }
 213         // forbid the LOD models
 214         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 215                 return FallbackPlayerModel;
 216         if(plyermodel != strtolower(plyermodel))
 217                 return FallbackPlayerModel;
 218         // also, restrict to server models
 219         if(autocvar_sv_servermodelsonly)
 220         {
 221                 if(!fexists(plyermodel))
 222                         return FallbackPlayerModel;
 223         }
 224         return plyermodel;
 225 }
 226
 227 void setplayermodel(entity e, string modelname)
 228 {
 229         precache_model(modelname);
 230         _setmodel(e, modelname);
 231         player_setupanimsformodel(e);
 232         if(!autocvar_g_debug_globalsounds)
 233                 UpdatePlayerSounds(e);
 234 }
 235
 236 /** putting a client as observer in the server */
 237 void PutObserverInServer(entity this)
 238 {
 239         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 240         PlayerState_detach(this);
 241
 242         if (IS_PLAYER(this))
 243         {
 244                 if(GetResource(this, RES_HEALTH) >= 1)
 245                 {
 246                         // despawn effect
 247                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 248                 }
 249
 250                 // was a player, recount votes and ready status
 251                 if(IS_REAL_CLIENT(this))
 252                 {
 253                         if (vote_called) { VoteCount(false); }
 254                         ReadyCount();
 255                 }
 256         }
 257
 258         entity spot = SelectSpawnPoint(this, true);
 259         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 260         this.angles = vec2(spot.angles);
 261         this.fixangle = true;
 262         // offset it so that the spectator spawns higher off the ground, looks better this way
 263         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 264         if (IS_REAL_CLIENT(this))
 265         {
 266                 msg_entity = this;
 267                 WriteByte(MSG_ONE, SVC_SETVIEW);
 268                 WriteEntity(MSG_ONE, this);
 269         }
 270         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 271         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 272         if(!autocvar_g_debug_globalsounds)
 273         {
 274                 // needed for player sounds
 275                 this.model = "";
 276                 FixPlayermodel(this);
 277         }
 278         setmodel(this, MDL_Null);
 279         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 280         this.view_ofs = '0 0 0';
 281
 282         RemoveGrapplingHooks(this);
 283         Portal_ClearAll(this);
 284         Unfreeze(this, false);
 285         SetSpectatee(this, NULL);
 286
 287         if (this.alivetime)
 288         {
 289                 if (!warmup_stage)
 290                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 291                 this.alivetime = 0;
 292         }
 293
 294         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 295
 296         WaypointSprite_PlayerDead(this);
 297
 298         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 299                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 300
 301         accuracy_resend(this);
 302
 303         CS(this).spectatortime = time;
 304         if(this.bot_attack)
 305                 IL_REMOVE(g_bot_targets, this);
 306         this.bot_attack = false;
 307         if(this.monster_attack)
 308                 IL_REMOVE(g_monster_targets, this);
 309         this.monster_attack = false;
 310         STAT(HUD, this) = HUD_NORMAL;
 311         TRANSMUTE(Observer, this);
 312         this.iscreature = false;
 313         this.teleportable = TELEPORT_SIMPLE;
 314         if(this.damagedbycontents)
 315                 IL_REMOVE(g_damagedbycontents, this);
 316         this.damagedbycontents = false;
 317         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 318         SetSpectatee_status(this, etof(this));
 319         this.takedamage = DAMAGE_NO;
 320         this.solid = SOLID_NOT;
 321         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 322         this.flags = FL_CLIENT | FL_NOTARGET;
 323         this.effects = 0;
 324         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 325         this.pauserotarmor_finished = 0;
 326         this.pauserothealth_finished = 0;
 327         this.pauseregen_finished = 0;
 328         this.damageforcescale = 0;
 329         this.death_time = 0;
 330         this.respawn_flags = 0;
 331         this.respawn_time = 0;
 332         STAT(RESPAWN_TIME, this) = 0;
 333         this.alpha = 0;
 334         this.scale = 0;
 335         this.fade_time = 0;
 336         this.pain_finished = 0;
 337         STAT(STRENGTH_FINISHED, this) = 0;
 338         STAT(INVINCIBLE_FINISHED, this) = 0;
 339         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 340         STAT(AIR_FINISHED, this) = 0;
 341         //this.dphitcontentsmask = 0;
 342         this.dphitcontentsmask = DPCONTENTS_SOLID;
 343         if (autocvar_g_playerclip_collisions)
 344                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 345         this.pushltime = 0;
 346         this.istypefrag = 0;
 347         setthink(this, func_null);
 348         this.nextthink = 0;
 349         this.deadflag = DEAD_NO;
 350         UNSET_DUCKED(this);
 351         STAT(REVIVE_PROGRESS, this) = 0;
 352         this.revival_time = 0;
 353         this.draggable = drag_undraggable;
 354
 355         this.items = 0;
 356         STAT(WEAPONS, this) = '0 0 0';
 357         this.drawonlytoclient = this;
 358
 359         this.viewloc = NULL;
 360
 361         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 362
 363         this.weaponmodel = "";
 364         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 365         {
 366                 this.weaponentities[slot] = NULL;
 367         }
 368         this.exteriorweaponentity = NULL;
 369         CS(this).killcount = FRAGS_SPECTATOR;
 370         this.velocity = '0 0 0';
 371         this.avelocity = '0 0 0';
 372         this.punchangle = '0 0 0';
 373         this.punchvector = '0 0 0';
 374         this.oldvelocity = this.velocity;
 375         this.fire_endtime = -1;
 376         this.event_damage = func_null;
 377         this.event_heal = func_null;
 378
 379         for(int slot = 0; slot < MAX_AXH; ++slot)
 380         {
 381                 entity axh = this.(AuxiliaryXhair[slot]);
 382                 this.(AuxiliaryXhair[slot]) = NULL;
 383
 384                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 385                         delete(axh);
 386         }
 387
 388         if (mutator_returnvalue)
 389         {
 390                 // mutator prevents resetting teams+score
 391         }
 392         else
 393         {
 394                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 395                 this.frags = FRAGS_SPECTATOR;
 396         }
 397         if (CS(this).just_joined)
 398                 CS(this).just_joined = false;
 399 }
 400
 401 int player_getspecies(entity this)
 402 {
 403         get_model_parameters(this.model, this.skin);
 404         int s = get_model_parameters_species;
 405         get_model_parameters(string_null, 0);
 406         if (s < 0) return SPECIES_HUMAN;
 407         return s;
 408 }
 409
 410 .float model_randomizer;
 411 void FixPlayermodel(entity player)
 412 {
 413         string defaultmodel = "";
 414         int defaultskin = 0;
 415         if(autocvar_sv_defaultcharacter)
 416         {
 417                 if(teamplay)
 418                 {
 419                         switch(player.team)
 420                         {
 421                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 422                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 423                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 424                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 425                         }
 426                 }
 427
 428                 if(defaultmodel == "")
 429                 {
 430                         defaultmodel = autocvar_sv_defaultplayermodel;
 431                         defaultskin = autocvar_sv_defaultplayerskin;
 432                 }
 433
 434                 int n = tokenize_console(defaultmodel);
 435                 if(n > 0)
 436                 {
 437                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 438                         // However, do NOT randomize if the player-selected model is in the list.
 439                         for (int i = 0; i < n; ++i)
 440                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 441                                         defaultmodel = argv(i);
 442                 }
 443
 444                 int i = strstrofs(defaultmodel, ":", 0);
 445                 if(i >= 0)
 446                 {
 447                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 448                         defaultmodel = substring(defaultmodel, 0, i);
 449                 }
 450         }
 451         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 452         {
 453                 if(teamplay)
 454                 {
 455                         switch(player.team)
 456                         {
 457                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 458                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 459                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 460                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 461                         }
 462                 }
 463
 464                 if(!defaultskin)
 465                         defaultskin = autocvar_sv_defaultplayerskin;
 466         }
 467
 468         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 469         defaultmodel = M_ARGV(0, string);
 470         defaultskin = M_ARGV(1, int);
 471
 472         bool chmdl = false;
 473         int oldskin;
 474         if(defaultmodel != "")
 475         {
 476                 if (defaultmodel != player.model)
 477                 {
 478                         vector m1 = player.mins;
 479                         vector m2 = player.maxs;
 480                         setplayermodel (player, defaultmodel);
 481                         setsize (player, m1, m2);
 482                         chmdl = true;
 483                 }
 484
 485                 oldskin = player.skin;
 486                 player.skin = defaultskin;
 487         } else {
 488                 if (player.playermodel != player.model || player.playermodel == "")
 489                 {
 490                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 491                         vector m1 = player.mins;
 492                         vector m2 = player.maxs;
 493                         setplayermodel (player, player.playermodel);
 494                         setsize (player, m1, m2);
 495                         chmdl = true;
 496                 }
 497
 498                 if(!autocvar_sv_defaultcharacterskin)
 499                 {
 500                         oldskin = player.skin;
 501                         player.skin = stof(player.playerskin);
 502                 }
 503                 else
 504                 {
 505                         oldskin = player.skin;
 506                         player.skin = defaultskin;
 507                 }
 508         }
 509
 510         if(chmdl || oldskin != player.skin) // model or skin has changed
 511         {
 512                 player.species = player_getspecies(player); // update species
 513                 if(!autocvar_g_debug_globalsounds)
 514                         UpdatePlayerSounds(player); // update skin sounds
 515         }
 516
 517         if(!teamplay)
 518                 if(strlen(autocvar_sv_defaultplayercolors))
 519                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 520                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 521 }
 522
 523 void PutPlayerInServer(entity this)
 524 {
 525         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 526
 527         PlayerState_attach(this);
 528         accuracy_resend(this);
 529
 530         if (this.team < 0)
 531                 TeamBalance_JoinBestTeam(this);
 532
 533         entity spot = SelectSpawnPoint(this, false);
 534         if (!spot) {
 535                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 536                 return; // spawn failed
 537         }
 538
 539         TRANSMUTE(Player, this);
 540
 541         CS(this).wasplayer = true;
 542         this.iscreature = true;
 543         this.teleportable = TELEPORT_NORMAL;
 544         if(!this.damagedbycontents)
 545                 IL_PUSH(g_damagedbycontents, this);
 546         this.damagedbycontents = true;
 547         set_movetype(this, MOVETYPE_WALK);
 548         this.solid = SOLID_SLIDEBOX;
 549         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 550         if (autocvar_g_playerclip_collisions)
 551                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 552         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 553                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 554         this.frags = FRAGS_PLAYER;
 555         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 556         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 557         if (autocvar__notarget)
 558                 this.flags |= FL_NOTARGET;
 559         this.takedamage = DAMAGE_AIM;
 560         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 561
 562         if (warmup_stage) {
 563                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 564                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 565                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 566                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 567                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 568                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 569                 SetResource(this, RES_HEALTH, warmup_start_health);
 570                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 571                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 572         } else {
 573                 SetResource(this, RES_SHELLS, start_ammo_shells);
 574                 SetResource(this, RES_BULLETS, start_ammo_nails);
 575                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 576                 SetResource(this, RES_CELLS, start_ammo_cells);
 577                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 578                 SetResource(this, RES_FUEL, start_ammo_fuel);
 579                 SetResource(this, RES_HEALTH, start_health);
 580                 SetResource(this, RES_ARMOR, start_armorvalue);
 581                 STAT(WEAPONS, this) = start_weapons;
 582                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 583                 {
 584                         GiveRandomWeapons(this, random_start_weapons_count,
 585                                 autocvar_g_random_start_weapons, random_start_ammo);
 586                 }
 587         }
 588         SetSpectatee_status(this, 0);
 589
 590         PS(this).dual_weapons = '0 0 0';
 591
 592         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 593
 594         this.items = start_items;
 595
 596         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 597         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 598         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 599         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 600         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 601         if (!sv_ready_restart_after_countdown && time < game_starttime)
 602         {
 603                 float f = game_starttime - time;
 604                 this.spawnshieldtime += f;
 605                 this.pauserotarmor_finished += f;
 606                 this.pauserothealth_finished += f;
 607                 this.pauseregen_finished += f;
 608         }
 609
 610         this.damageforcescale = autocvar_g_player_damageforcescale;
 611         this.death_time = 0;
 612         this.respawn_flags = 0;
 613         this.respawn_time = 0;
 614         STAT(RESPAWN_TIME, this) = 0;
 615         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 616         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 617         this.fade_time = 0;
 618         this.pain_finished = 0;
 619         this.pushltime = 0;
 620         setthink(this, func_null); // players have no think function
 621         this.nextthink = 0;
 622         this.dmg_team = 0;
 623         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 624
 625         this.deadflag = DEAD_NO;
 626
 627         this.angles = spot.angles;
 628         this.angles_z = 0; // never spawn tilted even if the spot says to
 629         if (IS_BOT_CLIENT(this))
 630         {
 631                 this.v_angle = this.angles;
 632                 bot_aim_reset(this);
 633         }
 634         this.fixangle = true; // turn this way immediately
 635         this.oldvelocity = this.velocity = '0 0 0';
 636         this.avelocity = '0 0 0';
 637         this.punchangle = '0 0 0';
 638         this.punchvector = '0 0 0';
 639
 640         STAT(STRENGTH_FINISHED, this) = 0;
 641         STAT(INVINCIBLE_FINISHED, this) = 0;
 642         this.fire_endtime = -1;
 643         STAT(REVIVE_PROGRESS, this) = 0;
 644         this.revival_time = 0;
 645
 646         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 647         STAT(BUFFS, this) = 0;
 648         STAT(BUFF_TIME, this) = 0;
 649
 650         STAT(AIR_FINISHED, this) = 0;
 651         this.waterlevel = WATERLEVEL_NONE;
 652         this.watertype = CONTENT_EMPTY;
 653
 654         entity spawnevent = new_pure(spawnevent);
 655         spawnevent.owner = this;
 656         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 657
 658         // Cut off any still running player sounds.
 659         stopsound(this, CH_PLAYER_SINGLE);
 660
 661         this.model = "";
 662         FixPlayermodel(this);
 663         this.drawonlytoclient = NULL;
 664
 665         this.viewloc = NULL;
 666
 667         for(int slot = 0; slot < MAX_AXH; ++slot)
 668         {
 669                 entity axh = this.(AuxiliaryXhair[slot]);
 670                 this.(AuxiliaryXhair[slot]) = NULL;
 671
 672                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 673                         delete(axh);
 674         }
 675
 676         this.spawnpoint_targ = NULL;
 677
 678         UNSET_DUCKED(this);
 679         this.view_ofs = STAT(PL_VIEW_OFS, this);
 680         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 681         this.spawnorigin = spot.origin;
 682         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 683         // don't reset back to last position, even if new position is stuck in solid
 684         this.oldorigin = this.origin;
 685         if(this.conveyor)
 686                 IL_REMOVE(g_conveyed, this);
 687         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 688         if(this.swampslug)
 689                 IL_REMOVE(g_swamped, this);
 690         this.swampslug = NULL;
 691         this.swamp_interval = 0;
 692         if(this.ladder_entity)
 693                 IL_REMOVE(g_ladderents, this);
 694         this.ladder_entity = NULL;
 695         IL_EACH(g_counters, it.realowner == this,
 696         {
 697                 delete(it);
 698         });
 699         STAT(HUD, this) = HUD_NORMAL;
 700
 701         this.event_damage = PlayerDamage;
 702         this.event_heal = PlayerHeal;
 703
 704         this.draggable = func_null;
 705
 706         if(!this.bot_attack)
 707                 IL_PUSH(g_bot_targets, this);
 708         this.bot_attack = true;
 709         if(!this.monster_attack)
 710                 IL_PUSH(g_monster_targets, this);
 711         this.monster_attack = true;
 712         navigation_dynamicgoal_init(this, false);
 713
 714         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 715
 716         // player was spectator
 717         if (CS(this).killcount == FRAGS_SPECTATOR) {
 718                 PlayerScore_Clear(this);
 719                 CS(this).killcount = 0;
 720                 CS(this).startplaytime = time;
 721         }
 722
 723         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 724         {
 725                 .entity weaponentity = weaponentities[slot];
 726                 CL_SpawnWeaponentity(this, weaponentity);
 727         }
 728         this.alpha = default_player_alpha;
 729         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 730         this.exteriorweaponentity.alpha = default_weapon_alpha;
 731
 732         this.speedrunning = false;
 733
 734         this.counter_cnt = 0;
 735         this.fragsfilter_cnt = 0;
 736
 737         target_voicescript_clear(this);
 738
 739         // reset fields the weapons may use
 740         FOREACH(Weapons, true, {
 741                 it.wr_resetplayer(it, this);
 742                         // reload all reloadable weapons
 743                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 744                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 745                         {
 746                                 .entity weaponentity = weaponentities[slot];
 747                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 748                         }
 749                 }
 750         });
 751
 752         {
 753                 string s = spot.target;
 754                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 755                         spot.target = string_null;
 756                 SUB_UseTargets(spot, this, NULL);
 757                 if(g_assault || g_race)
 758                         spot.target = s;
 759         }
 760
 761         Unfreeze(this, false);
 762
 763         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 764
 765         if (autocvar_spawn_debug)
 766         {
 767                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 768                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 769         }
 770
 771         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 772         {
 773                 .entity weaponentity = weaponentities[slot];
 774                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 775                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 776                 else
 777                         this.(weaponentity).m_switchweapon = WEP_Null;
 778                 this.(weaponentity).m_weapon = WEP_Null;
 779                 this.(weaponentity).weaponname = "";
 780                 this.(weaponentity).m_switchingweapon = WEP_Null;
 781                 this.(weaponentity).cnt = -1;
 782         }
 783
 784         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 785
 786         if (CS(this).impulse) ImpulseCommands(this);
 787
 788         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 789         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 790         {
 791                 .entity weaponentity = weaponentities[slot];
 792                 W_WeaponFrame(this, weaponentity);
 793         }
 794
 795         if (!warmup_stage && !this.alivetime)
 796                 this.alivetime = time;
 797
 798         antilag_clear(this, CS(this));
 799 }
 800
 801 /** Called when a client spawns in the server */
 802 void PutClientInServer(entity this)
 803 {
 804         if (IS_BOT_CLIENT(this)) {
 805                 TRANSMUTE(Player, this);
 806         } else if (IS_REAL_CLIENT(this)) {
 807                 msg_entity = this;
 808                 WriteByte(MSG_ONE, SVC_SETVIEW);
 809                 WriteEntity(MSG_ONE, this);
 810         }
 811         if (game_stopped)
 812                 TRANSMUTE(Observer, this);
 813
 814         SetSpectatee(this, NULL);
 815
 816         // reset player keys
 817         if(PS(this))
 818                 PS(this).itemkeys = 0;
 819
 820         MUTATOR_CALLHOOK(PutClientInServer, this);
 821
 822         if (IS_OBSERVER(this)) {
 823                 PutObserverInServer(this);
 824         } else if (IS_PLAYER(this)) {
 825                 PutPlayerInServer(this);
 826         }
 827 }
 828
 829 // TODO do we need all these fields, or should we stop autodetecting runtime
 830 // changes and just have a console command to update this?
 831 bool ClientInit_SendEntity(entity this, entity to, int sf)
 832 {
 833         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 834         return = true;
 835         msg_entity = to;
 836         // MSG_INIT replacement
 837         // TODO: make easier to use
 838         Registry_send_all();
 839         W_PROP_reload(MSG_ONE, to);
 840         ClientInit_misc(this);
 841         MUTATOR_CALLHOOK(Ent_Init);
 842 }
 843 void ClientInit_misc(entity this)
 844 {
 845         int channel = MSG_ONE;
 846         WriteHeader(channel, ENT_CLIENT_INIT);
 847         WriteByte(channel, g_nexball_meter_period * 32);
 848         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 849         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 850         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 851         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 852         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 853         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 854         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 855         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 856
 857         if(autocvar_sv_foginterval && world.fog != "")
 858                 WriteString(channel, world.fog);
 859         else
 860                 WriteString(channel, "");
 861         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 862         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 863         WriteByte(channel, serverflags);
 864         WriteCoord(channel, autocvar_g_trueaim_minrange);
 865 }
 866
 867 void ClientInit_CheckUpdate(entity this)
 868 {
 869         this.nextthink = time;
 870         if(this.count != autocvar_g_balance_armor_blockpercent)
 871         {
 872                 this.count = autocvar_g_balance_armor_blockpercent;
 873                 this.SendFlags |= 1;
 874         }
 875         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 876         {
 877                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 878                 this.SendFlags |= 1;
 879         }
 880 }
 881
 882 void ClientInit_Spawn()
 883 {
 884         entity e = new_pure(clientinit);
 885         setthink(e, ClientInit_CheckUpdate);
 886         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 887
 888         ClientInit_CheckUpdate(e);
 889 }
 890
 891 /*
 892 =============
 893 SetNewParms
 894 =============
 895 */
 896 void SetNewParms ()
 897 {
 898         // initialize parms for a new player
 899         parm1 = -(86400 * 366);
 900
 901         MUTATOR_CALLHOOK(SetNewParms);
 902 }
 903
 904 /*
 905 =============
 906 SetChangeParms
 907 =============
 908 */
 909 void SetChangeParms (entity this)
 910 {
 911         // save parms for level change
 912         parm1 = CS(this).parm_idlesince - time;
 913
 914         MUTATOR_CALLHOOK(SetChangeParms);
 915 }
 916
 917 /*
 918 =============
 919 DecodeLevelParms
 920 =============
 921 */
 922 void DecodeLevelParms(entity this)
 923 {
 924         // load parms
 925         CS(this).parm_idlesince = parm1;
 926         if (CS(this).parm_idlesince == -(86400 * 366))
 927                 CS(this).parm_idlesince = time;
 928
 929         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 930         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 931
 932         MUTATOR_CALLHOOK(DecodeLevelParms);
 933 }
 934
 935 void FixClientCvars(entity e)
 936 {
 937         // send prediction settings to the client
 938         stuffcmd(e, "\nin_bindmap 0 0\n");
 939         if(autocvar_g_antilag == 3) // client side hitscan
 940                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 941         if(autocvar_sv_gentle)
 942                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 943
 944         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 945         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 946
 947         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 948
 949         MUTATOR_CALLHOOK(FixClientCvars, e);
 950 }
 951
 952 bool findinlist_abbrev(string tofind, string list)
 953 {
 954         if(list == "" || tofind == "")
 955                 return false; // empty list or search, just return
 956
 957         // this function allows abbreviated strings!
 958         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 959         {
 960                 return true;
 961         });
 962
 963         return false;
 964 }
 965
 966 bool PlayerInIPList(entity p, string iplist)
 967 {
 968         // some safety checks (never allow local?)
 969         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 970                 return false;
 971
 972         return findinlist_abbrev(p.netaddress, iplist);
 973 }
 974
 975 bool PlayerInIDList(entity p, string idlist)
 976 {
 977         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 978         if(!p.crypto_idfp)
 979                 return false;
 980
 981         return findinlist_abbrev(p.crypto_idfp, idlist);
 982 }
 983
 984 bool PlayerInList(entity player, string list)
 985 {
 986         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 987 }
 988
 989 #ifdef DP_EXT_PRECONNECT
 990 /*
 991 =============
 992 ClientPreConnect
 993
 994 Called once (not at each match start) when a client begins a connection to the server
 995 =============
 996 */
 997 void ClientPreConnect(entity this)
 998 {
 999         if(autocvar_sv_eventlog)
1000         {
1001                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1002                         this.playerid,
1003                         etof(this),
1004                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1005                 ));
1006         }
1007 }
1008 #endif
1009
1010 string GetClientVersionMessage(entity this)
1011 {
1012         if (CS(this).version_mismatch) {
1013                 if(CS(this).version < autocvar_gameversion) {
1014                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1015                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1016                 } else {
1017                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1018                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1019                 }
1020         } else {
1021                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1022         }
1023 }
1024
1025 string getwelcomemessage(entity this)
1026 {
1027         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1028         string modifications = M_ARGV(0, string);
1029
1030         if(g_weaponarena)
1031         {
1032                 if(g_weaponarena_random)
1033                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1034                 else
1035                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1036         }
1037         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1038                 modifications = strcat(modifications, ", No start weapons");
1039         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1040                 modifications = strcat(modifications, ", Low gravity");
1041         if(g_weapon_stay && !g_cts)
1042                 modifications = strcat(modifications, ", Weapons stay");
1043         if(autocvar_g_jetpack)
1044                 modifications = strcat(modifications, ", Jet pack");
1045         if(autocvar_g_powerups == 0)
1046                 modifications = strcat(modifications, ", No powerups");
1047         if(autocvar_g_powerups > 0)
1048                 modifications = strcat(modifications, ", Powerups");
1049         modifications = substring(modifications, 2, strlen(modifications) - 2);
1050
1051         string versionmessage = GetClientVersionMessage(this);
1052         string s = strcat(versionmessage, "^8\n^8\nhost is ^9", autocvar_hostname, "^8\n");
1053
1054         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1055
1056         if(modifications != "")
1057                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1058
1059         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1060         {
1061                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1062                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1063         }
1064
1065         if (cache_mutatormsg != "") {
1066                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1067         }
1068
1069         string mutator_msg = "";
1070         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1071         mutator_msg = M_ARGV(0, string);
1072
1073         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1074
1075         string motd = autocvar_sv_motd;
1076         if (motd != "") {
1077                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1078         }
1079         return s;
1080 }
1081
1082 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1083
1084 /**
1085 =============
1086 ClientConnect
1087
1088 Called when a client connects to the server
1089 =============
1090 */
1091 void ClientConnect(entity this)
1092 {
1093         if (Ban_MaybeEnforceBanOnce(this)) return;
1094         assert(!IS_CLIENT(this), return);
1095         this.flags |= FL_CLIENT;
1096         assert(player_count >= 0, player_count = 0);
1097
1098         TRANSMUTE(Client, this);
1099         CS(this).version_nagtime = time + 10 + random() * 10;
1100
1101         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1102
1103         bot_clientconnect(this);
1104
1105         Player_DetermineForcedTeam(this);
1106
1107         TRANSMUTE(Observer, this);
1108
1109         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1110
1111         // always track bots, don't ask for cl_allow_uidtracking
1112         if (IS_BOT_CLIENT(this))
1113                 PlayerStats_GameReport_AddPlayer(this);
1114         else
1115                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1116
1117         if (autocvar_sv_eventlog)
1118                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1119
1120         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1121
1122         stuffcmd(this, clientstuff, "\n");
1123         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1124
1125         FixClientCvars(this);
1126
1127         // get version info from player
1128         stuffcmd(this, "cmd clientversion $gameversion\n");
1129
1130         // notify about available teams
1131         if (teamplay)
1132         {
1133                 entity balance = TeamBalance_CheckAllowedTeams(this);
1134                 int t = TeamBalance_GetAllowedTeams(balance);
1135                 TeamBalance_Destroy(balance);
1136                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1137         }
1138         else
1139         {
1140                 stuffcmd(this, "set _teams_available 0\n");
1141         }
1142
1143         bot_relinkplayerlist();
1144
1145         CS(this).spectatortime = time;
1146         if (blockSpectators)
1147         {
1148                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1149         }
1150
1151         CS(this).jointime = time;
1152
1153         if (IS_REAL_CLIENT(this))
1154         {
1155                 if (g_weaponarena_weapons == WEPSET(TUBA))
1156                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1157         }
1158
1159         if (!autocvar_sv_foginterval && world.fog != "")
1160                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1161
1162         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1163                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1164                         send_CSQC_teamnagger();
1165
1166         CSQCMODEL_AUTOINIT(this);
1167
1168         CS(this).model_randomizer = random();
1169
1170         if (IS_REAL_CLIENT(this))
1171                 sv_notice_join(this);
1172
1173         this.move_qcphysics = autocvar_sv_qcphysics;
1174
1175         // update physics stats (players can spawn before physics runs)
1176         Physics_UpdateStats(this);
1177
1178         IL_EACH(g_initforplayer, it.init_for_player, {
1179                 it.init_for_player(it, this);
1180         });
1181
1182         Handicap_Initialize(this);
1183
1184         MUTATOR_CALLHOOK(ClientConnect, this);
1185
1186         if (IS_REAL_CLIENT(this))
1187         {
1188                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1189                 {
1190                         CS(this).motd_actived_time = -1;
1191                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1192                 }
1193         }
1194 }
1195 /*
1196 =============
1197 ClientDisconnect
1198
1199 Called when a client disconnects from the server
1200 =============
1201 */
1202 .entity chatbubbleentity;
1203 void ClientDisconnect(entity this)
1204 {
1205         assert(IS_CLIENT(this), return);
1206
1207         PlayerStats_GameReport_FinalizePlayer(this);
1208         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1209         if (CS(this).active_minigame) part_minigame(this);
1210         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1211
1212         if (autocvar_sv_eventlog)
1213                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1214
1215         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1216
1217         if(IS_SPEC(this))
1218                 SetSpectatee(this, NULL);
1219
1220         MUTATOR_CALLHOOK(ClientDisconnect, this);
1221
1222         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1223         strfree(CS_CVAR(this).weaponorder_byimpulse);
1224         ClientState_detach(this);
1225
1226         Portal_ClearAll(this);
1227
1228         Unfreeze(this, false);
1229
1230         RemoveGrapplingHooks(this);
1231
1232         // Here, everything has been done that requires this player to be a client.
1233
1234         this.flags &= ~FL_CLIENT;
1235
1236         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1237         if (this.killindicator) delete(this.killindicator);
1238
1239         IL_EACH(g_counters, it.realowner == this,
1240         {
1241                 delete(it);
1242         });
1243
1244         WaypointSprite_PlayerGone(this);
1245
1246         bot_relinkplayerlist();
1247
1248         strfree(this.clientstatus);
1249         if (this.personal) delete(this.personal);
1250
1251         this.playerid = 0;
1252         ReadyCount();
1253         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1254
1255         ONREMOVE(this);
1256 }
1257
1258 void ChatBubbleThink(entity this)
1259 {
1260         this.nextthink = time;
1261         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1262         {
1263                 if(this.owner) // but why can that ever be NULL?
1264                         this.owner.chatbubbleentity = NULL;
1265                 delete(this);
1266                 return;
1267         }
1268
1269         this.mdl = "";
1270
1271         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1272         {
1273                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1274                         this.mdl = "models/sprites/minigame_busy.iqm";
1275                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1276                         this.mdl = "models/misc/chatbubble.spr";
1277         }
1278
1279         if ( this.model != this.mdl )
1280                 _setmodel(this, this.mdl);
1281
1282 }
1283
1284 void UpdateChatBubble(entity this)
1285 {
1286         if (this.alpha < 0)
1287                 return;
1288         // spawn a chatbubble entity if needed
1289         if (!this.chatbubbleentity)
1290         {
1291                 this.chatbubbleentity = new(chatbubbleentity);
1292                 this.chatbubbleentity.owner = this;
1293                 this.chatbubbleentity.exteriormodeltoclient = this;
1294                 setthink(this.chatbubbleentity, ChatBubbleThink);
1295                 this.chatbubbleentity.nextthink = time;
1296                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1297                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1298                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1299                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1300                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1301                 //this.chatbubbleentity.model = "";
1302                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1303         }
1304 }
1305
1306 void calculate_player_respawn_time(entity this)
1307 {
1308         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1309                 return;
1310
1311         float gametype_setting_tmp;
1312         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1313         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1314         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1315         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1316         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1317         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1318
1319         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1320         if (teamplay)
1321         {
1322                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1323                         if(it.team == this.team)
1324                                 ++pcount;
1325                 });
1326                 if (sdelay_small_count == 0)
1327                         sdelay_small_count = 1;
1328                 if (sdelay_large_count == 0)
1329                         sdelay_large_count = 1;
1330         }
1331         else
1332         {
1333                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1334                         ++pcount;
1335                 });
1336                 if (sdelay_small_count == 0)
1337                 {
1338                         if (IS_INDEPENDENT_PLAYER(this))
1339                         {
1340                                 // Players play independently. No point in requiring enemies.
1341                                 sdelay_small_count = 1;
1342                         }
1343                         else
1344                         {
1345                                 // Players play AGAINST each other. Enemies required.
1346                                 sdelay_small_count = 2;
1347                         }
1348                 }
1349                 if (sdelay_large_count == 0)
1350                 {
1351                         if (IS_INDEPENDENT_PLAYER(this))
1352                         {
1353                                 // Players play independently. No point in requiring enemies.
1354                                 sdelay_large_count = 1;
1355                         }
1356                         else
1357                         {
1358                                 // Players play AGAINST each other. Enemies required.
1359                                 sdelay_large_count = 2;
1360                         }
1361                 }
1362         }
1363
1364         float sdelay;
1365
1366         if (pcount <= sdelay_small_count)
1367                 sdelay = sdelay_small;
1368         else if (pcount >= sdelay_large_count)
1369                 sdelay = sdelay_large;
1370         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1371                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1372
1373         if(waves)
1374                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1375         else
1376                 this.respawn_time = time + sdelay;
1377
1378         if(sdelay < sdelay_max)
1379                 this.respawn_time_max = time + sdelay_max;
1380         else
1381                 this.respawn_time_max = this.respawn_time;
1382
1383         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1384                 this.respawn_countdown = 10; // first number to count down from is 10
1385         else
1386                 this.respawn_countdown = -1; // do not count down
1387
1388         if(autocvar_g_forced_respawn)
1389                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1390 }
1391
1392 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1393 // added to the model skins
1394 /*void UpdateColorModHack()
1395 {
1396         float c;
1397         c = this.clientcolors & 15;
1398         // LordHavoc: only bothering to support white, green, red, yellow, blue
1399              if (!teamplay) this.colormod = '0 0 0';
1400         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1401         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1402         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1403         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1404         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1405         else this.colormod = '1 1 1';
1406 }*/
1407
1408 void respawn(entity this)
1409 {
1410         bool damagedbycontents_prev = this.damagedbycontents;
1411         if(this.alpha >= 0)
1412         {
1413                 if(autocvar_g_respawn_ghosts)
1414                 {
1415                         this.solid = SOLID_NOT;
1416                         this.takedamage = DAMAGE_NO;
1417                         this.damagedbycontents = false;
1418                         set_movetype(this, MOVETYPE_FLY);
1419                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1420                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1421                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1422                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1423                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1424                         if(autocvar_g_respawn_ghosts_time > 0)
1425                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1426                 }
1427                 else
1428                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1429         }
1430
1431         CopyBody(this, 1);
1432         this.damagedbycontents = damagedbycontents_prev;
1433
1434         this.effects |= EF_NODRAW; // prevent another CopyBody
1435         PutClientInServer(this);
1436 }
1437
1438 void play_countdown(entity this, float finished, Sound samp)
1439 {
1440         TC(Sound, samp);
1441         if(IS_REAL_CLIENT(this))
1442                 if(floor(finished - time - frametime) != floor(finished - time))
1443                         if(finished - time < 6)
1444                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1445 }
1446
1447 void player_powerups(entity this)
1448 {
1449         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1450                 this.modelflags |= MF_ROCKET;
1451         else
1452                 this.modelflags &= ~MF_ROCKET;
1453
1454         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1455
1456         if (IS_DEAD(this))
1457         {
1458                 if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1459                 {
1460                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1461                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1462                         this.items &= ~ITEM_Strength.m_itemid;
1463                         this.items &= ~ITEM_Shield.m_itemid;
1464                         this.items -= (this.items & IT_SUPERWEAPON);
1465                 }
1466         }
1467
1468         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1469                 return;
1470
1471         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1472         int items_prev = this.items;
1473
1474         Fire_ApplyDamage(this);
1475         Fire_ApplyEffect(this);
1476
1477         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1478         {
1479                 if (this.items & ITEM_Strength.m_itemid)
1480                 {
1481                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1482                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1483                         if (time > STAT(STRENGTH_FINISHED, this))
1484                         {
1485                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1486                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1487                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1488                         }
1489                 }
1490                 else
1491                 {
1492                         if (time < STAT(STRENGTH_FINISHED, this))
1493                         {
1494                                 this.items = this.items | ITEM_Strength.m_itemid;
1495                                 if(!g_cts)
1496                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1497                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1498                         }
1499                 }
1500                 if (this.items & ITEM_Shield.m_itemid)
1501                 {
1502                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1503                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1504                         if (time > STAT(INVINCIBLE_FINISHED, this))
1505                         {
1506                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1507                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1508                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1509                         }
1510                 }
1511                 else
1512                 {
1513                         if (time < STAT(INVINCIBLE_FINISHED, this))
1514                         {
1515                                 this.items = this.items | ITEM_Shield.m_itemid;
1516                                 if(!g_cts)
1517                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1518                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1519                         }
1520                 }
1521                 if (this.items & IT_SUPERWEAPON)
1522                 {
1523                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1524                         {
1525                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1526                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1527                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1528                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1529                         }
1530                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1531                         {
1532                                 // don't let them run out
1533                         }
1534                         else
1535                         {
1536                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1537                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1538                                 {
1539                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1540                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1541                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1542                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1543                                 }
1544                         }
1545                 }
1546                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1547                 {
1548                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1549                         {
1550                                 this.items = this.items | IT_SUPERWEAPON;
1551                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1552                                 {
1553                                         if(!g_cts)
1554                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1555                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1556                                 }
1557                         }
1558                         else
1559                         {
1560                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1561                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1562                         }
1563                 }
1564                 else
1565                 {
1566                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1567                 }
1568         }
1569
1570         if(autocvar_g_nodepthtestplayers)
1571                 this.effects = this.effects | EF_NODEPTHTEST;
1572
1573         if(autocvar_g_fullbrightplayers)
1574                 this.effects = this.effects | EF_FULLBRIGHT;
1575
1576         if (time >= game_starttime)
1577         if (time < this.spawnshieldtime)
1578                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1579
1580         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1581 }
1582
1583 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1584 {
1585         if(current > stable)
1586                 return current;
1587         else if(current > stable - 0.25) // when close enough, "snap"
1588                 return stable;
1589         else
1590                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1591 }
1592
1593 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1594 {
1595         if(current < stable)
1596                 return current;
1597         else if(current < stable + 0.25) // when close enough, "snap"
1598                 return stable;
1599         else
1600                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1601 }
1602
1603 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1604 {
1605         float old = GetResource(this, res);
1606         float current = old;
1607         if(current > rotstable)
1608         {
1609                 if(rotframetime > 0)
1610                 {
1611                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1612                         current = max(rotstable, current - rotlinear * rotframetime);
1613                 }
1614         }
1615         else if(current < regenstable)
1616         {
1617                 if(regenframetime > 0)
1618                 {
1619                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1620                         current = min(regenstable, current + regenlinear * regenframetime);
1621                 }
1622         }
1623
1624         float limit = GetResourceLimit(this, res) * limit_mod;
1625         if(current > limit)
1626                 current = limit;
1627
1628         if (current != old)
1629                 SetResource(this, res, current);
1630 }
1631
1632 void player_regen(entity this)
1633 {
1634         float max_mod, regen_mod, rot_mod, limit_mod;
1635         max_mod = regen_mod = rot_mod = limit_mod = 1;
1636
1637         float regen_health = autocvar_g_balance_health_regen;
1638         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1639         float regen_health_rot = autocvar_g_balance_health_rot;
1640         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1641         float regen_health_stable = autocvar_g_balance_health_regenstable;
1642         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1643         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1644                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1645         max_mod = M_ARGV(1, float);
1646         regen_mod = M_ARGV(2, float);
1647         rot_mod = M_ARGV(3, float);
1648         limit_mod = M_ARGV(4, float);
1649         regen_health = M_ARGV(5, float);
1650         regen_health_linear = M_ARGV(6, float);
1651         regen_health_rot = M_ARGV(7, float);
1652         regen_health_rotlinear = M_ARGV(8, float);
1653         regen_health_stable = M_ARGV(9, float);
1654         regen_health_rotstable = M_ARGV(10, float);
1655
1656         if(!mutator_returnvalue)
1657         if(!STAT(FROZEN, this))
1658         {
1659                 float maxa = autocvar_g_balance_armor_rotstable;
1660                 float mina = autocvar_g_balance_armor_regenstable;
1661
1662                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1663                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1664                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1665
1666                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1667                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1668                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1669         }
1670
1671         // if player rotted to death...  die!
1672         // check this outside above checks, as player may still be able to rot to death
1673         if(GetResource(this, RES_HEALTH) < 1)
1674         {
1675                 if(this.vehicle)
1676                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1677                 if(this.event_damage)
1678                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1679         }
1680
1681         if (!(this.items & IT_UNLIMITED_AMMO))
1682         {
1683                 float maxf = autocvar_g_balance_fuel_rotstable;
1684                 float minf = autocvar_g_balance_fuel_regenstable;
1685
1686                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1687                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1688                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1689         }
1690 }
1691
1692 bool zoomstate_set;
1693 void SetZoomState(entity this, float newzoom)
1694 {
1695         if(newzoom != CS(this).zoomstate)
1696         {
1697                 CS(this).zoomstate = newzoom;
1698                 ClientData_Touch(this);
1699         }
1700         zoomstate_set = true;
1701 }
1702
1703 void GetPressedKeys(entity this)
1704 {
1705         MUTATOR_CALLHOOK(GetPressedKeys, this);
1706         int keys = STAT(PRESSED_KEYS, this);
1707         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1708         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1709         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1710         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1711
1712         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1713         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1714         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1715         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1716         CS(this).pressedkeys = keys; // store for other users
1717
1718         STAT(PRESSED_KEYS, this) = keys;
1719 }
1720
1721 /*
1722 ======================
1723 spectate mode routines
1724 ======================
1725 */
1726
1727 void SpectateCopy(entity this, entity spectatee)
1728 {
1729         TC(Client, this); TC(Client, spectatee);
1730
1731         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1732         PS(this) = PS(spectatee);
1733         this.armortype = spectatee.armortype;
1734         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1735         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1736         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1737         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1738         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1739         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1740         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1741         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1742         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1743         CS(this).impulse = 0;
1744         this.disableclientprediction = 1; // no need to run prediction on a spectator
1745         this.items = spectatee.items;
1746         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1747         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1748         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1749         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1750         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1751         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1752         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1753         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1754         this.punchangle = spectatee.punchangle;
1755         this.view_ofs = spectatee.view_ofs;
1756         this.velocity = spectatee.velocity;
1757         this.dmg_take = spectatee.dmg_take;
1758         this.dmg_save = spectatee.dmg_save;
1759         this.dmg_inflictor = spectatee.dmg_inflictor;
1760         this.v_angle = spectatee.v_angle;
1761         this.angles = spectatee.v_angle;
1762         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1763         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1764         this.viewloc = spectatee.viewloc;
1765         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1766                 this.fixangle = true;
1767         setorigin(this, spectatee.origin);
1768         setsize(this, spectatee.mins, spectatee.maxs);
1769         SetZoomState(this, CS(spectatee).zoomstate);
1770
1771     anticheat_spectatecopy(this, spectatee);
1772         STAT(HUD, this) = STAT(HUD, spectatee);
1773         if(spectatee.vehicle)
1774     {
1775         this.angles = spectatee.v_angle;
1776
1777         //this.fixangle = false;
1778         //this.velocity = spectatee.vehicle.velocity;
1779         this.vehicle_health = spectatee.vehicle_health;
1780         this.vehicle_shield = spectatee.vehicle_shield;
1781         this.vehicle_energy = spectatee.vehicle_energy;
1782         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1783         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1784         this.vehicle_reload1 = spectatee.vehicle_reload1;
1785         this.vehicle_reload2 = spectatee.vehicle_reload2;
1786
1787         //msg_entity = this;
1788
1789        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1790             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1791            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1792            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1793
1794         //WriteByte (MSG_ONE, SVC_SETVIEW);
1795         //    WriteEntity(MSG_ONE, this);
1796         //makevectors(spectatee.v_angle);
1797         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1798     }
1799 }
1800
1801 bool SpectateUpdate(entity this)
1802 {
1803         if(!this.enemy)
1804                 return false;
1805
1806         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1807         {
1808                 SetSpectatee(this, NULL);
1809                 return false;
1810         }
1811
1812         SpectateCopy(this, this.enemy);
1813
1814         return true;
1815 }
1816
1817 bool SpectateSet(entity this)
1818 {
1819         if(!IS_PLAYER(this.enemy))
1820                 return false;
1821
1822         ClientData_Touch(this.enemy);
1823
1824         msg_entity = this;
1825         WriteByte(MSG_ONE, SVC_SETVIEW);
1826         WriteEntity(MSG_ONE, this.enemy);
1827         set_movetype(this, MOVETYPE_NONE);
1828         accuracy_resend(this);
1829
1830         if(!SpectateUpdate(this))
1831                 PutObserverInServer(this);
1832
1833         return true;
1834 }
1835
1836 void SetSpectatee_status(entity this, int spectatee_num)
1837 {
1838         int oldspectatee_status = CS(this).spectatee_status;
1839         CS(this).spectatee_status = spectatee_num;
1840
1841         if (CS(this).spectatee_status != oldspectatee_status)
1842         {
1843                 if (STAT(PRESSED_KEYS, this))
1844                 {
1845                         CS(this).pressedkeys = 0;
1846                         STAT(PRESSED_KEYS, this) = 0;
1847                 }
1848                 ClientData_Touch(this);
1849                 if (g_race || g_cts) race_InitSpectator();
1850         }
1851 }
1852
1853 void SetSpectatee(entity this, entity spectatee)
1854 {
1855         if(IS_BOT_CLIENT(this))
1856                 return; // bots abuse .enemy, this code is useless to them
1857
1858         entity old_spectatee = this.enemy;
1859
1860         this.enemy = spectatee;
1861
1862         // WEAPONTODO
1863         // these are required to fix the spectator bug with arc
1864         if(old_spectatee)
1865         {
1866                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1867                 {
1868                         .entity weaponentity = weaponentities[slot];
1869                         if(old_spectatee.(weaponentity).arc_beam)
1870                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1871                 }
1872         }
1873         if(this.enemy)
1874         {
1875                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1876                 {
1877                         .entity weaponentity = weaponentities[slot];
1878                         if(this.enemy.(weaponentity).arc_beam)
1879                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1880                 }
1881         }
1882
1883         if (this.enemy)
1884                 SetSpectatee_status(this, etof(this.enemy));
1885
1886         // needed to update spectator list
1887         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1888 }
1889
1890 bool Spectate(entity this, entity pl)
1891 {
1892         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1893                 return false;
1894         pl = M_ARGV(1, entity);
1895
1896         SetSpectatee(this, pl);
1897         return SpectateSet(this);
1898 }
1899
1900 bool SpectateNext(entity this)
1901 {
1902         entity ent = find(this.enemy, classname, STR_PLAYER);
1903
1904         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1905                 ent = M_ARGV(1, entity);
1906         else if (!ent)
1907                 ent = find(ent, classname, STR_PLAYER);
1908
1909         if(ent) { SetSpectatee(this, ent); }
1910
1911         return SpectateSet(this);
1912 }
1913
1914 bool SpectatePrev(entity this)
1915 {
1916         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1917         entity ent = findchain(classname, STR_PLAYER);
1918         if (!ent) // no player
1919                 return false;
1920
1921         entity first = ent;
1922         // skip players until current spectated player
1923         if(this.enemy)
1924         while(ent && ent != this.enemy)
1925                 ent = ent.chain;
1926
1927         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1928         {
1929                 case MUT_SPECPREV_FOUND:
1930                         ent = M_ARGV(1, entity);
1931                         break;
1932                 case MUT_SPECPREV_RETURN:
1933                         return true;
1934                 case MUT_SPECPREV_CONTINUE:
1935                 default:
1936                 {
1937                         if(ent.chain)
1938                                 ent = ent.chain;
1939                         else
1940                                 ent = first;
1941                         break;
1942                 }
1943         }
1944
1945         SetSpectatee(this, ent);
1946         return SpectateSet(this);
1947 }
1948
1949 /*
1950 =============
1951 ShowRespawnCountdown()
1952
1953 Update a respawn countdown display.
1954 =============
1955 */
1956 void ShowRespawnCountdown(entity this)
1957 {
1958         float number;
1959         if(!IS_DEAD(this)) // just respawned?
1960                 return;
1961         else
1962         {
1963                 number = ceil(this.respawn_time - time);
1964                 if(number <= 0)
1965                         return;
1966                 if(number <= this.respawn_countdown)
1967                 {
1968                         this.respawn_countdown = number - 1;
1969                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1970                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1971                 }
1972         }
1973 }
1974
1975 .bool team_selected;
1976 bool ShowTeamSelection(entity this)
1977 {
1978         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1979                 return false;
1980         stuffcmd(this, "menu_showteamselect\n");
1981         return true;
1982 }
1983 void Join(entity this)
1984 {
1985         TRANSMUTE(Player, this);
1986
1987         if(!this.team_selected)
1988         if(autocvar_g_campaign || autocvar_g_balance_teams)
1989                 TeamBalance_JoinBestTeam(this);
1990
1991         if(autocvar_g_campaign)
1992                 campaign_bots_may_start = true;
1993
1994         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1995
1996         PutClientInServer(this);
1997
1998         if(IS_PLAYER(this))
1999         if(teamplay && this.team != -1)
2000         {
2001         }
2002         else
2003                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2004         this.team_selected = false;
2005 }
2006
2007 int GetPlayerLimit()
2008 {
2009         if(g_duel)
2010                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2011         int player_limit = autocvar_g_maxplayers;
2012         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2013         player_limit = M_ARGV(0, int);
2014         return player_limit;
2015 }
2016
2017 /**
2018  * Determines whether the player is allowed to join. This depends on cvar
2019  * g_maxplayers, if it isn't used this function always return true, otherwise
2020  * it checks whether the number of currently playing players exceeds g_maxplayers.
2021  * @return int number of free slots for players, 0 if none
2022  */
2023 int nJoinAllowed(entity this, entity ignore)
2024 {
2025         if(!ignore)
2026         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2027         // so report 0 free slots if restricted
2028         {
2029                 if(autocvar_g_forced_team_otherwise == "spectate")
2030                         return 0;
2031                 if(autocvar_g_forced_team_otherwise == "spectator")
2032                         return 0;
2033         }
2034
2035         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2036                 return 0; // forced spectators can never join
2037
2038         // TODO simplify this
2039         int totalClients = 0;
2040         int currentlyPlaying = 0;
2041         FOREACH_CLIENT(true, {
2042                 if(it != ignore)
2043                         ++totalClients;
2044                 if(IS_REAL_CLIENT(it))
2045                 if(IS_PLAYER(it) || it.caplayer)
2046                         ++currentlyPlaying;
2047         });
2048
2049         int player_limit = GetPlayerLimit();
2050
2051         int free_slots = 0;
2052         if (!player_limit)
2053                 free_slots = maxclients - totalClients;
2054         else if(player_limit > 0 && currentlyPlaying < player_limit)
2055                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2056
2057         static float msg_time = 0;
2058         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2059         {
2060                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2061                 msg_time = time + 0.5;
2062         }
2063
2064         return free_slots;
2065 }
2066
2067 /**
2068  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2069  * g_maxplayers_spectator_blocktime seconds
2070  */
2071 void checkSpectatorBlock(entity this)
2072 {
2073         if(IS_SPEC(this) || IS_OBSERVER(this))
2074         if(!this.caplayer)
2075         if(IS_REAL_CLIENT(this))
2076         {
2077                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2078                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2079                         dropclient(this);
2080                 }
2081         }
2082 }
2083
2084 void PrintWelcomeMessage(entity this)
2085 {
2086         if(CS(this).motd_actived_time == 0)
2087         {
2088                 if (autocvar_g_campaign) {
2089                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2090                                 CS(this).motd_actived_time = time;
2091                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2092                         }
2093                 } else {
2094                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2095                                 CS(this).motd_actived_time = time;
2096                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2097                         }
2098                 }
2099         }
2100         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2101         {
2102                 if (autocvar_g_campaign) {
2103                         if (PHYS_INPUT_BUTTON_INFO(this))
2104                                 CS(this).motd_actived_time = time;
2105                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2106                                 CS(this).motd_actived_time = 0;
2107                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2108                         }
2109                 } else {
2110                         if (PHYS_INPUT_BUTTON_INFO(this))
2111                                 CS(this).motd_actived_time = time;
2112                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2113                                 CS(this).motd_actived_time = 0;
2114                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2115                         }
2116                 }
2117         }
2118         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2119         {
2120                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2121                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2122                 else if (CS(this).motd_actived_time == -2)
2123                 {
2124                         // instantly hide MOTD
2125                         CS(this).motd_actived_time = 0;
2126                         if (autocvar_g_campaign)
2127                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2128                         else
2129                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2130                 }
2131                 else if (IS_PLAYER(this) || IS_SPEC(this))
2132                 {
2133                         // FIXME occasionally for some reason MOTD never goes away
2134                         // delay MOTD removal a little bit in the hope it fixes this bug
2135                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2136                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2137                         else //if (CS(this).motd_actived_time < -2)
2138                                 CS(this).motd_actived_time++;
2139                 }
2140         }
2141 }
2142
2143 bool joinAllowed(entity this)
2144 {
2145         if (CS(this).version_mismatch) return false;
2146         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2147         if (!nJoinAllowed(this, this)) return false;
2148         if (teamplay && lockteams) return false;
2149         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2150         if (ShowTeamSelection(this)) return false;
2151         return true;
2152 }
2153
2154 .string shootfromfixedorigin;
2155 .bool dualwielding_prev;
2156 bool PlayerThink(entity this)
2157 {
2158         if (game_stopped || intermission_running) {
2159                 this.modelflags &= ~MF_ROCKET;
2160                 if(intermission_running)
2161                         IntermissionThink(this);
2162                 return false;
2163         }
2164
2165         if (timeout_status == TIMEOUT_ACTIVE) {
2166                 // don't allow the player to turn around while game is paused
2167                 // FIXME turn this into CSQC stuff
2168                 this.v_angle = this.lastV_angle;
2169                 this.angles = this.lastV_angle;
2170                 this.fixangle = true;
2171         }
2172
2173         if (frametime) player_powerups(this);
2174
2175         if (IS_DEAD(this)) {
2176                 if (this.personal && g_race_qualifying) {
2177                         if (time > this.respawn_time) {
2178                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2179                                 respawn(this);
2180                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2181                         }
2182                 } else {
2183                         if (frametime) player_anim(this);
2184
2185                         if (this.respawn_flags & RESPAWN_DENY)
2186                         {
2187                                 STAT(RESPAWN_TIME, this) = 0;
2188                                 return false;
2189                         }
2190
2191                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2192
2193                         switch(this.deadflag)
2194                         {
2195                                 case DEAD_DYING:
2196                                 {
2197                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2198                                                 this.deadflag = DEAD_RESPAWNING;
2199                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2200                                                 this.deadflag = DEAD_DEAD;
2201                                         break;
2202                                 }
2203                                 case DEAD_DEAD:
2204                                 {
2205                                         if (button_pressed)
2206                                                 this.deadflag = DEAD_RESPAWNABLE;
2207                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2208                                                 this.deadflag = DEAD_RESPAWNING;
2209                                         break;
2210                                 }
2211                                 case DEAD_RESPAWNABLE:
2212                                 {
2213                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2214                                                 this.deadflag = DEAD_RESPAWNING;
2215                                         break;
2216                                 }
2217                                 case DEAD_RESPAWNING:
2218                                 {
2219                                         if (time > this.respawn_time)
2220                                         {
2221                                                 this.respawn_time = time + 1; // only retry once a second
2222                                                 this.respawn_time_max = this.respawn_time;
2223                                                 respawn(this);
2224                                         }
2225                                         break;
2226                                 }
2227                         }
2228
2229                         ShowRespawnCountdown(this);
2230
2231                         if (this.respawn_flags & RESPAWN_SILENT)
2232                                 STAT(RESPAWN_TIME, this) = 0;
2233                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2234                         {
2235                                 if (time < this.respawn_time)
2236                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2237                                 else if (this.deadflag != DEAD_RESPAWNING)
2238                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2239                         }
2240                         else
2241                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2242                 }
2243
2244                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2245                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2246                         STAT(RESPAWN_TIME, this) *= -1;
2247
2248                 return false;
2249         }
2250
2251         FixPlayermodel(this);
2252
2253         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2254                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2255                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2256         }
2257
2258         // reset gun alignment when dual wielding status changes
2259         // to ensure guns are always aligned right and left
2260         bool dualwielding = W_DualWielding(this);
2261         if(this.dualwielding_prev != dualwielding)
2262         {
2263                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2264                 this.dualwielding_prev = dualwielding;
2265         }
2266
2267         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2268         //if(frametime)
2269         {
2270                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2271                 {
2272                         .entity weaponentity = weaponentities[slot];
2273                         if(WEP_CVAR(vortex, charge_always))
2274                                 W_Vortex_Charge(this, weaponentity, frametime);
2275                         W_WeaponFrame(this, weaponentity);
2276                 }
2277         }
2278
2279         if (frametime)
2280         {
2281                 // WEAPONTODO: Add a weapon request for this
2282                 // rot vortex charge to the charge limit
2283                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2284                 {
2285                         .entity weaponentity = weaponentities[slot];
2286                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2287                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2288                 }
2289
2290                 player_regen(this);
2291                 player_anim(this);
2292                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2293         }
2294
2295         monsters_setstatus(this);
2296
2297         return true;
2298 }
2299
2300 .bool would_spectate;
2301 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2302 void ObserverOrSpectatorThink(entity this)
2303 {
2304         bool is_spec = IS_SPEC(this);
2305         if ( CS(this).impulse )
2306         {
2307                 int r = MinigameImpulse(this, CS(this).impulse);
2308                 if (!is_spec || r)
2309                         CS(this).impulse = 0;
2310
2311                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2312                 {
2313                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2314                         CS(this).impulse = 0;
2315                         return;
2316                 }
2317         }
2318
2319         if (this.flags & FL_JUMPRELEASED) {
2320                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2321                         this.flags &= ~FL_JUMPRELEASED;
2322                         this.flags |= FL_SPAWNING;
2323                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2324                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2325                         this.flags &= ~FL_JUMPRELEASED;
2326                         if(SpectateNext(this)) {
2327                                 TRANSMUTE(Spectator, this);
2328                         } else if (is_spec) {
2329                                 TRANSMUTE(Observer, this);
2330                                 PutClientInServer(this);
2331                         }
2332                         if (is_spec)
2333                                 CS(this).impulse = 0;
2334                 } else if (is_spec) {
2335                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2336                                 this.flags &= ~FL_JUMPRELEASED;
2337                                 if(SpectatePrev(this)) {
2338                                         TRANSMUTE(Spectator, this);
2339                                 } else {
2340                                         TRANSMUTE(Observer, this);
2341                                         PutClientInServer(this);
2342                                 }
2343                                 CS(this).impulse = 0;
2344                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2345                                 this.would_spectate = false;
2346                                 this.flags &= ~FL_JUMPRELEASED;
2347                                 TRANSMUTE(Observer, this);
2348                                 PutClientInServer(this);
2349                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2350                                 PutObserverInServer(this);
2351                                 this.would_spectate = true;
2352                         }
2353                 }
2354                 else {
2355                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS_CVAR(this).cvar_cl_clippedspectating : !CS_CVAR(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2356                         set_movetype(this, preferred_movetype);
2357                 }
2358         } else { // jump pressed
2359                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2360                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2361                         this.flags |= FL_JUMPRELEASED;
2362                         if(this.flags & FL_SPAWNING)
2363                         {
2364                                 this.flags &= ~FL_SPAWNING;
2365                                 if(joinAllowed(this))
2366                                         Join(this);
2367                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2368                                         CS(this).autojoin_checked = -1;
2369                                 return;
2370                         }
2371                 }
2372                 if(is_spec && !SpectateUpdate(this))
2373                         PutObserverInServer(this);
2374         }
2375         if (is_spec)
2376                 this.flags |= FL_CLIENT | FL_NOTARGET;
2377 }
2378
2379 void PlayerUseKey(entity this)
2380 {
2381         if (!IS_PLAYER(this))
2382                 return;
2383
2384         if(this.vehicle)
2385         {
2386                 if(!game_stopped)
2387                 {
2388                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2389                         return;
2390                 }
2391         }
2392         else if(autocvar_g_vehicles_enter)
2393         {
2394                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2395                 {
2396                         entity head, closest_target = NULL;
2397                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2398
2399                         while(head) // find the closest acceptable target to enter
2400                         {
2401                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2402                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2403                                 {
2404                                         if(closest_target)
2405                                         {
2406                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2407                                                 { closest_target = head; }
2408                                         }
2409                                         else { closest_target = head; }
2410                                 }
2411
2412                                 head = head.chain;
2413                         }
2414
2415                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2416                 }
2417         }
2418
2419         // a use key was pressed; call handlers
2420         MUTATOR_CALLHOOK(PlayerUseKey, this);
2421 }
2422
2423
2424 /*
2425 =============
2426 PlayerPreThink
2427
2428 Called every frame for each client before the physics are run
2429 =============
2430 */
2431 .float last_vehiclecheck;
2432 void PlayerPreThink (entity this)
2433 {
2434         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2435         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2436
2437         WarpZone_PlayerPhysics_FixVAngle(this);
2438
2439         if (frametime) {
2440                 // physics frames: update anticheat stuff
2441                 anticheat_prethink(this);
2442         }
2443
2444         if (blockSpectators && frametime) {
2445                 // WORKAROUND: only use dropclient in server frames (frametime set).
2446                 // Never use it in cl_movement frames (frametime zero).
2447                 checkSpectatorBlock(this);
2448         }
2449
2450         zoomstate_set = false;
2451
2452         // Check for nameless players
2453         if (this.netname == "" || this.netname != CS(this).netname_previous)
2454         {
2455                 bool assume_unchanged = (CS(this).netname_previous == "");
2456                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2457                 {
2458                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2459                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2460                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2461                         assume_unchanged = false;
2462                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2463                 }
2464                 if (isInvisibleString(this.netname))
2465                 {
2466                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2467                         sprint(this, "Warning: invisible names are not allowed.\n");
2468                         assume_unchanged = false;
2469                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2470                 }
2471                 if (!assume_unchanged && autocvar_sv_eventlog)
2472                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2473                 strcpy(CS(this).netname_previous, this.netname);
2474         }
2475
2476         // version nagging
2477         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2478         CS(this).version_nagtime = 0;
2479         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2480             // git client
2481         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2482             // git server
2483             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2484         } else {
2485             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2486             if (r < 0) { // old client
2487                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2488             } else if (r > 0) { // old server
2489                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2490             }
2491         }
2492     }
2493
2494         // GOD MODE info
2495         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2496         {
2497                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2498                 this.max_armorvalue = 0;
2499         }
2500
2501         if (frametime && IS_PLAYER(this))
2502         {
2503                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2504                 {
2505                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2506                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2507                         if (this.iceblock)
2508                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2509
2510                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2511                                 Unfreeze(this, false);
2512                 }
2513                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2514                 {
2515                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2516                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2517
2518                         if (GetResource(this, RES_HEALTH) < 1)
2519                         {
2520                                 if (this.vehicle)
2521                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2522                                 if(this.event_damage)
2523                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2524                         }
2525                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2526                                 Unfreeze(this, false);
2527                 }
2528         }
2529
2530         MUTATOR_CALLHOOK(PlayerPreThink, this);
2531
2532         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2533         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2534         {
2535                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2536                 {
2537                         if(!it.owner)
2538                         {
2539                                 if(!it.team || SAME_TEAM(this, it))
2540                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2541                                 else if(autocvar_g_vehicles_steal)
2542                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2543                         }
2544                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2545                         {
2546                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2547                         }
2548                 });
2549
2550                 this.last_vehiclecheck = time + 1;
2551         }
2552
2553         if(!CS_CVAR(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2554         {
2555                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2556                         PlayerUseKey(this);
2557                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2558         }
2559
2560         if (IS_REAL_CLIENT(this))
2561                 PrintWelcomeMessage(this);
2562
2563         if (IS_PLAYER(this)) {
2564                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2565                         error("Client can't be spawned as player on connection!");
2566                 if(!PlayerThink(this))
2567                         return;
2568         }
2569         else if (game_stopped || intermission_running) {
2570                 if(intermission_running)
2571                         IntermissionThink(this);
2572                 return;
2573         }
2574         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2575         {
2576                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2577                 CS(this).autojoin_checked = 1;
2578                 // don't do this in ClientConnect
2579                 // many things can go wrong if a client is spawned as player on connection
2580                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2581                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2582                                 && (!teamplay || autocvar_g_balance_teams)))
2583                 {
2584                         campaign_bots_may_start = true;
2585                         if(joinAllowed(this))
2586                                 Join(this);
2587                         return;
2588                 }
2589         }
2590         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2591                 ObserverOrSpectatorThink(this);
2592         }
2593
2594         // WEAPONTODO: Add weapon request for this
2595         if (!zoomstate_set) {
2596                 bool wep_zoomed = false;
2597                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2598                 {
2599                         .entity weaponentity = weaponentities[slot];
2600                         Weapon thiswep = this.(weaponentity).m_weapon;
2601                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2602                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2603                 }
2604                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2605         }
2606
2607         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2608         {
2609                 CS(this).teamkill_soundtime = 0;
2610
2611                 entity e = CS(this).teamkill_soundsource;
2612                 entity oldpusher = e.pusher;
2613                 e.pusher = this;
2614                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2615                 e.pusher = oldpusher;
2616         }
2617
2618         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2619                 CS(this).taunt_soundtime = 0;
2620                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2621         }
2622
2623         target_voicescript_next(this);
2624
2625         // WEAPONTODO: Move into weaponsystem somehow
2626         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2627         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2628         {
2629                 .entity weaponentity = weaponentities[slot];
2630                 if(this.(weaponentity).m_weapon == WEP_Null)
2631                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2632         }
2633 }
2634
2635 void DrownPlayer(entity this)
2636 {
2637         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2638                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2639         {
2640                 STAT(AIR_FINISHED, this) = 0;
2641                 return;
2642         }
2643
2644         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2645         {
2646                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2647                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2648                 STAT(AIR_FINISHED, this) = 0;
2649         }
2650         else
2651         {
2652                 if (!STAT(AIR_FINISHED, this))
2653                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2654                 if (STAT(AIR_FINISHED, this) < time)
2655                 {       // drown!
2656                         if (this.pain_finished < time)
2657                         {
2658                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2659                                 this.pain_finished = time + 0.5;
2660                         }
2661                 }
2662         }
2663 }
2664
2665 .bool move_qcphysics;
2666
2667 void Player_Physics(entity this)
2668 {
2669         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2670
2671         if(!this.move_qcphysics)
2672                 return;
2673
2674         if(!frametime && !CS(this).pm_frametime)
2675                 return;
2676
2677         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2678
2679         CS(this).pm_frametime = 0;
2680 }
2681
2682 /*
2683 =============
2684 PlayerPostThink
2685
2686 Called every frame for each client after the physics are run
2687 =============
2688 */
2689 void PlayerPostThink (entity this)
2690 {
2691         Player_Physics(this);
2692
2693         if (autocvar_sv_maxidle > 0)
2694         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2695         if (IS_REAL_CLIENT(this))
2696         if (IS_PLAYER(this) || autocvar_sv_maxidle_spectatorsareidle)
2697         {
2698                 int totalClients = 0;
2699                 if(autocvar_sv_maxidle_slots > 0)
2700                 {
2701                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2702                         {
2703                                 ++totalClients;
2704                         });
2705                 }
2706
2707                 if (autocvar_sv_maxidle_slots > 0 && (maxclients - totalClients) > autocvar_sv_maxidle_slots)
2708                 { /* do nothing */ }
2709                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2710                 {
2711                         if (CS(this).idlekick_lasttimeleft)
2712                         {
2713                                 CS(this).idlekick_lasttimeleft = 0;
2714                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2715                         }
2716                 }
2717                 else
2718                 {
2719                         float timeleft = ceil(autocvar_sv_maxidle - (time - CS(this).parm_idlesince));
2720                         if (timeleft == min(10, autocvar_sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2721                                 if (!CS(this).idlekick_lasttimeleft)
2722                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2723                         }
2724                         if (timeleft <= 0) {
2725                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2726                                 dropclient(this);
2727                                 return;
2728                         }
2729                         else if (timeleft <= 10) {
2730                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2731                                         Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2732                                 CS(this).idlekick_lasttimeleft = timeleft;
2733                         }
2734                 }
2735         }
2736
2737         CheatFrame(this);
2738
2739         if (game_stopped)
2740         {
2741                 this.solid = SOLID_NOT;
2742                 this.takedamage = DAMAGE_NO;
2743                 set_movetype(this, MOVETYPE_NONE);
2744                 CS(this).teamkill_complain = 0;
2745                 CS(this).teamkill_soundtime = 0;
2746                 CS(this).teamkill_soundsource = NULL;
2747         }
2748
2749         if (IS_PLAYER(this)) {
2750                 if(this.death_time == time && IS_DEAD(this))
2751                 {
2752                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2753                         // once all the damage events of this frame have been processed with normal size
2754                         this.maxs.z = 5;
2755                         setsize(this, this.mins, this.maxs);
2756                 }
2757                 DrownPlayer(this);
2758                 UpdateChatBubble(this);
2759                 if (CS(this).impulse) ImpulseCommands(this);
2760                 if (game_stopped)
2761                 {
2762                         CSQCMODEL_AUTOUPDATE(this);
2763                         return;
2764                 }
2765                 GetPressedKeys(this);
2766         }
2767         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2768         {
2769                 CS(this).pressedkeys = 0;
2770                 STAT(PRESSED_KEYS, this) = 0;
2771         }
2772
2773         if (this.waypointsprite_attachedforcarrier) {
2774                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2775                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2776         }
2777
2778         CSQCMODEL_AUTOUPDATE(this);
2779 }
2780
2781 // hack to copy the button fields from the client entity to the Client State
2782 void PM_UpdateButtons(entity this, entity store)
2783 {
2784         if(this.impulse)
2785                 store.impulse = this.impulse;
2786         this.impulse = 0;
2787
2788         bool typing = this.buttonchat || this.button12;
2789
2790         store.button0 = (typing) ? 0 : this.button0;
2791         //button1?!
2792         store.button2 = (typing) ? 0 : this.button2;
2793         store.button3 = (typing) ? 0 : this.button3;
2794         store.button4 = this.button4;
2795         store.button5 = (typing) ? 0 : this.button5;
2796         store.button6 = this.button6;
2797         store.button7 = this.button7;
2798         store.button8 = this.button8;
2799         store.button9 = this.button9;
2800         store.button10 = this.button10;
2801         store.button11 = this.button11;
2802         store.button12 = this.button12;
2803         store.button13 = this.button13;
2804         store.button14 = this.button14;
2805         store.button15 = this.button15;
2806         store.button16 = this.button16;
2807         store.buttonuse = this.buttonuse;
2808         store.buttonchat = this.buttonchat;
2809
2810         store.cursor_active = this.cursor_active;
2811         store.cursor_screen = this.cursor_screen;
2812         store.cursor_trace_start = this.cursor_trace_start;
2813         store.cursor_trace_endpos = this.cursor_trace_endpos;
2814         store.cursor_trace_ent = this.cursor_trace_ent;
2815
2816         store.ping = this.ping;
2817         store.ping_packetloss = this.ping_packetloss;
2818         store.ping_movementloss = this.ping_movementloss;
2819
2820         store.v_angle = this.v_angle;
2821         store.movement = this.movement;
2822 }
2823
2824 NET_HANDLE(fpsreport, bool)
2825 {
2826         int fps = ReadShort();
2827         PlayerScore_Set(sender, SP_FPS, fps);
2828         return true;
2829 }