qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/weapons/_all.qh>
   4 #include <common/stats.qh>
   5 #include <server/miscfunctions.qh>
   6 #include <common/effects/all.qh>
   7 #include "anticheat.qh"
   8 #include "impulse.qh"
   9 #include "player.qh"
  10 #include "ipban.qh"
  11 #include "miscfunctions.qh"
  12 #include "portals.qh"
  13 #include "teamplay.qh"
  14 #include "spawnpoints.qh"
  15 #include "resources.qh"
  16 #include "damage.qh"
  17 #include "handicap.qh"
  18 #include "hook.qh"
  19 #include "command/common.qh"
  20 #include "command/vote.qh"
  21 #include "clientkill.qh"
  22 #include "cheats.qh"
  23 #include "world.qh"
  24 #include <server/gamelog.qh>
  25 #include "race.qh"
  26 #include <server/main.qh>
  27 #include "antilag.qh"
  28 #include "campaign.qh"
  29 #include "command/common.qh"
  30 #include "scores_rules.qh"
  31 #include "weapons/common.qh"
  32
  33 #include "bot/api.qh"
  34
  35 #include "../common/ent_cs.qh"
  36 #include "../common/wepent.qh"
  37 #include <common/state.qh>
  38
  39 #include "compat/quake3.qh"
  40
  41 #include <common/effects/qc/globalsound.qh>
  42
  43 #include "../common/mapobjects/func/conveyor.qh"
  44 #include <common/mapobjects/func/ladder.qh>
  45 #include "../common/mapobjects/teleporters.qh"
  46 #include "../common/mapobjects/target/spawnpoint.qh"
  47 #include <common/mapobjects/trigger/counter.qh>
  48 #include <common/mapobjects/trigger/swamp.qh>
  49
  50 #include "../common/vehicles/all.qh"
  51
  52 #include "weapons/hitplot.qh"
  53 #include "weapons/selection.qh"
  54 #include "weapons/weaponsystem.qh"
  55
  56 #include "../common/net_notice.qh"
  57 #include "../common/net_linked.qh"
  58 #include "../common/physics/player.qh"
  59
  60 #include <common/vehicles/sv_vehicles.qh>
  61
  62 #include "../common/items/_mod.qh"
  63
  64 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  65
  66 #include "../common/mutators/mutator/waypoints/all.qh"
  67 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  68 #include <common/gamemodes/_mod.qh>
  69
  70 #include "../common/mapobjects/subs.qh"
  71 #include "../common/mapobjects/triggers.qh"
  72 #include "../common/mapobjects/trigger/secret.qh"
  73
  74 #include "../common/minigames/sv_minigames.qh"
  75
  76 #include "../common/items/inventory.qh"
  77
  78 #include "../common/monsters/sv_monsters.qh"
  79
  80 #include "../lib/warpzone/server.qh"
  81
  82 #include <common/mutators/mutator/overkill/oknex.qh>
  83
  84 #include <common/weapons/weapon/vortex.qh>
  85
  86 #define CHAT_NOSPECTATORS() ((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
  87
  88 STATIC_METHOD(Client, Add, void(Client this, int _team))
  89 {
  90     ClientConnect(this);
  91     TRANSMUTE(Player, this);
  92     this.frame = 12; // 7
  93     this.team = _team;
  94     PutClientInServer(this);
  95 }
  96
  97 STATIC_METHOD(Client, Remove, void(Client this))
  98 {
  99     TRANSMUTE(Observer, this);
 100     PutClientInServer(this);
 101     ClientDisconnect(this);
 102 }
 103
 104 void send_CSQC_teamnagger() {
 105         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
 106 }
 107
 108 int CountSpectators(entity player, entity to)
 109 {
 110         if(!player) { return 0; } // not sure how, but best to be safe
 111
 112         int spec_count = 0;
 113
 114         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 115         {
 116                 spec_count++;
 117         });
 118
 119         return spec_count;
 120 }
 121
 122 void WriteSpectators(entity player, entity to)
 123 {
 124         if(!player) { return; } // not sure how, but best to be safe
 125
 126         int spec_count = 0;
 127         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 128         {
 129                 if(spec_count >= MAX_SPECTATORS)
 130                         break;
 131                 WriteByte(MSG_ENTITY, num_for_edict(it));
 132                 ++spec_count;
 133         });
 134 }
 135
 136 bool ClientData_Send(entity this, entity to, int sf)
 137 {
 138         assert(to == this.owner, return false);
 139
 140         entity e = to;
 141         if (IS_SPEC(e)) e = e.enemy;
 142
 143         sf = 0;
 144         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 145         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 146         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 147         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 148
 149         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 150         WriteByte(MSG_ENTITY, sf);
 151
 152         if (sf & BIT(1))
 153                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 154
 155         if(sf & BIT(4))
 156         {
 157                 float specs = CountSpectators(e, to);
 158                 WriteByte(MSG_ENTITY, specs);
 159                 WriteSpectators(e, to);
 160         }
 161
 162         return true;
 163 }
 164
 165 void ClientData_Attach(entity this)
 166 {
 167         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 168         CS(this).clientdata.drawonlytoclient = this;
 169         CS(this).clientdata.owner = this;
 170 }
 171
 172 void ClientData_Detach(entity this)
 173 {
 174         delete(CS(this).clientdata);
 175         CS(this).clientdata = NULL;
 176 }
 177
 178 void ClientData_Touch(entity e)
 179 {
 180         entity cd = CS(e).clientdata;
 181         if (cd) { cd.SendFlags = 1; }
 182
 183         // make it spectatable
 184         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 185         {
 186                 entity cd = CS(it).clientdata;
 187                 if (cd) { cd.SendFlags = 1; }
 188         });
 189 }
 190
 191
 192 /*
 193 =============
 194 CheckPlayerModel
 195
 196 Checks if the argument string can be a valid playermodel.
 197 Returns a valid one in doubt.
 198 =============
 199 */
 200 string FallbackPlayerModel;
 201 string CheckPlayerModel(string plyermodel) {
 202         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 203         {
 204                 // note: we cannot summon Don Strunzone here, some player may
 205                 // still have the model string set. In case anyone manages how
 206                 // to change a cvar default, we'll have a small leak here.
 207                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 208         }
 209         // only in right path
 210         if( substring(plyermodel,0,14) != "models/player/")
 211                 return FallbackPlayerModel;
 212         // only good file extensions
 213         if(substring(plyermodel,-4,4) != ".zym")
 214         if(substring(plyermodel,-4,4) != ".dpm")
 215         if(substring(plyermodel,-4,4) != ".iqm")
 216         if(substring(plyermodel,-4,4) != ".md3")
 217         if(substring(plyermodel,-4,4) != ".psk")
 218                 return FallbackPlayerModel;
 219         // forbid the LOD models
 220         if(substring(plyermodel, -9,5) == "_lod1")
 221                 return FallbackPlayerModel;
 222         if(substring(plyermodel, -9,5) == "_lod2")
 223                 return FallbackPlayerModel;
 224         if(plyermodel != strtolower(plyermodel))
 225                 return FallbackPlayerModel;
 226         // also, restrict to server models
 227         if(autocvar_sv_servermodelsonly)
 228         {
 229                 if(!fexists(plyermodel))
 230                         return FallbackPlayerModel;
 231         }
 232         return plyermodel;
 233 }
 234
 235 void setplayermodel(entity e, string modelname)
 236 {
 237         precache_model(modelname);
 238         _setmodel(e, modelname);
 239         player_setupanimsformodel(e);
 240         if(!autocvar_g_debug_globalsounds)
 241                 UpdatePlayerSounds(e);
 242 }
 243
 244 /** putting a client as observer in the server */
 245 void PutObserverInServer(entity this)
 246 {
 247     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 248         PlayerState_detach(this);
 249
 250         if (IS_PLAYER(this))
 251         {
 252                 if(GetResource(this, RES_HEALTH) >= 1)
 253                 {
 254                         // despawn effect
 255                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 256                 }
 257
 258                 // was a player, recount votes and ready status
 259                 if(IS_REAL_CLIENT(this))
 260                 {
 261                         if (vote_called) { VoteCount(false); }
 262                         ReadyCount();
 263                 }
 264     }
 265
 266     {
 267         entity spot = SelectSpawnPoint(this, true);
 268         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 269         this.angles = vec2(spot.angles);
 270         this.fixangle = true;
 271         // offset it so that the spectator spawns higher off the ground, looks better this way
 272         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 273         if (IS_REAL_CLIENT(this))
 274         {
 275             msg_entity = this;
 276             WriteByte(MSG_ONE, SVC_SETVIEW);
 277             WriteEntity(MSG_ONE, this);
 278         }
 279         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 280         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 281         if(!autocvar_g_debug_globalsounds)
 282         {
 283                 // needed for player sounds
 284                 this.model = "";
 285                 FixPlayermodel(this);
 286         }
 287         setmodel(this, MDL_Null);
 288         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 289         this.view_ofs = '0 0 0';
 290     }
 291
 292     RemoveGrapplingHooks(this);
 293         Portal_ClearAll(this);
 294         Unfreeze(this, false);
 295         SetSpectatee(this, NULL);
 296
 297         if (this.alivetime)
 298         {
 299                 if (!warmup_stage)
 300                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 301                 this.alivetime = 0;
 302         }
 303
 304         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 305
 306         WaypointSprite_PlayerDead(this);
 307
 308         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 309                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 310
 311         accuracy_resend(this);
 312
 313         CS(this).spectatortime = time;
 314         if(this.bot_attack)
 315                 IL_REMOVE(g_bot_targets, this);
 316         this.bot_attack = false;
 317         if(this.monster_attack)
 318                 IL_REMOVE(g_monster_targets, this);
 319         this.monster_attack = false;
 320     STAT(HUD, this) = HUD_NORMAL;
 321         TRANSMUTE(Observer, this);
 322         this.iscreature = false;
 323         this.teleportable = TELEPORT_SIMPLE;
 324         if(this.damagedbycontents)
 325                 IL_REMOVE(g_damagedbycontents, this);
 326         this.damagedbycontents = false;
 327         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 328         SetSpectatee_status(this, etof(this));
 329         this.takedamage = DAMAGE_NO;
 330         this.solid = SOLID_NOT;
 331         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 332         this.flags = FL_CLIENT | FL_NOTARGET;
 333         this.effects = 0;
 334         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 335         this.pauserotarmor_finished = 0;
 336         this.pauserothealth_finished = 0;
 337         this.pauseregen_finished = 0;
 338         this.damageforcescale = 0;
 339         this.death_time = 0;
 340         this.respawn_flags = 0;
 341         this.respawn_time = 0;
 342         STAT(RESPAWN_TIME, this) = 0;
 343         this.alpha = 0;
 344         this.scale = 0;
 345         this.fade_time = 0;
 346         this.pain_finished = 0;
 347         STAT(STRENGTH_FINISHED, this) = 0;
 348         STAT(INVINCIBLE_FINISHED, this) = 0;
 349         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 350         STAT(AIR_FINISHED, this) = 0;
 351         //this.dphitcontentsmask = 0;
 352         this.dphitcontentsmask = DPCONTENTS_SOLID;
 353         if (autocvar_g_playerclip_collisions)
 354                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 355         this.pushltime = 0;
 356         this.istypefrag = 0;
 357         setthink(this, func_null);
 358         this.nextthink = 0;
 359         this.deadflag = DEAD_NO;
 360         UNSET_DUCKED(this);
 361         STAT(REVIVE_PROGRESS, this) = 0;
 362         this.revival_time = 0;
 363         this.draggable = drag_undraggable;
 364
 365         this.items = 0;
 366         STAT(WEAPONS, this) = '0 0 0';
 367         this.drawonlytoclient = this;
 368
 369         this.viewloc = NULL;
 370
 371         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 372
 373         this.weaponmodel = "";
 374         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 375         {
 376                 this.weaponentities[slot] = NULL;
 377         }
 378         this.exteriorweaponentity = NULL;
 379         CS(this).killcount = FRAGS_SPECTATOR;
 380         this.velocity = '0 0 0';
 381         this.avelocity = '0 0 0';
 382         this.punchangle = '0 0 0';
 383         this.punchvector = '0 0 0';
 384         this.oldvelocity = this.velocity;
 385         this.fire_endtime = -1;
 386         this.event_damage = func_null;
 387         this.event_heal = func_null;
 388
 389         for(int slot = 0; slot < MAX_AXH; ++slot)
 390         {
 391                 entity axh = this.(AuxiliaryXhair[slot]);
 392                 this.(AuxiliaryXhair[slot]) = NULL;
 393
 394                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 395                         delete(axh);
 396         }
 397
 398         if (mutator_returnvalue)
 399         {
 400                 // mutator prevents resetting teams+score
 401         }
 402         else
 403         {
 404                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 405                 this.frags = FRAGS_SPECTATOR;
 406         }
 407         if (CS(this).just_joined)
 408                 CS(this).just_joined = false;
 409 }
 410
 411 int player_getspecies(entity this)
 412 {
 413         get_model_parameters(this.model, this.skin);
 414         int s = get_model_parameters_species;
 415         get_model_parameters(string_null, 0);
 416         if (s < 0) return SPECIES_HUMAN;
 417         return s;
 418 }
 419
 420 .float model_randomizer;
 421 void FixPlayermodel(entity player)
 422 {
 423         string defaultmodel = "";
 424         int defaultskin = 0;
 425         if(autocvar_sv_defaultcharacter)
 426         {
 427                 if(teamplay)
 428                 {
 429                         switch(player.team)
 430                         {
 431                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 432                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 433                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 434                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 435                         }
 436                 }
 437
 438                 if(defaultmodel == "")
 439                 {
 440                         defaultmodel = autocvar_sv_defaultplayermodel;
 441                         defaultskin = autocvar_sv_defaultplayerskin;
 442                 }
 443
 444                 int n = tokenize_console(defaultmodel);
 445                 if(n > 0)
 446                 {
 447                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 448                         // However, do NOT randomize if the player-selected model is in the list.
 449                         for (int i = 0; i < n; ++i)
 450                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 451                                         defaultmodel = argv(i);
 452                 }
 453
 454                 int i = strstrofs(defaultmodel, ":", 0);
 455                 if(i >= 0)
 456                 {
 457                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 458                         defaultmodel = substring(defaultmodel, 0, i);
 459                 }
 460         }
 461         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 462         {
 463                 if(teamplay)
 464                 {
 465                         switch(player.team)
 466                         {
 467                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 468                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 469                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 470                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 471                         }
 472                 }
 473
 474                 if(!defaultskin)
 475                         defaultskin = autocvar_sv_defaultplayerskin;
 476         }
 477
 478         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 479         defaultmodel = M_ARGV(0, string);
 480         defaultskin = M_ARGV(1, int);
 481
 482         bool chmdl = false;
 483         int oldskin;
 484         if(defaultmodel != "")
 485         {
 486                 if (defaultmodel != player.model)
 487                 {
 488                         vector m1 = player.mins;
 489                         vector m2 = player.maxs;
 490                         setplayermodel (player, defaultmodel);
 491                         setsize (player, m1, m2);
 492                         chmdl = true;
 493                 }
 494
 495                 oldskin = player.skin;
 496                 player.skin = defaultskin;
 497         } else {
 498                 if (player.playermodel != player.model || player.playermodel == "")
 499                 {
 500                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 501                         vector m1 = player.mins;
 502                         vector m2 = player.maxs;
 503                         setplayermodel (player, player.playermodel);
 504                         setsize (player, m1, m2);
 505                         chmdl = true;
 506                 }
 507
 508                 if(!autocvar_sv_defaultcharacterskin)
 509                 {
 510                         oldskin = player.skin;
 511                         player.skin = stof(player.playerskin);
 512                 }
 513                 else
 514                 {
 515                         oldskin = player.skin;
 516                         player.skin = defaultskin;
 517                 }
 518         }
 519
 520         if(chmdl || oldskin != player.skin) // model or skin has changed
 521         {
 522                 player.species = player_getspecies(player); // update species
 523                 if(!autocvar_g_debug_globalsounds)
 524                         UpdatePlayerSounds(player); // update skin sounds
 525         }
 526
 527         if(!teamplay)
 528                 if(strlen(autocvar_sv_defaultplayercolors))
 529                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 530                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 531 }
 532
 533 void PutPlayerInServer(entity this)
 534 {
 535         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 536
 537         PlayerState_attach(this);
 538         accuracy_resend(this);
 539
 540         if (this.team < 0)
 541                 TeamBalance_JoinBestTeam(this);
 542
 543         entity spot = SelectSpawnPoint(this, false);
 544         if (!spot) {
 545                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 546                 return; // spawn failed
 547         }
 548
 549         TRANSMUTE(Player, this);
 550
 551         CS(this).wasplayer = true;
 552         this.iscreature = true;
 553         this.teleportable = TELEPORT_NORMAL;
 554         if(!this.damagedbycontents)
 555                 IL_PUSH(g_damagedbycontents, this);
 556         this.damagedbycontents = true;
 557         set_movetype(this, MOVETYPE_WALK);
 558         this.solid = SOLID_SLIDEBOX;
 559         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 560         if (autocvar_g_playerclip_collisions)
 561                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 562         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 563                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 564         this.frags = FRAGS_PLAYER;
 565         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 566         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 567         if (autocvar__notarget)
 568                 this.flags |= FL_NOTARGET;
 569         this.takedamage = DAMAGE_AIM;
 570         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 571
 572         if (warmup_stage) {
 573                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 574                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 575                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 576                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 577                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 578                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 579                 SetResource(this, RES_HEALTH, warmup_start_health);
 580                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 581                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 582         } else {
 583                 SetResource(this, RES_SHELLS, start_ammo_shells);
 584                 SetResource(this, RES_BULLETS, start_ammo_nails);
 585                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 586                 SetResource(this, RES_CELLS, start_ammo_cells);
 587                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 588                 SetResource(this, RES_FUEL, start_ammo_fuel);
 589                 SetResource(this, RES_HEALTH, start_health);
 590                 SetResource(this, RES_ARMOR, start_armorvalue);
 591                 STAT(WEAPONS, this) = start_weapons;
 592                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 593                 {
 594                         GiveRandomWeapons(this, random_start_weapons_count,
 595                                 autocvar_g_random_start_weapons, random_start_ammo);
 596                 }
 597         }
 598         SetSpectatee_status(this, 0);
 599
 600         PS(this).dual_weapons = '0 0 0';
 601
 602         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 603
 604         this.items = start_items;
 605
 606         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 607         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 608         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 609         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 610         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 611         if (!sv_ready_restart_after_countdown && time < game_starttime)
 612         {
 613                 float f = game_starttime - time;
 614                 this.spawnshieldtime += f;
 615                 this.pauserotarmor_finished += f;
 616                 this.pauserothealth_finished += f;
 617                 this.pauseregen_finished += f;
 618         }
 619
 620         this.damageforcescale = autocvar_g_player_damageforcescale;
 621         this.death_time = 0;
 622         this.respawn_flags = 0;
 623         this.respawn_time = 0;
 624         STAT(RESPAWN_TIME, this) = 0;
 625         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 626         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 627         this.fade_time = 0;
 628         this.pain_finished = 0;
 629         this.pushltime = 0;
 630         setthink(this, func_null); // players have no think function
 631         this.nextthink = 0;
 632         this.dmg_team = 0;
 633         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 634
 635         this.deadflag = DEAD_NO;
 636
 637         this.angles = spot.angles;
 638         this.angles_z = 0; // never spawn tilted even if the spot says to
 639         if (IS_BOT_CLIENT(this))
 640         {
 641                 this.v_angle = this.angles;
 642                 bot_aim_reset(this);
 643         }
 644         this.fixangle = true; // turn this way immediately
 645         this.oldvelocity = this.velocity = '0 0 0';
 646         this.avelocity = '0 0 0';
 647         this.punchangle = '0 0 0';
 648         this.punchvector = '0 0 0';
 649
 650         STAT(STRENGTH_FINISHED, this) = 0;
 651         STAT(INVINCIBLE_FINISHED, this) = 0;
 652         this.fire_endtime = -1;
 653         STAT(REVIVE_PROGRESS, this) = 0;
 654         this.revival_time = 0;
 655
 656         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 657         STAT(BUFFS, this) = 0;
 658         STAT(BUFF_TIME, this) = 0;
 659
 660         STAT(AIR_FINISHED, this) = 0;
 661         this.waterlevel = WATERLEVEL_NONE;
 662         this.watertype = CONTENT_EMPTY;
 663
 664         entity spawnevent = new_pure(spawnevent);
 665         spawnevent.owner = this;
 666         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 667
 668         // Cut off any still running player sounds.
 669         stopsound(this, CH_PLAYER_SINGLE);
 670
 671         this.model = "";
 672         FixPlayermodel(this);
 673         this.drawonlytoclient = NULL;
 674
 675         this.viewloc = NULL;
 676
 677         for(int slot = 0; slot < MAX_AXH; ++slot)
 678         {
 679                 entity axh = this.(AuxiliaryXhair[slot]);
 680                 this.(AuxiliaryXhair[slot]) = NULL;
 681
 682                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 683                         delete(axh);
 684         }
 685
 686         this.spawnpoint_targ = NULL;
 687
 688         UNSET_DUCKED(this);
 689         this.view_ofs = STAT(PL_VIEW_OFS, this);
 690         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 691         this.spawnorigin = spot.origin;
 692         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 693         // don't reset back to last position, even if new position is stuck in solid
 694         this.oldorigin = this.origin;
 695         if(this.conveyor)
 696                 IL_REMOVE(g_conveyed, this);
 697         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 698         if(this.swampslug)
 699                 IL_REMOVE(g_swamped, this);
 700         this.swampslug = NULL;
 701         this.swamp_interval = 0;
 702         if(this.ladder_entity)
 703                 IL_REMOVE(g_ladderents, this);
 704         this.ladder_entity = NULL;
 705         IL_EACH(g_counters, it.realowner == this,
 706         {
 707                 delete(it);
 708         });
 709         STAT(HUD, this) = HUD_NORMAL;
 710
 711         this.event_damage = PlayerDamage;
 712         this.event_heal = PlayerHeal;
 713
 714         this.draggable = func_null;
 715
 716         if(!this.bot_attack)
 717                 IL_PUSH(g_bot_targets, this);
 718         this.bot_attack = true;
 719         if(!this.monster_attack)
 720                 IL_PUSH(g_monster_targets, this);
 721         this.monster_attack = true;
 722         navigation_dynamicgoal_init(this, false);
 723
 724         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 725
 726         // player was spectator
 727         if (CS(this).killcount == FRAGS_SPECTATOR) {
 728                 PlayerScore_Clear(this);
 729                 CS(this).killcount = 0;
 730                 CS(this).startplaytime = time;
 731         }
 732
 733         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 734         {
 735                 .entity weaponentity = weaponentities[slot];
 736                 CL_SpawnWeaponentity(this, weaponentity);
 737         }
 738         this.alpha = default_player_alpha;
 739         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 740         this.exteriorweaponentity.alpha = default_weapon_alpha;
 741
 742         this.speedrunning = false;
 743
 744         this.counter_cnt = 0;
 745         this.fragsfilter_cnt = 0;
 746
 747         target_voicescript_clear(this);
 748
 749         // reset fields the weapons may use
 750         FOREACH(Weapons, true, {
 751                 it.wr_resetplayer(it, this);
 752                         // reload all reloadable weapons
 753                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 754                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 755                         {
 756                                 .entity weaponentity = weaponentities[slot];
 757                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 758                         }
 759                 }
 760         });
 761
 762         {
 763                 string s = spot.target;
 764                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 765                         spot.target = string_null;
 766                 SUB_UseTargets(spot, this, NULL);
 767                 if(g_assault || g_race)
 768                         spot.target = s;
 769         }
 770
 771         Unfreeze(this, false);
 772
 773         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 774
 775         if (autocvar_spawn_debug)
 776         {
 777                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 778                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 779         }
 780
 781         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 782         {
 783                 .entity weaponentity = weaponentities[slot];
 784                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 785                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 786                 else
 787                         this.(weaponentity).m_switchweapon = WEP_Null;
 788                 this.(weaponentity).m_weapon = WEP_Null;
 789                 this.(weaponentity).weaponname = "";
 790                 this.(weaponentity).m_switchingweapon = WEP_Null;
 791                 this.(weaponentity).cnt = -1;
 792         }
 793
 794         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 795
 796         if (CS(this).impulse) ImpulseCommands(this);
 797
 798         W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
 799         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 800         {
 801                 .entity weaponentity = weaponentities[slot];
 802                 W_WeaponFrame(this, weaponentity);
 803         }
 804
 805         if (!warmup_stage && !this.alivetime)
 806                 this.alivetime = time;
 807
 808         antilag_clear(this, CS(this));
 809 }
 810
 811 /** Called when a client spawns in the server */
 812 void PutClientInServer(entity this)
 813 {
 814         if (IS_BOT_CLIENT(this)) {
 815                 TRANSMUTE(Player, this);
 816         } else if (IS_REAL_CLIENT(this)) {
 817                 msg_entity = this;
 818                 WriteByte(MSG_ONE, SVC_SETVIEW);
 819                 WriteEntity(MSG_ONE, this);
 820         }
 821         if (game_stopped)
 822                 TRANSMUTE(Observer, this);
 823
 824         SetSpectatee(this, NULL);
 825
 826         // reset player keys
 827         if(PS(this))
 828                 PS(this).itemkeys = 0;
 829
 830         MUTATOR_CALLHOOK(PutClientInServer, this);
 831
 832         if (IS_OBSERVER(this)) {
 833                 PutObserverInServer(this);
 834         } else if (IS_PLAYER(this)) {
 835                 PutPlayerInServer(this);
 836         }
 837 }
 838
 839 // TODO do we need all these fields, or should we stop autodetecting runtime
 840 // changes and just have a console command to update this?
 841 bool ClientInit_SendEntity(entity this, entity to, int sf)
 842 {
 843         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 844         return = true;
 845         msg_entity = to;
 846         // MSG_INIT replacement
 847         // TODO: make easier to use
 848         Registry_send_all();
 849         W_PROP_reload(MSG_ONE, to);
 850         ClientInit_misc(this);
 851         MUTATOR_CALLHOOK(Ent_Init);
 852 }
 853 void ClientInit_misc(entity this)
 854 {
 855         int channel = MSG_ONE;
 856         WriteHeader(channel, ENT_CLIENT_INIT);
 857         WriteByte(channel, g_nexball_meter_period * 32);
 858         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 859         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 860         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 861         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 862         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 863         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 864         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 865         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 866
 867         if(sv_foginterval && world.fog != "")
 868                 WriteString(channel, world.fog);
 869         else
 870                 WriteString(channel, "");
 871         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 872         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 873         WriteByte(channel, serverflags);
 874         WriteCoord(channel, autocvar_g_trueaim_minrange);
 875 }
 876
 877 void ClientInit_CheckUpdate(entity this)
 878 {
 879         this.nextthink = time;
 880         if(this.count != autocvar_g_balance_armor_blockpercent)
 881         {
 882                 this.count = autocvar_g_balance_armor_blockpercent;
 883                 this.SendFlags |= 1;
 884         }
 885         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 886         {
 887                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 888                 this.SendFlags |= 1;
 889         }
 890 }
 891
 892 void ClientInit_Spawn()
 893 {
 894         entity e = new_pure(clientinit);
 895         setthink(e, ClientInit_CheckUpdate);
 896         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 897
 898         ClientInit_CheckUpdate(e);
 899 }
 900
 901 /*
 902 =============
 903 SetNewParms
 904 =============
 905 */
 906 void SetNewParms ()
 907 {
 908         // initialize parms for a new player
 909         parm1 = -(86400 * 366);
 910
 911         MUTATOR_CALLHOOK(SetNewParms);
 912 }
 913
 914 /*
 915 =============
 916 SetChangeParms
 917 =============
 918 */
 919 void SetChangeParms (entity this)
 920 {
 921         // save parms for level change
 922         parm1 = CS(this).parm_idlesince - time;
 923
 924         MUTATOR_CALLHOOK(SetChangeParms);
 925 }
 926
 927 /*
 928 =============
 929 DecodeLevelParms
 930 =============
 931 */
 932 void DecodeLevelParms(entity this)
 933 {
 934         // load parms
 935         CS(this).parm_idlesince = parm1;
 936         if (CS(this).parm_idlesince == -(86400 * 366))
 937                 CS(this).parm_idlesince = time;
 938
 939         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 940         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 941
 942         MUTATOR_CALLHOOK(DecodeLevelParms);
 943 }
 944
 945 void FixClientCvars(entity e)
 946 {
 947         // send prediction settings to the client
 948         stuffcmd(e, "\nin_bindmap 0 0\n");
 949         if(autocvar_g_antilag == 3) // client side hitscan
 950                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 951         if(autocvar_sv_gentle)
 952                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 953
 954         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 955         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 956
 957         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 958
 959         MUTATOR_CALLHOOK(FixClientCvars, e);
 960 }
 961
 962 bool findinlist_abbrev(string tofind, string list)
 963 {
 964         if(list == "" || tofind == "")
 965                 return false; // empty list or search, just return
 966
 967         // this function allows abbreviated strings!
 968         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 969         {
 970                 return true;
 971         });
 972
 973         return false;
 974 }
 975
 976 bool PlayerInIPList(entity p, string iplist)
 977 {
 978         // some safety checks (never allow local?)
 979         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 980                 return false;
 981
 982         return findinlist_abbrev(p.netaddress, iplist);
 983 }
 984
 985 bool PlayerInIDList(entity p, string idlist)
 986 {
 987         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 988         if(!p.crypto_idfp)
 989                 return false;
 990
 991         return findinlist_abbrev(p.crypto_idfp, idlist);
 992 }
 993
 994 bool PlayerInList(entity player, string list)
 995 {
 996         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 997 }
 998
 999 #ifdef DP_EXT_PRECONNECT
1000 /*
1001 =============
1002 ClientPreConnect
1003
1004 Called once (not at each match start) when a client begins a connection to the server
1005 =============
1006 */
1007 void ClientPreConnect(entity this)
1008 {
1009         if(autocvar_sv_eventlog)
1010         {
1011                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1012                         this.playerid,
1013                         etof(this),
1014                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1015                 ));
1016         }
1017 }
1018 #endif
1019
1020 string GetClientVersionMessage(entity this)
1021 {
1022         if (CS(this).version_mismatch) {
1023                 if(CS(this).version < autocvar_gameversion) {
1024                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1025                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1026                 } else {
1027                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1028                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1029                 }
1030         } else {
1031                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1032         }
1033 }
1034
1035 string getwelcomemessage(entity this)
1036 {
1037         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1038         string modifications = M_ARGV(0, string);
1039
1040         if(g_weaponarena)
1041         {
1042                 if(g_weaponarena_random)
1043                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1044                 else
1045                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1046         }
1047         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1048                 modifications = strcat(modifications, ", No start weapons");
1049         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1050                 modifications = strcat(modifications, ", Low gravity");
1051         if(g_weapon_stay && !g_cts)
1052                 modifications = strcat(modifications, ", Weapons stay");
1053         if(g_jetpack)
1054                 modifications = strcat(modifications, ", Jet pack");
1055         if(autocvar_g_powerups == 0)
1056                 modifications = strcat(modifications, ", No powerups");
1057         if(autocvar_g_powerups > 0)
1058                 modifications = strcat(modifications, ", Powerups");
1059         modifications = substring(modifications, 2, strlen(modifications) - 2);
1060
1061         string versionmessage = GetClientVersionMessage(this);
1062         string s = strcat(versionmessage, "^8\n^8\nhost is ^9", autocvar_hostname, "^8\n");
1063
1064         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1065
1066         if(modifications != "")
1067                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1068
1069         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1070         {
1071                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1072                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1073         }
1074
1075         if (cache_mutatormsg != "") {
1076                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1077         }
1078
1079         string mutator_msg = "";
1080         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1081         mutator_msg = M_ARGV(0, string);
1082
1083         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1084
1085         string motd = autocvar_sv_motd;
1086         if (motd != "") {
1087                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1088         }
1089         return s;
1090 }
1091
1092 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1093
1094 /**
1095 =============
1096 ClientConnect
1097
1098 Called when a client connects to the server
1099 =============
1100 */
1101 void ClientConnect(entity this)
1102 {
1103         if (Ban_MaybeEnforceBanOnce(this)) return;
1104         assert(!IS_CLIENT(this), return);
1105         this.flags |= FL_CLIENT;
1106         assert(player_count >= 0, player_count = 0);
1107
1108 #ifdef WATERMARK
1109         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1110 #endif
1111         TRANSMUTE(Client, this);
1112         CS(this).version_nagtime = time + 10 + random() * 10;
1113
1114         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1115
1116         bot_clientconnect(this);
1117
1118         Player_DetermineForcedTeam(this);
1119
1120         TRANSMUTE(Observer, this);
1121
1122         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1123
1124         // always track bots, don't ask for cl_allow_uidtracking
1125         if (IS_BOT_CLIENT(this))
1126                 PlayerStats_GameReport_AddPlayer(this);
1127         else
1128                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1129
1130         if (autocvar_sv_eventlog)
1131                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this, false)));
1132
1133         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1134
1135         stuffcmd(this, clientstuff, "\n");
1136         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1137
1138         FixClientCvars(this);
1139
1140         // get version info from player
1141         stuffcmd(this, "cmd clientversion $gameversion\n");
1142
1143         // notify about available teams
1144         if (teamplay)
1145         {
1146                 entity balance = TeamBalance_CheckAllowedTeams(this);
1147                 int t = TeamBalance_GetAllowedTeams(balance);
1148                 TeamBalance_Destroy(balance);
1149                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1150         }
1151         else
1152         {
1153                 stuffcmd(this, "set _teams_available 0\n");
1154         }
1155
1156         bot_relinkplayerlist();
1157
1158         CS(this).spectatortime = time;
1159         if (blockSpectators)
1160         {
1161                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1162         }
1163
1164         CS(this).jointime = time;
1165
1166         if (IS_REAL_CLIENT(this))
1167         {
1168                 if (g_weaponarena_weapons == WEPSET(TUBA))
1169                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1170         }
1171
1172         if (!sv_foginterval && world.fog != "")
1173                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1174
1175         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1176                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1177                         send_CSQC_teamnagger();
1178
1179         CSQCMODEL_AUTOINIT(this);
1180
1181         CS(this).model_randomizer = random();
1182
1183         if (IS_REAL_CLIENT(this))
1184                 sv_notice_join(this);
1185
1186         this.move_qcphysics = autocvar_sv_qcphysics;
1187
1188         // update physics stats (players can spawn before physics runs)
1189         Physics_UpdateStats(this);
1190
1191         IL_EACH(g_initforplayer, it.init_for_player, {
1192                 it.init_for_player(it, this);
1193         });
1194
1195         Handicap_Initialize(this);
1196
1197         MUTATOR_CALLHOOK(ClientConnect, this);
1198
1199         if (IS_REAL_CLIENT(this))
1200         {
1201                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1202                 {
1203                         CS(this).motd_actived_time = -1;
1204                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1205                 }
1206         }
1207 }
1208 /*
1209 =============
1210 ClientDisconnect
1211
1212 Called when a client disconnects from the server
1213 =============
1214 */
1215 .entity chatbubbleentity;
1216 void ClientDisconnect(entity this)
1217 {
1218         assert(IS_CLIENT(this), return);
1219
1220         PlayerStats_GameReport_FinalizePlayer(this);
1221         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1222         if (CS(this).active_minigame) part_minigame(this);
1223         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1224
1225         if (autocvar_sv_eventlog)
1226                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1227
1228         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1229
1230         if(IS_SPEC(this))
1231                 SetSpectatee(this, NULL);
1232
1233     MUTATOR_CALLHOOK(ClientDisconnect, this);
1234
1235         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1236         strfree(CS(this).weaponorder_byimpulse);
1237         ClientState_detach(this);
1238
1239         Portal_ClearAll(this);
1240
1241         Unfreeze(this, false);
1242
1243         RemoveGrapplingHooks(this);
1244
1245         // Here, everything has been done that requires this player to be a client.
1246
1247         this.flags &= ~FL_CLIENT;
1248
1249         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1250         if (this.killindicator) delete(this.killindicator);
1251
1252         IL_EACH(g_counters, it.realowner == this,
1253         {
1254                 delete(it);
1255         });
1256
1257         WaypointSprite_PlayerGone(this);
1258
1259         bot_relinkplayerlist();
1260
1261         strfree(this.clientstatus);
1262         if (this.personal) delete(this.personal);
1263
1264         this.playerid = 0;
1265         ReadyCount();
1266         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1267
1268         ONREMOVE(this);
1269 }
1270
1271 void ChatBubbleThink(entity this)
1272 {
1273         this.nextthink = time;
1274         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1275         {
1276                 if(this.owner) // but why can that ever be NULL?
1277                         this.owner.chatbubbleentity = NULL;
1278                 delete(this);
1279                 return;
1280         }
1281
1282         this.mdl = "";
1283
1284         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1285         {
1286                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1287                         this.mdl = "models/sprites/minigame_busy.iqm";
1288                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1289                         this.mdl = "models/misc/chatbubble.spr";
1290         }
1291
1292         if ( this.model != this.mdl )
1293                 _setmodel(this, this.mdl);
1294
1295 }
1296
1297 void UpdateChatBubble(entity this)
1298 {
1299         if (this.alpha < 0)
1300                 return;
1301         // spawn a chatbubble entity if needed
1302         if (!this.chatbubbleentity)
1303         {
1304                 this.chatbubbleentity = new(chatbubbleentity);
1305                 this.chatbubbleentity.owner = this;
1306                 this.chatbubbleentity.exteriormodeltoclient = this;
1307                 setthink(this.chatbubbleentity, ChatBubbleThink);
1308                 this.chatbubbleentity.nextthink = time;
1309                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1310                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1311                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1312                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1313                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1314                 //this.chatbubbleentity.model = "";
1315                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1316         }
1317 }
1318
1319 void calculate_player_respawn_time(entity this)
1320 {
1321         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1322                 return;
1323
1324         float gametype_setting_tmp;
1325         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1326         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1327         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1328         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1329         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1330         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1331
1332         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1333         if (teamplay)
1334         {
1335                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1336                         if(it.team == this.team)
1337                                 ++pcount;
1338                 });
1339                 if (sdelay_small_count == 0)
1340                         sdelay_small_count = 1;
1341                 if (sdelay_large_count == 0)
1342                         sdelay_large_count = 1;
1343         }
1344         else
1345         {
1346                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1347                         ++pcount;
1348                 });
1349                 if (sdelay_small_count == 0)
1350                 {
1351                         if (IS_INDEPENDENT_PLAYER(this))
1352                         {
1353                                 // Players play independently. No point in requiring enemies.
1354                                 sdelay_small_count = 1;
1355                         }
1356                         else
1357                         {
1358                                 // Players play AGAINST each other. Enemies required.
1359                                 sdelay_small_count = 2;
1360                         }
1361                 }
1362                 if (sdelay_large_count == 0)
1363                 {
1364                         if (IS_INDEPENDENT_PLAYER(this))
1365                         {
1366                                 // Players play independently. No point in requiring enemies.
1367                                 sdelay_large_count = 1;
1368                         }
1369                         else
1370                         {
1371                                 // Players play AGAINST each other. Enemies required.
1372                                 sdelay_large_count = 2;
1373                         }
1374                 }
1375         }
1376
1377         float sdelay;
1378
1379         if (pcount <= sdelay_small_count)
1380                 sdelay = sdelay_small;
1381         else if (pcount >= sdelay_large_count)
1382                 sdelay = sdelay_large;
1383         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1384                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1385
1386         if(waves)
1387                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1388         else
1389                 this.respawn_time = time + sdelay;
1390
1391         if(sdelay < sdelay_max)
1392                 this.respawn_time_max = time + sdelay_max;
1393         else
1394                 this.respawn_time_max = this.respawn_time;
1395
1396         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1397                 this.respawn_countdown = 10; // first number to count down from is 10
1398         else
1399                 this.respawn_countdown = -1; // do not count down
1400
1401         if(autocvar_g_forced_respawn)
1402                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1403 }
1404
1405 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1406 // added to the model skins
1407 /*void UpdateColorModHack()
1408 {
1409         float c;
1410         c = this.clientcolors & 15;
1411         // LordHavoc: only bothering to support white, green, red, yellow, blue
1412              if (!teamplay) this.colormod = '0 0 0';
1413         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1414         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1415         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1416         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1417         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1418         else this.colormod = '1 1 1';
1419 }*/
1420
1421 void respawn(entity this)
1422 {
1423         bool damagedbycontents_prev = this.damagedbycontents;
1424         if(this.alpha >= 0)
1425         {
1426                 if(autocvar_g_respawn_ghosts)
1427                 {
1428                         this.solid = SOLID_NOT;
1429                         this.takedamage = DAMAGE_NO;
1430                         this.damagedbycontents = false;
1431                         set_movetype(this, MOVETYPE_FLY);
1432                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1433                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1434                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1435                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1436                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1437                         if(autocvar_g_respawn_ghosts_time > 0)
1438                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1439                 }
1440                 else
1441                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1442         }
1443
1444         CopyBody(this, 1);
1445         this.damagedbycontents = damagedbycontents_prev;
1446
1447         this.effects |= EF_NODRAW; // prevent another CopyBody
1448         PutClientInServer(this);
1449 }
1450
1451 ERASEABLE
1452 void PrintToChat(entity client, string text)
1453 {
1454         text = strcat("\{1}^7", text, "\n");
1455         sprint(client, text);
1456 }
1457
1458 ERASEABLE
1459 void DebugPrintToChat(entity client, string text)
1460 {
1461         if (autocvar_developer > 0)
1462         {
1463                 PrintToChat(client, text);
1464         }
1465 }
1466
1467 ERASEABLE
1468 void PrintToChatAll(string text)
1469 {
1470         text = strcat("\{1}^7", text, "\n");
1471         bprint(text);
1472 }
1473
1474 ERASEABLE
1475 void DebugPrintToChatAll(string text)
1476 {
1477         if (autocvar_developer > 0)
1478         {
1479                 PrintToChatAll(text);
1480         }
1481 }
1482
1483 ERASEABLE
1484 void PrintToChatTeam(int team_num, string text)
1485 {
1486         text = strcat("\{1}^7", text, "\n");
1487         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1488         {
1489                 if (it.team == team_num)
1490                 {
1491                         sprint(it, text);
1492                 }
1493         });
1494 }
1495
1496 ERASEABLE
1497 void DebugPrintToChatTeam(int team_num, string text)
1498 {
1499         if (autocvar_developer > 0)
1500         {
1501                 PrintToChatTeam(team_num, text);
1502         }
1503 }
1504
1505 void play_countdown(entity this, float finished, Sound samp)
1506 {
1507         TC(Sound, samp);
1508         if(IS_REAL_CLIENT(this))
1509                 if(floor(finished - time - frametime) != floor(finished - time))
1510                         if(finished - time < 6)
1511                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1512 }
1513
1514 void player_powerups(entity this)
1515 {
1516         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1517                 this.modelflags |= MF_ROCKET;
1518         else
1519                 this.modelflags &= ~MF_ROCKET;
1520
1521         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1522
1523         if (IS_DEAD(this))
1524         {
1525                 if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1526                 {
1527                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1528                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1529                         this.items &= ~ITEM_Strength.m_itemid;
1530                         this.items &= ~ITEM_Shield.m_itemid;
1531                         this.items -= (this.items & IT_SUPERWEAPON);
1532                 }
1533         }
1534
1535         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1536                 return;
1537
1538         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1539         int items_prev = this.items;
1540
1541         Fire_ApplyDamage(this);
1542         Fire_ApplyEffect(this);
1543
1544         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1545         {
1546                 if (this.items & ITEM_Strength.m_itemid)
1547                 {
1548                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1549                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1550                         if (time > STAT(STRENGTH_FINISHED, this))
1551                         {
1552                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1553                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1554                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1555                         }
1556                 }
1557                 else
1558                 {
1559                         if (time < STAT(STRENGTH_FINISHED, this))
1560                         {
1561                                 this.items = this.items | ITEM_Strength.m_itemid;
1562                                 if(!g_cts)
1563                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1564                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1565                         }
1566                 }
1567                 if (this.items & ITEM_Shield.m_itemid)
1568                 {
1569                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1570                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1571                         if (time > STAT(INVINCIBLE_FINISHED, this))
1572                         {
1573                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1574                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1575                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1576                         }
1577                 }
1578                 else
1579                 {
1580                         if (time < STAT(INVINCIBLE_FINISHED, this))
1581                         {
1582                                 this.items = this.items | ITEM_Shield.m_itemid;
1583                                 if(!g_cts)
1584                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1585                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1586                         }
1587                 }
1588                 if (this.items & IT_SUPERWEAPON)
1589                 {
1590                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1591                         {
1592                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1593                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1594                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1595                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1596                         }
1597                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1598                         {
1599                                 // don't let them run out
1600                         }
1601                         else
1602                         {
1603                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1604                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1605                                 {
1606                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1607                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1608                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1609                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1610                                 }
1611                         }
1612                 }
1613                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1614                 {
1615                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1616                         {
1617                                 this.items = this.items | IT_SUPERWEAPON;
1618                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1619                                 {
1620                                         if(!g_cts)
1621                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1622                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1623                                 }
1624                         }
1625                         else
1626                         {
1627                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1628                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1629                         }
1630                 }
1631                 else
1632                 {
1633                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1634                 }
1635         }
1636
1637         if(autocvar_g_nodepthtestplayers)
1638                 this.effects = this.effects | EF_NODEPTHTEST;
1639
1640         if(autocvar_g_fullbrightplayers)
1641                 this.effects = this.effects | EF_FULLBRIGHT;
1642
1643         if (time >= game_starttime)
1644         if (time < this.spawnshieldtime)
1645                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1646
1647         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1648 }
1649
1650 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1651 {
1652         if(current > stable)
1653                 return current;
1654         else if(current > stable - 0.25) // when close enough, "snap"
1655                 return stable;
1656         else
1657                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1658 }
1659
1660 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1661 {
1662         if(current < stable)
1663                 return current;
1664         else if(current < stable + 0.25) // when close enough, "snap"
1665                 return stable;
1666         else
1667                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1668 }
1669
1670 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1671 {
1672         float old = GetResource(this, res);
1673         float current = old;
1674         if(current > rotstable)
1675         {
1676                 if(rotframetime > 0)
1677                 {
1678                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1679                         current = max(rotstable, current - rotlinear * rotframetime);
1680                 }
1681         }
1682         else if(current < regenstable)
1683         {
1684                 if(regenframetime > 0)
1685                 {
1686                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1687                         current = min(regenstable, current + regenlinear * regenframetime);
1688                 }
1689         }
1690
1691         float limit = GetResourceLimit(this, res) * limit_mod;
1692         if(current > limit)
1693                 current = limit;
1694
1695         if (current != old)
1696                 SetResource(this, res, current);
1697 }
1698
1699 void player_regen(entity this)
1700 {
1701         float max_mod, regen_mod, rot_mod, limit_mod;
1702         max_mod = regen_mod = rot_mod = limit_mod = 1;
1703
1704         float regen_health = autocvar_g_balance_health_regen;
1705         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1706         float regen_health_rot = autocvar_g_balance_health_rot;
1707         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1708         float regen_health_stable = autocvar_g_balance_health_regenstable;
1709         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1710         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1711                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1712         max_mod = M_ARGV(1, float);
1713         regen_mod = M_ARGV(2, float);
1714         rot_mod = M_ARGV(3, float);
1715         limit_mod = M_ARGV(4, float);
1716         regen_health = M_ARGV(5, float);
1717         regen_health_linear = M_ARGV(6, float);
1718         regen_health_rot = M_ARGV(7, float);
1719         regen_health_rotlinear = M_ARGV(8, float);
1720         regen_health_stable = M_ARGV(9, float);
1721         regen_health_rotstable = M_ARGV(10, float);
1722
1723         if(!mutator_returnvalue)
1724         if(!STAT(FROZEN, this))
1725         {
1726                 float maxa = autocvar_g_balance_armor_rotstable;
1727                 float mina = autocvar_g_balance_armor_regenstable;
1728
1729                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1730                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1731                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1732
1733                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1734                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1735                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1736         }
1737
1738         // if player rotted to death...  die!
1739         // check this outside above checks, as player may still be able to rot to death
1740         if(GetResource(this, RES_HEALTH) < 1)
1741         {
1742                 if(this.vehicle)
1743                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1744                 if(this.event_damage)
1745                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1746         }
1747
1748         if (!(this.items & IT_UNLIMITED_AMMO))
1749         {
1750                 float maxf = autocvar_g_balance_fuel_rotstable;
1751                 float minf = autocvar_g_balance_fuel_regenstable;
1752
1753                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1754                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1755                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1756         }
1757 }
1758
1759 bool zoomstate_set;
1760 void SetZoomState(entity this, float newzoom)
1761 {
1762         if(newzoom != CS(this).zoomstate)
1763         {
1764                 CS(this).zoomstate = newzoom;
1765                 ClientData_Touch(this);
1766         }
1767         zoomstate_set = true;
1768 }
1769
1770 void GetPressedKeys(entity this)
1771 {
1772         MUTATOR_CALLHOOK(GetPressedKeys, this);
1773         int keys = STAT(PRESSED_KEYS, this);
1774         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1775         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1776         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1777         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1778
1779         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1780         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1781         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1782         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1783         CS(this).pressedkeys = keys; // store for other users
1784
1785         STAT(PRESSED_KEYS, this) = keys;
1786 }
1787
1788 /*
1789 ======================
1790 spectate mode routines
1791 ======================
1792 */
1793
1794 void SpectateCopy(entity this, entity spectatee)
1795 {
1796         TC(Client, this); TC(Client, spectatee);
1797
1798         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1799         PS(this) = PS(spectatee);
1800         this.armortype = spectatee.armortype;
1801         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1802         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1803         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1804         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1805         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1806         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1807         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1808         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1809         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1810         CS(this).impulse = 0;
1811         this.disableclientprediction = 1; // no need to run prediction on a spectator
1812         this.items = spectatee.items;
1813         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1814         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1815         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1816         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1817         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1818         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1819         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1820         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1821         this.punchangle = spectatee.punchangle;
1822         this.view_ofs = spectatee.view_ofs;
1823         this.velocity = spectatee.velocity;
1824         this.dmg_take = spectatee.dmg_take;
1825         this.dmg_save = spectatee.dmg_save;
1826         this.dmg_inflictor = spectatee.dmg_inflictor;
1827         this.v_angle = spectatee.v_angle;
1828         this.angles = spectatee.v_angle;
1829         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1830         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1831         this.viewloc = spectatee.viewloc;
1832         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1833                 this.fixangle = true;
1834         setorigin(this, spectatee.origin);
1835         setsize(this, spectatee.mins, spectatee.maxs);
1836         SetZoomState(this, CS(spectatee).zoomstate);
1837
1838     anticheat_spectatecopy(this, spectatee);
1839         STAT(HUD, this) = STAT(HUD, spectatee);
1840         if(spectatee.vehicle)
1841     {
1842         this.angles = spectatee.v_angle;
1843
1844         //this.fixangle = false;
1845         //this.velocity = spectatee.vehicle.velocity;
1846         this.vehicle_health = spectatee.vehicle_health;
1847         this.vehicle_shield = spectatee.vehicle_shield;
1848         this.vehicle_energy = spectatee.vehicle_energy;
1849         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1850         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1851         this.vehicle_reload1 = spectatee.vehicle_reload1;
1852         this.vehicle_reload2 = spectatee.vehicle_reload2;
1853
1854         //msg_entity = this;
1855
1856        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1857             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1858            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1859            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1860
1861         //WriteByte (MSG_ONE, SVC_SETVIEW);
1862         //    WriteEntity(MSG_ONE, this);
1863         //makevectors(spectatee.v_angle);
1864         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1865     }
1866 }
1867
1868 bool SpectateUpdate(entity this)
1869 {
1870         if(!this.enemy)
1871                 return false;
1872
1873         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1874         {
1875                 SetSpectatee(this, NULL);
1876                 return false;
1877         }
1878
1879         SpectateCopy(this, this.enemy);
1880
1881         return true;
1882 }
1883
1884 bool SpectateSet(entity this)
1885 {
1886         if(!IS_PLAYER(this.enemy))
1887                 return false;
1888
1889         ClientData_Touch(this.enemy);
1890
1891         msg_entity = this;
1892         WriteByte(MSG_ONE, SVC_SETVIEW);
1893         WriteEntity(MSG_ONE, this.enemy);
1894         set_movetype(this, MOVETYPE_NONE);
1895         accuracy_resend(this);
1896
1897         if(!SpectateUpdate(this))
1898                 PutObserverInServer(this);
1899
1900         return true;
1901 }
1902
1903 void SetSpectatee_status(entity this, int spectatee_num)
1904 {
1905         int oldspectatee_status = CS(this).spectatee_status;
1906         CS(this).spectatee_status = spectatee_num;
1907
1908         if (CS(this).spectatee_status != oldspectatee_status)
1909         {
1910                 if (STAT(PRESSED_KEYS, this))
1911                 {
1912                         CS(this).pressedkeys = 0;
1913                         STAT(PRESSED_KEYS, this) = 0;
1914                 }
1915                 ClientData_Touch(this);
1916                 if (g_race || g_cts) race_InitSpectator();
1917         }
1918 }
1919
1920 void SetSpectatee(entity this, entity spectatee)
1921 {
1922         if(IS_BOT_CLIENT(this))
1923                 return; // bots abuse .enemy, this code is useless to them
1924
1925         entity old_spectatee = this.enemy;
1926
1927         this.enemy = spectatee;
1928
1929         // WEAPONTODO
1930         // these are required to fix the spectator bug with arc
1931         if(old_spectatee)
1932         {
1933                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1934                 {
1935                         .entity weaponentity = weaponentities[slot];
1936                         if(old_spectatee.(weaponentity).arc_beam)
1937                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1938                 }
1939         }
1940         if(this.enemy)
1941         {
1942                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1943                 {
1944                         .entity weaponentity = weaponentities[slot];
1945                         if(this.enemy.(weaponentity).arc_beam)
1946                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1947                 }
1948         }
1949
1950         if (this.enemy)
1951                 SetSpectatee_status(this, etof(this.enemy));
1952
1953         // needed to update spectator list
1954         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1955 }
1956
1957 bool Spectate(entity this, entity pl)
1958 {
1959         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1960                 return false;
1961         pl = M_ARGV(1, entity);
1962
1963         SetSpectatee(this, pl);
1964         return SpectateSet(this);
1965 }
1966
1967 bool SpectateNext(entity this)
1968 {
1969         entity ent = find(this.enemy, classname, STR_PLAYER);
1970
1971         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1972                 ent = M_ARGV(1, entity);
1973         else if (!ent)
1974                 ent = find(ent, classname, STR_PLAYER);
1975
1976         if(ent) { SetSpectatee(this, ent); }
1977
1978         return SpectateSet(this);
1979 }
1980
1981 bool SpectatePrev(entity this)
1982 {
1983         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1984         entity ent = findchain(classname, STR_PLAYER);
1985         if (!ent) // no player
1986                 return false;
1987
1988         entity first = ent;
1989         // skip players until current spectated player
1990         if(this.enemy)
1991         while(ent && ent != this.enemy)
1992                 ent = ent.chain;
1993
1994         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1995         {
1996                 case MUT_SPECPREV_FOUND:
1997                     ent = M_ARGV(1, entity);
1998                     break;
1999                 case MUT_SPECPREV_RETURN:
2000                     return true;
2001                 case MUT_SPECPREV_CONTINUE:
2002                 default:
2003                 {
2004                         if(ent.chain)
2005                                 ent = ent.chain;
2006                         else
2007                                 ent = first;
2008                         break;
2009                 }
2010         }
2011
2012         SetSpectatee(this, ent);
2013         return SpectateSet(this);
2014 }
2015
2016 /*
2017 =============
2018 ShowRespawnCountdown()
2019
2020 Update a respawn countdown display.
2021 =============
2022 */
2023 void ShowRespawnCountdown(entity this)
2024 {
2025         float number;
2026         if(!IS_DEAD(this)) // just respawned?
2027                 return;
2028         else
2029         {
2030                 number = ceil(this.respawn_time - time);
2031                 if(number <= 0)
2032                         return;
2033                 if(number <= this.respawn_countdown)
2034                 {
2035                         this.respawn_countdown = number - 1;
2036                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2037                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2038                 }
2039         }
2040 }
2041
2042 .bool team_selected;
2043 bool ShowTeamSelection(entity this)
2044 {
2045         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
2046                 return false;
2047         stuffcmd(this, "menu_showteamselect\n");
2048         return true;
2049 }
2050 void Join(entity this)
2051 {
2052         TRANSMUTE(Player, this);
2053
2054         if(!this.team_selected)
2055         if(autocvar_g_campaign || autocvar_g_balance_teams)
2056                 TeamBalance_JoinBestTeam(this);
2057
2058         if(autocvar_g_campaign)
2059                 campaign_bots_may_start = true;
2060
2061         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2062
2063         PutClientInServer(this);
2064
2065         if(IS_PLAYER(this))
2066         if(teamplay && this.team != -1)
2067         {
2068         }
2069         else
2070                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2071         this.team_selected = false;
2072 }
2073
2074 int GetPlayerLimit()
2075 {
2076         if(g_duel)
2077                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2078         int player_limit = autocvar_g_maxplayers;
2079         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2080         player_limit = M_ARGV(0, int);
2081         return player_limit;
2082 }
2083
2084 /**
2085  * Determines whether the player is allowed to join. This depends on cvar
2086  * g_maxplayers, if it isn't used this function always return true, otherwise
2087  * it checks whether the number of currently playing players exceeds g_maxplayers.
2088  * @return int number of free slots for players, 0 if none
2089  */
2090 int nJoinAllowed(entity this, entity ignore)
2091 {
2092         if(!ignore)
2093         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2094         // so report 0 free slots if restricted
2095         {
2096                 if(autocvar_g_forced_team_otherwise == "spectate")
2097                         return 0;
2098                 if(autocvar_g_forced_team_otherwise == "spectator")
2099                         return 0;
2100         }
2101
2102         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2103                 return 0; // forced spectators can never join
2104
2105         // TODO simplify this
2106         int totalClients = 0;
2107         int currentlyPlaying = 0;
2108         FOREACH_CLIENT(true, {
2109                 if(it != ignore)
2110                         ++totalClients;
2111                 if(IS_REAL_CLIENT(it))
2112                 if(IS_PLAYER(it) || it.caplayer)
2113                         ++currentlyPlaying;
2114         });
2115
2116         int player_limit = GetPlayerLimit();
2117
2118         int free_slots = 0;
2119         if (!player_limit)
2120                 free_slots = maxclients - totalClients;
2121         else if(player_limit > 0 && currentlyPlaying < player_limit)
2122                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2123
2124         static float msg_time = 0;
2125         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2126         {
2127                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2128                 msg_time = time + 0.5;
2129         }
2130
2131         return free_slots;
2132 }
2133
2134 /**
2135  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2136  * g_maxplayers_spectator_blocktime seconds
2137  */
2138 void checkSpectatorBlock(entity this)
2139 {
2140         if(IS_SPEC(this) || IS_OBSERVER(this))
2141         if(!this.caplayer)
2142         if(IS_REAL_CLIENT(this))
2143         {
2144                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2145                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2146                         dropclient(this);
2147                 }
2148         }
2149 }
2150
2151 void PrintWelcomeMessage(entity this)
2152 {
2153         if(CS(this).motd_actived_time == 0)
2154         {
2155                 if (autocvar_g_campaign) {
2156                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2157                                 CS(this).motd_actived_time = time;
2158                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2159                         }
2160                 } else {
2161                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2162                                 CS(this).motd_actived_time = time;
2163                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2164                         }
2165                 }
2166         }
2167         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2168         {
2169                 if (autocvar_g_campaign) {
2170                         if (PHYS_INPUT_BUTTON_INFO(this))
2171                                 CS(this).motd_actived_time = time;
2172                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2173                                 CS(this).motd_actived_time = 0;
2174                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2175                         }
2176                 } else {
2177                         if (PHYS_INPUT_BUTTON_INFO(this))
2178                                 CS(this).motd_actived_time = time;
2179                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2180                                 CS(this).motd_actived_time = 0;
2181                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2182                         }
2183                 }
2184         }
2185         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2186         {
2187                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2188                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2189                 else if (CS(this).motd_actived_time == -2)
2190                 {
2191                         // instantly hide MOTD
2192                         CS(this).motd_actived_time = 0;
2193                         if (autocvar_g_campaign)
2194                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2195                         else
2196                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2197                 }
2198                 else if (IS_PLAYER(this) || IS_SPEC(this))
2199                 {
2200                         // FIXME occasionally for some reason MOTD never goes away
2201                         // delay MOTD removal a little bit in the hope it fixes this bug
2202                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2203                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2204                         else //if (CS(this).motd_actived_time < -2)
2205                                 CS(this).motd_actived_time++;
2206                 }
2207         }
2208 }
2209
2210 bool joinAllowed(entity this)
2211 {
2212         if (CS(this).version_mismatch) return false;
2213         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2214         if (!nJoinAllowed(this, this)) return false;
2215         if (teamplay && lockteams) return false;
2216         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2217         if (ShowTeamSelection(this)) return false;
2218         return true;
2219 }
2220
2221 .string shootfromfixedorigin;
2222 .bool dualwielding_prev;
2223 bool PlayerThink(entity this)
2224 {
2225         if (game_stopped || intermission_running) {
2226                 this.modelflags &= ~MF_ROCKET;
2227                 if(intermission_running)
2228                         IntermissionThink(this);
2229                 return false;
2230         }
2231
2232         if (timeout_status == TIMEOUT_ACTIVE) {
2233         // don't allow the player to turn around while game is paused
2234                 // FIXME turn this into CSQC stuff
2235                 this.v_angle = this.lastV_angle;
2236                 this.angles = this.lastV_angle;
2237                 this.fixangle = true;
2238         }
2239
2240         if (frametime) player_powerups(this);
2241
2242         if (IS_DEAD(this)) {
2243                 if (this.personal && g_race_qualifying) {
2244                         if (time > this.respawn_time) {
2245                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2246                                 respawn(this);
2247                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2248                         }
2249                 } else {
2250                         if (frametime) player_anim(this);
2251
2252                         if (this.respawn_flags & RESPAWN_DENY)
2253                         {
2254                                 STAT(RESPAWN_TIME, this) = 0;
2255                                 return false;
2256                         }
2257
2258                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2259
2260                         switch(this.deadflag)
2261                         {
2262                                 case DEAD_DYING:
2263                                 {
2264                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2265                                                 this.deadflag = DEAD_RESPAWNING;
2266                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2267                                                 this.deadflag = DEAD_DEAD;
2268                                         break;
2269                                 }
2270                                 case DEAD_DEAD:
2271                                 {
2272                                         if (button_pressed)
2273                                                 this.deadflag = DEAD_RESPAWNABLE;
2274                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2275                                                 this.deadflag = DEAD_RESPAWNING;
2276                                         break;
2277                                 }
2278                                 case DEAD_RESPAWNABLE:
2279                                 {
2280                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2281                                                 this.deadflag = DEAD_RESPAWNING;
2282                                         break;
2283                                 }
2284                                 case DEAD_RESPAWNING:
2285                                 {
2286                                         if (time > this.respawn_time)
2287                                         {
2288                                                 this.respawn_time = time + 1; // only retry once a second
2289                                                 this.respawn_time_max = this.respawn_time;
2290                                                 respawn(this);
2291                                         }
2292                                         break;
2293                                 }
2294                         }
2295
2296                         ShowRespawnCountdown(this);
2297
2298                         if (this.respawn_flags & RESPAWN_SILENT)
2299                                 STAT(RESPAWN_TIME, this) = 0;
2300                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2301                         {
2302                                 if (time < this.respawn_time)
2303                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2304                                 else if (this.deadflag != DEAD_RESPAWNING)
2305                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2306                         }
2307                         else
2308                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2309                 }
2310
2311                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2312                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2313                         STAT(RESPAWN_TIME, this) *= -1;
2314
2315                 return false;
2316         }
2317
2318         FixPlayermodel(this);
2319
2320         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2321                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2322                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2323         }
2324
2325         // reset gun alignment when dual wielding status changes
2326         // to ensure guns are always aligned right and left
2327         bool dualwielding = W_DualWielding(this);
2328         if(this.dualwielding_prev != dualwielding)
2329         {
2330                 W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
2331                 this.dualwielding_prev = dualwielding;
2332         }
2333
2334         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2335         //if(frametime)
2336         {
2337                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2338                 {
2339                         .entity weaponentity = weaponentities[slot];
2340                         if(WEP_CVAR(vortex, charge_always))
2341                                 W_Vortex_Charge(this, weaponentity, frametime);
2342                         W_WeaponFrame(this, weaponentity);
2343                 }
2344         }
2345
2346         if (frametime)
2347         {
2348                 // WEAPONTODO: Add a weapon request for this
2349                 // rot vortex charge to the charge limit
2350                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2351                 {
2352                         .entity weaponentity = weaponentities[slot];
2353                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2354                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2355                 }
2356
2357                 player_regen(this);
2358                 player_anim(this);
2359                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2360         }
2361
2362         monsters_setstatus(this);
2363
2364         return true;
2365 }
2366
2367 .bool would_spectate;
2368 void ObserverOrSpectatorThink(entity this)
2369 {
2370         bool is_spec = IS_SPEC(this);
2371         if ( CS(this).impulse )
2372         {
2373                 int r = MinigameImpulse(this, CS(this).impulse);
2374                 if (!is_spec || r)
2375                         CS(this).impulse = 0;
2376
2377                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2378                 {
2379                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2380                         CS(this).impulse = 0;
2381                         return;
2382                 }
2383         }
2384
2385         if (this.flags & FL_JUMPRELEASED) {
2386                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2387                         this.flags &= ~FL_JUMPRELEASED;
2388                         this.flags |= FL_SPAWNING;
2389                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2390                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2391                         this.flags &= ~FL_JUMPRELEASED;
2392                         if(SpectateNext(this)) {
2393                                 TRANSMUTE(Spectator, this);
2394                         } else if (is_spec) {
2395                                 TRANSMUTE(Observer, this);
2396                                 PutClientInServer(this);
2397                         }
2398                         if (is_spec)
2399                                 CS(this).impulse = 0;
2400                 } else if (is_spec) {
2401                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2402                                 this.flags &= ~FL_JUMPRELEASED;
2403                                 if(SpectatePrev(this)) {
2404                                         TRANSMUTE(Spectator, this);
2405                                 } else {
2406                                         TRANSMUTE(Observer, this);
2407                                         PutClientInServer(this);
2408                                 }
2409                                 CS(this).impulse = 0;
2410                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2411                                 this.would_spectate = false;
2412                                 this.flags &= ~FL_JUMPRELEASED;
2413                                 TRANSMUTE(Observer, this);
2414                                 PutClientInServer(this);
2415                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2416                                 PutObserverInServer(this);
2417                                 this.would_spectate = true;
2418                         }
2419                 }
2420                 else {
2421                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2422                         set_movetype(this, preferred_movetype);
2423                 }
2424         } else {
2425                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2426                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2427                         this.flags |= FL_JUMPRELEASED;
2428                         if(this.flags & FL_SPAWNING)
2429                         {
2430                                 this.flags &= ~FL_SPAWNING;
2431                                 if(joinAllowed(this))
2432                                         Join(this);
2433                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2434                                         CS(this).autojoin_checked = -1;
2435                                 return;
2436                         }
2437                 }
2438                 if(is_spec && !SpectateUpdate(this))
2439                         PutObserverInServer(this);
2440         }
2441         if (is_spec)
2442                 this.flags |= FL_CLIENT | FL_NOTARGET;
2443 }
2444
2445 void PlayerUseKey(entity this)
2446 {
2447         if (!IS_PLAYER(this))
2448                 return;
2449
2450         if(this.vehicle)
2451         {
2452                 if(!game_stopped)
2453                 {
2454                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2455                         return;
2456                 }
2457         }
2458         else if(autocvar_g_vehicles_enter)
2459         {
2460                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2461                 {
2462                         entity head, closest_target = NULL;
2463                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2464
2465                         while(head) // find the closest acceptable target to enter
2466                         {
2467                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2468                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2469                                 {
2470                                         if(closest_target)
2471                                         {
2472                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2473                                                 { closest_target = head; }
2474                                         }
2475                                         else { closest_target = head; }
2476                                 }
2477
2478                                 head = head.chain;
2479                         }
2480
2481                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2482                 }
2483         }
2484
2485         // a use key was pressed; call handlers
2486         MUTATOR_CALLHOOK(PlayerUseKey, this);
2487 }
2488
2489
2490 /*
2491 =============
2492 PlayerPreThink
2493
2494 Called every frame for each client before the physics are run
2495 =============
2496 */
2497 .float last_vehiclecheck;
2498 void PlayerPreThink (entity this)
2499 {
2500         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2501         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2502
2503         WarpZone_PlayerPhysics_FixVAngle(this);
2504
2505         if (frametime) {
2506                 // physics frames: update anticheat stuff
2507                 anticheat_prethink(this);
2508         }
2509
2510         if (blockSpectators && frametime) {
2511                 // WORKAROUND: only use dropclient in server frames (frametime set).
2512                 // Never use it in cl_movement frames (frametime zero).
2513                 checkSpectatorBlock(this);
2514         }
2515
2516         zoomstate_set = false;
2517
2518         // Check for nameless players
2519         if (this.netname == "" || this.netname != CS(this).netname_previous)
2520         {
2521                 bool assume_unchanged = (CS(this).netname_previous == "");
2522                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2523                 {
2524                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2525                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2526                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2527                         assume_unchanged = false;
2528                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2529                 }
2530                 if (isInvisibleString(this.netname))
2531                 {
2532                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2533                         sprint(this, "Warning: invisible names are not allowed.\n");
2534                         assume_unchanged = false;
2535                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2536                 }
2537                 if (!assume_unchanged && autocvar_sv_eventlog)
2538                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2539                 strcpy(CS(this).netname_previous, this.netname);
2540         }
2541
2542         // version nagging
2543         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2544         CS(this).version_nagtime = 0;
2545         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2546             // git client
2547         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2548             // git server
2549             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2550         } else {
2551             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2552             if (r < 0) { // old client
2553                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2554             } else if (r > 0) { // old server
2555                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2556             }
2557         }
2558     }
2559
2560         // GOD MODE info
2561         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2562         {
2563                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2564                 this.max_armorvalue = 0;
2565         }
2566
2567         if (frametime && IS_PLAYER(this))
2568         {
2569                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2570                 {
2571                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2572                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2573                         if (this.iceblock)
2574                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2575
2576                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2577                                 Unfreeze(this, false);
2578                 }
2579                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2580                 {
2581                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2582                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2583
2584                         if (GetResource(this, RES_HEALTH) < 1)
2585                         {
2586                                 if (this.vehicle)
2587                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2588                                 if(this.event_damage)
2589                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2590                         }
2591                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2592                                 Unfreeze(this, false);
2593                 }
2594         }
2595
2596         MUTATOR_CALLHOOK(PlayerPreThink, this);
2597
2598         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2599         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2600         {
2601                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2602                 {
2603                         if(!it.owner)
2604                         {
2605                                 if(!it.team || SAME_TEAM(this, it))
2606                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2607                                 else if(autocvar_g_vehicles_steal)
2608                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2609                         }
2610                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2611                         {
2612                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2613                         }
2614                 });
2615
2616                 this.last_vehiclecheck = time + 1;
2617         }
2618
2619         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2620         {
2621                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2622                         PlayerUseKey(this);
2623                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2624         }
2625
2626         if (IS_REAL_CLIENT(this))
2627                 PrintWelcomeMessage(this);
2628
2629         if (IS_PLAYER(this)) {
2630                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2631                         error("Client can't be spawned as player on connection!");
2632                 if(!PlayerThink(this))
2633                         return;
2634         }
2635         else if (game_stopped || intermission_running) {
2636                 if(intermission_running)
2637                         IntermissionThink(this);
2638                 return;
2639         }
2640         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2641         {
2642                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2643                 CS(this).autojoin_checked = 1;
2644                 // don't do this in ClientConnect
2645                 // many things can go wrong if a client is spawned as player on connection
2646                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2647                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2648                                 && (!teamplay || autocvar_g_balance_teams)))
2649                 {
2650                         campaign_bots_may_start = true;
2651                         if(joinAllowed(this))
2652                                 Join(this);
2653                         return;
2654                 }
2655         }
2656         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2657                 ObserverOrSpectatorThink(this);
2658         }
2659
2660         // WEAPONTODO: Add weapon request for this
2661         if (!zoomstate_set) {
2662                 bool wep_zoomed = false;
2663                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2664                 {
2665                         .entity weaponentity = weaponentities[slot];
2666                         Weapon thiswep = this.(weaponentity).m_weapon;
2667                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2668                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2669                 }
2670                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2671         }
2672
2673         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2674         {
2675                 CS(this).teamkill_soundtime = 0;
2676
2677                 entity e = CS(this).teamkill_soundsource;
2678                 entity oldpusher = e.pusher;
2679                 e.pusher = this;
2680                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2681                 e.pusher = oldpusher;
2682         }
2683
2684         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2685                 CS(this).taunt_soundtime = 0;
2686                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2687         }
2688
2689         target_voicescript_next(this);
2690
2691         // WEAPONTODO: Move into weaponsystem somehow
2692         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2693         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2694         {
2695                 .entity weaponentity = weaponentities[slot];
2696                 if(this.(weaponentity).m_weapon == WEP_Null)
2697                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2698         }
2699 }
2700
2701 void DrownPlayer(entity this)
2702 {
2703         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2704                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2705         {
2706                 STAT(AIR_FINISHED, this) = 0;
2707                 return;
2708         }
2709
2710         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2711         {
2712                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2713                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2714                 STAT(AIR_FINISHED, this) = 0;
2715         }
2716         else
2717         {
2718                 if (!STAT(AIR_FINISHED, this))
2719                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2720                 if (STAT(AIR_FINISHED, this) < time)
2721                 {       // drown!
2722                         if (this.pain_finished < time)
2723                         {
2724                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2725                                 this.pain_finished = time + 0.5;
2726                         }
2727                 }
2728         }
2729 }
2730
2731 .bool move_qcphysics;
2732
2733 void Player_Physics(entity this)
2734 {
2735         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2736
2737         if(!this.move_qcphysics)
2738                 return;
2739
2740         if(!frametime && !CS(this).pm_frametime)
2741                 return;
2742
2743         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2744
2745         CS(this).pm_frametime = 0;
2746 }
2747
2748 /*
2749 =============
2750 PlayerPostThink
2751
2752 Called every frame for each client after the physics are run
2753 =============
2754 */
2755 void PlayerPostThink (entity this)
2756 {
2757         Player_Physics(this);
2758
2759         if (sv_maxidle > 0)
2760         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2761         if (IS_REAL_CLIENT(this))
2762         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2763         {
2764                 int totalClients = 0;
2765                 if(sv_maxidle_slots > 0)
2766                 {
2767                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2768                         {
2769                                 ++totalClients;
2770                         });
2771                 }
2772
2773                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2774                 { /* do nothing */ }
2775                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2776                 {
2777                         if (CS(this).idlekick_lasttimeleft)
2778                         {
2779                                 CS(this).idlekick_lasttimeleft = 0;
2780                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2781                         }
2782                 }
2783                 else
2784                 {
2785                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2786                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2787                                 if (!CS(this).idlekick_lasttimeleft)
2788                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2789                         }
2790                         if (timeleft <= 0) {
2791                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2792                                 dropclient(this);
2793                                 return;
2794                         }
2795                         else if (timeleft <= 10) {
2796                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2797                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2798                 }
2799                                 CS(this).idlekick_lasttimeleft = timeleft;
2800                         }
2801                 }
2802         }
2803
2804         CheatFrame(this);
2805
2806         if (game_stopped)
2807         {
2808                 this.solid = SOLID_NOT;
2809                 this.takedamage = DAMAGE_NO;
2810                 set_movetype(this, MOVETYPE_NONE);
2811                 CS(this).teamkill_complain = 0;
2812                 CS(this).teamkill_soundtime = 0;
2813                 CS(this).teamkill_soundsource = NULL;
2814         }
2815
2816         if (IS_PLAYER(this)) {
2817                 if(this.death_time == time && IS_DEAD(this))
2818                 {
2819                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2820                         // once all the damage events of this frame have been processed with normal size
2821                         this.maxs.z = 5;
2822                         setsize(this, this.mins, this.maxs);
2823                 }
2824                 DrownPlayer(this);
2825                 UpdateChatBubble(this);
2826                 if (CS(this).impulse) ImpulseCommands(this);
2827                 if (game_stopped)
2828                 {
2829                         CSQCMODEL_AUTOUPDATE(this);
2830                         return;
2831                 }
2832                 GetPressedKeys(this);
2833         }
2834         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2835         {
2836                 CS(this).pressedkeys = 0;
2837                 STAT(PRESSED_KEYS, this) = 0;
2838         }
2839
2840         if (this.waypointsprite_attachedforcarrier) {
2841                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2842                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2843         }
2844
2845         CSQCMODEL_AUTOUPDATE(this);
2846 }
2847
2848 /**
2849  * message "": do not say, just test flood control
2850  * return value:
2851  *   1 = accept
2852  *   0 = reject
2853  *  -1 = fake accept
2854  */
2855 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
2856 {
2857         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
2858                 msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
2859
2860         if (source)
2861                 msgin = formatmessage(source, msgin);
2862
2863         string colorstr;
2864         if (!(IS_PLAYER(source) || source.caplayer))
2865                 colorstr = "^0"; // black for spectators
2866         else if(teamplay)
2867                 colorstr = Team_ColorCode(source.team);
2868         else
2869         {
2870                 colorstr = "";
2871                 teamsay = false;
2872         }
2873
2874         if (!source) {
2875                 colorstr = "";
2876                 teamsay = false;
2877         }
2878
2879         if(msgin != "")
2880                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
2881
2882         /*
2883          * using bprint solves this... me stupid
2884         // how can we prevent the message from appearing in a listen server?
2885         // for now, just give "say" back and only handle say_team
2886         if(!teamsay)
2887         {
2888                 clientcommand(source, strcat("say ", msgin));
2889                 return;
2890         }
2891         */
2892
2893         string namestr = "";
2894         if (source)
2895                 namestr = playername(source, autocvar_g_chat_teamcolors);
2896
2897         string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
2898
2899         string msgstr = "", cmsgstr = "";
2900         string privatemsgprefix = string_null;
2901         int privatemsgprefixlen = 0;
2902         if (msgin != "")
2903         {
2904                 bool found_me = false;
2905                 if(strstrofs(msgin, "/me", 0) >= 0)
2906                 {
2907                         string newmsgin = "";
2908                         string newnamestr = ((teamsay) ? strcat(colorstr, "(", colorprefix, namestr, colorstr, ")", "^7") : strcat(colorprefix, namestr, "^7"));
2909                         FOREACH_WORD(msgin, true,
2910                         {
2911                                 if(strdecolorize(it) == "/me")
2912                                 {
2913                                         found_me = true;
2914                                         newmsgin = cons(newmsgin, newnamestr);
2915                                 }
2916                                 else
2917                                         newmsgin = cons(newmsgin, it);
2918                         });
2919                         msgin = newmsgin;
2920                 }
2921
2922                 if(privatesay)
2923                 {
2924                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
2925                         privatemsgprefixlen = strlen(msgstr);
2926                         msgstr = strcat(msgstr, msgin);
2927                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
2928                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
2929                 }
2930                 else if(teamsay)
2931                 {
2932                         if(found_me)
2933                         {
2934                                 //msgin = strreplace("/me", "", msgin);
2935                                 //msgin = substring(msgin, 3, strlen(msgin));
2936                                 //msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
2937                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
2938                         }
2939                         else
2940                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
2941                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
2942                 }
2943                 else
2944                 {
2945                         if(found_me)
2946                         {
2947                                 //msgin = strreplace("/me", "", msgin);
2948                                 //msgin = substring(msgin, 3, strlen(msgin));
2949                                 //msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
2950                                 msgstr = strcat("\{1}^4* ^7", msgin);
2951                         }
2952                         else {
2953                                 msgstr = "\{1}";
2954                                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
2955                                 msgstr = strcat(msgstr, msgin);
2956                         }
2957                         cmsgstr = "";
2958                 }
2959                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
2960         }
2961
2962         string fullmsgstr = msgstr;
2963         string fullcmsgstr = cmsgstr;
2964
2965         // FLOOD CONTROL
2966         int flood = 0;
2967         var .float flood_field = floodcontrol_chat;
2968         if(floodcontrol && source)
2969         {
2970                 float flood_spl, flood_burst, flood_lmax;
2971                 if(privatesay)
2972                 {
2973                         flood_spl = autocvar_g_chat_flood_spl_tell;
2974                         flood_burst = autocvar_g_chat_flood_burst_tell;
2975                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
2976                         flood_field = floodcontrol_chattell;
2977                 }
2978                 else if(teamsay)
2979                 {
2980                         flood_spl = autocvar_g_chat_flood_spl_team;
2981                         flood_burst = autocvar_g_chat_flood_burst_team;
2982                         flood_lmax = autocvar_g_chat_flood_lmax_team;
2983                         flood_field = floodcontrol_chatteam;
2984                 }
2985                 else
2986                 {
2987                         flood_spl = autocvar_g_chat_flood_spl;
2988                         flood_burst = autocvar_g_chat_flood_burst;
2989                         flood_lmax = autocvar_g_chat_flood_lmax;
2990                         flood_field = floodcontrol_chat;
2991                 }
2992                 flood_burst = max(0, flood_burst - 1);
2993                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
2994
2995                 // do flood control for the default line size
2996                 if(msgstr != "")
2997                 {
2998                         getWrappedLine_remaining = msgstr;
2999                         msgstr = "";
3000                         int lines = 0;
3001                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
3002                         {
3003                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
3004                                 ++lines;
3005                         }
3006                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
3007
3008                         if(getWrappedLine_remaining != "")
3009                         {
3010                                 msgstr = strcat(msgstr, "\n");
3011                                 flood = 2;
3012                         }
3013
3014                         if (time >= source.(flood_field))
3015                         {
3016                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
3017                         }
3018                         else
3019                         {
3020                                 flood = 1;
3021                                 msgstr = fullmsgstr;
3022                         }
3023                 }
3024                 else
3025                 {
3026                         if (time >= source.(flood_field))
3027                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
3028                         else
3029                                 flood = 1;
3030                 }
3031
3032                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
3033                         source.(flood_field) = flood = 0;
3034         }
3035
3036         string sourcemsgstr, sourcecmsgstr;
3037         if(flood == 2) // cannot happen for empty msgstr
3038         {
3039                 if(autocvar_g_chat_flood_notify_flooder)
3040                 {
3041                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
3042                         sourcecmsgstr = "";
3043                 }
3044                 else
3045                 {
3046                         sourcemsgstr = fullmsgstr;
3047                         sourcecmsgstr = fullcmsgstr;
3048                 }
3049                 cmsgstr = "";
3050         }
3051         else
3052         {
3053                 sourcemsgstr = msgstr;
3054                 sourcecmsgstr = cmsgstr;
3055         }
3056
3057         if (!privatesay && source && !(IS_PLAYER(source) || source.caplayer) && !game_stopped
3058                 && (teamsay || CHAT_NOSPECTATORS()))
3059         {
3060                 teamsay = -1; // spectators
3061         }
3062
3063         if(flood)
3064                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
3065
3066         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
3067         if(privatesay)
3068                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
3069
3070         int ret;
3071         if(source && CS(source).muted)
3072         {
3073                 // always fake the message
3074                 ret = -1;
3075         }
3076         else if(flood == 1)
3077         {
3078                 if (autocvar_g_chat_flood_notify_flooder)
3079                 {
3080                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
3081                         ret = 0;
3082                 }
3083                 else
3084                         ret = -1;
3085         }
3086         else
3087         {
3088                 ret = 1;
3089         }
3090
3091         if (privatesay && source && !(IS_PLAYER(source) || source.caplayer) && !game_stopped
3092                 && (IS_PLAYER(privatesay) || privatesay.caplayer) && CHAT_NOSPECTATORS())
3093         {
3094                 ret = -1; // just hide the message completely
3095         }
3096
3097         MUTATOR_CALLHOOK(ChatMessage, source, ret);
3098         ret = M_ARGV(1, int);
3099
3100         string event_log_msg = "";
3101
3102         if(sourcemsgstr != "" && ret != 0)
3103         {
3104                 if(ret < 0) // faked message, because the player is muted
3105                 {
3106                         sprint(source, sourcemsgstr);
3107                         if(sourcecmsgstr != "" && !privatesay)
3108                                 centerprint(source, sourcecmsgstr);
3109                 }
3110                 else if(privatesay) // private message, between 2 people only
3111                 {
3112                         sprint(source, sourcemsgstr);
3113                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
3114                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
3115                         {
3116                                 sprint(privatesay, msgstr);
3117                                 if(cmsgstr != "")
3118                                         centerprint(privatesay, cmsgstr);
3119                         }
3120                 }
3121                 else if ( teamsay && CS(source).active_minigame )
3122                 {
3123                         sprint(source, sourcemsgstr);
3124                         dedicated_print(msgstr); // send to server console too
3125                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3126                                 sprint(it, msgstr);
3127                         });
3128                         event_log_msg = sprintf(":chat_minigame:%d:%s:%s", source.playerid, CS(source).active_minigame.netname, msgin);
3129
3130                 }
3131                 else if(teamsay > 0) // team message, only sent to team mates
3132                 {
3133                         sprint(source, sourcemsgstr);
3134                         dedicated_print(msgstr); // send to server console too
3135                         if(sourcecmsgstr != "")
3136                                 centerprint(source, sourcecmsgstr);
3137                         FOREACH_CLIENT((IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3138                                 sprint(it, msgstr);
3139                                 if(cmsgstr != "")
3140                                         centerprint(it, cmsgstr);
3141                         });
3142                         event_log_msg = sprintf(":chat_team:%d:%d:%s", source.playerid, source.team, strreplace("\n", " ", msgin));
3143                 }
3144                 else if(teamsay < 0) // spectator message, only sent to spectators
3145                 {
3146                         sprint(source, sourcemsgstr);
3147                         dedicated_print(msgstr); // send to server console too
3148                         FOREACH_CLIENT(!(IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3149                                 sprint(it, msgstr);
3150                         });
3151                         event_log_msg = sprintf(":chat_spec:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3152                 }
3153                 else
3154                 {
3155                         if (source) {
3156                                 sprint(source, sourcemsgstr);
3157                                 dedicated_print(msgstr); // send to server console too
3158                                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
3159                         }
3160                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3161                                 sprint(it, msgstr);
3162                         });
3163                         event_log_msg = sprintf(":chat:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3164                 }
3165         }
3166
3167         if (autocvar_sv_eventlog && (event_log_msg != "")) {
3168                 GameLogEcho(event_log_msg);
3169         }
3170
3171         return ret;
3172 }
3173
3174 // hack to copy the button fields from the client entity to the Client State
3175 void PM_UpdateButtons(entity this, entity store)
3176 {
3177         if(this.impulse)
3178                 store.impulse = this.impulse;
3179         this.impulse = 0;
3180
3181         bool typing = this.buttonchat || this.button12;
3182
3183         store.button0 = (typing) ? 0 : this.button0;
3184         //button1?!
3185         store.button2 = (typing) ? 0 : this.button2;
3186         store.button3 = (typing) ? 0 : this.button3;
3187         store.button4 = this.button4;
3188         store.button5 = (typing) ? 0 : this.button5;
3189         store.button6 = this.button6;
3190         store.button7 = this.button7;
3191         store.button8 = this.button8;
3192         store.button9 = this.button9;
3193         store.button10 = this.button10;
3194         store.button11 = this.button11;
3195         store.button12 = this.button12;
3196         store.button13 = this.button13;
3197         store.button14 = this.button14;
3198         store.button15 = this.button15;
3199         store.button16 = this.button16;
3200         store.buttonuse = this.buttonuse;
3201         store.buttonchat = this.buttonchat;
3202
3203         store.cursor_active = this.cursor_active;
3204         store.cursor_screen = this.cursor_screen;
3205         store.cursor_trace_start = this.cursor_trace_start;
3206         store.cursor_trace_endpos = this.cursor_trace_endpos;
3207         store.cursor_trace_ent = this.cursor_trace_ent;
3208
3209         store.ping = this.ping;
3210         store.ping_packetloss = this.ping_packetloss;
3211         store.ping_movementloss = this.ping_movementloss;
3212
3213         store.v_angle = this.v_angle;
3214         store.movement = this.movement;
3215 }
3216
3217 NET_HANDLE(fpsreport, bool)
3218 {
3219         int fps = ReadShort();
3220         PlayerScore_Set(sender, SP_FPS, fps);
3221         return true;
3222 }