qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/waypoints/all.qh>
  27 #include <common/net_linked.qh>
  28 #include <common/net_notice.qh>
  29 #include <common/notifications/all.qh>
  30 #include <common/physics/player.qh>
  31 #include <common/playerstats.qh>
  32 #include <common/state.qh>
  33 #include <common/stats.qh>
  34 #include <common/vehicles/all.qh>
  35 #include <common/vehicles/sv_vehicles.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/weapons/_all.qh>
  38 #include <common/weapons/weapon/vortex.qh>
  39 #include <common/wepent.qh>
  40 #include <lib/csqcmodel/sv_model.qh>
  41 #include <lib/warpzone/common.qh>
  42 #include <lib/warpzone/server.qh>
  43 #include <server/anticheat.qh>
  44 #include <server/antilag.qh>
  45 #include <server/bot/api.qh>
  46 #include <server/bot/default/cvars.qh>
  47 #include <server/campaign.qh>
  48 #include <server/chat.qh>
  49 #include <server/cheats.qh>
  50 #include <server/clientkill.qh>
  51 #include <server/command/common.qh>
  52 #include <server/command/common.qh>
  53 #include <server/command/vote.qh>
  54 #include <server/compat/quake3.qh>
  55 #include <server/damage.qh>
  56 #include <server/gamelog.qh>
  57 #include <server/handicap.qh>
  58 #include <server/hook.qh>
  59 #include <server/impulse.qh>
  60 #include <server/intermission.qh>
  61 #include <server/ipban.qh>
  62 #include <server/main.qh>
  63 #include <server/mutators/_mod.qh>
  64 #include <server/player.qh>
  65 #include <server/portals.qh>
  66 #include <server/race.qh>
  67 #include <server/resources.qh>
  68 #include <server/scores.qh>
  69 #include <server/scores_rules.qh>
  70 #include <server/spawnpoints.qh>
  71 #include <server/teamplay.qh>
  72 #include <server/weapons/accuracy.qh>
  73 #include <server/weapons/common.qh>
  74 #include <server/weapons/hitplot.qh>
  75 #include <server/weapons/selection.qh>
  76 #include <server/weapons/tracing.qh>
  77 #include <server/weapons/weaponsystem.qh>
  78 #include <server/world.qh>
  79
  80 STATIC_METHOD(Client, Add, void(Client this, int _team))
  81 {
  82     ClientConnect(this);
  83     TRANSMUTE(Player, this);
  84     this.frame = 12; // 7
  85     this.team = _team;
  86     PutClientInServer(this);
  87 }
  88
  89 STATIC_METHOD(Client, Remove, void(Client this))
  90 {
  91     TRANSMUTE(Observer, this);
  92     PutClientInServer(this);
  93     ClientDisconnect(this);
  94 }
  95
  96 void send_CSQC_teamnagger() {
  97         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  98 }
  99
 100 int CountSpectators(entity player, entity to)
 101 {
 102         if(!player) { return 0; } // not sure how, but best to be safe
 103
 104         int spec_count = 0;
 105
 106         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 107         {
 108                 spec_count++;
 109         });
 110
 111         return spec_count;
 112 }
 113
 114 void WriteSpectators(entity player, entity to)
 115 {
 116         if(!player) { return; } // not sure how, but best to be safe
 117
 118         int spec_count = 0;
 119         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 120         {
 121                 if(spec_count >= MAX_SPECTATORS)
 122                         break;
 123                 WriteByte(MSG_ENTITY, num_for_edict(it));
 124                 ++spec_count;
 125         });
 126 }
 127
 128 bool ClientData_Send(entity this, entity to, int sf)
 129 {
 130         assert(to == this.owner, return false);
 131
 132         entity e = to;
 133         if (IS_SPEC(e)) e = e.enemy;
 134
 135         sf = 0;
 136         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 137         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 138         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 139         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 140
 141         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 142         WriteByte(MSG_ENTITY, sf);
 143
 144         if (sf & BIT(1))
 145                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 146
 147         if(sf & BIT(4))
 148         {
 149                 float specs = CountSpectators(e, to);
 150                 WriteByte(MSG_ENTITY, specs);
 151                 WriteSpectators(e, to);
 152         }
 153
 154         return true;
 155 }
 156
 157 void ClientData_Attach(entity this)
 158 {
 159         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 160         CS(this).clientdata.drawonlytoclient = this;
 161         CS(this).clientdata.owner = this;
 162 }
 163
 164 void ClientData_Detach(entity this)
 165 {
 166         delete(CS(this).clientdata);
 167         CS(this).clientdata = NULL;
 168 }
 169
 170 void ClientData_Touch(entity e)
 171 {
 172         entity cd = CS(e).clientdata;
 173         if (cd) { cd.SendFlags = 1; }
 174
 175         // make it spectatable
 176         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 177         {
 178                 entity cd = CS(it).clientdata;
 179                 if (cd) { cd.SendFlags = 1; }
 180         });
 181 }
 182
 183
 184 /*
 185 =============
 186 CheckPlayerModel
 187
 188 Checks if the argument string can be a valid playermodel.
 189 Returns a valid one in doubt.
 190 =============
 191 */
 192 string FallbackPlayerModel;
 193 string CheckPlayerModel(string plyermodel) {
 194         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 195         {
 196                 // note: we cannot summon Don Strunzone here, some player may
 197                 // still have the model string set. In case anyone manages how
 198                 // to change a cvar default, we'll have a small leak here.
 199                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 200         }
 201         // only in right path
 202         if(substring(plyermodel, 0, 14) != "models/player/")
 203                 return FallbackPlayerModel;
 204         // only good file extensions
 205         if(substring(plyermodel, -4, 4) != ".iqm"
 206                 && substring(plyermodel, -4, 4) != ".zym"
 207                 && substring(plyermodel, -4, 4) != ".dpm"
 208                 && substring(plyermodel, -4, 4) != ".md3"
 209                 && substring(plyermodel, -4, 4) != ".psk")
 210         {
 211                 return FallbackPlayerModel;
 212         }
 213         // forbid the LOD models
 214         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 215                 return FallbackPlayerModel;
 216         if(plyermodel != strtolower(plyermodel))
 217                 return FallbackPlayerModel;
 218         // also, restrict to server models
 219         if(autocvar_sv_servermodelsonly)
 220         {
 221                 if(!fexists(plyermodel))
 222                         return FallbackPlayerModel;
 223         }
 224         return plyermodel;
 225 }
 226
 227 void setplayermodel(entity e, string modelname)
 228 {
 229         precache_model(modelname);
 230         _setmodel(e, modelname);
 231         player_setupanimsformodel(e);
 232         if(!autocvar_g_debug_globalsounds)
 233                 UpdatePlayerSounds(e);
 234 }
 235
 236 /** putting a client as observer in the server */
 237 void PutObserverInServer(entity this)
 238 {
 239         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 240         PlayerState_detach(this);
 241
 242         if (IS_PLAYER(this))
 243         {
 244                 if(GetResource(this, RES_HEALTH) >= 1)
 245                 {
 246                         // despawn effect
 247                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 248                 }
 249
 250                 // was a player, recount votes and ready status
 251                 if(IS_REAL_CLIENT(this))
 252                 {
 253                         if (vote_called) { VoteCount(false); }
 254                         ReadyCount();
 255                 }
 256                 entcs_update_players(this);
 257         }
 258
 259         entity spot = SelectSpawnPoint(this, true);
 260         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 261         this.angles = vec2(spot.angles);
 262         this.fixangle = true;
 263         // offset it so that the spectator spawns higher off the ground, looks better this way
 264         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 265         if (IS_REAL_CLIENT(this))
 266         {
 267                 msg_entity = this;
 268                 WriteByte(MSG_ONE, SVC_SETVIEW);
 269                 WriteEntity(MSG_ONE, this);
 270         }
 271         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 272         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 273         if(!autocvar_g_debug_globalsounds)
 274         {
 275                 // needed for player sounds
 276                 this.model = "";
 277                 FixPlayermodel(this);
 278         }
 279         setmodel(this, MDL_Null);
 280         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 281         this.view_ofs = '0 0 0';
 282
 283         RemoveGrapplingHooks(this);
 284         Portal_ClearAll(this);
 285         Unfreeze(this, false);
 286         SetSpectatee(this, NULL);
 287
 288         if (this.alivetime)
 289         {
 290                 if (!warmup_stage)
 291                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 292                 this.alivetime = 0;
 293         }
 294
 295         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 296
 297         WaypointSprite_PlayerDead(this);
 298
 299         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 300                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 301
 302         accuracy_resend(this);
 303
 304         CS(this).spectatortime = time;
 305         if(this.bot_attack)
 306                 IL_REMOVE(g_bot_targets, this);
 307         this.bot_attack = false;
 308         if(this.monster_attack)
 309                 IL_REMOVE(g_monster_targets, this);
 310         this.monster_attack = false;
 311         STAT(HUD, this) = HUD_NORMAL;
 312         TRANSMUTE(Observer, this);
 313         this.iscreature = false;
 314         this.teleportable = TELEPORT_SIMPLE;
 315         if(this.damagedbycontents)
 316                 IL_REMOVE(g_damagedbycontents, this);
 317         this.damagedbycontents = false;
 318         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 319         SetSpectatee_status(this, etof(this));
 320         this.takedamage = DAMAGE_NO;
 321         this.solid = SOLID_NOT;
 322         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 323         this.flags = FL_CLIENT | FL_NOTARGET;
 324         this.effects = 0;
 325         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 326         this.pauserotarmor_finished = 0;
 327         this.pauserothealth_finished = 0;
 328         this.pauseregen_finished = 0;
 329         this.damageforcescale = 0;
 330         this.death_time = 0;
 331         this.respawn_flags = 0;
 332         this.respawn_time = 0;
 333         STAT(RESPAWN_TIME, this) = 0;
 334         this.alpha = 0;
 335         this.scale = 0;
 336         this.fade_time = 0;
 337         this.pain_finished = 0;
 338         STAT(STRENGTH_FINISHED, this) = 0;
 339         STAT(INVINCIBLE_FINISHED, this) = 0;
 340         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 341         STAT(AIR_FINISHED, this) = 0;
 342         //this.dphitcontentsmask = 0;
 343         this.dphitcontentsmask = DPCONTENTS_SOLID;
 344         if (autocvar_g_playerclip_collisions)
 345                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 346         this.pushltime = 0;
 347         this.istypefrag = 0;
 348         setthink(this, func_null);
 349         this.nextthink = 0;
 350         this.deadflag = DEAD_NO;
 351         UNSET_DUCKED(this);
 352         STAT(REVIVE_PROGRESS, this) = 0;
 353         this.revival_time = 0;
 354         this.draggable = drag_undraggable;
 355
 356         this.items = 0;
 357         STAT(WEAPONS, this) = '0 0 0';
 358         this.drawonlytoclient = this;
 359
 360         this.viewloc = NULL;
 361
 362         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 363
 364         this.weaponmodel = "";
 365         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 366         {
 367                 this.weaponentities[slot] = NULL;
 368         }
 369         this.exteriorweaponentity = NULL;
 370         CS(this).killcount = FRAGS_SPECTATOR;
 371         this.velocity = '0 0 0';
 372         this.avelocity = '0 0 0';
 373         this.punchangle = '0 0 0';
 374         this.punchvector = '0 0 0';
 375         this.oldvelocity = this.velocity;
 376         this.fire_endtime = -1;
 377         this.event_damage = func_null;
 378         this.event_heal = func_null;
 379
 380         for(int slot = 0; slot < MAX_AXH; ++slot)
 381         {
 382                 entity axh = this.(AuxiliaryXhair[slot]);
 383                 this.(AuxiliaryXhair[slot]) = NULL;
 384
 385                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 386                         delete(axh);
 387         }
 388
 389         if (mutator_returnvalue)
 390         {
 391                 // mutator prevents resetting teams+score
 392         }
 393         else
 394         {
 395                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 396                 this.frags = FRAGS_SPECTATOR;
 397         }
 398
 399         bot_relinkplayerlist();
 400
 401         if (CS(this).just_joined)
 402                 CS(this).just_joined = false;
 403 }
 404
 405 int player_getspecies(entity this)
 406 {
 407         get_model_parameters(this.model, this.skin);
 408         int s = get_model_parameters_species;
 409         get_model_parameters(string_null, 0);
 410         if (s < 0) return SPECIES_HUMAN;
 411         return s;
 412 }
 413
 414 .float model_randomizer;
 415 void FixPlayermodel(entity player)
 416 {
 417         string defaultmodel = "";
 418         int defaultskin = 0;
 419         if(autocvar_sv_defaultcharacter)
 420         {
 421                 if(teamplay)
 422                 {
 423                         switch(player.team)
 424                         {
 425                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 426                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 427                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 428                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 429                         }
 430                 }
 431
 432                 if(defaultmodel == "")
 433                 {
 434                         defaultmodel = autocvar_sv_defaultplayermodel;
 435                         defaultskin = autocvar_sv_defaultplayerskin;
 436                 }
 437
 438                 int n = tokenize_console(defaultmodel);
 439                 if(n > 0)
 440                 {
 441                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 442                         // However, do NOT randomize if the player-selected model is in the list.
 443                         for (int i = 0; i < n; ++i)
 444                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 445                                         defaultmodel = argv(i);
 446                 }
 447
 448                 int i = strstrofs(defaultmodel, ":", 0);
 449                 if(i >= 0)
 450                 {
 451                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 452                         defaultmodel = substring(defaultmodel, 0, i);
 453                 }
 454         }
 455         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 456         {
 457                 if(teamplay)
 458                 {
 459                         switch(player.team)
 460                         {
 461                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 462                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 463                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 464                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 465                         }
 466                 }
 467
 468                 if(!defaultskin)
 469                         defaultskin = autocvar_sv_defaultplayerskin;
 470         }
 471
 472         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 473         defaultmodel = M_ARGV(0, string);
 474         defaultskin = M_ARGV(1, int);
 475
 476         bool chmdl = false;
 477         int oldskin;
 478         if(defaultmodel != "")
 479         {
 480                 if (defaultmodel != player.model)
 481                 {
 482                         vector m1 = player.mins;
 483                         vector m2 = player.maxs;
 484                         setplayermodel (player, defaultmodel);
 485                         setsize (player, m1, m2);
 486                         chmdl = true;
 487                 }
 488
 489                 oldskin = player.skin;
 490                 player.skin = defaultskin;
 491         } else {
 492                 if (player.playermodel != player.model || player.playermodel == "")
 493                 {
 494                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 495                         vector m1 = player.mins;
 496                         vector m2 = player.maxs;
 497                         setplayermodel (player, player.playermodel);
 498                         setsize (player, m1, m2);
 499                         chmdl = true;
 500                 }
 501
 502                 if(!autocvar_sv_defaultcharacterskin)
 503                 {
 504                         oldskin = player.skin;
 505                         player.skin = stof(player.playerskin);
 506                 }
 507                 else
 508                 {
 509                         oldskin = player.skin;
 510                         player.skin = defaultskin;
 511                 }
 512         }
 513
 514         if(chmdl || oldskin != player.skin) // model or skin has changed
 515         {
 516                 player.species = player_getspecies(player); // update species
 517                 if(!autocvar_g_debug_globalsounds)
 518                         UpdatePlayerSounds(player); // update skin sounds
 519         }
 520
 521         if(!teamplay)
 522                 if(strlen(autocvar_sv_defaultplayercolors))
 523                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 524                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 525 }
 526
 527 void PutPlayerInServer(entity this)
 528 {
 529         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 530
 531         PlayerState_attach(this);
 532         accuracy_resend(this);
 533
 534         if (this.team < 0)
 535                 TeamBalance_JoinBestTeam(this);
 536
 537         entity spot = SelectSpawnPoint(this, false);
 538         if (!spot) {
 539                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 540                 return; // spawn failed
 541         }
 542
 543         TRANSMUTE(Player, this);
 544
 545         CS(this).wasplayer = true;
 546         this.iscreature = true;
 547         this.teleportable = TELEPORT_NORMAL;
 548         if(!this.damagedbycontents)
 549                 IL_PUSH(g_damagedbycontents, this);
 550         this.damagedbycontents = true;
 551         set_movetype(this, MOVETYPE_WALK);
 552         this.solid = SOLID_SLIDEBOX;
 553         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 554         if (autocvar_g_playerclip_collisions)
 555                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 556         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 557                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 558         this.frags = FRAGS_PLAYER;
 559         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 560         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 561         if (autocvar__notarget)
 562                 this.flags |= FL_NOTARGET;
 563         this.takedamage = DAMAGE_AIM;
 564         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 565
 566         if (warmup_stage) {
 567                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 568                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 569                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 570                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 571                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 572                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 573                 SetResource(this, RES_HEALTH, warmup_start_health);
 574                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 575                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 576         } else {
 577                 SetResource(this, RES_SHELLS, start_ammo_shells);
 578                 SetResource(this, RES_BULLETS, start_ammo_nails);
 579                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 580                 SetResource(this, RES_CELLS, start_ammo_cells);
 581                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 582                 SetResource(this, RES_FUEL, start_ammo_fuel);
 583                 SetResource(this, RES_HEALTH, start_health);
 584                 SetResource(this, RES_ARMOR, start_armorvalue);
 585                 STAT(WEAPONS, this) = start_weapons;
 586                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 587                 {
 588                         GiveRandomWeapons(this, random_start_weapons_count,
 589                                 autocvar_g_random_start_weapons, random_start_ammo);
 590                 }
 591         }
 592         SetSpectatee_status(this, 0);
 593
 594         PS(this).dual_weapons = '0 0 0';
 595
 596         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 597
 598         this.items = start_items;
 599
 600         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 601         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 602         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 603         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 604         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 605         if (!sv_ready_restart_after_countdown && time < game_starttime)
 606         {
 607                 float f = game_starttime - time;
 608                 this.spawnshieldtime += f;
 609                 this.pauserotarmor_finished += f;
 610                 this.pauserothealth_finished += f;
 611                 this.pauseregen_finished += f;
 612         }
 613
 614         this.damageforcescale = autocvar_g_player_damageforcescale;
 615         this.death_time = 0;
 616         this.respawn_flags = 0;
 617         this.respawn_time = 0;
 618         STAT(RESPAWN_TIME, this) = 0;
 619         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 620         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 621         this.fade_time = 0;
 622         this.pain_finished = 0;
 623         this.pushltime = 0;
 624         setthink(this, func_null); // players have no think function
 625         this.nextthink = 0;
 626         this.dmg_team = 0;
 627         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 628
 629         this.deadflag = DEAD_NO;
 630
 631         this.angles = spot.angles;
 632         this.angles_z = 0; // never spawn tilted even if the spot says to
 633         if (IS_BOT_CLIENT(this))
 634         {
 635                 this.v_angle = this.angles;
 636                 bot_aim_reset(this);
 637         }
 638         this.fixangle = true; // turn this way immediately
 639         this.oldvelocity = this.velocity = '0 0 0';
 640         this.avelocity = '0 0 0';
 641         this.punchangle = '0 0 0';
 642         this.punchvector = '0 0 0';
 643
 644         STAT(STRENGTH_FINISHED, this) = 0;
 645         STAT(INVINCIBLE_FINISHED, this) = 0;
 646         this.fire_endtime = -1;
 647         STAT(REVIVE_PROGRESS, this) = 0;
 648         this.revival_time = 0;
 649
 650         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 651         STAT(BUFFS, this) = 0;
 652         STAT(BUFF_TIME, this) = 0;
 653
 654         STAT(AIR_FINISHED, this) = 0;
 655         this.waterlevel = WATERLEVEL_NONE;
 656         this.watertype = CONTENT_EMPTY;
 657
 658         entity spawnevent = new_pure(spawnevent);
 659         spawnevent.owner = this;
 660         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 661
 662         // Cut off any still running player sounds.
 663         stopsound(this, CH_PLAYER_SINGLE);
 664
 665         this.model = "";
 666         FixPlayermodel(this);
 667         this.drawonlytoclient = NULL;
 668
 669         this.viewloc = NULL;
 670
 671         for(int slot = 0; slot < MAX_AXH; ++slot)
 672         {
 673                 entity axh = this.(AuxiliaryXhair[slot]);
 674                 this.(AuxiliaryXhair[slot]) = NULL;
 675
 676                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 677                         delete(axh);
 678         }
 679
 680         this.spawnpoint_targ = NULL;
 681
 682         UNSET_DUCKED(this);
 683         this.view_ofs = STAT(PL_VIEW_OFS, this);
 684         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 685         this.spawnorigin = spot.origin;
 686         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 687         // don't reset back to last position, even if new position is stuck in solid
 688         this.oldorigin = this.origin;
 689         if(this.conveyor)
 690                 IL_REMOVE(g_conveyed, this);
 691         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 692         if(this.swampslug)
 693                 IL_REMOVE(g_swamped, this);
 694         this.swampslug = NULL;
 695         this.swamp_interval = 0;
 696         if(this.ladder_entity)
 697                 IL_REMOVE(g_ladderents, this);
 698         this.ladder_entity = NULL;
 699         IL_EACH(g_counters, it.realowner == this,
 700         {
 701                 delete(it);
 702         });
 703         STAT(HUD, this) = HUD_NORMAL;
 704
 705         this.event_damage = PlayerDamage;
 706         this.event_heal = PlayerHeal;
 707
 708         this.draggable = func_null;
 709
 710         if(!this.bot_attack)
 711                 IL_PUSH(g_bot_targets, this);
 712         this.bot_attack = true;
 713         if(!this.monster_attack)
 714                 IL_PUSH(g_monster_targets, this);
 715         this.monster_attack = true;
 716         navigation_dynamicgoal_init(this, false);
 717
 718         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 719
 720         // player was spectator
 721         if (CS(this).killcount == FRAGS_SPECTATOR) {
 722                 PlayerScore_Clear(this);
 723                 CS(this).killcount = 0;
 724                 CS(this).startplaytime = time;
 725         }
 726
 727         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 728         {
 729                 .entity weaponentity = weaponentities[slot];
 730                 CL_SpawnWeaponentity(this, weaponentity);
 731         }
 732         this.alpha = default_player_alpha;
 733         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 734         this.exteriorweaponentity.alpha = default_weapon_alpha;
 735
 736         this.speedrunning = false;
 737
 738         this.counter_cnt = 0;
 739         this.fragsfilter_cnt = 0;
 740
 741         target_voicescript_clear(this);
 742
 743         // reset fields the weapons may use
 744         FOREACH(Weapons, true, {
 745                 it.wr_resetplayer(it, this);
 746                         // reload all reloadable weapons
 747                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 748                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 749                         {
 750                                 .entity weaponentity = weaponentities[slot];
 751                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 752                         }
 753                 }
 754         });
 755
 756         {
 757                 string s = spot.target;
 758                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 759                         spot.target = string_null;
 760                 SUB_UseTargets(spot, this, NULL);
 761                 if(g_assault || g_race)
 762                         spot.target = s;
 763         }
 764
 765         Unfreeze(this, false);
 766
 767         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 768
 769         if (autocvar_spawn_debug)
 770         {
 771                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 772                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 773         }
 774
 775         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 776         {
 777                 .entity weaponentity = weaponentities[slot];
 778                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 779                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 780                 else
 781                         this.(weaponentity).m_switchweapon = WEP_Null;
 782                 this.(weaponentity).m_weapon = WEP_Null;
 783                 this.(weaponentity).weaponname = "";
 784                 this.(weaponentity).m_switchingweapon = WEP_Null;
 785                 this.(weaponentity).cnt = -1;
 786         }
 787
 788         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 789
 790         if (CS(this).impulse) ImpulseCommands(this);
 791
 792         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 793         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 794         {
 795                 .entity weaponentity = weaponentities[slot];
 796                 W_WeaponFrame(this, weaponentity);
 797         }
 798
 799         if (!warmup_stage && !this.alivetime)
 800                 this.alivetime = time;
 801
 802         antilag_clear(this, CS(this));
 803 }
 804
 805 /** Called when a client spawns in the server */
 806 void PutClientInServer(entity this)
 807 {
 808         if (IS_BOT_CLIENT(this)) {
 809                 TRANSMUTE(Player, this);
 810         } else if (IS_REAL_CLIENT(this)) {
 811                 msg_entity = this;
 812                 WriteByte(MSG_ONE, SVC_SETVIEW);
 813                 WriteEntity(MSG_ONE, this);
 814         }
 815         if (game_stopped)
 816                 TRANSMUTE(Observer, this);
 817
 818         SetSpectatee(this, NULL);
 819
 820         // reset player keys
 821         if(PS(this))
 822                 PS(this).itemkeys = 0;
 823
 824         MUTATOR_CALLHOOK(PutClientInServer, this);
 825
 826         if (IS_OBSERVER(this)) {
 827                 PutObserverInServer(this);
 828         } else if (IS_PLAYER(this)) {
 829                 PutPlayerInServer(this);
 830         }
 831
 832         bot_relinkplayerlist();
 833 }
 834
 835 // TODO do we need all these fields, or should we stop autodetecting runtime
 836 // changes and just have a console command to update this?
 837 bool ClientInit_SendEntity(entity this, entity to, int sf)
 838 {
 839         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 840         return = true;
 841         msg_entity = to;
 842         // MSG_INIT replacement
 843         // TODO: make easier to use
 844         Registry_send_all();
 845         W_PROP_reload(MSG_ONE, to);
 846         ClientInit_misc(this);
 847         MUTATOR_CALLHOOK(Ent_Init);
 848 }
 849 void ClientInit_misc(entity this)
 850 {
 851         int channel = MSG_ONE;
 852         WriteHeader(channel, ENT_CLIENT_INIT);
 853         WriteByte(channel, g_nexball_meter_period * 32);
 854         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 855         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 856         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 857         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 858         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 859         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 860         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 861         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 862
 863         if(autocvar_sv_foginterval && world.fog != "")
 864                 WriteString(channel, world.fog);
 865         else
 866                 WriteString(channel, "");
 867         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 868         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 869         WriteByte(channel, serverflags);
 870         WriteCoord(channel, autocvar_g_trueaim_minrange);
 871 }
 872
 873 void ClientInit_CheckUpdate(entity this)
 874 {
 875         this.nextthink = time;
 876         if(this.count != autocvar_g_balance_armor_blockpercent)
 877         {
 878                 this.count = autocvar_g_balance_armor_blockpercent;
 879                 this.SendFlags |= 1;
 880         }
 881         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 882         {
 883                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 884                 this.SendFlags |= 1;
 885         }
 886 }
 887
 888 void ClientInit_Spawn()
 889 {
 890         entity e = new_pure(clientinit);
 891         setthink(e, ClientInit_CheckUpdate);
 892         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 893
 894         ClientInit_CheckUpdate(e);
 895 }
 896
 897 /*
 898 =============
 899 SetNewParms
 900 =============
 901 */
 902 void SetNewParms ()
 903 {
 904         // initialize parms for a new player
 905         parm1 = -(86400 * 366);
 906
 907         MUTATOR_CALLHOOK(SetNewParms);
 908 }
 909
 910 /*
 911 =============
 912 SetChangeParms
 913 =============
 914 */
 915 void SetChangeParms (entity this)
 916 {
 917         // save parms for level change
 918         parm1 = CS(this).parm_idlesince - time;
 919
 920         MUTATOR_CALLHOOK(SetChangeParms);
 921 }
 922
 923 /*
 924 =============
 925 DecodeLevelParms
 926 =============
 927 */
 928 void DecodeLevelParms(entity this)
 929 {
 930         // load parms
 931         CS(this).parm_idlesince = parm1;
 932         if (CS(this).parm_idlesince == -(86400 * 366))
 933                 CS(this).parm_idlesince = time;
 934
 935         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 936         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 937
 938         MUTATOR_CALLHOOK(DecodeLevelParms);
 939 }
 940
 941 void FixClientCvars(entity e)
 942 {
 943         // send prediction settings to the client
 944         stuffcmd(e, "\nin_bindmap 0 0\n");
 945         if(autocvar_g_antilag == 3) // client side hitscan
 946                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 947         if(autocvar_sv_gentle)
 948                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 949
 950         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 951         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 952
 953         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 954
 955         MUTATOR_CALLHOOK(FixClientCvars, e);
 956 }
 957
 958 bool findinlist_abbrev(string tofind, string list)
 959 {
 960         if(list == "" || tofind == "")
 961                 return false; // empty list or search, just return
 962
 963         // this function allows abbreviated strings!
 964         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 965         {
 966                 return true;
 967         });
 968
 969         return false;
 970 }
 971
 972 bool PlayerInIPList(entity p, string iplist)
 973 {
 974         // some safety checks (never allow local?)
 975         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 976                 return false;
 977
 978         return findinlist_abbrev(p.netaddress, iplist);
 979 }
 980
 981 bool PlayerInIDList(entity p, string idlist)
 982 {
 983         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 984         if(!p.crypto_idfp)
 985                 return false;
 986
 987         return findinlist_abbrev(p.crypto_idfp, idlist);
 988 }
 989
 990 bool PlayerInList(entity player, string list)
 991 {
 992         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 993 }
 994
 995 #ifdef DP_EXT_PRECONNECT
 996 /*
 997 =============
 998 ClientPreConnect
 999
1000 Called once (not at each match start) when a client begins a connection to the server
1001 =============
1002 */
1003 void ClientPreConnect(entity this)
1004 {
1005         if(autocvar_sv_eventlog)
1006         {
1007                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1008                         this.playerid,
1009                         etof(this),
1010                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1011                 ));
1012         }
1013 }
1014 #endif
1015
1016 string GetClientVersionMessage(entity this)
1017 {
1018         if (CS(this).version_mismatch) {
1019                 if(CS(this).version < autocvar_gameversion) {
1020                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1021                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1022                 } else {
1023                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1024                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1025                 }
1026         } else {
1027                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1028         }
1029 }
1030
1031 string getwelcomemessage(entity this)
1032 {
1033         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1034         string modifications = M_ARGV(0, string);
1035
1036         if(g_weaponarena)
1037         {
1038                 if(g_weaponarena_random)
1039                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1040                 else
1041                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1042         }
1043         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1044                 modifications = strcat(modifications, ", No start weapons");
1045         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1046                 modifications = strcat(modifications, ", Low gravity");
1047         if(g_weapon_stay && !g_cts)
1048                 modifications = strcat(modifications, ", Weapons stay");
1049         if(autocvar_g_jetpack)
1050                 modifications = strcat(modifications, ", Jet pack");
1051         if(autocvar_g_powerups == 0)
1052                 modifications = strcat(modifications, ", No powerups");
1053         if(autocvar_g_powerups > 0)
1054                 modifications = strcat(modifications, ", Powerups");
1055         modifications = substring(modifications, 2, strlen(modifications) - 2);
1056
1057         string versionmessage = GetClientVersionMessage(this);
1058         string s = strcat(versionmessage, "^8\n^8\nhost is ^9", autocvar_hostname, "^8\n");
1059
1060         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1061
1062         if(modifications != "")
1063                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1064
1065         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1066         {
1067                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1068                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1069         }
1070
1071         if (cache_mutatormsg != "") {
1072                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1073         }
1074
1075         string mutator_msg = "";
1076         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1077         mutator_msg = M_ARGV(0, string);
1078
1079         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1080
1081         string motd = autocvar_sv_motd;
1082         if (motd != "") {
1083                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1084         }
1085         return s;
1086 }
1087
1088 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1089
1090 /**
1091 =============
1092 ClientConnect
1093
1094 Called when a client connects to the server
1095 =============
1096 */
1097 void ClientConnect(entity this)
1098 {
1099         if (Ban_MaybeEnforceBanOnce(this)) return;
1100         assert(!IS_CLIENT(this), return);
1101         this.flags |= FL_CLIENT;
1102         assert(player_count >= 0, player_count = 0);
1103
1104         TRANSMUTE(Client, this);
1105         CS(this).version_nagtime = time + 10 + random() * 10;
1106
1107         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1108
1109         bot_clientconnect(this);
1110
1111         Player_DetermineForcedTeam(this);
1112
1113         TRANSMUTE(Observer, this);
1114
1115         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1116
1117         // always track bots, don't ask for cl_allow_uidtracking
1118         if (IS_BOT_CLIENT(this))
1119                 PlayerStats_GameReport_AddPlayer(this);
1120         else
1121                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1122
1123         if (autocvar_sv_eventlog)
1124                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1125
1126         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1127
1128         stuffcmd(this, clientstuff, "\n");
1129         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1130
1131         FixClientCvars(this);
1132
1133         // get version info from player
1134         stuffcmd(this, "cmd clientversion $gameversion\n");
1135
1136         // notify about available teams
1137         if (teamplay)
1138         {
1139                 entity balance = TeamBalance_CheckAllowedTeams(this);
1140                 int t = TeamBalance_GetAllowedTeams(balance);
1141                 TeamBalance_Destroy(balance);
1142                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1143         }
1144         else
1145         {
1146                 stuffcmd(this, "set _teams_available 0\n");
1147         }
1148
1149         bot_relinkplayerlist();
1150
1151         CS(this).spectatortime = time;
1152         if (blockSpectators)
1153         {
1154                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1155         }
1156
1157         CS(this).jointime = time;
1158
1159         if (IS_REAL_CLIENT(this))
1160         {
1161                 if (g_weaponarena_weapons == WEPSET(TUBA))
1162                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1163         }
1164
1165         if (!autocvar_sv_foginterval && world.fog != "")
1166                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1167
1168         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1169                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1170                         send_CSQC_teamnagger();
1171
1172         CSQCMODEL_AUTOINIT(this);
1173
1174         CS(this).model_randomizer = random();
1175
1176         if (IS_REAL_CLIENT(this))
1177                 sv_notice_join(this);
1178
1179         this.move_qcphysics = autocvar_sv_qcphysics;
1180
1181         // update physics stats (players can spawn before physics runs)
1182         Physics_UpdateStats(this);
1183
1184         IL_EACH(g_initforplayer, it.init_for_player, {
1185                 it.init_for_player(it, this);
1186         });
1187
1188         Handicap_Initialize(this);
1189
1190         MUTATOR_CALLHOOK(ClientConnect, this);
1191
1192         if (IS_REAL_CLIENT(this))
1193         {
1194                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1195                 {
1196                         CS(this).motd_actived_time = -1;
1197                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1198                 }
1199         }
1200 }
1201 /*
1202 =============
1203 ClientDisconnect
1204
1205 Called when a client disconnects from the server
1206 =============
1207 */
1208 .entity chatbubbleentity;
1209 void player_powerups_remove_all(entity this);
1210
1211 void ClientDisconnect(entity this)
1212 {
1213         assert(IS_CLIENT(this), return);
1214
1215         PlayerStats_GameReport_FinalizePlayer(this);
1216         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1217         if (CS(this).active_minigame) part_minigame(this);
1218         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1219
1220         if (autocvar_sv_eventlog)
1221                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1222
1223         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1224
1225         if(IS_SPEC(this))
1226                 SetSpectatee(this, NULL);
1227
1228         MUTATOR_CALLHOOK(ClientDisconnect, this);
1229
1230         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1231         strfree(CS_CVAR(this).weaponorder_byimpulse);
1232         ClientState_detach(this);
1233
1234         Portal_ClearAll(this);
1235
1236         Unfreeze(this, false);
1237
1238         RemoveGrapplingHooks(this);
1239
1240         // Here, everything has been done that requires this player to be a client.
1241
1242         this.flags &= ~FL_CLIENT;
1243
1244         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1245         if (this.killindicator) delete(this.killindicator);
1246
1247         IL_EACH(g_counters, it.realowner == this,
1248         {
1249                 delete(it);
1250         });
1251
1252         WaypointSprite_PlayerGone(this);
1253
1254         bot_relinkplayerlist();
1255
1256         strfree(this.clientstatus);
1257         if (this.personal) delete(this.personal);
1258
1259         this.playerid = 0;
1260         ReadyCount();
1261         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1262
1263         player_powerups_remove_all(this); // stop powerup sound
1264
1265         ONREMOVE(this);
1266 }
1267
1268 void ChatBubbleThink(entity this)
1269 {
1270         this.nextthink = time;
1271         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1272         {
1273                 if(this.owner) // but why can that ever be NULL?
1274                         this.owner.chatbubbleentity = NULL;
1275                 delete(this);
1276                 return;
1277         }
1278
1279         this.mdl = "";
1280
1281         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1282         {
1283                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1284                         this.mdl = "models/sprites/minigame_busy.iqm";
1285                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1286                         this.mdl = "models/misc/chatbubble.spr";
1287         }
1288
1289         if ( this.model != this.mdl )
1290                 _setmodel(this, this.mdl);
1291
1292 }
1293
1294 void UpdateChatBubble(entity this)
1295 {
1296         if (this.alpha < 0)
1297                 return;
1298         // spawn a chatbubble entity if needed
1299         if (!this.chatbubbleentity)
1300         {
1301                 this.chatbubbleentity = new(chatbubbleentity);
1302                 this.chatbubbleentity.owner = this;
1303                 this.chatbubbleentity.exteriormodeltoclient = this;
1304                 setthink(this.chatbubbleentity, ChatBubbleThink);
1305                 this.chatbubbleentity.nextthink = time;
1306                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1307                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1308                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1309                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1310                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1311                 //this.chatbubbleentity.model = "";
1312                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1313         }
1314 }
1315
1316 void calculate_player_respawn_time(entity this)
1317 {
1318         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1319                 return;
1320
1321         float gametype_setting_tmp;
1322         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1323         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1324         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1325         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1326         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1327         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1328
1329         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1330         if (teamplay)
1331         {
1332                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1333                         if(it.team == this.team)
1334                                 ++pcount;
1335                 });
1336                 if (sdelay_small_count == 0)
1337                         sdelay_small_count = 1;
1338                 if (sdelay_large_count == 0)
1339                         sdelay_large_count = 1;
1340         }
1341         else
1342         {
1343                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1344                         ++pcount;
1345                 });
1346                 if (sdelay_small_count == 0)
1347                 {
1348                         if (IS_INDEPENDENT_PLAYER(this))
1349                         {
1350                                 // Players play independently. No point in requiring enemies.
1351                                 sdelay_small_count = 1;
1352                         }
1353                         else
1354                         {
1355                                 // Players play AGAINST each other. Enemies required.
1356                                 sdelay_small_count = 2;
1357                         }
1358                 }
1359                 if (sdelay_large_count == 0)
1360                 {
1361                         if (IS_INDEPENDENT_PLAYER(this))
1362                         {
1363                                 // Players play independently. No point in requiring enemies.
1364                                 sdelay_large_count = 1;
1365                         }
1366                         else
1367                         {
1368                                 // Players play AGAINST each other. Enemies required.
1369                                 sdelay_large_count = 2;
1370                         }
1371                 }
1372         }
1373
1374         float sdelay;
1375
1376         if (pcount <= sdelay_small_count)
1377                 sdelay = sdelay_small;
1378         else if (pcount >= sdelay_large_count)
1379                 sdelay = sdelay_large;
1380         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1381                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1382
1383         if(waves)
1384                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1385         else
1386                 this.respawn_time = time + sdelay;
1387
1388         if(sdelay < sdelay_max)
1389                 this.respawn_time_max = time + sdelay_max;
1390         else
1391                 this.respawn_time_max = this.respawn_time;
1392
1393         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1394                 this.respawn_countdown = 10; // first number to count down from is 10
1395         else
1396                 this.respawn_countdown = -1; // do not count down
1397
1398         if(autocvar_g_forced_respawn)
1399                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1400 }
1401
1402 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1403 // added to the model skins
1404 /*void UpdateColorModHack()
1405 {
1406         float c;
1407         c = this.clientcolors & 15;
1408         // LordHavoc: only bothering to support white, green, red, yellow, blue
1409              if (!teamplay) this.colormod = '0 0 0';
1410         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1411         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1412         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1413         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1414         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1415         else this.colormod = '1 1 1';
1416 }*/
1417
1418 void respawn(entity this)
1419 {
1420         bool damagedbycontents_prev = this.damagedbycontents;
1421         if(this.alpha >= 0)
1422         {
1423                 if(autocvar_g_respawn_ghosts)
1424                 {
1425                         this.solid = SOLID_NOT;
1426                         this.takedamage = DAMAGE_NO;
1427                         this.damagedbycontents = false;
1428                         set_movetype(this, MOVETYPE_FLY);
1429                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1430                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1431                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1432                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1433                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1434                         if(autocvar_g_respawn_ghosts_time > 0)
1435                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1436                 }
1437                 else
1438                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1439         }
1440
1441         CopyBody(this, 1);
1442         this.damagedbycontents = damagedbycontents_prev;
1443
1444         this.effects |= EF_NODRAW; // prevent another CopyBody
1445         PutClientInServer(this);
1446 }
1447
1448 void play_countdown(entity this, float finished, Sound samp)
1449 {
1450         TC(Sound, samp);
1451         if(IS_REAL_CLIENT(this))
1452                 if(floor(finished - time - frametime) != floor(finished - time))
1453                         if(finished - time < 6)
1454                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1455 }
1456
1457 void player_powerups_remove_all(entity this)
1458 {
1459         if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1460         {
1461                 // don't play the poweroff sound when the game restarts or the player disconnects
1462                 if (time > game_starttime + 1 && IS_CLIENT(this))
1463                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1464                 stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1465                 this.items &= ~ITEM_Strength.m_itemid;
1466                 this.items &= ~ITEM_Shield.m_itemid;
1467                 this.items -= (this.items & IT_SUPERWEAPON);
1468         }
1469 }
1470
1471 void player_powerups(entity this)
1472 {
1473         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1474                 this.modelflags |= MF_ROCKET;
1475         else
1476                 this.modelflags &= ~MF_ROCKET;
1477
1478         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1479
1480         if (IS_DEAD(this))
1481                 player_powerups_remove_all(this);
1482
1483         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1484                 return;
1485
1486         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1487         int items_prev = this.items;
1488
1489         Fire_ApplyDamage(this);
1490         Fire_ApplyEffect(this);
1491
1492         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1493         {
1494                 if (this.items & ITEM_Strength.m_itemid)
1495                 {
1496                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1497                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1498                         if (time > STAT(STRENGTH_FINISHED, this))
1499                         {
1500                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1501                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1502                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1503                         }
1504                 }
1505                 else
1506                 {
1507                         if (time < STAT(STRENGTH_FINISHED, this))
1508                         {
1509                                 this.items = this.items | ITEM_Strength.m_itemid;
1510                                 if(!g_cts)
1511                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1512                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1513                         }
1514                 }
1515                 if (this.items & ITEM_Shield.m_itemid)
1516                 {
1517                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1518                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1519                         if (time > STAT(INVINCIBLE_FINISHED, this))
1520                         {
1521                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1522                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1523                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1524                         }
1525                 }
1526                 else
1527                 {
1528                         if (time < STAT(INVINCIBLE_FINISHED, this))
1529                         {
1530                                 this.items = this.items | ITEM_Shield.m_itemid;
1531                                 if(!g_cts)
1532                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1533                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1534                         }
1535                 }
1536                 if (this.items & IT_SUPERWEAPON)
1537                 {
1538                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1539                         {
1540                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1541                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1542                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1543                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1544                         }
1545                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1546                         {
1547                                 // don't let them run out
1548                         }
1549                         else
1550                         {
1551                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1552                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1553                                 {
1554                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1555                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1556                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1557                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1558                                 }
1559                         }
1560                 }
1561                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1562                 {
1563                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1564                         {
1565                                 this.items = this.items | IT_SUPERWEAPON;
1566                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1567                                 {
1568                                         if(!g_cts)
1569                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1570                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1571                                 }
1572                         }
1573                         else
1574                         {
1575                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1576                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1577                         }
1578                 }
1579                 else
1580                 {
1581                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1582                 }
1583         }
1584
1585         if(autocvar_g_nodepthtestplayers)
1586                 this.effects = this.effects | EF_NODEPTHTEST;
1587
1588         if(autocvar_g_fullbrightplayers)
1589                 this.effects = this.effects | EF_FULLBRIGHT;
1590
1591         if (time >= game_starttime)
1592         if (time < this.spawnshieldtime)
1593                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1594
1595         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1596 }
1597
1598 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1599 {
1600         if(current > stable)
1601                 return current;
1602         else if(current > stable - 0.25) // when close enough, "snap"
1603                 return stable;
1604         else
1605                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1606 }
1607
1608 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1609 {
1610         if(current < stable)
1611                 return current;
1612         else if(current < stable + 0.25) // when close enough, "snap"
1613                 return stable;
1614         else
1615                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1616 }
1617
1618 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1619 {
1620         float old = GetResource(this, res);
1621         float current = old;
1622         if(current > rotstable)
1623         {
1624                 if(rotframetime > 0)
1625                 {
1626                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1627                         current = max(rotstable, current - rotlinear * rotframetime);
1628                 }
1629         }
1630         else if(current < regenstable)
1631         {
1632                 if(regenframetime > 0)
1633                 {
1634                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1635                         current = min(regenstable, current + regenlinear * regenframetime);
1636                 }
1637         }
1638
1639         float limit = GetResourceLimit(this, res) * limit_mod;
1640         if(current > limit)
1641                 current = limit;
1642
1643         if (current != old)
1644                 SetResource(this, res, current);
1645 }
1646
1647 void player_regen(entity this)
1648 {
1649         float max_mod, regen_mod, rot_mod, limit_mod;
1650         max_mod = regen_mod = rot_mod = limit_mod = 1;
1651
1652         float regen_health = autocvar_g_balance_health_regen;
1653         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1654         float regen_health_rot = autocvar_g_balance_health_rot;
1655         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1656         float regen_health_stable = autocvar_g_balance_health_regenstable;
1657         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1658         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1659                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1660         max_mod = M_ARGV(1, float);
1661         regen_mod = M_ARGV(2, float);
1662         rot_mod = M_ARGV(3, float);
1663         limit_mod = M_ARGV(4, float);
1664         regen_health = M_ARGV(5, float);
1665         regen_health_linear = M_ARGV(6, float);
1666         regen_health_rot = M_ARGV(7, float);
1667         regen_health_rotlinear = M_ARGV(8, float);
1668         regen_health_stable = M_ARGV(9, float);
1669         regen_health_rotstable = M_ARGV(10, float);
1670
1671         if(!mutator_returnvalue)
1672         if(!STAT(FROZEN, this))
1673         {
1674                 float maxa = autocvar_g_balance_armor_rotstable;
1675                 float mina = autocvar_g_balance_armor_regenstable;
1676
1677                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1678                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1679                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1680
1681                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1682                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1683                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1684         }
1685
1686         // if player rotted to death...  die!
1687         // check this outside above checks, as player may still be able to rot to death
1688         if(GetResource(this, RES_HEALTH) < 1)
1689         {
1690                 if(this.vehicle)
1691                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1692                 if(this.event_damage)
1693                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1694         }
1695
1696         if (!(this.items & IT_UNLIMITED_AMMO))
1697         {
1698                 float maxf = autocvar_g_balance_fuel_rotstable;
1699                 float minf = autocvar_g_balance_fuel_regenstable;
1700
1701                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1702                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1703                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1704         }
1705 }
1706
1707 bool zoomstate_set;
1708 void SetZoomState(entity this, float newzoom)
1709 {
1710         if(newzoom != CS(this).zoomstate)
1711         {
1712                 CS(this).zoomstate = newzoom;
1713                 ClientData_Touch(this);
1714         }
1715         zoomstate_set = true;
1716 }
1717
1718 void GetPressedKeys(entity this)
1719 {
1720         MUTATOR_CALLHOOK(GetPressedKeys, this);
1721         if (game_stopped)
1722         {
1723                 CS(this).pressedkeys = 0;
1724                 STAT(PRESSED_KEYS, this) = 0;
1725                 return;
1726         }
1727
1728         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1729         int keys = STAT(PRESSED_KEYS, this);
1730         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1731         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1732         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1733         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1734
1735         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1736         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1737         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1738         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1739         CS(this).pressedkeys = keys; // store for other users
1740
1741         STAT(PRESSED_KEYS, this) = keys;
1742 }
1743
1744 /*
1745 ======================
1746 spectate mode routines
1747 ======================
1748 */
1749
1750 void SpectateCopy(entity this, entity spectatee)
1751 {
1752         TC(Client, this); TC(Client, spectatee);
1753
1754         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1755         PS(this) = PS(spectatee);
1756         this.armortype = spectatee.armortype;
1757         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1758         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1759         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1760         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1761         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1762         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1763         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1764         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1765         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1766         CS(this).impulse = 0;
1767         this.disableclientprediction = 1; // no need to run prediction on a spectator
1768         this.items = spectatee.items;
1769         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1770         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1771         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1772         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1773         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1774         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1775         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1776         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1777         this.punchangle = spectatee.punchangle;
1778         this.view_ofs = spectatee.view_ofs;
1779         this.velocity = spectatee.velocity;
1780         this.dmg_take = spectatee.dmg_take;
1781         this.dmg_save = spectatee.dmg_save;
1782         this.dmg_inflictor = spectatee.dmg_inflictor;
1783         this.v_angle = spectatee.v_angle;
1784         this.angles = spectatee.v_angle;
1785         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1786         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1787         this.viewloc = spectatee.viewloc;
1788         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1789                 this.fixangle = true;
1790         setorigin(this, spectatee.origin);
1791         setsize(this, spectatee.mins, spectatee.maxs);
1792         SetZoomState(this, CS(spectatee).zoomstate);
1793
1794     anticheat_spectatecopy(this, spectatee);
1795         STAT(HUD, this) = STAT(HUD, spectatee);
1796         if(spectatee.vehicle)
1797     {
1798         this.angles = spectatee.v_angle;
1799
1800         //this.fixangle = false;
1801         //this.velocity = spectatee.vehicle.velocity;
1802         this.vehicle_health = spectatee.vehicle_health;
1803         this.vehicle_shield = spectatee.vehicle_shield;
1804         this.vehicle_energy = spectatee.vehicle_energy;
1805         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1806         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1807         this.vehicle_reload1 = spectatee.vehicle_reload1;
1808         this.vehicle_reload2 = spectatee.vehicle_reload2;
1809
1810         //msg_entity = this;
1811
1812        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1813             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1814            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1815            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1816
1817         //WriteByte (MSG_ONE, SVC_SETVIEW);
1818         //    WriteEntity(MSG_ONE, this);
1819         //makevectors(spectatee.v_angle);
1820         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1821     }
1822 }
1823
1824 bool SpectateUpdate(entity this)
1825 {
1826         if(!this.enemy)
1827                 return false;
1828
1829         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1830         {
1831                 SetSpectatee(this, NULL);
1832                 return false;
1833         }
1834
1835         SpectateCopy(this, this.enemy);
1836
1837         return true;
1838 }
1839
1840 bool SpectateSet(entity this)
1841 {
1842         if(!IS_PLAYER(this.enemy))
1843                 return false;
1844
1845         ClientData_Touch(this.enemy);
1846
1847         msg_entity = this;
1848         WriteByte(MSG_ONE, SVC_SETVIEW);
1849         WriteEntity(MSG_ONE, this.enemy);
1850         set_movetype(this, MOVETYPE_NONE);
1851         accuracy_resend(this);
1852
1853         if(!SpectateUpdate(this))
1854                 PutObserverInServer(this);
1855
1856         return true;
1857 }
1858
1859 void SetSpectatee_status(entity this, int spectatee_num)
1860 {
1861         int oldspectatee_status = CS(this).spectatee_status;
1862         CS(this).spectatee_status = spectatee_num;
1863
1864         if (CS(this).spectatee_status != oldspectatee_status)
1865         {
1866                 if (STAT(PRESSED_KEYS, this))
1867                 {
1868                         CS(this).pressedkeys = 0;
1869                         STAT(PRESSED_KEYS, this) = 0;
1870                 }
1871                 ClientData_Touch(this);
1872                 if (g_race || g_cts) race_InitSpectator();
1873         }
1874 }
1875
1876 void SetSpectatee(entity this, entity spectatee)
1877 {
1878         if(IS_BOT_CLIENT(this))
1879                 return; // bots abuse .enemy, this code is useless to them
1880
1881         entity old_spectatee = this.enemy;
1882
1883         this.enemy = spectatee;
1884
1885         // WEAPONTODO
1886         // these are required to fix the spectator bug with arc
1887         if(old_spectatee)
1888         {
1889                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1890                 {
1891                         .entity weaponentity = weaponentities[slot];
1892                         if(old_spectatee.(weaponentity).arc_beam)
1893                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1894                 }
1895         }
1896         if(this.enemy)
1897         {
1898                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1899                 {
1900                         .entity weaponentity = weaponentities[slot];
1901                         if(this.enemy.(weaponentity).arc_beam)
1902                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1903                 }
1904         }
1905
1906         if (this.enemy)
1907                 SetSpectatee_status(this, etof(this.enemy));
1908
1909         // needed to update spectator list
1910         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1911 }
1912
1913 bool Spectate(entity this, entity pl)
1914 {
1915         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1916                 return false;
1917         pl = M_ARGV(1, entity);
1918
1919         SetSpectatee(this, pl);
1920         return SpectateSet(this);
1921 }
1922
1923 bool SpectateNext(entity this)
1924 {
1925         entity ent = find(this.enemy, classname, STR_PLAYER);
1926
1927         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1928                 ent = M_ARGV(1, entity);
1929         else if (!ent)
1930                 ent = find(ent, classname, STR_PLAYER);
1931
1932         if(ent) { SetSpectatee(this, ent); }
1933
1934         return SpectateSet(this);
1935 }
1936
1937 bool SpectatePrev(entity this)
1938 {
1939         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1940         entity ent = findchain(classname, STR_PLAYER);
1941         if (!ent) // no player
1942                 return false;
1943
1944         entity first = ent;
1945         // skip players until current spectated player
1946         if(this.enemy)
1947         while(ent && ent != this.enemy)
1948                 ent = ent.chain;
1949
1950         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1951         {
1952                 case MUT_SPECPREV_FOUND:
1953                         ent = M_ARGV(1, entity);
1954                         break;
1955                 case MUT_SPECPREV_RETURN:
1956                         return true;
1957                 case MUT_SPECPREV_CONTINUE:
1958                 default:
1959                 {
1960                         if(ent.chain)
1961                                 ent = ent.chain;
1962                         else
1963                                 ent = first;
1964                         break;
1965                 }
1966         }
1967
1968         SetSpectatee(this, ent);
1969         return SpectateSet(this);
1970 }
1971
1972 /*
1973 =============
1974 ShowRespawnCountdown()
1975
1976 Update a respawn countdown display.
1977 =============
1978 */
1979 void ShowRespawnCountdown(entity this)
1980 {
1981         float number;
1982         if(!IS_DEAD(this)) // just respawned?
1983                 return;
1984         else
1985         {
1986                 number = ceil(this.respawn_time - time);
1987                 if(number <= 0)
1988                         return;
1989                 if(number <= this.respawn_countdown)
1990                 {
1991                         this.respawn_countdown = number - 1;
1992                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1993                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1994                 }
1995         }
1996 }
1997
1998 .bool team_selected;
1999 bool ShowTeamSelection(entity this)
2000 {
2001         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
2002                 return false;
2003         stuffcmd(this, "menu_showteamselect\n");
2004         return true;
2005 }
2006 void Join(entity this)
2007 {
2008         TRANSMUTE(Player, this);
2009
2010         if(!this.team_selected)
2011         if(autocvar_g_campaign || autocvar_g_balance_teams)
2012                 TeamBalance_JoinBestTeam(this);
2013
2014         if(autocvar_g_campaign)
2015                 campaign_bots_may_start = true;
2016
2017         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2018
2019         PutClientInServer(this);
2020
2021         if(IS_PLAYER(this))
2022         if(teamplay && this.team != -1)
2023         {
2024         }
2025         else
2026                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2027         this.team_selected = false;
2028 }
2029
2030 int GetPlayerLimit()
2031 {
2032         if(g_duel)
2033                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2034         int player_limit = autocvar_g_maxplayers;
2035         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2036         player_limit = M_ARGV(0, int);
2037         return player_limit;
2038 }
2039
2040 /**
2041  * Determines whether the player is allowed to join. This depends on cvar
2042  * g_maxplayers, if it isn't used this function always return true, otherwise
2043  * it checks whether the number of currently playing players exceeds g_maxplayers.
2044  * @return int number of free slots for players, 0 if none
2045  */
2046 int nJoinAllowed(entity this, entity ignore)
2047 {
2048         if(!ignore)
2049         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2050         // so report 0 free slots if restricted
2051         {
2052                 if(autocvar_g_forced_team_otherwise == "spectate")
2053                         return 0;
2054                 if(autocvar_g_forced_team_otherwise == "spectator")
2055                         return 0;
2056         }
2057
2058         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2059                 return 0; // forced spectators can never join
2060
2061         // TODO simplify this
2062         int totalClients = 0;
2063         int currentlyPlaying = 0;
2064         FOREACH_CLIENT(true, {
2065                 if(it != ignore)
2066                         ++totalClients;
2067                 if(IS_REAL_CLIENT(it))
2068                 if(IS_PLAYER(it) || it.caplayer)
2069                         ++currentlyPlaying;
2070         });
2071
2072         int player_limit = GetPlayerLimit();
2073
2074         int free_slots = 0;
2075         if (!player_limit)
2076                 free_slots = maxclients - totalClients;
2077         else if(player_limit > 0 && currentlyPlaying < player_limit)
2078                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2079
2080         static float msg_time = 0;
2081         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2082         {
2083                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2084                 msg_time = time + 0.5;
2085         }
2086
2087         return free_slots;
2088 }
2089
2090 /**
2091  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2092  * g_maxplayers_spectator_blocktime seconds
2093  */
2094 void checkSpectatorBlock(entity this)
2095 {
2096         if(IS_SPEC(this) || IS_OBSERVER(this))
2097         if(!this.caplayer)
2098         if(IS_REAL_CLIENT(this))
2099         {
2100                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2101                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2102                         dropclient(this);
2103                 }
2104         }
2105 }
2106
2107 void PrintWelcomeMessage(entity this)
2108 {
2109         if(CS(this).motd_actived_time == 0)
2110         {
2111                 if (autocvar_g_campaign) {
2112                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2113                                 CS(this).motd_actived_time = time;
2114                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2115                         }
2116                 } else {
2117                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2118                                 CS(this).motd_actived_time = time;
2119                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2120                         }
2121                 }
2122         }
2123         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2124         {
2125                 if (autocvar_g_campaign) {
2126                         if (PHYS_INPUT_BUTTON_INFO(this))
2127                                 CS(this).motd_actived_time = time;
2128                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2129                                 CS(this).motd_actived_time = 0;
2130                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2131                         }
2132                 } else {
2133                         if (PHYS_INPUT_BUTTON_INFO(this))
2134                                 CS(this).motd_actived_time = time;
2135                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2136                                 CS(this).motd_actived_time = 0;
2137                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2138                         }
2139                 }
2140         }
2141         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2142         {
2143                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2144                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2145                 else if (CS(this).motd_actived_time == -2)
2146                 {
2147                         // instantly hide MOTD
2148                         CS(this).motd_actived_time = 0;
2149                         if (autocvar_g_campaign)
2150                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2151                         else
2152                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2153                 }
2154                 else if (IS_PLAYER(this) || IS_SPEC(this))
2155                 {
2156                         // FIXME occasionally for some reason MOTD never goes away
2157                         // delay MOTD removal a little bit in the hope it fixes this bug
2158                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2159                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2160                         else //if (CS(this).motd_actived_time < -2)
2161                                 CS(this).motd_actived_time++;
2162                 }
2163         }
2164 }
2165
2166 bool joinAllowed(entity this)
2167 {
2168         if (CS(this).version_mismatch) return false;
2169         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2170         if (!nJoinAllowed(this, this)) return false;
2171         if (teamplay && lockteams) return false;
2172         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2173         if (ShowTeamSelection(this)) return false;
2174         return true;
2175 }
2176
2177 .string shootfromfixedorigin;
2178 .bool dualwielding_prev;
2179 bool PlayerThink(entity this)
2180 {
2181         if (game_stopped || intermission_running) {
2182                 this.modelflags &= ~MF_ROCKET;
2183                 if(intermission_running)
2184                         IntermissionThink(this);
2185                 return false;
2186         }
2187
2188         if (timeout_status == TIMEOUT_ACTIVE) {
2189                 // don't allow the player to turn around while game is paused
2190                 // FIXME turn this into CSQC stuff
2191                 this.v_angle = this.lastV_angle;
2192                 this.angles = this.lastV_angle;
2193                 this.fixangle = true;
2194         }
2195
2196         if (frametime) player_powerups(this);
2197
2198         if (IS_DEAD(this)) {
2199                 if (this.personal && g_race_qualifying) {
2200                         if (time > this.respawn_time) {
2201                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2202                                 respawn(this);
2203                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2204                         }
2205                 } else {
2206                         if (frametime) player_anim(this);
2207
2208                         if (this.respawn_flags & RESPAWN_DENY)
2209                         {
2210                                 STAT(RESPAWN_TIME, this) = 0;
2211                                 return false;
2212                         }
2213
2214                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2215
2216                         switch(this.deadflag)
2217                         {
2218                                 case DEAD_DYING:
2219                                 {
2220                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2221                                                 this.deadflag = DEAD_RESPAWNING;
2222                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2223                                                 this.deadflag = DEAD_DEAD;
2224                                         break;
2225                                 }
2226                                 case DEAD_DEAD:
2227                                 {
2228                                         if (button_pressed)
2229                                                 this.deadflag = DEAD_RESPAWNABLE;
2230                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2231                                                 this.deadflag = DEAD_RESPAWNING;
2232                                         break;
2233                                 }
2234                                 case DEAD_RESPAWNABLE:
2235                                 {
2236                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2237                                                 this.deadflag = DEAD_RESPAWNING;
2238                                         break;
2239                                 }
2240                                 case DEAD_RESPAWNING:
2241                                 {
2242                                         if (time > this.respawn_time)
2243                                         {
2244                                                 this.respawn_time = time + 1; // only retry once a second
2245                                                 this.respawn_time_max = this.respawn_time;
2246                                                 respawn(this);
2247                                         }
2248                                         break;
2249                                 }
2250                         }
2251
2252                         ShowRespawnCountdown(this);
2253
2254                         if (this.respawn_flags & RESPAWN_SILENT)
2255                                 STAT(RESPAWN_TIME, this) = 0;
2256                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2257                         {
2258                                 if (time < this.respawn_time)
2259                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2260                                 else if (this.deadflag != DEAD_RESPAWNING)
2261                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2262                         }
2263                         else
2264                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2265                 }
2266
2267                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2268                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2269                         STAT(RESPAWN_TIME, this) *= -1;
2270
2271                 return false;
2272         }
2273
2274         FixPlayermodel(this);
2275
2276         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2277                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2278                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2279         }
2280
2281         // reset gun alignment when dual wielding status changes
2282         // to ensure guns are always aligned right and left
2283         bool dualwielding = W_DualWielding(this);
2284         if(this.dualwielding_prev != dualwielding)
2285         {
2286                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2287                 this.dualwielding_prev = dualwielding;
2288         }
2289
2290         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2291         //if(frametime)
2292         {
2293                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2294                 {
2295                         .entity weaponentity = weaponentities[slot];
2296                         if(WEP_CVAR(vortex, charge_always))
2297                                 W_Vortex_Charge(this, weaponentity, frametime);
2298                         W_WeaponFrame(this, weaponentity);
2299                 }
2300         }
2301
2302         if (frametime)
2303         {
2304                 // WEAPONTODO: Add a weapon request for this
2305                 // rot vortex charge to the charge limit
2306                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2307                 {
2308                         .entity weaponentity = weaponentities[slot];
2309                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2310                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2311                 }
2312
2313                 player_regen(this);
2314                 player_anim(this);
2315                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2316         }
2317
2318         monsters_setstatus(this);
2319
2320         return true;
2321 }
2322
2323 .bool would_spectate;
2324 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2325 void ObserverOrSpectatorThink(entity this)
2326 {
2327         bool is_spec = IS_SPEC(this);
2328         if ( CS(this).impulse )
2329         {
2330                 int r = MinigameImpulse(this, CS(this).impulse);
2331                 if (!is_spec || r)
2332                         CS(this).impulse = 0;
2333
2334                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2335                 {
2336                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2337                         CS(this).impulse = 0;
2338                         return;
2339                 }
2340         }
2341
2342         if (this.flags & FL_JUMPRELEASED) {
2343                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2344                         this.flags &= ~FL_JUMPRELEASED;
2345                         this.flags |= FL_SPAWNING;
2346                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2347                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2348                         this.flags &= ~FL_JUMPRELEASED;
2349                         if(SpectateNext(this)) {
2350                                 TRANSMUTE(Spectator, this);
2351                         } else if (is_spec) {
2352                                 TRANSMUTE(Observer, this);
2353                                 PutClientInServer(this);
2354                         }
2355                         else
2356                                 this.would_spectate = false; // unable to spectate anyone
2357                         if (is_spec)
2358                                 CS(this).impulse = 0;
2359                 } else if (is_spec) {
2360                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2361                                 this.flags &= ~FL_JUMPRELEASED;
2362                                 if(SpectatePrev(this)) {
2363                                         TRANSMUTE(Spectator, this);
2364                                 } else {
2365                                         TRANSMUTE(Observer, this);
2366                                         PutClientInServer(this);
2367                                 }
2368                                 CS(this).impulse = 0;
2369                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2370                                 this.would_spectate = false;
2371                                 this.flags &= ~FL_JUMPRELEASED;
2372                                 TRANSMUTE(Observer, this);
2373                                 PutClientInServer(this);
2374                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2375                                 PutObserverInServer(this);
2376                                 this.would_spectate = true;
2377                         }
2378                 }
2379                 else {
2380                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2381                         if (PHYS_INPUT_BUTTON_USE(this))
2382                                 wouldclip = !wouldclip;
2383                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2384                         set_movetype(this, preferred_movetype);
2385                 }
2386         } else { // jump pressed
2387                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2388                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2389                         this.flags |= FL_JUMPRELEASED;
2390                         if(this.flags & FL_SPAWNING)
2391                         {
2392                                 this.flags &= ~FL_SPAWNING;
2393                                 if(joinAllowed(this))
2394                                         Join(this);
2395                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2396                                         CS(this).autojoin_checked = -1;
2397                                 return;
2398                         }
2399                 }
2400                 if(is_spec && !SpectateUpdate(this))
2401                         PutObserverInServer(this);
2402         }
2403         if (is_spec)
2404                 this.flags |= FL_CLIENT | FL_NOTARGET;
2405 }
2406
2407 void PlayerUseKey(entity this)
2408 {
2409         if (!IS_PLAYER(this))
2410                 return;
2411
2412         if(this.vehicle)
2413         {
2414                 if(!game_stopped)
2415                 {
2416                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2417                         return;
2418                 }
2419         }
2420         else if(autocvar_g_vehicles_enter)
2421         {
2422                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2423                 {
2424                         entity head, closest_target = NULL;
2425                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2426
2427                         while(head) // find the closest acceptable target to enter
2428                         {
2429                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2430                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2431                                 {
2432                                         if(closest_target)
2433                                         {
2434                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2435                                                 { closest_target = head; }
2436                                         }
2437                                         else { closest_target = head; }
2438                                 }
2439
2440                                 head = head.chain;
2441                         }
2442
2443                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2444                 }
2445         }
2446
2447         // a use key was pressed; call handlers
2448         MUTATOR_CALLHOOK(PlayerUseKey, this);
2449 }
2450
2451
2452 /*
2453 =============
2454 PlayerPreThink
2455
2456 Called every frame for each client before the physics are run
2457 =============
2458 */
2459 .float last_vehiclecheck;
2460 void PlayerPreThink (entity this)
2461 {
2462         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2463         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2464
2465         WarpZone_PlayerPhysics_FixVAngle(this);
2466
2467         if (frametime) {
2468                 // physics frames: update anticheat stuff
2469                 anticheat_prethink(this);
2470         }
2471
2472         if (blockSpectators && frametime) {
2473                 // WORKAROUND: only use dropclient in server frames (frametime set).
2474                 // Never use it in cl_movement frames (frametime zero).
2475                 checkSpectatorBlock(this);
2476         }
2477
2478         zoomstate_set = false;
2479
2480         // Check for nameless players
2481         if (this.netname == "" || this.netname != CS(this).netname_previous)
2482         {
2483                 bool assume_unchanged = (CS(this).netname_previous == "");
2484                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2485                 {
2486                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2487                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2488                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2489                         assume_unchanged = false;
2490                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2491                 }
2492                 if (isInvisibleString(this.netname))
2493                 {
2494                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2495                         sprint(this, "Warning: invisible names are not allowed.\n");
2496                         assume_unchanged = false;
2497                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2498                 }
2499                 if (!assume_unchanged && autocvar_sv_eventlog)
2500                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2501                 strcpy(CS(this).netname_previous, this.netname);
2502         }
2503
2504         // version nagging
2505         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2506         CS(this).version_nagtime = 0;
2507         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2508             // git client
2509         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2510             // git server
2511             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2512         } else {
2513             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2514             if (r < 0) { // old client
2515                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2516             } else if (r > 0) { // old server
2517                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2518             }
2519         }
2520     }
2521
2522         // GOD MODE info
2523         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2524         {
2525                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2526                 this.max_armorvalue = 0;
2527         }
2528
2529         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2530         {
2531                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2532                 {
2533                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2534                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2535                         if (this.iceblock)
2536                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2537
2538                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2539                                 Unfreeze(this, false);
2540                 }
2541                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2542                 {
2543                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2544                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2545
2546                         if (GetResource(this, RES_HEALTH) < 1)
2547                         {
2548                                 if (this.vehicle)
2549                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2550                                 if(this.event_damage)
2551                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2552                         }
2553                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2554                                 Unfreeze(this, false);
2555                 }
2556         }
2557
2558         MUTATOR_CALLHOOK(PlayerPreThink, this);
2559
2560         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2561         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2562         {
2563                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2564                 {
2565                         if(!it.owner)
2566                         {
2567                                 if(!it.team || SAME_TEAM(this, it))
2568                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2569                                 else if(autocvar_g_vehicles_steal)
2570                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2571                         }
2572                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2573                         {
2574                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2575                         }
2576                 });
2577
2578                 this.last_vehiclecheck = time + 1;
2579         }
2580
2581         if(!CS_CVAR(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2582         {
2583                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2584                         PlayerUseKey(this);
2585                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2586         }
2587
2588         if (IS_REAL_CLIENT(this))
2589                 PrintWelcomeMessage(this);
2590
2591         if (IS_PLAYER(this)) {
2592                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2593                         error("Client can't be spawned as player on connection!");
2594                 if(!PlayerThink(this))
2595                         return;
2596         }
2597         else if (game_stopped || intermission_running) {
2598                 if(intermission_running)
2599                         IntermissionThink(this);
2600                 return;
2601         }
2602         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2603         {
2604                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2605                 CS(this).autojoin_checked = 1;
2606                 // don't do this in ClientConnect
2607                 // many things can go wrong if a client is spawned as player on connection
2608                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2609                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2610                                 && (!teamplay || autocvar_g_balance_teams)))
2611                 {
2612                         campaign_bots_may_start = true;
2613                         if(joinAllowed(this))
2614                                 Join(this);
2615                         return;
2616                 }
2617         }
2618         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2619                 ObserverOrSpectatorThink(this);
2620         }
2621
2622         // WEAPONTODO: Add weapon request for this
2623         if (!zoomstate_set) {
2624                 bool wep_zoomed = false;
2625                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2626                 {
2627                         .entity weaponentity = weaponentities[slot];
2628                         Weapon thiswep = this.(weaponentity).m_weapon;
2629                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2630                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2631                 }
2632                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2633         }
2634
2635         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2636         {
2637                 CS(this).teamkill_soundtime = 0;
2638
2639                 entity e = CS(this).teamkill_soundsource;
2640                 entity oldpusher = e.pusher;
2641                 e.pusher = this;
2642                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2643                 e.pusher = oldpusher;
2644         }
2645
2646         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2647                 CS(this).taunt_soundtime = 0;
2648                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2649         }
2650
2651         target_voicescript_next(this);
2652 }
2653
2654 void DrownPlayer(entity this)
2655 {
2656         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2657                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2658         {
2659                 STAT(AIR_FINISHED, this) = 0;
2660                 return;
2661         }
2662
2663         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2664         {
2665                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2666                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2667                 STAT(AIR_FINISHED, this) = 0;
2668         }
2669         else
2670         {
2671                 if (!STAT(AIR_FINISHED, this))
2672                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2673                 if (STAT(AIR_FINISHED, this) < time)
2674                 {       // drown!
2675                         if (this.pain_finished < time)
2676                         {
2677                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2678                                 this.pain_finished = time + 0.5;
2679                         }
2680                 }
2681         }
2682 }
2683
2684 .bool move_qcphysics;
2685
2686 void Player_Physics(entity this)
2687 {
2688         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2689
2690         if(!this.move_qcphysics)
2691                 return;
2692
2693         if(!frametime && !CS(this).pm_frametime)
2694                 return;
2695
2696         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2697
2698         CS(this).pm_frametime = 0;
2699 }
2700
2701 /*
2702 =============
2703 PlayerPostThink
2704
2705 Called every frame for each client after the physics are run
2706 =============
2707 */
2708 void PlayerPostThink (entity this)
2709 {
2710         Player_Physics(this);
2711
2712         if (autocvar_sv_maxidle > 0)
2713         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2714         if (IS_REAL_CLIENT(this))
2715         if (IS_PLAYER(this) || autocvar_sv_maxidle_spectatorsareidle)
2716         {
2717                 int totalClients = 0;
2718                 if(autocvar_sv_maxidle_slots > 0)
2719                 {
2720                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2721                         {
2722                                 ++totalClients;
2723                         });
2724                 }
2725
2726                 if (autocvar_sv_maxidle_slots > 0 && (maxclients - totalClients) > autocvar_sv_maxidle_slots)
2727                 { /* do nothing */ }
2728                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2729                 {
2730                         if (CS(this).idlekick_lasttimeleft)
2731                         {
2732                                 CS(this).idlekick_lasttimeleft = 0;
2733                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2734                         }
2735                 }
2736                 else
2737                 {
2738                         float timeleft = ceil(autocvar_sv_maxidle - (time - CS(this).parm_idlesince));
2739                         if (timeleft == min(10, autocvar_sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2740                                 if (!CS(this).idlekick_lasttimeleft)
2741                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2742                         }
2743                         if (timeleft <= 0) {
2744                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2745                                 dropclient(this);
2746                                 return;
2747                         }
2748                         else if (timeleft <= 10) {
2749                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2750                                         Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2751                                 CS(this).idlekick_lasttimeleft = timeleft;
2752                         }
2753                 }
2754         }
2755
2756         CheatFrame(this);
2757
2758         if (game_stopped)
2759         {
2760                 this.solid = SOLID_NOT;
2761                 this.takedamage = DAMAGE_NO;
2762                 set_movetype(this, MOVETYPE_NONE);
2763                 CS(this).teamkill_complain = 0;
2764                 CS(this).teamkill_soundtime = 0;
2765                 CS(this).teamkill_soundsource = NULL;
2766         }
2767
2768         if (IS_PLAYER(this)) {
2769                 if(this.death_time == time && IS_DEAD(this))
2770                 {
2771                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2772                         // once all the damage events of this frame have been processed with normal size
2773                         this.maxs.z = 5;
2774                         setsize(this, this.mins, this.maxs);
2775                 }
2776                 DrownPlayer(this);
2777                 UpdateChatBubble(this);
2778                 if (CS(this).impulse) ImpulseCommands(this);
2779                 GetPressedKeys(this);
2780                 if (game_stopped)
2781                 {
2782                         CSQCMODEL_AUTOUPDATE(this);
2783                         return;
2784                 }
2785         }
2786         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2787         {
2788                 CS(this).pressedkeys = 0;
2789                 STAT(PRESSED_KEYS, this) = 0;
2790         }
2791
2792         if (this.waypointsprite_attachedforcarrier) {
2793                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2794                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2795         }
2796
2797         CSQCMODEL_AUTOUPDATE(this);
2798 }
2799
2800 // hack to copy the button fields from the client entity to the Client State
2801 void PM_UpdateButtons(entity this, entity store)
2802 {
2803         if(this.impulse)
2804                 store.impulse = this.impulse;
2805         this.impulse = 0;
2806
2807         bool typing = this.buttonchat || this.button12;
2808
2809         store.button0 = (typing) ? 0 : this.button0;
2810         //button1?!
2811         store.button2 = (typing) ? 0 : this.button2;
2812         store.button3 = (typing) ? 0 : this.button3;
2813         store.button4 = this.button4;
2814         store.button5 = (typing) ? 0 : this.button5;
2815         store.button6 = this.button6;
2816         store.button7 = this.button7;
2817         store.button8 = this.button8;
2818         store.button9 = this.button9;
2819         store.button10 = this.button10;
2820         store.button11 = this.button11;
2821         store.button12 = this.button12;
2822         store.button13 = this.button13;
2823         store.button14 = this.button14;
2824         store.button15 = this.button15;
2825         store.button16 = this.button16;
2826         store.buttonuse = this.buttonuse;
2827         store.buttonchat = this.buttonchat;
2828
2829         store.cursor_active = this.cursor_active;
2830         store.cursor_screen = this.cursor_screen;
2831         store.cursor_trace_start = this.cursor_trace_start;
2832         store.cursor_trace_endpos = this.cursor_trace_endpos;
2833         store.cursor_trace_ent = this.cursor_trace_ent;
2834
2835         store.ping = this.ping;
2836         store.ping_packetloss = this.ping_packetloss;
2837         store.ping_movementloss = this.ping_movementloss;
2838
2839         store.v_angle = this.v_angle;
2840         store.movement = this.movement;
2841 }
2842
2843 NET_HANDLE(fpsreport, bool)
2844 {
2845         int fps = ReadShort();
2846         PlayerScore_Set(sender, SP_FPS, fps);
2847         return true;
2848 }