qcsrc/server/bot/default/bot.qc

   1 #include "bot.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/mapinfo.qh>
   5 #include <common/net_linked.qh>
   6 #include <common/physics/player.qh>
   7 #include <common/stats.qh>
   8 #include <common/teams.qh>
   9 #include <common/util.qh>
  10 #include <common/weapons/_all.qh>
  11 #include <lib/csqcmodel/sv_model.qh>
  12 #include <lib/warpzone/common.qh>
  13 #include <lib/warpzone/util_server.qh>
  14 #include <server/antilag.qh>
  15 #include <server/bot/default/aim.qh>
  16 #include <server/bot/default/cvars.qh>
  17 #include <server/bot/default/havocbot/havocbot.qh>
  18 #include <server/bot/default/havocbot/scripting.qh>
  19 #include <server/bot/default/navigation.qh>
  20 #include <server/bot/default/scripting.qh>
  21 #include <server/bot/default/waypoints.qh>
  22 #include <server/campaign.qh>
  23 #include <server/client.qh>
  24 #include <server/damage.qh>
  25 #include <server/items/items.qh>
  26 #include <server/mutators/_mod.qh>
  27 #include <server/race.qh>
  28 #include <server/scores_rules.qh>
  29 #include <server/teamplay.qh>
  30 #include <server/weapons/accuracy.qh>
  31 #include <server/weapons/selection.qh>
  32 #include <server/world.qh>
  33
  34 STATIC_INIT(bot) { bot_calculate_stepheightvec(); }
  35
  36 // TODO: remove this function! its only purpose is to update these fields since bot_setnameandstuff is called before ClientState
  37 void bot_setclientfields(entity this)
  38 {
  39         CS_CVAR(this).cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
  40         CS_CVAR(this).cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
  41 }
  42
  43 entity bot_spawn()
  44 {
  45         entity bot = spawnclient();
  46         if (bot)
  47         {
  48                 setItemGroupCount();
  49                 currentbots = currentbots + 1;
  50                 bot_setnameandstuff(bot);
  51                 ClientConnect(bot);
  52                 bot_setclientfields(bot);
  53                 PutClientInServer(bot);
  54         }
  55         return bot;
  56 }
  57
  58 void bot_think(entity this)
  59 {
  60         if (this.bot_nextthink > time)
  61                 return;
  62
  63         this.flags &= ~FL_GODMODE;
  64         if(autocvar_bot_god)
  65                 this.flags |= FL_GODMODE;
  66
  67         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * (0.5 ** this.bot_aiskill) * min(14 / (skill + 14), 1));
  68
  69         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
  70         {
  71                 if (IS_PLAYER(this))
  72                 {
  73                         .entity weaponentity = weaponentities[0];
  74                         if(this.(weaponentity).m_weapon == WEP_Null)
  75                                 W_NextWeapon(this, 0, weaponentity);
  76                 }
  77                 CS(this).movement = '0 0 0';
  78                 this.bot_nextthink = time + 0.5;
  79                 return;
  80         }
  81
  82         if (this.fixangle)
  83         {
  84                 this.v_angle = this.angles;
  85                 this.v_angle_z = 0;
  86                 this.fixangle = false;
  87         }
  88
  89         this.dmg_take = 0;
  90         this.dmg_save = 0;
  91         this.dmg_inflictor = NULL;
  92
  93         // calculate an aiming latency based on the skill setting
  94         // (simulated network latency + naturally delayed reflexes)
  95         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
  96         // minimum ping 20+10 random
  97         CS(this).ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
  98         // skill 10 = ping 0.2 (adrenaline)
  99         // skill 0 = ping 0.7 (slightly drunk)
 100
 101         // clear buttons
 102         PHYS_INPUT_BUTTON_ATCK(this) = false;
 103         // keep jump button pressed for a short while, useful with ramp jumps
 104         PHYS_INPUT_BUTTON_JUMP(this) = (!IS_DEAD(this) && time < this.bot_jump_time + 0.2);
 105         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 106         PHYS_INPUT_BUTTON_ZOOM(this) = false;
 107         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 108         PHYS_INPUT_BUTTON_HOOK(this) = false;
 109         PHYS_INPUT_BUTTON_INFO(this) = false;
 110         PHYS_INPUT_BUTTON_DRAG(this) = false;
 111         PHYS_INPUT_BUTTON_CHAT(this) = false;
 112         PHYS_INPUT_BUTTON_USE(this) = false;
 113
 114         if (time < game_starttime)
 115         {
 116                 .entity weaponentity = weaponentities[0];
 117                 if(this.(weaponentity).m_weapon == WEP_Null)
 118                         W_NextWeapon(this, 0, weaponentity);
 119                 // block the bot during the countdown to game start
 120                 CS(this).movement = '0 0 0';
 121                 this.bot_nextthink = game_starttime;
 122                 return;
 123         }
 124
 125         // if dead, just wait until we can respawn
 126         if (IS_DEAD(this) || IS_OBSERVER(this))
 127         {
 128                 if (bot_waypoint_queue_owner == this)
 129                         bot_waypoint_queue_owner = NULL;
 130                 this.aistatus = 0;
 131                 CS(this).movement = '0 0 0';
 132                 if (IS_OBSERVER(this))
 133                         return;
 134                 if (IS_DEAD(this))
 135                 {
 136                         if (!navigation_goalrating_timeout(this))
 137                                 navigation_goalrating_timeout_force(this);
 138                         // jump must not be pressed for at least one frame in order for
 139                         // PlayerThink to detect the key down event
 140                         if (this.deadflag == DEAD_DYING)
 141                                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 142                         else if (this.deadflag == DEAD_DEAD)
 143                                 PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
 144                 }
 145         }
 146         else if(this.aistatus & AI_STATUS_STUCK)
 147                 navigation_unstuck(this);
 148
 149         // now call the current bot AI (havocbot for example)
 150         this.bot_ai(this);
 151 }
 152
 153 void bot_setnameandstuff(entity this)
 154 {
 155         string readfile, s;
 156         int file, tokens, prio;
 157
 158         file = fopen(autocvar_bot_config_file, FILE_READ);
 159
 160         if(file < 0)
 161         {
 162                 LOG_INFOF("Error: Can not open the bot configuration file '%s'", autocvar_bot_config_file);
 163                 readfile = "";
 164         }
 165         else
 166         {
 167                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
 168                 TeamBalance_GetTeamCounts(balance, NULL);
 169                 int smallest_team = -1;
 170                 int smallest_count = -1;
 171                 if (teamplay)
 172                 {
 173                         for (int i = 1; i <= AvailableTeams(); ++i)
 174                         {
 175                                 // NOTE if (autocvar_g_campaign && autocvar_g_campaign_forceteam == i)
 176                                 // TeamBalance_GetNumberOfPlayers(balance, i); returns the number of players + 1
 177                                 // since it keeps a spot for the real player in the desired team
 178                                 int count = TeamBalance_GetNumberOfPlayers(balance, i);
 179                                 if (smallest_count < 0 || count < smallest_count)
 180                                 {
 181                                         smallest_team = i;
 182                                         smallest_count = count;
 183                                 }
 184                         }
 185                 }
 186                 TeamBalance_Destroy(balance);
 187                 RandomSelection_Init();
 188                 while((readfile = fgets(file)))
 189                 {
 190                         if(substring(readfile, 0, 2) == "//")
 191                                 continue;
 192                         if(substring(readfile, 0, 1) == "#")
 193                                 continue;
 194                         // NOTE if the line is empty tokenizebyseparator(readfile, "\t")
 195                         // will create 1 empty token because there's no separator (bug?)
 196                         if (readfile == "")
 197                                 continue;
 198                         tokens = tokenizebyseparator(readfile, "\t");
 199                         if(tokens == 0)
 200                                 continue;
 201                         s = argv(0);
 202                         prio = 0;
 203                         bool conflict = false;
 204                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 205                                 if (s == it.cleanname)
 206                                 {
 207                                         conflict = true;
 208                                         break;
 209                                 }
 210                         });
 211                         if (!conflict)
 212                                 prio += 1;
 213                         if (teamplay && !(autocvar_bot_vs_human && AvailableTeams() == 2))
 214                         {
 215                                 int forced_team = stof(argv(5));
 216                                 if (!Team_IsValidIndex(forced_team))
 217                                         forced_team = 0;
 218                                 if (!forced_team || forced_team == smallest_team)
 219                                         prio += 2;
 220                         }
 221                         RandomSelection_AddString(readfile, 1, prio);
 222                 }
 223                 readfile = RandomSelection_chosen_string;
 224                 fclose(file);
 225         }
 226
 227         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 228
 229         tokens = tokenizebyseparator(readfile, "\t");
 230         if(argv(0) != "") bot_name = argv(0);
 231         else bot_name = "Bot";
 232
 233         if(argv(1) != "") bot_model = argv(1);
 234         else bot_model = "";
 235
 236         if(argv(2) != "") bot_skin = argv(2);
 237         else bot_skin = "0";
 238
 239         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 240         else bot_shirt = ftos(floor(random() * 15));
 241
 242         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 243         else bot_pants = ftos(floor(random() * 15));
 244
 245         if (teamplay && !(autocvar_bot_vs_human && AvailableTeams() == 2))
 246                 this.bot_forced_team = stof(argv(5));
 247         else
 248                 this.bot_forced_team = 0;
 249
 250         prio = 6;
 251
 252         #define READSKILL(f, w, r) MACRO_BEGIN \
 253                 if(argv(prio) != "") \
 254                         this.f = stof(argv(prio)) * w; \
 255                 else \
 256                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
 257                 prio++; \
 258         MACRO_END
 259         //print(bot_name, ": ping=", argv(9), "\n");
 260
 261         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 262         READSKILL(bot_moveskill, 2, 0); // move skill
 263         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 264
 265         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 266
 267         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 268         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 269         READSKILL(bot_rangepreference, 1, 0); // read skill
 270
 271         READSKILL(bot_aimskill, 2, 0); // aim skill
 272         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 273         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 274
 275         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 276         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 277
 278         if (file >= 0 && argv(prio) != "")
 279                 LOG_INFOF("^1Warning^7: too many parameters for bot %s, please check format of %s", bot_name, autocvar_bot_config_file);
 280
 281         this.bot_config_loaded = true;
 282
 283         // this is really only a default, TeamBalance_JoinBestTeam is called later
 284         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
 285         this.bot_preferredcolors = this.clientcolors;
 286
 287         string prefix = (autocvar_g_campaign ? "" : autocvar_bot_prefix);
 288         string suffix = (autocvar_g_campaign ? "" : autocvar_bot_suffix);
 289         string name = (autocvar_bot_usemodelnames ? bot_model : bot_name);
 290
 291         if (name == "")
 292         {
 293                 name = ftos(etof(this));
 294                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 295         }
 296         else
 297         {
 298                 // number bots with identical names
 299                 int j = 0;
 300                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 301                         if(it.cleanname == name)
 302                                 ++j;
 303                 });
 304                 if (j)
 305                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
 306                 else
 307                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 308         }
 309         this.cleanname = strzone(name);
 310
 311         // pick the model and skin
 312         if(substring(bot_model, -4, 1) != ".")
 313                 bot_model = strcat(bot_model, ".iqm");
 314         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 315         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
 316 }
 317
 318 void bot_custom_weapon_priority_setup()
 319 {
 320         static string bot_priority_far_prev;
 321         static string bot_priority_mid_prev;
 322         static string bot_priority_close_prev;
 323         static string bot_priority_distances_prev;
 324         float tokens, i, w;
 325
 326         bot_custom_weapon = false;
 327
 328         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
 329                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
 330                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
 331                 autocvar_bot_ai_custom_weapon_priority_distances == ""
 332         )
 333                 return;
 334
 335         if (bot_priority_distances_prev != autocvar_bot_ai_custom_weapon_priority_distances)
 336         {
 337                 strcpy(bot_priority_distances_prev, autocvar_bot_ai_custom_weapon_priority_distances);
 338                 tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
 339
 340                 if (tokens!=2)
 341                         return;
 342
 343                 bot_distance_far = stof(argv(0));
 344                 bot_distance_close = stof(argv(1));
 345
 346                 if(bot_distance_far < bot_distance_close){
 347                         bot_distance_far = stof(argv(1));
 348                         bot_distance_close = stof(argv(0));
 349                 }
 350         }
 351
 352         int c;
 353
 354         #define PARSE_WEAPON_PRIORITIES(dist) MACRO_BEGIN \
 355                 if (bot_priority_##dist##_prev != autocvar_bot_ai_custom_weapon_priority_##dist) { \
 356                         strcpy(bot_priority_##dist##_prev, autocvar_bot_ai_custom_weapon_priority_##dist); \
 357                         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_##dist)," "); \
 358                         bot_weapons_##dist[0] = -1; \
 359                         c = 0; \
 360                         for(i = 0; i < tokens && c < REGISTRY_COUNT(Weapons); ++i) { \
 361                                 w = stof(argv(i)); \
 362                                 if (w >= WEP_FIRST && w <= WEP_LAST) { \
 363                                         bot_weapons_##dist[c] = w; \
 364                                         ++c; \
 365                                 } \
 366                         } \
 367                         if (c < REGISTRY_COUNT(Weapons)) \
 368                                 bot_weapons_##dist[c] = -1; \
 369                 } \
 370         MACRO_END
 371
 372         PARSE_WEAPON_PRIORITIES(far);
 373         PARSE_WEAPON_PRIORITIES(mid);
 374         PARSE_WEAPON_PRIORITIES(close);
 375
 376         bot_custom_weapon = true;
 377 }
 378
 379 void bot_endgame()
 380 {
 381         bot_relinkplayerlist();
 382         entity e = bot_list;
 383         while (e)
 384         {
 385                 setcolor(e, e.bot_preferredcolors);
 386                 e = e.nextbot;
 387         }
 388         // if dynamic waypoints are ever implemented, save them here
 389 }
 390
 391 void bot_relinkplayerlist()
 392 {
 393         player_count = 0;
 394         currentbots = 0;
 395         bot_list = NULL;
 396
 397         entity prevbot = NULL;
 398         FOREACH_CLIENT(true,
 399         {
 400                 ++player_count;
 401
 402                 if(IS_BOT_CLIENT(it))
 403                 {
 404                         if (!IS_OBSERVER(it) && !bot_ispaused(it))
 405                         {
 406                                 if(prevbot)
 407                                         prevbot.nextbot = it;
 408                                 else
 409                                         bot_list = it;
 410                                 prevbot = it;
 411                         }
 412                         ++currentbots;
 413                 }
 414         });
 415         if(prevbot)
 416                 prevbot.nextbot = NULL;
 417         bot_strategytoken = bot_list;
 418         bot_strategytoken_taken = true;
 419 }
 420
 421 void bot_clientdisconnect(entity this)
 422 {
 423         if (!IS_BOT_CLIENT(this))
 424                 return;
 425         bot_clearqueue(this);
 426         strfree(this.cleanname);
 427         strfree(this.netname_freeme);
 428         strfree(this.playermodel_freeme);
 429         strfree(this.playerskin_freeme);
 430         if(this.bot_cmd_current)
 431                 delete(this.bot_cmd_current);
 432         if(bot_waypoint_queue_owner == this)
 433                 bot_waypoint_queue_owner = NULL;
 434 }
 435
 436 void bot_clientconnect(entity this)
 437 {
 438         if (!IS_BOT_CLIENT(this)) return;
 439         this.bot_preferredcolors = this.clientcolors;
 440         this.bot_nextthink = time - random();
 441         this.lag_func = bot_lagfunc;
 442         this.isbot = true;
 443         this.createdtime = this.bot_nextthink;
 444
 445         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 446         {
 447                 bot_setnameandstuff(this);
 448                 bot_setclientfields(this);
 449         }
 450
 451         if (teamplay && Team_IsValidIndex(this.bot_forced_team))
 452         {
 453                 SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
 454         }
 455         else
 456         {
 457                 this.bot_forced_team = 0;
 458                 TeamBalance_JoinBestTeam(this);
 459         }
 460
 461         havocbot_setupbot(this);
 462 }
 463
 464 void bot_removefromlargestteam()
 465 {
 466         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 467         TeamBalance_GetTeamCounts(balance, NULL);
 468
 469         entity best = NULL;
 470         float besttime = 0;
 471         int bestcount = 0;
 472
 473         int bcount = 0;
 474         FOREACH_CLIENT(it.isbot,
 475         {
 476                 ++bcount;
 477
 478                 if(!best)
 479                 {
 480                         best = it;
 481                         besttime = it.createdtime;
 482                 }
 483
 484                 int thiscount = 0;
 485
 486                 if (Team_IsValidTeam(it.team))
 487                 {
 488                         thiscount = TeamBalance_GetNumberOfPlayers(balance,
 489                                 Team_TeamToIndex(it.team));
 490                 }
 491
 492                 if(thiscount > bestcount)
 493                 {
 494                         bestcount = thiscount;
 495                         besttime = it.createdtime;
 496                         best = it;
 497                 }
 498                 else if(thiscount == bestcount && besttime < it.createdtime)
 499                 {
 500                         besttime = it.createdtime;
 501                         best = it;
 502                 }
 503         });
 504         TeamBalance_Destroy(balance);
 505         if(!bcount)
 506                 return; // no bots to remove
 507         currentbots = currentbots - 1;
 508         dropclient(best);
 509 }
 510
 511 void bot_removenewest()
 512 {
 513         if(teamplay)
 514         {
 515                 bot_removefromlargestteam();
 516                 return;
 517         }
 518
 519         float besttime = 0;
 520         entity best = NULL;
 521         int bcount = 0;
 522
 523         FOREACH_CLIENT(it.isbot,
 524         {
 525                 ++bcount;
 526
 527                 if(!best)
 528                 {
 529                         best = it;
 530                         besttime = it.createdtime;
 531                 }
 532
 533                 if(besttime < it.createdtime)
 534                 {
 535                         besttime = it.createdtime;
 536                         best = it;
 537                 }
 538         });
 539
 540         if(!bcount)
 541                 return; // no bots to remove
 542
 543         currentbots = currentbots - 1;
 544         dropclient(best);
 545 }
 546
 547 void autoskill(float factor)
 548 {
 549         int bestbot = -1;
 550         int bestplayer = -1;
 551         FOREACH_CLIENT(IS_PLAYER(it), {
 552                 if(IS_REAL_CLIENT(it))
 553                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
 554                 else
 555                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
 556         });
 557
 558         string msg = strcat("autoskill: best player got ", ftos(bestplayer), ", ""best bot got ", ftos(bestbot), "; ");
 559         if(bestbot < 0 || bestplayer < 0)
 560         {
 561                 msg = strcat(msg, "not doing anything");
 562                 // don't return, let it reset all counters below
 563         }
 564         else if(bestbot <= bestplayer * factor - 2)
 565         {
 566                 if(autocvar_skill < 17)
 567                 {
 568                         msg = strcat(msg, "2 frags difference, increasing skill");
 569                         cvar_set("skill", ftos(autocvar_skill + 1));
 570                         bprint("^2BOT SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
 571                 }
 572         }
 573         else if(bestbot >= bestplayer * factor + 2)
 574         {
 575                 if(autocvar_skill > 0)
 576                 {
 577                         msg = strcat(msg, "2 frags difference, decreasing skill");
 578                         cvar_set("skill", ftos(autocvar_skill - 1));
 579                         bprint("^1BOT SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
 580                 }
 581         }
 582         else
 583         {
 584                 msg = strcat(msg, "not doing anything");
 585                 return;
 586                 // don't reset counters, wait for them to accumulate
 587         }
 588         LOG_DEBUG(msg);
 589
 590         FOREACH_CLIENT(IS_PLAYER(it), { it.totalfrags_lastcheck = it.totalfrags; });
 591 }
 592
 593 void bot_calculate_stepheightvec()
 594 {
 595         stepheightvec = autocvar_sv_stepheight * '0 0 1';
 596         jumpheight_vec = (autocvar_sv_jumpvelocity ** 2) / (2 * autocvar_sv_gravity) * '0 0 1';
 597         jumpstepheightvec = stepheightvec + jumpheight_vec * 0.85; // reduce it a bit to make the jumps easy
 598         jumpheight_time = autocvar_sv_jumpvelocity / autocvar_sv_gravity;
 599 }
 600
 601 bool bot_fixcount(bool multiple_per_frame)
 602 {
 603         int activerealplayers = 0;
 604         int realplayers = 0;
 605         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
 606                 activerealplayers = M_ARGV(0, int);
 607                 realplayers = M_ARGV(1, int);
 608         } else {
 609                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 610                         if(IS_PLAYER(it))
 611                                 ++activerealplayers;
 612                         ++realplayers;
 613                 });
 614         }
 615
 616         int bots;
 617         // But don't remove bots immediately on level change, as the real players
 618         // usually haven't rejoined yet
 619         bots_would_leave = false;
 620         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
 621                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
 622         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
 623         {
 624                 int minplayers = max(0, floor(autocvar_minplayers));
 625                 if (teamplay)
 626                         minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
 627                 int minbots = max(0, floor(autocvar_bot_number));
 628
 629                 // add bots to reach minplayers if needed
 630                 bots = max(minbots, minplayers - activerealplayers);
 631                 // cap bots to the max players allowed by the server
 632                 int player_limit = GetPlayerLimit();
 633                 if(player_limit)
 634                         bots = min(bots, max(player_limit - activerealplayers, 0));
 635                 bots = min(bots, maxclients - realplayers);
 636
 637                 if(bots > minbots)
 638                         bots_would_leave = true;
 639         }
 640         else
 641         {
 642                 // if there are no players, remove bots
 643                 bots = 0;
 644         }
 645
 646         // only add one bot per frame to avoid utter chaos
 647         if(time > botframe_nextthink)
 648         {
 649                 while (currentbots < bots)
 650                 {
 651                         if (bot_spawn() == NULL)
 652                         {
 653                                 bprint("Can not add bot, server full.\n");
 654                                 return false;
 655                         }
 656                         if (!multiple_per_frame)
 657                         {
 658                                 break;
 659                         }
 660                 }
 661                 while (currentbots > bots && bots >= 0)
 662                         bot_removenewest();
 663         }
 664
 665         return true;
 666 }
 667
 668 void bot_serverframe()
 669 {
 670         if (intermission_running && currentbots > 0)
 671         {
 672                 // after the end of the match all bots stay unless all human players disconnect
 673                 int realplayers = 0;
 674                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++realplayers; });
 675                 if (!realplayers)
 676                 {
 677                         FOREACH_CLIENT(IS_BOT_CLIENT(it), { dropclient(it); });
 678                         currentbots = 0;
 679                 }
 680                 return;
 681         }
 682
 683         if (game_stopped)
 684                 return;
 685
 686         // Added 0.5 to avoid possible addition + immediate removal of bots that would make them appear as
 687         // spectators in the scoreboard and never go away. This issue happens at time 2 if map is changed
 688         // with the gotomap command, minplayers is > 1 and human clients join as players very soon
 689         // either intentionally or automatically (sv_spectate 0)
 690         if (time < 2.5)
 691         {
 692                 currentbots = -1;
 693                 return;
 694         }
 695
 696         if (currentbots == -1)
 697         {
 698                 // count bots already in the server from the previous match
 699                 currentbots = 0;
 700                 FOREACH_CLIENT(IS_BOT_CLIENT(it), { ++currentbots; });
 701         }
 702
 703         if(autocvar_skill != skill)
 704         {
 705                 float wpcost_update = false;
 706                 if(skill >= autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill < autocvar_bot_ai_bunnyhop_skilloffset)
 707                         wpcost_update = true;
 708                 if(skill < autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 709                         wpcost_update = true;
 710
 711                 skill = autocvar_skill;
 712                 if (wpcost_update)
 713                         waypoint_updatecost_foralllinks();
 714         }
 715
 716         bot_calculate_stepheightvec();
 717         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 718
 719         if(time > autoskill_nextthink)
 720         {
 721                 float a;
 722                 a = autocvar_skill_auto;
 723                 if(a)
 724                         autoskill(a);
 725                 autoskill_nextthink = time + 5;
 726         }
 727
 728         if(time > botframe_nextthink)
 729         {
 730                 if(!bot_fixcount(false))
 731                         botframe_nextthink = time + 10;
 732         }
 733
 734         if(botframe_spawnedwaypoints)
 735         {
 736                 if(autocvar_waypoint_benchmark)
 737                         localcmd("quit\n");
 738         }
 739
 740         if (currentbots > 0 || waypointeditor_enabled || autocvar_g_waypointeditor_auto)
 741         if (botframe_spawnedwaypoints)
 742         {
 743                 if(botframe_cachedwaypointlinks)
 744                 {
 745                         if(!botframe_loadedforcedlinks)
 746                                 waypoint_load_hardwiredlinks();
 747                 }
 748                 else
 749                 {
 750                         // TODO: Make this check cleaner
 751                         IL_EACH(g_waypoints, time - it.nextthink > 10,
 752                         {
 753                                 waypoint_save_links();
 754                                 break;
 755                         });
 756                 }
 757         }
 758         else
 759         {
 760                 botframe_spawnedwaypoints = true;
 761                 waypoint_loadall();
 762                 waypoint_load_links();
 763         }
 764
 765         if (bot_list)
 766         {
 767                 // cycle the goal token from one bot to the next each frame
 768                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 769                 //  frame, which causes choppy framerates)
 770                 if (bot_strategytoken_taken)
 771                 {
 772                         // give goal token to the first bot without goals; if all bots don't have
 773                         // any goal (or are dead/frozen) simply give it to the next one
 774                         bot_strategytoken_taken = false;
 775                         entity bot_strategytoken_save = bot_strategytoken;
 776                         while (true)
 777                         {
 778                                 if (bot_strategytoken)
 779                                         bot_strategytoken = bot_strategytoken.nextbot;
 780                                 if (!bot_strategytoken)
 781                                         bot_strategytoken = bot_list;
 782
 783                                 if (!(IS_DEAD(bot_strategytoken) || STAT(FROZEN, bot_strategytoken))
 784                                         && !bot_strategytoken.goalcurrent)
 785                                         break;
 786
 787                                 if (!bot_strategytoken_save) // break loop if all the bots are dead or frozen
 788                                         break;
 789                                 if (bot_strategytoken == bot_strategytoken_save)
 790                                         bot_strategytoken_save = NULL; // looped through all the bots
 791                         }
 792                 }
 793
 794                 if (botframe_nextdangertime < time)
 795                 {
 796                         float interval;
 797                         interval = autocvar_bot_ai_dangerdetectioninterval;
 798                         if (botframe_nextdangertime < time - interval * 1.5)
 799                                 botframe_nextdangertime = time;
 800                         botframe_nextdangertime = botframe_nextdangertime + interval;
 801                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
 802                 }
 803         }
 804
 805         if (waypointeditor_enabled)
 806                 botframe_showwaypointlinks();
 807
 808         if (autocvar_g_waypointeditor_auto)
 809                 botframe_autowaypoints();
 810
 811         if (currentbots > 0)
 812                 bot_custom_weapon_priority_setup();
 813 }