qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/status_effects/_mod.qh>
  27 #include <common/mutators/mutator/waypoints/all.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/notifications/all.qh>
  31 #include <common/physics/player.qh>
  32 #include <common/playerstats.qh>
  33 #include <common/resources/sv_resources.qh>
  34 #include <common/state.qh>
  35 #include <common/stats.qh>
  36 #include <common/vehicles/all.qh>
  37 #include <common/vehicles/sv_vehicles.qh>
  38 #include <common/viewloc.qh>
  39 #include <common/weapons/_all.qh>
  40 #include <common/weapons/weapon/vortex.qh>
  41 #include <common/wepent.qh>
  42 #include <lib/csqcmodel/sv_model.qh>
  43 #include <lib/warpzone/common.qh>
  44 #include <lib/warpzone/server.qh>
  45 #include <server/anticheat.qh>
  46 #include <server/antilag.qh>
  47 #include <server/bot/api.qh>
  48 #include <server/bot/default/cvars.qh>
  49 #include <server/bot/default/waypoints.qh>
  50 #include <server/campaign.qh>
  51 #include <server/chat.qh>
  52 #include <server/cheats.qh>
  53 #include <server/clientkill.qh>
  54 #include <server/command/common.qh>
  55 #include <server/command/common.qh>
  56 #include <server/command/vote.qh>
  57 #include <server/compat/quake3.qh>
  58 #include <server/damage.qh>
  59 #include <server/gamelog.qh>
  60 #include <server/handicap.qh>
  61 #include <server/hook.qh>
  62 #include <server/impulse.qh>
  63 #include <server/intermission.qh>
  64 #include <server/ipban.qh>
  65 #include <server/main.qh>
  66 #include <server/mutators/_mod.qh>
  67 #include <server/player.qh>
  68 #include <server/portals.qh>
  69 #include <server/race.qh>
  70 #include <server/scores.qh>
  71 #include <server/scores_rules.qh>
  72 #include <server/spawnpoints.qh>
  73 #include <server/teamplay.qh>
  74 #include <server/weapons/accuracy.qh>
  75 #include <server/weapons/common.qh>
  76 #include <server/weapons/hitplot.qh>
  77 #include <server/weapons/selection.qh>
  78 #include <server/weapons/tracing.qh>
  79 #include <server/weapons/weaponsystem.qh>
  80 #include <server/world.qh>
  81
  82 STATIC_METHOD(Client, Add, void(Client this, int _team))
  83 {
  84     ClientConnect(this);
  85     TRANSMUTE(Player, this);
  86     this.frame = 12; // 7
  87     this.team = _team;
  88     PutClientInServer(this);
  89 }
  90
  91 STATIC_METHOD(Client, Remove, void(Client this))
  92 {
  93     TRANSMUTE(Observer, this);
  94     PutClientInServer(this);
  95     ClientDisconnect(this);
  96 }
  97
  98 void send_CSQC_teamnagger() {
  99         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
 100 }
 101
 102 int CountSpectators(entity player, entity to)
 103 {
 104         if(!player) { return 0; } // not sure how, but best to be safe
 105
 106         int spec_count = 0;
 107
 108         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 109         {
 110                 spec_count++;
 111         });
 112
 113         return spec_count;
 114 }
 115
 116 void WriteSpectators(entity player, entity to)
 117 {
 118         if(!player) { return; } // not sure how, but best to be safe
 119
 120         int spec_count = 0;
 121         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 122         {
 123                 if(spec_count >= MAX_SPECTATORS)
 124                         break;
 125                 WriteByte(MSG_ENTITY, num_for_edict(it));
 126                 ++spec_count;
 127         });
 128 }
 129
 130 bool ClientData_Send(entity this, entity to, int sf)
 131 {
 132         assert(to == this.owner, return false);
 133
 134         entity e = to;
 135         if (IS_SPEC(e)) e = e.enemy;
 136
 137         sf = 0;
 138         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 139         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 140         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 141         if (observe_blocked_if_eliminated && INGAME(to))
 142                                         sf |= BIT(3); // observing blocked
 143         if (autocvar_sv_showspectators == 1 || (autocvar_sv_showspectators && IS_SPEC(to)))
 144                                         sf |= BIT(4); // show spectators
 145
 146         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 147         WriteByte(MSG_ENTITY, sf);
 148
 149         if (sf & BIT(1))
 150                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 151
 152         if(sf & BIT(4))
 153         {
 154                 float specs = CountSpectators(e, to);
 155                 WriteByte(MSG_ENTITY, specs);
 156                 WriteSpectators(e, to);
 157         }
 158
 159         return true;
 160 }
 161
 162 void ClientData_Attach(entity this)
 163 {
 164         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 165         CS(this).clientdata.drawonlytoclient = this;
 166         CS(this).clientdata.owner = this;
 167 }
 168
 169 void ClientData_Detach(entity this)
 170 {
 171         delete(CS(this).clientdata);
 172         CS(this).clientdata = NULL;
 173 }
 174
 175 void ClientData_Touch(entity e)
 176 {
 177         entity cd = CS(e).clientdata;
 178         if (cd) { cd.SendFlags = 1; }
 179
 180         // make it spectatable
 181         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 182         {
 183                 entity cd = CS(it).clientdata;
 184                 if (cd) { cd.SendFlags = 1; }
 185         });
 186 }
 187
 188
 189 /*
 190 =============
 191 CheckPlayerModel
 192
 193 Checks if the argument string can be a valid playermodel.
 194 Returns a valid one in doubt.
 195 =============
 196 */
 197 string FallbackPlayerModel;
 198 string CheckPlayerModel(string plyermodel) {
 199         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 200         {
 201                 // note: we cannot summon Don Strunzone here, some player may
 202                 // still have the model string set. In case anyone manages how
 203                 // to change a cvar default, we'll have a small leak here.
 204                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 205         }
 206         // only in right path
 207         if(substring(plyermodel, 0, 14) != "models/player/")
 208                 return FallbackPlayerModel;
 209         // only good file extensions
 210         if(substring(plyermodel, -4, 4) != ".iqm"
 211                 && substring(plyermodel, -4, 4) != ".zym"
 212                 && substring(plyermodel, -4, 4) != ".dpm"
 213                 && substring(plyermodel, -4, 4) != ".md3"
 214                 && substring(plyermodel, -4, 4) != ".psk")
 215         {
 216                 return FallbackPlayerModel;
 217         }
 218         // forbid the LOD models
 219         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 220                 return FallbackPlayerModel;
 221         if(plyermodel != strtolower(plyermodel))
 222                 return FallbackPlayerModel;
 223         // also, restrict to server models
 224         if(autocvar_sv_servermodelsonly)
 225         {
 226                 if(!fexists(plyermodel))
 227                         return FallbackPlayerModel;
 228         }
 229         return plyermodel;
 230 }
 231
 232 void setplayermodel(entity e, string modelname)
 233 {
 234         precache_model(modelname);
 235         _setmodel(e, modelname);
 236         player_setupanimsformodel(e);
 237         if(!autocvar_g_debug_globalsounds)
 238                 UpdatePlayerSounds(e);
 239 }
 240
 241 /** putting a client as observer in the server */
 242 void PutObserverInServer(entity this, bool is_forced, bool use_spawnpoint)
 243 {
 244         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this, is_forced);
 245         bool recount_ready = false;
 246         PlayerState_detach(this);
 247
 248         if (IS_PLAYER(this))
 249         {
 250                 if(GetResource(this, RES_HEALTH) >= 1)
 251                 {
 252                         // despawn effect
 253                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 254                 }
 255
 256                 // was a player, recount votes and ready status
 257                 if(IS_REAL_CLIENT(this))
 258                 {
 259                         if (vote_called) { VoteCount(false); }
 260                         this.ready = false;
 261                         if (warmup_stage || game_starttime > time) recount_ready = true;
 262                 }
 263                 entcs_update_players(this);
 264         }
 265
 266         if (use_spawnpoint)
 267         {
 268                 entity spot = SelectSpawnPoint(this, true);
 269                 if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 270                 this.angles = vec2(spot.angles);
 271                 // offset it so that the spectator spawns higher off the ground, looks better this way
 272                 setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 273         }
 274         else // change origin to restore previous view origin
 275                 setorigin(this, this.origin + STAT(PL_VIEW_OFS, this) - STAT(PL_CROUCH_VIEW_OFS, this));
 276         this.fixangle = true;
 277
 278         if (IS_REAL_CLIENT(this))
 279         {
 280                 msg_entity = this;
 281                 WriteByte(MSG_ONE, SVC_SETVIEW);
 282                 WriteEntity(MSG_ONE, this);
 283         }
 284         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 285         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 286         if(!autocvar_g_debug_globalsounds)
 287         {
 288                 // needed for player sounds
 289                 this.model = "";
 290                 FixPlayermodel(this);
 291         }
 292         setmodel(this, MDL_Null);
 293         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 294         this.view_ofs = '0 0 0';
 295
 296         RemoveGrapplingHooks(this);
 297         Portal_ClearAll(this);
 298         Unfreeze(this, false);
 299         SetSpectatee(this, NULL);
 300
 301         if (this.alivetime)
 302         {
 303                 if (!warmup_stage)
 304                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 305                 this.alivetime = 0;
 306         }
 307
 308         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 309
 310         TRANSMUTE(Observer, this);
 311
 312         if(recount_ready) ReadyCount(); // FIXME: please add comment about why this is delayed
 313
 314         WaypointSprite_PlayerDead(this);
 315         accuracy_resend(this);
 316
 317         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 318                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 319
 320         CS(this).spectatortime = time;
 321         if(this.bot_attack)
 322                 IL_REMOVE(g_bot_targets, this);
 323         this.bot_attack = false;
 324         if(this.monster_attack)
 325                 IL_REMOVE(g_monster_targets, this);
 326         this.monster_attack = false;
 327         STAT(HUD, this) = HUD_NORMAL;
 328         this.iscreature = false;
 329         this.teleportable = TELEPORT_SIMPLE;
 330         if(this.damagedbycontents)
 331                 IL_REMOVE(g_damagedbycontents, this);
 332         this.damagedbycontents = false;
 333         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 334         SetSpectatee_status(this, etof(this));
 335         this.takedamage = DAMAGE_NO;
 336         this.solid = SOLID_NOT;
 337         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 338         this.flags = FL_CLIENT | FL_NOTARGET;
 339         this.effects = 0;
 340         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 341         this.pauserotarmor_finished = 0;
 342         this.pauserothealth_finished = 0;
 343         this.pauseregen_finished = 0;
 344         this.damageforcescale = 0;
 345         this.death_time = 0;
 346         this.respawn_flags = 0;
 347         this.respawn_time = 0;
 348         STAT(RESPAWN_TIME, this) = 0;
 349         this.alpha = 0;
 350         this.scale = 0;
 351         this.fade_time = 0;
 352         this.pain_finished = 0;
 353         STAT(AIR_FINISHED, this) = 0;
 354         //this.dphitcontentsmask = 0;
 355         this.dphitcontentsmask = DPCONTENTS_SOLID;
 356         if (autocvar_g_playerclip_collisions)
 357                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 358         this.pushltime = 0;
 359         this.istypefrag = 0;
 360         setthink(this, func_null);
 361         this.nextthink = 0;
 362         this.deadflag = DEAD_NO;
 363         UNSET_DUCKED(this);
 364         STAT(REVIVE_PROGRESS, this) = 0;
 365         this.revival_time = 0;
 366         this.draggable = drag_undraggable;
 367
 368         player_powerups_remove_all(this);
 369         this.items = 0;
 370         STAT(WEAPONS, this) = '0 0 0';
 371         this.drawonlytoclient = this;
 372
 373         this.viewloc = NULL;
 374
 375         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 376
 377         this.weaponmodel = "";
 378         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 379         {
 380                 this.weaponentities[slot] = NULL;
 381         }
 382         this.exteriorweaponentity = NULL;
 383         CS(this).killcount = FRAGS_SPECTATOR;
 384         this.velocity = '0 0 0';
 385         this.avelocity = '0 0 0';
 386         this.punchangle = '0 0 0';
 387         this.punchvector = '0 0 0';
 388         this.oldvelocity = this.velocity;
 389         this.event_damage = func_null;
 390         this.event_heal = func_null;
 391
 392         for(int slot = 0; slot < MAX_AXH; ++slot)
 393         {
 394                 entity axh = this.(AuxiliaryXhair[slot]);
 395                 this.(AuxiliaryXhair[slot]) = NULL;
 396
 397                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 398                         delete(axh);
 399         }
 400
 401         if (mutator_returnvalue)
 402         {
 403                 // mutator prevents resetting teams+score
 404         }
 405         else
 406         {
 407                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR); // clears scores too in game modes without teams
 408                 this.frags = FRAGS_SPECTATOR;
 409         }
 410
 411         bot_relinkplayerlist();
 412
 413         if (CS(this).just_joined)
 414                 CS(this).just_joined = false;
 415 }
 416
 417 int player_getspecies(entity this)
 418 {
 419         get_model_parameters(this.model, this.skin);
 420         int s = get_model_parameters_species;
 421         get_model_parameters(string_null, 0);
 422         if (s < 0) return SPECIES_HUMAN;
 423         return s;
 424 }
 425
 426 .float model_randomizer;
 427 void FixPlayermodel(entity player)
 428 {
 429         string defaultmodel = "";
 430         int defaultskin = 0;
 431         if(autocvar_sv_defaultcharacter)
 432         {
 433                 if(teamplay)
 434                 {
 435                         switch(player.team)
 436                         {
 437                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 438                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 439                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 440                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 441                         }
 442                 }
 443
 444                 if(defaultmodel == "")
 445                 {
 446                         defaultmodel = autocvar_sv_defaultplayermodel;
 447                         defaultskin = autocvar_sv_defaultplayerskin;
 448                 }
 449
 450                 int n = tokenize_console(defaultmodel);
 451                 if(n > 0)
 452                 {
 453                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 454                         // However, do NOT randomize if the player-selected model is in the list.
 455                         for (int i = 0; i < n; ++i)
 456                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 457                                         defaultmodel = argv(i);
 458                 }
 459
 460                 int i = strstrofs(defaultmodel, ":", 0);
 461                 if(i >= 0)
 462                 {
 463                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 464                         defaultmodel = substring(defaultmodel, 0, i);
 465                 }
 466         }
 467         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 468         {
 469                 if(teamplay)
 470                 {
 471                         switch(player.team)
 472                         {
 473                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 474                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 475                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 476                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 477                         }
 478                 }
 479
 480                 if(!defaultskin)
 481                         defaultskin = autocvar_sv_defaultplayerskin;
 482         }
 483
 484         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 485         defaultmodel = M_ARGV(0, string);
 486         defaultskin = M_ARGV(1, int);
 487
 488         bool chmdl = false;
 489         int oldskin;
 490         if(defaultmodel != "")
 491         {
 492                 if (defaultmodel != player.model)
 493                 {
 494                         vector m1 = player.mins;
 495                         vector m2 = player.maxs;
 496                         setplayermodel (player, defaultmodel);
 497                         setsize (player, m1, m2);
 498                         chmdl = true;
 499                 }
 500
 501                 oldskin = player.skin;
 502                 player.skin = defaultskin;
 503         } else {
 504                 if (player.playermodel != player.model || player.playermodel == "")
 505                 {
 506                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 507                         vector m1 = player.mins;
 508                         vector m2 = player.maxs;
 509                         setplayermodel (player, player.playermodel);
 510                         setsize (player, m1, m2);
 511                         chmdl = true;
 512                 }
 513
 514                 if(!autocvar_sv_defaultcharacterskin)
 515                 {
 516                         oldskin = player.skin;
 517                         player.skin = stof(player.playerskin);
 518                 }
 519                 else
 520                 {
 521                         oldskin = player.skin;
 522                         player.skin = defaultskin;
 523                 }
 524         }
 525
 526         if(chmdl || oldskin != player.skin) // model or skin has changed
 527         {
 528                 player.species = player_getspecies(player); // update species
 529                 if(!autocvar_g_debug_globalsounds)
 530                         UpdatePlayerSounds(player); // update skin sounds
 531         }
 532
 533         if(!teamplay)
 534                 if(strlen(autocvar_sv_defaultplayercolors))
 535                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 536                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 537 }
 538
 539 void GiveWarmupResources(entity this)
 540 {
 541         SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 542         SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 543         SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 544         SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 545         SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 546         SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 547         SetResource(this, RES_HEALTH, warmup_start_health);
 548         SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 549         STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 550 }
 551
 552 void PutPlayerInServer(entity this)
 553 {
 554         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 555
 556         PlayerState_attach(this);
 557         accuracy_resend(this);
 558
 559         if (teamplay && this.bot_forced_team)
 560                 SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
 561
 562         if (this.team < 0)
 563                 TeamBalance_JoinBestTeam(this);
 564
 565         entity spot = SelectSpawnPoint(this, false);
 566         if (!spot) {
 567                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 568                 return; // spawn failed
 569         }
 570
 571         TRANSMUTE(Player, this);
 572
 573         CS(this).wasplayer = true;
 574         this.iscreature = true;
 575         this.teleportable = TELEPORT_NORMAL;
 576         if(!this.damagedbycontents)
 577                 IL_PUSH(g_damagedbycontents, this);
 578         this.damagedbycontents = true;
 579         set_movetype(this, MOVETYPE_WALK);
 580         this.solid = SOLID_SLIDEBOX;
 581         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 582         if (autocvar_g_playerclip_collisions)
 583                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 584         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 585                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 586         this.frags = FRAGS_PLAYER;
 587         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 588         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 589         if (autocvar__notarget)
 590                 this.flags |= FL_NOTARGET;
 591         this.takedamage = DAMAGE_AIM;
 592         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 593
 594         if (warmup_stage)
 595                 GiveWarmupResources(this);
 596         else
 597         {
 598                 SetResource(this, RES_SHELLS, start_ammo_shells);
 599                 SetResource(this, RES_BULLETS, start_ammo_nails);
 600                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 601                 SetResource(this, RES_CELLS, start_ammo_cells);
 602                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 603                 SetResource(this, RES_FUEL, start_ammo_fuel);
 604                 SetResource(this, RES_HEALTH, start_health);
 605                 SetResource(this, RES_ARMOR, start_armorvalue);
 606                 STAT(WEAPONS, this) = start_weapons;
 607                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 608                 {
 609                         GiveRandomWeapons(this, random_start_weapons_count,
 610                                 autocvar_g_random_start_weapons, random_start_ammo);
 611                 }
 612         }
 613         SetSpectatee_status(this, 0);
 614
 615         PS(this).dual_weapons = '0 0 0';
 616
 617         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 618                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 619
 620         this.items = start_items;
 621
 622         float shieldtime = time + autocvar_g_spawnshieldtime;
 623
 624         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 625         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 626         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 627         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 628         if (!sv_ready_restart_after_countdown && time < game_starttime)
 629         {
 630                 float f = game_starttime - time;
 631                 shieldtime += f;
 632                 this.pauserotarmor_finished += f;
 633                 this.pauserothealth_finished += f;
 634                 this.pauseregen_finished += f;
 635         }
 636
 637         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 638
 639         this.damageforcescale = autocvar_g_player_damageforcescale;
 640         this.death_time = 0;
 641         this.respawn_flags = 0;
 642         this.respawn_time = 0;
 643         STAT(RESPAWN_TIME, this) = 0;
 644         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.9 : autocvar_sv_player_scale);
 645         this.fade_time = 0;
 646         this.pain_finished = 0;
 647         this.pushltime = 0;
 648         setthink(this, func_null); // players have no think function
 649         this.nextthink = 0;
 650         this.dmg_team = 0;
 651         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 652
 653         this.deadflag = DEAD_NO;
 654
 655         this.angles = spot.angles;
 656         this.angles_z = 0; // never spawn tilted even if the spot says to
 657         if (IS_BOT_CLIENT(this))
 658         {
 659                 this.v_angle = this.angles;
 660                 bot_aim_reset(this);
 661         }
 662         this.fixangle = true; // turn this way immediately
 663         this.oldvelocity = this.velocity = '0 0 0';
 664         this.avelocity = '0 0 0';
 665         this.punchangle = '0 0 0';
 666         this.punchvector = '0 0 0';
 667
 668         STAT(REVIVE_PROGRESS, this) = 0;
 669         this.revival_time = 0;
 670
 671         STAT(AIR_FINISHED, this) = 0;
 672         this.waterlevel = WATERLEVEL_NONE;
 673         this.watertype = CONTENT_EMPTY;
 674
 675         entity spawnevent = new_pure(spawnevent);
 676         spawnevent.owner = this;
 677         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 678
 679         // Cut off any still running player sounds.
 680         stopsound(this, CH_PLAYER_SINGLE);
 681
 682         this.model = "";
 683         FixPlayermodel(this);
 684         this.drawonlytoclient = NULL;
 685
 686         this.viewloc = NULL;
 687
 688         for(int slot = 0; slot < MAX_AXH; ++slot)
 689         {
 690                 entity axh = this.(AuxiliaryXhair[slot]);
 691                 this.(AuxiliaryXhair[slot]) = NULL;
 692
 693                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 694                         delete(axh);
 695         }
 696
 697         this.spawnpoint_targ = NULL;
 698
 699         UNSET_DUCKED(this);
 700         this.view_ofs = STAT(PL_VIEW_OFS, this);
 701         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 702         this.spawnorigin = spot.origin;
 703         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 704         // don't reset back to last position, even if new position is stuck in solid
 705         this.oldorigin = this.origin;
 706         if(this.conveyor)
 707                 IL_REMOVE(g_conveyed, this);
 708         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 709         if(this.swampslug)
 710                 IL_REMOVE(g_swamped, this);
 711         this.swampslug = NULL;
 712         this.swamp_interval = 0;
 713         if(this.ladder_entity)
 714                 IL_REMOVE(g_ladderents, this);
 715         this.ladder_entity = NULL;
 716         IL_EACH(g_counters, it.realowner == this,
 717         {
 718                 delete(it);
 719         });
 720         STAT(HUD, this) = HUD_NORMAL;
 721
 722         this.event_damage = PlayerDamage;
 723         this.event_heal = PlayerHeal;
 724
 725         this.draggable = func_null;
 726
 727         if(!this.bot_attack)
 728                 IL_PUSH(g_bot_targets, this);
 729         this.bot_attack = true;
 730         if(!this.monster_attack)
 731                 IL_PUSH(g_monster_targets, this);
 732         this.monster_attack = true;
 733         navigation_dynamicgoal_init(this, false);
 734
 735         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 736
 737         // player was spectator
 738         if (CS(this).killcount == FRAGS_SPECTATOR) {
 739                 PlayerScore_Clear(this);
 740                 CS(this).killcount = 0;
 741                 CS(this).startplaytime = time;
 742         }
 743
 744         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 745         {
 746                 .entity weaponentity = weaponentities[slot];
 747                 CL_SpawnWeaponentity(this, weaponentity);
 748         }
 749         this.alpha = default_player_alpha;
 750         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 751         this.exteriorweaponentity.alpha = default_weapon_alpha;
 752
 753         this.speedrunning = false;
 754
 755         this.counter_cnt = 0;
 756         this.fragsfilter_cnt = 0;
 757
 758         target_voicescript_clear(this);
 759
 760         // reset fields the weapons may use
 761         FOREACH(Weapons, true, {
 762                 it.wr_resetplayer(it, this);
 763                         // reload all reloadable weapons
 764                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 765                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 766                         {
 767                                 .entity weaponentity = weaponentities[slot];
 768                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 769                         }
 770                 }
 771         });
 772
 773         Unfreeze(this, false);
 774
 775         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 776         {
 777                 string s = spot.target;
 778                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 779                         spot.target = string_null;
 780                 SUB_UseTargets(spot, this, NULL);
 781                 if(g_assault || g_race)
 782                         spot.target = s;
 783         }
 784
 785         if (autocvar_spawn_debug)
 786         {
 787                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 788                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 789         }
 790
 791         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 792         {
 793                 .entity weaponentity = weaponentities[slot];
 794                 entity w_ent = this.(weaponentity);
 795                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 796                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 797                 else
 798                         w_ent.m_switchweapon = WEP_Null;
 799                 w_ent.m_weapon = WEP_Null;
 800                 w_ent.weaponname = "";
 801                 w_ent.m_switchingweapon = WEP_Null;
 802                 w_ent.cnt = -1;
 803         }
 804
 805         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 806
 807         if (CS(this).impulse) ImpulseCommands(this);
 808
 809         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 810         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 811         {
 812                 .entity weaponentity = weaponentities[slot];
 813                 W_WeaponFrame(this, weaponentity);
 814         }
 815
 816         if (!warmup_stage && !this.alivetime)
 817                 this.alivetime = time;
 818
 819         antilag_clear(this, CS(this));
 820
 821         if (warmup_stage < 0 || warmup_stage > 1)
 822                 ReadyCount();
 823 }
 824
 825 /** Called when a client spawns in the server */
 826 void PutClientInServer(entity this)
 827 {
 828         if (IS_REAL_CLIENT(this)) {
 829                 msg_entity = this;
 830                 WriteByte(MSG_ONE, SVC_SETVIEW);
 831                 WriteEntity(MSG_ONE, this);
 832         }
 833         if (game_stopped)
 834                 TRANSMUTE(Observer, this);
 835
 836         bool use_spawnpoint = (!this.enemy); // check this.enemy here since SetSpectatee will clear it
 837         SetSpectatee(this, NULL);
 838
 839         // reset player keys
 840         if(PS(this))
 841                 PS(this).itemkeys = 0;
 842
 843         MUTATOR_CALLHOOK(PutClientInServer, this);
 844
 845         if (IS_OBSERVER(this)) {
 846                 PutObserverInServer(this, false, use_spawnpoint);
 847         } else if (IS_PLAYER(this)) {
 848                 PutPlayerInServer(this);
 849         }
 850
 851         bot_relinkplayerlist();
 852 }
 853
 854 // TODO do we need all these fields, or should we stop autodetecting runtime
 855 // changes and just have a console command to update this?
 856 bool ClientInit_SendEntity(entity this, entity to, int sf)
 857 {
 858         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 859         return = true;
 860         msg_entity = to;
 861         // MSG_INIT replacement
 862         // TODO: make easier to use
 863         Registry_send_all();
 864         W_PROP_reload(MSG_ONE, to);
 865         ClientInit_misc(this);
 866         MUTATOR_CALLHOOK(Ent_Init);
 867 }
 868 void ClientInit_misc(entity this)
 869 {
 870         int channel = MSG_ONE;
 871         WriteHeader(channel, ENT_CLIENT_INIT);
 872         WriteByte(channel, g_nexball_meter_period * 32);
 873         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 874         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 875         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 876         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 877         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 878         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 879         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 880         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 881
 882         if(autocvar_sv_foginterval && world.fog != "")
 883                 WriteString(channel, world.fog);
 884         else
 885                 WriteString(channel, "");
 886         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 887         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 888         WriteByte(channel, serverflags);
 889         WriteCoord(channel, autocvar_g_trueaim_minrange);
 890 }
 891
 892 void ClientInit_CheckUpdate(entity this)
 893 {
 894         this.nextthink = time;
 895         if(this.count != autocvar_g_balance_armor_blockpercent)
 896         {
 897                 this.count = autocvar_g_balance_armor_blockpercent;
 898                 this.SendFlags |= 1;
 899         }
 900         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 901         {
 902                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 903                 this.SendFlags |= 1;
 904         }
 905 }
 906
 907 void ClientInit_Spawn()
 908 {
 909         entity e = new_pure(clientinit);
 910         setthink(e, ClientInit_CheckUpdate);
 911         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 912
 913         ClientInit_CheckUpdate(e);
 914 }
 915
 916 /*
 917 =============
 918 SetNewParms
 919 =============
 920 */
 921 void SetNewParms ()
 922 {
 923         // initialize parms for a new player
 924         parm1 = -(86400 * 366);
 925
 926         MUTATOR_CALLHOOK(SetNewParms);
 927 }
 928
 929 /*
 930 =============
 931 SetChangeParms
 932 =============
 933 */
 934 void SetChangeParms (entity this)
 935 {
 936         // save parms for level change
 937         parm1 = CS(this).parm_idlesince - time;
 938
 939         MUTATOR_CALLHOOK(SetChangeParms);
 940 }
 941
 942 /*
 943 =============
 944 DecodeLevelParms
 945 =============
 946 */
 947 void DecodeLevelParms(entity this)
 948 {
 949         // load parms
 950         CS(this).parm_idlesince = parm1;
 951         if (CS(this).parm_idlesince == -(86400 * 366))
 952                 CS(this).parm_idlesince = time;
 953
 954         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 955         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 956
 957         MUTATOR_CALLHOOK(DecodeLevelParms);
 958 }
 959
 960 void FixClientCvars(entity e)
 961 {
 962         // send prediction settings to the client
 963         if(autocvar_g_antilag == 3) // client side hitscan
 964                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 965         if(autocvar_sv_gentle)
 966                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 967
 968         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 969         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 970
 971         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 972
 973         MUTATOR_CALLHOOK(FixClientCvars, e);
 974 }
 975
 976 bool findinlist_abbrev(string tofind, string list)
 977 {
 978         if(list == "" || tofind == "")
 979                 return false; // empty list or search, just return
 980
 981         // this function allows abbreviated strings!
 982         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 983         {
 984                 return true;
 985         });
 986
 987         return false;
 988 }
 989
 990 bool PlayerInIPList(entity p, string iplist)
 991 {
 992         // some safety checks (never allow local?)
 993         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 994                 return false;
 995
 996         return findinlist_abbrev(p.netaddress, iplist);
 997 }
 998
 999 bool PlayerInIDList(entity p, string idlist)
1000 {
1001         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1002         if(!p.crypto_idfp)
1003                 return false;
1004
1005         return findinlist_abbrev(p.crypto_idfp, idlist);
1006 }
1007
1008 bool PlayerInList(entity player, string list)
1009 {
1010         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1011 }
1012
1013 #ifdef DP_EXT_PRECONNECT
1014 /*
1015 =============
1016 ClientPreConnect
1017
1018 Called once (not at each match start) when a client begins a connection to the server
1019 =============
1020 */
1021 void ClientPreConnect(entity this)
1022 {
1023         if(autocvar_sv_eventlog)
1024         {
1025                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1026                         this.playerid,
1027                         etof(this),
1028                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1029                 ));
1030         }
1031 }
1032 #endif
1033
1034 // NOTE csqc uses the active mutators list sent by this function
1035 // to understand which mutators are enabled
1036 // also note that they aren't all registered mutators, e.g. jetpack, low gravity
1037 void SendWelcomeMessage(entity this, int msg_type)
1038 {
1039         WriteByte(msg_type, boolean(autocvar_g_campaign));
1040         if (boolean(autocvar_g_campaign))
1041         {
1042                 WriteString(msg_type, Campaign_GetTitle());
1043                 WriteByte(msg_type, Campaign_GetLevelNum());
1044                 WriteString(msg_type, Campaign_GetMessage());
1045                 return;
1046         }
1047         WriteString(msg_type, autocvar_hostname);
1048         WriteString(msg_type, autocvar_g_xonoticversion);
1049         WriteByte(msg_type, CS(this).version_mismatch);
1050         WriteByte(msg_type, (CS(this).version < autocvar_gameversion));
1051         WriteByte(msg_type, autocvar_g_warmup > 1 ? autocvar_g_warmup : map_minplayers);
1052         WriteByte(msg_type, GetPlayerLimit());
1053
1054         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1055         string modifications = M_ARGV(0, string);
1056
1057         if (!g_weaponarena && cvar("g_balance_blaster_weaponstartoverride") == 0)
1058                 modifications = strcat(modifications, ", No start weapons");
1059         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1060                 modifications = strcat(modifications, ", Low gravity");
1061         if(g_weapon_stay && !g_cts)
1062                 modifications = strcat(modifications, ", Weapons stay");
1063         if(autocvar_g_jetpack)
1064                 modifications = strcat(modifications, ", Jetpack");
1065         modifications = substring(modifications, 2, strlen(modifications) - 2);
1066
1067         WriteString(msg_type, modifications);
1068
1069         WriteString(msg_type, g_weaponarena_list);
1070
1071         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1072         {
1073                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1074                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1075         }
1076
1077         WriteString(msg_type, cache_mutatormsg);
1078
1079         WriteString(msg_type, strreplace("\\n", "\n", autocvar_sv_motd));
1080 }
1081
1082 /**
1083 =============
1084 ClientConnect
1085
1086 Called when a client connects to the server
1087 =============
1088 */
1089 void ClientConnect(entity this)
1090 {
1091         if (Ban_MaybeEnforceBanOnce(this)) return;
1092         assert(!IS_CLIENT(this), return);
1093         this.flags |= FL_CLIENT;
1094         assert(player_count >= 0, player_count = 0);
1095
1096         TRANSMUTE(Client, this);
1097         CS(this).version_nagtime = time + 10 + random() * 10;
1098
1099         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1100
1101         bot_clientconnect(this);
1102
1103         Player_DetermineForcedTeam(this);
1104
1105         TRANSMUTE(Observer, this);
1106
1107         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1108
1109         // always track bots, don't ask for cl_allow_uidtracking
1110         if (IS_BOT_CLIENT(this))
1111                 PlayerStats_GameReport_AddPlayer(this);
1112         else
1113                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1114
1115         if (autocvar_sv_eventlog)
1116                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1117
1118         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1119
1120         stuffcmd(this, clientstuff, "\n");
1121         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1122
1123         FixClientCvars(this);
1124
1125         // get version info from player
1126         stuffcmd(this, "cmd clientversion $gameversion\n");
1127
1128         // notify about available teams
1129         if (teamplay)
1130         {
1131                 entity balance = TeamBalance_CheckAllowedTeams(this);
1132                 int t = TeamBalance_GetAllowedTeams(balance);
1133                 TeamBalance_Destroy(balance);
1134                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1135         }
1136         else
1137         {
1138                 stuffcmd(this, "set _teams_available 0\n");
1139         }
1140
1141         bot_relinkplayerlist();
1142
1143         CS(this).spectatortime = time;
1144         if (blockSpectators)
1145         {
1146                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1147         }
1148
1149         CS(this).jointime = time;
1150
1151         if (IS_REAL_CLIENT(this))
1152         {
1153                 if (g_weaponarena_weapons == WEPSET(TUBA))
1154                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1155                 // quickmenu file must be put in a subfolder with an unique name
1156                 // to reduce chances of overriding custom client quickmenus
1157                 if (waypointeditor_enabled)
1158                         stuffcmd(this, sprintf("cl_cmd settemp _hud_panel_quickmenu_file_from_server %s\n", "wpeditor.txt"));
1159                 else if (autocvar_sv_quickmenu_file != "" && strstrofs(autocvar_sv_quickmenu_file, "/", 0) && fexists(autocvar_sv_quickmenu_file))
1160                         stuffcmd(this, sprintf("cl_cmd settemp _hud_panel_quickmenu_file_from_server %s\n", autocvar_sv_quickmenu_file));
1161         }
1162
1163         if (!autocvar_sv_foginterval && world.fog != "")
1164                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1165
1166         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AVAILABLE_TEAMS == 2))
1167                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1168                         send_CSQC_teamnagger();
1169
1170         CSQCMODEL_AUTOINIT(this);
1171
1172         CS(this).model_randomizer = random();
1173
1174         if (IS_REAL_CLIENT(this))
1175                 sv_notice_join(this);
1176
1177         this.move_qcphysics = true;
1178
1179         // update physics stats (players can spawn before physics runs)
1180         Physics_UpdateStats(this);
1181
1182         IL_EACH(g_initforplayer, it.init_for_player, {
1183                 it.init_for_player(it, this);
1184         });
1185
1186         Handicap_Initialize(this);
1187
1188         MUTATOR_CALLHOOK(ClientConnect, this);
1189
1190         if (player_count == 1)
1191                 localcmd("\nsv_hook_firstjoin\n");
1192 }
1193 /*
1194 =============
1195 ClientDisconnect
1196
1197 Called when a client disconnects from the server
1198 =============
1199 */
1200 .entity chatbubbleentity;
1201 void player_powerups_remove_all(entity this);
1202
1203 void ClientDisconnect(entity this)
1204 {
1205         assert(IS_CLIENT(this), return);
1206
1207         PlayerStats_GameReport_FinalizePlayer(this);
1208         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1209         if (CS(this).active_minigame) part_minigame(this);
1210         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1211
1212         if (autocvar_sv_eventlog)
1213                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1214
1215         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1216
1217         if(IS_SPEC(this))
1218                 SetSpectatee(this, NULL);
1219
1220         MUTATOR_CALLHOOK(ClientDisconnect, this);
1221
1222         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1223         strfree(CS_CVAR(this).weaponorder_byimpulse);
1224         ClientState_detach(this);
1225
1226         Portal_ClearAll(this);
1227
1228         Unfreeze(this, false);
1229
1230         RemoveGrapplingHooks(this);
1231
1232         // Here, everything has been done that requires this player to be a client.
1233
1234         this.flags &= ~FL_CLIENT;
1235
1236         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1237         if (this.killindicator) delete(this.killindicator);
1238
1239         IL_EACH(g_counters, it.realowner == this,
1240         {
1241                 delete(it);
1242         });
1243
1244         WaypointSprite_PlayerGone(this);
1245
1246         bot_relinkplayerlist();
1247
1248         strfree(this.clientstatus);
1249         if (this.personal) delete(this.personal);
1250
1251         this.playerid = 0;
1252         if (warmup_stage || game_starttime > time) ReadyCount();
1253         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1254
1255         player_powerups_remove_all(this); // stop powerup sound
1256
1257         ONREMOVE(this);
1258
1259         if (player_count == 0)
1260                 localcmd("\nsv_hook_lastleave\n");
1261 }
1262
1263 void ChatBubbleThink(entity this)
1264 {
1265         this.nextthink = time;
1266         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1267         {
1268                 if(this.owner) // but why can that ever be NULL?
1269                         this.owner.chatbubbleentity = NULL;
1270                 delete(this);
1271                 return;
1272         }
1273
1274         this.mdl = "";
1275
1276         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1277         {
1278                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1279                         this.mdl = "models/sprites/minigame_busy.iqm";
1280                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1281                         this.mdl = "models/misc/chatbubble.spr";
1282         }
1283
1284         if ( this.model != this.mdl )
1285                 _setmodel(this, this.mdl);
1286
1287 }
1288
1289 void UpdateChatBubble(entity this)
1290 {
1291         if (this.alpha < 0)
1292                 return;
1293         // spawn a chatbubble entity if needed
1294         if (!this.chatbubbleentity)
1295         {
1296                 this.chatbubbleentity = new(chatbubbleentity);
1297                 this.chatbubbleentity.owner = this;
1298                 this.chatbubbleentity.exteriormodeltoclient = this;
1299                 setthink(this.chatbubbleentity, ChatBubbleThink);
1300                 this.chatbubbleentity.nextthink = time;
1301                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1302                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1303                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1304                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1305                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1306                 //this.chatbubbleentity.model = "";
1307                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1308         }
1309 }
1310
1311 void calculate_player_respawn_time(entity this)
1312 {
1313         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1314                 return;
1315
1316         float gametype_setting_tmp;
1317         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1318         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1319         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1320         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1321         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1322         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1323
1324         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1325         if (teamplay)
1326         {
1327                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1328                         if(it.team == this.team)
1329                                 ++pcount;
1330                 });
1331                 if (sdelay_small_count == 0)
1332                         sdelay_small_count = 1;
1333                 if (sdelay_large_count == 0)
1334                         sdelay_large_count = 1;
1335         }
1336         else
1337         {
1338                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1339                         ++pcount;
1340                 });
1341                 if (sdelay_small_count == 0)
1342                 {
1343                         if (IS_INDEPENDENT_PLAYER(this))
1344                         {
1345                                 // Players play independently. No point in requiring enemies.
1346                                 sdelay_small_count = 1;
1347                         }
1348                         else
1349                         {
1350                                 // Players play AGAINST each other. Enemies required.
1351                                 sdelay_small_count = 2;
1352                         }
1353                 }
1354                 if (sdelay_large_count == 0)
1355                 {
1356                         if (IS_INDEPENDENT_PLAYER(this))
1357                         {
1358                                 // Players play independently. No point in requiring enemies.
1359                                 sdelay_large_count = 1;
1360                         }
1361                         else
1362                         {
1363                                 // Players play AGAINST each other. Enemies required.
1364                                 sdelay_large_count = 2;
1365                         }
1366                 }
1367         }
1368
1369         float sdelay;
1370
1371         if (pcount <= sdelay_small_count)
1372                 sdelay = sdelay_small;
1373         else if (pcount >= sdelay_large_count)
1374                 sdelay = sdelay_large;
1375         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1376                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1377
1378         if(waves)
1379                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1380         else
1381                 this.respawn_time = time + sdelay;
1382
1383         if(sdelay < sdelay_max)
1384                 this.respawn_time_max = time + sdelay_max;
1385         else
1386                 this.respawn_time_max = this.respawn_time;
1387
1388         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1389                 this.respawn_countdown = 10; // first number to count down from is 10
1390         else
1391                 this.respawn_countdown = -1; // do not count down
1392
1393         if(autocvar_g_forced_respawn)
1394                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1395 }
1396
1397 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1398 // added to the model skins
1399 /*void UpdateColorModHack()
1400 {
1401         float c;
1402         c = this.clientcolors & 15;
1403         // LordHavoc: only bothering to support white, green, red, yellow, blue
1404              if (!teamplay) this.colormod = '0 0 0';
1405         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1406         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1407         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1408         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1409         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1410         else this.colormod = '1 1 1';
1411 }*/
1412
1413 void respawn(entity this)
1414 {
1415         bool damagedbycontents_prev = this.damagedbycontents;
1416         if(this.alpha >= 0)
1417         {
1418                 if(autocvar_g_respawn_ghosts)
1419                 {
1420                         this.solid = SOLID_NOT;
1421                         this.takedamage = DAMAGE_NO;
1422                         this.damagedbycontents = false;
1423                         set_movetype(this, MOVETYPE_FLY);
1424                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1425                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1426                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1427                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1428                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1429                         if(autocvar_g_respawn_ghosts_time > 0)
1430                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1431                 }
1432                 else
1433                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1434         }
1435
1436         CopyBody(this, 1);
1437         this.damagedbycontents = damagedbycontents_prev;
1438
1439         this.effects |= EF_NODRAW; // prevent another CopyBody
1440         PutClientInServer(this);
1441 }
1442
1443 void play_countdown(entity this, float finished, Sound samp)
1444 {
1445         TC(Sound, samp);
1446         float time_left = finished - time;
1447         if(IS_REAL_CLIENT(this) && time_left < 6 && floor(time_left - frametime) != floor(time_left))
1448                 sound(this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1449 }
1450
1451 // it removes special powerups not handled by StatusEffects
1452 void player_powerups_remove_all(entity this)
1453 {
1454         if (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1455         {
1456                 // don't play the poweroff sound when the game restarts or the player disconnects
1457                 if (time > game_starttime + 1 && IS_CLIENT(this)
1458                         && !(start_items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS)))
1459                 {
1460                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1461                 }
1462                 if (this.items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1463                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1464                 this.items -= (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS));
1465         }
1466 }
1467
1468 void player_powerups(entity this)
1469 {
1470         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1471                 this.modelflags |= MF_ROCKET;
1472         else
1473                 this.modelflags &= ~MF_ROCKET;
1474
1475         this.effects &= ~EF_NODEPTHTEST;
1476
1477         if (IS_DEAD(this))
1478                 player_powerups_remove_all(this);
1479
1480         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1481                 return;
1482
1483         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1484         int items_prev = this.items;
1485
1486         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1487         {
1488                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1489                 if (this.items & IT_SUPERWEAPON)
1490                 {
1491                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1492                         {
1493                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1494                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1495                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1496                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1497                         }
1498                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1499                         {
1500                                 // don't let them run out
1501                         }
1502                         else
1503                         {
1504                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1505                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1506                                 {
1507                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1508                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1509                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1510                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1511                                 }
1512                         }
1513                 }
1514                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1515                 {
1516                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1517                         {
1518                                 this.items = this.items | IT_SUPERWEAPON;
1519                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1520                                 {
1521                                         if(!g_cts)
1522                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1523                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1524                                 }
1525                         }
1526                         else
1527                         {
1528                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1529                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1530                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1531                         }
1532                 }
1533                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1534                 {
1535                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1536                 }
1537         }
1538
1539         if(autocvar_g_nodepthtestplayers)
1540                 this.effects = this.effects | EF_NODEPTHTEST;
1541
1542         if(autocvar_g_fullbrightplayers)
1543                 this.effects = this.effects | EF_FULLBRIGHT;
1544
1545         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1546 }
1547
1548 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1549 {
1550         if(current > stable)
1551                 return current;
1552         else if(current > stable - 0.25) // when close enough, "snap"
1553                 return stable;
1554         else
1555                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1556 }
1557
1558 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1559 {
1560         if(current < stable)
1561                 return current;
1562         else if(current < stable + 0.25) // when close enough, "snap"
1563                 return stable;
1564         else
1565                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1566 }
1567
1568 void RotRegen(entity this, Resource res, float limit_mod,
1569         float regenstable, float regenfactor, float regenlinear, float regenframetime,
1570         float rotstable, float rotfactor, float rotlinear, float rotframetime)
1571 {
1572         float old = GetResource(this, res);
1573         float current = old;
1574         if(current > rotstable)
1575         {
1576                 if(rotframetime > 0)
1577                 {
1578                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1579                         current = max(rotstable, current - rotlinear * rotframetime);
1580                 }
1581         }
1582         else if(current < regenstable)
1583         {
1584                 if(regenframetime > 0)
1585                 {
1586                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1587                         current = min(regenstable, current + regenlinear * regenframetime);
1588                 }
1589         }
1590
1591         float limit = GetResourceLimit(this, res) * limit_mod;
1592         if(current > limit)
1593                 current = limit;
1594
1595         if (current != old)
1596                 SetResource(this, res, current);
1597 }
1598
1599 void player_regen(entity this)
1600 {
1601         float max_mod, regen_mod, rot_mod, limit_mod;
1602         max_mod = regen_mod = rot_mod = limit_mod = 1;
1603
1604         float regen_health = autocvar_g_balance_health_regen;
1605         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1606         float regen_health_rot = autocvar_g_balance_health_rot;
1607         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1608         float regen_health_stable = autocvar_g_balance_health_regenstable;
1609         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1610         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1611                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1612         max_mod = M_ARGV(1, float);
1613         regen_mod = M_ARGV(2, float);
1614         rot_mod = M_ARGV(3, float);
1615         limit_mod = M_ARGV(4, float);
1616         regen_health = M_ARGV(5, float);
1617         regen_health_linear = M_ARGV(6, float);
1618         regen_health_rot = M_ARGV(7, float);
1619         regen_health_rotlinear = M_ARGV(8, float);
1620         regen_health_stable = M_ARGV(9, float);
1621         regen_health_rotstable = M_ARGV(10, float);
1622
1623         float rotstable, regenstable, rotframetime, regenframetime;
1624
1625         if(!mutator_returnvalue)
1626         if(!STAT(FROZEN, this))
1627         {
1628                 regenstable = autocvar_g_balance_armor_regenstable;
1629                 rotstable = autocvar_g_balance_armor_rotstable;
1630                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1631                 rotframetime = (time > this.pauserotarmor_finished) ? (rot_mod * frametime) : 0;
1632                 RotRegen(this, RES_ARMOR, limit_mod,
1633                         regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regenframetime,
1634                         rotstable, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rotframetime);
1635
1636                 // NOTE: max_mod is only applied to health
1637                 regenstable = regen_health_stable * max_mod;
1638                 rotstable = regen_health_rotstable * max_mod;
1639                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1640                 rotframetime = (time > this.pauserothealth_finished) ? (rot_mod * frametime) : 0;
1641                 RotRegen(this, RES_HEALTH, limit_mod,
1642                         regenstable, regen_health, regen_health_linear, regenframetime,
1643                         rotstable, regen_health_rot, regen_health_rotlinear, rotframetime);
1644         }
1645
1646         // if player rotted to death...  die!
1647         // check this outside above checks, as player may still be able to rot to death
1648         if(GetResource(this, RES_HEALTH) < 1)
1649         {
1650                 if(this.vehicle)
1651                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1652                 if(this.event_damage)
1653                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1654         }
1655
1656         if (!(this.items & IT_UNLIMITED_AMMO))
1657         {
1658                 regenstable = autocvar_g_balance_fuel_regenstable;
1659                 rotstable = autocvar_g_balance_fuel_rotstable;
1660                 regenframetime = ((time > this.pauseregen_finished) && (this.items & ITEM_JetpackRegen.m_itemid)) ? frametime : 0;
1661                 rotframetime = (time > this.pauserotfuel_finished) ? frametime : 0;
1662                 RotRegen(this, RES_FUEL, 1,
1663                         regenstable, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regenframetime,
1664                         rotstable, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rotframetime);
1665         }
1666 }
1667
1668 bool zoomstate_set;
1669 void SetZoomState(entity this, float newzoom)
1670 {
1671         if(newzoom != CS(this).zoomstate)
1672         {
1673                 CS(this).zoomstate = newzoom;
1674                 ClientData_Touch(this);
1675         }
1676         zoomstate_set = true;
1677 }
1678
1679 void GetPressedKeys(entity this)
1680 {
1681         MUTATOR_CALLHOOK(GetPressedKeys, this);
1682         if (game_stopped)
1683         {
1684                 CS(this).pressedkeys = 0;
1685                 STAT(PRESSED_KEYS, this) = 0;
1686                 return;
1687         }
1688
1689         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1690         int keys = STAT(PRESSED_KEYS, this);
1691         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1692         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1693         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1694         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1695
1696         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1697         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1698         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1699         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1700         CS(this).pressedkeys = keys; // store for other users
1701
1702         STAT(PRESSED_KEYS, this) = keys;
1703 }
1704
1705 /*
1706 ======================
1707 spectate mode routines
1708 ======================
1709 */
1710
1711 void SpectateCopy(entity this, entity spectatee)
1712 {
1713         TC(Client, this); TC(Client, spectatee);
1714
1715         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1716         PS(this) = PS(spectatee);
1717         this.armortype = spectatee.armortype;
1718         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1719         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1720         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1721         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1722         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1723         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1724         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1725         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1726         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1727         CS(this).impulse = 0;
1728         this.disableclientprediction = 1; // no need to run prediction on a spectator
1729         this.items = spectatee.items;
1730         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1731         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1732         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1733         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1734         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1735         this.punchangle = spectatee.punchangle;
1736         this.view_ofs = spectatee.view_ofs;
1737         this.velocity = spectatee.velocity;
1738         this.dmg_take = spectatee.dmg_take;
1739         this.dmg_save = spectatee.dmg_save;
1740         this.dmg_inflictor = spectatee.dmg_inflictor;
1741         this.v_angle = spectatee.v_angle;
1742         this.angles = spectatee.v_angle;
1743         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1744         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1745         this.viewloc = spectatee.viewloc;
1746         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1747                 this.fixangle = true;
1748         setorigin(this, spectatee.origin);
1749         setsize(this, spectatee.mins, spectatee.maxs);
1750         SetZoomState(this, CS(spectatee).zoomstate);
1751
1752     anticheat_spectatecopy(this, spectatee);
1753         STAT(HUD, this) = STAT(HUD, spectatee);
1754         if(spectatee.vehicle)
1755     {
1756         this.angles = spectatee.v_angle;
1757
1758         //this.fixangle = false;
1759         //this.velocity = spectatee.vehicle.velocity;
1760         this.vehicle_health = spectatee.vehicle_health;
1761         this.vehicle_shield = spectatee.vehicle_shield;
1762         this.vehicle_energy = spectatee.vehicle_energy;
1763         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1764         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1765         this.vehicle_reload1 = spectatee.vehicle_reload1;
1766         this.vehicle_reload2 = spectatee.vehicle_reload2;
1767
1768         //msg_entity = this;
1769
1770        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1771             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1772            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1773            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1774
1775         //WriteByte (MSG_ONE, SVC_SETVIEW);
1776         //    WriteEntity(MSG_ONE, this);
1777         //makevectors(spectatee.v_angle);
1778         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1779     }
1780 }
1781
1782 bool SpectateUpdate(entity this)
1783 {
1784         if(!this.enemy)
1785                 return false;
1786
1787         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1788         {
1789                 SetSpectatee(this, NULL);
1790                 return false;
1791         }
1792
1793         SpectateCopy(this, this.enemy);
1794
1795         return true;
1796 }
1797
1798 bool SpectateSet(entity this)
1799 {
1800         if(!IS_PLAYER(this.enemy))
1801                 return false;
1802
1803         ClientData_Touch(this.enemy);
1804
1805         msg_entity = this;
1806         WriteByte(MSG_ONE, SVC_SETVIEW);
1807         WriteEntity(MSG_ONE, this.enemy);
1808         set_movetype(this, MOVETYPE_NONE);
1809         accuracy_resend(this);
1810
1811         if(!SpectateUpdate(this))
1812                 PutObserverInServer(this, false, true);
1813
1814         return true;
1815 }
1816
1817 void SetSpectatee_status(entity this, int spectatee_num)
1818 {
1819         int oldspectatee_status = CS(this).spectatee_status;
1820         CS(this).spectatee_status = spectatee_num;
1821
1822         if (CS(this).spectatee_status != oldspectatee_status)
1823         {
1824                 if (STAT(PRESSED_KEYS, this))
1825                 {
1826                         CS(this).pressedkeys = 0;
1827                         STAT(PRESSED_KEYS, this) = 0;
1828                 }
1829                 ClientData_Touch(this);
1830                 if (g_race || g_cts) race_InitSpectator();
1831         }
1832 }
1833
1834 void SetSpectatee(entity this, entity spectatee)
1835 {
1836         if(IS_BOT_CLIENT(this))
1837                 return; // bots abuse .enemy, this code is useless to them
1838
1839         entity old_spectatee = this.enemy;
1840
1841         this.enemy = spectatee;
1842
1843         // WEAPONTODO
1844         // these are required to fix the spectator bug with arc
1845         if(old_spectatee)
1846         {
1847                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1848                 {
1849                         .entity weaponentity = weaponentities[slot];
1850                         if(old_spectatee.(weaponentity).arc_beam)
1851                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1852                 }
1853         }
1854         if(spectatee)
1855         {
1856                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1857                 {
1858                         .entity weaponentity = weaponentities[slot];
1859                         if(spectatee.(weaponentity).arc_beam)
1860                                 spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1861                 }
1862         }
1863
1864         if (spectatee)
1865                 SetSpectatee_status(this, etof(spectatee));
1866
1867         // needed to update spectator list
1868         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1869 }
1870
1871 bool Spectate(entity this, entity pl)
1872 {
1873         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1874                 return false;
1875         pl = M_ARGV(1, entity);
1876
1877         SetSpectatee(this, pl);
1878         return SpectateSet(this);
1879 }
1880
1881 bool SpectateNext(entity this)
1882 {
1883         entity ent = find(this.enemy, classname, STR_PLAYER);
1884
1885         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1886                 ent = M_ARGV(1, entity);
1887         else if (!ent)
1888                 ent = find(ent, classname, STR_PLAYER);
1889
1890         if(ent) { SetSpectatee(this, ent); }
1891
1892         return SpectateSet(this);
1893 }
1894
1895 bool SpectatePrev(entity this)
1896 {
1897         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1898         entity ent = findchain(classname, STR_PLAYER);
1899         if (!ent) // no player
1900                 return false;
1901
1902         entity first = ent;
1903         // skip players until current spectated player
1904         if(this.enemy)
1905         while(ent && ent != this.enemy)
1906                 ent = ent.chain;
1907
1908         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1909         {
1910                 case MUT_SPECPREV_FOUND:
1911                         ent = M_ARGV(1, entity);
1912                         break;
1913                 case MUT_SPECPREV_RETURN:
1914                         return true;
1915                 case MUT_SPECPREV_CONTINUE:
1916                 default:
1917                 {
1918                         if(ent.chain)
1919                                 ent = ent.chain;
1920                         else
1921                                 ent = first;
1922                         break;
1923                 }
1924         }
1925
1926         SetSpectatee(this, ent);
1927         return SpectateSet(this);
1928 }
1929
1930 /*
1931 =============
1932 ShowRespawnCountdown()
1933
1934 Update a respawn countdown display.
1935 =============
1936 */
1937 void ShowRespawnCountdown(entity this)
1938 {
1939         float number;
1940         if(!IS_DEAD(this)) // just respawned?
1941                 return;
1942         else
1943         {
1944                 number = ceil(this.respawn_time - time);
1945                 if(number <= 0)
1946                         return;
1947                 if(number <= this.respawn_countdown)
1948                 {
1949                         this.respawn_countdown = number - 1;
1950                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1951                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1952                 }
1953         }
1954 }
1955
1956 .bool team_selected;
1957 bool ShowTeamSelection(entity this)
1958 {
1959         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1960                 return false;
1961         if (frametime) // once per frame is more than enough
1962                 stuffcmd(this, "_scoreboard_team_selection 1\n");
1963         return true;
1964 }
1965 void Join(entity this)
1966 {
1967         if (autocvar_g_campaign && !campaign_bots_may_start && !game_stopped && time >= game_starttime)
1968                 ReadyRestart(true);
1969
1970         TRANSMUTE(Player, this);
1971
1972         if(!this.team_selected)
1973         if(autocvar_g_campaign || autocvar_g_balance_teams)
1974                 TeamBalance_JoinBestTeam(this);
1975
1976         if(autocvar_g_campaign)
1977                 campaign_bots_may_start = true;
1978
1979         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1980
1981         PutClientInServer(this);
1982
1983         if(IS_PLAYER(this))
1984         if(teamplay && this.team != -1)
1985         {
1986         }
1987         else
1988                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1989         this.team_selected = false;
1990 }
1991
1992 int GetPlayerLimit()
1993 {
1994         if(g_duel)
1995                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1996         // don't return map_maxplayers during intermission as it would interfere with MapHasRightSize()
1997         int player_limit = (autocvar_g_maxplayers >= 0 || intermission_running) ? autocvar_g_maxplayers : map_maxplayers;
1998         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1999         player_limit = M_ARGV(0, int);
2000         return player_limit < maxclients ? player_limit : 0;
2001 }
2002
2003 /**
2004  * Determines whether the player is allowed to join. This depends on cvar
2005  * g_maxplayers, if it isn't used this function always return true, otherwise
2006  * it checks whether the number of currently playing players exceeds g_maxplayers.
2007  * @return int number of free slots for players, 0 if none
2008  */
2009 int nJoinAllowed(entity this, entity ignore)
2010 {
2011         if(!ignore)
2012         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2013         // so report 0 free slots if restricted
2014         {
2015                 if(autocvar_g_forced_team_otherwise == "spectate")
2016                         return 0;
2017                 if(autocvar_g_forced_team_otherwise == "spectator")
2018                         return 0;
2019         }
2020
2021         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2022                 return 0; // forced spectators can never join
2023
2024         // TODO simplify this
2025         int totalClients = 0;
2026         int currentlyPlaying = 0;
2027         FOREACH_CLIENT(true, {
2028                 if(it != ignore)
2029                         ++totalClients;
2030                 if(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME(it)))
2031                         ++currentlyPlaying;
2032         });
2033
2034         int player_limit = GetPlayerLimit();
2035
2036         int free_slots = 0;
2037         if (!player_limit)
2038                 free_slots = maxclients - totalClients;
2039         else if(player_limit > 0 && currentlyPlaying < player_limit)
2040                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2041
2042         static float msg_time = 0;
2043         if(this && !INGAME(this) && ignore && !free_slots && time > msg_time)
2044         {
2045                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT, player_limit);
2046                 msg_time = time + 0.5;
2047         }
2048
2049         return free_slots;
2050 }
2051
2052 bool joinAllowed(entity this)
2053 {
2054         if (CS(this).version_mismatch) return false;
2055         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2056         if (!nJoinAllowed(this, this)) return false;
2057         if (teamplay && lockteams) return false;
2058         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2059         if (ShowTeamSelection(this)) return false;
2060         return true;
2061 }
2062
2063 .string shootfromfixedorigin;
2064 .bool dualwielding_prev;
2065 bool PlayerThink(entity this)
2066 {
2067         if (game_stopped || intermission_running) {
2068                 this.modelflags &= ~MF_ROCKET;
2069                 if(intermission_running)
2070                         IntermissionThink(this);
2071                 return false;
2072         }
2073
2074         if (timeout_status == TIMEOUT_ACTIVE) {
2075                 // don't allow the player to turn around while game is paused
2076                 // FIXME turn this into CSQC stuff
2077                 this.v_angle = this.lastV_angle;
2078                 this.angles = this.lastV_angle;
2079                 this.fixangle = true;
2080         }
2081
2082         if (frametime) player_powerups(this);
2083
2084         if (IS_DEAD(this)) {
2085                 if (this.personal && g_race_qualifying) {
2086                         if (time > this.respawn_time) {
2087                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2088                                 respawn(this);
2089                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2090                         }
2091                 } else {
2092                         if (frametime) player_anim(this);
2093
2094                         if (this.respawn_flags & RESPAWN_DENY)
2095                         {
2096                                 STAT(RESPAWN_TIME, this) = 0;
2097                                 return false;
2098                         }
2099
2100                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2101
2102                         switch(this.deadflag)
2103                         {
2104                                 case DEAD_DYING:
2105                                 {
2106                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2107                                                 this.deadflag = DEAD_RESPAWNING;
2108                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2109                                                 this.deadflag = DEAD_DEAD;
2110                                         break;
2111                                 }
2112                                 case DEAD_DEAD:
2113                                 {
2114                                         if (button_pressed)
2115                                                 this.deadflag = DEAD_RESPAWNABLE;
2116                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2117                                                 this.deadflag = DEAD_RESPAWNING;
2118                                         break;
2119                                 }
2120                                 case DEAD_RESPAWNABLE:
2121                                 {
2122                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2123                                                 this.deadflag = DEAD_RESPAWNING;
2124                                         break;
2125                                 }
2126                                 case DEAD_RESPAWNING:
2127                                 {
2128                                         if (time > this.respawn_time)
2129                                         {
2130                                                 this.respawn_time = time + 1; // only retry once a second
2131                                                 this.respawn_time_max = this.respawn_time;
2132                                                 respawn(this);
2133                                         }
2134                                         break;
2135                                 }
2136                         }
2137
2138                         ShowRespawnCountdown(this);
2139
2140                         if (this.respawn_flags & RESPAWN_SILENT)
2141                                 STAT(RESPAWN_TIME, this) = 0;
2142                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2143                         {
2144                                 if (time < this.respawn_time)
2145                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2146                                 else if (this.deadflag != DEAD_RESPAWNING)
2147                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2148                         }
2149                         else
2150                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2151                 }
2152
2153                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2154                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2155                         STAT(RESPAWN_TIME, this) *= -1;
2156
2157                 return false;
2158         }
2159
2160         FixPlayermodel(this);
2161
2162         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2163                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2164                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2165         }
2166
2167         // reset gun alignment when dual wielding status changes
2168         // to ensure guns are always aligned right and left
2169         bool dualwielding = W_DualWielding(this);
2170         if(this.dualwielding_prev != dualwielding)
2171         {
2172                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2173                 this.dualwielding_prev = dualwielding;
2174         }
2175
2176         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2177         //if(frametime)
2178         {
2179                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2180                 {
2181                         .entity weaponentity = weaponentities[slot];
2182                         if(WEP_CVAR(vortex, charge_always))
2183                                 W_Vortex_Charge(this, weaponentity, frametime);
2184                         W_WeaponFrame(this, weaponentity);
2185                 }
2186         }
2187
2188         if (frametime)
2189         {
2190                 // WEAPONTODO: Add a weapon request for this
2191                 // rot vortex charge to the charge limit
2192                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2193                 {
2194                         .entity weaponentity = weaponentities[slot];
2195                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2196                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2197                 }
2198
2199                 player_regen(this);
2200                 player_anim(this);
2201                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2202         }
2203
2204         monsters_setstatus(this);
2205
2206         return true;
2207 }
2208
2209 .bool would_spectate;
2210 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2211 void ObserverOrSpectatorThink(entity this)
2212 {
2213         bool is_spec = IS_SPEC(this);
2214         if ( CS(this).impulse )
2215         {
2216                 int r = MinigameImpulse(this, CS(this).impulse);
2217                 if (!is_spec || r)
2218                         CS(this).impulse = 0;
2219
2220                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2221                 {
2222                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2223                         CS(this).impulse = 0;
2224                         return;
2225                 }
2226         }
2227
2228         if (IS_BOT_CLIENT(this) && !CS(this).autojoin_checked)
2229         {
2230                 CS(this).autojoin_checked = true;
2231                 TRANSMUTE(Player, this);
2232                 PutClientInServer(this);
2233                 return;
2234         }
2235
2236         if (this.flags & FL_JUMPRELEASED) {
2237                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2238                         this.flags &= ~FL_JUMPRELEASED;
2239                         this.flags |= FL_SPAWNING;
2240                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2241                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2242                         this.flags &= ~FL_JUMPRELEASED;
2243                         if(SpectateNext(this)) {
2244                                 TRANSMUTE(Spectator, this);
2245                         } else if (is_spec) {
2246                                 TRANSMUTE(Observer, this);
2247                                 PutClientInServer(this);
2248                         }
2249                         else
2250                                 this.would_spectate = false; // unable to spectate anyone
2251                         if (is_spec)
2252                                 CS(this).impulse = 0;
2253                 } else if (is_spec) {
2254                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2255                                 this.flags &= ~FL_JUMPRELEASED;
2256                                 if(SpectatePrev(this)) {
2257                                         TRANSMUTE(Spectator, this);
2258                                 } else {
2259                                         TRANSMUTE(Observer, this);
2260                                         PutClientInServer(this);
2261                                 }
2262                                 CS(this).impulse = 0;
2263                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2264                                 if(!observe_blocked_if_eliminated || !INGAME(this)) {
2265                                         this.would_spectate = false;
2266                                         this.flags &= ~FL_JUMPRELEASED;
2267                                         TRANSMUTE(Observer, this);
2268                                         PutClientInServer(this);
2269                                 }
2270                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2271                                 PutObserverInServer(this, false, true);
2272                                 this.would_spectate = true;
2273                         }
2274                 }
2275                 else {
2276                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2277                         if (PHYS_INPUT_BUTTON_USE(this))
2278                                 wouldclip = !wouldclip;
2279                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2280                         set_movetype(this, preferred_movetype);
2281                 }
2282         } else { // jump pressed
2283                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2284                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2285                         this.flags |= FL_JUMPRELEASED;
2286                         if(this.flags & FL_SPAWNING)
2287                         {
2288                                 this.flags &= ~FL_SPAWNING;
2289                                 if(joinAllowed(this))
2290                                         Join(this);
2291                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2292                                         CS(this).autojoin_checked = -1;
2293                                 return;
2294                         }
2295                 }
2296                 if(is_spec && !SpectateUpdate(this))
2297                         PutObserverInServer(this, false, true);
2298         }
2299         if (is_spec)
2300                 this.flags |= FL_CLIENT | FL_NOTARGET;
2301 }
2302
2303 void PlayerUseKey(entity this)
2304 {
2305         if (!IS_PLAYER(this))
2306                 return;
2307
2308         if(this.vehicle)
2309         {
2310                 if(!game_stopped)
2311                 {
2312                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2313                         return;
2314                 }
2315         }
2316         else if(autocvar_g_vehicles_enter)
2317         {
2318                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2319                 {
2320                         entity head, closest_target = NULL;
2321                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2322
2323                         while(head) // find the closest acceptable target to enter
2324                         {
2325                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2326                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2327                                 {
2328                                         if(closest_target)
2329                                         {
2330                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2331                                                 { closest_target = head; }
2332                                         }
2333                                         else { closest_target = head; }
2334                                 }
2335
2336                                 head = head.chain;
2337                         }
2338
2339                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2340                 }
2341         }
2342
2343         // a use key was pressed; call handlers
2344         MUTATOR_CALLHOOK(PlayerUseKey, this);
2345 }
2346
2347
2348 /*
2349 =============
2350 PlayerPreThink
2351
2352 Called every frame for each client before the physics are run
2353 =============
2354 */
2355 .float last_vehiclecheck;
2356 void PlayerPreThink (entity this)
2357 {
2358         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2359         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2360
2361         WarpZone_PlayerPhysics_FixVAngle(this);
2362
2363         if (frametime) {
2364                 // physics frames: update anticheat stuff
2365                 anticheat_prethink(this);
2366
2367                 // WORKAROUND: only use dropclient in server frames (frametime set).
2368                 // Never use it in cl_movement frames (frametime zero).
2369                 if (blockSpectators && IS_REAL_CLIENT(this)
2370                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !INGAME(this)
2371                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2372                 {
2373                         if (dropclient_schedule(this))
2374                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2375                 }
2376         }
2377
2378         zoomstate_set = false;
2379
2380         // Check for nameless players
2381         if (this.netname == "" || this.netname != CS(this).netname_previous)
2382         {
2383                 bool assume_unchanged = (CS(this).netname_previous == "");
2384                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2385                 {
2386                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2387                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2388                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2389                         assume_unchanged = false;
2390                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2391                 }
2392                 if (isInvisibleString(this.netname))
2393                 {
2394                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2395                         sprint(this, "Warning: invisible names are not allowed.\n");
2396                         assume_unchanged = false;
2397                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2398                 }
2399                 if (!assume_unchanged && autocvar_sv_eventlog)
2400                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2401                 strcpy(CS(this).netname_previous, this.netname);
2402         }
2403
2404         // version nagging
2405         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2406         CS(this).version_nagtime = 0;
2407         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2408             // git client
2409         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2410             // git server
2411             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2412         } else {
2413             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2414             if (r < 0) { // old client
2415                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2416             } else if (r > 0) { // old server
2417                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2418             }
2419         }
2420     }
2421
2422         // GOD MODE info
2423         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2424         {
2425                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2426                 this.max_armorvalue = 0;
2427         }
2428
2429         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2430         {
2431                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2432                 {
2433                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2434                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2435                         if (this.iceblock)
2436                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2437
2438                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2439                                 Unfreeze(this, false);
2440                 }
2441                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2442                 {
2443                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2444                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2445
2446                         if (GetResource(this, RES_HEALTH) < 1)
2447                         {
2448                                 if (this.vehicle)
2449                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2450                                 if(this.event_damage)
2451                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2452                         }
2453                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2454                                 Unfreeze(this, false);
2455                 }
2456         }
2457
2458         MUTATOR_CALLHOOK(PlayerPreThink, this);
2459
2460         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2461         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2462         {
2463                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2464                 {
2465                         if(!it.owner)
2466                         {
2467                                 if(!it.team || SAME_TEAM(this, it))
2468                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2469                                 else if(autocvar_g_vehicles_steal)
2470                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2471                         }
2472                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2473                         {
2474                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2475                         }
2476                 });
2477
2478                 this.last_vehiclecheck = time + 1;
2479         }
2480
2481         if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2482                 PlayerUseKey(this);
2483         CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2484
2485         if (IS_PLAYER(this)) {
2486                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2487                         error("Client can't be spawned as player on connection!");
2488                 if(!PlayerThink(this))
2489                         return;
2490         }
2491         else if (game_stopped || intermission_running) {
2492                 if(intermission_running)
2493                         IntermissionThink(this);
2494                 return;
2495         }
2496         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2497         {
2498                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2499                 CS(this).autojoin_checked = 1;
2500                 // don't do this in ClientConnect
2501                 // many things can go wrong if a client is spawned as player on connection
2502                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2503                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2504                                 && (!teamplay || autocvar_g_balance_teams)))
2505                 {
2506                         if(joinAllowed(this))
2507                                 Join(this);
2508                         return;
2509                 }
2510         }
2511         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2512                 ObserverOrSpectatorThink(this);
2513         }
2514
2515         // WEAPONTODO: Add weapon request for this
2516         if (!zoomstate_set) {
2517                 bool wep_zoomed = false;
2518                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2519                 {
2520                         .entity weaponentity = weaponentities[slot];
2521                         Weapon thiswep = this.(weaponentity).m_weapon;
2522                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2523                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2524                 }
2525                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2526         }
2527
2528         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2529         {
2530                 CS(this).teamkill_soundtime = 0;
2531
2532                 entity e = CS(this).teamkill_soundsource;
2533                 entity oldpusher = e.pusher;
2534                 e.pusher = this;
2535                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2536                 e.pusher = oldpusher;
2537         }
2538
2539         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2540                 CS(this).taunt_soundtime = 0;
2541                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2542         }
2543
2544         target_voicescript_next(this);
2545 }
2546
2547 void DrownPlayer(entity this)
2548 {
2549         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2550                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2551         {
2552                 STAT(AIR_FINISHED, this) = 0;
2553                 return;
2554         }
2555
2556         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2557         {
2558                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2559                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2560                 STAT(AIR_FINISHED, this) = 0;
2561         }
2562         else
2563         {
2564                 if (!STAT(AIR_FINISHED, this))
2565                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2566                 if (STAT(AIR_FINISHED, this) < time)
2567                 {       // drown!
2568                         if (this.pain_finished < time)
2569                         {
2570                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2571                                 this.pain_finished = time + 0.5;
2572                         }
2573                 }
2574         }
2575 }
2576
2577 .bool move_qcphysics;
2578
2579 void Player_Physics(entity this)
2580 {
2581         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2582
2583         if(!this.move_qcphysics)
2584                 return;
2585
2586         if(!frametime && !CS(this).pm_frametime)
2587                 return;
2588
2589         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2590
2591         CS(this).pm_frametime = 0;
2592 }
2593
2594 /*
2595 =============
2596 PlayerPostThink
2597
2598 Called every frame for each client after the physics are run
2599 =============
2600 */
2601 void PlayerPostThink (entity this)
2602 {
2603         Player_Physics(this);
2604
2605         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2606         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2607         if (IS_REAL_CLIENT(this))
2608         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2609         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2610         {
2611                 int totalClients = 0;
2612                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2613                 {
2614                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2615                         if (server_is_dedicated)
2616                         {
2617                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2618                                 {
2619                                         ++totalClients;
2620                                 });
2621                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2622                                         totalClients = 0;
2623                         }
2624                 }
2625                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2626                 {
2627                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2628                         {
2629                                 ++totalClients;
2630                         });
2631                 }
2632
2633                 if (totalClients < autocvar_sv_maxidle_minplayers)
2634                 {
2635                         // idle kick disabled
2636                         CS(this).parm_idlesince = time;
2637                 }
2638                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2639                 {
2640                         if (CS(this).idlekick_lasttimeleft)
2641                         {
2642                                 CS(this).idlekick_lasttimeleft = 0;
2643                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2644                         }
2645                 }
2646                 else
2647                 {
2648                         float maxidle_time = autocvar_sv_maxidle;
2649                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2650                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2651                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2652                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2653                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2654                         {
2655                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2656                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2657                                 else
2658                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2659                         }
2660                         if (timeleft <= 0) {
2661                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2662                                 {
2663                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2664                                         PutObserverInServer(this, true, true);
2665                                 }
2666                                 else
2667                                 {
2668                                         if (dropclient_schedule(this))
2669                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2670                                 }
2671                                 return;
2672                         }
2673                         else if (timeleft <= countdown_time) {
2674                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2675                                         play2(this, SND(TALK2));
2676                                 CS(this).idlekick_lasttimeleft = timeleft;
2677                         }
2678                 }
2679         }
2680
2681         CheatFrame(this);
2682
2683         if (game_stopped)
2684         {
2685                 this.solid = SOLID_NOT;
2686                 this.takedamage = DAMAGE_NO;
2687                 set_movetype(this, MOVETYPE_NONE);
2688                 CS(this).teamkill_complain = 0;
2689                 CS(this).teamkill_soundtime = 0;
2690                 CS(this).teamkill_soundsource = NULL;
2691         }
2692
2693         if (IS_PLAYER(this)) {
2694                 if(this.death_time == time && IS_DEAD(this))
2695                 {
2696                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2697                         // once all the damage events of this frame have been processed with normal size
2698                         this.maxs.z = 5;
2699                         setsize(this, this.mins, this.maxs);
2700                 }
2701                 DrownPlayer(this);
2702                 UpdateChatBubble(this);
2703                 if (CS(this).impulse) ImpulseCommands(this);
2704                 GetPressedKeys(this);
2705                 if (game_stopped)
2706                 {
2707                         CSQCMODEL_AUTOUPDATE(this);
2708                         return;
2709                 }
2710         }
2711         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2712         {
2713                 CS(this).pressedkeys = 0;
2714                 STAT(PRESSED_KEYS, this) = 0;
2715         }
2716
2717         if (this.waypointsprite_attachedforcarrier) {
2718                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2719                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2720         }
2721
2722         CSQCMODEL_AUTOUPDATE(this);
2723 }
2724
2725 // hack to copy the button fields from the client entity to the Client State
2726 void PM_UpdateButtons(entity this, entity store)
2727 {
2728         if(this.impulse)
2729                 store.impulse = this.impulse;
2730         this.impulse = 0;
2731
2732         bool typing = this.buttonchat || this.button12;
2733
2734         store.button0 = (typing) ? 0 : this.button0;
2735         //button1?!
2736         store.button2 = (typing) ? 0 : this.button2;
2737         store.button3 = (typing) ? 0 : this.button3;
2738         store.button4 = this.button4;
2739         store.button5 = (typing) ? 0 : this.button5;
2740         store.button6 = this.button6;
2741         store.button7 = this.button7;
2742         store.button8 = this.button8;
2743         store.button9 = this.button9;
2744         store.button10 = this.button10;
2745         store.button11 = this.button11;
2746         store.button12 = this.button12;
2747         store.button13 = this.button13;
2748         store.button14 = this.button14;
2749         store.button15 = this.button15;
2750         store.button16 = this.button16;
2751         store.buttonuse = this.buttonuse;
2752         store.buttonchat = this.buttonchat;
2753
2754         store.cursor_active = this.cursor_active;
2755         store.cursor_screen = this.cursor_screen;
2756         store.cursor_trace_start = this.cursor_trace_start;
2757         store.cursor_trace_endpos = this.cursor_trace_endpos;
2758         store.cursor_trace_ent = this.cursor_trace_ent;
2759
2760         store.ping = this.ping;
2761         store.ping_packetloss = this.ping_packetloss;
2762         store.ping_movementloss = this.ping_movementloss;
2763
2764         store.v_angle = this.v_angle;
2765         store.movement = this.movement;
2766 }
2767
2768 NET_HANDLE(fpsreport, bool)
2769 {
2770         int fps = ReadShort();
2771         PlayerScore_Set(sender, SP_FPS, fps);
2772         return true;
2773 }