qcsrc/server/bot/default/bot.qc

   1 #include "bot.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/mapinfo.qh>
   5 #include <common/net_linked.qh>
   6 #include <common/physics/player.qh>
   7 #include <common/stats.qh>
   8 #include <common/teams.qh>
   9 #include <common/util.qh>
  10 #include <common/weapons/_all.qh>
  11 #include <lib/csqcmodel/sv_model.qh>
  12 #include <lib/warpzone/common.qh>
  13 #include <lib/warpzone/util_server.qh>
  14 #include <server/antilag.qh>
  15 #include <server/autocvars.qh>
  16 #include <server/bot/default/aim.qh>
  17 #include <server/bot/default/cvars.qh>
  18 #include <server/bot/default/havocbot/havocbot.qh>
  19 #include <server/bot/default/havocbot/scripting.qh>
  20 #include <server/bot/default/navigation.qh>
  21 #include <server/bot/default/scripting.qh>
  22 #include <server/bot/default/waypoints.qh>
  23 #include <server/campaign.qh>
  24 #include <server/client.qh>
  25 #include <server/damage.qh>
  26 #include <server/items/items.qh>
  27 #include <server/mutators/_mod.qh>
  28 #include <server/race.qh>
  29 #include <server/scores_rules.qh>
  30 #include <server/teamplay.qh>
  31 #include <server/weapons/accuracy.qh>
  32 #include <server/world.qh>
  33
  34 STATIC_INIT(bot) { bot_calculate_stepheightvec(); }
  35
  36 // TODO: remove this function! its only purpose is to update these fields since bot_setnameandstuff is called before ClientState
  37 void bot_setclientfields(entity this)
  38 {
  39         CS(this).cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
  40         CS(this).cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
  41 }
  42
  43 entity bot_spawn()
  44 {
  45         entity bot = spawnclient();
  46         if (bot)
  47         {
  48                 setItemGroupCount();
  49                 currentbots = currentbots + 1;
  50                 bot_setnameandstuff(bot);
  51                 ClientConnect(bot);
  52                 bot_setclientfields(bot);
  53                 PutClientInServer(bot);
  54         }
  55         return bot;
  56 }
  57
  58 void bot_think(entity this)
  59 {
  60         if (this.bot_nextthink > time)
  61                 return;
  62
  63         this.flags &= ~FL_GODMODE;
  64         if(autocvar_bot_god)
  65                 this.flags |= FL_GODMODE;
  66
  67         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * (0.5 ** this.bot_aiskill) * min(14 / (skill + 14), 1));
  68
  69         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
  70         {
  71                 CS(this).movement = '0 0 0';
  72                 this.bot_nextthink = time + 0.5;
  73                 return;
  74         }
  75
  76         if (this.fixangle)
  77         {
  78                 this.v_angle = this.angles;
  79                 this.v_angle_z = 0;
  80                 this.fixangle = false;
  81         }
  82
  83         this.dmg_take = 0;
  84         this.dmg_save = 0;
  85         this.dmg_inflictor = NULL;
  86
  87         // calculate an aiming latency based on the skill setting
  88         // (simulated network latency + naturally delayed reflexes)
  89         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
  90         // minimum ping 20+10 random
  91         CS(this).ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
  92         // skill 10 = ping 0.2 (adrenaline)
  93         // skill 0 = ping 0.7 (slightly drunk)
  94
  95         // clear buttons
  96         PHYS_INPUT_BUTTON_ATCK(this) = false;
  97         // keep jump button pressed for a short while, useful with ramp jumps
  98         PHYS_INPUT_BUTTON_JUMP(this) = (!IS_DEAD(this) && time < this.bot_jump_time + 0.2);
  99         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 100         PHYS_INPUT_BUTTON_ZOOM(this) = false;
 101         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 102         PHYS_INPUT_BUTTON_HOOK(this) = false;
 103         PHYS_INPUT_BUTTON_INFO(this) = false;
 104         PHYS_INPUT_BUTTON_DRAG(this) = false;
 105         PHYS_INPUT_BUTTON_CHAT(this) = false;
 106         PHYS_INPUT_BUTTON_USE(this) = false;
 107
 108         if (time < game_starttime)
 109         {
 110                 // block the bot during the countdown to game start
 111                 CS(this).movement = '0 0 0';
 112                 this.bot_nextthink = game_starttime;
 113                 return;
 114         }
 115
 116         // if dead, just wait until we can respawn
 117         if (IS_DEAD(this))
 118         {
 119                 if (bot_waypoint_queue_owner == this)
 120                         bot_waypoint_queue_owner = NULL;
 121                 this.aistatus = 0;
 122                 CS(this).movement = '0 0 0';
 123                 if (this.deadflag == DEAD_DEAD)
 124                 {
 125                         PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
 126                         navigation_goalrating_timeout_force(this);
 127                 }
 128         }
 129         else if(this.aistatus & AI_STATUS_STUCK)
 130                 navigation_unstuck(this);
 131
 132         // now call the current bot AI (havocbot for example)
 133         this.bot_ai(this);
 134 }
 135
 136 void bot_setnameandstuff(entity this)
 137 {
 138         string readfile, s;
 139         int file, tokens, prio;
 140
 141         file = fopen(autocvar_bot_config_file, FILE_READ);
 142
 143         if(file < 0)
 144         {
 145                 LOG_INFOF("Error: Can not open the bot configuration file '%s'", autocvar_bot_config_file);
 146                 readfile = "";
 147         }
 148         else
 149         {
 150                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
 151                 TeamBalance_GetTeamCounts(balance, NULL);
 152                 int smallest_team = -1;
 153                 int smallest_count = -1;
 154                 if (teamplay)
 155                 {
 156                         for (int i = 1; i <= AvailableTeams(); ++i)
 157                         {
 158                                 // NOTE if (autocvar_g_campaign && autocvar_g_campaign_forceteam == i)
 159                                 // TeamBalance_GetNumberOfPlayers(balance, i); returns the number of players + 1
 160                                 // since it keeps a spot for the real player in the desired team
 161                                 int count = TeamBalance_GetNumberOfPlayers(balance, i);
 162                                 if (smallest_count < 0 || count < smallest_count)
 163                                 {
 164                                         smallest_team = i;
 165                                         smallest_count = count;
 166                                 }
 167                         }
 168                 }
 169                 TeamBalance_Destroy(balance);
 170                 RandomSelection_Init();
 171                 while((readfile = fgets(file)))
 172                 {
 173                         if(substring(readfile, 0, 2) == "//")
 174                                 continue;
 175                         if(substring(readfile, 0, 1) == "#")
 176                                 continue;
 177                         // NOTE if the line is empty tokenizebyseparator(readfile, "\t")
 178                         // will create 1 empty token because there's no separator (bug?)
 179                         if (readfile == "")
 180                                 continue;
 181                         tokens = tokenizebyseparator(readfile, "\t");
 182                         if(tokens == 0)
 183                                 continue;
 184                         s = argv(0);
 185                         prio = 0;
 186                         bool conflict = false;
 187                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 188                                 if (s == it.cleanname)
 189                                 {
 190                                         conflict = true;
 191                                         break;
 192                                 }
 193                         });
 194                         if (!conflict)
 195                                 prio += 1;
 196                         if (teamplay && !(autocvar_bot_vs_human && AvailableTeams() == 2))
 197                         {
 198                                 int forced_team = stof(argv(5));
 199                                 if (!Team_IsValidIndex(forced_team))
 200                                         forced_team = 0;
 201                                 if (!forced_team || forced_team == smallest_team)
 202                                         prio += 2;
 203                         }
 204                         RandomSelection_AddString(readfile, 1, prio);
 205                 }
 206                 readfile = RandomSelection_chosen_string;
 207                 fclose(file);
 208         }
 209
 210         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 211
 212         tokens = tokenizebyseparator(readfile, "\t");
 213         if(argv(0) != "") bot_name = argv(0);
 214         else bot_name = "Bot";
 215
 216         if(argv(1) != "") bot_model = argv(1);
 217         else bot_model = "";
 218
 219         if(argv(2) != "") bot_skin = argv(2);
 220         else bot_skin = "0";
 221
 222         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 223         else bot_shirt = ftos(floor(random() * 15));
 224
 225         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 226         else bot_pants = ftos(floor(random() * 15));
 227
 228         if (teamplay && !(autocvar_bot_vs_human && AvailableTeams() == 2))
 229                 this.bot_forced_team = stof(argv(5));
 230         else
 231                 this.bot_forced_team = 0;
 232
 233         prio = 6;
 234
 235         #define READSKILL(f, w, r) MACRO_BEGIN \
 236                 if(argv(prio) != "") \
 237                         this.f = stof(argv(prio)) * w; \
 238                 else \
 239                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
 240                 prio++; \
 241         MACRO_END
 242         //print(bot_name, ": ping=", argv(9), "\n");
 243
 244         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 245         READSKILL(bot_moveskill, 2, 0); // move skill
 246         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 247
 248         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 249
 250         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 251         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 252         READSKILL(bot_rangepreference, 1, 0); // read skill
 253
 254         READSKILL(bot_aimskill, 2, 0); // aim skill
 255         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 256         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 257
 258         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 259         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 260
 261         if (file >= 0 && argv(prio) != "")
 262                 LOG_INFOF("^1Warning^7: too many parameters for bot %s, please check format of %s", bot_name, autocvar_bot_config_file);
 263
 264         this.bot_config_loaded = true;
 265
 266         // this is really only a default, TeamBalance_JoinBestTeam is called later
 267         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
 268         this.bot_preferredcolors = this.clientcolors;
 269
 270         string prefix = (autocvar_g_campaign ? "" : autocvar_bot_prefix);
 271         string suffix = (autocvar_g_campaign ? "" : autocvar_bot_suffix);
 272         string name = (autocvar_bot_usemodelnames ? bot_model : bot_name);
 273
 274         if (name == "")
 275         {
 276                 name = ftos(etof(this));
 277                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 278         }
 279         else
 280         {
 281                 // number bots with identical names
 282                 int j = 0;
 283                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 284                         if(it.cleanname == name)
 285                                 ++j;
 286                 });
 287                 if (j)
 288                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
 289                 else
 290                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 291         }
 292         this.cleanname = strzone(name);
 293
 294         // pick the model and skin
 295         if(substring(bot_model, -4, 1) != ".")
 296                 bot_model = strcat(bot_model, ".iqm");
 297         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 298         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
 299 }
 300
 301 void bot_custom_weapon_priority_setup()
 302 {
 303         static string bot_priority_far_prev;
 304         static string bot_priority_mid_prev;
 305         static string bot_priority_close_prev;
 306         static string bot_priority_distances_prev;
 307         float tokens, i, w;
 308
 309         bot_custom_weapon = false;
 310
 311         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
 312                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
 313                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
 314                 autocvar_bot_ai_custom_weapon_priority_distances == ""
 315         )
 316                 return;
 317
 318         if (bot_priority_distances_prev != autocvar_bot_ai_custom_weapon_priority_distances)
 319         {
 320                 strcpy(bot_priority_distances_prev, autocvar_bot_ai_custom_weapon_priority_distances);
 321                 tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
 322
 323                 if (tokens!=2)
 324                         return;
 325
 326                 bot_distance_far = stof(argv(0));
 327                 bot_distance_close = stof(argv(1));
 328
 329                 if(bot_distance_far < bot_distance_close){
 330                         bot_distance_far = stof(argv(1));
 331                         bot_distance_close = stof(argv(0));
 332                 }
 333         }
 334
 335         int c;
 336
 337         #define PARSE_WEAPON_PRIORITIES(dist) MACRO_BEGIN \
 338                 if (bot_priority_##dist##_prev != autocvar_bot_ai_custom_weapon_priority_##dist) { \
 339                         strcpy(bot_priority_##dist##_prev, autocvar_bot_ai_custom_weapon_priority_##dist); \
 340                         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_##dist)," "); \
 341                         bot_weapons_##dist[0] = -1; \
 342                         c = 0; \
 343                         for(i = 0; i < tokens && c < REGISTRY_COUNT(Weapons); ++i) { \
 344                                 w = stof(argv(i)); \
 345                                 if (w >= WEP_FIRST && w <= WEP_LAST) { \
 346                                         bot_weapons_##dist[c] = w; \
 347                                         ++c; \
 348                                 } \
 349                         } \
 350                         if (c < REGISTRY_COUNT(Weapons)) \
 351                                 bot_weapons_##dist[c] = -1; \
 352                 } \
 353         MACRO_END
 354
 355         PARSE_WEAPON_PRIORITIES(far);
 356         PARSE_WEAPON_PRIORITIES(mid);
 357         PARSE_WEAPON_PRIORITIES(close);
 358
 359         bot_custom_weapon = true;
 360 }
 361
 362 void bot_endgame()
 363 {
 364         bot_relinkplayerlist();
 365         entity e = bot_list;
 366         while (e)
 367         {
 368                 setcolor(e, e.bot_preferredcolors);
 369                 e = e.nextbot;
 370         }
 371         // if dynamic waypoints are ever implemented, save them here
 372 }
 373
 374 void bot_relinkplayerlist()
 375 {
 376         player_count = 0;
 377         currentbots = 0;
 378         bot_list = NULL;
 379
 380         entity prevbot = NULL;
 381         FOREACH_CLIENT(true,
 382         {
 383                 ++player_count;
 384
 385                 if(IS_BOT_CLIENT(it))
 386                 {
 387                         if(prevbot)
 388                                 prevbot.nextbot = it;
 389                         else
 390                                 bot_list = it;
 391                         prevbot = it;
 392                         ++currentbots;
 393                 }
 394         });
 395         if(prevbot)
 396                 prevbot.nextbot = NULL;
 397         LOG_TRACE("relink: ", ftos(currentbots), " bots seen.");
 398         bot_strategytoken = bot_list;
 399         bot_strategytoken_taken = true;
 400 }
 401
 402 void bot_clientdisconnect(entity this)
 403 {
 404         if (!IS_BOT_CLIENT(this))
 405                 return;
 406         bot_clearqueue(this);
 407         strfree(this.cleanname);
 408         strfree(this.netname_freeme);
 409         strfree(this.playermodel_freeme);
 410         strfree(this.playerskin_freeme);
 411         if(this.bot_cmd_current)
 412                 delete(this.bot_cmd_current);
 413         if(bot_waypoint_queue_owner == this)
 414                 bot_waypoint_queue_owner = NULL;
 415 }
 416
 417 void bot_clientconnect(entity this)
 418 {
 419         if (!IS_BOT_CLIENT(this)) return;
 420         this.bot_preferredcolors = this.clientcolors;
 421         this.bot_nextthink = time - random();
 422         this.lag_func = bot_lagfunc;
 423         this.isbot = true;
 424         this.createdtime = this.bot_nextthink;
 425
 426         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 427         {
 428                 bot_setnameandstuff(this);
 429                 bot_setclientfields(this);
 430         }
 431
 432         if (teamplay && Team_IsValidIndex(this.bot_forced_team))
 433         {
 434                 SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
 435         }
 436         else
 437         {
 438                 this.bot_forced_team = 0;
 439                 TeamBalance_JoinBestTeam(this);
 440         }
 441
 442         havocbot_setupbot(this);
 443 }
 444
 445 void bot_removefromlargestteam()
 446 {
 447         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 448         TeamBalance_GetTeamCounts(balance, NULL);
 449
 450         entity best = NULL;
 451         float besttime = 0;
 452         int bestcount = 0;
 453
 454         int bcount = 0;
 455         FOREACH_CLIENT(it.isbot,
 456         {
 457                 ++bcount;
 458
 459                 if(!best)
 460                 {
 461                         best = it;
 462                         besttime = it.createdtime;
 463                 }
 464
 465                 int thiscount = 0;
 466
 467                 if (Team_IsValidTeam(it.team))
 468                 {
 469                         thiscount = TeamBalance_GetNumberOfPlayers(balance,
 470                                 Team_TeamToIndex(it.team));
 471                 }
 472
 473                 if(thiscount > bestcount)
 474                 {
 475                         bestcount = thiscount;
 476                         besttime = it.createdtime;
 477                         best = it;
 478                 }
 479                 else if(thiscount == bestcount && besttime < it.createdtime)
 480                 {
 481                         besttime = it.createdtime;
 482                         best = it;
 483                 }
 484         });
 485         TeamBalance_Destroy(balance);
 486         if(!bcount)
 487                 return; // no bots to remove
 488         currentbots = currentbots - 1;
 489         dropclient(best);
 490 }
 491
 492 void bot_removenewest()
 493 {
 494         if(teamplay)
 495         {
 496                 bot_removefromlargestteam();
 497                 return;
 498         }
 499
 500         float besttime = 0;
 501         entity best = NULL;
 502         int bcount = 0;
 503
 504         FOREACH_CLIENT(it.isbot,
 505         {
 506                 ++bcount;
 507
 508                 if(!best)
 509                 {
 510                         best = it;
 511                         besttime = it.createdtime;
 512                 }
 513
 514                 if(besttime < it.createdtime)
 515                 {
 516                         besttime = it.createdtime;
 517                         best = it;
 518                 }
 519         });
 520
 521         if(!bcount)
 522                 return; // no bots to remove
 523
 524         currentbots = currentbots - 1;
 525         dropclient(best);
 526 }
 527
 528 void autoskill(float factor)
 529 {
 530         float bestbot;
 531         float bestplayer;
 532
 533         bestbot = -1;
 534         bestplayer = -1;
 535         FOREACH_CLIENT(IS_PLAYER(it), {
 536                 if(IS_REAL_CLIENT(it))
 537                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
 538                 else
 539                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
 540         });
 541
 542         LOG_DEBUG("autoskill: best player got ", ftos(bestplayer), ", ");
 543         LOG_DEBUG("best bot got ", ftos(bestbot), "; ");
 544         if(bestbot < 0 || bestplayer < 0)
 545         {
 546                 LOG_DEBUG("not doing anything");
 547                 // don't return, let it reset all counters below
 548         }
 549         else if(bestbot <= bestplayer * factor - 2)
 550         {
 551                 if(autocvar_skill < 17)
 552                 {
 553                         LOG_DEBUG("2 frags difference, increasing skill");
 554                         cvar_set("skill", ftos(autocvar_skill + 1));
 555                         bprint("^2SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
 556                 }
 557         }
 558         else if(bestbot >= bestplayer * factor + 2)
 559         {
 560                 if(autocvar_skill > 0)
 561                 {
 562                         LOG_DEBUG("2 frags difference, decreasing skill");
 563                         cvar_set("skill", ftos(autocvar_skill - 1));
 564                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
 565                 }
 566         }
 567         else
 568         {
 569                 LOG_DEBUG("not doing anything");
 570                 return;
 571                 // don't reset counters, wait for them to accumulate
 572         }
 573
 574         FOREACH_CLIENT(IS_PLAYER(it), { it.totalfrags_lastcheck = it.totalfrags; });
 575 }
 576
 577 void bot_calculate_stepheightvec()
 578 {
 579         stepheightvec = autocvar_sv_stepheight * '0 0 1';
 580         jumpheight_vec = (autocvar_sv_jumpvelocity ** 2) / (2 * autocvar_sv_gravity) * '0 0 1';
 581         jumpstepheightvec = stepheightvec + jumpheight_vec * 0.85; // reduce it a bit to make the jumps easy
 582         jumpheight_time = autocvar_sv_jumpvelocity / autocvar_sv_gravity;
 583 }
 584
 585 bool bot_fixcount()
 586 {
 587         int activerealplayers = 0;
 588         int realplayers = 0;
 589         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
 590                 activerealplayers = M_ARGV(0, int);
 591                 realplayers = M_ARGV(1, int);
 592         } else {
 593                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 594                         if(IS_PLAYER(it))
 595                                 ++activerealplayers;
 596                         ++realplayers;
 597                 });
 598         }
 599
 600         int bots;
 601         // But don't remove bots immediately on level change, as the real players
 602         // usually haven't rejoined yet
 603         bots_would_leave = false;
 604         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
 605                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
 606         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
 607         {
 608                 int minplayers = max(0, floor(autocvar_minplayers));
 609                 if (teamplay)
 610                         minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
 611                 int minbots = max(0, floor(autocvar_bot_number));
 612
 613                 // add bots to reach minplayers if needed
 614                 bots = max(minbots, minplayers - activerealplayers);
 615                 // cap bots to the max players allowed by the server
 616                 int player_limit = GetPlayerLimit();
 617                 if(player_limit)
 618                         bots = min(bots, max(player_limit - activerealplayers, 0));
 619                 bots = min(bots, maxclients - realplayers);
 620
 621                 if(bots > minbots)
 622                         bots_would_leave = true;
 623         }
 624         else
 625         {
 626                 // if there are no players, remove bots
 627                 bots = 0;
 628         }
 629
 630         // only add one bot per frame to avoid utter chaos
 631         if(time > botframe_nextthink)
 632         {
 633                 if (currentbots < bots)
 634                 {
 635                         if (bot_spawn() == NULL)
 636                         {
 637                                 bprint("Can not add bot, server full.\n");
 638                                 return false;
 639                         }
 640                 }
 641                 while (currentbots > bots && bots >= 0)
 642                         bot_removenewest();
 643         }
 644
 645         return true;
 646 }
 647
 648 void bot_remove_from_bot_list(entity this)
 649 {
 650         entity e = bot_list;
 651         entity prev_bot = NULL;
 652         while (e)
 653         {
 654                 if(e == this)
 655                 {
 656                         if(!prev_bot)
 657                                 bot_list = this.nextbot;
 658                         else
 659                                 prev_bot.nextbot = this.nextbot;
 660                         if(bot_strategytoken == this)
 661                         {
 662                                 bot_strategytoken = this.nextbot;
 663                                 bot_strategytoken_taken = true;
 664                         }
 665                         this.nextbot = NULL;
 666                         break;
 667                 }
 668                 prev_bot = e;
 669                 e = e.nextbot;
 670         }
 671 }
 672
 673 void bot_clear(entity this)
 674 {
 675         bot_remove_from_bot_list(this);
 676         if(bot_waypoint_queue_owner == this)
 677                 bot_waypoint_queue_owner = NULL;
 678         this.aistatus &= ~AI_STATUS_STUCK; // otherwise bot_waypoint_queue_owner will be set again to this by navigation_unstuck
 679 }
 680
 681 void bot_serverframe()
 682 {
 683         if (intermission_running && currentbots > 0)
 684         {
 685                 // after the end of the match all bots stay unless all human players disconnect
 686                 int realplayers = 0;
 687                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++realplayers; });
 688                 if (!realplayers)
 689                 {
 690                         FOREACH_CLIENT(IS_BOT_CLIENT(it), { dropclient(it); });
 691                         currentbots = 0;
 692                 }
 693                 return;
 694         }
 695
 696         if (game_stopped)
 697                 return;
 698
 699         // Added 0.5 to avoid possible addition + immediate removal of bots that would make them appear as
 700         // spectators in the scoreboard and never go away. This issue happens at time 2 if map is changed
 701         // with the gotomap command, minplayers is > 1 and human clients join as players very soon
 702         // either intentionally or automatically (sv_spectate 0)
 703         if (time < 2.5)
 704         {
 705                 currentbots = -1;
 706                 return;
 707         }
 708
 709         if (currentbots == -1)
 710         {
 711                 // count bots already in the server from the previous match
 712                 currentbots = 0;
 713                 FOREACH_CLIENT(IS_BOT_CLIENT(it), { ++currentbots; });
 714         }
 715
 716         if(autocvar_skill != skill)
 717         {
 718                 float wpcost_update = false;
 719                 if(skill >= autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill < autocvar_bot_ai_bunnyhop_skilloffset)
 720                         wpcost_update = true;
 721                 if(skill < autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 722                         wpcost_update = true;
 723
 724                 skill = autocvar_skill;
 725                 if (wpcost_update)
 726                         waypoint_updatecost_foralllinks();
 727         }
 728
 729         bot_calculate_stepheightvec();
 730         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 731
 732         if(time > autoskill_nextthink)
 733         {
 734                 float a;
 735                 a = autocvar_skill_auto;
 736                 if(a)
 737                         autoskill(a);
 738                 autoskill_nextthink = time + 5;
 739         }
 740
 741         if(time > botframe_nextthink)
 742         {
 743                 if(!bot_fixcount())
 744                         botframe_nextthink = time + 10;
 745         }
 746
 747         if(botframe_spawnedwaypoints)
 748         {
 749                 if(autocvar_waypoint_benchmark)
 750                         localcmd("quit\n");
 751         }
 752
 753         if (currentbots > 0 || autocvar_g_waypointeditor || autocvar_g_waypointeditor_auto)
 754         if (botframe_spawnedwaypoints)
 755         {
 756                 if(botframe_cachedwaypointlinks)
 757                 {
 758                         if(!botframe_loadedforcedlinks)
 759                                 waypoint_load_hardwiredlinks();
 760                 }
 761                 else
 762                 {
 763                         // TODO: Make this check cleaner
 764                         IL_EACH(g_waypoints, time - it.nextthink > 10,
 765                         {
 766                                 waypoint_save_links();
 767                                 break;
 768                         });
 769                 }
 770         }
 771         else
 772         {
 773                 botframe_spawnedwaypoints = true;
 774                 waypoint_loadall();
 775                 waypoint_load_links();
 776         }
 777
 778         if (bot_list)
 779         {
 780                 // cycle the goal token from one bot to the next each frame
 781                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 782                 //  frame, which causes choppy framerates)
 783                 if (bot_strategytoken_taken)
 784                 {
 785                         // give goal token to the first bot without goals; if all bots don't have
 786                         // any goal (or are dead/frozen) simply give it to the next one
 787                         bot_strategytoken_taken = false;
 788                         entity bot_strategytoken_save = bot_strategytoken;
 789                         while (true)
 790                         {
 791                                 if (bot_strategytoken)
 792                                         bot_strategytoken = bot_strategytoken.nextbot;
 793                                 if (!bot_strategytoken)
 794                                         bot_strategytoken = bot_list;
 795
 796                                 if (!(IS_DEAD(bot_strategytoken) || STAT(FROZEN, bot_strategytoken))
 797                                         && !bot_strategytoken.goalcurrent)
 798                                         break;
 799
 800                                 if (!bot_strategytoken_save) // break loop if all the bots are dead or frozen
 801                                         break;
 802                                 if (bot_strategytoken == bot_strategytoken_save)
 803                                         bot_strategytoken_save = NULL; // looped through all the bots
 804                         }
 805                 }
 806
 807                 if (botframe_nextdangertime < time)
 808                 {
 809                         float interval;
 810                         interval = autocvar_bot_ai_dangerdetectioninterval;
 811                         if (botframe_nextdangertime < time - interval * 1.5)
 812                                 botframe_nextdangertime = time;
 813                         botframe_nextdangertime = botframe_nextdangertime + interval;
 814                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
 815                 }
 816         }
 817
 818         if (autocvar_g_waypointeditor)
 819                 botframe_showwaypointlinks();
 820
 821         if (autocvar_g_waypointeditor_auto)
 822                 botframe_autowaypoints();
 823
 824         if (currentbots > 0)
 825                 bot_custom_weapon_priority_setup();
 826 }