qcsrc/server/bot/default/bot.qc

   1 #include "bot.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "aim.qh"
   6 #include "navigation.qh"
   7 #include "scripting.qh"
   8 #include "waypoints.qh"
   9
  10 #include "havocbot/havocbot.qh"
  11 #include "havocbot/scripting.qh"
  12
  13 #include "../../teamplay.qh"
  14
  15 #include "../../antilag.qh"
  16 #include "../../autocvars.qh"
  17 #include "../../campaign.qh"
  18 #include "../../client.qh"
  19 #include "../../constants.qh"
  20 #include "../../defs.qh"
  21 #include "../../race.qh"
  22 #include <common/t_items.qh>
  23
  24 #include <server/mutators/_mod.qh>
  25
  26 #include "../../weapons/accuracy.qh"
  27
  28 #include <common/physics/player.qh>
  29 #include <common/constants.qh>
  30 #include <common/net_linked.qh>
  31 #include <common/mapinfo.qh>
  32 #include <common/teams.qh>
  33 #include <common/util.qh>
  34
  35 #include <server/scores_rules.qh>
  36
  37 #include <common/weapons/_all.qh>
  38
  39 #include <lib/csqcmodel/sv_model.qh>
  40
  41 #include <lib/warpzone/common.qh>
  42 #include <lib/warpzone/util_server.qh>
  43
  44 STATIC_INIT(bot) { bot_calculate_stepheightvec(); }
  45
  46 // TODO: remove this function! its only purpose is to update these fields since bot_setnameandstuff is called before ClientState
  47 void bot_setclientfields(entity this)
  48 {
  49         CS(this).cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
  50         CS(this).cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
  51 }
  52
  53 entity bot_spawn()
  54 {
  55         entity bot = spawnclient();
  56         if (bot)
  57         {
  58                 setItemGroupCount();
  59                 currentbots = currentbots + 1;
  60                 bot_setnameandstuff(bot);
  61                 ClientConnect(bot);
  62                 bot_setclientfields(bot);
  63                 PutClientInServer(bot);
  64         }
  65         return bot;
  66 }
  67
  68 void bot_think(entity this)
  69 {
  70         if (this.bot_nextthink > time)
  71                 return;
  72
  73         this.flags &= ~FL_GODMODE;
  74         if(autocvar_bot_god)
  75                 this.flags |= FL_GODMODE;
  76
  77         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * (0.5 ** this.bot_aiskill) * min(14 / (skill + 14), 1));
  78
  79         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
  80         {
  81                 CS(this).movement = '0 0 0';
  82                 this.bot_nextthink = time + 0.5;
  83                 return;
  84         }
  85
  86         if (this.fixangle)
  87         {
  88                 this.v_angle = this.angles;
  89                 this.v_angle_z = 0;
  90                 this.fixangle = false;
  91         }
  92
  93         this.dmg_take = 0;
  94         this.dmg_save = 0;
  95         this.dmg_inflictor = NULL;
  96
  97         // calculate an aiming latency based on the skill setting
  98         // (simulated network latency + naturally delayed reflexes)
  99         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
 100         // minimum ping 20+10 random
 101         CS(this).ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
 102         // skill 10 = ping 0.2 (adrenaline)
 103         // skill 0 = ping 0.7 (slightly drunk)
 104
 105         // clear buttons
 106         PHYS_INPUT_BUTTON_ATCK(this) = false;
 107         // keep jump button pressed for a short while, useful with ramp jumps
 108         PHYS_INPUT_BUTTON_JUMP(this) = (!IS_DEAD(this) && time < this.bot_jump_time + 0.2);
 109         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 110         PHYS_INPUT_BUTTON_ZOOM(this) = false;
 111         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 112         PHYS_INPUT_BUTTON_HOOK(this) = false;
 113         PHYS_INPUT_BUTTON_INFO(this) = false;
 114         PHYS_INPUT_BUTTON_DRAG(this) = false;
 115         PHYS_INPUT_BUTTON_CHAT(this) = false;
 116         PHYS_INPUT_BUTTON_USE(this) = false;
 117
 118         if (time < game_starttime)
 119         {
 120                 // block the bot during the countdown to game start
 121                 CS(this).movement = '0 0 0';
 122                 this.bot_nextthink = game_starttime;
 123                 return;
 124         }
 125
 126         // if dead, just wait until we can respawn
 127         if (IS_DEAD(this))
 128         {
 129                 if (bot_waypoint_queue_owner == this)
 130                         bot_waypoint_queue_owner = NULL;
 131                 this.aistatus = 0;
 132                 CS(this).movement = '0 0 0';
 133                 if (this.deadflag == DEAD_DEAD)
 134                 {
 135                         PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
 136                         navigation_goalrating_timeout_force(this);
 137                 }
 138         }
 139         else if(this.aistatus & AI_STATUS_STUCK)
 140                 navigation_unstuck(this);
 141
 142         // now call the current bot AI (havocbot for example)
 143         this.bot_ai(this);
 144 }
 145
 146 void bot_setnameandstuff(entity this)
 147 {
 148         string readfile, s;
 149         float file, tokens, prio;
 150
 151         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 152         string name, prefix, suffix;
 153
 154         if(autocvar_g_campaign)
 155         {
 156                 prefix = "";
 157                 suffix = "";
 158         }
 159         else
 160         {
 161                 prefix = autocvar_bot_prefix;
 162                 suffix = autocvar_bot_suffix;
 163         }
 164
 165         file = fopen(autocvar_bot_config_file, FILE_READ);
 166
 167         if(file < 0)
 168         {
 169                 LOG_INFOF("Error: Can not open the bot configuration file '%s'", autocvar_bot_config_file);
 170                 readfile = "";
 171         }
 172         else
 173         {
 174                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
 175                 TeamBalance_GetTeamCounts(balance, NULL);
 176                 int smallest_team = -1;
 177                 int smallest_count = -1;
 178                 if (teamplay)
 179                 {
 180                         for (int i = 1; i <= AvailableTeams(); ++i)
 181                         {
 182                                 // NOTE if (autocvar_g_campaign && autocvar_g_campaign_forceteam == i)
 183                                 // TeamBalance_GetNumberOfPlayers(balance, i); returns the number of players + 1
 184                                 // since it keeps a spot for the real player in the desired team
 185                                 int count = TeamBalance_GetNumberOfPlayers(balance, i);
 186                                 if (smallest_count < 0 || count < smallest_count)
 187                                 {
 188                                         smallest_team = i;
 189                                         smallest_count = count;
 190                                 }
 191                         }
 192                 }
 193                 TeamBalance_Destroy(balance);
 194                 RandomSelection_Init();
 195                 while((readfile = fgets(file)))
 196                 {
 197                         if(substring(readfile, 0, 2) == "//")
 198                                 continue;
 199                         if(substring(readfile, 0, 1) == "#")
 200                                 continue;
 201                         // NOTE if the line is empty tokenizebyseparator(readfile, "\t")
 202                         // will create 1 empty token because there's no separator (bug?)
 203                         if (readfile == "")
 204                                 continue;
 205                         tokens = tokenizebyseparator(readfile, "\t");
 206                         if(tokens == 0)
 207                                 continue;
 208                         s = argv(0);
 209                         prio = 0;
 210                         bool conflict = false;
 211                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 212                                 if (s == it.cleanname)
 213                                 {
 214                                         conflict = true;
 215                                         break;
 216                                 }
 217                         });
 218                         if (!conflict)
 219                                 prio += 1;
 220                         if (teamplay && !(autocvar_bot_vs_human && AvailableTeams() == 2))
 221                         {
 222                                 int forced_team = stof(argv(5));
 223                                 if (!Team_IsValidIndex(forced_team))
 224                                         forced_team = 0;
 225                                 if (!forced_team || forced_team == smallest_team)
 226                                         prio += 2;
 227                         }
 228                         RandomSelection_AddString(readfile, 1, prio);
 229                 }
 230                 readfile = RandomSelection_chosen_string;
 231                 fclose(file);
 232         }
 233
 234         tokens = tokenizebyseparator(readfile, "\t");
 235         if(argv(0) != "") bot_name = argv(0);
 236         else bot_name = "Bot";
 237
 238         if(argv(1) != "") bot_model = argv(1);
 239         else bot_model = "";
 240
 241         if(argv(2) != "") bot_skin = argv(2);
 242         else bot_skin = "0";
 243
 244         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 245         else bot_shirt = ftos(floor(random() * 15));
 246
 247         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 248         else bot_pants = ftos(floor(random() * 15));
 249
 250         if (teamplay && !(autocvar_bot_vs_human && AvailableTeams() == 2))
 251                 this.bot_forced_team = stof(argv(5));
 252         else
 253                 this.bot_forced_team = 0;
 254
 255         prio = 6;
 256
 257         #define READSKILL(f, w, r) MACRO_BEGIN \
 258                 if(argv(prio) != "") \
 259                         this.f = stof(argv(prio)) * w; \
 260                 else \
 261                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
 262                 prio++; \
 263         MACRO_END
 264         //print(bot_name, ": ping=", argv(9), "\n");
 265
 266         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 267         READSKILL(bot_moveskill, 2, 0); // move skill
 268         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 269
 270         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 271
 272         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 273         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 274         READSKILL(bot_rangepreference, 1, 0); // read skill
 275
 276         READSKILL(bot_aimskill, 2, 0); // aim skill
 277         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 278         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 279
 280         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 281         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 282
 283         if (file >= 0 && argv(prio) != "")
 284                 LOG_INFOF("^1Warning^7: too many parameters for bot %s, please check format of %s", bot_name, autocvar_bot_config_file);
 285
 286         this.bot_config_loaded = true;
 287
 288         // this is really only a default, TeamBalance_JoinBestTeam is called later
 289         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
 290         this.bot_preferredcolors = this.clientcolors;
 291
 292         // pick the name
 293         if (autocvar_bot_usemodelnames)
 294                 name = bot_model;
 295         else
 296                 name = bot_name;
 297
 298         // number bots with identical names
 299         if (name == "")
 300         {
 301                 name = ftos(etof(this));
 302                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 303         }
 304         else
 305         {
 306                 int j = 0;
 307                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 308                         if(it.cleanname == name)
 309                                 ++j;
 310                 });
 311                 if (j)
 312                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
 313                 else
 314                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 315         }
 316         this.cleanname = strzone(name);
 317
 318         // pick the model and skin
 319         if(substring(bot_model, -4, 1) != ".")
 320                 bot_model = strcat(bot_model, ".iqm");
 321         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 322         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
 323 }
 324
 325 void bot_custom_weapon_priority_setup()
 326 {
 327         static string bot_priority_far_prev;
 328         static string bot_priority_mid_prev;
 329         static string bot_priority_close_prev;
 330         static string bot_priority_distances_prev;
 331         float tokens, i, w;
 332
 333         bot_custom_weapon = false;
 334
 335         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
 336                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
 337                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
 338                 autocvar_bot_ai_custom_weapon_priority_distances == ""
 339         )
 340                 return;
 341
 342         if (bot_priority_distances_prev != autocvar_bot_ai_custom_weapon_priority_distances)
 343         {
 344                 strcpy(bot_priority_distances_prev, autocvar_bot_ai_custom_weapon_priority_distances);
 345                 tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
 346
 347                 if (tokens!=2)
 348                         return;
 349
 350                 bot_distance_far = stof(argv(0));
 351                 bot_distance_close = stof(argv(1));
 352
 353                 if(bot_distance_far < bot_distance_close){
 354                         bot_distance_far = stof(argv(1));
 355                         bot_distance_close = stof(argv(0));
 356                 }
 357         }
 358
 359         int c;
 360
 361         #define PARSE_WEAPON_PRIORITIES(dist) MACRO_BEGIN \
 362                 if (bot_priority_##dist##_prev != autocvar_bot_ai_custom_weapon_priority_##dist) { \
 363                         strcpy(bot_priority_##dist##_prev, autocvar_bot_ai_custom_weapon_priority_##dist); \
 364                         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_##dist)," "); \
 365                         bot_weapons_##dist[0] = -1; \
 366                         c = 0; \
 367                         for(i = 0; i < tokens && c < Weapons_COUNT; ++i) { \
 368                                 w = stof(argv(i)); \
 369                                 if (w >= WEP_FIRST && w <= WEP_LAST) { \
 370                                         bot_weapons_##dist[c] = w; \
 371                                         ++c; \
 372                                 } \
 373                         } \
 374                         if (c < Weapons_COUNT) \
 375                                 bot_weapons_##dist[c] = -1; \
 376                 } \
 377         MACRO_END
 378
 379         PARSE_WEAPON_PRIORITIES(far);
 380         PARSE_WEAPON_PRIORITIES(mid);
 381         PARSE_WEAPON_PRIORITIES(close);
 382
 383         bot_custom_weapon = true;
 384 }
 385
 386 void bot_endgame()
 387 {
 388         bot_relinkplayerlist();
 389         entity e = bot_list;
 390         while (e)
 391         {
 392                 setcolor(e, e.bot_preferredcolors);
 393                 e = e.nextbot;
 394         }
 395         // if dynamic waypoints are ever implemented, save them here
 396 }
 397
 398 void bot_relinkplayerlist()
 399 {
 400         player_count = 0;
 401         currentbots = 0;
 402         bot_list = NULL;
 403
 404         entity prevbot = NULL;
 405         FOREACH_CLIENT(true,
 406         {
 407                 ++player_count;
 408
 409                 if(IS_BOT_CLIENT(it))
 410                 {
 411                         if(prevbot)
 412                                 prevbot.nextbot = it;
 413                         else
 414                                 bot_list = it;
 415                         prevbot = it;
 416                         ++currentbots;
 417                 }
 418         });
 419         if(prevbot)
 420                 prevbot.nextbot = NULL;
 421         LOG_TRACE("relink: ", ftos(currentbots), " bots seen.");
 422         bot_strategytoken = bot_list;
 423         bot_strategytoken_taken = true;
 424 }
 425
 426 void bot_clientdisconnect(entity this)
 427 {
 428         if (!IS_BOT_CLIENT(this))
 429                 return;
 430         bot_clearqueue(this);
 431         strfree(this.cleanname);
 432         strfree(this.netname_freeme);
 433         strfree(this.playermodel_freeme);
 434         strfree(this.playerskin_freeme);
 435         if(this.bot_cmd_current)
 436                 delete(this.bot_cmd_current);
 437         if(bot_waypoint_queue_owner == this)
 438                 bot_waypoint_queue_owner = NULL;
 439 }
 440
 441 void bot_clientconnect(entity this)
 442 {
 443         if (!IS_BOT_CLIENT(this)) return;
 444         this.bot_preferredcolors = this.clientcolors;
 445         this.bot_nextthink = time - random();
 446         this.lag_func = bot_lagfunc;
 447         this.isbot = true;
 448         this.createdtime = this.bot_nextthink;
 449
 450         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 451         {
 452                 bot_setnameandstuff(this);
 453                 bot_setclientfields(this);
 454         }
 455
 456         if (teamplay && Team_IsValidIndex(this.bot_forced_team))
 457         {
 458                 SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
 459         }
 460         else
 461         {
 462                 this.bot_forced_team = 0;
 463                 TeamBalance_JoinBestTeam(this);
 464         }
 465
 466         havocbot_setupbot(this);
 467 }
 468
 469 void bot_removefromlargestteam()
 470 {
 471         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 472         TeamBalance_GetTeamCounts(balance, NULL);
 473
 474         entity best = NULL;
 475         float besttime = 0;
 476         int bestcount = 0;
 477
 478         int bcount = 0;
 479         FOREACH_CLIENT(it.isbot,
 480         {
 481                 ++bcount;
 482
 483                 if(!best)
 484                 {
 485                         best = it;
 486                         besttime = it.createdtime;
 487                 }
 488
 489                 int thiscount = 0;
 490
 491                 if (Team_IsValidTeam(it.team))
 492                 {
 493                         thiscount = TeamBalance_GetNumberOfPlayers(balance,
 494                                 Team_TeamToIndex(it.team));
 495                 }
 496
 497                 if(thiscount > bestcount)
 498                 {
 499                         bestcount = thiscount;
 500                         besttime = it.createdtime;
 501                         best = it;
 502                 }
 503                 else if(thiscount == bestcount && besttime < it.createdtime)
 504                 {
 505                         besttime = it.createdtime;
 506                         best = it;
 507                 }
 508         });
 509         TeamBalance_Destroy(balance);
 510         if(!bcount)
 511                 return; // no bots to remove
 512         currentbots = currentbots - 1;
 513         dropclient(best);
 514 }
 515
 516 void bot_removenewest()
 517 {
 518         if(teamplay)
 519         {
 520                 bot_removefromlargestteam();
 521                 return;
 522         }
 523
 524         float besttime = 0;
 525         entity best = NULL;
 526         int bcount = 0;
 527
 528         FOREACH_CLIENT(it.isbot,
 529         {
 530                 ++bcount;
 531
 532                 if(!best)
 533                 {
 534                         best = it;
 535                         besttime = it.createdtime;
 536                 }
 537
 538                 if(besttime < it.createdtime)
 539                 {
 540                         besttime = it.createdtime;
 541                         best = it;
 542                 }
 543         });
 544
 545         if(!bcount)
 546                 return; // no bots to remove
 547
 548         currentbots = currentbots - 1;
 549         dropclient(best);
 550 }
 551
 552 void autoskill(float factor)
 553 {
 554         float bestbot;
 555         float bestplayer;
 556
 557         bestbot = -1;
 558         bestplayer = -1;
 559         FOREACH_CLIENT(IS_PLAYER(it), {
 560                 if(IS_REAL_CLIENT(it))
 561                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
 562                 else
 563                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
 564         });
 565
 566         LOG_DEBUG("autoskill: best player got ", ftos(bestplayer), ", ");
 567         LOG_DEBUG("best bot got ", ftos(bestbot), "; ");
 568         if(bestbot < 0 || bestplayer < 0)
 569         {
 570                 LOG_DEBUG("not doing anything");
 571                 // don't return, let it reset all counters below
 572         }
 573         else if(bestbot <= bestplayer * factor - 2)
 574         {
 575                 if(autocvar_skill < 17)
 576                 {
 577                         LOG_DEBUG("2 frags difference, increasing skill");
 578                         cvar_set("skill", ftos(autocvar_skill + 1));
 579                         bprint("^2SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
 580                 }
 581         }
 582         else if(bestbot >= bestplayer * factor + 2)
 583         {
 584                 if(autocvar_skill > 0)
 585                 {
 586                         LOG_DEBUG("2 frags difference, decreasing skill");
 587                         cvar_set("skill", ftos(autocvar_skill - 1));
 588                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
 589                 }
 590         }
 591         else
 592         {
 593                 LOG_DEBUG("not doing anything");
 594                 return;
 595                 // don't reset counters, wait for them to accumulate
 596         }
 597
 598         FOREACH_CLIENT(IS_PLAYER(it), { it.totalfrags_lastcheck = it.totalfrags; });
 599 }
 600
 601 void bot_calculate_stepheightvec()
 602 {
 603         stepheightvec = autocvar_sv_stepheight * '0 0 1';
 604         jumpheight_vec = (autocvar_sv_jumpvelocity ** 2) / (2 * autocvar_sv_gravity) * '0 0 1';
 605         jumpstepheightvec = stepheightvec + jumpheight_vec * 0.85; // reduce it a bit to make the jumps easy
 606         jumpheight_time = autocvar_sv_jumpvelocity / autocvar_sv_gravity;
 607 }
 608
 609 bool bot_fixcount()
 610 {
 611         int activerealplayers = 0;
 612         int realplayers = 0;
 613         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
 614                 activerealplayers = M_ARGV(0, int);
 615                 realplayers = M_ARGV(1, int);
 616         } else {
 617                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 618                         if(IS_PLAYER(it))
 619                                 ++activerealplayers;
 620                         ++realplayers;
 621                 });
 622         }
 623
 624         int bots;
 625         // But don't remove bots immediately on level change, as the real players
 626         // usually haven't rejoined yet
 627         bots_would_leave = false;
 628         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
 629                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
 630         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
 631         {
 632                 int minplayers = max(0, floor(autocvar_minplayers));
 633                 if (teamplay)
 634                         minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
 635                 int minbots = max(0, floor(autocvar_bot_number));
 636
 637                 // add bots to reach minplayers if needed
 638                 bots = max(minbots, minplayers - activerealplayers);
 639                 // cap bots to the max players allowed by the server
 640                 int player_limit = GetPlayerLimit();
 641                 if(player_limit)
 642                         bots = min(bots, max(player_limit - activerealplayers, 0));
 643                 bots = min(bots, maxclients - realplayers);
 644
 645                 if(bots > minbots)
 646                         bots_would_leave = true;
 647         }
 648         else
 649         {
 650                 // if there are no players, remove bots
 651                 bots = 0;
 652         }
 653
 654         // only add one bot per frame to avoid utter chaos
 655         if(time > botframe_nextthink)
 656         {
 657                 if (currentbots < bots)
 658                 {
 659                         if (bot_spawn() == NULL)
 660                         {
 661                                 bprint("Can not add bot, server full.\n");
 662                                 return false;
 663                         }
 664                 }
 665                 while (currentbots > bots && bots >= 0)
 666                         bot_removenewest();
 667         }
 668
 669         return true;
 670 }
 671
 672 void bot_remove_from_bot_list(entity this)
 673 {
 674         entity e = bot_list;
 675         entity prev_bot = NULL;
 676         while (e)
 677         {
 678                 if(e == this)
 679                 {
 680                         if(!prev_bot)
 681                                 bot_list = this.nextbot;
 682                         else
 683                                 prev_bot.nextbot = this.nextbot;
 684                         if(bot_strategytoken == this)
 685                         {
 686                                 bot_strategytoken = this.nextbot;
 687                                 bot_strategytoken_taken = true;
 688                         }
 689                         this.nextbot = NULL;
 690                         break;
 691                 }
 692                 prev_bot = e;
 693                 e = e.nextbot;
 694         }
 695 }
 696
 697 void bot_clear(entity this)
 698 {
 699         bot_remove_from_bot_list(this);
 700         if(bot_waypoint_queue_owner == this)
 701                 bot_waypoint_queue_owner = NULL;
 702         this.aistatus &= ~AI_STATUS_STUCK; // otherwise bot_waypoint_queue_owner will be set again to this by navigation_unstuck
 703 }
 704
 705 void bot_serverframe()
 706 {
 707         if (intermission_running && currentbots > 0)
 708         {
 709                 // after the end of the match all bots stay unless all human players disconnect
 710                 int realplayers = 0;
 711                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++realplayers; });
 712                 if (!realplayers)
 713                 {
 714                         FOREACH_CLIENT(IS_BOT_CLIENT(it), { dropclient(it); });
 715                         currentbots = 0;
 716                 }
 717                 return;
 718         }
 719
 720         if (game_stopped)
 721                 return;
 722
 723         // Added 0.5 to avoid possible addition + immediate removal of bots that would make them appear as
 724         // spectators in the scoreboard and never go away. This issue happens at time 2 if map is changed
 725         // with the gotomap command, minplayers is > 1 and human clients join as players very soon
 726         // either intentionally or automatically (sv_spectate 0)
 727         if (time < 2.5)
 728         {
 729                 currentbots = -1;
 730                 return;
 731         }
 732
 733         if (currentbots == -1)
 734         {
 735                 // count bots already in the server from the previous match
 736                 currentbots = 0;
 737                 FOREACH_CLIENT(IS_BOT_CLIENT(it), { ++currentbots; });
 738         }
 739
 740         if(autocvar_skill != skill)
 741         {
 742                 float wpcost_update = false;
 743                 if(skill >= autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill < autocvar_bot_ai_bunnyhop_skilloffset)
 744                         wpcost_update = true;
 745                 if(skill < autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 746                         wpcost_update = true;
 747
 748                 skill = autocvar_skill;
 749                 if (wpcost_update)
 750                         waypoint_updatecost_foralllinks();
 751         }
 752
 753         bot_calculate_stepheightvec();
 754         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 755
 756         if(time > autoskill_nextthink)
 757         {
 758                 float a;
 759                 a = autocvar_skill_auto;
 760                 if(a)
 761                         autoskill(a);
 762                 autoskill_nextthink = time + 5;
 763         }
 764
 765         if(time > botframe_nextthink)
 766         {
 767                 if(!bot_fixcount())
 768                         botframe_nextthink = time + 10;
 769         }
 770
 771         if(botframe_spawnedwaypoints)
 772         {
 773                 if(autocvar_waypoint_benchmark)
 774                         localcmd("quit\n");
 775         }
 776
 777         if (currentbots > 0 || autocvar_g_waypointeditor || autocvar_g_waypointeditor_auto)
 778         if (botframe_spawnedwaypoints)
 779         {
 780                 if(botframe_cachedwaypointlinks)
 781                 {
 782                         if(!botframe_loadedforcedlinks)
 783                                 waypoint_load_hardwiredlinks();
 784                 }
 785                 else
 786                 {
 787                         // TODO: Make this check cleaner
 788                         IL_EACH(g_waypoints, time - it.nextthink > 10,
 789                         {
 790                                 waypoint_save_links();
 791                                 break;
 792                         });
 793                 }
 794         }
 795         else
 796         {
 797                 botframe_spawnedwaypoints = true;
 798                 waypoint_loadall();
 799                 waypoint_load_links();
 800         }
 801
 802         if (bot_list)
 803         {
 804                 // cycle the goal token from one bot to the next each frame
 805                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 806                 //  frame, which causes choppy framerates)
 807                 if (bot_strategytoken_taken)
 808                 {
 809                         // give goal token to the first bot without goals; if all bots don't have
 810                         // any goal (or are dead/frozen) simply give it to the next one
 811                         bot_strategytoken_taken = false;
 812                         entity bot_strategytoken_save = bot_strategytoken;
 813                         while (true)
 814                         {
 815                                 if (bot_strategytoken)
 816                                         bot_strategytoken = bot_strategytoken.nextbot;
 817                                 if (!bot_strategytoken)
 818                                         bot_strategytoken = bot_list;
 819
 820                                 if (!(IS_DEAD(bot_strategytoken) || STAT(FROZEN, bot_strategytoken))
 821                                         && !bot_strategytoken.goalcurrent)
 822                                         break;
 823
 824                                 if (!bot_strategytoken_save) // break loop if all the bots are dead or frozen
 825                                         break;
 826                                 if (bot_strategytoken == bot_strategytoken_save)
 827                                         bot_strategytoken_save = NULL; // looped through all the bots
 828                         }
 829                 }
 830
 831                 if (botframe_nextdangertime < time)
 832                 {
 833                         float interval;
 834                         interval = autocvar_bot_ai_dangerdetectioninterval;
 835                         if (botframe_nextdangertime < time - interval * 1.5)
 836                                 botframe_nextdangertime = time;
 837                         botframe_nextdangertime = botframe_nextdangertime + interval;
 838                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
 839                 }
 840         }
 841
 842         if (autocvar_g_waypointeditor)
 843                 botframe_showwaypointlinks();
 844
 845         if (autocvar_g_waypointeditor_auto)
 846                 botframe_autowaypoints();
 847
 848         if (currentbots > 0)
 849                 bot_custom_weapon_priority_setup();
 850 }