qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "spawnpoints.qh"
  14 #include "resources.qh"
  15 #include "g_damage.qh"
  16 #include "handicap.qh"
  17 #include "g_hook.qh"
  18 #include "command/common.qh"
  19 #include "command/vote.qh"
  20 #include "clientkill.qh"
  21 #include "cheats.qh"
  22 #include "g_world.qh"
  23 #include "race.qh"
  24 #include "antilag.qh"
  25 #include "campaign.qh"
  26 #include "command/common.qh"
  27 #include "scores_rules.qh"
  28 #include "weapons/common.qh"
  29
  30 #include "bot/api.qh"
  31
  32 #include "../common/ent_cs.qh"
  33 #include "../common/wepent.qh"
  34 #include <common/state.qh>
  35
  36 #include "compat/quake3.qh"
  37
  38 #include <common/effects/qc/globalsound.qh>
  39
  40 #include "../common/mapobjects/func/conveyor.qh"
  41 #include "../common/mapobjects/teleporters.qh"
  42 #include "../common/mapobjects/target/spawnpoint.qh"
  43 #include <common/mapobjects/trigger/counter.qh>
  44 #include <common/mapobjects/trigger/swamp.qh>
  45
  46 #include "../common/vehicles/all.qh"
  47
  48 #include "weapons/hitplot.qh"
  49 #include "weapons/weaponsystem.qh"
  50
  51 #include "../common/net_notice.qh"
  52 #include "../common/net_linked.qh"
  53 #include "../common/physics/player.qh"
  54
  55 #include <common/vehicles/sv_vehicles.qh>
  56
  57 #include "../common/items/_mod.qh"
  58
  59 #include "../common/mutators/mutator/waypoints/all.qh"
  60 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  61 #include <common/gamemodes/_mod.qh>
  62
  63 #include "../common/mapobjects/subs.qh"
  64 #include "../common/mapobjects/triggers.qh"
  65 #include "../common/mapobjects/trigger/secret.qh"
  66
  67 #include "../common/minigames/sv_minigames.qh"
  68
  69 #include "../common/items/inventory.qh"
  70
  71 #include "../common/monsters/sv_monsters.qh"
  72
  73 #include "../lib/warpzone/server.qh"
  74
  75 #include <common/mutators/mutator/overkill/oknex.qh>
  76
  77 STATIC_METHOD(Client, Add, void(Client this, int _team))
  78 {
  79     ClientConnect(this);
  80     TRANSMUTE(Player, this);
  81     this.frame = 12; // 7
  82     this.team = _team;
  83     PutClientInServer(this);
  84 }
  85
  86 STATIC_METHOD(Client, Remove, void(Client this))
  87 {
  88     TRANSMUTE(Observer, this);
  89     PutClientInServer(this);
  90     ClientDisconnect(this);
  91 }
  92
  93 void send_CSQC_teamnagger() {
  94         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  95 }
  96
  97 int CountSpectators(entity player, entity to)
  98 {
  99         if(!player) { return 0; } // not sure how, but best to be safe
 100
 101         int spec_count = 0;
 102
 103         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 104         {
 105                 spec_count++;
 106         });
 107
 108         return spec_count;
 109 }
 110
 111 void WriteSpectators(entity player, entity to)
 112 {
 113         if(!player) { return; } // not sure how, but best to be safe
 114
 115         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 116         {
 117                 WriteByte(MSG_ENTITY, num_for_edict(it));
 118         });
 119 }
 120
 121 bool ClientData_Send(entity this, entity to, int sf)
 122 {
 123         assert(to == this.owner, return false);
 124
 125         entity e = to;
 126         if (IS_SPEC(e)) e = e.enemy;
 127
 128         sf = 0;
 129         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 130         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 131         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 132         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 133
 134         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 135         WriteByte(MSG_ENTITY, sf);
 136
 137         if (sf & BIT(1))
 138                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 139
 140         if(sf & BIT(4))
 141         {
 142                 float specs = CountSpectators(e, to);
 143                 WriteByte(MSG_ENTITY, specs);
 144                 WriteSpectators(e, to);
 145         }
 146
 147         return true;
 148 }
 149
 150 void ClientData_Attach(entity this)
 151 {
 152         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 153         CS(this).clientdata.drawonlytoclient = this;
 154         CS(this).clientdata.owner = this;
 155 }
 156
 157 void ClientData_Detach(entity this)
 158 {
 159         delete(CS(this).clientdata);
 160         CS(this).clientdata = NULL;
 161 }
 162
 163 void ClientData_Touch(entity e)
 164 {
 165         entity cd = CS(e).clientdata;
 166         if (cd) { cd.SendFlags = 1; }
 167
 168         // make it spectatable
 169         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 170         {
 171                 entity cd = CS(it).clientdata;
 172                 if (cd) { cd.SendFlags = 1; }
 173         });
 174 }
 175
 176
 177 /*
 178 =============
 179 CheckPlayerModel
 180
 181 Checks if the argument string can be a valid playermodel.
 182 Returns a valid one in doubt.
 183 =============
 184 */
 185 string FallbackPlayerModel;
 186 string CheckPlayerModel(string plyermodel) {
 187         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 188         {
 189                 // note: we cannot summon Don Strunzone here, some player may
 190                 // still have the model string set. In case anyone manages how
 191                 // to change a cvar default, we'll have a small leak here.
 192                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 193         }
 194         // only in right path
 195         if( substring(plyermodel,0,14) != "models/player/")
 196                 return FallbackPlayerModel;
 197         // only good file extensions
 198         if(substring(plyermodel,-4,4) != ".zym")
 199         if(substring(plyermodel,-4,4) != ".dpm")
 200         if(substring(plyermodel,-4,4) != ".iqm")
 201         if(substring(plyermodel,-4,4) != ".md3")
 202         if(substring(plyermodel,-4,4) != ".psk")
 203                 return FallbackPlayerModel;
 204         // forbid the LOD models
 205         if(substring(plyermodel, -9,5) == "_lod1")
 206                 return FallbackPlayerModel;
 207         if(substring(plyermodel, -9,5) == "_lod2")
 208                 return FallbackPlayerModel;
 209         if(plyermodel != strtolower(plyermodel))
 210                 return FallbackPlayerModel;
 211         // also, restrict to server models
 212         if(autocvar_sv_servermodelsonly)
 213         {
 214                 if(!fexists(plyermodel))
 215                         return FallbackPlayerModel;
 216         }
 217         return plyermodel;
 218 }
 219
 220 void setplayermodel(entity e, string modelname)
 221 {
 222         precache_model(modelname);
 223         _setmodel(e, modelname);
 224         player_setupanimsformodel(e);
 225         if(!autocvar_g_debug_globalsounds)
 226                 UpdatePlayerSounds(e);
 227 }
 228
 229 /** putting a client as observer in the server */
 230 void PutObserverInServer(entity this)
 231 {
 232     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 233         PlayerState_detach(this);
 234
 235         if (IS_PLAYER(this))
 236         {
 237                 if(GetResource(this, RES_HEALTH) >= 1)
 238                 {
 239                         // despawn effect
 240                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 241                 }
 242
 243                 // was a player, recount votes and ready status
 244                 if(IS_REAL_CLIENT(this))
 245                 {
 246                         if (vote_called) { VoteCount(false); }
 247                         ReadyCount();
 248                 }
 249     }
 250
 251     {
 252         entity spot = SelectSpawnPoint(this, true);
 253         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 254         this.angles = vec2(spot.angles);
 255         this.fixangle = true;
 256         // offset it so that the spectator spawns higher off the ground, looks better this way
 257         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 258         if (IS_REAL_CLIENT(this))
 259         {
 260             msg_entity = this;
 261             WriteByte(MSG_ONE, SVC_SETVIEW);
 262             WriteEntity(MSG_ONE, this);
 263         }
 264         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 265         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 266         if(!autocvar_g_debug_globalsounds)
 267         {
 268                 // needed for player sounds
 269                 this.model = "";
 270                 FixPlayermodel(this);
 271         }
 272         setmodel(this, MDL_Null);
 273         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 274         this.view_ofs = '0 0 0';
 275     }
 276
 277     RemoveGrapplingHooks(this);
 278         Portal_ClearAll(this);
 279         Unfreeze(this, false);
 280         SetSpectatee(this, NULL);
 281
 282         if (this.alivetime)
 283         {
 284                 if (!warmup_stage)
 285                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 286                 this.alivetime = 0;
 287         }
 288
 289         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 290
 291         WaypointSprite_PlayerDead(this);
 292
 293         if (CS(this).killcount != FRAGS_SPECTATOR)
 294         {
 295                 if(!game_stopped)
 296                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 297                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 298         }
 299
 300         accuracy_resend(this);
 301
 302         CS(this).spectatortime = time;
 303         if(this.bot_attack)
 304                 IL_REMOVE(g_bot_targets, this);
 305         this.bot_attack = false;
 306         if(this.monster_attack)
 307                 IL_REMOVE(g_monster_targets, this);
 308         this.monster_attack = false;
 309     STAT(HUD, this) = HUD_NORMAL;
 310         TRANSMUTE(Observer, this);
 311         this.iscreature = false;
 312         this.teleportable = TELEPORT_SIMPLE;
 313         if(this.damagedbycontents)
 314                 IL_REMOVE(g_damagedbycontents, this);
 315         this.damagedbycontents = false;
 316         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 317         SetSpectatee_status(this, etof(this));
 318         this.takedamage = DAMAGE_NO;
 319         this.solid = SOLID_NOT;
 320         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 321         this.flags = FL_CLIENT | FL_NOTARGET;
 322         this.effects = 0;
 323         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 324         this.pauserotarmor_finished = 0;
 325         this.pauserothealth_finished = 0;
 326         this.pauseregen_finished = 0;
 327         this.damageforcescale = 0;
 328         this.death_time = 0;
 329         this.respawn_flags = 0;
 330         this.respawn_time = 0;
 331         STAT(RESPAWN_TIME, this) = 0;
 332         this.alpha = 0;
 333         this.scale = 0;
 334         this.fade_time = 0;
 335         this.pain_frame = 0;
 336         this.pain_finished = 0;
 337         STAT(STRENGTH_FINISHED, this) = 0;
 338         STAT(INVINCIBLE_FINISHED, this) = 0;
 339         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 340         this.air_finished = 0;
 341         //this.dphitcontentsmask = 0;
 342         this.dphitcontentsmask = DPCONTENTS_SOLID;
 343         if (autocvar_g_playerclip_collisions)
 344                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 345         this.pushltime = 0;
 346         this.istypefrag = 0;
 347         setthink(this, func_null);
 348         this.nextthink = 0;
 349         this.deadflag = DEAD_NO;
 350         this.crouch = false;
 351         STAT(REVIVE_PROGRESS, this) = 0;
 352         this.revival_time = 0;
 353         this.draggable = drag_undraggable;
 354
 355         this.items = 0;
 356         STAT(WEAPONS, this) = '0 0 0';
 357         this.drawonlytoclient = this;
 358
 359         this.viewloc = NULL;
 360
 361         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 362
 363         this.weaponmodel = "";
 364         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 365         {
 366                 this.weaponentities[slot] = NULL;
 367         }
 368         this.exteriorweaponentity = NULL;
 369         CS(this).killcount = FRAGS_SPECTATOR;
 370         this.velocity = '0 0 0';
 371         this.avelocity = '0 0 0';
 372         this.punchangle = '0 0 0';
 373         this.punchvector = '0 0 0';
 374         this.oldvelocity = this.velocity;
 375         this.fire_endtime = -1;
 376         this.event_damage = func_null;
 377         this.event_heal = func_null;
 378
 379         for(int slot = 0; slot < MAX_AXH; ++slot)
 380         {
 381                 entity axh = this.(AuxiliaryXhair[slot]);
 382                 this.(AuxiliaryXhair[slot]) = NULL;
 383
 384                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 385                         delete(axh);
 386         }
 387
 388         if (mutator_returnvalue)
 389         {
 390                 // mutator prevents resetting teams+score
 391         }
 392         else
 393         {
 394                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 395                 this.frags = FRAGS_SPECTATOR;
 396         }
 397         if (CS(this).just_joined)
 398                 CS(this).just_joined = false;
 399 }
 400
 401 int player_getspecies(entity this)
 402 {
 403         get_model_parameters(this.model, this.skin);
 404         int s = get_model_parameters_species;
 405         get_model_parameters(string_null, 0);
 406         if (s < 0) return SPECIES_HUMAN;
 407         return s;
 408 }
 409
 410 .float model_randomizer;
 411 void FixPlayermodel(entity player)
 412 {
 413         string defaultmodel = "";
 414         int defaultskin = 0;
 415         if(autocvar_sv_defaultcharacter)
 416         {
 417                 if(teamplay)
 418                 {
 419                         switch(player.team)
 420                         {
 421                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 422                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 423                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 424                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 425                         }
 426                 }
 427
 428                 if(defaultmodel == "")
 429                 {
 430                         defaultmodel = autocvar_sv_defaultplayermodel;
 431                         defaultskin = autocvar_sv_defaultplayerskin;
 432                 }
 433
 434                 int n = tokenize_console(defaultmodel);
 435                 if(n > 0)
 436                 {
 437                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 438                         // However, do NOT randomize if the player-selected model is in the list.
 439                         for (int i = 0; i < n; ++i)
 440                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 441                                         defaultmodel = argv(i);
 442                 }
 443
 444                 int i = strstrofs(defaultmodel, ":", 0);
 445                 if(i >= 0)
 446                 {
 447                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 448                         defaultmodel = substring(defaultmodel, 0, i);
 449                 }
 450         }
 451         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 452         {
 453                 if(teamplay)
 454                 {
 455                         switch(player.team)
 456                         {
 457                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 458                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 459                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 460                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 461                         }
 462                 }
 463
 464                 if(!defaultskin)
 465                         defaultskin = autocvar_sv_defaultplayerskin;
 466         }
 467
 468         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 469         defaultmodel = M_ARGV(0, string);
 470         defaultskin = M_ARGV(1, int);
 471
 472         bool chmdl = false;
 473         int oldskin;
 474         if(defaultmodel != "")
 475         {
 476                 if (defaultmodel != player.model)
 477                 {
 478                         vector m1 = player.mins;
 479                         vector m2 = player.maxs;
 480                         setplayermodel (player, defaultmodel);
 481                         setsize (player, m1, m2);
 482                         chmdl = true;
 483                 }
 484
 485                 oldskin = player.skin;
 486                 player.skin = defaultskin;
 487         } else {
 488                 if (player.playermodel != player.model || player.playermodel == "")
 489                 {
 490                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 491                         vector m1 = player.mins;
 492                         vector m2 = player.maxs;
 493                         setplayermodel (player, player.playermodel);
 494                         setsize (player, m1, m2);
 495                         chmdl = true;
 496                 }
 497
 498                 if(!autocvar_sv_defaultcharacterskin)
 499                 {
 500                         oldskin = player.skin;
 501                         player.skin = stof(player.playerskin);
 502                 }
 503                 else
 504                 {
 505                         oldskin = player.skin;
 506                         player.skin = defaultskin;
 507                 }
 508         }
 509
 510         if(chmdl || oldskin != player.skin) // model or skin has changed
 511         {
 512                 player.species = player_getspecies(player); // update species
 513                 if(!autocvar_g_debug_globalsounds)
 514                         UpdatePlayerSounds(player); // update skin sounds
 515         }
 516
 517         if(!teamplay)
 518                 if(strlen(autocvar_sv_defaultplayercolors))
 519                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 520                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 521 }
 522
 523 void PutPlayerInServer(entity this)
 524 {
 525         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 526
 527         PlayerState_attach(this);
 528         accuracy_resend(this);
 529
 530         if (this.team < 0)
 531                 TeamBalance_JoinBestTeam(this);
 532
 533         entity spot = SelectSpawnPoint(this, false);
 534         if (!spot) {
 535                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 536                 return; // spawn failed
 537         }
 538
 539         TRANSMUTE(Player, this);
 540
 541         CS(this).wasplayer = true;
 542         this.iscreature = true;
 543         this.teleportable = TELEPORT_NORMAL;
 544         if(!this.damagedbycontents)
 545                 IL_PUSH(g_damagedbycontents, this);
 546         this.damagedbycontents = true;
 547         set_movetype(this, MOVETYPE_WALK);
 548         this.solid = SOLID_SLIDEBOX;
 549         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 550         if (autocvar_g_playerclip_collisions)
 551                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 552         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 553                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 554         this.frags = FRAGS_PLAYER;
 555         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 556         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 557         if (autocvar__notarget)
 558                 this.flags |= FL_NOTARGET;
 559         this.takedamage = DAMAGE_AIM;
 560         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 561
 562         if (warmup_stage) {
 563                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 564                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 565                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 566                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 567                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 568                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 569                 SetResource(this, RES_HEALTH, warmup_start_health);
 570                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 571                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 572         } else {
 573                 SetResource(this, RES_SHELLS, start_ammo_shells);
 574                 SetResource(this, RES_BULLETS, start_ammo_nails);
 575                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 576                 SetResource(this, RES_CELLS, start_ammo_cells);
 577                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 578                 SetResource(this, RES_FUEL, start_ammo_fuel);
 579                 SetResource(this, RES_HEALTH, start_health);
 580                 SetResource(this, RES_ARMOR, start_armorvalue);
 581                 STAT(WEAPONS, this) = start_weapons;
 582                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 583                 {
 584                         GiveRandomWeapons(this, random_start_weapons_count,
 585                                 autocvar_g_random_start_weapons, random_start_ammo);
 586                 }
 587         }
 588         SetSpectatee_status(this, 0);
 589
 590         PS(this).dual_weapons = '0 0 0';
 591
 592         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 593
 594         this.items = start_items;
 595
 596         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 597         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 598         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 599         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 600         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 601         if (!sv_ready_restart_after_countdown && time < game_starttime)
 602         {
 603                 float f = game_starttime - time;
 604                 this.spawnshieldtime += f;
 605                 this.pauserotarmor_finished += f;
 606                 this.pauserothealth_finished += f;
 607                 this.pauseregen_finished += f;
 608         }
 609
 610         this.damageforcescale = autocvar_g_player_damageforcescale;
 611         this.death_time = 0;
 612         this.respawn_flags = 0;
 613         this.respawn_time = 0;
 614         STAT(RESPAWN_TIME, this) = 0;
 615         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 616         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 617         this.fade_time = 0;
 618         this.pain_frame = 0;
 619         this.pain_finished = 0;
 620         this.pushltime = 0;
 621         setthink(this, func_null); // players have no think function
 622         this.nextthink = 0;
 623         this.dmg_team = 0;
 624         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 625
 626         this.deadflag = DEAD_NO;
 627
 628         this.angles = spot.angles;
 629         this.angles_z = 0; // never spawn tilted even if the spot says to
 630         if (IS_BOT_CLIENT(this))
 631         {
 632                 this.v_angle = this.angles;
 633                 bot_aim_reset(this);
 634         }
 635         this.fixangle = true; // turn this way immediately
 636         this.oldvelocity = this.velocity = '0 0 0';
 637         this.avelocity = '0 0 0';
 638         this.punchangle = '0 0 0';
 639         this.punchvector = '0 0 0';
 640
 641         STAT(STRENGTH_FINISHED, this) = 0;
 642         STAT(INVINCIBLE_FINISHED, this) = 0;
 643         this.fire_endtime = -1;
 644         STAT(REVIVE_PROGRESS, this) = 0;
 645         this.revival_time = 0;
 646
 647         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 648         STAT(BUFFS, this) = 0;
 649         STAT(BUFF_TIME, this) = 0;
 650
 651         this.air_finished = 0;
 652         this.waterlevel = WATERLEVEL_NONE;
 653         this.watertype = CONTENT_EMPTY;
 654
 655         entity spawnevent = new_pure(spawnevent);
 656         spawnevent.owner = this;
 657         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 658
 659         // Cut off any still running player sounds.
 660         stopsound(this, CH_PLAYER_SINGLE);
 661
 662         this.model = "";
 663         FixPlayermodel(this);
 664         this.drawonlytoclient = NULL;
 665
 666         this.viewloc = NULL;
 667
 668         for(int slot = 0; slot < MAX_AXH; ++slot)
 669         {
 670                 entity axh = this.(AuxiliaryXhair[slot]);
 671                 this.(AuxiliaryXhair[slot]) = NULL;
 672
 673                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 674                         delete(axh);
 675         }
 676
 677         this.spawnpoint_targ = NULL;
 678
 679         this.crouch = false;
 680         this.view_ofs = STAT(PL_VIEW_OFS, this);
 681         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 682         this.spawnorigin = spot.origin;
 683         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 684         // don't reset back to last position, even if new position is stuck in solid
 685         this.oldorigin = this.origin;
 686         if(this.conveyor)
 687                 IL_REMOVE(g_conveyed, this);
 688         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 689         if(this.swampslug)
 690                 IL_REMOVE(g_swamped, this);
 691         this.swampslug = NULL;
 692         this.swamp_interval = 0;
 693         IL_EACH(g_counters, it.realowner == this,
 694         {
 695                 delete(it);
 696         });
 697         STAT(HUD, this) = HUD_NORMAL;
 698
 699         this.event_damage = PlayerDamage;
 700         this.event_heal = PlayerHeal;
 701
 702         this.draggable = func_null;
 703
 704         if(!this.bot_attack)
 705                 IL_PUSH(g_bot_targets, this);
 706         this.bot_attack = true;
 707         if(!this.monster_attack)
 708                 IL_PUSH(g_monster_targets, this);
 709         this.monster_attack = true;
 710         navigation_dynamicgoal_init(this, false);
 711
 712         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 713
 714         // player was spectator
 715         if (CS(this).killcount == FRAGS_SPECTATOR) {
 716                 PlayerScore_Clear(this);
 717                 CS(this).killcount = 0;
 718                 CS(this).startplaytime = time;
 719         }
 720
 721         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 722         {
 723                 .entity weaponentity = weaponentities[slot];
 724                 CL_SpawnWeaponentity(this, weaponentity);
 725         }
 726         this.alpha = default_player_alpha;
 727         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 728         this.exteriorweaponentity.alpha = default_weapon_alpha;
 729
 730         this.speedrunning = false;
 731
 732         this.counter_cnt = 0;
 733         this.fragsfilter_cnt = 0;
 734
 735         target_voicescript_clear(this);
 736
 737         // reset fields the weapons may use
 738         FOREACH(Weapons, true, {
 739                 it.wr_resetplayer(it, this);
 740                         // reload all reloadable weapons
 741                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 742                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 743                         {
 744                                 .entity weaponentity = weaponentities[slot];
 745                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 746                         }
 747                 }
 748         });
 749
 750         {
 751                 string s = spot.target;
 752                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 753                         spot.target = string_null;
 754                 SUB_UseTargets(spot, this, NULL);
 755                 if(g_assault || g_race)
 756                         spot.target = s;
 757         }
 758
 759         Unfreeze(this, false);
 760
 761         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 762
 763         if (autocvar_spawn_debug)
 764         {
 765                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 766                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 767         }
 768
 769         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 770         {
 771                 .entity weaponentity = weaponentities[slot];
 772                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 773                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 774                 else
 775                         this.(weaponentity).m_switchweapon = WEP_Null;
 776                 this.(weaponentity).m_weapon = WEP_Null;
 777                 this.(weaponentity).weaponname = "";
 778                 this.(weaponentity).m_switchingweapon = WEP_Null;
 779                 this.(weaponentity).cnt = -1;
 780         }
 781
 782         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 783
 784         if (CS(this).impulse) ImpulseCommands(this);
 785
 786         W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
 787         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 788         {
 789                 .entity weaponentity = weaponentities[slot];
 790                 W_WeaponFrame(this, weaponentity);
 791         }
 792
 793         if (!warmup_stage && !this.alivetime)
 794                 this.alivetime = time;
 795
 796         antilag_clear(this, CS(this));
 797 }
 798
 799 /** Called when a client spawns in the server */
 800 void PutClientInServer(entity this)
 801 {
 802         if (IS_BOT_CLIENT(this)) {
 803                 TRANSMUTE(Player, this);
 804         } else if (IS_REAL_CLIENT(this)) {
 805                 msg_entity = this;
 806                 WriteByte(MSG_ONE, SVC_SETVIEW);
 807                 WriteEntity(MSG_ONE, this);
 808         }
 809         if (game_stopped)
 810                 TRANSMUTE(Observer, this);
 811
 812         SetSpectatee(this, NULL);
 813
 814         // reset player keys
 815         if(PS(this))
 816                 PS(this).itemkeys = 0;
 817
 818         MUTATOR_CALLHOOK(PutClientInServer, this);
 819
 820         if (IS_OBSERVER(this)) {
 821                 PutObserverInServer(this);
 822         } else if (IS_PLAYER(this)) {
 823                 PutPlayerInServer(this);
 824         }
 825 }
 826
 827 // TODO do we need all these fields, or should we stop autodetecting runtime
 828 // changes and just have a console command to update this?
 829 bool ClientInit_SendEntity(entity this, entity to, int sf)
 830 {
 831         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 832         return = true;
 833         msg_entity = to;
 834         // MSG_INIT replacement
 835         // TODO: make easier to use
 836         Registry_send_all();
 837         W_PROP_reload(MSG_ONE, to);
 838         ClientInit_misc(this);
 839         MUTATOR_CALLHOOK(Ent_Init);
 840 }
 841 void ClientInit_misc(entity this)
 842 {
 843         int channel = MSG_ONE;
 844         WriteHeader(channel, ENT_CLIENT_INIT);
 845         WriteByte(channel, g_nexball_meter_period * 32);
 846         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 847         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 848         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 849         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 850         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 851         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 852         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 853         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 854
 855         if(sv_foginterval && world.fog != "")
 856                 WriteString(channel, world.fog);
 857         else
 858                 WriteString(channel, "");
 859         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 860         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 861         WriteByte(channel, serverflags);
 862         WriteCoord(channel, autocvar_g_trueaim_minrange);
 863 }
 864
 865 void ClientInit_CheckUpdate(entity this)
 866 {
 867         this.nextthink = time;
 868         if(this.count != autocvar_g_balance_armor_blockpercent)
 869         {
 870                 this.count = autocvar_g_balance_armor_blockpercent;
 871                 this.SendFlags |= 1;
 872         }
 873         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 874         {
 875                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 876                 this.SendFlags |= 1;
 877         }
 878 }
 879
 880 void ClientInit_Spawn()
 881 {
 882         entity e = new_pure(clientinit);
 883         setthink(e, ClientInit_CheckUpdate);
 884         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 885
 886         ClientInit_CheckUpdate(e);
 887 }
 888
 889 /*
 890 =============
 891 SetNewParms
 892 =============
 893 */
 894 void SetNewParms ()
 895 {
 896         // initialize parms for a new player
 897         parm1 = -(86400 * 366);
 898
 899         MUTATOR_CALLHOOK(SetNewParms);
 900 }
 901
 902 /*
 903 =============
 904 SetChangeParms
 905 =============
 906 */
 907 void SetChangeParms (entity this)
 908 {
 909         // save parms for level change
 910         parm1 = CS(this).parm_idlesince - time;
 911
 912         MUTATOR_CALLHOOK(SetChangeParms);
 913 }
 914
 915 /*
 916 =============
 917 DecodeLevelParms
 918 =============
 919 */
 920 void DecodeLevelParms(entity this)
 921 {
 922         // load parms
 923         CS(this).parm_idlesince = parm1;
 924         if (CS(this).parm_idlesince == -(86400 * 366))
 925                 CS(this).parm_idlesince = time;
 926
 927         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 928         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 929
 930         MUTATOR_CALLHOOK(DecodeLevelParms);
 931 }
 932
 933 void FixClientCvars(entity e)
 934 {
 935         // send prediction settings to the client
 936         stuffcmd(e, "\nin_bindmap 0 0\n");
 937         if(autocvar_g_antilag == 3) // client side hitscan
 938                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 939         if(autocvar_sv_gentle)
 940                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 941
 942         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 943         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 944
 945         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 946
 947         MUTATOR_CALLHOOK(FixClientCvars, e);
 948 }
 949
 950 bool findinlist_abbrev(string tofind, string list)
 951 {
 952         if(list == "" || tofind == "")
 953                 return false; // empty list or search, just return
 954
 955         // this function allows abbreviated strings!
 956         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 957         {
 958                 return true;
 959         });
 960
 961         return false;
 962 }
 963
 964 bool PlayerInIPList(entity p, string iplist)
 965 {
 966         // some safety checks (never allow local?)
 967         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 968                 return false;
 969
 970         return findinlist_abbrev(p.netaddress, iplist);
 971 }
 972
 973 bool PlayerInIDList(entity p, string idlist)
 974 {
 975         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 976         if(!p.crypto_idfp)
 977                 return false;
 978
 979         return findinlist_abbrev(p.crypto_idfp, idlist);
 980 }
 981
 982 bool PlayerInList(entity player, string list)
 983 {
 984         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 985 }
 986
 987 #ifdef DP_EXT_PRECONNECT
 988 /*
 989 =============
 990 ClientPreConnect
 991
 992 Called once (not at each match start) when a client begins a connection to the server
 993 =============
 994 */
 995 void ClientPreConnect(entity this)
 996 {
 997         if(autocvar_sv_eventlog)
 998         {
 999                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1000                         this.playerid,
1001                         etof(this),
1002                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1003                 ));
1004         }
1005 }
1006 #endif
1007
1008 string GetClientVersionMessage(entity this)
1009 {
1010         if (CS(this).version_mismatch) {
1011                 if(CS(this).version < autocvar_gameversion) {
1012                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1013                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1014                 } else {
1015                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1016                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1017                 }
1018         } else {
1019                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1020         }
1021 }
1022
1023 string getwelcomemessage(entity this)
1024 {
1025         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1026         string modifications = M_ARGV(0, string);
1027
1028         if(g_weaponarena)
1029         {
1030                 if(g_weaponarena_random)
1031                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1032                 else
1033                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1034         }
1035         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1036                 modifications = strcat(modifications, ", No start weapons");
1037         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1038                 modifications = strcat(modifications, ", Low gravity");
1039         if(g_weapon_stay && !g_cts)
1040                 modifications = strcat(modifications, ", Weapons stay");
1041         if(g_jetpack)
1042                 modifications = strcat(modifications, ", Jet pack");
1043         if(autocvar_g_powerups == 0)
1044                 modifications = strcat(modifications, ", No powerups");
1045         if(autocvar_g_powerups > 0)
1046                 modifications = strcat(modifications, ", Powerups");
1047         modifications = substring(modifications, 2, strlen(modifications) - 2);
1048
1049         string versionmessage = GetClientVersionMessage(this);
1050         string s = strcat(versionmessage, "^8\n^8\nhost is ^9", autocvar_hostname, "^8\n");
1051
1052         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1053
1054         if(modifications != "")
1055                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1056
1057         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1058         {
1059                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1060                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1061         }
1062
1063         if (cache_mutatormsg != "") {
1064                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1065         }
1066
1067         string mutator_msg = "";
1068         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1069         mutator_msg = M_ARGV(0, string);
1070
1071         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1072
1073         string motd = autocvar_sv_motd;
1074         if (motd != "") {
1075                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1076         }
1077         return s;
1078 }
1079
1080 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1081
1082 /**
1083 =============
1084 ClientConnect
1085
1086 Called when a client connects to the server
1087 =============
1088 */
1089 void ClientConnect(entity this)
1090 {
1091         if (Ban_MaybeEnforceBanOnce(this)) return;
1092         assert(!IS_CLIENT(this), return);
1093         this.flags |= FL_CLIENT;
1094         assert(player_count >= 0, player_count = 0);
1095
1096 #ifdef WATERMARK
1097         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1098 #endif
1099         TRANSMUTE(Client, this);
1100         CS(this).version_nagtime = time + 10 + random() * 10;
1101
1102         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1103
1104         bot_clientconnect(this);
1105
1106         Player_DetermineForcedTeam(this);
1107
1108         TRANSMUTE(Observer, this);
1109
1110         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1111
1112         // always track bots, don't ask for cl_allow_uidtracking
1113         if (IS_BOT_CLIENT(this))
1114                 PlayerStats_GameReport_AddPlayer(this);
1115         else
1116                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1117
1118         if (autocvar_sv_eventlog)
1119                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this, false)));
1120
1121         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1122
1123         stuffcmd(this, clientstuff, "\n");
1124         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1125
1126         FixClientCvars(this);
1127
1128         // get version info from player
1129         stuffcmd(this, "cmd clientversion $gameversion\n");
1130
1131         // notify about available teams
1132         if (teamplay)
1133         {
1134                 entity balance = TeamBalance_CheckAllowedTeams(this);
1135                 int t = TeamBalance_GetAllowedTeams(balance);
1136                 TeamBalance_Destroy(balance);
1137                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1138         }
1139         else
1140         {
1141                 stuffcmd(this, "set _teams_available 0\n");
1142         }
1143
1144         bot_relinkplayerlist();
1145
1146         CS(this).spectatortime = time;
1147         if (blockSpectators)
1148         {
1149                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1150         }
1151
1152         CS(this).jointime = time;
1153
1154         if (IS_REAL_CLIENT(this))
1155         {
1156                 if (g_weaponarena_weapons == WEPSET(TUBA))
1157                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1158         }
1159
1160         if (!sv_foginterval && world.fog != "")
1161                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1162
1163         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1164                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1165                         send_CSQC_teamnagger();
1166
1167         CSQCMODEL_AUTOINIT(this);
1168
1169         CS(this).model_randomizer = random();
1170
1171         if (IS_REAL_CLIENT(this))
1172                 sv_notice_join(this);
1173
1174         this.move_qcphysics = autocvar_sv_qcphysics;
1175
1176         // update physics stats (players can spawn before physics runs)
1177         Physics_UpdateStats(this);
1178
1179         IL_EACH(g_initforplayer, it.init_for_player, {
1180                 it.init_for_player(it, this);
1181         });
1182
1183         Handicap_Initialize(this);
1184
1185         MUTATOR_CALLHOOK(ClientConnect, this);
1186
1187         if (IS_REAL_CLIENT(this))
1188         {
1189                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1190                 {
1191                         CS(this).motd_actived_time = -1;
1192                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1193                 }
1194         }
1195 }
1196 /*
1197 =============
1198 ClientDisconnect
1199
1200 Called when a client disconnects from the server
1201 =============
1202 */
1203 .entity chatbubbleentity;
1204 void ClientDisconnect(entity this)
1205 {
1206         assert(IS_CLIENT(this), return);
1207
1208         PlayerStats_GameReport_FinalizePlayer(this);
1209         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1210         if (CS(this).active_minigame) part_minigame(this);
1211         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1212
1213         if (autocvar_sv_eventlog)
1214                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1215
1216         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1217
1218         if(IS_SPEC(this))
1219                 SetSpectatee(this, NULL);
1220
1221     MUTATOR_CALLHOOK(ClientDisconnect, this);
1222
1223         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1224         strfree(CS(this).weaponorder_byimpulse);
1225         ClientState_detach(this);
1226
1227         Portal_ClearAll(this);
1228
1229         Unfreeze(this, false);
1230
1231         RemoveGrapplingHooks(this);
1232
1233         // Here, everything has been done that requires this player to be a client.
1234
1235         this.flags &= ~FL_CLIENT;
1236
1237         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1238         if (this.killindicator) delete(this.killindicator);
1239
1240         IL_EACH(g_counters, it.realowner == this,
1241         {
1242                 delete(it);
1243         });
1244
1245         WaypointSprite_PlayerGone(this);
1246
1247         bot_relinkplayerlist();
1248
1249         strfree(this.clientstatus);
1250         if (this.personal) delete(this.personal);
1251
1252         this.playerid = 0;
1253         ReadyCount();
1254         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1255
1256         ONREMOVE(this);
1257 }
1258
1259 void ChatBubbleThink(entity this)
1260 {
1261         this.nextthink = time;
1262         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1263         {
1264                 if(this.owner) // but why can that ever be NULL?
1265                         this.owner.chatbubbleentity = NULL;
1266                 delete(this);
1267                 return;
1268         }
1269
1270         this.mdl = "";
1271
1272         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1273         {
1274                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1275                         this.mdl = "models/sprites/minigame_busy.iqm";
1276                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1277                         this.mdl = "models/misc/chatbubble.spr";
1278         }
1279
1280         if ( this.model != this.mdl )
1281                 _setmodel(this, this.mdl);
1282
1283 }
1284
1285 void UpdateChatBubble(entity this)
1286 {
1287         if (this.alpha < 0)
1288                 return;
1289         // spawn a chatbubble entity if needed
1290         if (!this.chatbubbleentity)
1291         {
1292                 this.chatbubbleentity = new(chatbubbleentity);
1293                 this.chatbubbleentity.owner = this;
1294                 this.chatbubbleentity.exteriormodeltoclient = this;
1295                 setthink(this.chatbubbleentity, ChatBubbleThink);
1296                 this.chatbubbleentity.nextthink = time;
1297                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1298                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1299                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1300                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1301                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1302                 //this.chatbubbleentity.model = "";
1303                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1304         }
1305 }
1306
1307
1308 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1309 // added to the model skins
1310 /*void UpdateColorModHack()
1311 {
1312         float c;
1313         c = this.clientcolors & 15;
1314         // LordHavoc: only bothering to support white, green, red, yellow, blue
1315              if (!teamplay) this.colormod = '0 0 0';
1316         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1317         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1318         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1319         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1320         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1321         else this.colormod = '1 1 1';
1322 }*/
1323
1324 void respawn(entity this)
1325 {
1326         if(this.alpha >= 0)
1327         {
1328                 if(autocvar_g_respawn_ghosts)
1329                 {
1330                         this.solid = SOLID_NOT;
1331                         this.takedamage = DAMAGE_NO;
1332                         set_movetype(this, MOVETYPE_FLY);
1333                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1334                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1335                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1336                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1337                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1338                         if(autocvar_g_respawn_ghosts_time > 0)
1339                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1340                 }
1341                 else
1342                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1343         }
1344
1345         CopyBody(this, 1);
1346
1347         this.effects |= EF_NODRAW; // prevent another CopyBody
1348         PutClientInServer(this);
1349 }
1350
1351 ERASEABLE
1352 void PrintToChat(entity client, string text)
1353 {
1354         text = strcat("\{1}^7", text, "\n");
1355         sprint(client, text);
1356 }
1357
1358 ERASEABLE
1359 void DebugPrintToChat(entity client, string text)
1360 {
1361         if (autocvar_developer > 0)
1362         {
1363                 PrintToChat(client, text);
1364         }
1365 }
1366
1367 ERASEABLE
1368 void PrintToChatAll(string text)
1369 {
1370         text = strcat("\{1}^7", text, "\n");
1371         bprint(text);
1372 }
1373
1374 ERASEABLE
1375 void DebugPrintToChatAll(string text)
1376 {
1377         if (autocvar_developer > 0)
1378         {
1379                 PrintToChatAll(text);
1380         }
1381 }
1382
1383 ERASEABLE
1384 void PrintToChatTeam(int team_num, string text)
1385 {
1386         text = strcat("\{1}^7", text, "\n");
1387         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1388         {
1389                 if (it.team == team_num)
1390                 {
1391                         sprint(it, text);
1392                 }
1393         });
1394 }
1395
1396 ERASEABLE
1397 void DebugPrintToChatTeam(int team_num, string text)
1398 {
1399         if (autocvar_developer > 0)
1400         {
1401                 PrintToChatTeam(team_num, text);
1402         }
1403 }
1404
1405 void play_countdown(entity this, float finished, Sound samp)
1406 {
1407         TC(Sound, samp);
1408         if(IS_REAL_CLIENT(this))
1409                 if(floor(finished - time - frametime) != floor(finished - time))
1410                         if(finished - time < 6)
1411                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1412 }
1413
1414 void player_powerups(entity this)
1415 {
1416         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1417                 this.modelflags |= MF_ROCKET;
1418         else
1419                 this.modelflags &= ~MF_ROCKET;
1420
1421         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1422
1423         if (IS_DEAD(this))
1424         {
1425                 if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1426                 {
1427                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1428                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1429                         this.items &= ~ITEM_Strength.m_itemid;
1430                         this.items &= ~ITEM_Shield.m_itemid;
1431                         this.items -= (this.items & IT_SUPERWEAPON);
1432                 }
1433         }
1434
1435         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1436                 return;
1437
1438         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1439         int items_prev = this.items;
1440
1441         Fire_ApplyDamage(this);
1442         Fire_ApplyEffect(this);
1443
1444         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1445         {
1446                 if (this.items & ITEM_Strength.m_itemid)
1447                 {
1448                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1449                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1450                         if (time > STAT(STRENGTH_FINISHED, this))
1451                         {
1452                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1453                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1454                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1455                         }
1456                 }
1457                 else
1458                 {
1459                         if (time < STAT(STRENGTH_FINISHED, this))
1460                         {
1461                                 this.items = this.items | ITEM_Strength.m_itemid;
1462                                 if(!g_cts)
1463                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1464                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1465                         }
1466                 }
1467                 if (this.items & ITEM_Shield.m_itemid)
1468                 {
1469                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1470                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1471                         if (time > STAT(INVINCIBLE_FINISHED, this))
1472                         {
1473                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1474                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1475                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1476                         }
1477                 }
1478                 else
1479                 {
1480                         if (time < STAT(INVINCIBLE_FINISHED, this))
1481                         {
1482                                 this.items = this.items | ITEM_Shield.m_itemid;
1483                                 if(!g_cts)
1484                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1485                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1486                         }
1487                 }
1488                 if (this.items & IT_SUPERWEAPON)
1489                 {
1490                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1491                         {
1492                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1493                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1494                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1495                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1496                         }
1497                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1498                         {
1499                                 // don't let them run out
1500                         }
1501                         else
1502                         {
1503                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1504                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1505                                 {
1506                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1507                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1508                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1509                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1510                                 }
1511                         }
1512                 }
1513                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1514                 {
1515                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1516                         {
1517                                 this.items = this.items | IT_SUPERWEAPON;
1518                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1519                                 {
1520                                         if(!g_cts)
1521                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1522                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1523                                 }
1524                         }
1525                         else
1526                         {
1527                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1528                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1529                         }
1530                 }
1531                 else
1532                 {
1533                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1534                 }
1535         }
1536
1537         if(autocvar_g_nodepthtestplayers)
1538                 this.effects = this.effects | EF_NODEPTHTEST;
1539
1540         if(autocvar_g_fullbrightplayers)
1541                 this.effects = this.effects | EF_FULLBRIGHT;
1542
1543         if (time >= game_starttime)
1544         if (time < this.spawnshieldtime)
1545                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1546
1547         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1548 }
1549
1550 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1551 {
1552         if(current > stable)
1553                 return current;
1554         else if(current > stable - 0.25) // when close enough, "snap"
1555                 return stable;
1556         else
1557                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1558 }
1559
1560 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1561 {
1562         if(current < stable)
1563                 return current;
1564         else if(current < stable + 0.25) // when close enough, "snap"
1565                 return stable;
1566         else
1567                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1568 }
1569
1570 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1571 {
1572         float old = GetResource(this, res);
1573         float current = old;
1574         if(current > rotstable)
1575         {
1576                 if(rotframetime > 0)
1577                 {
1578                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1579                         current = max(rotstable, current - rotlinear * rotframetime);
1580                 }
1581         }
1582         else if(current < regenstable)
1583         {
1584                 if(regenframetime > 0)
1585                 {
1586                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1587                         current = min(regenstable, current + regenlinear * regenframetime);
1588                 }
1589         }
1590
1591         float limit = GetResourceLimit(this, res) * limit_mod;
1592         if(current > limit)
1593                 current = limit;
1594
1595         if (current != old)
1596                 SetResource(this, res, current);
1597 }
1598
1599 void player_regen(entity this)
1600 {
1601         float max_mod, regen_mod, rot_mod, limit_mod;
1602         max_mod = regen_mod = rot_mod = limit_mod = 1;
1603
1604         float regen_health = autocvar_g_balance_health_regen;
1605         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1606         float regen_health_rot = autocvar_g_balance_health_rot;
1607         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1608         float regen_health_stable = autocvar_g_balance_health_regenstable;
1609         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1610         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1611                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1612         max_mod = M_ARGV(1, float);
1613         regen_mod = M_ARGV(2, float);
1614         rot_mod = M_ARGV(3, float);
1615         limit_mod = M_ARGV(4, float);
1616         regen_health = M_ARGV(5, float);
1617         regen_health_linear = M_ARGV(6, float);
1618         regen_health_rot = M_ARGV(7, float);
1619         regen_health_rotlinear = M_ARGV(8, float);
1620         regen_health_stable = M_ARGV(9, float);
1621         regen_health_rotstable = M_ARGV(10, float);
1622
1623         if(!mutator_returnvalue)
1624         if(!STAT(FROZEN, this))
1625         {
1626                 float maxa = autocvar_g_balance_armor_rotstable;
1627                 float mina = autocvar_g_balance_armor_regenstable;
1628
1629                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1630                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1631                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1632
1633                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1634                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1635                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1636         }
1637
1638         // if player rotted to death...  die!
1639         // check this outside above checks, as player may still be able to rot to death
1640         if(GetResource(this, RES_HEALTH) < 1)
1641         {
1642                 if(this.vehicle)
1643                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1644                 if(this.event_damage)
1645                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1646         }
1647
1648         if (!(this.items & IT_UNLIMITED_AMMO))
1649         {
1650                 float maxf = autocvar_g_balance_fuel_rotstable;
1651                 float minf = autocvar_g_balance_fuel_regenstable;
1652
1653                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1654                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1655                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1656         }
1657 }
1658
1659 bool zoomstate_set;
1660 void SetZoomState(entity this, float newzoom)
1661 {
1662         if(newzoom != CS(this).zoomstate)
1663         {
1664                 CS(this).zoomstate = newzoom;
1665                 ClientData_Touch(this);
1666         }
1667         zoomstate_set = true;
1668 }
1669
1670 void GetPressedKeys(entity this)
1671 {
1672         MUTATOR_CALLHOOK(GetPressedKeys, this);
1673         int keys = STAT(PRESSED_KEYS, this);
1674         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1675         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1676         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1677         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1678
1679         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1680         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1681         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1682         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1683         CS(this).pressedkeys = keys; // store for other users
1684
1685         STAT(PRESSED_KEYS, this) = keys;
1686 }
1687
1688 /*
1689 ======================
1690 spectate mode routines
1691 ======================
1692 */
1693
1694 void SpectateCopy(entity this, entity spectatee)
1695 {
1696         TC(Client, this); TC(Client, spectatee);
1697
1698         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1699         PS(this) = PS(spectatee);
1700         this.armortype = spectatee.armortype;
1701         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1702         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1703         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1704         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1705         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1706         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1707         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1708         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1709         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1710         CS(this).impulse = 0;
1711         this.disableclientprediction = 1; // no need to run prediction on a spectator
1712         this.items = spectatee.items;
1713         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1714         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1715         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1716         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1717         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1718         this.air_finished = spectatee.air_finished;
1719         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1720         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1721         this.punchangle = spectatee.punchangle;
1722         this.view_ofs = spectatee.view_ofs;
1723         this.velocity = spectatee.velocity;
1724         this.dmg_take = spectatee.dmg_take;
1725         this.dmg_save = spectatee.dmg_save;
1726         this.dmg_inflictor = spectatee.dmg_inflictor;
1727         this.v_angle = spectatee.v_angle;
1728         this.angles = spectatee.v_angle;
1729         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1730         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1731         this.viewloc = spectatee.viewloc;
1732         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1733                 this.fixangle = true;
1734         setorigin(this, spectatee.origin);
1735         setsize(this, spectatee.mins, spectatee.maxs);
1736         SetZoomState(this, CS(spectatee).zoomstate);
1737
1738     anticheat_spectatecopy(this, spectatee);
1739         STAT(HUD, this) = STAT(HUD, spectatee);
1740         if(spectatee.vehicle)
1741     {
1742         this.angles = spectatee.v_angle;
1743
1744         //this.fixangle = false;
1745         //this.velocity = spectatee.vehicle.velocity;
1746         this.vehicle_health = spectatee.vehicle_health;
1747         this.vehicle_shield = spectatee.vehicle_shield;
1748         this.vehicle_energy = spectatee.vehicle_energy;
1749         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1750         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1751         this.vehicle_reload1 = spectatee.vehicle_reload1;
1752         this.vehicle_reload2 = spectatee.vehicle_reload2;
1753
1754         //msg_entity = this;
1755
1756        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1757             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1758            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1759            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1760
1761         //WriteByte (MSG_ONE, SVC_SETVIEW);
1762         //    WriteEntity(MSG_ONE, this);
1763         //makevectors(spectatee.v_angle);
1764         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1765     }
1766 }
1767
1768 bool SpectateUpdate(entity this)
1769 {
1770         if(!this.enemy)
1771                 return false;
1772
1773         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1774         {
1775                 SetSpectatee(this, NULL);
1776                 return false;
1777         }
1778
1779         SpectateCopy(this, this.enemy);
1780
1781         return true;
1782 }
1783
1784 bool SpectateSet(entity this)
1785 {
1786         if(!IS_PLAYER(this.enemy))
1787                 return false;
1788
1789         ClientData_Touch(this.enemy);
1790
1791         msg_entity = this;
1792         WriteByte(MSG_ONE, SVC_SETVIEW);
1793         WriteEntity(MSG_ONE, this.enemy);
1794         set_movetype(this, MOVETYPE_NONE);
1795         accuracy_resend(this);
1796
1797         if(!SpectateUpdate(this))
1798                 PutObserverInServer(this);
1799
1800         return true;
1801 }
1802
1803 void SetSpectatee_status(entity this, int spectatee_num)
1804 {
1805         int oldspectatee_status = CS(this).spectatee_status;
1806         CS(this).spectatee_status = spectatee_num;
1807
1808         if (CS(this).spectatee_status != oldspectatee_status)
1809         {
1810                 if (STAT(PRESSED_KEYS, this))
1811                 {
1812                         CS(this).pressedkeys = 0;
1813                         STAT(PRESSED_KEYS, this) = 0;
1814                 }
1815                 ClientData_Touch(this);
1816                 if (g_race || g_cts) race_InitSpectator();
1817         }
1818 }
1819
1820 void SetSpectatee(entity this, entity spectatee)
1821 {
1822         if(IS_BOT_CLIENT(this))
1823                 return; // bots abuse .enemy, this code is useless to them
1824
1825         entity old_spectatee = this.enemy;
1826
1827         this.enemy = spectatee;
1828
1829         // WEAPONTODO
1830         // these are required to fix the spectator bug with arc
1831         if(old_spectatee)
1832         {
1833                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1834                 {
1835                         .entity weaponentity = weaponentities[slot];
1836                         if(old_spectatee.(weaponentity).arc_beam)
1837                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1838                 }
1839         }
1840         if(this.enemy)
1841         {
1842                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1843                 {
1844                         .entity weaponentity = weaponentities[slot];
1845                         if(this.enemy.(weaponentity).arc_beam)
1846                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1847                 }
1848         }
1849
1850         if (this.enemy)
1851                 SetSpectatee_status(this, etof(this.enemy));
1852
1853         // needed to update spectator list
1854         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1855 }
1856
1857 bool Spectate(entity this, entity pl)
1858 {
1859         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1860                 return false;
1861         pl = M_ARGV(1, entity);
1862
1863         SetSpectatee(this, pl);
1864         return SpectateSet(this);
1865 }
1866
1867 bool SpectateNext(entity this)
1868 {
1869         entity ent = find(this.enemy, classname, STR_PLAYER);
1870
1871         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1872                 ent = M_ARGV(1, entity);
1873         else if (!ent)
1874                 ent = find(ent, classname, STR_PLAYER);
1875
1876         if(ent) { SetSpectatee(this, ent); }
1877
1878         return SpectateSet(this);
1879 }
1880
1881 bool SpectatePrev(entity this)
1882 {
1883         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1884         entity ent = findchain(classname, STR_PLAYER);
1885         if (!ent) // no player
1886                 return false;
1887
1888         entity first = ent;
1889         // skip players until current spectated player
1890         if(this.enemy)
1891         while(ent && ent != this.enemy)
1892                 ent = ent.chain;
1893
1894         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1895         {
1896                 case MUT_SPECPREV_FOUND:
1897                     ent = M_ARGV(1, entity);
1898                     break;
1899                 case MUT_SPECPREV_RETURN:
1900                     return true;
1901                 case MUT_SPECPREV_CONTINUE:
1902                 default:
1903                 {
1904                         if(ent.chain)
1905                                 ent = ent.chain;
1906                         else
1907                                 ent = first;
1908                         break;
1909                 }
1910         }
1911
1912         SetSpectatee(this, ent);
1913         return SpectateSet(this);
1914 }
1915
1916 /*
1917 =============
1918 ShowRespawnCountdown()
1919
1920 Update a respawn countdown display.
1921 =============
1922 */
1923 void ShowRespawnCountdown(entity this)
1924 {
1925         float number;
1926         if(!IS_DEAD(this)) // just respawned?
1927                 return;
1928         else
1929         {
1930                 number = ceil(this.respawn_time - time);
1931                 if(number <= 0)
1932                         return;
1933                 if(number <= this.respawn_countdown)
1934                 {
1935                         this.respawn_countdown = number - 1;
1936                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1937                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1938                 }
1939         }
1940 }
1941
1942 .bool team_selected;
1943 bool ShowTeamSelection(entity this)
1944 {
1945         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1946                 return false;
1947         stuffcmd(this, "menu_showteamselect\n");
1948         return true;
1949 }
1950 void Join(entity this)
1951 {
1952         TRANSMUTE(Player, this);
1953
1954         if(!this.team_selected)
1955         if(autocvar_g_campaign || autocvar_g_balance_teams)
1956                 TeamBalance_JoinBestTeam(this);
1957
1958         if(autocvar_g_campaign)
1959                 campaign_bots_may_start = true;
1960
1961         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1962
1963         PutClientInServer(this);
1964
1965         if(IS_PLAYER(this))
1966         if(teamplay && this.team != -1)
1967         {
1968         }
1969         else
1970                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1971         this.team_selected = false;
1972 }
1973
1974 int GetPlayerLimit()
1975 {
1976         if(g_duel)
1977                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1978         int player_limit = autocvar_g_maxplayers;
1979         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1980         player_limit = M_ARGV(0, int);
1981         return player_limit;
1982 }
1983
1984 /**
1985  * Determines whether the player is allowed to join. This depends on cvar
1986  * g_maxplayers, if it isn't used this function always return true, otherwise
1987  * it checks whether the number of currently playing players exceeds g_maxplayers.
1988  * @return int number of free slots for players, 0 if none
1989  */
1990 int nJoinAllowed(entity this, entity ignore)
1991 {
1992         if(!ignore)
1993         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1994         // so report 0 free slots if restricted
1995         {
1996                 if(autocvar_g_forced_team_otherwise == "spectate")
1997                         return 0;
1998                 if(autocvar_g_forced_team_otherwise == "spectator")
1999                         return 0;
2000         }
2001
2002         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2003                 return 0; // forced spectators can never join
2004
2005         // TODO simplify this
2006         int totalClients = 0;
2007         int currentlyPlaying = 0;
2008         FOREACH_CLIENT(true, {
2009                 if(it != ignore)
2010                         ++totalClients;
2011                 if(IS_REAL_CLIENT(it))
2012                 if(IS_PLAYER(it) || it.caplayer)
2013                         ++currentlyPlaying;
2014         });
2015
2016         int player_limit = GetPlayerLimit();
2017
2018         float free_slots = 0;
2019         if (!player_limit)
2020                 free_slots = maxclients - totalClients;
2021         else if(currentlyPlaying < player_limit)
2022                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2023
2024         static float msg_time = 0;
2025         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2026         {
2027                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2028                 msg_time = time + 0.5;
2029         }
2030
2031         return free_slots;
2032 }
2033
2034 /**
2035  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2036  * g_maxplayers_spectator_blocktime seconds
2037  */
2038 void checkSpectatorBlock(entity this)
2039 {
2040         if(IS_SPEC(this) || IS_OBSERVER(this))
2041         if(!this.caplayer)
2042         if(IS_REAL_CLIENT(this))
2043         {
2044                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2045                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2046                         dropclient(this);
2047                 }
2048         }
2049 }
2050
2051 void PrintWelcomeMessage(entity this)
2052 {
2053         if(CS(this).motd_actived_time == 0)
2054         {
2055                 if (autocvar_g_campaign) {
2056                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2057                                 CS(this).motd_actived_time = time;
2058                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2059                         }
2060                 } else {
2061                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2062                                 CS(this).motd_actived_time = time;
2063                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2064                         }
2065                 }
2066         }
2067         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2068         {
2069                 if (autocvar_g_campaign) {
2070                         if (PHYS_INPUT_BUTTON_INFO(this))
2071                                 CS(this).motd_actived_time = time;
2072                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2073                                 CS(this).motd_actived_time = 0;
2074                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2075                         }
2076                 } else {
2077                         if (PHYS_INPUT_BUTTON_INFO(this))
2078                                 CS(this).motd_actived_time = time;
2079                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2080                                 CS(this).motd_actived_time = 0;
2081                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2082                         }
2083                 }
2084         }
2085         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2086         {
2087                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2088                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2089                 else if (CS(this).motd_actived_time == -2)
2090                 {
2091                         // instantly hide MOTD
2092                         CS(this).motd_actived_time = 0;
2093                         if (autocvar_g_campaign)
2094                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2095                         else
2096                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2097                 }
2098                 else if (IS_PLAYER(this) || IS_SPEC(this))
2099                 {
2100                         // FIXME occasionally for some reason MOTD never goes away
2101                         // delay MOTD removal a little bit in the hope it fixes this bug
2102                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2103                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2104                         else //if (CS(this).motd_actived_time < -2)
2105                                 CS(this).motd_actived_time++;
2106                 }
2107         }
2108 }
2109
2110 const int MIN_SPEC_TIME = 1;
2111 bool joinAllowed(entity this)
2112 {
2113         if (CS(this).version_mismatch) return false;
2114         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2115         if (!nJoinAllowed(this, this)) return false;
2116         if (teamplay && lockteams) return false;
2117         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2118         if (ShowTeamSelection(this)) return false;
2119         return true;
2120 }
2121
2122 .string shootfromfixedorigin;
2123 .bool dualwielding_prev;
2124 bool PlayerThink(entity this)
2125 {
2126         if (game_stopped || intermission_running) {
2127                 this.modelflags &= ~MF_ROCKET;
2128                 if(intermission_running)
2129                         IntermissionThink(this);
2130                 return false;
2131         }
2132
2133         if (timeout_status == TIMEOUT_ACTIVE) {
2134         // don't allow the player to turn around while game is paused
2135                 // FIXME turn this into CSQC stuff
2136                 this.v_angle = this.lastV_angle;
2137                 this.angles = this.lastV_angle;
2138                 this.fixangle = true;
2139         }
2140
2141         if (frametime) player_powerups(this);
2142
2143         if (IS_DEAD(this)) {
2144                 if (this.personal && g_race_qualifying) {
2145                         if (time > this.respawn_time) {
2146                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2147                                 respawn(this);
2148                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2149                         }
2150                 } else {
2151                         if (frametime) player_anim(this);
2152
2153                         if (this.respawn_flags & RESPAWN_DENY)
2154                         {
2155                                 STAT(RESPAWN_TIME, this) = 0;
2156                                 return false;
2157                         }
2158
2159                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2160
2161                         switch(this.deadflag)
2162                         {
2163                                 case DEAD_DYING:
2164                                 {
2165                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2166                                                 this.deadflag = DEAD_RESPAWNING;
2167                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2168                                                 this.deadflag = DEAD_DEAD;
2169                                         break;
2170                                 }
2171                                 case DEAD_DEAD:
2172                                 {
2173                                         if (button_pressed)
2174                                                 this.deadflag = DEAD_RESPAWNABLE;
2175                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2176                                                 this.deadflag = DEAD_RESPAWNING;
2177                                         break;
2178                                 }
2179                                 case DEAD_RESPAWNABLE:
2180                                 {
2181                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2182                                                 this.deadflag = DEAD_RESPAWNING;
2183                                         break;
2184                                 }
2185                                 case DEAD_RESPAWNING:
2186                                 {
2187                                         if (time > this.respawn_time)
2188                                         {
2189                                                 this.respawn_time = time + 1; // only retry once a second
2190                                                 this.respawn_time_max = this.respawn_time;
2191                                                 respawn(this);
2192                                         }
2193                                         break;
2194                                 }
2195                         }
2196
2197                         ShowRespawnCountdown(this);
2198
2199                         if (this.respawn_flags & RESPAWN_SILENT)
2200                                 STAT(RESPAWN_TIME, this) = 0;
2201                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2202                         {
2203                                 if (time < this.respawn_time)
2204                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2205                                 else if (this.deadflag != DEAD_RESPAWNING)
2206                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2207                         }
2208                         else
2209                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2210                 }
2211
2212                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2213                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2214                         STAT(RESPAWN_TIME, this) *= -1;
2215
2216                 return false;
2217         }
2218
2219         FixPlayermodel(this);
2220
2221         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2222                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2223                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2224         }
2225
2226         // reset gun alignment when dual wielding status changes
2227         // to ensure guns are always aligned right and left
2228         bool dualwielding = W_DualWielding(this);
2229         if(this.dualwielding_prev != dualwielding)
2230         {
2231                 W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
2232                 this.dualwielding_prev = dualwielding;
2233         }
2234
2235         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2236         //if(frametime)
2237         {
2238                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2239                 {
2240                         .entity weaponentity = weaponentities[slot];
2241                         if(WEP_CVAR(vortex, charge_always))
2242                                 W_Vortex_Charge(this, weaponentity, frametime);
2243                         W_WeaponFrame(this, weaponentity);
2244                 }
2245         }
2246
2247         if (frametime)
2248         {
2249                 // WEAPONTODO: Add a weapon request for this
2250                 // rot vortex charge to the charge limit
2251                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2252                 {
2253                         .entity weaponentity = weaponentities[slot];
2254                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2255                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2256                 }
2257
2258                 player_regen(this);
2259                 player_anim(this);
2260                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2261         }
2262
2263         secrets_setstatus(this);
2264         monsters_setstatus(this);
2265
2266         return true;
2267 }
2268
2269 .bool would_spectate;
2270 void ObserverThink(entity this)
2271 {
2272         if ( CS(this).impulse )
2273         {
2274                 MinigameImpulse(this, CS(this).impulse);
2275                 CS(this).impulse = 0;
2276         }
2277
2278         if (this.flags & FL_JUMPRELEASED) {
2279                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2280                         this.flags &= ~FL_JUMPRELEASED;
2281                         this.flags |= FL_SPAWNING;
2282                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2283                         this.flags &= ~FL_JUMPRELEASED;
2284                         if(SpectateNext(this)) {
2285                                 TRANSMUTE(Spectator, this);
2286                         }
2287                 } else {
2288                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2289                         set_movetype(this, preferred_movetype);
2290                 }
2291         } else {
2292                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2293                         this.flags |= FL_JUMPRELEASED;
2294                         if(this.flags & FL_SPAWNING)
2295                         {
2296                                 this.flags &= ~FL_SPAWNING;
2297                                 if(joinAllowed(this))
2298                                         Join(this);
2299                                 return;
2300                         }
2301                 }
2302         }
2303 }
2304
2305 void SpectatorThink(entity this)
2306 {
2307         if ( CS(this).impulse )
2308         {
2309                 if(MinigameImpulse(this, CS(this).impulse))
2310                         CS(this).impulse = 0;
2311
2312                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2313                 {
2314                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2315                         CS(this).impulse = 0;
2316                         return;
2317                 }
2318         }
2319
2320         if (this.flags & FL_JUMPRELEASED) {
2321                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2322                         this.flags &= ~FL_JUMPRELEASED;
2323                         this.flags |= FL_SPAWNING;
2324                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2325                         this.flags &= ~FL_JUMPRELEASED;
2326                         if(SpectateNext(this)) {
2327                                 TRANSMUTE(Spectator, this);
2328                         } else {
2329                                 TRANSMUTE(Observer, this);
2330                                 PutClientInServer(this);
2331                         }
2332                         CS(this).impulse = 0;
2333                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2334                         this.flags &= ~FL_JUMPRELEASED;
2335                         if(SpectatePrev(this)) {
2336                                 TRANSMUTE(Spectator, this);
2337                         } else {
2338                                 TRANSMUTE(Observer, this);
2339                                 PutClientInServer(this);
2340                         }
2341                         CS(this).impulse = 0;
2342                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2343                         this.would_spectate = false;
2344                         this.flags &= ~FL_JUMPRELEASED;
2345                         TRANSMUTE(Observer, this);
2346                         PutClientInServer(this);
2347                 } else {
2348                         if(!SpectateUpdate(this))
2349                         {
2350                                 if(!SpectateNext(this))
2351                                 {
2352                                         PutObserverInServer(this);
2353                                         this.would_spectate = true;
2354                                 }
2355                         }
2356                 }
2357         } else {
2358                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2359                         this.flags |= FL_JUMPRELEASED;
2360                         if(this.flags & FL_SPAWNING)
2361                         {
2362                                 this.flags &= ~FL_SPAWNING;
2363                                 Join(this);
2364                                 return;
2365                         }
2366                 }
2367                 if(!SpectateUpdate(this))
2368                         PutObserverInServer(this);
2369         }
2370
2371         this.flags |= FL_CLIENT | FL_NOTARGET;
2372 }
2373
2374 void PlayerUseKey(entity this)
2375 {
2376         if (!IS_PLAYER(this))
2377                 return;
2378
2379         if(this.vehicle)
2380         {
2381                 if(!game_stopped)
2382                 {
2383                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2384                         return;
2385                 }
2386         }
2387         else if(autocvar_g_vehicles_enter)
2388         {
2389                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2390                 {
2391                         entity head, closest_target = NULL;
2392                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2393
2394                         while(head) // find the closest acceptable target to enter
2395                         {
2396                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2397                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2398                                 {
2399                                         if(closest_target)
2400                                         {
2401                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2402                                                 { closest_target = head; }
2403                                         }
2404                                         else { closest_target = head; }
2405                                 }
2406
2407                                 head = head.chain;
2408                         }
2409
2410                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2411                 }
2412         }
2413
2414         // a use key was pressed; call handlers
2415         MUTATOR_CALLHOOK(PlayerUseKey, this);
2416 }
2417
2418
2419 /*
2420 =============
2421 PlayerPreThink
2422
2423 Called every frame for each client before the physics are run
2424 =============
2425 */
2426 .float last_vehiclecheck;
2427 void PlayerPreThink (entity this)
2428 {
2429         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2430         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2431
2432         WarpZone_PlayerPhysics_FixVAngle(this);
2433
2434         if (frametime) {
2435                 // physics frames: update anticheat stuff
2436                 anticheat_prethink(this);
2437         }
2438
2439         if (blockSpectators && frametime) {
2440                 // WORKAROUND: only use dropclient in server frames (frametime set).
2441                 // Never use it in cl_movement frames (frametime zero).
2442                 checkSpectatorBlock(this);
2443         }
2444
2445         zoomstate_set = false;
2446
2447         // Check for nameless players
2448         if (this.netname == "" || this.netname != CS(this).netname_previous)
2449         {
2450                 bool assume_unchanged = (CS(this).netname_previous == "");
2451                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2452                 {
2453                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2454                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2455                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2456                         assume_unchanged = false;
2457                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2458                 }
2459                 if (isInvisibleString(this.netname))
2460                 {
2461                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2462                         sprint(this, "Warning: invisible names are not allowed.\n");
2463                         assume_unchanged = false;
2464                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2465                 }
2466                 if (!assume_unchanged && autocvar_sv_eventlog)
2467                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2468                 strcpy(CS(this).netname_previous, this.netname);
2469         }
2470
2471         // version nagging
2472         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2473         CS(this).version_nagtime = 0;
2474         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2475             // git client
2476         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2477             // git server
2478             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2479         } else {
2480             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2481             if (r < 0) { // old client
2482                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2483             } else if (r > 0) { // old server
2484                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2485             }
2486         }
2487     }
2488
2489         // GOD MODE info
2490         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2491         {
2492                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2493                 this.max_armorvalue = 0;
2494         }
2495
2496         if (frametime && IS_PLAYER(this))
2497         {
2498                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2499                 {
2500                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2501                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2502                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2503
2504                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2505                                 Unfreeze(this, false);
2506                 }
2507                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2508                 {
2509                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2510                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2511
2512                         if (GetResource(this, RES_HEALTH) < 1)
2513                         {
2514                                 if (this.vehicle)
2515                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2516                                 if(this.event_damage)
2517                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2518                         }
2519                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2520                                 Unfreeze(this, false);
2521                 }
2522         }
2523
2524         MUTATOR_CALLHOOK(PlayerPreThink, this);
2525
2526         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2527         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2528         {
2529                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2530                 {
2531                         if(!it.owner)
2532                         {
2533                                 if(!it.team || SAME_TEAM(this, it))
2534                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2535                                 else if(autocvar_g_vehicles_steal)
2536                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2537                         }
2538                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2539                         {
2540                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2541                         }
2542                 });
2543
2544                 this.last_vehiclecheck = time + 1;
2545         }
2546
2547         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2548         {
2549                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2550                         PlayerUseKey(this);
2551                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2552         }
2553
2554         if (IS_REAL_CLIENT(this))
2555                 PrintWelcomeMessage(this);
2556
2557         if (IS_PLAYER(this)) {
2558                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2559                         error("Client can't be spawned as player on connection!");
2560                 if(!PlayerThink(this))
2561                         return;
2562         }
2563         else if (game_stopped || intermission_running) {
2564                 if(intermission_running)
2565                         IntermissionThink(this);
2566                 return;
2567         }
2568         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2569         {
2570                 CS(this).autojoin_checked = true;
2571                 // don't do this in ClientConnect
2572                 // many things can go wrong if a client is spawned as player on connection
2573                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2574                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2575                                 && (!teamplay || autocvar_g_balance_teams)))
2576                 {
2577                         campaign_bots_may_start = true;
2578                         Join(this);
2579                         return;
2580                 }
2581         }
2582         else if (IS_OBSERVER(this)) {
2583                 ObserverThink(this);
2584         }
2585         else if (IS_SPEC(this)) {
2586                 SpectatorThink(this);
2587         }
2588
2589         // WEAPONTODO: Add weapon request for this
2590         if (!zoomstate_set) {
2591                 bool wep_zoomed = false;
2592                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2593                 {
2594                         .entity weaponentity = weaponentities[slot];
2595                         Weapon thiswep = this.(weaponentity).m_weapon;
2596                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2597                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2598                 }
2599                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2600     }
2601
2602         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2603         {
2604                 CS(this).teamkill_soundtime = 0;
2605
2606                 entity e = CS(this).teamkill_soundsource;
2607                 entity oldpusher = e.pusher;
2608                 e.pusher = this;
2609                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2610                 e.pusher = oldpusher;
2611         }
2612
2613         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2614                 CS(this).taunt_soundtime = 0;
2615                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2616         }
2617
2618         target_voicescript_next(this);
2619
2620         // WEAPONTODO: Move into weaponsystem somehow
2621         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2622         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2623         {
2624                 .entity weaponentity = weaponentities[slot];
2625                 if(this.(weaponentity).m_weapon == WEP_Null)
2626                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2627         }
2628 }
2629
2630 void DrownPlayer(entity this)
2631 {
2632         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2633                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2634         {
2635                 this.air_finished = 0;
2636                 return;
2637         }
2638
2639         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2640         {
2641                 if(this.air_finished && this.air_finished < time)
2642                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2643                 this.air_finished = 0;
2644         }
2645         else
2646         {
2647                 if (!this.air_finished)
2648                         this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2649                 if (this.air_finished < time)
2650                 {       // drown!
2651                         if (this.pain_finished < time)
2652                         {
2653                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2654                                 this.pain_finished = time + 0.5;
2655                         }
2656                 }
2657         }
2658 }
2659
2660 .bool move_qcphysics;
2661
2662 void Player_Physics(entity this)
2663 {
2664         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2665
2666         if(!this.move_qcphysics)
2667                 return;
2668
2669         if(!frametime && !CS(this).pm_frametime)
2670                 return;
2671
2672         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2673
2674         CS(this).pm_frametime = 0;
2675 }
2676
2677 /*
2678 =============
2679 PlayerPostThink
2680
2681 Called every frame for each client after the physics are run
2682 =============
2683 */
2684 void PlayerPostThink (entity this)
2685 {
2686         Player_Physics(this);
2687
2688         if (sv_maxidle > 0)
2689         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2690         if (IS_REAL_CLIENT(this))
2691         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2692         {
2693                 int totalClients = 0;
2694                 if(sv_maxidle_slots > 0)
2695                 {
2696                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2697                         {
2698                                 ++totalClients;
2699                         });
2700                 }
2701
2702                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2703                 { /* do nothing */ }
2704                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2705                 {
2706                         if (CS(this).idlekick_lasttimeleft)
2707                         {
2708                                 CS(this).idlekick_lasttimeleft = 0;
2709                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2710                         }
2711                 }
2712                 else
2713                 {
2714                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2715                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2716                                 if (!CS(this).idlekick_lasttimeleft)
2717                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2718                         }
2719                         if (timeleft <= 0) {
2720                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2721                                 dropclient(this);
2722                                 return;
2723                         }
2724                         else if (timeleft <= 10) {
2725                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2726                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2727                 }
2728                                 CS(this).idlekick_lasttimeleft = timeleft;
2729                         }
2730                 }
2731         }
2732
2733         CheatFrame(this);
2734
2735         if (game_stopped)
2736         {
2737                 this.solid = SOLID_NOT;
2738                 this.takedamage = DAMAGE_NO;
2739                 set_movetype(this, MOVETYPE_NONE);
2740         }
2741
2742         if (IS_PLAYER(this)) {
2743                 if(this.death_time == time && IS_DEAD(this))
2744                 {
2745                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2746                         // once all the damage events of this frame have been processed with normal size
2747                         this.maxs.z = 5;
2748                         setsize(this, this.mins, this.maxs);
2749                 }
2750                 DrownPlayer(this);
2751                 UpdateChatBubble(this);
2752                 if (CS(this).impulse) ImpulseCommands(this);
2753                 if (game_stopped)
2754                 {
2755                         CSQCMODEL_AUTOUPDATE(this);
2756                         return;
2757                 }
2758                 GetPressedKeys(this);
2759         }
2760         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2761         {
2762                 CS(this).pressedkeys = 0;
2763                 STAT(PRESSED_KEYS, this) = 0;
2764         }
2765
2766         if (this.waypointsprite_attachedforcarrier) {
2767                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2768                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2769         }
2770
2771         CSQCMODEL_AUTOUPDATE(this);
2772 }
2773
2774 /**
2775  * message "": do not say, just test flood control
2776  * return value:
2777  *   1 = accept
2778  *   0 = reject
2779  *  -1 = fake accept
2780  */
2781 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
2782 {
2783         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
2784                 msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
2785
2786         if (source)
2787                 msgin = formatmessage(source, msgin);
2788
2789         string colorstr;
2790         if (!(IS_PLAYER(source) || source.caplayer))
2791                 colorstr = "^0"; // black for spectators
2792         else if(teamplay)
2793                 colorstr = Team_ColorCode(source.team);
2794         else
2795         {
2796                 colorstr = "";
2797                 teamsay = false;
2798         }
2799
2800         if (!source) {
2801                 colorstr = "";
2802                 teamsay = false;
2803         }
2804
2805         if(msgin != "")
2806                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
2807
2808         /*
2809          * using bprint solves this... me stupid
2810         // how can we prevent the message from appearing in a listen server?
2811         // for now, just give "say" back and only handle say_team
2812         if(!teamsay)
2813         {
2814                 clientcommand(source, strcat("say ", msgin));
2815                 return;
2816         }
2817         */
2818
2819         string namestr = "";
2820         if (source)
2821                 namestr = playername(source, autocvar_g_chat_teamcolors);
2822
2823         string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
2824
2825         string msgstr = "", cmsgstr = "";
2826         string privatemsgprefix = string_null;
2827         int privatemsgprefixlen = 0;
2828         if (msgin != "")
2829         {
2830                 bool found_me = false;
2831                 if(strstrofs(msgin, "/me", 0) >= 0)
2832                 {
2833                         string newmsgin = "";
2834                         string newnamestr = ((teamsay) ? strcat(colorstr, "(", colorprefix, namestr, colorstr, ")", "^7") : strcat(colorprefix, namestr, "^7"));
2835                         FOREACH_WORD(msgin, true,
2836                         {
2837                                 if(strdecolorize(it) == "/me")
2838                                 {
2839                                         found_me = true;
2840                                         newmsgin = cons(newmsgin, newnamestr);
2841                                 }
2842                                 else
2843                                         newmsgin = cons(newmsgin, it);
2844                         });
2845                         msgin = newmsgin;
2846                 }
2847
2848                 if(privatesay)
2849                 {
2850                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
2851                         privatemsgprefixlen = strlen(msgstr);
2852                         msgstr = strcat(msgstr, msgin);
2853                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
2854                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
2855                 }
2856                 else if(teamsay)
2857                 {
2858                         if(found_me)
2859                         {
2860                                 //msgin = strreplace("/me", "", msgin);
2861                                 //msgin = substring(msgin, 3, strlen(msgin));
2862                                 //msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
2863                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
2864                         }
2865                         else
2866                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
2867                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
2868                 }
2869                 else
2870                 {
2871                         if(found_me)
2872                         {
2873                                 //msgin = strreplace("/me", "", msgin);
2874                                 //msgin = substring(msgin, 3, strlen(msgin));
2875                                 //msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
2876                                 msgstr = strcat("\{1}^4* ^7", msgin);
2877                         }
2878                         else {
2879                                 msgstr = "\{1}";
2880                                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
2881                                 msgstr = strcat(msgstr, msgin);
2882                         }
2883                         cmsgstr = "";
2884                 }
2885                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
2886         }
2887
2888         string fullmsgstr = msgstr;
2889         string fullcmsgstr = cmsgstr;
2890
2891         // FLOOD CONTROL
2892         int flood = 0;
2893         var .float flood_field = floodcontrol_chat;
2894         if(floodcontrol && source)
2895         {
2896                 float flood_spl;
2897                 float flood_burst;
2898                 float flood_lmax;
2899                 float lines;
2900                 if(privatesay)
2901                 {
2902                         flood_spl = autocvar_g_chat_flood_spl_tell;
2903                         flood_burst = autocvar_g_chat_flood_burst_tell;
2904                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
2905                         flood_field = floodcontrol_chattell;
2906                 }
2907                 else if(teamsay)
2908                 {
2909                         flood_spl = autocvar_g_chat_flood_spl_team;
2910                         flood_burst = autocvar_g_chat_flood_burst_team;
2911                         flood_lmax = autocvar_g_chat_flood_lmax_team;
2912                         flood_field = floodcontrol_chatteam;
2913                 }
2914                 else
2915                 {
2916                         flood_spl = autocvar_g_chat_flood_spl;
2917                         flood_burst = autocvar_g_chat_flood_burst;
2918                         flood_lmax = autocvar_g_chat_flood_lmax;
2919                         flood_field = floodcontrol_chat;
2920                 }
2921                 flood_burst = max(0, flood_burst - 1);
2922                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
2923
2924                 // do flood control for the default line size
2925                 if(msgstr != "")
2926                 {
2927                         getWrappedLine_remaining = msgstr;
2928                         msgstr = "";
2929                         lines = 0;
2930                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
2931                         {
2932                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
2933                                 ++lines;
2934                         }
2935                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
2936
2937                         if(getWrappedLine_remaining != "")
2938                         {
2939                                 msgstr = strcat(msgstr, "\n");
2940                                 flood = 2;
2941                         }
2942
2943                         if (time >= source.(flood_field))
2944                         {
2945                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
2946                         }
2947                         else
2948                         {
2949                                 flood = 1;
2950                                 msgstr = fullmsgstr;
2951                         }
2952                 }
2953                 else
2954                 {
2955                         if (time >= source.(flood_field))
2956                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
2957                         else
2958                                 flood = 1;
2959                 }
2960
2961                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
2962                         source.(flood_field) = flood = 0;
2963         }
2964
2965         string sourcemsgstr, sourcecmsgstr;
2966         if(flood == 2) // cannot happen for empty msgstr
2967         {
2968                 if(autocvar_g_chat_flood_notify_flooder)
2969                 {
2970                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
2971                         sourcecmsgstr = "";
2972                 }
2973                 else
2974                 {
2975                         sourcemsgstr = fullmsgstr;
2976                         sourcecmsgstr = fullcmsgstr;
2977                 }
2978                 cmsgstr = "";
2979         }
2980         else
2981         {
2982                 sourcemsgstr = msgstr;
2983                 sourcecmsgstr = cmsgstr;
2984         }
2985
2986         if (!privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2987         {
2988                 if (!game_stopped)
2989                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
2990                         teamsay = -1; // spectators
2991         }
2992
2993         if(flood)
2994                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
2995
2996         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
2997         if(privatesay)
2998                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
2999
3000         int ret;
3001         if(source && CS(source).muted)
3002         {
3003                 // always fake the message
3004                 ret = -1;
3005         }
3006         else if(flood == 1)
3007         {
3008                 if (autocvar_g_chat_flood_notify_flooder)
3009                 {
3010                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
3011                         ret = 0;
3012                 }
3013                 else
3014                         ret = -1;
3015         }
3016         else
3017         {
3018                 ret = 1;
3019         }
3020
3021         if (privatesay && source && !(IS_PLAYER(source) || source.caplayer))
3022         {
3023                 if (!game_stopped)
3024                 if ((privatesay && (IS_PLAYER(privatesay) || privatesay.caplayer)) && ((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage)))
3025                         ret = -1; // just hide the message completely
3026         }
3027
3028         MUTATOR_CALLHOOK(ChatMessage, source, ret);
3029         ret = M_ARGV(1, int);
3030
3031         string event_log_msg = "";
3032
3033         if(sourcemsgstr != "" && ret != 0)
3034         {
3035                 if(ret < 0) // faked message, because the player is muted
3036                 {
3037                         sprint(source, sourcemsgstr);
3038                         if(sourcecmsgstr != "" && !privatesay)
3039                                 centerprint(source, sourcecmsgstr);
3040                 }
3041                 else if(privatesay) // private message, between 2 people only
3042                 {
3043                         sprint(source, sourcemsgstr);
3044                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
3045                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
3046                         {
3047                                 sprint(privatesay, msgstr);
3048                                 if(cmsgstr != "")
3049                                         centerprint(privatesay, cmsgstr);
3050                         }
3051                 }
3052                 else if ( teamsay && CS(source).active_minigame )
3053                 {
3054                         sprint(source, sourcemsgstr);
3055                         dedicated_print(msgstr); // send to server console too
3056                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3057                                 sprint(it, msgstr);
3058                         });
3059                         event_log_msg = sprintf(":chat_minigame:%d:%s:%s", source.playerid, CS(source).active_minigame.netname, msgin);
3060
3061                 }
3062                 else if(teamsay > 0) // team message, only sent to team mates
3063                 {
3064                         sprint(source, sourcemsgstr);
3065                         dedicated_print(msgstr); // send to server console too
3066                         if(sourcecmsgstr != "")
3067                                 centerprint(source, sourcecmsgstr);
3068                         FOREACH_CLIENT((IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3069                                 sprint(it, msgstr);
3070                                 if(cmsgstr != "")
3071                                         centerprint(it, cmsgstr);
3072                         });
3073                         event_log_msg = sprintf(":chat_team:%d:%d:%s", source.playerid, source.team, strreplace("\n", " ", msgin));
3074                 }
3075                 else if(teamsay < 0) // spectator message, only sent to spectators
3076                 {
3077                         sprint(source, sourcemsgstr);
3078                         dedicated_print(msgstr); // send to server console too
3079                         FOREACH_CLIENT(!(IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3080                                 sprint(it, msgstr);
3081                         });
3082                         event_log_msg = sprintf(":chat_spec:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3083                 }
3084                 else
3085                 {
3086                         if (source) {
3087                                 sprint(source, sourcemsgstr);
3088                                 dedicated_print(msgstr); // send to server console too
3089                                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
3090                         }
3091                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3092                                 sprint(it, msgstr);
3093                         });
3094                         event_log_msg = sprintf(":chat:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3095                 }
3096         }
3097
3098         if (autocvar_sv_eventlog && (event_log_msg != "")) {
3099                 GameLogEcho(event_log_msg);
3100         }
3101
3102         return ret;
3103 }
3104
3105 // hack to copy the button fields from the client entity to the Client State
3106 void PM_UpdateButtons(entity this, entity store)
3107 {
3108         if(this.impulse)
3109                 store.impulse = this.impulse;
3110         this.impulse = 0;
3111
3112         bool typing = this.buttonchat || this.button12;
3113
3114         store.button0 = (typing) ? 0 : this.button0;
3115         //button1?!
3116         store.button2 = (typing) ? 0 : this.button2;
3117         store.button3 = (typing) ? 0 : this.button3;
3118         store.button4 = this.button4;
3119         store.button5 = (typing) ? 0 : this.button5;
3120         store.button6 = this.button6;
3121         store.button7 = this.button7;
3122         store.button8 = this.button8;
3123         store.button9 = this.button9;
3124         store.button10 = this.button10;
3125         store.button11 = this.button11;
3126         store.button12 = this.button12;
3127         store.button13 = this.button13;
3128         store.button14 = this.button14;
3129         store.button15 = this.button15;
3130         store.button16 = this.button16;
3131         store.buttonuse = this.buttonuse;
3132         store.buttonchat = this.buttonchat;
3133
3134         store.cursor_active = this.cursor_active;
3135         store.cursor_screen = this.cursor_screen;
3136         store.cursor_trace_start = this.cursor_trace_start;
3137         store.cursor_trace_endpos = this.cursor_trace_endpos;
3138         store.cursor_trace_ent = this.cursor_trace_ent;
3139
3140         store.ping = this.ping;
3141         store.ping_packetloss = this.ping_packetloss;
3142         store.ping_movementloss = this.ping_movementloss;
3143
3144         store.v_angle = this.v_angle;
3145         store.movement = (typing) ? '0 0 0' : this.movement;
3146 }
3147
3148 NET_HANDLE(fpsreport, bool)
3149 {
3150         int fps = ReadShort();
3151         PlayerScore_Set(sender, SP_FPS, fps);
3152         return true;
3153 }